CPAN is upstream for Time::Local again
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats. Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>. In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character. These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match. Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character. For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>. This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl 5.6, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional. C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s. These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore). No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs. C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors. A few other names are also
42 exempt in these ways:
43
44         ENV      STDIN
45         INC      STDOUT
46         ARGV     STDERR
47         ARGVOUT
48         SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl. Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60         use English;
61
62 at the top of your program. This aliases all the short names to the long
63 names in the current package. Some even have medium names, generally
64 borrowed from B<awk>. To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68         use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables. In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space. The following pairs are
87 equivalent:
88
89         while (<>) {...}    # equivalent only in while!
90         while (defined($_ = <>)) {...}
91
92         /^Subject:/
93         $_ =~ /^Subject:/
94
95         tr/a-z/A-Z/
96         $_ =~ tr/a-z/A-Z/
97
98         chomp
99         chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot, cos, defined, eval, exp, glob,
110 hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print,
111 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
112 rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst,
113 unlink, unpack.
114
115 =item *
116
117 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
118 See L<perlfunc/-X>
119
120 =item *
121
122 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
123 when used without an C<=~> operator.
124
125 =item *
126
127 The default iterator variable in a C<foreach> loop if no other
128 variable is supplied.
129
130 =item *
131
132 The implicit iterator variable in the C<grep()> and C<map()> functions.
133
134 =item *
135
136 The implicit variable of C<given()>.
137
138 =item *
139
140 The default place to put an input record when a C<< <FH> >>
141 operation's result is tested by itself as the sole criterion of a C<while>
142 test. Outside a C<while> test, this will not happen.
143
144 =back
145
146 As C<$_> is a global variable, this may lead in some cases to unwanted
147 side-effects. As of perl 5.9.1, you can now use a lexical version of
148 C<$_> by declaring it in a file or in a block with C<my>. Moreover,
149 declaring C<our $_> restores the global C<$_> in the current scope.
150
151 Mnemonic: underline is understood in certain operations.
152
153 =item @ARG
154
155 =item @_
156 X<@_> X<@ARG>
157
158 Within a subroutine the array C<@_> contains the parameters passed to
159 that subroutine. Inside a subroutine, C<@_> is the default array for
160 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
161
162 See L<perlsub>.
163
164 =item $LIST_SEPARATOR
165
166 =item $"
167 X<$"> X<$LIST_SEPARATOR>
168
169 When an array or an array slice is interpolated into a double-quoted
170 string or a similar context such as C</.../>, its elements are
171 separated by this value. Default is a space. For example, this:
172
173         print "The array is: @array\n";
174
175 is equivalent to this:
176
177         print "The array is: " . join($", @array) . "\n";
178
179 Mnemonic: works in double-quoted context.
180
181 =item $PROCESS_ID
182
183 =item $PID
184
185 =item $$
186 X<$$> X<$PID> X<$PROCESS_ID>
187
188 The process number of the Perl running this script. You should
189 consider this variable read-only, although it will be altered
190 across C<fork()> calls.
191
192 Note for Linux users: on Linux, the C functions C<getpid()> and
193 C<getppid()> return different values from different threads. In order to
194 be portable, this behavior is not reflected by C<$$>, whose value remains
195 consistent across threads. If you want to call the underlying C<getpid()>,
196 you may use the CPAN module C<Linux::Pid>.
197
198 Mnemonic: same as shells.
199
200 =item $REAL_GROUP_ID
201
202 =item $GID
203
204 =item $(
205 X<$(> X<$GID> X<$REAL_GROUP_ID>
206
207 The real gid of this process. If you are on a machine that supports
208 membership in multiple groups simultaneously, gives a space separated
209 list of groups you are in. The first number is the one returned by
210 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
211 the same as the first number.
212
213 However, a value assigned to C<$(> must be a single number used to
214 set the real gid. So the value given by C<$(> should I<not> be assigned
215 back to C<$(> without being forced numeric, such as by adding zero. Note
216 that this is different to the effective gid (C<$)>) which does take a
217 list.
218
219 You can change both the real gid and the effective gid at the same
220 time by using C<POSIX::setgid()>. Changes to C<$(> require a check to C<$!>
221 to detect any possible errors after an attempted change.
222
223 Mnemonic: parentheses are used to I<group> things. The real gid is the
224 group you I<left>, if you're running setgid.
225
226 =item $EFFECTIVE_GROUP_ID
227
228 =item $EGID
229
230 =item $)
231 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
232
233 The effective gid of this process. If you are on a machine that
234 supports membership in multiple groups simultaneously, gives a space
235 separated list of groups you are in. The first number is the one
236 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
237 one of which may be the same as the first number.
238
239 Similarly, a value assigned to C<$)> must also be a space-separated
240 list of numbers. The first number sets the effective gid, and
241 the rest (if any) are passed to C<setgroups()>. To get the effect of an
242 empty list for C<setgroups()>, just repeat the new effective gid; that is,
243 to force an effective gid of 5 and an effectively empty C<setgroups()>
244 list, say C< $) = "5 5" >.
245
246 You can change both the effective gid and the real gid at the same
247 time by using C<POSIX::setgid()> (use only a single numeric argument).
248 Changes to C<$)> require a check to C<$!> to detect any possible errors
249 after an attempted change.
250
251 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
252 machines that support the corresponding I<set[re][ug]id()> routine. C<$(>
253 and C<$)> can be swapped only on machines supporting C<setregid()>.
254
255 Mnemonic: parentheses are used to I<group> things. The effective gid
256 is the group that's I<right> for you, if you're running setgid.
257
258 =item $PROGRAM_NAME
259
260 =item $0
261 X<$0> X<$PROGRAM_NAME>
262
263 Contains the name of the program being executed.
264
265 On some (but not all) operating systems assigning to C<$0> modifies
266 the argument area that the C<ps> program sees. On some platforms you
267 may have to use special C<ps> options or a different C<ps> to see the
268 changes. Modifying the C<$0> is more useful as a way of indicating the
269 current program state than it is for hiding the program you're
270 running.
271
272 Note that there are platform-specific limitations on the maximum
273 length of C<$0>. In the most extreme case it may be limited to the
274 space occupied by the original C<$0>.
275
276 In some platforms there may be arbitrary amount of padding, for
277 example space characters, after the modified name as shown by C<ps>.
278 In some platforms this padding may extend all the way to the original
279 length of the argument area, no matter what you do (this is the case
280 for example with Linux 2.2).
281
282 Note for BSD users: setting C<$0> does not completely remove "perl"
283 from the ps(1) output. For example, setting C<$0> to C<"foobar"> may
284 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
285 and the " (perl)" suffix are shown depends on your exact BSD variant
286 and version). This is an operating system feature, Perl cannot help it.
287
288 In multithreaded scripts Perl coordinates the threads so that any
289 thread may modify its copy of the C<$0> and the change becomes visible
290 to ps(1) (assuming the operating system plays along). Note that
291 the view of C<$0> the other threads have will not change since they
292 have their own copies of it.
293
294 If the program has been given to perl via the switches C<-e> or C<-E>,
295 C<$0> will contain the string C<"-e">.
296
297 On Linux as of perl 5.14 the legacy process name will be set with
298 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
299 perl has done since version 4.000. Now system utilities that read the
300 legacy process name such as ps, top and killall will recognize the
301 name you set when assigning to C<$0>. The string you supply will be
302 cut off at 16 bytes, this is a limitation imposed by Linux.
303
304 Mnemonic: same as B<sh> and B<ksh>.
305
306 =item $SUBSCRIPT_SEPARATOR
307
308 =item $SUBSEP
309
310 =item $;
311 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
312
313 The subscript separator for multidimensional array emulation. If you
314 refer to a hash element as
315
316         $foo{$a,$b,$c}
317
318 it really means
319
320         $foo{join($;, $a, $b, $c)}
321
322 But don't put
323
324         @foo{$a,$b,$c}  # a slice--note the @
325
326 which means
327
328         ($foo{$a},$foo{$b},$foo{$c})
329
330 Default is "\034", the same as SUBSEP in B<awk>. If your keys contain
331 binary data there might not be any safe value for C<$;>.
332
333 Consider using "real" multidimensional arrays as described
334 in L<perllol>.
335
336 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
337
338 =item $REAL_USER_ID
339
340 =item $UID
341
342 =item $<
343 X<< $< >> X<$UID> X<$REAL_USER_ID>
344
345 The real uid of this process. You can change both the real uid and the
346 effective uid at the same time by using C<POSIX::setuid()>. Since
347 changes to C<< $< >> require a system call, check C<$!> after a change
348 attempt to detect any possible errors.
349
350 Mnemonic: it's the uid you came I<from>, if you're running setuid.
351
352 =item $EFFECTIVE_USER_ID
353
354 =item $EUID
355
356 =item $>
357 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
358
359 The effective uid of this process. For example:
360
361         $< = $>;            # set real to effective uid
362         ($<,$>) = ($>,$<);  # swap real and effective uids
363
364 You can change both the effective uid and the real uid at the same
365 time by using C<POSIX::setuid()>. Changes to C<< $> >> require a check
366 to C<$!> to detect any possible errors after an attempted change.
367
368 C<< $< >> and C<< $> >> can be swapped only on machines
369 supporting C<setreuid()>.
370
371 Mnemonic: it's the uid you went I<to>, if you're running setuid.
372
373 =item $a
374
375 =item $b
376 X<$a> X<$b>
377
378 Special package variables when using C<sort()>, see L<perlfunc/sort>.
379 Because of this specialness C<$a> and C<$b> don't need to be declared
380 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
381 pragma. Don't lexicalize them with C<my $a> or C<my $b> if you want to
382 be able to use them in the C<sort()> comparison block or function.
383
384 =item $COMPILING
385
386 =item $^C
387 X<$^C> X<$COMPILING>
388
389 The current value of the flag associated with the B<-c> switch.
390 Mainly of use with B<-MO=...> to allow code to alter its behavior
391 when being compiled, such as for example to C<AUTOLOAD> at compile
392 time rather than normal, deferred loading. Setting
393 C<$^C = 1> is similar to calling C<B::minus_c>.
394
395 This variable was added in Perl 5.6.
396
397 =item $DEBUGGING
398
399 =item $^D
400 X<$^D> X<$DEBUGGING>
401
402 The current value of the debugging flags. May be read or set. Like its
403 command-line equivalent, you can use numeric or symbolic values, eg
404 C<$^D = 10> or C<$^D = "st">.
405
406 Mnemonic: value of B<-D> switch.
407
408 =item ${^ENCODING}
409 X<${^ENCODING}>
410
411 The I<object reference> to the C<Encode> object that is used to convert
412 the source code to Unicode. Thanks to this variable your Perl script
413 does not have to be written in UTF-8. Default is I<undef>. The direct
414 manipulation of this variable is highly discouraged.
415
416 This variable was added in Perl 5.8.2.
417
418 =item %ENV
419 X<%ENV>
420
421 The hash C<%ENV> contains your current environment. Setting a
422 value in C<ENV> changes the environment for any child processes
423 you subsequently C<fork()> off.
424
425 =item $SYSTEM_FD_MAX
426
427 =item $^F
428 X<$^F> X<$SYSTEM_FD_MAX>
429
430 The maximum system file descriptor, ordinarily 2. System file
431 descriptors are passed to C<exec()>ed processes, while higher file
432 descriptors are not. Also, during an C<open()>, system file descriptors are
433 preserved even if the C<open()> fails (ordinary file descriptors are
434 closed before the C<open()> is attempted). The close-on-exec
435 status of a file descriptor will be decided according to the value of
436 C<$^F> when the corresponding file, pipe, or socket was opened, not the
437 time of the C<exec()>.
438
439 =item @F
440 X<@F>
441
442 The array C<@F> contains the fields of each line read in when autosplit
443 mode is turned on. See L<perlrun> for the B<-a> switch. This array
444 is package-specific, and must be declared or given a full package name
445 if not in package main when running under C<strict 'vars'>.
446
447 =item ${^GLOBAL_PHASE}
448 X<${^GLOBAL_PHASE}>
449
450 The current phase of the perl interpreter.
451
452 Possible values are:
453
454 =over 8
455
456 =item CONSTRUCT
457
458 The C<PerlInterpreter*> is being constructed via C<perl_construct>. This
459 value is mostly there for completeness and for use via the
460 underlying C variable C<PL_phase>. It's not really possible for Perl
461 code to be executed unless construction of the interpreter is
462 finished.
463
464 =item START
465
466 This is the global compile-time. That includes, basically, every
467 C<BEGIN> block executed directly or indirectly from during the
468 compile-time of the top-level program.
469
470 This phase is not called "BEGIN" to avoid confusion with
471 C<BEGIN>-blocks, as those are executed during compile-time of any
472 compilation unit, not just the top-level program. A new, localised
473 compile-time entered at run-time, for example by constructs as
474 C<eval "use SomeModule"> are not global interpreter phases, and
475 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
476
477 =item CHECK
478
479 Execution of any C<CHECK> blocks.
480
481 =item INIT
482
483 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
484
485 =item RUN
486
487 The main run-time, i.e. the execution of C<PL_main_root>.
488
489 =item END
490
491 Execution of any C<END> blocks.
492
493 =item DESTRUCT
494
495 Global destruction.
496
497 =back
498
499 Also note that there's no value for UNITCHECK-blocks. That's because
500 those are run for each compilation unit individually, and therefore is
501 not a global interpreter phase.
502
503 Not every program has to go through each of the possible phases, but
504 transition from one phase to another can only happen in the order
505 described in the above list.
506
507 An example of all of the phases Perl code can see:
508
509     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
510
511     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
512
513     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
514
515     {
516         package Print::Phase;
517
518         sub new {
519             my ($class, $time) = @_;
520             return bless \$time, $class;
521         }
522
523         sub DESTROY {
524             my $self = shift;
525             print "$$self: ${^GLOBAL_PHASE}\n";
526         }
527     }
528
529     print "run-time: ${^GLOBAL_PHASE}\n";
530
531     my $runtime = Print::Phase->new(
532         "lexical variables are garbage collected before END"
533     );
534
535     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
536
537     our $destruct = Print::Phase->new(
538         "package variables are garbage collected after END"
539     );
540
541 This will print out
542
543     compile-time: START
544     check-time: CHECK
545     init-time: INIT
546     run-time: RUN
547     lexical variables are garbage collected before END: RUN
548     end-time: END
549     package variables are garbage collected after END: DESTRUCT
550
551 This variable was added in Perl 5.14.0.
552
553 =item $^H
554 X<$^H>
555
556 WARNING: This variable is strictly for internal use only. Its availability,
557 behavior, and contents are subject to change without notice.
558
559 This variable contains compile-time hints for the Perl interpreter. At the
560 end of compilation of a BLOCK the value of this variable is restored to the
561 value when the interpreter started to compile the BLOCK.
562
563 When perl begins to parse any block construct that provides a lexical scope
564 (e.g., eval body, required file, subroutine body, loop body, or conditional
565 block), the existing value of C<$^H> is saved, but its value is left unchanged.
566 When the compilation of the block is completed, it regains the saved value.
567 Between the points where its value is saved and restored, code that
568 executes within BEGIN blocks is free to change the value of C<$^H>.
569
570 This behavior provides the semantic of lexical scoping, and is used in,
571 for instance, the C<use strict> pragma.
572
573 The contents should be an integer; different bits of it are used for
574 different pragmatic flags. Here's an example:
575
576         sub add_100 { $^H |= 0x100 }
577
578         sub foo {
579                 BEGIN { add_100() }
580                 bar->baz($boon);
581         }
582
583 Consider what happens during execution of the BEGIN block. At this point
584 the BEGIN block has already been compiled, but the body of C<foo()> is still
585 being compiled. The new value of C<$^H> will therefore be visible only while
586 the body of C<foo()> is being compiled.
587
588 Substitution of C<BEGIN { add_100() }> block with:
589
590         BEGIN { require strict; strict->import('vars') }
591
592 demonstrates how C<use strict 'vars'> is implemented. Here's a conditional
593 version of the same lexical pragma:
594
595         BEGIN { require strict; strict->import('vars') if $condition }
596
597 This variable was added in Perl 5.003.
598
599 =item %^H
600 X<%^H>
601
602 The C<%^H> hash provides the same scoping semantic as C<$^H>. This makes it
603 useful for implementation of lexically scoped pragmas. See L<perlpragma>.
604
605 This variable was added in Perl 5.6.
606
607 =item @INC
608 X<@INC>
609
610 The array C<@INC> contains the list of places that the C<do EXPR>,
611 C<require>, or C<use> constructs look for their library files. It
612 initially consists of the arguments to any B<-I> command-line
613 switches, followed by the default Perl library, probably
614 F</usr/local/lib/perl>, followed by ".", to represent the current
615 directory. ("." will not be appended if taint checks are enabled,
616 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
617 you should use the C<use lib> pragma to get the machine-dependent
618 library properly loaded also:
619
620         use lib '/mypath/libdir/';
621         use SomeMod;
622
623 You can also insert hooks into the file inclusion system by putting Perl
624 code directly into C<@INC>. Those hooks may be subroutine references, array
625 references or blessed objects. See L<perlfunc/require> for details.
626
627 =item %INC
628 X<%INC>
629
630 The hash C<%INC> contains entries for each filename included via the
631 C<do>, C<require>, or C<use> operators. The key is the filename
632 you specified (with module names converted to pathnames), and the
633 value is the location of the file found. The C<require>
634 operator uses this hash to determine whether a particular file has
635 already been included.
636
637 If the file was loaded via a hook (e.g. a subroutine reference, see
638 L<perlfunc/require> for a description of these hooks), this hook is
639 by default inserted into C<%INC> in place of a filename. Note, however,
640 that the hook may have set the C<%INC> entry by itself to provide some more
641 specific info.
642
643 =item $INPLACE_EDIT
644
645 =item $^I
646 X<$^I> X<$INPLACE_EDIT>
647
648 The current value of the inplace-edit extension. Use C<undef> to disable
649 inplace editing.
650
651 Mnemonic: value of B<-i> switch.
652
653 =item $^M
654 X<$^M>
655
656 By default, running out of memory is an untrappable, fatal error.
657 However, if suitably built, Perl can use the contents of C<$^M>
658 as an emergency memory pool after C<die()>ing. Suppose that your Perl
659 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
660 Then
661
662         $^M = 'a' x (1 << 16);
663
664 would allocate a 64K buffer for use in an emergency. See the
665 F<INSTALL> file in the Perl distribution for information on how to
666 add custom C compilation flags when compiling perl. To discourage casual
667 use of this advanced feature, there is no L<English|English> long name for
668 this variable.
669
670 This variable was added in Perl 5.004.
671
672 =item $OSNAME
673
674 =item $^O
675 X<$^O> X<$OSNAME>
676
677 The name of the operating system under which this copy of Perl was
678 built, as determined during the configuration process. For examples
679 see L<perlport/PLATFORMS>.
680
681 The value is identical to C<$Config{'osname'}>. See also L<Config>
682 and the B<-V> command-line switch documented in L<perlrun>.
683
684 In Windows platforms, C<$^O> is not very helpful: since it is always
685 C<MSWin32>, it doesn't tell the difference between
686 95/98/ME/NT/2000/XP/CE/.NET. Use C<Win32::GetOSName()> or
687 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
688 between the variants.
689
690 This variable was added in Perl 5.003.
691
692 =item ${^OPEN}
693 X<${^OPEN}>
694
695 An internal variable used by PerlIO. A string in two parts, separated
696 by a C<\0> byte, the first part describes the input layers, the second
697 part describes the output layers.
698
699 This variable was added in Perl 5.8.2.
700
701 =item $PERLDB
702
703 =item $^P
704 X<$^P> X<$PERLDB>
705
706 The internal variable for debugging support. The meanings of the
707 various bits are subject to change, but currently indicate:
708
709 =over 6
710
711 =item 0x01
712
713 Debug subroutine enter/exit.
714
715 =item 0x02
716
717 Line-by-line debugging. Causes C<DB::DB()> subroutine to be called for each
718 statement executed. Also causes saving source code lines (like 0x400).
719
720 =item 0x04
721
722 Switch off optimizations.
723
724 =item 0x08
725
726 Preserve more data for future interactive inspections.
727
728 =item 0x10
729
730 Keep info about source lines on which a subroutine is defined.
731
732 =item 0x20
733
734 Start with single-step on.
735
736 =item 0x40
737
738 Use subroutine address instead of name when reporting.
739
740 =item 0x80
741
742 Report C<goto &subroutine> as well.
743
744 =item 0x100
745
746 Provide informative "file" names for evals based on the place they were compiled.
747
748 =item 0x200
749
750 Provide informative names to anonymous subroutines based on the place they
751 were compiled.
752
753 =item 0x400
754
755 Save source code lines into C<@{"_<$filename"}>.
756
757 =back
758
759 Some bits may be relevant at compile-time only, some at
760 run-time only. This is a new mechanism and the details may change.
761 See also L<perldebguts>.
762
763 =item %SIG
764 X<%SIG>
765
766 The hash C<%SIG> contains signal handlers for signals. For example:
767
768         sub handler {   # 1st argument is signal name
769                 my($sig) = @_;
770                 print "Caught a SIG$sig--shutting down\n";
771                 close(LOG);
772                 exit(0);
773                 }
774
775         $SIG{'INT'}  = \&handler;
776         $SIG{'QUIT'} = \&handler;
777         ...
778         $SIG{'INT'}  = 'DEFAULT';   # restore default action
779         $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
780
781 Using a value of C<'IGNORE'> usually has the effect of ignoring the
782 signal, except for the C<CHLD> signal. See L<perlipc> for more about
783 this special case.
784
785 Here are some other examples:
786
787         $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
788         $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
789         $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
790         $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
791
792 Be sure not to use a bareword as the name of a signal handler,
793 lest you inadvertently call it.
794
795 If your system has the C<sigaction()> function then signal handlers
796 are installed using it. This means you get reliable signal handling.
797
798 The default delivery policy of signals changed in Perl 5.8.0 from
799 immediate (also known as "unsafe") to deferred, also known as "safe
800 signals". See L<perlipc> for more information.
801
802 Certain internal hooks can be also set using the C<%SIG> hash. The
803 routine indicated by C<$SIG{__WARN__}> is called when a warning
804 message is about to be printed. The warning message is passed as the
805 first argument. The presence of a C<__WARN__> hook causes the
806 ordinary printing of warnings to C<STDERR> to be suppressed. You can
807 use this to save warnings in a variable, or turn warnings into fatal
808 errors, like this:
809
810         local $SIG{__WARN__} = sub { die $_[0] };
811         eval $proggie;
812
813 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
814 disable warnings using the empty subroutine:
815
816         local $SIG{__WARN__} = sub {};
817
818 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
819 exception is about to be thrown. The error message is passed as the
820 first argument. When a C<__DIE__> hook routine returns, the exception
821 processing continues as it would have in the absence of the hook,
822 unless the hook routine itself exits via a C<goto>, a loop exit, or a
823 C<die()>. The C<__DIE__> handler is explicitly disabled during the
824 call, so that you can die from a C<__DIE__> handler. Similarly for
825 C<__WARN__>.
826
827 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
828 even inside an C<eval()>. Do not use this to rewrite a pending
829 exception in C<$@>, or as a bizarre substitute for overriding
830 C<CORE::GLOBAL::die()>. This strange action at a distance may be fixed
831 in a future release so that C<$SIG{__DIE__}> is only called if your
832 program is about to exit, as was the original intent. Any other use is
833 deprecated.
834
835 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
836 may be called to report (probable) errors found by the parser. In such
837 a case the parser may be in inconsistent state, so any attempt to
838 evaluate Perl code from such a handler will probably result in a
839 segfault. This means that warnings or errors that result from parsing
840 Perl should be used with extreme caution, like this:
841
842         require Carp if defined $^S;
843         Carp::confess("Something wrong") if defined &Carp::confess;
844         die "Something wrong, but could not load Carp to give backtrace...
845            To see backtrace try starting Perl with -MCarp switch";
846
847 Here the first line will load C<Carp> I<unless> it is the parser who
848 called the handler. The second line will print backtrace and die if
849 C<Carp> was available. The third line will be executed only if C<Carp> was
850 not available.
851
852 Having to even think about the C<$^S> variable in your exception
853 handlers is simply wrong. C<$SIG{__DIE__}> as currently implemented
854 invites grievous and difficult to track down errors. Avoid it
855 and use an C<END{}> or CORE::GLOBAL::die override instead.
856
857 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
858 L<warnings> for additional information.
859
860 =item $BASETIME
861
862 =item $^T
863 X<$^T> X<$BASETIME>
864
865 The time at which the program began running, in seconds since the
866 epoch (beginning of 1970). The values returned by the B<-M>, B<-A>,
867 and B<-C> filetests are based on this value.
868
869 =item ${^TAINT}
870 X<${^TAINT}>
871
872 Reflects if taint mode is on or off. 1 for on (the program was run with
873 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
874 B<-t> or B<-TU>).
875
876 This variable is read-only.
877
878 This variable was added in Perl 5.8.
879
880 =item ${^UNICODE}
881 X<${^UNICODE}>
882
883 Reflects certain Unicode settings of Perl. See L<perlrun>
884 documentation for the C<-C> switch for more information about
885 the possible values.
886
887 This variable is set during Perl startup and is thereafter read-only.
888
889 This variable was added in Perl 5.8.2.
890
891 =item ${^UTF8CACHE}
892 X<${^UTF8CACHE}>
893
894 This variable controls the state of the internal UTF-8 offset caching code.
895 1 for on (the default), 0 for off, -1 to debug the caching code by checking
896 all its results against linear scans, and panicking on any discrepancy.
897
898 This variable was added in Perl 5.8.9.
899
900 =item ${^UTF8LOCALE}
901 X<${^UTF8LOCALE}>
902
903 This variable indicates whether a UTF-8 locale was detected by perl at
904 startup. This information is used by perl when it's in
905 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
906 switch); see L<perlrun> for more info on this.
907
908 This variable was added in Perl 5.8.8.
909
910 =item $PERL_VERSION
911
912 =item $^V
913 X<$^V> X<$PERL_VERSION>
914
915 The revision, version, and subversion of the Perl interpreter,
916 represented as a C<version> object.
917
918 This variable first appeared in perl 5.6.0; earlier versions of perl
919 will see an undefined value. Before perl 5.10.0 C<$^V> was represented
920 as a v-string.
921
922 C<$^V> can be used to determine whether the Perl interpreter executing
923 a script is in the right range of versions. For example:
924
925         warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
926
927 To convert C<$^V> into its string representation use C<sprintf()>'s
928 C<"%vd"> conversion:
929
930         printf "version is v%vd\n", $^V;  # Perl's version
931
932 See the documentation of C<use VERSION> and C<require VERSION>
933 for a convenient way to fail if the running Perl interpreter is too old.
934
935 See also C<$]> for an older representation of the Perl version.
936
937 This variable was added in Perl 5.6.
938
939 Mnemonic: use ^V for Version Control.
940
941 =item ${^WIN32_SLOPPY_STAT}
942 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
943
944 If this variable is set to a true value, then C<stat()> on Windows will
945 not try to open the file. This means that the link count cannot be
946 determined and file attributes may be out of date if additional
947 hardlinks to the file exist. On the other hand, not opening the file
948 is considerably faster, especially for files on network drives.
949
950 This variable could be set in the F<sitecustomize.pl> file to
951 configure the local Perl installation to use "sloppy" C<stat()> by
952 default. See the documentation for B<-f> in
953 L<perlrun|perlrun/"Command Switches"> for more information about site
954 customization.
955
956 This variable was added in Perl 5.10.
957
958 =item $EXECUTABLE_NAME
959
960 =item $^X
961 X<$^X> X<$EXECUTABLE_NAME>
962
963 The name used to execute the current copy of Perl, from C's
964 C<argv[0]> or (where supported) F</proc/self/exe>.
965
966 Depending on the host operating system, the value of C<$^X> may be
967 a relative or absolute pathname of the perl program file, or may
968 be the string used to invoke perl but not the pathname of the
969 perl program file. Also, most operating systems permit invoking
970 programs that are not in the PATH environment variable, so there
971 is no guarantee that the value of C<$^X> is in PATH. For VMS, the
972 value may or may not include a version number.
973
974 You usually can use the value of C<$^X> to re-invoke an independent
975 copy of the same perl that is currently running, e.g.,
976
977         @first_run = `$^X -le "print int rand 100 for 1..100"`;
978
979 But recall that not all operating systems support forking or
980 capturing of the output of commands, so this complex statement
981 may not be portable.
982
983 It is not safe to use the value of C<$^X> as a path name of a file,
984 as some operating systems that have a mandatory suffix on
985 executable files do not require use of the suffix when invoking
986 a command. To convert the value of C<$^X> to a path name, use the
987 following statements:
988
989         # Build up a set of file names (not command names).
990         use Config;
991         my $this_perl = $^X;
992         if ($^O ne 'VMS') {
993                 $this_perl .= $Config{_exe}
994                   unless $this_perl =~ m/$Config{_exe}$/i;
995                 }
996
997 Because many operating systems permit anyone with read access to
998 the Perl program file to make a copy of it, patch the copy, and
999 then execute the copy, the security-conscious Perl programmer
1000 should take care to invoke the installed copy of perl, not the
1001 copy referenced by C<$^X>. The following statements accomplish
1002 this goal, and produce a pathname that can be invoked as a
1003 command or referenced as a file.
1004
1005         use Config;
1006         my $secure_perl_path = $Config{perlpath};
1007         if ($^O ne 'VMS') {
1008                 $secure_perl_path .= $Config{_exe}
1009                         unless $secure_perl_path =~ m/$Config{_exe}$/i;
1010                 }
1011
1012 =back
1013
1014 =head2 Variables related to regular expressions
1015
1016 Most of the special variables related to regular expressions are side
1017 effects. Perl sets these variables when it has a successful match, so
1018 you should check the match result before using them. For instance:
1019
1020         if( /P(A)TT(ER)N/ ) {
1021                 print "I found $1 and $2\n";
1022                 }
1023
1024 These variables are read-only and dynamically-scoped, unless we note
1025 otherwise.
1026
1027 The dynamic nature of the regular expression variables means that
1028 their value is limited to the block that they are in, as demonstrated
1029 by this bit of code:
1030
1031         my $outer = 'Wallace and Grommit';
1032         my $inner = 'Mutt and Jeff';
1033
1034         my $pattern = qr/(\S+) and (\S+)/;
1035
1036         sub show_n { print "\$1 is $1; \$2 is $2\n" }
1037
1038         {
1039         OUTER:
1040                 show_n() if $outer =~ m/$pattern/;
1041
1042                 INNER: {
1043                         show_n() if $inner =~ m/$pattern/;
1044                         }
1045
1046                 show_n();
1047         }
1048
1049 The output shows that while in the C<OUTER> block, the values of C<$1>
1050 and C<$2> are from the match against C<$outer>. Inside the C<INNER>
1051 block, the values of C<$1> and C<$2> are from the match against
1052 C<$inner>, but only until the end of the block (i.e. the dynamic
1053 scope). After the C<INNER> block completes, the values of C<$1> and
1054 C<$2> return to the values for the match against C<$outer> even though
1055 we have not made another match:
1056
1057         $1 is Wallace; $2 is Grommit
1058         $1 is Mutt; $2 is Jeff
1059         $1 is Wallace; $2 is Grommit
1060
1061 Due to an unfortunate accident of Perl's implementation, C<use
1062 English> imposes a considerable performance penalty on all regular
1063 expression matches in a program because it uses the C<$`>, C<$&>, and
1064 C<$'>, regardless of whether they occur in the scope of C<use
1065 English>. For that reason, saying C<use English> in libraries is
1066 strongly discouraged unless you import it without the match variables:
1067
1068         use English '-no_match_vars'
1069
1070 The C<Devel::NYTProf> module can help you find uses of these
1071 problematic match variables in your code.
1072
1073 Since Perl 5.10, you can use the C</p> match operator flag and the
1074 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
1075 so you only suffer the performance penalties.
1076
1077 =over 8
1078
1079 =item $<I<digits>> ($1, $2, ...)
1080 X<$1> X<$2> X<$3>
1081
1082 Contains the subpattern from the corresponding set of capturing
1083 parentheses from the last successful pattern match, not counting patterns
1084 matched in nested blocks that have been exited already.
1085
1086 These variables are read-only and dynamically-scoped.
1087
1088 Mnemonic: like \digits.
1089
1090 =item $MATCH
1091
1092 =item $&
1093 X<$&> X<$MATCH>
1094
1095 The string matched by the last successful pattern match (not counting
1096 any matches hidden within a BLOCK or C<eval()> enclosed by the current
1097 BLOCK).
1098
1099 The use of this variable anywhere in a program imposes a considerable
1100 performance penalty on all regular expression matches. To avoid this
1101 penalty, you can extract the same substring by using L</@->. Starting
1102 with Perl 5.10, you can use the </p> match flag and the C<${^MATCH}>
1103 variable to do the same thing for particular match operations.
1104
1105 This variable is read-only and dynamically-scoped.
1106
1107 Mnemonic: like C<&> in some editors.
1108
1109 =item ${^MATCH}
1110 X<${^MATCH}>
1111
1112 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
1113 performance penalty associated with that variable, and is only guaranteed
1114 to return a defined value when the pattern was compiled or executed with
1115 the C</p> modifier.
1116
1117 This variable was added in Perl 5.10.
1118
1119 This variable is read-only and dynamically-scoped.
1120
1121 =item $PREMATCH
1122
1123 =item $`
1124 X<$`> X<$PREMATCH> X<${^PREMATCH}>
1125
1126 The string preceding whatever was matched by the last successful
1127 pattern match, not counting any matches hidden within a BLOCK or C<eval>
1128 enclosed by the current BLOCK.
1129
1130 The use of this variable anywhere in a program imposes a considerable
1131 performance penalty on all regular expression matches. To avoid this
1132 penalty, you can extract the same substring by using L</@->. Starting
1133 with Perl 5.10, you can use the </p> match flag and the
1134 C<${^PREMATCH}> variable to do the same thing for particular match
1135 operations.
1136
1137 This variable is read-only and dynamically-scoped.
1138
1139 Mnemonic: C<`> often precedes a quoted string.
1140
1141 =item ${^PREMATCH}
1142 X<$`> X<${^PREMATCH}>
1143
1144 This is similar to C<$`> ($PREMATCH) except that it does not incur the
1145 performance penalty associated with that variable, and is only guaranteed
1146 to return a defined value when the pattern was compiled or executed with
1147 the C</p> modifier.
1148
1149 This variable was added in Perl 5.10
1150
1151 This variable is read-only and dynamically-scoped.
1152
1153 =item $POSTMATCH
1154
1155 =item $'
1156 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
1157
1158 The string following whatever was matched by the last successful
1159 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
1160 enclosed by the current BLOCK). Example:
1161
1162         local $_ = 'abcdefghi';
1163         /def/;
1164         print "$`:$&:$'\n";     # prints abc:def:ghi
1165
1166 The use of this variable anywhere in a program imposes a considerable
1167 performance penalty on all regular expression matches.
1168 To avoid this penalty, you can extract the same substring by
1169 using L</@->. Starting with Perl 5.10, you can use the </p> match flag
1170 and the C<${^POSTMATCH}> variable to do the same thing for particular
1171 match operations.
1172
1173 This variable is read-only and dynamically-scoped.
1174
1175 Mnemonic: C<'> often follows a quoted string.
1176
1177 =item ${^POSTMATCH}
1178 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
1179
1180 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
1181 performance penalty associated with that variable, and is only guaranteed
1182 to return a defined value when the pattern was compiled or executed with
1183 the C</p> modifier.
1184
1185 This variable was added in Perl 5.10.
1186
1187 This variable is read-only and dynamically-scoped.
1188
1189 =item $LAST_PAREN_MATCH
1190
1191 =item $+
1192 X<$+> X<$LAST_PAREN_MATCH>
1193
1194 The text matched by the last bracket of the last successful search pattern.
1195 This is useful if you don't know which one of a set of alternative patterns
1196 matched. For example:
1197
1198         /Version: (.*)|Revision: (.*)/ && ($rev = $+);
1199
1200 This variable is read-only and dynamically-scoped.
1201
1202 Mnemonic: be positive and forward looking.
1203
1204 =item $LAST_SUBMATCH_RESULT
1205
1206 =item $^N
1207 X<$^N> X<$LAST_SUBMATCH_RESULT>
1208
1209 The text matched by the used group most-recently closed (i.e. the group
1210 with the rightmost closing parenthesis) of the last successful search
1211 pattern.
1212
1213 This is primarily used inside C<(?{...})> blocks for examining text
1214 recently matched. For example, to effectively capture text to a variable
1215 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
1216
1217         (?:(...)(?{ $var = $^N }))
1218
1219 By setting and then using C<$var> in this way relieves you from having to
1220 worry about exactly which numbered set of parentheses they are.
1221
1222 This variable was added in Perl 5.8.
1223
1224 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
1225
1226 =item @LAST_MATCH_END
1227
1228 =item @+
1229 X<@+> X<@LAST_MATCH_END>
1230
1231 This array holds the offsets of the ends of the last successful
1232 submatches in the currently active dynamic scope. C<$+[0]> is
1233 the offset into the string of the end of the entire match. This
1234 is the same value as what the C<pos> function returns when called
1235 on the variable that was matched against. The I<n>th element
1236 of this array holds the offset of the I<n>th submatch, so
1237 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
1238 past where C<$2> ends, and so on. You can use C<$#+> to determine
1239 how many subgroups were in the last successful match. See the
1240 examples given for the C<@-> variable.
1241
1242 This variable was added in Perl 5.6.
1243
1244 =item %LAST_PAREN_MATCH
1245
1246 =item %+
1247 X<%+> X<%LAST_PAREN_MATCH>
1248
1249 Similar to C<@+>, the C<%+> hash allows access to the named capture
1250 buffers, should they exist, in the last successful match in the
1251 currently active dynamic scope.
1252
1253 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
1254
1255         'foo' =~ /(?<foo>foo)/;
1256
1257 The keys of the C<%+> hash list only the names of buffers that have
1258 captured (and that are thus associated to defined values).
1259
1260 The underlying behaviour of C<%+> is provided by the
1261 L<Tie::Hash::NamedCapture> module.
1262
1263 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1264 associated with the last successful regular expression. Therefore mixing
1265 iterative access to them via C<each> may have unpredictable results.
1266 Likewise, if the last successful match changes, then the results may be
1267 surprising.
1268
1269 This variable was added in Perl 5.10.
1270
1271 This variable is read-only and dynamically-scoped.
1272
1273 =item @LAST_MATCH_START
1274
1275 =item @-
1276 X<@-> X<@LAST_MATCH_START>
1277
1278 C<$-[0]> is the offset of the start of the last successful match.
1279 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
1280 I<n>-th subpattern, or undef if the subpattern did not match.
1281
1282 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
1283 $+[0] - $-[0]>. Similarly, $I<n> coincides with C<substr $_, $-[n],
1284 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1285 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>. One can use C<$#-> to find the last
1286 matched subgroup in the last successful match. Contrast with
1287 C<$#+>, the number of subgroups in the regular expression. Compare
1288 with C<@+>.
1289
1290 This array holds the offsets of the beginnings of the last
1291 successful submatches in the currently active dynamic scope.
1292 C<$-[0]> is the offset into the string of the beginning of the
1293 entire match. The I<n>th element of this array holds the offset
1294 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1295 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1296
1297 After a match against some variable C<$var>:
1298
1299 =over 5
1300
1301 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1302
1303 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1304
1305 =item C<$'> is the same as C<substr($var, $+[0])>
1306
1307 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1308
1309 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1310
1311 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1312
1313 =back
1314
1315 This variable was added in Perl 5.6.
1316
1317 =item %LAST_MATCH_START
1318
1319 =item %-
1320 X<%-> X<%LAST_MATCH_START>
1321
1322 Similar to C<%+>, this variable allows access to the named capture groups
1323 in the last successful match in the currently active dynamic scope. To
1324 each capture group name found in the regular expression, it associates a
1325 reference to an array containing the list of values captured by all
1326 buffers with that name (should there be several of them), in the order
1327 where they appear.
1328
1329 Here's an example:
1330
1331     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1332         foreach my $bufname (sort keys %-) {
1333             my $ary = $-{$bufname};
1334             foreach my $idx (0..$#$ary) {
1335                 print "\$-{$bufname}[$idx] : ",
1336                       (defined($ary->[$idx]) ? "'$ary->[$idx]'" : "undef"),
1337                       "\n";
1338             }
1339         }
1340     }
1341
1342 would print out:
1343
1344         $-{A}[0] : '1'
1345         $-{A}[1] : '3'
1346         $-{B}[0] : '2'
1347         $-{B}[1] : '4'
1348
1349 The keys of the C<%-> hash correspond to all buffer names found in
1350 the regular expression.
1351
1352 The behaviour of C<%-> is implemented via the
1353 L<Tie::Hash::NamedCapture> module.
1354
1355 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1356 associated with the last successful regular expression. Therefore mixing
1357 iterative access to them via C<each> may have unpredictable results.
1358 Likewise, if the last successful match changes, then the results may be
1359 surprising.
1360
1361 This variable was added in Perl 5.10
1362
1363 This variable is read-only and dynamically-scoped.
1364
1365 =item $LAST_REGEXP_CODE_RESULT
1366
1367 =item $^R
1368 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1369
1370 The result of evaluation of the last successful C<(?{ code })>
1371 regular expression assertion (see L<perlre>). May be written to.
1372
1373 This variable was added in Perl 5.005.
1374
1375 =item ${^RE_DEBUG_FLAGS}
1376 X<${^RE_DEBUG_FLAGS}>
1377
1378 The current value of the regex debugging flags. Set to 0 for no debug output
1379 even when the C<re 'debug'> module is loaded. See L<re> for details.
1380
1381 This variable was added in Perl 5.10.
1382
1383 =item ${^RE_TRIE_MAXBUF}
1384 X<${^RE_TRIE_MAXBUF}>
1385
1386 Controls how certain regex optimisations are applied and how much memory they
1387 utilize. This value by default is 65536 which corresponds to a 512kB temporary
1388 cache. Set this to a higher value to trade memory for speed when matching
1389 large alternations. Set it to a lower value if you want the optimisations to
1390 be as conservative of memory as possible but still occur, and set it to a
1391 negative value to prevent the optimisation and conserve the most memory.
1392 Under normal situations this variable should be of no interest to you.
1393
1394 This variable was added in Perl 5.10.
1395
1396 =back
1397
1398 =head2 Variables related to filehandles
1399
1400 Variables that depend on the currently selected filehandle may be set
1401 by calling an appropriate object method on the C<IO::Handle> object,
1402 although this is less efficient than using the regular built-in
1403 variables. (Summary lines below for this contain the word HANDLE.)
1404 First you must say
1405
1406         use IO::Handle;
1407
1408 after which you may use either
1409
1410         method HANDLE EXPR
1411
1412 or more safely,
1413
1414         HANDLE->method(EXPR)
1415
1416 Each method returns the old value of the C<IO::Handle> attribute. The
1417 methods each take an optional EXPR, which, if supplied, specifies the
1418 new value for the C<IO::Handle> attribute in question. If not
1419 supplied, most methods do nothing to the current value--except for
1420 C<autoflush()>, which will assume a 1 for you, just to be different.
1421
1422 Because loading in the C<IO::Handle> class is an expensive operation,
1423 you should learn how to use the regular built-in variables.
1424
1425 A few of these variables are considered "read-only". This means that
1426 if you try to assign to this variable, either directly or indirectly
1427 through a reference, you'll raise a run-time exception.
1428
1429 You should be very careful when modifying the default values of most
1430 special variables described in this document. In most cases you want
1431 to localize these variables before changing them, since if you don't,
1432 the change may affect other modules which rely on the default values
1433 of the special variables that you have changed. This is one of the
1434 correct ways to read the whole file at once:
1435
1436         open my $fh, "<", "foo" or die $!;
1437         local $/; # enable localized slurp mode
1438         my $content = <$fh>;
1439         close $fh;
1440
1441 But the following code is quite bad:
1442
1443         open my $fh, "<", "foo" or die $!;
1444         undef $/; # enable slurp mode
1445         my $content = <$fh>;
1446         close $fh;
1447
1448 since some other module, may want to read data from some file in the
1449 default "line mode", so if the code we have just presented has been
1450 executed, the global value of C<$/> is now changed for any other code
1451 running inside the same Perl interpreter.
1452
1453 Usually when a variable is localized you want to make sure that this
1454 change affects the shortest scope possible. So unless you are already
1455 inside some short C<{}> block, you should create one yourself. For
1456 example:
1457
1458         my $content = '';
1459         open my $fh, "<", "foo" or die $!;
1460         {
1461                 local $/;
1462                 $content = <$fh>;
1463         }
1464         close $fh;
1465
1466 Here is an example of how your own code can go broken:
1467
1468         for ( 1..3 ){
1469                 $\ = "\r\n";
1470                 nasty_break();
1471                 print "$_";
1472         }
1473
1474         sub nasty_break {
1475         $\ = "\f";
1476         # do something with $_
1477         }
1478
1479 You probably expect this code to print the equivalent of
1480
1481     "1\r\n2\r\n3\r\n"
1482
1483 but instead you get:
1484
1485     "1\f2\f3\f"
1486
1487 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1488 first. The value you set in  C<nasty_break()> is still there when you
1489 return. The fix is to add C<local()> so the value doesn't leak out of
1490 C<nasty_break()>:
1491
1492         local $\ = "\f";
1493
1494 It's easy to notice the problem in such a short example, but in more
1495 complicated code you are looking for trouble if you don't localize
1496 changes to the special variables.
1497
1498 =over 8
1499
1500 =item $ARGV
1501 X<$ARGV>
1502
1503 Contains the name of the current file when reading from C<< <> >>.
1504
1505 =item @ARGV
1506 X<@ARGV>
1507
1508 The array C<@ARGV> contains the command-line arguments intended for
1509 the script. C<$#ARGV> is generally the number of arguments minus
1510 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1511 command name itself. See C<$0> for the command name.
1512
1513 =item ARGV
1514 X<ARGV>
1515
1516 The special filehandle that iterates over command-line filenames in
1517 C<@ARGV>. Usually written as the null filehandle in the angle operator
1518 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1519 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1520 corresponding to the last file opened by C<< <> >>. In particular,
1521 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1522 may not cause your function to automatically read the contents of all the
1523 files in C<@ARGV>.
1524
1525 =item ARGVOUT
1526 X<ARGVOUT>
1527
1528 The special filehandle that points to the currently open output file
1529 when doing edit-in-place processing with B<-i>. Useful when you have
1530 to do a lot of inserting and don't want to keep modifying C<$_>. See
1531 L<perlrun> for the B<-i> switch.
1532
1533 =item Handle->output_field_separator( EXPR )
1534
1535 =item $OUTPUT_FIELD_SEPARATOR
1536
1537 =item $OFS
1538
1539 =item $,
1540 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1541
1542 The output field separator for the print operator. If defined, this
1543 value is printed between each of print's arguments. Default is C<undef>.
1544
1545 Mnemonic: what is printed when there is a "," in your print statement.
1546
1547 =item HANDLE->input_line_number( EXPR )
1548
1549 =item $INPUT_LINE_NUMBER
1550
1551 =item $NR
1552
1553 =item $.
1554 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1555
1556 Current line number for the last filehandle accessed.
1557
1558 Each filehandle in Perl counts the number of lines that have been read
1559 from it. (Depending on the value of C<$/>, Perl's idea of what
1560 constitutes a line may not match yours.)  When a line is read from a
1561 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1562 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1563 for that filehandle.
1564
1565 You can adjust the counter by assigning to C<$.>, but this will not
1566 actually move the seek pointer. I<Localizing C<$.> will not localize
1567 the filehandle's line count>. Instead, it will localize perl's notion
1568 of which filehandle C<$.> is currently aliased to.
1569
1570 C<$.> is reset when the filehandle is closed, but B<not> when an open
1571 filehandle is reopened without an intervening C<close()>. For more
1572 details, see L<perlop/"IE<sol>O Operators">. Because C<< <> >> never does
1573 an explicit close, line numbers increase across C<ARGV> files (but see
1574 examples in L<perlfunc/eof>).
1575
1576 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1577 line counter for a given filehandle without having to worry about
1578 which handle you last accessed.
1579
1580 Mnemonic: many programs use "." to mean the current line number.
1581
1582 =item HANDLE->input_record_separator( EXPR )
1583
1584 =item $INPUT_RECORD_SEPARATOR
1585
1586 =item $RS
1587
1588 =item $/
1589 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1590
1591 The input record separator, newline by default. This influences Perl's
1592 idea of what a "line" is. Works like B<awk>'s RS variable, including
1593 treating empty lines as a terminator if set to the null string (an
1594 empty line cannot contain any spaces or tabs). You may set it to a
1595 multi-character string to match a multi-character terminator, or to
1596 C<undef> to read through the end of file. Setting it to C<"\n\n">
1597 means something slightly different than setting to C<"">, if the file
1598 contains consecutive empty lines. Setting to C<""> will treat two or
1599 more consecutive empty lines as a single empty line. Setting to
1600 C<"\n\n"> will blindly assume that the next input character belongs to
1601 the next paragraph, even if it's a newline.
1602
1603     local $/;           # enable "slurp" mode
1604     local $_ = <FH>;    # whole file now here
1605     s/\n[ \t]+/ /g;
1606
1607 Remember: the value of C<$/> is a string, not a regex. B<awk> has to
1608 be better for something. :-)
1609
1610 Setting C<$/> to a reference to an integer, scalar containing an
1611 integer, or scalar that's convertible to an integer will attempt to
1612 read records instead of lines, with the maximum record size being the
1613 referenced integer. So this:
1614
1615     local $/ = \32768; # or \"32768", or \$var_containing_32768
1616     open my $fh, "<", $myfile or die $!;
1617     local $_ = <$fh>;
1618
1619 will read a record of no more than 32768 bytes from FILE. If you're
1620 not reading from a record-oriented file (or your OS doesn't have
1621 record-oriented files), then you'll likely get a full chunk of data
1622 with every read. If a record is larger than the record size you've
1623 set, you'll get the record back in pieces. Trying to set the record
1624 size to zero or less will cause reading in the (rest of the) whole file.
1625
1626 On VMS, record reads are done with the equivalent of C<sysread>,
1627 so it's best not to mix record and non-record reads on the same
1628 file. (This is unlikely to be a problem, because any file you'd
1629 want to read in record mode is probably unusable in line mode.)
1630 Non-VMS systems do normal I/O, so it's safe to mix record and
1631 non-record reads of a file.
1632
1633 See also L<perlport/"Newlines">. Also see C<$.>.
1634
1635 Mnemonic: / delimits line boundaries when quoting poetry.
1636
1637 =item Handle->output_record_separator( EXPR )
1638
1639 =item $OUTPUT_RECORD_SEPARATOR
1640
1641 =item $ORS
1642
1643 =item $\
1644 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1645
1646 The output record separator for the print operator. If defined, this
1647 value is printed after the last of print's arguments. Default is C<undef>.
1648
1649 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1650 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1651
1652 =item HANDLE->autoflush( EXPR )
1653
1654 =item $OUTPUT_AUTOFLUSH
1655
1656 =item $|
1657 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1658
1659 If set to nonzero, forces a flush right away and after every write or
1660 print on the currently selected output channel. Default is 0
1661 (regardless of whether the channel is really buffered by the system or
1662 not; C<$|> tells you only whether you've asked Perl explicitly to
1663 flush after each write). STDOUT will typically be line buffered if
1664 output is to the terminal and block buffered otherwise. Setting this
1665 variable is useful primarily when you are outputting to a pipe or
1666 socket, such as when you are running a Perl program under B<rsh> and
1667 want to see the output as it's happening. This has no effect on input
1668 buffering. See L<perlfunc/getc> for that. See L<perlfunc/select> on
1669 how to select the output channel. See also L<IO::Handle>.
1670
1671 Mnemonic: when you want your pipes to be piping hot.
1672
1673 =back
1674
1675 =head3 Variables related to formats
1676
1677 The special variables for formats are a subset of those for
1678 filehandles. See L<perlform> for more information about Perl's
1679 formats.
1680
1681 =over 8
1682
1683 =item $ACCUMULATOR
1684
1685 =item $^A
1686 X<$^A> X<$ACCUMULATOR>
1687
1688 The current value of the C<write()> accumulator for C<format()> lines.
1689 A format contains C<formline()> calls that put their result into
1690 C<$^A>. After calling its format, C<write()> prints out the contents
1691 of C<$^A> and empties. So you never really see the contents of C<$^A>
1692 unless you call C<formline()> yourself and then look at it. See
1693 L<perlform> and L<perlfunc/formline()>.
1694
1695 =item HANDLE->format_formfeed(EXPR)
1696
1697 =item $FORMAT_FORMFEED
1698
1699 =item $^L
1700 X<$^L> X<$FORMAT_FORMFEED>
1701
1702 What formats output as a form feed. The default is C<\f>.
1703
1704 =item HANDLE->format_page_number(EXPR)
1705
1706 =item $FORMAT_PAGE_NUMBER
1707
1708 =item $%
1709 X<$%> X<$FORMAT_PAGE_NUMBER>
1710
1711 The current page number of the currently selected output channel.
1712
1713 Mnemonic: C<%> is page number in B<nroff>.
1714
1715 =item HANDLE->format_lines_left(EXPR)
1716
1717 =item $FORMAT_LINES_LEFT
1718
1719 =item $-
1720 X<$-> X<$FORMAT_LINES_LEFT>
1721
1722 The number of lines left on the page of the currently selected output
1723 channel.
1724
1725 Mnemonic: lines_on_page - lines_printed.
1726
1727 =item Handle->format_line_break_characters EXPR
1728
1729 =item $FORMAT_LINE_BREAK_CHARACTERS
1730
1731 =item $:
1732 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1733
1734 The current set of characters after which a string may be broken to
1735 fill continuation fields (starting with C<^>) in a format. The default is
1736 S<" \n-">, to break on a space, newline, or a hyphen.
1737
1738 Mnemonic: a "colon" in poetry is a part of a line.
1739
1740 =item HANDLE->format_lines_per_page(EXPR)
1741
1742 =item $FORMAT_LINES_PER_PAGE
1743
1744 =item $=
1745 X<$=> X<$FORMAT_LINES_PER_PAGE>
1746
1747 The current page length (printable lines) of the currently selected
1748 output channel. The default is 60.
1749
1750 Mnemonic: = has horizontal lines.
1751
1752 =item HANDLE->format_top_name(EXPR)
1753
1754 =item $FORMAT_TOP_NAME
1755
1756 =item $^
1757 X<$^> X<$FORMAT_TOP_NAME>
1758
1759 The name of the current top-of-page format for the currently selected
1760 output channel. The default is the name of the filehandle with C<_TOP>
1761 appended. For example, the default format top name for the C<STDOUT>
1762 filehanlde is C<STDOUT_TOP>.
1763
1764 Mnemonic: points to top of page.
1765
1766 =item HANDLE->format_name(EXPR)
1767
1768 =item $FORMAT_NAME
1769
1770 =item $~
1771 X<$~> X<$FORMAT_NAME>
1772
1773 The name of the current report format for the currently selected
1774 output channel. The default format name is the same as the filehandle
1775 name. For example, the default format name for the C<STDOUT>
1776 filehandle is just C<STDOUT>.
1777
1778 Mnemonic: brother to C<$^>.
1779
1780 =back
1781
1782 =head2 Error Variables
1783 X<error> X<exception>
1784
1785 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1786 about different types of error conditions that may appear during
1787 execution of a Perl program. The variables are shown ordered by
1788 the "distance" between the subsystem which reported the error and
1789 the Perl process. They correspond to errors detected by the Perl
1790 interpreter, C library, operating system, or an external program,
1791 respectively.
1792
1793 To illustrate the differences between these variables, consider the
1794 following Perl expression, which uses a single-quoted string. After
1795 execution of this statement, perl may have set all four special error
1796 variables:
1797
1798         eval q{
1799                 open my $pipe, "/cdrom/install |" or die $!;
1800                 my @res = <$pipe>;
1801                 close $pipe or die "bad pipe: $?, $!";
1802             };
1803
1804 When perl executes the C<eval()> expression, it translates the
1805 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1806 and thence to the operating system kernel. perl sets C<$!> to
1807 the C library's C<errno> if one of these calls fails.
1808
1809 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1810 happen if C<open> or C<close> were imported with bad prototypes), or
1811 if Perl code executed during evaluation C<die()>d. In these cases the
1812 value of C<$@> is the compile error, or the argument to C<die> (which
1813 will interpolate C<$!> and C<$?>). (See also L<Fatal>, though.)
1814
1815 Under a few operating systems, C<$^E> may contain a more verbose error
1816 indicator, such as in this case, "CDROM tray not closed." Systems that
1817 do not support extended error messages leave C<$^E> the same as C<$!>.
1818
1819 Finally, C<$?> may be set to non-0 value if the external program
1820 F</cdrom/install> fails. The upper eight bits reflect specific error
1821 conditions encountered by the program (the program's C<exit()> value).
1822 The lower eight bits reflect mode of failure, like signal death and
1823 core dump information. See C<wait(2)> for details. In contrast to
1824 C<$!> and C<$^E>, which are set only if error condition is detected,
1825 the variable C<$?> is set on each C<wait> or pipe C<close>,
1826 overwriting the old value. This is more like C<$@>, which on every
1827 C<eval()> is always set on failure and cleared on success.
1828
1829 For more details, see the individual descriptions at C<$@>, C<$!>,
1830 C<$^E>, and C<$?>.
1831
1832 =over 8
1833
1834 =item ${^CHILD_ERROR_NATIVE}
1835 X<$^CHILD_ERROR_NATIVE>
1836
1837 The native status returned by the last pipe close, backtick (C<``>)
1838 command, successful call to C<wait()> or C<waitpid()>, or from the
1839 C<system()> operator. On POSIX-like systems this value can be decoded
1840 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1841 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1842
1843 Under VMS this reflects the actual VMS exit status; i.e. it is the
1844 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1845
1846 This variable was added in Perl 5.8.9.
1847
1848 =item $EXTENDED_OS_ERROR
1849
1850 =item $^E
1851 X<$^E> X<$EXTENDED_OS_ERROR>
1852
1853 Error information specific to the current operating system. At the
1854 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1855 for MacPerl). On all other platforms, C<$^E> is always just the same
1856 as C<$!>.
1857
1858 Under VMS, C<$^E> provides the VMS status value from the last system
1859 error. This is more specific information about the last system error
1860 than that provided by C<$!>. This is particularly important when C<$!>
1861 is set to B<EVMSERR>.
1862
1863 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1864 API either via CRT, or directly from perl.
1865
1866 Under Win32, C<$^E> always returns the last error information reported
1867 by the Win32 call C<GetLastError()> which describes the last error
1868 from within the Win32 API. Most Win32-specific code will report errors
1869 via C<$^E>. ANSI C and Unix-like calls set C<errno> and so most
1870 portable Perl code will report errors via C<$!>.
1871
1872 Caveats mentioned in the description of C<$!> generally apply to
1873 C<$^E>, also.
1874
1875 This variable was added in Perl 5.003.
1876
1877 Mnemonic: Extra error explanation.
1878
1879 =item $EXCEPTIONS_BEING_CAUGHT
1880
1881 =item $^S
1882 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1883
1884 Current state of the interpreter.
1885
1886         $^S         State
1887         ---------   -------------------
1888         undef       Parsing module/eval
1889         true (1)    Executing an eval
1890         false (0)   Otherwise
1891
1892 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1893 handlers.
1894
1895 This variable was added in Perl 5.004.
1896
1897 =item $WARNING
1898
1899 =item $^W
1900 X<$^W> X<$WARNING>
1901
1902 The current value of the warning switch, initially true if B<-w> was
1903 used, false otherwise, but directly modifiable.
1904
1905 See also L<warnings>.
1906
1907 Mnemonic: related to the B<-w> switch.
1908
1909 =item ${^WARNING_BITS}
1910 X<${^WARNING_BITS}>
1911
1912 The current set of warning checks enabled by the C<use warnings> pragma.
1913 See the documentation of C<warnings> for more details.
1914
1915 This variable was added in Perl 5.10.
1916
1917 =item $OS_ERROR
1918
1919 =item $ERRNO
1920
1921 =item $!
1922 X<$!> X<$ERRNO> X<$OS_ERROR>
1923
1924 If used numerically, yields the current value of the C C<errno>
1925 variable, or in other words, if a system or library call fails, it
1926 sets this variable. This means that the value of C<$!> is meaningful
1927 only I<immediately> after a B<failure>:
1928
1929         if (open my $fh, "<", $filename) {
1930                 # Here $! is meaningless.
1931                 ...
1932     }
1933     else {
1934                 # ONLY here is $! meaningful.
1935                 ...
1936                 # Already here $! might be meaningless.
1937     }
1938     # Since here we might have either success or failure,
1939     # here $! is meaningless.
1940
1941 The I<meaningless> stands for anything: zero, non-zero,
1942 C<undef>. A successful system or library call does B<not> set the
1943 variable to zero.
1944
1945 If used as a string, yields the corresponding system error string. You
1946 can assign a number to C<$!> to set I<errno> if, for instance, you
1947 want C<"$!"> to return the string for error I<n>, or you want to set
1948 the exit value for the C<die()> operator.
1949
1950 Mnemonic: What just went bang?
1951
1952 =item %OS_ERROR
1953
1954 =item %ERRNO
1955
1956 =item %!
1957 X<%!> X<%OS_ERROR> X<%ERRNO>
1958
1959 Each element of C<%!> has a true value only if C<$!> is set to that
1960 value. For example, C<$!{ENOENT}> is true if and only if the current
1961 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1962 such file or directory" (or its moral equivalent: not all operating
1963 systems give that exact error, and certainly not all languages). To
1964 check if a particular key is meaningful on your system, use C<exists
1965 $!{the_key}>; for a list of legal keys, use C<keys %!>. See L<Errno>
1966 for more information, and also see L</$!>.
1967
1968 This variable was added in Perl 5.005.
1969
1970 =item $CHILD_ERROR
1971
1972 =item $?
1973 X<$?> X<$CHILD_ERROR>
1974
1975 The status returned by the last pipe close, backtick (C<``>) command,
1976 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1977 operator. This is just the 16-bit status word returned by the
1978 traditional Unix C<wait()> system call (or else is made up to look
1979 like it). Thus, the exit value of the subprocess is really (C<<< $? >>
1980 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1981 from, and C<$? & 128> reports whether there was a core dump.
1982
1983 Additionally, if the C<h_errno> variable is supported in C, its value
1984 is returned via C<$?> if any C<gethost*()> function fails.
1985
1986 If you have installed a signal handler for C<SIGCHLD>, the
1987 value of C<$?> will usually be wrong outside that handler.
1988
1989 Inside an C<END> subroutine C<$?> contains the value that is going to be
1990 given to C<exit()>. You can modify C<$?> in an C<END> subroutine to
1991 change the exit status of your program. For example:
1992
1993     END {
1994         $? = 1 if $? == 255;  # die would make it 255
1995     }
1996
1997 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1998 actual VMS exit status, instead of the default emulation of POSIX
1999 status; see L<perlvms/$?> for details.
2000
2001 Mnemonic: similar to B<sh> and B<ksh>.
2002
2003 =item $EVAL_ERROR
2004
2005 =item $@
2006 X<$@> X<$EVAL_ERROR>
2007
2008 The Perl syntax error message from the last C<eval()> operator. If C<$@> is
2009 the null string, the last C<eval()> parsed and executed correctly
2010 (although the operations you invoked may have failed in the normal
2011 fashion).
2012
2013 Warning messages are not collected in this variable. You can, however,
2014 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
2015 described in L</%SIG>.
2016
2017 Mnemonic: Where was the syntax error "at"?
2018
2019 =back
2020
2021 =head2 Deprecated and removed variables
2022
2023 Deprecating a variable announces the intent of the perl maintainers to
2024 eventually remove the variable from the langauge. It may still be
2025 available despite its status. Using a deprecated variable triggers
2026 a warning.
2027
2028 Once a variable is removed, its use triggers an error telling you
2029 the variable is unsupported.
2030
2031 See L<perldiag> for details about error messages.
2032
2033 =over 8
2034
2035 =item $OFMT
2036
2037 =item $#
2038 X<$#> X<$OFMT>
2039
2040 C<$#> was a variable that you could be use to format printed numbers.
2041 After a deprecation cycle, its magic was removed in Perl 5.10 and
2042 using it now triggers a warning: C<$# is no longer supported>.
2043
2044 This is not the sigil you use in front of an array name to get the
2045 last index, like C<$#array>. That's still how you get the last index
2046 of an array in Perl. The two have nothing to do with each other.
2047
2048 Deprecated in Perl 5.
2049
2050 Removed in Perl 5.10.
2051
2052 =item $*
2053 X<$*>
2054
2055 C<$*> was a variable that you could use to enable multiline matching.
2056 After a deprecation cycle, its magic was removed in Perl 5.10.
2057 Using it now triggers a warning: C<$* is no longer supported>.
2058 You should use the C</s> and C</m> regexp modifiers instead.
2059
2060 Deprecated in Perl 5.
2061
2062 Removed in Perl 5.10.
2063
2064 =item $ARRAY_BASE
2065
2066 =item $[
2067 X<$[> X<$ARRAY_BASE>
2068
2069 This variable stores the index of the first element in an array, and
2070 of the first character in a substring. You used to be able to assign to
2071 this variable, but you can't do that anymore. It's now always 0, like
2072 it should be.
2073
2074 Mnemonic: [ begins subscripts.
2075
2076 This variable is read-only.
2077
2078 Deprecated in Perl 5.12.
2079
2080 =item $OLD_PERL_VERSION
2081
2082 =item $]
2083 X<$]> X<$OLD_PERL_VERSION>
2084
2085 See C<$^V> for a more modern representation of the Perl version that allows
2086 accurate string comparisons.
2087
2088 The version + patchlevel / 1000 of the Perl interpreter. This variable
2089 can be used to determine whether the Perl interpreter executing a
2090 script is in the right range of versions:
2091
2092     warn "No checksumming!\n" if $] < 3.019;
2093
2094 The floating point representation can sometimes lead to inaccurate
2095 numeric comparisons.
2096
2097 See also the documentation of C<use VERSION> and C<require VERSION>
2098 for a convenient way to fail if the running Perl interpreter is too old.
2099
2100 Mnemonic: Is this version of perl in the right bracket?
2101
2102 Deprecated in Perl 5.6.
2103
2104 =back
2105
2106 =cut