Convert tied SPLICE to using Perl_tied_method()
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides a scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in a scalar context by
59 returning the undefined value, and in a list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) all return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule are C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<hex>, C<index>, C<lc>, C<lcfirst>,
111 C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 =item Regular expressions and pattern matching
115 X<regular expression> X<regex> X<regexp>
116
117 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
118
119 =item Numeric functions
120 X<numeric> X<number> X<trigonometric> X<trigonometry>
121
122 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
123 C<sin>, C<sqrt>, C<srand>
124
125 =item Functions for real @ARRAYs
126 X<array>
127
128 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
129
130 =item Functions for list data
131 X<list>
132
133 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
134
135 =item Functions for real %HASHes
136 X<hash>
137
138 C<delete>, C<each>, C<exists>, C<keys>, C<values>
139
140 =item Input and output functions
141 X<I/O> X<input> X<output> X<dbm>
142
143 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
144 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
145 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
146 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
147 C<warn>, C<write>
148
149 =item Functions for fixed length data or records
150
151 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
152
153 =item Functions for filehandles, files, or directories
154 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
155
156 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
157 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
158 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
159 C<umask>, C<unlink>, C<utime>
160
161 =item Keywords related to the control flow of your Perl program
162 X<control flow>
163
164 C<caller>, C<continue>, C<die>, C<do>, C<dump>, C<eval>, C<exit>,
165 C<goto>, C<last>, C<next>, C<redo>, C<return>, C<sub>, C<wantarray>
166
167 =item Keywords related to switch
168
169 C<break>, C<continue>, C<given>, C<when>, C<default>
170
171 (These are available only if you enable the C<"switch"> feature.
172 See L<feature> and L<perlsyn/"Switch statements">.)
173
174 =item Keywords related to scoping
175
176 C<caller>, C<import>, C<local>, C<my>, C<our>, C<state>, C<package>,
177 C<use>
178
179 (C<state> is available only if the C<"state"> feature is enabled. See
180 L<feature>.)
181
182 =item Miscellaneous functions
183
184 C<defined>, C<dump>, C<eval>, C<formline>, C<local>, C<my>, C<our>,
185 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
186
187 =item Functions for processes and process groups
188 X<process> X<pid> X<process id>
189
190 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
191 C<pipe>, C<qx//>, C<setpgrp>, C<setpriority>, C<sleep>, C<system>,
192 C<times>, C<wait>, C<waitpid>
193
194 =item Keywords related to Perl modules
195 X<module>
196
197 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
198
199 =item Keywords related to classes and object-orientation
200 X<object> X<class> X<package>
201
202 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
203 C<untie>, C<use>
204
205 =item Low-level socket functions
206 X<socket> X<sock>
207
208 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
209 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
210 C<socket>, C<socketpair>
211
212 =item System V interprocess communication functions
213 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
214
215 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
216 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
217
218 =item Fetching user and group info
219 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
220
221 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
222 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
223 C<getpwuid>, C<setgrent>, C<setpwent>
224
225 =item Fetching network info
226 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
227
228 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
229 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
230 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
231 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
232 C<setnetent>, C<setprotoent>, C<setservent>
233
234 =item Time-related functions
235 X<time> X<date>
236
237 C<gmtime>, C<localtime>, C<time>, C<times>
238
239 =item Functions new in perl5
240 X<perl5>
241
242 C<abs>, C<bless>, C<break>, C<chomp>, C<chr>, C<continue>, C<default>, 
243 C<exists>, C<formline>, C<given>, C<glob>, C<import>, C<lc>, C<lcfirst>,
244 C<lock>, C<map>, C<my>, C<no>, C<our>, C<prototype>, C<qr//>, C<qw//>, C<qx//>,
245 C<readline>, C<readpipe>, C<ref>, C<sub>*, C<sysopen>, C<tie>, C<tied>, C<uc>,
246 C<ucfirst>, C<untie>, C<use>, C<when>
247
248 * C<sub> was a keyword in Perl 4, but in Perl 5 it is an
249 operator, which can be used in expressions.
250
251 =item Functions obsoleted in perl5
252
253 C<dbmclose>, C<dbmopen>
254
255 =back
256
257 =head2 Portability
258 X<portability> X<Unix> X<portable>
259
260 Perl was born in Unix and can therefore access all common Unix
261 system calls.  In non-Unix environments, the functionality of some
262 Unix system calls may not be available, or details of the available
263 functionality may differ slightly.  The Perl functions affected
264 by this are:
265
266 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
267 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
268 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
269 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
270 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
271 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
272 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
273 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
274 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
275 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
276 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
277 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
278 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
279 C<shmwrite>, C<socket>, C<socketpair>,
280 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
281 C<times>, C<truncate>, C<umask>, C<unlink>,
282 C<utime>, C<wait>, C<waitpid>
283
284 For more information about the portability of these functions, see
285 L<perlport> and other available platform-specific documentation.
286
287 =head2 Alphabetical Listing of Perl Functions
288
289 =over 
290
291 =item -X FILEHANDLE
292 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
293 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
294
295 =item -X EXPR
296
297 =item -X DIRHANDLE
298
299 =item -X
300
301 A file test, where X is one of the letters listed below.  This unary
302 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
303 and tests the associated file to see if something is true about it.  If the
304 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
305 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
306 the undefined value if the file doesn't exist.  Despite the funny
307 names, precedence is the same as any other named unary operator.  The
308 operator may be any of:
309
310     -r  File is readable by effective uid/gid.
311     -w  File is writable by effective uid/gid.
312     -x  File is executable by effective uid/gid.
313     -o  File is owned by effective uid.
314
315     -R  File is readable by real uid/gid.
316     -W  File is writable by real uid/gid.
317     -X  File is executable by real uid/gid.
318     -O  File is owned by real uid.
319
320     -e  File exists.
321     -z  File has zero size (is empty).
322     -s  File has nonzero size (returns size in bytes).
323
324     -f  File is a plain file.
325     -d  File is a directory.
326     -l  File is a symbolic link.
327     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
328     -S  File is a socket.
329     -b  File is a block special file.
330     -c  File is a character special file.
331     -t  Filehandle is opened to a tty.
332
333     -u  File has setuid bit set.
334     -g  File has setgid bit set.
335     -k  File has sticky bit set.
336
337     -T  File is an ASCII text file (heuristic guess).
338     -B  File is a "binary" file (opposite of -T).
339
340     -M  Script start time minus file modification time, in days.
341     -A  Same for access time.
342     -C  Same for inode change time (Unix, may differ for other platforms)
343
344 Example:
345
346     while (<>) {
347         chomp;
348         next unless -f $_;  # ignore specials
349         #...
350     }
351
352 The interpretation of the file permission operators C<-r>, C<-R>,
353 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
354 of the file and the uids and gids of the user.  There may be other
355 reasons you can't actually read, write, or execute the file: for
356 example network filesystem access controls, ACLs (access control lists),
357 read-only filesystems, and unrecognized executable formats.  Note
358 that the use of these six specific operators to verify if some operation
359 is possible is usually a mistake, because it may be open to race
360 conditions.
361
362 Also note that, for the superuser on the local filesystems, the C<-r>,
363 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
364 if any execute bit is set in the mode.  Scripts run by the superuser
365 may thus need to do a stat() to determine the actual mode of the file,
366 or temporarily set their effective uid to something else.
367
368 If you are using ACLs, there is a pragma called C<filetest> that may
369 produce more accurate results than the bare stat() mode bits.
370 When under the C<use filetest 'access'> the above-mentioned filetests
371 test whether the permission can (not) be granted using the
372 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
373 under this pragma return true even if there are no execute permission
374 bits set (nor any extra execute permission ACLs).  This strangeness is
375 due to the underlying system calls' definitions. Note also that, due to
376 the implementation of C<use filetest 'access'>, the C<_> special
377 filehandle won't cache the results of the file tests when this pragma is
378 in effect.  Read the documentation for the C<filetest> pragma for more
379 information.
380
381 Note that C<-s/a/b/> does not do a negated substitution.  Saying
382 C<-exp($foo)> still works as expected, however: only single letters
383 following a minus are interpreted as file tests.
384
385 The C<-T> and C<-B> switches work as follows.  The first block or so of the
386 file is examined for odd characters such as strange control codes or
387 characters with the high bit set.  If too many strange characters (>30%)
388 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
389 containing a zero byte in the first block is considered a binary file.  If C<-T>
390 or C<-B> is used on a filehandle, the current IO buffer is examined
391 rather than the first block.  Both C<-T> and C<-B> return true on an empty
392 file, or a file at EOF when testing a filehandle.  Because you have to
393 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
394 against the file first, as in C<next unless -f $file && -T $file>.
395
396 If any of the file tests (or either the C<stat> or C<lstat> operators) are given
397 the special filehandle consisting of a solitary underline, then the stat
398 structure of the previous file test (or stat operator) is used, saving
399 a system call.  (This doesn't work with C<-t>, and you need to remember
400 that lstat() and C<-l> leave values in the stat structure for the
401 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
402 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
403 Example:
404
405     print "Can do.\n" if -r $a || -w _ || -x _;
406
407     stat($filename);
408     print "Readable\n" if -r _;
409     print "Writable\n" if -w _;
410     print "Executable\n" if -x _;
411     print "Setuid\n" if -u _;
412     print "Setgid\n" if -g _;
413     print "Sticky\n" if -k _;
414     print "Text\n" if -T _;
415     print "Binary\n" if -B _;
416
417 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
418 test operators, in a way that C<-f -w -x $file> is equivalent to
419 C<-x $file && -w _ && -f _>. (This is only fancy fancy: if you use
420 the return value of C<-f $file> as an argument to another filetest
421 operator, no special magic will happen.)
422
423 =item abs VALUE
424 X<abs> X<absolute>
425
426 =item abs
427
428 Returns the absolute value of its argument.
429 If VALUE is omitted, uses C<$_>.
430
431 =item accept NEWSOCKET,GENERICSOCKET
432 X<accept>
433
434 Accepts an incoming socket connect, just as accept(2) 
435 does.  Returns the packed address if it succeeded, false otherwise.
436 See the example in L<perlipc/"Sockets: Client/Server Communication">.
437
438 On systems that support a close-on-exec flag on files, the flag will
439 be set for the newly opened file descriptor, as determined by the
440 value of $^F.  See L<perlvar/$^F>.
441
442 =item alarm SECONDS
443 X<alarm>
444 X<SIGALRM>
445 X<timer>
446
447 =item alarm
448
449 Arranges to have a SIGALRM delivered to this process after the
450 specified number of wallclock seconds has elapsed.  If SECONDS is not
451 specified, the value stored in C<$_> is used. (On some machines,
452 unfortunately, the elapsed time may be up to one second less or more
453 than you specified because of how seconds are counted, and process
454 scheduling may delay the delivery of the signal even further.)
455
456 Only one timer may be counting at once.  Each call disables the
457 previous timer, and an argument of C<0> may be supplied to cancel the
458 previous timer without starting a new one.  The returned value is the
459 amount of time remaining on the previous timer.
460
461 For delays of finer granularity than one second, the Time::HiRes module
462 (from CPAN, and starting from Perl 5.8 part of the standard
463 distribution) provides ualarm().  You may also use Perl's four-argument
464 version of select() leaving the first three arguments undefined, or you
465 might be able to use the C<syscall> interface to access setitimer(2) if
466 your system supports it. See L<perlfaq8> for details.
467
468 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
469 C<sleep> may be internally implemented on your system with C<alarm>.
470
471 If you want to use C<alarm> to time out a system call you need to use an
472 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
473 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
474 restart system calls on some systems.  Using C<eval>/C<die> always works,
475 modulo the caveats given in L<perlipc/"Signals">.
476
477     eval {
478         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
479         alarm $timeout;
480         $nread = sysread SOCKET, $buffer, $size;
481         alarm 0;
482     };
483     if ($@) {
484         die unless $@ eq "alarm\n";   # propagate unexpected errors
485         # timed out
486     }
487     else {
488         # didn't
489     }
490
491 For more information see L<perlipc>.
492
493 =item atan2 Y,X
494 X<atan2> X<arctangent> X<tan> X<tangent>
495
496 Returns the arctangent of Y/X in the range -PI to PI.
497
498 For the tangent operation, you may use the C<Math::Trig::tan>
499 function, or use the familiar relation:
500
501     sub tan { sin($_[0]) / cos($_[0])  }
502
503 The return value for C<atan2(0,0)> is implementation-defined; consult
504 your atan2(3) manpage for more information.
505
506 =item bind SOCKET,NAME
507 X<bind>
508
509 Binds a network address to a socket, just as bind(2)
510 does.  Returns true if it succeeded, false otherwise.  NAME should be a
511 packed address of the appropriate type for the socket.  See the examples in
512 L<perlipc/"Sockets: Client/Server Communication">.
513
514 =item binmode FILEHANDLE, LAYER
515 X<binmode> X<binary> X<text> X<DOS> X<Windows>
516
517 =item binmode FILEHANDLE
518
519 Arranges for FILEHANDLE to be read or written in "binary" or "text"
520 mode on systems where the run-time libraries distinguish between
521 binary and text files.  If FILEHANDLE is an expression, the value is
522 taken as the name of the filehandle.  Returns true on success,
523 otherwise it returns C<undef> and sets C<$!> (errno).
524
525 On some systems (in general, DOS and Windows-based systems) binmode()
526 is necessary when you're not working with a text file.  For the sake
527 of portability it is a good idea to always use it when appropriate,
528 and to never use it when it isn't appropriate.  Also, people can
529 set their I/O to be by default UTF-8 encoded Unicode, not bytes.
530
531 In other words: regardless of platform, use binmode() on binary data,
532 like for example images.
533
534 If LAYER is present it is a single string, but may contain multiple
535 directives. The directives alter the behaviour of the filehandle.
536 When LAYER is present using binmode on a text file makes sense.
537
538 If LAYER is omitted or specified as C<:raw> the filehandle is made
539 suitable for passing binary data. This includes turning off possible CRLF
540 translation and marking it as bytes (as opposed to Unicode characters).
541 Note that, despite what may be implied in I<"Programming Perl"> (the
542 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
543 Other layers that would affect the binary nature of the stream are
544 I<also> disabled. See L<PerlIO>, L<perlrun>, and the discussion about the
545 PERLIO environment variable.
546
547 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
548 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
549 establish default I/O layers.  See L<open>.
550
551 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
552 in "Programming Perl, 3rd Edition".  However, since the publishing of this
553 book, by many known as "Camel III", the consensus of the naming of this
554 functionality has moved from "discipline" to "layer".  All documentation
555 of this version of Perl therefore refers to "layers" rather than to
556 "disciplines".  Now back to the regularly scheduled documentation...>
557
558 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(utf8)>.
559 C<:utf8> just marks the data as UTF-8 without further checking,
560 while C<:encoding(utf8)> checks the data for actually being valid
561 UTF-8. More details can be found in L<PerlIO::encoding>.
562
563 In general, binmode() should be called after open() but before any I/O
564 is done on the filehandle.  Calling binmode() normally flushes any
565 pending buffered output data (and perhaps pending input data) on the
566 handle.  An exception to this is the C<:encoding> layer that
567 changes the default character encoding of the handle, see L<open>.
568 The C<:encoding> layer sometimes needs to be called in
569 mid-stream, and it doesn't flush the stream.  The C<:encoding>
570 also implicitly pushes on top of itself the C<:utf8> layer because
571 internally Perl operates on UTF8-encoded Unicode characters.
572
573 The operating system, device drivers, C libraries, and Perl run-time
574 system all work together to let the programmer treat a single
575 character (C<\n>) as the line terminator, irrespective of the external
576 representation.  On many operating systems, the native text file
577 representation matches the internal representation, but on some
578 platforms the external representation of C<\n> is made up of more than
579 one character.
580
581 Mac OS, all variants of Unix, and Stream_LF files on VMS use a single
582 character to end each line in the external representation of text (even
583 though that single character is CARRIAGE RETURN on Mac OS and LINE FEED
584 on Unix and most VMS files). In other systems like OS/2, DOS and the
585 various flavors of MS-Windows your program sees a C<\n> as a simple C<\cJ>,
586 but what's stored in text files are the two characters C<\cM\cJ>.  That
587 means that, if you don't use binmode() on these systems, C<\cM\cJ>
588 sequences on disk will be converted to C<\n> on input, and any C<\n> in
589 your program will be converted back to C<\cM\cJ> on output.  This is what
590 you want for text files, but it can be disastrous for binary files.
591
592 Another consequence of using binmode() (on some systems) is that
593 special end-of-file markers will be seen as part of the data stream.
594 For systems from the Microsoft family this means that if your binary
595 data contains C<\cZ>, the I/O subsystem will regard it as the end of
596 the file, unless you use binmode().
597
598 binmode() is important not only for readline() and print() operations,
599 but also when using read(), seek(), sysread(), syswrite() and tell()
600 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
601 in L<perlvar> for how to manually set your input and output
602 line-termination sequences.
603
604 =item bless REF,CLASSNAME
605 X<bless>
606
607 =item bless REF
608
609 This function tells the thingy referenced by REF that it is now an object
610 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
611 is used.  Because a C<bless> is often the last thing in a constructor,
612 it returns the reference for convenience.  Always use the two-argument
613 version if a derived class might inherit the function doing the blessing.
614 See L<perltoot> and L<perlobj> for more about the blessing (and blessings)
615 of objects.
616
617 Consider always blessing objects in CLASSNAMEs that are mixed case.
618 Namespaces with all lowercase names are considered reserved for
619 Perl pragmata.  Builtin types have all uppercase names. To prevent
620 confusion, you may wish to avoid such package names as well.  Make sure
621 that CLASSNAME is a true value.
622
623 See L<perlmod/"Perl Modules">.
624
625 =item break
626
627 Break out of a C<given()> block.
628
629 This keyword is enabled by the C<"switch"> feature: see L<feature>
630 for more information.
631
632 =item caller EXPR
633 X<caller> X<call stack> X<stack> X<stack trace>
634
635 =item caller
636
637 Returns the context of the current subroutine call.  In scalar context,
638 returns the caller's package name if there I<is> a caller (that is, if
639 we're in a subroutine or C<eval> or C<require>) and the undefined value
640 otherwise.  In list context, returns
641
642     # 0         1          2
643     ($package, $filename, $line) = caller;
644
645 With EXPR, it returns some extra information that the debugger uses to
646 print a stack trace.  The value of EXPR indicates how many call frames
647 to go back before the current one.
648
649     #  0         1          2      3            4
650     ($package, $filename, $line, $subroutine, $hasargs,
651
652     #  5          6          7            8       9         10
653     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
654      = caller($i);
655
656 Here $subroutine may be C<(eval)> if the frame is not a subroutine
657 call, but an C<eval>.  In such a case additional elements $evaltext and
658 C<$is_require> are set: C<$is_require> is true if the frame is created by a
659 C<require> or C<use> statement, $evaltext contains the text of the
660 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
661 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
662 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
663 frame.)  $subroutine may also be C<(unknown)> if this particular
664 subroutine happens to have been deleted from the symbol table.
665 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
666 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
667 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
668 between versions of Perl, and are not meant for external use.
669
670 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
671 caller was compiled, or C<undef> if C<%^H> was empty. Do not modify the values
672 of this hash, as they are the actual values stored in the optree.
673
674 Furthermore, when called from within the DB package, caller returns more
675 detailed information: it sets the list variable C<@DB::args> to be the
676 arguments with which the subroutine was invoked.
677
678 Be aware that the optimizer might have optimized call frames away before
679 C<caller> had a chance to get the information.  That means that C<caller(N)>
680 might not return information about the call frame you expect it to, for
681 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
682 previous time C<caller> was called.
683
684 Also be aware that setting C<@DB::args> is I<best effort>, intended for
685 debugging or generating backtraces, and should not be relied upon. In
686 particular, as C<@_> contains aliases to the caller's arguments, Perl does
687 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
688 subroutine makes to C<@_> or its contents, not the original values at call
689 time. C<@DB::args>, like C<@_>, does not hold explicit references to its
690 elements, so under certain cases its elements may have become freed and
691 reallocated for other variables or temporary values. Finally, a side effect
692 of the current implementation means that the effects of C<shift @_> can
693 I<normally> be undone (but not C<pop @_> or other splicing, and not if a
694 reference to C<@_> has been taken, and subject to the caveat about reallocated
695 elements), so C<@DB::args> is actually a hybrid of the current state and
696 initial state of C<@_>. Buyer beware.
697
698 =item chdir EXPR
699 X<chdir>
700 X<cd>
701 X<directory, change>
702
703 =item chdir FILEHANDLE
704
705 =item chdir DIRHANDLE
706
707 =item chdir
708
709 Changes the working directory to EXPR, if possible. If EXPR is omitted,
710 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
711 changes to the directory specified by C<$ENV{LOGDIR}>. (Under VMS, the
712 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.) If
713 neither is set, C<chdir> does nothing. It returns true on success,
714 false otherwise. See the example under C<die>.
715
716 On systems that support fchdir(2), you may pass a filehandle or
717 directory handle as argument.  On systems that don't support fchdir(2),
718 passing handles raises an exception.
719
720 =item chmod LIST
721 X<chmod> X<permission> X<mode>
722
723 Changes the permissions of a list of files.  The first element of the
724 list must be the numerical mode, which should probably be an octal
725 number, and which definitely should I<not> be a string of octal digits:
726 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
727 successfully changed.  See also L</oct>, if all you have is a string.
728
729     $cnt = chmod 0755, "foo", "bar";
730     chmod 0755, @executables;
731     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
732                                              # --w----r-T
733     $mode = "0644"; chmod oct($mode), "foo"; # this is better
734     $mode = 0644;   chmod $mode, "foo";      # this is best
735
736 On systems that support fchmod(2), you may pass filehandles among the
737 files.  On systems that don't support fchmod(2), passing filehandles raises
738 an exception.  Filehandles must be passed as globs or glob references to be
739 recognized; barewords are considered filenames.
740
741     open(my $fh, "<", "foo");
742     my $perm = (stat $fh)[2] & 07777;
743     chmod($perm | 0600, $fh);
744
745 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
746 module:
747
748     use Fcntl qw( :mode );
749     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
750     # Identical to the chmod 0755 of the example above.
751
752 =item chomp VARIABLE
753 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
754
755 =item chomp( LIST )
756
757 =item chomp
758
759 This safer version of L</chop> removes any trailing string
760 that corresponds to the current value of C<$/> (also known as
761 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
762 number of characters removed from all its arguments.  It's often used to
763 remove the newline from the end of an input record when you're worried
764 that the final record may be missing its newline.  When in paragraph
765 mode (C<$/ = "">), it removes all trailing newlines from the string.
766 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
767 a reference to an integer or the like, see L<perlvar>) chomp() won't
768 remove anything.
769 If VARIABLE is omitted, it chomps C<$_>.  Example:
770
771     while (<>) {
772         chomp;  # avoid \n on last field
773         @array = split(/:/);
774         # ...
775     }
776
777 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
778
779 You can actually chomp anything that's an lvalue, including an assignment:
780
781     chomp($cwd = `pwd`);
782     chomp($answer = <STDIN>);
783
784 If you chomp a list, each element is chomped, and the total number of
785 characters removed is returned.
786
787 Note that parentheses are necessary when you're chomping anything
788 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
789 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
790 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
791 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
792 as C<chomp($a, $b)>.
793
794 =item chop VARIABLE
795 X<chop>
796
797 =item chop( LIST )
798
799 =item chop
800
801 Chops off the last character of a string and returns the character
802 chopped.  It is much more efficient than C<s/.$//s> because it neither
803 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
804 If VARIABLE is a hash, it chops the hash's values, but not its keys.
805
806 You can actually chop anything that's an lvalue, including an assignment.
807
808 If you chop a list, each element is chopped.  Only the value of the
809 last C<chop> is returned.
810
811 Note that C<chop> returns the last character.  To return all but the last
812 character, use C<substr($string, 0, -1)>.
813
814 See also L</chomp>.
815
816 =item chown LIST
817 X<chown> X<owner> X<user> X<group>
818
819 Changes the owner (and group) of a list of files.  The first two
820 elements of the list must be the I<numeric> uid and gid, in that
821 order.  A value of -1 in either position is interpreted by most
822 systems to leave that value unchanged.  Returns the number of files
823 successfully changed.
824
825     $cnt = chown $uid, $gid, 'foo', 'bar';
826     chown $uid, $gid, @filenames;
827
828 On systems that support fchown(2), you may pass filehandles among the
829 files.  On systems that don't support fchown(2), passing filehandles raises
830 an exception.  Filehandles must be passed as globs or glob references to be
831 recognized; barewords are considered filenames.
832
833 Here's an example that looks up nonnumeric uids in the passwd file:
834
835     print "User: ";
836     chomp($user = <STDIN>);
837     print "Files: ";
838     chomp($pattern = <STDIN>);
839
840     ($login,$pass,$uid,$gid) = getpwnam($user)
841         or die "$user not in passwd file";
842
843     @ary = glob($pattern);  # expand filenames
844     chown $uid, $gid, @ary;
845
846 On most systems, you are not allowed to change the ownership of the
847 file unless you're the superuser, although you should be able to change
848 the group to any of your secondary groups.  On insecure systems, these
849 restrictions may be relaxed, but this is not a portable assumption.
850 On POSIX systems, you can detect this condition this way:
851
852     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
853     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
854
855 =item chr NUMBER
856 X<chr> X<character> X<ASCII> X<Unicode>
857
858 =item chr
859
860 Returns the character represented by that NUMBER in the character set.
861 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
862 chr(0x263a) is a Unicode smiley face.  
863
864 Negative values give the Unicode replacement character (chr(0xfffd)),
865 except under the L<bytes> pragma, where the low eight bits of the value
866 (truncated to an integer) are used.
867
868 If NUMBER is omitted, uses C<$_>.
869
870 For the reverse, use L</ord>.
871
872 Note that characters from 128 to 255 (inclusive) are by default
873 internally not encoded as UTF-8 for backward compatibility reasons.
874
875 See L<perlunicode> for more about Unicode.
876
877 =item chroot FILENAME
878 X<chroot> X<root>
879
880 =item chroot
881
882 This function works like the system call by the same name: it makes the
883 named directory the new root directory for all further pathnames that
884 begin with a C</> by your process and all its children.  (It doesn't
885 change your current working directory, which is unaffected.)  For security
886 reasons, this call is restricted to the superuser.  If FILENAME is
887 omitted, does a C<chroot> to C<$_>.
888
889 =item close FILEHANDLE
890 X<close>
891
892 =item close
893
894 Closes the file or pipe associated with the filehandle, flushes the IO
895 buffers, and closes the system file descriptor.  Returns true if those
896 operations have succeeded and if no error was reported by any PerlIO
897 layer.  Closes the currently selected filehandle if the argument is
898 omitted.
899
900 You don't have to close FILEHANDLE if you are immediately going to do
901 another C<open> on it, because C<open> closes it for you.  (See
902 C<open>.)  However, an explicit C<close> on an input file resets the line
903 counter (C<$.>), while the implicit close done by C<open> does not.
904
905 If the filehandle came from a piped open, C<close> returns false if one of
906 the other syscalls involved fails or if its program exits with non-zero
907 status.  If the only problem was that the program exited non-zero, C<$!>
908 will be set to C<0>.  Closing a pipe also waits for the process executing
909 on the pipe to exit--in case you wish to look at the output of the pipe
910 afterwards--and implicitly puts the exit status value of that command into
911 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
912
913 Closing the read end of a pipe before the process writing to it at the
914 other end is done writing results in the writer receiving a SIGPIPE.  If
915 the other end can't handle that, be sure to read all the data before
916 closing the pipe.
917
918 Example:
919
920     open(OUTPUT, '|sort >foo')  # pipe to sort
921         or die "Can't start sort: $!";
922     #...                        # print stuff to output
923     close OUTPUT                # wait for sort to finish
924         or warn $! ? "Error closing sort pipe: $!"
925                    : "Exit status $? from sort";
926     open(INPUT, 'foo')          # get sort's results
927         or die "Can't open 'foo' for input: $!";
928
929 FILEHANDLE may be an expression whose value can be used as an indirect
930 filehandle, usually the real filehandle name.
931
932 =item closedir DIRHANDLE
933 X<closedir>
934
935 Closes a directory opened by C<opendir> and returns the success of that
936 system call.
937
938 =item connect SOCKET,NAME
939 X<connect>
940
941 Attempts to connect to a remote socket, just like connect(2).
942 Returns true if it succeeded, false otherwise.  NAME should be a
943 packed address of the appropriate type for the socket.  See the examples in
944 L<perlipc/"Sockets: Client/Server Communication">.
945
946 =item continue BLOCK
947 X<continue>
948
949 =item continue
950
951 C<continue> is actually a flow control statement rather than a function.  If
952 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
953 C<foreach>), it is always executed just before the conditional is about to
954 be evaluated again, just like the third part of a C<for> loop in C.  Thus
955 it can be used to increment a loop variable, even when the loop has been
956 continued via the C<next> statement (which is similar to the C C<continue>
957 statement).
958
959 C<last>, C<next>, or C<redo> may appear within a C<continue>
960 block; C<last> and C<redo> behave as if they had been executed within
961 the main block.  So will C<next>, but since it will execute a C<continue>
962 block, it may be more entertaining.
963
964     while (EXPR) {
965         ### redo always comes here
966         do_something;
967     } continue {
968         ### next always comes here
969         do_something_else;
970         # then back the top to re-check EXPR
971     }
972     ### last always comes here
973
974 Omitting the C<continue> section is equivalent to using an
975 empty one, logically enough, so C<next> goes directly back
976 to check the condition at the top of the loop.
977
978 If the C<"switch"> feature is enabled, C<continue> is also a
979 function that exits the current C<when> (or C<default>) block and
980 falls through to the next one.  See L<feature> and
981 L<perlsyn/"Switch statements"> for more information.
982
983
984 =item cos EXPR
985 X<cos> X<cosine> X<acos> X<arccosine>
986
987 =item cos
988
989 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
990 takes cosine of C<$_>.
991
992 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
993 function, or use this relation:
994
995     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
996
997 =item crypt PLAINTEXT,SALT
998 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
999 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1000
1001 Creates a digest string exactly like the crypt(3) function in the C
1002 library (assuming that you actually have a version there that has not
1003 been extirpated as a potential munition).
1004
1005 crypt() is a one-way hash function.  The PLAINTEXT and SALT is turned
1006 into a short string, called a digest, which is returned.  The same
1007 PLAINTEXT and SALT will always return the same string, but there is no
1008 (known) way to get the original PLAINTEXT from the hash.  Small
1009 changes in the PLAINTEXT or SALT will result in large changes in the
1010 digest.
1011
1012 There is no decrypt function.  This function isn't all that useful for
1013 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1014 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1015 primarily used to check if two pieces of text are the same without
1016 having to transmit or store the text itself.  An example is checking
1017 if a correct password is given.  The digest of the password is stored,
1018 not the password itself.  The user types in a password that is
1019 crypt()'d with the same salt as the stored digest.  If the two digests
1020 match the password is correct.
1021
1022 When verifying an existing digest string you should use the digest as
1023 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1024 to create the digest is visible as part of the digest.  This ensures
1025 crypt() will hash the new string with the same salt as the digest.
1026 This allows your code to work with the standard L<crypt|/crypt> and
1027 with more exotic implementations.  In other words, do not assume
1028 anything about the returned string itself, or how many bytes in the
1029 digest matter.
1030
1031 Traditionally the result is a string of 13 bytes: two first bytes of
1032 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1033 the first eight bytes of PLAINTEXT mattered. But alternative
1034 hashing schemes (like MD5), higher level security schemes (like C2),
1035 and implementations on non-Unix platforms may produce different
1036 strings.
1037
1038 When choosing a new salt create a random two character string whose
1039 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1040 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1041 characters is just a recommendation; the characters allowed in
1042 the salt depend solely on your system's crypt library, and Perl can't
1043 restrict what salts C<crypt()> accepts.
1044
1045 Here's an example that makes sure that whoever runs this program knows
1046 their password:
1047
1048     $pwd = (getpwuid($<))[1];
1049
1050     system "stty -echo";
1051     print "Password: ";
1052     chomp($word = <STDIN>);
1053     print "\n";
1054     system "stty echo";
1055
1056     if (crypt($word, $pwd) ne $pwd) {
1057         die "Sorry...\n";
1058     } else {
1059         print "ok\n";
1060     }
1061
1062 Of course, typing in your own password to whoever asks you
1063 for it is unwise.
1064
1065 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1066 of data, not least of all because you can't get the information
1067 back.  Look at the L<Digest> module for more robust algorithms.
1068
1069 If using crypt() on a Unicode string (which I<potentially> has
1070 characters with codepoints above 255), Perl tries to make sense
1071 of the situation by trying to downgrade (a copy of the string)
1072 the string back to an eight-bit byte string before calling crypt()
1073 (on that copy).  If that works, good.  If not, crypt() dies with
1074 C<Wide character in crypt>.
1075
1076 =item dbmclose HASH
1077 X<dbmclose>
1078
1079 [This function has been largely superseded by the C<untie> function.]
1080
1081 Breaks the binding between a DBM file and a hash.
1082
1083 =item dbmopen HASH,DBNAME,MASK
1084 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1085
1086 [This function has been largely superseded by the C<tie> function.]
1087
1088 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1089 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1090 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1091 is the name of the database (without the F<.dir> or F<.pag> extension if
1092 any).  If the database does not exist, it is created with protection
1093 specified by MASK (as modified by the C<umask>).  If your system supports
1094 only the older DBM functions, you may make only one C<dbmopen> call in your
1095 program.  In older versions of Perl, if your system had neither DBM nor
1096 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1097 sdbm(3).
1098
1099 If you don't have write access to the DBM file, you can only read hash
1100 variables, not set them.  If you want to test whether you can write,
1101 either use file tests or try setting a dummy hash entry inside an C<eval> 
1102 to trap the error.
1103
1104 Note that functions such as C<keys> and C<values> may return huge lists
1105 when used on large DBM files.  You may prefer to use the C<each>
1106 function to iterate over large DBM files.  Example:
1107
1108     # print out history file offsets
1109     dbmopen(%HIST,'/usr/lib/news/history',0666);
1110     while (($key,$val) = each %HIST) {
1111         print $key, ' = ', unpack('L',$val), "\n";
1112     }
1113     dbmclose(%HIST);
1114
1115 See also L<AnyDBM_File> for a more general description of the pros and
1116 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1117 rich implementation.
1118
1119 You can control which DBM library you use by loading that library
1120 before you call dbmopen():
1121
1122     use DB_File;
1123     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1124         or die "Can't open netscape history file: $!";
1125
1126 =item defined EXPR
1127 X<defined> X<undef> X<undefined>
1128
1129 =item defined
1130
1131 Returns a Boolean value telling whether EXPR has a value other than
1132 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1133 checked.
1134
1135 Many operations return C<undef> to indicate failure, end of file,
1136 system error, uninitialized variable, and other exceptional
1137 conditions.  This function allows you to distinguish C<undef> from
1138 other values.  (A simple Boolean test will not distinguish among
1139 C<undef>, zero, the empty string, and C<"0">, which are all equally
1140 false.)  Note that since C<undef> is a valid scalar, its presence
1141 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1142 returns C<undef> when its argument is an empty array, I<or> when the
1143 element to return happens to be C<undef>.
1144
1145 You may also use C<defined(&func)> to check whether subroutine C<&func>
1146 has ever been defined.  The return value is unaffected by any forward
1147 declarations of C<&func>.  A subroutine that is not defined
1148 may still be callable: its package may have an C<AUTOLOAD> method that
1149 makes it spring into existence the first time that it is called; see
1150 L<perlsub>.
1151
1152 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1153 used to report whether memory for that aggregate has ever been
1154 allocated.  This behavior may disappear in future versions of Perl.
1155 You should instead use a simple test for size:
1156
1157     if (@an_array) { print "has array elements\n" }
1158     if (%a_hash)   { print "has hash members\n"   }
1159
1160 When used on a hash element, it tells you whether the value is defined,
1161 not whether the key exists in the hash.  Use L</exists> for the latter
1162 purpose.
1163
1164 Examples:
1165
1166     print if defined $switch{'D'};
1167     print "$val\n" while defined($val = pop(@ary));
1168     die "Can't readlink $sym: $!"
1169         unless defined($value = readlink $sym);
1170     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1171     $debugging = 0 unless defined $debugging;
1172
1173 Note:  Many folks tend to overuse C<defined>, and then are surprised to
1174 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1175 defined values.  For example, if you say
1176
1177     "ab" =~ /a(.*)b/;
1178
1179 The pattern match succeeds and C<$1> is defined, although it
1180 matched "nothing".  It didn't really fail to match anything.  Rather, it
1181 matched something that happened to be zero characters long.  This is all
1182 very above-board and honest.  When a function returns an undefined value,
1183 it's an admission that it couldn't give you an honest answer.  So you
1184 should use C<defined> only when questioning the integrity of what
1185 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1186 what you want.
1187
1188 See also L</undef>, L</exists>, L</ref>.
1189
1190 =item delete EXPR
1191 X<delete>
1192
1193 Given an expression that specifies an element or slice of a hash, C<delete>
1194 deletes the specified elements from that hash so that exists() on that element
1195 no longer returns true.  Setting a hash element to the undefined value does
1196 not remove its key, but deleting it does; see L</exists>.
1197
1198 It returns the value or values deleted in list context, or the last such
1199 element in scalar context.  The return list's length always matches that of
1200 the argument list: deleting non-existent elements returns the undefined value
1201 in their corresponding positions.
1202
1203 delete() may also be used on arrays and array slices, but its behavior is less
1204 straightforward.  Although exists() will return false for deleted entries,
1205 deleting array elements never changes indices of existing values; use shift()
1206 or splice() for that.  However, if all deleted elements fall at the end of an
1207 array, the array's size shrinks to the position of the highest element that
1208 still tests true for exists(), or to 0 if none do.
1209
1210 B<Be aware> that calling delete on array values is deprecated and likely to
1211 be removed in a future version of Perl.
1212
1213 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1214 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1215 or array may not necessarily return anything; it depends on the implementation
1216 of the C<tied> package's DELETE method, which may do whatever it pleases.
1217
1218 The C<delete local EXPR> construct localizes the deletion to the current
1219 block at run time.  Until the block exits, elements locally deleted
1220 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1221 of composite types">.
1222
1223     %hash = (foo => 11, bar => 22, baz => 33);
1224     $scalar = delete $hash{foo};             # $scalar is 11
1225     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1226     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1227
1228 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1229
1230     foreach $key (keys %HASH) {
1231         delete $HASH{$key};
1232     }
1233
1234     foreach $index (0 .. $#ARRAY) {
1235         delete $ARRAY[$index];
1236     }
1237
1238 And so do these:
1239
1240     delete @HASH{keys %HASH};
1241
1242     delete @ARRAY[0 .. $#ARRAY];
1243
1244 But both are slower than assigning the empty list
1245 or undefining %HASH or @ARRAY, which is the customary 
1246 way to empty out an aggregate:
1247
1248     %HASH = ();     # completely empty %HASH
1249     undef %HASH;    # forget %HASH ever existed
1250
1251     @ARRAY = ();    # completely empty @ARRAY
1252     undef @ARRAY;   # forget @ARRAY ever existed
1253
1254 The EXPR can be arbitrarily complicated provided its
1255 final operation is an element or slice of an aggregate:
1256
1257     delete $ref->[$x][$y]{$key};
1258     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1259
1260     delete $ref->[$x][$y][$index];
1261     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1262
1263 =item die LIST
1264 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1265
1266 C<die> raises an exception. Inside an C<eval> the error message is stuffed
1267 into C<$@> and the C<eval> is terminated with the undefined value.
1268 If the exception is outside of all enclosing C<eval>s, then the uncaught
1269 exception prints LIST to C<STDERR> and exits with a non-zero value. If you
1270 need to exit the process with a specific exit code, see L<exit>.
1271
1272 Equivalent examples:
1273
1274     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1275     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1276
1277 If the last element of LIST does not end in a newline, the current
1278 script line number and input line number (if any) are also printed,
1279 and a newline is supplied.  Note that the "input line number" (also
1280 known as "chunk") is subject to whatever notion of "line" happens to
1281 be currently in effect, and is also available as the special variable
1282 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1283
1284 Hint: sometimes appending C<", stopped"> to your message will cause it
1285 to make better sense when the string C<"at foo line 123"> is appended.
1286 Suppose you are running script "canasta".
1287
1288     die "/etc/games is no good";
1289     die "/etc/games is no good, stopped";
1290
1291 produce, respectively
1292
1293     /etc/games is no good at canasta line 123.
1294     /etc/games is no good, stopped at canasta line 123.
1295
1296 If the output is empty and C<$@> already contains a value (typically from a
1297 previous eval) that value is reused after appending C<"\t...propagated">.
1298 This is useful for propagating exceptions:
1299
1300     eval { ... };
1301     die unless $@ =~ /Expected exception/;
1302
1303 If the output is empty and C<$@> contains an object reference that has a
1304 C<PROPAGATE> method, that method will be called with additional file
1305 and line number parameters.  The return value replaces the value in
1306 C<$@>.  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1307 were called.
1308
1309 If C<$@> is empty then the string C<"Died"> is used.
1310
1311 If an uncaught exception results in interpreter exit, the exit code is
1312 determined from the values of C<$!> and C<$?> with this pseudocode:
1313
1314     exit $! if $!;              # errno
1315     exit $? >> 8 if $? >> 8;    # child exit status
1316     exit 255;                   # last resort
1317
1318 The intent is to squeeze as much possible information about the likely cause
1319 into the limited space of the system exit code. However, as C<$!> is the value
1320 of C's C<errno>, which can be set by any system call, this means that the value
1321 of the exit code used by C<die> can be non-predictable, so should not be relied
1322 upon, other than to be non-zero.
1323
1324 You can also call C<die> with a reference argument, and if this is trapped
1325 within an C<eval>, C<$@> contains that reference.  This permits more
1326 elaborate exception handling using objects that maintain arbitrary state
1327 about the exception.  Such a scheme is sometimes preferable to matching
1328 particular string values of C<$@> with regular expressions.  Because C<$@> 
1329 is a global variable and C<eval> may be used within object implementations,
1330 be careful that analyzing the error object doesn't replace the reference in
1331 the global variable.  It's easiest to make a local copy of the reference
1332 before any manipulations.  Here's an example:
1333
1334     use Scalar::Util "blessed";
1335
1336     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1337     if (my $ev_err = $@) {
1338         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1339             # handle Some::Module::Exception
1340         }
1341         else {
1342             # handle all other possible exceptions
1343         }
1344     }
1345
1346 Because Perl stringifies uncaught exception messages before display,
1347 you'll probably want to overload stringification operations on
1348 exception objects.  See L<overload> for details about that.
1349
1350 You can arrange for a callback to be run just before the C<die>
1351 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1352 handler is called with the error text and can change the error
1353 message, if it sees fit, by calling C<die> again.  See
1354 L<perlvar/$SIG{expr}> for details on setting C<%SIG> entries, and
1355 L<"eval BLOCK"> for some examples.  Although this feature was 
1356 to be run only right before your program was to exit, this is not
1357 currently so: the C<$SIG{__DIE__}> hook is currently called
1358 even inside eval()ed blocks/strings!  If one wants the hook to do
1359 nothing in such situations, put
1360
1361     die @_ if $^S;
1362
1363 as the first line of the handler (see L<perlvar/$^S>).  Because
1364 this promotes strange action at a distance, this counterintuitive
1365 behavior may be fixed in a future release.
1366
1367 See also exit(), warn(), and the Carp module.
1368
1369 =item do BLOCK
1370 X<do> X<block>
1371
1372 Not really a function.  Returns the value of the last command in the
1373 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1374 C<until> loop modifier, executes the BLOCK once before testing the loop
1375 condition. (On other statements the loop modifiers test the conditional
1376 first.)
1377
1378 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1379 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1380 See L<perlsyn> for alternative strategies.
1381
1382 =item do SUBROUTINE(LIST)
1383 X<do>
1384
1385 This form of subroutine call is deprecated.  See L<perlsub>.
1386
1387 =item do EXPR
1388 X<do>
1389
1390 Uses the value of EXPR as a filename and executes the contents of the
1391 file as a Perl script.
1392
1393     do 'stat.pl';
1394
1395 is just like
1396
1397     eval `cat stat.pl`;
1398
1399 except that it's more efficient and concise, keeps track of the current
1400 filename for error messages, searches the @INC directories, and updates
1401 C<%INC> if the file is found.  See L<perlvar/Predefined Names> for these
1402 variables.  It also differs in that code evaluated with C<do FILENAME>
1403 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1404 same, however, in that it does reparse the file every time you call it,
1405 so you probably don't want to do this inside a loop.
1406
1407 If C<do> cannot read the file, it returns undef and sets C<$!> to the
1408 error.  If C<do> can read the file but cannot compile it, it
1409 returns undef and sets an error message in C<$@>.   If the file is
1410 successfully compiled, C<do> returns the value of the last expression
1411 evaluated.
1412
1413 Inclusion of library modules is better done with the
1414 C<use> and C<require> operators, which also do automatic error checking
1415 and raise an exception if there's a problem.
1416
1417 You might like to use C<do> to read in a program configuration
1418 file.  Manual error checking can be done this way:
1419
1420     # read in config files: system first, then user
1421     for $file ("/share/prog/defaults.rc",
1422                "$ENV{HOME}/.someprogrc")
1423     {
1424         unless ($return = do $file) {
1425             warn "couldn't parse $file: $@" if $@;
1426             warn "couldn't do $file: $!"    unless defined $return;
1427             warn "couldn't run $file"       unless $return;
1428         }
1429     }
1430
1431 =item dump LABEL
1432 X<dump> X<core> X<undump>
1433
1434 =item dump
1435
1436 This function causes an immediate core dump.  See also the B<-u>
1437 command-line switch in L<perlrun>, which does the same thing.
1438 Primarily this is so that you can use the B<undump> program (not
1439 supplied) to turn your core dump into an executable binary after
1440 having initialized all your variables at the beginning of the
1441 program.  When the new binary is executed it will begin by executing
1442 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1443 Think of it as a goto with an intervening core dump and reincarnation.
1444 If C<LABEL> is omitted, restarts the program from the top.
1445
1446 B<WARNING>: Any files opened at the time of the dump will I<not>
1447 be open any more when the program is reincarnated, with possible
1448 resulting confusion by Perl.
1449
1450 This function is now largely obsolete, mostly because it's very hard to
1451 convert a core file into an executable. That's why you should now invoke
1452 it as C<CORE::dump()>, if you don't want to be warned against a possible
1453 typo.
1454
1455 =item each HASH (or HASHREF)
1456 X<each> X<hash, iterator>
1457
1458 =item each ARRAY (or ARRAYREF)
1459 X<array, iterator>
1460
1461 When called in list context, returns a 2-element list consisting of the key
1462 and value for the next element of a hash, or the index and value for the
1463 next element of an array, so that you can iterate over it.  When called in
1464 scalar context, returns only the key (not the value) in a hash, or the index
1465 in an array.
1466
1467 Hash entries are returned in an apparently random order.  The actual random
1468 order is subject to change in future versions of Perl, but it is
1469 guaranteed to be in the same order as either the C<keys> or C<values>
1470 function would produce on the same (unmodified) hash.  Since Perl
1471 5.8.2 the ordering can be different even between different runs of Perl
1472 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1473
1474 After C<each> has returned all entries from the hash or array, the next
1475 call to C<each> returns the empty list in list context and C<undef> in
1476 scalar context.  The next call following that one restarts iteration.  Each
1477 hash or array has its own internal iterator, accessed by C<each>, C<keys>,
1478 and C<values>.  The iterator is implicitly reset when C<each> has reached
1479 the end as just described; it can be explicitly reset by calling C<keys> or
1480 C<values> on the hash or array.  If you add or delete a hash's elements
1481 while iterating over it, entries may be skipped or duplicated--so don't do
1482 that.  Exception: It is always safe to delete the item most recently
1483 returned by C<each()>, so the following code works properly:
1484
1485         while (($key, $value) = each %hash) {
1486           print $key, "\n";
1487           delete $hash{$key};   # This is safe
1488         }
1489
1490 This prints out your environment like the printenv(1) program,
1491 but in a different order:
1492
1493     while (($key,$value) = each %ENV) {
1494         print "$key=$value\n";
1495     }
1496
1497 When given a reference to a hash or array, the argument will be
1498 dereferenced automatically.
1499
1500     while (($key,$value) = each $hashref) { ... }
1501
1502 If the reference is a blessed object that overrides either C<%{}> or
1503 C<@{}>, the override will be used instead of dereferencing the underlying
1504 variable type.  If both overrides are provided, C<%{}> will be the default.
1505 If this is not desired, you must dereference the argument yourself.
1506
1507 See also C<keys>, C<values> and C<sort>.
1508
1509 =item eof FILEHANDLE
1510 X<eof>
1511 X<end of file>
1512 X<end-of-file>
1513
1514 =item eof ()
1515
1516 =item eof
1517
1518 Returns 1 if the next read on FILEHANDLE will return end of file, or if
1519 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1520 gives the real filehandle.  (Note that this function actually
1521 reads a character and then C<ungetc>s it, so isn't useful in an
1522 interactive context.)  Do not read from a terminal file (or call
1523 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1524 as terminals may lose the end-of-file condition if you do.
1525
1526 An C<eof> without an argument uses the last file read.  Using C<eof()>
1527 with empty parentheses is different.  It refers to the pseudo file
1528 formed from the files listed on the command line and accessed via the
1529 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1530 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1531 used will cause C<@ARGV> to be examined to determine if input is
1532 available.   Similarly, an C<eof()> after C<< <> >> has returned
1533 end-of-file will assume you are processing another C<@ARGV> list,
1534 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1535 see L<perlop/"I/O Operators">.
1536
1537 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1538 detect the end of each file, C<eof()> will detect the end of only the
1539 last file.  Examples:
1540
1541     # reset line numbering on each input file
1542     while (<>) {
1543         next if /^\s*#/;  # skip comments
1544         print "$.\t$_";
1545     } continue {
1546         close ARGV if eof;  # Not eof()!
1547     }
1548
1549     # insert dashes just before last line of last file
1550     while (<>) {
1551         if (eof()) {  # check for end of last file
1552             print "--------------\n";
1553         }
1554         print;
1555         last if eof();          # needed if we're reading from a terminal
1556     }
1557
1558 Practical hint: you almost never need to use C<eof> in Perl, because the
1559 input operators typically return C<undef> when they run out of data, or if
1560 there was an error.
1561
1562 =item eval EXPR
1563 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1564 X<error, handling> X<exception, handling>
1565
1566 =item eval BLOCK
1567
1568 =item eval
1569
1570 In the first form, the return value of EXPR is parsed and executed as if it
1571 were a little Perl program.  The value of the expression (which is itself
1572 determined within scalar context) is first parsed, and if there weren't any
1573 errors, executed in the lexical context of the current Perl program, so
1574 that any variable settings or subroutine and format definitions remain
1575 afterwards.  Note that the value is parsed every time the C<eval> executes.
1576 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1577 delay parsing and subsequent execution of the text of EXPR until run time.
1578
1579 In the second form, the code within the BLOCK is parsed only once--at the
1580 same time the code surrounding the C<eval> itself was parsed--and executed
1581 within the context of the current Perl program.  This form is typically
1582 used to trap exceptions more efficiently than the first (see below), while
1583 also providing the benefit of checking the code within BLOCK at compile
1584 time.
1585
1586 The final semicolon, if any, may be omitted from the value of EXPR or within
1587 the BLOCK.
1588
1589 In both forms, the value returned is the value of the last expression
1590 evaluated inside the mini-program; a return statement may be also used, just
1591 as with subroutines.  The expression providing the return value is evaluated
1592 in void, scalar, or list context, depending on the context of the C<eval> 
1593 itself.  See L</wantarray> for more on how the evaluation context can be 
1594 determined.
1595
1596 If there is a syntax error or runtime error, or a C<die> statement is
1597 executed, C<eval> returns an undefined value in scalar context
1598 or an empty list in list context, and C<$@> is set to the
1599 error message.  If there was no error, C<$@> is guaranteed to be the empty
1600 string.  Beware that using C<eval> neither silences Perl from printing
1601 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1602 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1603 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1604 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1605
1606 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1607 determining whether a particular feature (such as C<socket> or C<symlink>)
1608 is implemented.  It is also Perl's exception trapping mechanism, where
1609 the die operator is used to raise exceptions.
1610
1611 If you want to trap errors when loading an XS module, some problems with
1612 the binary interface (such as Perl version skew) may be fatal even with
1613 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set. See L<perlrun>.
1614
1615 If the code to be executed doesn't vary, you may use the eval-BLOCK
1616 form to trap run-time errors without incurring the penalty of
1617 recompiling each time.  The error, if any, is still returned in C<$@>.
1618 Examples:
1619
1620     # make divide-by-zero nonfatal
1621     eval { $answer = $a / $b; }; warn $@ if $@;
1622
1623     # same thing, but less efficient
1624     eval '$answer = $a / $b'; warn $@ if $@;
1625
1626     # a compile-time error
1627     eval { $answer = }; # WRONG
1628
1629     # a run-time error
1630     eval '$answer =';   # sets $@
1631
1632 Using the C<eval{}> form as an exception trap in libraries does have some
1633 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1634 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1635 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1636 as this example shows:
1637
1638     # a private exception trap for divide-by-zero
1639     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1640     warn $@ if $@;
1641
1642 This is especially significant, given that C<__DIE__> hooks can call
1643 C<die> again, which has the effect of changing their error messages:
1644
1645     # __DIE__ hooks may modify error messages
1646     {
1647        local $SIG{'__DIE__'} =
1648               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1649        eval { die "foo lives here" };
1650        print $@ if $@;                # prints "bar lives here"
1651     }
1652
1653 Because this promotes action at a distance, this counterintuitive behavior
1654 may be fixed in a future release.
1655
1656 With an C<eval>, you should be especially careful to remember what's
1657 being looked at when:
1658
1659     eval $x;        # CASE 1
1660     eval "$x";      # CASE 2
1661
1662     eval '$x';      # CASE 3
1663     eval { $x };    # CASE 4
1664
1665     eval "\$$x++";  # CASE 5
1666     $$x++;          # CASE 6
1667
1668 Cases 1 and 2 above behave identically: they run the code contained in
1669 the variable $x.  (Although case 2 has misleading double quotes making
1670 the reader wonder what else might be happening (nothing is).)  Cases 3
1671 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1672 does nothing but return the value of $x.  (Case 4 is preferred for
1673 purely visual reasons, but it also has the advantage of compiling at
1674 compile-time instead of at run-time.)  Case 5 is a place where
1675 normally you I<would> like to use double quotes, except that in this
1676 particular situation, you can just use symbolic references instead, as
1677 in case 6.
1678
1679 The assignment to C<$@> occurs before restoration of localised variables,
1680 which means a temporary is required if you want to mask some but not all
1681 errors:
1682
1683     # alter $@ on nefarious repugnancy only
1684     {
1685        my $e;
1686        {
1687           local $@; # protect existing $@
1688           eval { test_repugnancy() };
1689           # $@ =~ /nefarious/ and die $@; # DOES NOT WORK
1690           $@ =~ /nefarious/ and $e = $@;
1691        }
1692        die $e if defined $e
1693     }
1694
1695 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1696 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1697
1698 An C<eval ''> executed within the C<DB> package doesn't see the usual
1699 surrounding lexical scope, but rather the scope of the first non-DB piece
1700 of code that called it. You don't normally need to worry about this unless
1701 you are writing a Perl debugger.
1702
1703 =item exec LIST
1704 X<exec> X<execute>
1705
1706 =item exec PROGRAM LIST
1707
1708 The C<exec> function executes a system command I<and never returns>;
1709 use C<system> instead of C<exec> if you want it to return.  It fails and
1710 returns false only if the command does not exist I<and> it is executed
1711 directly instead of via your system's command shell (see below).
1712
1713 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1714 warns you if there is a following statement that isn't C<die>, C<warn>,
1715 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1716 I<really> want to follow an C<exec> with some other statement, you
1717 can use one of these styles to avoid the warning:
1718
1719     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1720     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1721
1722 If there is more than one argument in LIST, or if LIST is an array
1723 with more than one value, calls execvp(3) with the arguments in LIST.
1724 If there is only one scalar argument or an array with one element in it,
1725 the argument is checked for shell metacharacters, and if there are any,
1726 the entire argument is passed to the system's command shell for parsing
1727 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1728 If there are no shell metacharacters in the argument, it is split into
1729 words and passed directly to C<execvp>, which is more efficient.
1730 Examples:
1731
1732     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1733     exec "sort $outfile | uniq";
1734
1735 If you don't really want to execute the first argument, but want to lie
1736 to the program you are executing about its own name, you can specify
1737 the program you actually want to run as an "indirect object" (without a
1738 comma) in front of the LIST.  (This always forces interpretation of the
1739 LIST as a multivalued list, even if there is only a single scalar in
1740 the list.)  Example:
1741
1742     $shell = '/bin/csh';
1743     exec $shell '-sh';    # pretend it's a login shell
1744
1745 or, more directly,
1746
1747     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1748
1749 When the arguments get executed via the system shell, results are
1750 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1751 for details.
1752
1753 Using an indirect object with C<exec> or C<system> is also more
1754 secure.  This usage (which also works fine with system()) forces
1755 interpretation of the arguments as a multivalued list, even if the
1756 list had just one argument.  That way you're safe from the shell
1757 expanding wildcards or splitting up words with whitespace in them.
1758
1759     @args = ( "echo surprise" );
1760
1761     exec @args;               # subject to shell escapes
1762                                 # if @args == 1
1763     exec { $args[0] } @args;  # safe even with one-arg list
1764
1765 The first version, the one without the indirect object, ran the I<echo>
1766 program, passing it C<"surprise"> an argument.  The second version didn't;
1767 it tried to run a program named I<"echo surprise">, didn't find it, and set
1768 C<$?> to a non-zero value indicating failure.
1769
1770 Beginning with v5.6.0, Perl attempts to flush all files opened for
1771 output before the exec, but this may not be supported on some platforms
1772 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1773 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1774 open handles to avoid lost output.
1775
1776 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1777 C<DESTROY> methods on your objects.
1778
1779 =item exists EXPR
1780 X<exists> X<autovivification>
1781
1782 Given an expression that specifies an element of a hash, returns true if the
1783 specified element in the hash has ever been initialized, even if the
1784 corresponding value is undefined.
1785
1786     print "Exists\n"    if exists $hash{$key};
1787     print "Defined\n"   if defined $hash{$key};
1788     print "True\n"      if $hash{$key};
1789
1790 exists may also be called on array elements, but its behavior is much less
1791 obvious, and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1792 that calling exists on array values is deprecated and likely to be removed in
1793 a future version of Perl.
1794
1795     print "Exists\n"    if exists $array[$index];
1796     print "Defined\n"   if defined $array[$index];
1797     print "True\n"      if $array[$index];
1798
1799 A hash or array element can be true only if it's defined, and defined if
1800 it exists, but the reverse doesn't necessarily hold true.
1801
1802 Given an expression that specifies the name of a subroutine,
1803 returns true if the specified subroutine has ever been declared, even
1804 if it is undefined.  Mentioning a subroutine name for exists or defined
1805 does not count as declaring it.  Note that a subroutine that does not
1806 exist may still be callable: its package may have an C<AUTOLOAD>
1807 method that makes it spring into existence the first time that it is
1808 called; see L<perlsub>.
1809
1810     print "Exists\n"  if exists &subroutine;
1811     print "Defined\n" if defined &subroutine;
1812
1813 Note that the EXPR can be arbitrarily complicated as long as the final
1814 operation is a hash or array key lookup or subroutine name:
1815
1816     if (exists $ref->{A}->{B}->{$key})  { }
1817     if (exists $hash{A}{B}{$key})       { }
1818
1819     if (exists $ref->{A}->{B}->[$ix])   { }
1820     if (exists $hash{A}{B}[$ix])        { }
1821
1822     if (exists &{$ref->{A}{B}{$key}})   { }
1823
1824 Although the mostly deeply nested array or hash will not spring into
1825 existence just because its existence was tested, any intervening ones will.
1826 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1827 into existence due to the existence test for the $key element above.
1828 This happens anywhere the arrow operator is used, including even here:
1829
1830     undef $ref;
1831     if (exists $ref->{"Some key"})    { }
1832     print $ref;  # prints HASH(0x80d3d5c)
1833
1834 This surprising autovivification in what does not at first--or even
1835 second--glance appear to be an lvalue context may be fixed in a future
1836 release.
1837
1838 Use of a subroutine call, rather than a subroutine name, as an argument
1839 to exists() is an error.
1840
1841     exists &sub;    # OK
1842     exists &sub();  # Error
1843
1844 =item exit EXPR
1845 X<exit> X<terminate> X<abort>
1846
1847 =item exit
1848
1849 Evaluates EXPR and exits immediately with that value.    Example:
1850
1851     $ans = <STDIN>;
1852     exit 0 if $ans =~ /^[Xx]/;
1853
1854 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1855 universally recognized values for EXPR are C<0> for success and C<1>
1856 for error; other values are subject to interpretation depending on the
1857 environment in which the Perl program is running.  For example, exiting
1858 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1859 the mailer to return the item undelivered, but that's not true everywhere.
1860
1861 Don't use C<exit> to abort a subroutine if there's any chance that
1862 someone might want to trap whatever error happened.  Use C<die> instead,
1863 which can be trapped by an C<eval>.
1864
1865 The exit() function does not always exit immediately.  It calls any
1866 defined C<END> routines first, but these C<END> routines may not
1867 themselves abort the exit.  Likewise any object destructors that need to
1868 be called are called before the real exit.  C<END> routines and destructors
1869 can change the exit status by modifying C<$?>. If this is a problem, you
1870 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1871 See L<perlmod> for details.
1872
1873 =item exp EXPR
1874 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1875
1876 =item exp
1877
1878 Returns I<e> (the natural logarithm base) to the power of EXPR.
1879 If EXPR is omitted, gives C<exp($_)>.
1880
1881 =item fcntl FILEHANDLE,FUNCTION,SCALAR
1882 X<fcntl>
1883
1884 Implements the fcntl(2) function.  You'll probably have to say
1885
1886     use Fcntl;
1887
1888 first to get the correct constant definitions.  Argument processing and
1889 value returned work just like C<ioctl> below.
1890 For example:
1891
1892     use Fcntl;
1893     fcntl($filehandle, F_GETFL, $packed_return_buffer)
1894         or die "can't fcntl F_GETFL: $!";
1895
1896 You don't have to check for C<defined> on the return from C<fcntl>.
1897 Like C<ioctl>, it maps a C<0> return from the system call into
1898 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
1899 in numeric context.  It is also exempt from the normal B<-w> warnings
1900 on improper numeric conversions.
1901
1902 Note that C<fcntl> raises an exception if used on a machine that
1903 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
1904 manpage to learn what functions are available on your system.
1905
1906 Here's an example of setting a filehandle named C<REMOTE> to be
1907 non-blocking at the system level.  You'll have to negotiate C<$|>
1908 on your own, though.
1909
1910     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
1911
1912     $flags = fcntl(REMOTE, F_GETFL, 0)
1913                 or die "Can't get flags for the socket: $!\n";
1914
1915     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
1916                 or die "Can't set flags for the socket: $!\n";
1917
1918 =item fileno FILEHANDLE
1919 X<fileno>
1920
1921 Returns the file descriptor for a filehandle, or undefined if the
1922 filehandle is not open.  This is mainly useful for constructing
1923 bitmaps for C<select> and low-level POSIX tty-handling operations.
1924 If FILEHANDLE is an expression, the value is taken as an indirect
1925 filehandle, generally its name.
1926
1927 You can use this to find out whether two handles refer to the
1928 same underlying descriptor:
1929
1930     if (fileno(THIS) == fileno(THAT)) {
1931         print "THIS and THAT are dups\n";
1932     }
1933
1934 (Filehandles connected to memory objects via new features of C<open> may
1935 return undefined even though they are open.)
1936
1937
1938 =item flock FILEHANDLE,OPERATION
1939 X<flock> X<lock> X<locking>
1940
1941 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
1942 for success, false on failure.  Produces a fatal error if used on a
1943 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
1944 C<flock> is Perl's portable file locking interface, although it locks
1945 entire files only, not records.
1946
1947 Two potentially non-obvious but traditional C<flock> semantics are
1948 that it waits indefinitely until the lock is granted, and that its locks
1949 B<merely advisory>.  Such discretionary locks are more flexible, but offer
1950 fewer guarantees.  This means that programs that do not also use C<flock>
1951 may modify files locked with C<flock>.  See L<perlport>, 
1952 your port's specific documentation, or your system-specific local manpages
1953 for details.  It's best to assume traditional behavior if you're writing
1954 portable programs.  (But if you're not, you should as always feel perfectly
1955 free to write for your own system's idiosyncrasies (sometimes called
1956 "features").  Slavish adherence to portability concerns shouldn't get
1957 in the way of your getting your job done.)
1958
1959 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
1960 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
1961 you can use the symbolic names if you import them from the Fcntl module,
1962 either individually, or as a group using the ':flock' tag.  LOCK_SH
1963 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
1964 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
1965 LOCK_SH or LOCK_EX then C<flock> returns immediately rather than blocking
1966 waiting for the lock; check the return status to see if you got it.
1967
1968 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
1969 before locking or unlocking it.
1970
1971 Note that the emulation built with lockf(3) doesn't provide shared
1972 locks, and it requires that FILEHANDLE be open with write intent.  These
1973 are the semantics that lockf(3) implements.  Most if not all systems
1974 implement lockf(3) in terms of fcntl(2) locking, though, so the
1975 differing semantics shouldn't bite too many people.
1976
1977 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
1978 be open with read intent to use LOCK_SH and requires that it be open
1979 with write intent to use LOCK_EX.
1980
1981 Note also that some versions of C<flock> cannot lock things over the
1982 network; you would need to use the more system-specific C<fcntl> for
1983 that.  If you like you can force Perl to ignore your system's flock(2)
1984 function, and so provide its own fcntl(2)-based emulation, by passing
1985 the switch C<-Ud_flock> to the F<Configure> program when you configure
1986 Perl.
1987
1988 Here's a mailbox appender for BSD systems.
1989
1990     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
1991
1992     sub lock {
1993         my ($fh) = @_;
1994         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
1995
1996         # and, in case someone appended while we were waiting...
1997         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
1998     }
1999
2000     sub unlock {
2001         my ($fh) = @_;
2002         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2003     }
2004
2005     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2006         or die "Can't open mailbox: $!";
2007
2008     lock($mbox);
2009     print $mbox $msg,"\n\n";
2010     unlock($mbox);
2011
2012 On systems that support a real flock(2), locks are inherited across fork()
2013 calls, whereas those that must resort to the more capricious fcntl(2)
2014 function lose their locks, making it seriously harder to write servers.
2015
2016 See also L<DB_File> for other flock() examples.
2017
2018 =item fork
2019 X<fork> X<child> X<parent>
2020
2021 Does a fork(2) system call to create a new process running the
2022 same program at the same point.  It returns the child pid to the
2023 parent process, C<0> to the child process, or C<undef> if the fork is
2024 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2025 are shared, while everything else is copied.  On most systems supporting
2026 fork(), great care has gone into making it extremely efficient (for
2027 example, using copy-on-write technology on data pages), making it the
2028 dominant paradigm for multitasking over the last few decades.
2029
2030 Beginning with v5.6.0, Perl attempts to flush all files opened for
2031 output before forking the child process, but this may not be supported
2032 on some platforms (see L<perlport>).  To be safe, you may need to set
2033 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2034 C<IO::Handle> on any open handles to avoid duplicate output.
2035
2036 If you C<fork> without ever waiting on your children, you will
2037 accumulate zombies.  On some systems, you can avoid this by setting
2038 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2039 forking and reaping moribund children.
2040
2041 Note that if your forked child inherits system file descriptors like
2042 STDIN and STDOUT that are actually connected by a pipe or socket, even
2043 if you exit, then the remote server (such as, say, a CGI script or a
2044 backgrounded job launched from a remote shell) won't think you're done.
2045 You should reopen those to F</dev/null> if it's any issue.
2046
2047 =item format
2048 X<format>
2049
2050 Declare a picture format for use by the C<write> function.  For
2051 example:
2052
2053     format Something =
2054         Test: @<<<<<<<< @||||| @>>>>>
2055               $str,     $%,    '$' . int($num)
2056     .
2057
2058     $str = "widget";
2059     $num = $cost/$quantity;
2060     $~ = 'Something';
2061     write;
2062
2063 See L<perlform> for many details and examples.
2064
2065 =item formline PICTURE,LIST
2066 X<formline>
2067
2068 This is an internal function used by C<format>s, though you may call it,
2069 too.  It formats (see L<perlform>) a list of values according to the
2070 contents of PICTURE, placing the output into the format output
2071 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2072 Eventually, when a C<write> is done, the contents of
2073 C<$^A> are written to some filehandle.  You could also read C<$^A>
2074 and then set C<$^A> back to C<"">.  Note that a format typically
2075 does one C<formline> per line of form, but the C<formline> function itself
2076 doesn't care how many newlines are embedded in the PICTURE.  This means
2077 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2078 You may therefore need to use multiple formlines to implement a single
2079 record format, just like the C<format> compiler.
2080
2081 Be careful if you put double quotes around the picture, because an C<@>
2082 character may be taken to mean the beginning of an array name.
2083 C<formline> always returns true.  See L<perlform> for other examples.
2084
2085 =item getc FILEHANDLE
2086 X<getc> X<getchar> X<character> X<file, read>
2087
2088 =item getc
2089
2090 Returns the next character from the input file attached to FILEHANDLE,
2091 or the undefined value at end of file or if there was an error (in
2092 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2093 STDIN.  This is not particularly efficient.  However, it cannot be
2094 used by itself to fetch single characters without waiting for the user
2095 to hit enter.  For that, try something more like:
2096
2097     if ($BSD_STYLE) {
2098         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2099     }
2100     else {
2101         system "stty", '-icanon', 'eol', "\001";
2102     }
2103
2104     $key = getc(STDIN);
2105
2106     if ($BSD_STYLE) {
2107         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2108     }
2109     else {
2110         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2111     }
2112     print "\n";
2113
2114 Determination of whether $BSD_STYLE should be set
2115 is left as an exercise to the reader.
2116
2117 The C<POSIX::getattr> function can do this more portably on
2118 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2119 module from your nearest CPAN site; details on CPAN can be found on
2120 L<perlmodlib/CPAN>.
2121
2122 =item getlogin
2123 X<getlogin> X<login>
2124
2125 This implements the C library function of the same name, which on most
2126 systems returns the current login from F</etc/utmp>, if any.  If it
2127 returns the empty string, use C<getpwuid>.
2128
2129     $login = getlogin || getpwuid($<) || "Kilroy";
2130
2131 Do not consider C<getlogin> for authentication: it is not as
2132 secure as C<getpwuid>.
2133
2134 =item getpeername SOCKET
2135 X<getpeername> X<peer>
2136
2137 Returns the packed sockaddr address of other end of the SOCKET connection.
2138
2139     use Socket;
2140     $hersockaddr    = getpeername(SOCK);
2141     ($port, $iaddr) = sockaddr_in($hersockaddr);
2142     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2143     $herstraddr     = inet_ntoa($iaddr);
2144
2145 =item getpgrp PID
2146 X<getpgrp> X<group>
2147
2148 Returns the current process group for the specified PID.  Use
2149 a PID of C<0> to get the current process group for the
2150 current process.  Will raise an exception if used on a machine that
2151 doesn't implement getpgrp(2).  If PID is omitted, returns process
2152 group of current process.  Note that the POSIX version of C<getpgrp>
2153 does not accept a PID argument, so only C<PID==0> is truly portable.
2154
2155 =item getppid
2156 X<getppid> X<parent> X<pid>
2157
2158 Returns the process id of the parent process.
2159
2160 Note for Linux users: on Linux, the C functions C<getpid()> and
2161 C<getppid()> return different values from different threads. In order to
2162 be portable, this behavior is not reflected by the Perl-level function
2163 C<getppid()>, that returns a consistent value across threads. If you want
2164 to call the underlying C<getppid()>, you may use the CPAN module
2165 C<Linux::Pid>.
2166
2167 =item getpriority WHICH,WHO
2168 X<getpriority> X<priority> X<nice>
2169
2170 Returns the current priority for a process, a process group, or a user.
2171 (See C<getpriority(2)>.)  Will raise a fatal exception if used on a
2172 machine that doesn't implement getpriority(2).
2173
2174 =item getpwnam NAME
2175 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2176 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2177 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2178 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2179 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2180 X<endnetent> X<endprotoent> X<endservent> 
2181
2182 =item getgrnam NAME
2183
2184 =item gethostbyname NAME
2185
2186 =item getnetbyname NAME
2187
2188 =item getprotobyname NAME
2189
2190 =item getpwuid UID
2191
2192 =item getgrgid GID
2193
2194 =item getservbyname NAME,PROTO
2195
2196 =item gethostbyaddr ADDR,ADDRTYPE
2197
2198 =item getnetbyaddr ADDR,ADDRTYPE
2199
2200 =item getprotobynumber NUMBER
2201
2202 =item getservbyport PORT,PROTO
2203
2204 =item getpwent
2205
2206 =item getgrent
2207
2208 =item gethostent
2209
2210 =item getnetent
2211
2212 =item getprotoent
2213
2214 =item getservent
2215
2216 =item setpwent
2217
2218 =item setgrent
2219
2220 =item sethostent STAYOPEN
2221
2222 =item setnetent STAYOPEN
2223
2224 =item setprotoent STAYOPEN
2225
2226 =item setservent STAYOPEN
2227
2228 =item endpwent
2229
2230 =item endgrent
2231
2232 =item endhostent
2233
2234 =item endnetent
2235
2236 =item endprotoent
2237
2238 =item endservent
2239
2240 These routines are the same as their counterparts in the
2241 system C library.  In list context, the return values from the
2242 various get routines are as follows:
2243
2244     ($name,$passwd,$uid,$gid,
2245        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2246     ($name,$passwd,$gid,$members) = getgr*
2247     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2248     ($name,$aliases,$addrtype,$net) = getnet*
2249     ($name,$aliases,$proto) = getproto*
2250     ($name,$aliases,$port,$proto) = getserv*
2251
2252 (If the entry doesn't exist you get an empty list.)
2253
2254 The exact meaning of the $gcos field varies but it usually contains
2255 the real name of the user (as opposed to the login name) and other
2256 information pertaining to the user.  Beware, however, that in many
2257 system users are able to change this information and therefore it
2258 cannot be trusted and therefore the $gcos is tainted (see
2259 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2260 login shell, are also tainted, because of the same reason.
2261
2262 In scalar context, you get the name, unless the function was a
2263 lookup by name, in which case you get the other thing, whatever it is.
2264 (If the entry doesn't exist you get the undefined value.)  For example:
2265
2266     $uid   = getpwnam($name);
2267     $name  = getpwuid($num);
2268     $name  = getpwent();
2269     $gid   = getgrnam($name);
2270     $name  = getgrgid($num);
2271     $name  = getgrent();
2272     #etc.
2273
2274 In I<getpw*()> the fields $quota, $comment, and $expire are special
2275 in that they are unsupported on many systems.  If the
2276 $quota is unsupported, it is an empty scalar.  If it is supported, it
2277 usually encodes the disk quota.  If the $comment field is unsupported,
2278 it is an empty scalar.  If it is supported it usually encodes some
2279 administrative comment about the user.  In some systems the $quota
2280 field may be $change or $age, fields that have to do with password
2281 aging.  In some systems the $comment field may be $class.  The $expire
2282 field, if present, encodes the expiration period of the account or the
2283 password.  For the availability and the exact meaning of these fields
2284 in your system, please consult your getpwnam(3) documentation and your
2285 F<pwd.h> file.  You can also find out from within Perl what your
2286 $quota and $comment fields mean and whether you have the $expire field
2287 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2288 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2289 files are supported only if your vendor has implemented them in the
2290 intuitive fashion that calling the regular C library routines gets the
2291 shadow versions if you're running under privilege or if there exists
2292 the shadow(3) functions as found in System V (this includes Solaris
2293 and Linux.)  Those systems that implement a proprietary shadow password
2294 facility are unlikely to be supported.
2295
2296 The $members value returned by I<getgr*()> is a space separated list of
2297 the login names of the members of the group.
2298
2299 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2300 C, it will be returned to you via C<$?> if the function call fails.  The
2301 C<@addrs> value returned by a successful call is a list of raw
2302 addresses returned by the corresponding library call.  In the
2303 Internet domain, each address is four bytes long; you can unpack it
2304 by saying something like:
2305
2306     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2307
2308 The Socket library makes this slightly easier:
2309
2310     use Socket;
2311     $iaddr = inet_aton("127.1"); # or whatever address
2312     $name  = gethostbyaddr($iaddr, AF_INET);
2313
2314     # or going the other way
2315     $straddr = inet_ntoa($iaddr);
2316
2317 In the opposite way, to resolve a hostname to the IP address
2318 you can write this:
2319
2320     use Socket;
2321     $packed_ip = gethostbyname("www.perl.org");
2322     if (defined $packed_ip) {
2323         $ip_address = inet_ntoa($packed_ip);
2324     }
2325
2326 Make sure <gethostbyname()> is called in SCALAR context and that
2327 its return value is checked for definedness.
2328
2329 If you get tired of remembering which element of the return list
2330 contains which return value, by-name interfaces are provided
2331 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2332 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2333 and C<User::grent>.  These override the normal built-ins, supplying
2334 versions that return objects with the appropriate names
2335 for each field.  For example:
2336
2337    use File::stat;
2338    use User::pwent;
2339    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2340
2341 Even though it looks like they're the same method calls (uid),
2342 they aren't, because a C<File::stat> object is different from
2343 a C<User::pwent> object.
2344
2345 =item getsockname SOCKET
2346 X<getsockname>
2347
2348 Returns the packed sockaddr address of this end of the SOCKET connection,
2349 in case you don't know the address because you have several different
2350 IPs that the connection might have come in on.
2351
2352     use Socket;
2353     $mysockaddr = getsockname(SOCK);
2354     ($port, $myaddr) = sockaddr_in($mysockaddr);
2355     printf "Connect to %s [%s]\n",
2356        scalar gethostbyaddr($myaddr, AF_INET),
2357        inet_ntoa($myaddr);
2358
2359 =item getsockopt SOCKET,LEVEL,OPTNAME
2360 X<getsockopt>
2361
2362 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2363 Options may exist at multiple protocol levels depending on the socket
2364 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2365 C<Socket> module) will exist. To query options at another level the
2366 protocol number of the appropriate protocol controlling the option
2367 should be supplied. For example, to indicate that an option is to be
2368 interpreted by the TCP protocol, LEVEL should be set to the protocol
2369 number of TCP, which you can get using C<getprotobyname>.
2370
2371 The function returns a packed string representing the requested socket
2372 option, or C<undef> on error, with the reason for the error placed in
2373 C<$!>). Just what is in the packed string depends on LEVEL and OPTNAME;
2374 consult getsockopt(2) for details.  A common case is that the option is an
2375 integer, in which case the result is a packed integer, which you can decode
2376 using C<unpack> with the C<i> (or C<I>) format.
2377
2378 An example to test whether Nagle's algorithm is turned on on a socket:
2379
2380     use Socket qw(:all);
2381
2382     defined(my $tcp = getprotobyname("tcp"))
2383         or die "Could not determine the protocol number for tcp";
2384     # my $tcp = IPPROTO_TCP; # Alternative
2385     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2386         or die "getsockopt TCP_NODELAY: $!";
2387     my $nodelay = unpack("I", $packed);
2388     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2389
2390
2391 =item glob EXPR
2392 X<glob> X<wildcard> X<filename, expansion> X<expand>
2393
2394 =item glob
2395
2396 In list context, returns a (possibly empty) list of filename expansions on
2397 the value of EXPR such as the standard Unix shell F</bin/csh> would do. In
2398 scalar context, glob iterates through such filename expansions, returning
2399 undef when the list is exhausted. This is the internal function
2400 implementing the C<< <*.c> >> operator, but you can use it directly. If
2401 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2402 more detail in L<perlop/"I/O Operators">.
2403
2404 Note that C<glob> splits its arguments on whitespace and treats
2405 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2406 matches all files with a F<.c> or F<.h> extension.  The expression
2407 C<glob(".* *")> matches all files in the current working directory.
2408
2409 If non-empty braces are the only wildcard characters used in the
2410 C<glob>, no filenames are matched, but potentially many strings
2411 are returned.  For example, this produces nine strings, one for
2412 each pairing of fruits and colors:
2413
2414     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2415
2416 Beginning with v5.6.0, this operator is implemented using the standard
2417 C<File::Glob> extension.  See L<File::Glob> for details, including
2418 C<bsd_glob> which does not treat whitespace as a pattern separator.
2419
2420 =item gmtime EXPR
2421 X<gmtime> X<UTC> X<Greenwich>
2422
2423 =item gmtime
2424
2425 Works just like L<localtime> but the returned values are
2426 localized for the standard Greenwich time zone.
2427
2428 Note: when called in list context, $isdst, the last value
2429 returned by gmtime is always C<0>.  There is no
2430 Daylight Saving Time in GMT.
2431
2432 See L<perlport/gmtime> for portability concerns.
2433
2434 =item goto LABEL
2435 X<goto> X<jump> X<jmp>
2436
2437 =item goto EXPR
2438
2439 =item goto &NAME
2440
2441 The C<goto-LABEL> form finds the statement labeled with LABEL and
2442 resumes execution there. It can't be used to get out of a block or
2443 subroutine given to C<sort>.  It can be used to go almost anywhere
2444 else within the dynamic scope, including out of subroutines, but it's
2445 usually better to use some other construct such as C<last> or C<die>.
2446 The author of Perl has never felt the need to use this form of C<goto>
2447 (in Perl, that is; C is another matter).  (The difference is that C
2448 does not offer named loops combined with loop control.  Perl does, and
2449 this replaces most structured uses of C<goto> in other languages.)
2450
2451 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2452 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2453 necessarily recommended if you're optimizing for maintainability:
2454
2455     goto ("FOO", "BAR", "GLARCH")[$i];
2456
2457 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2458 deprecated and will issue a warning.  Even then, it may not be used to
2459 go into any construct that requires initialization, such as a
2460 subroutine or a C<foreach> loop.  It also can't be used to go into a
2461 construct that is optimized away.
2462
2463 The C<goto-&NAME> form is quite different from the other forms of
2464 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2465 doesn't have the stigma associated with other gotos.  Instead, it
2466 exits the current subroutine (losing any changes set by local()) and
2467 immediately calls in its place the named subroutine using the current
2468 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2469 load another subroutine and then pretend that the other subroutine had
2470 been called in the first place (except that any modifications to C<@_>
2471 in the current subroutine are propagated to the other subroutine.)
2472 After the C<goto>, not even C<caller> will be able to tell that this
2473 routine was called first.
2474
2475 NAME needn't be the name of a subroutine; it can be a scalar variable
2476 containing a code reference, or a block that evaluates to a code
2477 reference.
2478
2479 =item grep BLOCK LIST
2480 X<grep>
2481
2482 =item grep EXPR,LIST
2483
2484 This is similar in spirit to, but not the same as, grep(1) and its
2485 relatives.  In particular, it is not limited to using regular expressions.
2486
2487 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2488 C<$_> to each element) and returns the list value consisting of those
2489 elements for which the expression evaluated to true.  In scalar
2490 context, returns the number of times the expression was true.
2491
2492     @foo = grep(!/^#/, @bar);    # weed out comments
2493
2494 or equivalently,
2495
2496     @foo = grep {!/^#/} @bar;    # weed out comments
2497
2498 Note that C<$_> is an alias to the list value, so it can be used to
2499 modify the elements of the LIST.  While this is useful and supported,
2500 it can cause bizarre results if the elements of LIST are not variables.
2501 Similarly, grep returns aliases into the original list, much as a for
2502 loop's index variable aliases the list elements.  That is, modifying an
2503 element of a list returned by grep (for example, in a C<foreach>, C<map>
2504 or another C<grep>) actually modifies the element in the original list.
2505 This is usually something to be avoided when writing clear code.
2506
2507 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2508 been declared with C<my $_>) then, in addition to being locally aliased to
2509 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2510 can't be seen from the outside, avoiding any potential side-effects.
2511
2512 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2513
2514 =item hex EXPR
2515 X<hex> X<hexadecimal>
2516
2517 =item hex
2518
2519 Interprets EXPR as a hex string and returns the corresponding value.
2520 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2521 L</oct>.)  If EXPR is omitted, uses C<$_>.
2522
2523     print hex '0xAf'; # prints '175'
2524     print hex 'aF';   # same
2525
2526 Hex strings may only represent integers.  Strings that would cause
2527 integer overflow trigger a warning.  Leading whitespace is not stripped,
2528 unlike oct(). To present something as hex, look into L</printf>,
2529 L</sprintf>, or L</unpack>.
2530
2531 =item import LIST
2532 X<import>
2533
2534 There is no builtin C<import> function.  It is just an ordinary
2535 method (subroutine) defined (or inherited) by modules that wish to export
2536 names to another module.  The C<use> function calls the C<import> method
2537 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2538
2539 =item index STR,SUBSTR,POSITION
2540 X<index> X<indexOf> X<InStr>
2541
2542 =item index STR,SUBSTR
2543
2544 The index function searches for one string within another, but without
2545 the wildcard-like behavior of a full regular-expression pattern match.
2546 It returns the position of the first occurrence of SUBSTR in STR at
2547 or after POSITION.  If POSITION is omitted, starts searching from the
2548 beginning of the string.  POSITION before the beginning of the string
2549 or after its end is treated as if it were the beginning or the end,
2550 respectively.  POSITION and the return value are based at C<0> (or whatever
2551 you've set the C<$[> variable to--but don't do that).  If the substring
2552 is not found, C<index> returns one less than the base, ordinarily C<-1>.
2553
2554 =item int EXPR
2555 X<int> X<integer> X<truncate> X<trunc> X<floor>
2556
2557 =item int
2558
2559 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2560 You should not use this function for rounding: one because it truncates
2561 towards C<0>, and two because machine representations of floating-point
2562 numbers can sometimes produce counterintuitive results.  For example,
2563 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2564 because it's really more like -268.99999999999994315658 instead.  Usually,
2565 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2566 functions will serve you better than will int().
2567
2568 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2569 X<ioctl>
2570
2571 Implements the ioctl(2) function.  You'll probably first have to say
2572
2573     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2574
2575 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2576 exist or doesn't have the correct definitions you'll have to roll your
2577 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2578 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2579 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2580 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2581 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2582 has no string value but does have a numeric value, that value will be
2583 passed rather than a pointer to the string value.  To guarantee this to be
2584 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2585 functions may be needed to manipulate the values of structures used by
2586 C<ioctl>.
2587
2588 The return value of C<ioctl> (and C<fcntl>) is as follows:
2589
2590     if OS returns:      then Perl returns:
2591         -1               undefined value
2592          0              string "0 but true"
2593     anything else           that number
2594
2595 Thus Perl returns true on success and false on failure, yet you can
2596 still easily determine the actual value returned by the operating
2597 system:
2598
2599     $retval = ioctl(...) || -1;
2600     printf "System returned %d\n", $retval;
2601
2602 The special string C<"0 but true"> is exempt from B<-w> complaints
2603 about improper numeric conversions.
2604
2605 =item join EXPR,LIST
2606 X<join>
2607
2608 Joins the separate strings of LIST into a single string with fields
2609 separated by the value of EXPR, and returns that new string.  Example:
2610
2611     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2612
2613 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2614 first argument.  Compare L</split>.
2615
2616 =item keys HASH (or HASHREF)
2617 X<keys> X<key>
2618
2619 =item keys ARRAY (or ARRAYREF)
2620
2621 Returns a list consisting of all the keys of the named hash, or the indices
2622 of an array. (In scalar context, returns the number of keys or indices.)
2623
2624 The keys of a hash are returned in an apparently random order.  The actual
2625 random order is subject to change in future versions of Perl, but it
2626 is guaranteed to be the same order as either the C<values> or C<each>
2627 function produces (given that the hash has not been modified).  Since
2628 Perl 5.8.1 the ordering can be different even between different runs of
2629 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2630 Attacks">).
2631
2632 As a side effect, calling keys() resets the HASH or ARRAY's internal iterator
2633 (see L</each>).  In particular, calling keys() in void context resets
2634 the iterator with no other overhead.
2635
2636 Here is yet another way to print your environment:
2637
2638     @keys = keys %ENV;
2639     @values = values %ENV;
2640     while (@keys) {
2641         print pop(@keys), '=', pop(@values), "\n";
2642     }
2643
2644 or how about sorted by key:
2645
2646     foreach $key (sort(keys %ENV)) {
2647         print $key, '=', $ENV{$key}, "\n";
2648     }
2649
2650 The returned values are copies of the original keys in the hash, so
2651 modifying them will not affect the original hash.  Compare L</values>.
2652
2653 To sort a hash by value, you'll need to use a C<sort> function.
2654 Here's a descending numeric sort of a hash by its values:
2655
2656     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2657         printf "%4d %s\n", $hash{$key}, $key;
2658     }
2659
2660 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2661 allocated for the given hash.  This can gain you a measure of efficiency if
2662 you know the hash is going to get big.  (This is similar to pre-extending
2663 an array by assigning a larger number to $#array.)  If you say
2664
2665     keys %hash = 200;
2666
2667 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2668 in fact, since it rounds up to the next power of two.  These
2669 buckets will be retained even if you do C<%hash = ()>, use C<undef
2670 %hash> if you want to free the storage while C<%hash> is still in scope.
2671 You can't shrink the number of buckets allocated for the hash using
2672 C<keys> in this way (but you needn't worry about doing this by accident,
2673 as trying has no effect). C<keys @array> in an lvalue context is a syntax
2674 error.
2675
2676 When given a reference to a hash or array, the argument will be
2677 dereferenced automatically.
2678
2679     for (keys $hashref) { ... }
2680     for (keys $obj->get_arrayref) { ... }
2681
2682 If the reference is a blessed object that overrides either C<%{}> or
2683 C<@{}>, the override will be used instead of dereferencing the underlying
2684 variable type.  If both overrides are provided, C<%{}> will be the default.
2685 If this is not desired, you must dereference the argument yourself.
2686
2687 See also C<each>, C<values> and C<sort>.
2688
2689 =item kill SIGNAL, LIST
2690 X<kill> X<signal>
2691
2692 Sends a signal to a list of processes.  Returns the number of
2693 processes successfully signaled (which is not necessarily the
2694 same as the number actually killed).
2695
2696     $cnt = kill 1, $child1, $child2;
2697     kill 9, @goners;
2698
2699 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2700 checks whether it's I<possible> to send a signal to it (that
2701 means, to be brief, that the process is owned by the same user, or we are
2702 the super-user).  This is useful to check that a child process is still
2703 alive (even if only as a zombie) and hasn't changed its UID.  See
2704 L<perlport> for notes on the portability of this construct.
2705
2706 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2707 of processes. That means you usually want to use positive not negative signals.
2708 You may also use a signal name in quotes.
2709
2710 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2711 the operating system.  For example, on POSIX-conforming systems, zero will
2712 signal the current process group and -1 will signal all processes.
2713
2714 See L<perlipc/"Signals"> for more details.
2715
2716 =item last LABEL
2717 X<last> X<break>
2718
2719 =item last
2720
2721 The C<last> command is like the C<break> statement in C (as used in
2722 loops); it immediately exits the loop in question.  If the LABEL is
2723 omitted, the command refers to the innermost enclosing loop.  The
2724 C<continue> block, if any, is not executed:
2725
2726     LINE: while (<STDIN>) {
2727         last LINE if /^$/;  # exit when done with header
2728         #...
2729     }
2730
2731 C<last> cannot be used to exit a block that returns a value such as
2732 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
2733 a grep() or map() operation.
2734
2735 Note that a block by itself is semantically identical to a loop
2736 that executes once.  Thus C<last> can be used to effect an early
2737 exit out of such a block.
2738
2739 See also L</continue> for an illustration of how C<last>, C<next>, and
2740 C<redo> work.
2741
2742 =item lc EXPR
2743 X<lc> X<lowercase>
2744
2745 =item lc
2746
2747 Returns a lowercased version of EXPR.  This is the internal function
2748 implementing the C<\L> escape in double-quoted strings.
2749
2750 If EXPR is omitted, uses C<$_>.
2751
2752 What gets returned depends on several factors:
2753
2754 =over
2755
2756 =item If C<use bytes> is in effect:
2757
2758 =over
2759
2760 =item On EBCDIC platforms
2761
2762 The results are what the C language system call C<tolower()> returns.
2763
2764 =item On ASCII platforms
2765
2766 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
2767 respectively.
2768
2769 =back
2770
2771 =item Otherwise, If EXPR has the UTF8 flag set
2772
2773 If the current package has a subroutine named C<ToLower>, it will be used to
2774 change the case (See L<perlunicode/User-Defined Case Mappings>.)
2775 Otherwise Unicode semantics are used for the case change.
2776
2777 =item Otherwise, if C<use locale> is in effect
2778
2779 Respects current LC_CTYPE locale.  See L<perllocale>.
2780
2781 =item Otherwise, if C<use feature 'unicode_strings'> is in effect:
2782
2783 Unicode semantics are used for the case change.  Any subroutine named
2784 C<ToLower> will not be used.
2785
2786 =item Otherwise:
2787
2788 =over
2789
2790 =item On EBCDIC platforms
2791
2792 The results are what the C language system call C<tolower()> returns.
2793
2794 =item On ASCII platforms
2795
2796 ASCII semantics are used for the case change.  The lowercase of any character
2797 outside the ASCII range is the character itself.
2798
2799 =back
2800
2801 =back
2802
2803 =item lcfirst EXPR
2804 X<lcfirst> X<lowercase>
2805
2806 =item lcfirst
2807
2808 Returns the value of EXPR with the first character lowercased.  This
2809 is the internal function implementing the C<\l> escape in
2810 double-quoted strings.
2811
2812 If EXPR is omitted, uses C<$_>.
2813
2814 This function behaves the same way under various pragma, such as in a locale,
2815 as L</lc> does.
2816
2817 =item length EXPR
2818 X<length> X<size>
2819
2820 =item length
2821
2822 Returns the length in I<characters> of the value of EXPR.  If EXPR is
2823 omitted, returns length of C<$_>.  If EXPR is undefined, returns C<undef>.
2824
2825 This function cannot be used on an entire array or hash to find out how
2826 many elements these have.  For that, use C<scalar @array> and C<scalar keys
2827 %hash>, respectively.
2828
2829 Like all Perl character operations, length() normally deals in logical
2830 characters, not physical bytes.  For how many bytes a string encoded as
2831 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
2832 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
2833
2834 =item link OLDFILE,NEWFILE
2835 X<link>
2836
2837 Creates a new filename linked to the old filename.  Returns true for
2838 success, false otherwise.
2839
2840 =item listen SOCKET,QUEUESIZE
2841 X<listen>
2842
2843 Does the same thing that the listen(2) system call does.  Returns true if
2844 it succeeded, false otherwise.  See the example in
2845 L<perlipc/"Sockets: Client/Server Communication">.
2846
2847 =item local EXPR
2848 X<local>
2849
2850 You really probably want to be using C<my> instead, because C<local> isn't
2851 what most people think of as "local".  See
2852 L<perlsub/"Private Variables via my()"> for details.
2853
2854 A local modifies the listed variables to be local to the enclosing
2855 block, file, or eval.  If more than one value is listed, the list must
2856 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
2857 for details, including issues with tied arrays and hashes.
2858
2859 The C<delete local EXPR> construct can also be used to localize the deletion
2860 of array/hash elements to the current block.
2861 See L<perlsub/"Localized deletion of elements of composite types">.
2862
2863 =item localtime EXPR
2864 X<localtime> X<ctime>
2865
2866 =item localtime
2867
2868 Converts a time as returned by the time function to a 9-element list
2869 with the time analyzed for the local time zone.  Typically used as
2870 follows:
2871
2872     #  0    1    2     3     4    5     6     7     8
2873     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
2874                                                 localtime(time);
2875
2876 All list elements are numeric, and come straight out of the C `struct
2877 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
2878 of the specified time.
2879
2880 C<$mday> is the day of the month, and C<$mon> is the month itself, in
2881 the range C<0..11> with 0 indicating January and 11 indicating December.
2882 This makes it easy to get a month name from a list:
2883
2884     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
2885     print "$abbr[$mon] $mday";
2886     # $mon=9, $mday=18 gives "Oct 18"
2887
2888 C<$year> is the number of years since 1900, not just the last two digits
2889 of the year.  That is, C<$year> is C<123> in year 2023.  The proper way
2890 to get a 4-digit year is simply:
2891
2892     $year += 1900;
2893
2894 Otherwise you create non-Y2K-compliant programs--and you wouldn't want
2895 to do that, would you?
2896
2897 To get the last two digits of the year (e.g., '01' in 2001) do:
2898
2899     $year = sprintf("%02d", $year % 100);
2900
2901 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
2902 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
2903 (or C<0..365> in leap years.)
2904
2905 C<$isdst> is true if the specified time occurs during Daylight Saving
2906 Time, false otherwise.
2907
2908 If EXPR is omitted, C<localtime()> uses the current time (as returned
2909 by time(3)).
2910
2911 In scalar context, C<localtime()> returns the ctime(3) value:
2912
2913     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
2914
2915 This scalar value is B<not> locale dependent but is a Perl builtin. For GMT
2916 instead of local time use the L</gmtime> builtin. See also the
2917 C<Time::Local> module (to convert the second, minutes, hours, ... back to
2918 the integer value returned by time()), and the L<POSIX> module's strftime(3)
2919 and mktime(3) functions.
2920
2921 To get somewhat similar but locale dependent date strings, set up your
2922 locale environment variables appropriately (please see L<perllocale>) and
2923 try for example:
2924
2925     use POSIX qw(strftime);
2926     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
2927     # or for GMT formatted appropriately for your locale:
2928     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
2929
2930 Note that the C<%a> and C<%b>, the short forms of the day of the week
2931 and the month of the year, may not necessarily be three characters wide.
2932
2933 See L<perlport/localtime> for portability concerns.
2934
2935 The L<Time::gmtime> and L<Time::localtime> modules provides a convenient,
2936 by-name access mechanism to the gmtime() and localtime() functions,
2937 respectively.
2938
2939 For a comprehensive date and time representation look at the
2940 L<DateTime> module on CPAN.
2941
2942 =item lock THING
2943 X<lock>
2944
2945 This function places an advisory lock on a shared variable, or referenced
2946 object contained in I<THING> until the lock goes out of scope.
2947
2948 lock() is a "weak keyword" : this means that if you've defined a function
2949 by this name (before any calls to it), that function will be called
2950 instead.  If you are not under C<use threads::shared> this does nothing.
2951 See L<threads::shared>.
2952
2953 =item log EXPR
2954 X<log> X<logarithm> X<e> X<ln> X<base>
2955
2956 =item log
2957
2958 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
2959 returns log of C<$_>.  To get the log of another base, use basic algebra:
2960 The base-N log of a number is equal to the natural log of that number
2961 divided by the natural log of N.  For example:
2962
2963     sub log10 {
2964         my $n = shift;
2965         return log($n)/log(10);
2966     }
2967
2968 See also L</exp> for the inverse operation.
2969
2970 =item lstat EXPR
2971 X<lstat>
2972
2973 =item lstat
2974
2975 Does the same thing as the C<stat> function (including setting the
2976 special C<_> filehandle) but stats a symbolic link instead of the file
2977 the symbolic link points to.  If symbolic links are unimplemented on
2978 your system, a normal C<stat> is done.  For much more detailed
2979 information, please see the documentation for C<stat>.
2980
2981 If EXPR is omitted, stats C<$_>.
2982
2983 =item m//
2984
2985 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
2986
2987 =item map BLOCK LIST
2988 X<map>
2989
2990 =item map EXPR,LIST
2991
2992 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2993 C<$_> to each element) and returns the list value composed of the
2994 results of each such evaluation.  In scalar context, returns the
2995 total number of elements so generated.  Evaluates BLOCK or EXPR in
2996 list context, so each element of LIST may produce zero, one, or
2997 more elements in the returned value.
2998
2999     @chars = map(chr, @nums);
3000
3001 translates a list of numbers to the corresponding characters.  And
3002
3003     %hash = map { get_a_key_for($_) => $_ } @array;
3004
3005 is just a funny way to write
3006
3007     %hash = ();
3008     foreach (@array) {
3009         $hash{get_a_key_for($_)} = $_;
3010     }
3011
3012 Note that C<$_> is an alias to the list value, so it can be used to
3013 modify the elements of the LIST.  While this is useful and supported,
3014 it can cause bizarre results if the elements of LIST are not variables.
3015 Using a regular C<foreach> loop for this purpose would be clearer in
3016 most cases.  See also L</grep> for an array composed of those items of
3017 the original list for which the BLOCK or EXPR evaluates to true.
3018
3019 If C<$_> is lexical in the scope where the C<map> appears (because it has
3020 been declared with C<my $_>), then, in addition to being locally aliased to
3021 the list elements, C<$_> keeps being lexical inside the block; that is, it
3022 can't be seen from the outside, avoiding any potential side-effects.
3023
3024 C<{> starts both hash references and blocks, so C<map { ...> could be either
3025 the start of map BLOCK LIST or map EXPR, LIST. Because Perl doesn't look
3026 ahead for the closing C<}> it has to take a guess at which it's dealing with
3027 based on what it finds just after the C<{>. Usually it gets it right, but if it
3028 doesn't it won't realize something is wrong until it gets to the C<}> and
3029 encounters the missing (or unexpected) comma. The syntax error will be
3030 reported close to the C<}>, but you'll need to change something near the C<{>
3031 such as using a unary C<+> to give Perl some help:
3032
3033     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3034     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3035     %hash = map { ("\L$_" => 1) } @array  # this also works
3036     %hash = map {  lc($_) => 1  } @array  # as does this.
3037     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3038
3039     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3040
3041 or to force an anon hash constructor use C<+{>:
3042
3043    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3044
3045 to get a list of anonymous hashes each with only one entry apiece.
3046
3047 =item mkdir FILENAME,MASK
3048 X<mkdir> X<md> X<directory, create>
3049
3050 =item mkdir FILENAME
3051
3052 =item mkdir
3053
3054 Creates the directory specified by FILENAME, with permissions
3055 specified by MASK (as modified by C<umask>).  If it succeeds it
3056 returns true, otherwise it returns false and sets C<$!> (errno).
3057 If omitted, MASK defaults to 0777. If omitted, FILENAME defaults
3058 to C<$_>.
3059
3060 In general, it is better to create directories with permissive MASK,
3061 and let the user modify that with their C<umask>, than it is to supply
3062 a restrictive MASK and give the user no way to be more permissive.
3063 The exceptions to this rule are when the file or directory should be
3064 kept private (mail files, for instance).  The perlfunc(1) entry on
3065 C<umask> discusses the choice of MASK in more detail.
3066
3067 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3068 number of trailing slashes.  Some operating and filesystems do not get
3069 this right, so Perl automatically removes all trailing slashes to keep
3070 everyone happy.
3071
3072 To recursively create a directory structure, look at
3073 the C<mkpath> function of the L<File::Path> module.
3074
3075 =item msgctl ID,CMD,ARG
3076 X<msgctl>
3077
3078 Calls the System V IPC function msgctl(2).  You'll probably have to say
3079
3080     use IPC::SysV;
3081
3082 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3083 then ARG must be a variable that will hold the returned C<msqid_ds>
3084 structure.  Returns like C<ioctl>: the undefined value for error,
3085 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3086 L<perlipc/"SysV IPC">, C<IPC::SysV>, and C<IPC::Semaphore> documentation.
3087
3088 =item msgget KEY,FLAGS
3089 X<msgget>
3090
3091 Calls the System V IPC function msgget(2).  Returns the message queue
3092 id, or the undefined value if there is an error.  See also
3093 L<perlipc/"SysV IPC"> and C<IPC::SysV> and C<IPC::Msg> documentation.
3094
3095 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3096 X<msgrcv>
3097
3098 Calls the System V IPC function msgrcv to receive a message from
3099 message queue ID into variable VAR with a maximum message size of
3100 SIZE.  Note that when a message is received, the message type as a
3101 native long integer will be the first thing in VAR, followed by the
3102 actual message.  This packing may be opened with C<unpack("l! a*")>.
3103 Taints the variable.  Returns true if successful, or false if there is
3104 an error.  See also L<perlipc/"SysV IPC">, C<IPC::SysV>, and
3105 C<IPC::SysV::Msg> documentation.
3106
3107 =item msgsnd ID,MSG,FLAGS
3108 X<msgsnd>
3109
3110 Calls the System V IPC function msgsnd to send the message MSG to the
3111 message queue ID.  MSG must begin with the native long integer message
3112 type, and be followed by the length of the actual message, and finally
3113 the message itself.  This kind of packing can be achieved with
3114 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3115 or false if there is an error.  See also C<IPC::SysV>
3116 and C<IPC::SysV::Msg> documentation.
3117
3118 =item my EXPR
3119 X<my>
3120
3121 =item my TYPE EXPR
3122
3123 =item my EXPR : ATTRS
3124
3125 =item my TYPE EXPR : ATTRS
3126
3127 A C<my> declares the listed variables to be local (lexically) to the
3128 enclosing block, file, or C<eval>.  If more than one value is listed,
3129 the list must be placed in parentheses.
3130
3131 The exact semantics and interface of TYPE and ATTRS are still
3132 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3133 and attributes are handled using the C<attributes> pragma, or starting
3134 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3135 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3136 L<attributes>, and L<Attribute::Handlers>.
3137
3138 =item next LABEL
3139 X<next> X<continue>
3140
3141 =item next
3142
3143 The C<next> command is like the C<continue> statement in C; it starts
3144 the next iteration of the loop:
3145
3146     LINE: while (<STDIN>) {
3147         next LINE if /^#/;  # discard comments
3148         #...
3149     }
3150
3151 Note that if there were a C<continue> block on the above, it would get
3152 executed even on discarded lines.  If LABEL is omitted, the command
3153 refers to the innermost enclosing loop.
3154
3155 C<next> cannot be used to exit a block which returns a value such as
3156 C<eval {}>, C<sub {}> or C<do {}>, and should not be used to exit
3157 a grep() or map() operation.
3158
3159 Note that a block by itself is semantically identical to a loop
3160 that executes once.  Thus C<next> will exit such a block early.
3161
3162 See also L</continue> for an illustration of how C<last>, C<next>, and
3163 C<redo> work.
3164
3165 =item no MODULE VERSION LIST
3166 X<no declarations>
3167 X<unimporting>
3168
3169 =item no MODULE VERSION
3170
3171 =item no MODULE LIST
3172
3173 =item no MODULE
3174
3175 =item no VERSION
3176
3177 See the C<use> function, of which C<no> is the opposite.
3178
3179 =item oct EXPR
3180 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3181
3182 =item oct
3183
3184 Interprets EXPR as an octal string and returns the corresponding
3185 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3186 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3187 binary string.  Leading whitespace is ignored in all three cases.)
3188 The following will handle decimal, binary, octal, and hex in standard
3189 Perl notation:
3190
3191     $val = oct($val) if $val =~ /^0/;
3192
3193 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3194 in octal), use sprintf() or printf():
3195
3196     $dec_perms = (stat("filename"))[2] & 07777;
3197     $oct_perm_str = sprintf "%o", $perms;
3198
3199 The oct() function is commonly used when a string such as C<644> needs
3200 to be converted into a file mode, for example.  Although Perl 
3201 automatically converts strings into numbers as needed, this automatic
3202 conversion assumes base 10.
3203
3204 Leading white space is ignored without warning, as too are any trailing 
3205 non-digits, such as a decimal point (C<oct> only handles non-negative
3206 integers, not negative integers or floating point).
3207
3208 =item open FILEHANDLE,EXPR
3209 X<open> X<pipe> X<file, open> X<fopen>
3210
3211 =item open FILEHANDLE,MODE,EXPR
3212
3213 =item open FILEHANDLE,MODE,EXPR,LIST
3214
3215 =item open FILEHANDLE,MODE,REFERENCE
3216
3217 =item open FILEHANDLE
3218
3219 Opens the file whose filename is given by EXPR, and associates it with
3220 FILEHANDLE.
3221
3222 Simple examples to open a file for reading:
3223
3224     open(my $fh, '<', "input.txt") or die $!;
3225
3226 and for writing:
3227
3228     open(my $fh, '>', "output.txt") or die $!;
3229
3230 (The following is a comprehensive reference to open(): for a gentler
3231 introduction you may consider L<perlopentut>.)
3232
3233 If FILEHANDLE is an undefined scalar variable (or array or hash element)
3234 the variable is assigned a reference to a new anonymous filehandle,
3235 otherwise if FILEHANDLE is an expression, its value is used as the name of
3236 the real filehandle wanted.  (This is considered a symbolic reference, so
3237 C<use strict 'refs'> should I<not> be in effect.)
3238
3239 If EXPR is omitted, the scalar variable of the same name as the
3240 FILEHANDLE contains the filename.  (Note that lexical variables--those
3241 declared with C<my>--will not work for this purpose; so if you're
3242 using C<my>, specify EXPR in your call to open.)
3243
3244 If three or more arguments are specified then the mode of opening and
3245 the filename are separate. If MODE is C<< '<' >> or nothing, the file
3246 is opened for input.  If MODE is C<< '>' >>, the file is truncated and
3247 opened for output, being created if necessary.  If MODE is C<<< '>>' >>>,
3248 the file is opened for appending, again being created if necessary.
3249
3250 You can put a C<'+'> in front of the C<< '>' >> or C<< '<' >> to
3251 indicate that you want both read and write access to the file; thus
3252 C<< '+<' >> is almost always preferred for read/write updates--the 
3253 C<< '+>' >> mode would clobber the file first.  You can't usually use
3254 either read-write mode for updating textfiles, since they have
3255 variable length records.  See the B<-i> switch in L<perlrun> for a
3256 better approach.  The file is created with permissions of C<0666>
3257 modified by the process's C<umask> value.
3258
3259 These various prefixes correspond to the fopen(3) modes of C<'r'>,
3260 C<'r+'>, C<'w'>, C<'w+'>, C<'a'>, and C<'a+'>.
3261
3262 In the two-argument (and one-argument) form of the call, the mode and
3263 filename should be concatenated (in that order), possibly separated by
3264 spaces.  You may omit the mode in these forms when that mode is
3265 C<< '<' >>.
3266
3267 If the filename begins with C<'|'>, the filename is interpreted as a
3268 command to which output is to be piped, and if the filename ends with a
3269 C<'|'>, the filename is interpreted as a command that pipes output to
3270 us.  See L<perlipc/"Using open() for IPC">
3271 for more examples of this.  (You are not allowed to C<open> to a command
3272 that pipes both in I<and> out, but see L<IPC::Open2>, L<IPC::Open3>,
3273 and L<perlipc/"Bidirectional Communication with Another Process">
3274 for alternatives.)
3275
3276 For three or more arguments if MODE is C<'|-'>, the filename is
3277 interpreted as a command to which output is to be piped, and if MODE
3278 is C<'-|'>, the filename is interpreted as a command that pipes
3279 output to us.  In the two-argument (and one-argument) form, one should
3280 replace dash (C<'-'>) with the command.
3281 See L<perlipc/"Using open() for IPC"> for more examples of this.
3282 (You are not allowed to C<open> to a command that pipes both in I<and>
3283 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3284 L<perlipc/"Bidirectional Communication"> for alternatives.)
3285
3286 In the form of pipe opens taking three or more arguments, if LIST is specified
3287 (extra arguments after the command name) then LIST becomes arguments
3288 to the command invoked if the platform supports it.  The meaning of
3289 C<open> with more than three arguments for non-pipe modes is not yet
3290 defined, but experimental "layers" may give extra LIST arguments
3291 meaning.
3292
3293 In the two-argument (and one-argument) form, opening C<< '<-' >> 
3294 or C<'-'> opens STDIN and opening C<< '>-' >> opens STDOUT.
3295
3296 You may use the three-argument form of open to specify I/O layers
3297 (sometimes referred to as "disciplines") to apply to the handle
3298 that affect how the input and output are processed (see L<open> and
3299 L<PerlIO> for more details). For example:
3300
3301   open(my $fh, "<:encoding(UTF-8)", "filename")
3302     || die "can't open UTF-8 encoded filename: $!";
3303
3304 opens the UTF-8 encoded file containing Unicode characters;
3305 see L<perluniintro>. Note that if layers are specified in the
3306 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3307 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3308
3309 Open returns nonzero on success, the undefined value otherwise.  If
3310 the C<open> involved a pipe, the return value happens to be the pid of
3311 the subprocess.
3312
3313 If you're running Perl on a system that distinguishes between text
3314 files and binary files, then you should check out L</binmode> for tips
3315 for dealing with this.  The key distinction between systems that need
3316 C<binmode> and those that don't is their text file formats.  Systems
3317 like Unix, Mac OS, and Plan 9, that end lines with a single
3318 character and encode that character in C as C<"\n"> do not
3319 need C<binmode>.  The rest need it.
3320
3321 When opening a file, it's seldom a good idea to continue 
3322 if the request failed, so C<open> is frequently used with
3323 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3324 where you want to format a suitable error message (but there are
3325 modules that can help with that problem)) always check
3326 the return value from opening a file.  
3327
3328 As a special case the 3-arg form with a read/write mode and the third
3329 argument being C<undef>:
3330
3331     open(my $tmp, "+>", undef) or die ...
3332
3333 opens a filehandle to an anonymous temporary file.  Also using "+<"
3334 works for symmetry, but you really should consider writing something
3335 to the temporary file first.  You will need to seek() to do the
3336 reading.
3337
3338 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3339 changed this (i.e., Configure -Uuseperlio), you can open filehandles 
3340 directly to Perl scalars via:
3341
3342     open($fh, '>', \$variable) || ..
3343
3344 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3345
3346     close STDOUT;
3347     open STDOUT, '>', \$variable or die "Can't open STDOUT: $!";
3348
3349 General examples:
3350
3351     $ARTICLE = 100;
3352     open ARTICLE or die "Can't find article $ARTICLE: $!\n";
3353     while (<ARTICLE>) {...
3354
3355     open(LOG, '>>/usr/spool/news/twitlog');  # (log is reserved)
3356     # if the open fails, output is discarded
3357
3358     open(my $dbase, '+<', 'dbase.mine')      # open for update
3359         or die "Can't open 'dbase.mine' for update: $!";
3360
3361     open(my $dbase, '+<dbase.mine')          # ditto
3362         or die "Can't open 'dbase.mine' for update: $!";
3363
3364     open(ARTICLE, '-|', "caesar <$article")  # decrypt article
3365         or die "Can't start caesar: $!";
3366
3367     open(ARTICLE, "caesar <$article |")      # ditto
3368         or die "Can't start caesar: $!";
3369
3370     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3371         or die "Can't start sort: $!";
3372
3373     # in-memory files
3374     open(MEMORY,'>', \$var)
3375         or die "Can't open memory file: $!";
3376     print MEMORY "foo!\n";                   # output will appear in $var
3377
3378     # process argument list of files along with any includes
3379
3380     foreach $file (@ARGV) {
3381         process($file, 'fh00');
3382     }
3383
3384     sub process {
3385         my($filename, $input) = @_;
3386         $input++;    # this is a string increment
3387         unless (open($input, $filename)) {
3388             print STDERR "Can't open $filename: $!\n";
3389             return;
3390         }
3391
3392         local $_;
3393         while (<$input>) {    # note use of indirection
3394             if (/^#include "(.*)"/) {
3395                 process($1, $input);
3396                 next;
3397             }
3398             #...          # whatever
3399         }
3400     }
3401
3402 See L<perliol> for detailed info on PerlIO.
3403
3404 You may also, in the Bourne shell tradition, specify an EXPR beginning
3405 with C<< '>&' >>, in which case the rest of the string is interpreted
3406 as the name of a filehandle (or file descriptor, if numeric) to be
3407 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3408 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3409 The mode you specify should match the mode of the original filehandle.
3410 (Duping a filehandle does not take into account any existing contents
3411 of IO buffers.) If you use the 3-arg form then you can pass either a
3412 number, the name of a filehandle or the normal "reference to a glob".
3413
3414 Here is a script that saves, redirects, and restores C<STDOUT> and
3415 C<STDERR> using various methods:
3416
3417     #!/usr/bin/perl
3418     open my $oldout, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3419     open OLDERR,     ">&", \*STDERR or die "Can't dup STDERR: $!";
3420
3421     open STDOUT, '>', "foo.out" or die "Can't redirect STDOUT: $!";
3422     open STDERR, ">&STDOUT"     or die "Can't dup STDOUT: $!";
3423
3424     select STDERR; $| = 1;  # make unbuffered
3425     select STDOUT; $| = 1;  # make unbuffered
3426
3427     print STDOUT "stdout 1\n";  # this works for
3428     print STDERR "stderr 1\n";  # subprocesses too
3429
3430     open STDOUT, ">&", $oldout or die "Can't dup \$oldout: $!";
3431     open STDERR, ">&OLDERR"    or die "Can't dup OLDERR: $!";
3432
3433     print STDOUT "stdout 2\n";
3434     print STDERR "stderr 2\n";
3435
3436 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3437 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3438 that file descriptor (and not call C<dup(2)>); this is more
3439 parsimonious of file descriptors.  For example:
3440
3441     # open for input, reusing the fileno of $fd
3442     open(FILEHANDLE, "<&=$fd")
3443
3444 or
3445
3446     open(FILEHANDLE, "<&=", $fd)
3447
3448 or
3449
3450     # open for append, using the fileno of OLDFH
3451     open(FH, ">>&=", OLDFH)
3452
3453 or
3454
3455     open(FH, ">>&=OLDFH")
3456
3457 Being parsimonious on filehandles is also useful (besides being
3458 parsimonious) for example when something is dependent on file
3459 descriptors, like for example locking using flock().  If you do just
3460 C<< open(A, '>>&B') >>, the filehandle A will not have the same file
3461 descriptor as B, and therefore flock(A) will not flock(B), and vice
3462 versa.  But with C<< open(A, '>>&=B') >> the filehandles will share
3463 the same file descriptor.
3464
3465 Note that if you are using Perls older than 5.8.0, Perl will be using
3466 the standard C libraries' fdopen() to implement the "=" functionality.
3467 On many Unix systems fdopen() fails when file descriptors exceed a
3468 certain value, typically 255.  For Perls 5.8.0 and later, PerlIO is
3469 most often the default.
3470
3471 You can see whether Perl has been compiled with PerlIO or not by
3472 running C<perl -V> and looking for C<useperlio=> line.  If C<useperlio>
3473 is C<define>, you have PerlIO, otherwise you don't.
3474
3475 If you open a pipe on the command C<'-'>, i.e., either C<'|-'> or C<'-|'>
3476 with 2-arguments (or 1-argument) form of open(), then
3477 there is an implicit fork done, and the return value of open is the pid
3478 of the child within the parent process, and C<0> within the child
3479 process.  (Use C<defined($pid)> to determine whether the open was successful.)
3480 The filehandle behaves normally for the parent, but I/O to that
3481 filehandle is piped from/to the STDOUT/STDIN of the child process.
3482 In the child process, the filehandle isn't opened--I/O happens from/to
3483 the new STDOUT/STDIN.  Typically this is used like the normal
3484 piped open when you want to exercise more control over just how the
3485 pipe command gets executed, such as when running setuid and
3486 you don't want to have to scan shell commands for metacharacters.
3487
3488 The following blocks are more or less equivalent:
3489
3490     open(FOO, "|tr '[a-z]' '[A-Z]'");
3491     open(FOO, '|-', "tr '[a-z]' '[A-Z]'");
3492     open(FOO, '|-') || exec 'tr', '[a-z]', '[A-Z]';
3493     open(FOO, '|-', "tr", '[a-z]', '[A-Z]');
3494
3495     open(FOO, "cat -n '$file'|");
3496     open(FOO, '-|', "cat -n '$file'");
3497     open(FOO, '-|') || exec 'cat', '-n', $file;
3498     open(FOO, '-|', "cat", '-n', $file);
3499
3500 The last two examples in each block shows the pipe as "list form", which is
3501 not yet supported on all platforms.  A good rule of thumb is that if
3502 your platform has true C<fork()> (in other words, if your platform is
3503 Unix) you can use the list form.
3504
3505 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3506
3507 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3508 output before any operation that may do a fork, but this may not be
3509 supported on some platforms (see L<perlport>).  To be safe, you may need
3510 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3511 of C<IO::Handle> on any open handles.
3512
3513 On systems that support a close-on-exec flag on files, the flag will
3514 be set for the newly opened file descriptor as determined by the value
3515 of $^F.  See L<perlvar/$^F>.
3516
3517 Closing any piped filehandle causes the parent process to wait for the
3518 child to finish, and returns the status value in C<$?> and
3519 C<${^CHILD_ERROR_NATIVE}>.
3520
3521 The filename passed to 2-argument (or 1-argument) form of open() will
3522 have leading and trailing whitespace deleted, and the normal
3523 redirection characters honored.  This property, known as "magic open",
3524 can often be used to good effect.  A user could specify a filename of
3525 F<"rsh cat file |">, or you could change certain filenames as needed:
3526
3527     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3528     open(FH, $filename) or die "Can't open $filename: $!";
3529
3530 Use 3-argument form to open a file with arbitrary weird characters in it,
3531
3532     open(FOO, '<', $file);
3533
3534 otherwise it's necessary to protect any leading and trailing whitespace:
3535
3536     $file =~ s#^(\s)#./$1#;
3537     open(FOO, "< $file\0");
3538
3539 (this may not work on some bizarre filesystems).  One should
3540 conscientiously choose between the I<magic> and 3-arguments form
3541 of open():
3542
3543     open IN, $ARGV[0];
3544
3545 will allow the user to specify an argument of the form C<"rsh cat file |">,
3546 but will not work on a filename that happens to have a trailing space, while
3547
3548     open IN, '<', $ARGV[0];
3549
3550 will have exactly the opposite restrictions.
3551
3552 If you want a "real" C C<open> (see C<open(2)> on your system), then you
3553 should use the C<sysopen> function, which involves no such magic (but
3554 may use subtly different filemodes than Perl open(), which is mapped
3555 to C fopen()).  This is
3556 another way to protect your filenames from interpretation.  For example:
3557
3558     use IO::Handle;
3559     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3560         or die "sysopen $path: $!";
3561     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3562     print HANDLE "stuff $$\n";
3563     seek(HANDLE, 0, 0);
3564     print "File contains: ", <HANDLE>;
3565
3566 Using the constructor from the C<IO::Handle> package (or one of its
3567 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3568 filehandles that have the scope of whatever variables hold references to
3569 them, and automatically close whenever and however you leave that scope:
3570
3571     use IO::File;
3572     #...
3573     sub read_myfile_munged {
3574         my $ALL = shift;
3575         my $handle = IO::File->new;
3576         open($handle, "myfile") or die "myfile: $!";
3577         $first = <$handle>
3578             or return ();     # Automatically closed here.
3579         mung $first or die "mung failed";  # Or here.
3580         return $first, <$handle> if $ALL;  # Or here.
3581         $first;          # Or here.
3582     }
3583
3584 See L</seek> for some details about mixing reading and writing.
3585
3586 =item opendir DIRHANDLE,EXPR
3587 X<opendir>
3588
3589 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3590 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3591 DIRHANDLE may be an expression whose value can be used as an indirect
3592 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3593 scalar variable (or array or hash element), the variable is assigned a
3594 reference to a new anonymous dirhandle.
3595 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3596
3597 See example at C<readdir>.
3598
3599 =item ord EXPR
3600 X<ord> X<encoding>
3601
3602 =item ord
3603
3604 Returns the numeric (the native 8-bit encoding, like ASCII or EBCDIC,
3605 or Unicode) value of the first character of EXPR.  If EXPR is an empty
3606 string, returns 0.  If EXPR is omitted, uses C<$_>.
3607
3608 For the reverse, see L</chr>.
3609 See L<perlunicode> for more about Unicode.
3610
3611 =item our EXPR
3612 X<our> X<global>
3613
3614 =item our TYPE EXPR
3615
3616 =item our EXPR : ATTRS
3617
3618 =item our TYPE EXPR : ATTRS
3619
3620 C<our> associates a simple name with a package variable in the current
3621 package for use within the current scope.  When C<use strict 'vars'> is in
3622 effect, C<our> lets you use declared global variables without qualifying
3623 them with package names, within the lexical scope of the C<our> declaration.
3624 In this way C<our> differs from C<use vars>, which is package scoped.
3625
3626 Unlike C<my>, which both allocates storage for a variable and associates
3627 a simple name with that storage for use within the current scope, C<our>
3628 associates a simple name with a package variable in the current package,
3629 for use within the current scope.  In other words, C<our> has the same
3630 scoping rules as C<my>, but does not necessarily create a
3631 variable.
3632
3633 If more than one value is listed, the list must be placed
3634 in parentheses.
3635
3636     our $foo;
3637     our($bar, $baz);
3638
3639 An C<our> declaration declares a global variable that will be visible
3640 across its entire lexical scope, even across package boundaries.  The
3641 package in which the variable is entered is determined at the point
3642 of the declaration, not at the point of use.  This means the following
3643 behavior holds:
3644
3645     package Foo;
3646     our $bar;      # declares $Foo::bar for rest of lexical scope
3647     $bar = 20;
3648
3649     package Bar;
3650     print $bar;    # prints 20, as it refers to $Foo::bar
3651
3652 Multiple C<our> declarations with the same name in the same lexical
3653 scope are allowed if they are in different packages.  If they happen
3654 to be in the same package, Perl will emit warnings if you have asked
3655 for them, just like multiple C<my> declarations.  Unlike a second
3656 C<my> declaration, which will bind the name to a fresh variable, a
3657 second C<our> declaration in the same package, in the same scope, is
3658 merely redundant.
3659
3660     use warnings;
3661     package Foo;
3662     our $bar;      # declares $Foo::bar for rest of lexical scope
3663     $bar = 20;
3664
3665     package Bar;
3666     our $bar = 30; # declares $Bar::bar for rest of lexical scope
3667     print $bar;    # prints 30
3668
3669     our $bar;      # emits warning but has no other effect
3670     print $bar;    # still prints 30
3671
3672 An C<our> declaration may also have a list of attributes associated
3673 with it.
3674
3675 The exact semantics and interface of TYPE and ATTRS are still
3676 evolving.  TYPE is currently bound to the use of C<fields> pragma,
3677 and attributes are handled using the C<attributes> pragma, or starting
3678 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3679 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3680 L<attributes>, and L<Attribute::Handlers>.
3681
3682 =item pack TEMPLATE,LIST
3683 X<pack>
3684
3685 Takes a LIST of values and converts it into a string using the rules
3686 given by the TEMPLATE.  The resulting string is the concatenation of
3687 the converted values.  Typically, each converted value looks
3688 like its machine-level representation.  For example, on 32-bit machines
3689 an integer may be represented by a sequence of 4 bytes, which  will in
3690 Perl be presented as a string that's 4 characters long. 
3691
3692 See L<perlpacktut> for an introduction to this function.
3693
3694 The TEMPLATE is a sequence of characters that give the order and type
3695 of values, as follows:
3696
3697     a  A string with arbitrary binary data, will be null padded.
3698     A  A text (ASCII) string, will be space padded.
3699     Z  A null-terminated (ASCIZ) string, will be null padded.
3700
3701     b  A bit string (ascending bit order inside each byte, like vec()).
3702     B  A bit string (descending bit order inside each byte).
3703     h  A hex string (low nybble first).
3704     H  A hex string (high nybble first).
3705
3706     c  A signed char (8-bit) value.
3707     C  An unsigned char (octet) value.
3708     W  An unsigned char value (can be greater than 255).
3709
3710     s  A signed short (16-bit) value.
3711     S  An unsigned short value.
3712
3713     l  A signed long (32-bit) value.
3714     L  An unsigned long value.
3715
3716     q  A signed quad (64-bit) value.
3717     Q  An unsigned quad value.
3718       (Quads are available only if your system supports 64-bit
3719        integer values _and_ if Perl has been compiled to support those.
3720            Raises an exception otherwise.)
3721
3722     i  A signed integer value.
3723     I  A unsigned integer value.
3724       (This 'integer' is _at_least_ 32 bits wide.  Its exact
3725            size depends on what a local C compiler calls 'int'.)
3726
3727     n  An unsigned short (16-bit) in "network" (big-endian) order.
3728     N  An unsigned long (32-bit) in "network" (big-endian) order.
3729     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
3730     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
3731
3732     j   A Perl internal signed integer value (IV).
3733     J   A Perl internal unsigned integer value (UV).
3734
3735     f  A single-precision float in native format.
3736     d  A double-precision float in native format.
3737
3738     F  A Perl internal floating-point value (NV) in native format
3739     D  A float of long-double precision in native format.
3740       (Long doubles are available only if your system supports long
3741        double values _and_ if Perl has been compiled to support those.
3742            Raises an exception otherwise.)
3743
3744     p  A pointer to a null-terminated string.
3745     P  A pointer to a structure (fixed-length string).
3746
3747     u  A uuencoded string.
3748     U  A Unicode character number.  Encodes to a character in character mode
3749         and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in byte mode.
3750
3751     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut for
3752        details).  Its bytes represent an unsigned integer in base 128,
3753        most significant digit first, with as few digits as possible.  Bit
3754        eight (the high bit) is set on each byte except the last.
3755
3756     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
3757     X  Back up a byte.
3758     @  Null-fill or truncate to absolute position, counted from the
3759        start of the innermost ()-group.
3760     .  Null-fill or truncate to absolute position specified by the value.
3761     (  Start of a ()-group.
3762
3763 One or more modifiers below may optionally follow certain letters in the
3764 TEMPLATE (the second column lists letters for which the modifier is valid):
3765
3766     !   sSlLiI     Forces native (short, long, int) sizes instead
3767                    of fixed (16-/32-bit) sizes.
3768
3769         xX         Make x and X act as alignment commands.
3770
3771         nNvV       Treat integers as signed instead of unsigned.
3772
3773         @.         Specify position as byte offset in the internal
3774                    representation of the packed string. Efficient but
3775                    dangerous.
3776
3777     >   sSiIlLqQ   Force big-endian byte-order on the type.
3778         jJfFdDpP   (The "big end" touches the construct.)
3779
3780     <   sSiIlLqQ   Force little-endian byte-order on the type.
3781         jJfFdDpP   (The "little end" touches the construct.)
3782
3783 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
3784 to force a particular byte-order on all components in that group, 
3785 including all its subgroups.
3786
3787 The following rules apply:
3788
3789 =over 
3790
3791 =item *
3792
3793 Each letter may optionally be followed by a number indicating the repeat
3794 count.  A numeric repeat count may optionally be enclosed in brackets, as
3795 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
3796 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
3797 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
3798 something else, dscribed below.  Supplying a C<*> for the repeat count
3799 instead of a number means to use however many items are left, except for:
3800
3801 =over 
3802
3803 =item * 
3804
3805 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
3806
3807 =item * 
3808
3809 <.>, where it means relative to the start of the string.
3810
3811 =item * 
3812
3813 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
3814
3815 =back 
3816
3817 One can replace a numeric repeat count with a template letter enclosed in
3818 brackets to use the packed byte length of the bracketed template for the
3819 repeat count.
3820
3821 For example, the template C<x[L]> skips as many bytes as in a packed long,
3822 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
3823 variable-expanded) unpacks.  If the template in brackets contains alignment
3824 commands (such as C<x![d]>), its packed length is calculated as if the
3825 start of the template had the maximal possible alignment.
3826
3827 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
3828 trailing null byte, so the resulting string is always one byte longer than
3829 the byte length of the item itself.
3830
3831 When used with C<@>, the repeat count represents an offset from the start
3832 of the innermost C<()> group.
3833
3834 When used with C<.>, the repeat count determines the starting position to
3835 calculate the value offset as follows:
3836
3837 =over 
3838
3839 =item *
3840
3841 If the repeat count is C<0>, it's relative to the current position.
3842
3843 =item *
3844
3845 If the repeat count is C<*>, the offset is relative to the start of the
3846 packed string.
3847
3848 =item *
3849
3850 And if it's an integer I<n>, the offset is relative to the start of the
3851 I<n>th innermost C<()> group, or to the start of the string if I<n> is
3852 bigger then the group level.
3853
3854 =back
3855
3856 The repeat count for C<u> is interpreted as the maximal number of bytes
3857 to encode per line of output, with 0, 1 and 2 replaced by 45. The repeat 
3858 count should not be more than 65.
3859
3860 =item *
3861
3862 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
3863 string of length count, padding with nulls or spaces as needed.  When
3864 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
3865 after the first null, and C<a> returns data without any sort of trimming.
3866
3867 If the value to pack is too long, the result is truncated.  If it's too
3868 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
3869 followed by a null byte.  Thus C<Z> always packs a trailing null, except
3870 for when the count is 0.
3871
3872 =item *
3873
3874 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
3875 Each such format generates 1 bit of the result.
3876
3877 Each result bit is based on the least-significant bit of the corresponding
3878 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
3879 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
3880
3881 Starting from the beginning of the input string, each 8-tuple
3882 of characters is converted to 1 character of output.  With format C<b>,
3883 the first character of the 8-tuple determines the least-significant bit of a
3884 character; with format C<B>, it determines the most-significant bit of
3885 a character.
3886
3887 If the length of the input string is not evenly divisible by 8, the
3888 remainder is packed as if the input string were padded by null characters
3889 at the end.  Similarly during unpacking, "extra" bits are ignored.
3890
3891 If the input string is longer than needed, remaining characters are ignored.
3892
3893 A C<*> for the repeat count uses all characters of the input field.  
3894 On unpacking, bits are converted to a string of C<"0">s and C<"1">s.
3895
3896 =item *
3897
3898 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
3899 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
3900
3901 For each such format, pack() generates 4 bits of the result.
3902 With non-alphabetical characters, the result is based on the 4 least-significant
3903 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
3904 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
3905 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
3906 is compatible with the usual hexadecimal digits, so that C<"a"> and
3907 C<"A"> both generate the nybble C<0xa==10>.  Do not use any characters
3908 but these with this format.
3909
3910 Starting from the beginning of the template to pack(), each pair
3911 of characters is converted to 1 character of output.  With format C<h>, the
3912 first character of the pair determines the least-significant nybble of the
3913 output character; with format C<H>, it determines the most-significant
3914 nybble.
3915
3916 If the length of the input string is not even, it behaves as if padded by
3917 a null character at the end.  Similarly, "extra" nybbles are ignored during
3918 unpacking.
3919
3920 If the input string is longer than needed, extra characters are ignored.
3921
3922 A C<*> for the repeat count uses all characters of the input field.  For
3923 unpack(), nybbles are converted to a string of hexadecimal digits.
3924
3925 =item *
3926
3927 The C<p> format packs a pointer to a null-terminated string.  You are
3928 responsible for ensuring that the string is not a temporary value, as that
3929 could potentially get deallocated before you got around to using the packed
3930 result.  The C<P> format packs a pointer to a structure of the size indicated
3931 by the length.  A null pointer is created if the corresponding value for
3932 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
3933 unpacks into C<undef>.
3934
3935 If your system has a strange pointer size--meaning a pointer is neither as
3936 big as an int nor as big as a long--it may not be possible to pack or
3937 unpack pointers in big- or little-endian byte order.  Attempting to do
3938 so raises an exception.
3939
3940 =item *
3941
3942 The C</> template character allows packing and unpacking of a sequence of
3943 items where the packed structure contains a packed item count followed by
3944 the packed items themselves.  This is useful when the structure you're
3945 unpacking has encoded the sizes or repeat counts for some of its fields
3946 within the structure itself as separate fields.
3947
3948 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
3949 I<length-item> describes how the length value is packed. Formats likely
3950 to be of most use are integer-packing ones like C<n> for Java strings,
3951 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
3952
3953 For C<pack>, I<sequence-item> may have a repeat count, in which case
3954 the minimum of that and the number of available items is used as the argument
3955 for I<length-item>. If it has no repeat count or uses a '*', the number
3956 of available items is used.
3957
3958 For C<unpack>, an internal stack of integer arguments unpacked so far is
3959 used. You write C</>I<sequence-item> and the repeat count is obtained by
3960 popping off the last element from the stack. The I<sequence-item> must not
3961 have a repeat count.
3962
3963 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
3964 the I<length-item> is the string length, not the number of strings.  With
3965 an explicit repeat count for pack, the packed string is adjusted to that
3966 length.  For example:
3967
3968     unpack("W/a", "\004Gurusamy")           gives ("Guru")
3969     unpack("a3/A A*", "007 Bond  J ")       gives (" Bond", "J")
3970     unpack("a3 x2 /A A*", "007: Bond, J.")  gives ("Bond, J", ".")
3971
3972     pack("n/a* w/a","hello,","world")       gives "\000\006hello,\005world"
3973     pack("a/W2", ord("a") .. ord("z"))      gives "2ab"
3974
3975 The I<length-item> is not returned explicitly from C<unpack>.
3976
3977 Supplying a count to the I<length-item> format letter is only useful with
3978 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
3979 introduce C<"\000"> characters, which Perl does not regard as legal in
3980 numeric strings.
3981
3982 =item *
3983
3984 The integer types C<s>, C<S>, C<l>, and C<L> may be
3985 followed by a C<!> modifier to specify native shorts or
3986 longs.  As shown in the example above, a bare C<l> means
3987 exactly 32 bits, although the native C<long> as seen by the local C compiler
3988 may be larger.  This is mainly an issue on 64-bit platforms.  You can
3989 see whether using C<!> makes any difference this way:
3990
3991     printf "format s is %d, s! is %d\n", 
3992         length pack("s"), length pack("s!");
3993
3994     printf "format l is %d, l! is %d\n", 
3995         length pack("l"), length pack("l!");
3996
3997
3998 C<i!> and C<I!> are also allowed, but only for completeness' sake:
3999 they are identical to C<i> and C<I>.
4000
4001 The actual sizes (in bytes) of native shorts, ints, longs, and long
4002 longs on the platform where Perl was built are also available from
4003 the command line:
4004
4005     $ perl -V:{short,int,long{,long}}size
4006     shortsize='2';
4007     intsize='4';
4008     longsize='4';
4009     longlongsize='8';
4010
4011 or programmatically via the C<Config> module:
4012
4013        use Config;
4014        print $Config{shortsize},    "\n";
4015        print $Config{intsize},      "\n";
4016        print $Config{longsize},     "\n";
4017        print $Config{longlongsize}, "\n";
4018
4019 C<$Config{longlongsize}> is undefined on systems without 
4020 long long support.
4021
4022 =item *
4023
4024 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4025 inherently non-portable between processors and operating systems because
4026 they obey native byteorder and endianness.  For example, a 4-byte integer
4027 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4028 handled by the CPU registers) into bytes as
4029
4030     0x12 0x34 0x56 0x78  # big-endian
4031     0x78 0x56 0x34 0x12  # little-endian
4032
4033 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4034 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4035 big-endian.  Alpha and MIPS can be either: Digital/Compaq used/uses them in
4036 little-endian mode, but SGI/Cray uses them in big-endian mode.
4037
4038 The names I<big-endian> and I<little-endian> are comic references to the
4039 egg-eating habits of the little-endian Lilliputians and the big-endian
4040 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4041 This entered computer lingo via the paper "On Holy Wars and a Plea for
4042 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4043
4044 Some systems may have even weirder byte orders such as
4045
4046    0x56 0x78 0x12 0x34
4047    0x34 0x12 0x78 0x56
4048
4049 You can determine your system endianness with this incantation:
4050
4051    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4052
4053 The byteorder on the platform where Perl was built is also available
4054 via L<Config>:
4055
4056     use Config;
4057     print "$Config{byteorder}\n";
4058
4059 or from the command line:
4060
4061     $ perl -V:byteorder
4062
4063 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4064 and C<"87654321"> are big-endian.
4065
4066 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4067 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4068 immediately below.  See also L<perlport>.
4069
4070 =item *
4071
4072 Starting with Perl 5.9.2, integer and floating-point formats, along with
4073 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4074 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4075 or little-endian byte-order.  These modifiers are especially useful 
4076 given how C<n>, C<N>, C<v> and C<V> don't cover signed integers, 
4077 64-bit integers, or floating-point values.
4078
4079 Here are some concerns to keep in mind when using endianness modifier:
4080
4081 =over
4082
4083 =item * 
4084
4085 Exchanging signed integers between different platforms works only 
4086 when all platforms store them in the same format.  Most platforms store
4087 signed integers in two's-complement notation, so usually this is not an issue.
4088
4089 =item * 
4090
4091 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4092 formats on big- or little-endian machines.  Otherwise, attempting to
4093 use them raises an exception.
4094
4095 =item * 
4096
4097 Forcing big- or little-endian byte-order on floating-point values for
4098 data exchange can work only if all platforms use the same
4099 binary representation such as IEEE floating-point.  Even if all
4100 platforms are using IEEE, there may still be subtle differences.  Being able
4101 to use C<< > >> or C<< < >> on floating-point values can be useful,
4102 but also dangerous if you don't know exactly what you're doing.
4103 It is not a general way to portably store floating-point values.
4104
4105 =item * 
4106
4107 When using C<< > >> or C<< < >> on a C<()> group, this affects
4108 all types inside the group that accept byte-order modifiers,
4109 including all subgroups.  It is silently ignored for all other
4110 types.  You are not allowed to override the byte-order within a group
4111 that already has a byte-order modifier suffix.
4112
4113 =back
4114
4115 =item *
4116
4117 Real numbers (floats and doubles) are in native machine format only.
4118 Due to the multiplicity of floating-point formats and the lack of a
4119 standard "network" representation for them, no facility for interchange has been
4120 made.  This means that packed floating-point data written on one machine
4121 may not be readable on another, even if both use IEEE floating-point
4122 arithmetic (because the endianness of the memory representation is not part
4123 of the IEEE spec).  See also L<perlport>.
4124
4125 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4126 modifiers to force big- or little-endian byte-order on floating-point values.
4127
4128 Because Perl uses doubles (or long doubles, if configured) internally for
4129 all numeric calculation, converting from double into float and thence 
4130 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4131 will not in general equal $foo.
4132
4133 =item *
4134
4135 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4136 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4137 where the packed string is processed in its UTF-8-encoded Unicode form on
4138 a byte-by-byte basis. Character mode is the default unless the format string 
4139 starts with C<U>. You can always switch mode mid-format with an explicit 
4140 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4141 mode change, or until the end of the C<()> group it (directly) applies to.
4142
4143 =item *
4144
4145 You must yourself do any alignment or padding by inserting, for example,
4146 enough C<"x">es while packing.  There is no way for pack() and unpack()
4147 to know where characters are going to or coming from, so they 
4148 handle their output and input as flat sequences of characters.
4149
4150 =item *
4151
4152 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4153 take a repeat count either as postfix, or for unpack(), also via the C</>
4154 template character.  Within each repetition of a group, positioning with
4155 C<@> starts over at 0. Therefore, the result of
4156
4157     pack("@1A((@2A)@3A)", qw[X Y Z])
4158
4159 is the string C<"\0X\0\0YZ">.
4160
4161 =item *
4162
4163 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4164 jump forward or back to the closest position aligned at a multiple of C<count>
4165 characters. For example, to pack() or unpack() a C structure like
4166
4167     struct {
4168         char   c;    /* one signed, 8-bit character */
4169         double d; 
4170         char   cc[2];
4171     }
4172
4173 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4174 doubles must be aligned to the size of double.
4175
4176 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4177 both are no-ops.
4178
4179 =item *
4180
4181 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4182 represent signed 16-/32-bit integers in big-/little-endian order.
4183 This is portable only when all platforms sharing packed data use the
4184 same binary representation for signed integers; for example, when all
4185 platforms use two's-complement representation.
4186
4187 =item *
4188
4189 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4190 White space can separate pack codes from each other, but modifiers and
4191 repeat counts must follow immediately.  Breaking complex templates into
4192 individual line-by-line components, suitably annotated, can do as much to
4193 improve legibility and maintainability of pack/unpack formats as C</x> can
4194 for complicated pattern matches.
4195
4196 =item *
4197
4198 If TEMPLATE requires more arguments that pack() is given, pack()
4199 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4200 than given, extra arguments are ignored.
4201
4202 =back
4203
4204 Examples:
4205
4206     $foo = pack("WWWW",65,66,67,68);
4207     # foo eq "ABCD"
4208     $foo = pack("W4",65,66,67,68);
4209     # same thing
4210     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4211     # same thing with Unicode circled letters.
4212     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4213     # same thing with Unicode circled letters. You don't get the UTF-8
4214     # bytes because the U at the start of the format caused a switch to
4215     # U0-mode, so the UTF-8 bytes get joined into characters
4216     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4217     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4218     # This is the UTF-8 encoding of the string in the previous example
4219
4220     $foo = pack("ccxxcc",65,66,67,68);
4221     # foo eq "AB\0\0CD"
4222
4223     # NOTE: The examples above featuring "W" and "c" are true
4224     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4225     # and UTF-8.  On EBCDIC systems, the first example would be
4226     #      $foo = pack("WWWW",193,194,195,196);
4227
4228     $foo = pack("s2",1,2);
4229     # "\001\000\002\000" on little-endian
4230     # "\000\001\000\002" on big-endian
4231
4232     $foo = pack("a4","abcd","x","y","z");
4233     # "abcd"
4234
4235     $foo = pack("aaaa","abcd","x","y","z");
4236     # "axyz"
4237
4238     $foo = pack("a14","abcdefg");
4239     # "abcdefg\0\0\0\0\0\0\0"
4240
4241     $foo = pack("i9pl", gmtime);
4242     # a real struct tm (on my system anyway)
4243
4244     $utmp_template = "Z8 Z8 Z16 L";
4245     $utmp = pack($utmp_template, @utmp1);
4246     # a struct utmp (BSDish)
4247
4248     @utmp2 = unpack($utmp_template, $utmp);
4249     # "@utmp1" eq "@utmp2"
4250
4251     sub bintodec {
4252         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4253     }
4254
4255     $foo = pack('sx2l', 12, 34);
4256     # short 12, two zero bytes padding, long 34
4257     $bar = pack('s@4l', 12, 34);
4258     # short 12, zero fill to position 4, long 34
4259     # $foo eq $bar
4260     $baz = pack('s.l', 12, 4, 34);
4261     # short 12, zero fill to position 4, long 34
4262
4263     $foo = pack('nN', 42, 4711);
4264     # pack big-endian 16- and 32-bit unsigned integers
4265     $foo = pack('S>L>', 42, 4711);
4266     # exactly the same
4267     $foo = pack('s<l<', -42, 4711);
4268     # pack little-endian 16- and 32-bit signed integers
4269     $foo = pack('(sl)<', -42, 4711);
4270     # exactly the same
4271
4272 The same template may generally also be used in unpack().
4273
4274 =item package NAMESPACE VERSION
4275 X<package> X<module> X<namespace> X<version>
4276
4277 =item package NAMESPACE
4278
4279 =item package NAMESPACE VERSION BLOCK
4280 X<package> X<module> X<namespace> X<version>
4281
4282 =item package NAMESPACE BLOCK
4283
4284 Declares the BLOCK, or the rest of the compilation unit, as being in
4285 the given namespace.  The scope of the package declaration is either the
4286 supplied code BLOCK or, in the absence of a BLOCK, from the declaration
4287 itself through the end of the enclosing block, file, or eval (the same
4288 as the C<my> operator).  All unqualified dynamic identifiers in this
4289 scope will be in the given namespace, except where overridden by another
4290 C<package> declaration.
4291
4292 A package statement affects dynamic variables only, including those
4293 you've used C<local> on, but I<not> lexical variables, which are created
4294 with C<my> (or C<our> (or C<state>)).  Typically it would be the first 
4295 declaration in a file included by C<require> or C<use>.  You can switch into a
4296 package in more than one place, since this only determines which default 
4297 symbol table the compiler uses for the rest of that block.  You can refer to
4298 identifiers in other packages than the current one by prefixing the identifier
4299 with the package name and a double colon, as in C<$SomePack::var>
4300 or C<ThatPack::INPUT_HANDLE>.  If package name is omitted, the C<main>
4301 package as assumed.  That is, C<$::sail> is equivalent to
4302 C<$main::sail> (as well as to C<$main'sail>, still seen in ancient
4303 code, mostly from Perl 4).
4304
4305 If VERSION is provided, C<package> sets the C<$VERSION> variable in the given
4306 namespace to a L<version> object with the VERSION provided.  VERSION must be a
4307 "strict" style version number as defined by the L<version> module: a positive
4308 decimal number (integer or decimal-fraction) without exponentiation or else a
4309 dotted-decimal v-string with a leading 'v' character and at least three
4310 components.  You should set C<$VERSION> only once per package.
4311
4312 See L<perlmod/"Packages"> for more information about packages, modules,
4313 and classes.  See L<perlsub> for other scoping issues.
4314
4315 =item pipe READHANDLE,WRITEHANDLE
4316 X<pipe>
4317
4318 Opens a pair of connected pipes like the corresponding system call.
4319 Note that if you set up a loop of piped processes, deadlock can occur
4320 unless you are very careful.  In addition, note that Perl's pipes use
4321 IO buffering, so you may need to set C<$|> to flush your WRITEHANDLE
4322 after each command, depending on the application.
4323
4324 See L<IPC::Open2>, L<IPC::Open3>, and L<perlipc/"Bidirectional Communication">
4325 for examples of such things.
4326
4327 On systems that support a close-on-exec flag on files, that flag is set
4328 on all newly opened file descriptors whose C<fileno>s are I<higher> than 
4329 the current value of $^F (by default 2 for C<STDERR>).  See L<perlvar/$^F>.
4330
4331 =item pop ARRAY (or ARRAYREF)
4332 X<pop> X<stack>
4333
4334 =item pop
4335
4336 Pops and returns the last value of the array, shortening the array by
4337 one element.
4338
4339 Returns the undefined value if the array is empty, although this may also
4340 happen at other times.  If ARRAY is omitted, pops the C<@ARGV> array in the
4341 main program, but the C<@_> array in subroutines, just like C<shift>.
4342
4343 If given a reference to an array, the argument will be dereferenced
4344 automatically.
4345
4346 =item pos SCALAR
4347 X<pos> X<match, position>
4348
4349 =item pos
4350
4351 Returns the offset of where the last C<m//g> search left off for the
4352 variable in question (C<$_> is used when the variable is not
4353 specified). Note that 0 is a valid match offset. C<undef> indicates
4354 that the search position is reset (usually due to match failure, but
4355 can also be because no match has yet been run on the scalar).
4356
4357 C<pos> directly accesses the location used by the regexp engine to
4358 store the offset, so assigning to C<pos> will change that offset, and
4359 so will also influence the C<\G> zero-width assertion in regular
4360 expressions. Both of these effects take place for the next match, so
4361 you can't affect the position with C<pos> during the current match,
4362 such as in C<(?{pos() = 5})> or C<s//pos() = 5/e>.
4363
4364 Because a failed C<m//gc> match doesn't reset the offset, the return
4365 from C<pos> won't change either in this case.  See L<perlre> and
4366 L<perlop>.
4367
4368 =item print FILEHANDLE LIST
4369 X<print>
4370
4371 =item print LIST
4372
4373 =item print
4374
4375 Prints a string or a list of strings.  Returns true if successful.
4376 FILEHANDLE may be a scalar variable containing
4377 the name of or a reference to the filehandle, thus introducing
4378 one level of indirection.  (NOTE: If FILEHANDLE is a variable and
4379 the next token is a term, it may be misinterpreted as an operator
4380 unless you interpose a C<+> or put parentheses around the arguments.)
4381 If FILEHANDLE is omitted, prints to standard output by default, or
4382 to the last selected output channel; see L</select>.  If LIST is
4383 also omitted, prints C<$_> to the currently selected output handle.
4384 To set the default output handle to something other than STDOUT
4385 use the select operation.  The current value of C<$,> (if any) is
4386 printed between each LIST item.  The current value of C<$\> (if
4387 any) is printed after the entire LIST has been printed.  Because
4388 print takes a LIST, anything in the LIST is evaluated in list
4389 context, and any subroutine that you call will have one or more of
4390 its expressions evaluated in list context.  Also be careful not to
4391 follow the print keyword with a left parenthesis unless you want
4392 the corresponding right parenthesis to terminate the arguments to
4393 the print; put parentheses around all the arguments 
4394 (or interpose a C<+>, but that doesn't look as good).
4395
4396 Note that if you're storing FILEHANDLEs in an array, or if you're using
4397 any other expression more complex than a scalar variable to retrieve it,
4398 you will have to use a block returning the filehandle value instead:
4399
4400     print { $files[$i] } "stuff\n";
4401     print { $OK ? STDOUT : STDERR } "stuff\n";
4402
4403 Printing to a closed pipe or socket will generate a SIGPIPE signal.  See
4404 L<perlipc> for more on signal handling.
4405
4406 =item printf FILEHANDLE FORMAT, LIST
4407 X<printf>
4408
4409 =item printf FORMAT, LIST
4410
4411 Equivalent to C<print FILEHANDLE sprintf(FORMAT, LIST)>, except that C<$\>
4412 (the output record separator) is not appended.  The first argument
4413 of the list will be interpreted as the C<printf> format. See C<sprintf>
4414 for an explanation of the format argument.  If C<use locale> is in effect,
4415 and POSIX::setlocale() has been called, the character used for the decimal
4416 separator in formatted floating-point numbers is affected by the LC_NUMERIC
4417 locale.  See L<perllocale> and L<POSIX>.
4418
4419 Don't fall into the trap of using a C<printf> when a simple
4420 C<print> would do.  The C<print> is more efficient and less
4421 error prone.
4422
4423 =item prototype FUNCTION
4424 X<prototype>
4425
4426 Returns the prototype of a function as a string (or C<undef> if the
4427 function has no prototype).  FUNCTION is a reference to, or the name of,
4428 the function whose prototype you want to retrieve.
4429
4430 If FUNCTION is a string starting with C<CORE::>, the rest is taken as a
4431 name for a Perl builtin.  If the builtin is not I<overridable> (such as
4432 C<qw//>) or if its arguments cannot be adequately expressed by a prototype
4433 (such as C<system>), prototype() returns C<undef>, because the builtin
4434 does not really behave like a Perl function.  Otherwise, the string
4435 describing the equivalent prototype is returned.
4436
4437 =item push ARRAY (or ARRAYREF),LIST
4438 X<push> X<stack>
4439
4440 Treats ARRAY as a stack, and pushes the values of LIST
4441 onto the end of ARRAY.  The length of ARRAY increases by the length of
4442 LIST.  Has the same effect as
4443
4444     for $value (LIST) {
4445         $ARRAY[++$#ARRAY] = $value;
4446     }
4447
4448 but is more efficient.  Returns the number of elements in the array following
4449 the completed C<push>.
4450
4451 If given a reference to an array, the argument will be dereferenced
4452 automatically.
4453
4454 =item q/STRING/
4455
4456 =item qq/STRING/
4457
4458 =item qx/STRING/
4459
4460 =item qw/STRING/
4461
4462 Generalized quotes.  See L<perlop/"Quote-Like Operators">.
4463
4464 =item qr/STRING/
4465
4466 Regexp-like quote.  See L<perlop/"Regexp Quote-Like Operators">.
4467
4468 =item quotemeta EXPR
4469 X<quotemeta> X<metacharacter>
4470
4471 =item quotemeta
4472
4473 Returns the value of EXPR with all non-"word"
4474 characters backslashed.  (That is, all characters not matching
4475 C</[A-Za-z_0-9]/> will be preceded by a backslash in the
4476 returned string, regardless of any locale settings.)
4477 This is the internal function implementing
4478 the C<\Q> escape in double-quoted strings.
4479
4480 If EXPR is omitted, uses C<$_>.
4481
4482 quotemeta (and C<\Q> ... C<\E>) are useful when interpolating strings into
4483 regular expressions, because by default an interpolated variable will be
4484 considered a mini-regular expression. For example:
4485
4486     my $sentence = 'The quick brown fox jumped over the lazy dog';
4487     my $substring = 'quick.*?fox';
4488     $sentence =~ s{$substring}{big bad wolf};
4489
4490 Will cause C<$sentence> to become C<'The big bad wolf jumped over...'>.
4491
4492 On the other hand:
4493
4494     my $sentence = 'The quick brown fox jumped over the lazy dog';
4495     my $substring = 'quick.*?fox';
4496     $sentence =~ s{\Q$substring\E}{big bad wolf};
4497
4498 Or:
4499
4500     my $sentence = 'The quick brown fox jumped over the lazy dog';
4501     my $substring = 'quick.*?fox';
4502     my $quoted_substring = quotemeta($substring);
4503     $sentence =~ s{$quoted_substring}{big bad wolf};
4504
4505 Will both leave the sentence as is. Normally, when accepting string input from
4506 the user, quotemeta() or C<\Q> must be used.
4507
4508 =item rand EXPR
4509 X<rand> X<random>
4510
4511 =item rand
4512
4513 Returns a random fractional number greater than or equal to C<0> and less
4514 than the value of EXPR.  (EXPR should be positive.)  If EXPR is
4515 omitted, the value C<1> is used.  Currently EXPR with the value C<0> is
4516 also special-cased as C<1> (this was undocumented before Perl 5.8.0
4517 and is subject to change in future versions of Perl).  Automatically calls
4518 C<srand> unless C<srand> has already been called.  See also C<srand>.
4519
4520 Apply C<int()> to the value returned by C<rand()> if you want random
4521 integers instead of random fractional numbers.  For example,
4522
4523     int(rand(10))
4524
4525 returns a random integer between C<0> and C<9>, inclusive.
4526
4527 (Note: If your rand function consistently returns numbers that are too
4528 large or too small, then your version of Perl was probably compiled
4529 with the wrong number of RANDBITS.)
4530
4531 =item read FILEHANDLE,SCALAR,LENGTH,OFFSET
4532 X<read> X<file, read>
4533
4534 =item read FILEHANDLE,SCALAR,LENGTH
4535
4536 Attempts to read LENGTH I<characters> of data into variable SCALAR
4537 from the specified FILEHANDLE.  Returns the number of characters
4538 actually read, C<0> at end of file, or undef if there was an error (in
4539 the latter case C<$!> is also set).  SCALAR will be grown or shrunk 
4540 so that the last character actually read is the last character of the
4541 scalar after the read.
4542
4543 An OFFSET may be specified to place the read data at some place in the
4544 string other than the beginning.  A negative OFFSET specifies
4545 placement at that many characters counting backwards from the end of
4546 the string.  A positive OFFSET greater than the length of SCALAR
4547 results in the string being padded to the required size with C<"\0">
4548 bytes before the result of the read is appended.
4549
4550 The call is implemented in terms of either Perl's or your system's native
4551 fread(3) library function.  To get a true read(2) system call, see C<sysread>.
4552
4553 Note the I<characters>: depending on the status of the filehandle,
4554 either (8-bit) bytes or characters are read.  By default all
4555 filehandles operate on bytes, but for example if the filehandle has
4556 been opened with the C<:utf8> I/O layer (see L</open>, and the C<open>
4557 pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4558 characters, not bytes.  Similarly for the C<:encoding> pragma:
4559 in that case pretty much any characters can be read.
4560
4561 =item readdir DIRHANDLE
4562 X<readdir>
4563
4564 Returns the next directory entry for a directory opened by C<opendir>.
4565 If used in list context, returns all the rest of the entries in the
4566 directory.  If there are no more entries, returns the undefined value in
4567 scalar context and the empty list in list context.
4568
4569 If you're planning to filetest the return values out of a C<readdir>, you'd
4570 better prepend the directory in question.  Otherwise, because we didn't
4571 C<chdir> there, it would have been testing the wrong file.
4572
4573     opendir(my $dh, $some_dir) || die "can't opendir $some_dir: $!";
4574     @dots = grep { /^\./ && -f "$some_dir/$_" } readdir($dh);
4575     closedir $dh;
4576
4577 As of Perl 5.11.2 you can use a bare C<readdir> in a C<while> loop,
4578 which will set C<$_> on every iteration.
4579
4580     opendir(my $dh, $some_dir) || die;
4581     while(readdir $dh) {
4582         print "$some_dir/$_\n";
4583     }
4584     closedir $dh;
4585
4586 =item readline EXPR
4587
4588 =item readline
4589 X<readline> X<gets> X<fgets>
4590
4591 Reads from the filehandle whose typeglob is contained in EXPR (or from
4592 *ARGV if EXPR is not provided).  In scalar context, each call reads and
4593 returns the next line until end-of-file is reached, whereupon the
4594 subsequent call returns C<undef>.  In list context, reads until end-of-file
4595 is reached and returns a list of lines.  Note that the notion of "line"
4596 used here is whatever you may have defined with C<$/> or
4597 C<$INPUT_RECORD_SEPARATOR>).  See L<perlvar/"$/">.
4598
4599 When C<$/> is set to C<undef>, when C<readline> is in scalar
4600 context (i.e., file slurp mode), and when an empty file is read, it
4601 returns C<''> the first time, followed by C<undef> subsequently.
4602
4603 This is the internal function implementing the C<< <EXPR> >>
4604 operator, but you can use it directly.  The C<< <EXPR> >>
4605 operator is discussed in more detail in L<perlop/"I/O Operators">.
4606
4607     $line = <STDIN>;
4608     $line = readline(*STDIN);    # same thing
4609
4610 If C<readline> encounters an operating system error, C<$!> will be set
4611 with the corresponding error message.  It can be helpful to check
4612 C<$!> when you are reading from filehandles you don't trust, such as a
4613 tty or a socket.  The following example uses the operator form of
4614 C<readline> and dies if the result is not defined.
4615
4616     while ( ! eof($fh) ) {
4617         defined( $_ = <$fh> ) or die "readline failed: $!";
4618         ...
4619     }
4620
4621 Note that you have can't handle C<readline> errors that way with the
4622 C<ARGV> filehandle. In that case, you have to open each element of
4623 C<@ARGV> yourself since C<eof> handles C<ARGV> differently.
4624
4625     foreach my $arg (@ARGV) {
4626         open(my $fh, $arg) or warn "Can't open $arg: $!";
4627
4628         while ( ! eof($fh) ) {
4629             defined( $_ = <$fh> )
4630                 or die "readline failed for $arg: $!";
4631             ...
4632         }
4633     }
4634
4635 =item readlink EXPR
4636 X<readlink>
4637
4638 =item readlink
4639
4640 Returns the value of a symbolic link, if symbolic links are
4641 implemented.  If not, raises an exception.  If there is a system
4642 error, returns the undefined value and sets C<$!> (errno).  If EXPR is
4643 omitted, uses C<$_>.
4644
4645 =item readpipe EXPR
4646
4647 =item readpipe
4648 X<readpipe>
4649
4650 EXPR is executed as a system command.
4651 The collected standard output of the command is returned.
4652 In scalar context, it comes back as a single (potentially
4653 multi-line) string.  In list context, returns a list of lines
4654 (however you've defined lines with C<$/> or C<$INPUT_RECORD_SEPARATOR>).
4655 This is the internal function implementing the C<qx/EXPR/>
4656 operator, but you can use it directly.  The C<qx/EXPR/>
4657 operator is discussed in more detail in L<perlop/"I/O Operators">.
4658 If EXPR is omitted, uses C<$_>.
4659
4660 =item recv SOCKET,SCALAR,LENGTH,FLAGS
4661 X<recv>
4662
4663 Receives a message on a socket.  Attempts to receive LENGTH characters
4664 of data into variable SCALAR from the specified SOCKET filehandle.
4665 SCALAR will be grown or shrunk to the length actually read.  Takes the
4666 same flags as the system call of the same name.  Returns the address
4667 of the sender if SOCKET's protocol supports this; returns an empty
4668 string otherwise.  If there's an error, returns the undefined value.
4669 This call is actually implemented in terms of recvfrom(2) system call.
4670 See L<perlipc/"UDP: Message Passing"> for examples.
4671
4672 Note the I<characters>: depending on the status of the socket, either
4673 (8-bit) bytes or characters are received.  By default all sockets
4674 operate on bytes, but for example if the socket has been changed using
4675 binmode() to operate with the C<:encoding(utf8)> I/O layer (see the
4676 C<open> pragma, L<open>), the I/O will operate on UTF-8 encoded Unicode
4677 characters, not bytes.  Similarly for the C<:encoding> pragma: in that
4678 case pretty much any characters can be read.
4679
4680 =item redo LABEL
4681 X<redo>
4682
4683 =item redo
4684
4685 The C<redo> command restarts the loop block without evaluating the
4686 conditional again.  The C<continue> block, if any, is not executed.  If
4687 the LABEL is omitted, the command refers to the innermost enclosing
4688 loop.  Programs that want to lie to themselves about what was just input