Exporter-5.72 is now on the CPAN
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19 New in v5.22, L<C<use re 'strict'>|re/'strict' mode> applies stricter
20 rules than otherwise when compiling regular expression patterns.  It can
21 find things that, while legal, may not be what you intended.
22
23 =head2 Modifiers
24
25 Matching operations can have various modifiers.  Modifiers
26 that relate to the interpretation of the regular expression inside
27 are listed below.  Modifiers that alter the way a regular expression
28 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
29 L<perlop/"Gory details of parsing quoted constructs">.
30
31 =over 4
32
33 =item m
34 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
35
36 Treat string as multiple lines.  That is, change "^" and "$" from matching
37 the start of the string's first line and the end of its last line to
38 matching the start and end of each line within the string.
39
40 =item s
41 X</s> X<regex, single-line> X<regexp, single-line>
42 X<regular expression, single-line>
43
44 Treat string as single line.  That is, change "." to match any character
45 whatsoever, even a newline, which normally it would not match.
46
47 Used together, as C</ms>, they let the "." match any character whatsoever,
48 while still allowing "^" and "$" to match, respectively, just after
49 and just before newlines within the string.
50
51 =item i
52 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
53 X<regular expression, case-insensitive>
54
55 Do case-insensitive pattern matching.
56
57 If locale matching rules are in effect, the case map is taken from the
58 current
59 locale for code points less than 255, and from Unicode rules for larger
60 code points.  However, matches that would cross the Unicode
61 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
62 L<perllocale>.
63
64 There are a number of Unicode characters that match multiple characters
65 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
66 should match the sequence C<fi>.  Perl is not
67 currently able to do this when the multiple characters are in the pattern and
68 are split between groupings, or when one or more are quantified.  Thus
69
70  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
71  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
72  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
73
74  # The below doesn't match, and it isn't clear what $1 and $2 would
75  # be even if it did!!
76  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
77
78 Perl doesn't match multiple characters in a bracketed
79 character class unless the character that maps to them is explicitly
80 mentioned, and it doesn't match them at all if the character class is
81 inverted, which otherwise could be highly confusing.  See
82 L<perlrecharclass/Bracketed Character Classes>, and
83 L<perlrecharclass/Negation>.
84
85 =item x
86 X</x>
87
88 Extend your pattern's legibility by permitting whitespace and comments.
89 Details in L</"/x">
90
91 =item p
92 X</p> X<regex, preserve> X<regexp, preserve>
93
94 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
95 ${^POSTMATCH} are available for use after matching.
96
97 In Perl 5.20 and higher this is ignored. Due to a new copy-on-write
98 mechanism, ${^PREMATCH}, ${^MATCH}, and ${^POSTMATCH} will be available
99 after the match regardless of the modifier.
100
101 =item a, d, l and u
102 X</a> X</d> X</l> X</u>
103
104 These modifiers, all new in 5.14, affect which character-set rules
105 (Unicode, etc.) are used, as described below in
106 L</Character set modifiers>.
107
108 =item n
109 X</n> X<regex, non-capture> X<regexp, non-capture>
110 X<regular expression, non-capture>
111
112 Prevent the grouping metacharacters C<()> from capturing. This modifier,
113 new in 5.22, will stop C<$1>, C<$2>, etc... from being filled in.
114
115   "hello" =~ /(hi|hello)/;   # $1 is "hello"
116   "hello" =~ /(hi|hello)/n;  # $1 is undef
117
118 This is equivalent to putting C<?:> at the beginning of every capturing group:
119
120   "hello" =~ /(?:hi|hello)/; # $1 is undef
121
122 C</n> can be negated on a per-group basis. Alternatively, named captures
123 may still be used.
124
125   "hello" =~ /(?-n:(hi|hello))/n;   # $1 is "hello"
126   "hello" =~ /(?<greet>hi|hello)/n; # $1 is "hello", $+{greet} is
127                                     # "hello"
128
129 =item Other Modifiers
130
131 There are a number of flags that can be found at the end of regular
132 expression constructs that are I<not> generic regular expression flags, but
133 apply to the operation being performed, like matching or substitution (C<m//>
134 or C<s///> respectively).
135
136 Flags described further in
137 L<perlretut/"Using regular expressions in Perl"> are:
138
139   c  - keep the current position during repeated matching
140   g  - globally match the pattern repeatedly in the string
141
142 Substitution-specific modifiers described in
143
144 L<perlop/"s/PATTERN/REPLACEMENT/msixpodualngcer"> are:
145
146   e  - evaluate the right-hand side as an expression
147   ee - evaluate the right side as a string then eval the result
148   o  - pretend to optimize your code, but actually introduce bugs
149   r  - perform non-destructive substitution and return the new value
150
151 =back
152
153 Regular expression modifiers are usually written in documentation
154 as e.g., "the C</x> modifier", even though the delimiter
155 in question might not really be a slash.  The modifiers C</imsxadlup>
156 may also be embedded within the regular expression itself using
157 the C<(?...)> construct, see L</Extended Patterns> below.
158
159 =head3 /x
160
161 C</x> tells
162 the regular expression parser to ignore most whitespace that is neither
163 backslashed nor within a bracketed character class.  You can use this to
164 break up your regular expression into (slightly) more readable parts.
165 Also, the C<#> character is treated as a metacharacter introducing a
166 comment that runs up to the pattern's closing delimiter, or to the end
167 of the current line if the pattern extends onto the next line.  Hence,
168 this is very much like an ordinary Perl code comment.  (You can include
169 the closing delimiter within the comment only if you precede it with a
170 backslash, so be careful!)
171
172 Use of C</x> means that if you want real
173 whitespace or C<#> characters in the pattern (outside a bracketed character
174 class, which is unaffected by C</x>), then you'll either have to
175 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
176 hex, or C<\N{}> escapes.
177 It is ineffective to try to continue a comment onto the next line by
178 escaping the C<\n> with a backslash or C<\Q>.
179
180 You can use L</(?#text)> to create a comment that ends earlier than the
181 end of the current line, but C<text> also can't contain the closing
182 delimiter unless escaped with a backslash.
183
184 Taken together, these features go a long way towards
185 making Perl's regular expressions more readable.  Here's an example:
186
187     # Delete (most) C comments.
188     $program =~ s {
189         /\*     # Match the opening delimiter.
190         .*?     # Match a minimal number of characters.
191         \*/     # Match the closing delimiter.
192     } []gsx;
193
194 Note that anything inside
195 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
196 space interpretation within a single multi-character construct.  For
197 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
198 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
199 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<(>,
200 C<?>, and C<:>.  Within any delimiters for such a
201 construct, allowed spaces are not affected by C</x>, and depend on the
202 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
203 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
204 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
205 L<perluniprops/Properties accessible through \p{} and \P{}>.
206 X</x>
207
208 The set of characters that are deemed whitespace are those that Unicode
209 calls "Pattern White Space", namely:
210
211  U+0009 CHARACTER TABULATION
212  U+000A LINE FEED
213  U+000B LINE TABULATION
214  U+000C FORM FEED
215  U+000D CARRIAGE RETURN
216  U+0020 SPACE
217  U+0085 NEXT LINE
218  U+200E LEFT-TO-RIGHT MARK
219  U+200F RIGHT-TO-LEFT MARK
220  U+2028 LINE SEPARATOR
221  U+2029 PARAGRAPH SEPARATOR
222
223 =head3 Character set modifiers
224
225 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
226 the character set modifiers; they affect the character set rules
227 used for the regular expression.
228
229 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
230 to you, and so you need not worry about them very much.  They exist for
231 Perl's internal use, so that complex regular expression data structures
232 can be automatically serialized and later exactly reconstituted,
233 including all their nuances.  But, since Perl can't keep a secret, and
234 there may be rare instances where they are useful, they are documented
235 here.
236
237 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
238 allow code that is to work mostly on ASCII data to not have to concern
239 itself with Unicode.
240
241 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
242 effect at the time of the execution of the pattern match.
243
244 C</u> sets the character set to B<U>nicode.
245
246 C</a> also sets the character set to Unicode, BUT adds several
247 restrictions for B<A>SCII-safe matching.
248
249 C</d> is the old, problematic, pre-5.14 B<D>efault character set
250 behavior.  Its only use is to force that old behavior.
251
252 At any given time, exactly one of these modifiers is in effect.  Their
253 existence allows Perl to keep the originally compiled behavior of a
254 regular expression, regardless of what rules are in effect when it is
255 actually executed.  And if it is interpolated into a larger regex, the
256 original's rules continue to apply to it, and only it.
257
258 The C</l> and C</u> modifiers are automatically selected for
259 regular expressions compiled within the scope of various pragmas,
260 and we recommend that in general, you use those pragmas instead of
261 specifying these modifiers explicitly.  For one thing, the modifiers
262 affect only pattern matching, and do not extend to even any replacement
263 done, whereas using the pragmas give consistent results for all
264 appropriate operations within their scopes.  For example,
265
266  s/foo/\Ubar/il
267
268 will match "foo" using the locale's rules for case-insensitive matching,
269 but the C</l> does not affect how the C<\U> operates.  Most likely you
270 want both of them to use locale rules.  To do this, instead compile the
271 regular expression within the scope of C<use locale>.  This both
272 implicitly adds the C</l>, and applies locale rules to the C<\U>.   The
273 lesson is to C<use locale>, and not C</l> explicitly.
274
275 Similarly, it would be better to use C<use feature 'unicode_strings'>
276 instead of,
277
278  s/foo/\Lbar/iu
279
280 to get Unicode rules, as the C<\L> in the former (but not necessarily
281 the latter) would also use Unicode rules.
282
283 More detail on each of the modifiers follows.  Most likely you don't
284 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
285 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
286
287 =head4 /l
288
289 means to use the current locale's rules (see L<perllocale>) when pattern
290 matching.  For example, C<\w> will match the "word" characters of that
291 locale, and C<"/i"> case-insensitive matching will match according to
292 the locale's case folding rules.  The locale used will be the one in
293 effect at the time of execution of the pattern match.  This may not be
294 the same as the compilation-time locale, and can differ from one match
295 to another if there is an intervening call of the
296 L<setlocale() function|perllocale/The setlocale function>.
297
298 The only non-single-byte locale Perl supports is (starting in v5.20)
299 UTF-8.  This means that code points above 255 are treated as Unicode no
300 matter what locale is in effect (since UTF-8 implies Unicode).
301
302 Under Unicode rules, there are a few case-insensitive matches that cross
303 the 255/256 boundary.  Except for UTF-8 locales in Perls v5.20 and
304 later, these are disallowed under C</l>.  For example, 0xFF (on ASCII
305 platforms) does not caselessly match the character at 0x178, C<LATIN
306 CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be C<LATIN SMALL
307 LETTER Y WITH DIAERESIS> in the current locale, and Perl has no way of
308 knowing if that character even exists in the locale, much less what code
309 point it is.
310
311 In a UTF-8 locale in v5.20 and later, the only visible difference
312 between locale and non-locale in regular expressions should be tainting
313 (see L<perlsec>).
314
315 This modifier may be specified to be the default by C<use locale>, but
316 see L</Which character set modifier is in effect?>.
317 X</l>
318
319 =head4 /u
320
321 means to use Unicode rules when pattern matching.  On ASCII platforms,
322 this means that the code points between 128 and 255 take on their
323 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
324 (Otherwise Perl considers their meanings to be undefined.)  Thus,
325 under this modifier, the ASCII platform effectively becomes a Unicode
326 platform; and hence, for example, C<\w> will match any of the more than
327 100_000 word characters in Unicode.
328
329 Unlike most locales, which are specific to a language and country pair,
330 Unicode classifies all the characters that are letters I<somewhere> in
331 the world as
332 C<\w>.  For example, your locale might not think that C<LATIN SMALL
333 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
334 Unicode does.  Similarly, all the characters that are decimal digits
335 somewhere in the world will match C<\d>; this is hundreds, not 10,
336 possible matches.  And some of those digits look like some of the 10
337 ASCII digits, but mean a different number, so a human could easily think
338 a number is a different quantity than it really is.  For example,
339 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
340 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
341 that are a mixture from different writing systems, creating a security
342 issue.  L<Unicode::UCD/num()> can be used to sort
343 this out.  Or the C</a> modifier can be used to force C<\d> to match
344 just the ASCII 0 through 9.
345
346 Also, under this modifier, case-insensitive matching works on the full
347 set of Unicode
348 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
349 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
350 if you're not prepared, might make it look like a hexadecimal constant,
351 presenting another potential security issue.  See
352 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
353 security issues.
354
355 This modifier may be specified to be the default by C<use feature
356 'unicode_strings>, C<use locale ':not_characters'>, or
357 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
358 but see L</Which character set modifier is in effect?>.
359 X</u>
360
361 =head4 /d
362
363 This modifier means to use the "Default" native rules of the platform
364 except when there is cause to use Unicode rules instead, as follows:
365
366 =over 4
367
368 =item 1
369
370 the target string is encoded in UTF-8; or
371
372 =item 2
373
374 the pattern is encoded in UTF-8; or
375
376 =item 3
377
378 the pattern explicitly mentions a code point that is above 255 (say by
379 C<\x{100}>); or
380
381 =item 4
382
383 the pattern uses a Unicode name (C<\N{...}>);  or
384
385 =item 5
386
387 the pattern uses a Unicode property (C<\p{...}> or C<\P{...}>); or
388
389 =item 6
390
391 the pattern uses a Unicode break (C<\b{...}> or C<\B{...}>); or
392
393 =item 7
394
395 the pattern uses L</C<(?[ ])>>
396
397 =back
398
399 Another mnemonic for this modifier is "Depends", as the rules actually
400 used depend on various things, and as a result you can get unexpected
401 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
402 become rather infamous, leading to yet another (printable) name for this
403 modifier, "Dodgy".
404
405 Unless the pattern or string are encoded in UTF-8, only ASCII characters
406 can match positively.
407
408 Here are some examples of how that works on an ASCII platform:
409
410  $str =  "\xDF";      # $str is not in UTF-8 format.
411  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
412  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
413  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
414  chop $str;
415  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
416
417 This modifier is automatically selected by default when none of the
418 others are, so yet another name for it is "Default".
419
420 Because of the unexpected behaviors associated with this modifier, you
421 probably should only use it to maintain weird backward compatibilities.
422
423 =head4 /a (and /aa)
424
425 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
426 unlike the others, may be doubled-up to increase its effect.
427
428 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
429 the Posix character classes to match only in the ASCII range.  They thus
430 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
431 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
432 characters C<[ \f\n\r\t]>, and starting in Perl v5.18, the vertical tab;
433 C<\w> means the 63 characters
434 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
435 C<[[:print:]]> match only the appropriate ASCII-range characters.
436
437 This modifier is useful for people who only incidentally use Unicode,
438 and who do not wish to be burdened with its complexities and security
439 concerns.
440
441 With C</a>, one can write C<\d> with confidence that it will only match
442 ASCII characters, and should the need arise to match beyond ASCII, you
443 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
444 similar C<\p{...}> constructs that can match beyond ASCII both white
445 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
446 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
447 doesn't mean you can't use Unicode, it means that to get Unicode
448 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
449 signals Unicode.
450
451 As you would expect, this modifier causes, for example, C<\D> to mean
452 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
453 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
454 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
455 for C<\B>).
456
457 Otherwise, C</a> behaves like the C</u> modifier, in that
458 case-insensitive matching uses Unicode rules; for example, "k" will
459 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
460 points in the Latin1 range, above ASCII will have Unicode rules when it
461 comes to case-insensitive matching.
462
463 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
464 specify the "a" twice, for example C</aai> or C</aia>.  (The first
465 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
466 adds the C</i> restrictions.)  But, note that code points outside the
467 ASCII range will use Unicode rules for C</i> matching, so the modifier
468 doesn't really restrict things to just ASCII; it just forbids the
469 intermixing of ASCII and non-ASCII.
470
471 To summarize, this modifier provides protection for applications that
472 don't wish to be exposed to all of Unicode.  Specifying it twice
473 gives added protection.
474
475 This modifier may be specified to be the default by C<use re '/a'>
476 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
477 the C</u> modifier explicitly if there are a few regular expressions
478 where you do want full Unicode rules (but even here, it's best if
479 everything were under feature C<"unicode_strings">, along with the
480 C<use re '/aa'>).  Also see L</Which character set modifier is in
481 effect?>.
482 X</a>
483 X</aa>
484
485 =head4 Which character set modifier is in effect?
486
487 Which of these modifiers is in effect at any given point in a regular
488 expression depends on a fairly complex set of interactions.  These have
489 been designed so that in general you don't have to worry about it, but
490 this section gives the gory details.  As
491 explained below in L</Extended Patterns> it is possible to explicitly
492 specify modifiers that apply only to portions of a regular expression.
493 The innermost always has priority over any outer ones, and one applying
494 to the whole expression has priority over any of the default settings that are
495 described in the remainder of this section.
496
497 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
498 default modifiers (including these) for regular expressions compiled
499 within its scope.  This pragma has precedence over the other pragmas
500 listed below that also change the defaults.
501
502 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
503 and C<L<use feature 'unicode_strings|feature>>, or
504 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
505 C</u> when not in the same scope as either C<L<use locale|perllocale>>
506 or C<L<use bytes|bytes>>.
507 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
508 sets the default to C</u>, overriding any plain C<use locale>.)
509 Unlike the mechanisms mentioned above, these
510 affect operations besides regular expressions pattern matching, and so
511 give more consistent results with other operators, including using
512 C<\U>, C<\l>, etc. in substitution replacements.
513
514 If none of the above apply, for backwards compatibility reasons, the
515 C</d> modifier is the one in effect by default.  As this can lead to
516 unexpected results, it is best to specify which other rule set should be
517 used.
518
519 =head4 Character set modifier behavior prior to Perl 5.14
520
521 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
522 for regexes compiled within the scope of C<use locale>, and C</d> was
523 implied otherwise.  However, interpolating a regex into a larger regex
524 would ignore the original compilation in favor of whatever was in effect
525 at the time of the second compilation.  There were a number of
526 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
527 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
528 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
529
530 =head2 Regular Expressions
531
532 =head3 Metacharacters
533
534 The patterns used in Perl pattern matching evolved from those supplied in
535 the Version 8 regex routines.  (The routines are derived
536 (distantly) from Henry Spencer's freely redistributable reimplementation
537 of the V8 routines.)  See L<Version 8 Regular Expressions> for
538 details.
539
540 In particular the following metacharacters have their standard I<egrep>-ish
541 meanings:
542 X<metacharacter>
543 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
544
545
546     \        Quote the next metacharacter
547     ^        Match the beginning of the line
548     .        Match any character (except newline)
549     $        Match the end of the string (or before newline at the end
550              of the string)
551     |        Alternation
552     ()       Grouping
553     []       Bracketed Character class
554
555 By default, the "^" character is guaranteed to match only the
556 beginning of the string, the "$" character only the end (or before the
557 newline at the end), and Perl does certain optimizations with the
558 assumption that the string contains only one line.  Embedded newlines
559 will not be matched by "^" or "$".  You may, however, wish to treat a
560 string as a multi-line buffer, such that the "^" will match after any
561 newline within the string (except if the newline is the last character in
562 the string), and "$" will match before any newline.  At the
563 cost of a little more overhead, you can do this by using the /m modifier
564 on the pattern match operator.  (Older programs did this by setting C<$*>,
565 but this option was removed in perl 5.10.)
566 X<^> X<$> X</m>
567
568 To simplify multi-line substitutions, the "." character never matches a
569 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
570 the string is a single line--even if it isn't.
571 X<.> X</s>
572
573 =head3 Quantifiers
574
575 The following standard quantifiers are recognized:
576 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
577
578     *           Match 0 or more times
579     +           Match 1 or more times
580     ?           Match 1 or 0 times
581     {n}         Match exactly n times
582     {n,}        Match at least n times
583     {n,m}       Match at least n but not more than m times
584
585 (If a curly bracket occurs in any other context and does not form part of
586 a backslashed sequence like C<\x{...}>, it is treated as a regular
587 character.  However, a deprecation warning is raised for all such
588 occurrences, and in Perl v5.26, literal uses of a curly bracket will be
589 required to be escaped, say by preceding them with a backslash (C<"\{">)
590 or enclosing them within square brackets  (C<"[{]">).  This change will
591 allow for future syntax extensions (like making the lower bound of a
592 quantifier optional), and better error checking of quantifiers.)
593
594 The "*" quantifier is equivalent to C<{0,}>, the "+"
595 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
596 to non-negative integral values less than a preset limit defined when perl is built.
597 This is usually 32766 on the most common platforms.  The actual limit can
598 be seen in the error message generated by code such as this:
599
600     $_ **= $_ , / {$_} / for 2 .. 42;
601
602 By default, a quantified subpattern is "greedy", that is, it will match as
603 many times as possible (given a particular starting location) while still
604 allowing the rest of the pattern to match.  If you want it to match the
605 minimum number of times possible, follow the quantifier with a "?".  Note
606 that the meanings don't change, just the "greediness":
607 X<metacharacter> X<greedy> X<greediness>
608 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
609
610     *?        Match 0 or more times, not greedily
611     +?        Match 1 or more times, not greedily
612     ??        Match 0 or 1 time, not greedily
613     {n}?      Match exactly n times, not greedily (redundant)
614     {n,}?     Match at least n times, not greedily
615     {n,m}?    Match at least n but not more than m times, not greedily
616
617 Normally when a quantified subpattern does not allow the rest of the
618 overall pattern to match, Perl will backtrack. However, this behaviour is
619 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
620 as well.
621
622  *+     Match 0 or more times and give nothing back
623  ++     Match 1 or more times and give nothing back
624  ?+     Match 0 or 1 time and give nothing back
625  {n}+   Match exactly n times and give nothing back (redundant)
626  {n,}+  Match at least n times and give nothing back
627  {n,m}+ Match at least n but not more than m times and give nothing back
628
629 For instance,
630
631    'aaaa' =~ /a++a/
632
633 will never match, as the C<a++> will gobble up all the C<a>'s in the
634 string and won't leave any for the remaining part of the pattern. This
635 feature can be extremely useful to give perl hints about where it
636 shouldn't backtrack. For instance, the typical "match a double-quoted
637 string" problem can be most efficiently performed when written as:
638
639    /"(?:[^"\\]++|\\.)*+"/
640
641 as we know that if the final quote does not match, backtracking will not
642 help. See the independent subexpression
643 L</C<< (?>pattern) >>> for more details;
644 possessive quantifiers are just syntactic sugar for that construct. For
645 instance the above example could also be written as follows:
646
647    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
648
649 Note that the possessive quantifier modifier can not be be combined
650 with the non-greedy modifier. This is because it would make no sense.
651 Consider the follow equivalency table:
652
653     Illegal         Legal
654     ------------    ------
655     X??+            X{0}
656     X+?+            X{1}
657     X{min,max}?+    X{min}
658
659 =head3 Escape sequences
660
661 Because patterns are processed as double-quoted strings, the following
662 also work:
663
664  \t          tab                   (HT, TAB)
665  \n          newline               (LF, NL)
666  \r          return                (CR)
667  \f          form feed             (FF)
668  \a          alarm (bell)          (BEL)
669  \e          escape (think troff)  (ESC)
670  \cK         control char          (example: VT)
671  \x{}, \x00  character whose ordinal is the given hexadecimal number
672  \N{name}    named Unicode character or character sequence
673  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
674  \o{}, \000  character whose ordinal is the given octal number
675  \l          lowercase next char (think vi)
676  \u          uppercase next char (think vi)
677  \L          lowercase until \E (think vi)
678  \U          uppercase until \E (think vi)
679  \Q          quote (disable) pattern metacharacters until \E
680  \E          end either case modification or quoted section, think vi
681
682 Details are in L<perlop/Quote and Quote-like Operators>.
683
684 =head3 Character Classes and other Special Escapes
685
686 In addition, Perl defines the following:
687 X<\g> X<\k> X<\K> X<backreference>
688
689  Sequence   Note    Description
690   [...]     [1]  Match a character according to the rules of the
691                    bracketed character class defined by the "...".
692                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
693   [[:...:]] [2]  Match a character according to the rules of the POSIX
694                    character class "..." within the outer bracketed
695                    character class.  Example: [[:upper:]] matches any
696                    uppercase character.
697   (?[...])  [8]  Extended bracketed character class
698   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
699                    other connector punctuation chars plus Unicode
700                    marks)
701   \W        [3]  Match a non-"word" character
702   \s        [3]  Match a whitespace character
703   \S        [3]  Match a non-whitespace character
704   \d        [3]  Match a decimal digit character
705   \D        [3]  Match a non-digit character
706   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
707   \PP       [3]  Match non-P
708   \X        [4]  Match Unicode "eXtended grapheme cluster"
709   \C             Match a single C-language char (octet) even if that is
710                    part of a larger UTF-8 character.  Thus it breaks up
711                    characters into their UTF-8 bytes, so you may end up
712                    with malformed pieces of UTF-8.  Unsupported in
713                    lookbehind. (Deprecated.)
714   \1        [5]  Backreference to a specific capture group or buffer.
715                    '1' may actually be any positive integer.
716   \g1       [5]  Backreference to a specific or previous group,
717   \g{-1}    [5]  The number may be negative indicating a relative
718                    previous group and may optionally be wrapped in
719                    curly brackets for safer parsing.
720   \g{name}  [5]  Named backreference
721   \k<name>  [5]  Named backreference
722   \K        [6]  Keep the stuff left of the \K, don't include it in $&
723   \N        [7]  Any character but \n.  Not affected by /s modifier
724   \v        [3]  Vertical whitespace
725   \V        [3]  Not vertical whitespace
726   \h        [3]  Horizontal whitespace
727   \H        [3]  Not horizontal whitespace
728   \R        [4]  Linebreak
729
730 =over 4
731
732 =item [1]
733
734 See L<perlrecharclass/Bracketed Character Classes> for details.
735
736 =item [2]
737
738 See L<perlrecharclass/POSIX Character Classes> for details.
739
740 =item [3]
741
742 See L<perlrecharclass/Backslash sequences> for details.
743
744 =item [4]
745
746 See L<perlrebackslash/Misc> for details.
747
748 =item [5]
749
750 See L</Capture groups> below for details.
751
752 =item [6]
753
754 See L</Extended Patterns> below for details.
755
756 =item [7]
757
758 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
759 character or character sequence whose name is C<NAME>; and similarly
760 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
761 code point is I<hex>.  Otherwise it matches any character but C<\n>.
762
763 =item [8]
764
765 See L<perlrecharclass/Extended Bracketed Character Classes> for details.
766
767 =back
768
769 =head3 Assertions
770
771 Perl defines the following zero-width assertions:
772 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
773 X<regexp, zero-width assertion>
774 X<regular expression, zero-width assertion>
775 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
776
777     \b{} Match at Unicode boundary of specified type
778     \B{} Match where corresponding \b{} doesn't match
779     \b  Match a word boundary
780     \B  Match except at a word boundary
781     \A  Match only at beginning of string
782     \Z  Match only at end of string, or before newline at the end
783     \z  Match only at end of string
784     \G  Match only at pos() (e.g. at the end-of-match position
785         of prior m//g)
786
787 A Unicode boundary (C<\b{}>), available starting in v5.22, is a spot
788 between two characters, or before the first character in the string, or
789 after the final character in the string where certain criteria defined
790 by Unicode are met.  See L<perlrebackslash/\b{}, \b, \B{}, \B> for
791 details.
792
793 A word boundary (C<\b>) is a spot between two characters
794 that has a C<\w> on one side of it and a C<\W> on the other side
795 of it (in either order), counting the imaginary characters off the
796 beginning and end of the string as matching a C<\W>.  (Within
797 character classes C<\b> represents backspace rather than a word
798 boundary, just as it normally does in any double-quoted string.)
799 The C<\A> and C<\Z> are just like "^" and "$", except that they
800 won't match multiple times when the C</m> modifier is used, while
801 "^" and "$" will match at every internal line boundary.  To match
802 the actual end of the string and not ignore an optional trailing
803 newline, use C<\z>.
804 X<\b> X<\A> X<\Z> X<\z> X</m>
805
806 The C<\G> assertion can be used to chain global matches (using
807 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
808 It is also useful when writing C<lex>-like scanners, when you have
809 several patterns that you want to match against consequent substrings
810 of your string; see the previous reference.  The actual location
811 where C<\G> will match can also be influenced by using C<pos()> as
812 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
813 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
814 is modified somewhat, in that contents to the left of C<\G> are
815 not counted when determining the length of the match. Thus the following
816 will not match forever:
817 X<\G>
818
819      my $string = 'ABC';
820      pos($string) = 1;
821      while ($string =~ /(.\G)/g) {
822          print $1;
823      }
824
825 It will print 'A' and then terminate, as it considers the match to
826 be zero-width, and thus will not match at the same position twice in a
827 row.
828
829 It is worth noting that C<\G> improperly used can result in an infinite
830 loop. Take care when using patterns that include C<\G> in an alternation.
831
832 Note also that C<s///> will refuse to overwrite part of a substitution
833 that has already been replaced; so for example this will stop after the
834 first iteration, rather than iterating its way backwards through the
835 string:
836
837     $_ = "123456789";
838     pos = 6;
839     s/.(?=.\G)/X/g;
840     print;      # prints 1234X6789, not XXXXX6789
841
842
843 =head3 Capture groups
844
845 The bracketing construct C<( ... )> creates capture groups (also referred to as
846 capture buffers). To refer to the current contents of a group later on, within
847 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
848 for the second, and so on.
849 This is called a I<backreference>.
850 X<regex, capture buffer> X<regexp, capture buffer>
851 X<regex, capture group> X<regexp, capture group>
852 X<regular expression, capture buffer> X<backreference>
853 X<regular expression, capture group> X<backreference>
854 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
855 X<named capture buffer> X<regular expression, named capture buffer>
856 X<named capture group> X<regular expression, named capture group>
857 X<%+> X<$+{name}> X<< \k<name> >>
858 There is no limit to the number of captured substrings that you may use.
859 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
860 a group did not match, the associated backreference won't match either. (This
861 can happen if the group is optional, or in a different branch of an
862 alternation.)
863 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
864 this form, described below.
865
866 You can also refer to capture groups relatively, by using a negative number, so
867 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
868 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
869 example:
870
871         /
872          (Y)            # group 1
873          (              # group 2
874             (X)         # group 3
875             \g{-1}      # backref to group 3
876             \g{-3}      # backref to group 1
877          )
878         /x
879
880 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
881 interpolate regexes into larger regexes and not have to worry about the
882 capture groups being renumbered.
883
884 You can dispense with numbers altogether and create named capture groups.
885 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
886 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
887 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
888 I<name> must not begin with a number, nor contain hyphens.
889 When different groups within the same pattern have the same name, any reference
890 to that name assumes the leftmost defined group.  Named groups count in
891 absolute and relative numbering, and so can also be referred to by those
892 numbers.
893 (It's possible to do things with named capture groups that would otherwise
894 require C<(??{})>.)
895
896 Capture group contents are dynamically scoped and available to you outside the
897 pattern until the end of the enclosing block or until the next successful
898 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
899 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
900 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
901
902 Braces are required in referring to named capture groups, but are optional for
903 absolute or relative numbered ones.  Braces are safer when creating a regex by
904 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
905 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
906 is probably not what you intended.
907
908 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
909 there were no named nor relative numbered capture groups.  Absolute numbered
910 groups were referred to using C<\1>,
911 C<\2>, etc., and this notation is still
912 accepted (and likely always will be).  But it leads to some ambiguities if
913 there are more than 9 capture groups, as C<\10> could mean either the tenth
914 capture group, or the character whose ordinal in octal is 010 (a backspace in
915 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
916 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
917 a backreference only if at least 11 left parentheses have opened before it.
918 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
919 There are several examples below that illustrate these perils.  You can avoid
920 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
921 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
922 digits padded with leading zeros, since a leading zero implies an octal
923 constant.
924
925 The C<\I<digit>> notation also works in certain circumstances outside
926 the pattern.  See L</Warning on \1 Instead of $1> below for details.
927
928 Examples:
929
930     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
931
932     /(.)\g1/                        # find first doubled char
933          and print "'$1' is the first doubled character\n";
934
935     /(?<char>.)\k<char>/            # ... a different way
936          and print "'$+{char}' is the first doubled character\n";
937
938     /(?'char'.)\g1/                 # ... mix and match
939          and print "'$1' is the first doubled character\n";
940
941     if (/Time: (..):(..):(..)/) {   # parse out values
942         $hours = $1;
943         $minutes = $2;
944         $seconds = $3;
945     }
946
947     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
948     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
949     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
950     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
951
952     $a = '(.)\1';        # Creates problems when concatenated.
953     $b = '(.)\g{1}';     # Avoids the problems.
954     "aa" =~ /${a}/;      # True
955     "aa" =~ /${b}/;      # True
956     "aa0" =~ /${a}0/;    # False!
957     "aa0" =~ /${b}0/;    # True
958     "aa\x08" =~ /${a}0/;  # True!
959     "aa\x08" =~ /${b}0/;  # False
960
961 Several special variables also refer back to portions of the previous
962 match.  C<$+> returns whatever the last bracket match matched.
963 C<$&> returns the entire matched string.  (At one point C<$0> did
964 also, but now it returns the name of the program.)  C<$`> returns
965 everything before the matched string.  C<$'> returns everything
966 after the matched string. And C<$^N> contains whatever was matched by
967 the most-recently closed group (submatch). C<$^N> can be used in
968 extended patterns (see below), for example to assign a submatch to a
969 variable.
970 X<$+> X<$^N> X<$&> X<$`> X<$'>
971
972 These special variables, like the C<%+> hash and the numbered match variables
973 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
974 until the end of the enclosing block or until the next successful
975 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
976 X<$+> X<$^N> X<$&> X<$`> X<$'>
977 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
978
979 B<NOTE>: Failed matches in Perl do not reset the match variables,
980 which makes it easier to write code that tests for a series of more
981 specific cases and remembers the best match.
982
983 B<WARNING>: If your code is to run on Perl 5.16 or earlier,
984 beware that once Perl sees that you need one of C<$&>, C<$`>, or
985 C<$'> anywhere in the program, it has to provide them for every
986 pattern match.  This may substantially slow your program.
987
988 Perl uses the same mechanism to produce C<$1>, C<$2>, etc, so you also
989 pay a price for each pattern that contains capturing parentheses.
990 (To avoid this cost while retaining the grouping behaviour, use the
991 extended regular expression C<(?: ... )> instead.)  But if you never
992 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
993 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
994 if you can, but if you can't (and some algorithms really appreciate
995 them), once you've used them once, use them at will, because you've
996 already paid the price.
997 X<$&> X<$`> X<$'>
998
999 Perl 5.16 introduced a slightly more efficient mechanism that notes
1000 separately whether each of C<$`>, C<$&>, and C<$'> have been seen, and
1001 thus may only need to copy part of the string.  Perl 5.20 introduced a
1002 much more efficient copy-on-write mechanism which eliminates any slowdown.
1003
1004 As another workaround for this problem, Perl 5.10.0 introduced C<${^PREMATCH}>,
1005 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
1006 and C<$'>, B<except> that they are only guaranteed to be defined after a
1007 successful match that was executed with the C</p> (preserve) modifier.
1008 The use of these variables incurs no global performance penalty, unlike
1009 their punctuation char equivalents, however at the trade-off that you
1010 have to tell perl when you want to use them.  As of Perl 5.20, these three
1011 variables are equivalent to C<$`>, C<$&> and C<$'>, and C</p> is ignored.
1012 X</p> X<p modifier>
1013
1014 =head2 Quoting metacharacters
1015
1016 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
1017 C<\w>, C<\n>.  Unlike some other regular expression languages, there
1018 are no backslashed symbols that aren't alphanumeric.  So anything
1019 that looks like \\, \(, \), \[, \], \{, or \} is always
1020 interpreted as a literal character, not a metacharacter.  This was
1021 once used in a common idiom to disable or quote the special meanings
1022 of regular expression metacharacters in a string that you want to
1023 use for a pattern. Simply quote all non-"word" characters:
1024
1025     $pattern =~ s/(\W)/\\$1/g;
1026
1027 (If C<use locale> is set, then this depends on the current locale.)
1028 Today it is more common to use the quotemeta() function or the C<\Q>
1029 metaquoting escape sequence to disable all metacharacters' special
1030 meanings like this:
1031
1032     /$unquoted\Q$quoted\E$unquoted/
1033
1034 Beware that if you put literal backslashes (those not inside
1035 interpolated variables) between C<\Q> and C<\E>, double-quotish
1036 backslash interpolation may lead to confusing results.  If you
1037 I<need> to use literal backslashes within C<\Q...\E>,
1038 consult L<perlop/"Gory details of parsing quoted constructs">.
1039
1040 C<quotemeta()> and C<\Q> are fully described in L<perlfunc/quotemeta>.
1041
1042 =head2 Extended Patterns
1043
1044 Perl also defines a consistent extension syntax for features not
1045 found in standard tools like B<awk> and
1046 B<lex>.  The syntax for most of these is a
1047 pair of parentheses with a question mark as the first thing within
1048 the parentheses.  The character after the question mark indicates
1049 the extension.
1050
1051 The stability of these extensions varies widely.  Some have been
1052 part of the core language for many years.  Others are experimental
1053 and may change without warning or be completely removed.  Check
1054 the documentation on an individual feature to verify its current
1055 status.
1056
1057 A question mark was chosen for this and for the minimal-matching
1058 construct because 1) question marks are rare in older regular
1059 expressions, and 2) whenever you see one, you should stop and
1060 "question" exactly what is going on.  That's psychology....
1061
1062 =over 4
1063
1064 =item C<(?#text)>
1065 X<(?#)>
1066
1067 A comment.  The text is ignored.
1068 Note that Perl closes
1069 the comment as soon as it sees a C<)>, so there is no way to put a literal
1070 C<)> in the comment.  The pattern's closing delimiter must be escaped by
1071 a backslash if it appears in the comment.
1072
1073 See L</E<sol>x> for another way to have comments in patterns.
1074
1075 =item C<(?adlupimsx-imsx)>
1076
1077 =item C<(?^alupimsx)>
1078 X<(?)> X<(?^)>
1079
1080 One or more embedded pattern-match modifiers, to be turned on (or
1081 turned off, if preceded by C<->) for the remainder of the pattern or
1082 the remainder of the enclosing pattern group (if any).
1083
1084 This is particularly useful for dynamic patterns, such as those read in from a
1085 configuration file, taken from an argument, or specified in a table
1086 somewhere.  Consider the case where some patterns want to be
1087 case-sensitive and some do not:  The case-insensitive ones merely need to
1088 include C<(?i)> at the front of the pattern.  For example:
1089
1090     $pattern = "foobar";
1091     if ( /$pattern/i ) { }
1092
1093     # more flexible:
1094
1095     $pattern = "(?i)foobar";
1096     if ( /$pattern/ ) { }
1097
1098 These modifiers are restored at the end of the enclosing group. For example,
1099
1100     ( (?i) blah ) \s+ \g1
1101
1102 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
1103 repetition of the previous word, assuming the C</x> modifier, and no C</i>
1104 modifier outside this group.
1105
1106 These modifiers do not carry over into named subpatterns called in the
1107 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
1108 change the case-sensitivity of the "NAME" pattern.
1109
1110 Any of these modifiers can be set to apply globally to all regular
1111 expressions compiled within the scope of a C<use re>.  See
1112 L<re/"'/flags' mode">.
1113
1114 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1115 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
1116 C<"d">) may follow the caret to override it.
1117 But a minus sign is not legal with it.
1118
1119 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
1120 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
1121 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1122 others, and a maximum of one (or two C<a>'s) may appear in the
1123 construct.  Thus, for
1124 example, C<(?-p)> will warn when compiled under C<use warnings>;
1125 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1126
1127 Note also that the C<p> modifier is special in that its presence
1128 anywhere in a pattern has a global effect.
1129
1130 =item C<(?:pattern)>
1131 X<(?:)>
1132
1133 =item C<(?adluimsx-imsx:pattern)>
1134
1135 =item C<(?^aluimsx:pattern)>
1136 X<(?^:)>
1137
1138 This is for clustering, not capturing; it groups subexpressions like
1139 "()", but doesn't make backreferences as "()" does.  So
1140
1141     @fields = split(/\b(?:a|b|c)\b/)
1142
1143 is like
1144
1145     @fields = split(/\b(a|b|c)\b/)
1146
1147 but doesn't spit out extra fields.  It's also cheaper not to capture
1148 characters if you don't need to.
1149
1150 Any letters between C<?> and C<:> act as flags modifiers as with
1151 C<(?adluimsx-imsx)>.  For example,
1152
1153     /(?s-i:more.*than).*million/i
1154
1155 is equivalent to the more verbose
1156
1157     /(?:(?s-i)more.*than).*million/i
1158
1159 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1160 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1161 flags (except C<"d">) may follow the caret, so
1162
1163     (?^x:foo)
1164
1165 is equivalent to
1166
1167     (?x-ims:foo)
1168
1169 The caret tells Perl that this cluster doesn't inherit the flags of any
1170 surrounding pattern, but uses the system defaults (C<d-imsx>),
1171 modified by any flags specified.
1172
1173 The caret allows for simpler stringification of compiled regular
1174 expressions.  These look like
1175
1176     (?^:pattern)
1177
1178 with any non-default flags appearing between the caret and the colon.
1179 A test that looks at such stringification thus doesn't need to have the
1180 system default flags hard-coded in it, just the caret.  If new flags are
1181 added to Perl, the meaning of the caret's expansion will change to include
1182 the default for those flags, so the test will still work, unchanged.
1183
1184 Specifying a negative flag after the caret is an error, as the flag is
1185 redundant.
1186
1187 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1188 to match at the beginning.
1189
1190 =item C<(?|pattern)>
1191 X<(?|)> X<Branch reset>
1192
1193 This is the "branch reset" pattern, which has the special property
1194 that the capture groups are numbered from the same starting point
1195 in each alternation branch. It is available starting from perl 5.10.0.
1196
1197 Capture groups are numbered from left to right, but inside this
1198 construct the numbering is restarted for each branch.
1199
1200 The numbering within each branch will be as normal, and any groups
1201 following this construct will be numbered as though the construct
1202 contained only one branch, that being the one with the most capture
1203 groups in it.
1204
1205 This construct is useful when you want to capture one of a
1206 number of alternative matches.
1207
1208 Consider the following pattern.  The numbers underneath show in
1209 which group the captured content will be stored.
1210
1211
1212     # before  ---------------branch-reset----------- after        
1213     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1214     # 1            2         2  3        2     3     4  
1215
1216 Be careful when using the branch reset pattern in combination with 
1217 named captures. Named captures are implemented as being aliases to 
1218 numbered groups holding the captures, and that interferes with the
1219 implementation of the branch reset pattern. If you are using named
1220 captures in a branch reset pattern, it's best to use the same names,
1221 in the same order, in each of the alternations:
1222
1223    /(?|  (?<a> x ) (?<b> y )
1224       |  (?<a> z ) (?<b> w )) /x
1225
1226 Not doing so may lead to surprises:
1227
1228   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1229   say $+ {a};   # Prints '12'
1230   say $+ {b};   # *Also* prints '12'.
1231
1232 The problem here is that both the group named C<< a >> and the group
1233 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1234
1235 =item Look-Around Assertions
1236 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1237
1238 Look-around assertions are zero-width patterns which match a specific
1239 pattern without including it in C<$&>. Positive assertions match when
1240 their subpattern matches, negative assertions match when their subpattern
1241 fails. Look-behind matches text up to the current match position,
1242 look-ahead matches text following the current match position.
1243
1244 =over 4
1245
1246 =item C<(?=pattern)>
1247 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1248
1249 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1250 matches a word followed by a tab, without including the tab in C<$&>.
1251
1252 =item C<(?!pattern)>
1253 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1254
1255 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1256 matches any occurrence of "foo" that isn't followed by "bar".  Note
1257 however that look-ahead and look-behind are NOT the same thing.  You cannot
1258 use this for look-behind.
1259
1260 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1261 will not do what you want.  That's because the C<(?!foo)> is just saying that
1262 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1263 match.  Use look-behind instead (see below).
1264
1265 =item C<(?<=pattern)> C<\K>
1266 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1267
1268 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1269 matches a word that follows a tab, without including the tab in C<$&>.
1270 Works only for fixed-width look-behind.
1271
1272 There is a special form of this construct, called C<\K> (available since
1273 Perl 5.10.0), which causes the
1274 regex engine to "keep" everything it had matched prior to the C<\K> and
1275 not include it in C<$&>. This effectively provides variable-length
1276 look-behind. The use of C<\K> inside of another look-around assertion
1277 is allowed, but the behaviour is currently not well defined.
1278
1279 For various reasons C<\K> may be significantly more efficient than the
1280 equivalent C<< (?<=...) >> construct, and it is especially useful in
1281 situations where you want to efficiently remove something following
1282 something else in a string. For instance
1283
1284   s/(foo)bar/$1/g;
1285
1286 can be rewritten as the much more efficient
1287
1288   s/foo\Kbar//g;
1289
1290 =item C<(?<!pattern)>
1291 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1292
1293 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1294 matches any occurrence of "foo" that does not follow "bar".  Works
1295 only for fixed-width look-behind.
1296
1297 =back
1298
1299 =item C<(?'NAME'pattern)>
1300
1301 =item C<< (?<NAME>pattern) >>
1302 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1303
1304 A named capture group. Identical in every respect to normal capturing
1305 parentheses C<()> but for the additional fact that the group
1306 can be referred to by name in various regular expression
1307 constructs (like C<\g{NAME}>) and can be accessed by name
1308 after a successful match via C<%+> or C<%->. See L<perlvar>
1309 for more details on the C<%+> and C<%-> hashes.
1310
1311 If multiple distinct capture groups have the same name then the
1312 $+{NAME} will refer to the leftmost defined group in the match.
1313
1314 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1315
1316 B<NOTE:> While the notation of this construct is the same as the similar
1317 function in .NET regexes, the behavior is not. In Perl the groups are
1318 numbered sequentially regardless of being named or not. Thus in the
1319 pattern
1320
1321   /(x)(?<foo>y)(z)/
1322
1323 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1324 the opposite which is what a .NET regex hacker might expect.
1325
1326 Currently NAME is restricted to simple identifiers only.
1327 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1328 its Unicode extension (see L<utf8>),
1329 though it isn't extended by the locale (see L<perllocale>).
1330
1331 B<NOTE:> In order to make things easier for programmers with experience
1332 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1333 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1334 support the use of single quotes as a delimiter for the name.
1335
1336 =item C<< \k<NAME> >>
1337
1338 =item C<< \k'NAME' >>
1339
1340 Named backreference. Similar to numeric backreferences, except that
1341 the group is designated by name and not number. If multiple groups
1342 have the same name then it refers to the leftmost defined group in
1343 the current match.
1344
1345 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1346 earlier in the pattern.
1347
1348 Both forms are equivalent.
1349
1350 B<NOTE:> In order to make things easier for programmers with experience
1351 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1352 may be used instead of C<< \k<NAME> >>.
1353
1354 =item C<(?{ code })>
1355 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1356
1357 B<WARNING>: Using this feature safely requires that you understand its
1358 limitations.  Code executed that has side effects may not perform identically
1359 from version to version due to the effect of future optimisations in the regex
1360 engine.  For more information on this, see L</Embedded Code Execution
1361 Frequency>.
1362
1363 This zero-width assertion executes any embedded Perl code.  It always
1364 succeeds, and its return value is set as C<$^R>.
1365
1366 In literal patterns, the code is parsed at the same time as the
1367 surrounding code. While within the pattern, control is passed temporarily
1368 back to the perl parser, until the logically-balancing closing brace is
1369 encountered. This is similar to the way that an array index expression in
1370 a literal string is handled, for example
1371
1372     "abc$array[ 1 + f('[') + g()]def"
1373
1374 In particular, braces do not need to be balanced:
1375
1376     s/abc(?{ f('{'); })/def/
1377
1378 Even in a pattern that is interpolated and compiled at run-time, literal
1379 code blocks will be compiled once, at perl compile time; the following
1380 prints "ABCD":
1381
1382     print "D";
1383     my $qr = qr/(?{ BEGIN { print "A" } })/;
1384     my $foo = "foo";
1385     /$foo$qr(?{ BEGIN { print "B" } })/;
1386     BEGIN { print "C" }
1387
1388 In patterns where the text of the code is derived from run-time
1389 information rather than appearing literally in a source code /pattern/,
1390 the code is compiled at the same time that the pattern is compiled, and
1391 for reasons of security, C<use re 'eval'> must be in scope. This is to
1392 stop user-supplied patterns containing code snippets from being
1393 executable.
1394
1395 In situations where you need to enable this with C<use re 'eval'>, you should
1396 also have taint checking enabled.  Better yet, use the carefully
1397 constrained evaluation within a Safe compartment.  See L<perlsec> for
1398 details about both these mechanisms.
1399
1400 From the viewpoint of parsing, lexical variable scope and closures,
1401
1402     /AAA(?{ BBB })CCC/
1403
1404 behaves approximately like
1405
1406     /AAA/ && do { BBB } && /CCC/
1407
1408 Similarly,
1409
1410     qr/AAA(?{ BBB })CCC/
1411
1412 behaves approximately like
1413
1414     sub { /AAA/ && do { BBB } && /CCC/ }
1415
1416 In particular:
1417
1418     { my $i = 1; $r = qr/(?{ print $i })/ }
1419     my $i = 2;
1420     /$r/; # prints "1"
1421
1422 Inside a C<(?{...})> block, C<$_> refers to the string the regular
1423 expression is matching against. You can also use C<pos()> to know what is
1424 the current position of matching within this string.
1425
1426 The code block introduces a new scope from the perspective of lexical
1427 variable declarations, but B<not> from the perspective of C<local> and
1428 similar localizing behaviours. So later code blocks within the same
1429 pattern will still see the values which were localized in earlier blocks.
1430 These accumulated localizations are undone either at the end of a
1431 successful match, or if the assertion is backtracked (compare
1432 L<"Backtracking">). For example,
1433
1434   $_ = 'a' x 8;
1435   m<
1436      (?{ $cnt = 0 })               # Initialize $cnt.
1437      (
1438        a
1439        (?{
1440            local $cnt = $cnt + 1;  # Update $cnt,
1441                                    # backtracking-safe.
1442        })
1443      )*
1444      aaaa
1445      (?{ $res = $cnt })            # On success copy to
1446                                    # non-localized location.
1447    >x;
1448
1449 will initially increment C<$cnt> up to 8; then during backtracking, its
1450 value will be unwound back to 4, which is the value assigned to C<$res>.
1451 At the end of the regex execution, $cnt will be wound back to its initial
1452 value of 0.
1453
1454 This assertion may be used as the condition in a
1455
1456     (?(condition)yes-pattern|no-pattern)
1457
1458 switch.  If I<not> used in this way, the result of evaluation of C<code>
1459 is put into the special variable C<$^R>.  This happens immediately, so
1460 C<$^R> can be used from other C<(?{ code })> assertions inside the same
1461 regular expression.
1462
1463 The assignment to C<$^R> above is properly localized, so the old
1464 value of C<$^R> is restored if the assertion is backtracked; compare
1465 L<"Backtracking">.
1466
1467 Note that the special variable C<$^N>  is particularly useful with code
1468 blocks to capture the results of submatches in variables without having to
1469 keep track of the number of nested parentheses. For example:
1470
1471   $_ = "The brown fox jumps over the lazy dog";
1472   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1473   print "color = $color, animal = $animal\n";
1474
1475
1476 =item C<(??{ code })>
1477 X<(??{})>
1478 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1479
1480 B<WARNING>: Using this feature safely requires that you understand its
1481 limitations.  Code executed that has side effects may not perform
1482 identically from version to version due to the effect of future
1483 optimisations in the regex engine.  For more information on this, see
1484 L</Embedded Code Execution Frequency>.
1485
1486 This is a "postponed" regular subexpression.  It behaves in I<exactly> the
1487 same way as a C<(?{ code })> code block as described above, except that
1488 its return value, rather than being assigned to C<$^R>, is treated as a
1489 pattern, compiled if it's a string (or used as-is if its a qr// object),
1490 then matched as if it were inserted instead of this construct.
1491
1492 During the matching of this sub-pattern, it has its own set of
1493 captures which are valid during the sub-match, but are discarded once
1494 control returns to the main pattern. For example, the following matches,
1495 with the inner pattern capturing "B" and matching "BB", while the outer
1496 pattern captures "A";
1497
1498     my $inner = '(.)\1';
1499     "ABBA" =~ /^(.)(??{ $inner })\1/;
1500     print $1; # prints "A";
1501
1502 Note that this means that  there is no way for the inner pattern to refer
1503 to a capture group defined outside.  (The code block itself can use C<$1>,
1504 etc., to refer to the enclosing pattern's capture groups.)  Thus, although
1505
1506     ('a' x 100)=~/(??{'(.)' x 100})/
1507
1508 I<will> match, it will I<not> set $1 on exit.
1509
1510 The following pattern matches a parenthesized group:
1511
1512  $re = qr{
1513             \(
1514             (?:
1515                (?> [^()]+ )  # Non-parens without backtracking
1516              |
1517                (??{ $re })   # Group with matching parens
1518             )*
1519             \)
1520          }x;
1521
1522 See also
1523 L<C<(?I<PARNO>)>|/(?PARNO) (?-PARNO) (?+PARNO) (?R) (?0)>
1524 for a different, more efficient way to accomplish
1525 the same task.
1526
1527 Executing a postponed regular expression 50 times without consuming any
1528 input string will result in a fatal error.  The maximum depth is compiled
1529 into perl, so changing it requires a custom build.
1530
1531 =item C<(?I<PARNO>)> C<(?-I<PARNO>)> C<(?+I<PARNO>)> C<(?R)> C<(?0)>
1532 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1533 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1534 X<regex, relative recursion> X<GOSUB> X<GOSTART>
1535
1536 Recursive subpattern. Treat the contents of a given capture buffer in the
1537 current pattern as an independent subpattern and attempt to match it at
1538 the current position in the string. Information about capture state from
1539 the caller for things like backreferences is available to the subpattern,
1540 but capture buffers set by the subpattern are not visible to the caller.
1541
1542 Similar to C<(??{ code })> except that it does not involve executing any
1543 code or potentially compiling a returned pattern string; instead it treats
1544 the part of the current pattern contained within a specified capture group
1545 as an independent pattern that must match at the current position. Also
1546 different is the treatment of capture buffers, unlike C<(??{ code })>
1547 recursive patterns have access to their callers match state, so one can
1548 use backreferences safely.
1549
1550 I<PARNO> is a sequence of digits (not starting with 0) whose value reflects
1551 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1552 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1553 C<(?R)>. If I<PARNO> is preceded by a plus or minus sign then it is assumed
1554 to be relative, with negative numbers indicating preceding capture groups
1555 and positive ones following. Thus C<(?-1)> refers to the most recently
1556 declared group, and C<(?+1)> indicates the next group to be declared.
1557 Note that the counting for relative recursion differs from that of
1558 relative backreferences, in that with recursion unclosed groups B<are>
1559 included.
1560
1561 The following pattern matches a function foo() which may contain
1562 balanced parentheses as the argument.
1563
1564   $re = qr{ (                   # paren group 1 (full function)
1565               foo
1566               (                 # paren group 2 (parens)
1567                 \(
1568                   (             # paren group 3 (contents of parens)
1569                   (?:
1570                    (?> [^()]+ ) # Non-parens without backtracking
1571                   |
1572                    (?2)         # Recurse to start of paren group 2
1573                   )*
1574                   )
1575                 \)
1576               )
1577             )
1578           }x;
1579
1580 If the pattern was used as follows
1581
1582     'foo(bar(baz)+baz(bop))'=~/$re/
1583         and print "\$1 = $1\n",
1584                   "\$2 = $2\n",
1585                   "\$3 = $3\n";
1586
1587 the output produced should be the following:
1588
1589     $1 = foo(bar(baz)+baz(bop))
1590     $2 = (bar(baz)+baz(bop))
1591     $3 = bar(baz)+baz(bop)
1592
1593 If there is no corresponding capture group defined, then it is a
1594 fatal error.  Recursing deeper than 50 times without consuming any input
1595 string will also result in a fatal error.  The maximum depth is compiled
1596 into perl, so changing it requires a custom build.
1597
1598 The following shows how using negative indexing can make it
1599 easier to embed recursive patterns inside of a C<qr//> construct
1600 for later use:
1601
1602     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1603     if (/foo $parens \s+ \+ \s+ bar $parens/x) {
1604        # do something here...
1605     }
1606
1607 B<Note> that this pattern does not behave the same way as the equivalent
1608 PCRE or Python construct of the same form. In Perl you can backtrack into
1609 a recursed group, in PCRE and Python the recursed into group is treated
1610 as atomic. Also, modifiers are resolved at compile time, so constructs
1611 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1612 be processed.
1613
1614 =item C<(?&NAME)>
1615 X<(?&NAME)>
1616
1617 Recurse to a named subpattern. Identical to C<(?I<PARNO>)> except that the
1618 parenthesis to recurse to is determined by name. If multiple parentheses have
1619 the same name, then it recurses to the leftmost.
1620
1621 It is an error to refer to a name that is not declared somewhere in the
1622 pattern.
1623
1624 B<NOTE:> In order to make things easier for programmers with experience
1625 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1626 may be used instead of C<< (?&NAME) >>.
1627
1628 =item C<(?(condition)yes-pattern|no-pattern)>
1629 X<(?()>
1630
1631 =item C<(?(condition)yes-pattern)>
1632
1633 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1634 a true value, matches C<no-pattern> otherwise. A missing pattern always
1635 matches.
1636
1637 C<(condition)> should be one of: 1) an integer in
1638 parentheses (which is valid if the corresponding pair of parentheses
1639 matched); 2) a look-ahead/look-behind/evaluate zero-width assertion; 3) a
1640 name in angle brackets or single quotes (which is valid if a group
1641 with the given name matched); or 4) the special symbol (R) (true when
1642 evaluated inside of recursion or eval). Additionally the R may be
1643 followed by a number, (which will be true when evaluated when recursing
1644 inside of the appropriate group), or by C<&NAME>, in which case it will
1645 be true only when evaluated during recursion in the named group.
1646
1647 Here's a summary of the possible predicates:
1648
1649 =over 4
1650
1651 =item (1) (2) ...
1652
1653 Checks if the numbered capturing group has matched something.
1654
1655 =item (<NAME>) ('NAME')
1656
1657 Checks if a group with the given name has matched something.
1658
1659 =item (?=...) (?!...) (?<=...) (?<!...)
1660
1661 Checks whether the pattern matches (or does not match, for the '!'
1662 variants).
1663
1664 =item (?{ CODE })
1665
1666 Treats the return value of the code block as the condition.
1667
1668 =item (R)
1669
1670 Checks if the expression has been evaluated inside of recursion.
1671
1672 =item (R1) (R2) ...
1673
1674 Checks if the expression has been evaluated while executing directly
1675 inside of the n-th capture group. This check is the regex equivalent of
1676
1677   if ((caller(0))[3] eq 'subname') { ... }
1678
1679 In other words, it does not check the full recursion stack.
1680
1681 =item (R&NAME)
1682
1683 Similar to C<(R1)>, this predicate checks to see if we're executing
1684 directly inside of the leftmost group with a given name (this is the same
1685 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1686 stack, but only the name of the innermost active recursion.
1687
1688 =item (DEFINE)
1689
1690 In this case, the yes-pattern is never directly executed, and no
1691 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1692 See below for details.
1693
1694 =back
1695
1696 For example:
1697
1698     m{ ( \( )?
1699        [^()]+
1700        (?(1) \) )
1701      }x
1702
1703 matches a chunk of non-parentheses, possibly included in parentheses
1704 themselves.
1705
1706 A special form is the C<(DEFINE)> predicate, which never executes its
1707 yes-pattern directly, and does not allow a no-pattern. This allows one to
1708 define subpatterns which will be executed only by the recursion mechanism.
1709 This way, you can define a set of regular expression rules that can be
1710 bundled into any pattern you choose.
1711
1712 It is recommended that for this usage you put the DEFINE block at the
1713 end of the pattern, and that you name any subpatterns defined within it.
1714
1715 Also, it's worth noting that patterns defined this way probably will
1716 not be as efficient, as the optimizer is not very clever about
1717 handling them.
1718
1719 An example of how this might be used is as follows:
1720
1721   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1722    (?(DEFINE)
1723      (?<NAME_PAT>....)
1724      (?<ADDRESS_PAT>....)
1725    )/x
1726
1727 Note that capture groups matched inside of recursion are not accessible
1728 after the recursion returns, so the extra layer of capturing groups is
1729 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1730 C<$+{NAME}> would be.
1731
1732 Finally, keep in mind that subpatterns created inside a DEFINE block
1733 count towards the absolute and relative number of captures, so this:
1734
1735     my @captures = "a" =~ /(.)                  # First capture
1736                            (?(DEFINE)
1737                                (?<EXAMPLE> 1 )  # Second capture
1738                            )/x;
1739     say scalar @captures;
1740
1741 Will output 2, not 1. This is particularly important if you intend to
1742 compile the definitions with the C<qr//> operator, and later
1743 interpolate them in another pattern.
1744
1745 =item C<< (?>pattern) >>
1746 X<backtrack> X<backtracking> X<atomic> X<possessive>
1747
1748 An "independent" subexpression, one which matches the substring
1749 that a I<standalone> C<pattern> would match if anchored at the given
1750 position, and it matches I<nothing other than this substring>.  This
1751 construct is useful for optimizations of what would otherwise be
1752 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1753 It may also be useful in places where the "grab all you can, and do not
1754 give anything back" semantic is desirable.
1755
1756 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1757 (anchored at the beginning of string, as above) will match I<all>
1758 characters C<a> at the beginning of string, leaving no C<a> for
1759 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1760 since the match of the subgroup C<a*> is influenced by the following
1761 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1762 C<a*ab> will match fewer characters than a standalone C<a*>, since
1763 this makes the tail match.
1764
1765 C<< (?>pattern) >> does not disable backtracking altogether once it has
1766 matched. It is still possible to backtrack past the construct, but not
1767 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1768
1769 An effect similar to C<< (?>pattern) >> may be achieved by writing
1770 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1771 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1772 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1773 (The difference between these two constructs is that the second one
1774 uses a capturing group, thus shifting ordinals of backreferences
1775 in the rest of a regular expression.)
1776
1777 Consider this pattern:
1778
1779     m{ \(
1780           (
1781             [^()]+           # x+
1782           |
1783             \( [^()]* \)
1784           )+
1785        \)
1786      }x
1787
1788 That will efficiently match a nonempty group with matching parentheses
1789 two levels deep or less.  However, if there is no such group, it
1790 will take virtually forever on a long string.  That's because there
1791 are so many different ways to split a long string into several
1792 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1793 to a subpattern of the above pattern.  Consider how the pattern
1794 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1795 seconds, but that each extra letter doubles this time.  This
1796 exponential performance will make it appear that your program has
1797 hung.  However, a tiny change to this pattern
1798
1799     m{ \(
1800           (
1801             (?> [^()]+ )        # change x+ above to (?> x+ )
1802           |
1803             \( [^()]* \)
1804           )+
1805        \)
1806      }x
1807
1808 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1809 this yourself would be a productive exercise), but finishes in a fourth
1810 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1811 however, that, when this construct is followed by a
1812 quantifier, it currently triggers a warning message under
1813 the C<use warnings> pragma or B<-w> switch saying it
1814 C<"matches null string many times in regex">.
1815
1816 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1817 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1818 This was only 4 times slower on a string with 1000000 C<a>s.
1819
1820 The "grab all you can, and do not give anything back" semantic is desirable
1821 in many situations where on the first sight a simple C<()*> looks like
1822 the correct solution.  Suppose we parse text with comments being delimited
1823 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1824 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1825 the comment delimiter, because it may "give up" some whitespace if
1826 the remainder of the pattern can be made to match that way.  The correct
1827 answer is either one of these:
1828
1829     (?>#[ \t]*)
1830     #[ \t]*(?![ \t])
1831
1832 For example, to grab non-empty comments into $1, one should use either
1833 one of these:
1834
1835     / (?> \# [ \t]* ) (        .+ ) /x;
1836     /     \# [ \t]*   ( [^ \t] .* ) /x;
1837
1838 Which one you pick depends on which of these expressions better reflects
1839 the above specification of comments.
1840
1841 In some literature this construct is called "atomic matching" or
1842 "possessive matching".
1843
1844 Possessive quantifiers are equivalent to putting the item they are applied
1845 to inside of one of these constructs. The following equivalences apply:
1846
1847     Quantifier Form     Bracketing Form
1848     ---------------     ---------------
1849     PAT*+               (?>PAT*)
1850     PAT++               (?>PAT+)
1851     PAT?+               (?>PAT?)
1852     PAT{min,max}+       (?>PAT{min,max})
1853
1854 =item C<(?[ ])>
1855
1856 See L<perlrecharclass/Extended Bracketed Character Classes>.
1857
1858 =back
1859
1860 =head2 Special Backtracking Control Verbs
1861
1862 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1863 otherwise stated the ARG argument is optional; in some cases, it is
1864 forbidden.
1865
1866 Any pattern containing a special backtracking verb that allows an argument
1867 has the special behaviour that when executed it sets the current package's
1868 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1869 rules apply:
1870
1871 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1872 verb pattern, if the verb was involved in the failure of the match. If the
1873 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1874 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1875 none. Also, the C<$REGMARK> variable will be set to FALSE.
1876
1877 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1878 the C<$REGMARK> variable will be set to the name of the last
1879 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1880 C<(*MARK:NAME)> verb below for more details.
1881
1882 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1883 and most other regex-related variables. They are not local to a scope, nor
1884 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1885 Use C<local> to localize changes to them to a specific scope if necessary.
1886
1887 If a pattern does not contain a special backtracking verb that allows an
1888 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1889
1890 =over 3
1891
1892 =item Verbs that take an argument
1893
1894 =over 4
1895
1896 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1897 X<(*PRUNE)> X<(*PRUNE:NAME)>
1898
1899 This zero-width pattern prunes the backtracking tree at the current point
1900 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1901 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1902 A may backtrack as necessary to match. Once it is reached, matching
1903 continues in B, which may also backtrack as necessary; however, should B
1904 not match, then no further backtracking will take place, and the pattern
1905 will fail outright at the current starting position.
1906
1907 The following example counts all the possible matching strings in a
1908 pattern (without actually matching any of them).
1909
1910     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1911     print "Count=$count\n";
1912
1913 which produces:
1914
1915     aaab
1916     aaa
1917     aa
1918     a
1919     aab
1920     aa
1921     a
1922     ab
1923     a
1924     Count=9
1925
1926 If we add a C<(*PRUNE)> before the count like the following
1927
1928     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1929     print "Count=$count\n";
1930
1931 we prevent backtracking and find the count of the longest matching string
1932 at each matching starting point like so:
1933
1934     aaab
1935     aab
1936     ab
1937     Count=3
1938
1939 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1940
1941 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1942 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1943 replaced with a C<< (?>pattern) >> with no functional difference; however,
1944 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1945 C<< (?>pattern) >> alone.
1946
1947 =item C<(*SKIP)> C<(*SKIP:NAME)>
1948 X<(*SKIP)>
1949
1950 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1951 failure it also signifies that whatever text that was matched leading up
1952 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1953 of this pattern. This effectively means that the regex engine "skips" forward
1954 to this position on failure and tries to match again, (assuming that
1955 there is sufficient room to match).
1956
1957 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1958 C<(*MARK:NAME)> was encountered while matching, then it is that position
1959 which is used as the "skip point". If no C<(*MARK)> of that name was
1960 encountered, then the C<(*SKIP)> operator has no effect. When used
1961 without a name the "skip point" is where the match point was when
1962 executing the (*SKIP) pattern.
1963
1964 Compare the following to the examples in C<(*PRUNE)>; note the string
1965 is twice as long:
1966
1967  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1968  print "Count=$count\n";
1969
1970 outputs
1971
1972     aaab
1973     aaab
1974     Count=2
1975
1976 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1977 executed, the next starting point will be where the cursor was when the
1978 C<(*SKIP)> was executed.
1979
1980 =item C<(*MARK:NAME)> C<(*:NAME)>
1981 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1982
1983 This zero-width pattern can be used to mark the point reached in a string
1984 when a certain part of the pattern has been successfully matched. This
1985 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1986 forward to that point if backtracked into on failure. Any number of
1987 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1988
1989 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1990 can be used to "label" a pattern branch, so that after matching, the
1991 program can determine which branches of the pattern were involved in the
1992 match.
1993
1994 When a match is successful, the C<$REGMARK> variable will be set to the
1995 name of the most recently executed C<(*MARK:NAME)> that was involved
1996 in the match.
1997
1998 This can be used to determine which branch of a pattern was matched
1999 without using a separate capture group for each branch, which in turn
2000 can result in a performance improvement, as perl cannot optimize
2001 C</(?:(x)|(y)|(z))/> as efficiently as something like
2002 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
2003
2004 When a match has failed, and unless another verb has been involved in
2005 failing the match and has provided its own name to use, the C<$REGERROR>
2006 variable will be set to the name of the most recently executed
2007 C<(*MARK:NAME)>.
2008
2009 See L</(*SKIP)> for more details.
2010
2011 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
2012
2013 =item C<(*THEN)> C<(*THEN:NAME)>
2014
2015 This is similar to the "cut group" operator C<::> from Perl 6.  Like
2016 C<(*PRUNE)>, this verb always matches, and when backtracked into on
2017 failure, it causes the regex engine to try the next alternation in the
2018 innermost enclosing group (capturing or otherwise) that has alternations.
2019 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
2020 count as an alternation, as far as C<(*THEN)> is concerned.
2021
2022 Its name comes from the observation that this operation combined with the
2023 alternation operator (C<|>) can be used to create what is essentially a
2024 pattern-based if/then/else block:
2025
2026   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
2027
2028 Note that if this operator is used and NOT inside of an alternation then
2029 it acts exactly like the C<(*PRUNE)> operator.
2030
2031   / A (*PRUNE) B /
2032
2033 is the same as
2034
2035   / A (*THEN) B /
2036
2037 but
2038
2039   / ( A (*THEN) B | C ) /
2040
2041 is not the same as
2042
2043   / ( A (*PRUNE) B | C ) /
2044
2045 as after matching the A but failing on the B the C<(*THEN)> verb will
2046 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
2047
2048 =back
2049
2050 =item Verbs without an argument
2051
2052 =over 4
2053
2054 =item C<(*COMMIT)>
2055 X<(*COMMIT)>
2056
2057 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
2058 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
2059 into on failure it causes the match to fail outright. No further attempts
2060 to find a valid match by advancing the start pointer will occur again.
2061 For example,
2062
2063  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
2064  print "Count=$count\n";
2065
2066 outputs
2067
2068     aaab
2069     Count=1
2070
2071 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
2072 does not match, the regex engine will not try any further matching on the
2073 rest of the string.
2074
2075 =item C<(*FAIL)> C<(*F)>
2076 X<(*FAIL)> X<(*F)>
2077
2078 This pattern matches nothing and always fails. It can be used to force the
2079 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
2080 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
2081
2082 It is probably useful only when combined with C<(?{})> or C<(??{})>.
2083
2084 =item C<(*ACCEPT)>
2085 X<(*ACCEPT)>
2086
2087 This pattern matches nothing and causes the end of successful matching at
2088 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
2089 whether there is actually more to match in the string. When inside of a
2090 nested pattern, such as recursion, or in a subpattern dynamically generated
2091 via C<(??{})>, only the innermost pattern is ended immediately.
2092
2093 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
2094 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
2095 For instance:
2096
2097   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
2098
2099 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
2100 be set. If another branch in the inner parentheses was matched, such as in the
2101 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
2102
2103 =back
2104
2105 =back
2106
2107 =head2 Backtracking
2108 X<backtrack> X<backtracking>
2109
2110 NOTE: This section presents an abstract approximation of regular
2111 expression behavior.  For a more rigorous (and complicated) view of
2112 the rules involved in selecting a match among possible alternatives,
2113 see L<Combining RE Pieces>.
2114
2115 A fundamental feature of regular expression matching involves the
2116 notion called I<backtracking>, which is currently used (when needed)
2117 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
2118 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
2119 internally, but the general principle outlined here is valid.
2120
2121 For a regular expression to match, the I<entire> regular expression must
2122 match, not just part of it.  So if the beginning of a pattern containing a
2123 quantifier succeeds in a way that causes later parts in the pattern to
2124 fail, the matching engine backs up and recalculates the beginning
2125 part--that's why it's called backtracking.
2126
2127 Here is an example of backtracking:  Let's say you want to find the
2128 word following "foo" in the string "Food is on the foo table.":
2129
2130     $_ = "Food is on the foo table.";
2131     if ( /\b(foo)\s+(\w+)/i ) {
2132         print "$2 follows $1.\n";
2133     }
2134
2135 When the match runs, the first part of the regular expression (C<\b(foo)>)
2136 finds a possible match right at the beginning of the string, and loads up
2137 $1 with "Foo".  However, as soon as the matching engine sees that there's
2138 no whitespace following the "Foo" that it had saved in $1, it realizes its
2139 mistake and starts over again one character after where it had the
2140 tentative match.  This time it goes all the way until the next occurrence
2141 of "foo". The complete regular expression matches this time, and you get
2142 the expected output of "table follows foo."
2143
2144 Sometimes minimal matching can help a lot.  Imagine you'd like to match
2145 everything between "foo" and "bar".  Initially, you write something
2146 like this:
2147
2148     $_ =  "The food is under the bar in the barn.";
2149     if ( /foo(.*)bar/ ) {
2150         print "got <$1>\n";
2151     }
2152
2153 Which perhaps unexpectedly yields:
2154
2155   got <d is under the bar in the >
2156
2157 That's because C<.*> was greedy, so you get everything between the
2158 I<first> "foo" and the I<last> "bar".  Here it's more effective
2159 to use minimal matching to make sure you get the text between a "foo"
2160 and the first "bar" thereafter.
2161
2162     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2163   got <d is under the >
2164
2165 Here's another example. Let's say you'd like to match a number at the end
2166 of a string, and you also want to keep the preceding part of the match.
2167 So you write this:
2168
2169     $_ = "I have 2 numbers: 53147";
2170     if ( /(.*)(\d*)/ ) {                                # Wrong!
2171         print "Beginning is <$1>, number is <$2>.\n";
2172     }
2173
2174 That won't work at all, because C<.*> was greedy and gobbled up the
2175 whole string. As C<\d*> can match on an empty string the complete
2176 regular expression matched successfully.
2177
2178     Beginning is <I have 2 numbers: 53147>, number is <>.
2179
2180 Here are some variants, most of which don't work:
2181
2182     $_ = "I have 2 numbers: 53147";
2183     @pats = qw{
2184         (.*)(\d*)
2185         (.*)(\d+)
2186         (.*?)(\d*)
2187         (.*?)(\d+)
2188         (.*)(\d+)$
2189         (.*?)(\d+)$
2190         (.*)\b(\d+)$
2191         (.*\D)(\d+)$
2192     };
2193
2194     for $pat (@pats) {
2195         printf "%-12s ", $pat;
2196         if ( /$pat/ ) {
2197             print "<$1> <$2>\n";
2198         } else {
2199             print "FAIL\n";
2200         }
2201     }
2202
2203 That will print out:
2204
2205     (.*)(\d*)    <I have 2 numbers: 53147> <>
2206     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2207     (.*?)(\d*)   <> <>
2208     (.*?)(\d+)   <I have > <2>
2209     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2210     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2211     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2212     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2213
2214 As you see, this can be a bit tricky.  It's important to realize that a
2215 regular expression is merely a set of assertions that gives a definition
2216 of success.  There may be 0, 1, or several different ways that the
2217 definition might succeed against a particular string.  And if there are
2218 multiple ways it might succeed, you need to understand backtracking to
2219 know which variety of success you will achieve.
2220
2221 When using look-ahead assertions and negations, this can all get even
2222 trickier.  Imagine you'd like to find a sequence of non-digits not
2223 followed by "123".  You might try to write that as
2224
2225     $_ = "ABC123";
2226     if ( /^\D*(?!123)/ ) {                # Wrong!
2227         print "Yup, no 123 in $_\n";
2228     }
2229
2230 But that isn't going to match; at least, not the way you're hoping.  It
2231 claims that there is no 123 in the string.  Here's a clearer picture of
2232 why that pattern matches, contrary to popular expectations:
2233
2234     $x = 'ABC123';
2235     $y = 'ABC445';
2236
2237     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2238     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2239
2240     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2241     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2242
2243 This prints
2244
2245     2: got ABC
2246     3: got AB
2247     4: got ABC
2248
2249 You might have expected test 3 to fail because it seems to a more
2250 general purpose version of test 1.  The important difference between
2251 them is that test 3 contains a quantifier (C<\D*>) and so can use
2252 backtracking, whereas test 1 will not.  What's happening is
2253 that you've asked "Is it true that at the start of $x, following 0 or more
2254 non-digits, you have something that's not 123?"  If the pattern matcher had
2255 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2256 fail.
2257
2258 The search engine will initially match C<\D*> with "ABC".  Then it will
2259 try to match C<(?!123)> with "123", which fails.  But because
2260 a quantifier (C<\D*>) has been used in the regular expression, the
2261 search engine can backtrack and retry the match differently
2262 in the hope of matching the complete regular expression.
2263
2264 The pattern really, I<really> wants to succeed, so it uses the
2265 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2266 time.  Now there's indeed something following "AB" that is not
2267 "123".  It's "C123", which suffices.
2268
2269 We can deal with this by using both an assertion and a negation.
2270 We'll say that the first part in $1 must be followed both by a digit
2271 and by something that's not "123".  Remember that the look-aheads
2272 are zero-width expressions--they only look, but don't consume any
2273 of the string in their match.  So rewriting this way produces what
2274 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2275
2276     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2277     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2278
2279     6: got ABC
2280
2281 In other words, the two zero-width assertions next to each other work as though
2282 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2283 matches only if you're at the beginning of the line AND the end of the
2284 line simultaneously.  The deeper underlying truth is that juxtaposition in
2285 regular expressions always means AND, except when you write an explicit OR
2286 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2287 although the attempted matches are made at different positions because "a"
2288 is not a zero-width assertion, but a one-width assertion.
2289
2290 B<WARNING>: Particularly complicated regular expressions can take
2291 exponential time to solve because of the immense number of possible
2292 ways they can use backtracking to try for a match.  For example, without
2293 internal optimizations done by the regular expression engine, this will
2294 take a painfully long time to run:
2295
2296     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2297
2298 And if you used C<*>'s in the internal groups instead of limiting them
2299 to 0 through 5 matches, then it would take forever--or until you ran
2300 out of stack space.  Moreover, these internal optimizations are not
2301 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2302 on the external group, no current optimization is applicable, and the
2303 match takes a long time to finish.
2304
2305 A powerful tool for optimizing such beasts is what is known as an
2306 "independent group",
2307 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2308 zero-length look-ahead/look-behind assertions will not backtrack to make
2309 the tail match, since they are in "logical" context: only
2310 whether they match is considered relevant.  For an example
2311 where side-effects of look-ahead I<might> have influenced the
2312 following match, see L</C<< (?>pattern) >>>.
2313
2314 =head2 Version 8 Regular Expressions
2315 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2316
2317 In case you're not familiar with the "regular" Version 8 regex
2318 routines, here are the pattern-matching rules not described above.
2319
2320 Any single character matches itself, unless it is a I<metacharacter>
2321 with a special meaning described here or above.  You can cause
2322 characters that normally function as metacharacters to be interpreted
2323 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2324 character; "\\" matches a "\"). This escape mechanism is also required
2325 for the character used as the pattern delimiter.
2326
2327 A series of characters matches that series of characters in the target
2328 string, so the pattern C<blurfl> would match "blurfl" in the target
2329 string.
2330
2331 You can specify a character class, by enclosing a list of characters
2332 in C<[]>, which will match any character from the list.  If the
2333 first character after the "[" is "^", the class matches any character not
2334 in the list.  Within a list, the "-" character specifies a
2335 range, so that C<a-z> represents all characters between "a" and "z",
2336 inclusive.  If you want either "-" or "]" itself to be a member of a
2337 class, put it at the start of the list (possibly after a "^"), or
2338 escape it with a backslash.  "-" is also taken literally when it is
2339 at the end of the list, just before the closing "]".  (The
2340 following all specify the same class of three characters: C<[-az]>,
2341 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2342 specifies a class containing twenty-six characters, even on EBCDIC-based
2343 character sets.)  Also, if you try to use the character
2344 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2345 a range, the "-" is understood literally.
2346
2347 Note also that the whole range idea is rather unportable between
2348 character sets, except for four situations that Perl handles specially.
2349 Any subset of the ranges C<[A-Z]>, C<[a-z]>, and C<[0-9]> are guaranteed
2350 to match the expected subset of ASCII characters, no matter what
2351 character set the platform is running.  The fourth portable way to
2352 specify ranges is to use the C<\N{...}> syntax to specify either end
2353 point of the range.  For example, C<[\N{U+04}-\N{U+07}]> means to match
2354 the Unicode code points C<\N{U+04}>, C<\N{U+05}>, C<\N{U+06}>, and
2355 C<\N{U+07}>, whatever their native values may be on the platform.  Under
2356 L<use re 'strict'|re/'strict' mode> or within a L</C<(?[ ])>>, a warning
2357 is raised, if enabled, and the other end point of a range which has a
2358 C<\N{...}> endpoint is not portably specified.  For example,
2359
2360  [\N{U+00}-\x06]    # Warning under "use re 'strict'".
2361
2362 It is hard to understand without digging what exactly matches ranges
2363 other than subsets of C<[A-Z]>, C<[a-z]>, and C<[0-9]>.  A sound
2364 principle is to use only ranges that begin from and end at either
2365 alphabetics of equal case ([a-e], [A-E]), or digits ([0-9]).  Anything
2366 else is unsafe or unclear.  If in doubt, spell out the range in full.
2367
2368 Characters may be specified using a metacharacter syntax much like that
2369 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2370 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2371 of three octal digits, matches the character whose coded character set value
2372 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2373 matches the character whose ordinal is I<nn>. The expression \cI<x>
2374 matches the character control-I<x>.  Finally, the "." metacharacter
2375 matches any character except "\n" (unless you use C</s>).
2376
2377 You can specify a series of alternatives for a pattern using "|" to
2378 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2379 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2380 first alternative includes everything from the last pattern delimiter
2381 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2382 the last alternative contains everything from the last "|" to the next
2383 closing pattern delimiter.  That's why it's common practice to include
2384 alternatives in parentheses: to minimize confusion about where they
2385 start and end.
2386
2387 Alternatives are tried from left to right, so the first
2388 alternative found for which the entire expression matches, is the one that
2389 is chosen. This means that alternatives are not necessarily greedy. For
2390 example: when matching C<foo|foot> against "barefoot", only the "foo"
2391 part will match, as that is the first alternative tried, and it successfully
2392 matches the target string. (This might not seem important, but it is
2393 important when you are capturing matched text using parentheses.)
2394
2395 Also remember that "|" is interpreted as a literal within square brackets,
2396 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2397
2398 Within a pattern, you may designate subpatterns for later reference
2399 by enclosing them in parentheses, and you may refer back to the
2400 I<n>th subpattern later in the pattern using the metacharacter
2401 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2402 of their opening parenthesis.  A backreference matches whatever
2403 actually matched the subpattern in the string being examined, not
2404 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2405 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2406 1 matched "0x", even though the rule C<0|0x> could potentially match
2407 the leading 0 in the second number.
2408
2409 =head2 Warning on \1 Instead of $1
2410
2411 Some people get too used to writing things like:
2412
2413     $pattern =~ s/(\W)/\\\1/g;
2414
2415 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2416 shocking the
2417 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2418 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2419 the usual double-quoted string means a control-A.  The customary Unix
2420 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2421 of doing that, you get yourself into trouble if you then add an C</e>
2422 modifier.
2423
2424     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2425
2426 Or if you try to do
2427
2428     s/(\d+)/\1000/;
2429
2430 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2431 C<${1}000>.  The operation of interpolation should not be confused
2432 with the operation of matching a backreference.  Certainly they mean two
2433 different things on the I<left> side of the C<s///>.
2434
2435 =head2 Repeated Patterns Matching a Zero-length Substring
2436
2437 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2438
2439 Regular expressions provide a terse and powerful programming language.  As
2440 with most other power tools, power comes together with the ability
2441 to wreak havoc.
2442
2443 A common abuse of this power stems from the ability to make infinite
2444 loops using regular expressions, with something as innocuous as:
2445
2446     'foo' =~ m{ ( o? )* }x;
2447
2448 The C<o?> matches at the beginning of C<'foo'>, and since the position
2449 in the string is not moved by the match, C<o?> would match again and again
2450 because of the C<*> quantifier.  Another common way to create a similar cycle
2451 is with the looping modifier C<//g>:
2452
2453     @matches = ( 'foo' =~ m{ o? }xg );
2454
2455 or
2456
2457     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2458
2459 or the loop implied by split().
2460
2461 However, long experience has shown that many programming tasks may
2462 be significantly simplified by using repeated subexpressions that
2463 may match zero-length substrings.  Here's a simple example being:
2464
2465     @chars = split //, $string;           # // is not magic in split
2466     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2467
2468 Thus Perl allows such constructs, by I<forcefully breaking
2469 the infinite loop>.  The rules for this are different for lower-level
2470 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2471 ones like the C</g> modifier or split() operator.
2472
2473 The lower-level loops are I<interrupted> (that is, the loop is
2474 broken) when Perl detects that a repeated expression matched a
2475 zero-length substring.   Thus
2476
2477    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2478
2479 is made equivalent to
2480
2481    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2482
2483 For example, this program
2484
2485    #!perl -l
2486    "aaaaab" =~ /
2487      (?:
2488         a                 # non-zero
2489         |                 # or
2490        (?{print "hello"}) # print hello whenever this
2491                           #    branch is tried
2492        (?=(b))            # zero-width assertion
2493      )*  # any number of times
2494     /x;
2495    print $&;
2496    print $1;
2497
2498 prints
2499
2500    hello
2501    aaaaa
2502    b
2503
2504 Notice that "hello" is only printed once, as when Perl sees that the sixth
2505 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2506 the C<*>.
2507
2508 The higher-level loops preserve an additional state between iterations:
2509 whether the last match was zero-length.  To break the loop, the following
2510 match after a zero-length match is prohibited to have a length of zero.
2511 This prohibition interacts with backtracking (see L<"Backtracking">),
2512 and so the I<second best> match is chosen if the I<best> match is of
2513 zero length.
2514
2515 For example:
2516
2517     $_ = 'bar';
2518     s/\w??/<$&>/g;
2519
2520 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2521 match given by non-greedy C<??> is the zero-length match, and the I<second
2522 best> match is what is matched by C<\w>.  Thus zero-length matches
2523 alternate with one-character-long matches.
2524
2525 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2526 position one notch further in the string.
2527
2528 The additional state of being I<matched with zero-length> is associated with
2529 the matched string, and is reset by each assignment to pos().
2530 Zero-length matches at the end of the previous match are ignored
2531 during C<split>.
2532
2533 =head2 Combining RE Pieces
2534
2535 Each of the elementary pieces of regular expressions which were described
2536 before (such as C<ab> or C<\Z>) could match at most one substring
2537 at the given position of the input string.  However, in a typical regular
2538 expression these elementary pieces are combined into more complicated
2539 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2540 (in these examples C<S> and C<T> are regular subexpressions).
2541
2542 Such combinations can include alternatives, leading to a problem of choice:
2543 if we match a regular expression C<a|ab> against C<"abc">, will it match
2544 substring C<"a"> or C<"ab">?  One way to describe which substring is
2545 actually matched is the concept of backtracking (see L<"Backtracking">).
2546 However, this description is too low-level and makes you think
2547 in terms of a particular implementation.
2548
2549 Another description starts with notions of "better"/"worse".  All the
2550 substrings which may be matched by the given regular expression can be
2551 sorted from the "best" match to the "worst" match, and it is the "best"
2552 match which is chosen.  This substitutes the question of "what is chosen?"
2553 by the question of "which matches are better, and which are worse?".
2554
2555 Again, for elementary pieces there is no such question, since at most
2556 one match at a given position is possible.  This section describes the
2557 notion of better/worse for combining operators.  In the description
2558 below C<S> and C<T> are regular subexpressions.
2559
2560 =over 4
2561
2562 =item C<ST>
2563
2564 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2565 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2566 which can be matched by C<T>.
2567
2568 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2569 match than C<A'B'>.
2570
2571 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2572 C<B> is a better match for C<T> than C<B'>.
2573
2574 =item C<S|T>
2575
2576 When C<S> can match, it is a better match than when only C<T> can match.
2577
2578 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2579 two matches for C<T>.
2580
2581 =item C<S{REPEAT_COUNT}>
2582
2583 Matches as C<SSS...S> (repeated as many times as necessary).
2584
2585 =item C<S{min,max}>
2586
2587 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2588
2589 =item C<S{min,max}?>
2590
2591 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2592
2593 =item C<S?>, C<S*>, C<S+>
2594
2595 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2596
2597 =item C<S??>, C<S*?>, C<S+?>
2598
2599 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2600
2601 =item C<< (?>S) >>
2602
2603 Matches the best match for C<S> and only that.
2604
2605 =item C<(?=S)>, C<(?<=S)>
2606
2607 Only the best match for C<S> is considered.  (This is important only if
2608 C<S> has capturing parentheses, and backreferences are used somewhere
2609 else in the whole regular expression.)
2610
2611 =item C<(?!S)>, C<(?<!S)>
2612
2613 For this grouping operator there is no need to describe the ordering, since
2614 only whether or not C<S> can match is important.
2615
2616 =item C<(??{ EXPR })>, C<(?I<PARNO>)>
2617
2618 The ordering is the same as for the regular expression which is
2619 the result of EXPR, or the pattern contained by capture group I<PARNO>.
2620
2621 =item C<(?(condition)yes-pattern|no-pattern)>
2622
2623 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2624 already determined.  The ordering of the matches is the same as for the
2625 chosen subexpression.
2626
2627 =back
2628
2629 The above recipes describe the ordering of matches I<at a given position>.
2630 One more rule is needed to understand how a match is determined for the
2631 whole regular expression: a match at an earlier position is always better
2632 than a match at a later position.
2633
2634 =head2 Creating Custom RE Engines
2635
2636 As of Perl 5.10.0, one can create custom regular expression engines.  This
2637 is not for the faint of heart, as they have to plug in at the C level.  See
2638 L<perlreapi> for more details.
2639
2640 As an alternative, overloaded constants (see L<overload>) provide a simple
2641 way to extend the functionality of the RE engine, by substituting one
2642 pattern for another.
2643
2644 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2645 matches at a boundary between whitespace characters and non-whitespace
2646 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2647 at these positions, so we want to have each C<\Y|> in the place of the
2648 more complicated version.  We can create a module C<customre> to do
2649 this:
2650
2651     package customre;
2652     use overload;
2653
2654     sub import {
2655       shift;
2656       die "No argument to customre::import allowed" if @_;
2657       overload::constant 'qr' => \&convert;
2658     }
2659
2660     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2661
2662     # We must also take care of not escaping the legitimate \\Y|
2663     # sequence, hence the presence of '\\' in the conversion rules.
2664     my %rules = ( '\\' => '\\\\',
2665                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2666     sub convert {
2667       my $re = shift;
2668       $re =~ s{
2669                 \\ ( \\ | Y . )
2670               }
2671               { $rules{$1} or invalid($re,$1) }sgex;
2672       return $re;
2673     }
2674
2675 Now C<use customre> enables the new escape in constant regular
2676 expressions, i.e., those without any runtime variable interpolations.
2677 As documented in L<overload>, this conversion will work only over
2678 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2679 part of this regular expression needs to be converted explicitly
2680 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2681
2682     use customre;
2683     $re = <>;
2684     chomp $re;
2685     $re = customre::convert $re;
2686     /\Y|$re\Y|/;
2687
2688 =head2 Embedded Code Execution Frequency
2689
2690 The exact rules for how often (??{}) and (?{}) are executed in a pattern
2691 are unspecified.  In the case of a successful match you can assume that
2692 they DWIM and will be executed in left to right order the appropriate
2693 number of times in the accepting path of the pattern as would any other
2694 meta-pattern.  How non-accepting pathways and match failures affect the
2695 number of times a pattern is executed is specifically unspecified and
2696 may vary depending on what optimizations can be applied to the pattern
2697 and is likely to change from version to version.
2698
2699 For instance in
2700
2701   "aaabcdeeeee"=~/a(?{print "a"})b(?{print "b"})cde/;
2702
2703 the exact number of times "a" or "b" are printed out is unspecified for
2704 failure, but you may assume they will be printed at least once during
2705 a successful match, additionally you may assume that if "b" is printed,
2706 it will be preceded by at least one "a".
2707
2708 In the case of branching constructs like the following:
2709
2710   /a(b|(?{ print "a" }))c(?{ print "c" })/;
2711
2712 you can assume that the input "ac" will output "ac", and that "abc"
2713 will output only "c".
2714
2715 When embedded code is quantified, successful matches will call the
2716 code once for each matched iteration of the quantifier.  For
2717 example:
2718
2719   "good" =~ /g(?:o(?{print "o"}))*d/;
2720
2721 will output "o" twice.
2722
2723 =head2 PCRE/Python Support
2724
2725 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2726 to the regex syntax. While Perl programmers are encouraged to use the
2727 Perl-specific syntax, the following are also accepted:
2728
2729 =over 4
2730
2731 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2732
2733 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2734
2735 =item C<< (?P=NAME) >>
2736
2737 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2738
2739 =item C<< (?P>NAME) >>
2740
2741 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2742
2743 =back
2744
2745 =head1 BUGS
2746
2747 Many regular expression constructs don't work on EBCDIC platforms.
2748
2749 There are a number of issues with regard to case-insensitive matching
2750 in Unicode rules.  See C<i> under L</Modifiers> above.
2751
2752 This document varies from difficult to understand to completely
2753 and utterly opaque.  The wandering prose riddled with jargon is
2754 hard to fathom in several places.
2755
2756 This document needs a rewrite that separates the tutorial content
2757 from the reference content.
2758
2759 =head1 SEE ALSO
2760
2761 L<perlrequick>.
2762
2763 L<perlretut>.
2764
2765 L<perlop/"Regexp Quote-Like Operators">.
2766
2767 L<perlop/"Gory details of parsing quoted constructs">.
2768
2769 L<perlfaq6>.
2770
2771 L<perlfunc/pos>.
2772
2773 L<perllocale>.
2774
2775 L<perlebcdic>.
2776
2777 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2778 by O'Reilly and Associates.