mktables: Omit unnecessary duplicates
[perl.git] / t / op / pack.t
1 #!./perl -w
2
3 BEGIN {
4     chdir 't' if -d 't';
5     require './test.pl'; require './charset_tools.pl';
6     set_up_inc(qw '../lib ../dist/Math-BigInt/lib');
7 }
8
9 # This is truth in an if statement, and could be a skip message
10 my $no_endianness = $] > 5.009 ? '' :
11   "Endianness pack modifiers not available on this perl";
12 my $no_signedness = $] > 5.009 ? '' :
13   "Signed/unsigned pack modifiers not available on this perl";
14
15 plan tests => 14718;
16
17 use strict;
18 use warnings qw(FATAL all);
19 use Config;
20
21 my $Perl = which_perl();
22 my @valid_errors = (qr/^Invalid type '\w'/);
23
24 my $ByteOrder = 'unknown';
25 my $maybe_not_avail = '(?:hto[bl]e|[bl]etoh)';
26 if ($no_endianness) {
27   push @valid_errors, qr/^Invalid type '[<>]'/;
28 } elsif ($Config{byteorder} =~ /^1234(?:5678)?$/) {
29   $ByteOrder = 'little';
30   $maybe_not_avail = '(?:htobe|betoh)';
31 }
32 elsif ($Config{byteorder} =~ /^(?:8765)?4321$/) {
33   $ByteOrder = 'big';
34   $maybe_not_avail = '(?:htole|letoh)';
35 }
36 else {
37   push @valid_errors, qr/^Can't (?:un)?pack (?:big|little)-endian .*? on this platform/;
38 }
39
40 if ($no_signedness) {
41   push @valid_errors, qr/^'!' allowed only after types sSiIlLxX in (?:un)?pack/;
42 }
43
44 for my $size ( 16, 32, 64 ) {
45   if (defined $Config{"u${size}size"} and ($Config{"u${size}size"}||0) != ($size >> 3)) {
46     push @valid_errors, qr/^Perl_my_$maybe_not_avail$size\(\) not available/;
47   }
48 }
49
50 my $IsTwosComplement = pack('i', -1) eq "\xFF" x $Config{intsize};
51 print "# \$IsTwosComplement = $IsTwosComplement\n";
52
53 sub is_valid_error
54 {
55   my $err = shift;
56
57   for my $e (@valid_errors) {
58     $err =~ $e and return 1;
59   }
60
61   return 0;
62 }
63
64 sub encode_list {
65   my @result = map {_qq($_)} @_;
66   if (@result == 1) {
67     return @result;
68   }
69   return '(' . join (', ', @result) . ')';
70 }
71
72
73 sub list_eq ($$) {
74   my ($l, $r) = @_;
75   return 0 unless @$l == @$r;
76   for my $i (0..$#$l) {
77     if (defined $l->[$i]) {
78       return 0 unless defined ($r->[$i]) && $l->[$i] eq $r->[$i];
79     } else {
80       return 0 if defined $r->[$i]
81     }
82   }
83   return 1;
84 }
85
86 ##############################################################################
87 #
88 # Here starteth the tests
89 #
90
91 {
92     my $format = "c2 x5 C C x s d i l a6";
93     # Need the expression in here to force ary[5] to be numeric.  This avoids
94     # test2 failing because ary2 goes str->numeric->str and ary doesn't.
95     my @ary = (1,-100,127,128,32767,987.654321098 / 100.0,12345,123456,
96                "abcdef");
97     my $foo = pack($format,@ary);
98     my @ary2 = unpack($format,$foo);
99
100     is($#ary, $#ary2);
101
102     my $out1=join(':',@ary);
103     my $out2=join(':',@ary2);
104     # Using long double NVs may introduce greater accuracy than wanted.
105     $out1 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
106     $out2 =~ s/:9\.87654321097999\d*:/:9.87654321098:/;
107     is($out1, $out2);
108
109     like($foo, qr/def/);
110 }
111 # How about counting bits?
112
113 {
114     my $x;
115     is( ($x = unpack("%32B*", "\001\002\004\010\020\040\100\200\377")), 16 );
116
117     is( ($x = unpack("%32b69", "\001\002\004\010\020\040\100\200\017")), 12 );
118
119     is( ($x = unpack("%32B69", "\001\002\004\010\020\040\100\200\017")), 9 );
120 }
121
122 {
123     my $sum = 129; # ASCII
124     $sum = 103 if $::IS_EBCDIC;
125
126     my $x;
127     is( ($x = unpack("%32B*", "Now is the time for all good blurfl")), $sum );
128
129     my $foo;
130     open(BIN, $Perl) || die "Can't open $Perl: $!\n";
131     binmode BIN;
132     sysread BIN, $foo, 8192;
133     close BIN;
134
135     $sum = unpack("%32b*", $foo);
136     my $longway = unpack("b*", $foo);
137     is( $sum, $longway =~ tr/1/1/ );
138 }
139
140 {
141   my $x;
142   is( ($x = unpack("I",pack("I", 0xFFFFFFFF))), 0xFFFFFFFF );
143 }
144
145 {
146     # check 'w'
147     my @x = (5,130,256,560,32000,3097152,268435455,1073741844, 2**33,
148              '4503599627365785','23728385234614992549757750638446');
149     my $x = pack('w*', @x);
150     my $y = pack 'H*', '0581028200843081fa0081bd8440ffffff7f8480808014A0808'.
151                        '0800087ffffffffffdb19caefe8e1eeeea0c2e1e3e8ede1ee6e';
152
153     is($x, $y);
154
155     my @y = unpack('w*', $y);
156     my $a;
157     while ($a = pop @x) {
158         my $b = pop @y;
159         is($a, $b);
160     }
161
162     @y = unpack('w2', $x);
163
164     is(scalar(@y), 2);
165     is($y[1], 130);
166     $x = pack('w*', 5000000000); $y = '';
167     eval {
168     use Math::BigInt;
169     $y = pack('w*', Math::BigInt::->new(5000000000));
170     };
171     is($x, $y);
172
173     $x = pack 'w', ~0;
174     $y = pack 'w', (~0).'';
175     is($x, $y);
176     is(unpack ('w',$x), ~0);
177     is(unpack ('w',$y), ~0);
178
179     $x = pack 'w', ~0 - 1;
180     $y = pack 'w', (~0) - 2;
181
182     if (~0 - 1 == (~0) - 2) {
183         is($x, $y, "NV arithmetic");
184     } else {
185         isnt($x, $y, "IV/NV arithmetic");
186     }
187     cmp_ok(unpack ('w',$x), '==', ~0 - 1);
188     cmp_ok(unpack ('w',$y), '==', ~0 - 2);
189
190     # These should spot that pack 'w' is using NV, not double, on platforms
191     # where IVs are smaller than doubles, and harmlessly pass elsewhere.
192     # (tests for change 16861)
193     my $x0 = 2**54+3;
194     my $y0 = 2**54-2;
195
196     $x = pack 'w', $x0;
197     $y = pack 'w', $y0;
198
199     if ($x0 == $y0) {
200         is($x, $y, "NV arithmetic");
201     } else {
202         isnt($x, $y, "IV/NV arithmetic");
203     }
204     cmp_ok(unpack ('w',$x), '==', $x0);
205     cmp_ok(unpack ('w',$y), '==', $y0);
206 }
207
208
209 {
210   print "# test exceptions\n";
211   my $x;
212   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff};
213   like($@, qr/^Unterminated compressed integer/);
214
215   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff};
216   like($@, qr/^Unterminated compressed integer/);
217
218   eval { $x = unpack 'w', pack 'C*', 0xff, 0xff, 0xff, 0xff, 0xff, 0xff, 0xff};
219   like($@, qr/^Unterminated compressed integer/);
220
221   eval { $x = pack 'w', -1 };
222   like ($@, qr/^Cannot compress negative numbers/);
223
224   eval { $x = pack 'w', '1'x(1 + length ~0) . 'e0' };
225   like ($@, qr/^Can only compress unsigned integers/);
226
227   # Check that the warning behaviour on the modifiers !, < and > is as we
228   # expect it for this perl.
229   my $can_endian = $no_endianness ? '' : 'sSiIlLqQjJfFdDpP';
230   my $can_shriek = 'sSiIlL';
231   $can_shriek .= 'nNvV' unless $no_signedness;
232   # h and H can't do either, so act as sanity checks in blead
233   foreach my $base (split '', 'hHsSiIlLqQjJfFdDpPnNvV') {
234     foreach my $mod ('', '<', '>', '!', '<!', '>!', '!<', '!>') {
235     SKIP: {
236         # Avoid void context warnings.
237         my $a = eval {pack "$base$mod"};
238         skip "pack can't $base", 1 if $@ =~ /^Invalid type '\w'/;
239         # Which error you get when 2 would be possible seems to be emergent
240         # behaviour of pack's format parser.
241
242         my $fails_shriek = $mod =~ /!/ && index ($can_shriek, $base) == -1;
243         my $fails_endian = $mod =~ /[<>]/ && index ($can_endian, $base) == -1;
244         my $shriek_first = $mod =~ /^!/;
245
246         if ($no_endianness and ($mod eq '<!' or $mod eq '>!')) {
247           # The ! isn't seem as part of $base. Instead it's seen as a modifier
248           # on > or <
249           $fails_shriek = 1;
250           undef $fails_endian;
251         } elsif ($fails_shriek and $fails_endian) {
252           if ($shriek_first) {
253             undef $fails_endian;
254           }
255         }
256
257         if ($fails_endian) {
258           if ($no_endianness) {
259             # < and > are seen as pattern letters, not modifiers
260             like ($@, qr/^Invalid type '[<>]'/, "pack can't $base$mod");
261           } else {
262             like ($@, qr/^'[<>]' allowed only after types/,
263                   "pack can't $base$mod");
264           }
265         } elsif ($fails_shriek) {
266           like ($@, qr/^'!' allowed only after types/,
267                 "pack can't $base$mod");
268         } else {
269           is ($@, '', "pack can $base$mod");
270         }
271       }
272     }
273   }
274
275  SKIP: {
276     skip $no_endianness, 2*3 + 2*8 if $no_endianness;
277     for my $mod (qw( ! < > )) {
278       eval { $x = pack "a$mod", 42 };
279       like ($@, qr/^'$mod' allowed only after types \S+ in pack/);
280
281       eval { $x = unpack "a$mod", 'x'x8 };
282       like ($@, qr/^'$mod' allowed only after types \S+ in unpack/);
283     }
284
285     for my $mod (qw( <> >< !<> !>< <!> >!< <>! ><! )) {
286       eval { $x = pack "sI${mod}s", 42, 47, 11 };
287       like ($@, qr/^Can't use both '<' and '>' after type 'I' in pack/);
288
289       eval { $x = unpack "sI${mod}s", 'x'x16 };
290       like ($@, qr/^Can't use both '<' and '>' after type 'I' in unpack/);
291     }
292   }
293
294  SKIP: {
295     # Is this a stupid thing to do on VMS, VOS and other unusual platforms?
296
297     skip("-- the IEEE infinity model is unavailable in this configuration.", 1)
298        if (($^O eq 'VMS') && !defined($Config{useieee}) || !$Config{d_double_has_inf});
299
300     skip("-- $^O has serious fp indigestion on w-packed infinities", 1)
301        if (
302            ($^O eq 'ultrix')
303            ||
304            ($^O =~ /^svr4/ && -f "/etc/issue" && -f "/etc/.relid") # NCR MP-RAS
305            );
306
307     my $inf = eval '2**1000000';
308
309     skip("Couldn't generate infinity - got error '$@'", 1)
310       unless defined $inf and $inf == $inf / 2 and $inf + 1 == $inf;
311
312     local our $TODO;
313     $TODO = "VOS needs a fix for posix-1022 to pass this test."
314       if ($^O eq 'vos');
315
316     eval { $x = pack 'w', $inf };
317     like ($@, qr/^Cannot compress Inf/, "Cannot compress infinity");
318   }
319
320  SKIP: {
321
322     skip("-- the full range of an IEEE double may not be available in this configuration.", 3)
323        if (($^O eq 'VMS') && !defined($Config{useieee}) || !$Config{d_double_style_ieee});
324
325     skip("-- $^O does not like 2**1023", 3)
326        if (($^O eq 'ultrix'));
327
328     # This should be about the biggest thing possible on an IEEE double
329     my $big = eval '2**1023';
330
331     skip("Couldn't generate 2**1023 - got error '$@'", 3)
332       unless defined $big and $big != $big / 2;
333
334     eval { $x = pack 'w', $big };
335     is ($@, '', "Should be able to pack 'w', $big # 2**1023");
336
337     my $y = eval {unpack 'w', $x};
338     is ($@, '',
339         "Should be able to unpack 'w' the result of pack 'w', $big # 2**1023");
340
341     # I'm getting about 1e-16 on FreeBSD
342     my $quotient = int (100 * ($y - $big) / $big);
343     ok($quotient < 2 && $quotient > -2,
344        "Round trip pack, unpack 'w' of $big is within 1% ($quotient%)");
345   }
346
347 }
348
349 print "# test the 'p' template\n";
350
351 # literals
352 is(unpack("p",pack("p","foo")), "foo");
353 SKIP: {
354   skip $no_endianness, 2 if $no_endianness;
355   is(unpack("p<",pack("p<","foo")), "foo");
356   is(unpack("p>",pack("p>","foo")), "foo");
357 }
358 # scalars
359 is(unpack("p",pack("p",239)), 239);
360 SKIP: {
361   skip $no_endianness, 2 if $no_endianness;
362   is(unpack("p<",pack("p<",239)), 239);
363   is(unpack("p>",pack("p>",239)), 239);
364 }
365
366 # temps
367 sub foo { my $a = "a"; return $a . $a++ . $a++ }
368 {
369   use warnings qw(NONFATAL all);;
370   my $warning;
371   local $SIG{__WARN__} = sub {
372       $warning = $_[0];
373   };
374   my $junk = pack("p", &foo);
375
376   like($warning, qr/temporary val/);
377 }
378
379 # undef should give null pointer
380 like(pack("p", undef), qr/^\0+$/);
381 SKIP: {
382   skip $no_endianness, 2 if $no_endianness;
383   like(pack("p<", undef), qr/^\0+$/);
384   like(pack("p>", undef), qr/^\0+$/);
385 }
386
387 # Check for optimizer bug (e.g.  Digital Unix GEM cc with -O4 on DU V4.0B gives
388 #                                4294967295 instead of -1)
389 #                                see #ifdef __osf__ in pp.c pp_unpack
390 is((unpack("i",pack("i",-1))), -1);
391
392 print "# test the pack lengths of s S i I l L n N v V + modifiers\n";
393
394 my @lengths = (
395   qw(s 2 S 2 i -4 I -4 l 4 L 4 n 2 N 4 v 2 V 4 n! 2 N! 4 v! 2 V! 4),
396   's!'  => $Config{shortsize}, 'S!'  => $Config{shortsize},
397   'i!'  => $Config{intsize},   'I!'  => $Config{intsize},
398   'l!'  => $Config{longsize},  'L!'  => $Config{longsize},
399 );
400
401 while (my ($base, $expect) = splice @lengths, 0, 2) {
402   my @formats = ($base);
403   $base =~ /^[nv]/i or push @formats, "$base>", "$base<";
404   for my $format (@formats) {
405   SKIP: {
406       skip $no_endianness, 1 if $no_endianness && $format =~ m/[<>]/;
407       skip $no_signedness, 1 if $no_signedness && $format =~ /[nNvV]!/;
408       my $len = length(pack($format, 0));
409       if ($expect > 0) {
410         is($expect, $len, "format '$format'");
411       } else {
412         $expect = -$expect;
413         ok ($len >= $expect, "format '$format'") ||
414           print "# format '$format' has length $len, expected >= $expect\n";
415       }
416     }
417   }
418 }
419
420
421 print "# test unpack-pack lengths\n";
422
423 my @templates = qw(c C W i I s S l L n N v V f d q Q);
424
425 foreach my $base (@templates) {
426     my @tmpl = ($base);
427     $base =~ /^[cwnv]/i or push @tmpl, "$base>", "$base<";
428     foreach my $t (@tmpl) {
429         SKIP: {
430             my @t = eval { unpack("$t*", pack("$t*", 12, 34)) };
431
432             skip "cannot pack '$t' on this perl", 4
433               if is_valid_error($@);
434
435             is( $@, '', "Template $t works");
436             is(scalar @t, 2);
437
438             is($t[0], 12);
439             is($t[1], 34);
440         }
441     }
442 }
443
444 {
445     # uuencode/decode
446
447     # Note that first uuencoding known 'text' data and then checking the
448     # binary values of the uuencoded version would not be portable between
449     # character sets.  Uuencoding is meant for encoding binary data, not
450     # text data.
451
452     my $in = pack 'C*', 0 .. 255;
453
454     # just to be anal, we do some random tr/`/ /
455     my $uu = <<'EOUU';
456 M` $"`P0%!@<("0H+# T.#Q`1$A,4%187&!D:&QP='A\@(2(C)"4F)R@I*BLL
457 M+2XO,#$R,S0U-C<X.3H[/#T^/T!!0D-$149'2$E*2TQ-3D]045)35%565UA9
458 M6EM<75Y?8&%B8V1E9F=H:6IK;&UN;W!Q<G-T=79W>'EZ>WQ]?G^`@8*#A(6&
459 MAXB)BHN,C8Z/D)&2DY25EI>8F9J;G)V>GZ"AHJ.DI::GJ*FJJZRMKJ^PL;*S
460 MM+6VM[BYNKN\O;Z_P,'"P\3%QL?(R<K+S,W.S]#1TM/4U=;7V-G:V]S=WM_@
461 ?X>+CY.7FY^CIZNOL[>[O\/'R\_3U]O?X^?K[_/W^_P `
462 EOUU
463
464     $_ = $uu;
465     tr/ /`/;
466
467     is(pack('u', $in), $_);
468
469     is(unpack('u', $uu), $in);
470
471     $in = "\x1f\x8b\x08\x08\x58\xdc\xc4\x35\x02\x03\x4a\x41\x50\x55\x00\xf3\x2a\x2d\x2e\x51\x48\xcc\xcb\x2f\xc9\x48\x2d\x52\x08\x48\x2d\xca\x51\x28\x2d\x4d\xce\x4f\x49\x2d\xe2\x02\x00\x64\x66\x60\x5c\x1a\x00\x00\x00";
472     $uu = <<'EOUU';
473 M'XL("%C<Q#4"`TI!4%4`\RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>("`&1F
474 &8%P:````
475 EOUU
476
477     is(unpack('u', $uu), $in);
478
479 # This is identical to the above except that backquotes have been
480 # changed to spaces
481
482     $uu = <<'EOUU';
483 M'XL("%C<Q#4" TI!4%4 \RHM+E%(S,LOR4@M4@A(+<I1*"U-SD])+>(" &1F
484 &8%P:
485 EOUU
486
487     # ' # Grr
488     is(unpack('u', $uu), $in);
489
490 }
491
492 # test the ascii template types (A, a, Z)
493
494 foreach (
495 ['p', 'A*',  "foo\0bar\0 ", "foo\0bar\0 "],
496 ['p', 'A11', "foo\0bar\0 ", "foo\0bar\0   "],
497 ['u', 'A*',  "foo\0bar \0", "foo\0bar"],
498 ['u', 'A8',  "foo\0bar \0", "foo\0bar"],
499 ['p', 'a*',  "foo\0bar\0 ", "foo\0bar\0 "],
500 ['p', 'a11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
501 ['u', 'a*',  "foo\0bar \0", "foo\0bar \0"],
502 ['u', 'a8',  "foo\0bar \0", "foo\0bar "],
503 ['p', 'Z*',  "foo\0bar\0 ", "foo\0bar\0 \0"],
504 ['p', 'Z11', "foo\0bar\0 ", "foo\0bar\0 \0\0"],
505 ['p', 'Z3',  "foo",         "fo\0"],
506 ['u', 'Z*',  "foo\0bar \0", "foo"],
507 ['u', 'Z8',  "foo\0bar \0", "foo"],
508 )
509 {
510     my ($what, $template, $in, $out) = @$_;
511     my $got = $what eq 'u' ? (unpack $template, $in) : (pack $template, $in);
512     unless (is($got, $out)) {
513         my $un = $what eq 'u' ? 'un' : '';
514         print "# ${un}pack ('$template', "._qq($in).') gave '._qq($out).
515             ' not '._qq($got)."\n";
516     }
517 }
518
519 print "# packing native shorts/ints/longs\n";
520
521 is(length(pack("s!", 0)), $Config{shortsize});
522 is(length(pack("i!", 0)), $Config{intsize});
523 is(length(pack("l!", 0)), $Config{longsize});
524 ok(length(pack("s!", 0)) <= length(pack("i!", 0)));
525 ok(length(pack("i!", 0)) <= length(pack("l!", 0)));
526 is(length(pack("i!", 0)), length(pack("i", 0)));
527
528 sub numbers {
529   my $base = shift;
530   my @formats = ($base);
531   $base =~ /^[silqjfdp]/i and push @formats, "$base>", "$base<";
532   for my $format (@formats) {
533     numbers_with_total ($format, undef, @_);
534   }
535 }
536
537 sub numbers_with_total {
538   my $format = shift;
539   my $total = shift;
540   if (!defined $total) {
541     foreach (@_) {
542       $total += $_;
543     }
544   }
545   print "# numbers test for $format\n";
546   foreach (@_) {
547     SKIP: {
548         my $out = eval {unpack($format, pack($format, $_))};
549         skip "cannot pack '$format' on this perl", 2
550           if is_valid_error($@);
551
552         is($@, '', "no error");
553         is($out, $_, "unpack pack $format $_");
554     }
555   }
556
557   my $skip_if_longer_than = ~0; # "Infinity"
558   if (~0 - 1 == ~0) {
559     # If we're running with -DNO_PERLPRESERVE_IVUV and NVs don't preserve all
560     # UVs (in which case ~0 is NV, ~0-1 will be the same NV) then we can't
561     # correctly in perl calculate UV totals for long checksums, as pp_unpack
562     # is using UV maths, and we've only got NVs.
563     $skip_if_longer_than = $Config{nv_preserves_uv_bits};
564   }
565
566   foreach ('', 1, 2, 3, 15, 16, 17, 31, 32, 33, 53, 54, 63, 64, 65) {
567     SKIP: {
568       my $sum = eval {unpack "%$_$format*", pack "$format*", @_};
569       skip "cannot pack '$format' on this perl", 3
570         if is_valid_error($@);
571
572       is($@, '', "no error");
573       ok(defined $sum, "sum bits $_, format $format defined");
574
575       my $len = $_; # Copy, so that we can reassign ''
576       $len = 16 unless length $len;
577
578       SKIP: {
579         skip "cannot test checksums over $skip_if_longer_than bits", 1
580           if $len > $skip_if_longer_than;
581
582         # Our problem with testing this portably is that the checksum code in
583         # pp_unpack is able to cast signed to unsigned, and do modulo 2**n
584         # arithmetic in unsigned ints, which perl has no operators to do.
585         # (use integer; does signed ints, which won't wrap on UTS, which is just
586         # fine with ANSI, but not with most people's assumptions.
587         # This is why we need to supply the totals for 'Q' as there's no way in
588         # perl to calculate them, short of unpack '%0Q' (is that documented?)
589         # ** returns NVs; make sure it's IV.
590         my $max = 1 + 2 * (int (2 ** ($len-1))-1); # The max possible checksum
591         my $max_p1 = $max + 1;
592         my ($max_is_integer, $max_p1_is_integer);
593         $max_p1_is_integer = 1 unless $max_p1 + 1 == $max_p1;
594         $max_is_integer = 1 if $max - 1 < ~0;
595
596         my $calc_sum;
597         if (ref $total) {
598             $calc_sum = &$total($len);
599         } else {
600             $calc_sum = $total;
601             # Shift into range by some multiple of the total
602             my $mult = $max_p1 ? int ($total / $max_p1) : undef;
603             # Need this to make sure that -1 + (~0+1) is ~0 (ie still integer)
604             $calc_sum = $total - $mult;
605             $calc_sum -= $mult * $max;
606             if ($calc_sum < 0) {
607                 $calc_sum += 1;
608                 $calc_sum += $max;
609             }
610         }
611         if ($calc_sum == $calc_sum - 1 && $calc_sum == $max_p1) {
612             # we're into floating point (either by getting out of the range of
613             # UV arithmetic, or because we're doing a floating point checksum)
614             # and our calculation of the checksum has become rounded up to
615             # max_checksum + 1
616             $calc_sum = 0;
617         }
618
619         if ($calc_sum == $sum) { # HAS to be ==, not eq (so no is()).
620             pass ("unpack '%$_$format' gave $sum");
621         } else {
622             my $delta = 1.000001;
623             if ($format =~ tr /dDfF//
624                 && ($calc_sum <= $sum * $delta && $calc_sum >= $sum / $delta)) {
625                 pass ("unpack '%$_$format' gave $sum, expected $calc_sum");
626             } else {
627                 my $text = ref $total ? &$total($len) : $total;
628                 fail;
629                 print "# For list (" . join (", ", @_) . ") (total $text)"
630                     . " packed with $format unpack '%$_$format' gave $sum,"
631                     . " expected $calc_sum\n";
632             }
633         }
634       }
635     }
636   }
637 }
638
639 numbers ('c', -128, -1, 0, 1, 127);
640 numbers ('C', 0, 1, 127, 128, 255);
641 numbers ('W', 0, 1, 127, 128, 255, 256, 0x7ff, 0x800, 0xfffd);
642 numbers ('s', -32768, -1, 0, 1, 32767);
643 numbers ('S', 0, 1, 32767, 32768, 65535);
644 numbers ('i', -2147483648, -1, 0, 1, 2147483647);
645 numbers ('I', 0, 1, 2147483647, 2147483648, 4294967295);
646 numbers ('l', -2147483648, -1, 0, 1, 2147483647);
647 numbers ('L', 0, 1, 2147483647, 2147483648, 4294967295);
648 numbers ('s!', -32768, -1, 0, 1, 32767);
649 numbers ('S!', 0, 1, 32767, 32768, 65535);
650 numbers ('i!', -2147483648, -1, 0, 1, 2147483647);
651 numbers ('I!', 0, 1, 2147483647, 2147483648, 4294967295);
652 numbers ('l!', -2147483648, -1, 0, 1, 2147483647);
653 numbers ('L!', 0, 1, 2147483647, 2147483648, 4294967295);
654 numbers ('n', 0, 1, 32767, 32768, 65535);
655 numbers ('v', 0, 1, 32767, 32768, 65535);
656 numbers ('N', 0, 1, 2147483647, 2147483648, 4294967295);
657 numbers ('V', 0, 1, 2147483647, 2147483648, 4294967295);
658 numbers ('n!', -32768, -1, 0, 1, 32767);
659 numbers ('v!', -32768, -1, 0, 1, 32767);
660 numbers ('N!', -2147483648, -1, 0, 1, 2147483647);
661 numbers ('V!', -2147483648, -1, 0, 1, 2147483647);
662 # All these should have exact binary representations:
663 numbers ('f', -1, 0, 0.5, 42, 2**34);
664 numbers ('d', -(2**34), -1, 0, 1, 2**34);
665 ## These don't, but 'd' is NV.  XXX wrong, it's double
666 #numbers ('d', -1, 0, 1, 1-exp(-1), -exp(1));
667
668 numbers_with_total ('q', -1,
669                     -9223372036854775808, -1, 0, 1,9223372036854775807);
670 # This total is icky, but the true total is 2**65-1, and need a way to generate
671 # the expected checksum on any system including those where NVs can preserve
672 # 65 bits. (long double is 128 bits on sparc, so they certainly can)
673 # or where rounding is down not up on binary conversion (crays)
674 numbers_with_total ('Q', sub {
675                       my $len = shift;
676                       $len = 65 if $len > 65; # unmasked total is 2**65-1 here
677                       my $total = 1 + 2 * (int (2**($len - 1)) - 1);
678                       return 0 if $total == $total - 1; # Overflowed integers
679                       return $total; # NVs still accurate to nearest integer
680                     },
681                     0, 1,9223372036854775807, 9223372036854775808,
682                     18446744073709551615);
683
684 print "# pack nvNV byteorders\n";
685
686 is(pack("n", 0xdead), "\xde\xad");
687 is(pack("v", 0xdead), "\xad\xde");
688 is(pack("N", 0xdeadbeef), "\xde\xad\xbe\xef");
689 is(pack("V", 0xdeadbeef), "\xef\xbe\xad\xde");
690
691 SKIP: {
692   skip $no_signedness, 4 if $no_signedness;
693   is(pack("n!", 0xdead), "\xde\xad");
694   is(pack("v!", 0xdead), "\xad\xde");
695   is(pack("N!", 0xdeadbeef), "\xde\xad\xbe\xef");
696   is(pack("V!", 0xdeadbeef), "\xef\xbe\xad\xde");
697 }
698
699 print "# test big-/little-endian conversion\n";
700
701 sub byteorder
702 {
703   my $format = shift;
704   print "# byteorder test for $format\n";
705   for my $value (@_) {
706     SKIP: {
707       my($nat,$be,$le) = eval { map { pack $format.$_, $value } '', '>', '<' };
708       skip "cannot pack '$format' on this perl", 5
709         if is_valid_error($@);
710
711       {
712         use warnings qw(NONFATAL utf8);
713         print "# [$value][$nat][$be][$le][$@]\n";
714       }
715
716       SKIP: {
717         skip "cannot compare native byteorder with big-/little-endian", 1
718             if $ByteOrder eq 'unknown';
719
720         is($nat, $ByteOrder eq 'big' ? $be : $le);
721       }
722       is($be, reverse($le));
723       my @x = eval { unpack "$format$format>$format<", $nat.$be.$le };
724
725       print "# [$value][", join('][', @x), "][$@]\n";
726
727       is($@, '');
728       is($x[0], $x[1]);
729       is($x[0], $x[2]);
730     }
731   }
732 }
733
734 byteorder('s', -32768, -1, 0, 1, 32767);
735 byteorder('S', 0, 1, 32767, 32768, 65535);
736 byteorder('i', -2147483648, -1, 0, 1, 2147483647);
737 byteorder('I', 0, 1, 2147483647, 2147483648, 4294967295);
738 byteorder('l', -2147483648, -1, 0, 1, 2147483647);
739 byteorder('L', 0, 1, 2147483647, 2147483648, 4294967295);
740 byteorder('j', -2147483648, -1, 0, 1, 2147483647);
741 byteorder('J', 0, 1, 2147483647, 2147483648, 4294967295);
742 byteorder('s!', -32768, -1, 0, 1, 32767);
743 byteorder('S!', 0, 1, 32767, 32768, 65535);
744 byteorder('i!', -2147483648, -1, 0, 1, 2147483647);
745 byteorder('I!', 0, 1, 2147483647, 2147483648, 4294967295);
746 byteorder('l!', -2147483648, -1, 0, 1, 2147483647);
747 byteorder('L!', 0, 1, 2147483647, 2147483648, 4294967295);
748 byteorder('q', -9223372036854775808, -1, 0, 1, 9223372036854775807);
749 byteorder('Q', 0, 1, 9223372036854775807, 9223372036854775808, 18446744073709551615);
750 byteorder('f', -1, 0, 0.5, 42, 2**34);
751 byteorder('F', -1, 0, 0.5, 42, 2**34);
752 byteorder('d', -(2**34), -1, 0, 1, 2**34);
753 byteorder('D', -(2**34), -1, 0, 1, 2**34);
754
755 print "# test negative numbers\n";
756
757 SKIP: {
758   skip "platform is not using two's complement for negative integers", 120
759     unless $IsTwosComplement;
760
761   for my $format (qw(s i l j s! i! l! q)) {
762     SKIP: {
763       my($nat,$be,$le) = eval { map { pack $format.$_, -1 } '', '>', '<' };
764       skip "cannot pack '$format' on this perl", 15
765         if is_valid_error($@);
766
767       my $len = length $nat;
768       is($_, "\xFF"x$len) for $nat, $be, $le;
769
770       my(@val,@ref);
771       if ($len >= 8) {
772         @val = (-2, -81985529216486896, -9223372036854775808);
773         @ref = ("\xFF\xFF\xFF\xFF\xFF\xFF\xFF\xFE",
774                 "\xFE\xDC\xBA\x98\x76\x54\x32\x10",
775                 "\x80\x00\x00\x00\x00\x00\x00\x00");
776       }
777       elsif ($len >= 4) {
778         @val = (-2, -19088744, -2147483648);
779         @ref = ("\xFF\xFF\xFF\xFE",
780                 "\xFE\xDC\xBA\x98",
781                 "\x80\x00\x00\x00");
782       }
783       else {
784         @val = (-2, -292, -32768);
785         @ref = ("\xFF\xFE",
786                 "\xFE\xDC",
787                 "\x80\x00");
788       }
789       for my $x (@ref) {
790         if ($len > length $x) {
791           $x = $x . "\xFF" x ($len - length $x);
792         }
793       }
794
795       for my $i (0 .. $#val) {
796         my($nat,$be,$le) = eval { map { pack $format.$_, $val[$i] } '', '>', '<' };
797         is($@, '');
798
799         SKIP: {
800           skip "cannot compare native byteorder with big-/little-endian", 1
801               if $ByteOrder eq 'unknown';
802
803           is($nat, $ByteOrder eq 'big' ? $be : $le);
804         }
805
806         is($be, $ref[$i]);
807         is($be, reverse($le));
808       }
809     }
810   }
811 }
812
813 {
814   # /
815
816   my ($x, $y, $z, @a);
817   eval { ($x) = unpack '/a*','hello' };
818   like($@, qr!'/' must follow a numeric type!);
819   undef $x;
820   eval { $x = unpack '/a*','hello' };
821   like($@, qr!'/' must follow a numeric type!);
822
823   # [perl #60204] Unhelpful error message from unpack
824   eval { @a = unpack 'v/a*','h' };
825   is($@, '');
826   is(scalar @a, 0);
827   eval { $x = unpack 'v/a*','h' };
828   is($@, '');
829   is($x, undef);
830
831   undef $x;
832   eval { ($z,$x,$y) = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
833   is($@, '');
834   is($z, 'ok');
835   is($x, 'yes');
836   is($y, 'z');
837   undef $z;
838   eval { $z = unpack 'a3/A C/a* C/Z', "003ok \003yes\004z\000abc" };
839   is($@, '');
840   is($z, 'ok');
841
842
843   undef $x;
844   eval { ($x) = pack '/a*','hello' };
845   like($@,  qr!Invalid type '/'!);
846   undef $x;
847   eval { $x = pack '/a*','hello' };
848   like($@,  qr!Invalid type '/'!);
849
850   $z = pack 'n/a* N/Z* w/A*','string','hi there ','etc';
851   my $expect = "\000\006string\0\0\0\012hi there \000\003etc";
852   is($z, $expect);
853
854   undef $x;
855   $expect = 'hello world';
856   eval { ($x) = unpack ("w/a", chr (11) . "hello world!")};
857   is($x, $expect);
858   is($@, '');
859
860   undef $x;
861   # Doing this in scalar context used to fail.
862   eval { $x = unpack ("w/a", chr (11) . "hello world!")};
863   is($@, '');
864   is($x, $expect);
865
866   foreach (
867            ['a/a*/a*', '212ab345678901234567','ab3456789012'],
868            ['a/a*/a*', '3012ab345678901234567', 'ab3456789012'],
869            ['a/a*/b*', '212ab', $::IS_EBCDIC ? '100000010100' : '100001100100'],
870   )
871   {
872     my ($pat, $in, $expect) = @$_;
873     undef $x;
874     eval { ($x) = unpack $pat, $in };
875     is($@, '');
876     is($x, $expect) ||
877       printf "# list unpack ('$pat', '$in') gave %s, expected '$expect'\n",
878              encode_list ($x);
879
880     undef $x;
881     eval { $x = unpack $pat, $in };
882     is($@, '');
883     is($x, $expect) ||
884       printf "# scalar unpack ('$pat', '$in') gave %s, expected '$expect'\n",
885              encode_list ($x);
886   }
887
888   # / with #
889
890   my $pattern = <<'EOU';
891  a3/A                   # Count in ASCII
892  C/a*                   # Count in a C char
893  C/Z                    # Count in a C char but skip after \0
894 EOU
895
896   $x = $y = $z =undef;
897   eval { ($z,$x,$y) = unpack $pattern, "003ok \003yes\004z\000abc" };
898   is($@, '');
899   is($z, 'ok');
900   is($x, 'yes');
901   is($y, 'z');
902   undef $x;
903   eval { $z = unpack $pattern, "003ok \003yes\004z\000abc" };
904   is($@, '');
905   is($z, 'ok');
906
907   $pattern = <<'EOP';
908   n/a*                  # Count as network short
909   w/A*                  # Count a  BER integer
910 EOP
911   $expect = "\000\006string\003etc";
912   $z = pack $pattern,'string','etc';
913   is($z, $expect);
914 }
915
916
917 {
918     is("1.20.300.4000", sprintf "%vd", pack("U*",utf8::native_to_unicode(1),utf8::native_to_unicode(20),300,4000));
919     is("1.20.300.4000", sprintf "%vd", pack("  U*",utf8::native_to_unicode(1),utf8::native_to_unicode(20),300,4000));
920 }
921 isnt(v1.20.300.4000, sprintf "%vd", pack("C0U*",utf8::native_to_unicode(1),utf8::native_to_unicode(20),300,4000));
922
923 my $rslt = join " ", map { ord } split "", byte_utf8a_to_utf8n("\xc7\xa2");
924 # The ASCII UTF-8 of U+1E2 is "\xc7\xa2"
925 is(join(" ", unpack("U0 C*", chr(0x1e2))), $rslt);
926
927 # does pack U create Unicode?
928 is(ord(pack('U', 300)), 300);
929
930 # does unpack U deref Unicode?
931 is((unpack('U', chr(300)))[0], 300);
932
933 # is unpack U the reverse of pack U for Unicode string?
934 is("@{[unpack('U*', pack('U*', 100, 200, 300))]}", "100 200 300");
935
936 # is unpack U the reverse of pack U for byte string?
937 is("@{[unpack('U*', pack('U*', 100, 200))]}", "100 200");
938
939 {
940     # does pack U0C create Unicode?
941     my $cp202 = chr(202);
942     utf8::upgrade $cp202;
943     my @bytes202;
944     {   # This is portable across character sets
945         use bytes;
946         @bytes202 = map { ord } split "", $cp202;
947     }
948
949     # This test requires the first number to be invariant; 64 is invariant on
950     # ASCII and EBCDIC.
951     is("@{[pack('U0C*', 64, @bytes202)]}", v64.v202);
952
953     # does pack C0U create characters?
954     # The U* is expecting Unicode, so convert to that.
955     is("@{[pack('C0U*', map { utf8::native_to_unicode($_) } 64, 202)]}",
956        pack("C*", 64, @bytes202));
957
958     # does unpack U0U on byte data warn?
959     {
960         use warnings qw(NONFATAL all);;
961
962         my $bad = pack("U0C", 202);
963         local $SIG{__WARN__} = sub { $@ = "@_" };
964         my @null = unpack('U0U', $bad);
965         like($@, qr/^Malformed UTF-8 character: /);
966     }
967 }
968
969 {
970   my $p = pack 'i*', -2147483648, ~0, 0, 1, 2147483647;
971   my (@a);
972   # bug - % had to be at the start of the pattern, no leading whitespace or
973   # comments. %i! didn't work at all.
974   foreach my $pat ('%32i*', ' %32i*', "# Muhahahaha\n%32i*", '%32i*  ',
975                    '%32i!*', ' %32i!*', "\n#\n#\n\r \t\f%32i!*", '%32i!*#') {
976     @a = unpack $pat, $p;
977     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
978     @a = scalar unpack $pat, $p;
979     is($a[0], 0xFFFFFFFF) || print "# $pat\n";
980   }
981
982
983   $p = pack 'I*', 42, 12;
984   # Multiline patterns in scalar context failed.
985   foreach my $pat ('I', <<EOPOEMSNIPPET, 'I#I', 'I # I', 'I # !!!') {
986 # On the Ning Nang Nong
987 # Where the Cows go Bong!
988 # And the Monkeys all say Boo!
989 I
990 EOPOEMSNIPPET
991     @a = unpack $pat, $p;
992     is(scalar @a, 1);
993     is($a[0], 42);
994     @a = scalar unpack $pat, $p;
995     is(scalar @a, 1);
996     is($a[0], 42);
997   }
998
999   # shorts (of all flavours) didn't calculate checksums > 32 bits with floating
1000   # point, so a pathologically long pattern would wrap at 32 bits.
1001   my $pat = "\xff\xff"x65538; # Start with it long, to save any copying.
1002   foreach (4,3,2,1,0) {
1003     my $len = 65534 + $_;
1004     is(unpack ("%33n$len", $pat), 65535 * $len);
1005   }
1006 }
1007
1008
1009 # pack x X @
1010 foreach (
1011          ['x', "N", "\0"],
1012          ['x4', "N", "\0"x4],
1013          ['xX', "N", ""],
1014          ['xXa*', "Nick", "Nick"],
1015          ['a5Xa5', "cameL", "llama", "camellama"],
1016          ['@4', 'N', "\0"x4],
1017          ['a*@8a*', 'Camel', 'Dromedary', "Camel\0\0\0Dromedary"],
1018          ['a*@4a', 'Perl rules', '!', 'Perl!'],
1019 )
1020 {
1021   my ($template, @in) = @$_;
1022   my $out = pop @in;
1023   my $got = eval {pack $template, @in};
1024   is($@, '');
1025   is($out, $got) ||
1026     printf "# pack ('$template', %s) gave %s expected %s\n",
1027            encode_list (@in), encode_list ($got), encode_list ($out);
1028 }
1029
1030 # unpack x X @
1031 foreach (
1032          ['x', "N"],
1033          ['xX', "N"],
1034          ['xXa*', "Nick", "Nick"],
1035          ['a5Xa5', "camellama", "camel", "llama"],
1036          ['@3', "ice"],
1037          ['@2a2', "water", "te"],
1038          ['a*@1a3', "steam", "steam", "tea"],
1039 )
1040 {
1041   my ($template, $in, @out) = @$_;
1042   my @got = eval {unpack $template, $in};
1043   is($@, '');
1044   ok (list_eq (\@got, \@out)) ||
1045     printf "# list unpack ('$template', %s) gave %s expected %s\n",
1046            _qq($in), encode_list (@got), encode_list (@out);
1047
1048   my $got = eval {unpack $template, $in};
1049   is($@, '');
1050   @out ? is( $got, $out[0] ) # 1 or more items; should get first
1051        : ok( !defined $got ) # 0 items; should get undef
1052     or printf "# scalar unpack ('$template', %s) gave %s expected %s\n",
1053               _qq($in), encode_list ($got), encode_list ($out[0]);
1054 }
1055
1056 {
1057     my $t = 'Z*Z*';
1058     my ($u, $v) = qw(foo xyzzy);
1059     my $p = pack($t, $u, $v);
1060     my @u = unpack($t, $p);
1061     is(scalar @u, 2);
1062     is($u[0], $u);
1063     is($u[1], $v);
1064 }
1065
1066 {
1067     is((unpack("w/a*", "\x02abc"))[0], "ab");
1068
1069     # "w/a*" should be seen as one unit
1070
1071     is(scalar unpack("w/a*", "\x02abc"), "ab");
1072 }
1073
1074 SKIP: {
1075   print "# group modifiers\n";
1076
1077   skip $no_endianness, 3 * 2 + 3 * 2 + 1 if $no_endianness;
1078
1079   for my $t (qw{ (s<)< (sl>s)> (s(l(sl)<l)s)< }) {
1080     print "# testing pattern '$t'\n";
1081     eval { ($_) = unpack($t, 'x'x18); };
1082     is($@, '');
1083     eval { $_ = pack($t, (0)x6); };
1084     is($@, '');
1085   }
1086
1087   for my $t (qw{ (s<)> (sl>s)< (s(l(sl)<l)s)> }) {
1088     print "# testing pattern '$t'\n";
1089     eval { ($_) = unpack($t, 'x'x18); };
1090     like($@, qr/Can't use '[<>]' in a group with different byte-order in unpack/);
1091     eval { $_ = pack($t, (0)x6); };
1092     like($@, qr/Can't use '[<>]' in a group with different byte-order in pack/);
1093   }
1094
1095   is(pack('L<L>', (0x12345678)x2),
1096      pack('(((L1)1)<)(((L)1)1)>1', (0x12345678)x2));
1097 }
1098
1099 {
1100   sub compress_template {
1101     my $t = shift;
1102     for my $mod (qw( < > )) {
1103       $t =~ s/((?:(?:[SILQJFDP]!?$mod|[^SILQJFDP\W]!?)(?:\d+|\*|\[(?:[^]]+)\])?\/?){2,})/
1104               my $x = $1; $x =~ s!$mod!!g ? "($x)$mod" : $x /ieg;
1105     }
1106     return $t;
1107   }
1108
1109   my %templates = (
1110     's<'                  => [-42],
1111     's<c2x![S]S<'         => [-42, -11, 12, 4711],
1112     '(i<j<[s]l<)3'        => [-11, -22, -33, 1000000, 1100, 2201, 3302,
1113                               -1000000, 32767, -32768, 1, -123456789 ],
1114     '(I!<4(J<2L<)3)5'     => [1 .. 65],
1115     'q<Q<'                => [-50000000005, 60000000006],
1116     'f<F<d<'              => [3.14159, 111.11, 2222.22],
1117     'D<cCD<'              => [1e42, -128, 255, 1e-42],
1118     'n/a*'                => ['/usr/bin/perl'],
1119     'C/a*S</A*L</Z*I</a*' => [qw(Just another Perl hacker)],
1120   );
1121
1122   for my $tle (sort keys %templates) {
1123     my @d = @{$templates{$tle}};
1124     my $tbe = $tle;
1125     $tbe =~ y/</>/;
1126     for my $t ($tbe, $tle) {
1127       my $c = compress_template($t);
1128       print "# '$t' -> '$c'\n";
1129       SKIP: {
1130         my $p1 = eval { pack $t, @d };
1131         skip "cannot pack '$t' on this perl", 5 if is_valid_error($@);
1132         my $p2 = eval { pack $c, @d };
1133         is($@, '');
1134         is($p1, $p2);
1135         s!(/[aAZ])\*!$1!g for $t, $c;
1136         my @u1 = eval { unpack $t, $p1 };
1137         is($@, '');
1138         my @u2 = eval { unpack $c, $p2 };
1139         is($@, '');
1140         is(join('!', @u1), join('!', @u2));
1141       }
1142     }
1143   }
1144 }
1145
1146 {
1147     # from Wolfgang Laun: fix in change #13163
1148
1149     my $s = 'ABC' x 10;
1150     my $t = '*';
1151     my $x = ord($t);
1152     my $buf = pack( 'Z*/A* C',  $s, $x );
1153     my $y;
1154
1155     my $h = $buf;
1156     $h =~ s/[^[:print:]]/./g;
1157     ( $s, $y ) = unpack( "Z*/A* C", $buf );
1158     is($h, "30.ABCABCABCABCABCABCABCABCABCABC$t");
1159     is(length $buf, 34);
1160     is($s, "ABCABCABCABCABCABCABCABCABCABC");
1161     is($y, $x);
1162 }
1163
1164 {
1165     # from Wolfgang Laun: fix in change #13288
1166
1167     eval { my $t=unpack("P*", "abc") };
1168     like($@, qr/'P' must have an explicit size/);
1169 }
1170
1171 {   # Grouping constructs
1172     my (@a, @b);
1173     @a = unpack '(SL)',   pack 'SLSLSL', 67..90;
1174     is("@a", "67 68");
1175     @a = unpack '(SL)3',   pack 'SLSLSL', 67..90;
1176     @b = (67..72);
1177     is("@a", "@b");
1178     @a = unpack '(SL)3',   pack 'SLSLSLSL', 67..90;
1179     is("@a", "@b");
1180     @a = unpack '(SL)[3]', pack 'SLSLSLSL', 67..90;
1181     is("@a", "@b");
1182     @a = unpack '(SL)[2] SL', pack 'SLSLSLSL', 67..90;
1183     is("@a", "@b");
1184     @a = unpack 'A/(SL)',  pack 'ASLSLSLSL', 3, 67..90;
1185     is("@a", "@b");
1186     @a = unpack 'A/(SL)SL',  pack 'ASLSLSLSL', 2, 67..90;
1187     is("@a", "@b");
1188     @a = unpack '(SL)*',   pack 'SLSLSLSL', 67..90;
1189     @b = (67..74);
1190     is("@a", "@b");
1191     @a = unpack '(SL)*SL',   pack 'SLSLSLSL', 67..90;
1192     is("@a", "@b");
1193     eval { @a = unpack '(*SL)',   '' };
1194     like($@, qr/\(\)-group starts with a count/);
1195     eval { @a = unpack '(3SL)',   '' };
1196     like($@, qr/\(\)-group starts with a count/);
1197     eval { @a = unpack '([3]SL)',   '' };
1198     like($@, qr/\(\)-group starts with a count/);
1199     eval { @a = pack '(*SL)' };
1200     like($@, qr/\(\)-group starts with a count/);
1201     @a = unpack '(SL)3 SL',   pack '(SL)4', 67..74;
1202     is("@a", "@b");
1203     @a = unpack '(SL)3 SL',   pack '(SL)[4]', 67..74;
1204     is("@a", "@b");
1205     @a = unpack '(SL)3 SL',   pack '(SL)*', 67..74;
1206     is("@a", "@b");
1207 }
1208
1209 {  # more on grouping (W.Laun)
1210   # @ absolute within ()-group
1211   my $badc = pack( '(a)*', unpack( '(@1a @0a @2)*', 'abcd' ) );
1212   is( $badc, 'badc' );
1213   my @b = ( 1, 2, 3 );
1214   my $buf = pack( '(@1c)((@2C)@3c)', @b );
1215   is( $buf, "\0\1\0\0\2\3" );
1216   my @a = unpack( '(@1c)((@2c)@3c)', $buf );
1217   is( "@a", "@b" );
1218
1219   # various unpack count/code scenarios
1220   my @Env = ( a => 'AAA', b => 'BBB' );
1221   my $env = pack( 'S(S/A*S/A*)*', @Env/2, @Env );
1222
1223   # unpack full length - ok
1224   my @pup = unpack( 'S/(S/A* S/A*)', $env );
1225   is( "@pup", "@Env" );
1226
1227   # warn when count/code goes beyond end of string
1228   # \0002 \0001 a \0003 AAA \0001 b \0003 BBB
1229   #     2     4 5     7  10    1213
1230   eval { @pup = unpack( 'S/(S/A* S/A*)', substr( $env, 0, 13 ) ) };
1231   like( $@, qr{length/code after end of string} );
1232
1233   # postfix repeat count
1234   $env = pack( '(S/A* S/A*)' . @Env/2, @Env );
1235
1236   # warn when count/code goes beyond end of string
1237   # \0001 a \0003 AAA \0001  b \0003 BBB
1238   #     2 3c    5   8    10 11    13  16
1239   eval { @pup = unpack( '(S/A* S/A*)' . @Env/2, substr( $env, 0, 11 ) ) };
1240   like( $@, qr{length/code after end of string} );
1241
1242   # catch stack overflow/segfault
1243   eval { $_ = pack( ('(' x 105) . 'A' . (')' x 105) ); };
1244   like( $@, qr{Too deeply nested \(\)-groups} );
1245 }
1246
1247 { # syntax checks (W.Laun)
1248   use warnings qw(NONFATAL all);;
1249   my @warning;
1250   local $SIG{__WARN__} = sub {
1251       push( @warning, $_[0] );
1252   };
1253   eval { my $s = pack( 'Ax![4c]A', 1..5 ); };
1254   like( $@, qr{Malformed integer in \[\]} );
1255
1256   eval { my $buf = pack( '(c/*a*)', 'AAA', 'BB' ); };
1257   like( $@, qr{'/' does not take a repeat count} );
1258
1259   eval { my @inf = unpack( 'c/1a', "\x03AAA\x02BB" ); };
1260   like( $@, qr{'/' does not take a repeat count} );
1261
1262   eval { my @inf = unpack( 'c/*a', "\x03AAA\x02BB" ); };
1263   like( $@, qr{'/' does not take a repeat count} );
1264
1265   # white space where possible
1266   my @Env = ( a => 'AAA', b => 'BBB' );
1267   my $env = pack( ' S ( S / A*   S / A* )* ', @Env/2, @Env );
1268   my @pup = unpack( ' S / ( S / A*   S / A* ) ', $env );
1269   is( "@pup", "@Env" );
1270
1271   # white space in 4 wrong places
1272   for my $temp (  'A ![4]', 'A [4]', 'A *', 'A 4' ){
1273       eval { my $s = pack( $temp, 'B' ); };
1274       like( $@, qr{Invalid type } );
1275   }
1276
1277   # warning for commas
1278   @warning = ();
1279   my $x = pack( 'I,A', 4, 'X' );
1280   like( $warning[0], qr{Invalid type ','} );
1281
1282   # comma warning only once
1283   @warning = ();
1284   $x = pack( 'C(C,C)C,C', 65..71  );
1285   cmp_ok( scalar(@warning), '==', 1 );
1286
1287   # forbidden code in []
1288   eval { my $x = pack( 'A[@4]', 'XXXX' ); };
1289   like( $@, qr{Within \[\]-length '\@' not allowed} );
1290
1291   # @ repeat default 1
1292   my $s = pack( 'AA@A', 'A', 'B', 'C' );
1293   my @c = unpack( 'AA@A', $s );
1294   is( $s, 'AC' );
1295   is( "@c", "A C C" );
1296
1297   # no unpack code after /
1298   eval { my @a = unpack( "C/", "\3" ); };
1299   like( $@, qr{Code missing after '/'} );
1300
1301  SKIP: {
1302     skip $no_endianness, 6 if $no_endianness;
1303
1304     # modifier warnings
1305     @warning = ();
1306     $x = pack "I>>s!!", 47, 11;
1307     ($x) = unpack "I<<l!>!>", 'x'x20;
1308     is(scalar @warning, 5);
1309     like($warning[0], qr/Duplicate modifier '>' after 'I' in pack/);
1310     like($warning[1], qr/Duplicate modifier '!' after 's' in pack/);
1311     like($warning[2], qr/Duplicate modifier '<' after 'I' in unpack/);
1312     like($warning[3], qr/Duplicate modifier '!' after 'l' in unpack/);
1313     like($warning[4], qr/Duplicate modifier '>' after 'l' in unpack/);
1314   }
1315 }
1316
1317 {  # Repeat count [SUBEXPR]
1318    my @codes = qw( x A Z a c C W B b H h s v n S i I l V N L p P f F d
1319                    s! S! i! I! l! L! j J);
1320    my $G;
1321    if (eval { pack 'q', 1 } ) {
1322      push @codes, qw(q Q);
1323    } else {
1324      push @codes, qw(s S);      # Keep the count the same
1325    }
1326    if (eval { pack 'D', 1 } ) {
1327      push @codes, 'D';
1328    } else {
1329      push @codes, 'd';  # Keep the count the same
1330    }
1331
1332    push @codes, map { /^[silqjfdp]/i ? ("$_<", "$_>") : () } @codes;
1333
1334    my %val;
1335    @val{@codes} = map { / [Xx]  (?{ undef })
1336                         | [AZa] (?{ 'something' })
1337                         | C     (?{ 214 })
1338                         | W     (?{ 8188 })
1339                         | c     (?{ 114 })
1340                         | [Bb]  (?{ '101' })
1341                         | [Hh]  (?{ 'b8' })
1342                         | [svnSiIlVNLqQjJ]  (?{ 10111 })
1343                         | [FfDd]  (?{ 1.36514538e37 })
1344                         | [pP]  (?{ "try this buffer" })
1345                         /x; $^R } @codes;
1346    my @end = (0x12345678, 0x23456781, 0x35465768, 0x15263748);
1347    my $end = "N4";
1348
1349    for my $type (@codes) {
1350      my @list = $val{$type};
1351      @list = () unless defined $list[0];
1352      for my $count ('', '3', '[11]') {
1353        my $c = 1;
1354        $c = $1 if $count =~ /(\d+)/;
1355        my @list1 = @list;
1356        @list1 = (@list1) x $c unless $type =~ /[XxAaZBbHhP]/;
1357        for my $groupend ('', ')2', ')[8]') {
1358            my $groupbegin = ($groupend ? '(' : '');
1359            $c = 1;
1360            $c = $1 if $groupend =~ /(\d+)/;
1361            my @list2 = (@list1) x $c;
1362
1363            SKIP: {
1364              my $junk1 = "$groupbegin $type$count $groupend";
1365              # print "# junk1=$junk1\n";
1366              my $p = eval { pack $junk1, @list2 };
1367              skip "cannot pack '$type' on this perl", 12
1368                if is_valid_error($@);
1369              die "pack $junk1 failed: $@" if $@;
1370
1371              my $half = int( (length $p)/2 );
1372              for my $move ('', "X$half", "X!$half", 'x1', 'x!8', "x$half") {
1373                my $junk = "$junk1 $move";
1374                # print "# junk='$junk', list=(@list2)\n";
1375                $p = pack "$junk $end", @list2, @end;
1376                my @l = unpack "x[$junk] $end", $p;
1377                is(scalar @l, scalar @end);
1378                is("@l", "@end", "skipping x[$junk]");
1379              }
1380            }
1381        }
1382      }
1383    }
1384 }
1385
1386 # / is recognized after spaces in scalar context
1387 # XXXX no spaces are allowed in pack...  In pack only before the slash...
1388 is(scalar unpack('A /A Z20', pack 'A/A* Z20', 'bcde', 'xxxxx'), 'bcde');
1389 is(scalar unpack('A /A /A Z20', '3004bcde'), 'bcde');
1390
1391 { # X! and x!
1392   my $t = 'C[3]  x!8 C[2]';
1393   my @a = (0x73..0x77);
1394   my $p = pack($t, @a);
1395   is($p, "\x73\x74\x75\0\0\0\0\0\x76\x77");
1396   my @b = unpack $t, $p;
1397   is(scalar @b, scalar @a);
1398   is("@b", "@a", 'x!8');
1399   $t = 'x[5] C[6] X!8 C[2]';
1400   @a = (0x73..0x7a);
1401   $p = pack($t, @a);
1402   is($p, "\0\0\0\0\0\x73\x74\x75\x79\x7a");
1403   @b = unpack $t, $p;
1404   @a = (0x73..0x75, 0x79, 0x7a, 0x79, 0x7a);
1405   is(scalar @b, scalar @a);
1406   is("@b", "@a");
1407 }
1408
1409 { # struct {char c1; double d; char cc[2];}
1410   my $t = 'C x![d] d C[2]';
1411   my @a = (173, 1.283476517e-45, 42, 215);
1412   my $p = pack $t, @a;
1413   ok( length $p);
1414   my @b = unpack "$t X[$t] $t", $p;     # Extract, step back, extract again
1415   is(scalar @b, 2 * scalar @a);
1416   $b = "@b";
1417   $b =~ s/(?:17000+|16999+)\d+(e-0?45) /17$1 /gi; # stringification is gamble
1418   is($b, "@a @a");
1419
1420   use warnings qw(NONFATAL all);;
1421   my $warning;
1422   local $SIG{__WARN__} = sub {
1423       $warning = $_[0];
1424   };
1425   @b = unpack "x[C] x[$t] X[$t] X[C] $t", "$p\0";
1426
1427   is($warning, undef);
1428   is(scalar @b, scalar @a);
1429   $b = "@b";
1430   $b =~ s/(?:17000+|16999+)\d+(e-0?45) /17$1 /gi; # stringification is gamble
1431   is($b, "@a");
1432 }
1433
1434 is(length(pack("j", 0)), $Config{ivsize});
1435 is(length(pack("J", 0)), $Config{uvsize});
1436 is(length(pack("F", 0)), $Config{nvsize});
1437
1438 numbers ('j', -2147483648, -1, 0, 1, 2147483647);
1439 numbers ('J', 0, 1, 2147483647, 2147483648, 4294967295);
1440 numbers ('F', -(2**34), -1, 0, 1, 2**34);
1441 SKIP: {
1442     my $t = eval { unpack("D*", pack("D", 12.34)) };
1443
1444     skip "Long doubles not in use", 166 if $@ =~ /Invalid type/;
1445
1446     is(length(pack("D", 0)), $Config{longdblsize});
1447     numbers ('D', -(2**34), -1, 0, 1, 2**34);
1448 }
1449
1450 # Maybe this knowledge needs to be "global" for all of pack.t
1451 # Or a "can checksum" which would effectively be all the number types"
1452 my %cant_checksum = map {$_=> 1} qw(A Z u w);
1453 # not a b B h H
1454 foreach my $template (qw(A Z c C s S i I l L n N v V q Q j J f d F D u U w)) {
1455   SKIP: {
1456     my $packed = eval {pack "${template}4", 1, 4, 9, 16};
1457     if ($@) {
1458       die unless $@ =~ /Invalid type '$template'/;
1459       skip ("$template not supported on this perl",
1460             $cant_checksum{$template} ? 4 : 8);
1461     }
1462     my @unpack4 = unpack "${template}4", $packed;
1463     my @unpack = unpack "${template}*", $packed;
1464     my @unpack1 = unpack "${template}", $packed;
1465     my @unpack1s = scalar unpack "${template}", $packed;
1466     my @unpack4s = scalar unpack "${template}4", $packed;
1467     my @unpacks = scalar unpack "${template}*", $packed;
1468
1469     my @tests = ( ["${template}4 vs ${template}*", \@unpack4, \@unpack],
1470                   ["scalar ${template} ${template}", \@unpack1s, \@unpack1],
1471                   ["scalar ${template}4 vs ${template}", \@unpack4s, \@unpack1],
1472                   ["scalar ${template}* vs ${template}", \@unpacks, \@unpack1],
1473                 );
1474
1475     unless ($cant_checksum{$template}) {
1476       my @unpack4_c = unpack "\%${template}4", $packed;
1477       my @unpack_c = unpack "\%${template}*", $packed;
1478       my @unpack1_c = unpack "\%${template}", $packed;
1479       my @unpack1s_c = scalar unpack "\%${template}", $packed;
1480       my @unpack4s_c = scalar unpack "\%${template}4", $packed;
1481       my @unpacks_c = scalar unpack "\%${template}*", $packed;
1482
1483       push @tests,
1484         ( ["% ${template}4 vs ${template}*", \@unpack4_c, \@unpack_c],
1485           ["% scalar ${template} ${template}", \@unpack1s_c, \@unpack1_c],
1486           ["% scalar ${template}4 vs ${template}*", \@unpack4s_c, \@unpack_c],
1487           ["% scalar ${template}* vs ${template}*", \@unpacks_c, \@unpack_c],
1488         );
1489     }
1490     foreach my $test (@tests) {
1491       ok (list_eq ($test->[1], $test->[2]), $test->[0]) ||
1492         printf "# unpack gave %s expected %s\n",
1493           encode_list (@{$test->[1]}), encode_list (@{$test->[2]});
1494     }
1495   }
1496 }
1497
1498 ok(pack('u2', 'AA'), "[perl #8026]"); # used to hang and eat RAM in perl 5.7.2
1499
1500 $_ = pack('c', 65); # 'A' would not be EBCDIC-friendly
1501 is(unpack('c'), 65, "one-arg unpack (change #18751)"); # defaulting to $_
1502
1503 {
1504     my $a = "X\x0901234567\n" x 100; # \t would not be EBCDIC TAB
1505     my @a = unpack("(a1 c/a)*", $a);
1506     is(scalar @a, 200,       "[perl #15288]");
1507     is($a[-1], "01234567\n", "[perl #15288]");
1508     is($a[-2], "X",          "[perl #15288]");
1509 }
1510
1511 {
1512     use warnings qw(NONFATAL all);;
1513     my $warning;
1514     local $SIG{__WARN__} = sub {
1515         $warning = $_[0];
1516     };
1517
1518     # This test is looking for the encoding of the bit pattern "\x66\x6f\x6f",
1519     # which is ASCII "foo"
1520     my $out = pack("u99", native_to_uni("foo") x 99);
1521     like($warning, qr/Field too wide in 'u' format in pack at /,
1522          "Warn about too wide uuencode");
1523     is($out, ("_" . "9F]O" x 21 . "\n") x 4 . "M" . "9F]O" x 15 . "\n",
1524        "Use max width in case of too wide uuencode");
1525 }
1526
1527 # checksums
1528 {
1529     # verify that unpack advances correctly wrt a checksum
1530     my (@x) = unpack("b10a", "abcd");
1531     my (@y) = unpack("%b10a", "abcd");
1532     is($x[1], $y[1], "checksum advance ok");
1533
1534     SKIP: {
1535         skip("-- non-IEEE float", 1) if !$Config{d_double_style_ieee};
1536         # verify that the checksum is not overflowed with C0
1537         is(unpack("C0%128U", "abcd"), unpack("U0%128U", "abcd"), "checksum not overflowed");
1538     }
1539 }
1540
1541 my $U_1FFC_bytes = byte_utf8a_to_utf8n("\341\277\274");
1542 {
1543     # U0 and C0 must be scoped
1544     my (@x) = unpack("a(U0)U", "b$U_1FFC_bytes");
1545     is($x[0], 'b', 'before scope');
1546     is($x[1], 8188, 'after scope');
1547
1548     is(pack("a(U0)U", "b", 8188), "b$U_1FFC_bytes");
1549 }
1550
1551 {
1552     # counted length prefixes shouldn't change C0/U0 mode
1553     # (note the length is actually 0 in this test, as the C/ is replaced by C0
1554     # due to the \0 in the string)
1555     is(join(',', unpack("aC/UU",   "b\0$U_1FFC_bytes")), 'b,8188');
1556     is(join(',', unpack("aC/CU",   "b\0$U_1FFC_bytes")), 'b,8188');
1557
1558     # The U expects Unicode, so convert from native
1559     my $first_byte = utf8::native_to_unicode(ord substr($U_1FFC_bytes, 0, 1));
1560
1561     is(join(',', unpack("aU0C/UU", "b\0$U_1FFC_bytes")), "b,$first_byte");
1562     is(join(',', unpack("aU0C/CU", "b\0$U_1FFC_bytes")), "b,$first_byte");
1563 }
1564
1565 {
1566     # "Z0" (bug #34062)
1567     my (@x) = unpack("C*", pack("CZ0", 1, "b"));
1568     is(join(',', @x), '1', 'pack Z0 doesn\'t destroy the character before');
1569 }
1570
1571 {
1572     # Encoding neutrality
1573     # String we will pull apart and rebuild in several ways:
1574     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1575     my $up   = $down;
1576     utf8::upgrade($up);
1577
1578     my %expect =
1579         # [expected result,
1580         #  how many chars it should progress,
1581         #  (optional) expected result of pack]
1582         (a5 => ["\xf8\xf9\xfa\xfb\xfc", 5],
1583          A5 => ["\xf8\xf9\xfa\xfb\xfc", 5],
1584          Z5 => ["\xf8\xf9\xfa\xfb\xfc", 5, "\xf8\xf9\xfa\xfb\x00\xfd"],
1585          b21 => ["000111111001111101011", 3, "\xf8\xf9\x1a\xfb"],
1586          B21 => ["111110001111100111111", 3, "\xf8\xf9\xf8\xfb"],
1587          H5 => ["f8f9f", 3, "\xf8\xf9\xf0\xfb"],
1588          h5 => ["8f9fa", 3, "\xf8\xf9\x0a\xfb"],
1589          "s<"  => [-1544, 2],
1590          "s>"  => [-1799, 2],
1591          "S<"  => [0xf9f8, 2],
1592          "S>"  => [0xf8f9, 2],
1593          "l<"  => [-67438088, 4],
1594          "l>"  => [-117835013, 4],
1595          "L>"  => [0xf8f9fafb, 4],
1596          "L<"  => [0xfbfaf9f8, 4],
1597          n     => [0xf8f9, 2],
1598          N     => [0xf8f9fafb, 4],
1599          v     => [63992, 2],
1600          V     => [0xfbfaf9f8, 4],
1601          c     => [-8, 1],
1602          U0U   => [0xf8, 1],
1603          w     => ["8715569050387726213", 9],
1604          q     => ["-283686952306184", 8],
1605          Q     => ["18446460386757245432", 8],
1606          );
1607
1608     for my $string ($down, $up) {
1609         for my $format (sort {lc($a) cmp lc($b) || $a cmp $b } keys %expect) {
1610           SKIP: {
1611               my $expect = $expect{$format};
1612               # unpack upgraded and downgraded string
1613               my @result = eval { unpack("$format C0 W", $string) };
1614               skip "cannot pack/unpack '$format C0 W' on this perl", 5 if
1615                   $@ && is_valid_error($@);
1616               is(@result, 2, "Two results from unpack $format C0 W");
1617
1618               # pack to downgraded
1619               my $new = pack("$format C0 W", @result);
1620               is(length($new), $expect->[1]+1,
1621                  "pack $format C0 W should give $expect->[1]+1 chars");
1622               is($new, $expect->[2] || substr($string, 0, length $new),
1623                  "pack $format C0 W returns expected value");
1624
1625               # pack to upgraded
1626               $new = pack("a0 $format C0 W", chr(256), @result);
1627               is(length($new), $expect->[1]+1,
1628                  "pack a0 $format C0 W should give $expect->[1]+1 chars");
1629               is($new, $expect->[2] || substr($string, 0, length $new),
1630                  "pack a0 $format C0 W returns expected value");
1631           }
1632         }
1633     }
1634 }
1635
1636 {
1637     # Encoding neutrality, numbers
1638     my $val = -2.68;
1639     for my $format (qw(s S i I l L j J f d F D q Q
1640                        s! S! i! I! l! L! n! N! v! V!)) {
1641       SKIP: {
1642           my $down = eval { pack($format, $val) };
1643           skip "cannot pack/unpack $format on this perl", 9 if
1644               $@ && is_valid_error($@);
1645           ok(!utf8::is_utf8($down), "Simple $format pack doesn't get upgraded");
1646           my $up = pack("a0 $format", chr(256), $val);
1647           ok(utf8::is_utf8($up), "a0 $format with high char leads to upgrade");
1648           is($down, $up, "$format generated strings are equal though");
1649           my @down_expanded = unpack("$format W", $down . chr(0xce));
1650           is(@down_expanded, 2, "Expand to two values");
1651           is($down_expanded[1], 0xce,
1652              "unpack $format left us at the expected position");
1653           my @up_expanded   = unpack("$format W", $up   . chr(0xce));
1654           is(@up_expanded, 2, "Expand to two values");
1655           is($up_expanded[1], 0xce,
1656              "unpack $format left us at the expected position");
1657           is($down_expanded[0], $up_expanded[0], "$format unpack was neutral");
1658           is(pack($format, $down_expanded[0]), $down, "Pack $format undoes unpack $format");
1659       }
1660     }
1661 }
1662
1663 {
1664     # C *is* neutral
1665     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1666     my $up   = $down;
1667     utf8::upgrade($up);
1668     my @down = unpack("C*", $down);
1669     my @expect_down = (0xf8, 0xf9, 0xfa, 0xfb, 0xfc, 0xfd, 0xfe, 0xff, 0x05, 0x06);
1670     is("@down", "@expect_down", "byte expand");
1671     is(pack("C*", @down), $down, "byte join");
1672
1673     my @up   = unpack("C*", $up);
1674     my @expect_up = (0xf8, 0xf9, 0xfa, 0xfb, 0xfc, 0xfd, 0xfe, 0xff, 0x05, 0x06);
1675     is("@up", "@expect_up", "UTF-8 expand");
1676     is(pack("U0C0C*", @up), $up, "UTF-8 join");
1677 }
1678
1679 {
1680     # Harder cases for the neutrality test
1681
1682     # u format
1683     my $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1684     my $up   = $down;
1685     utf8::upgrade($up);
1686     is(pack("u", $down), pack("u", $up), "u pack is neutral");
1687     is(unpack("u", pack("u", $down)), $down, "u unpack to downgraded works");
1688     is(unpack("U0C0u", pack("u", $down)), $up, "u unpack to upgraded works");
1689
1690     # p/P format
1691     # This actually only tests something if the address contains a byte >= 0x80
1692     my $str = "abc\xa5\x00\xfede";
1693     $down = pack("p", $str);
1694     is(pack("P", $str), $down);
1695     is(pack("U0C0p", $str), $down);
1696     is(pack("U0C0P", $str), $down);
1697     is(unpack("p", $down), "abc\xa5", "unpack p downgraded");
1698     $up   = $down;
1699     utf8::upgrade($up);
1700     is(unpack("p", $up), "abc\xa5", "unpack p upgraded");
1701
1702     is(unpack("P7", $down), "abc\xa5\x00\xfed", "unpack P downgraded");
1703     is(unpack("P7", $up),   "abc\xa5\x00\xfed", "unpack P upgraded");
1704
1705     # x, X and @
1706     $down = "\xf8\xf9\xfa\xfb\xfc\xfd\xfe\xff\x05\x06";
1707     $up   = $down;
1708     utf8::upgrade($up);
1709
1710     is(unpack('@4W', $down), 0xfc, "\@positioning on downgraded string");
1711     is(unpack('@4W', $up),   0xfc, "\@positioning on upgraded string");
1712
1713     is(unpack('@4x2W', $down), 0xfe, "x moving on downgraded string");
1714     is(unpack('@4x2W', $up),   0xfe, "x moving on upgraded string");
1715     is(unpack('@4x!4W', $down), 0xfc, "x! moving on downgraded string");
1716     is(unpack('@4x!4W', $up),   0xfc, "x! moving on upgraded string");
1717     is(unpack('@5x!4W', $down), 0x05, "x! moving on downgraded string");
1718     is(unpack('@5x!4W', $up),   0x05, "x! moving on upgraded string");
1719
1720     is(unpack('@4X2W', $down), 0xfa, "X moving on downgraded string");
1721     is(unpack('@4X2W', $up),   0xfa, "X moving on upgraded string");
1722     is(unpack('@4X!4W', $down), 0xfc, "X! moving on downgraded string");
1723     is(unpack('@4X!4W', $up),   0xfc, "X! moving on upgraded string");
1724     is(unpack('@5X!4W', $down), 0xfc, "X! moving on downgraded string");
1725     is(unpack('@5X!4W', $up),   0xfc, "X! moving on upgraded string");
1726     is(unpack('@5X!8W', $down), 0xf8, "X! moving on downgraded string");
1727     is(unpack('@5X!8W', $up),   0xf8, "X! moving on upgraded string");
1728
1729     is(pack("W2x", 0xfa, 0xe3), "\xfa\xe3\x00", "x on downgraded string");
1730     is(pack("W2x!4", 0xfa, 0xe3), "\xfa\xe3\x00\x00",
1731        "x! on downgraded string");
1732     is(pack("W2x!2", 0xfa, 0xe3), "\xfa\xe3", "x! on downgraded string");
1733     is(pack("U0C0W2x", 0xfa, 0xe3), "\xfa\xe3\x00", "x on upgraded string");
1734     is(pack("U0C0W2x!4", 0xfa, 0xe3), "\xfa\xe3\x00\x00",
1735        "x! on upgraded string");
1736     is(pack("U0C0W2x!2", 0xfa, 0xe3), "\xfa\xe3", "x! on upgraded string");
1737     is(pack("W2X", 0xfa, 0xe3), "\xfa", "X on downgraded string");
1738     is(pack("U0C0W2X", 0xfa, 0xe3), "\xfa", "X on upgraded string");
1739     is(pack("W2X!2", 0xfa, 0xe3), "\xfa\xe3", "X! on downgraded string");
1740     is(pack("U0C0W2X!2", 0xfa, 0xe3), "\xfa\xe3", "X! on upgraded string");
1741     is(pack("W3X!2", 0xfa, 0xe3, 0xa6), "\xfa\xe3", "X! on downgraded string");
1742     is(pack("U0C0W3X!2", 0xfa, 0xe3, 0xa6), "\xfa\xe3",
1743        "X! on upgraded string");
1744
1745     # backward eating through a ( moves the group starting point backwards
1746     is(pack("a*(Xa)", "abc", "q"), "abq",
1747        "eating before strbeg moves it back");
1748     is(pack("a*(Xa)", "ab" . chr(512), "q"), "abq",
1749        "eating before strbeg moves it back");
1750
1751     # Check marked_upgrade
1752     is(pack('W(W(Wa@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, "a", 0xa4, 0xa5, 0xa6),
1753        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6");
1754     $up = "a";
1755     utf8::upgrade($up);
1756     is(pack('W(W(Wa@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, $up, 0xa4, 0xa5, 0xa6),
1757        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6", "marked upgrade caused by a");
1758     is(pack('W(W(WW@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, 256, 0xa4, 0xa5, 0xa6),
1759        "\xa1\xa2\xa3\x{100}\x00\xa4\x00\xa5\x00\xa6",
1760        "marked upgrade caused by W");
1761     is(pack('W(W(WU0aC0@3W)@6W)@9W', 0xa1, 0xa2, 0xa3, "a", 0xa4, 0xa5, 0xa6),
1762        "\xa1\xa2\xa3a\x00\xa4\x00\xa5\x00\xa6", "marked upgrade caused by U0");
1763
1764     # a, A and Z
1765     $down = "\xa4\xa6\xa7";
1766     $up   = $down;
1767     utf8::upgrade($up);
1768     utf8::upgrade(my $high = "\xfeb");
1769
1770     for my $format ("a0", "A0", "Z0", "U0a0C0", "U0A0C0", "U0Z0C0") {
1771         is(pack("a* $format a*", "ab", $down, "cd"), "abcd",
1772            "$format format on plain string");
1773         is(pack("a* $format a*", "ab", $up,   "cd"), "abcd",
1774            "$format format on upgraded string");
1775         is(pack("a* $format a*", $high, $down, "cd"), "\xfebcd",
1776            "$format format on plain string");
1777         is(pack("a* $format a*", $high, $up,   "cd"), "\xfebcd",
1778            "$format format on upgraded string");
1779         my @down = unpack("a1 $format a*", "\xfeb");
1780         is("@down", "\xfe  b", "unpack $format");
1781         my @up = unpack("a1 $format a*", $high);
1782         is("@up", "\xfe  b", "unpack $format");
1783     }
1784     is(pack("a1", $high), "\xfe");
1785     is(pack("A1", $high), "\xfe");
1786     is(pack("Z1", $high), "\x00");
1787     is(pack("a2", $high), "\xfeb");
1788     is(pack("A2", $high), "\xfeb");
1789     is(pack("Z2", $high), "\xfe\x00");
1790     is(pack("a5", $high), "\xfeb\x00\x00\x00");
1791     is(pack("A5", $high), "\xfeb   ");
1792     is(pack("Z5", $high), "\xfeb\x00\x00\x00");
1793     is(pack("a*", $high), "\xfeb");
1794     is(pack("A*", $high), "\xfeb");
1795     is(pack("Z*", $high), "\xfeb\x00");
1796
1797     utf8::upgrade($high = byte_utf8a_to_utf8n("\xc3\xbe") . "b");
1798     is(pack("U0a2", $high), uni_to_native("\xfe"));
1799     is(pack("U0A2", $high), uni_to_native("\xfe"));
1800     is(pack("U0Z1", $high), uni_to_native("\x00"));
1801     is(pack("U0a3", $high), uni_to_native("\xfe") . "b");
1802     is(pack("U0A3", $high), uni_to_native("\xfe") . "b");
1803     is(pack("U0Z3", $high), uni_to_native("\xfe\x00"));
1804     is(pack("U0a6", $high), uni_to_native("\xfe") . "b" . uni_to_native("\x00\x00\x00"));
1805     is(pack("U0A6", $high), uni_to_native("\xfe") . "b   ");
1806     is(pack("U0Z6", $high), uni_to_native("\xfe") . "b" . uni_to_native("\x00\x00\x00"));
1807     is(pack("U0a*", $high), uni_to_native("\xfe") . "b");
1808     is(pack("U0A*", $high), uni_to_native("\xfe") . "b");
1809     is(pack("U0Z*", $high), uni_to_native("\xfe") . "b" . uni_to_native("\x00"));
1810 }
1811 {
1812     # pack /
1813     my @array = 1..14;
1814     my @out = unpack("N/S", pack("N/S", @array) . "abcd");
1815     is("@out", "@array", "pack N/S works");
1816     @out = unpack("N/S*", pack("N/S*", @array) . "abcd");
1817     is("@out", "@array", "pack N/S* works");
1818     @out = unpack("N/S*", pack("N/S14", @array) . "abcd");
1819     is("@out", "@array", "pack N/S14 works");
1820     @out = unpack("N/S*", pack("N/S15", @array) . "abcd");
1821     is("@out", "@array", "pack N/S15 works");
1822     @out = unpack("N/S*", pack("N/S13", @array) . "abcd");
1823     is("@out", "@array[0..12]", "pack N/S13 works");
1824     @out = unpack("N/S*", pack("N/S0", @array) . "abcd");
1825     is("@out", "", "pack N/S0 works");
1826     is(pack("Z*/a0", "abc"), "0\0", "pack Z*/a0 makes a short string");
1827     is(pack("Z*/Z0", "abc"), "0\0", "pack Z*/Z0 makes a short string");
1828     is(pack("Z*/a3", "abc"), "3\0abc", "pack Z*/a3 makes a full string");
1829     is(pack("Z*/Z3", "abc"), "3\0ab\0", "pack Z*/Z3 makes a short string");
1830     is(pack("Z*/a5", "abc"), "5\0abc\0\0", "pack Z*/a5 makes a long string");
1831     is(pack("Z*/Z5", "abc"), "5\0abc\0\0", "pack Z*/Z5 makes a long string");
1832     is(pack("Z*/Z"), "1\0\0", "pack Z*/Z makes an extended string");
1833     is(pack("Z*/Z", ""), "1\0\0", "pack Z*/Z makes an extended string");
1834     is(pack("Z*/a", ""), "0\0", "pack Z*/a makes an extended string");
1835 }
1836 {
1837     # unpack("A*", $unicode) strips general unicode spaces
1838     is(unpack("A*", "ab \n" . uni_to_native("\xa0") . " \0"), "ab \n" . uni_to_native("\xa0"),
1839        'normal A* strip leaves \xa0');
1840     is(unpack("U0C0A*", "ab \n" . uni_to_native("\xa0") . " \0"), "ab \n" . uni_to_native("\xa0"),
1841        'normal A* strip leaves \xa0 even if it got upgraded for technical reasons');
1842     is(unpack("A*", pack("a*(U0U)a*", "ab \n", 0xa0, " \0")), "ab",
1843        'upgraded strings A* removes \xa0');
1844     is(unpack("A*", pack("a*(U0UU)a*", "ab \n", 0xa0, 0x1680, " \0")), "ab",
1845        'upgraded strings A* removes all unicode whitespace');
1846     is(unpack("A5", pack("a*(U0U)a*", "ab \n", 0x1680, "def", "ab")), "ab",
1847        'upgraded strings A5 removes all unicode whitespace');
1848     is(unpack("A*", pack("U", 0x1680)), "",
1849        'upgraded strings A* with nothing left');
1850 }
1851 {
1852     # Testing unpack . and .!
1853     is(unpack(".", "ABCD"), 0, "offset at start of string is 0");
1854     is(unpack(".", ""), 0, "offset at start of empty string is 0");
1855     is(unpack("x3.", "ABCDEF"), 3, "simple offset works");
1856     is(unpack("x3.", "ABC"), 3, "simple offset at end of string works");
1857     is(unpack("x3.0", "ABC"), 0, "self offset is 0");
1858     is(unpack("x3(x2.)", "ABCDEF"), 2, "offset is relative to inner group");
1859     is(unpack("x3(X2.)", "ABCDEF"), -2,
1860        "negative offset relative to inner group");
1861     is(unpack("x3(X2.2)", "ABCDEF"), 1, "offset is relative to inner group");
1862     is(unpack("x3(x2.0)", "ABCDEF"), 0, "self offset in group is still 0");
1863     is(unpack("x3(x2.2)", "ABCDEF"), 5, "offset counts groups");
1864     is(unpack("x3(x2.*)", "ABCDEF"), 5, "star offset is relative to start");
1865
1866     my $high = chr(8188) x 6;
1867     is(unpack("x3(x2.)", $high), 2, "utf8 offset is relative to inner group");
1868     is(unpack("x3(X2.)", $high), -2,
1869        "utf8 negative offset relative to inner group");
1870     is(unpack("x3(X2.2)", $high), 1, "utf8 offset counts groups");
1871     is(unpack("x3(x2.0)", $high), 0, "utf8 self offset in group is still 0");
1872     is(unpack("x3(x2.2)", $high), 5, "utf8 offset counts groups");
1873     is(unpack("x3(x2.*)", $high), 5, "utf8 star offset is relative to start");
1874
1875     is(unpack("U0x3(x2.)", $high), 2,
1876        "U0 mode utf8 offset is relative to inner group");
1877     is(unpack("U0x3(X2.)", $high), -2,
1878        "U0 mode utf8 negative offset relative to inner group");
1879     is(unpack("U0x3(X2.2)", $high), 1,
1880        "U0 mode utf8 offset counts groups");
1881     is(unpack("U0x3(x2.0)", $high), 0,
1882        "U0 mode utf8 self offset in group is still 0");
1883     is(unpack("U0x3(x2.2)", $high), 5,
1884        "U0 mode utf8 offset counts groups");
1885     is(unpack("U0x3(x2.*)", $high), 5,
1886        "U0 mode utf8 star offset is relative to start");
1887
1888     is(unpack("x3(x2.!)", $high), 2*3,
1889        "utf8 offset is relative to inner group");
1890     is(unpack("x3(X2.!)", $high), -2*3,
1891        "utf8 negative offset relative to inner group");
1892     is(unpack("x3(X2.!2)", $high), 1*3,
1893        "utf8 offset counts groups");
1894     is(unpack("x3(x2.!0)", $high), 0,
1895        "utf8 self offset in group is still 0");
1896     is(unpack("x3(x2.!2)", $high), 5*3,
1897        "utf8 offset counts groups");
1898     is(unpack("x3(x2.!*)", $high), 5*3,
1899        "utf8 star offset is relative to start");
1900
1901     is(unpack("U0x3(x2.!)", $high), 2,
1902        "U0 mode utf8 offset is relative to inner group");
1903     is(unpack("U0x3(X2.!)", $high), -2,
1904        "U0 mode utf8 negative offset relative to inner group");
1905     is(unpack("U0x3(X2.!2)", $high), 1,
1906        "U0 mode utf8 offset counts groups");
1907     is(unpack("U0x3(x2.!0)", $high), 0,
1908        "U0 mode utf8 self offset in group is still 0");
1909     is(unpack("U0x3(x2.!2)", $high), 5,
1910        "U0 mode utf8 offset counts groups");
1911     is(unpack("U0x3(x2.!*)", $high), 5,
1912        "U0 mode utf8 star offset is relative to start");
1913 }
1914 {
1915     # Testing pack . and .!
1916     is(pack("(a)5 .", 1..5, 3), "123", ". relative to string start, shorten");
1917     eval { () = pack("(a)5 .", 1..5, -3) };
1918     like($@, qr{'\.' outside of string in pack}, "Proper error message");
1919     is(pack("(a)5 .", 1..5, 8), "12345\x00\x00\x00",
1920        ". relative to string start, extend");
1921     is(pack("(a)5 .", 1..5, 5), "12345", ". relative to string start, keep");
1922
1923     is(pack("(a)5 .0", 1..5, -3), "12",
1924        ". relative to string current, shorten");
1925     is(pack("(a)5 .0", 1..5, 2), "12345\x00\x00",
1926        ". relative to string current, extend");
1927     is(pack("(a)5 .0", 1..5, 0), "12345",
1928        ". relative to string current, keep");
1929
1930     is(pack("(a)5 (.)", 1..5, -3), "12",
1931        ". relative to group, shorten");
1932     is(pack("(a)5 (.)", 1..5, 2), "12345\x00\x00",
1933        ". relative to group, extend");
1934     is(pack("(a)5 (.)", 1..5, 0), "12345",
1935        ". relative to group, keep");
1936
1937     is(pack("(a)3 ((a)2 .)", 1..5, -2), "1",
1938        ". relative to group, shorten");
1939     is(pack("(a)3 ((a)2 .)", 1..5, 2), "12345",
1940        ". relative to group, keep");
1941     is(pack("(a)3 ((a)2 .)", 1..5, 4), "12345\x00\x00",
1942        ". relative to group, extend");
1943
1944     is(pack("(a)3 ((a)2 .2)", 1..5, 2), "12",
1945        ". relative to counted group, shorten");
1946     is(pack("(a)3 ((a)2 .2)", 1..5, 7), "12345\x00\x00",
1947        ". relative to counted group, extend");
1948     is(pack("(a)3 ((a)2 .2)", 1..5, 5), "12345",
1949        ". relative to counted group, keep");
1950
1951     is(pack("(a)3 ((a)2 .*)", 1..5, 2), "12",
1952        ". relative to start, shorten");
1953     is(pack("(a)3 ((a)2 .*)", 1..5, 7), "12345\x00\x00",
1954        ". relative to start, extend");
1955     is(pack("(a)3 ((a)2 .*)", 1..5, 5), "12345",
1956        ". relative to start, keep");
1957
1958     is(pack('(a)5 (. @2 a)', 1..5, -3, "a"), "12\x00\x00a",
1959        ". based shrink properly updates group starts");
1960
1961     is(pack("(W)3 ((W)2 .)", 0x301..0x305, -2), "\x{301}",
1962        "utf8 . relative to group, shorten");
1963     is(pack("(W)3 ((W)2 .)", 0x301..0x305, 2),
1964        "\x{301}\x{302}\x{303}\x{304}\x{305}",
1965        "utf8 . relative to group, keep");
1966     is(pack("(W)3 ((W)2 .)", 0x301..0x305, 4),
1967        "\x{301}\x{302}\x{303}\x{304}\x{305}\x00\x00",
1968        "utf8 . relative to group, extend");
1969
1970     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, -2), "\x{301}\x{302}",
1971        "utf8 . relative to group, shorten");
1972     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, 4),
1973        "\x{301}\x{302}\x{303}\x{304}\x{305}",
1974        "utf8 . relative to group, keep");
1975     is(pack("(W)3 ((W)2 .!)", 0x301..0x305, 6),
1976        "\x{301}\x{302}\x{303}\x{304}\x{305}\x00\x00",
1977        "utf8 . relative to group, extend");
1978
1979     is(pack('(W)5 (. @2 a)', 0x301..0x305, -3, "a"),
1980        "\x{301}\x{302}\x00\x00a",
1981        "utf8 . based shrink properly updates group starts");
1982 }
1983 {
1984     # Testing @!
1985     is(pack('a* @3',  "abcde"), "abc", 'Test basic @');
1986     is(pack('a* @!3', "abcde"), "abc", 'Test basic @!');
1987     is(pack('a* @2', "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{301}\x{302}",
1988        'Test basic utf8 @');
1989     is(pack('a* @!2', "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{301}",
1990        'Test basic utf8 @!');
1991
1992     is(unpack('@4 a*',  "abcde"), "e", 'Test basic @');
1993     is(unpack('@!4 a*', "abcde"), "e", 'Test basic @!');
1994     is(unpack('@4 a*',  "\x{301}\x{302}\x{303}\x{304}\x{305}"), "\x{305}",
1995        'Test basic utf8 @');
1996     is(unpack('@!4 a*', "\x{301}\x{302}\x{303}\x{304}\x{305}"),
1997        "\x{303}\x{304}\x{305}", 'Test basic utf8 @!');
1998 }
1999 {
2000     #50256
2001     # This test is for the bit pattern "\x61\x62", which is ASCII "ab"
2002     my ($v) = split //, unpack ('(B)*', native_to_uni('ab'));
2003     is($v, 0); # Doesn't SEGV :-)
2004 }
2005 {
2006     #73814
2007     my $x = runperl( prog => 'print split( /,/, unpack(q(%2H*), q(hello world))), qq(\n)' );
2008     is($x, "0\n", "split /a/, unpack('%2H*'...) didn't crash");
2009
2010     my $y = runperl( prog => 'print split( /,/, unpack(q(%32u*), q(#,3,Q)), qq(\n)), qq(\n)' );
2011     is($y, "0\n", "split /a/, unpack('%32u*'...) didn't crash");
2012 }
2013
2014 #90160
2015 is(eval { () = unpack "C0 U*", ""; "ok" }, "ok",
2016   'medial U* on empty string');
2017
2018 package o {
2019     use overload
2020         '""' => sub { ++$o::str; "42" },
2021         '0+' => sub { ++$o::num; 42 };
2022 }
2023 is pack("c", bless [], "o"), chr(42), 'overloading called';
2024 is $o::str, undef, 'pack "c" does not call string overloading';
2025 is $o::num, 1,     'pack "c" does call num overloading';
2026
2027 #[perl #123874]: argument underflow leads to corrupt length
2028 eval q{ pack "pi/x" };
2029 ok(1, "argument underflow did not crash");
2030
2031 {
2032     # [perl #126325] pack [hH] with a unicode string
2033     # the hex encoders would read past the end of the string, using
2034     # invalid source bytes
2035     my $twenty_nuls = "\0" x 20;
2036     # This is the case that failed
2037     is(pack("WH40", 0x100, ""), "\x{100}$twenty_nuls",
2038        "check pack H zero fills (utf8 target)");
2039     my $up_nul = "\0";
2040
2041     utf8::upgrade($up_nul);
2042     # check the other combinations too
2043     is(pack("WH40", 0x100, $up_nul), "\x{100}$twenty_nuls",
2044        "check pack H zero fills (utf8 target/source)");
2045     is(pack("H40", ""), $twenty_nuls,
2046        "check pack H zero fills (utf8 none)");
2047     is(pack("H40", $up_nul), $twenty_nuls,
2048        "check pack H zero fills (utf8 source)");
2049 }
2050
2051 SKIP:
2052 {
2053     # [perl #129149] the code below would write one past the end of the output
2054     # buffer, only detected by ASAN, not by valgrind
2055     $Config{ivsize} >= 8
2056       or skip "[perl #129149] need 64-bit for this test", 1;
2057     fresh_perl_is(<<'EOS', "ok\n", { stderr => 1 }, "pack W overflow");
2058 print pack("ucW", "0000", 0, 140737488355327) eq "\$,#`P,```\n\0\x{7fffffffffff}"
2059  ? "ok\n" : "not ok\n";
2060 EOS
2061 }
2062
2063 SKIP:
2064 {
2065   # [perl #131844] pointer addition overflow
2066     $Config{ptrsize} == 4
2067       or skip "[perl #131844] need 32-bit build for this test", 4;
2068     # prevent ASAN just crashing on the allocation failure
2069     local $ENV{ASAN_OPTIONS} = $ENV{ASAN_OPTIONS};
2070     $ENV{ASAN_OPTIONS} .= ",allocator_may_return_null=1";
2071     fresh_perl_like('pack "f999999999"', qr/Out of memory during pack/, { stderr => 1 },
2072                     "pointer addition overflow");
2073
2074     # integer (STRLEN) overflow from addition of glen to current length
2075     fresh_perl_like('pack "c10f1073741823"', qr/Out of memory during pack/, { stderr => 1 },
2076                     "integer overflow calculating allocation (addition)");
2077
2078     fresh_perl_like('pack "W10f536870913", 256', qr/Out of memory during pack/, { stderr => 1 },
2079                     "integer overflow calculating allocation (utf8)");
2080
2081     fresh_perl_like('pack "c10f1073741824"', qr/Out of memory during pack/, { stderr => 1 },
2082                     "integer overflow calculating allocation (multiply)");
2083 }
2084
2085 {
2086     # [perl #132655] heap-buffer-overflow READ of size 11
2087     # only expect failure under ASAN (and maybe valgrind)
2088     fresh_perl_is('0.0 + unpack("u", "ab")', "", { stderr => 1 },
2089                   "ensure unpack u of invalid data nul terminates result");
2090 }