Move OP prototypes from pp_proto.h to proto.h
[perl.git] / opcode.pl
1 #!/usr/bin/perl -w
2
3 # Regenerate (overwriting only if changed):
4 #
5 #    opcode.h
6 #    opnames.h
7 #    pp.sym
8 #
9 # from information stored in the DATA section of this file, plus the
10 # values hardcoded into this script in @raw_alias.
11 #
12 # Accepts the standard regen_lib -q and -v args.
13 #
14 # This script is normally invoked from regen.pl.
15
16 use strict;
17
18 BEGIN {
19     # Get function prototypes
20     require 'regen_lib.pl';
21 }
22
23 my $opcode_new = 'opcode.h-new';
24 my $opname_new = 'opnames.h-new';
25 my $oc = safer_open($opcode_new);
26 my $on = safer_open($opname_new);
27 select $oc;
28
29 # Read data.
30
31 my %seen;
32 my (@ops, %desc, %check, %ckname, %flags, %args, %opnum);
33
34 while (<DATA>) {
35     chop;
36     next unless $_;
37     next if /^#/;
38     my ($key, $desc, $check, $flags, $args) = split(/\t+/, $_, 5);
39     $args = '' unless defined $args;
40
41     warn qq[Description "$desc" duplicates $seen{$desc}\n] if $seen{$desc};
42     die qq[Opcode "$key" duplicates $seen{$key}\n] if $seen{$key};
43     $seen{$desc} = qq[description of opcode "$key"];
44     $seen{$key} = qq[opcode "$key"];
45
46     push(@ops, $key);
47     $opnum{$key} = $#ops;
48     $desc{$key} = $desc;
49     $check{$key} = $check;
50     $ckname{$check}++;
51     $flags{$key} = $flags;
52     $args{$key} = $args;
53 }
54
55 # Set up aliases
56
57 my %alias;
58
59 # Format is "this function" => "does these op names"
60 my @raw_alias = (
61                  Perl_do_kv => [qw( keys values )],
62                  Perl_unimplemented_op => [qw(padany mapstart custom)],
63                  # All the ops with a body of { return NORMAL; }
64                  Perl_pp_null => [qw(scalar regcmaybe lineseq scope)],
65
66                  Perl_pp_goto => ['dump'],
67                  Perl_pp_require => ['dofile'],
68                  Perl_pp_untie => ['dbmclose'],
69                  Perl_pp_sysread => [qw(read recv)],
70                  Perl_pp_sysseek => ['seek'],
71                  Perl_pp_ioctl => ['fcntl'],
72                  Perl_pp_ssockopt => ['gsockopt'],
73                  Perl_pp_getpeername => ['getsockname'],
74                  Perl_pp_stat => ['lstat'],
75                  Perl_pp_ftrowned => [qw(fteowned ftzero ftsock ftchr ftblk
76                                          ftfile ftdir ftpipe ftsuid ftsgid
77                                          ftsvtx)],
78                  Perl_pp_fttext => ['ftbinary'],
79                  Perl_pp_gmtime => ['localtime'],
80                  Perl_pp_semget => [qw(shmget msgget)],
81                  Perl_pp_semctl => [qw(shmctl msgctl)],
82                  Perl_pp_ghostent => [qw(ghbyname ghbyaddr)],
83                  Perl_pp_gnetent => [qw(gnbyname gnbyaddr)],
84                  Perl_pp_gprotoent => [qw(gpbyname gpbynumber)],
85                  Perl_pp_gservent => [qw(gsbyname gsbyport)],
86                  Perl_pp_gpwent => [qw(gpwnam gpwuid)],
87                  Perl_pp_ggrent => [qw(ggrnam ggrgid)],
88                  Perl_pp_ftis => [qw(ftsize ftmtime ftatime ftctime)],
89                  Perl_pp_chown => [qw(unlink chmod utime kill)],
90                  Perl_pp_link => ['symlink'],
91                  Perl_pp_ftrread => [qw(ftrwrite ftrexec fteread ftewrite
92                                         fteexec)],
93                  Perl_pp_shmwrite => [qw(shmread msgsnd msgrcv semop)],
94                  Perl_pp_send => ['syswrite'],
95                  Perl_pp_defined => [qw(dor dorassign)],
96                  Perl_pp_and => ['andassign'],
97                  Perl_pp_or => ['orassign'],
98                  Perl_pp_ucfirst => ['lcfirst'],
99                  Perl_pp_sle => [qw(slt sgt sge)],
100                  Perl_pp_print => ['say'],
101                  Perl_pp_index => ['rindex'],
102                  Perl_pp_oct => ['hex'],
103                  Perl_pp_shift => ['pop'],
104                  Perl_pp_sin => [qw(cos exp log sqrt)],
105                  Perl_pp_bit_or => ['bit_xor'],
106                  Perl_pp_rv2av => ['rv2hv'],
107                  Perl_pp_akeys => ['avalues'],
108                 );
109
110 while (my ($func, $names) = splice @raw_alias, 0, 2) {
111     foreach (@$names) {
112         $alias{$_} = $func;
113     }
114 }
115
116 # Emit defines.
117
118 print <<"END";
119 /* -*- buffer-read-only: t -*-
120  *
121  *    opcode.h
122  *
123  *    Copyright (C) 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
124  *    2001, 2002, 2003, 2004, 2005, 2006, 2007 by Larry Wall and others
125  *
126  *    You may distribute under the terms of either the GNU General Public
127  *    License or the Artistic License, as specified in the README file.
128  *
129  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
130  *  This file is built by opcode.pl from its data.  Any changes made here
131  *  will be lost!
132  */
133
134 #ifndef PERL_GLOBAL_STRUCT_INIT
135
136 #define Perl_pp_i_preinc Perl_pp_preinc
137 #define Perl_pp_i_predec Perl_pp_predec
138 #define Perl_pp_i_postinc Perl_pp_postinc
139 #define Perl_pp_i_postdec Perl_pp_postdec
140
141 PERL_PPDEF(Perl_unimplemented_op)
142
143 END
144
145 print $on <<"END";
146 /* -*- buffer-read-only: t -*-
147  *
148  *    opnames.h
149  *
150  *    Copyright (C) 1999, 2000, 2001, 2002, 2003, 2004, 2005, 2006,
151  *    2007, 2008 by Larry Wall and others
152  *
153  *    You may distribute under the terms of either the GNU General Public
154  *    License or the Artistic License, as specified in the README file.
155  *
156  *
157  * !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
158  *  This file is built by opcode.pl from its data.  Any changes made here
159  *  will be lost!
160  */
161
162 typedef enum opcode {
163 END
164
165 my $i = 0;
166 for (@ops) {
167     # print $on "\t", &tab(3,"OP_\U$_,"), "/* ", $i++, " */\n";
168       print $on "\t", &tab(3,"OP_\U$_"), " = ", $i++, ",\n";
169 }
170 print $on "\t", &tab(3,"OP_max"), "\n";
171 print $on "} opcode;\n";
172 print $on "\n#define MAXO ", scalar @ops, "\n";
173 print $on "#define OP_phoney_INPUT_ONLY -1\n";
174 print $on "#define OP_phoney_OUTPUT_ONLY -2\n\n";
175
176 # Emit op names and descriptions.
177
178 print <<END;
179 START_EXTERN_C
180
181 #define OP_NAME(o) ((o)->op_type == OP_CUSTOM ? custom_op_name(o) : \\
182                     PL_op_name[(o)->op_type])
183 #define OP_DESC(o) ((o)->op_type == OP_CUSTOM ? custom_op_desc(o) : \\
184                     PL_op_desc[(o)->op_type])
185
186 #ifndef DOINIT
187 EXTCONST char* const PL_op_name[];
188 #else
189 EXTCONST char* const PL_op_name[] = {
190 END
191
192 for (@ops) {
193     print qq(\t"$_",\n);
194 }
195
196 print <<END;
197 };
198 #endif
199
200 END
201
202 print <<END;
203 #ifndef DOINIT
204 EXTCONST char* const PL_op_desc[];
205 #else
206 EXTCONST char* const PL_op_desc[] = {
207 END
208
209 for (@ops) {
210     my($safe_desc) = $desc{$_};
211
212     # Have to escape double quotes and escape characters.
213     $safe_desc =~ s/([\\"])/\\$1/g;
214
215     print qq(\t"$safe_desc",\n);
216 }
217
218 print <<END;
219 };
220 #endif
221
222 END_EXTERN_C
223
224 #endif /* !PERL_GLOBAL_STRUCT_INIT */
225 END
226
227 # Emit function declarations.
228
229 #for (sort keys %ckname) {
230 #    print "OP *\t", &tab(3,$_),"(pTHX_ OP* o);\n";
231 #}
232 #
233 #print "\n";
234 #
235 #for (@ops) {
236 #    print "OP *\t", &tab(3, "pp_$_"), "(pTHX);\n";
237 #}
238
239 # Emit ppcode switch array.
240
241 print <<END;
242
243 START_EXTERN_C
244
245 #ifdef PERL_GLOBAL_STRUCT_INIT
246 #  define PERL_PPADDR_INITED
247 static const Perl_ppaddr_t Gppaddr[]
248 #else
249 #  ifndef PERL_GLOBAL_STRUCT
250 #    define PERL_PPADDR_INITED
251 EXT Perl_ppaddr_t PL_ppaddr[] /* or perlvars.h */
252 #  endif
253 #endif /* PERL_GLOBAL_STRUCT */
254 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
255 #  define PERL_PPADDR_INITED
256 = {
257 END
258
259 for (@ops) {
260     if (my $name = $alias{$_}) {
261         print "\tMEMBER_TO_FPTR($name),\t/* Perl_pp_$_ */\n";
262     }
263     else {
264         print "\tMEMBER_TO_FPTR(Perl_pp_$_),\n";
265     }
266 }
267
268 print <<END;
269 }
270 #endif
271 #ifdef PERL_PPADDR_INITED
272 ;
273 #endif
274
275 END
276
277 # Emit check routines.
278
279 print <<END;
280 #ifdef PERL_GLOBAL_STRUCT_INIT
281 #  define PERL_CHECK_INITED
282 static const Perl_check_t Gcheck[]
283 #else
284 #  ifndef PERL_GLOBAL_STRUCT
285 #    define PERL_CHECK_INITED
286 EXT Perl_check_t PL_check[] /* or perlvars.h */
287 #  endif
288 #endif
289 #if (defined(DOINIT) && !defined(PERL_GLOBAL_STRUCT)) || defined(PERL_GLOBAL_STRUCT_INIT)
290 #  define PERL_CHECK_INITED
291 = {
292 END
293
294 for (@ops) {
295     print "\t", &tab(3, "MEMBER_TO_FPTR(Perl_$check{$_}),"), "\t/* $_ */\n";
296 }
297
298 print <<END;
299 }
300 #endif
301 #ifdef PERL_CHECK_INITED
302 ;
303 #endif /* #ifdef PERL_CHECK_INITED */
304
305 END
306
307 # Emit allowed argument types.
308
309 my $ARGBITS = 32;
310
311 print <<END;
312 #ifndef PERL_GLOBAL_STRUCT_INIT
313
314 #ifndef DOINIT
315 EXTCONST U32 PL_opargs[];
316 #else
317 EXTCONST U32 PL_opargs[] = {
318 END
319
320 my %argnum = (
321     'S',  1,            # scalar
322     'L',  2,            # list
323     'A',  3,            # array value
324     'H',  4,            # hash value
325     'C',  5,            # code value
326     'F',  6,            # file value
327     'R',  7,            # scalar reference
328 );
329
330 my %opclass = (
331     '0',  0,            # baseop
332     '1',  1,            # unop
333     '2',  2,            # binop
334     '|',  3,            # logop
335     '@',  4,            # listop
336     '/',  5,            # pmop
337     '$',  6,            # svop_or_padop
338     '#',  7,            # padop
339     '"',  8,            # pvop_or_svop
340     '{',  9,            # loop
341     ';',  10,           # cop
342     '%',  11,           # baseop_or_unop
343     '-',  12,           # filestatop
344     '}',  13,           # loopexop
345 );
346
347 my %opflags = (
348     'm' =>   1,         # needs stack mark
349     'f' =>   2,         # fold constants
350     's' =>   4,         # always produces scalar
351     't' =>   8,         # needs target scalar
352     'T' =>   8 | 16,    # ... which may be lexical
353     'i' =>   0,         # always produces integer (unused since e7311069)
354     'I' =>  32,         # has corresponding int op
355     'd' =>  64,         # danger, unknown side effects
356     'u' => 128,         # defaults to $_
357 );
358
359 my %OP_IS_SOCKET;
360 my %OP_IS_FILETEST;
361 my %OP_IS_FT_ACCESS;
362 my $OCSHIFT = 8;
363 my $OASHIFT = 12;
364
365 for my $op (@ops) {
366     my $argsum = 0;
367     my $flags = $flags{$op};
368     for my $flag (keys %opflags) {
369         if ($flags =~ s/$flag//) {
370             die "Flag collision for '$op' ($flags{$op}, $flag)\n"
371                 if $argsum & $opflags{$flag};
372             $argsum |= $opflags{$flag};
373         }
374     }
375     die qq[Opcode '$op' has no class indicator ($flags{$op} => $flags)\n]
376         unless exists $opclass{$flags};
377     $argsum |= $opclass{$flags} << $OCSHIFT;
378     my $argshift = $OASHIFT;
379     for my $arg (split(' ',$args{$op})) {
380         if ($arg =~ /^F/) {
381             # record opnums of these opnames
382             $OP_IS_SOCKET{$op}   = $opnum{$op} if $arg =~ s/s//;
383             $OP_IS_FILETEST{$op} = $opnum{$op} if $arg =~ s/-//;
384             $OP_IS_FT_ACCESS{$op} = $opnum{$op} if $arg =~ s/\+//;
385         }
386         my $argnum = ($arg =~ s/\?//) ? 8 : 0;
387         die "op = $op, arg = $arg\n"
388             unless exists $argnum{$arg};
389         $argnum += $argnum{$arg};
390         die "Argument overflow for '$op'\n"
391             if $argshift >= $ARGBITS ||
392                $argnum > ((1 << ($ARGBITS - $argshift)) - 1);
393         $argsum += $argnum << $argshift;
394         $argshift += 4;
395     }
396     $argsum = sprintf("0x%08x", $argsum);
397     print "\t", &tab(3, "$argsum,"), "/* $op */\n";
398 }
399
400 print <<END;
401 };
402 #endif
403
404 #endif /* !PERL_GLOBAL_STRUCT_INIT */
405
406 END_EXTERN_C
407
408 END
409
410 # Emit OP_IS_* macros
411
412 print $on <<EO_OP_IS_COMMENT;
413
414 /* the OP_IS_(SOCKET|FILETEST) macros are optimized to a simple range
415     check because all the member OPs are contiguous in opcode.pl
416     <DATA> table.  opcode.pl verifies the range contiguity.  */
417
418 EO_OP_IS_COMMENT
419
420 gen_op_is_macro( \%OP_IS_SOCKET, 'OP_IS_SOCKET');
421 gen_op_is_macro( \%OP_IS_FILETEST, 'OP_IS_FILETEST');
422 gen_op_is_macro( \%OP_IS_FT_ACCESS, 'OP_IS_FILETEST_ACCESS');
423
424 sub gen_op_is_macro {
425     my ($op_is, $macname) = @_;
426     if (keys %$op_is) {
427         
428         # get opnames whose numbers are lowest and highest
429         my ($first, @rest) = sort {
430             $op_is->{$a} <=> $op_is->{$b}
431         } keys %$op_is;
432         
433         my $last = pop @rest;   # @rest slurped, get its last
434         die "Invalid range of ops: $first .. $last\n" unless $last;
435
436         print $on "#define $macname(op) \\\n\t(";
437
438         # verify that op-ct matches 1st..last range (and fencepost)
439         # (we know there are no dups)
440         if ( $op_is->{$last} - $op_is->{$first} == scalar @rest + 1) {
441             
442             # contiguous ops -> optimized version
443             print $on "(op) >= OP_" . uc($first) . " && (op) <= OP_" . uc($last);
444             print $on ")\n\n";
445         }
446         else {
447             print $on join(" || \\\n\t ",
448                           map { "(op) == OP_" . uc() } sort keys %$op_is);
449             print $on ")\n\n";
450         }
451     }
452 }
453
454 print $oc "/* ex: set ro: */\n";
455 print $on "/* ex: set ro: */\n";
456
457 safer_close($oc);
458 safer_close($on);
459
460 rename_if_different $opcode_new, 'opcode.h';
461 rename_if_different $opname_new, 'opnames.h';
462
463 my $pp_sym_new  = 'pp.sym-new';
464 my $ppsym = safer_open($pp_sym_new);
465
466 print $ppsym <<"END";
467 # -*- buffer-read-only: t -*-
468 #
469 # !!!!!!!   DO NOT EDIT THIS FILE   !!!!!!!
470 #   This file is built by opcode.pl from its data.  Any changes made here
471 #   will be lost!
472 #
473
474 END
475
476
477 for (sort keys %ckname) {
478     print $ppsym "Perl_$_\n";
479 #OP *\t", &tab(3,$_),"(OP* o);\n";
480 }
481
482 for (@ops) {
483     next if /^i_(pre|post)(inc|dec)$/;
484     next if /^custom$/;
485     print $ppsym "Perl_pp_$_\n";
486 }
487 print $ppsym "\n# ex: set ro:\n";
488
489 safer_close($ppsym);
490
491 rename_if_different $pp_sym_new, 'pp.sym';
492
493 END {
494   foreach ('opcode.h', 'opnames.h', 'pp.sym') {
495     1 while unlink "$_-old";
496   }
497 }
498
499 ###########################################################################
500 sub tab {
501     my ($l, $t) = @_;
502     $t .= "\t" x ($l - (length($t) + 1) / 8);
503     $t;
504 }
505 ###########################################################################
506
507 # Some comments about 'T' opcode classifier:
508
509 # Safe to set if the ppcode uses:
510 #       tryAMAGICbin, tryAMAGICun, SETn, SETi, SETu, PUSHn, PUSHTARG, SETTARG,
511 #       SETs(TARG), XPUSHn, XPUSHu,
512
513 # Unsafe to set if the ppcode uses dTARG or [X]RETPUSH[YES|NO|UNDEF]
514
515 # lt and friends do SETs (including ncmp, but not scmp)
516
517 # Additional mode of failure: the opcode can modify TARG before it "used"
518 # all the arguments (or may call an external function which does the same).
519 # If the target coincides with one of the arguments ==> kaboom.
520
521 # pp.c  pos substr each not OK (RETPUSHUNDEF)
522 #       substr vec also not OK due to LV to target (are they???)
523 #       ref not OK (RETPUSHNO)
524 #       trans not OK (dTARG; TARG = sv_newmortal();)
525 #       ucfirst etc not OK: TMP arg processed inplace
526 #       quotemeta not OK (unsafe when TARG == arg)
527 #       each repeat not OK too due to list context
528 #       pack split - unknown whether they are safe
529 #       sprintf: is calling do_sprintf(TARG,...) which can act on TARG
530 #         before other args are processed.
531
532 #       Suspicious wrt "additional mode of failure" (and only it):
533 #       schop, chop, postinc/dec, bit_and etc, negate, complement.
534
535 #       Also suspicious: 4-arg substr, sprintf, uc/lc (POK_only), reverse, pack.
536
537 #       substr/vec: doing TAINT_off()???
538
539 # pp_hot.c
540 #       readline - unknown whether it is safe
541 #       match subst not OK (dTARG)
542 #       grepwhile not OK (not always setting)
543 #       join not OK (unsafe when TARG == arg)
544
545 #       Suspicious wrt "additional mode of failure": concat (dealt with
546 #       in ck_sassign()), join (same).
547
548 # pp_ctl.c
549 #       mapwhile flip caller not OK (not always setting)
550
551 # pp_sys.c
552 #       backtick glob warn die not OK (not always setting)
553 #       warn not OK (RETPUSHYES)
554 #       open fileno getc sysread syswrite ioctl accept shutdown
555 #        ftsize(etc) readlink telldir fork alarm getlogin not OK (RETPUSHUNDEF)
556 #       umask select not OK (XPUSHs(&PL_sv_undef);)
557 #       fileno getc sysread syswrite tell not OK (meth("FILENO" "GETC"))
558 #       sselect shm* sem* msg* syscall - unknown whether they are safe
559 #       gmtime not OK (list context)
560
561 #       Suspicious wrt "additional mode of failure": warn, die, select.
562
563 __END__
564
565 # New ops always go at the end
566 # The restriction on having custom as the last op has been removed
567
568 # A recapitulation of the format of this file:
569 # The file consists of five columns: the name of the op, an English
570 # description, the name of the "check" routine used to optimize this
571 # operation, some flags, and a description of the operands.
572
573 # The flags consist of options followed by a mandatory op class signifier
574
575 # The classes are:
576 # baseop      - 0            unop     - 1            binop      - 2
577 # logop       - |            listop   - @            pmop       - /
578 # padop/svop  - $            padop    - # (unused)   loop       - {
579 # baseop/unop - %            loopexop - }            filestatop - -
580 # pvop/svop   - "            cop      - ;
581
582 # Other options are:
583 #   needs stack mark                    - m
584 #   needs constant folding              - f
585 #   produces a scalar                   - s
586 #   produces an integer                 - i
587 #   needs a target                      - t
588 #   target can be in a pad              - T
589 #   has a corresponding integer version - I
590 #   has side effects                    - d
591 #   uses $_ if no argument given        - u
592
593 # Values for the operands are:
594 # scalar      - S            list     - L            array     - A
595 # hash        - H            sub (CV) - C            file      - F
596 # socket      - Fs           filetest - F-           filetest_access - F-+
597
598 # reference - R
599 # "?" denotes an optional operand.
600
601 # Nothing.
602
603 null            null operation          ck_null         0       
604 stub            stub                    ck_null         0
605 scalar          scalar                  ck_fun          s%      S
606
607 # Pushy stuff.
608
609 pushmark        pushmark                ck_null         s0      
610 wantarray       wantarray               ck_null         is0     
611
612 const           constant item           ck_svconst      s$      
613
614 gvsv            scalar variable         ck_null         ds$     
615 gv              glob value              ck_null         ds$     
616 gelem           glob elem               ck_null         d2      S S
617 padsv           private variable        ck_null         ds0
618 padav           private array           ck_null         d0
619 padhv           private hash            ck_null         d0
620 padany          private value           ck_null         d0
621
622 pushre          push regexp             ck_null         d/
623
624 # References and stuff.
625
626 rv2gv           ref-to-glob cast        ck_rvconst      ds1     
627 rv2sv           scalar dereference      ck_rvconst      ds1     
628 av2arylen       array length            ck_null         is1     
629 rv2cv           subroutine dereference  ck_rvconst      d1
630 anoncode        anonymous subroutine    ck_anoncode     $       
631 prototype       subroutine prototype    ck_null         s%      S
632 refgen          reference constructor   ck_spair        m1      L
633 srefgen         single ref constructor  ck_null         fs1     S
634 ref             reference-type operator ck_fun          stu%    S?
635 bless           bless                   ck_fun          s@      S S?
636
637 # Pushy I/O.
638
639 backtick        quoted execution (``, qx)       ck_open         tu%     S?
640 # glob defaults its first arg to $_
641 glob            glob                    ck_glob         t@      S?
642 readline        <HANDLE>                ck_readline     t%      F?
643 rcatline        append I/O operator     ck_null         t$
644
645 # Bindable operators.
646
647 regcmaybe       regexp internal guard   ck_fun          s1      S
648 regcreset       regexp internal reset   ck_fun          s1      S
649 regcomp         regexp compilation      ck_null         s|      S
650 match           pattern match (m//)     ck_match        d/
651 qr              pattern quote (qr//)    ck_match        s/
652 subst           substitution (s///)     ck_match        dis/    S
653 substcont       substitution iterator   ck_null         dis|    
654 trans           transliteration (tr///) ck_match        is"     S
655
656 # Lvalue operators.
657 # sassign is special-cased for op class
658
659 sassign         scalar assignment       ck_sassign      s0
660 aassign         list assignment         ck_null         t2      L L
661
662 chop            chop                    ck_spair        mts%    L
663 schop           scalar chop             ck_null         stu%    S?
664 chomp           chomp                   ck_spair        mTs%    L
665 schomp          scalar chomp            ck_null         sTu%    S?
666 defined         defined operator        ck_defined      isu%    S?
667 undef           undef operator          ck_lfun         s%      S?
668 study           study                   ck_fun          su%     S?
669 pos             match position          ck_lfun         stu%    S?
670
671 preinc          preincrement (++)               ck_lfun         dIs1    S
672 i_preinc        integer preincrement (++)       ck_lfun         dis1    S
673 predec          predecrement (--)               ck_lfun         dIs1    S
674 i_predec        integer predecrement (--)       ck_lfun         dis1    S
675 postinc         postincrement (++)              ck_lfun         dIst1   S
676 i_postinc       integer postincrement (++)      ck_lfun         disT1   S
677 postdec         postdecrement (--)              ck_lfun         dIst1   S
678 i_postdec       integer postdecrement (--)      ck_lfun         disT1   S
679
680 # Ordinary operators.
681
682 pow             exponentiation (**)     ck_null         fsT2    S S
683
684 multiply        multiplication (*)      ck_null         IfsT2   S S
685 i_multiply      integer multiplication (*)      ck_null         ifsT2   S S
686 divide          division (/)            ck_null         IfsT2   S S
687 i_divide        integer division (/)    ck_null         ifsT2   S S
688 modulo          modulus (%)             ck_null         IifsT2  S S
689 i_modulo        integer modulus (%)     ck_null         ifsT2   S S
690 repeat          repeat (x)              ck_repeat       mt2     L S
691
692 add             addition (+)            ck_null         IfsT2   S S
693 i_add           integer addition (+)    ck_null         ifsT2   S S
694 subtract        subtraction (-)         ck_null         IfsT2   S S
695 i_subtract      integer subtraction (-) ck_null         ifsT2   S S
696 concat          concatenation (.) or string     ck_concat       fsT2    S S
697 stringify       string                  ck_fun          fsT@    S
698
699 left_shift      left bitshift (<<)      ck_bitop        fsT2    S S
700 right_shift     right bitshift (>>)     ck_bitop        fsT2    S S
701
702 lt              numeric lt (<)          ck_null         Iifs2   S S
703 i_lt            integer lt (<)          ck_null         ifs2    S S
704 gt              numeric gt (>)          ck_null         Iifs2   S S
705 i_gt            integer gt (>)          ck_null         ifs2    S S
706 le              numeric le (<=)         ck_null         Iifs2   S S
707 i_le            integer le (<=)         ck_null         ifs2    S S
708 ge              numeric ge (>=)         ck_null         Iifs2   S S
709 i_ge            integer ge (>=)         ck_null         ifs2    S S
710 eq              numeric eq (==)         ck_null         Iifs2   S S
711 i_eq            integer eq (==)         ck_null         ifs2    S S
712 ne              numeric ne (!=)         ck_null         Iifs2   S S
713 i_ne            integer ne (!=)         ck_null         ifs2    S S
714 ncmp            numeric comparison (<=>)        ck_null         Iifst2  S S
715 i_ncmp          integer comparison (<=>)        ck_null         ifst2   S S
716
717 slt             string lt               ck_null         ifs2    S S
718 sgt             string gt               ck_null         ifs2    S S
719 sle             string le               ck_null         ifs2    S S
720 sge             string ge               ck_null         ifs2    S S
721 seq             string eq               ck_null         ifs2    S S
722 sne             string ne               ck_null         ifs2    S S
723 scmp            string comparison (cmp) ck_null         ifst2   S S
724
725 bit_and         bitwise and (&)         ck_bitop        fst2    S S
726 bit_xor         bitwise xor (^)         ck_bitop        fst2    S S
727 bit_or          bitwise or (|)          ck_bitop        fst2    S S
728
729 negate          negation (-)            ck_null         Ifst1   S
730 i_negate        integer negation (-)    ck_null         ifsT1   S
731 not             not                     ck_null         ifs1    S
732 complement      1's complement (~)      ck_bitop        fst1    S
733
734 smartmatch      smart match             ck_smartmatch   s2
735
736 # High falutin' math.
737
738 atan2           atan2                   ck_fun          fsT@    S S
739 sin             sin                     ck_fun          fsTu%   S?
740 cos             cos                     ck_fun          fsTu%   S?
741 rand            rand                    ck_fun          sT%     S?
742 srand           srand                   ck_fun          sT%     S?
743 exp             exp                     ck_fun          fsTu%   S?
744 log             log                     ck_fun          fsTu%   S?
745 sqrt            sqrt                    ck_fun          fsTu%   S?
746
747 # Lowbrow math.
748
749 int             int                     ck_fun          fsTu%   S?
750 hex             hex                     ck_fun          fsTu%   S?
751 oct             oct                     ck_fun          fsTu%   S?
752 abs             abs                     ck_fun          fsTu%   S?
753
754 # String stuff.
755
756 length          length                  ck_fun          ifsTu%  S?
757 substr          substr                  ck_substr       st@     S S S? S?
758 vec             vec                     ck_fun          ist@    S S S
759
760 index           index                   ck_index        isT@    S S S?
761 rindex          rindex                  ck_index        isT@    S S S?
762
763 sprintf         sprintf                 ck_fun          fmst@   S L
764 formline        formline                ck_fun          ms@     S L
765 ord             ord                     ck_fun          ifsTu%  S?
766 chr             chr                     ck_fun          fsTu%   S?
767 crypt           crypt                   ck_fun          fsT@    S S
768 ucfirst         ucfirst                 ck_fun          fstu%   S?
769 lcfirst         lcfirst                 ck_fun          fstu%   S?
770 uc              uc                      ck_fun          fstu%   S?
771 lc              lc                      ck_fun          fstu%   S?
772 quotemeta       quotemeta               ck_fun          fstu%   S?
773
774 # Arrays.
775
776 rv2av           array dereference       ck_rvconst      dt1     
777 aelemfast       constant array element  ck_null         s$      A S
778 aelem           array element           ck_null         s2      A S
779 aslice          array slice             ck_null         m@      A L
780
781 aeach           each on array           ck_each         %       A
782 akeys           keys on array           ck_each         t%      A
783 avalues         values on array         ck_each         t%      A
784
785 # Hashes.
786
787 each            each                    ck_each         %       H
788 values          values                  ck_each         t%      H
789 keys            keys                    ck_each         t%      H
790 delete          delete                  ck_delete       %       S
791 exists          exists                  ck_exists       is%     S
792 rv2hv           hash dereference        ck_rvconst      dt1     
793 helem           hash element            ck_null         s2      H S
794 hslice          hash slice              ck_null         m@      H L
795 boolkeys        boolkeys                ck_fun          %       H
796
797 # Explosives and implosives.
798
799 unpack          unpack                  ck_unpack       @       S S?
800 pack            pack                    ck_fun          mst@    S L
801 split           split                   ck_split        t@      S S S
802 join            join or string          ck_join         mst@    S L
803
804 # List operators.
805
806 list            list                    ck_null         m@      L
807 lslice          list slice              ck_null         2       H L L
808 anonlist        anonymous list ([])     ck_fun          ms@     L
809 anonhash        anonymous hash ({})     ck_fun          ms@     L
810
811 splice          splice                  ck_fun          m@      A S? S? L
812 push            push                    ck_fun          imsT@   A L
813 pop             pop                     ck_shift        s%      A?
814 shift           shift                   ck_shift        s%      A?
815 unshift         unshift                 ck_fun          imsT@   A L
816 sort            sort                    ck_sort         dm@     C? L
817 reverse         reverse                 ck_fun          mt@     L
818
819 grepstart       grep                    ck_grep         dm@     C L
820 grepwhile       grep iterator           ck_null         dt|     
821
822 mapstart        map                     ck_grep         dm@     C L
823 mapwhile        map iterator            ck_null         dt|
824
825 # Range stuff.
826
827 range           flipflop                ck_null         |       S S
828 flip            range (or flip)         ck_null         1       S S
829 flop            range (or flop)         ck_null         1
830
831 # Control.
832
833 and             logical and (&&)                ck_null         |       
834 or              logical or (||)                 ck_null         |       
835 xor             logical xor                     ck_null         fs2     S S     
836 dor             defined or (//)                 ck_null         |
837 cond_expr       conditional expression          ck_null         d|      
838 andassign       logical and assignment (&&=)    ck_null         s|      
839 orassign        logical or assignment (||=)     ck_null         s|      
840 dorassign       defined or assignment (//=)     ck_null         s|
841
842 method          method lookup           ck_method       d1
843 entersub        subroutine entry        ck_subr         dmt1    L
844 leavesub        subroutine exit         ck_null         1       
845 leavesublv      lvalue subroutine return        ck_null         1       
846 caller          caller                  ck_fun          t%      S?
847 warn            warn                    ck_fun          imst@   L
848 die             die                     ck_die          dimst@  L
849 reset           symbol reset            ck_fun          is%     S?
850
851 lineseq         line sequence           ck_null         @       
852 nextstate       next statement          ck_null         s;      
853 dbstate         debug next statement    ck_null         s;      
854 unstack         iteration finalizer     ck_null         s0
855 enter           block entry             ck_null         0       
856 leave           block exit              ck_null         @       
857 scope           block                   ck_null         @       
858 enteriter       foreach loop entry      ck_null         d{      
859 iter            foreach loop iterator   ck_null         0       
860 enterloop       loop entry              ck_null         d{      
861 leaveloop       loop exit               ck_null         2       
862 return          return                  ck_return       dm@     L
863 last            last                    ck_null         ds}     
864 next            next                    ck_null         ds}     
865 redo            redo                    ck_null         ds}     
866 dump            dump                    ck_null         ds}     
867 goto            goto                    ck_null         ds}     
868 exit            exit                    ck_exit         ds%     S?
869 method_named    method with known name  ck_null         d$
870
871 entergiven      given()                 ck_null         d|
872 leavegiven      leave given block       ck_null         1
873 enterwhen       when()                  ck_null         d|
874 leavewhen       leave when block        ck_null         1
875 break           break                   ck_null         0
876 continue        continue                ck_null         0
877
878 # I/O.
879
880 open            open                    ck_open         ismt@   F S? L
881 close           close                   ck_fun          is%     F?
882 pipe_op         pipe                    ck_fun          is@     F F
883
884 fileno          fileno                  ck_fun          ist%    F
885 umask           umask                   ck_fun          ist%    S?
886 binmode         binmode                 ck_fun          s@      F S?
887
888 tie             tie                     ck_fun          idms@   R S L
889 untie           untie                   ck_fun          is%     R
890 tied            tied                    ck_fun          s%      R
891 dbmopen         dbmopen                 ck_fun          is@     H S S
892 dbmclose        dbmclose                ck_fun          is%     H
893
894 sselect         select system call      ck_select       t@      S S S S
895 select          select                  ck_select       st@     F?
896
897 getc            getc                    ck_eof          st%     F?
898 read            read                    ck_fun          imst@   F R S S?
899 enterwrite      write                   ck_fun          dis%    F?
900 leavewrite      write exit              ck_null         1       
901
902 prtf            printf                  ck_listiob      ims@    F? L
903 print           print                   ck_listiob      ims@    F? L
904 say             say                     ck_listiob      ims@    F? L
905
906 sysopen         sysopen                 ck_fun          s@      F S S S?
907 sysseek         sysseek                 ck_fun          s@      F S S
908 sysread         sysread                 ck_fun          imst@   F R S S?
909 syswrite        syswrite                ck_fun          imst@   F S S? S?
910
911 eof             eof                     ck_eof          is%     F?
912 tell            tell                    ck_fun          st%     F?
913 seek            seek                    ck_fun          s@      F S S
914 # truncate really behaves as if it had both "S S" and "F S"
915 truncate        truncate                ck_trunc        is@     S S
916
917 fcntl           fcntl                   ck_fun          st@     F S S
918 ioctl           ioctl                   ck_fun          st@     F S S
919 flock           flock                   ck_fun          isT@    F S
920
921 # Sockets.  OP_IS_SOCKET wants them consecutive (so moved 1st 2)
922
923 send            send                    ck_fun          imst@   Fs S S S?
924 recv            recv                    ck_fun          imst@   Fs R S S
925
926 socket          socket                  ck_fun          is@     Fs S S S
927 sockpair        socketpair              ck_fun          is@     Fs Fs S S S
928
929 bind            bind                    ck_fun          is@     Fs S
930 connect         connect                 ck_fun          is@     Fs S
931 listen          listen                  ck_fun          is@     Fs S
932 accept          accept                  ck_fun          ist@    Fs Fs
933 shutdown        shutdown                ck_fun          ist@    Fs S
934
935 gsockopt        getsockopt              ck_fun          is@     Fs S S
936 ssockopt        setsockopt              ck_fun          is@     Fs S S S
937
938 getsockname     getsockname             ck_fun          is%     Fs
939 getpeername     getpeername             ck_fun          is%     Fs
940
941 # Stat calls.  OP_IS_FILETEST wants them consecutive.
942
943 lstat           lstat                   ck_ftst         u-      F
944 stat            stat                    ck_ftst         u-      F
945 ftrread         -R                      ck_ftst         isu-    F-+
946 ftrwrite        -W                      ck_ftst         isu-    F-+
947 ftrexec         -X                      ck_ftst         isu-    F-+
948 fteread         -r                      ck_ftst         isu-    F-+
949 ftewrite        -w                      ck_ftst         isu-    F-+
950 fteexec         -x                      ck_ftst         isu-    F-+
951 ftis            -e                      ck_ftst         isu-    F-
952 ftsize          -s                      ck_ftst         istu-   F-
953 ftmtime         -M                      ck_ftst         stu-    F-
954 ftatime         -A                      ck_ftst         stu-    F-
955 ftctime         -C                      ck_ftst         stu-    F-
956 ftrowned        -O                      ck_ftst         isu-    F-
957 fteowned        -o                      ck_ftst         isu-    F-
958 ftzero          -z                      ck_ftst         isu-    F-
959 ftsock          -S                      ck_ftst         isu-    F-
960 ftchr           -c                      ck_ftst         isu-    F-
961 ftblk           -b                      ck_ftst         isu-    F-
962 ftfile          -f                      ck_ftst         isu-    F-
963 ftdir           -d                      ck_ftst         isu-    F-
964 ftpipe          -p                      ck_ftst         isu-    F-
965 ftsuid          -u                      ck_ftst         isu-    F-
966 ftsgid          -g                      ck_ftst         isu-    F-
967 ftsvtx          -k                      ck_ftst         isu-    F-
968 ftlink          -l                      ck_ftst         isu-    F-
969 fttty           -t                      ck_ftst         is-     F-
970 fttext          -T                      ck_ftst         isu-    F-
971 ftbinary        -B                      ck_ftst         isu-    F-
972
973 # File calls.
974
975 # chdir really behaves as if it had both "S?" and "F?"
976 chdir           chdir                   ck_chdir        isT%    S?
977 chown           chown                   ck_fun          imsT@   L
978 chroot          chroot                  ck_fun          isTu%   S?
979 unlink          unlink                  ck_fun          imsTu@  L
980 chmod           chmod                   ck_fun          imsT@   L
981 utime           utime                   ck_fun          imsT@   L
982 rename          rename                  ck_fun          isT@    S S
983 link            link                    ck_fun          isT@    S S
984 symlink         symlink                 ck_fun          isT@    S S
985 readlink        readlink                ck_fun          stu%    S?
986 mkdir           mkdir                   ck_fun          isTu@   S? S?
987 rmdir           rmdir                   ck_fun          isTu%   S?
988
989 # Directory calls.
990
991 open_dir        opendir                 ck_fun          is@     F S
992 readdir         readdir                 ck_fun          %       F
993 telldir         telldir                 ck_fun          st%     F
994 seekdir         seekdir                 ck_fun          s@      F S
995 rewinddir       rewinddir               ck_fun          s%      F
996 closedir        closedir                ck_fun          is%     F
997
998 # Process control.
999
1000 fork            fork                    ck_null         ist0    
1001 wait            wait                    ck_null         isT0    
1002 waitpid         waitpid                 ck_fun          isT@    S S
1003 system          system                  ck_exec         imsT@   S? L
1004 exec            exec                    ck_exec         dimsT@  S? L
1005 kill            kill                    ck_fun          dimsT@  L
1006 getppid         getppid                 ck_null         isT0    
1007 getpgrp         getpgrp                 ck_fun          isT%    S?
1008 setpgrp         setpgrp                 ck_fun          isT@    S? S?
1009 getpriority     getpriority             ck_fun          isT@    S S
1010 setpriority     setpriority             ck_fun          isT@    S S S
1011
1012 # Time calls.
1013
1014 # NOTE: MacOS patches the 'i' of time() away later when the interpreter
1015 # is created because in MacOS time() is already returning times > 2**31-1,
1016 # that is, non-integers.
1017
1018 time            time                    ck_null         isT0    
1019 tms             times                   ck_null         0       
1020 localtime       localtime               ck_fun          t%      S?
1021 gmtime          gmtime                  ck_fun          t%      S?
1022 alarm           alarm                   ck_fun          istu%   S?
1023 sleep           sleep                   ck_fun          isT%    S?
1024
1025 # Shared memory.
1026
1027 shmget          shmget                  ck_fun          imst@   S S S
1028 shmctl          shmctl                  ck_fun          imst@   S S S
1029 shmread         shmread                 ck_fun          imst@   S S S S
1030 shmwrite        shmwrite                ck_fun          imst@   S S S S
1031
1032 # Message passing.
1033
1034 msgget          msgget                  ck_fun          imst@   S S
1035 msgctl          msgctl                  ck_fun          imst@   S S S
1036 msgsnd          msgsnd                  ck_fun          imst@   S S S
1037 msgrcv          msgrcv                  ck_fun          imst@   S S S S S
1038
1039 # Semaphores.
1040
1041 semop           semop                   ck_fun          imst@   S S
1042 semget          semget                  ck_fun          imst@   S S S
1043 semctl          semctl                  ck_fun          imst@   S S S S
1044
1045 # Eval.
1046
1047 require         require                 ck_require      du%     S?
1048 dofile          do "file"               ck_fun          d1      S
1049 hintseval       eval hints              ck_svconst      s$
1050 entereval       eval "string"           ck_eval         d%      S
1051 leaveeval       eval "string" exit      ck_null         1       S
1052 #evalonce       eval constant string    ck_null         d1      S
1053 entertry        eval {block}            ck_eval         d%      
1054 leavetry        eval {block} exit       ck_null         @       
1055
1056 # Get system info.
1057
1058 ghbyname        gethostbyname           ck_fun          %       S
1059 ghbyaddr        gethostbyaddr           ck_fun          @       S S
1060 ghostent        gethostent              ck_null         0       
1061 gnbyname        getnetbyname            ck_fun          %       S
1062 gnbyaddr        getnetbyaddr            ck_fun          @       S S
1063 gnetent         getnetent               ck_null         0       
1064 gpbyname        getprotobyname          ck_fun          %       S
1065 gpbynumber      getprotobynumber        ck_fun          @       S
1066 gprotoent       getprotoent             ck_null         0       
1067 gsbyname        getservbyname           ck_fun          @       S S
1068 gsbyport        getservbyport           ck_fun          @       S S
1069 gservent        getservent              ck_null         0       
1070 shostent        sethostent              ck_fun          is%     S
1071 snetent         setnetent               ck_fun          is%     S
1072 sprotoent       setprotoent             ck_fun          is%     S
1073 sservent        setservent              ck_fun          is%     S
1074 ehostent        endhostent              ck_null         is0     
1075 enetent         endnetent               ck_null         is0     
1076 eprotoent       endprotoent             ck_null         is0     
1077 eservent        endservent              ck_null         is0     
1078 gpwnam          getpwnam                ck_fun          %       S
1079 gpwuid          getpwuid                ck_fun          %       S
1080 gpwent          getpwent                ck_null         0       
1081 spwent          setpwent                ck_null         is0     
1082 epwent          endpwent                ck_null         is0     
1083 ggrnam          getgrnam                ck_fun          %       S
1084 ggrgid          getgrgid                ck_fun          %       S
1085 ggrent          getgrent                ck_null         0       
1086 sgrent          setgrent                ck_null         is0     
1087 egrent          endgrent                ck_null         is0     
1088 getlogin        getlogin                ck_null         st0     
1089
1090 # Miscellaneous.
1091
1092 syscall         syscall                 ck_fun          imst@   S L
1093
1094 # For multi-threading
1095 lock            lock                    ck_rfun         s%      R
1096
1097 # For state support
1098
1099 once            once                    ck_null         |       
1100
1101 custom          unknown custom operator         ck_null         0