Convert tied SPLICE to using Perl_tied_method()
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore most whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
93 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
99 whether space interpretation within a single multi-character construct.  For
100 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
101 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
102 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
103 but can between the C<(> and C<?>.  Within any delimiters for such a
104 construct, allowed spaces are not affected by C</x>, and depend on the
105 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
106 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
107 in C<\p{...}>  there can be spaces that follow the Unicode rules, for which see
108 L<perluniprops/Properties accessible through \p{} and \P{}>.
109 X</x>
110
111 =head2 Regular Expressions
112
113 =head3 Metacharacters
114
115 The patterns used in Perl pattern matching evolved from those supplied in
116 the Version 8 regex routines.  (The routines are derived
117 (distantly) from Henry Spencer's freely redistributable reimplementation
118 of the V8 routines.)  See L<Version 8 Regular Expressions> for
119 details.
120
121 In particular the following metacharacters have their standard I<egrep>-ish
122 meanings:
123 X<metacharacter>
124 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
125
126
127     \        Quote the next metacharacter
128     ^        Match the beginning of the line
129     .        Match any character (except newline)
130     $        Match the end of the line (or before newline at the end)
131     |        Alternation
132     ()       Grouping
133     []       Bracketed Character class
134
135 By default, the "^" character is guaranteed to match only the
136 beginning of the string, the "$" character only the end (or before the
137 newline at the end), and Perl does certain optimizations with the
138 assumption that the string contains only one line.  Embedded newlines
139 will not be matched by "^" or "$".  You may, however, wish to treat a
140 string as a multi-line buffer, such that the "^" will match after any
141 newline within the string (except if the newline is the last character in
142 the string), and "$" will match before any newline.  At the
143 cost of a little more overhead, you can do this by using the /m modifier
144 on the pattern match operator.  (Older programs did this by setting C<$*>,
145 but this practice has been removed in perl 5.9.)
146 X<^> X<$> X</m>
147
148 To simplify multi-line substitutions, the "." character never matches a
149 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
150 the string is a single line--even if it isn't.
151 X<.> X</s>
152
153 =head3 Quantifiers
154
155 The following standard quantifiers are recognized:
156 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
157
158     *           Match 0 or more times
159     +           Match 1 or more times
160     ?           Match 1 or 0 times
161     {n}         Match exactly n times
162     {n,}        Match at least n times
163     {n,m}       Match at least n but not more than m times
164
165 (If a curly bracket occurs in any other context, it is treated
166 as a regular character.  In particular, the lower bound
167 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
168 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
169 to non-negative integral values less than a preset limit defined when perl is built.
170 This is usually 32766 on the most common platforms.  The actual limit can
171 be seen in the error message generated by code such as this:
172
173     $_ **= $_ , / {$_} / for 2 .. 42;
174
175 By default, a quantified subpattern is "greedy", that is, it will match as
176 many times as possible (given a particular starting location) while still
177 allowing the rest of the pattern to match.  If you want it to match the
178 minimum number of times possible, follow the quantifier with a "?".  Note
179 that the meanings don't change, just the "greediness":
180 X<metacharacter> X<greedy> X<greediness>
181 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
182
183     *?        Match 0 or more times, not greedily
184     +?        Match 1 or more times, not greedily
185     ??        Match 0 or 1 time, not greedily
186     {n}?      Match exactly n times, not greedily
187     {n,}?     Match at least n times, not greedily
188     {n,m}?    Match at least n but not more than m times, not greedily
189
190 By default, when a quantified subpattern does not allow the rest of the
191 overall pattern to match, Perl will backtrack. However, this behaviour is
192 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
193 as well.
194
195  *+     Match 0 or more times and give nothing back
196  ++     Match 1 or more times and give nothing back
197  ?+     Match 0 or 1 time and give nothing back
198  {n}+   Match exactly n times and give nothing back (redundant)
199  {n,}+  Match at least n times and give nothing back
200  {n,m}+ Match at least n but not more than m times and give nothing back
201
202 For instance,
203
204    'aaaa' =~ /a++a/
205
206 will never match, as the C<a++> will gobble up all the C<a>'s in the
207 string and won't leave any for the remaining part of the pattern. This
208 feature can be extremely useful to give perl hints about where it
209 shouldn't backtrack. For instance, the typical "match a double-quoted
210 string" problem can be most efficiently performed when written as:
211
212    /"(?:[^"\\]++|\\.)*+"/
213
214 as we know that if the final quote does not match, backtracking will not
215 help. See the independent subexpression C<< (?>...) >> for more details;
216 possessive quantifiers are just syntactic sugar for that construct. For
217 instance the above example could also be written as follows:
218
219    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
220
221 =head3 Escape sequences
222
223 Because patterns are processed as double quoted strings, the following
224 also work:
225
226  \t          tab                   (HT, TAB)
227  \n          newline               (LF, NL)
228  \r          return                (CR)
229  \f          form feed             (FF)
230  \a          alarm (bell)          (BEL)
231  \e          escape (think troff)  (ESC)
232  \cK         control char          (example: VT)
233  \x{}, \x00  character whose ordinal is the given hexadecimal number
234  \N{name}    named Unicode character or character sequence
235  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
236  \o{}, \000  character whose ordinal is the given octal number
237  \l          lowercase next char (think vi)
238  \u          uppercase next char (think vi)
239  \L          lowercase till \E (think vi)
240  \U          uppercase till \E (think vi)
241  \Q          quote (disable) pattern metacharacters till \E
242  \E          end either case modification or quoted section, think vi
243
244 Details are in L<perlop/Quote and Quote-like Operators>.
245
246 =head3 Character Classes and other Special Escapes
247
248 In addition, Perl defines the following:
249 X<\g> X<\k> X<\K> X<backreference>
250
251  Sequence   Note    Description
252   [...]     [1]  Match a character according to the rules of the
253                    bracketed character class defined by the "...".
254                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
255   [[:...:]] [2]  Match a character according to the rules of the POSIX
256                    character class "..." within the outer bracketed
257                    character class.  Example: [[:upper:]] matches any
258                    uppercase character.
259   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
260                    other connector punctuation chars plus Unicode
261                    marks
262   \W        [3]  Match a non-"word" character
263   \s        [3]  Match a whitespace character
264   \S        [3]  Match a non-whitespace character
265   \d        [3]  Match a decimal digit character
266   \D        [3]  Match a non-digit character
267   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
268   \PP       [3]  Match non-P
269   \X        [4]  Match Unicode "eXtended grapheme cluster"
270   \C             Match a single C-language char (octet) even if that is
271                    part of a larger UTF-8 character.  Thus it breaks up
272                    characters into their UTF-8 bytes, so you may end up
273                    with malformed pieces of UTF-8.  Unsupported in
274                    lookbehind.
275   \1        [5]  Backreference to a specific capture group or buffer.
276                    '1' may actually be any positive integer.
277   \g1       [5]  Backreference to a specific or previous group,
278   \g{-1}    [5]  The number may be negative indicating a relative
279                    previous group and may optionally be wrapped in
280                    curly brackets for safer parsing.
281   \g{name}  [5]  Named backreference
282   \k<name>  [5]  Named backreference
283   \K        [6]  Keep the stuff left of the \K, don't include it in $&
284   \N        [7]  Any character but \n (experimental).  Not affected by
285                    /s modifier
286   \v        [3]  Vertical whitespace
287   \V        [3]  Not vertical whitespace
288   \h        [3]  Horizontal whitespace
289   \H        [3]  Not horizontal whitespace
290   \R        [4]  Linebreak
291
292 =over 4
293
294 =item [1]
295
296 See L<perlrecharclass/Bracketed Character Classes> for details.
297
298 =item [2]
299
300 See L<perlrecharclass/POSIX Character Classes> for details.
301
302 =item [3]
303
304 See L<perlrecharclass/Backslash sequences> for details.
305
306 =item [4]
307
308 See L<perlrebackslash/Misc> for details.
309
310 =item [5]
311
312 See L</Capture groups> below for details.
313
314 =item [6]
315
316 See L</Extended Patterns> below for details.
317
318 =item [7]
319
320 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
321 character or character sequence whose name is C<NAME>; and similarly
322 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
323 code point is I<hex>.  Otherwise it matches any character but C<\n>.
324
325 =back
326
327 =head3 Assertions
328
329 Perl defines the following zero-width assertions:
330 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
331 X<regexp, zero-width assertion>
332 X<regular expression, zero-width assertion>
333 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
334
335     \b  Match a word boundary
336     \B  Match except at a word boundary
337     \A  Match only at beginning of string
338     \Z  Match only at end of string, or before newline at the end
339     \z  Match only at end of string
340     \G  Match only at pos() (e.g. at the end-of-match position
341         of prior m//g)
342
343 A word boundary (C<\b>) is a spot between two characters
344 that has a C<\w> on one side of it and a C<\W> on the other side
345 of it (in either order), counting the imaginary characters off the
346 beginning and end of the string as matching a C<\W>.  (Within
347 character classes C<\b> represents backspace rather than a word
348 boundary, just as it normally does in any double-quoted string.)
349 The C<\A> and C<\Z> are just like "^" and "$", except that they
350 won't match multiple times when the C</m> modifier is used, while
351 "^" and "$" will match at every internal line boundary.  To match
352 the actual end of the string and not ignore an optional trailing
353 newline, use C<\z>.
354 X<\b> X<\A> X<\Z> X<\z> X</m>
355
356 The C<\G> assertion can be used to chain global matches (using
357 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
358 It is also useful when writing C<lex>-like scanners, when you have
359 several patterns that you want to match against consequent substrings
360 of your string, see the previous reference.  The actual location
361 where C<\G> will match can also be influenced by using C<pos()> as
362 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
363 matches is modified somewhat, in that contents to the left of C<\G> is
364 not counted when determining the length of the match. Thus the following
365 will not match forever:
366 X<\G>
367
368      my $string = 'ABC';
369      pos($string) = 1;
370      while ($string =~ /(.\G)/g) {
371          print $1;
372      }
373
374 It will print 'A' and then terminate, as it considers the match to
375 be zero-width, and thus will not match at the same position twice in a
376 row.
377
378 It is worth noting that C<\G> improperly used can result in an infinite
379 loop. Take care when using patterns that include C<\G> in an alternation.
380
381 =head3 Capture groups
382
383 The bracketing construct C<( ... )> creates capture groups (also referred to as
384 capture buffers). To refer to the current contents of a group later on, within
385 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
386 for the second, and so on.
387 This is called a I<backreference>.
388 X<regex, capture buffer> X<regexp, capture buffer>
389 X<regex, capture group> X<regexp, capture group>
390 X<regular expression, capture buffer> X<backreference>
391 X<regular expression, capture group> X<backreference>
392 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
393 X<named capture buffer> X<regular expression, named capture buffer>
394 X<named capture group> X<regular expression, named capture group>
395 X<%+> X<$+{name}> X<< \k<name> >>
396 There is no limit to the number of captured substrings that you may use.
397 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
398 a group did not match, the associated backreference won't match either. (This
399 can happen if the group is optional, or in a different branch of an
400 alternation.)
401 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
402 this form, described below.
403
404 You can also refer to capture groups relatively, by using a negative number, so
405 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
406 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
407 example:
408
409         /
410          (Y)            # group 1
411          (              # group 2
412             (X)         # group 3
413             \g{-1}      # backref to group 3
414             \g{-3}      # backref to group 1
415          )
416         /x
417
418 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
419 interpolate regexes into larger regexes and not have to worry about the
420 capture groups being renumbered.
421
422 You can dispense with numbers altogether and create named capture groups.
423 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
424 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
425 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
426 I<name> must not begin with a number, nor contain hyphens.
427 When different groups within the same pattern have the same name, any reference
428 to that name assumes the leftmost defined group.  Named groups count in
429 absolute and relative numbering, and so can also be referred to by those
430 numbers.
431 (It's possible to do things with named capture groups that would otherwise
432 require C<(??{})>.)
433
434 Capture group contents are dynamically scoped and available to you outside the
435 pattern until the end of the enclosing block or until the next successful
436 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
437 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
438 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
439
440 Braces are required in referring to named capture groups, but are optional for
441 absolute or relative numbered ones.  Braces are safer when creating a regex by
442 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
443 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
444 is probably not what you intended.
445
446 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
447 there were no named nor relative numbered capture groups.  Absolute numbered
448 groups were referred to using C<\1>, C<\2>, etc, and this notation is still
449 accepted (and likely always will be).  But it leads to some ambiguities if
450 there are more than 9 capture groups, as C<\10> could mean either the tenth
451 capture group, or the character whose ordinal in octal is 010 (a backspace in
452 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
453 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
454 a backreference only if at least 11 left parentheses have opened before it.
455 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
456 There are several examples below that illustrate these perils.  You can avoid
457 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
458 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
459 digits padded with leading zeros, since a leading zero implies an octal
460 constant.
461
462 The C<\I<digit>> notation also works in certain circumstances outside
463 the pattern.  See L</Warning on \1 Instead of $1> below for details.)
464
465 Examples:
466
467     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
468
469     /(.)\g1/                        # find first doubled char
470          and print "'$1' is the first doubled character\n";
471
472     /(?<char>.)\k<char>/            # ... a different way
473          and print "'$+{char}' is the first doubled character\n";
474
475     /(?'char'.)\g1/                 # ... mix and match
476          and print "'$1' is the first doubled character\n";
477
478     if (/Time: (..):(..):(..)/) {   # parse out values
479         $hours = $1;
480         $minutes = $2;
481         $seconds = $3;
482     }
483
484     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
485     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
486     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
487     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
488
489     $a = '(.)\1';        # Creates problems when concatenated.
490     $b = '(.)\g{1}';     # Avoids the problems.
491     "aa" =~ /${a}/;      # True
492     "aa" =~ /${b}/;      # True
493     "aa0" =~ /${a}0/;    # False!
494     "aa0" =~ /${b}0/;    # True
495     "aa\x08" =~ /${a}0/;  # True!
496     "aa\x08" =~ /${b}0/;  # False
497
498 Several special variables also refer back to portions of the previous
499 match.  C<$+> returns whatever the last bracket match matched.
500 C<$&> returns the entire matched string.  (At one point C<$0> did
501 also, but now it returns the name of the program.)  C<$`> returns
502 everything before the matched string.  C<$'> returns everything
503 after the matched string. And C<$^N> contains whatever was matched by
504 the most-recently closed group (submatch). C<$^N> can be used in
505 extended patterns (see below), for example to assign a submatch to a
506 variable.
507 X<$+> X<$^N> X<$&> X<$`> X<$'>
508
509 These special variables, like the C<%+> hash and the numbered match variables
510 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
511 until the end of the enclosing block or until the next successful
512 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
513 X<$+> X<$^N> X<$&> X<$`> X<$'>
514 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
515
516 B<NOTE>: Failed matches in Perl do not reset the match variables,
517 which makes it easier to write code that tests for a series of more
518 specific cases and remembers the best match.
519
520 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
521 C<$'> anywhere in the program, it has to provide them for every
522 pattern match.  This may substantially slow your program.  Perl
523 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
524 price for each pattern that contains capturing parentheses.  (To
525 avoid this cost while retaining the grouping behaviour, use the
526 extended regular expression C<(?: ... )> instead.)  But if you never
527 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
528 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
529 if you can, but if you can't (and some algorithms really appreciate
530 them), once you've used them once, use them at will, because you've
531 already paid the price.  As of 5.005, C<$&> is not so costly as the
532 other two.
533 X<$&> X<$`> X<$'>
534
535 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
536 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
537 and C<$'>, B<except> that they are only guaranteed to be defined after a
538 successful match that was executed with the C</p> (preserve) modifier.
539 The use of these variables incurs no global performance penalty, unlike
540 their punctuation char equivalents, however at the trade-off that you
541 have to tell perl when you want to use them.
542 X</p> X<p modifier>
543
544 =head2 Quoting metacharacters
545
546 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
547 C<\w>, C<\n>.  Unlike some other regular expression languages, there
548 are no backslashed symbols that aren't alphanumeric.  So anything
549 that looks like \\, \(, \), \<, \>, \{, or \} is always
550 interpreted as a literal character, not a metacharacter.  This was
551 once used in a common idiom to disable or quote the special meanings
552 of regular expression metacharacters in a string that you want to
553 use for a pattern. Simply quote all non-"word" characters:
554
555     $pattern =~ s/(\W)/\\$1/g;
556
557 (If C<use locale> is set, then this depends on the current locale.)
558 Today it is more common to use the quotemeta() function or the C<\Q>
559 metaquoting escape sequence to disable all metacharacters' special
560 meanings like this:
561
562     /$unquoted\Q$quoted\E$unquoted/
563
564 Beware that if you put literal backslashes (those not inside
565 interpolated variables) between C<\Q> and C<\E>, double-quotish
566 backslash interpolation may lead to confusing results.  If you
567 I<need> to use literal backslashes within C<\Q...\E>,
568 consult L<perlop/"Gory details of parsing quoted constructs">.
569
570 =head2 Extended Patterns
571
572 Perl also defines a consistent extension syntax for features not
573 found in standard tools like B<awk> and B<lex>.  The syntax is a
574 pair of parentheses with a question mark as the first thing within
575 the parentheses.  The character after the question mark indicates
576 the extension.
577
578 The stability of these extensions varies widely.  Some have been
579 part of the core language for many years.  Others are experimental
580 and may change without warning or be completely removed.  Check
581 the documentation on an individual feature to verify its current
582 status.
583
584 A question mark was chosen for this and for the minimal-matching
585 construct because 1) question marks are rare in older regular
586 expressions, and 2) whenever you see one, you should stop and
587 "question" exactly what is going on.  That's psychology...
588
589 =over 10
590
591 =item C<(?#text)>
592 X<(?#)>
593
594 A comment.  The text is ignored.  If the C</x> modifier enables
595 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
596 the comment as soon as it sees a C<)>, so there is no way to put a literal
597 C<)> in the comment.
598
599 =item C<(?dlupimsx-imsx)>
600
601 =item C<(?^lupimsx)>
602 X<(?)> X<(?^)>
603
604 One or more embedded pattern-match modifiers, to be turned on (or
605 turned off, if preceded by C<->) for the remainder of the pattern or
606 the remainder of the enclosing pattern group (if any).
607
608 This is particularly useful for dynamic patterns, such as those read in from a
609 configuration file, taken from an argument, or specified in a table
610 somewhere.  Consider the case where some patterns want to be case
611 sensitive and some do not:  The case insensitive ones merely need to
612 include C<(?i)> at the front of the pattern.  For example:
613
614     $pattern = "foobar";
615     if ( /$pattern/i ) { }
616
617     # more flexible:
618
619     $pattern = "(?i)foobar";
620     if ( /$pattern/ ) { }
621
622 These modifiers are restored at the end of the enclosing group. For example,
623
624     ( (?i) blah ) \s+ \g1
625
626 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
627 repetition of the previous word, assuming the C</x> modifier, and no C</i>
628 modifier outside this group.
629
630 These modifiers do not carry over into named subpatterns called in the
631 enclosing group. In other words, a pattern such as C<((?i)(&NAME))> does not
632 change the case-sensitivity of the "NAME" pattern.
633
634 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
635 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
636 C<"d">) may follow the caret to override it.
637 But a minus sign is not legal with it.
638
639 Also, starting in Perl 5.14, are modifiers C<"d">, C<"l">, and C<"u">,
640 which for 5.14 may not be used as suffix modifiers.
641
642 C<"l"> means to use a locale (see L<perllocale>) when pattern matching.
643 The locale used will be the one in effect at the time of execution of
644 the pattern match.  This may not be the same as the compilation-time
645 locale, and can differ from one match to another if there is an
646 intervening call of the
647 L<setlocale() function|perllocale/The setlocale function>.
648 This modifier is automatically set if the regular expression is compiled
649 within the scope of a C<"use locale"> pragma.  Results are not
650 well-defined when using this and matching against a utf8-encoded string.
651
652 C<"u"> means to use Unicode semantics when pattern matching.  It is
653 automatically set if the regular expression is encoded in utf8, or is
654 compiled within the scope of a
655 L<C<"use feature 'unicode_strings">|feature> pragma (and isn't also in
656 the scope of L<C<"use locale">|locale> nor L<C<"use bytes">|bytes>
657 pragmas.  On ASCII platforms, the code points between 128 and 255 take on their
658 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's), whereas
659 in strict ASCII their meanings are undefined.  Thus the platform
660 effectively becomes a Unicode platform.  The ASCII characters remain as
661 ASCII characters (since ASCII is a subset of Latin-1 and Unicode).  For
662 example, when this option is not on, on a non-utf8 string, C<"\w">
663 matches precisely C<[A-Za-z0-9_]>.  When the option is on, it matches
664 not just those, but all the Latin-1 word characters (such as an "n" with
665 a tilde).  On EBCDIC platforms, which already are equivalent to Latin-1,
666 this modifier changes behavior only when the C<"/i"> modifier is also
667 specified, and affects only two characters, giving them full Unicode
668 semantics: the C<MICRO SIGN> will match the Greek capital and
669 small letters C<MU>; otherwise not; and the C<LATIN CAPITAL LETTER SHARP
670 S> will match any of C<SS>, C<Ss>, C<sS>, and C<ss>, otherwise not.
671 (This last case is buggy, however.)
672
673 C<"d"> means to use the traditional Perl pattern matching behavior.
674 This is dualistic (hence the name C<"d">, which also could stand for
675 "depends").  When this is in effect, Perl matches utf8-encoded strings
676 using Unicode rules, and matches non-utf8-encoded strings using the
677 platform's native character set rules.  (If the regular expression
678 itself is encoded in utf8, Unicode rules are used regardless of the
679 target string's encoding.)
680 See L<perlunicode/The "Unicode Bug">.  It is automatically selected by
681 default if the regular expression is compiled neither within the scope
682 of a C<"use locale"> pragma nor a <C<"use feature 'unicode_strings">
683 pragma.
684
685 Note that the C<d>, C<l>, C<p>, and C<u> modifiers are special in that
686 they can only be enabled, not disabled, and the C<d>, C<l>, and C<u>
687 modifiers are mutually exclusive: specifying one de-specifies the
688 others, and a maximum of one may appear in the construct.  Thus, for
689 example, C<(?-p)>, C<(?-d:...)>, and C<(?dl:...)> will warn when
690 compiled under C<use warnings>.
691
692 Note also that the C<p> modifier is special in that its presence
693 anywhere in a pattern has a global effect.
694
695 =item C<(?:pattern)>
696 X<(?:)>
697
698 =item C<(?dluimsx-imsx:pattern)>
699
700 =item C<(?^luimsx:pattern)>
701 X<(?^:)>
702
703 This is for clustering, not capturing; it groups subexpressions like
704 "()", but doesn't make backreferences as "()" does.  So
705
706     @fields = split(/\b(?:a|b|c)\b/)
707
708 is like
709
710     @fields = split(/\b(a|b|c)\b/)
711
712 but doesn't spit out extra fields.  It's also cheaper not to capture
713 characters if you don't need to.
714
715 Any letters between C<?> and C<:> act as flags modifiers as with
716 C<(?dluimsx-imsx)>.  For example,
717
718     /(?s-i:more.*than).*million/i
719
720 is equivalent to the more verbose
721
722     /(?:(?s-i)more.*than).*million/i
723
724 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
725 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
726 flags (except C<"d">) may follow the caret, so
727
728     (?^x:foo)
729
730 is equivalent to
731
732     (?x-ims:foo)
733
734 The caret tells Perl that this cluster doesn't inherit the flags of any
735 surrounding pattern, but to go back to the system defaults (C<d-imsx>),
736 modified by any flags specified.
737
738 The caret allows for simpler stringification of compiled regular
739 expressions.  These look like
740
741     (?^:pattern)
742
743 with any non-default flags appearing between the caret and the colon.
744 A test that looks at such stringification thus doesn't need to have the
745 system default flags hard-coded in it, just the caret.  If new flags are
746 added to Perl, the meaning of the caret's expansion will change to include
747 the default for those flags, so the test will still work, unchanged.
748
749 Specifying a negative flag after the caret is an error, as the flag is
750 redundant.
751
752 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
753 to match at the beginning.
754
755 =item C<(?|pattern)>
756 X<(?|)> X<Branch reset>
757
758 This is the "branch reset" pattern, which has the special property
759 that the capture groups are numbered from the same starting point
760 in each alternation branch. It is available starting from perl 5.10.0.
761
762 Capture groups are numbered from left to right, but inside this
763 construct the numbering is restarted for each branch.
764
765 The numbering within each branch will be as normal, and any groups
766 following this construct will be numbered as though the construct
767 contained only one branch, that being the one with the most capture
768 groups in it.
769
770 This construct will be useful when you want to capture one of a
771 number of alternative matches.
772
773 Consider the following pattern.  The numbers underneath show in
774 which group the captured content will be stored.
775
776
777     # before  ---------------branch-reset----------- after        
778     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
779     # 1            2         2  3        2     3     4  
780
781 Be careful when using the branch reset pattern in combination with 
782 named captures. Named captures are implemented as being aliases to 
783 numbered groups holding the captures, and that interferes with the
784 implementation of the branch reset pattern. If you are using named
785 captures in a branch reset pattern, it's best to use the same names,
786 in the same order, in each of the alternations:
787
788    /(?|  (?<a> x ) (?<b> y )
789       |  (?<a> z ) (?<b> w )) /x
790
791 Not doing so may lead to surprises:
792
793   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
794   say $+ {a};   # Prints '12'
795   say $+ {b};   # *Also* prints '12'.
796
797 The problem here is that both the group named C<< a >> and the group
798 named C<< b >> are aliases for the group belonging to C<< $1 >>.
799
800 =item Look-Around Assertions
801 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
802
803 Look-around assertions are zero width patterns which match a specific
804 pattern without including it in C<$&>. Positive assertions match when
805 their subpattern matches, negative assertions match when their subpattern
806 fails. Look-behind matches text up to the current match position,
807 look-ahead matches text following the current match position.
808
809 =over 4
810
811 =item C<(?=pattern)>
812 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
813
814 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
815 matches a word followed by a tab, without including the tab in C<$&>.
816
817 =item C<(?!pattern)>
818 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
819
820 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
821 matches any occurrence of "foo" that isn't followed by "bar".  Note
822 however that look-ahead and look-behind are NOT the same thing.  You cannot
823 use this for look-behind.
824
825 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
826 will not do what you want.  That's because the C<(?!foo)> is just saying that
827 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
828 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
829 say "like" because there's the case of your "bar" not having three characters
830 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
831 Sometimes it's still easier just to say:
832
833     if (/bar/ && $` !~ /foo$/)
834
835 For look-behind see below.
836
837 =item C<(?<=pattern)> C<\K>
838 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
839
840 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
841 matches a word that follows a tab, without including the tab in C<$&>.
842 Works only for fixed-width look-behind.
843
844 There is a special form of this construct, called C<\K>, which causes the
845 regex engine to "keep" everything it had matched prior to the C<\K> and
846 not include it in C<$&>. This effectively provides variable length
847 look-behind. The use of C<\K> inside of another look-around assertion
848 is allowed, but the behaviour is currently not well defined.
849
850 For various reasons C<\K> may be significantly more efficient than the
851 equivalent C<< (?<=...) >> construct, and it is especially useful in
852 situations where you want to efficiently remove something following
853 something else in a string. For instance
854
855   s/(foo)bar/$1/g;
856
857 can be rewritten as the much more efficient
858
859   s/foo\Kbar//g;
860
861 =item C<(?<!pattern)>
862 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
863
864 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
865 matches any occurrence of "foo" that does not follow "bar".  Works
866 only for fixed-width look-behind.
867
868 =back
869
870 =item C<(?'NAME'pattern)>
871
872 =item C<< (?<NAME>pattern) >>
873 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
874
875 A named capture group. Identical in every respect to normal capturing
876 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
877 used after a successful match to refer to a named group. See C<perlvar>
878 for more details on the C<%+> and C<%-> hashes.
879
880 If multiple distinct capture groups have the same name then the
881 $+{NAME} will refer to the leftmost defined group in the match.
882
883 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
884
885 B<NOTE:> While the notation of this construct is the same as the similar
886 function in .NET regexes, the behavior is not. In Perl the groups are
887 numbered sequentially regardless of being named or not. Thus in the
888 pattern
889
890   /(x)(?<foo>y)(z)/
891
892 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
893 the opposite which is what a .NET regex hacker might expect.
894
895 Currently NAME is restricted to simple identifiers only.
896 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
897 its Unicode extension (see L<utf8>),
898 though it isn't extended by the locale (see L<perllocale>).
899
900 B<NOTE:> In order to make things easier for programmers with experience
901 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
902 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
903 support the use of single quotes as a delimiter for the name.
904
905 =item C<< \k<NAME> >>
906
907 =item C<< \k'NAME' >>
908
909 Named backreference. Similar to numeric backreferences, except that
910 the group is designated by name and not number. If multiple groups
911 have the same name then it refers to the leftmost defined group in
912 the current match.
913
914 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
915 earlier in the pattern.
916
917 Both forms are equivalent.
918
919 B<NOTE:> In order to make things easier for programmers with experience
920 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
921 may be used instead of C<< \k<NAME> >>.
922
923 =item C<(?{ code })>
924 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
925
926 B<WARNING>: This extended regular expression feature is considered
927 experimental, and may be changed without notice. Code executed that
928 has side effects may not perform identically from version to version
929 due to the effect of future optimisations in the regex engine.
930
931 This zero-width assertion evaluates any embedded Perl code.  It
932 always succeeds, and its C<code> is not interpolated.  Currently,
933 the rules to determine where the C<code> ends are somewhat convoluted.
934
935 This feature can be used together with the special variable C<$^N> to
936 capture the results of submatches in variables without having to keep
937 track of the number of nested parentheses. For example:
938
939   $_ = "The brown fox jumps over the lazy dog";
940   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
941   print "color = $color, animal = $animal\n";
942
943 Inside the C<(?{...})> block, C<$_> refers to the string the regular
944 expression is matching against. You can also use C<pos()> to know what is
945 the current position of matching within this string.
946
947 The C<code> is properly scoped in the following sense: If the assertion
948 is backtracked (compare L<"Backtracking">), all changes introduced after
949 C<local>ization are undone, so that
950
951   $_ = 'a' x 8;
952   m<
953      (?{ $cnt = 0 })                   # Initialize $cnt.
954      (
955        a
956        (?{
957            local $cnt = $cnt + 1;      # Update $cnt, backtracking-safe.
958        })
959      )*
960      aaaa
961      (?{ $res = $cnt })                # On success copy to
962                                        # non-localized location.
963    >x;
964
965 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
966 introduced value, because the scopes that restrict C<local> operators
967 are unwound.
968
969 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
970 switch.  If I<not> used in this way, the result of evaluation of
971 C<code> is put into the special variable C<$^R>.  This happens
972 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
973 inside the same regular expression.
974
975 The assignment to C<$^R> above is properly localized, so the old
976 value of C<$^R> is restored if the assertion is backtracked; compare
977 L<"Backtracking">.
978
979 For reasons of security, this construct is forbidden if the regular
980 expression involves run-time interpolation of variables, unless the
981 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
982 variables contain results of C<qr//> operator (see
983 L<perlop/"qr/STRINGE<sol>msixpo">).
984
985 This restriction is due to the wide-spread and remarkably convenient
986 custom of using run-time determined strings as patterns.  For example:
987
988     $re = <>;
989     chomp $re;
990     $string =~ /$re/;
991
992 Before Perl knew how to execute interpolated code within a pattern,
993 this operation was completely safe from a security point of view,
994 although it could raise an exception from an illegal pattern.  If
995 you turn on the C<use re 'eval'>, though, it is no longer secure,
996 so you should only do so if you are also using taint checking.
997 Better yet, use the carefully constrained evaluation within a Safe
998 compartment.  See L<perlsec> for details about both these mechanisms.
999
1000 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1001 broken. The result is unpredictable and will make perl unstable. The
1002 workaround is to use global (C<our>) variables.
1003
1004 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1005 was not re-entrant, so interpolated code could not
1006 safely invoke the regex engine either directly with
1007 C<m//> or C<s///>), or indirectly with functions such as
1008 C<split>. Invoking the regex engine in these blocks would make perl
1009 unstable.
1010
1011 =item C<(??{ code })>
1012 X<(??{})>
1013 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1014
1015 B<WARNING>: This extended regular expression feature is considered
1016 experimental, and may be changed without notice. Code executed that
1017 has side effects may not perform identically from version to version
1018 due to the effect of future optimisations in the regex engine.
1019
1020 This is a "postponed" regular subexpression.  The C<code> is evaluated
1021 at run time, at the moment this subexpression may match.  The result
1022 of evaluation is considered as a regular expression and matched as
1023 if it were inserted instead of this construct.  Note that this means
1024 that the contents of capture groups defined inside an eval'ed pattern
1025 are not available outside of the pattern, and vice versa, there is no
1026 way for the inner pattern to refer to a capture group defined outside.
1027 Thus,
1028
1029     ('a' x 100)=~/(??{'(.)' x 100})/
1030
1031 B<will> match, it will B<not> set $1.
1032
1033 The C<code> is not interpolated.  As before, the rules to determine
1034 where the C<code> ends are currently somewhat convoluted.
1035
1036 The following pattern matches a parenthesized group:
1037
1038   $re = qr{
1039              \(
1040              (?:
1041                 (?> [^()]+ )       # Non-parens without backtracking
1042               |
1043                 (??{ $re })        # Group with matching parens
1044              )*
1045              \)
1046           }x;
1047
1048 See also C<(?PARNO)> for a different, more efficient way to accomplish
1049 the same task.
1050
1051 For reasons of security, this construct is forbidden if the regular
1052 expression involves run-time interpolation of variables, unless the
1053 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1054 variables contain results of C<qr//> operator (see
1055 L<perlop/"qrE<sol>STRINGE<sol>msixpo">).
1056
1057 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1058 delayed code could not safely invoke the regex engine either directly with
1059 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1060
1061 Recursing deeper than 50 times without consuming any input string will
1062 result in a fatal error.  The maximum depth is compiled into perl, so
1063 changing it requires a custom build.
1064
1065 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1066 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1067 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1068 X<regex, relative recursion>
1069
1070 Similar to C<(??{ code })> except it does not involve compiling any code,
1071 instead it treats the contents of a capture group as an independent
1072 pattern that must match at the current position.  Capture groups
1073 contained by the pattern will have the value as determined by the
1074 outermost recursion.
1075
1076 PARNO is a sequence of digits (not starting with 0) whose value reflects
1077 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1078 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1079 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1080 to be relative, with negative numbers indicating preceding capture groups
1081 and positive ones following. Thus C<(?-1)> refers to the most recently
1082 declared group, and C<(?+1)> indicates the next group to be declared.
1083 Note that the counting for relative recursion differs from that of
1084 relative backreferences, in that with recursion unclosed groups B<are>
1085 included.
1086
1087 The following pattern matches a function foo() which may contain
1088 balanced parentheses as the argument.
1089
1090   $re = qr{ (                    # paren group 1 (full function)
1091               foo
1092               (                  # paren group 2 (parens)
1093                 \(
1094                   (              # paren group 3 (contents of parens)
1095                   (?:
1096                    (?> [^()]+ )  # Non-parens without backtracking
1097                   |
1098                    (?2)          # Recurse to start of paren group 2
1099                   )*
1100                   )
1101                 \)
1102               )
1103             )
1104           }x;
1105
1106 If the pattern was used as follows
1107
1108     'foo(bar(baz)+baz(bop))'=~/$re/
1109         and print "\$1 = $1\n",
1110                   "\$2 = $2\n",
1111                   "\$3 = $3\n";
1112
1113 the output produced should be the following:
1114
1115     $1 = foo(bar(baz)+baz(bop))
1116     $2 = (bar(baz)+baz(bop))
1117     $3 = bar(baz)+baz(bop)
1118
1119 If there is no corresponding capture group defined, then it is a
1120 fatal error.  Recursing deeper than 50 times without consuming any input
1121 string will also result in a fatal error.  The maximum depth is compiled
1122 into perl, so changing it requires a custom build.
1123
1124 The following shows how using negative indexing can make it
1125 easier to embed recursive patterns inside of a C<qr//> construct
1126 for later use:
1127
1128     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1129     if (/foo $parens \s+ + \s+ bar $parens/x) {
1130        # do something here...
1131     }
1132
1133 B<Note> that this pattern does not behave the same way as the equivalent
1134 PCRE or Python construct of the same form. In Perl you can backtrack into
1135 a recursed group, in PCRE and Python the recursed into group is treated
1136 as atomic. Also, modifiers are resolved at compile time, so constructs
1137 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1138 be processed.
1139
1140 =item C<(?&NAME)>
1141 X<(?&NAME)>
1142
1143 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1144 parenthesis to recurse to is determined by name. If multiple parentheses have
1145 the same name, then it recurses to the leftmost.
1146
1147 It is an error to refer to a name that is not declared somewhere in the
1148 pattern.
1149
1150 B<NOTE:> In order to make things easier for programmers with experience
1151 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1152 may be used instead of C<< (?&NAME) >>.
1153
1154 =item C<(?(condition)yes-pattern|no-pattern)>
1155 X<(?()>
1156
1157 =item C<(?(condition)yes-pattern)>
1158
1159 Conditional expression.  C<(condition)> should be either an integer in
1160 parentheses (which is valid if the corresponding pair of parentheses
1161 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1162 name in angle brackets or single quotes (which is valid if a group
1163 with the given name matched), or the special symbol (R) (true when
1164 evaluated inside of recursion or eval). Additionally the R may be
1165 followed by a number, (which will be true when evaluated when recursing
1166 inside of the appropriate group), or by C<&NAME>, in which case it will
1167 be true only when evaluated during recursion in the named group.
1168
1169 Here's a summary of the possible predicates:
1170
1171 =over 4
1172
1173 =item (1) (2) ...
1174
1175 Checks if the numbered capturing group has matched something.
1176
1177 =item (<NAME>) ('NAME')
1178
1179 Checks if a group with the given name has matched something.
1180
1181 =item (?{ CODE })
1182
1183 Treats the code block as the condition.
1184
1185 =item (R)
1186
1187 Checks if the expression has been evaluated inside of recursion.
1188
1189 =item (R1) (R2) ...
1190
1191 Checks if the expression has been evaluated while executing directly
1192 inside of the n-th capture group. This check is the regex equivalent of
1193
1194   if ((caller(0))[3] eq 'subname') { ... }
1195
1196 In other words, it does not check the full recursion stack.
1197
1198 =item (R&NAME)
1199
1200 Similar to C<(R1)>, this predicate checks to see if we're executing
1201 directly inside of the leftmost group with a given name (this is the same
1202 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1203 stack, but only the name of the innermost active recursion.
1204
1205 =item (DEFINE)
1206
1207 In this case, the yes-pattern is never directly executed, and no
1208 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1209 See below for details.
1210
1211 =back
1212
1213 For example:
1214
1215     m{ ( \( )?
1216        [^()]+
1217        (?(1) \) )
1218      }x
1219
1220 matches a chunk of non-parentheses, possibly included in parentheses
1221 themselves.
1222
1223 A special form is the C<(DEFINE)> predicate, which never executes directly
1224 its yes-pattern, and does not allow a no-pattern. This allows to define
1225 subpatterns which will be executed only by using the recursion mechanism.
1226 This way, you can define a set of regular expression rules that can be
1227 bundled into any pattern you choose.
1228
1229 It is recommended that for this usage you put the DEFINE block at the
1230 end of the pattern, and that you name any subpatterns defined within it.
1231
1232 Also, it's worth noting that patterns defined this way probably will
1233 not be as efficient, as the optimiser is not very clever about
1234 handling them.
1235
1236 An example of how this might be used is as follows:
1237
1238   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1239    (?(DEFINE)
1240      (?<NAME_PAT>....)
1241      (?<ADRESS_PAT>....)
1242    )/x
1243
1244 Note that capture groups matched inside of recursion are not accessible
1245 after the recursion returns, so the extra layer of capturing groups is
1246 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1247 C<$+{NAME}> would be.
1248
1249 =item C<< (?>pattern) >>
1250 X<backtrack> X<backtracking> X<atomic> X<possessive>
1251
1252 An "independent" subexpression, one which matches the substring
1253 that a I<standalone> C<pattern> would match if anchored at the given
1254 position, and it matches I<nothing other than this substring>.  This
1255 construct is useful for optimizations of what would otherwise be
1256 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1257 It may also be useful in places where the "grab all you can, and do not
1258 give anything back" semantic is desirable.
1259
1260 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1261 (anchored at the beginning of string, as above) will match I<all>
1262 characters C<a> at the beginning of string, leaving no C<a> for
1263 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1264 since the match of the subgroup C<a*> is influenced by the following
1265 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1266 C<a*ab> will match fewer characters than a standalone C<a*>, since
1267 this makes the tail match.
1268
1269 An effect similar to C<< (?>pattern) >> may be achieved by writing
1270 C<(?=(pattern))\g1>.  This matches the same substring as a standalone
1271 C<a+>, and the following C<\g1> eats the matched string; it therefore
1272 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1273 (The difference between these two constructs is that the second one
1274 uses a capturing group, thus shifting ordinals of backreferences
1275 in the rest of a regular expression.)
1276
1277 Consider this pattern:
1278
1279     m{ \(
1280           (
1281             [^()]+           # x+
1282           |
1283             \( [^()]* \)
1284           )+
1285        \)
1286      }x
1287
1288 That will efficiently match a nonempty group with matching parentheses
1289 two levels deep or less.  However, if there is no such group, it
1290 will take virtually forever on a long string.  That's because there
1291 are so many different ways to split a long string into several
1292 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1293 to a subpattern of the above pattern.  Consider how the pattern
1294 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1295 seconds, but that each extra letter doubles this time.  This
1296 exponential performance will make it appear that your program has
1297 hung.  However, a tiny change to this pattern
1298
1299     m{ \(
1300           (
1301             (?> [^()]+ )        # change x+ above to (?> x+ )
1302           |
1303             \( [^()]* \)
1304           )+
1305        \)
1306      }x
1307
1308 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1309 this yourself would be a productive exercise), but finishes in a fourth
1310 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1311 however, that this pattern currently triggers a warning message under
1312 the C<use warnings> pragma or B<-w> switch saying it
1313 C<"matches null string many times in regex">.
1314
1315 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1316 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1317 This was only 4 times slower on a string with 1000000 C<a>s.
1318
1319 The "grab all you can, and do not give anything back" semantic is desirable
1320 in many situations where on the first sight a simple C<()*> looks like
1321 the correct solution.  Suppose we parse text with comments being delimited
1322 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1323 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1324 the comment delimiter, because it may "give up" some whitespace if
1325 the remainder of the pattern can be made to match that way.  The correct
1326 answer is either one of these:
1327
1328     (?>#[ \t]*)
1329     #[ \t]*(?![ \t])
1330
1331 For example, to grab non-empty comments into $1, one should use either
1332 one of these:
1333
1334     / (?> \# [ \t]* ) (        .+ ) /x;
1335     /     \# [ \t]*   ( [^ \t] .* ) /x;
1336
1337 Which one you pick depends on which of these expressions better reflects
1338 the above specification of comments.
1339
1340 In some literature this construct is called "atomic matching" or
1341 "possessive matching".
1342
1343 Possessive quantifiers are equivalent to putting the item they are applied
1344 to inside of one of these constructs. The following equivalences apply:
1345
1346     Quantifier Form     Bracketing Form
1347     ---------------     ---------------
1348     PAT*+               (?>PAT*)
1349     PAT++               (?>PAT+)
1350     PAT?+               (?>PAT?)
1351     PAT{min,max}+       (?>PAT{min,max})
1352
1353 =back
1354
1355 =head2 Special Backtracking Control Verbs
1356
1357 B<WARNING:> These patterns are experimental and subject to change or
1358 removal in a future version of Perl. Their usage in production code should
1359 be noted to avoid problems during upgrades.
1360
1361 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1362 otherwise stated the ARG argument is optional; in some cases, it is
1363 forbidden.
1364
1365 Any pattern containing a special backtracking verb that allows an argument
1366 has the special behaviour that when executed it sets the current package's
1367 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1368 rules apply:
1369
1370 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1371 verb pattern, if the verb was involved in the failure of the match. If the
1372 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1373 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1374 none. Also, the C<$REGMARK> variable will be set to FALSE.
1375
1376 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1377 the C<$REGMARK> variable will be set to the name of the last
1378 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1379 C<(*MARK:NAME)> verb below for more details.
1380
1381 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1382 and most other regex related variables. They are not local to a scope, nor
1383 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1384 Use C<local> to localize changes to them to a specific scope if necessary.
1385
1386 If a pattern does not contain a special backtracking verb that allows an
1387 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1388
1389 =over 4
1390
1391 =item Verbs that take an argument
1392
1393 =over 4
1394
1395 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1396 X<(*PRUNE)> X<(*PRUNE:NAME)>
1397
1398 This zero-width pattern prunes the backtracking tree at the current point
1399 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1400 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1401 A may backtrack as necessary to match. Once it is reached, matching
1402 continues in B, which may also backtrack as necessary; however, should B
1403 not match, then no further backtracking will take place, and the pattern
1404 will fail outright at the current starting position.
1405
1406 The following example counts all the possible matching strings in a
1407 pattern (without actually matching any of them).
1408
1409     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1410     print "Count=$count\n";
1411
1412 which produces:
1413
1414     aaab
1415     aaa
1416     aa
1417     a
1418     aab
1419     aa
1420     a
1421     ab
1422     a
1423     Count=9
1424
1425 If we add a C<(*PRUNE)> before the count like the following
1426
1427     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1428     print "Count=$count\n";
1429
1430 we prevent backtracking and find the count of the longest matching
1431 at each matching starting point like so:
1432
1433     aaab
1434     aab
1435     ab
1436     Count=3
1437
1438 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1439
1440 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1441 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1442 replaced with a C<< (?>pattern) >> with no functional difference; however,
1443 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1444 C<< (?>pattern) >> alone.
1445
1446
1447 =item C<(*SKIP)> C<(*SKIP:NAME)>
1448 X<(*SKIP)>
1449
1450 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1451 failure it also signifies that whatever text that was matched leading up
1452 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1453 of this pattern. This effectively means that the regex engine "skips" forward
1454 to this position on failure and tries to match again, (assuming that
1455 there is sufficient room to match).
1456
1457 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1458 C<(*MARK:NAME)> was encountered while matching, then it is that position
1459 which is used as the "skip point". If no C<(*MARK)> of that name was
1460 encountered, then the C<(*SKIP)> operator has no effect. When used
1461 without a name the "skip point" is where the match point was when
1462 executing the (*SKIP) pattern.
1463
1464 Compare the following to the examples in C<(*PRUNE)>, note the string
1465 is twice as long:
1466
1467     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1468     print "Count=$count\n";
1469
1470 outputs
1471
1472     aaab
1473     aaab
1474     Count=2
1475
1476 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1477 executed, the next starting point will be where the cursor was when the
1478 C<(*SKIP)> was executed.
1479
1480 =item C<(*MARK:NAME)> C<(*:NAME)>
1481 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1482
1483 This zero-width pattern can be used to mark the point reached in a string
1484 when a certain part of the pattern has been successfully matched. This
1485 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1486 forward to that point if backtracked into on failure. Any number of
1487 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1488
1489 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1490 can be used to "label" a pattern branch, so that after matching, the
1491 program can determine which branches of the pattern were involved in the
1492 match.
1493
1494 When a match is successful, the C<$REGMARK> variable will be set to the
1495 name of the most recently executed C<(*MARK:NAME)> that was involved
1496 in the match.
1497
1498 This can be used to determine which branch of a pattern was matched
1499 without using a separate capture group for each branch, which in turn
1500 can result in a performance improvement, as perl cannot optimize
1501 C</(?:(x)|(y)|(z))/> as efficiently as something like
1502 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1503
1504 When a match has failed, and unless another verb has been involved in
1505 failing the match and has provided its own name to use, the C<$REGERROR>
1506 variable will be set to the name of the most recently executed
1507 C<(*MARK:NAME)>.
1508
1509 See C<(*SKIP)> for more details.
1510
1511 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1512
1513 =item C<(*THEN)> C<(*THEN:NAME)>
1514
1515 This is similar to the "cut group" operator C<::> from Perl 6. Like
1516 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1517 failure, it causes the regex engine to try the next alternation in the
1518 innermost enclosing group (capturing or otherwise).
1519
1520 Its name comes from the observation that this operation combined with the
1521 alternation operator (C<|>) can be used to create what is essentially a
1522 pattern-based if/then/else block:
1523
1524   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1525
1526 Note that if this operator is used and NOT inside of an alternation then
1527 it acts exactly like the C<(*PRUNE)> operator.
1528
1529   / A (*PRUNE) B /
1530
1531 is the same as
1532
1533   / A (*THEN) B /
1534
1535 but
1536
1537   / ( A (*THEN) B | C (*THEN) D ) /
1538
1539 is not the same as
1540
1541   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1542
1543 as after matching the A but failing on the B the C<(*THEN)> verb will
1544 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1545
1546 =item C<(*COMMIT)>
1547 X<(*COMMIT)>
1548
1549 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1550 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1551 into on failure it causes the match to fail outright. No further attempts
1552 to find a valid match by advancing the start pointer will occur again.
1553 For example,
1554
1555     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1556     print "Count=$count\n";
1557
1558 outputs
1559
1560     aaab
1561     Count=1
1562
1563 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1564 does not match, the regex engine will not try any further matching on the
1565 rest of the string.
1566
1567 =back
1568
1569 =item Verbs without an argument
1570
1571 =over 4
1572
1573 =item C<(*FAIL)> C<(*F)>
1574 X<(*FAIL)> X<(*F)>
1575
1576 This pattern matches nothing and always fails. It can be used to force the
1577 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1578 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1579
1580 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1581
1582 =item C<(*ACCEPT)>
1583 X<(*ACCEPT)>
1584
1585 B<WARNING:> This feature is highly experimental. It is not recommended
1586 for production code.
1587
1588 This pattern matches nothing and causes the end of successful matching at
1589 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1590 whether there is actually more to match in the string. When inside of a
1591 nested pattern, such as recursion, or in a subpattern dynamically generated
1592 via C<(??{})>, only the innermost pattern is ended immediately.
1593
1594 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1595 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1596 For instance:
1597
1598   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1599
1600 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1601 be set. If another branch in the inner parentheses were matched, such as in the
1602 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1603
1604 =back
1605
1606 =back
1607
1608 =head2 Backtracking
1609 X<backtrack> X<backtracking>
1610
1611 NOTE: This section presents an abstract approximation of regular
1612 expression behavior.  For a more rigorous (and complicated) view of
1613 the rules involved in selecting a match among possible alternatives,
1614 see L<Combining RE Pieces>.
1615
1616 A fundamental feature of regular expression matching involves the
1617 notion called I<backtracking>, which is currently used (when needed)
1618 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1619 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1620 internally, but the general principle outlined here is valid.
1621
1622 For a regular expression to match, the I<entire> regular expression must
1623 match, not just part of it.  So if the beginning of a pattern containing a
1624 quantifier succeeds in a way that causes later parts in the pattern to
1625 fail, the matching engine backs up and recalculates the beginning
1626 part--that's why it's called backtracking.
1627
1628 Here is an example of backtracking:  Let's say you want to find the
1629 word following "foo" in the string "Food is on the foo table.":
1630
1631     $_ = "Food is on the foo table.";
1632     if ( /\b(foo)\s+(\w+)/i ) {
1633         print "$2 follows $1.\n";
1634     }
1635
1636 When the match runs, the first part of the regular expression (C<\b(foo)>)
1637 finds a possible match right at the beginning of the string, and loads up
1638 $1 with "Foo".  However, as soon as the matching engine sees that there's
1639 no whitespace following the "Foo" that it had saved in $1, it realizes its
1640 mistake and starts over again one character after where it had the
1641 tentative match.  This time it goes all the way until the next occurrence
1642 of "foo". The complete regular expression matches this time, and you get
1643 the expected output of "table follows foo."
1644
1645 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1646 everything between "foo" and "bar".  Initially, you write something
1647 like this:
1648
1649     $_ =  "The food is under the bar in the barn.";
1650     if ( /foo(.*)bar/ ) {
1651         print "got <$1>\n";
1652     }
1653
1654 Which perhaps unexpectedly yields:
1655
1656   got <d is under the bar in the >
1657
1658 That's because C<.*> was greedy, so you get everything between the
1659 I<first> "foo" and the I<last> "bar".  Here it's more effective
1660 to use minimal matching to make sure you get the text between a "foo"
1661 and the first "bar" thereafter.
1662
1663     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1664   got <d is under the >
1665
1666 Here's another example. Let's say you'd like to match a number at the end
1667 of a string, and you also want to keep the preceding part of the match.
1668 So you write this:
1669
1670     $_ = "I have 2 numbers: 53147";
1671     if ( /(.*)(\d*)/ ) {                                # Wrong!
1672         print "Beginning is <$1>, number is <$2>.\n";
1673     }
1674
1675 That won't work at all, because C<.*> was greedy and gobbled up the
1676 whole string. As C<\d*> can match on an empty string the complete
1677 regular expression matched successfully.
1678
1679     Beginning is <I have 2 numbers: 53147>, number is <>.
1680
1681 Here are some variants, most of which don't work:
1682
1683     $_ = "I have 2 numbers: 53147";
1684     @pats = qw{
1685         (.*)(\d*)
1686         (.*)(\d+)
1687         (.*?)(\d*)
1688         (.*?)(\d+)
1689         (.*)(\d+)$
1690         (.*?)(\d+)$
1691         (.*)\b(\d+)$
1692         (.*\D)(\d+)$
1693     };
1694
1695     for $pat (@pats) {
1696         printf "%-12s ", $pat;
1697         if ( /$pat/ ) {
1698             print "<$1> <$2>\n";
1699         } else {
1700             print "FAIL\n";
1701         }
1702     }
1703
1704 That will print out:
1705
1706     (.*)(\d*)    <I have 2 numbers: 53147> <>
1707     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1708     (.*?)(\d*)   <> <>
1709     (.*?)(\d+)   <I have > <2>
1710     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1711     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1712     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1713     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1714
1715 As you see, this can be a bit tricky.  It's important to realize that a
1716 regular expression is merely a set of assertions that gives a definition
1717 of success.  There may be 0, 1, or several different ways that the
1718 definition might succeed against a particular string.  And if there are
1719 multiple ways it might succeed, you need to understand backtracking to
1720 know which variety of success you will achieve.
1721
1722 When using look-ahead assertions and negations, this can all get even
1723 trickier.  Imagine you'd like to find a sequence of non-digits not
1724 followed by "123".  You might try to write that as
1725
1726     $_ = "ABC123";
1727     if ( /^\D*(?!123)/ ) {                # Wrong!
1728         print "Yup, no 123 in $_\n";
1729     }
1730
1731 But that isn't going to match; at least, not the way you're hoping.  It
1732 claims that there is no 123 in the string.  Here's a clearer picture of
1733 why that pattern matches, contrary to popular expectations:
1734
1735     $x = 'ABC123';
1736     $y = 'ABC445';
1737
1738     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1739     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1740
1741     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1742     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1743
1744 This prints
1745
1746     2: got ABC
1747     3: got AB
1748     4: got ABC
1749
1750 You might have expected test 3 to fail because it seems to a more
1751 general purpose version of test 1.  The important difference between
1752 them is that test 3 contains a quantifier (C<\D*>) and so can use
1753 backtracking, whereas test 1 will not.  What's happening is
1754 that you've asked "Is it true that at the start of $x, following 0 or more
1755 non-digits, you have something that's not 123?"  If the pattern matcher had
1756 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1757 fail.
1758
1759 The search engine will initially match C<\D*> with "ABC".  Then it will
1760 try to match C<(?!123> with "123", which fails.  But because
1761 a quantifier (C<\D*>) has been used in the regular expression, the
1762 search engine can backtrack and retry the match differently
1763 in the hope of matching the complete regular expression.
1764
1765 The pattern really, I<really> wants to succeed, so it uses the
1766 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1767 time.  Now there's indeed something following "AB" that is not
1768 "123".  It's "C123", which suffices.
1769
1770 We can deal with this by using both an assertion and a negation.
1771 We'll say that the first part in $1 must be followed both by a digit
1772 and by something that's not "123".  Remember that the look-aheads
1773 are zero-width expressions--they only look, but don't consume any
1774 of the string in their match.  So rewriting this way produces what
1775 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1776
1777     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1778     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1779
1780     6: got ABC
1781
1782 In other words, the two zero-width assertions next to each other work as though
1783 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1784 matches only if you're at the beginning of the line AND the end of the
1785 line simultaneously.  The deeper underlying truth is that juxtaposition in
1786 regular expressions always means AND, except when you write an explicit OR
1787 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1788 although the attempted matches are made at different positions because "a"
1789 is not a zero-width assertion, but a one-width assertion.
1790
1791 B<WARNING>: Particularly complicated regular expressions can take
1792 exponential time to solve because of the immense number of possible
1793 ways they can use backtracking to try for a match.  For example, without
1794 internal optimizations done by the regular expression engine, this will
1795 take a painfully long time to run:
1796
1797     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1798
1799 And if you used C<*>'s in the internal groups instead of limiting them
1800 to 0 through 5 matches, then it would take forever--or until you ran
1801 out of stack space.  Moreover, these internal optimizations are not
1802 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1803 on the external group, no current optimization is applicable, and the
1804 match takes a long time to finish.
1805
1806 A powerful tool for optimizing such beasts is what is known as an
1807 "independent group",
1808 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1809 zero-length look-ahead/look-behind assertions will not backtrack to make
1810 the tail match, since they are in "logical" context: only
1811 whether they match is considered relevant.  For an example
1812 where side-effects of look-ahead I<might> have influenced the
1813 following match, see L<C<< (?>pattern) >>>.
1814
1815 =head2 Version 8 Regular Expressions
1816 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1817
1818 In case you're not familiar with the "regular" Version 8 regex
1819 routines, here are the pattern-matching rules not described above.
1820
1821 Any single character matches itself, unless it is a I<metacharacter>
1822 with a special meaning described here or above.  You can cause
1823 characters that normally function as metacharacters to be interpreted
1824 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1825 character; "\\" matches a "\"). This escape mechanism is also required
1826 for the character used as the pattern delimiter.
1827
1828 A series of characters matches that series of characters in the target
1829 string, so the pattern  C<blurfl> would match "blurfl" in the target
1830 string.
1831
1832 You can specify a character class, by enclosing a list of characters
1833 in C<[]>, which will match any character from the list.  If the
1834 first character after the "[" is "^", the class matches any character not
1835 in the list.  Within a list, the "-" character specifies a
1836 range, so that C<a-z> represents all characters between "a" and "z",
1837 inclusive.  If you want either "-" or "]" itself to be a member of a
1838 class, put it at the start of the list (possibly after a "^"), or
1839 escape it with a backslash.  "-" is also taken literally when it is
1840 at the end of the list, just before the closing "]".  (The
1841 following all specify the same class of three characters: C<[-az]>,
1842 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1843 specifies a class containing twenty-six characters, even on EBCDIC-based
1844 character sets.)  Also, if you try to use the character
1845 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1846 a range, the "-" is understood literally.
1847
1848 Note also that the whole range idea is rather unportable between
1849 character sets--and even within character sets they may cause results
1850 you probably didn't expect.  A sound principle is to use only ranges
1851 that begin from and end at either alphabetics of equal case ([a-e],
1852 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1853 spell out the character sets in full.
1854
1855 Characters may be specified using a metacharacter syntax much like that
1856 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1857 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1858 of three octal digits, matches the character whose coded character set value
1859 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1860 matches the character whose ordinal is I<nn>. The expression \cI<x>
1861 matches the character control-I<x>.  Finally, the "." metacharacter
1862 matches any character except "\n" (unless you use C</s>).
1863
1864 You can specify a series of alternatives for a pattern using "|" to
1865 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1866 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1867 first alternative includes everything from the last pattern delimiter
1868 ("(", "[", or the beginning of the pattern) up to the first "|", and
1869 the last alternative contains everything from the last "|" to the next
1870 pattern delimiter.  That's why it's common practice to include
1871 alternatives in parentheses: to minimize confusion about where they
1872 start and end.
1873
1874 Alternatives are tried from left to right, so the first
1875 alternative found for which the entire expression matches, is the one that
1876 is chosen. This means that alternatives are not necessarily greedy. For
1877 example: when matching C<foo|foot> against "barefoot", only the "foo"
1878 part will match, as that is the first alternative tried, and it successfully
1879 matches the target string. (This might not seem important, but it is
1880 important when you are capturing matched text using parentheses.)
1881
1882 Also remember that "|" is interpreted as a literal within square brackets,
1883 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1884
1885 Within a pattern, you may designate subpatterns for later reference
1886 by enclosing them in parentheses, and you may refer back to the
1887 I<n>th subpattern later in the pattern using the metacharacter
1888 \I<n>.  Subpatterns are numbered based on the left to right order
1889 of their opening parenthesis.  A backreference matches whatever
1890 actually matched the subpattern in the string being examined, not
1891 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
1892 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1893 1 matched "0x", even though the rule C<0|0x> could potentially match
1894 the leading 0 in the second number.
1895
1896 =head2 Warning on \1 Instead of $1
1897
1898 Some people get too used to writing things like:
1899
1900     $pattern =~ s/(\W)/\\\1/g;
1901
1902 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
1903 shocking the
1904 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1905 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1906 the usual double-quoted string means a control-A.  The customary Unix
1907 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1908 of doing that, you get yourself into trouble if you then add an C</e>
1909 modifier.
1910
1911     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
1912
1913 Or if you try to do
1914
1915     s/(\d+)/\1000/;
1916
1917 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1918 C<${1}000>.  The operation of interpolation should not be confused
1919 with the operation of matching a backreference.  Certainly they mean two
1920 different things on the I<left> side of the C<s///>.
1921
1922 =head2 Repeated Patterns Matching a Zero-length Substring
1923
1924 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1925
1926 Regular expressions provide a terse and powerful programming language.  As
1927 with most other power tools, power comes together with the ability
1928 to wreak havoc.
1929
1930 A common abuse of this power stems from the ability to make infinite
1931 loops using regular expressions, with something as innocuous as:
1932
1933     'foo' =~ m{ ( o? )* }x;
1934
1935 The C<o?> matches at the beginning of C<'foo'>, and since the position
1936 in the string is not moved by the match, C<o?> would match again and again
1937 because of the C<*> quantifier.  Another common way to create a similar cycle
1938 is with the looping modifier C<//g>:
1939
1940     @matches = ( 'foo' =~ m{ o? }xg );
1941
1942 or
1943
1944     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1945
1946 or the loop implied by split().
1947
1948 However, long experience has shown that many programming tasks may
1949 be significantly simplified by using repeated subexpressions that
1950 may match zero-length substrings.  Here's a simple example being:
1951
1952     @chars = split //, $string;                  # // is not magic in split
1953     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1954
1955 Thus Perl allows such constructs, by I<forcefully breaking
1956 the infinite loop>.  The rules for this are different for lower-level
1957 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1958 ones like the C</g> modifier or split() operator.
1959
1960 The lower-level loops are I<interrupted> (that is, the loop is
1961 broken) when Perl detects that a repeated expression matched a
1962 zero-length substring.   Thus
1963
1964    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1965
1966 is made equivalent to
1967
1968    m{   (?: NON_ZERO_LENGTH )*
1969       |
1970         (?: ZERO_LENGTH )?
1971     }x;
1972
1973 The higher level-loops preserve an additional state between iterations:
1974 whether the last match was zero-length.  To break the loop, the following
1975 match after a zero-length match is prohibited to have a length of zero.
1976 This prohibition interacts with backtracking (see L<"Backtracking">),
1977 and so the I<second best> match is chosen if the I<best> match is of
1978 zero length.
1979
1980 For example:
1981
1982     $_ = 'bar';
1983     s/\w??/<$&>/g;
1984
1985 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1986 match given by non-greedy C<??> is the zero-length match, and the I<second
1987 best> match is what is matched by C<\w>.  Thus zero-length matches
1988 alternate with one-character-long matches.
1989
1990 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1991 position one notch further in the string.
1992
1993 The additional state of being I<matched with zero-length> is associated with
1994 the matched string, and is reset by each assignment to pos().
1995 Zero-length matches at the end of the previous match are ignored
1996 during C<split>.
1997
1998 =head2 Combining RE Pieces
1999
2000 Each of the elementary pieces of regular expressions which were described
2001 before (such as C<ab> or C<\Z>) could match at most one substring
2002 at the given position of the input string.  However, in a typical regular
2003 expression these elementary pieces are combined into more complicated
2004 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
2005 (in these examples C<S> and C<T> are regular subexpressions).
2006
2007 Such combinations can include alternatives, leading to a problem of choice:
2008 if we match a regular expression C<a|ab> against C<"abc">, will it match
2009 substring C<"a"> or C<"ab">?  One way to describe which substring is
2010 actually matched is the concept of backtracking (see L<"Backtracking">).
2011 However, this description is too low-level and makes you think
2012 in terms of a particular implementation.
2013
2014 Another description starts with notions of "better"/"worse".  All the
2015 substrings which may be matched by the given regular expression can be
2016 sorted from the "best" match to the "worst" match, and it is the "best"
2017 match which is chosen.  This substitutes the question of "what is chosen?"
2018 by the question of "which matches are better, and which are worse?".
2019
2020 Again, for elementary pieces there is no such question, since at most
2021 one match at a given position is possible.  This section describes the
2022 notion of better/worse for combining operators.  In the description
2023 below C<S> and C<T> are regular subexpressions.
2024
2025 =over 4
2026
2027 =item C<ST>
2028
2029 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2030 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2031 which can be matched by C<T>.
2032
2033 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
2034 match than C<A'B'>.
2035
2036 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2037 C<B> is better match for C<T> than C<B'>.
2038
2039 =item C<S|T>
2040
2041 When C<S> can match, it is a better match than when only C<T> can match.
2042
2043 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2044 two matches for C<T>.
2045
2046 =item C<S{REPEAT_COUNT}>
2047
2048 Matches as C<SSS...S> (repeated as many times as necessary).
2049
2050 =item C<S{min,max}>
2051
2052 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2053
2054 =item C<S{min,max}?>
2055
2056 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2057
2058 =item C<S?>, C<S*>, C<S+>
2059
2060 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2061
2062 =item C<S??>, C<S*?>, C<S+?>
2063
2064 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2065
2066 =item C<< (?>S) >>
2067
2068 Matches the best match for C<S> and only that.
2069
2070 =item C<(?=S)>, C<(?<=S)>
2071
2072 Only the best match for C<S> is considered.  (This is important only if
2073 C<S> has capturing parentheses, and backreferences are used somewhere
2074 else in the whole regular expression.)
2075
2076 =item C<(?!S)>, C<(?<!S)>
2077
2078 For this grouping operator there is no need to describe the ordering, since
2079 only whether or not C<S> can match is important.
2080
2081 =item C<(??{ EXPR })>, C<(?PARNO)>
2082
2083 The ordering is the same as for the regular expression which is
2084 the result of EXPR, or the pattern contained by capture group PARNO.
2085
2086 =item C<(?(condition)yes-pattern|no-pattern)>
2087
2088 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2089 already determined.  The ordering of the matches is the same as for the
2090 chosen subexpression.
2091
2092 =back
2093
2094 The above recipes describe the ordering of matches I<at a given position>.
2095 One more rule is needed to understand how a match is determined for the
2096 whole regular expression: a match at an earlier position is always better
2097 than a match at a later position.
2098
2099 =head2 Creating Custom RE Engines
2100
2101 Overloaded constants (see L<overload>) provide a simple way to extend
2102 the functionality of the RE engine.
2103
2104 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2105 matches at a boundary between whitespace characters and non-whitespace
2106 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2107 at these positions, so we want to have each C<\Y|> in the place of the
2108 more complicated version.  We can create a module C<customre> to do
2109 this:
2110
2111     package customre;
2112     use overload;
2113
2114     sub import {
2115       shift;
2116       die "No argument to customre::import allowed" if @_;
2117       overload::constant 'qr' => \&convert;
2118     }
2119
2120     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2121
2122     # We must also take care of not escaping the legitimate \\Y|
2123     # sequence, hence the presence of '\\' in the conversion rules.
2124     my %rules = ( '\\' => '\\\\',
2125                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2126     sub convert {
2127       my $re = shift;
2128       $re =~ s{
2129                 \\ ( \\ | Y . )
2130               }
2131               { $rules{$1} or invalid($re,$1) }sgex;
2132       return $re;
2133     }
2134
2135 Now C<use customre> enables the new escape in constant regular
2136 expressions, i.e., those without any runtime variable interpolations.
2137 As documented in L<overload>, this conversion will work only over
2138 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2139 part of this regular expression needs to be converted explicitly
2140 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2141
2142     use customre;
2143     $re = <>;
2144     chomp $re;
2145     $re = customre::convert $re;
2146     /\Y|$re\Y|/;
2147
2148 =head1 PCRE/Python Support
2149
2150 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2151 to the regex syntax. While Perl programmers are encouraged to use the
2152 Perl specific syntax, the following are also accepted:
2153
2154 =over 4
2155
2156 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2157
2158 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2159
2160 =item C<< (?P=NAME) >>
2161
2162 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2163
2164 =item C<< (?P>NAME) >>
2165
2166 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2167
2168 =back
2169
2170 =head1 BUGS
2171
2172 There are numerous problems with case insensitive matching of characters
2173 outside the ASCII range, especially with those whose folds are multiple
2174 characters, such as ligatures like C<LATIN SMALL LIGATURE FF>.
2175
2176 In a bracketed character class with case insensitive matching, ranges only work
2177 for ASCII characters.  For example,
2178 C<m/[\N{CYRILLIC CAPITAL LETTER A}-\N{CYRILLIC CAPITAL LETTER YA}]/i>
2179 doesn't match all the Russian upper and lower case letters.
2180
2181 Many regular expression constructs don't work on EBCDIC platforms.
2182
2183 This document varies from difficult to understand to completely
2184 and utterly opaque.  The wandering prose riddled with jargon is
2185 hard to fathom in several places.
2186
2187 This document needs a rewrite that separates the tutorial content
2188 from the reference content.
2189
2190 =head1 SEE ALSO
2191
2192 L<perlrequick>.
2193
2194 L<perlretut>.
2195
2196 L<perlop/"Regexp Quote-Like Operators">.
2197
2198 L<perlop/"Gory details of parsing quoted constructs">.
2199
2200 L<perlfaq6>.
2201
2202 L<perlfunc/pos>.
2203
2204 L<perllocale>.
2205
2206 L<perlebcdic>.
2207
2208 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2209 by O'Reilly and Associates.