Convert tied SPLICE to using Perl_tied_method()
[perl.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation
4
5 =head1 DESCRIPTION
6
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
9
10 =head1 Data: Numbers
11
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
13
14 For the long explanation, see David Goldberg's "What Every Computer
15 Scientist Should Know About Floating-Point Arithmetic"
16 (http://docs.sun.com/source/806-3568/ncg_goldberg.html).
17
18 Internally, your computer represents floating-point numbers in binary.
19 Digital (as in powers of two) computers cannot store all numbers
20 exactly.  Some real numbers lose precision in the process.  This is a
21 problem with how computers store numbers and affects all computer
22 languages, not just Perl.
23
24 L<perlnumber> shows the gory details of number representations and
25 conversions.
26
27 To limit the number of decimal places in your numbers, you can use the
28 C<printf> or C<sprintf> function.  See the L<"Floating Point
29 Arithmetic"|perlop> for more details.
30
31         printf "%.2f", 10/3;
32
33         my $number = sprintf "%.2f", 10/3;
34
35 =head2 Why is int() broken?
36
37 Your C<int()> is most probably working just fine.  It's the numbers that
38 aren't quite what you think.
39
40 First, see the answer to "Why am I getting long decimals
41 (eg, 19.9499999999999) instead of the numbers I should be getting
42 (eg, 19.95)?".
43
44 For example, this
45
46         print int(0.6/0.2-2), "\n";
47
48 will in most computers print 0, not 1, because even such simple
49 numbers as 0.6 and 0.2 cannot be presented exactly by floating-point
50 numbers.  What you think in the above as 'three' is really more like
51 2.9999999999999995559.
52
53 =head2 Why isn't my octal data interpreted correctly?
54
55 (contributed by brian d foy)
56
57 You're probably trying to convert a string to a number, which Perl only
58 converts as a decimal number. When Perl converts a string to a number, it
59 ignores leading spaces and zeroes, then assumes the rest of the digits
60 are in base 10:
61
62         my $string = '0644';
63
64         print $string + 0;  # prints 644
65
66         print $string + 44; # prints 688, certainly not octal!
67
68 This problem usually involves one of the Perl built-ins that has the
69 same name a Unix command that uses octal numbers as arguments on the
70 command line. In this example, C<chmod> on the command line knows that
71 its first argument is octal because that's what it does:
72
73         %prompt> chmod 644 file
74
75 If you want to use the same literal digits (644) in Perl, you have to tell
76 Perl to treat them as octal numbers either by prefixing the digits with
77 a C<0> or using C<oct>:
78
79         chmod(     0644, $file);   # right, has leading zero
80         chmod( oct(644), $file );  # also correct
81
82 The problem comes in when you take your numbers from something that Perl
83 thinks is a string, such as a command line argument in C<@ARGV>:
84
85         chmod( $ARGV[0],      $file);   # wrong, even if "0644"
86
87         chmod( oct($ARGV[0]), $file );  # correct, treat string as octal
88
89 You can always check the value you're using by printing it in octal
90 notation to ensure it matches what you think it should be. Print it
91 in octal  and decimal format:
92
93         printf "0%o %d", $number, $number;
94
95 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
96
97 Remember that C<int()> merely truncates toward 0.  For rounding to a
98 certain number of digits, C<sprintf()> or C<printf()> is usually the
99 easiest route.
100
101         printf("%.3f", 3.1415926535);   # prints 3.142
102
103 The C<POSIX> module (part of the standard Perl distribution)
104 implements C<ceil()>, C<floor()>, and a number of other mathematical
105 and trigonometric functions.
106
107         use POSIX;
108         $ceil   = ceil(3.5);   # 4
109         $floor  = floor(3.5);  # 3
110
111 In 5.000 to 5.003 perls, trigonometry was done in the C<Math::Complex>
112 module.  With 5.004, the C<Math::Trig> module (part of the standard Perl
113 distribution) implements the trigonometric functions. Internally it
114 uses the C<Math::Complex> module and some functions can break out from
115 the real axis into the complex plane, for example the inverse sine of
116 2.
117
118 Rounding in financial applications can have serious implications, and
119 the rounding method used should be specified precisely.  In these
120 cases, it probably pays not to trust whichever system rounding is
121 being used by Perl, but to instead implement the rounding function you
122 need yourself.
123
124 To see why, notice how you'll still have an issue on half-way-point
125 alternation:
126
127         for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
128
129         0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
130         0.8 0.8 0.9 0.9 1.0 1.0
131
132 Don't blame Perl.  It's the same as in C.  IEEE says we have to do
133 this. Perl numbers whose absolute values are integers under 2**31 (on
134 32 bit machines) will work pretty much like mathematical integers.
135 Other numbers are not guaranteed.
136
137 =head2 How do I convert between numeric representations/bases/radixes?
138
139 As always with Perl there is more than one way to do it.  Below are a
140 few examples of approaches to making common conversions between number
141 representations.  This is intended to be representational rather than
142 exhaustive.
143
144 Some of the examples later in L<perlfaq4> use the C<Bit::Vector>
145 module from CPAN. The reason you might choose C<Bit::Vector> over the
146 perl built in functions is that it works with numbers of ANY size,
147 that it is optimized for speed on some operations, and for at least
148 some programmers the notation might be familiar.
149
150 =over 4
151
152 =item How do I convert hexadecimal into decimal
153
154 Using perl's built in conversion of C<0x> notation:
155
156         $dec = 0xDEADBEEF;
157
158 Using the C<hex> function:
159
160         $dec = hex("DEADBEEF");
161
162 Using C<pack>:
163
164         $dec = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
165
166 Using the CPAN module C<Bit::Vector>:
167
168         use Bit::Vector;
169         $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
170         $dec = $vec->to_Dec();
171
172 =item How do I convert from decimal to hexadecimal
173
174 Using C<sprintf>:
175
176         $hex = sprintf("%X", 3735928559); # upper case A-F
177         $hex = sprintf("%x", 3735928559); # lower case a-f
178
179 Using C<unpack>:
180
181         $hex = unpack("H*", pack("N", 3735928559));
182
183 Using C<Bit::Vector>:
184
185         use Bit::Vector;
186         $vec = Bit::Vector->new_Dec(32, -559038737);
187         $hex = $vec->to_Hex();
188
189 And C<Bit::Vector> supports odd bit counts:
190
191         use Bit::Vector;
192         $vec = Bit::Vector->new_Dec(33, 3735928559);
193         $vec->Resize(32); # suppress leading 0 if unwanted
194         $hex = $vec->to_Hex();
195
196 =item How do I convert from octal to decimal
197
198 Using Perl's built in conversion of numbers with leading zeros:
199
200         $dec = 033653337357; # note the leading 0!
201
202 Using the C<oct> function:
203
204         $dec = oct("33653337357");
205
206 Using C<Bit::Vector>:
207
208         use Bit::Vector;
209         $vec = Bit::Vector->new(32);
210         $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
211         $dec = $vec->to_Dec();
212
213 =item How do I convert from decimal to octal
214
215 Using C<sprintf>:
216
217         $oct = sprintf("%o", 3735928559);
218
219 Using C<Bit::Vector>:
220
221         use Bit::Vector;
222         $vec = Bit::Vector->new_Dec(32, -559038737);
223         $oct = reverse join('', $vec->Chunk_List_Read(3));
224
225 =item How do I convert from binary to decimal
226
227 Perl 5.6 lets you write binary numbers directly with
228 the C<0b> notation:
229
230         $number = 0b10110110;
231
232 Using C<oct>:
233
234         my $input = "10110110";
235         $decimal = oct( "0b$input" );
236
237 Using C<pack> and C<ord>:
238
239         $decimal = ord(pack('B8', '10110110'));
240
241 Using C<pack> and C<unpack> for larger strings:
242
243         $int = unpack("N", pack("B32",
244         substr("0" x 32 . "11110101011011011111011101111", -32)));
245         $dec = sprintf("%d", $int);
246
247         # substr() is used to left pad a 32 character string with zeros.
248
249 Using C<Bit::Vector>:
250
251         $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
252         $dec = $vec->to_Dec();
253
254 =item How do I convert from decimal to binary
255
256 Using C<sprintf> (perl 5.6+):
257
258         $bin = sprintf("%b", 3735928559);
259
260 Using C<unpack>:
261
262         $bin = unpack("B*", pack("N", 3735928559));
263
264 Using C<Bit::Vector>:
265
266         use Bit::Vector;
267         $vec = Bit::Vector->new_Dec(32, -559038737);
268         $bin = $vec->to_Bin();
269
270 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
271 are left as an exercise to the inclined reader.
272
273 =back
274
275 =head2 Why doesn't & work the way I want it to?
276
277 The behavior of binary arithmetic operators depends on whether they're
278 used on numbers or strings.  The operators treat a string as a series
279 of bits and work with that (the string C<"3"> is the bit pattern
280 C<00110011>).  The operators work with the binary form of a number
281 (the number C<3> is treated as the bit pattern C<00000011>).
282
283 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
284 C<3>).  Saying C<"11" & "3"> performs the "and" operation on strings
285 (yielding C<"1">).
286
287 Most problems with C<&> and C<|> arise because the programmer thinks
288 they have a number but really it's a string.  The rest arise because
289 the programmer says:
290
291         if ("\020\020" & "\101\101") {
292                 # ...
293                 }
294
295 but a string consisting of two null bytes (the result of C<"\020\020"
296 & "\101\101">) is not a false value in Perl.  You need:
297
298         if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
299                 # ...
300                 }
301
302 =head2 How do I multiply matrices?
303
304 Use the C<Math::Matrix> or C<Math::MatrixReal> modules (available from CPAN)
305 or the C<PDL> extension (also available from CPAN).
306
307 =head2 How do I perform an operation on a series of integers?
308
309 To call a function on each element in an array, and collect the
310 results, use:
311
312         @results = map { my_func($_) } @array;
313
314 For example:
315
316         @triple = map { 3 * $_ } @single;
317
318 To call a function on each element of an array, but ignore the
319 results:
320
321         foreach $iterator (@array) {
322                 some_func($iterator);
323                 }
324
325 To call a function on each integer in a (small) range, you B<can> use:
326
327         @results = map { some_func($_) } (5 .. 25);
328
329 but you should be aware that the C<..> operator creates an array of
330 all integers in the range.  This can take a lot of memory for large
331 ranges.  Instead use:
332
333         @results = ();
334         for ($i=5; $i <= 500_005; $i++) {
335                 push(@results, some_func($i));
336                 }
337
338 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
339 loop will iterate over the range, without creating the entire range.
340
341         for my $i (5 .. 500_005) {
342                 push(@results, some_func($i));
343                 }
344
345 will not create a list of 500,000 integers.
346
347 =head2 How can I output Roman numerals?
348
349 Get the L<http://www.cpan.org/modules/by-module/Roman> module.
350
351 =head2 Why aren't my random numbers random?
352
353 If you're using a version of Perl before 5.004, you must call C<srand>
354 once at the start of your program to seed the random number generator.
355
356          BEGIN { srand() if $] < 5.004 }
357
358 5.004 and later automatically call C<srand> at the beginning.  Don't
359 call C<srand> more than once--you make your numbers less random,
360 rather than more.
361
362 Computers are good at being predictable and bad at being random
363 (despite appearances caused by bugs in your programs :-).  see the
364 F<random> article in the "Far More Than You Ever Wanted To Know"
365 collection in L<http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz>, courtesy
366 of Tom Phoenix, talks more about this.  John von Neumann said, "Anyone
367 who attempts to generate random numbers by deterministic means is, of
368 course, living in a state of sin."
369
370 If you want numbers that are more random than C<rand> with C<srand>
371 provides, you should also check out the C<Math::TrulyRandom> module from
372 CPAN.  It uses the imperfections in your system's timer to generate
373 random numbers, but this takes quite a while.  If you want a better
374 pseudorandom generator than comes with your operating system, look at
375 "Numerical Recipes in C" at L<http://www.nr.com/>.
376
377 =head2 How do I get a random number between X and Y?
378
379 To get a random number between two values, you can use the C<rand()>
380 built-in to get a random number between 0 and 1. From there, you shift
381 that into the range that you want.
382
383 C<rand($x)> returns a number such that C<< 0 <= rand($x) < $x >>. Thus
384 what you want to have perl figure out is a random number in the range
385 from 0 to the difference between your I<X> and I<Y>.
386
387 That is, to get a number between 10 and 15, inclusive, you want a
388 random number between 0 and 5 that you can then add to 10.
389
390         my $number = 10 + int rand( 15-10+1 ); # ( 10,11,12,13,14, or 15 )
391
392 Hence you derive the following simple function to abstract
393 that. It selects a random integer between the two given
394 integers (inclusive), For example: C<random_int_between(50,120)>.
395
396         sub random_int_between {
397                 my($min, $max) = @_;
398                 # Assumes that the two arguments are integers themselves!
399                 return $min if $min == $max;
400                 ($min, $max) = ($max, $min)  if  $min > $max;
401                 return $min + int rand(1 + $max - $min);
402                 }
403
404 =head1 Data: Dates
405
406 =head2 How do I find the day or week of the year?
407
408 The C<localtime> function returns the day of the year.  Without an
409 argument C<localtime> uses the current time.
410
411         $day_of_year = (localtime)[7];
412
413 The C<POSIX> module can also format a date as the day of the year or
414 week of the year.
415
416         use POSIX qw/strftime/;
417         my $day_of_year  = strftime "%j", localtime;
418         my $week_of_year = strftime "%W", localtime;
419
420 To get the day of year for any date, use C<POSIX>'s C<mktime> to get
421 a time in epoch seconds for the argument to C<localtime>.
422
423         use POSIX qw/mktime strftime/;
424         my $week_of_year = strftime "%W",
425                 localtime( mktime( 0, 0, 0, 18, 11, 87 ) );
426
427 The C<Date::Calc> module provides two functions to calculate these.
428
429         use Date::Calc;
430         my $day_of_year  = Day_of_Year(  1987, 12, 18 );
431         my $week_of_year = Week_of_Year( 1987, 12, 18 );
432
433 =head2 How do I find the current century or millennium?
434
435 Use the following simple functions:
436
437         sub get_century    {
438                 return int((((localtime(shift || time))[5] + 1999))/100);
439                 }
440
441         sub get_millennium {
442                 return 1+int((((localtime(shift || time))[5] + 1899))/1000);
443                 }
444
445 On some systems, the C<POSIX> module's C<strftime()> function has been
446 extended in a non-standard way to use a C<%C> format, which they
447 sometimes claim is the "century". It isn't, because on most such
448 systems, this is only the first two digits of the four-digit year, and
449 thus cannot be used to reliably determine the current century or
450 millennium.
451
452 =head2 How can I compare two dates and find the difference?
453
454 (contributed by brian d foy)
455
456 You could just store all your dates as a number and then subtract.
457 Life isn't always that simple though. If you want to work with
458 formatted dates, the C<Date::Manip>, C<Date::Calc>, or C<DateTime>
459 modules can help you.
460
461 =head2 How can I take a string and turn it into epoch seconds?
462
463 If it's a regular enough string that it always has the same format,
464 you can split it up and pass the parts to C<timelocal> in the standard
465 C<Time::Local> module.  Otherwise, you should look into the C<Date::Calc>
466 and C<Date::Manip> modules from CPAN.
467
468 =head2 How can I find the Julian Day?
469
470 (contributed by brian d foy and Dave Cross)
471
472 You can use the C<Time::JulianDay> module available on CPAN.  Ensure
473 that you really want to find a Julian day, though, as many people have
474 different ideas about Julian days.  See
475 http://www.hermetic.ch/cal_stud/jdn.htm for instance.
476
477 You can also try the C<DateTime> module, which can convert a date/time
478 to a Julian Day.
479
480         $ perl -MDateTime -le'print DateTime->today->jd'
481         2453401.5
482
483 Or the modified Julian Day
484
485         $ perl -MDateTime -le'print DateTime->today->mjd'
486         53401
487
488 Or even the day of the year (which is what some people think of as a
489 Julian day)
490
491         $ perl -MDateTime -le'print DateTime->today->doy'
492         31
493
494 =head2 How do I find yesterday's date?
495 X<date> X<yesterday> X<DateTime> X<Date::Calc> X<Time::Local>
496 X<daylight saving time> X<day> X<Today_and_Now> X<localtime>
497 X<timelocal>
498
499 (contributed by brian d foy)
500
501 Use one of the Date modules. The C<DateTime> module makes it simple, and
502 give you the same time of day, only the day before.
503
504         use DateTime;
505
506         my $yesterday = DateTime->now->subtract( days => 1 );
507
508         print "Yesterday was $yesterday\n";
509
510 You can also use the C<Date::Calc> module using its C<Today_and_Now>
511 function.
512
513         use Date::Calc qw( Today_and_Now Add_Delta_DHMS );
514
515         my @date_time = Add_Delta_DHMS( Today_and_Now(), -1, 0, 0, 0 );
516
517         print "@date_time\n";
518
519 Most people try to use the time rather than the calendar to figure out
520 dates, but that assumes that days are twenty-four hours each.  For
521 most people, there are two days a year when they aren't: the switch to
522 and from summer time throws this off. Let the modules do the work.
523
524 If you absolutely must do it yourself (or can't use one of the
525 modules), here's a solution using C<Time::Local>, which comes with
526 Perl:
527
528         # contributed by Gunnar Hjalmarsson
529          use Time::Local;
530          my $today = timelocal 0, 0, 12, ( localtime )[3..5];
531          my ($d, $m, $y) = ( localtime $today-86400 )[3..5];
532          printf "Yesterday: %d-%02d-%02d\n", $y+1900, $m+1, $d;
533
534 In this case, you measure the day starting at noon, and subtract 24
535 hours. Even if the length of the calendar day is 23 or 25 hours,
536 you'll still end up on the previous calendar day, although not at
537 noon. Since you don't care about the time, the one hour difference
538 doesn't matter and you end up with the previous date.
539
540 =head2 Does Perl have a Year 2000 or 2038 problem? Is Perl Y2K compliant?
541
542 (contributed by brian d foy)
543
544 Perl itself never had a Y2K problem, although that never stopped people
545 from creating Y2K problems on their own. See the documentation for
546 C<localtime> for its proper use.
547
548 Starting with Perl 5.11, C<localtime> and C<gmtime> can handle dates past
549 03:14:08 January 19, 2038, when a 32-bit based time would overflow. You
550 still might get a warning on a 32-bit C<perl>:
551
552         % perl5.11.2 -E 'say scalar localtime( 0x9FFF_FFFFFFFF )'
553         Integer overflow in hexadecimal number at -e line 1.
554         Wed Nov  1 19:42:39 5576711
555
556 On a 64-bit C<perl>, you can get even larger dates for those really long
557 running projects:
558
559         % perl5.11.2 -E 'say scalar gmtime( 0x9FFF_FFFFFFFF )'
560         Thu Nov  2 00:42:39 5576711
561
562 You're still out of luck if you need to keep track of decaying protons
563 though.
564
565 =head1 Data: Strings
566
567 =head2 How do I validate input?
568
569 (contributed by brian d foy)
570
571 There are many ways to ensure that values are what you expect or
572 want to accept. Besides the specific examples that we cover in the
573 perlfaq, you can also look at the modules with "Assert" and "Validate"
574 in their names, along with other modules such as C<Regexp::Common>.
575
576 Some modules have validation for particular types of input, such
577 as C<Business::ISBN>, C<Business::CreditCard>, C<Email::Valid>,
578 and C<Data::Validate::IP>.
579
580 =head2 How do I unescape a string?
581
582 It depends just what you mean by "escape".  URL escapes are dealt
583 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
584 character are removed with
585
586         s/\\(.)/$1/g;
587
588 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
589
590 =head2 How do I remove consecutive pairs of characters?
591
592 (contributed by brian d foy)
593
594 You can use the substitution operator to find pairs of characters (or
595 runs of characters) and replace them with a single instance. In this
596 substitution, we find a character in C<(.)>. The memory parentheses
597 store the matched character in the back-reference C<\g1> and we use
598 that to require that the same thing immediately follow it. We replace
599 that part of the string with the character in C<$1>.
600
601         s/(.)\g1/$1/g;
602
603 We can also use the transliteration operator, C<tr///>. In this
604 example, the search list side of our C<tr///> contains nothing, but
605 the C<c> option complements that so it contains everything. The
606 replacement list also contains nothing, so the transliteration is
607 almost a no-op since it won't do any replacements (or more exactly,
608 replace the character with itself). However, the C<s> option squashes
609 duplicated and consecutive characters in the string so a character
610 does not show up next to itself
611
612         my $str = 'Haarlem';   # in the Netherlands
613         $str =~ tr///cs;       # Now Harlem, like in New York
614
615 =head2 How do I expand function calls in a string?
616
617 (contributed by brian d foy)
618
619 This is documented in L<perlref>, and although it's not the easiest
620 thing to read, it does work. In each of these examples, we call the
621 function inside the braces used to dereference a reference. If we
622 have more than one return value, we can construct and dereference an
623 anonymous array. In this case, we call the function in list context.
624
625         print "The time values are @{ [localtime] }.\n";
626
627 If we want to call the function in scalar context, we have to do a bit
628 more work. We can really have any code we like inside the braces, so
629 we simply have to end with the scalar reference, although how you do
630 that is up to you, and you can use code inside the braces. Note that
631 the use of parens creates a list context, so we need C<scalar> to
632 force the scalar context on the function:
633
634         print "The time is ${\(scalar localtime)}.\n"
635
636         print "The time is ${ my $x = localtime; \$x }.\n";
637
638 If your function already returns a reference, you don't need to create
639 the reference yourself.
640
641         sub timestamp { my $t = localtime; \$t }
642
643         print "The time is ${ timestamp() }.\n";
644
645 The C<Interpolation> module can also do a lot of magic for you. You can
646 specify a variable name, in this case C<E>, to set up a tied hash that
647 does the interpolation for you. It has several other methods to do this
648 as well.
649
650         use Interpolation E => 'eval';
651         print "The time values are $E{localtime()}.\n";
652
653 In most cases, it is probably easier to simply use string concatenation,
654 which also forces scalar context.
655
656         print "The time is " . localtime() . ".\n";
657
658 =head2 How do I find matching/nesting anything?
659
660 This isn't something that can be done in one regular expression, no
661 matter how complicated.  To find something between two single
662 characters, a pattern like C</x([^x]*)x/> will get the intervening
663 bits in $1. For multiple ones, then something more like
664 C</alpha(.*?)omega/> would be needed. But none of these deals with
665 nested patterns.  For balanced expressions using C<(>, C<{>, C<[> or
666 C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
667 L<perlre/(??{ code })>.  For other cases, you'll have to write a
668 parser.
669
670 If you are serious about writing a parser, there are a number of
671 modules or oddities that will make your life a lot easier.  There are
672 the CPAN modules C<Parse::RecDescent>, C<Parse::Yapp>, and
673 C<Text::Balanced>; and the C<byacc> program. Starting from perl 5.8
674 the C<Text::Balanced> is part of the standard distribution.
675
676 One simple destructive, inside-out approach that you might try is to
677 pull out the smallest nesting parts one at a time:
678
679         while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
680                 # do something with $1
681                 }
682
683 A more complicated and sneaky approach is to make Perl's regular
684 expression engine do it for you.  This is courtesy Dean Inada, and
685 rather has the nature of an Obfuscated Perl Contest entry, but it
686 really does work:
687
688         # $_ contains the string to parse
689         # BEGIN and END are the opening and closing markers for the
690         # nested text.
691
692         @( = ('(','');
693         @) = (')','');
694         ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
695         @$ = (eval{/$re/},$@!~/unmatched/i);
696         print join("\n",@$[0..$#$]) if( $$[-1] );
697
698 =head2 How do I reverse a string?
699
700 Use C<reverse()> in scalar context, as documented in
701 L<perlfunc/reverse>.
702
703         $reversed = reverse $string;
704
705 =head2 How do I expand tabs in a string?
706
707 You can do it yourself:
708
709         1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
710
711 Or you can just use the C<Text::Tabs> module (part of the standard Perl
712 distribution).
713
714         use Text::Tabs;
715         @expanded_lines = expand(@lines_with_tabs);
716
717 =head2 How do I reformat a paragraph?
718
719 Use C<Text::Wrap> (part of the standard Perl distribution):
720
721         use Text::Wrap;
722         print wrap("\t", '  ', @paragraphs);
723
724 The paragraphs you give to C<Text::Wrap> should not contain embedded
725 newlines.  C<Text::Wrap> doesn't justify the lines (flush-right).
726
727 Or use the CPAN module C<Text::Autoformat>.  Formatting files can be
728 easily done by making a shell alias, like so:
729
730         alias fmt="perl -i -MText::Autoformat -n0777 \
731                 -e 'print autoformat $_, {all=>1}' $*"
732
733 See the documentation for C<Text::Autoformat> to appreciate its many
734 capabilities.
735
736 =head2 How can I access or change N characters of a string?
737
738 You can access the first characters of a string with substr().
739 To get the first character, for example, start at position 0
740 and grab the string of length 1.
741
742
743         $string = "Just another Perl Hacker";
744         $first_char = substr( $string, 0, 1 );  #  'J'
745
746 To change part of a string, you can use the optional fourth
747 argument which is the replacement string.
748
749         substr( $string, 13, 4, "Perl 5.8.0" );
750
751 You can also use substr() as an lvalue.
752
753         substr( $string, 13, 4 ) =  "Perl 5.8.0";
754
755 =head2 How do I change the Nth occurrence of something?
756
757 You have to keep track of N yourself.  For example, let's say you want
758 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
759 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
760 all assume that $_ contains the string to be altered.
761
762         $count = 0;
763         s{((whom?)ever)}{
764         ++$count == 5       # is it the 5th?
765             ? "${2}soever"  # yes, swap
766             : $1            # renege and leave it there
767                 }ige;
768
769 In the more general case, you can use the C</g> modifier in a C<while>
770 loop, keeping count of matches.
771
772         $WANT = 3;
773         $count = 0;
774         $_ = "One fish two fish red fish blue fish";
775         while (/(\w+)\s+fish\b/gi) {
776                 if (++$count == $WANT) {
777                         print "The third fish is a $1 one.\n";
778                         }
779                 }
780
781 That prints out: C<"The third fish is a red one.">  You can also use a
782 repetition count and repeated pattern like this:
783
784         /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
785
786 =head2 How can I count the number of occurrences of a substring within a string?
787
788 There are a number of ways, with varying efficiency.  If you want a
789 count of a certain single character (X) within a string, you can use the
790 C<tr///> function like so:
791
792         $string = "ThisXlineXhasXsomeXx'sXinXit";
793         $count = ($string =~ tr/X//);
794         print "There are $count X characters in the string";
795
796 This is fine if you are just looking for a single character.  However,
797 if you are trying to count multiple character substrings within a
798 larger string, C<tr///> won't work.  What you can do is wrap a while()
799 loop around a global pattern match.  For example, let's count negative
800 integers:
801
802         $string = "-9 55 48 -2 23 -76 4 14 -44";
803         while ($string =~ /-\d+/g) { $count++ }
804         print "There are $count negative numbers in the string";
805
806 Another version uses a global match in list context, then assigns the
807 result to a scalar, producing a count of the number of matches.
808
809         $count = () = $string =~ /-\d+/g;
810
811 =head2 How do I capitalize all the words on one line?
812 X<Text::Autoformat> X<capitalize> X<case, title> X<case, sentence>
813
814 (contributed by brian d foy)
815
816 Damian Conway's L<Text::Autoformat> handles all of the thinking
817 for you.
818
819         use Text::Autoformat;
820         my $x = "Dr. Strangelove or: How I Learned to Stop ".
821           "Worrying and Love the Bomb";
822
823         print $x, "\n";
824         for my $style (qw( sentence title highlight )) {
825                 print autoformat($x, { case => $style }), "\n";
826                 }
827
828 How do you want to capitalize those words?
829
830         FRED AND BARNEY'S LODGE        # all uppercase
831         Fred And Barney's Lodge        # title case
832         Fred and Barney's Lodge        # highlight case
833
834 It's not as easy a problem as it looks. How many words do you think
835 are in there? Wait for it... wait for it.... If you answered 5
836 you're right. Perl words are groups of C<\w+>, but that's not what
837 you want to capitalize. How is Perl supposed to know not to capitalize
838 that C<s> after the apostrophe? You could try a regular expression:
839
840         $string =~ s/ (
841                                  (^\w)    #at the beginning of the line
842                                    |      # or
843                                  (\s\w)   #preceded by whitespace
844                                    )
845                                 /\U$1/xg;
846
847         $string =~ s/([\w']+)/\u\L$1/g;
848
849 Now, what if you don't want to capitalize that "and"? Just use
850 L<Text::Autoformat> and get on with the next problem. :)
851
852 =head2 How can I split a [character] delimited string except when inside [character]?
853
854 Several modules can handle this sort of parsing--C<Text::Balanced>,
855 C<Text::CSV>, C<Text::CSV_XS>, and C<Text::ParseWords>, among others.
856
857 Take the example case of trying to split a string that is
858 comma-separated into its different fields. You can't use C<split(/,/)>
859 because you shouldn't split if the comma is inside quotes.  For
860 example, take a data line like this:
861
862         SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
863
864 Due to the restriction of the quotes, this is a fairly complex
865 problem.  Thankfully, we have Jeffrey Friedl, author of
866 I<Mastering Regular Expressions>, to handle these for us.  He
867 suggests (assuming your string is contained in C<$text>):
868
869          @new = ();
870          push(@new, $+) while $text =~ m{
871                  "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
872                 | ([^,]+),?
873                 | ,
874                 }gx;
875          push(@new, undef) if substr($text,-1,1) eq ',';
876
877 If you want to represent quotation marks inside a
878 quotation-mark-delimited field, escape them with backslashes (eg,
879 C<"like \"this\"">.
880
881 Alternatively, the C<Text::ParseWords> module (part of the standard
882 Perl distribution) lets you say:
883
884         use Text::ParseWords;
885         @new = quotewords(",", 0, $text);
886
887 =head2 How do I strip blank space from the beginning/end of a string?
888
889 (contributed by brian d foy)
890
891 A substitution can do this for you. For a single line, you want to
892 replace all the leading or trailing whitespace with nothing. You
893 can do that with a pair of substitutions:
894
895         s/^\s+//;
896         s/\s+$//;
897
898 You can also write that as a single substitution, although it turns
899 out the combined statement is slower than the separate ones. That
900 might not matter to you, though:
901
902         s/^\s+|\s+$//g;
903
904 In this regular expression, the alternation matches either at the
905 beginning or the end of the string since the anchors have a lower
906 precedence than the alternation. With the C</g> flag, the substitution
907 makes all possible matches, so it gets both. Remember, the trailing
908 newline matches the C<\s+>, and  the C<$> anchor can match to the
909 absolute end of the string, so the newline disappears too. Just add
910 the newline to the output, which has the added benefit of preserving
911 "blank" (consisting entirely of whitespace) lines which the C<^\s+>
912 would remove all by itself:
913
914         while( <> ) {
915                 s/^\s+|\s+$//g;
916                 print "$_\n";
917                 }
918
919 For a multi-line string, you can apply the regular expression to each
920 logical line in the string by adding the C</m> flag (for
921 "multi-line"). With the C</m> flag, the C<$> matches I<before> an
922 embedded newline, so it doesn't remove it. This pattern still removes
923 the newline at the end of the string:
924
925         $string =~ s/^\s+|\s+$//gm;
926
927 Remember that lines consisting entirely of whitespace will disappear,
928 since the first part of the alternation can match the entire string
929 and replace it with nothing. If you need to keep embedded blank lines,
930 you have to do a little more work. Instead of matching any whitespace
931 (since that includes a newline), just match the other whitespace:
932
933         $string =~ s/^[\t\f ]+|[\t\f ]+$//mg;
934
935 =head2 How do I pad a string with blanks or pad a number with zeroes?
936
937 In the following examples, C<$pad_len> is the length to which you wish
938 to pad the string, C<$text> or C<$num> contains the string to be padded,
939 and C<$pad_char> contains the padding character. You can use a single
940 character string constant instead of the C<$pad_char> variable if you
941 know what it is in advance. And in the same way you can use an integer in
942 place of C<$pad_len> if you know the pad length in advance.
943
944 The simplest method uses the C<sprintf> function. It can pad on the left
945 or right with blanks and on the left with zeroes and it will not
946 truncate the result. The C<pack> function can only pad strings on the
947 right with blanks and it will truncate the result to a maximum length of
948 C<$pad_len>.
949
950         # Left padding a string with blanks (no truncation):
951         $padded = sprintf("%${pad_len}s", $text);
952         $padded = sprintf("%*s", $pad_len, $text);  # same thing
953
954         # Right padding a string with blanks (no truncation):
955         $padded = sprintf("%-${pad_len}s", $text);
956         $padded = sprintf("%-*s", $pad_len, $text); # same thing
957
958         # Left padding a number with 0 (no truncation):
959         $padded = sprintf("%0${pad_len}d", $num);
960         $padded = sprintf("%0*d", $pad_len, $num); # same thing
961
962         # Right padding a string with blanks using pack (will truncate):
963         $padded = pack("A$pad_len",$text);
964
965 If you need to pad with a character other than blank or zero you can use
966 one of the following methods.  They all generate a pad string with the
967 C<x> operator and combine that with C<$text>. These methods do
968 not truncate C<$text>.
969
970 Left and right padding with any character, creating a new string:
971
972         $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
973         $padded = $text . $pad_char x ( $pad_len - length( $text ) );
974
975 Left and right padding with any character, modifying C<$text> directly:
976
977         substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
978         $text .= $pad_char x ( $pad_len - length( $text ) );
979
980 =head2 How do I extract selected columns from a string?
981
982 (contributed by brian d foy)
983
984 If you know the columns that contain the data, you can
985 use C<substr> to extract a single column.
986
987         my $column = substr( $line, $start_column, $length );
988
989 You can use C<split> if the columns are separated by whitespace or
990 some other delimiter, as long as whitespace or the delimiter cannot
991 appear as part of the data.
992
993         my $line    = ' fred barney   betty   ';
994         my @columns = split /\s+/, $line;
995                 # ( '', 'fred', 'barney', 'betty' );
996
997         my $line    = 'fred||barney||betty';
998         my @columns = split /\|/, $line;
999                 # ( 'fred', '', 'barney', '', 'betty' );
1000
1001 If you want to work with comma-separated values, don't do this since
1002 that format is a bit more complicated. Use one of the modules that
1003 handle that format, such as C<Text::CSV>, C<Text::CSV_XS>, or
1004 C<Text::CSV_PP>.
1005
1006 If you want to break apart an entire line of fixed columns, you can use
1007 C<unpack> with the A (ASCII) format. By using a number after the format
1008 specifier, you can denote the column width. See the C<pack> and C<unpack>
1009 entries in L<perlfunc> for more details.
1010
1011         my @fields = unpack( $line, "A8 A8 A8 A16 A4" );
1012
1013 Note that spaces in the format argument to C<unpack> do not denote literal
1014 spaces. If you have space separated data, you may want C<split> instead.
1015
1016 =head2 How do I find the soundex value of a string?
1017
1018 (contributed by brian d foy)
1019
1020 You can use the Text::Soundex module. If you want to do fuzzy or close
1021 matching, you might also try the C<String::Approx>, and
1022 C<Text::Metaphone>, and C<Text::DoubleMetaphone> modules.
1023
1024 =head2 How can I expand variables in text strings?
1025
1026 (contributed by brian d foy)
1027
1028 If you can avoid it, don't, or if you can use a templating system,
1029 such as C<Text::Template> or C<Template> Toolkit, do that instead. You
1030 might even be able to get the job done with C<sprintf> or C<printf>:
1031
1032         my $string = sprintf 'Say hello to %s and %s', $foo, $bar;
1033
1034 However, for the one-off simple case where I don't want to pull out a
1035 full templating system, I'll use a string that has two Perl scalar
1036 variables in it. In this example, I want to expand C<$foo> and C<$bar>
1037 to their variable's values:
1038
1039         my $foo = 'Fred';
1040         my $bar = 'Barney';
1041         $string = 'Say hello to $foo and $bar';
1042
1043 One way I can do this involves the substitution operator and a double
1044 C</e> flag.  The first C</e> evaluates C<$1> on the replacement side and
1045 turns it into C<$foo>. The second /e starts with C<$foo> and replaces
1046 it with its value. C<$foo>, then, turns into 'Fred', and that's finally
1047 what's left in the string:
1048
1049         $string =~ s/(\$\w+)/$1/eeg; # 'Say hello to Fred and Barney'
1050
1051 The C</e> will also silently ignore violations of strict, replacing
1052 undefined variable names with the empty string. Since I'm using the
1053 C</e> flag (twice even!), I have all of the same security problems I
1054 have with C<eval> in its string form. If there's something odd in
1055 C<$foo>, perhaps something like C<@{[ system "rm -rf /" ]}>, then
1056 I could get myself in trouble.
1057
1058 To get around the security problem, I could also pull the values from
1059 a hash instead of evaluating variable names. Using a single C</e>, I
1060 can check the hash to ensure the value exists, and if it doesn't, I
1061 can replace the missing value with a marker, in this case C<???> to
1062 signal that I missed something:
1063
1064         my $string = 'This has $foo and $bar';
1065
1066         my %Replacements = (
1067                 foo  => 'Fred',
1068                 );
1069
1070         # $string =~ s/\$(\w+)/$Replacements{$1}/g;
1071         $string =~ s/\$(\w+)/
1072                 exists $Replacements{$1} ? $Replacements{$1} : '???'
1073                 /eg;
1074
1075         print $string;
1076
1077 =head2 What's wrong with always quoting "$vars"?
1078
1079 The problem is that those double-quotes force
1080 stringification--coercing numbers and references into strings--even
1081 when you don't want them to be strings.  Think of it this way:
1082 double-quote expansion is used to produce new strings.  If you already
1083 have a string, why do you need more?
1084
1085 If you get used to writing odd things like these:
1086
1087         print "$var";           # BAD
1088         $new = "$old";          # BAD
1089         somefunc("$var");       # BAD
1090
1091 You'll be in trouble.  Those should (in 99.8% of the cases) be
1092 the simpler and more direct:
1093
1094         print $var;
1095         $new = $old;
1096         somefunc($var);
1097
1098 Otherwise, besides slowing you down, you're going to break code when
1099 the thing in the scalar is actually neither a string nor a number, but
1100 a reference:
1101
1102         func(\@array);
1103         sub func {
1104                 my $aref = shift;
1105                 my $oref = "$aref";  # WRONG
1106                 }
1107
1108 You can also get into subtle problems on those few operations in Perl
1109 that actually do care about the difference between a string and a
1110 number, such as the magical C<++> autoincrement operator or the
1111 syscall() function.
1112
1113 Stringification also destroys arrays.
1114
1115         @lines = `command`;
1116         print "@lines";     # WRONG - extra blanks
1117         print @lines;       # right
1118
1119 =head2 Why don't my E<lt>E<lt>HERE documents work?
1120
1121 Check for these three things:
1122
1123 =over 4
1124
1125 =item There must be no space after the E<lt>E<lt> part.
1126
1127 =item There (probably) should be a semicolon at the end.
1128
1129 =item You can't (easily) have any space in front of the tag.
1130
1131 =back
1132
1133 If you want to indent the text in the here document, you
1134 can do this:
1135
1136     # all in one
1137     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1138         your text
1139         goes here
1140     HERE_TARGET
1141
1142 But the HERE_TARGET must still be flush against the margin.
1143 If you want that indented also, you'll have to quote
1144 in the indentation.
1145
1146     ($quote = <<'    FINIS') =~ s/^\s+//gm;
1147             ...we will have peace, when you and all your works have
1148             perished--and the works of your dark master to whom you
1149             would deliver us. You are a liar, Saruman, and a corrupter
1150             of men's hearts.  --Theoden in /usr/src/perl/taint.c
1151         FINIS
1152     $quote =~ s/\s+--/\n--/;
1153
1154 A nice general-purpose fixer-upper function for indented here documents
1155 follows.  It expects to be called with a here document as its argument.
1156 It looks to see whether each line begins with a common substring, and
1157 if so, strips that substring off.  Otherwise, it takes the amount of leading
1158 whitespace found on the first line and removes that much off each
1159 subsequent line.
1160
1161     sub fix {
1162         local $_ = shift;
1163         my ($white, $leader);  # common whitespace and common leading string
1164         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\g1\g2?.*\n)+$/) {
1165             ($white, $leader) = ($2, quotemeta($1));
1166         } else {
1167             ($white, $leader) = (/^(\s+)/, '');
1168         }
1169         s/^\s*?$leader(?:$white)?//gm;
1170         return $_;
1171     }
1172
1173 This works with leading special strings, dynamically determined:
1174
1175         $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1176         @@@ int
1177         @@@ runops() {
1178         @@@     SAVEI32(runlevel);
1179         @@@     runlevel++;
1180         @@@     while ( op = (*op->op_ppaddr)() );
1181         @@@     TAINT_NOT;
1182         @@@     return 0;
1183         @@@ }
1184         MAIN_INTERPRETER_LOOP
1185
1186 Or with a fixed amount of leading whitespace, with remaining
1187 indentation correctly preserved:
1188
1189         $poem = fix<<EVER_ON_AND_ON;
1190        Now far ahead the Road has gone,
1191           And I must follow, if I can,
1192        Pursuing it with eager feet,
1193           Until it joins some larger way
1194        Where many paths and errands meet.
1195           And whither then? I cannot say.
1196                 --Bilbo in /usr/src/perl/pp_ctl.c
1197         EVER_ON_AND_ON
1198
1199 =head1 Data: Arrays
1200
1201 =head2 What is the difference between a list and an array?
1202
1203 (contributed by brian d foy)
1204
1205 A list is a fixed collection of scalars. An array is a variable that
1206 holds a variable collection of scalars. An array can supply its collection
1207 for list operations, so list operations also work on arrays:
1208
1209         # slices
1210         ( 'dog', 'cat', 'bird' )[2,3];
1211         @animals[2,3];
1212
1213         # iteration
1214         foreach ( qw( dog cat bird ) ) { ... }
1215         foreach ( @animals ) { ... }
1216
1217         my @three = grep { length == 3 } qw( dog cat bird );
1218         my @three = grep { length == 3 } @animals;
1219
1220         # supply an argument list
1221         wash_animals( qw( dog cat bird ) );
1222         wash_animals( @animals );
1223
1224 Array operations, which change the scalars, reaaranges them, or adds
1225 or subtracts some scalars, only work on arrays. These can't work on a
1226 list, which is fixed. Array operations include C<shift>, C<unshift>,
1227 C<push>, C<pop>, and C<splice>.
1228
1229 An array can also change its length:
1230
1231         $#animals = 1;  # truncate to two elements
1232         $#animals = 10000; # pre-extend to 10,001 elements
1233
1234 You can change an array element, but you can't change a list element:
1235
1236         $animals[0] = 'Rottweiler';
1237         qw( dog cat bird )[0] = 'Rottweiler'; # syntax error!
1238
1239         foreach ( @animals ) {
1240                 s/^d/fr/;  # works fine
1241                 }
1242
1243         foreach ( qw( dog cat bird ) ) {
1244                 s/^d/fr/;  # Error! Modification of read only value!
1245                 }
1246
1247 However, if the list element is itself a variable, it appears that you
1248 can change a list element. However, the list element is the variable, not
1249 the data. You're not changing the list element, but something the list
1250 element refers to. The list element itself doesn't change: it's still
1251 the same variable.
1252
1253 You also have to be careful about context. You can assign an array to
1254 a scalar to get the number of elements in the array. This only works
1255 for arrays, though:
1256
1257         my $count = @animals;  # only works with arrays
1258
1259 If you try to do the same thing with what you think is a list, you
1260 get a quite different result. Although it looks like you have a list
1261 on the righthand side, Perl actually sees a bunch of scalars separated
1262 by a comma:
1263
1264         my $scalar = ( 'dog', 'cat', 'bird' );  # $scalar gets bird
1265
1266 Since you're assigning to a scalar, the righthand side is in scalar
1267 context. The comma operator (yes, it's an operator!) in scalar
1268 context evaluates its lefthand side, throws away the result, and
1269 evaluates it's righthand side and returns the result. In effect,
1270 that list-lookalike assigns to C<$scalar> it's rightmost value. Many
1271 people mess this up becuase they choose a list-lookalike whose
1272 last element is also the count they expect:
1273
1274         my $scalar = ( 1, 2, 3 );  # $scalar gets 3, accidentally
1275
1276 =head2 What is the difference between $array[1] and @array[1]?
1277
1278 (contributed by brian d foy)
1279
1280 The difference is the sigil, that special character in front of the
1281 array name. The C<$> sigil means "exactly one item", while the C<@>
1282 sigil means "zero or more items". The C<$> gets you a single scalar,
1283 while the C<@> gets you a list.
1284
1285 The confusion arises because people incorrectly assume that the sigil
1286 denotes the variable type.
1287
1288 The C<$array[1]> is a single-element access to the array. It's going
1289 to return the item in index 1 (or undef if there is no item there).
1290 If you intend to get exactly one element from the array, this is the
1291 form you should use.
1292
1293 The C<@array[1]> is an array slice, although it has only one index.
1294 You can pull out multiple elements simultaneously by specifying
1295 additional indices as a list, like C<@array[1,4,3,0]>.
1296
1297 Using a slice on the lefthand side of the assignment supplies list
1298 context to the righthand side. This can lead to unexpected results.
1299 For instance, if you want to read a single line from a filehandle,
1300 assigning to a scalar value is fine:
1301
1302         $array[1] = <STDIN>;
1303
1304 However, in list context, the line input operator returns all of the
1305 lines as a list. The first line goes into C<@array[1]> and the rest
1306 of the lines mysteriously disappear:
1307
1308         @array[1] = <STDIN>;  # most likely not what you want
1309
1310 Either the C<use warnings> pragma or the B<-w> flag will warn you when
1311 you use an array slice with a single index.
1312
1313 =head2 How can I remove duplicate elements from a list or array?
1314
1315 (contributed by brian d foy)
1316
1317 Use a hash. When you think the words "unique" or "duplicated", think
1318 "hash keys".
1319
1320 If you don't care about the order of the elements, you could just
1321 create the hash then extract the keys. It's not important how you
1322 create that hash: just that you use C<keys> to get the unique
1323 elements.
1324
1325         my %hash   = map { $_, 1 } @array;
1326         # or a hash slice: @hash{ @array } = ();
1327         # or a foreach: $hash{$_} = 1 foreach ( @array );
1328
1329         my @unique = keys %hash;
1330
1331 If you want to use a module, try the C<uniq> function from
1332 C<List::MoreUtils>. In list context it returns the unique elements,
1333 preserving their order in the list. In scalar context, it returns the
1334 number of unique elements.
1335
1336         use List::MoreUtils qw(uniq);
1337
1338         my @unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 1,2,3,4,5,6,7
1339         my $unique = uniq( 1, 2, 3, 4, 4, 5, 6, 5, 7 ); # 7
1340
1341 You can also go through each element and skip the ones you've seen
1342 before. Use a hash to keep track. The first time the loop sees an
1343 element, that element has no key in C<%Seen>. The C<next> statement
1344 creates the key and immediately uses its value, which is C<undef>, so
1345 the loop continues to the C<push> and increments the value for that
1346 key. The next time the loop sees that same element, its key exists in
1347 the hash I<and> the value for that key is true (since it's not 0 or
1348 C<undef>), so the next skips that iteration and the loop goes to the
1349 next element.
1350
1351         my @unique = ();
1352         my %seen   = ();
1353
1354         foreach my $elem ( @array )
1355                 {
1356                 next if $seen{ $elem }++;
1357                 push @unique, $elem;
1358                 }
1359
1360 You can write this more briefly using a grep, which does the
1361 same thing.
1362
1363         my %seen = ();
1364         my @unique = grep { ! $seen{ $_ }++ } @array;
1365
1366 =head2 How can I tell whether a certain element is contained in a list or array?
1367
1368 (portions of this answer contributed by Anno Siegel and brian d foy)
1369
1370 Hearing the word "in" is an I<in>dication that you probably should have
1371 used a hash, not a list or array, to store your data.  Hashes are
1372 designed to answer this question quickly and efficiently.  Arrays aren't.
1373
1374 That being said, there are several ways to approach this.  In Perl 5.10
1375 and later, you can use the smart match operator to check that an item is
1376 contained in an array or a hash:
1377
1378         use 5.010;
1379
1380         if( $item ~~ @array )
1381                 {
1382                 say "The array contains $item"
1383                 }
1384
1385         if( $item ~~ %hash )
1386                 {
1387                 say "The hash contains $item"
1388                 }
1389
1390 With earlier versions of Perl, you have to do a bit more work. If you
1391 are going to make this query many times over arbitrary string values,
1392 the fastest way is probably to invert the original array and maintain a
1393 hash whose keys are the first array's values:
1394
1395         @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1396         %is_blue = ();
1397         for (@blues) { $is_blue{$_} = 1 }
1398
1399 Now you can check whether C<$is_blue{$some_color}>.  It might have
1400 been a good idea to keep the blues all in a hash in the first place.
1401
1402 If the values are all small integers, you could use a simple indexed
1403 array.  This kind of an array will take up less space:
1404
1405         @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1406         @is_tiny_prime = ();
1407         for (@primes) { $is_tiny_prime[$_] = 1 }
1408         # or simply  @istiny_prime[@primes] = (1) x @primes;
1409
1410 Now you check whether $is_tiny_prime[$some_number].
1411
1412 If the values in question are integers instead of strings, you can save
1413 quite a lot of space by using bit strings instead:
1414
1415         @articles = ( 1..10, 150..2000, 2017 );
1416         undef $read;
1417         for (@articles) { vec($read,$_,1) = 1 }
1418
1419 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1420
1421 These methods guarantee fast individual tests but require a re-organization
1422 of the original list or array.  They only pay off if you have to test
1423 multiple values against the same array.
1424
1425 If you are testing only once, the standard module C<List::Util> exports
1426 the function C<first> for this purpose.  It works by stopping once it
1427 finds the element. It's written in C for speed, and its Perl equivalent
1428 looks like this subroutine:
1429
1430         sub first (&@) {
1431                 my $code = shift;
1432                 foreach (@_) {
1433                         return $_ if &{$code}();
1434                 }
1435                 undef;
1436         }
1437
1438 If speed is of little concern, the common idiom uses grep in scalar context
1439 (which returns the number of items that passed its condition) to traverse the
1440 entire list. This does have the benefit of telling you how many matches it
1441 found, though.
1442
1443         my $is_there = grep $_ eq $whatever, @array;
1444
1445 If you want to actually extract the matching elements, simply use grep in
1446 list context.
1447
1448         my @matches = grep $_ eq $whatever, @array;
1449
1450 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1451
1452 Use a hash.  Here's code to do both and more.  It assumes that each
1453 element is unique in a given array:
1454
1455         @union = @intersection = @difference = ();
1456         %count = ();
1457         foreach $element (@array1, @array2) { $count{$element}++ }
1458         foreach $element (keys %count) {
1459                 push @union, $element;
1460                 push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1461                 }
1462
1463 Note that this is the I<symmetric difference>, that is, all elements
1464 in either A or in B but not in both.  Think of it as an xor operation.
1465
1466 =head2 How do I test whether two arrays or hashes are equal?
1467
1468 With Perl 5.10 and later, the smart match operator can give you the answer
1469 with the least amount of work:
1470
1471         use 5.010;
1472
1473         if( @array1 ~~ @array2 )
1474                 {
1475                 say "The arrays are the same";
1476                 }
1477
1478         if( %hash1 ~~ %hash2 ) # doesn't check values!
1479                 {
1480                 say "The hash keys are the same";
1481                 }
1482
1483 The following code works for single-level arrays.  It uses a
1484 stringwise comparison, and does not distinguish defined versus
1485 undefined empty strings.  Modify if you have other needs.
1486
1487         $are_equal = compare_arrays(\@frogs, \@toads);
1488
1489         sub compare_arrays {
1490                 my ($first, $second) = @_;
1491                 no warnings;  # silence spurious -w undef complaints
1492                 return 0 unless @$first == @$second;
1493                 for (my $i = 0; $i < @$first; $i++) {
1494                         return 0 if $first->[$i] ne $second->[$i];
1495                         }
1496                 return 1;
1497                 }
1498
1499 For multilevel structures, you may wish to use an approach more
1500 like this one.  It uses the CPAN module C<FreezeThaw>:
1501
1502         use FreezeThaw qw(cmpStr);
1503         @a = @b = ( "this", "that", [ "more", "stuff" ] );
1504
1505         printf "a and b contain %s arrays\n",
1506                 cmpStr(\@a, \@b) == 0
1507                 ? "the same"
1508                 : "different";
1509
1510 This approach also works for comparing hashes.  Here we'll demonstrate
1511 two different answers:
1512
1513         use FreezeThaw qw(cmpStr cmpStrHard);
1514
1515         %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1516         $a{EXTRA} = \%b;
1517         $b{EXTRA} = \%a;
1518
1519         printf "a and b contain %s hashes\n",
1520         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1521
1522         printf "a and b contain %s hashes\n",
1523         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1524
1525
1526 The first reports that both those the hashes contain the same data,
1527 while the second reports that they do not.  Which you prefer is left as
1528 an exercise to the reader.
1529
1530 =head2 How do I find the first array element for which a condition is true?
1531
1532 To find the first array element which satisfies a condition, you can
1533 use the C<first()> function in the C<List::Util> module, which comes
1534 with Perl 5.8. This example finds the first element that contains
1535 "Perl".
1536
1537         use List::Util qw(first);
1538
1539         my $element = first { /Perl/ } @array;
1540
1541 If you cannot use C<List::Util>, you can make your own loop to do the
1542 same thing.  Once you find the element, you stop the loop with last.
1543
1544         my $found;
1545         foreach ( @array ) {
1546                 if( /Perl/ ) { $found = $_; last }
1547                 }
1548
1549 If you want the array index, you can iterate through the indices
1550 and check the array element at each index until you find one
1551 that satisfies the condition.
1552
1553         my( $found, $index ) = ( undef, -1 );
1554         for( $i = 0; $i < @array; $i++ ) {
1555                 if( $array[$i] =~ /Perl/ ) {
1556                         $found = $array[$i];
1557                         $index = $i;
1558                         last;
1559                         }
1560                 }
1561
1562 =head2 How do I handle linked lists?
1563
1564 (contributed by brian d foy)
1565
1566 Perl's arrays do not have a fixed size, so you don't need linked lists
1567 if you just want to add or remove items. You can use array operations
1568 such as C<push>, C<pop>, C<shift>, C<unshift>, or C<splice> to do
1569 that.
1570
1571 Sometimes, however, linked lists can be useful in situations where you
1572 want to "shard" an array so you have have many small arrays instead of
1573 a single big array. You can keep arrays longer than Perl's largest
1574 array index, lock smaller arrays separately in threaded programs,
1575 reallocate less memory, or quickly insert elements in the middle of
1576 the chain.
1577
1578 Steve Lembark goes through the details in his YAPC::NA 2009 talk "Perly
1579 Linked Lists" ( http://www.slideshare.net/lembark/perly-linked-lists ),
1580 although you can just use his C<LinkedList::Single> module.
1581
1582 =head2 How do I handle circular lists?
1583 X<circular> X<array> X<Tie::Cycle> X<Array::Iterator::Circular>
1584 X<cycle> X<modulus>
1585
1586 (contributed by brian d foy)
1587
1588 If you want to cycle through an array endlessly, you can increment the
1589 index modulo the number of elements in the array:
1590
1591         my @array = qw( a b c );
1592         my $i = 0;
1593
1594         while( 1 ) {
1595                 print $array[ $i++ % @array ], "\n";
1596                 last if $i > 20;
1597                 }
1598
1599 You can also use C<Tie::Cycle> to use a scalar that always has the
1600 next element of the circular array:
1601
1602         use Tie::Cycle;
1603
1604         tie my $cycle, 'Tie::Cycle', [ qw( FFFFFF 000000 FFFF00 ) ];
1605
1606         print $cycle; # FFFFFF
1607         print $cycle; # 000000
1608         print $cycle; # FFFF00
1609
1610 The C<Array::Iterator::Circular> creates an iterator object for
1611 circular arrays:
1612
1613         use Array::Iterator::Circular;
1614
1615         my $color_iterator = Array::Iterator::Circular->new(
1616                 qw(red green blue orange)
1617                 );
1618
1619         foreach ( 1 .. 20 ) {
1620                 print $color_iterator->next, "\n";
1621                 }
1622
1623 =head2 How do I shuffle an array randomly?
1624
1625 If you either have Perl 5.8.0 or later installed, or if you have
1626 Scalar-List-Utils 1.03 or later installed, you can say:
1627
1628         use List::Util 'shuffle';
1629
1630         @shuffled = shuffle(@list);
1631
1632 If not, you can use a Fisher-Yates shuffle.
1633
1634         sub fisher_yates_shuffle {
1635                 my $deck = shift;  # $deck is a reference to an array
1636                 return unless @$deck; # must not be empty!
1637
1638                 my $i = @$deck;
1639                 while (--$i) {
1640                         my $j = int rand ($i+1);
1641                         @$deck[$i,$j] = @$deck[$j,$i];
1642                         }
1643         }
1644
1645         # shuffle my mpeg collection
1646         #
1647         my @mpeg = <audio/*/*.mp3>;
1648         fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1649         print @mpeg;
1650
1651 Note that the above implementation shuffles an array in place,
1652 unlike the C<List::Util::shuffle()> which takes a list and returns
1653 a new shuffled list.
1654
1655 You've probably seen shuffling algorithms that work using splice,
1656 randomly picking another element to swap the current element with
1657
1658         srand;
1659         @new = ();
1660         @old = 1 .. 10;  # just a demo
1661         while (@old) {
1662                 push(@new, splice(@old, rand @old, 1));
1663                 }
1664
1665 This is bad because splice is already O(N), and since you do it N
1666 times, you just invented a quadratic algorithm; that is, O(N**2).
1667 This does not scale, although Perl is so efficient that you probably
1668 won't notice this until you have rather largish arrays.
1669
1670 =head2 How do I process/modify each element of an array?
1671
1672 Use C<for>/C<foreach>:
1673
1674         for (@lines) {
1675                 s/foo/bar/;     # change that word
1676                 tr/XZ/ZX/;      # swap those letters
1677                 }
1678
1679 Here's another; let's compute spherical volumes:
1680
1681         for (@volumes = @radii) {   # @volumes has changed parts
1682                 $_ **= 3;
1683                 $_ *= (4/3) * 3.14159;  # this will be constant folded
1684                 }
1685
1686 which can also be done with C<map()> which is made to transform
1687 one list into another:
1688
1689         @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1690
1691 If you want to do the same thing to modify the values of the
1692 hash, you can use the C<values> function.  As of Perl 5.6
1693 the values are not copied, so if you modify $orbit (in this
1694 case), you modify the value.
1695
1696         for $orbit ( values %orbits ) {
1697                 ($orbit **= 3) *= (4/3) * 3.14159;
1698                 }
1699
1700 Prior to perl 5.6 C<values> returned copies of the values,
1701 so older perl code often contains constructions such as
1702 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1703 the hash is to be modified.
1704
1705 =head2 How do I select a random element from an array?
1706
1707 Use the C<rand()> function (see L<perlfunc/rand>):
1708
1709         $index   = rand @array;
1710         $element = $array[$index];
1711
1712 Or, simply:
1713
1714         my $element = $array[ rand @array ];
1715
1716 =head2 How do I permute N elements of a list?
1717 X<List::Permuter> X<permute> X<Algorithm::Loops> X<Knuth>
1718 X<The Art of Computer Programming> X<Fischer-Krause>
1719
1720 Use the C<List::Permutor> module on CPAN. If the list is actually an
1721 array, try the C<Algorithm::Permute> module (also on CPAN). It's
1722 written in XS code and is very efficient:
1723
1724         use Algorithm::Permute;
1725
1726         my @array = 'a'..'d';
1727         my $p_iterator = Algorithm::Permute->new ( \@array );
1728
1729         while (my @perm = $p_iterator->next) {
1730            print "next permutation: (@perm)\n";
1731                 }
1732
1733 For even faster execution, you could do:
1734
1735         use Algorithm::Permute;
1736
1737         my @array = 'a'..'d';
1738
1739         Algorithm::Permute::permute {
1740                 print "next permutation: (@array)\n";
1741                 } @array;
1742
1743 Here's a little program that generates all permutations of all the
1744 words on each line of input. The algorithm embodied in the
1745 C<permute()> function is discussed in Volume 4 (still unpublished) of
1746 Knuth's I<The Art of Computer Programming> and will work on any list:
1747
1748         #!/usr/bin/perl -n
1749         # Fischer-Krause ordered permutation generator
1750
1751         sub permute (&@) {
1752                 my $code = shift;
1753                 my @idx = 0..$#_;
1754                 while ( $code->(@_[@idx]) ) {
1755                         my $p = $#idx;
1756                         --$p while $idx[$p-1] > $idx[$p];
1757                         my $q = $p or return;
1758                         push @idx, reverse splice @idx, $p;
1759                         ++$q while $idx[$p-1] > $idx[$q];
1760                         @idx[$p-1,$q]=@idx[$q,$p-1];
1761                 }
1762         }
1763
1764         permute { print "@_\n" } split;
1765
1766 The C<Algorithm::Loops> module also provides the C<NextPermute> and
1767 C<NextPermuteNum> functions which efficiently find all unique permutations
1768 of an array, even if it contains duplicate values, modifying it in-place:
1769 if its elements are in reverse-sorted order then the array is reversed,
1770 making it sorted, and it returns false; otherwise the next
1771 permutation is returned.
1772
1773 C<NextPermute> uses string order and C<NextPermuteNum> numeric order, so
1774 you can enumerate all the permutations of C<0..9> like this:
1775
1776         use Algorithm::Loops qw(NextPermuteNum);
1777
1778     my @list= 0..9;
1779     do { print "@list\n" } while NextPermuteNum @list;
1780
1781 =head2 How do I sort an array by (anything)?
1782
1783 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1784
1785         @list = sort { $a <=> $b } @list;
1786
1787 The default sort function is cmp, string comparison, which would
1788 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1789 the numerical comparison operator.
1790
1791 If you have a complicated function needed to pull out the part you
1792 want to sort on, then don't do it inside the sort function.  Pull it
1793 out first, because the sort BLOCK can be called many times for the
1794 same element.  Here's an example of how to pull out the first word
1795 after the first number on each item, and then sort those words
1796 case-insensitively.
1797
1798         @idx = ();
1799         for (@data) {
1800                 ($item) = /\d+\s*(\S+)/;
1801                 push @idx, uc($item);
1802             }
1803         @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1804
1805 which could also be written this way, using a trick
1806 that's come to be known as the Schwartzian Transform:
1807
1808         @sorted = map  { $_->[0] }
1809                 sort { $a->[1] cmp $b->[1] }
1810                 map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1811
1812 If you need to sort on several fields, the following paradigm is useful.
1813
1814         @sorted = sort {
1815                 field1($a) <=> field1($b) ||
1816                 field2($a) cmp field2($b) ||
1817                 field3($a) cmp field3($b)
1818                 } @data;
1819
1820 This can be conveniently combined with precalculation of keys as given
1821 above.
1822
1823 See the F<sort> article in the "Far More Than You Ever Wanted
1824 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1825 more about this approach.
1826
1827 See also the question later in L<perlfaq4> on sorting hashes.
1828
1829 =head2 How do I manipulate arrays of bits?
1830
1831 Use C<pack()> and C<unpack()>, or else C<vec()> and the bitwise
1832 operations.
1833
1834 For example, you don't have to store individual bits in an array
1835 (which would mean that you're wasting a lot of space). To convert an
1836 array of bits to a string, use C<vec()> to set the right bits. This
1837 sets C<$vec> to have bit N set only if C<$ints[N]> was set:
1838
1839         @ints = (...); # array of bits, e.g. ( 1, 0, 0, 1, 1, 0 ... )
1840         $vec = '';
1841         foreach( 0 .. $#ints ) {
1842                 vec($vec,$_,1) = 1 if $ints[$_];
1843                 }
1844
1845 The string C<$vec> only takes up as many bits as it needs. For
1846 instance, if you had 16 entries in C<@ints>, C<$vec> only needs two
1847 bytes to store them (not counting the scalar variable overhead).
1848
1849 Here's how, given a vector in C<$vec>, you can get those bits into
1850 your C<@ints> array:
1851
1852         sub bitvec_to_list {
1853                 my $vec = shift;
1854                 my @ints;
1855                 # Find null-byte density then select best algorithm
1856                 if ($vec =~ tr/\0// / length $vec > 0.95) {
1857                         use integer;
1858                         my $i;
1859
1860                         # This method is faster with mostly null-bytes
1861                         while($vec =~ /[^\0]/g ) {
1862                                 $i = -9 + 8 * pos $vec;
1863                                 push @ints, $i if vec($vec, ++$i, 1);
1864                                 push @ints, $i if vec($vec, ++$i, 1);
1865                                 push @ints, $i if vec($vec, ++$i, 1);
1866                                 push @ints, $i if vec($vec, ++$i, 1);
1867                                 push @ints, $i if vec($vec, ++$i, 1);
1868                                 push @ints, $i if vec($vec, ++$i, 1);
1869                                 push @ints, $i if vec($vec, ++$i, 1);
1870                                 push @ints, $i if vec($vec, ++$i, 1);
1871                                 }
1872                         }
1873                 else {
1874                         # This method is a fast general algorithm
1875                         use integer;
1876                         my $bits = unpack "b*", $vec;
1877                         push @ints, 0 if $bits =~ s/^(\d)// && $1;
1878                         push @ints, pos $bits while($bits =~ /1/g);
1879                         }
1880
1881                 return \@ints;
1882                 }
1883
1884 This method gets faster the more sparse the bit vector is.
1885 (Courtesy of Tim Bunce and Winfried Koenig.)
1886
1887 You can make the while loop a lot shorter with this suggestion
1888 from Benjamin Goldberg:
1889
1890         while($vec =~ /[^\0]+/g ) {
1891                 push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1892                 }
1893
1894 Or use the CPAN module C<Bit::Vector>:
1895
1896         $vector = Bit::Vector->new($num_of_bits);
1897         $vector->Index_List_Store(@ints);
1898         @ints = $vector->Index_List_Read();
1899
1900 C<Bit::Vector> provides efficient methods for bit vector, sets of
1901 small integers and "big int" math.
1902
1903 Here's a more extensive illustration using vec():
1904
1905         # vec demo
1906         $vector = "\xff\x0f\xef\xfe";
1907         print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1908         unpack("N", $vector), "\n";
1909         $is_set = vec($vector, 23, 1);
1910         print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1911         pvec($vector);
1912
1913         set_vec(1,1,1);
1914         set_vec(3,1,1);
1915         set_vec(23,1,1);
1916
1917         set_vec(3,1,3);
1918         set_vec(3,2,3);
1919         set_vec(3,4,3);
1920         set_vec(3,4,7);
1921         set_vec(3,8,3);
1922         set_vec(3,8,7);
1923
1924         set_vec(0,32,17);
1925         set_vec(1,32,17);
1926
1927         sub set_vec {
1928                 my ($offset, $width, $value) = @_;
1929                 my $vector = '';
1930                 vec($vector, $offset, $width) = $value;
1931                 print "offset=$offset width=$width value=$value\n";
1932                 pvec($vector);
1933                 }
1934
1935         sub pvec {
1936                 my $vector = shift;
1937                 my $bits = unpack("b*", $vector);
1938                 my $i = 0;
1939                 my $BASE = 8;
1940
1941                 print "vector length in bytes: ", length($vector), "\n";
1942                 @bytes = unpack("A8" x length($vector), $bits);
1943                 print "bits are: @bytes\n\n";
1944                 }
1945
1946 =head2 Why does defined() return true on empty arrays and hashes?
1947
1948 The short story is that you should probably only use defined on scalars or
1949 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1950 in the 5.004 release or later of Perl for more detail.
1951
1952 =head1 Data: Hashes (Associative Arrays)
1953
1954 =head2 How do I process an entire hash?
1955
1956 (contributed by brian d foy)
1957
1958 There are a couple of ways that you can process an entire hash. You
1959 can get a list of keys, then go through each key, or grab a one
1960 key-value pair at a time.
1961
1962 To go through all of the keys, use the C<keys> function. This extracts
1963 all of the keys of the hash and gives them back to you as a list. You
1964 can then get the value through the particular key you're processing:
1965
1966         foreach my $key ( keys %hash ) {
1967                 my $value = $hash{$key}
1968                 ...
1969                 }
1970
1971 Once you have the list of keys, you can process that list before you
1972 process the hash elements. For instance, you can sort the keys so you
1973 can process them in lexical order:
1974
1975         foreach my $key ( sort keys %hash ) {
1976                 my $value = $hash{$key}
1977                 ...
1978                 }
1979
1980 Or, you might want to only process some of the items. If you only want
1981 to deal with the keys that start with C<text:>, you can select just
1982 those using C<grep>:
1983
1984         foreach my $key ( grep /^text:/, keys %hash ) {
1985                 my $value = $hash{$key}
1986                 ...
1987                 }
1988
1989 If the hash is very large, you might not want to create a long list of
1990 keys. To save some memory, you can grab one key-value pair at a time using
1991 C<each()>, which returns a pair you haven't seen yet:
1992
1993         while( my( $key, $value ) = each( %hash ) ) {
1994                 ...
1995                 }
1996
1997 The C<each> operator returns the pairs in apparently random order, so if
1998 ordering matters to you, you'll have to stick with the C<keys> method.
1999
2000 The C<each()> operator can be a bit tricky though. You can't add or
2001 delete keys of the hash while you're using it without possibly
2002 skipping or re-processing some pairs after Perl internally rehashes
2003 all of the elements. Additionally, a hash has only one iterator, so if
2004 you use C<keys>, C<values>, or C<each> on the same hash, you can reset
2005 the iterator and mess up your processing. See the C<each> entry in
2006 L<perlfunc> for more details.
2007
2008 =head2 How do I merge two hashes?
2009 X<hash> X<merge> X<slice, hash>
2010
2011 (contributed by brian d foy)
2012
2013 Before you decide to merge two hashes, you have to decide what to do
2014 if both hashes contain keys that are the same and if you want to leave
2015 the original hashes as they were.
2016
2017 If you want to preserve the original hashes, copy one hash (C<%hash1>)
2018 to a new hash (C<%new_hash>), then add the keys from the other hash
2019 (C<%hash2> to the new hash. Checking that the key already exists in
2020 C<%new_hash> gives you a chance to decide what to do with the
2021 duplicates:
2022
2023         my %new_hash = %hash1; # make a copy; leave %hash1 alone
2024
2025         foreach my $key2 ( keys %hash2 )
2026                 {
2027                 if( exists $new_hash{$key2} )
2028                         {
2029                         warn "Key [$key2] is in both hashes!";
2030                         # handle the duplicate (perhaps only warning)
2031                         ...
2032                         next;
2033                         }
2034                 else
2035                         {
2036                         $new_hash{$key2} = $hash2{$key2};
2037                         }
2038                 }
2039
2040 If you don't want to create a new hash, you can still use this looping
2041 technique; just change the C<%new_hash> to C<%hash1>.
2042
2043         foreach my $key2 ( keys %hash2 )
2044                 {
2045                 if( exists $hash1{$key2} )
2046                         {
2047                         warn "Key [$key2] is in both hashes!";
2048                         # handle the duplicate (perhaps only warning)
2049                         ...
2050                         next;
2051                         }
2052                 else
2053                         {
2054                         $hash1{$key2} = $hash2{$key2};
2055                         }
2056                 }
2057
2058 If you don't care that one hash overwrites keys and values from the other, you
2059 could just use a hash slice to add one hash to another. In this case, values
2060 from C<%hash2> replace values from C<%hash1> when they have keys in common:
2061
2062         @hash1{ keys %hash2 } = values %hash2;
2063
2064 =head2 What happens if I add or remove keys from a hash while iterating over it?
2065
2066 (contributed by brian d foy)
2067
2068 The easy answer is "Don't do that!"
2069
2070 If you iterate through the hash with each(), you can delete the key
2071 most recently returned without worrying about it.  If you delete or add
2072 other keys, the iterator may skip or double up on them since perl
2073 may rearrange the hash table.  See the
2074 entry for C<each()> in L<perlfunc>.
2075
2076 =head2 How do I look up a hash element by value?
2077
2078 Create a reverse hash:
2079
2080         %by_value = reverse %by_key;
2081         $key = $by_value{$value};
2082
2083 That's not particularly efficient.  It would be more space-efficient
2084 to use:
2085
2086         while (($key, $value) = each %by_key) {
2087                 $by_value{$value} = $key;
2088             }
2089
2090 If your hash could have repeated values, the methods above will only find
2091 one of the associated keys.   This may or may not worry you.  If it does
2092 worry you, you can always reverse the hash into a hash of arrays instead:
2093
2094         while (($key, $value) = each %by_key) {
2095                  push @{$key_list_by_value{$value}}, $key;
2096                 }
2097
2098 =head2 How can I know how many entries are in a hash?
2099
2100 (contributed by brian d foy)
2101
2102 This is very similar to "How do I process an entire hash?", also in
2103 L<perlfaq4>, but a bit simpler in the common cases.
2104
2105 You can use the C<keys()> built-in function in scalar context to find out
2106 have many entries you have in a hash:
2107
2108         my $key_count = keys %hash; # must be scalar context!
2109
2110 If you want to find out how many entries have a defined value, that's
2111 a bit different. You have to check each value. A C<grep> is handy:
2112
2113         my $defined_value_count = grep { defined } values %hash;
2114
2115 You can use that same structure to count the entries any way that
2116 you like. If you want the count of the keys with vowels in them,
2117 you just test for that instead:
2118
2119         my $vowel_count = grep { /[aeiou]/ } keys %hash;
2120
2121 The C<grep> in scalar context returns the count. If you want the list
2122 of matching items, just use it in list context instead:
2123
2124         my @defined_values = grep { defined } values %hash;
2125
2126 The C<keys()> function also resets the iterator, which means that you may
2127 see strange results if you use this between uses of other hash operators
2128 such as C<each()>.
2129
2130 =head2 How do I sort a hash (optionally by value instead of key)?
2131
2132 (contributed by brian d foy)
2133
2134 To sort a hash, start with the keys. In this example, we give the list of
2135 keys to the sort function which then compares them ASCIIbetically (which
2136 might be affected by your locale settings). The output list has the keys
2137 in ASCIIbetical order. Once we have the keys, we can go through them to
2138 create a report which lists the keys in ASCIIbetical order.
2139
2140         my @keys = sort { $a cmp $b } keys %hash;
2141
2142         foreach my $key ( @keys )
2143                 {
2144                 printf "%-20s %6d\n", $key, $hash{$key};
2145                 }
2146
2147 We could get more fancy in the C<sort()> block though. Instead of
2148 comparing the keys, we can compute a value with them and use that
2149 value as the comparison.
2150
2151 For instance, to make our report order case-insensitive, we use
2152 the C<\L> sequence in a double-quoted string to make everything
2153 lowercase. The C<sort()> block then compares the lowercased
2154 values to determine in which order to put the keys.
2155
2156         my @keys = sort { "\L$a" cmp "\L$b" } keys %hash;
2157
2158 Note: if the computation is expensive or the hash has many elements,
2159 you may want to look at the Schwartzian Transform to cache the
2160 computation results.
2161
2162 If we want to sort by the hash value instead, we use the hash key
2163 to look it up. We still get out a list of keys, but this time they
2164 are ordered by their value.
2165
2166         my @keys = sort { $hash{$a} <=> $hash{$b} } keys %hash;
2167
2168 From there we can get more complex. If the hash values are the same,
2169 we can provide a secondary sort on the hash key.
2170
2171         my @keys = sort {
2172                 $hash{$a} <=> $hash{$b}
2173                         or
2174                 "\L$a" cmp "\L$b"
2175                 } keys %hash;
2176
2177 =head2 How can I always keep my hash sorted?
2178 X<hash tie sort DB_File Tie::IxHash>
2179
2180 You can look into using the C<DB_File> module and C<tie()> using the
2181 C<$DB_BTREE> hash bindings as documented in L<DB_File/"In Memory
2182 Databases">. The C<Tie::IxHash> module from CPAN might also be
2183 instructive. Although this does keep your hash sorted, you might not
2184 like the slow down you suffer from the tie interface. Are you sure you
2185 need to do this? :)
2186
2187 =head2 What's the difference between "delete" and "undef" with hashes?
2188
2189 Hashes contain pairs of scalars: the first is the key, the
2190 second is the value.  The key will be coerced to a string,
2191 although the value can be any kind of scalar: string,
2192 number, or reference.  If a key C<$key> is present in
2193 %hash, C<exists($hash{$key})> will return true.  The value
2194 for a given key can be C<undef>, in which case
2195 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
2196 will return true.  This corresponds to (C<$key>, C<undef>)
2197 being in the hash.
2198
2199 Pictures help...  Here's the C<%hash> table:
2200
2201           keys  values
2202         +------+------+
2203         |  a   |  3   |
2204         |  x   |  7   |
2205         |  d   |  0   |
2206         |  e   |  2   |
2207         +------+------+
2208
2209 And these conditions hold
2210
2211         $hash{'a'}                       is true
2212         $hash{'d'}                       is false
2213         defined $hash{'d'}               is true
2214         defined $hash{'a'}               is true
2215         exists $hash{'a'}                is true (Perl 5 only)
2216         grep ($_ eq 'a', keys %hash)     is true
2217
2218 If you now say
2219
2220         undef $hash{'a'}
2221
2222 your table now reads:
2223
2224
2225           keys  values
2226         +------+------+
2227         |  a   | undef|
2228         |  x   |  7   |
2229         |  d   |  0   |
2230         |  e   |  2   |
2231         +------+------+
2232
2233 and these conditions now hold; changes in caps:
2234
2235         $hash{'a'}                       is FALSE
2236         $hash{'d'}                       is false
2237         defined $hash{'d'}               is true
2238         defined $hash{'a'}               is FALSE
2239         exists $hash{'a'}                is true (Perl 5 only)
2240         grep ($_ eq 'a', keys %hash)     is true
2241
2242 Notice the last two: you have an undef value, but a defined key!
2243
2244 Now, consider this:
2245
2246         delete $hash{'a'}
2247
2248 your table now reads:
2249
2250           keys  values
2251         +------+------+
2252         |  x   |  7   |
2253         |  d   |  0   |
2254         |  e   |  2   |
2255         +------+------+
2256
2257 and these conditions now hold; changes in caps:
2258
2259         $hash{'a'}                       is false
2260         $hash{'d'}                       is false
2261         defined $hash{'d'}               is true
2262         defined $hash{'a'}               is false
2263         exists $hash{'a'}                is FALSE (Perl 5 only)
2264         grep ($_ eq 'a', keys %hash)     is FALSE
2265
2266 See, the whole entry is gone!
2267
2268 =head2 Why don't my tied hashes make the defined/exists distinction?
2269
2270 This depends on the tied hash's implementation of EXISTS().
2271 For example, there isn't the concept of undef with hashes
2272 that are tied to DBM* files. It also means that exists() and
2273 defined() do the same thing with a DBM* file, and what they
2274 end up doing is not what they do with ordinary hashes.
2275
2276 =head2 How do I reset an each() operation part-way through?
2277
2278 (contributed by brian d foy)
2279
2280 You can use the C<keys> or C<values> functions to reset C<each>. To
2281 simply reset the iterator used by C<each> without doing anything else,
2282 use one of them in void context:
2283
2284         keys %hash; # resets iterator, nothing else.
2285         values %hash; # resets iterator, nothing else.
2286
2287 See the documentation for C<each> in L<perlfunc>.
2288
2289 =head2 How can I get the unique keys from two hashes?
2290
2291 First you extract the keys from the hashes into lists, then solve
2292 the "removing duplicates" problem described above.  For example:
2293
2294         %seen = ();
2295         for $element (keys(%foo), keys(%bar)) {
2296                 $seen{$element}++;
2297                 }
2298         @uniq = keys %seen;
2299
2300 Or more succinctly:
2301
2302         @uniq = keys %{{%foo,%bar}};
2303
2304 Or if you really want to save space:
2305
2306         %seen = ();
2307         while (defined ($key = each %foo)) {
2308                 $seen{$key}++;
2309         }
2310         while (defined ($key = each %bar)) {
2311                 $seen{$key}++;
2312         }
2313         @uniq = keys %seen;
2314
2315 =head2 How can I store a multidimensional array in a DBM file?
2316
2317 Either stringify the structure yourself (no fun), or else
2318 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
2319 it on top of either DB_File or GDBM_File.
2320
2321 =head2 How can I make my hash remember the order I put elements into it?
2322
2323 Use the C<Tie::IxHash> from CPAN.
2324
2325         use Tie::IxHash;
2326
2327         tie my %myhash, 'Tie::IxHash';
2328
2329         for (my $i=0; $i<20; $i++) {
2330                 $myhash{$i} = 2*$i;
2331                 }
2332
2333         my @keys = keys %myhash;
2334         # @keys = (0,1,2,3,...)
2335
2336 =head2 Why does passing a subroutine an undefined element in a hash create it?
2337
2338 (contributed by brian d foy)
2339
2340 Are you using a really old version of Perl?
2341
2342 Normally, accessing a hash key's value for a nonexistent key will
2343 I<not> create the key.
2344
2345         my %hash  = ();
2346         my $value = $hash{ 'foo' };
2347         print "This won't print\n" if exists $hash{ 'foo' };
2348
2349 Passing C<$hash{ 'foo' }> to a subroutine used to be a special case, though.
2350 Since you could assign directly to C<$_[0]>, Perl had to be ready to
2351 make that assignment so it created the hash key ahead of time:
2352
2353     my_sub( $hash{ 'foo' } );
2354         print "This will print before 5.004\n" if exists $hash{ 'foo' };
2355
2356         sub my_sub {
2357                 # $_[0] = 'bar'; # create hash key in case you do this
2358                 1;
2359                 }
2360
2361 Since Perl 5.004, however, this situation is a special case and Perl
2362 creates the hash key only when you make the assignment:
2363
2364     my_sub( $hash{ 'foo' } );
2365         print "This will print, even after 5.004\n" if exists $hash{ 'foo' };
2366
2367         sub my_sub {
2368                 $_[0] = 'bar';
2369                 }
2370
2371 However, if you want the old behavior (and think carefully about that
2372 because it's a weird side effect), you can pass a hash slice instead.
2373 Perl 5.004 didn't make this a special case:
2374
2375         my_sub( @hash{ qw/foo/ } );
2376
2377 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
2378
2379 Usually a hash ref, perhaps like this:
2380
2381         $record = {
2382                 NAME   => "Jason",
2383                 EMPNO  => 132,
2384                 TITLE  => "deputy peon",
2385                 AGE    => 23,
2386                 SALARY => 37_000,
2387                 PALS   => [ "Norbert", "Rhys", "Phineas"],
2388         };
2389
2390 References are documented in L<perlref> and L<perlreftut>.
2391 Examples of complex data structures are given in L<perldsc> and
2392 L<perllol>.  Examples of structures and object-oriented classes are
2393 in L<perltoot>.
2394
2395 =head2 How can I use a reference as a hash key?
2396
2397 (contributed by brian d foy and Ben Morrow)
2398
2399 Hash keys are strings, so you can't really use a reference as the key.
2400 When you try to do that, perl turns the reference into its stringified
2401 form (for instance, C<HASH(0xDEADBEEF)>). From there you can't get
2402 back the reference from the stringified form, at least without doing
2403 some extra work on your own.
2404
2405 Remember that the entry in the hash will still be there even if
2406 the referenced variable  goes out of scope, and that it is entirely
2407 possible for Perl to subsequently allocate a different variable at
2408 the same address. This will mean a new variable might accidentally
2409 be associated with the value for an old.
2410
2411 If you have Perl 5.10 or later, and you just want to store a value
2412 against the reference for lookup later, you can use the core
2413 Hash::Util::Fieldhash module. This will also handle renaming the
2414 keys if you use multiple threads (which causes all variables to be
2415 reallocated at new addresses, changing their stringification), and
2416 garbage-collecting the entries when the referenced variable goes out
2417 of scope.
2418
2419 If you actually need to be able to get a real reference back from
2420 each hash entry, you can use the Tie::RefHash module, which does the
2421 required work for you.
2422
2423 =head2 How can I check if a key exists in a multilevel hash?
2424
2425 (contributed by brian d foy)
2426
2427 The trick to this problem is avoiding accidental autovivification. If 
2428 you want to check three keys deep, you might na├»vely try this:
2429
2430         my %hash;
2431         if( exists $hash{key1}{key2}{key3} ) {
2432                 ...;
2433                 }
2434                 
2435 Even though you started with a completely empty hash, after that call to 
2436 C<exists> you've created the structure you needed to check for C<key3>:
2437
2438         %hash = (
2439                           'key1' => {
2440                                                   'key2' => {}
2441                                                 }
2442                         );
2443
2444 That's autovivification. You can get around this in a few ways. The
2445 easiest way is to just turn it off. The lexical C<autovivification>
2446 pragma is available on CPAN. Now you don't add to the hash:
2447
2448         {
2449         no autovivification;
2450         my %hash;
2451         if( exists $hash{key1}{key2}{key3} ) {
2452                 ...;
2453                 }
2454         }
2455
2456 The C<Data::Diver> module on CPAN can do it for you too. Its C<Dive>
2457 subroutine can tell you not only if the keys exist but also get the
2458 value:
2459
2460         use Data::Diver qw(Dive);
2461         
2462     my @exists = Dive( \%hash, qw(key1 key2 key3) );
2463     if(  ! @exists  ) {
2464         ...; # keys do not exist
2465         } 
2466     elsif(  ! defined $exists[0]  ) {
2467         ...; # keys exist but value is undef
2468         }
2469
2470 You can easily do this yourself too by checking each level of the hash
2471 before you move onto the next level. This is essentially what
2472 C<Data::Diver> does for you:
2473
2474         if( check_hash( \%hash, qw(key1 key2 key3) ) ) {
2475                 ...;
2476                 }
2477         
2478         sub check_hash {
2479            my( $hash, @keys ) = @_;
2480         
2481            return unless @keys;
2482         
2483            foreach my $key ( @keys ) {
2484                    return unless eval { exists $hash->{$key} };
2485                    $hash = $hash->{$key};
2486                    }
2487         
2488            return 1;
2489            }
2490
2491 =head1 Data: Misc
2492
2493 =head2 How do I handle binary data correctly?
2494
2495 Perl is binary clean, so it can handle binary data just fine.
2496 On Windows or DOS, however, you have to use C<binmode> for binary
2497 files to avoid conversions for line endings. In general, you should
2498 use C<binmode> any time you want to work with binary data.
2499
2500 Also see L<perlfunc/"binmode"> or L<perlopentut>.
2501
2502 If you're concerned about 8-bit textual data then see L<perllocale>.
2503 If you want to deal with multibyte characters, however, there are
2504 some gotchas.  See the section on Regular Expressions.
2505
2506 =head2 How do I determine whether a scalar is a number/whole/integer/float?
2507
2508 Assuming that you don't care about IEEE notations like "NaN" or
2509 "Infinity", you probably just want to use a regular expression:
2510
2511         use 5.010;
2512         
2513         given( $number ) {
2514                 when( /\D/ )             
2515                         { say "\thas nondigits"; continue }
2516                 when( /^\d+\z/ )         
2517                         { say "\tis a whole number"; continue }
2518                 when( /^-?\d+\z/ )       
2519                         { say "\tis an integer"; continue }
2520                 when( /^[+-]?\d+\z/ )    
2521                         { say "\tis a +/- integer"; continue }
2522                 when( /^-?(?:\d+\.?|\.\d)\d*\z/ ) 
2523                         { say "\tis a real number"; continue }
2524                 when( /^[+-]?(?=\.?\d)\d*\.?\d*(?:e[+-]?\d+)?\z/i)
2525                         { say "\tis a C float" }
2526                 }
2527
2528 There are also some commonly used modules for the task.
2529 L<Scalar::Util> (distributed with 5.8) provides access to perl's
2530 internal function C<looks_like_number> for determining whether a
2531 variable looks like a number. L<Data::Types> exports functions that
2532 validate data types using both the above and other regular
2533 expressions. Thirdly, there is C<Regexp::Common> which has regular
2534 expressions to match various types of numbers. Those three modules are
2535 available from the CPAN.
2536
2537 If you're on a POSIX system, Perl supports the C<POSIX::strtod>
2538 function. Its semantics are somewhat cumbersome, so here's a
2539 C<getnum> wrapper function for more convenient access. This function
2540 takes a string and returns the number it found, or C<undef> for input
2541 that isn't a C float. The C<is_numeric> function is a front end to
2542 C<getnum> if you just want to say, "Is this a float?"
2543
2544         sub getnum {
2545                 use POSIX qw(strtod);
2546                 my $str = shift;
2547                 $str =~ s/^\s+//;
2548                 $str =~ s/\s+$//;
2549                 $! = 0;
2550                 my($num, $unparsed) = strtod($str);
2551                 if (($str eq '') || ($unparsed != 0) || $!) {
2552                                 return undef;
2553                         }
2554                 else {
2555                         return $num;
2556                         }
2557                 }
2558
2559         sub is_numeric { defined getnum($_[0]) }
2560
2561 Or you could check out the L<String::Scanf> module on the CPAN
2562 instead. The C<POSIX> module (part of the standard Perl distribution)
2563 provides the C<strtod> and C<strtol> for converting strings to double
2564 and longs, respectively.
2565
2566 =head2 How do I keep persistent data across program calls?
2567
2568 For some specific applications, you can use one of the DBM modules.
2569 See L<AnyDBM_File>.  More generically, you should consult the C<FreezeThaw>
2570 or C<Storable> modules from CPAN.  Starting from Perl 5.8 C<Storable> is part
2571 of the standard distribution.  Here's one example using C<Storable>'s C<store>
2572 and C<retrieve> functions:
2573
2574         use Storable;
2575         store(\%hash, "filename");
2576
2577         # later on...
2578         $href = retrieve("filename");        # by ref
2579         %hash = %{ retrieve("filename") };   # direct to hash
2580
2581 =head2 How do I print out or copy a recursive data structure?
2582
2583 The C<Data::Dumper> module on CPAN (or the 5.005 release of Perl) is great
2584 for printing out data structures.  The C<Storable> module on CPAN (or the
2585 5.8 release of Perl), provides a function called C<dclone> that recursively
2586 copies its argument.
2587
2588         use Storable qw(dclone);
2589         $r2 = dclone($r1);
2590
2591 Where C<$r1> can be a reference to any kind of data structure you'd like.
2592 It will be deeply copied.  Because C<dclone> takes and returns references,
2593 you'd have to add extra punctuation if you had a hash of arrays that
2594 you wanted to copy.
2595
2596         %newhash = %{ dclone(\%oldhash) };
2597
2598 =head2 How do I define methods for every class/object?
2599
2600 (contributed by Ben Morrow)
2601
2602 You can use the C<UNIVERSAL> class (see L<UNIVERSAL>). However, please
2603 be very careful to consider the consequences of doing this: adding
2604 methods to every object is very likely to have unintended
2605 consequences. If possible, it would be better to have all your object
2606 inherit from some common base class, or to use an object system like
2607 Moose that supports roles.
2608
2609 =head2 How do I verify a credit card checksum?
2610
2611 Get the C<Business::CreditCard> module from CPAN.
2612
2613 =head2 How do I pack arrays of doubles or floats for XS code?
2614
2615 The arrays.h/arrays.c code in the C<PGPLOT> module on CPAN does just this.
2616 If you're doing a lot of float or double processing, consider using
2617 the C<PDL> module from CPAN instead--it makes number-crunching easy.
2618
2619 See L<http://search.cpan.org/dist/PGPLOT> for the code.
2620
2621 =head1 AUTHOR AND COPYRIGHT
2622
2623 Copyright (c) 1997-2010 Tom Christiansen, Nathan Torkington, and
2624 other authors as noted. All rights reserved.
2625
2626 This documentation is free; you can redistribute it and/or modify it
2627 under the same terms as Perl itself.
2628
2629 Irrespective of its distribution, all code examples in this file
2630 are hereby placed into the public domain.  You are permitted and
2631 encouraged to use this code in your own programs for fun
2632 or for profit as you see fit.  A simple comment in the code giving
2633 credit would be courteous but is not required.