Exporter-5.72 is now on the CPAN
[perl.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME(SIG) BLOCK           #  with a signature instead
19     sub NAME : ATTRS BLOCK        #  with attributes
20     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
21     sub NAME(SIG) : ATTRS BLOCK   #  with a signature and attributes
22
23 To define an anonymous subroutine at runtime:
24 X<subroutine, anonymous>
25
26     $subref = sub BLOCK;                 # no proto
27     $subref = sub (PROTO) BLOCK;         # with proto
28     $subref = sub (SIG) BLOCK;           # with signature
29     $subref = sub : ATTRS BLOCK;         # with attributes
30     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
31     $subref = sub (SIG) : ATTRS BLOCK;   # with signature and attributes
32
33 To import subroutines:
34 X<import>
35
36     use MODULE qw(NAME1 NAME2 NAME3);
37
38 To call subroutines:
39 X<subroutine, call> X<call>
40
41     NAME(LIST);    # & is optional with parentheses.
42     NAME LIST;     # Parentheses optional if predeclared/imported.
43     &NAME(LIST);   # Circumvent prototypes.
44     &NAME;         # Makes current @_ visible to called subroutine.
45
46 =head1 DESCRIPTION
47
48 Like many languages, Perl provides for user-defined subroutines.
49 These may be located anywhere in the main program, loaded in from
50 other files via the C<do>, C<require>, or C<use> keywords, or
51 generated on the fly using C<eval> or anonymous subroutines.
52 You can even call a function indirectly using a variable containing
53 its name or a CODE reference.
54
55 The Perl model for function call and return values is simple: all
56 functions are passed as parameters one single flat list of scalars, and
57 all functions likewise return to their caller one single flat list of
58 scalars.  Any arrays or hashes in these call and return lists will
59 collapse, losing their identities--but you may always use
60 pass-by-reference instead to avoid this.  Both call and return lists may
61 contain as many or as few scalar elements as you'd like.  (Often a
62 function without an explicit return statement is called a subroutine, but
63 there's really no difference from Perl's perspective.)
64 X<subroutine, parameter> X<parameter>
65
66 Any arguments passed in show up in the array C<@_>.
67 (They may also show up in lexical variables introduced by a signature;
68 see L</Signatures> below.)  Therefore, if
69 you called a function with two arguments, those would be stored in
70 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
71 elements are aliases for the actual scalar parameters.  In particular,
72 if an element C<$_[0]> is updated, the corresponding argument is
73 updated (or an error occurs if it is not updatable).  If an argument
74 is an array or hash element which did not exist when the function
75 was called, that element is created only when (and if) it is modified
76 or a reference to it is taken.  (Some earlier versions of Perl
77 created the element whether or not the element was assigned to.)
78 Assigning to the whole array C<@_> removes that aliasing, and does
79 not update any arguments.
80 X<subroutine, argument> X<argument> X<@_>
81
82 A C<return> statement may be used to exit a subroutine, optionally
83 specifying the returned value, which will be evaluated in the
84 appropriate context (list, scalar, or void) depending on the context of
85 the subroutine call.  If you specify no return value, the subroutine
86 returns an empty list in list context, the undefined value in scalar
87 context, or nothing in void context.  If you return one or more
88 aggregates (arrays and hashes), these will be flattened together into
89 one large indistinguishable list.
90
91 If no C<return> is found and if the last statement is an expression, its
92 value is returned.  If the last statement is a loop control structure
93 like a C<foreach> or a C<while>, the returned value is unspecified.  The
94 empty sub returns the empty list.
95 X<subroutine, return value> X<return value> X<return>
96
97 Aside from an experimental facility (see L</Signatures> below),
98 Perl does not have named formal parameters.  In practice all you
99 do is assign to a C<my()> list of these.  Variables that aren't
100 declared to be private are global variables.  For gory details
101 on creating private variables, see L<"Private Variables via my()">
102 and L<"Temporary Values via local()">.  To create protected
103 environments for a set of functions in a separate package (and
104 probably a separate file), see L<perlmod/"Packages">.
105 X<formal parameter> X<parameter, formal>
106
107 Example:
108
109     sub max {
110         my $max = shift(@_);
111         foreach $foo (@_) {
112             $max = $foo if $max < $foo;
113         }
114         return $max;
115     }
116     $bestday = max($mon,$tue,$wed,$thu,$fri);
117
118 Example:
119
120     # get a line, combining continuation lines
121     #  that start with whitespace
122
123     sub get_line {
124         $thisline = $lookahead;  # global variables!
125         LINE: while (defined($lookahead = <STDIN>)) {
126             if ($lookahead =~ /^[ \t]/) {
127                 $thisline .= $lookahead;
128             }
129             else {
130                 last LINE;
131             }
132         }
133         return $thisline;
134     }
135
136     $lookahead = <STDIN>;       # get first line
137     while (defined($line = get_line())) {
138         ...
139     }
140
141 Assigning to a list of private variables to name your arguments:
142
143     sub maybeset {
144         my($key, $value) = @_;
145         $Foo{$key} = $value unless $Foo{$key};
146     }
147
148 Because the assignment copies the values, this also has the effect
149 of turning call-by-reference into call-by-value.  Otherwise a
150 function is free to do in-place modifications of C<@_> and change
151 its caller's values.
152 X<call-by-reference> X<call-by-value>
153
154     upcase_in($v1, $v2);  # this changes $v1 and $v2
155     sub upcase_in {
156         for (@_) { tr/a-z/A-Z/ }
157     }
158
159 You aren't allowed to modify constants in this way, of course.  If an
160 argument were actually literal and you tried to change it, you'd take a
161 (presumably fatal) exception.   For example, this won't work:
162 X<call-by-reference> X<call-by-value>
163
164     upcase_in("frederick");
165
166 It would be much safer if the C<upcase_in()> function
167 were written to return a copy of its parameters instead
168 of changing them in place:
169
170     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
171     sub upcase {
172         return unless defined wantarray;  # void context, do nothing
173         my @parms = @_;
174         for (@parms) { tr/a-z/A-Z/ }
175         return wantarray ? @parms : $parms[0];
176     }
177
178 Notice how this (unprototyped) function doesn't care whether it was
179 passed real scalars or arrays.  Perl sees all arguments as one big,
180 long, flat parameter list in C<@_>.  This is one area where
181 Perl's simple argument-passing style shines.  The C<upcase()>
182 function would work perfectly well without changing the C<upcase()>
183 definition even if we fed it things like this:
184
185     @newlist   = upcase(@list1, @list2);
186     @newlist   = upcase( split /:/, $var );
187
188 Do not, however, be tempted to do this:
189
190     (@a, @b)   = upcase(@list1, @list2);
191
192 Like the flattened incoming parameter list, the return list is also
193 flattened on return.  So all you have managed to do here is stored
194 everything in C<@a> and made C<@b> empty.  See 
195 L<Pass by Reference> for alternatives.
196
197 A subroutine may be called using an explicit C<&> prefix.  The
198 C<&> is optional in modern Perl, as are parentheses if the
199 subroutine has been predeclared.  The C<&> is I<not> optional
200 when just naming the subroutine, such as when it's used as
201 an argument to defined() or undef().  Nor is it optional when you
202 want to do an indirect subroutine call with a subroutine name or
203 reference using the C<&$subref()> or C<&{$subref}()> constructs,
204 although the C<< $subref->() >> notation solves that problem.
205 See L<perlref> for more about all that.
206 X<&>
207
208 Subroutines may be called recursively.  If a subroutine is called
209 using the C<&> form, the argument list is optional, and if omitted,
210 no C<@_> array is set up for the subroutine: the C<@_> array at the
211 time of the call is visible to subroutine instead.  This is an
212 efficiency mechanism that new users may wish to avoid.
213 X<recursion>
214
215     &foo(1,2,3);        # pass three arguments
216     foo(1,2,3);         # the same
217
218     foo();              # pass a null list
219     &foo();             # the same
220
221     &foo;               # foo() get current args, like foo(@_) !!
222     foo;                # like foo() IFF sub foo predeclared, else "foo"
223
224 Not only does the C<&> form make the argument list optional, it also
225 disables any prototype checking on arguments you do provide.  This
226 is partly for historical reasons, and partly for having a convenient way
227 to cheat if you know what you're doing.  See L</Prototypes> below.
228 X<&>
229
230 Since Perl 5.16.0, the C<__SUB__> token is available under C<use feature
231 'current_sub'> and C<use 5.16.0>.  It will evaluate to a reference to the
232 currently-running sub, which allows for recursive calls without knowing
233 your subroutine's name.
234
235     use 5.16.0;
236     my $factorial = sub {
237       my ($x) = @_;
238       return 1 if $x == 1;
239       return($x * __SUB__->( $x - 1 ) );
240     };
241
242 The behavior of C<__SUB__> within a regex code block (such as C</(?{...})/>)
243 is subject to change.
244
245 Subroutines whose names are in all upper case are reserved to the Perl
246 core, as are modules whose names are in all lower case.  A subroutine in
247 all capitals is a loosely-held convention meaning it will be called
248 indirectly by the run-time system itself, usually due to a triggered event.
249 Subroutines whose name start with a left parenthesis are also reserved the 
250 same way.  The following is a list of some subroutines that currently do 
251 special, pre-defined things.
252
253 =over
254
255 =item documented later in this document
256
257 C<AUTOLOAD>
258
259 =item documented in L<perlmod>
260
261 C<CLONE>, C<CLONE_SKIP>, 
262
263 =item documented in L<perlobj>
264
265 C<DESTROY>
266
267 =item documented in L<perltie>
268
269 C<BINMODE>, C<CLEAR>, C<CLOSE>, C<DELETE>, C<DESTROY>, C<EOF>, C<EXISTS>, 
270 C<EXTEND>, C<FETCH>, C<FETCHSIZE>, C<FILENO>, C<FIRSTKEY>, C<GETC>, 
271 C<NEXTKEY>, C<OPEN>, C<POP>, C<PRINT>, C<PRINTF>, C<PUSH>, C<READ>, 
272 C<READLINE>, C<SCALAR>, C<SEEK>, C<SHIFT>, C<SPLICE>, C<STORE>, 
273 C<STORESIZE>, C<TELL>, C<TIEARRAY>, C<TIEHANDLE>, C<TIEHASH>, 
274 C<TIESCALAR>, C<UNSHIFT>, C<UNTIE>, C<WRITE>
275
276 =item documented in L<PerlIO::via>
277
278 C<BINMODE>, C<CLEARERR>, C<CLOSE>, C<EOF>, C<ERROR>, C<FDOPEN>, C<FILENO>, 
279 C<FILL>, C<FLUSH>, C<OPEN>, C<POPPED>, C<PUSHED>, C<READ>, C<SEEK>, 
280 C<SETLINEBUF>, C<SYSOPEN>, C<TELL>, C<UNREAD>, C<UTF8>, C<WRITE>
281
282 =item documented in L<perlfunc>
283
284 L<< C<import> | perlfunc/use >>, L<< C<unimport> | perlfunc/use >>,
285 L<< C<INC> | perlfunc/require >>
286
287 =item documented in L<UNIVERSAL>
288
289 C<VERSION>
290
291 =item documented in L<perldebguts>
292
293 C<DB::DB>, C<DB::sub>, C<DB::lsub>, C<DB::goto>, C<DB::postponed>
294
295 =item undocumented, used internally by the L<overload> feature
296
297 any starting with C<(>
298
299 =back
300
301 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
302 are not so much subroutines as named special code blocks, of which you
303 can have more than one in a package, and which you can B<not> call
304 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
305
306 =head2 Signatures
307
308 B<WARNING>: Subroutine signatures are experimental.  The feature may be
309 modified or removed in future versions of Perl.
310
311 Perl has an experimental facility to allow a subroutine's formal
312 parameters to be introduced by special syntax, separate from the
313 procedural code of the subroutine body.  The formal parameter list
314 is known as a I<signature>.  The facility must be enabled first by a
315 pragmatic declaration, C<use feature 'signatures'>, and it will produce
316 a warning unless the "experimental::signatures" warnings category is
317 disabled.
318
319 The signature is part of a subroutine's body.  Normally the body of a
320 subroutine is simply a braced block of code.  When using a signature,
321 the signature is a parenthesised list that goes immediately after
322 the subroutine name.  The signature declares lexical variables that are
323 in scope for the block.  When the subroutine is called, the signature
324 takes control first.  It populates the signature variables from the
325 list of arguments that were passed.  If the argument list doesn't meet
326 the requirements of the signature, then it will throw an exception.
327 When the signature processing is complete, control passes to the block.
328
329 Positional parameters are handled by simply naming scalar variables in
330 the signature.  For example,
331
332     sub foo ($left, $right) {
333         return $left + $right;
334     }
335
336 takes two positional parameters, which must be filled at runtime by
337 two arguments.  By default the parameters are mandatory, and it is
338 not permitted to pass more arguments than expected.  So the above is
339 equivalent to
340
341     sub foo {
342         die "Too many arguments for subroutine" unless @_ <= 2;
343         die "Too few arguments for subroutine" unless @_ >= 2;
344         my $left = $_[0];
345         my $right = $_[1];
346         return $left + $right;
347     }
348
349 An argument can be ignored by omitting the main part of the name from
350 a parameter declaration, leaving just a bare C<$> sigil.  For example,
351
352     sub foo ($first, $, $third) {
353         return "first=$first, third=$third";
354     }
355
356 Although the ignored argument doesn't go into a variable, it is still
357 mandatory for the caller to pass it.
358
359 A positional parameter is made optional by giving a default value,
360 separated from the parameter name by C<=>:
361
362     sub foo ($left, $right = 0) {
363         return $left + $right;
364     }
365
366 The above subroutine may be called with either one or two arguments.
367 The default value expression is evaluated when the subroutine is called,
368 so it may provide different default values for different calls.  It is
369 only evaluated if the argument was actually omitted from the call.
370 For example,
371
372     my $auto_id = 0;
373     sub foo ($thing, $id = $auto_id++) {
374         print "$thing has ID $id";
375     }
376
377 automatically assigns distinct sequential IDs to things for which no
378 ID was supplied by the caller.  A default value expression may also
379 refer to parameters earlier in the signature, making the default for
380 one parameter vary according to the earlier parameters.  For example,
381
382     sub foo ($first_name, $surname, $nickname = $first_name) {
383         print "$first_name $surname is known as \"$nickname\"";
384     }
385
386 An optional parameter can be nameless just like a mandatory parameter.
387 For example,
388
389     sub foo ($thing, $ = 1) {
390         print $thing;
391     }
392
393 The parameter's default value will still be evaluated if the corresponding
394 argument isn't supplied, even though the value won't be stored anywhere.
395 This is in case evaluating it has important side effects.  However, it
396 will be evaluated in void context, so if it doesn't have side effects
397 and is not trivial it will generate a warning if the "void" warning
398 category is enabled.  If a nameless optional parameter's default value
399 is not important, it may be omitted just as the parameter's name was:
400
401     sub foo ($thing, $=) {
402         print $thing;
403     }
404
405 Optional positional parameters must come after all mandatory positional
406 parameters.  (If there are no mandatory positional parameters then an
407 optional positional parameters can be the first thing in the signature.)
408 If there are multiple optional positional parameters and not enough
409 arguments are supplied to fill them all, they will be filled from left
410 to right.
411
412 After positional parameters, additional arguments may be captured in a
413 slurpy parameter.  The simplest form of this is just an array variable:
414
415     sub foo ($filter, @inputs) {
416         print $filter->($_) foreach @inputs;
417     }
418
419 With a slurpy parameter in the signature, there is no upper limit on how
420 many arguments may be passed.  A slurpy array parameter may be nameless
421 just like a positional parameter, in which case its only effect is to
422 turn off the argument limit that would otherwise apply:
423
424     sub foo ($thing, @) {
425         print $thing;
426     }
427
428 A slurpy parameter may instead be a hash, in which case the arguments
429 available to it are interpreted as alternating keys and values.
430 There must be as many keys as values: if there is an odd argument then
431 an exception will be thrown.  Keys will be stringified, and if there are
432 duplicates then the later instance takes precedence over the earlier,
433 as with standard hash construction.
434
435     sub foo ($filter, %inputs) {
436         print $filter->($_, $inputs{$_}) foreach sort keys %inputs;
437     }
438
439 A slurpy hash parameter may be nameless just like other kinds of
440 parameter.  It still insists that the number of arguments available to
441 it be even, even though they're not being put into a variable.
442
443     sub foo ($thing, %) {
444         print $thing;
445     }
446
447 A slurpy parameter, either array or hash, must be the last thing in the
448 signature.  It may follow mandatory and optional positional parameters;
449 it may also be the only thing in the signature.  Slurpy parameters cannot
450 have default values: if no arguments are supplied for them then you get
451 an empty array or empty hash.
452
453 A signature may be entirely empty, in which case all it does is check
454 that the caller passed no arguments:
455
456     sub foo () {
457         return 123;
458     }
459
460 When using a signature, the arguments are still available in the special
461 array variable C<@_>, in addition to the lexical variables of the
462 signature.  There is a difference between the two ways of accessing the
463 arguments: C<@_> I<aliases> the arguments, but the signature variables
464 get I<copies> of the arguments.  So writing to a signature variable
465 only changes that variable, and has no effect on the caller's variables,
466 but writing to an element of C<@_> modifies whatever the caller used to
467 supply that argument.
468
469 There is a potential syntactic ambiguity between signatures and prototypes
470 (see L</Prototypes>), because both start with an opening parenthesis and
471 both can appear in some of the same places, such as just after the name
472 in a subroutine declaration.  For historical reasons, when signatures
473 are not enabled, any opening parenthesis in such a context will trigger
474 very forgiving prototype parsing.  Most signatures will be interpreted
475 as prototypes in those circumstances, but won't be valid prototypes.
476 (A valid prototype cannot contain any alphabetic character.)  This will
477 lead to somewhat confusing error messages.
478
479 To avoid ambiguity, when signatures are enabled the special syntax
480 for prototypes is disabled.  There is no attempt to guess whether a
481 parenthesised group was intended to be a prototype or a signature.
482 To give a subroutine a prototype under these circumstances, use a
483 L<prototype attribute|attributes/Built-in Attributes>.  For example,
484
485     sub foo :prototype($) { $_[0] }
486
487 It is entirely possible for a subroutine to have both a prototype and
488 a signature.  They do different jobs: the prototype affects compilation
489 of calls to the subroutine, and the signature puts argument values into
490 lexical variables at runtime.  You can therefore write
491
492     sub foo ($left, $right) : prototype($$) {
493         return $left + $right;
494     }
495
496 The prototype attribute, and any other attributes, come after 
497 the signature.
498
499 =head2 Private Variables via my()
500 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
501 X<lexical scope> X<attributes, my>
502
503 Synopsis:
504
505     my $foo;            # declare $foo lexically local
506     my (@wid, %get);    # declare list of variables local
507     my $foo = "flurp";  # declare $foo lexical, and init it
508     my @oof = @bar;     # declare @oof lexical, and init it
509     my $x : Foo = $y;   # similar, with an attribute applied
510
511 B<WARNING>: The use of attribute lists on C<my> declarations is still
512 evolving.  The current semantics and interface are subject to change.
513 See L<attributes> and L<Attribute::Handlers>.
514
515 The C<my> operator declares the listed variables to be lexically
516 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
517 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
518 or C<do/require/use>'d file.  If more than one value is listed, the
519 list must be placed in parentheses.  All listed elements must be
520 legal lvalues.  Only alphanumeric identifiers may be lexically
521 scoped--magical built-ins like C<$/> must currently be C<local>ized
522 with C<local> instead.
523
524 Unlike dynamic variables created by the C<local> operator, lexical
525 variables declared with C<my> are totally hidden from the outside
526 world, including any called subroutines.  This is true if it's the
527 same subroutine called from itself or elsewhere--every call gets
528 its own copy.
529 X<local>
530
531 This doesn't mean that a C<my> variable declared in a statically
532 enclosing lexical scope would be invisible.  Only dynamic scopes
533 are cut off.   For example, the C<bumpx()> function below has access
534 to the lexical $x variable because both the C<my> and the C<sub>
535 occurred at the same scope, presumably file scope.
536
537     my $x = 10;
538     sub bumpx { $x++ } 
539
540 An C<eval()>, however, can see lexical variables of the scope it is
541 being evaluated in, so long as the names aren't hidden by declarations within
542 the C<eval()> itself.  See L<perlref>.
543 X<eval, scope of>
544
545 The parameter list to my() may be assigned to if desired, which allows you
546 to initialize your variables.  (If no initializer is given for a
547 particular variable, it is created with the undefined value.)  Commonly
548 this is used to name input parameters to a subroutine.  Examples:
549
550     $arg = "fred";        # "global" variable
551     $n = cube_root(27);
552     print "$arg thinks the root is $n\n";
553  fred thinks the root is 3
554
555     sub cube_root {
556         my $arg = shift;  # name doesn't matter
557         $arg **= 1/3;
558         return $arg;
559     }
560
561 The C<my> is simply a modifier on something you might assign to.  So when
562 you do assign to variables in its argument list, C<my> doesn't
563 change whether those variables are viewed as a scalar or an array.  So
564
565     my ($foo) = <STDIN>;                # WRONG?
566     my @FOO = <STDIN>;
567
568 both supply a list context to the right-hand side, while
569
570     my $foo = <STDIN>;
571
572 supplies a scalar context.  But the following declares only one variable:
573
574     my $foo, $bar = 1;                  # WRONG
575
576 That has the same effect as
577
578     my $foo;
579     $bar = 1;
580
581 The declared variable is not introduced (is not visible) until after
582 the current statement.  Thus,
583
584     my $x = $x;
585
586 can be used to initialize a new $x with the value of the old $x, and
587 the expression
588
589     my $x = 123 and $x == 123
590
591 is false unless the old $x happened to have the value C<123>.
592
593 Lexical scopes of control structures are not bounded precisely by the
594 braces that delimit their controlled blocks; control expressions are
595 part of that scope, too.  Thus in the loop
596
597     while (my $line = <>) {
598         $line = lc $line;
599     } continue {
600         print $line;
601     }
602
603 the scope of $line extends from its declaration throughout the rest of
604 the loop construct (including the C<continue> clause), but not beyond
605 it.  Similarly, in the conditional
606
607     if ((my $answer = <STDIN>) =~ /^yes$/i) {
608         user_agrees();
609     } elsif ($answer =~ /^no$/i) {
610         user_disagrees();
611     } else {
612         chomp $answer;
613         die "'$answer' is neither 'yes' nor 'no'";
614     }
615
616 the scope of $answer extends from its declaration through the rest
617 of that conditional, including any C<elsif> and C<else> clauses, 
618 but not beyond it.  See L<perlsyn/"Simple Statements"> for information
619 on the scope of variables in statements with modifiers.
620
621 The C<foreach> loop defaults to scoping its index variable dynamically
622 in the manner of C<local>.  However, if the index variable is
623 prefixed with the keyword C<my>, or if there is already a lexical
624 by that name in scope, then a new lexical is created instead.  Thus
625 in the loop
626 X<foreach> X<for>
627
628     for my $i (1, 2, 3) {
629         some_function();
630     }
631
632 the scope of $i extends to the end of the loop, but not beyond it,
633 rendering the value of $i inaccessible within C<some_function()>.
634 X<foreach> X<for>
635
636 Some users may wish to encourage the use of lexically scoped variables.
637 As an aid to catching implicit uses to package variables,
638 which are always global, if you say
639
640     use strict 'vars';
641
642 then any variable mentioned from there to the end of the enclosing
643 block must either refer to a lexical variable, be predeclared via
644 C<our> or C<use vars>, or else must be fully qualified with the package name.
645 A compilation error results otherwise.  An inner block may countermand
646 this with C<no strict 'vars'>.
647
648 A C<my> has both a compile-time and a run-time effect.  At compile
649 time, the compiler takes notice of it.  The principal usefulness
650 of this is to quiet C<use strict 'vars'>, but it is also essential
651 for generation of closures as detailed in L<perlref>.  Actual
652 initialization is delayed until run time, though, so it gets executed
653 at the appropriate time, such as each time through a loop, for
654 example.
655
656 Variables declared with C<my> are not part of any package and are therefore
657 never fully qualified with the package name.  In particular, you're not
658 allowed to try to make a package variable (or other global) lexical:
659
660     my $pack::var;      # ERROR!  Illegal syntax
661
662 In fact, a dynamic variable (also known as package or global variables)
663 are still accessible using the fully qualified C<::> notation even while a
664 lexical of the same name is also visible:
665
666     package main;
667     local $x = 10;
668     my    $x = 20;
669     print "$x and $::x\n";
670
671 That will print out C<20> and C<10>.
672
673 You may declare C<my> variables at the outermost scope of a file
674 to hide any such identifiers from the world outside that file.  This
675 is similar in spirit to C's static variables when they are used at
676 the file level.  To do this with a subroutine requires the use of
677 a closure (an anonymous function that accesses enclosing lexicals).
678 If you want to create a private subroutine that cannot be called
679 from outside that block, it can declare a lexical variable containing
680 an anonymous sub reference:
681
682     my $secret_version = '1.001-beta';
683     my $secret_sub = sub { print $secret_version };
684     &$secret_sub();
685
686 As long as the reference is never returned by any function within the
687 module, no outside module can see the subroutine, because its name is not in
688 any package's symbol table.  Remember that it's not I<REALLY> called
689 C<$some_pack::secret_version> or anything; it's just $secret_version,
690 unqualified and unqualifiable.
691
692 This does not work with object methods, however; all object methods
693 have to be in the symbol table of some package to be found.  See
694 L<perlref/"Function Templates"> for something of a work-around to
695 this.
696
697 =head2 Persistent Private Variables
698 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
699
700 There are two ways to build persistent private variables in Perl 5.10.
701 First, you can simply use the C<state> feature.  Or, you can use closures,
702 if you want to stay compatible with releases older than 5.10.
703
704 =head3 Persistent variables via state()
705
706 Beginning with Perl 5.10.0, you can declare variables with the C<state>
707 keyword in place of C<my>.  For that to work, though, you must have
708 enabled that feature beforehand, either by using the C<feature> pragma, or
709 by using C<-E> on one-liners (see L<feature>).  Beginning with Perl 5.16,
710 the C<CORE::state> form does not require the
711 C<feature> pragma.
712
713 The C<state> keyword creates a lexical variable (following the same scoping
714 rules as C<my>) that persists from one subroutine call to the next.  If a
715 state variable resides inside an anonymous subroutine, then each copy of
716 the subroutine has its own copy of the state variable.  However, the value
717 of the state variable will still persist between calls to the same copy of
718 the anonymous subroutine.  (Don't forget that C<sub { ... }> creates a new
719 subroutine each time it is executed.)
720
721 For example, the following code maintains a private counter, incremented
722 each time the gimme_another() function is called:
723
724     use feature 'state';
725     sub gimme_another { state $x; return ++$x }
726
727 And this example uses anonymous subroutines to create separate counters:
728
729     use feature 'state';
730     sub create_counter {
731         return sub { state $x; return ++$x }
732     }
733
734 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
735 code outside.
736
737 When combined with variable declaration, simple scalar assignment to C<state>
738 variables (as in C<state $x = 42>) is executed only the first time.  When such
739 statements are evaluated subsequent times, the assignment is ignored.  The
740 behavior of this sort of assignment to non-scalar variables is undefined.
741
742 =head3 Persistent variables with closures
743
744 Just because a lexical variable is lexically (also called statically)
745 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
746 within a function it works like a C static.  It normally works more
747 like a C auto, but with implicit garbage collection.  
748
749 Unlike local variables in C or C++, Perl's lexical variables don't
750 necessarily get recycled just because their scope has exited.
751 If something more permanent is still aware of the lexical, it will
752 stick around.  So long as something else references a lexical, that
753 lexical won't be freed--which is as it should be.  You wouldn't want
754 memory being free until you were done using it, or kept around once you
755 were done.  Automatic garbage collection takes care of this for you.
756
757 This means that you can pass back or save away references to lexical
758 variables, whereas to return a pointer to a C auto is a grave error.
759 It also gives us a way to simulate C's function statics.  Here's a
760 mechanism for giving a function private variables with both lexical
761 scoping and a static lifetime.  If you do want to create something like
762 C's static variables, just enclose the whole function in an extra block,
763 and put the static variable outside the function but in the block.
764
765     {
766         my $secret_val = 0;
767         sub gimme_another {
768             return ++$secret_val;
769         }
770     }
771     # $secret_val now becomes unreachable by the outside
772     # world, but retains its value between calls to gimme_another
773
774 If this function is being sourced in from a separate file
775 via C<require> or C<use>, then this is probably just fine.  If it's
776 all in the main program, you'll need to arrange for the C<my>
777 to be executed early, either by putting the whole block above
778 your main program, or more likely, placing merely a C<BEGIN>
779 code block around it to make sure it gets executed before your program
780 starts to run:
781
782     BEGIN {
783         my $secret_val = 0;
784         sub gimme_another {
785             return ++$secret_val;
786         }
787     }
788
789 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
790 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
791 C<INIT> and C<END>.
792
793 If declared at the outermost scope (the file scope), then lexicals
794 work somewhat like C's file statics.  They are available to all
795 functions in that same file declared below them, but are inaccessible
796 from outside that file.  This strategy is sometimes used in modules
797 to create private variables that the whole module can see.
798
799 =head2 Temporary Values via local()
800 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
801 X<variable, temporary>
802
803 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
804 it's faster and safer.  Exceptions to this include the global punctuation
805 variables, global filehandles and formats, and direct manipulation of the
806 Perl symbol table itself.  C<local> is mostly used when the current value
807 of a variable must be visible to called subroutines.
808
809 Synopsis:
810
811     # localization of values
812
813     local $foo;                # make $foo dynamically local
814     local (@wid, %get);        # make list of variables local
815     local $foo = "flurp";      # make $foo dynamic, and init it
816     local @oof = @bar;         # make @oof dynamic, and init it
817
818     local $hash{key} = "val";  # sets a local value for this hash entry
819     delete local $hash{key};   # delete this entry for the current block
820     local ($cond ? $v1 : $v2); # several types of lvalues support
821                                # localization
822
823     # localization of symbols
824
825     local *FH;                 # localize $FH, @FH, %FH, &FH  ...
826     local *merlyn = *randal;   # now $merlyn is really $randal, plus
827                                #     @merlyn is really @randal, etc
828     local *merlyn = 'randal';  # SAME THING: promote 'randal' to *randal
829     local *merlyn = \$randal;  # just alias $merlyn, not @merlyn etc
830
831 A C<local> modifies its listed variables to be "local" to the
832 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
833 called from within that block>.  A C<local> just gives temporary
834 values to global (meaning package) variables.  It does I<not> create
835 a local variable.  This is known as dynamic scoping.  Lexical scoping
836 is done with C<my>, which works more like C's auto declarations.
837
838 Some types of lvalues can be localized as well: hash and array elements
839 and slices, conditionals (provided that their result is always
840 localizable), and symbolic references.  As for simple variables, this
841 creates new, dynamically scoped values.
842
843 If more than one variable or expression is given to C<local>, they must be
844 placed in parentheses.  This operator works
845 by saving the current values of those variables in its argument list on a
846 hidden stack and restoring them upon exiting the block, subroutine, or
847 eval.  This means that called subroutines can also reference the local
848 variable, but not the global one.  The argument list may be assigned to if
849 desired, which allows you to initialize your local variables.  (If no
850 initializer is given for a particular variable, it is created with an
851 undefined value.)
852
853 Because C<local> is a run-time operator, it gets executed each time
854 through a loop.  Consequently, it's more efficient to localize your
855 variables outside the loop.
856
857 =head3 Grammatical note on local()
858 X<local, context>
859
860 A C<local> is simply a modifier on an lvalue expression.  When you assign to
861 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
862 as a scalar or an array.  So
863
864     local($foo) = <STDIN>;
865     local @FOO = <STDIN>;
866
867 both supply a list context to the right-hand side, while
868
869     local $foo = <STDIN>;
870
871 supplies a scalar context.
872
873 =head3 Localization of special variables
874 X<local, special variable>
875
876 If you localize a special variable, you'll be giving a new value to it,
877 but its magic won't go away.  That means that all side-effects related
878 to this magic still work with the localized value.
879
880 This feature allows code like this to work :
881
882     # Read the whole contents of FILE in $slurp
883     { local $/ = undef; $slurp = <FILE>; }
884
885 Note, however, that this restricts localization of some values ; for
886 example, the following statement dies, as of perl 5.10.0, with an error
887 I<Modification of a read-only value attempted>, because the $1 variable is
888 magical and read-only :
889
890     local $1 = 2;
891
892 One exception is the default scalar variable: starting with perl 5.14
893 C<local($_)> will always strip all magic from $_, to make it possible
894 to safely reuse $_ in a subroutine.
895
896 B<WARNING>: Localization of tied arrays and hashes does not currently
897 work as described.
898 This will be fixed in a future release of Perl; in the meantime, avoid
899 code that relies on any particular behavior of localising tied arrays
900 or hashes (localising individual elements is still okay).
901 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
902 details.
903 X<local, tie>
904
905 =head3 Localization of globs
906 X<local, glob> X<glob>
907
908 The construct
909
910     local *name;
911
912 creates a whole new symbol table entry for the glob C<name> in the
913 current package.  That means that all variables in its glob slot ($name,
914 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
915
916 This implies, among other things, that any magic eventually carried by
917 those variables is locally lost.  In other words, saying C<local */>
918 will not have any effect on the internal value of the input record
919 separator.
920
921 =head3 Localization of elements of composite types
922 X<local, composite type element> X<local, array element> X<local, hash element>
923
924 It's also worth taking a moment to explain what happens when you
925 C<local>ize a member of a composite type (i.e. an array or hash element).
926 In this case, the element is C<local>ized I<by name>.  This means that
927 when the scope of the C<local()> ends, the saved value will be
928 restored to the hash element whose key was named in the C<local()>, or
929 the array element whose index was named in the C<local()>.  If that
930 element was deleted while the C<local()> was in effect (e.g. by a
931 C<delete()> from a hash or a C<shift()> of an array), it will spring
932 back into existence, possibly extending an array and filling in the
933 skipped elements with C<undef>.  For instance, if you say
934
935     %hash = ( 'This' => 'is', 'a' => 'test' );
936     @ary  = ( 0..5 );
937     {
938          local($ary[5]) = 6;
939          local($hash{'a'}) = 'drill';
940          while (my $e = pop(@ary)) {
941              print "$e . . .\n";
942              last unless $e > 3;
943          }
944          if (@ary) {
945              $hash{'only a'} = 'test';
946              delete $hash{'a'};
947          }
948     }
949     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
950     print "The array has ",scalar(@ary)," elements: ",
951           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
952
953 Perl will print
954
955     6 . . .
956     4 . . .
957     3 . . .
958     This is a test only a test.
959     The array has 6 elements: 0, 1, 2, undef, undef, 5
960
961 The behavior of local() on non-existent members of composite
962 types is subject to change in future.
963
964 =head3 Localized deletion of elements of composite types
965 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
966
967 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
968 constructs to delete a composite type entry for the current block and restore
969 it when it ends.  They return the array/hash value before the localization,
970 which means that they are respectively equivalent to
971
972     do {
973         my $val = $array[$idx];
974         local  $array[$idx];
975         delete $array[$idx];
976         $val
977     }
978
979 and
980
981     do {
982         my $val = $hash{key};
983         local  $hash{key};
984         delete $hash{key};
985         $val
986     }
987
988 except that for those the C<local> is
989 scoped to the C<do> block.  Slices are
990 also accepted.
991
992     my %hash = (
993      a => [ 7, 8, 9 ],
994      b => 1,
995     )
996
997     {
998      my $a = delete local $hash{a};
999      # $a is [ 7, 8, 9 ]
1000      # %hash is (b => 1)
1001
1002      {
1003       my @nums = delete local @$a[0, 2]
1004       # @nums is (7, 9)
1005       # $a is [ undef, 8 ]
1006
1007       $a[0] = 999; # will be erased when the scope ends
1008      }
1009      # $a is back to [ 7, 8, 9 ]
1010
1011     }
1012     # %hash is back to its original state
1013
1014 =head2 Lvalue subroutines
1015 X<lvalue> X<subroutine, lvalue>
1016
1017 It is possible to return a modifiable value from a subroutine.
1018 To do this, you have to declare the subroutine to return an lvalue.
1019
1020     my $val;
1021     sub canmod : lvalue {
1022         $val;  # or:  return $val;
1023     }
1024     sub nomod {
1025         $val;
1026     }
1027
1028     canmod() = 5;   # assigns to $val
1029     nomod()  = 5;   # ERROR
1030
1031 The scalar/list context for the subroutine and for the right-hand
1032 side of assignment is determined as if the subroutine call is replaced
1033 by a scalar.  For example, consider:
1034
1035     data(2,3) = get_data(3,4);
1036
1037 Both subroutines here are called in a scalar context, while in:
1038
1039     (data(2,3)) = get_data(3,4);
1040
1041 and in:
1042
1043     (data(2),data(3)) = get_data(3,4);
1044
1045 all the subroutines are called in a list context.
1046
1047 Lvalue subroutines are convenient, but you have to keep in mind that,
1048 when used with objects, they may violate encapsulation.  A normal
1049 mutator can check the supplied argument before setting the attribute
1050 it is protecting, an lvalue subroutine cannot.  If you require any
1051 special processing when storing and retrieving the values, consider
1052 using the CPAN module Sentinel or something similar.
1053
1054 =head2 Lexical Subroutines
1055 X<my sub> X<state sub> X<our sub> X<subroutine, lexical>
1056
1057 B<WARNING>: Lexical subroutines are still experimental.  The feature may be
1058 modified or removed in future versions of Perl.
1059
1060 Lexical subroutines are only available under the C<use feature
1061 'lexical_subs'> pragma, which produces a warning unless the
1062 "experimental::lexical_subs" warnings category is disabled.
1063
1064 Beginning with Perl 5.18, you can declare a private subroutine with C<my>
1065 or C<state>.  As with state variables, the C<state> keyword is only
1066 available under C<use feature 'state'> or C<use 5.010> or higher.
1067
1068 These subroutines are only visible within the block in which they are
1069 declared, and only after that declaration:
1070
1071     no warnings "experimental::lexical_subs";
1072     use feature 'lexical_subs';
1073
1074     foo();              # calls the package/global subroutine
1075     state sub foo {
1076         foo();          # also calls the package subroutine
1077     }
1078     foo();              # calls "state" sub
1079     my $ref = \&foo;    # take a reference to "state" sub
1080
1081     my sub bar { ... }
1082     bar();              # calls "my" sub
1083
1084 To use a lexical subroutine from inside the subroutine itself, you must
1085 predeclare it.  The C<sub foo {...}> subroutine definition syntax respects
1086 any previous C<my sub;> or C<state sub;> declaration.
1087
1088     my sub baz;         # predeclaration
1089     sub baz {           # define the "my" sub
1090         baz();          # recursive call
1091     }
1092
1093 =head3 C<state sub> vs C<my sub>
1094
1095 What is the difference between "state" subs and "my" subs?  Each time that
1096 execution enters a block when "my" subs are declared, a new copy of each
1097 sub is created.  "State" subroutines persist from one execution of the
1098 containing block to the next.
1099
1100 So, in general, "state" subroutines are faster.  But "my" subs are
1101 necessary if you want to create closures:
1102
1103     no warnings "experimental::lexical_subs";
1104     use feature 'lexical_subs';
1105
1106     sub whatever {
1107         my $x = shift;
1108         my sub inner {
1109             ... do something with $x ...
1110         }
1111         inner();
1112     }
1113
1114 In this example, a new C<$x> is created when C<whatever> is called, and
1115 also a new C<inner>, which can see the new C<$x>.  A "state" sub will only
1116 see the C<$x> from the first call to C<whatever>.
1117
1118 =head3 C<our> subroutines
1119
1120 Like C<our $variable>, C<our sub> creates a lexical alias to the package
1121 subroutine of the same name.
1122
1123 The two main uses for this are to switch back to using the package sub
1124 inside an inner scope:
1125
1126     no warnings "experimental::lexical_subs";
1127     use feature 'lexical_subs';
1128
1129     sub foo { ... }
1130
1131     sub bar {
1132         my sub foo { ... }
1133         {
1134             # need to use the outer foo here
1135             our sub foo;
1136             foo();
1137         }
1138     }
1139
1140 and to make a subroutine visible to other packages in the same scope:
1141
1142     package MySneakyModule;
1143
1144     no warnings "experimental::lexical_subs";
1145     use feature 'lexical_subs';
1146
1147     our sub do_something { ... }
1148
1149     sub do_something_with_caller {
1150         package DB;
1151         () = caller 1;          # sets @DB::args
1152         do_something(@args);    # uses MySneakyModule::do_something
1153     }
1154
1155 =head2 Passing Symbol Table Entries (typeglobs)
1156 X<typeglob> X<*>
1157
1158 B<WARNING>: The mechanism described in this section was originally
1159 the only way to simulate pass-by-reference in older versions of
1160 Perl.  While it still works fine in modern versions, the new reference
1161 mechanism is generally easier to work with.  See below.
1162
1163 Sometimes you don't want to pass the value of an array to a subroutine
1164 but rather the name of it, so that the subroutine can modify the global
1165 copy of it rather than working with a local copy.  In perl you can
1166 refer to all objects of a particular name by prefixing the name
1167 with a star: C<*foo>.  This is often known as a "typeglob", because the
1168 star on the front can be thought of as a wildcard match for all the
1169 funny prefix characters on variables and subroutines and such.
1170
1171 When evaluated, the typeglob produces a scalar value that represents
1172 all the objects of that name, including any filehandle, format, or
1173 subroutine.  When assigned to, it causes the name mentioned to refer to
1174 whatever C<*> value was assigned to it.  Example:
1175
1176     sub doubleary {
1177         local(*someary) = @_;
1178         foreach $elem (@someary) {
1179             $elem *= 2;
1180         }
1181     }
1182     doubleary(*foo);
1183     doubleary(*bar);
1184
1185 Scalars are already passed by reference, so you can modify
1186 scalar arguments without using this mechanism by referring explicitly
1187 to C<$_[0]> etc.  You can modify all the elements of an array by passing
1188 all the elements as scalars, but you have to use the C<*> mechanism (or
1189 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
1190 an array.  It will certainly be faster to pass the typeglob (or reference).
1191
1192 Even if you don't want to modify an array, this mechanism is useful for
1193 passing multiple arrays in a single LIST, because normally the LIST
1194 mechanism will merge all the array values so that you can't extract out
1195 the individual arrays.  For more on typeglobs, see
1196 L<perldata/"Typeglobs and Filehandles">.
1197
1198 =head2 When to Still Use local()
1199 X<local> X<variable, local>
1200
1201 Despite the existence of C<my>, there are still three places where the
1202 C<local> operator still shines.  In fact, in these three places, you
1203 I<must> use C<local> instead of C<my>.
1204
1205 =over 4
1206
1207 =item 1.
1208
1209 You need to give a global variable a temporary value, especially $_.
1210
1211 The global variables, like C<@ARGV> or the punctuation variables, must be 
1212 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
1213 it up into chunks separated by lines of equal signs, which are placed
1214 in C<@Fields>.
1215
1216     {
1217         local @ARGV = ("/etc/motd");
1218         local $/ = undef;
1219         local $_ = <>;  
1220         @Fields = split /^\s*=+\s*$/;
1221     } 
1222
1223 It particular, it's important to C<local>ize $_ in any routine that assigns
1224 to it.  Look out for implicit assignments in C<while> conditionals.
1225
1226 =item 2.
1227
1228 You need to create a local file or directory handle or a local function.
1229
1230 A function that needs a filehandle of its own must use
1231 C<local()> on a complete typeglob.   This can be used to create new symbol
1232 table entries:
1233
1234     sub ioqueue {
1235         local  (*READER, *WRITER);    # not my!
1236         pipe    (READER,  WRITER)     or die "pipe: $!";
1237         return (*READER, *WRITER);
1238     }
1239     ($head, $tail) = ioqueue();
1240
1241 See the Symbol module for a way to create anonymous symbol table
1242 entries.
1243
1244 Because assignment of a reference to a typeglob creates an alias, this
1245 can be used to create what is effectively a local function, or at least,
1246 a local alias.
1247
1248     {
1249         local *grow = \&shrink; # only until this block exits
1250         grow();                # really calls shrink()
1251         move();                # if move() grow()s, it shrink()s too
1252     }
1253     grow();                    # get the real grow() again
1254
1255 See L<perlref/"Function Templates"> for more about manipulating
1256 functions by name in this way.
1257
1258 =item 3.
1259
1260 You want to temporarily change just one element of an array or hash.
1261
1262 You can C<local>ize just one element of an aggregate.  Usually this
1263 is done on dynamics:
1264
1265     {
1266         local $SIG{INT} = 'IGNORE';
1267         funct();                            # uninterruptible
1268     } 
1269     # interruptibility automatically restored here
1270
1271 But it also works on lexically declared aggregates.
1272
1273 =back
1274
1275 =head2 Pass by Reference
1276 X<pass by reference> X<pass-by-reference> X<reference>
1277
1278 If you want to pass more than one array or hash into a function--or
1279 return them from it--and have them maintain their integrity, then
1280 you're going to have to use an explicit pass-by-reference.  Before you
1281 do that, you need to understand references as detailed in L<perlref>.
1282 This section may not make much sense to you otherwise.
1283
1284 Here are a few simple examples.  First, let's pass in several arrays
1285 to a function and have it C<pop> all of then, returning a new list
1286 of all their former last elements:
1287
1288     @tailings = popmany ( \@a, \@b, \@c, \@d );
1289
1290     sub popmany {
1291         my $aref;
1292         my @retlist = ();
1293         foreach $aref ( @_ ) {
1294             push @retlist, pop @$aref;
1295         }
1296         return @retlist;
1297     }
1298
1299 Here's how you might write a function that returns a
1300 list of keys occurring in all the hashes passed to it:
1301
1302     @common = inter( \%foo, \%bar, \%joe );
1303     sub inter {
1304         my ($k, $href, %seen); # locals
1305         foreach $href (@_) {
1306             while ( $k = each %$href ) {
1307                 $seen{$k}++;
1308             }
1309         }
1310         return grep { $seen{$_} == @_ } keys %seen;
1311     }
1312
1313 So far, we're using just the normal list return mechanism.
1314 What happens if you want to pass or return a hash?  Well,
1315 if you're using only one of them, or you don't mind them
1316 concatenating, then the normal calling convention is ok, although
1317 a little expensive.
1318
1319 Where people get into trouble is here:
1320
1321     (@a, @b) = func(@c, @d);
1322 or
1323     (%a, %b) = func(%c, %d);
1324
1325 That syntax simply won't work.  It sets just C<@a> or C<%a> and
1326 clears the C<@b> or C<%b>.  Plus the function didn't get passed
1327 into two separate arrays or hashes: it got one long list in C<@_>,
1328 as always.
1329
1330 If you can arrange for everyone to deal with this through references, it's
1331 cleaner code, although not so nice to look at.  Here's a function that
1332 takes two array references as arguments, returning the two array elements
1333 in order of how many elements they have in them:
1334
1335     ($aref, $bref) = func(\@c, \@d);
1336     print "@$aref has more than @$bref\n";
1337     sub func {
1338         my ($cref, $dref) = @_;
1339         if (@$cref > @$dref) {
1340             return ($cref, $dref);
1341         } else {
1342             return ($dref, $cref);
1343         }
1344     }
1345
1346 It turns out that you can actually do this also:
1347
1348     (*a, *b) = func(\@c, \@d);
1349     print "@a has more than @b\n";
1350     sub func {
1351         local (*c, *d) = @_;
1352         if (@c > @d) {
1353             return (\@c, \@d);
1354         } else {
1355             return (\@d, \@c);
1356         }
1357     }
1358
1359 Here we're using the typeglobs to do symbol table aliasing.  It's
1360 a tad subtle, though, and also won't work if you're using C<my>
1361 variables, because only globals (even in disguise as C<local>s)
1362 are in the symbol table.
1363
1364 If you're passing around filehandles, you could usually just use the bare
1365 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1366 For example:
1367
1368     splutter(\*STDOUT);
1369     sub splutter {
1370         my $fh = shift;
1371         print $fh "her um well a hmmm\n";
1372     }
1373
1374     $rec = get_rec(\*STDIN);
1375     sub get_rec {
1376         my $fh = shift;
1377         return scalar <$fh>;
1378     }
1379
1380 If you're planning on generating new filehandles, you could do this.
1381 Notice to pass back just the bare *FH, not its reference.
1382
1383     sub openit {
1384         my $path = shift;
1385         local *FH;
1386         return open (FH, $path) ? *FH : undef;
1387     }
1388
1389 =head2 Prototypes
1390 X<prototype> X<subroutine, prototype>
1391
1392 Perl supports a very limited kind of compile-time argument checking
1393 using function prototyping.  This can be declared in either the PROTO
1394 section or with a L<prototype attribute|attributes/Built-in Attributes>.
1395 If you declare either of
1396
1397     sub mypush (+@)
1398     sub mypush :prototype(+@)
1399
1400 then C<mypush()> takes arguments exactly like C<push()> does.
1401
1402 If subroutine signatures are enabled (see L</Signatures>), then
1403 the shorter PROTO syntax is unavailable, because it would clash with
1404 signatures.  In that case, a prototype can only be declared in the form
1405 of an attribute.
1406
1407 The
1408 function declaration must be visible at compile time.  The prototype
1409 affects only interpretation of new-style calls to the function,
1410 where new-style is defined as not using the C<&> character.  In
1411 other words, if you call it like a built-in function, then it behaves
1412 like a built-in function.  If you call it like an old-fashioned
1413 subroutine, then it behaves like an old-fashioned subroutine.  It
1414 naturally falls out from this rule that prototypes have no influence
1415 on subroutine references like C<\&foo> or on indirect subroutine
1416 calls like C<&{$subref}> or C<< $subref->() >>.
1417
1418 Method calls are not influenced by prototypes either, because the
1419 function to be called is indeterminate at compile time, since
1420 the exact code called depends on inheritance.
1421
1422 Because the intent of this feature is primarily to let you define
1423 subroutines that work like built-in functions, here are prototypes
1424 for some other functions that parse almost exactly like the
1425 corresponding built-in.
1426
1427    Declared as             Called as
1428
1429    sub mylink ($$)         mylink $old, $new
1430    sub myvec ($$$)         myvec $var, $offset, 1
1431    sub myindex ($$;$)      myindex &getstring, "substr"
1432    sub mysyswrite ($$$;$)  mysyswrite $buf, 0, length($buf) - $off, $off
1433    sub myreverse (@)       myreverse $a, $b, $c
1434    sub myjoin ($@)         myjoin ":", $a, $b, $c
1435    sub mypop (+)           mypop @array
1436    sub mysplice (+$$@)     mysplice @array, 0, 2, @pushme
1437    sub mykeys (+)          mykeys %{$hashref}
1438    sub myopen (*;$)        myopen HANDLE, $name
1439    sub mypipe (**)         mypipe READHANDLE, WRITEHANDLE
1440    sub mygrep (&@)         mygrep { /foo/ } $a, $b, $c
1441    sub myrand (;$)         myrand 42
1442    sub mytime ()           mytime
1443
1444 Any backslashed prototype character represents an actual argument
1445 that must start with that character (optionally preceded by C<my>,
1446 C<our> or C<local>), with the exception of C<$>, which will
1447 accept any scalar lvalue expression, such as C<$foo = 7> or
1448 C<< my_function()->[0] >>.  The value passed as part of C<@_> will be a
1449 reference to the actual argument given in the subroutine call,
1450 obtained by applying C<\> to that argument.
1451
1452 You can use the C<\[]> backslash group notation to specify more than one
1453 allowed argument type.  For example:
1454
1455     sub myref (\[$@%&*])
1456
1457 will allow calling myref() as
1458
1459     myref $var
1460     myref @array
1461     myref %hash
1462     myref &sub
1463     myref *glob
1464
1465 and the first argument of myref() will be a reference to
1466 a scalar, an array, a hash, a code, or a glob.
1467
1468 Unbackslashed prototype characters have special meanings.  Any
1469 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1470 list context.  An argument represented by C<$> forces scalar context.  An
1471 C<&> requires an anonymous subroutine, which, if passed as the first
1472 argument, does not require the C<sub> keyword or a subsequent comma.
1473
1474 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1475 typeglob, or a reference to a typeglob in that slot.  The value will be
1476 available to the subroutine either as a simple scalar, or (in the latter
1477 two cases) as a reference to the typeglob.  If you wish to always convert
1478 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1479 follows:
1480
1481     use Symbol 'qualify_to_ref';
1482
1483     sub foo (*) {
1484         my $fh = qualify_to_ref(shift, caller);
1485         ...
1486     }
1487
1488 The C<+> prototype is a special alternative to C<$> that will act like
1489 C<\[@%]> when given a literal array or hash variable, but will otherwise
1490 force scalar context on the argument.  This is useful for functions which
1491 should accept either a literal array or an array reference as the argument:
1492
1493     sub mypush (+@) {
1494         my $aref = shift;
1495         die "Not an array or arrayref" unless ref $aref eq 'ARRAY';
1496         push @$aref, @_;
1497     }
1498
1499 When using the C<+> prototype, your function must check that the argument
1500 is of an acceptable type.
1501
1502 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1503 It is redundant before C<@> or C<%>, which gobble up everything else.
1504
1505 As the last character of a prototype, or just before a semicolon, a C<@>
1506 or a C<%>, you can use C<_> in place of C<$>: if this argument is not
1507 provided, C<$_> will be used instead.
1508
1509 Note how the last three examples in the table above are treated
1510 specially by the parser.  C<mygrep()> is parsed as a true list
1511 operator, C<myrand()> is parsed as a true unary operator with unary
1512 precedence the same as C<rand()>, and C<mytime()> is truly without
1513 arguments, just like C<time()>.  That is, if you say
1514
1515     mytime +2;
1516
1517 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1518 without a prototype.  If you want to force a unary function to have the
1519 same precedence as a list operator, add C<;> to the end of the prototype:
1520
1521     sub mygetprotobynumber($;);
1522     mygetprotobynumber $a > $b; # parsed as mygetprotobynumber($a > $b)
1523
1524 The interesting thing about C<&> is that you can generate new syntax with it,
1525 provided it's in the initial position:
1526 X<&>
1527
1528     sub try (&@) {
1529         my($try,$catch) = @_;
1530         eval { &$try };
1531         if ($@) {
1532             local $_ = $@;
1533             &$catch;
1534         }
1535     }
1536     sub catch (&) { $_[0] }
1537
1538     try {
1539         die "phooey";
1540     } catch {
1541         /phooey/ and print "unphooey\n";
1542     };
1543
1544 That prints C<"unphooey">.  (Yes, there are still unresolved
1545 issues having to do with visibility of C<@_>.  I'm ignoring that
1546 question for the moment.  (But note that if we make C<@_> lexically
1547 scoped, those anonymous subroutines can act like closures... (Gee,
1548 is this sounding a little Lispish?  (Never mind.))))
1549
1550 And here's a reimplementation of the Perl C<grep> operator:
1551 X<grep>
1552
1553     sub mygrep (&@) {
1554         my $code = shift;
1555         my @result;
1556         foreach $_ (@_) {
1557             push(@result, $_) if &$code;
1558         }
1559         @result;
1560     }
1561
1562 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1563 been intentionally left out of prototypes for the express purpose of
1564 someday in the future adding named, formal parameters.  The current
1565 mechanism's main goal is to let module writers provide better diagnostics
1566 for module users.  Larry feels the notation quite understandable to Perl
1567 programmers, and that it will not intrude greatly upon the meat of the
1568 module, nor make it harder to read.  The line noise is visually
1569 encapsulated into a small pill that's easy to swallow.
1570
1571 If you try to use an alphanumeric sequence in a prototype you will
1572 generate an optional warning - "Illegal character in prototype...".
1573 Unfortunately earlier versions of Perl allowed the prototype to be
1574 used as long as its prefix was a valid prototype.  The warning may be
1575 upgraded to a fatal error in a future version of Perl once the
1576 majority of offending code is fixed.
1577
1578 It's probably best to prototype new functions, not retrofit prototyping
1579 into older ones.  That's because you must be especially careful about
1580 silent impositions of differing list versus scalar contexts.  For example,
1581 if you decide that a function should take just one parameter, like this:
1582
1583     sub func ($) {
1584         my $n = shift;
1585         print "you gave me $n\n";
1586     }
1587
1588 and someone has been calling it with an array or expression
1589 returning a list:
1590
1591     func(@foo);
1592     func( split /:/ );
1593
1594 Then you've just supplied an automatic C<scalar> in front of their
1595 argument, which can be more than a bit surprising.  The old C<@foo>
1596 which used to hold one thing doesn't get passed in.  Instead,
1597 C<func()> now gets passed in a C<1>; that is, the number of elements
1598 in C<@foo>.  And the C<split> gets called in scalar context so it
1599 starts scribbling on your C<@_> parameter list.  Ouch!
1600
1601 If a sub has both a PROTO and a BLOCK, the prototype is not applied
1602 until after the BLOCK is completely defined.  This means that a recursive
1603 function with a prototype has to be predeclared for the prototype to take
1604 effect, like so:
1605
1606         sub foo($$);
1607         sub foo($$) {
1608                 foo 1, 2;
1609         }
1610
1611 This is all very powerful, of course, and should be used only in moderation
1612 to make the world a better place.
1613
1614 =head2 Constant Functions
1615 X<constant>
1616
1617 Functions with a prototype of C<()> are potential candidates for
1618 inlining.  If the result after optimization and constant folding
1619 is either a constant or a lexically-scoped scalar which has no other
1620 references, then it will be used in place of function calls made
1621 without C<&>.  Calls made using C<&> are never inlined.  (See
1622 F<constant.pm> for an easy way to declare most constants.)
1623
1624 The following functions would all be inlined:
1625
1626     sub pi ()           { 3.14159 }             # Not exact, but close.
1627     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1628                                                 # and it's inlined, too!
1629     sub ST_DEV ()       { 0 }
1630     sub ST_INO ()       { 1 }
1631
1632     sub FLAG_FOO ()     { 1 << 8 }
1633     sub FLAG_BAR ()     { 1 << 9 }
1634     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1635
1636     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1637
1638     sub N () { int(OPT_BAZ) / 3 }
1639
1640     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1641     sub FOO_SET2 () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1642
1643 (Be aware that the last example was not always inlined in Perl 5.20 and
1644 earlier, which did not behave consistently with subroutines containing
1645 inner scopes.)  You can countermand inlining by using an explicit
1646 C<return>:
1647
1648     sub baz_val () {
1649         if (OPT_BAZ) {
1650             return 23;
1651         }
1652         else {
1653             return 42;
1654         }
1655     }
1656     sub bonk_val () { return 12345 }
1657
1658 As alluded to earlier you can also declare inlined subs dynamically at
1659 BEGIN time if their body consists of a lexically-scoped scalar which
1660 has no other references.  Only the first example here will be inlined:
1661
1662     BEGIN {
1663         my $var = 1;
1664         no strict 'refs';
1665         *INLINED = sub () { $var };
1666     }
1667
1668     BEGIN {
1669         my $var = 1;
1670         my $ref = \$var;
1671         no strict 'refs';
1672         *NOT_INLINED = sub () { $var };
1673     }
1674
1675 A not so obvious caveat with this (see [RT #79908]) is that the
1676 variable will be immediately inlined, and will stop behaving like a
1677 normal lexical variable, e.g. this will print C<79907>, not C<79908>:
1678
1679     BEGIN {
1680         my $x = 79907;
1681         *RT_79908 = sub () { $x };
1682         $x++;
1683     }
1684     print RT_79908(); # prints 79907
1685
1686 As of Perl 5.22, this buggy behavior, while preserved for backward
1687 compatibility, is detected and emits a deprecation warning.  If you want
1688 the subroutine to be inlined (with no warning), make sure the variable is
1689 not used in a context where it could be modified aside from where it is
1690 declared.
1691
1692     # Fine, no warning
1693     BEGIN {
1694         my $x = 54321;
1695         *INLINED = sub () { $x };
1696     }
1697     # Warns.  Future Perl versions will stop inlining it.
1698     BEGIN {
1699         my $x;
1700         $x = 54321;
1701         *ALSO_INLINED = sub () { $x };
1702     }
1703
1704 Perl 5.22 also introduces the experimental "const" attribute as an
1705 alternative.  (Disable the "experimental::const_attr" warnings if you want
1706 to use it.)  When applied to an anonymous subroutine, it forces the sub to
1707 be called when the C<sub> expression is evaluated.  The return value is
1708 captured and turned into a constant subroutine:
1709
1710     my $x = 54321;
1711     *INLINED = sub : const { $x };
1712     $x++;
1713
1714 The return value of C<INLINED> in this example will always be 54321,
1715 regardless of later modifications to $x.  You can also put any arbitrary
1716 code inside the sub, at it will be executed immediately and its return
1717 value captured the same way.
1718
1719 If you really want a subroutine with a C<()> prototype that returns a
1720 lexical variable you can easily force it to not be inlined by adding
1721 an explicit C<return>:
1722
1723     BEGIN {
1724         my $x = 79907;
1725         *RT_79908 = sub () { return $x };
1726         $x++;
1727     }
1728     print RT_79908(); # prints 79908
1729
1730 The easiest way to tell if a subroutine was inlined is by using
1731 L<B::Deparse>.  Consider this example of two subroutines returning
1732 C<1>, one with a C<()> prototype causing it to be inlined, and one
1733 without (with deparse output truncated for clarity):
1734
1735  $ perl -MO=Deparse -le 'sub ONE { 1 } if (ONE) { print ONE if ONE }'
1736  sub ONE {
1737      1;
1738  }
1739  if (ONE ) {
1740      print ONE() if ONE ;
1741  }
1742  $ perl -MO=Deparse -le 'sub ONE () { 1 } if (ONE) { print ONE if ONE }'
1743  sub ONE () { 1 }
1744  do {
1745      print 1
1746  };
1747
1748 If you redefine a subroutine that was eligible for inlining, you'll
1749 get a warning by default.  You can use this warning to tell whether or
1750 not a particular subroutine is considered inlinable, since it's
1751 different than the warning for overriding non-inlined subroutines:
1752
1753     $ perl -e 'sub one () {1} sub one () {2}'
1754     Constant subroutine one redefined at -e line 1.
1755     $ perl -we 'sub one {1} sub one {2}'
1756     Subroutine one redefined at -e line 1.
1757
1758 The warning is considered severe enough not to be affected by the
1759 B<-w> switch (or its absence) because previously compiled invocations
1760 of the function will still be using the old value of the function.  If
1761 you need to be able to redefine the subroutine, you need to ensure
1762 that it isn't inlined, either by dropping the C<()> prototype (which
1763 changes calling semantics, so beware) or by thwarting the inlining
1764 mechanism in some other way, e.g. by adding an explicit C<return>, as
1765 mentioned above:
1766
1767     sub not_inlined () { return 23 }
1768
1769 =head2 Overriding Built-in Functions
1770 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1771
1772 Many built-in functions may be overridden, though this should be tried
1773 only occasionally and for good reason.  Typically this might be
1774 done by a package attempting to emulate missing built-in functionality
1775 on a non-Unix system.
1776
1777 Overriding may be done only by importing the name from a module at
1778 compile time--ordinary predeclaration isn't good enough.  However, the
1779 C<use subs> pragma lets you, in effect, predeclare subs
1780 via the import syntax, and these names may then override built-in ones:
1781
1782     use subs 'chdir', 'chroot', 'chmod', 'chown';
1783     chdir $somewhere;
1784     sub chdir { ... }
1785
1786 To unambiguously refer to the built-in form, precede the
1787 built-in name with the special package qualifier C<CORE::>.  For example,
1788 saying C<CORE::open()> always refers to the built-in C<open()>, even
1789 if the current package has imported some other subroutine called
1790 C<&open()> from elsewhere.  Even though it looks like a regular
1791 function call, it isn't: the CORE:: prefix in that case is part of Perl's
1792 syntax, and works for any keyword, regardless of what is in the CORE
1793 package.  Taking a reference to it, that is, C<\&CORE::open>, only works
1794 for some keywords.  See L<CORE>.
1795
1796 Library modules should not in general export built-in names like C<open>
1797 or C<chdir> as part of their default C<@EXPORT> list, because these may
1798 sneak into someone else's namespace and change the semantics unexpectedly.
1799 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1800 possible for a user to import the name explicitly, but not implicitly.
1801 That is, they could say
1802
1803     use Module 'open';
1804
1805 and it would import the C<open> override.  But if they said
1806
1807     use Module;
1808
1809 they would get the default imports without overrides.
1810
1811 The foregoing mechanism for overriding built-in is restricted, quite
1812 deliberately, to the package that requests the import.  There is a second
1813 method that is sometimes applicable when you wish to override a built-in
1814 everywhere, without regard to namespace boundaries.  This is achieved by
1815 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1816 example that quite brazenly replaces the C<glob> operator with something
1817 that understands regular expressions.
1818
1819     package REGlob;
1820     require Exporter;
1821     @ISA = 'Exporter';
1822     @EXPORT_OK = 'glob';
1823
1824     sub import {
1825         my $pkg = shift;
1826         return unless @_;
1827         my $sym = shift;
1828         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1829         $pkg->export($where, $sym, @_);
1830     }
1831
1832     sub glob {
1833         my $pat = shift;
1834         my @got;
1835         if (opendir my $d, '.') { 
1836             @got = grep /$pat/, readdir $d; 
1837             closedir $d;   
1838         }
1839         return @got;
1840     }
1841     1;
1842
1843 And here's how it could be (ab)used:
1844
1845     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1846     package Foo;
1847     use REGlob 'glob';              # override glob() in Foo:: only
1848     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1849
1850 The initial comment shows a contrived, even dangerous example.
1851 By overriding C<glob> globally, you would be forcing the new (and
1852 subversive) behavior for the C<glob> operator for I<every> namespace,
1853 without the complete cognizance or cooperation of the modules that own
1854 those namespaces.  Naturally, this should be done with extreme caution--if
1855 it must be done at all.
1856
1857 The C<REGlob> example above does not implement all the support needed to
1858 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1859 different behaviors depending on whether it appears in a scalar or list
1860 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1861 context sensitive behaviors, and these must be adequately supported by
1862 a properly written override.  For a fully functional example of overriding
1863 C<glob>, study the implementation of C<File::DosGlob> in the standard
1864 library.
1865
1866 When you override a built-in, your replacement should be consistent (if
1867 possible) with the built-in native syntax.  You can achieve this by using
1868 a suitable prototype.  To get the prototype of an overridable built-in,
1869 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1870 (see L<perlfunc/prototype>).
1871
1872 Note however that some built-ins can't have their syntax expressed by a
1873 prototype (such as C<system> or C<chomp>).  If you override them you won't
1874 be able to fully mimic their original syntax.
1875
1876 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1877 to special magic, their original syntax is preserved, and you don't have
1878 to define a prototype for their replacements.  (You can't override the
1879 C<do BLOCK> syntax, though).
1880
1881 C<require> has special additional dark magic: if you invoke your
1882 C<require> replacement as C<require Foo::Bar>, it will actually receive
1883 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1884
1885 And, as you'll have noticed from the previous example, if you override
1886 C<glob>, the C<< <*> >> glob operator is overridden as well.
1887
1888 In a similar fashion, overriding the C<readline> function also overrides
1889 the equivalent I/O operator C<< <FILEHANDLE> >>.  Also, overriding
1890 C<readpipe> also overrides the operators C<``> and C<qx//>.
1891
1892 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1893
1894 =head2 Autoloading
1895 X<autoloading> X<AUTOLOAD>
1896
1897 If you call a subroutine that is undefined, you would ordinarily
1898 get an immediate, fatal error complaining that the subroutine doesn't
1899 exist.  (Likewise for subroutines being used as methods, when the
1900 method doesn't exist in any base class of the class's package.)
1901 However, if an C<AUTOLOAD> subroutine is defined in the package or
1902 packages used to locate the original subroutine, then that
1903 C<AUTOLOAD> subroutine is called with the arguments that would have
1904 been passed to the original subroutine.  The fully qualified name
1905 of the original subroutine magically appears in the global $AUTOLOAD
1906 variable of the same package as the C<AUTOLOAD> routine.  The name
1907 is not passed as an ordinary argument because, er, well, just
1908 because, that's why.  (As an exception, a method call to a nonexistent
1909 C<import> or C<unimport> method is just skipped instead.  Also, if
1910 the AUTOLOAD subroutine is an XSUB, there are other ways to retrieve the
1911 subroutine name.  See L<perlguts/Autoloading with XSUBs> for details.)
1912
1913
1914 Many C<AUTOLOAD> routines load in a definition for the requested
1915 subroutine using eval(), then execute that subroutine using a special
1916 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1917 without a trace.  (See the source to the standard module documented
1918 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1919 also just emulate the routine and never define it.   For example,
1920 let's pretend that a function that wasn't defined should just invoke
1921 C<system> with those arguments.  All you'd do is:
1922
1923     sub AUTOLOAD {
1924         my $program = $AUTOLOAD;
1925         $program =~ s/.*:://;
1926         system($program, @_);
1927     }
1928     date();
1929     who('am', 'i');
1930     ls('-l');
1931
1932 In fact, if you predeclare functions you want to call that way, you don't
1933 even need parentheses:
1934
1935     use subs qw(date who ls);
1936     date;
1937     who "am", "i";
1938     ls '-l';
1939
1940 A more complete example of this is the Shell module on CPAN, which
1941 can treat undefined subroutine calls as calls to external programs.
1942
1943 Mechanisms are available to help modules writers split their modules
1944 into autoloadable files.  See the standard AutoLoader module
1945 described in L<AutoLoader> and in L<AutoSplit>, the standard
1946 SelfLoader modules in L<SelfLoader>, and the document on adding C
1947 functions to Perl code in L<perlxs>.
1948
1949 =head2 Subroutine Attributes
1950 X<attribute> X<subroutine, attribute> X<attrs>
1951
1952 A subroutine declaration or definition may have a list of attributes
1953 associated with it.  If such an attribute list is present, it is
1954 broken up at space or colon boundaries and treated as though a
1955 C<use attributes> had been seen.  See L<attributes> for details
1956 about what attributes are currently supported.
1957 Unlike the limitation with the obsolescent C<use attrs>, the
1958 C<sub : ATTRLIST> syntax works to associate the attributes with
1959 a pre-declaration, and not just with a subroutine definition.
1960
1961 The attributes must be valid as simple identifier names (without any
1962 punctuation other than the '_' character).  They may have a parameter
1963 list appended, which is only checked for whether its parentheses ('(',')')
1964 nest properly.
1965
1966 Examples of valid syntax (even though the attributes are unknown):
1967
1968     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1969     sub plugh () : Ugly('\(") :Bad;
1970     sub xyzzy : _5x5 { ... }
1971
1972 Examples of invalid syntax:
1973
1974     sub fnord : switch(10,foo(); # ()-string not balanced
1975     sub snoid : Ugly('(');        # ()-string not balanced
1976     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1977     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1978     sub snurt : foo + bar;        # "+" not a colon or space
1979
1980 The attribute list is passed as a list of constant strings to the code
1981 which associates them with the subroutine.  In particular, the second example
1982 of valid syntax above currently looks like this in terms of how it's
1983 parsed and invoked:
1984
1985     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1986
1987 For further details on attribute lists and their manipulation,
1988 see L<attributes> and L<Attribute::Handlers>.
1989
1990 =head1 SEE ALSO
1991
1992 See L<perlref/"Function Templates"> for more about references and closures.
1993 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1994 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1995 See L<perlmod> to learn about bundling up your functions in separate files.
1996 See L<perlmodlib> to learn what library modules come standard on your system.
1997 See L<perlootut> to learn how to make object method calls.