incremental improvement in ~~ documentation, already in maint-5.10
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.08';
4
5 sub nil {}
6
7 sub OVERLOAD {
8   $package = shift;
9   my %arg = @_;
10   my ($sub, $fb);
11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
13   for (keys %arg) {
14     if ($_ eq 'fallback') {
15       $fb = $arg{$_};
16     } else {
17       $sub = $arg{$_};
18       if (not ref $sub and $sub !~ /::/) {
19         $ {$package . "::(" . $_} = $sub;
20         $sub = \&nil;
21       }
22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
23       *{$package . "::(" . $_} = \&{ $sub };
24     }
25   }
26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
27 }
28
29 sub import {
30   $package = (caller())[0];
31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
32   shift;
33   $package->overload::OVERLOAD(@_);
34 }
35
36 sub unimport {
37   $package = (caller())[0];
38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
39   shift;
40   for (@_) {
41     if ($_ eq 'fallback') {
42       undef $ {$package . "::()"};
43     } else {
44       delete $ {$package . "::"}{"(" . $_};
45     }
46   }
47 }
48
49 sub Overloaded {
50   my $package = shift;
51   $package = ref $package if ref $package;
52   $package->can('()');
53 }
54
55 sub ov_method {
56   my $globref = shift;
57   return undef unless $globref;
58   my $sub = \&{*$globref};
59   return $sub if $sub ne \&nil;
60   return shift->can($ {*$globref});
61 }
62
63 sub OverloadedStringify {
64   my $package = shift;
65   $package = ref $package if ref $package;
66   #$package->can('(""')
67   ov_method mycan($package, '(""'), $package
68     or ov_method mycan($package, '(0+'), $package
69     or ov_method mycan($package, '(bool'), $package
70     or ov_method mycan($package, '(nomethod'), $package;
71 }
72
73 sub Method {
74   my $package = shift;
75   if(ref $package) {
76     local $@;
77     local $!;
78     require Scalar::Util;
79     $package = Scalar::Util::blessed($package);
80     return undef if !defined $package;
81   }
82   #my $meth = $package->can('(' . shift);
83   ov_method mycan($package, '(' . shift), $package;
84   #return $meth if $meth ne \&nil;
85   #return $ {*{$meth}};
86 }
87
88 sub AddrRef {
89   my $package = ref $_[0];
90   return "$_[0]" unless $package;
91
92   local $@;
93   local $!;
94   require Scalar::Util;
95   my $class = Scalar::Util::blessed($_[0]);
96   my $class_prefix = defined($class) ? "$class=" : "";
97   my $type = Scalar::Util::reftype($_[0]);
98   my $addr = Scalar::Util::refaddr($_[0]);
99   return sprintf("$class_prefix$type(0x%x)", $addr);
100 }
101
102 *StrVal = *AddrRef;
103
104 sub mycan {                             # Real can would leave stubs.
105   my ($package, $meth) = @_;
106
107   local $@;
108   local $!;
109   require mro;
110
111   my $mro = mro::get_linear_isa($package);
112   foreach my $p (@$mro) {
113     my $fqmeth = $p . q{::} . $meth;
114     return \*{$fqmeth} if defined &{$fqmeth};
115   }
116
117   return undef;
118 }
119
120 %constants = (
121               'integer'   =>  0x1000, # HINT_NEW_INTEGER
122               'float'     =>  0x2000, # HINT_NEW_FLOAT
123               'binary'    =>  0x4000, # HINT_NEW_BINARY
124               'q'         =>  0x8000, # HINT_NEW_STRING
125               'qr'        => 0x10000, # HINT_NEW_RE
126              );
127
128 %ops = ( with_assign      => "+ - * / % ** << >> x .",
129          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
130          num_comparison   => "< <= >  >= == !=",
131          '3way_comparison'=> "<=> cmp",
132          str_comparison   => "lt le gt ge eq ne",
133          binary           => '& &= | |= ^ ^=',
134          unary            => "neg ! ~",
135          mutators         => '++ --',
136          func             => "atan2 cos sin exp abs log sqrt int",
137          conversion       => 'bool "" 0+',
138          iterators        => '<>',
139          filetest         => "-X",
140          dereferencing    => '${} @{} %{} &{} *{}',
141          matching         => '~~',
142          special          => 'nomethod fallback =');
143
144 use warnings::register;
145 sub constant {
146   # Arguments: what, sub
147   while (@_) {
148     if (@_ == 1) {
149         warnings::warnif ("Odd number of arguments for overload::constant");
150         last;
151     }
152     elsif (!exists $constants {$_ [0]}) {
153         warnings::warnif ("`$_[0]' is not an overloadable type");
154     }
155     elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
156         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
157         # blessed, and C<ref> would return the package the ref is blessed into.
158         if (warnings::enabled) {
159             $_ [1] = "undef" unless defined $_ [1];
160             warnings::warn ("`$_[1]' is not a code reference");
161         }
162     }
163     else {
164         $^H{$_[0]} = $_[1];
165         $^H |= $constants{$_[0]};
166     }
167     shift, shift;
168   }
169 }
170
171 sub remove_constant {
172   # Arguments: what, sub
173   while (@_) {
174     delete $^H{$_[0]};
175     $^H &= ~ $constants{$_[0]};
176     shift, shift;
177   }
178 }
179
180 1;
181
182 __END__
183
184 =head1 NAME
185
186 overload - Package for overloading Perl operations
187
188 =head1 SYNOPSIS
189
190     package SomeThing;
191
192     use overload
193         '+' => \&myadd,
194         '-' => \&mysub;
195         # etc
196     ...
197
198     package main;
199     $a = SomeThing->new( 57 );
200     $b=5+$a;
201     ...
202     if (overload::Overloaded $b) {...}
203     ...
204     $strval = overload::StrVal $b;
205
206 =head1 DESCRIPTION
207
208 This pragma allows overloading of Perl's operators for a class.
209 To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead.
210
211 =head2 Declaration of overloaded functions
212
213 The compilation directive
214
215     package Number;
216     use overload
217         "+" => \&add,
218         "*=" => "muas";
219
220 declares function Number::add() for addition, and method muas() in
221 the "class" C<Number> (or one of its base classes)
222 for the assignment form C<*=> of multiplication.
223
224 Arguments of this directive come in (key, value) pairs.  Legal values
225 are values legal inside a C<&{ ... }> call, so the name of a
226 subroutine, a reference to a subroutine, or an anonymous subroutine
227 will all work.  Note that values specified as strings are
228 interpreted as methods, not subroutines.  Legal keys are listed below.
229
230 The subroutine C<add> will be called to execute C<$a+$b> if $a
231 is a reference to an object blessed into the package C<Number>, or if $a is
232 not an object from a package with defined mathemagic addition, but $b is a
233 reference to a C<Number>.  It can also be called in other situations, like
234 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
235 methods refer to methods triggered by an overloaded mathematical
236 operator.)
237
238 Since overloading respects inheritance via the @ISA hierarchy, the
239 above declaration would also trigger overloading of C<+> and C<*=> in
240 all the packages which inherit from C<Number>.
241
242 =head2 Calling Conventions for Binary Operations
243
244 The functions specified in the C<use overload ...> directive are called
245 with three (in one particular case with four, see L<Last Resort>)
246 arguments.  If the corresponding operation is binary, then the first
247 two arguments are the two arguments of the operation.  However, due to
248 general object calling conventions, the first argument should always be
249 an object in the package, so in the situation of C<7+$a>, the
250 order of the arguments is interchanged.  It probably does not matter
251 when implementing the addition method, but whether the arguments
252 are reversed is vital to the subtraction method.  The method can
253 query this information by examining the third argument, which can take
254 three different values:
255
256 =over 7
257
258 =item FALSE
259
260 the order of arguments is as in the current operation.
261
262 =item TRUE
263
264 the arguments are reversed.
265
266 =item C<undef>
267
268 the current operation is an assignment variant (as in
269 C<$a+=7>), but the usual function is called instead.  This additional
270 information can be used to generate some optimizations.  Compare
271 L<Calling Conventions for Mutators>.
272
273 =back
274
275 =head2 Calling Conventions for Unary Operations
276
277 Unary operation are considered binary operations with the second
278 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
279 is called with arguments C<($a,undef,'')> when $a++ is executed.
280
281 =head2 Calling Conventions for Mutators
282
283 Two types of mutators have different calling conventions:
284
285 =over
286
287 =item C<++> and C<-->
288
289 The routines which implement these operators are expected to actually
290 I<mutate> their arguments.  So, assuming that $obj is a reference to a
291 number,
292
293   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
294
295 is an appropriate implementation of overloaded C<++>.  Note that
296
297   sub incr { ++$ {$_[0]} ; shift }
298
299 is OK if used with preincrement and with postincrement. (In the case
300 of postincrement a copying will be performed, see L<Copy Constructor>.)
301
302 =item C<x=> and other assignment versions
303
304 There is nothing special about these methods.  They may change the
305 value of their arguments, and may leave it as is.  The result is going
306 to be assigned to the value in the left-hand-side if different from
307 this value.
308
309 This allows for the same method to be used as overloaded C<+=> and
310 C<+>.  Note that this is I<allowed>, but not recommended, since by the
311 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
312 if C<+=> is not overloaded.
313
314 =back
315
316 B<Warning.>  Due to the presence of assignment versions of operations,
317 routines which may be called in assignment context may create
318 self-referential structures.  Currently Perl will not free self-referential
319 structures until cycles are C<explicitly> broken.  You may get problems
320 when traversing your structures too.
321
322 Say,
323
324   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
325
326 is asking for trouble, since for code C<$obj += $foo> the subroutine
327 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
328 \$foo]>.  If using such a subroutine is an important optimization, one
329 can overload C<+=> explicitly by a non-"optimized" version, or switch
330 to non-optimized version if C<not defined $_[2]> (see
331 L<Calling Conventions for Binary Operations>).
332
333 Even if no I<explicit> assignment-variants of operators are present in
334 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
335 C<',' . $obj . ','> may be both optimized to
336
337   my $tmp = ',' . $obj;    $tmp .= ',';
338
339 =head2 Overloadable Operations
340
341 The following symbols can be specified in C<use overload> directive:
342
343 =over 5
344
345 =item * I<Arithmetic operations>
346
347     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
348     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
349
350 For these operations a substituted non-assignment variant can be called if
351 the assignment variant is not available.  Methods for operations C<+>,
352 C<->, C<+=>, and C<-=> can be called to automatically generate
353 increment and decrement methods.  The operation C<-> can be used to
354 autogenerate missing methods for unary minus or C<abs>.
355
356 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
357 L<"Calling Conventions for Binary Operations">) for details of these
358 substitutions.
359
360 =item * I<Comparison operations>
361
362     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
363     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
364
365 If the corresponding "spaceship" variant is available, it can be
366 used to substitute for the missing operation.  During C<sort>ing
367 arrays, C<cmp> is used to compare values subject to C<use overload>.
368
369 =item * I<Bit operations>
370
371     "&", "&=", "^", "^=", "|", "|=", "neg", "!", "~",
372
373 C<neg> stands for unary minus.  If the method for C<neg> is not
374 specified, it can be autogenerated using the method for
375 subtraction. If the method for C<!> is not specified, it can be
376 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
377
378 The same remarks in L<"Arithmetic operations"> about
379 assignment-variants and autogeneration apply for
380 bit operations C<"&">, C<"^">, and C<"|"> as well.
381
382 =item * I<Increment and decrement>
383
384     "++", "--",
385
386 If undefined, addition and subtraction methods can be
387 used instead.  These operations are called both in prefix and
388 postfix form.
389
390 =item * I<Transcendental functions>
391
392     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
393
394 If C<abs> is unavailable, it can be autogenerated using methods
395 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
396
397 Note that traditionally the Perl function L<int> rounds to 0, thus for
398 floating-point-like types one should follow the same semantic.  If
399 C<int> is unavailable, it can be autogenerated using the overloading of
400 C<0+>.
401
402 =item * I<Boolean, string and numeric conversion>
403
404     'bool', '""', '0+',
405
406 If one or two of these operations are not overloaded, the remaining ones can
407 be used instead.  C<bool> is used in the flow control operators
408 (like C<while>) and for the ternary C<?:> operation.  These functions can
409 return any arbitrary Perl value.  If the corresponding operation for this value
410 is overloaded too, that operation will be called again with this value.
411
412 As a special case if the overload returns the object itself then it will
413 be used directly. An overloaded conversion returning the object is
414 probably a bug, because you're likely to get something that looks like
415 C<YourPackage=HASH(0x8172b34)>.
416
417 =item * I<Iteration>
418
419     "<>"
420
421 If not overloaded, the argument will be converted to a filehandle or
422 glob (which may require a stringification).  The same overloading
423 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
424 I<globbing> syntax C<E<lt>${var}E<gt>>.
425
426 B<BUGS> Even in list context, the iterator is currently called only
427 once and with scalar context.
428
429 =item * I<File tests>
430
431     "-X"
432
433 This overload is used for all the filetest operators (C<-f>, C<-x> and
434 so on: see L<perlfunc/-X> for the full list). Even though these are
435 unary operators, the method will be called with a second argument which
436 is a single letter indicating which test was performed. Note that the
437 overload key is the literal string C<"-X">: you can't provide separate
438 overloads for the different tests.
439
440 Calling an overloaded filetest operator does not affect the stat value
441 associated with the special filehandle C<_>. It still refers to the
442 result of the last C<stat>, C<lstat> or unoverloaded filetest.
443
444 If not overloaded, these operators will fall back to the default
445 behaviour even without C<< fallback => 1 >>. This means that if the
446 object is a blessed glob or blessed IO ref it will be treated as a
447 filehandle, otherwise string overloading will be invoked and the result
448 treated as a filename.
449
450 This overload was introduced in perl 5.12.
451
452 =item * I<Matching>
453
454 The key C<"~~"> allows you to override the smart matching logic used by
455 the C<~~> operator and the switch construct (C<given>/C<when>).  See
456 L<perlsyn/switch> and L<feature>.
457
458 =item * I<Dereferencing>
459
460     '${}', '@{}', '%{}', '&{}', '*{}'.
461
462 If not overloaded, the argument will be dereferenced I<as is>, thus
463 should be of correct type.  These functions should return a reference
464 of correct type, or another object with overloaded dereferencing.
465
466 As a special case if the overload returns the object itself then it
467 will be used directly (provided it is the correct type).
468
469 The dereference operators must be specified explicitly they will not be passed to
470 "nomethod".
471
472 =item * I<Special>
473
474     "nomethod", "fallback", "=".
475
476 see L<SPECIAL SYMBOLS FOR C<use overload>>.
477
478 =back
479
480 See L<"Fallback"> for an explanation of when a missing method can be
481 autogenerated.
482
483 A computer-readable form of the above table is available in the hash
484 %overload::ops, with values being space-separated lists of names:
485
486  with_assign      => '+ - * / % ** << >> x .',
487  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
488  num_comparison   => '< <= > >= == !=',
489  '3way_comparison'=> '<=> cmp',
490  str_comparison   => 'lt le gt ge eq ne',
491  binary           => '& &= | |= ^ ^=',
492  unary            => 'neg ! ~',
493  mutators         => '++ --',
494  func             => 'atan2 cos sin exp abs log sqrt',
495  conversion       => 'bool "" 0+',
496  iterators        => '<>',
497  filetest         => '-X',
498  dereferencing    => '${} @{} %{} &{} *{}',
499  matching         => '~~',
500  special          => 'nomethod fallback ='
501
502 =head2 Inheritance and overloading
503
504 Inheritance interacts with overloading in two ways.
505
506 =over
507
508 =item Strings as values of C<use overload> directive
509
510 If C<value> in
511
512   use overload key => value;
513
514 is a string, it is interpreted as a method name.
515
516 =item Overloading of an operation is inherited by derived classes
517
518 Any class derived from an overloaded class is also overloaded.  The
519 set of overloaded methods is the union of overloaded methods of all
520 the ancestors. If some method is overloaded in several ancestor, then
521 which description will be used is decided by the usual inheritance
522 rules:
523
524 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
525 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
526 then the subroutine C<D::plus_sub> will be called to implement
527 operation C<+> for an object in package C<A>.
528
529 =back
530
531 Note that since the value of the C<fallback> key is not a subroutine,
532 its inheritance is not governed by the above rules.  In the current
533 implementation, the value of C<fallback> in the first overloaded
534 ancestor is used, but this is accidental and subject to change.
535
536 =head1 SPECIAL SYMBOLS FOR C<use overload>
537
538 Three keys are recognized by Perl that are not covered by the above
539 description.
540
541 =head2 Last Resort
542
543 C<"nomethod"> should be followed by a reference to a function of four
544 parameters.  If defined, it is called when the overloading mechanism
545 cannot find a method for some operation.  The first three arguments of
546 this function coincide with the arguments for the corresponding method if
547 it were found, the fourth argument is the symbol
548 corresponding to the missing method.  If several methods are tried,
549 the last one is used.  Say, C<1-$a> can be equivalent to
550
551         &nomethodMethod($a,1,1,"-")
552
553 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
554 C<use overload> directive.
555
556 The C<"nomethod"> mechanism is I<not> used for the dereference operators
557 ( ${} @{} %{} &{} *{} ).
558
559
560 If some operation cannot be resolved, and there is no function
561 assigned to C<"nomethod">, then an exception will be raised via die()--
562 unless C<"fallback"> was specified as a key in C<use overload> directive.
563
564
565 =head2 Fallback
566
567 The key C<"fallback"> governs what to do if a method for a particular
568 operation is not found.  Three different cases are possible depending on
569 the value of C<"fallback">:
570
571 =over 16
572
573 =item * C<undef>
574
575 Perl tries to use a
576 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
577 then tries to calls C<"nomethod"> value; if missing, an exception
578 will be raised.
579
580 =item * TRUE
581
582 The same as for the C<undef> value, but no exception is raised.  Instead,
583 it silently reverts to what it would have done were there no C<use overload>
584 present.
585
586 =item * defined, but FALSE
587
588 No autogeneration is tried.  Perl tries to call
589 C<"nomethod"> value, and if this is missing, raises an exception.
590
591 =back
592
593 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
594 yet, see L<"Inheritance and overloading">.
595
596 =head2 Copy Constructor
597
598 The value for C<"="> is a reference to a function with three
599 arguments, i.e., it looks like the other values in C<use
600 overload>. However, it does not overload the Perl assignment
601 operator. This would go against Camel hair.
602
603 This operation is called in the situations when a mutator is applied
604 to a reference that shares its object with some other reference, such
605 as
606
607         $a=$b;
608         ++$a;
609
610 To make this change $a and not change $b, a copy of C<$$a> is made,
611 and $a is assigned a reference to this new object.  This operation is
612 done during execution of the C<++$a>, and not during the assignment,
613 (so before the increment C<$$a> coincides with C<$$b>).  This is only
614 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
615 C<nomethod>).  Note that if this operation is expressed via C<'+'>
616 a nonmutator, i.e., as in
617
618         $a=$b;
619         $a=$a+1;
620
621 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
622 appear as lvalue when the above code is executed.
623
624 If the copy constructor is required during the execution of some mutator,
625 but a method for C<'='> was not specified, it can be autogenerated as a
626 string copy if the object is a plain scalar or a simple assignment if it
627 is not.
628
629 =over 5
630
631 =item B<Example>
632
633 The actually executed code for
634
635         $a=$b;
636         Something else which does not modify $a or $b....
637         ++$a;
638
639 may be
640
641         $a=$b;
642         Something else which does not modify $a or $b....
643         $a = $a->clone(undef,"");
644         $a->incr(undef,"");
645
646 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
647 C<'='> was overloaded with C<\&clone>.
648
649 =back
650
651 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
652 C<$b = $a; ++$a>.
653
654 =head1 MAGIC AUTOGENERATION
655
656 If a method for an operation is not found, and the value for  C<"fallback"> is
657 TRUE or undefined, Perl tries to autogenerate a substitute method for
658 the missing operation based on the defined operations.  Autogenerated method
659 substitutions are possible for the following operations:
660
661 =over 16
662
663 =item I<Assignment forms of arithmetic operations>
664
665 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
666 is not defined.
667
668 =item I<Conversion operations>
669
670 String, numeric, and boolean conversion are calculated in terms of one
671 another if not all of them are defined.
672
673 =item I<Increment and decrement>
674
675 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
676 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
677
678 =item C<abs($a)>
679
680 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
681
682 =item I<Unary minus>
683
684 can be expressed in terms of subtraction.
685
686 =item I<Negation>
687
688 C<!> and C<not> can be expressed in terms of boolean conversion, or
689 string or numerical conversion.
690
691 =item I<Concatenation>
692
693 can be expressed in terms of string conversion.
694
695 =item I<Comparison operations>
696
697 can be expressed in terms of its "spaceship" counterpart: either
698 C<E<lt>=E<gt>> or C<cmp>:
699
700     <, >, <=, >=, ==, !=        in terms of <=>
701     lt, gt, le, ge, eq, ne      in terms of cmp
702
703 =item I<Iterator>
704
705     <>                          in terms of builtin operations
706
707 =item I<Dereferencing>
708
709     ${} @{} %{} &{} *{}         in terms of builtin operations
710
711 =item I<Copy operator>
712
713 can be expressed in terms of an assignment to the dereferenced value, if this
714 value is a scalar and not a reference, or simply a reference assignment
715 otherwise.
716
717 =back
718
719 =head1 Minimal set of overloaded operations
720
721 Since some operations can be automatically generated from others, there is
722 a minimal set of operations that need to be overloaded in order to have
723 the complete set of overloaded operations at one's disposal.
724 Of course, the autogenerated operations may not do exactly what the user
725 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
726
727     + - * / % ** << >> x
728     <=> cmp
729     & | ^ ~
730     atan2 cos sin exp log sqrt int
731
732 Additionally, you need to define at least one of string, boolean or
733 numeric conversions because any one can be used to emulate the others.
734 The string conversion can also be used to emulate concatenation.
735
736 =head1 Losing overloading
737
738 The restriction for the comparison operation is that even if, for example,
739 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
740 function will produce only a standard logical value based on the
741 numerical value of the result of `C<cmp>'.  In particular, a working
742 numeric conversion is needed in this case (possibly expressed in terms of
743 other conversions).
744
745 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
746 if the string conversion substitution is applied.
747
748 When you chop() a mathemagical object it is promoted to a string and its
749 mathemagical properties are lost.  The same can happen with other
750 operations as well.
751
752 =head1 Run-time Overloading
753
754 Since all C<use> directives are executed at compile-time, the only way to
755 change overloading during run-time is to
756
757     eval 'use overload "+" => \&addmethod';
758
759 You can also use
760
761     eval 'no overload "+", "--", "<="';
762
763 though the use of these constructs during run-time is questionable.
764
765 =head1 Public functions
766
767 Package C<overload.pm> provides the following public functions:
768
769 =over 5
770
771 =item overload::StrVal(arg)
772
773 Gives string value of C<arg> as in absence of stringify overloading. If you
774 are using this to get the address of a reference (useful for checking if two
775 references point to the same thing) then you may be better off using
776 C<Scalar::Util::refaddr()>, which is faster.
777
778 =item overload::Overloaded(arg)
779
780 Returns true if C<arg> is subject to overloading of some operations.
781
782 =item overload::Method(obj,op)
783
784 Returns C<undef> or a reference to the method that implements C<op>.
785
786 =back
787
788 =head1 Overloading constants
789
790 For some applications, the Perl parser mangles constants too much.
791 It is possible to hook into this process via C<overload::constant()>
792 and C<overload::remove_constant()> functions.
793
794 These functions take a hash as an argument.  The recognized keys of this hash
795 are:
796
797 =over 8
798
799 =item integer
800
801 to overload integer constants,
802
803 =item float
804
805 to overload floating point constants,
806
807 =item binary
808
809 to overload octal and hexadecimal constants,
810
811 =item q
812
813 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
814 strings and here-documents,
815
816 =item qr
817
818 to overload constant pieces of regular expressions.
819
820 =back
821
822 The corresponding values are references to functions which take three arguments:
823 the first one is the I<initial> string form of the constant, the second one
824 is how Perl interprets this constant, the third one is how the constant is used.
825 Note that the initial string form does not
826 contain string delimiters, and has backslashes in backslash-delimiter
827 combinations stripped (thus the value of delimiter is not relevant for
828 processing of this string).  The return value of this function is how this
829 constant is going to be interpreted by Perl.  The third argument is undefined
830 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
831 context (comes from strings, regular expressions, and single-quote HERE
832 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
833 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
834
835 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
836 it is expected that overloaded constant strings are equipped with reasonable
837 overloaded catenation operator, otherwise absurd results will result.
838 Similarly, negative numbers are considered as negations of positive constants.
839
840 Note that it is probably meaningless to call the functions overload::constant()
841 and overload::remove_constant() from anywhere but import() and unimport() methods.
842 From these methods they may be called as
843
844         sub import {
845           shift;
846           return unless @_;
847           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
848           overload::constant integer => sub {Math::BigInt->new(shift)};
849         }
850
851 =head1 IMPLEMENTATION
852
853 What follows is subject to change RSN.
854
855 The table of methods for all operations is cached in magic for the
856 symbol table hash for the package.  The cache is invalidated during
857 processing of C<use overload>, C<no overload>, new function
858 definitions, and changes in @ISA. However, this invalidation remains
859 unprocessed until the next C<bless>ing into the package. Hence if you
860 want to change overloading structure dynamically, you'll need an
861 additional (fake) C<bless>ing to update the table.
862
863 (Every SVish thing has a magic queue, and magic is an entry in that
864 queue.  This is how a single variable may participate in multiple
865 forms of magic simultaneously.  For instance, environment variables
866 regularly have two forms at once: their %ENV magic and their taint
867 magic. However, the magic which implements overloading is applied to
868 the stashes, which are rarely used directly, thus should not slow down
869 Perl.)
870
871 If an object belongs to a package using overload, it carries a special
872 flag.  Thus the only speed penalty during arithmetic operations without
873 overloading is the checking of this flag.
874
875 In fact, if C<use overload> is not present, there is almost no overhead
876 for overloadable operations, so most programs should not suffer
877 measurable performance penalties.  A considerable effort was made to
878 minimize the overhead when overload is used in some package, but the
879 arguments in question do not belong to packages using overload.  When
880 in doubt, test your speed with C<use overload> and without it.  So far
881 there have been no reports of substantial speed degradation if Perl is
882 compiled with optimization turned on.
883
884 There is no size penalty for data if overload is not used. The only
885 size penalty if overload is used in some package is that I<all> the
886 packages acquire a magic during the next C<bless>ing into the
887 package. This magic is three-words-long for packages without
888 overloading, and carries the cache table if the package is overloaded.
889
890 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
891 carried out before any operation that can imply an assignment to the
892 object $a (or $b) refers to, like C<$a++>.  You can override this
893 behavior by defining your own copy constructor (see L<"Copy Constructor">).
894
895 It is expected that arguments to methods that are not explicitly supposed
896 to be changed are constant (but this is not enforced).
897
898 =head1 Metaphor clash
899
900 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
901 If it I<looks> counter intuitive to you, you are subject to a metaphor
902 clash.
903
904 Here is a Perl object metaphor:
905
906 I<  object is a reference to blessed data>
907
908 and an arithmetic metaphor:
909
910 I<  object is a thing by itself>.
911
912 The I<main> problem of overloading C<=> is the fact that these metaphors
913 imply different actions on the assignment C<$a = $b> if $a and $b are
914 objects.  Perl-think implies that $a becomes a reference to whatever
915 $b was referencing.  Arithmetic-think implies that the value of "object"
916 $a is changed to become the value of the object $b, preserving the fact
917 that $a and $b are separate entities.
918
919 The difference is not relevant in the absence of mutators.  After
920 a Perl-way assignment an operation which mutates the data referenced by $a
921 would change the data referenced by $b too.  Effectively, after
922 C<$a = $b> values of $a and $b become I<indistinguishable>.
923
924 On the other hand, anyone who has used algebraic notation knows the
925 expressive power of the arithmetic metaphor.  Overloading works hard
926 to enable this metaphor while preserving the Perlian way as far as
927 possible.  Since it is not possible to freely mix two contradicting
928 metaphors, overloading allows the arithmetic way to write things I<as
929 far as all the mutators are called via overloaded access only>.  The
930 way it is done is described in L<Copy Constructor>.
931
932 If some mutator methods are directly applied to the overloaded values,
933 one may need to I<explicitly unlink> other values which references the
934 same value:
935
936     $a = Data->new(23);
937     ...
938     $b = $a;            # $b is "linked" to $a
939     ...
940     $a = $a->clone;     # Unlink $b from $a
941     $a->increment_by(4);
942
943 Note that overloaded access makes this transparent:
944
945     $a = Data->new(23);
946     $b = $a;            # $b is "linked" to $a
947     $a += 4;            # would unlink $b automagically
948
949 However, it would not make
950
951     $a = Data->new(23);
952     $a = 4;             # Now $a is a plain 4, not 'Data'
953
954 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
955 to an object do whatever you want.  It is just not the overload, but
956 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
957 which returns the object itself, and STORE() method which changes the
958 value of the object, one can reproduce the arithmetic metaphor in its
959 completeness, at least for variables which were tie()d from the start.
960
961 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
962
963 =head1 Cookbook
964
965 Please add examples to what follows!
966
967 =head2 Two-face scalars
968
969 Put this in F<two_face.pm> in your Perl library directory:
970
971   package two_face;             # Scalars with separate string and
972                                 # numeric values.
973   sub new { my $p = shift; bless [@_], $p }
974   use overload '""' => \&str, '0+' => \&num, fallback => 1;
975   sub num {shift->[1]}
976   sub str {shift->[0]}
977
978 Use it as follows:
979
980   require two_face;
981   my $seven = two_face->new("vii", 7);
982   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
983   print "seven contains `i'\n" if $seven =~ /i/;
984
985 (The second line creates a scalar which has both a string value, and a
986 numeric value.)  This prints:
987
988   seven=vii, seven=7, eight=8
989   seven contains `i'
990
991 =head2 Two-face references
992
993 Suppose you want to create an object which is accessible as both an
994 array reference and a hash reference.
995
996   package two_refs;
997   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
998   sub new {
999     my $p = shift;
1000     bless \ [@_], $p;
1001   }
1002   sub gethash {
1003     my %h;
1004     my $self = shift;
1005     tie %h, ref $self, $self;
1006     \%h;
1007   }
1008
1009   sub TIEHASH { my $p = shift; bless \ shift, $p }
1010   my %fields;
1011   my $i = 0;
1012   $fields{$_} = $i++ foreach qw{zero one two three};
1013   sub STORE {
1014     my $self = ${shift()};
1015     my $key = $fields{shift()};
1016     defined $key or die "Out of band access";
1017     $$self->[$key] = shift;
1018   }
1019   sub FETCH {
1020     my $self = ${shift()};
1021     my $key = $fields{shift()};
1022     defined $key or die "Out of band access";
1023     $$self->[$key];
1024   }
1025
1026 Now one can access an object using both the array and hash syntax:
1027
1028   my $bar = two_refs->new(3,4,5,6);
1029   $bar->[2] = 11;
1030   $bar->{two} == 11 or die 'bad hash fetch';
1031
1032 Note several important features of this example.  First of all, the
1033 I<actual> type of $bar is a scalar reference, and we do not overload
1034 the scalar dereference.  Thus we can get the I<actual> non-overloaded
1035 contents of $bar by just using C<$$bar> (what we do in functions which
1036 overload dereference).  Similarly, the object returned by the
1037 TIEHASH() method is a scalar reference.
1038
1039 Second, we create a new tied hash each time the hash syntax is used.
1040 This allows us not to worry about a possibility of a reference loop,
1041 which would lead to a memory leak.
1042
1043 Both these problems can be cured.  Say, if we want to overload hash
1044 dereference on a reference to an object which is I<implemented> as a
1045 hash itself, the only problem one has to circumvent is how to access
1046 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1047 overloaded dereference operator).  Here is one possible fetching routine:
1048
1049   sub access_hash {
1050     my ($self, $key) = (shift, shift);
1051     my $class = ref $self;
1052     bless $self, 'overload::dummy'; # Disable overloading of %{}
1053     my $out = $self->{$key};
1054     bless $self, $class;        # Restore overloading
1055     $out;
1056   }
1057
1058 To remove creation of the tied hash on each access, one may an extra
1059 level of indirection which allows a non-circular structure of references:
1060
1061   package two_refs1;
1062   use overload '%{}' => sub { ${shift()}->[1] },
1063                '@{}' => sub { ${shift()}->[0] };
1064   sub new {
1065     my $p = shift;
1066     my $a = [@_];
1067     my %h;
1068     tie %h, $p, $a;
1069     bless \ [$a, \%h], $p;
1070   }
1071   sub gethash {
1072     my %h;
1073     my $self = shift;
1074     tie %h, ref $self, $self;
1075     \%h;
1076   }
1077
1078   sub TIEHASH { my $p = shift; bless \ shift, $p }
1079   my %fields;
1080   my $i = 0;
1081   $fields{$_} = $i++ foreach qw{zero one two three};
1082   sub STORE {
1083     my $a = ${shift()};
1084     my $key = $fields{shift()};
1085     defined $key or die "Out of band access";
1086     $a->[$key] = shift;
1087   }
1088   sub FETCH {
1089     my $a = ${shift()};
1090     my $key = $fields{shift()};
1091     defined $key or die "Out of band access";
1092     $a->[$key];
1093   }
1094
1095 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1096 reference to the intermediate array, which keeps a reference to an
1097 actual array, and the access hash.  The tie()ing object for the access
1098 hash is a reference to a reference to the actual array, so
1099
1100 =over
1101
1102 =item *
1103
1104 There are no loops of references.
1105
1106 =item *
1107
1108 Both "objects" which are blessed into the class C<two_refs1> are
1109 references to a reference to an array, thus references to a I<scalar>.
1110 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1111 overloaded operations.
1112
1113 =back
1114
1115 =head2 Symbolic calculator
1116
1117 Put this in F<symbolic.pm> in your Perl library directory:
1118
1119   package symbolic;             # Primitive symbolic calculator
1120   use overload nomethod => \&wrap;
1121
1122   sub new { shift; bless ['n', @_] }
1123   sub wrap {
1124     my ($obj, $other, $inv, $meth) = @_;
1125     ($obj, $other) = ($other, $obj) if $inv;
1126     bless [$meth, $obj, $other];
1127   }
1128
1129 This module is very unusual as overloaded modules go: it does not
1130 provide any usual overloaded operators, instead it provides the L<Last
1131 Resort> operator C<nomethod>.  In this example the corresponding
1132 subroutine returns an object which encapsulates operations done over
1133 the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 +
1134 symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>.
1135
1136 Here is an example of the script which "calculates" the side of
1137 circumscribed octagon using the above package:
1138
1139   require symbolic;
1140   my $iter = 1;                 # 2**($iter+2) = 8
1141   my $side = symbolic->new(1);
1142   my $cnt = $iter;
1143
1144   while ($cnt--) {
1145     $side = (sqrt(1 + $side**2) - 1)/$side;
1146   }
1147   print "OK\n";
1148
1149 The value of $side is
1150
1151   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1152                        undef], 1], ['n', 1]]
1153
1154 Note that while we obtained this value using a nice little script,
1155 there is no simple way to I<use> this value.  In fact this value may
1156 be inspected in debugger (see L<perldebug>), but only if
1157 C<bareStringify> B<O>ption is set, and not via C<p> command.
1158
1159 If one attempts to print this value, then the overloaded operator
1160 C<""> will be called, which will call C<nomethod> operator.  The
1161 result of this operator will be stringified again, but this result is
1162 again of type C<symbolic>, which will lead to an infinite loop.
1163
1164 Add a pretty-printer method to the module F<symbolic.pm>:
1165
1166   sub pretty {
1167     my ($meth, $a, $b) = @{+shift};
1168     $a = 'u' unless defined $a;
1169     $b = 'u' unless defined $b;
1170     $a = $a->pretty if ref $a;
1171     $b = $b->pretty if ref $b;
1172     "[$meth $a $b]";
1173   }
1174
1175 Now one can finish the script by
1176
1177   print "side = ", $side->pretty, "\n";
1178
1179 The method C<pretty> is doing object-to-string conversion, so it
1180 is natural to overload the operator C<""> using this method.  However,
1181 inside such a method it is not necessary to pretty-print the
1182 I<components> $a and $b of an object.  In the above subroutine
1183 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1184 and $b.  If these components use overloading, the catenation operator
1185 will look for an overloaded operator C<.>; if not present, it will
1186 look for an overloaded operator C<"">.  Thus it is enough to use
1187
1188   use overload nomethod => \&wrap, '""' => \&str;
1189   sub str {
1190     my ($meth, $a, $b) = @{+shift};
1191     $a = 'u' unless defined $a;
1192     $b = 'u' unless defined $b;
1193     "[$meth $a $b]";
1194   }
1195
1196 Now one can change the last line of the script to
1197
1198   print "side = $side\n";
1199
1200 which outputs
1201
1202   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1203
1204 and one can inspect the value in debugger using all the possible
1205 methods.
1206
1207 Something is still amiss: consider the loop variable $cnt of the
1208 script.  It was a number, not an object.  We cannot make this value of
1209 type C<symbolic>, since then the loop will not terminate.
1210
1211 Indeed, to terminate the cycle, the $cnt should become false.
1212 However, the operator C<bool> for checking falsity is overloaded (this
1213 time via overloaded C<"">), and returns a long string, thus any object
1214 of type C<symbolic> is true.  To overcome this, we need a way to
1215 compare an object to 0.  In fact, it is easier to write a numeric
1216 conversion routine.
1217
1218 Here is the text of F<symbolic.pm> with such a routine added (and
1219 slightly modified str()):
1220
1221   package symbolic;             # Primitive symbolic calculator
1222   use overload
1223     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1224
1225   sub new { shift; bless ['n', @_] }
1226   sub wrap {
1227     my ($obj, $other, $inv, $meth) = @_;
1228     ($obj, $other) = ($other, $obj) if $inv;
1229     bless [$meth, $obj, $other];
1230   }
1231   sub str {
1232     my ($meth, $a, $b) = @{+shift};
1233     $a = 'u' unless defined $a;
1234     if (defined $b) {
1235       "[$meth $a $b]";
1236     } else {
1237       "[$meth $a]";
1238     }
1239   }
1240   my %subr = ( n => sub {$_[0]},
1241                sqrt => sub {sqrt $_[0]},
1242                '-' => sub {shift() - shift()},
1243                '+' => sub {shift() + shift()},
1244                '/' => sub {shift() / shift()},
1245                '*' => sub {shift() * shift()},
1246                '**' => sub {shift() ** shift()},
1247              );
1248   sub num {
1249     my ($meth, $a, $b) = @{+shift};
1250     my $subr = $subr{$meth}
1251       or die "Do not know how to ($meth) in symbolic";
1252     $a = $a->num if ref $a eq __PACKAGE__;
1253     $b = $b->num if ref $b eq __PACKAGE__;
1254     $subr->($a,$b);
1255   }
1256
1257 All the work of numeric conversion is done in %subr and num().  Of
1258 course, %subr is not complete, it contains only operators used in the
1259 example below.  Here is the extra-credit question: why do we need an
1260 explicit recursion in num()?  (Answer is at the end of this section.)
1261
1262 Use this module like this:
1263
1264   require symbolic;
1265   my $iter = symbolic->new(2);  # 16-gon
1266   my $side = symbolic->new(1);
1267   my $cnt = $iter;
1268
1269   while ($cnt) {
1270     $cnt = $cnt - 1;            # Mutator `--' not implemented
1271     $side = (sqrt(1 + $side**2) - 1)/$side;
1272   }
1273   printf "%s=%f\n", $side, $side;
1274   printf "pi=%f\n", $side*(2**($iter+2));
1275
1276 It prints (without so many line breaks)
1277
1278   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1279                           [n 1]] 2]]] 1]
1280      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1281   pi=3.182598
1282
1283 The above module is very primitive.  It does not implement
1284 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1285 (not required without mutators!), and implements only those arithmetic
1286 operations which are used in the example.
1287
1288 To implement most arithmetic operations is easy; one should just use
1289 the tables of operations, and change the code which fills %subr to
1290
1291   my %subr = ( 'n' => sub {$_[0]} );
1292   foreach my $op (split " ", $overload::ops{with_assign}) {
1293     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1294   }
1295   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1296   foreach my $op (split " ", "@overload::ops{ @bins }") {
1297     $subr{$op} = eval "sub {shift() $op shift()}";
1298   }
1299   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1300     print "defining `$op'\n";
1301     $subr{$op} = eval "sub {$op shift()}";
1302   }
1303
1304 Due to L<Calling Conventions for Mutators>, we do not need anything
1305 special to make C<+=> and friends work, except filling C<+=> entry of
1306 %subr, and defining a copy constructor (needed since Perl has no
1307 way to know that the implementation of C<'+='> does not mutate
1308 the argument, compare L<Copy Constructor>).
1309
1310 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1311 line, and code (this code assumes that mutators change things one level
1312 deep only, so recursive copying is not needed):
1313
1314   sub cpy {
1315     my $self = shift;
1316     bless [@$self], ref $self;
1317   }
1318
1319 To make C<++> and C<--> work, we need to implement actual mutators,
1320 either directly, or in C<nomethod>.  We continue to do things inside
1321 C<nomethod>, thus add
1322
1323     if ($meth eq '++' or $meth eq '--') {
1324       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1325       return $obj;
1326     }
1327
1328 after the first line of wrap().  This is not a most effective
1329 implementation, one may consider
1330
1331   sub inc { $_[0] = bless ['++', shift, 1]; }
1332
1333 instead.
1334
1335 As a final remark, note that one can fill %subr by
1336
1337   my %subr = ( 'n' => sub {$_[0]} );
1338   foreach my $op (split " ", $overload::ops{with_assign}) {
1339     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1340   }
1341   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1342   foreach my $op (split " ", "@overload::ops{ @bins }") {
1343     $subr{$op} = eval "sub {shift() $op shift()}";
1344   }
1345   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1346     $subr{$op} = eval "sub {$op shift()}";
1347   }
1348   $subr{'++'} = $subr{'+'};
1349   $subr{'--'} = $subr{'-'};
1350
1351 This finishes implementation of a primitive symbolic calculator in
1352 50 lines of Perl code.  Since the numeric values of subexpressions
1353 are not cached, the calculator is very slow.
1354
1355 Here is the answer for the exercise: In the case of str(), we need no
1356 explicit recursion since the overloaded C<.>-operator will fall back
1357 to an existing overloaded operator C<"">.  Overloaded arithmetic
1358 operators I<do not> fall back to numeric conversion if C<fallback> is
1359 not explicitly requested.  Thus without an explicit recursion num()
1360 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1361 the argument of num().
1362
1363 If you wonder why defaults for conversion are different for str() and
1364 num(), note how easy it was to write the symbolic calculator.  This
1365 simplicity is due to an appropriate choice of defaults.  One extra
1366 note: due to the explicit recursion num() is more fragile than sym():
1367 we need to explicitly check for the type of $a and $b.  If components
1368 $a and $b happen to be of some related type, this may lead to problems.
1369
1370 =head2 I<Really> symbolic calculator
1371
1372 One may wonder why we call the above calculator symbolic.  The reason
1373 is that the actual calculation of the value of expression is postponed
1374 until the value is I<used>.
1375
1376 To see it in action, add a method
1377
1378   sub STORE {
1379     my $obj = shift;
1380     $#$obj = 1;
1381     @$obj->[0,1] = ('=', shift);
1382   }
1383
1384 to the package C<symbolic>.  After this change one can do
1385
1386   my $a = symbolic->new(3);
1387   my $b = symbolic->new(4);
1388   my $c = sqrt($a**2 + $b**2);
1389
1390 and the numeric value of $c becomes 5.  However, after calling
1391
1392   $a->STORE(12);  $b->STORE(5);
1393
1394 the numeric value of $c becomes 13.  There is no doubt now that the module
1395 symbolic provides a I<symbolic> calculator indeed.
1396
1397 To hide the rough edges under the hood, provide a tie()d interface to the
1398 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1399
1400   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1401   sub FETCH { shift }
1402   sub nop {  }          # Around a bug
1403
1404 (the bug is described in L<"BUGS">).  One can use this new interface as
1405
1406   tie $a, 'symbolic', 3;
1407   tie $b, 'symbolic', 4;
1408   $a->nop;  $b->nop;    # Around a bug
1409
1410   my $c = sqrt($a**2 + $b**2);
1411
1412 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1413 of $c becomes 13.  To insulate the user of the module add a method
1414
1415   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1416
1417 Now
1418
1419   my ($a, $b);
1420   symbolic->vars($a, $b);
1421   my $c = sqrt($a**2 + $b**2);
1422
1423   $a = 3; $b = 4;
1424   printf "c5  %s=%f\n", $c, $c;
1425
1426   $a = 12; $b = 5;
1427   printf "c13  %s=%f\n", $c, $c;
1428
1429 shows that the numeric value of $c follows changes to the values of $a
1430 and $b.
1431
1432 =head1 AUTHOR
1433
1434 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1435
1436 =head1 SEE ALSO
1437
1438 The L<overloading> pragma can be used to enable or disable overloaded
1439 operations within a lexical scope.
1440
1441 =head1 DIAGNOSTICS
1442
1443 When Perl is run with the B<-Do> switch or its equivalent, overloading
1444 induces diagnostic messages.
1445
1446 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1447 deduce which operations are overloaded (and which ancestor triggers
1448 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1449 is shown by debugger. The method C<()> corresponds to the C<fallback>
1450 key (in fact a presence of this method shows that this package has
1451 overloading enabled, and it is what is used by the C<Overloaded>
1452 function of module C<overload>).
1453
1454 The module might issue the following warnings:
1455
1456 =over 4
1457
1458 =item Odd number of arguments for overload::constant
1459
1460 (W) The call to overload::constant contained an odd number of arguments.
1461 The arguments should come in pairs.
1462
1463 =item `%s' is not an overloadable type
1464
1465 (W) You tried to overload a constant type the overload package is unaware of.
1466
1467 =item `%s' is not a code reference
1468
1469 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1470 to be a code reference. Either an anonymous subroutine, or a reference
1471 to a subroutine.
1472
1473 =back
1474
1475 =head1 BUGS
1476
1477 Because it is used for overloading, the per-package hash %OVERLOAD now
1478 has a special meaning in Perl. The symbol table is filled with names
1479 looking like line-noise.
1480
1481 For the purpose of inheritance every overloaded package behaves as if
1482 C<fallback> is present (possibly undefined). This may create
1483 interesting effects if some package is not overloaded, but inherits
1484 from two overloaded packages.
1485
1486 Relation between overloading and tie()ing is broken.  Overloading is
1487 triggered or not basing on the I<previous> class of tie()d value.
1488
1489 This happens because the presence of overloading is checked too early,
1490 before any tie()d access is attempted.  If the FETCH()ed class of the
1491 tie()d value does not change, a simple workaround is to access the value
1492 immediately after tie()ing, so that after this call the I<previous> class
1493 coincides with the current one.
1494
1495 B<Needed:> a way to fix this without a speed penalty.
1496
1497 Barewords are not covered by overloaded string constants.
1498
1499 This document is confusing.  There are grammos and misleading language
1500 used in places.  It would seem a total rewrite is needed.
1501
1502 =cut
1503