CPAN is upstream for Time::Local again
[perl.git] / pod / perlrecharclass.pod
1 =head1 NAME
2 X<character class>
3
4 perlrecharclass - Perl Regular Expression Character Classes
5
6 =head1 DESCRIPTION
7
8 The top level documentation about Perl regular expressions
9 is found in L<perlre>.
10
11 This manual page discusses the syntax and use of character
12 classes in Perl regular expressions.
13
14 A character class is a way of denoting a set of characters
15 in such a way that one character of the set is matched.
16 It's important to remember that: matching a character class
17 consumes exactly one character in the source string. (The source
18 string is the string the regular expression is matched against.)
19
20 There are three types of character classes in Perl regular
21 expressions: the dot, backslash sequences, and the form enclosed in square
22 brackets.  Keep in mind, though, that often the term "character class" is used
23 to mean just the bracketed form.  Certainly, most Perl documentation does that.
24
25 =head2 The dot
26
27 The dot (or period), C<.> is probably the most used, and certainly
28 the most well-known character class. By default, a dot matches any
29 character, except for the newline. The default can be changed to
30 add matching the newline by using the I<single line> modifier: either
31 for the entire regular expression with the C</s> modifier, or
32 locally with C<(?s)>.  (The experimental C<\N> backslash sequence, described
33 below, matches any character except newline without regard to the
34 I<single line> modifier.)
35
36 Here are some examples:
37
38  "a"  =~  /./       # Match
39  "."  =~  /./       # Match
40  ""   =~  /./       # No match (dot has to match a character)
41  "\n" =~  /./       # No match (dot does not match a newline)
42  "\n" =~  /./s      # Match (global 'single line' modifier)
43  "\n" =~  /(?s:.)/  # Match (local 'single line' modifier)
44  "ab" =~  /^.$/     # No match (dot matches one character)
45
46 =head2 Backslash sequences
47 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\p> X<\P> 
48 X<\N> X<\v> X<\V> X<\h> X<\H>
49 X<word> X<whitespace>
50
51 A backslash sequence is a sequence of characters, the first one of which is a
52 backslash.  Perl ascribes special meaning to many such sequences, and some of
53 these are character classes.  That is, they match a single character each,
54 provided that the character belongs to the specific set of characters defined
55 by the sequence.
56
57 Here's a list of the backslash sequences that are character classes.  They
58 are discussed in more detail below.  (For the backslash sequences that aren't
59 character classes, see L<perlrebackslash>.)
60
61  \d             Match a decimal digit character.
62  \D             Match a non-decimal-digit character.
63  \w             Match a "word" character.
64  \W             Match a non-"word" character.
65  \s             Match a whitespace character.
66  \S             Match a non-whitespace character.
67  \h             Match a horizontal whitespace character.
68  \H             Match a character that isn't horizontal whitespace.
69  \v             Match a vertical whitespace character.
70  \V             Match a character that isn't vertical whitespace.
71  \N             Match a character that isn't a newline.  Experimental.
72  \pP, \p{Prop}  Match a character that has the given Unicode property.
73  \PP, \P{Prop}  Match a character that doesn't have the Unicode property
74
75 =head3 Digits
76
77 C<\d> matches a single character that is considered to be a decimal I<digit>.
78 What is considered a decimal digit depends on several factors, detailed
79 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
80 indicate a Unicode interpretation, C<\d> not only matches the digits
81 '0' - '9', but also Arabic, Devanagari and digits from other languages.
82 Otherwise, if there is a locale in effect, it will match whatever
83 characters the locale considers decimal digits.  Without a locale, C<\d>
84 matches just the digits '0' to '9'.
85
86 Unicode digits may cause some confusion, and some security issues.  In UTF-8
87 strings, C<\d> matches the same characters matched by
88 C<\p{General_Category=Decimal_Number}>, or synonymously,
89 C<\p{General_Category=Digit}>.  Starting with Unicode version 4.1, this is the
90 same set of characters matched by C<\p{Numeric_Type=Decimal}>.  
91
92 But Unicode also has a different property with a similar name,
93 C<\p{Numeric_Type=Digit}>, which matches a completely different set of
94 characters.  These characters are things such as subscripts.
95
96 The design intent is for C<\d> to match all the digits (and no other characters)
97 that can be used with "normal" big-endian positional decimal syntax, whereby a
98 sequence of such digits {N0, N1, N2, ...Nn} has the numeric value (...(N0 * 10
99 + N1) * 10 + N2) * 10 ... + Nn).  In Unicode 5.2, the Tamil digits (U+0BE6 -
100 U+0BEF) can also legally be used in old-style Tamil numbers in which they would
101 appear no more than one in a row, separated by characters that mean "times 10",
102 "times 100", etc.  (See L<http://www.unicode.org/notes/tn21>.)
103
104 Some of the non-European digits that C<\d> matches look like European ones, but
105 have different values.  For example, BENGALI DIGIT FOUR (U+09EA) looks
106 very much like an ASCII DIGIT EIGHT (U+0038).
107
108 It may be useful for security purposes for an application to require that all
109 digits in a row be from the same script.   See L<Unicode::UCD/charscript()>.
110
111 Any character that isn't matched by C<\d> will be matched by C<\D>.
112
113 =head3 Word characters
114
115 A C<\w> matches a single alphanumeric character (an alphabetic character, or a
116 decimal digit) or a connecting punctuation character, such as an
117 underscore ("_").  It does not match a whole word.  To match a whole
118 word, use C<\w+>.  This isn't the same thing as matching an English word, but 
119 in the ASCII range is the same as a string of Perl-identifier
120 characters.  What is considered a
121 word character depends on several factors, detailed below in L</Locale,
122 EBCDIC, Unicode and UTF-8>.  If those factors indicate a Unicode
123 interpretation, C<\w> matches the characters that are considered word
124 characters in the Unicode database. That is, it not only matches ASCII letters,
125 but also Thai letters, Greek letters, etc.  This includes connector
126 punctuation (like the underscore) which connect two words together, or
127 marks, such as a C<COMBINING TILDE>, which are generally used to add
128 diacritical marks to letters.   If a Unicode interpretation
129 is not indicated, C<\w> matches those characters that are considered
130 word characters by the current locale or EBCDIC code page.  Without a
131 locale or EBCDIC code page, C<\w> matches the ASCII letters, digits and
132 the underscore.
133
134 There are a number of security issues with the full Unicode list of word
135 characters.  See L<http://unicode.org/reports/tr36>.
136
137 Also, for a somewhat finer-grained set of characters that are in programming
138 language identifiers beyond the ASCII range, you may wish to instead use the
139 more customized Unicode properties, "ID_Start", ID_Continue", "XID_Start", and
140 "XID_Continue".  See L<http://unicode.org/reports/tr31>.
141
142 Any character that isn't matched by C<\w> will be matched by C<\W>.
143
144 =head3 Whitespace
145
146 C<\s> matches any single character that is considered whitespace.  The exact
147 set of characters matched by C<\s> depends on several factors, detailed
148 below in L</Locale, EBCDIC, Unicode and UTF-8>.  If those factors
149 indicate a Unicode interpretation, C<\s> matches what is considered
150 whitespace in the Unicode database; the complete list is in the table
151 below. Otherwise, if there is a locale or EBCDIC code page in effect,
152 C<\s> matches whatever is considered whitespace by the current locale or
153 EBCDIC code page. Without a locale or EBCDIC code page, C<\s> matches
154 the horizontal tab (C<\t>), the newline (C<\n>), the form feed (C<\f>),
155 the carriage return (C<\r>), and the space.  (Note that it doesn't match
156 the vertical tab, C<\cK>.)  Perhaps the most notable possible surprise
157 is that C<\s> matches a non-breaking space only if a Unicode
158 interpretation is indicated, or the locale or EBCDIC code page that is
159 in effect has that character.
160
161 Any character that isn't matched by C<\s> will be matched by C<\S>.
162
163 C<\h> will match any character that is considered horizontal whitespace;
164 this includes the space and the tab characters and a number other characters,
165 all of which are listed in the table below.  C<\H> will match any character
166 that is not considered horizontal whitespace.
167
168 C<\v> will match any character that is considered vertical whitespace;
169 this includes the carriage return and line feed characters (newline) plus several
170 other characters, all listed in the table below.
171 C<\V> will match any character that is not considered vertical whitespace.
172
173 C<\R> matches anything that can be considered a newline under Unicode
174 rules. It's not a character class, as it can match a multi-character
175 sequence. Therefore, it cannot be used inside a bracketed character
176 class; use C<\v> instead (vertical whitespace).
177 Details are discussed in L<perlrebackslash>.
178
179 Note that unlike C<\s>, C<\d> and C<\w>, C<\h> and C<\v> always match
180 the same characters, without regard to other factors, such as if the
181 source string is in UTF-8 format or not.
182
183 One might think that C<\s> is equivalent to C<[\h\v]>. This is not true.  The
184 vertical tab (C<"\x0b">) is not matched by C<\s>, it is however considered
185 vertical whitespace. Furthermore, if the source string is not in UTF-8 format,
186 and any locale or EBCDIC code page that is in effect doesn't include them, the
187 next line (ASCII-platform C<"\x85">) and the no-break space (ASCII-platform
188 C<"\xA0">) characters are not matched by C<\s>, but are by C<\v> and C<\h>
189 respectively.  If the source string is in UTF-8 format, both the next line and
190 the no-break space are matched by C<\s>.
191
192 The following table is a complete listing of characters matched by
193 C<\s>, C<\h> and C<\v> as of Unicode 5.2.
194
195 The first column gives the code point of the character (in hex format),
196 the second column gives the (Unicode) name. The third column indicates
197 by which class(es) the character is matched (assuming no locale or EBCDIC code
198 page is in effect that changes the C<\s> matching).
199
200  0x00009        CHARACTER TABULATION   h s
201  0x0000a              LINE FEED (LF)    vs
202  0x0000b             LINE TABULATION    v
203  0x0000c              FORM FEED (FF)    vs
204  0x0000d        CARRIAGE RETURN (CR)    vs
205  0x00020                       SPACE   h s
206  0x00085             NEXT LINE (NEL)    vs  [1]
207  0x000a0              NO-BREAK SPACE   h s  [1]
208  0x01680            OGHAM SPACE MARK   h s
209  0x0180e   MONGOLIAN VOWEL SEPARATOR   h s
210  0x02000                     EN QUAD   h s
211  0x02001                     EM QUAD   h s
212  0x02002                    EN SPACE   h s
213  0x02003                    EM SPACE   h s
214  0x02004          THREE-PER-EM SPACE   h s
215  0x02005           FOUR-PER-EM SPACE   h s
216  0x02006            SIX-PER-EM SPACE   h s
217  0x02007                FIGURE SPACE   h s
218  0x02008           PUNCTUATION SPACE   h s
219  0x02009                  THIN SPACE   h s
220  0x0200a                  HAIR SPACE   h s
221  0x02028              LINE SEPARATOR    vs
222  0x02029         PARAGRAPH SEPARATOR    vs
223  0x0202f       NARROW NO-BREAK SPACE   h s
224  0x0205f   MEDIUM MATHEMATICAL SPACE   h s
225  0x03000           IDEOGRAPHIC SPACE   h s
226
227 =over 4
228
229 =item [1]
230
231 NEXT LINE and NO-BREAK SPACE only match C<\s> if the source string is in
232 UTF-8 format, or the locale or EBCDIC code page that is in effect includes them.
233
234 =back
235
236 It is worth noting that C<\d>, C<\w>, etc, match single characters, not
237 complete numbers or words. To match a number (that consists of digits),
238 use C<\d+>; to match a word, use C<\w+>.
239
240 =head3 \N
241
242 C<\N> is new in 5.12, and is experimental.  It, like the dot, will match any
243 character that is not a newline. The difference is that C<\N> is not influenced
244 by the I<single line> regular expression modifier (see L</The dot> above).  Note
245 that the form C<\N{...}> may mean something completely different.  When the
246 C<{...}> is a L<quantifier|perlre/Quantifiers>, it means to match a non-newline
247 character that many times.  For example, C<\N{3}> means to match 3
248 non-newlines; C<\N{5,}> means to match 5 or more non-newlines.  But if C<{...}>
249 is not a legal quantifier, it is presumed to be a named character.  See
250 L<charnames> for those.  For example, none of C<\N{COLON}>, C<\N{4F}>, and
251 C<\N{F4}> contain legal quantifiers, so Perl will try to find characters whose
252 names are, respectively, C<COLON>, C<4F>, and C<F4>.
253
254 =head3 Unicode Properties
255
256 C<\pP> and C<\p{Prop}> are character classes to match characters that fit given
257 Unicode properties.  One letter property names can be used in the C<\pP> form,
258 with the property name following the C<\p>, otherwise, braces are required.
259 When using braces, there is a single form, which is just the property name
260 enclosed in the braces, and a compound form which looks like C<\p{name=value}>,
261 which means to match if the property "name" for the character has the particular
262 "value".
263 For instance, a match for a number can be written as C</\pN/> or as
264 C</\p{Number}/>, or as C</\p{Number=True}/>.
265 Lowercase letters are matched by the property I<Lowercase_Letter> which
266 has as short form I<Ll>. They need the braces, so are written as C</\p{Ll}/> or
267 C</\p{Lowercase_Letter}/>, or C</\p{General_Category=Lowercase_Letter}/>
268 (the underscores are optional).
269 C</\pLl/> is valid, but means something different.
270 It matches a two character string: a letter (Unicode property C<\pL>),
271 followed by a lowercase C<l>.
272
273 For more details, see L<perlunicode/Unicode Character Properties>; for a
274 complete list of possible properties, see
275 L<perluniprops/Properties accessible through \p{} and \P{}>.
276 It is also possible to define your own properties. This is discussed in
277 L<perlunicode/User-Defined Character Properties>.
278
279
280 =head4 Examples
281
282  "a"  =~  /\w/      # Match, "a" is a 'word' character.
283  "7"  =~  /\w/      # Match, "7" is a 'word' character as well.
284  "a"  =~  /\d/      # No match, "a" isn't a digit.
285  "7"  =~  /\d/      # Match, "7" is a digit.
286  " "  =~  /\s/      # Match, a space is whitespace.
287  "a"  =~  /\D/      # Match, "a" is a non-digit.
288  "7"  =~  /\D/      # No match, "7" is not a non-digit.
289  " "  =~  /\S/      # No match, a space is not non-whitespace.
290
291  " "  =~  /\h/      # Match, space is horizontal whitespace.
292  " "  =~  /\v/      # No match, space is not vertical whitespace.
293  "\r" =~  /\v/      # Match, a return is vertical whitespace.
294
295  "a"  =~  /\pL/     # Match, "a" is a letter.
296  "a"  =~  /\p{Lu}/  # No match, /\p{Lu}/ matches upper case letters.
297
298  "\x{0e0b}" =~ /\p{Thai}/  # Match, \x{0e0b} is the character
299                            # 'THAI CHARACTER SO SO', and that's in
300                            # Thai Unicode class.
301  "a"  =~  /\P{Lao}/ # Match, as "a" is not a Laotian character.
302
303
304 =head2 Bracketed Character Classes
305
306 The third form of character class you can use in Perl regular expressions
307 is the bracketed character class.  In its simplest form, it lists the characters
308 that may be matched, surrounded by square brackets, like this: C<[aeiou]>.
309 This matches one of C<a>, C<e>, C<i>, C<o> or C<u>.  Like the other
310 character classes, exactly one character will be matched. To match
311 a longer string consisting of characters mentioned in the character
312 class, follow the character class with a L<quantifier|perlre/Quantifiers>.  For
313 instance, C<[aeiou]+> matches a string of one or more lowercase English vowels.
314
315 Repeating a character in a character class has no
316 effect; it's considered to be in the set only once.
317
318 Examples:
319
320  "e"  =~  /[aeiou]/        # Match, as "e" is listed in the class.
321  "p"  =~  /[aeiou]/        # No match, "p" is not listed in the class.
322  "ae" =~  /^[aeiou]$/      # No match, a character class only matches
323                            # a single character.
324  "ae" =~  /^[aeiou]+$/     # Match, due to the quantifier.
325
326 =head3 Special Characters Inside a Bracketed Character Class
327
328 Most characters that are meta characters in regular expressions (that
329 is, characters that carry a special meaning like C<.>, C<*>, or C<(>) lose
330 their special meaning and can be used inside a character class without
331 the need to escape them. For instance, C<[()]> matches either an opening
332 parenthesis, or a closing parenthesis, and the parens inside the character
333 class don't group or capture.
334
335 Characters that may carry a special meaning inside a character class are:
336 C<\>, C<^>, C<->, C<[> and C<]>, and are discussed below. They can be
337 escaped with a backslash, although this is sometimes not needed, in which
338 case the backslash may be omitted.
339
340 The sequence C<\b> is special inside a bracketed character class. While
341 outside the character class, C<\b> is an assertion indicating a point
342 that does not have either two word characters or two non-word characters
343 on either side, inside a bracketed character class, C<\b> matches a
344 backspace character.
345
346 The sequences
347 C<\a>,
348 C<\c>,
349 C<\e>,
350 C<\f>,
351 C<\n>,
352 C<\N{I<NAME>}>,
353 C<\N{U+I<wide hex char>}>,
354 C<\r>,
355 C<\t>,
356 and
357 C<\x>
358 are also special and have the same meanings as they do outside a
359 bracketed character class.  (However, inside a bracketed character
360 class, if C<\N{I<NAME>}> expands to a sequence of characters, only the first
361 one in the sequence is used, with a warning.)
362
363 Also, a backslash followed by two or three octal digits is considered an octal
364 number.
365
366 A C<[> is not special inside a character class, unless it's the start of a
367 POSIX character class (see L</POSIX Character Classes> below). It normally does
368 not need escaping.
369
370 A C<]> is normally either the end of a POSIX character class (see
371 L</POSIX Character Classes> below), or it signals the end of the bracketed
372 character class.  If you want to include a C<]> in the set of characters, you
373 must generally escape it.
374 However, if the C<]> is the I<first> (or the second if the first
375 character is a caret) character of a bracketed character class, it
376 does not denote the end of the class (as you cannot have an empty class)
377 and is considered part of the set of characters that can be matched without
378 escaping.
379
380 Examples:
381
382  "+"   =~ /[+?*]/     #  Match, "+" in a character class is not special.
383  "\cH" =~ /[\b]/      #  Match, \b inside in a character class
384                       #  is equivalent to a backspace.
385  "]"   =~ /[][]/      #  Match, as the character class contains.
386                       #  both [ and ].
387  "[]"  =~ /[[]]/      #  Match, the pattern contains a character class
388                       #  containing just ], and the character class is
389                       #  followed by a ].
390
391 =head3 Character Ranges
392
393 It is not uncommon to want to match a range of characters. Luckily, instead
394 of listing all the characters in the range, one may use the hyphen (C<->).
395 If inside a bracketed character class you have two characters separated
396 by a hyphen, it's treated as if all the characters between the two are in
397 the class. For instance, C<[0-9]> matches any ASCII digit, and C<[a-m]>
398 matches any lowercase letter from the first half of the ASCII alphabet.
399
400 Note that the two characters on either side of the hyphen are not
401 necessary both letters or both digits. Any character is possible,
402 although not advisable.  C<['-?]> contains a range of characters, but
403 most people will not know which characters that will be. Furthermore,
404 such ranges may lead to portability problems if the code has to run on
405 a platform that uses a different character set, such as EBCDIC.
406
407 If a hyphen in a character class cannot syntactically be part of a range, for
408 instance because it is the first or the last character of the character class,
409 or if it immediately follows a range, the hyphen isn't special, and will be
410 considered a character that is to be matched literally. You have to escape the
411 hyphen with a backslash if you want to have a hyphen in your set of characters
412 to be matched, and its position in the class is such that it could be
413 considered part of a range.
414
415 Examples:
416
417  [a-z]       #  Matches a character that is a lower case ASCII letter.
418  [a-fz]      #  Matches any letter between 'a' and 'f' (inclusive) or
419              #  the letter 'z'.
420  [-z]        #  Matches either a hyphen ('-') or the letter 'z'.
421  [a-f-m]     #  Matches any letter between 'a' and 'f' (inclusive), the
422              #  hyphen ('-'), or the letter 'm'.
423  ['-?]       #  Matches any of the characters  '()*+,-./0123456789:;<=>?
424              #  (But not on an EBCDIC platform).
425
426
427 =head3 Negation
428
429 It is also possible to instead list the characters you do not want to
430 match. You can do so by using a caret (C<^>) as the first character in the
431 character class. For instance, C<[^a-z]> matches a character that is not a
432 lowercase ASCII letter.
433
434 This syntax make the caret a special character inside a bracketed character
435 class, but only if it is the first character of the class. So if you want
436 to have the caret as one of the characters you want to match, you either
437 have to escape the caret, or not list it first.
438
439 Examples:
440
441  "e"  =~  /[^aeiou]/   #  No match, the 'e' is listed.
442  "x"  =~  /[^aeiou]/   #  Match, as 'x' isn't a lowercase vowel.
443  "^"  =~  /[^^]/       #  No match, matches anything that isn't a caret.
444  "^"  =~  /[x^]/       #  Match, caret is not special here.
445
446 =head3 Backslash Sequences
447
448 You can put any backslash sequence character class (with the exception of
449 C<\N>) inside a bracketed character class, and it will act just
450 as if you put all the characters matched by the backslash sequence inside the
451 character class. For instance, C<[a-f\d]> will match any decimal digit, or any
452 of the lowercase letters between 'a' and 'f' inclusive.
453
454 C<\N> within a bracketed character class must be of the forms C<\N{I<name>}>
455 or C<\N{U+I<wide hex char>}>, and NOT be the form that matches non-newlines,
456 for the same reason that a dot C<.> inside a bracketed character class loses
457 its special meaning: it matches nearly anything, which generally isn't what you
458 want to happen.
459
460
461 Examples:
462
463  /[\p{Thai}\d]/     # Matches a character that is either a Thai
464                     # character, or a digit.
465  /[^\p{Arabic}()]/  # Matches a character that is neither an Arabic
466                     # character, nor a parenthesis.
467
468 Backslash sequence character classes cannot form one of the endpoints
469 of a range.  Thus, you can't say:
470
471  /[\p{Thai}-\d]/     # Wrong!
472
473 =head3 POSIX Character Classes
474 X<character class> X<\p> X<\p{}>
475 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
476 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
477
478 POSIX character classes have the form C<[:class:]>, where I<class> is
479 name, and the C<[:> and C<:]> delimiters. POSIX character classes only appear
480 I<inside> bracketed character classes, and are a convenient and descriptive
481 way of listing a group of characters, though they currently suffer from
482 portability issues (see below and L<Locale, EBCDIC, Unicode and UTF-8>).
483
484 Be careful about the syntax,
485
486  # Correct:
487  $string =~ /[[:alpha:]]/
488
489  # Incorrect (will warn):
490  $string =~ /[:alpha:]/
491
492 The latter pattern would be a character class consisting of a colon,
493 and the letters C<a>, C<l>, C<p> and C<h>.
494 POSIX character classes can be part of a larger bracketed character class.  For
495 example,
496
497  [01[:alpha:]%]
498
499 is valid and matches '0', '1', any alphabetic character, and the percent sign.
500
501 Perl recognizes the following POSIX character classes:
502
503  alpha  Any alphabetical character ("[A-Za-z]").
504  alnum  Any alphanumerical character. ("[A-Za-z0-9]")
505  ascii  Any character in the ASCII character set.
506  blank  A GNU extension, equal to a space or a horizontal tab ("\t").
507  cntrl  Any control character.  See Note [2] below.
508  digit  Any decimal digit ("[0-9]"), equivalent to "\d".
509  graph  Any printable character, excluding a space.  See Note [3] below.
510  lower  Any lowercase character ("[a-z]").
511  print  Any printable character, including a space.  See Note [4] below.
512  punct  Any graphical character excluding "word" characters.  Note [5].
513  space  Any whitespace character. "\s" plus the vertical tab ("\cK").
514  upper  Any uppercase character ("[A-Z]").
515  word   A Perl extension ("[A-Za-z0-9_]"), equivalent to "\w".
516  xdigit Any hexadecimal digit ("[0-9a-fA-F]").
517
518 Most POSIX character classes have two Unicode-style C<\p> property
519 counterparts.  (They are not official Unicode properties, but Perl extensions
520 derived from official Unicode properties.)  The table below shows the relation
521 between POSIX character classes and these counterparts.
522
523 One counterpart, in the column labelled "ASCII-range Unicode" in
524 the table, will only match characters in the ASCII character set.
525
526 The other counterpart, in the column labelled "Full-range Unicode", matches any
527 appropriate characters in the full Unicode character set.  For example,
528 C<\p{Alpha}> will match not just the ASCII alphabetic characters, but any
529 character in the entire Unicode character set that is considered to be
530 alphabetic.  The backslash sequence column is a (short) synonym for
531 the Full-range Unicode form.
532
533 (Each of the counterparts has various synonyms as well.
534 L<perluniprops/Properties accessible through \p{} and \P{}> lists all the
535 synonyms, plus all the characters matched by each of the ASCII-range
536 properties.  For example C<\p{AHex}> is a synonym for C<\p{ASCII_Hex_Digit}>,
537 and any C<\p> property name can be prefixed with "Is" such as C<\p{IsAlpha}>.)
538
539 Both the C<\p> forms are unaffected by any locale that is in effect, or whether
540 the string is in UTF-8 format or not, or whether the platform is EBCDIC or not.
541 In contrast, the POSIX character classes are affected.  If the source string is
542 in UTF-8 format, the POSIX classes behave like their "Full-range"
543 Unicode counterparts.  If the
544 source string is not in UTF-8 format, and no locale is in effect, and the
545 platform is not EBCDIC, all the POSIX classes behave like their ASCII-range
546 counterparts.  Otherwise, they behave based on the rules of the locale or
547 EBCDIC code page.
548
549 It is proposed to change this behavior in a future release of Perl so that the
550 the UTF8ness of the source string will be irrelevant to the behavior of the
551 POSIX character classes.  This means they will always behave in strict
552 accordance with the official POSIX standard.  That is, if either locale or
553 EBCDIC code page is present, they will behave in accordance with those; if
554 absent, the classes will match only their ASCII-range counterparts.  If you
555 disagree with this proposal, send email to C<perl5-porters@perl.org>.
556
557  [[:...:]]      ASCII-range          Full-range  backslash  Note
558                  Unicode              Unicode     sequence
559  -----------------------------------------------------
560    alpha      \p{PosixAlpha}       \p{XPosixAlpha}
561    alnum      \p{PosixAlnum}       \p{XPosixAlnum}
562    ascii      \p{ASCII}          
563    blank      \p{PosixBlank}       \p{XPosixBlank}  \h      [1]
564                                    or \p{HorizSpace}        [1]
565    cntrl      \p{PosixCntrl}       \p{XPosixCntrl}          [2]
566    digit      \p{PosixDigit}       \p{XPosixDigit}  \d
567    graph      \p{PosixGraph}       \p{XPosixGraph}          [3]
568    lower      \p{PosixLower}       \p{XPosixLower}
569    print      \p{PosixPrint}       \p{XPosixPrint}          [4]
570    punct      \p{PosixPunct}       \p{XPosixPunct}          [5]
571               \p{PerlSpace}        \p{XPerlSpace}   \s      [6]
572    space      \p{PosixSpace}       \p{XPosixSpace}          [6]
573    upper      \p{PosixUpper}       \p{XPosixUpper}
574    word       \p{PosixWord}        \p{XPosixWord}   \w
575    xdigit     \p{ASCII_Hex_Digit}  \p{XPosixXDigit}
576
577 =over 4
578
579 =item [1]
580
581 C<\p{Blank}> and C<\p{HorizSpace}> are synonyms.
582
583 =item [2]
584
585 Control characters don't produce output as such, but instead usually control
586 the terminal somehow: for example newline and backspace are control characters.
587 In the ASCII range, characters whose ordinals are between 0 and 31 inclusive,
588 plus 127 (C<DEL>) are control characters.
589
590 On EBCDIC platforms, it is likely that the code page will define C<[[:cntrl:]]>
591 to be the EBCDIC equivalents of the ASCII controls, plus the controls
592 that in Unicode have ordinals from 128 through 159.
593
594 =item [3]
595
596 Any character that is I<graphical>, that is, visible. This class consists
597 of all the alphanumerical characters and all punctuation characters.
598
599 =item [4]
600
601 All printable characters, which is the set of all the graphical characters
602 plus whitespace characters that are not also controls.
603
604 =item [5]
605
606 C<\p{PosixPunct}> and C<[[:punct:]]> in the ASCII range match all the
607 non-controls, non-alphanumeric, non-space characters:
608 C<[-!"#$%&'()*+,./:;<=E<gt>?@[\\\]^_`{|}~]> (although if a locale is in effect,
609 it could alter the behavior of C<[[:punct:]]>).
610
611 The similarly named property, C<\p{Punct}>, matches a somewhat different
612 set in the ASCII range, namely
613 C<[-!"#%&'()*,./:;?@[\\\]_{}]>.  That is, it is missing C<[$+E<lt>=E<gt>^`|~]>.
614 This is because Unicode splits what POSIX considers to be punctuation into two
615 categories, Punctuation and Symbols.
616
617 C<\p{PosixPunct>, and when the matching string is in UTF-8 format,
618 C<[[:punct:]]>, match what they match in the ASCII range, plus what
619 C<\p{Punct}> matches.  This is different
620 than strictly matching according to C<\p{Punct}>.  Another way to say it is that
621 for a UTF-8 string, C<[[:punct:]]> matches all the characters that Unicode
622 considers to be punctuation, plus all the ASCII-range characters that Unicode
623 considers to be symbols.
624
625 =item [6]
626
627 C<\p{SpacePerl}> and C<\p{Space}> differ only in that C<\p{Space}> additionally
628 matches the vertical tab, C<\cK>.   Same for the two ASCII-only range forms.
629
630 =back
631
632 There are various other synonyms that can be used for these besides
633 C<\p{HorizSpace}> and \C<\p{XPosixBlank}>.  For example
634 C<\p{PosixAlpha}> can be written as C<\p{Alpha}>.  All are listed
635 in L<perluniprops/Properties accessible through \p{} and \P{}>.
636
637 =head4 Negation
638 X<character class, negation>
639
640 A Perl extension to the POSIX character class is the ability to
641 negate it. This is done by prefixing the class name with a caret (C<^>).
642 Some examples:
643
644      POSIX         ASCII-range     Full-range  backslash
645                     Unicode         Unicode    sequence
646  -----------------------------------------------------
647  [[:^digit:]]   \P{PosixDigit}  \P{XPosixDigit}   \D
648  [[:^space:]]   \P{PosixSpace}  \P{XPosixSpace}
649                 \P{PerlSpace}   \P{XPerlSpace}    \S
650  [[:^word:]]    \P{PerlWord}    \P{XPosixWord}    \W
651
652 Again, the backslash sequence means Full-range Unicode.
653
654 =head4 [= =] and [. .]
655
656 Perl will recognize the POSIX character classes C<[=class=]>, and
657 C<[.class.]>, but does not (yet?) support them.  Use of
658 such a construct will lead to an error.
659
660
661 =head4 Examples
662
663  /[[:digit:]]/            # Matches a character that is a digit.
664  /[01[:lower:]]/          # Matches a character that is either a
665                           # lowercase letter, or '0' or '1'.
666  /[[:digit:][:^xdigit:]]/ # Matches a character that can be anything
667                           # except the letters 'a' to 'f'.  This is
668                           # because the main character class is composed
669                           # of two POSIX character classes that are ORed
670                           # together, one that matches any digit, and
671                           # the other that matches anything that isn't a
672                           # hex digit.  The result matches all
673                           # characters except the letters 'a' to 'f' and
674                           # 'A' to 'F'.
675
676
677 =head2 Locale, EBCDIC, Unicode and UTF-8
678
679 Some of the character classes have a somewhat different behaviour depending
680 on the internal encoding of the source string, if the regular expression
681 is marked as having Unicode semantics, the locale that is in effect,
682 and if the program is running on an EBCDIC platform.
683
684 C<\w>, C<\d>, C<\s> and the POSIX character classes (and their negations,
685 including C<\W>, C<\D>, C<\S>) have this behaviour.  (Since the backslash
686 sequences C<\b> and C<\B> are defined in terms of C<\w> and C<\W>, they also are
687 affected.)
688
689 The rule is that if the source string is in UTF-8 format or the regular
690 expression is marked as indicating Unicode semantics (see the next
691 paragraph), the character classes match according to the Unicode
692 properties.  Otherwise, the character classes match according to
693 whatever locale or EBCDIC code page is in effect. If there is no locale
694 nor EBCDIC, they match the ASCII defaults (0 to 9 for C<\d>; 52 letters,
695 10 digits and underscore for C<\w>; etc.).
696
697 A regular expression is marked for Unicode semantics if it is encoded in
698 utf8 (usually as a result of including a literal character whose code
699 point is above 255), or if it contains a C<\N{U+...}> or C<\N{I<name>}>
700 construct, or (starting in Perl 5.14) if it was compiled in the scope of a
701 C<S<use feature "unicode_strings">> pragma, or has the C<"u"> regular
702 expression modifier.
703
704 The differences in behavior between locale and non-locale semantics
705 can affect any character whose code point is 255 or less.  The
706 differences in behavior between Unicode and non-Unicode semantics
707 affects only ASCII platforms, and only when matching against characters
708 whose code points are between 128 and 255 inclusive.  See
709 L<perlunicode/The "Unicode Bug">.
710
711 For portability reasons, it may be better to not use C<\w>, C<\d>, C<\s>
712 or the POSIX character classes, and use the Unicode properties instead.
713 That way you can control whether you want matching of just characters in
714 the ASCII character set, or any Unicode characters.
715 C<S<use feature "unicode_strings">> will allow seamless Unicode behavior
716 no matter what the internal encodings are, but won't allow restricting
717 to just the ASCII characters.
718
719 =head4 Examples
720
721  $str =  "\xDF";      # $str is not in UTF-8 format.
722  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
723  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
724  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
725  chop $str;
726  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
727
728 =cut