[perl #47365] Docs for \$ prototypes
[perl.git] / pod / perlsub.pod
1 =head1 NAME
2 X<subroutine> X<function>
3
4 perlsub - Perl subroutines
5
6 =head1 SYNOPSIS
7
8 To declare subroutines:
9 X<subroutine, declaration> X<sub>
10
11     sub NAME;                     # A "forward" declaration.
12     sub NAME(PROTO);              #  ditto, but with prototypes
13     sub NAME : ATTRS;             #  with attributes
14     sub NAME(PROTO) : ATTRS;      #  with attributes and prototypes
15
16     sub NAME BLOCK                # A declaration and a definition.
17     sub NAME(PROTO) BLOCK         #  ditto, but with prototypes
18     sub NAME : ATTRS BLOCK        #  with attributes
19     sub NAME(PROTO) : ATTRS BLOCK #  with prototypes and attributes
20
21 To define an anonymous subroutine at runtime:
22 X<subroutine, anonymous>
23
24     $subref = sub BLOCK;                 # no proto
25     $subref = sub (PROTO) BLOCK;         # with proto
26     $subref = sub : ATTRS BLOCK;         # with attributes
27     $subref = sub (PROTO) : ATTRS BLOCK; # with proto and attributes
28
29 To import subroutines:
30 X<import>
31
32     use MODULE qw(NAME1 NAME2 NAME3);
33
34 To call subroutines:
35 X<subroutine, call> X<call>
36
37     NAME(LIST);    # & is optional with parentheses.
38     NAME LIST;     # Parentheses optional if predeclared/imported.
39     &NAME(LIST);   # Circumvent prototypes.
40     &NAME;         # Makes current @_ visible to called subroutine.
41
42 =head1 DESCRIPTION
43
44 Like many languages, Perl provides for user-defined subroutines.
45 These may be located anywhere in the main program, loaded in from
46 other files via the C<do>, C<require>, or C<use> keywords, or
47 generated on the fly using C<eval> or anonymous subroutines.
48 You can even call a function indirectly using a variable containing
49 its name or a CODE reference.
50
51 The Perl model for function call and return values is simple: all
52 functions are passed as parameters one single flat list of scalars, and
53 all functions likewise return to their caller one single flat list of
54 scalars.  Any arrays or hashes in these call and return lists will
55 collapse, losing their identities--but you may always use
56 pass-by-reference instead to avoid this.  Both call and return lists may
57 contain as many or as few scalar elements as you'd like.  (Often a
58 function without an explicit return statement is called a subroutine, but
59 there's really no difference from Perl's perspective.)
60 X<subroutine, parameter> X<parameter>
61
62 Any arguments passed in show up in the array C<@_>.  Therefore, if
63 you called a function with two arguments, those would be stored in
64 C<$_[0]> and C<$_[1]>.  The array C<@_> is a local array, but its
65 elements are aliases for the actual scalar parameters.  In particular,
66 if an element C<$_[0]> is updated, the corresponding argument is
67 updated (or an error occurs if it is not updatable).  If an argument
68 is an array or hash element which did not exist when the function
69 was called, that element is created only when (and if) it is modified
70 or a reference to it is taken.  (Some earlier versions of Perl
71 created the element whether or not the element was assigned to.)
72 Assigning to the whole array C<@_> removes that aliasing, and does
73 not update any arguments.
74 X<subroutine, argument> X<argument> X<@_>
75
76 A C<return> statement may be used to exit a subroutine, optionally
77 specifying the returned value, which will be evaluated in the
78 appropriate context (list, scalar, or void) depending on the context of
79 the subroutine call.  If you specify no return value, the subroutine
80 returns an empty list in list context, the undefined value in scalar
81 context, or nothing in void context.  If you return one or more
82 aggregates (arrays and hashes), these will be flattened together into
83 one large indistinguishable list.
84
85 If no C<return> is found and if the last statement is an expression, its
86 value is returned. If the last statement is a loop control structure
87 like a C<foreach> or a C<while>, the returned value is unspecified. The
88 empty sub returns the empty list.
89 X<subroutine, return value> X<return value> X<return>
90
91 Perl does not have named formal parameters.  In practice all you
92 do is assign to a C<my()> list of these.  Variables that aren't
93 declared to be private are global variables.  For gory details
94 on creating private variables, see L<"Private Variables via my()">
95 and L<"Temporary Values via local()">.  To create protected
96 environments for a set of functions in a separate package (and
97 probably a separate file), see L<perlmod/"Packages">.
98 X<formal parameter> X<parameter, formal>
99
100 Example:
101
102     sub max {
103         my $max = shift(@_);
104         foreach $foo (@_) {
105             $max = $foo if $max < $foo;
106         }
107         return $max;
108     }
109     $bestday = max($mon,$tue,$wed,$thu,$fri);
110
111 Example:
112
113     # get a line, combining continuation lines
114     #  that start with whitespace
115
116     sub get_line {
117         $thisline = $lookahead;  # global variables!
118         LINE: while (defined($lookahead = <STDIN>)) {
119             if ($lookahead =~ /^[ \t]/) {
120                 $thisline .= $lookahead;
121             }
122             else {
123                 last LINE;
124             }
125         }
126         return $thisline;
127     }
128
129     $lookahead = <STDIN>;       # get first line
130     while (defined($line = get_line())) {
131         ...
132     }
133
134 Assigning to a list of private variables to name your arguments:
135
136     sub maybeset {
137         my($key, $value) = @_;
138         $Foo{$key} = $value unless $Foo{$key};
139     }
140
141 Because the assignment copies the values, this also has the effect
142 of turning call-by-reference into call-by-value.  Otherwise a
143 function is free to do in-place modifications of C<@_> and change
144 its caller's values.
145 X<call-by-reference> X<call-by-value>
146
147     upcase_in($v1, $v2);  # this changes $v1 and $v2
148     sub upcase_in {
149         for (@_) { tr/a-z/A-Z/ }
150     }
151
152 You aren't allowed to modify constants in this way, of course.  If an
153 argument were actually literal and you tried to change it, you'd take a
154 (presumably fatal) exception.   For example, this won't work:
155 X<call-by-reference> X<call-by-value>
156
157     upcase_in("frederick");
158
159 It would be much safer if the C<upcase_in()> function
160 were written to return a copy of its parameters instead
161 of changing them in place:
162
163     ($v3, $v4) = upcase($v1, $v2);  # this doesn't change $v1 and $v2
164     sub upcase {
165         return unless defined wantarray;  # void context, do nothing
166         my @parms = @_;
167         for (@parms) { tr/a-z/A-Z/ }
168         return wantarray ? @parms : $parms[0];
169     }
170
171 Notice how this (unprototyped) function doesn't care whether it was
172 passed real scalars or arrays.  Perl sees all arguments as one big,
173 long, flat parameter list in C<@_>.  This is one area where
174 Perl's simple argument-passing style shines.  The C<upcase()>
175 function would work perfectly well without changing the C<upcase()>
176 definition even if we fed it things like this:
177
178     @newlist   = upcase(@list1, @list2);
179     @newlist   = upcase( split /:/, $var );
180
181 Do not, however, be tempted to do this:
182
183     (@a, @b)   = upcase(@list1, @list2);
184
185 Like the flattened incoming parameter list, the return list is also
186 flattened on return.  So all you have managed to do here is stored
187 everything in C<@a> and made C<@b> empty.  See 
188 L<Pass by Reference> for alternatives.
189
190 A subroutine may be called using an explicit C<&> prefix.  The
191 C<&> is optional in modern Perl, as are parentheses if the
192 subroutine has been predeclared.  The C<&> is I<not> optional
193 when just naming the subroutine, such as when it's used as
194 an argument to defined() or undef().  Nor is it optional when you
195 want to do an indirect subroutine call with a subroutine name or
196 reference using the C<&$subref()> or C<&{$subref}()> constructs,
197 although the C<< $subref->() >> notation solves that problem.
198 See L<perlref> for more about all that.
199 X<&>
200
201 Subroutines may be called recursively.  If a subroutine is called
202 using the C<&> form, the argument list is optional, and if omitted,
203 no C<@_> array is set up for the subroutine: the C<@_> array at the
204 time of the call is visible to subroutine instead.  This is an
205 efficiency mechanism that new users may wish to avoid.
206 X<recursion>
207
208     &foo(1,2,3);        # pass three arguments
209     foo(1,2,3);         # the same
210
211     foo();              # pass a null list
212     &foo();             # the same
213
214     &foo;               # foo() get current args, like foo(@_) !!
215     foo;                # like foo() IFF sub foo predeclared, else "foo"
216
217 Not only does the C<&> form make the argument list optional, it also
218 disables any prototype checking on arguments you do provide.  This
219 is partly for historical reasons, and partly for having a convenient way
220 to cheat if you know what you're doing.  See L<Prototypes> below.
221 X<&>
222
223 Subroutines whose names are in all upper case are reserved to the Perl
224 core, as are modules whose names are in all lower case.  A subroutine in
225 all capitals is a loosely-held convention meaning it will be called
226 indirectly by the run-time system itself, usually due to a triggered event.
227 Subroutines that do special, pre-defined things include C<AUTOLOAD>, C<CLONE>,
228 C<DESTROY> plus all functions mentioned in L<perltie> and L<PerlIO::via>.
229
230 The C<BEGIN>, C<UNITCHECK>, C<CHECK>, C<INIT> and C<END> subroutines
231 are not so much subroutines as named special code blocks, of which you
232 can have more than one in a package, and which you can B<not> call
233 explicitly.  See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END">
234
235 =head2 Private Variables via my()
236 X<my> X<variable, lexical> X<lexical> X<lexical variable> X<scope, lexical>
237 X<lexical scope> X<attributes, my>
238
239 Synopsis:
240
241     my $foo;            # declare $foo lexically local
242     my (@wid, %get);    # declare list of variables local
243     my $foo = "flurp";  # declare $foo lexical, and init it
244     my @oof = @bar;     # declare @oof lexical, and init it
245     my $x : Foo = $y;   # similar, with an attribute applied
246
247 B<WARNING>: The use of attribute lists on C<my> declarations is still
248 evolving.  The current semantics and interface are subject to change.
249 See L<attributes> and L<Attribute::Handlers>.
250
251 The C<my> operator declares the listed variables to be lexically
252 confined to the enclosing block, conditional (C<if/unless/elsif/else>),
253 loop (C<for/foreach/while/until/continue>), subroutine, C<eval>,
254 or C<do/require/use>'d file.  If more than one value is listed, the
255 list must be placed in parentheses.  All listed elements must be
256 legal lvalues.  Only alphanumeric identifiers may be lexically
257 scoped--magical built-ins like C<$/> must currently be C<local>ized
258 with C<local> instead.
259
260 Unlike dynamic variables created by the C<local> operator, lexical
261 variables declared with C<my> are totally hidden from the outside
262 world, including any called subroutines.  This is true if it's the
263 same subroutine called from itself or elsewhere--every call gets
264 its own copy.
265 X<local>
266
267 This doesn't mean that a C<my> variable declared in a statically
268 enclosing lexical scope would be invisible.  Only dynamic scopes
269 are cut off.   For example, the C<bumpx()> function below has access
270 to the lexical $x variable because both the C<my> and the C<sub>
271 occurred at the same scope, presumably file scope.
272
273     my $x = 10;
274     sub bumpx { $x++ } 
275
276 An C<eval()>, however, can see lexical variables of the scope it is
277 being evaluated in, so long as the names aren't hidden by declarations within
278 the C<eval()> itself.  See L<perlref>.
279 X<eval, scope of>
280
281 The parameter list to my() may be assigned to if desired, which allows you
282 to initialize your variables.  (If no initializer is given for a
283 particular variable, it is created with the undefined value.)  Commonly
284 this is used to name input parameters to a subroutine.  Examples:
285
286     $arg = "fred";        # "global" variable
287     $n = cube_root(27);
288     print "$arg thinks the root is $n\n";
289  fred thinks the root is 3
290
291     sub cube_root {
292         my $arg = shift;  # name doesn't matter
293         $arg **= 1/3;
294         return $arg;
295     }
296
297 The C<my> is simply a modifier on something you might assign to.  So when
298 you do assign to variables in its argument list, C<my> doesn't
299 change whether those variables are viewed as a scalar or an array.  So
300
301     my ($foo) = <STDIN>;                # WRONG?
302     my @FOO = <STDIN>;
303
304 both supply a list context to the right-hand side, while
305
306     my $foo = <STDIN>;
307
308 supplies a scalar context.  But the following declares only one variable:
309
310     my $foo, $bar = 1;                  # WRONG
311
312 That has the same effect as
313
314     my $foo;
315     $bar = 1;
316
317 The declared variable is not introduced (is not visible) until after
318 the current statement.  Thus,
319
320     my $x = $x;
321
322 can be used to initialize a new $x with the value of the old $x, and
323 the expression
324
325     my $x = 123 and $x == 123
326
327 is false unless the old $x happened to have the value C<123>.
328
329 Lexical scopes of control structures are not bounded precisely by the
330 braces that delimit their controlled blocks; control expressions are
331 part of that scope, too.  Thus in the loop
332
333     while (my $line = <>) {
334         $line = lc $line;
335     } continue {
336         print $line;
337     }
338
339 the scope of $line extends from its declaration throughout the rest of
340 the loop construct (including the C<continue> clause), but not beyond
341 it.  Similarly, in the conditional
342
343     if ((my $answer = <STDIN>) =~ /^yes$/i) {
344         user_agrees();
345     } elsif ($answer =~ /^no$/i) {
346         user_disagrees();
347     } else {
348         chomp $answer;
349         die "'$answer' is neither 'yes' nor 'no'";
350     }
351
352 the scope of $answer extends from its declaration through the rest
353 of that conditional, including any C<elsif> and C<else> clauses, 
354 but not beyond it.  See L<perlsyn/"Simple statements"> for information
355 on the scope of variables in statements with modifiers.
356
357 The C<foreach> loop defaults to scoping its index variable dynamically
358 in the manner of C<local>.  However, if the index variable is
359 prefixed with the keyword C<my>, or if there is already a lexical
360 by that name in scope, then a new lexical is created instead.  Thus
361 in the loop
362 X<foreach> X<for>
363
364     for my $i (1, 2, 3) {
365         some_function();
366     }
367
368 the scope of $i extends to the end of the loop, but not beyond it,
369 rendering the value of $i inaccessible within C<some_function()>.
370 X<foreach> X<for>
371
372 Some users may wish to encourage the use of lexically scoped variables.
373 As an aid to catching implicit uses to package variables,
374 which are always global, if you say
375
376     use strict 'vars';
377
378 then any variable mentioned from there to the end of the enclosing
379 block must either refer to a lexical variable, be predeclared via
380 C<our> or C<use vars>, or else must be fully qualified with the package name.
381 A compilation error results otherwise.  An inner block may countermand
382 this with C<no strict 'vars'>.
383
384 A C<my> has both a compile-time and a run-time effect.  At compile
385 time, the compiler takes notice of it.  The principal usefulness
386 of this is to quiet C<use strict 'vars'>, but it is also essential
387 for generation of closures as detailed in L<perlref>.  Actual
388 initialization is delayed until run time, though, so it gets executed
389 at the appropriate time, such as each time through a loop, for
390 example.
391
392 Variables declared with C<my> are not part of any package and are therefore
393 never fully qualified with the package name.  In particular, you're not
394 allowed to try to make a package variable (or other global) lexical:
395
396     my $pack::var;      # ERROR!  Illegal syntax
397
398 In fact, a dynamic variable (also known as package or global variables)
399 are still accessible using the fully qualified C<::> notation even while a
400 lexical of the same name is also visible:
401
402     package main;
403     local $x = 10;
404     my    $x = 20;
405     print "$x and $::x\n";
406
407 That will print out C<20> and C<10>.
408
409 You may declare C<my> variables at the outermost scope of a file
410 to hide any such identifiers from the world outside that file.  This
411 is similar in spirit to C's static variables when they are used at
412 the file level.  To do this with a subroutine requires the use of
413 a closure (an anonymous function that accesses enclosing lexicals).
414 If you want to create a private subroutine that cannot be called
415 from outside that block, it can declare a lexical variable containing
416 an anonymous sub reference:
417
418     my $secret_version = '1.001-beta';
419     my $secret_sub = sub { print $secret_version };
420     &$secret_sub();
421
422 As long as the reference is never returned by any function within the
423 module, no outside module can see the subroutine, because its name is not in
424 any package's symbol table.  Remember that it's not I<REALLY> called
425 C<$some_pack::secret_version> or anything; it's just $secret_version,
426 unqualified and unqualifiable.
427
428 This does not work with object methods, however; all object methods
429 have to be in the symbol table of some package to be found.  See
430 L<perlref/"Function Templates"> for something of a work-around to
431 this.
432
433 =head2 Persistent Private Variables
434 X<state> X<state variable> X<static> X<variable, persistent> X<variable, static> X<closure>
435
436 There are two ways to build persistent private variables in Perl 5.10.
437 First, you can simply use the C<state> feature. Or, you can use closures,
438 if you want to stay compatible with releases older than 5.10.
439
440 =head3 Persistent variables via state()
441
442 Beginning with perl 5.9.4, you can declare variables with the C<state>
443 keyword in place of C<my>. For that to work, though, you must have
444 enabled that feature beforehand, either by using the C<feature> pragma, or
445 by using C<-E> on one-liners. (see L<feature>)
446
447 For example, the following code maintains a private counter, incremented
448 each time the gimme_another() function is called:
449
450     use feature 'state';
451     sub gimme_another { state $x; return ++$x }
452
453 Also, since C<$x> is lexical, it can't be reached or modified by any Perl
454 code outside.
455
456 When combined with variable declaration, simple scalar assignment to C<state>
457 variables (as in C<state $x = 42>) is executed only the first time.  When such
458 statements are evaluated subsequent times, the assignment is ignored.  The
459 behavior of this sort of assignment to non-scalar variables is undefined.
460
461 =head3 Persistent variables with closures
462
463 Just because a lexical variable is lexically (also called statically)
464 scoped to its enclosing block, C<eval>, or C<do> FILE, this doesn't mean that
465 within a function it works like a C static.  It normally works more
466 like a C auto, but with implicit garbage collection.  
467
468 Unlike local variables in C or C++, Perl's lexical variables don't
469 necessarily get recycled just because their scope has exited.
470 If something more permanent is still aware of the lexical, it will
471 stick around.  So long as something else references a lexical, that
472 lexical won't be freed--which is as it should be.  You wouldn't want
473 memory being free until you were done using it, or kept around once you
474 were done.  Automatic garbage collection takes care of this for you.
475
476 This means that you can pass back or save away references to lexical
477 variables, whereas to return a pointer to a C auto is a grave error.
478 It also gives us a way to simulate C's function statics.  Here's a
479 mechanism for giving a function private variables with both lexical
480 scoping and a static lifetime.  If you do want to create something like
481 C's static variables, just enclose the whole function in an extra block,
482 and put the static variable outside the function but in the block.
483
484     {
485         my $secret_val = 0;
486         sub gimme_another {
487             return ++$secret_val;
488         }
489     }
490     # $secret_val now becomes unreachable by the outside
491     # world, but retains its value between calls to gimme_another
492
493 If this function is being sourced in from a separate file
494 via C<require> or C<use>, then this is probably just fine.  If it's
495 all in the main program, you'll need to arrange for the C<my>
496 to be executed early, either by putting the whole block above
497 your main program, or more likely, placing merely a C<BEGIN>
498 code block around it to make sure it gets executed before your program
499 starts to run:
500
501     BEGIN {
502         my $secret_val = 0;
503         sub gimme_another {
504             return ++$secret_val;
505         }
506     }
507
508 See L<perlmod/"BEGIN, UNITCHECK, CHECK, INIT and END"> about the
509 special triggered code blocks, C<BEGIN>, C<UNITCHECK>, C<CHECK>,
510 C<INIT> and C<END>.
511
512 If declared at the outermost scope (the file scope), then lexicals
513 work somewhat like C's file statics.  They are available to all
514 functions in that same file declared below them, but are inaccessible
515 from outside that file.  This strategy is sometimes used in modules
516 to create private variables that the whole module can see.
517
518 =head2 Temporary Values via local()
519 X<local> X<scope, dynamic> X<dynamic scope> X<variable, local>
520 X<variable, temporary>
521
522 B<WARNING>: In general, you should be using C<my> instead of C<local>, because
523 it's faster and safer.  Exceptions to this include the global punctuation
524 variables, global filehandles and formats, and direct manipulation of the
525 Perl symbol table itself.  C<local> is mostly used when the current value
526 of a variable must be visible to called subroutines.
527
528 Synopsis:
529
530     # localization of values
531
532     local $foo;                 # make $foo dynamically local
533     local (@wid, %get);         # make list of variables local
534     local $foo = "flurp";       # make $foo dynamic, and init it
535     local @oof = @bar;          # make @oof dynamic, and init it
536
537     local $hash{key} = "val";   # sets a local value for this hash entry
538     delete local $hash{key};    # delete this entry for the current block
539     local ($cond ? $v1 : $v2);  # several types of lvalues support
540                                 # localization
541
542     # localization of symbols
543
544     local *FH;                  # localize $FH, @FH, %FH, &FH  ...
545     local *merlyn = *randal;    # now $merlyn is really $randal, plus
546                                 #     @merlyn is really @randal, etc
547     local *merlyn = 'randal';   # SAME THING: promote 'randal' to *randal
548     local *merlyn = \$randal;   # just alias $merlyn, not @merlyn etc
549
550 A C<local> modifies its listed variables to be "local" to the
551 enclosing block, C<eval>, or C<do FILE>--and to I<any subroutine
552 called from within that block>.  A C<local> just gives temporary
553 values to global (meaning package) variables.  It does I<not> create
554 a local variable.  This is known as dynamic scoping.  Lexical scoping
555 is done with C<my>, which works more like C's auto declarations.
556
557 Some types of lvalues can be localized as well : hash and array elements
558 and slices, conditionals (provided that their result is always
559 localizable), and symbolic references.  As for simple variables, this
560 creates new, dynamically scoped values.
561
562 If more than one variable or expression is given to C<local>, they must be
563 placed in parentheses.  This operator works
564 by saving the current values of those variables in its argument list on a
565 hidden stack and restoring them upon exiting the block, subroutine, or
566 eval.  This means that called subroutines can also reference the local
567 variable, but not the global one.  The argument list may be assigned to if
568 desired, which allows you to initialize your local variables.  (If no
569 initializer is given for a particular variable, it is created with an
570 undefined value.)
571
572 Because C<local> is a run-time operator, it gets executed each time
573 through a loop.  Consequently, it's more efficient to localize your
574 variables outside the loop.
575
576 =head3 Grammatical note on local()
577 X<local, context>
578
579 A C<local> is simply a modifier on an lvalue expression.  When you assign to
580 a C<local>ized variable, the C<local> doesn't change whether its list is viewed
581 as a scalar or an array.  So
582
583     local($foo) = <STDIN>;
584     local @FOO = <STDIN>;
585
586 both supply a list context to the right-hand side, while
587
588     local $foo = <STDIN>;
589
590 supplies a scalar context.
591
592 =head3 Localization of special variables
593 X<local, special variable>
594
595 If you localize a special variable, you'll be giving a new value to it,
596 but its magic won't go away.  That means that all side-effects related
597 to this magic still work with the localized value.
598
599 This feature allows code like this to work :
600
601     # Read the whole contents of FILE in $slurp
602     { local $/ = undef; $slurp = <FILE>; }
603
604 Note, however, that this restricts localization of some values ; for
605 example, the following statement dies, as of perl 5.9.0, with an error
606 I<Modification of a read-only value attempted>, because the $1 variable is
607 magical and read-only :
608
609     local $1 = 2;
610
611 Similarly, but in a way more difficult to spot, the following snippet will
612 die in perl 5.9.0 :
613
614     sub f { local $_ = "foo"; print }
615     for ($1) {
616         # now $_ is aliased to $1, thus is magic and readonly
617         f();
618     }
619
620 See next section for an alternative to this situation.
621
622 B<WARNING>: Localization of tied arrays and hashes does not currently
623 work as described.
624 This will be fixed in a future release of Perl; in the meantime, avoid
625 code that relies on any particular behaviour of localising tied arrays
626 or hashes (localising individual elements is still okay).
627 See L<perl58delta/"Localising Tied Arrays and Hashes Is Broken"> for more
628 details.
629 X<local, tie>
630
631 =head3 Localization of globs
632 X<local, glob> X<glob>
633
634 The construct
635
636     local *name;
637
638 creates a whole new symbol table entry for the glob C<name> in the
639 current package.  That means that all variables in its glob slot ($name,
640 @name, %name, &name, and the C<name> filehandle) are dynamically reset.
641
642 This implies, among other things, that any magic eventually carried by
643 those variables is locally lost.  In other words, saying C<local */>
644 will not have any effect on the internal value of the input record
645 separator.
646
647 Notably, if you want to work with a brand new value of the default scalar
648 $_, and avoid the potential problem listed above about $_ previously
649 carrying a magic value, you should use C<local *_> instead of C<local $_>.
650 As of perl 5.9.1, you can also use the lexical form of C<$_> (declaring it
651 with C<my $_>), which avoids completely this problem.
652
653 =head3 Localization of elements of composite types
654 X<local, composite type element> X<local, array element> X<local, hash element>
655
656 It's also worth taking a moment to explain what happens when you
657 C<local>ize a member of a composite type (i.e. an array or hash element).
658 In this case, the element is C<local>ized I<by name>. This means that
659 when the scope of the C<local()> ends, the saved value will be
660 restored to the hash element whose key was named in the C<local()>, or
661 the array element whose index was named in the C<local()>.  If that
662 element was deleted while the C<local()> was in effect (e.g. by a
663 C<delete()> from a hash or a C<shift()> of an array), it will spring
664 back into existence, possibly extending an array and filling in the
665 skipped elements with C<undef>.  For instance, if you say
666
667     %hash = ( 'This' => 'is', 'a' => 'test' );
668     @ary  = ( 0..5 );
669     {
670          local($ary[5]) = 6;
671          local($hash{'a'}) = 'drill';
672          while (my $e = pop(@ary)) {
673              print "$e . . .\n";
674              last unless $e > 3;
675          }
676          if (@ary) {
677              $hash{'only a'} = 'test';
678              delete $hash{'a'};
679          }
680     }
681     print join(' ', map { "$_ $hash{$_}" } sort keys %hash),".\n";
682     print "The array has ",scalar(@ary)," elements: ",
683           join(', ', map { defined $_ ? $_ : 'undef' } @ary),"\n";
684
685 Perl will print
686
687     6 . . .
688     4 . . .
689     3 . . .
690     This is a test only a test.
691     The array has 6 elements: 0, 1, 2, undef, undef, 5
692
693 The behavior of local() on non-existent members of composite
694 types is subject to change in future.
695
696 =head3 Localized deletion of elements of composite types
697 X<delete> X<local, composite type element> X<local, array element> X<local, hash element>
698
699 You can use the C<delete local $array[$idx]> and C<delete local $hash{key}>
700 constructs to delete a composite type entry for the current block and restore
701 it when it ends. They return the array/hash value before the localization,
702 which means that they are respectively equivalent to
703
704     do {
705         my $val = $array[$idx];
706         local  $array[$idx];
707         delete $array[$idx];
708         $val
709     }
710
711 and
712
713     do {
714         my $val = $hash{key};
715         local  $hash{key};
716         delete $hash{key};
717         $val
718     }
719
720 except that for those the C<local> is scoped to the C<do> block. Slices are
721 also accepted.
722
723     my %hash = (
724      a => [ 7, 8, 9 ],
725      b => 1,
726     )
727
728     {
729      my $a = delete local $hash{a};
730      # $a is [ 7, 8, 9 ]
731      # %hash is (b => 1)
732
733      {
734       my @nums = delete local @$a[0, 2]
735       # @nums is (7, 9)
736       # $a is [ undef, 8 ]
737
738       $a[0] = 999; # will be erased when the scope ends
739      }
740      # $a is back to [ 7, 8, 9 ]
741
742     }
743     # %hash is back to its original state
744
745 =head2 Lvalue subroutines
746 X<lvalue> X<subroutine, lvalue>
747
748 B<WARNING>: Lvalue subroutines are still experimental and the
749 implementation may change in future versions of Perl.
750
751 It is possible to return a modifiable value from a subroutine.
752 To do this, you have to declare the subroutine to return an lvalue.
753
754     my $val;
755     sub canmod : lvalue {
756         # return $val; this doesn't work, don't say "return"
757         $val;
758     }
759     sub nomod {
760         $val;
761     }
762
763     canmod() = 5;   # assigns to $val
764     nomod()  = 5;   # ERROR
765
766 The scalar/list context for the subroutine and for the right-hand
767 side of assignment is determined as if the subroutine call is replaced
768 by a scalar. For example, consider:
769
770     data(2,3) = get_data(3,4);
771
772 Both subroutines here are called in a scalar context, while in:
773
774     (data(2,3)) = get_data(3,4);
775
776 and in:
777
778     (data(2),data(3)) = get_data(3,4);
779
780 all the subroutines are called in a list context.
781
782 =over 4
783
784 =item Lvalue subroutines are EXPERIMENTAL
785
786 They appear to be convenient, but there are several reasons to be
787 circumspect.
788
789 You can't use the return keyword, you must pass out the value before
790 falling out of subroutine scope. (see comment in example above).  This
791 is usually not a problem, but it disallows an explicit return out of a
792 deeply nested loop, which is sometimes a nice way out.
793
794 They violate encapsulation.  A normal mutator can check the supplied
795 argument before setting the attribute it is protecting, an lvalue
796 subroutine never gets that chance.  Consider;
797
798     my $some_array_ref = [];    # protected by mutators ??
799
800     sub set_arr {               # normal mutator
801         my $val = shift;
802         die("expected array, you supplied ", ref $val)
803            unless ref $val eq 'ARRAY';
804         $some_array_ref = $val;
805     }
806     sub set_arr_lv : lvalue {   # lvalue mutator
807         $some_array_ref;
808     }
809
810     # set_arr_lv cannot stop this !
811     set_arr_lv() = { a => 1 };
812
813 =back
814
815 =head2 Passing Symbol Table Entries (typeglobs)
816 X<typeglob> X<*>
817
818 B<WARNING>: The mechanism described in this section was originally
819 the only way to simulate pass-by-reference in older versions of
820 Perl.  While it still works fine in modern versions, the new reference
821 mechanism is generally easier to work with.  See below.
822
823 Sometimes you don't want to pass the value of an array to a subroutine
824 but rather the name of it, so that the subroutine can modify the global
825 copy of it rather than working with a local copy.  In perl you can
826 refer to all objects of a particular name by prefixing the name
827 with a star: C<*foo>.  This is often known as a "typeglob", because the
828 star on the front can be thought of as a wildcard match for all the
829 funny prefix characters on variables and subroutines and such.
830
831 When evaluated, the typeglob produces a scalar value that represents
832 all the objects of that name, including any filehandle, format, or
833 subroutine.  When assigned to, it causes the name mentioned to refer to
834 whatever C<*> value was assigned to it.  Example:
835
836     sub doubleary {
837         local(*someary) = @_;
838         foreach $elem (@someary) {
839             $elem *= 2;
840         }
841     }
842     doubleary(*foo);
843     doubleary(*bar);
844
845 Scalars are already passed by reference, so you can modify
846 scalar arguments without using this mechanism by referring explicitly
847 to C<$_[0]> etc.  You can modify all the elements of an array by passing
848 all the elements as scalars, but you have to use the C<*> mechanism (or
849 the equivalent reference mechanism) to C<push>, C<pop>, or change the size of
850 an array.  It will certainly be faster to pass the typeglob (or reference).
851
852 Even if you don't want to modify an array, this mechanism is useful for
853 passing multiple arrays in a single LIST, because normally the LIST
854 mechanism will merge all the array values so that you can't extract out
855 the individual arrays.  For more on typeglobs, see
856 L<perldata/"Typeglobs and Filehandles">.
857
858 =head2 When to Still Use local()
859 X<local> X<variable, local>
860
861 Despite the existence of C<my>, there are still three places where the
862 C<local> operator still shines.  In fact, in these three places, you
863 I<must> use C<local> instead of C<my>.
864
865 =over 4
866
867 =item 1.
868
869 You need to give a global variable a temporary value, especially $_.
870
871 The global variables, like C<@ARGV> or the punctuation variables, must be 
872 C<local>ized with C<local()>.  This block reads in F</etc/motd>, and splits
873 it up into chunks separated by lines of equal signs, which are placed
874 in C<@Fields>.
875
876     {
877         local @ARGV = ("/etc/motd");
878         local $/ = undef;
879         local $_ = <>;  
880         @Fields = split /^\s*=+\s*$/;
881     } 
882
883 It particular, it's important to C<local>ize $_ in any routine that assigns
884 to it.  Look out for implicit assignments in C<while> conditionals.
885
886 =item 2.
887
888 You need to create a local file or directory handle or a local function.
889
890 A function that needs a filehandle of its own must use
891 C<local()> on a complete typeglob.   This can be used to create new symbol
892 table entries:
893
894     sub ioqueue {
895         local  (*READER, *WRITER);    # not my!
896         pipe    (READER,  WRITER)     or die "pipe: $!";
897         return (*READER, *WRITER);
898     }
899     ($head, $tail) = ioqueue();
900
901 See the Symbol module for a way to create anonymous symbol table
902 entries.
903
904 Because assignment of a reference to a typeglob creates an alias, this
905 can be used to create what is effectively a local function, or at least,
906 a local alias.
907
908     {
909         local *grow = \&shrink; # only until this block exists
910         grow();                 # really calls shrink()
911         move();                 # if move() grow()s, it shrink()s too
912     }
913     grow();                     # get the real grow() again
914
915 See L<perlref/"Function Templates"> for more about manipulating
916 functions by name in this way.
917
918 =item 3.
919
920 You want to temporarily change just one element of an array or hash.
921
922 You can C<local>ize just one element of an aggregate.  Usually this
923 is done on dynamics:
924
925     {
926         local $SIG{INT} = 'IGNORE';
927         funct();                            # uninterruptible
928     } 
929     # interruptibility automatically restored here
930
931 But it also works on lexically declared aggregates.  Prior to 5.005,
932 this operation could on occasion misbehave.
933
934 =back
935
936 =head2 Pass by Reference
937 X<pass by reference> X<pass-by-reference> X<reference>
938
939 If you want to pass more than one array or hash into a function--or
940 return them from it--and have them maintain their integrity, then
941 you're going to have to use an explicit pass-by-reference.  Before you
942 do that, you need to understand references as detailed in L<perlref>.
943 This section may not make much sense to you otherwise.
944
945 Here are a few simple examples.  First, let's pass in several arrays
946 to a function and have it C<pop> all of then, returning a new list
947 of all their former last elements:
948
949     @tailings = popmany ( \@a, \@b, \@c, \@d );
950
951     sub popmany {
952         my $aref;
953         my @retlist = ();
954         foreach $aref ( @_ ) {
955             push @retlist, pop @$aref;
956         }
957         return @retlist;
958     }
959
960 Here's how you might write a function that returns a
961 list of keys occurring in all the hashes passed to it:
962
963     @common = inter( \%foo, \%bar, \%joe );
964     sub inter {
965         my ($k, $href, %seen); # locals
966         foreach $href (@_) {
967             while ( $k = each %$href ) {
968                 $seen{$k}++;
969             }
970         }
971         return grep { $seen{$_} == @_ } keys %seen;
972     }
973
974 So far, we're using just the normal list return mechanism.
975 What happens if you want to pass or return a hash?  Well,
976 if you're using only one of them, or you don't mind them
977 concatenating, then the normal calling convention is ok, although
978 a little expensive.
979
980 Where people get into trouble is here:
981
982     (@a, @b) = func(@c, @d);
983 or
984     (%a, %b) = func(%c, %d);
985
986 That syntax simply won't work.  It sets just C<@a> or C<%a> and
987 clears the C<@b> or C<%b>.  Plus the function didn't get passed
988 into two separate arrays or hashes: it got one long list in C<@_>,
989 as always.
990
991 If you can arrange for everyone to deal with this through references, it's
992 cleaner code, although not so nice to look at.  Here's a function that
993 takes two array references as arguments, returning the two array elements
994 in order of how many elements they have in them:
995
996     ($aref, $bref) = func(\@c, \@d);
997     print "@$aref has more than @$bref\n";
998     sub func {
999         my ($cref, $dref) = @_;
1000         if (@$cref > @$dref) {
1001             return ($cref, $dref);
1002         } else {
1003             return ($dref, $cref);
1004         }
1005     }
1006
1007 It turns out that you can actually do this also:
1008
1009     (*a, *b) = func(\@c, \@d);
1010     print "@a has more than @b\n";
1011     sub func {
1012         local (*c, *d) = @_;
1013         if (@c > @d) {
1014             return (\@c, \@d);
1015         } else {
1016             return (\@d, \@c);
1017         }
1018     }
1019
1020 Here we're using the typeglobs to do symbol table aliasing.  It's
1021 a tad subtle, though, and also won't work if you're using C<my>
1022 variables, because only globals (even in disguise as C<local>s)
1023 are in the symbol table.
1024
1025 If you're passing around filehandles, you could usually just use the bare
1026 typeglob, like C<*STDOUT>, but typeglobs references work, too.
1027 For example:
1028
1029     splutter(\*STDOUT);
1030     sub splutter {
1031         my $fh = shift;
1032         print $fh "her um well a hmmm\n";
1033     }
1034
1035     $rec = get_rec(\*STDIN);
1036     sub get_rec {
1037         my $fh = shift;
1038         return scalar <$fh>;
1039     }
1040
1041 If you're planning on generating new filehandles, you could do this.
1042 Notice to pass back just the bare *FH, not its reference.
1043
1044     sub openit {
1045         my $path = shift;
1046         local *FH;
1047         return open (FH, $path) ? *FH : undef;
1048     }
1049
1050 =head2 Prototypes
1051 X<prototype> X<subroutine, prototype>
1052
1053 Perl supports a very limited kind of compile-time argument checking
1054 using function prototyping.  If you declare
1055
1056     sub mypush (\@@)
1057
1058 then C<mypush()> takes arguments exactly like C<push()> does.  The
1059 function declaration must be visible at compile time.  The prototype
1060 affects only interpretation of new-style calls to the function,
1061 where new-style is defined as not using the C<&> character.  In
1062 other words, if you call it like a built-in function, then it behaves
1063 like a built-in function.  If you call it like an old-fashioned
1064 subroutine, then it behaves like an old-fashioned subroutine.  It
1065 naturally falls out from this rule that prototypes have no influence
1066 on subroutine references like C<\&foo> or on indirect subroutine
1067 calls like C<&{$subref}> or C<< $subref->() >>.
1068
1069 Method calls are not influenced by prototypes either, because the
1070 function to be called is indeterminate at compile time, since
1071 the exact code called depends on inheritance.
1072
1073 Because the intent of this feature is primarily to let you define
1074 subroutines that work like built-in functions, here are prototypes
1075 for some other functions that parse almost exactly like the
1076 corresponding built-in.
1077
1078     Declared as                 Called as
1079
1080     sub mylink ($$)          mylink $old, $new
1081     sub myvec ($$$)          myvec $var, $offset, 1
1082     sub myindex ($$;$)       myindex &getstring, "substr"
1083     sub mysyswrite ($$$;$)   mysyswrite $buf, 0, length($buf) - $off, $off
1084     sub myreverse (@)        myreverse $a, $b, $c
1085     sub myjoin ($@)          myjoin ":", $a, $b, $c
1086     sub mypop (\@)           mypop @array
1087     sub mysplice (\@$$@)     mysplice @array, 0, 2, @pushme
1088     sub mykeys (\%)          mykeys %{$hashref}
1089     sub myopen (*;$)         myopen HANDLE, $name
1090     sub mypipe (**)          mypipe READHANDLE, WRITEHANDLE
1091     sub mygrep (&@)          mygrep { /foo/ } $a, $b, $c
1092     sub myrand (;$)          myrand 42
1093     sub mytime ()            mytime
1094
1095 Any backslashed prototype character represents an actual argument
1096 that must start with that character (optionally preceded by C<my>,
1097 C<our> or C<local>), with the exception of C<$>, which will accept a
1098 hash or array element even without a dollar sign, such as
1099 C<my_function()->[0]>. The value passed as part of C<@_> will be a
1100 reference to the actual argument given in the subroutine call,
1101 obtained by applying C<\> to that argument.
1102
1103 You can also backslash several argument types simultaneously by using
1104 the C<\[]> notation:
1105
1106     sub myref (\[$@%&*])
1107
1108 will allow calling myref() as
1109
1110     myref $var
1111     myref @array
1112     myref %hash
1113     myref &sub
1114     myref *glob
1115
1116 and the first argument of myref() will be a reference to
1117 a scalar, an array, a hash, a code, or a glob.
1118
1119 Unbackslashed prototype characters have special meanings.  Any
1120 unbackslashed C<@> or C<%> eats all remaining arguments, and forces
1121 list context.  An argument represented by C<$> forces scalar context.  An
1122 C<&> requires an anonymous subroutine, which, if passed as the first
1123 argument, does not require the C<sub> keyword or a subsequent comma.
1124
1125 A C<*> allows the subroutine to accept a bareword, constant, scalar expression,
1126 typeglob, or a reference to a typeglob in that slot.  The value will be
1127 available to the subroutine either as a simple scalar, or (in the latter
1128 two cases) as a reference to the typeglob.  If you wish to always convert
1129 such arguments to a typeglob reference, use Symbol::qualify_to_ref() as
1130 follows:
1131
1132     use Symbol 'qualify_to_ref';
1133
1134     sub foo (*) {
1135         my $fh = qualify_to_ref(shift, caller);
1136         ...
1137     }
1138
1139 A semicolon (C<;>) separates mandatory arguments from optional arguments.
1140 It is redundant before C<@> or C<%>, which gobble up everything else.
1141
1142 As the last character of a prototype, or just before a semicolon, you can
1143 use C<_> in place of C<$>: if this argument is not provided, C<$_> will be
1144 used instead.
1145
1146 Note how the last three examples in the table above are treated
1147 specially by the parser.  C<mygrep()> is parsed as a true list
1148 operator, C<myrand()> is parsed as a true unary operator with unary
1149 precedence the same as C<rand()>, and C<mytime()> is truly without
1150 arguments, just like C<time()>.  That is, if you say
1151
1152     mytime +2;
1153
1154 you'll get C<mytime() + 2>, not C<mytime(2)>, which is how it would be parsed
1155 without a prototype.
1156
1157 The interesting thing about C<&> is that you can generate new syntax with it,
1158 provided it's in the initial position:
1159 X<&>
1160
1161     sub try (&@) {
1162         my($try,$catch) = @_;
1163         eval { &$try };
1164         if ($@) {
1165             local $_ = $@;
1166             &$catch;
1167         }
1168     }
1169     sub catch (&) { $_[0] }
1170
1171     try {
1172         die "phooey";
1173     } catch {
1174         /phooey/ and print "unphooey\n";
1175     };
1176
1177 That prints C<"unphooey">.  (Yes, there are still unresolved
1178 issues having to do with visibility of C<@_>.  I'm ignoring that
1179 question for the moment.  (But note that if we make C<@_> lexically
1180 scoped, those anonymous subroutines can act like closures... (Gee,
1181 is this sounding a little Lispish?  (Never mind.))))
1182
1183 And here's a reimplementation of the Perl C<grep> operator:
1184 X<grep>
1185
1186     sub mygrep (&@) {
1187         my $code = shift;
1188         my @result;
1189         foreach $_ (@_) {
1190             push(@result, $_) if &$code;
1191         }
1192         @result;
1193     }
1194
1195 Some folks would prefer full alphanumeric prototypes.  Alphanumerics have
1196 been intentionally left out of prototypes for the express purpose of
1197 someday in the future adding named, formal parameters.  The current
1198 mechanism's main goal is to let module writers provide better diagnostics
1199 for module users.  Larry feels the notation quite understandable to Perl
1200 programmers, and that it will not intrude greatly upon the meat of the
1201 module, nor make it harder to read.  The line noise is visually
1202 encapsulated into a small pill that's easy to swallow.
1203
1204 If you try to use an alphanumeric sequence in a prototype you will
1205 generate an optional warning - "Illegal character in prototype...".
1206 Unfortunately earlier versions of Perl allowed the prototype to be
1207 used as long as its prefix was a valid prototype.  The warning may be
1208 upgraded to a fatal error in a future version of Perl once the
1209 majority of offending code is fixed.
1210
1211 It's probably best to prototype new functions, not retrofit prototyping
1212 into older ones.  That's because you must be especially careful about
1213 silent impositions of differing list versus scalar contexts.  For example,
1214 if you decide that a function should take just one parameter, like this:
1215
1216     sub func ($) {
1217         my $n = shift;
1218         print "you gave me $n\n";
1219     }
1220
1221 and someone has been calling it with an array or expression
1222 returning a list:
1223
1224     func(@foo);
1225     func( split /:/ );
1226
1227 Then you've just supplied an automatic C<scalar> in front of their
1228 argument, which can be more than a bit surprising.  The old C<@foo>
1229 which used to hold one thing doesn't get passed in.  Instead,
1230 C<func()> now gets passed in a C<1>; that is, the number of elements
1231 in C<@foo>.  And the C<split> gets called in scalar context so it
1232 starts scribbling on your C<@_> parameter list.  Ouch!
1233
1234 This is all very powerful, of course, and should be used only in moderation
1235 to make the world a better place.
1236
1237 =head2 Constant Functions
1238 X<constant>
1239
1240 Functions with a prototype of C<()> are potential candidates for
1241 inlining.  If the result after optimization and constant folding
1242 is either a constant or a lexically-scoped scalar which has no other
1243 references, then it will be used in place of function calls made
1244 without C<&>.  Calls made using C<&> are never inlined.  (See
1245 F<constant.pm> for an easy way to declare most constants.)
1246
1247 The following functions would all be inlined:
1248
1249     sub pi ()           { 3.14159 }             # Not exact, but close.
1250     sub PI ()           { 4 * atan2 1, 1 }      # As good as it gets,
1251                                                 # and it's inlined, too!
1252     sub ST_DEV ()       { 0 }
1253     sub ST_INO ()       { 1 }
1254
1255     sub FLAG_FOO ()     { 1 << 8 }
1256     sub FLAG_BAR ()     { 1 << 9 }
1257     sub FLAG_MASK ()    { FLAG_FOO | FLAG_BAR }
1258
1259     sub OPT_BAZ ()      { not (0x1B58 & FLAG_MASK) }
1260
1261     sub N () { int(OPT_BAZ) / 3 }
1262
1263     sub FOO_SET () { 1 if FLAG_MASK & FLAG_FOO }
1264
1265 Be aware that these will not be inlined; as they contain inner scopes,
1266 the constant folding doesn't reduce them to a single constant:
1267
1268     sub foo_set () { if (FLAG_MASK & FLAG_FOO) { 1 } }
1269
1270     sub baz_val () {
1271         if (OPT_BAZ) {
1272             return 23;
1273         }
1274         else {
1275             return 42;
1276         }
1277     }
1278
1279 If you redefine a subroutine that was eligible for inlining, you'll get
1280 a mandatory warning.  (You can use this warning to tell whether or not a
1281 particular subroutine is considered constant.)  The warning is
1282 considered severe enough not to be optional because previously compiled
1283 invocations of the function will still be using the old value of the
1284 function.  If you need to be able to redefine the subroutine, you need to
1285 ensure that it isn't inlined, either by dropping the C<()> prototype
1286 (which changes calling semantics, so beware) or by thwarting the
1287 inlining mechanism in some other way, such as
1288
1289     sub not_inlined () {
1290         23 if $];
1291     }
1292
1293 =head2 Overriding Built-in Functions
1294 X<built-in> X<override> X<CORE> X<CORE::GLOBAL>
1295
1296 Many built-in functions may be overridden, though this should be tried
1297 only occasionally and for good reason.  Typically this might be
1298 done by a package attempting to emulate missing built-in functionality
1299 on a non-Unix system.
1300
1301 Overriding may be done only by importing the name from a module at
1302 compile time--ordinary predeclaration isn't good enough.  However, the
1303 C<use subs> pragma lets you, in effect, predeclare subs
1304 via the import syntax, and these names may then override built-in ones:
1305
1306     use subs 'chdir', 'chroot', 'chmod', 'chown';
1307     chdir $somewhere;
1308     sub chdir { ... }
1309
1310 To unambiguously refer to the built-in form, precede the
1311 built-in name with the special package qualifier C<CORE::>.  For example,
1312 saying C<CORE::open()> always refers to the built-in C<open()>, even
1313 if the current package has imported some other subroutine called
1314 C<&open()> from elsewhere.  Even though it looks like a regular
1315 function call, it isn't: you can't take a reference to it, such as
1316 the incorrect C<\&CORE::open> might appear to produce.
1317
1318 Library modules should not in general export built-in names like C<open>
1319 or C<chdir> as part of their default C<@EXPORT> list, because these may
1320 sneak into someone else's namespace and change the semantics unexpectedly.
1321 Instead, if the module adds that name to C<@EXPORT_OK>, then it's
1322 possible for a user to import the name explicitly, but not implicitly.
1323 That is, they could say
1324
1325     use Module 'open';
1326
1327 and it would import the C<open> override.  But if they said
1328
1329     use Module;
1330
1331 they would get the default imports without overrides.
1332
1333 The foregoing mechanism for overriding built-in is restricted, quite
1334 deliberately, to the package that requests the import.  There is a second
1335 method that is sometimes applicable when you wish to override a built-in
1336 everywhere, without regard to namespace boundaries.  This is achieved by
1337 importing a sub into the special namespace C<CORE::GLOBAL::>.  Here is an
1338 example that quite brazenly replaces the C<glob> operator with something
1339 that understands regular expressions.
1340
1341     package REGlob;
1342     require Exporter;
1343     @ISA = 'Exporter';
1344     @EXPORT_OK = 'glob';
1345
1346     sub import {
1347         my $pkg = shift;
1348         return unless @_;
1349         my $sym = shift;
1350         my $where = ($sym =~ s/^GLOBAL_// ? 'CORE::GLOBAL' : caller(0));
1351         $pkg->export($where, $sym, @_);
1352     }
1353
1354     sub glob {
1355         my $pat = shift;
1356         my @got;
1357         if (opendir my $d, '.') { 
1358             @got = grep /$pat/, readdir $d; 
1359             closedir $d;   
1360         }
1361         return @got;
1362     }
1363     1;
1364
1365 And here's how it could be (ab)used:
1366
1367     #use REGlob 'GLOBAL_glob';      # override glob() in ALL namespaces
1368     package Foo;
1369     use REGlob 'glob';              # override glob() in Foo:: only
1370     print for <^[a-z_]+\.pm\$>;     # show all pragmatic modules
1371
1372 The initial comment shows a contrived, even dangerous example.
1373 By overriding C<glob> globally, you would be forcing the new (and
1374 subversive) behavior for the C<glob> operator for I<every> namespace,
1375 without the complete cognizance or cooperation of the modules that own
1376 those namespaces.  Naturally, this should be done with extreme caution--if
1377 it must be done at all.
1378
1379 The C<REGlob> example above does not implement all the support needed to
1380 cleanly override perl's C<glob> operator.  The built-in C<glob> has
1381 different behaviors depending on whether it appears in a scalar or list
1382 context, but our C<REGlob> doesn't.  Indeed, many perl built-in have such
1383 context sensitive behaviors, and these must be adequately supported by
1384 a properly written override.  For a fully functional example of overriding
1385 C<glob>, study the implementation of C<File::DosGlob> in the standard
1386 library.
1387
1388 When you override a built-in, your replacement should be consistent (if
1389 possible) with the built-in native syntax.  You can achieve this by using
1390 a suitable prototype.  To get the prototype of an overridable built-in,
1391 use the C<prototype> function with an argument of C<"CORE::builtin_name">
1392 (see L<perlfunc/prototype>).
1393
1394 Note however that some built-ins can't have their syntax expressed by a
1395 prototype (such as C<system> or C<chomp>).  If you override them you won't
1396 be able to fully mimic their original syntax.
1397
1398 The built-ins C<do>, C<require> and C<glob> can also be overridden, but due
1399 to special magic, their original syntax is preserved, and you don't have
1400 to define a prototype for their replacements.  (You can't override the
1401 C<do BLOCK> syntax, though).
1402
1403 C<require> has special additional dark magic: if you invoke your
1404 C<require> replacement as C<require Foo::Bar>, it will actually receive
1405 the argument C<"Foo/Bar.pm"> in @_.  See L<perlfunc/require>.
1406
1407 And, as you'll have noticed from the previous example, if you override
1408 C<glob>, the C<< <*> >> glob operator is overridden as well.
1409
1410 In a similar fashion, overriding the C<readline> function also overrides
1411 the equivalent I/O operator C<< <FILEHANDLE> >>. Also, overriding
1412 C<readpipe> also overrides the operators C<``> and C<qx//>.
1413
1414 Finally, some built-ins (e.g. C<exists> or C<grep>) can't be overridden.
1415
1416 =head2 Autoloading
1417 X<autoloading> X<AUTOLOAD>
1418
1419 If you call a subroutine that is undefined, you would ordinarily
1420 get an immediate, fatal error complaining that the subroutine doesn't
1421 exist.  (Likewise for subroutines being used as methods, when the
1422 method doesn't exist in any base class of the class's package.)
1423 However, if an C<AUTOLOAD> subroutine is defined in the package or
1424 packages used to locate the original subroutine, then that
1425 C<AUTOLOAD> subroutine is called with the arguments that would have
1426 been passed to the original subroutine.  The fully qualified name
1427 of the original subroutine magically appears in the global $AUTOLOAD
1428 variable of the same package as the C<AUTOLOAD> routine.  The name
1429 is not passed as an ordinary argument because, er, well, just
1430 because, that's why.  (As an exception, a method call to a nonexistent
1431 C<import> or C<unimport> method is just skipped instead.  Also, if
1432 the AUTOLOAD subroutine is an XSUB, C<$AUTOLOAD> is not populated;
1433 instead, you should call L<< C<SvPVX>E<sol>C<SvCUR>|perlapi >> on the
1434 C<CV> for C<AUTOLOAD> to retrieve the method name.)
1435
1436
1437 Many C<AUTOLOAD> routines load in a definition for the requested
1438 subroutine using eval(), then execute that subroutine using a special
1439 form of goto() that erases the stack frame of the C<AUTOLOAD> routine
1440 without a trace.  (See the source to the standard module documented
1441 in L<AutoLoader>, for example.)  But an C<AUTOLOAD> routine can
1442 also just emulate the routine and never define it.   For example,
1443 let's pretend that a function that wasn't defined should just invoke
1444 C<system> with those arguments.  All you'd do is:
1445
1446     sub AUTOLOAD {
1447         my $program = $AUTOLOAD;
1448         $program =~ s/.*:://;
1449         system($program, @_);
1450     }
1451     date();
1452     who('am', 'i');
1453     ls('-l');
1454
1455 In fact, if you predeclare functions you want to call that way, you don't
1456 even need parentheses:
1457
1458     use subs qw(date who ls);
1459     date;
1460     who "am", "i";
1461     ls '-l';
1462
1463 A more complete example of this is the standard Shell module, which
1464 can treat undefined subroutine calls as calls to external programs.
1465
1466 Mechanisms are available to help modules writers split their modules
1467 into autoloadable files.  See the standard AutoLoader module
1468 described in L<AutoLoader> and in L<AutoSplit>, the standard
1469 SelfLoader modules in L<SelfLoader>, and the document on adding C
1470 functions to Perl code in L<perlxs>.
1471
1472 =head2 Subroutine Attributes
1473 X<attribute> X<subroutine, attribute> X<attrs>
1474
1475 A subroutine declaration or definition may have a list of attributes
1476 associated with it.  If such an attribute list is present, it is
1477 broken up at space or colon boundaries and treated as though a
1478 C<use attributes> had been seen.  See L<attributes> for details
1479 about what attributes are currently supported.
1480 Unlike the limitation with the obsolescent C<use attrs>, the
1481 C<sub : ATTRLIST> syntax works to associate the attributes with
1482 a pre-declaration, and not just with a subroutine definition.
1483
1484 The attributes must be valid as simple identifier names (without any
1485 punctuation other than the '_' character).  They may have a parameter
1486 list appended, which is only checked for whether its parentheses ('(',')')
1487 nest properly.
1488
1489 Examples of valid syntax (even though the attributes are unknown):
1490
1491     sub fnord (&\%) : switch(10,foo(7,3))  :  expensive;
1492     sub plugh () : Ugly('\(") :Bad;
1493     sub xyzzy : _5x5 { ... }
1494
1495 Examples of invalid syntax:
1496
1497     sub fnord : switch(10,foo(); # ()-string not balanced
1498     sub snoid : Ugly('(');        # ()-string not balanced
1499     sub xyzzy : 5x5;              # "5x5" not a valid identifier
1500     sub plugh : Y2::north;        # "Y2::north" not a simple identifier
1501     sub snurt : foo + bar;        # "+" not a colon or space
1502
1503 The attribute list is passed as a list of constant strings to the code
1504 which associates them with the subroutine.  In particular, the second example
1505 of valid syntax above currently looks like this in terms of how it's
1506 parsed and invoked:
1507
1508     use attributes __PACKAGE__, \&plugh, q[Ugly('\(")], 'Bad';
1509
1510 For further details on attribute lists and their manipulation,
1511 see L<attributes> and L<Attribute::Handlers>.
1512
1513 =head1 SEE ALSO
1514
1515 See L<perlref/"Function Templates"> for more about references and closures.
1516 See L<perlxs> if you'd like to learn about calling C subroutines from Perl.  
1517 See L<perlembed> if you'd like to learn about calling Perl subroutines from C.  
1518 See L<perlmod> to learn about bundling up your functions in separate files.
1519 See L<perlmodlib> to learn what library modules come standard on your system.
1520 See L<perltoot> to learn how to make object method calls.