Exporter-5.72 is now on the CPAN
[perl.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  For a more in-depth discussion
28 on identifiers, see L<Identifier parsing>.  It's possible to
29 substitute for a simple identifier, an expression that produces a reference
30 to the value at runtime.   This is described in more detail below
31 and in L<perlref>.
32 X<identifier>
33
34 Perl also has its own built-in variables whose names don't follow
35 these rules.  They have strange names so they don't accidentally
36 collide with one of your normal variables.  Strings that match
37 parenthesized parts of a regular expression are saved under names
38 containing only digits after the C<$> (see L<perlop> and L<perlre>).
39 In addition, several special variables that provide windows into
40 the inner working of Perl have names containing punctuation characters
41 and control characters.  These are documented in L<perlvar>.
42 X<variable, built-in>
43
44 Scalar values are always named with '$', even when referring to a
45 scalar that is part of an array or a hash.  The '$' symbol works
46 semantically like the English word "the" in that it indicates a
47 single value is expected.
48 X<scalar>
49
50     $days               # the simple scalar value "days"
51     $days[28]           # the 29th element of array @days
52     $days{'Feb'}        # the 'Feb' value from hash %days
53     $#days              # the last index of array @days
54
55 Entire arrays (and slices of arrays and hashes) are denoted by '@',
56 which works much as the word "these" or "those" does in English,
57 in that it indicates multiple values are expected.
58 X<array>
59
60     @days               # ($days[0], $days[1],... $days[n])
61     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
62     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
63
64 Entire hashes are denoted by '%':
65 X<hash>
66
67     %days               # (key1, val1, key2, val2 ...)
68
69 In addition, subroutines are named with an initial '&', though this
70 is optional when unambiguous, just as the word "do" is often redundant
71 in English.  Symbol table entries can be named with an initial '*',
72 but you don't really care about that yet (if ever :-).
73
74 Every variable type has its own namespace, as do several
75 non-variable identifiers.  This means that you can, without fear
76 of conflict, use the same name for a scalar variable, an array, or
77 a hash--or, for that matter, for a filehandle, a directory handle, a
78 subroutine name, a format name, or a label.  This means that $foo
79 and @foo are two different variables.  It also means that C<$foo[1]>
80 is a part of @foo, not a part of $foo.  This may seem a bit weird,
81 but that's okay, because it is weird.
82 X<namespace>
83
84 Because variable references always start with '$', '@', or '%', the
85 "reserved" words aren't in fact reserved with respect to variable
86 names.  They I<are> reserved with respect to labels and filehandles,
87 however, which don't have an initial special character.  You can't
88 have a filehandle named "log", for instance.  Hint: you could say
89 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
90 uppercase filehandles also improves readability and protects you
91 from conflict with future reserved words.  Case I<is> significant--"FOO",
92 "Foo", and "foo" are all different names.  Names that start with a
93 letter or underscore may also contain digits and underscores.
94 X<identifier, case sensitivity>
95 X<case>
96
97 It is possible to replace such an alphanumeric name with an expression
98 that returns a reference to the appropriate type.  For a description
99 of this, see L<perlref>.
100
101 Names that start with a digit may contain only more digits.  Names
102 that do not start with a letter, underscore, digit or a caret (i.e.
103 a control character) are limited to one character, e.g.,  C<$%> or
104 C<$$>.  (Most of these one character names have a predefined
105 significance to Perl.  For instance, C<$$> is the current process
106 id.)
107
108 =head2 Identifier parsing
109 X<identifiers>
110
111 Up until Perl 5.18, the actual rules of what a valid identifier
112 was were a bit fuzzy.  However, in general, anything defined here should
113 work on previous versions of Perl, while the opposite -- edge cases
114 that work in previous versions, but aren't defined here -- probably
115 won't work on newer versions.
116 As an important side note, please note that the following only applies
117 to bareword identifiers as found in Perl source code, not identifiers
118 introduced through symbolic references, which have much fewer
119 restrictions.
120 If working under the effect of the C<use utf8;> pragma, the following
121 rules apply:
122
123     / (?[ ( \p{Word} & \p{XID_Start} ) + [_] ])
124       (?[ ( \p{Word} & \p{XID_Continue} ) ]) *    /x
125
126 That is, a "start" character followed by any number of "continue"
127 characters.  Perl requires every character in an identifier to also
128 match C<\w> (this prevents some problematic cases); and Perl
129 additionally accepts identfier names beginning with an underscore.
130
131 If not under C<use utf8>, the source is treated as ASCII + 128 extra
132 controls, and identifiers should match
133
134     / (?aa) (?!\d) \w+ /x
135
136 That is, any word character in the ASCII range, as long as the first
137 character is not a digit.
138
139 There are two package separators in Perl: A double colon (C<::>) and a single
140 quote (C<'>).  Normal identifiers can start or end with a double colon, and
141 can contain several parts delimited by double colons.
142 Single quotes have similar rules, but with the exception that they are not
143 legal at the end of an identifier: That is, C<$'foo> and C<$foo'bar> are
144 legal, but C<$foo'bar'> is not.
145
146 Additionally, if the identifier is preceded by a sigil --
147 that is, if the identifier is part of a variable name -- it
148 may optionally be enclosed in braces.
149
150 While you can mix double colons with singles quotes, the quotes must come
151 after the colons: C<$::::'foo> and C<$foo::'bar> are legal, but C<$::'::foo>
152 and C<$foo'::bar> are not.
153
154 Put together, a grammar to match a basic identifier becomes
155
156  /
157   (?(DEFINE)
158       (?<variable>
159           (?&sigil)
160           (?:
161                   (?&normal_identifier)
162               |   \{ \s* (?&normal_identifier) \s* \}
163           )
164       )
165       (?<normal_identifier>
166           (?: :: )* '?
167            (?&basic_identifier)
168            (?: (?= (?: :: )+ '? | (?: :: )* ' ) (?&normal_identifier) )?
169           (?: :: )*
170       )
171       (?<basic_identifier>
172         # is use utf8 on?
173           (?(?{ (caller(0))[8] & $utf8::hint_bits })
174               (?&Perl_XIDS) (?&Perl_XIDC)*
175             | (?aa) (?!\d) \w+
176           )
177       )
178       (?<sigil> [&*\$\@\%])
179       (?<Perl_XIDS> (?[ ( \p{Word} & \p{XID_Start} ) + [_] ]) )
180       (?<Perl_XIDC> (?[ \p{Word} & \p{XID_Continue} ]) )
181   )
182  /x
183
184 Meanwhile, special identifiers don't follow the above rules; For the most
185 part, all of the identifiers in this category have a special meaning given
186 by Perl.  Because they have special parsing rules, these generally can't be
187 fully-qualified.  They come in four forms:
188
189 =over
190
191 =item *
192
193 A sigil, followed solely by digits matching C<\p{POSIX_Digit}>, like
194 C<$0>, C<$1>, or C<$10000>.
195
196 =item *
197
198 A sigil, followed by either a caret and a single POSIX uppercase letter,
199 like C<$^V> or C<$^W>, or a sigil followed by a literal non-space,
200 non-C<NUL> control character matching the C<\p{POSIX_Cntrl}> property.
201 Due to a historical oddity, if not running under C<use utf8>, the 128
202 characters in the C<[0x80-0xff]> range are considered to be controls,
203 and may also be used in length-one variables.  However, the use of
204 non-graphical characters is deprecated as of v5.22, and support for them
205 will be removed in a future version of perl.  ASCII space characters and
206 C<NUL> already aren't allowed, so this means that a single-character
207 variable name with that name being any other C0 control C<[0x01-0x1F]>,
208 or C<DEL> will generate a deprecated warning.  Already, under C<"use
209 utf8">, non-ASCII characters must match C<Perl_XIDS>.  As of v5.22, when
210 not under C<"use utf8"> C1 controls C<[0x80-0x9F]>, NO BREAK SPACE, and
211 SOFT HYPHEN (C<SHY>)) generate a deprecated warning.
212
213 =item *
214
215 Similar to the above, a sigil, followed by bareword text in brackets,
216 where the first character is either a caret followed by an uppercase
217 letter, like C<${^GLOBAL_PHASE}> or a non-C<NUL>, non-space literal
218 control like C<${\7LOBAL_PHASE}>.  Like the above, when not under
219 C<"use utf8">, the characters in C<[0x80-0xFF]> are considered controls, but as
220 of v5.22, the use of any that are non-graphical are deprecated, and as
221 of v5.20 the use of any ASCII-range literal control is deprecated.
222 Support for these will be removed in a future version of perl.
223
224 =item *
225
226 A sigil followed by a single character matching the C<\p{POSIX_Punct}>
227 property, like C<$!> or C<%+>, except the character C<"{"> doesn't work.
228
229 =back
230
231 Note that as of Perl 5.20, literal control characters in variable names
232 are deprecated; and as of Perl 5.22, any other non-graphic characters
233 are also deprecated.
234
235 =head2 Context
236 X<context> X<scalar context> X<list context>
237
238 The interpretation of operations and values in Perl sometimes depends
239 on the requirements of the context around the operation or value.
240 There are two major contexts: list and scalar.  Certain operations
241 return list values in contexts wanting a list, and scalar values
242 otherwise.  If this is true of an operation it will be mentioned in
243 the documentation for that operation.  In other words, Perl overloads
244 certain operations based on whether the expected return value is
245 singular or plural.  Some words in English work this way, like "fish"
246 and "sheep".
247
248 In a reciprocal fashion, an operation provides either a scalar or a
249 list context to each of its arguments.  For example, if you say
250
251     int( <STDIN> )
252
253 the integer operation provides scalar context for the <>
254 operator, which responds by reading one line from STDIN and passing it
255 back to the integer operation, which will then find the integer value
256 of that line and return that.  If, on the other hand, you say
257
258     sort( <STDIN> )
259
260 then the sort operation provides list context for <>, which
261 will proceed to read every line available up to the end of file, and
262 pass that list of lines back to the sort routine, which will then
263 sort those lines and return them as a list to whatever the context
264 of the sort was.
265
266 Assignment is a little bit special in that it uses its left argument
267 to determine the context for the right argument.  Assignment to a
268 scalar evaluates the right-hand side in scalar context, while
269 assignment to an array or hash evaluates the righthand side in list
270 context.  Assignment to a list (or slice, which is just a list
271 anyway) also evaluates the right-hand side in list context.
272
273 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
274 option, you may see warnings
275 about useless uses of constants or functions in "void context".
276 Void context just means the value has been discarded, such as a
277 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
278 counts as scalar context for functions that care whether or not
279 they're being called in list context.
280
281 User-defined subroutines may choose to care whether they are being
282 called in a void, scalar, or list context.  Most subroutines do not
283 need to bother, though.  That's because both scalars and lists are
284 automatically interpolated into lists.  See L<perlfunc/wantarray>
285 for how you would dynamically discern your function's calling
286 context.
287
288 =head2 Scalar values
289 X<scalar> X<number> X<string> X<reference>
290
291 All data in Perl is a scalar, an array of scalars, or a hash of
292 scalars.  A scalar may contain one single value in any of three
293 different flavors: a number, a string, or a reference.  In general,
294 conversion from one form to another is transparent.  Although a
295 scalar may not directly hold multiple values, it may contain a
296 reference to an array or hash which in turn contains multiple values.
297
298 Scalars aren't necessarily one thing or another.  There's no place
299 to declare a scalar variable to be of type "string", type "number",
300 type "reference", or anything else.  Because of the automatic
301 conversion of scalars, operations that return scalars don't need
302 to care (and in fact, cannot care) whether their caller is looking
303 for a string, a number, or a reference.  Perl is a contextually
304 polymorphic language whose scalars can be strings, numbers, or
305 references (which includes objects).  Although strings and numbers
306 are considered pretty much the same thing for nearly all purposes,
307 references are strongly-typed, uncastable pointers with builtin
308 reference-counting and destructor invocation.
309
310 A scalar value is interpreted as FALSE in the Boolean sense
311 if it is undefined, the null string or the number 0 (or its
312 string equivalent, "0"), and TRUE if it is anything else.  The
313 Boolean context is just a special kind of scalar context where no 
314 conversion to a string or a number is ever performed.
315 X<boolean> X<bool> X<true> X<false> X<truth>
316
317 There are actually two varieties of null strings (sometimes referred
318 to as "empty" strings), a defined one and an undefined one.  The
319 defined version is just a string of length zero, such as C<"">.
320 The undefined version is the value that indicates that there is
321 no real value for something, such as when there was an error, or
322 at end of file, or when you refer to an uninitialized variable or
323 element of an array or hash.  Although in early versions of Perl,
324 an undefined scalar could become defined when first used in a
325 place expecting a defined value, this no longer happens except for
326 rare cases of autovivification as explained in L<perlref>.  You can
327 use the defined() operator to determine whether a scalar value is
328 defined (this has no meaning on arrays or hashes), and the undef()
329 operator to produce an undefined value.
330 X<defined> X<undefined> X<undef> X<null> X<string, null>
331
332 To find out whether a given string is a valid non-zero number, it's
333 sometimes enough to test it against both numeric 0 and also lexical
334 "0" (although this will cause noises if warnings are on).  That's 
335 because strings that aren't numbers count as 0, just as they do in B<awk>:
336
337     if ($str == 0 && $str ne "0")  {
338         warn "That doesn't look like a number";
339     }
340
341 That method may be best because otherwise you won't treat IEEE
342 notations like C<NaN> or C<Infinity> properly.  At other times, you
343 might prefer to determine whether string data can be used numerically
344 by calling the POSIX::strtod() function or by inspecting your string
345 with a regular expression (as documented in L<perlre>).
346
347     warn "has nondigits"        if     /\D/;
348     warn "not a natural number" unless /^\d+$/;             # rejects -3
349     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
350     warn "not an integer"       unless /^[+-]?\d+$/;
351     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
352     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
353     warn "not a C float"
354         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
355
356 The length of an array is a scalar value.  You may find the length
357 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
358 isn't the length of the array; it's the subscript of the last element,
359 which is a different value since there is ordinarily a 0th element.
360 Assigning to C<$#days> actually changes the length of the array.
361 Shortening an array this way destroys intervening values.  Lengthening
362 an array that was previously shortened does not recover values
363 that were in those elements.
364 X<$#> X<array, length>
365
366 You can also gain some minuscule measure of efficiency by pre-extending
367 an array that is going to get big.  You can also extend an array
368 by assigning to an element that is off the end of the array.  You
369 can truncate an array down to nothing by assigning the null list
370 () to it.  The following are equivalent:
371
372     @whatever = ();
373     $#whatever = -1;
374
375 If you evaluate an array in scalar context, it returns the length
376 of the array.  (Note that this is not true of lists, which return
377 the last value, like the C comma operator, nor of built-in functions,
378 which return whatever they feel like returning.)  The following is
379 always true:
380 X<array, length>
381
382     scalar(@whatever) == $#whatever + 1;
383
384 Some programmers choose to use an explicit conversion so as to 
385 leave nothing to doubt:
386
387     $element_count = scalar(@whatever);
388
389 If you evaluate a hash in scalar context, it returns false if the
390 hash is empty.  If there are any key/value pairs, it returns true;
391 more precisely, the value returned is a string consisting of the
392 number of used buckets and the number of allocated buckets, separated
393 by a slash.  This is pretty much useful only to find out whether
394 Perl's internal hashing algorithm is performing poorly on your data
395 set.  For example, you stick 10,000 things in a hash, but evaluating
396 %HASH in scalar context reveals C<"1/16">, which means only one out
397 of sixteen buckets has been touched, and presumably contains all
398 10,000 of your items.  This isn't supposed to happen.  If a tied hash
399 is evaluated in scalar context, the C<SCALAR> method is called (with a
400 fallback to C<FIRSTKEY>).
401 X<hash, scalar context> X<hash, bucket> X<bucket>
402
403 You can preallocate space for a hash by assigning to the keys() function.
404 This rounds up the allocated buckets to the next power of two:
405
406     keys(%users) = 1000;                # allocate 1024 buckets
407
408 =head2 Scalar value constructors
409 X<scalar, literal> X<scalar, constant>
410
411 Numeric literals are specified in any of the following floating point or
412 integer formats:
413
414  12345
415  12345.67
416  .23E-10             # a very small number
417  3.14_15_92          # a very important number
418  4_294_967_296       # underscore for legibility
419  0xff                # hex
420  0xdead_beef         # more hex
421  0377                # octal (only numbers, begins with 0)
422  0b011011            # binary
423  0x1.999ap-4         # hexadecimal floating point (the 'p' is required)
424
425 You are allowed to use underscores (underbars) in numeric literals
426 between digits for legibility (but not multiple underscores in a row:
427 C<23__500> is not legal; C<23_500> is).
428 You could, for example, group binary
429 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
430 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
431 X<number, literal>
432
433 String literals are usually delimited by either single or double
434 quotes.  They work much like quotes in the standard Unix shells:
435 double-quoted string literals are subject to backslash and variable
436 substitution; single-quoted strings are not (except for C<\'> and
437 C<\\>).  The usual C-style backslash rules apply for making
438 characters such as newline, tab, etc., as well as some more exotic
439 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
440 X<string, literal>
441
442 Hexadecimal, octal, or binary, representations in string literals
443 (e.g. '0xff') are not automatically converted to their integer
444 representation.  The hex() and oct() functions make these conversions
445 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
446
447 Hexadecimal floating point can start just like a hexadecimal literal,
448 and it can be followed by an optional fractional hexadecimal part,
449 but it must be followed by C<p>, an optional sign, and a power of two.
450 The format is useful for accurately presenting floating point values,
451 avoiding conversions to or from decimal floating point, and therefore
452 avoiding possible loss in precision.  Notice that while most current
453 platforms use the 64-bit IEEE 754 floating point, not all do.  Another
454 potential source of (low-order) differences are the floating point
455 rounding modes, which can differ between CPUs, operating systems,
456 and compilers, and which Perl doesn't control.
457
458 You can also embed newlines directly in your strings, i.e., they can end
459 on a different line than they begin.  This is nice, but if you forget
460 your trailing quote, the error will not be reported until Perl finds
461 another line containing the quote character, which may be much further
462 on in the script.  Variable substitution inside strings is limited to
463 scalar variables, arrays, and array or hash slices.  (In other words,
464 names beginning with $ or @, followed by an optional bracketed
465 expression as a subscript.)  The following code segment prints out "The
466 price is $Z<>100."
467 X<interpolation>
468
469     $Price = '$100';    # not interpolated
470     print "The price is $Price.\n";     # interpolated
471
472 There is no double interpolation in Perl, so the C<$100> is left as is.
473
474 By default floating point numbers substituted inside strings use the
475 dot (".")  as the decimal separator.  If C<use locale> is in effect,
476 and POSIX::setlocale() has been called, the character used for the
477 decimal separator is affected by the LC_NUMERIC locale.
478 See L<perllocale> and L<POSIX>.
479
480 As in some shells, you can enclose the variable name in braces to
481 disambiguate it from following alphanumerics (and underscores).
482 You must also do
483 this when interpolating a variable into a string to separate the
484 variable name from a following double-colon or an apostrophe, since
485 these would be otherwise treated as a package separator:
486 X<interpolation>
487
488     $who = "Larry";
489     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
490     print "We use ${who}speak when ${who}'s here.\n";
491
492 Without the braces, Perl would have looked for a $whospeak, a
493 C<$who::0>, and a C<$who's> variable.  The last two would be the
494 $0 and the $s variables in the (presumably) non-existent package
495 C<who>.
496
497 In fact, a simple identifier within such curlies is forced to be
498 a string, and likewise within a hash subscript.  Neither need
499 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
500 C<$days{Feb}> and the quotes will be assumed automatically.  But
501 anything more complicated in the subscript will be interpreted as an
502 expression.  This means for example that C<$version{2.0}++> is
503 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
504
505 =head3 Special floating point: infinity (Inf) and not-a-number (NaN)
506
507 Floating point values include the special values C<Inf> and C<NaN>,
508 for infinity and not-a-number.  The infinity can be also negative.
509
510 The infinity is the result of certain math operations that overflow
511 the floating point range, like 9**9**9.  The not-a-number is the
512 result when the result is undefined or unrepresentable.  Though note
513 that you cannot get C<NaN> from some common "undefined" or
514 "out-of-range" operations like dividing by zero, or square root of
515 a negative number, since Perl generates fatal errors for those.
516
517 The infinity and not-a-number have their own special arithmetic rules.
518 The general rule is that they are "contagious": C<Inf> plus one is
519 C<Inf>, and C<NaN> plus one is C<NaN>.  Where things get interesting
520 is when you combine infinities and not-a-numbers: C<Inf> minus C<Inf>
521 and C<Inf> divided by C<INf> are C<NaN> (while C<Inf> plus C<Inf> is
522 C<Inf> and C<Inf> times C<Inf> is C<Inf>).  C<NaN> is also curious
523 in that it does not equal any number, I<including> itself:
524 C<NaN> != C<NaN>.
525
526 Perl doesn't understand C<Inf> and C<NaN> as numeric literals, but
527 you can have them as strings, and Perl will convert them as needed:
528 "Inf" + 1.  (You can, however, import them from the POSIX extension;
529 C<use POSIX qw(Inf NaN);> and then use them as literals.)
530
531 Note that on input (string to number) Perl accepts C<Inf> and C<NaN>
532 in many forms.   Case is ignored, and the Win32-specific forms like
533 C<1.#INF> are understood, but on output the values are normalized to
534 C<Inf> and C<NaN>.
535
536 =head3 Version Strings
537 X<version string> X<vstring> X<v-string>
538
539 A literal of the form C<v1.20.300.4000> is parsed as a string composed
540 of characters with the specified ordinals.  This form, known as
541 v-strings, provides an alternative, more readable way to construct
542 strings, rather than use the somewhat less readable interpolation form
543 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
544 Unicode strings, and for comparing version "numbers" using the string
545 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
546 more dots in the literal, the leading C<v> may be omitted.
547
548     print v9786;              # prints SMILEY, "\x{263a}"
549     print v102.111.111;       # prints "foo"
550     print 102.111.111;        # same
551
552 Such literals are accepted by both C<require> and C<use> for
553 doing a version check.  Note that using the v-strings for IPv4
554 addresses is not portable unless you also use the
555 inet_aton()/inet_ntoa() routines of the Socket package.
556
557 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
558 are not v-strings before the C<< => >> operator (which is usually used
559 to separate a hash key from a hash value); instead they are interpreted
560 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
561 Perl 5.8.0, but that caused more confusion and breakage than good.
562 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
563 be v-strings always.
564
565 =head3 Special Literals
566 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
567 X<end> X<data> X<^D> X<^Z>
568
569 The special literals __FILE__, __LINE__, and __PACKAGE__
570 represent the current filename, line number, and package name at that
571 point in your program.  __SUB__ gives a reference to the current
572 subroutine.  They may be used only as separate tokens; they
573 will not be interpolated into strings.  If there is no current package
574 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
575 value.  (But the empty C<package;> is no longer supported, as of version
576 5.10.)  Outside of a subroutine, __SUB__ is the undefined value.  __SUB__
577 is only available in 5.16 or higher, and only with a C<use v5.16> or
578 C<use feature "current_sub"> declaration.
579 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<__SUB__>
580 X<line> X<file> X<package>
581
582 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
583 may be used to indicate the logical end of the script before the actual
584 end of file.  Any following text is ignored.
585
586 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
587 where C<PACKNAME> is the package that was current when the __DATA__
588 token was encountered.  The filehandle is left open pointing to the
589 line after __DATA__.  The program should C<close DATA> when it is done
590 reading from it.  (Leaving it open leaks filehandles if the module is
591 reloaded for any reason, so it's a safer practice to close it.)  For
592 compatibility with older scripts written before __DATA__ was
593 introduced, __END__ behaves like __DATA__ in the top level script (but
594 not in files loaded with C<require> or C<do>) and leaves the remaining
595 contents of the file accessible via C<main::DATA>.
596
597 See L<SelfLoader> for more description of __DATA__, and
598 an example of its use.  Note that you cannot read from the DATA
599 filehandle in a BEGIN block: the BEGIN block is executed as soon
600 as it is seen (during compilation), at which point the corresponding
601 __DATA__ (or __END__) token has not yet been seen.
602
603 =head3 Barewords
604 X<bareword>
605
606 A word that has no other interpretation in the grammar will
607 be treated as if it were a quoted string.  These are known as
608 "barewords".  As with filehandles and labels, a bareword that consists
609 entirely of lowercase letters risks conflict with future reserved
610 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
611 Perl will warn you about any such words.  Perl limits barewords (like
612 identifiers) to about 250 characters.  Future versions of Perl are likely
613 to eliminate these arbitrary limitations.
614
615 Some people may wish to outlaw barewords entirely.  If you
616 say
617
618     use strict 'subs';
619
620 then any bareword that would NOT be interpreted as a subroutine call
621 produces a compile-time error instead.  The restriction lasts to the
622 end of the enclosing block.  An inner block may countermand this
623 by saying C<no strict 'subs'>.
624
625 =head3 Array Interpolation
626 X<array, interpolation> X<interpolation, array> X<$">
627
628 Arrays and slices are interpolated into double-quoted strings
629 by joining the elements with the delimiter specified in the C<$">
630 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
631 space by default.  The following are equivalent:
632
633     $temp = join($", @ARGV);
634     system "echo $temp";
635
636     system "echo @ARGV";
637
638 Within search patterns (which also undergo double-quotish substitution)
639 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
640 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
641 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
642 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
643 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
644 and is almost always right.  If it does guess wrong, or if you're just
645 plain paranoid, you can force the correct interpretation with curly
646 braces as above.
647
648 If you're looking for the information on how to use here-documents,
649 which used to be here, that's been moved to
650 L<perlop/Quote and Quote-like Operators>.
651
652 =head2 List value constructors
653 X<list>
654
655 List values are denoted by separating individual values by commas
656 (and enclosing the list in parentheses where precedence requires it):
657
658     (LIST)
659
660 In a context not requiring a list value, the value of what appears
661 to be a list literal is simply the value of the final element, as
662 with the C comma operator.  For example,
663
664     @foo = ('cc', '-E', $bar);
665
666 assigns the entire list value to array @foo, but
667
668     $foo = ('cc', '-E', $bar);
669
670 assigns the value of variable $bar to the scalar variable $foo.
671 Note that the value of an actual array in scalar context is the
672 length of the array; the following assigns the value 3 to $foo:
673
674     @foo = ('cc', '-E', $bar);
675     $foo = @foo;                # $foo gets 3
676
677 You may have an optional comma before the closing parenthesis of a
678 list literal, so that you can say:
679
680     @foo = (
681         1,
682         2,
683         3,
684     );
685
686 To use a here-document to assign an array, one line per element,
687 you might use an approach like this:
688
689     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
690         normal tomato
691         spicy tomato
692         green chile
693         pesto
694         white wine
695     End_Lines
696
697 LISTs do automatic interpolation of sublists.  That is, when a LIST is
698 evaluated, each element of the list is evaluated in list context, and
699 the resulting list value is interpolated into LIST just as if each
700 individual element were a member of LIST.  Thus arrays and hashes lose their
701 identity in a LIST--the list
702
703     (@foo,@bar,&SomeSub,%glarch)
704
705 contains all the elements of @foo followed by all the elements of @bar,
706 followed by all the elements returned by the subroutine named SomeSub 
707 called in list context, followed by the key/value pairs of %glarch.
708 To make a list reference that does I<NOT> interpolate, see L<perlref>.
709
710 The null list is represented by ().  Interpolating it in a list
711 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
712 interpolating an array with no elements is the same as if no
713 array had been interpolated at that point.
714
715 This interpolation combines with the facts that the opening
716 and closing parentheses are optional (except when necessary for
717 precedence) and lists may end with an optional comma to mean that
718 multiple commas within lists are legal syntax.  The list C<1,,3> is a
719 concatenation of two lists, C<1,> and C<3>, the first of which ends
720 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
721 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
722 we'd advise you to use this obfuscation.
723
724 A list value may also be subscripted like a normal array.  You must
725 put the list in parentheses to avoid ambiguity.  For example:
726
727     # Stat returns list value.
728     $time = (stat($file))[8];
729
730     # SYNTAX ERROR HERE.
731     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
732
733     # Find a hex digit.
734     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
735
736     # A "reverse comma operator".
737     return (pop(@foo),pop(@foo))[0];
738
739 Lists may be assigned to only when each element of the list
740 is itself legal to assign to:
741
742     ($a, $b, $c) = (1, 2, 3);
743
744     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
745
746 An exception to this is that you may assign to C<undef> in a list.
747 This is useful for throwing away some of the return values of a
748 function:
749
750     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
751
752 As of Perl 5.22, you can also use C<(undef)x2> instead of C<undef, undef>.
753 (You can also do C<($x) x 2>, which is less useful, because it assigns to
754 the same variable twice, clobbering the first value assigned.)
755
756 List assignment in scalar context returns the number of elements
757 produced by the expression on the right side of the assignment:
758
759     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
760     $x = (($foo,$bar) = f());           # set $x to f()'s return count
761
762 This is handy when you want to do a list assignment in a Boolean
763 context, because most list functions return a null list when finished,
764 which when assigned produces a 0, which is interpreted as FALSE.
765
766 It's also the source of a useful idiom for executing a function or
767 performing an operation in list context and then counting the number of
768 return values, by assigning to an empty list and then using that
769 assignment in scalar context.  For example, this code:
770
771     $count = () = $string =~ /\d+/g;
772
773 will place into $count the number of digit groups found in $string.
774 This happens because the pattern match is in list context (since it
775 is being assigned to the empty list), and will therefore return a list
776 of all matching parts of the string.  The list assignment in scalar
777 context will translate that into the number of elements (here, the
778 number of times the pattern matched) and assign that to $count.  Note
779 that simply using
780
781     $count = $string =~ /\d+/g;
782
783 would not have worked, since a pattern match in scalar context will
784 only return true or false, rather than a count of matches.
785
786 The final element of a list assignment may be an array or a hash:
787
788     ($a, $b, @rest) = split;
789     my($a, $b, %rest) = @_;
790
791 You can actually put an array or hash anywhere in the list, but the first one
792 in the list will soak up all the values, and anything after it will become
793 undefined.  This may be useful in a my() or local().
794
795 A hash can be initialized using a literal list holding pairs of
796 items to be interpreted as a key and a value:
797
798     # same as map assignment above
799     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
800
801 While literal lists and named arrays are often interchangeable, that's
802 not the case for hashes.  Just because you can subscript a list value like
803 a normal array does not mean that you can subscript a list value as a
804 hash.  Likewise, hashes included as parts of other lists (including
805 parameters lists and return lists from functions) always flatten out into
806 key/value pairs.  That's why it's good to use references sometimes.
807
808 It is often more readable to use the C<< => >> operator between key/value
809 pairs.  The C<< => >> operator is mostly just a more visually distinctive
810 synonym for a comma, but it also arranges for its left-hand operand to be
811 interpreted as a string if it's a bareword that would be a legal simple
812 identifier.  C<< => >> doesn't quote compound identifiers, that contain
813 double colons.  This makes it nice for initializing hashes:
814
815     %map = (
816                  red   => 0x00f,
817                  blue  => 0x0f0,
818                  green => 0xf00,
819    );
820
821 or for initializing hash references to be used as records:
822
823     $rec = {
824                 witch => 'Mable the Merciless',
825                 cat   => 'Fluffy the Ferocious',
826                 date  => '10/31/1776',
827     };
828
829 or for using call-by-named-parameter to complicated functions:
830
831    $field = $query->radio_group(
832                name      => 'group_name',
833                values    => ['eenie','meenie','minie'],
834                default   => 'meenie',
835                linebreak => 'true',
836                labels    => \%labels
837    );
838
839 Note that just because a hash is initialized in that order doesn't
840 mean that it comes out in that order.  See L<perlfunc/sort> for examples
841 of how to arrange for an output ordering.
842
843 If a key appears more than once in the initializer list of a hash, the last
844 occurrence wins:
845
846     %circle = (
847                   center => [5, 10],
848                   center => [27, 9],
849                   radius => 100,
850                   color => [0xDF, 0xFF, 0x00],
851                   radius => 54,
852     );
853
854     # same as
855     %circle = (
856                   center => [27, 9],
857                   color => [0xDF, 0xFF, 0x00],
858                   radius => 54,
859     );
860
861 This can be used to provide overridable configuration defaults:
862
863     # values in %args take priority over %config_defaults
864     %config = (%config_defaults, %args);
865
866 =head2 Subscripts
867
868 An array can be accessed one scalar at a
869 time by specifying a dollar sign (C<$>), then the
870 name of the array (without the leading C<@>), then the subscript inside
871 square brackets.  For example:
872
873     @myarray = (5, 50, 500, 5000);
874     print "The Third Element is", $myarray[2], "\n";
875
876 The array indices start with 0.  A negative subscript retrieves its 
877 value from the end.  In our example, C<$myarray[-1]> would have been 
878 5000, and C<$myarray[-2]> would have been 500.
879
880 Hash subscripts are similar, only instead of square brackets curly brackets
881 are used.  For example:
882
883     %scientists = 
884     (
885         "Newton" => "Isaac",
886         "Einstein" => "Albert",
887         "Darwin" => "Charles",
888         "Feynman" => "Richard",
889     );
890
891     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
892
893 You can also subscript a list to get a single element from it:
894
895     $dir = (getpwnam("daemon"))[7];
896
897 =head2 Multi-dimensional array emulation
898
899 Multidimensional arrays may be emulated by subscripting a hash with a
900 list.  The elements of the list are joined with the subscript separator
901 (see L<perlvar/$;>).
902
903     $foo{$a,$b,$c}
904
905 is equivalent to
906
907     $foo{join($;, $a, $b, $c)}
908
909 The default subscript separator is "\034", the same as SUBSEP in B<awk>.
910
911 =head2 Slices
912 X<slice> X<array, slice> X<hash, slice>
913
914 A slice accesses several elements of a list, an array, or a hash
915 simultaneously using a list of subscripts.  It's more convenient
916 than writing out the individual elements as a list of separate
917 scalar values.
918
919     ($him, $her)   = @folks[0,-1];              # array slice
920     @them          = @folks[0 .. 3];            # array slice
921     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
922     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
923
924 Since you can assign to a list of variables, you can also assign to
925 an array or hash slice.
926
927     @days[3..5]    = qw/Wed Thu Fri/;
928     @colors{'red','blue','green'} 
929                    = (0xff0000, 0x0000ff, 0x00ff00);
930     @folks[0, -1]  = @folks[-1, 0];
931
932 The previous assignments are exactly equivalent to
933
934     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
935     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
936                    = (0xff0000, 0x0000ff, 0x00ff00);
937     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
938
939 Since changing a slice changes the original array or hash that it's
940 slicing, a C<foreach> construct will alter some--or even all--of the
941 values of the array or hash.
942
943     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
944
945     foreach (@hash{qw[key1 key2]}) {
946         s/^\s+//;           # trim leading whitespace
947         s/\s+$//;           # trim trailing whitespace
948         s/(\w+)/\u\L$1/g;   # "titlecase" words
949     }
950
951 As a special exception, when you slice a list (but not an array or a hash),
952 if the list evaluates to empty, then taking a slice of that empty list will
953 always yield the empty list in turn.  Thus:
954
955     @a = ()[0,1];          # @a has no elements
956     @b = (@a)[0,1];        # @b has no elements
957     @c = (sub{}->())[0,1]; # @c has no elements
958     @d = ('a','b')[0,1];   # @d has two elements
959     @e = (@d)[0,1,8,9];    # @e has four elements
960     @f = (@d)[8,9];        # @f has two elements
961
962 This makes it easy to write loops that terminate when a null list
963 is returned:
964
965     while ( ($home, $user) = (getpwent)[7,0] ) {
966         printf "%-8s %s\n", $user, $home;
967     }
968
969 As noted earlier in this document, the scalar sense of list assignment
970 is the number of elements on the right-hand side of the assignment.
971 The null list contains no elements, so when the password file is
972 exhausted, the result is 0, not 2.
973
974 Slices in scalar context return the last item of the slice.
975
976     @a = qw/first second third/;
977     %h = (first => 'A', second => 'B');
978     $t = @a[0, 1];                  # $t is now 'second'
979     $u = @h{'first', 'second'};     # $u is now 'B'
980
981 If you're confused about why you use an '@' there on a hash slice
982 instead of a '%', think of it like this.  The type of bracket (square
983 or curly) governs whether it's an array or a hash being looked at.
984 On the other hand, the leading symbol ('$' or '@') on the array or
985 hash indicates whether you are getting back a singular value (a
986 scalar) or a plural one (a list).
987
988 =head3 Key/Value Hash Slices
989
990 Starting in Perl 5.20, a hash slice operation
991 with the % symbol is a variant of slice operation
992 returning a list of key/value pairs rather than just values:
993
994     %h = (blonk => 2, foo => 3, squink => 5, bar => 8);
995     %subset = %h{'foo', 'bar'}; # key/value hash slice
996     # %subset is now (foo => 3, bar => 8)
997
998 However, the result of such a slice cannot be localized, deleted or used
999 in assignment.  These are otherwise very much consistent with hash slices
1000 using the @ symbol.
1001
1002 =head3 Index/Value Array Slices
1003
1004 Similar to key/value hash slices (and also introduced
1005 in Perl 5.20), the % array slice syntax returns a list
1006 of index/value pairs:
1007
1008     @a = "a".."z";
1009     @list = %a[3,4,6];
1010     # @list is now (3, "d", 4, "e", 6, "g")
1011
1012 =head2 Typeglobs and Filehandles
1013 X<typeglob> X<filehandle> X<*>
1014
1015 Perl uses an internal type called a I<typeglob> to hold an entire
1016 symbol table entry.  The type prefix of a typeglob is a C<*>, because
1017 it represents all types.  This used to be the preferred way to
1018 pass arrays and hashes by reference into a function, but now that
1019 we have real references, this is seldom needed.  
1020
1021 The main use of typeglobs in modern Perl is create symbol table aliases.
1022 This assignment:
1023
1024     *this = *that;
1025
1026 makes $this an alias for $that, @this an alias for @that, %this an alias
1027 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
1028 This:
1029
1030     local *Here::blue = \$There::green;
1031
1032 temporarily makes $Here::blue an alias for $There::green, but doesn't
1033 make @Here::blue an alias for @There::green, or %Here::blue an alias for
1034 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
1035 of this.  Strange though this may seem, this is the basis for the whole
1036 module import/export system.
1037
1038 Another use for typeglobs is to pass filehandles into a function or
1039 to create new filehandles.  If you need to use a typeglob to save away
1040 a filehandle, do it this way:
1041
1042     $fh = *STDOUT;
1043
1044 or perhaps as a real reference, like this:
1045
1046     $fh = \*STDOUT;
1047
1048 See L<perlsub> for examples of using these as indirect filehandles
1049 in functions.
1050
1051 Typeglobs are also a way to create a local filehandle using the local()
1052 operator.  These last until their block is exited, but may be passed back.
1053 For example:
1054
1055     sub newopen {
1056         my $path = shift;
1057         local  *FH;  # not my!
1058         open   (FH, $path)          or  return undef;
1059         return *FH;
1060     }
1061     $fh = newopen('/etc/passwd');
1062
1063 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
1064 for filehandle manipulations, although they're still needed to pass brand
1065 new file and directory handles into or out of functions.  That's because
1066 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
1067 In other words, C<*FH> must be used to create new symbol table entries;
1068 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
1069
1070 All functions that are capable of creating filehandles (open(),
1071 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
1072 automatically create an anonymous filehandle if the handle passed to
1073 them is an uninitialized scalar variable.  This allows the constructs
1074 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
1075 create filehandles that will conveniently be closed automatically when
1076 the scope ends, provided there are no other references to them.  This
1077 largely eliminates the need for typeglobs when opening filehandles
1078 that must be passed around, as in the following example:
1079
1080     sub myopen {
1081         open my $fh, "@_"
1082              or die "Can't open '@_': $!";
1083         return $fh;
1084     }
1085
1086     {
1087         my $f = myopen("</etc/motd");
1088         print <$f>;
1089         # $f implicitly closed here
1090     }
1091
1092 Note that if an initialized scalar variable is used instead the
1093 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
1094 to C<open( *{'zzz'}, ...)>.
1095 C<use strict 'refs'> forbids such practice.
1096
1097 Another way to create anonymous filehandles is with the Symbol
1098 module or with the IO::Handle module and its ilk.  These modules
1099 have the advantage of not hiding different types of the same name
1100 during the local().  See the bottom of L<perlfunc/open> for an
1101 example.
1102
1103 =head1 SEE ALSO
1104
1105 See L<perlvar> for a description of Perl's built-in variables and
1106 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
1107 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
1108 the C<*foo{THING}> syntax.