perl 5.003_07: lib/ExtUtils/xsubpp
[perl.git] / pod / perlre.pod
1 =head1 NAME
2
3 perlre - Perl regular expressions
4
5 =head1 DESCRIPTION
6
7 This page describes the syntax of regular expressions in Perl.  For a
8 description of how to actually I<use> regular expressions in matching
9 operations, plus various examples of the same, see C<m//> and C<s///> in
10 L<perlop>.
11
12 The matching operations can
13 have various modifiers, some of which relate to the interpretation of
14 the regular expression inside.  These are:
15
16     i   Do case-insensitive pattern matching.
17     m   Treat string as multiple lines.
18     s   Treat string as single line.
19     x   Extend your pattern's legibility with whitespace and comments.
20
21 These are usually written as "the C</x> modifier", even though the delimiter
22 in question might not actually be a slash.  In fact, any of these
23 modifiers may also be embedded within the regular expression itself using
24 the new C<(?...)> construct.  See below.
25
26 The C</x> modifier itself needs a little more explanation.  It tells
27 the regular expression parser to ignore whitespace that is not
28 backslashed or within a character class.  You can use this to break up
29 your regular expression into (slightly) more readable parts.  The C<#>
30 character is also treated as a metacharacter introducing a comment,
31 just as in ordinary Perl code.  Taken together, these features go a
32 long way towards making Perl 5 a readable language.  See the C comment
33 deletion code in L<perlop>.
34
35 =head2 Regular Expressions
36
37 The patterns used in pattern matching are regular expressions such as
38 those supplied in the Version 8 regexp routines.  (In fact, the
39 routines are derived (distantly) from Henry Spencer's freely
40 redistributable reimplementation of the V8 routines.)
41 See L<Version 8 Regular Expressions> for details.
42
43 In particular the following metacharacters have their standard I<egrep>-ish
44 meanings:
45
46     \   Quote the next metacharacter
47     ^   Match the beginning of the line
48     .   Match any character (except newline)
49     $   Match the end of the line (or before newline at the end)
50     |   Alternation
51     ()  Grouping
52     []  Character class
53
54 By default, the "^" character is guaranteed to match only at the
55 beginning of the string, the "$" character only at the end (or before the
56 newline at the end) and Perl does certain optimizations with the
57 assumption that the string contains only one line.  Embedded newlines
58 will not be matched by "^" or "$".  You may, however, wish to treat a
59 string as a multi-line buffer, such that the "^" will match after any
60 newline within the string, and "$" will match before any newline.  At the
61 cost of a little more overhead, you can do this by using the /m modifier
62 on the pattern match operator.  (Older programs did this by setting C<$*>,
63 but this practice is deprecated in Perl 5.)
64
65 To facilitate multi-line substitutions, the "." character never matches a
66 newline unless you use the C</s> modifier, which tells Perl to pretend
67 the string is a single line--even if it isn't.  The C</s> modifier also
68 overrides the setting of C<$*>, in case you have some (badly behaved) older
69 code that sets it in another module.
70
71 The following standard quantifiers are recognized:
72
73     *      Match 0 or more times
74     +      Match 1 or more times
75     ?      Match 1 or 0 times
76     {n}    Match exactly n times
77     {n,}   Match at least n times
78     {n,m}  Match at least n but not more than m times
79
80 (If a curly bracket occurs in any other context, it is treated
81 as a regular character.)  The "*" modifier is equivalent to C<{0,}>, the "+"
82 modifier to C<{1,}>, and the "?" modifier to C<{0,1}>.  n and m are limited
83 to integral values less than 65536.
84
85 By default, a quantified subpattern is "greedy", that is, it will match as
86 many times as possible without causing the rest of the pattern not to match.  
87 The standard quantifiers are all "greedy", in that they match as many
88 occurrences as possible (given a particular starting location) without
89 causing the pattern to fail.  If you want it to match the minimum number
90 of times possible, follow the quantifier with a "?" after any of them.
91 Note that the meanings don't change, just the "gravity":
92
93     *?     Match 0 or more times
94     +?     Match 1 or more times
95     ??     Match 0 or 1 time
96     {n}?   Match exactly n times
97     {n,}?  Match at least n times
98     {n,m}? Match at least n but not more than m times
99
100 Since patterns are processed as double quoted strings, the following
101 also work:
102
103     \t          tab                   (HT, TAB)
104     \n          newline               (LF, NL)
105     \r          return                (CR)
106     \f          form feed             (FF)
107     \a          alarm (bell)          (BEL)
108     \e          escape (think troff)  (ESC)
109     \033        octal char (think of a PDP-11)
110     \x1B        hex char
111     \c[         control char
112     \l          lowercase next char (think vi)
113     \u          uppercase next char (think vi)
114     \L          lowercase till \E (think vi)
115     \U          uppercase till \E (think vi)
116     \E          end case modification (think vi)
117     \Q          quote regexp metacharacters till \E
118
119 In addition, Perl defines the following:
120
121     \w  Match a "word" character (alphanumeric plus "_")
122     \W  Match a non-word character
123     \s  Match a whitespace character
124     \S  Match a non-whitespace character
125     \d  Match a digit character
126     \D  Match a non-digit character
127
128 Note that C<\w> matches a single alphanumeric character, not a whole
129 word.  To match a word you'd need to say C<\w+>.  You may use C<\w>,
130 C<\W>, C<\s>, C<\S>, C<\d> and C<\D> within character classes (though not
131 as either end of a range).
132
133 Perl defines the following zero-width assertions:
134
135     \b  Match a word boundary
136     \B  Match a non-(word boundary)
137     \A  Match only at beginning of string
138     \Z  Match only at end of string (or before newline at the end)
139     \G  Match only where previous m//g left off
140
141 A word boundary (C<\b>) is defined as a spot between two characters that
142 has a C<\w> on one side of it and and a C<\W> on the other side of it (in
143 either order), counting the imaginary characters off the beginning and
144 end of the string as matching a C<\W>.  (Within character classes C<\b>
145 represents backspace rather than a word boundary.)  The C<\A> and C<\Z> are
146 just like "^" and "$" except that they won't match multiple times when the
147 C</m> modifier is used, while "^" and "$" will match at every internal line
148 boundary.  To match the actual end of the string, not ignoring newline,
149 you can use C<\Z(?!\n)>.
150
151 When the bracketing construct C<( ... )> is used, \E<lt>digitE<gt> matches the
152 digit'th substring.  Outside of the pattern, always use "$" instead of "\"
153 in front of the digit.  (While the \E<lt>digitE<gt> notation can on rare occasion work
154 outside the current pattern, this should not be relied upon.  See the
155 WARNING below.) The scope of $E<lt>digitE<gt> (and C<$`>, C<$&>, and C<$'>)
156 extends to the end of the enclosing BLOCK or eval string, or to the next
157 successful pattern match, whichever comes first.  If you want to use
158 parentheses to delimit a subpattern (e.g. a set of alternatives) without
159 saving it as a subpattern, follow the ( with a ?:.
160
161 You may have as many parentheses as you wish.  If you have more
162 than 9 substrings, the variables $10, $11, ... refer to the
163 corresponding substring.  Within the pattern, \10, \11, etc. refer back
164 to substrings if there have been at least that many left parens before
165 the backreference.  Otherwise (for backward compatibility) \10 is the
166 same as \010, a backspace, and \11 the same as \011, a tab.  And so
167 on.  (\1 through \9 are always backreferences.)
168
169 C<$+> returns whatever the last bracket match matched.  C<$&> returns the
170 entire matched string.  (C<$0> used to return the same thing, but not any
171 more.)  C<$`> returns everything before the matched string.  C<$'> returns
172 everything after the matched string.  Examples:
173
174     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
175
176     if (/Time: (..):(..):(..)/) {
177         $hours = $1;
178         $minutes = $2;
179         $seconds = $3;
180     }
181
182 You will note that all backslashed metacharacters in Perl are
183 alphanumeric, such as C<\b>, C<\w>, C<\n>.  Unlike some other regular expression
184 languages, there are no backslashed symbols that aren't alphanumeric.
185 So anything that looks like \\, \(, \), \E<lt>, \E<gt>, \{, or \} is always
186 interpreted as a literal character, not a metacharacter.  This makes it
187 simple to quote a string that you want to use for a pattern but that
188 you are afraid might contain metacharacters.  Simply quote all the
189 non-alphanumeric characters:
190
191     $pattern =~ s/(\W)/\\$1/g;
192
193 You can also use the built-in quotemeta() function to do this.
194 An even easier way to quote metacharacters right in the match operator
195 is to say
196
197     /$unquoted\Q$quoted\E$unquoted/
198
199 Perl 5 defines a consistent extension syntax for regular expressions.
200 The syntax is a pair of parens with a question mark as the first thing
201 within the parens (this was a syntax error in Perl 4).  The character
202 after the question mark gives the function of the extension.  Several
203 extensions are already supported:
204
205 =over 10
206
207 =item (?#text)
208
209 A comment.  The text is ignored.  If the C</x> switch is used to enable
210 whitespace formatting, a simple C<#> will suffice.
211
212 =item (?:regexp)
213
214 This groups things like "()" but doesn't make backreferences like "()" does.  So
215
216     split(/\b(?:a|b|c)\b/)
217
218 is like
219
220     split(/\b(a|b|c)\b/)
221
222 but doesn't spit out extra fields.
223
224 =item (?=regexp)
225
226 A zero-width positive lookahead assertion.  For example, C</\w+(?=\t)/>
227 matches a word followed by a tab, without including the tab in C<$&>.
228
229 =item (?!regexp)
230
231 A zero-width negative lookahead assertion.  For example C</foo(?!bar)/>
232 matches any occurrence of "foo" that isn't followed by "bar".  Note
233 however that lookahead and lookbehind are NOT the same thing.  You cannot
234 use this for lookbehind: C</(?!foo)bar/> will not find an occurrence of
235 "bar" that is preceded by something which is not "foo".  That's because
236 the C<(?!foo)> is just saying that the next thing cannot be "foo"--and
237 it's not, it's a "bar", so "foobar" will match.  You would have to do
238 something like C</(?!foo)...bar/> for that.   We say "like" because there's
239 the case of your "bar" not having three characters before it.  You could
240 cover that this way: C</(?:(?!foo)...|^..?)bar/>.  Sometimes it's still
241 easier just to say:
242
243     if (/foo/ && $` =~ /bar$/)
244
245
246 =item (?imsx)
247
248 One or more embedded pattern-match modifiers.  This is particularly
249 useful for patterns that are specified in a table somewhere, some of
250 which want to be case sensitive, and some of which don't.  The case
251 insensitive ones merely need to include C<(?i)> at the front of the
252 pattern.  For example:
253
254     $pattern = "foobar";
255     if ( /$pattern/i )
256
257     # more flexible:
258
259     $pattern = "(?i)foobar";
260     if ( /$pattern/ )
261
262 =back
263
264 The specific choice of question mark for this and the new minimal
265 matching construct was because 1) question mark is pretty rare in older
266 regular expressions, and 2) whenever you see one, you should stop
267 and "question" exactly what is going on.  That's psychology...
268
269 =head2 Backtracking
270
271 A fundamental feature of regular expression matching involves the notion
272 called I<backtracking>.  which is used (when needed) by all regular
273 expression quantifiers, namely C<*>, C<*?>, C<+>, C<+?>, C<{n,m}>, and
274 C<{n,m}?>.
275
276 For a regular expression to match, the I<entire> regular expression must
277 match, not just part of it.  So if the beginning of a pattern containing a
278 quantifier succeeds in a way that causes later parts in the pattern to
279 fail, the matching engine backs up and recalculates the beginning
280 part--that's why it's called backtracking.
281
282 Here is an example of backtracking:  Let's say you want to find the
283 word following "foo" in the string "Food is on the foo table.":
284
285     $_ = "Food is on the foo table.";
286     if ( /\b(foo)\s+(\w+)/i ) {
287         print "$2 follows $1.\n";
288     }
289
290 When the match runs, the first part of the regular expression (C<\b(foo)>)
291 finds a possible match right at the beginning of the string, and loads up
292 $1 with "Foo".  However, as soon as the matching engine sees that there's
293 no whitespace following the "Foo" that it had saved in $1, it realizes its
294 mistake and starts over again one character after where it had had the
295 tentative match.  This time it goes all the way until the next occurrence
296 of "foo". The complete regular expression matches this time, and you get
297 the expected output of "table follows foo."
298
299 Sometimes minimal matching can help a lot.  Imagine you'd like to match
300 everything between "foo" and "bar".  Initially, you write something
301 like this:
302
303     $_ =  "The food is under the bar in the barn.";
304     if ( /foo(.*)bar/ ) {
305         print "got <$1>\n";
306     }
307
308 Which perhaps unexpectedly yields:
309
310   got <d is under the bar in the >
311
312 That's because C<.*> was greedy, so you get everything between the
313 I<first> "foo" and the I<last> "bar".  In this case, it's more effective
314 to use minimal matching to make sure you get the text between a "foo"
315 and the first "bar" thereafter.
316
317     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
318   got <d is under the >
319
320 Here's another example: let's say you'd like to match a number at the end
321 of a string, and you also want to keep the preceding part the match.
322 So you write this:
323
324     $_ = "I have 2 numbers: 53147";
325     if ( /(.*)(\d*)/ ) {                                # Wrong!
326         print "Beginning is <$1>, number is <$2>.\n";
327     }
328
329 That won't work at all, because C<.*> was greedy and gobbled up the
330 whole string. As C<\d*> can match on an empty string the complete
331 regular expression matched successfully.
332
333     Beginning is <I have 2 numbers: 53147>, number is <>.
334
335 Here are some variants, most of which don't work:
336
337     $_ = "I have 2 numbers: 53147";
338     @pats = qw{
339         (.*)(\d*)
340         (.*)(\d+)
341         (.*?)(\d*)
342         (.*?)(\d+)
343         (.*)(\d+)$
344         (.*?)(\d+)$
345         (.*)\b(\d+)$
346         (.*\D)(\d+)$
347     };
348
349     for $pat (@pats) {
350         printf "%-12s ", $pat;
351         if ( /$pat/ ) {
352             print "<$1> <$2>\n";
353         } else {
354             print "FAIL\n";
355         }
356     }
357
358 That will print out:
359
360     (.*)(\d*)    <I have 2 numbers: 53147> <>
361     (.*)(\d+)    <I have 2 numbers: 5314> <7>
362     (.*?)(\d*)   <> <>
363     (.*?)(\d+)   <I have > <2>
364     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
365     (.*?)(\d+)$  <I have 2 numbers: > <53147>
366     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
367     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
368
369 As you see, this can be a bit tricky.  It's important to realize that a
370 regular expression is merely a set of assertions that gives a definition
371 of success.  There may be 0, 1, or several different ways that the
372 definition might succeed against a particular string.  And if there are
373 multiple ways it might succeed, you need to understand backtracking in
374 order to know which variety of success you will achieve.
375
376 When using lookahead assertions and negations, this can all get even
377 tricker.  Imagine you'd like to find a sequence of nondigits not 
378 followed by "123".  You might try to write that as
379
380         $_ = "ABC123";
381         if ( /^\D*(?!123)/ ) {                          # Wrong!
382             print "Yup, no 123 in $_\n";
383         }
384
385 But that isn't going to match; at least, not the way you're hoping.  It
386 claims that there is no 123 in the string.  Here's a clearer picture of
387 why it that pattern matches, contrary to popular expectations:
388
389     $x = 'ABC123' ;
390     $y = 'ABC445' ;
391
392     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/ ;
393     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/ ;
394
395     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/ ;
396     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/ ;
397
398 This prints
399
400     2: got ABC
401     3: got AB
402     4: got ABC
403
404 You might have expected test 3 to fail because it just seems to a more
405 general purpose version of test 1.  The important difference between
406 them is that test 3 contains a quantifier (C<\D*>) and so can use
407 backtracking, whereas test 1 will not.  What's happening is
408 that you've asked "Is it true that at the start of $x, following 0 or more
409 nondigits, you have something that's not 123?"  If the pattern matcher had
410 let C<\D*> expand to "ABC", this would have caused the whole pattern to
411 fail.  
412 The search engine will initially match C<\D*> with "ABC".  Then it will
413 try to match C<(?!123> with "123" which, of course, fails.  But because
414 a quantifier (C<\D*>) has been used in the regular expression, the
415 search engine can backtrack and retry the match differently
416 in the hope of matching the complete regular expression.  
417
418 Well now, 
419 the pattern really, I<really> wants to succeed, so it uses the
420 standard regexp backoff-and-retry and lets C<\D*> expand to just "AB" this
421 time.  Now there's indeed something following "AB" that is not
422 "123".  It's in fact "C123", which suffices.
423
424 We can deal with this by using both an assertion and a negation.  We'll
425 say that the first part in $1 must be followed by a digit, and in fact, it
426 must also be followed by something that's not "123".  Remember that the
427 lookaheads are zero-width expressions--they only look, but don't consume
428 any of the string in their match.  So rewriting this way produces what
429 you'd expect; that is, case 5 will fail, but case 6 succeeds:
430
431     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/ ;
432     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/ ;
433
434     6: got ABC
435
436 In other words, the two zero-width assertions next to each other work like
437 they're ANDed together, just as you'd use any builtin assertions:  C</^$/>
438 matches only if you're at the beginning of the line AND the end of the
439 line simultaneously.  The deeper underlying truth is that juxtaposition in
440 regular expressions always means AND, except when you write an explicit OR
441 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
442 although the attempted matches are made at different positions because "a"
443 is not a zero-width assertion, but a one-width assertion.
444
445 One warning: particularly complicated regular expressions can take
446 exponential time to solve due to the immense number of possible ways they
447 can use backtracking to try match.  For example this will take a very long
448 time to run
449
450     /((a{0,5}){0,5}){0,5}/
451
452 And if you used C<*>'s instead of limiting it to 0 through 5 matches, then
453 it would take literally forever--or until you ran out of stack space.
454
455 =head2 Version 8 Regular Expressions
456
457 In case you're not familiar with the "regular" Version 8 regexp
458 routines, here are the pattern-matching rules not described above.
459
460 Any single character matches itself, unless it is a I<metacharacter>
461 with a special meaning described here or above.  You can cause
462 characters which normally function as metacharacters to be interpreted
463 literally by prefixing them with a "\" (e.g. "\." matches a ".", not any
464 character; "\\" matches a "\").  A series of characters matches that
465 series of characters in the target string, so the pattern C<blurfl>
466 would match "blurfl" in the target string.
467
468 You can specify a character class, by enclosing a list of characters
469 in C<[]>, which will match any one of the characters in the list.  If the
470 first character after the "[" is "^", the class matches any character not
471 in the list.  Within a list, the "-" character is used to specify a
472 range, so that C<a-z> represents all the characters between "a" and "z",
473 inclusive.
474
475 Characters may be specified using a metacharacter syntax much like that
476 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
477 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
478 of octal digits, matches the character whose ASCII value is I<nnn>.
479 Similarly, \xI<nn>, where I<nn> are hexadecimal digits, matches the
480 character whose ASCII value is I<nn>. The expression \cI<x> matches the
481 ASCII character control-I<x>.  Finally, the "." metacharacter matches any
482 character except "\n" (unless you use C</s>).
483
484 You can specify a series of alternatives for a pattern using "|" to
485 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
486 or "foe" in the target string (as would C<f(e|i|o)e>).  Note that the
487 first alternative includes everything from the last pattern delimiter
488 ("(", "[", or the beginning of the pattern) up to the first "|", and
489 the last alternative contains everything from the last "|" to the next
490 pattern delimiter.  For this reason, it's common practice to include
491 alternatives in parentheses, to minimize confusion about where they
492 start and end.  Note however that "|" is interpreted as a literal with
493 square brackets, so if you write C<[fee|fie|foe]> you're really only
494 matching C<[feio|]>.
495
496 Within a pattern, you may designate subpatterns for later reference by
497 enclosing them in parentheses, and you may refer back to the I<n>th
498 subpattern later in the pattern using the metacharacter \I<n>.
499 Subpatterns are numbered based on the left to right order of their
500 opening parenthesis.  Note that a backreference matches whatever
501 actually matched the subpattern in the string being examined, not the
502 rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
503 match "0x1234 0x4321",but not "0x1234 01234", since subpattern 1
504 actually matched "0x", even though the rule C<0|0x> could
505 potentially match the leading 0 in the second number.
506
507 =head2 WARNING on \1 vs $1
508
509 Some people get too used to writing things like
510
511     $pattern =~ s/(\W)/\\\1/g;
512
513 This is grandfathered for the RHS of a substitute to avoid shocking the
514 B<sed> addicts, but it's a dirty habit to get into.  That's because in
515 PerlThink, the right-hand side of a C<s///> is a double-quoted string.  C<\1> in
516 the usual double-quoted string means a control-A.  The customary Unix
517 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
518 of doing that, you get yourself into trouble if you then add an C</e>
519 modifier.
520
521     s/(\d+)/ \1 + 1 /eg;
522
523 Or if you try to do
524
525     s/(\d+)/\1000/;
526
527 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
528 C<${1}000>.  Basically, the operation of interpolation should not be confused
529 with the operation of matching a backreference.  Certainly they mean two
530 different things on the I<left> side of the C<s///>.