Revert "Remove deprecation warnings related to $* and $#."
[perl.git] / Porting / corelist.pl
1 #!perl
2 # Generates info for Module::CoreList from this perl tree
3 # run this from the root of a perl tree
4 #
5 # Data is on STDOUT.
6 #
7 # With an optional arg specifying the root of a CPAN mirror, outputs the
8 # %upstream and %bug_tracker hashes too.
9
10 use autodie;
11 use strict;
12 use warnings;
13 use File::Find;
14 use ExtUtils::MM_Unix;
15 use version;
16 use lib "Porting";
17 use Maintainers qw(%Modules files_to_modules);
18 use File::Spec;
19 use Parse::CPAN::Meta;
20 use IPC::Cmd 'can_run';
21 use HTTP::Tiny;
22 use IO::Uncompress::Gunzip;
23
24 my $corelist_file = 'dist/Module-CoreList/lib/Module/CoreList.pm';
25 my $utils_file = 'dist/Module-CoreList/lib/Module/CoreList/Utils.pm';
26
27 my %lines;
28 my %module_to_file;
29 my %modlist;
30
31 die "usage: $0 [ cpan-mirror/ ] [ 5.x.y] \n" unless @ARGV <= 2;
32 my $cpan         = shift;
33 my $raw_version  = shift || $];
34 my $perl_version = version->parse("$raw_version");
35 my $perl_vnum    = $perl_version->numify;
36 my $perl_vstring = $perl_version->normal; # how do we get version.pm to not give us leading v?
37 $perl_vstring =~ s/^v//;
38
39 if ( !-f 'MANIFEST' ) {
40     die "Must be run from the root of a clean perl tree\n";
41 }
42
43 open( my $corelist_fh, '<', $corelist_file );
44 my $corelist = join( '', <$corelist_fh> );
45 close $corelist_fh;
46
47 unless (
48     $corelist =~ /^%released \s* = \s* \(
49         .*?
50         $perl_vnum \s* => \s* .*?
51         \);/ismx
52     )
53 {
54     warn "Adding $perl_vnum to the list of released perl versions. Please consider adding a release date.\n";
55     $corelist =~ s/^(%released \s* = \s* .*?) ( \) )
56                 /$1  $perl_vnum => '????-??-??',\n  $2/ismx;
57 }
58
59 if ($cpan) {
60     my $modlistfile = File::Spec->catfile( $cpan, 'modules', '02packages.details.txt' );
61     my $content;
62
63     my $fh;
64     if ( -e $modlistfile ) {
65         warn "Reading the module list from $modlistfile";
66         open $fh, '<', $modlistfile;
67     } elsif ( -e $modlistfile . ".gz" ) {
68         my $zcat = can_run('gzcat') || can_run('zcat') or die "Can't find gzcat or zcat";
69         warn "Reading the module list from $modlistfile.gz";
70         open $fh, '-|', "$zcat $modlistfile.gz";
71     } else {
72         warn "About to fetch 02packages from ftp.funet.fi. This may take a few minutes\n";
73         my $gzipped_content = fetch_url('http://ftp.funet.fi/pub/CPAN/modules/02packages.details.txt.gz');
74         unless ($gzipped_content) {
75             die "Unable to read 02packages.details.txt from either your CPAN mirror or ftp.funet.fi";
76         }
77         IO::Uncompress::Gunzip::gunzip(\$gzipped_content, \$content, Transparent => 0)
78             or die "Can't gunzip content: $IO::Uncompress::Gunzip::GunzipError";
79     }
80
81     if ( $fh and !$content ) {
82         local $/ = "\n";
83         $content = join( '', <$fh> );
84     }
85
86     die "Incompatible modlist format"
87         unless $content =~ /^Columns: +package name, version, path/m;
88
89     # Converting the file to a hash is about 5 times faster than a regexp flat
90     # lookup.
91     for ( split( qr/\n/, $content ) ) {
92         next unless /^([A-Za-z_:0-9]+) +[-0-9.undefHASHVERSIONvsetwhenloadingbogus]+ +(\S+)/;
93         $modlist{$1} = $2;
94     }
95 }
96
97 find(
98     sub {
99         /(\.pm|_pm\.PL)$/ or return;
100         /PPPort\.pm$/ and return;
101         my $module = $File::Find::name;
102         $module =~ /\b(demo|t|private|corpus)\b/ and return;    # demo or test modules
103         my $version = MM->parse_version($_);
104         defined $version or $version = 'undef';
105         $version =~ /\d/ and $version = "'$version'";
106
107         # some heuristics to figure out the module name from the file name
108         $module =~ s{^(lib|cpan|dist|(?:symbian/)?ext|os2/OS2)/}{}
109                         and $1 ne 'lib'
110             and (
111             $module =~ s{\b(\w+)/\1\b}{$1},
112             $module =~ s{^B/O}{O},
113             $module =~ s{^Devel-PPPort}{Devel},
114             $module =~ s{^libnet/}{},
115             $module =~ s{^PathTools/}{},
116             $module =~ s{REXX/DLL}{DLL},
117             $module =~ s{^Encode/encoding}{encoding},
118             $module =~ s{^IPC-SysV/}{IPC/},
119             $module =~ s{^MIME-Base64/QuotedPrint}{MIME/QuotedPrint},
120             $module =~ s{^(?:DynaLoader|Errno|Opcode|XSLoader)/}{},
121             $module =~ s{^Sys-Syslog/win32}{Sys-Syslog},
122             $module =~ s{^Time-Piece/Seconds}{Time/Seconds},
123             );
124                 $module =~ s{^lib/}{}g;
125         $module =~ s{/}{::}g;
126         $module =~ s{-}{::}g;
127                 $module =~ s{^.*::lib::}{}; # turns Foo/lib/Foo.pm into Foo.pm
128         $module =~ s/(\.pm|_pm\.PL)$//;
129         $lines{$module}          = $version;
130         $module_to_file{$module} = $File::Find::name;
131     },
132     'os2/OS2',
133     'symbian/ext',
134     'lib',
135     'ext',
136         'cpan',
137         'dist'
138 );
139
140 -e 'configpm' and $lines{Config} = "$]";
141
142 if ( open my $ucdv, "<", "lib/unicore/version" ) {
143     chomp( my $ucd = <$ucdv> );
144     $lines{Unicode} = "'$ucd'";
145     close $ucdv;
146 }
147
148 my $delta_data = make_corelist_delta(
149   $perl_vnum,
150   \%lines,
151   \%Module::CoreList::version
152 );
153
154 my $versions_in_release = "    " . $perl_vnum . " => {\n";
155 $versions_in_release .= "        delta_from => $delta_data->{delta_from},\n";
156 $versions_in_release .= "        changed => {\n";
157 foreach my $key (sort keys $delta_data->{changed}->%*) {
158   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
159       defined $delta_data->{changed}{$key} ? "'"
160         . $delta_data->{changed}{$key} . "'" : "undef";
161 }
162 $versions_in_release .= "        },\n";
163 $versions_in_release .= "        removed => {\n";
164 for my $key (sort keys %{ $delta_data->{removed} || {} }) {
165   $versions_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
166 }
167 $versions_in_release .= "        }\n";
168 $versions_in_release .= "    },\n";
169
170 $corelist =~ s/^(%delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
171 $corelist =~ s/^(%delta\s*=\s*.*?)(^\);)$/$1$versions_in_release$2/ism;
172
173 exit unless %modlist;
174
175 # We have to go through this two stage lookup, given how Maintainers.pl keys its
176 # data by "Module", which is really a dist.
177 my $file_to_M = files_to_modules( values %module_to_file );
178
179 sub slurp_utf8($) {
180     open my $fh, "<:utf8", "$_[0]"
181         or die "can't open $_[0] for reading: $!";
182     return do { local $/; <$fh> };
183 }
184
185 sub parse_cpan_meta($) {
186     return Parse::CPAN::Meta->${
187         $_[0] =~ /\A\x7b/ ? \"load_json_string" : \"load_yaml_string"
188     }($_[0]);
189 }
190
191 my %module_to_upstream;
192 my %module_to_dist;
193 my %dist_to_meta_YAML;
194 my %module_to_deprecated;
195 while ( my ( $module, $file ) = each %module_to_file ) {
196     my $M = $file_to_M->{$file};
197     next unless $M;
198     next if $Modules{$M}{MAINTAINER} && $Modules{$M}{MAINTAINER} eq 'P5P';
199     $module_to_upstream{$module} = $Modules{$M}{UPSTREAM};
200     $module_to_deprecated{$module} = 1 if $Modules{$M}{DEPRECATED};
201     next
202         if defined $module_to_upstream{$module}
203             && $module_to_upstream{$module} eq 'blead';
204     my $dist = $modlist{$module};
205     unless ($dist) {
206         warn "Can't find a distribution for $module\n";
207         next;
208     }
209     $module_to_dist{$module} = $dist;
210
211     next if exists $dist_to_meta_YAML{$dist};
212
213     $dist_to_meta_YAML{$dist} = undef;
214
215     # Like it or lump it, this has to be Unix format.
216     my $meta_YAML_path = "authors/id/$dist";
217     $meta_YAML_path =~ s/(?:tar\.gz|tar\.bz2|zip|tgz)$/meta/
218         or die "ERROR: bad meta YAML path: '$meta_YAML_path'";
219     my $meta_YAML_url = 'http://ftp.funet.fi/pub/CPAN/' . $meta_YAML_path;
220
221     if ( -e "$cpan/$meta_YAML_path" ) {
222         $dist_to_meta_YAML{$dist} = parse_cpan_meta(slurp_utf8( $cpan . "/" . $meta_YAML_path ));
223     } elsif ( my $content = fetch_url($meta_YAML_url) ) {
224         unless ($content) {
225             warn "Failed to fetch $meta_YAML_url\n";
226             next;
227         }
228         eval { $dist_to_meta_YAML{$dist} = parse_cpan_meta($content); };
229         if ( my $err = $@ ) {
230             warn "$meta_YAML_path: ".$err;
231             next;
232         }
233     } else {
234         warn "$meta_YAML_path does not exist for $module\n";
235
236         # I tried code to open the tarballs with Archive::Tar to find and
237         # extract META.yml, but only Text-Tabs+Wrap-2006.1117.tar.gz had one,
238         # so it's not worth including.
239         next;
240     }
241 }
242
243 my $upstream_stanza = "%upstream = (\n";
244 foreach my $module ( sort keys %module_to_upstream ) {
245     my $upstream = defined $module_to_upstream{$module} ? "'$module_to_upstream{$module}'" : 'undef';
246     $upstream_stanza .= sprintf "    %-24s=> %s,\n", "'$module'", $upstream;
247 }
248 $upstream_stanza .= ");";
249
250 $corelist =~ s/^%upstream .*? ;$/$upstream_stanza/ismx;
251
252 # Deprecation generation
253 {
254   my $delta_data = make_corelist_delta(
255     $perl_vnum,
256     \%module_to_deprecated,
257     do { no warnings 'once'; \%Module::CoreList::deprecated },
258   );
259
260   my $deprecated_stanza = "    " . $perl_vnum . " => {\n";
261   $deprecated_stanza .= "        delta_from => $delta_data->{delta_from},\n";
262   $deprecated_stanza .= "        changed => {\n";
263   foreach my $key (sort keys $delta_data->{changed}->%*) {
264     $deprecated_stanza .= sprintf "            %-24s=> %s,\n", "'$key'",
265         defined $delta_data->{changed}{$key} ? "'"
266           . $delta_data->{changed}{$key} . "'" : "undef";
267   }
268   $deprecated_stanza .= "        },\n";
269   $deprecated_stanza .= "        removed => {\n";
270   for my $key (sort keys %{ $delta_data->{removed} || {} }) {
271     $deprecated_stanza .= sprintf "           %-24s=> %s,\n", "'$key'", 1;
272   }
273   $deprecated_stanza .= "        }\n";
274   $deprecated_stanza .= "    },\n";
275
276   $corelist =~ s/^(%deprecated\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
277   $corelist =~ s/^(%deprecated\s*=\s*.*?)(^\);)$/$1$deprecated_stanza$2/xism;
278 }
279
280 my $tracker = "%bug_tracker = (\n";
281 foreach my $module ( sort keys %module_to_upstream ) {
282     my $upstream = defined $module_to_upstream{$module};
283     next
284         if defined $upstream and $upstream eq 'blead';
285
286     my $bug_tracker;
287
288     my $dist = $module_to_dist{$module};
289     $bug_tracker = $dist_to_meta_YAML{$dist}->{resources}{bugtracker}
290         if $dist;
291     $bug_tracker = $bug_tracker->{web} if ref($bug_tracker) eq "HASH";
292
293     $bug_tracker = defined $bug_tracker ? quote($bug_tracker) : 'undef';
294         next if $bug_tracker eq "'http://rt.perl.org/perlbug/'";
295     $tracker .= sprintf "    %-24s=> %s,\n", "'$module'", $bug_tracker;
296 }
297 $tracker .= ");";
298
299 $corelist =~ s/^%bug_tracker .*? ;/$tracker/eismx;
300
301 write_corelist($corelist,$corelist_file);
302
303 open( my $utils_fh, '<', $utils_file );
304 my $utils = join( '', <$utils_fh> );
305 close $utils_fh;
306
307 my %utils = map { ( $_ => 1 ) } parse_utils_lst();
308
309 my $delta_utils = make_coreutils_delta($perl_vnum, \%utils);
310
311 my $utilities_in_release = "    " . $perl_vnum . " => {\n";
312 $utilities_in_release .= "        delta_from => $delta_utils->{delta_from},\n";
313 $utilities_in_release .= "        changed => {\n";
314 foreach my $key (sort keys $delta_utils->{changed}->%*) {
315   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'",
316       defined $delta_utils->{changed}{$key} ? "'"
317         . $delta_utils->{changed}{$key} . "'" : "undef";
318 }
319 $utilities_in_release .= "        },\n";
320 $utilities_in_release .= "        removed => {\n";
321 for my $key (sort keys %{ $delta_utils->{removed} || {} }) {
322   $utilities_in_release .= sprintf "            %-24s=> %s,\n", "'$key'", 1;
323 }
324 $utilities_in_release .= "        }\n";
325 $utilities_in_release .= "    },\n";
326
327 $utils =~ s/^(my %delta\s*=\s*.*?)^\s*$perl_vnum\s*=>\s*{.*?},\s*(^\);)$/$1$2/ism;
328 $utils =~ s/^(my %delta\s*=\s*.*?)(^\);)$/$1$utilities_in_release$2/ism;
329
330 write_corelist($utils,$utils_file);
331
332 warn "All done. Please check over the following files carefully before committing.\nThanks!\n";
333 warn "$corelist_file\n$utils_file\n";
334
335 sub write_corelist {
336     my $content = shift;
337     my $filename = shift;
338     open (my $clfh, ">", $filename);
339     binmode $clfh;
340     print $clfh $content;
341     close($clfh);
342 }
343
344 sub fetch_url {
345     my $url = shift;
346     my $http = HTTP::Tiny->new;
347     my $response = $http->get($url);
348     if ($response->{success}) {
349         return $response->{content};
350     } else {
351         warn "Error fetching $url: $response->{status} $response->{reason}\n";
352         return;
353     }
354 }
355
356 sub make_corelist_delta {
357   my($version, $lines, $existing) = @_;
358   # Trust core perl, if someone does use a weird version number the worst that
359   # can happen is an extra delta entry for a module.
360   my %versions = map { $_ => eval $lines->{$_} } keys %$lines;
361
362   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
363   require $corelist_file;
364
365   my %deltas;
366   # Search for the release with the least amount of changes (this avoids having
367   # to ask for where this perl was branched from).
368   for my $previous (reverse sort { $a <=> $b } keys %$existing) {
369     # Shouldn't happen, but ensure we don't load weird data...
370     next if $previous > $version || $previous == $version;
371     my $delta = $deltas{$previous} = {};
372     ($delta->{changed}, $delta->{removed}) = calculate_delta(
373       $existing->{$previous}, \%versions);
374   }
375
376   my $smallest = (sort {
377       ((keys($deltas{$a}->{changed}->%*) + keys($deltas{$a}->{removed}->%*)) <=>
378        (keys($deltas{$b}->{changed}->%*) + keys($deltas{$b}->{removed}->%*))) ||
379       $b <=> $a
380     } keys %deltas)[0];
381
382   return {
383     delta_from => $smallest,
384     changed => $deltas{$smallest}{changed},
385     removed => $deltas{$smallest}{removed},
386   }
387 }
388
389 sub make_coreutils_delta {
390   my($version, $lines) = @_;
391   # Trust core perl, if someone does use a weird version number the worst that
392   # can happen is an extra delta entry for a module.
393   my %utilities = map { $_ => eval $lines->{$_} } keys %$lines;
394
395   # Ensure we have the corelist data loaded from this perl checkout, not the system one.
396   require $utils_file;
397
398   my %deltas;
399   # Search for the release with the least amount of changes (this avoids having
400   # to ask for where this perl was branched from).
401   for my $previous (reverse sort { $a <=> $b } keys %Module::CoreList::Utils::utilities) {
402     # Shouldn't happen, but ensure we don't load weird data...
403     next if $previous > $version || $previous == $version;
404
405     my $delta = $deltas{$previous} = {};
406     ($delta->{changed}, $delta->{removed}) = calculate_delta(
407       $Module::CoreList::Utils::utilities{$previous}, \%utilities);
408   }
409
410   my $smallest = (sort {
411       ((keys($deltas{$a}->{changed}->%*) + keys($deltas{$a}->{removed}->%*)) <=>
412        (keys($deltas{$b}->{changed}->%*) + keys($deltas{$b}->{removed}->%*))) ||
413       $b <=> $a
414     } keys %deltas)[0];
415
416   return {
417     delta_from => $smallest,
418     changed => $deltas{$smallest}{changed},
419     removed => $deltas{$smallest}{removed},
420   }
421 }
422
423 # Calculate (changed, removed) modules between two versions.
424 sub calculate_delta {
425   my($from, $to) = @_;
426   my(%changed, %removed);
427
428   for my $package(keys %$from) {
429     if(not exists $to->{$package}) {
430       $removed{$package} = 1;
431     }
432   }
433
434   for my $package(keys %$to) {
435     if(!exists $from->{$package}
436         || (defined $from->{$package} && !defined $to->{$package})
437         || (!defined $from->{$package} && defined $to->{$package})
438         || (defined $from->{$package} && defined $to->{$package}
439             && $from->{$package} ne $to->{$package})) {
440       $changed{$package} = $to->{$package};
441     }
442   }
443
444   return \%changed, \%removed;
445 }
446
447 sub quote {
448     my ($str) = @_;
449     # There's gotta be something already doing this properly that we could just
450     # reuse, but I can't quite thing of where to look for it, so I'm gonna do
451     # the simplest possible thing that'll allow me to release 5.17.7.  --rafl
452     $str =~ s/'/\\'/g;
453     "'${str}'";
454 }
455
456 sub parse_utils_lst {
457   require File::Spec::Unix;
458   my @scripts;
459   open my $fh, '<', 'utils.lst' or die "$!\n";
460   while (<$fh>) {
461     chomp;
462     my ($file,$extra) = split m!#!;
463     $file =~ s!\s+!!g;
464     push @scripts, $file;
465     $extra =~ s!\s+!!g if $extra;
466     if ( $extra and my ($link) = $extra =~ m!^link=(.+?)$! ) {
467       push @scripts, $link;
468     }
469   }
470   return map { +( File::Spec::Unix->splitpath( $_ ) )[-1] } @scripts;
471 }