Put a watchdog on openpid.t: it has been found to hang in some Win32 smokes.
[perl.git] / pod / perluniintro.pod
1 =head1 NAME
2
3 perluniintro - Perl Unicode introduction
4
5 =head1 DESCRIPTION
6
7 This document gives a general idea of Unicode and how to use Unicode
8 in Perl.
9
10 =head2 Unicode
11
12 Unicode is a character set standard which plans to codify all of the
13 writing systems of the world, plus many other symbols.
14
15 Unicode and ISO/IEC 10646 are coordinated standards that provide code
16 points for characters in almost all modern character set standards,
17 covering more than 30 writing systems and hundreds of languages,
18 including all commercially-important modern languages.  All characters
19 in the largest Chinese, Japanese, and Korean dictionaries are also
20 encoded. The standards will eventually cover almost all characters in
21 more than 250 writing systems and thousands of languages.
22 Unicode 1.0 was released in October 1991, and 4.0 in April 2003.
23
24 A Unicode I<character> is an abstract entity.  It is not bound to any
25 particular integer width, especially not to the C language C<char>.
26 Unicode is language-neutral and display-neutral: it does not encode the
27 language of the text and it does not generally define fonts or other graphical
28 layout details.  Unicode operates on characters and on text built from
29 those characters.
30
31 Unicode defines characters like C<LATIN CAPITAL LETTER A> or C<GREEK
32 SMALL LETTER ALPHA> and unique numbers for the characters, in this
33 case 0x0041 and 0x03B1, respectively.  These unique numbers are called
34 I<code points>.
35
36 The Unicode standard prefers using hexadecimal notation for the code
37 points.  If numbers like C<0x0041> are unfamiliar to you, take a peek
38 at a later section, L</"Hexadecimal Notation">.  The Unicode standard
39 uses the notation C<U+0041 LATIN CAPITAL LETTER A>, to give the
40 hexadecimal code point and the normative name of the character.
41
42 Unicode also defines various I<properties> for the characters, like
43 "uppercase" or "lowercase", "decimal digit", or "punctuation";
44 these properties are independent of the names of the characters.
45 Furthermore, various operations on the characters like uppercasing,
46 lowercasing, and collating (sorting) are defined.
47
48 A Unicode character consists either of a single code point, or a
49 I<base character> (like C<LATIN CAPITAL LETTER A>), followed by one or
50 more I<modifiers> (like C<COMBINING ACUTE ACCENT>).  This sequence of
51 base character and modifiers is called a I<combining character
52 sequence>.
53
54 Whether to call these combining character sequences "characters"
55 depends on your point of view. If you are a programmer, you probably
56 would tend towards seeing each element in the sequences as one unit,
57 or "character".  The whole sequence could be seen as one "character",
58 however, from the user's point of view, since that's probably what it
59 looks like in the context of the user's language.
60
61 With this "whole sequence" view of characters, the total number of
62 characters is open-ended. But in the programmer's "one unit is one
63 character" point of view, the concept of "characters" is more
64 deterministic.  In this document, we take that second  point of view:
65 one "character" is one Unicode code point, be it a base character or
66 a combining character.
67
68 For some combinations, there are I<precomposed> characters.
69 C<LATIN CAPITAL LETTER A WITH ACUTE>, for example, is defined as
70 a single code point.  These precomposed characters are, however,
71 only available for some combinations, and are mainly
72 meant to support round-trip conversions between Unicode and legacy
73 standards (like the ISO 8859).  In the general case, the composing
74 method is more extensible.  To support conversion between
75 different compositions of the characters, various I<normalization
76 forms> to standardize representations are also defined.
77
78 Because of backward compatibility with legacy encodings, the "a unique
79 number for every character" idea breaks down a bit: instead, there is
80 "at least one number for every character".  The same character could
81 be represented differently in several legacy encodings.  The
82 converse is also not true: some code points do not have an assigned
83 character.  Firstly, there are unallocated code points within
84 otherwise used blocks.  Secondly, there are special Unicode control
85 characters that do not represent true characters.
86
87 A common myth about Unicode is that it would be "16-bit", that is,
88 Unicode is only represented as C<0x10000> (or 65536) characters from
89 C<0x0000> to C<0xFFFF>.  B<This is untrue.>  Since Unicode 2.0 (July
90 1996), Unicode has been defined all the way up to 21 bits (C<0x10FFFF>),
91 and since Unicode 3.1 (March 2001), characters have been defined
92 beyond C<0xFFFF>.  The first C<0x10000> characters are called the
93 I<Plane 0>, or the I<Basic Multilingual Plane> (BMP).  With Unicode
94 3.1, 17 (yes, seventeen) planes in all were defined--but they are
95 nowhere near full of defined characters, yet.
96
97 Another myth is that the 256-character blocks have something to
98 do with languages--that each block would define the characters used
99 by a language or a set of languages.  B<This is also untrue.>
100 The division into blocks exists, but it is almost completely
101 accidental--an artifact of how the characters have been and
102 still are allocated.  Instead, there is a concept called I<scripts>,
103 which is more useful: there is C<Latin> script, C<Greek> script, and
104 so on.  Scripts usually span varied parts of several blocks.
105 For further information see L<Unicode::UCD>.
106
107 The Unicode code points are just abstract numbers.  To input and
108 output these abstract numbers, the numbers must be I<encoded> or
109 I<serialised> somehow.  Unicode defines several I<character encoding
110 forms>, of which I<UTF-8> is perhaps the most popular.  UTF-8 is a
111 variable length encoding that encodes Unicode characters as 1 to 6
112 bytes (only 4 with the currently defined characters).  Other encodings
113 include UTF-16 and UTF-32 and their big- and little-endian variants
114 (UTF-8 is byte-order independent) The ISO/IEC 10646 defines the UCS-2
115 and UCS-4 encoding forms.
116
117 For more information about encodings--for instance, to learn what
118 I<surrogates> and I<byte order marks> (BOMs) are--see L<perlunicode>.
119
120 =head2 Perl's Unicode Support
121
122 Starting from Perl 5.6.0, Perl has had the capacity to handle Unicode
123 natively.  Perl 5.8.0, however, is the first recommended release for
124 serious Unicode work.  The maintenance release 5.6.1 fixed many of the
125 problems of the initial Unicode implementation, but for example
126 regular expressions still do not work with Unicode in 5.6.1.
127
128 B<Starting from Perl 5.8.0, the use of C<use utf8> is needed only in much more restricted circumstances.> In earlier releases the C<utf8> pragma was used to declare
129 that operations in the current block or file would be Unicode-aware.
130 This model was found to be wrong, or at least clumsy: the "Unicodeness"
131 is now carried with the data, instead of being attached to the
132 operations.  Only one case remains where an explicit C<use utf8> is
133 needed: if your Perl script itself is encoded in UTF-8, you can use
134 UTF-8 in your identifier names, and in string and regular expression
135 literals, by saying C<use utf8>.  This is not the default because
136 scripts with legacy 8-bit data in them would break.  See L<utf8>.
137
138 =head2 Perl's Unicode Model
139
140 Perl supports both pre-5.6 strings of eight-bit native bytes, and
141 strings of Unicode characters.  The principle is that Perl tries to
142 keep its data as eight-bit bytes for as long as possible, but as soon
143 as Unicodeness cannot be avoided, the data is transparently upgraded
144 to Unicode.
145
146 Internally, Perl currently uses either whatever the native eight-bit
147 character set of the platform (for example Latin-1) is, defaulting to
148 UTF-8, to encode Unicode strings. Specifically, if all code points in
149 the string are C<0xFF> or less, Perl uses the native eight-bit
150 character set.  Otherwise, it uses UTF-8.
151
152 A user of Perl does not normally need to know nor care how Perl
153 happens to encode its internal strings, but it becomes relevant when
154 outputting Unicode strings to a stream without a PerlIO layer -- one with
155 the "default" encoding.  In such a case, the raw bytes used internally
156 (the native character set or UTF-8, as appropriate for each string)
157 will be used, and a "Wide character" warning will be issued if those
158 strings contain a character beyond 0x00FF.
159
160 For example,
161
162       perl -e 'print "\x{DF}\n", "\x{0100}\x{DF}\n"'
163
164 produces a fairly useless mixture of native bytes and UTF-8, as well
165 as a warning:
166
167      Wide character in print at ...
168
169 To output UTF-8, use the C<:encoding> or C<:utf8> output layer.  Prepending
170
171       binmode(STDOUT, ":utf8");
172
173 to this sample program ensures that the output is completely UTF-8,
174 and removes the program's warning.
175
176 You can enable automatic UTF-8-ification of your standard file
177 handles, default C<open()> layer, and C<@ARGV> by using either
178 the C<-C> command line switch or the C<PERL_UNICODE> environment
179 variable, see L<perlrun> for the documentation of the C<-C> switch.
180
181 Note that this means that Perl expects other software to work, too:
182 if Perl has been led to believe that STDIN should be UTF-8, but then
183 STDIN coming in from another command is not UTF-8, Perl will complain
184 about the malformed UTF-8.
185
186 All features that combine Unicode and I/O also require using the new
187 PerlIO feature.  Almost all Perl 5.8 platforms do use PerlIO, though:
188 you can see whether yours is by running "perl -V" and looking for
189 C<useperlio=define>.
190
191 =head2 Unicode and EBCDIC
192
193 Perl 5.8.0 also supports Unicode on EBCDIC platforms.  There,
194 Unicode support is somewhat more complex to implement since
195 additional conversions are needed at every step.  Some problems
196 remain, see L<perlebcdic> for details.
197
198 In any case, the Unicode support on EBCDIC platforms is better than
199 in the 5.6 series, which didn't work much at all for EBCDIC platform.
200 On EBCDIC platforms, the internal Unicode encoding form is UTF-EBCDIC
201 instead of UTF-8.  The difference is that as UTF-8 is "ASCII-safe" in
202 that ASCII characters encode to UTF-8 as-is, while UTF-EBCDIC is
203 "EBCDIC-safe".
204
205 =head2 Creating Unicode
206
207 To create Unicode characters in literals for code points above C<0xFF>,
208 use the C<\x{...}> notation in double-quoted strings:
209
210     my $smiley = "\x{263a}";
211
212 Similarly, it can be used in regular expression literals
213
214     $smiley =~ /\x{263a}/;
215
216 At run-time you can use C<chr()>:
217
218     my $hebrew_alef = chr(0x05d0);
219
220 See L</"Further Resources"> for how to find all these numeric codes.
221
222 Naturally, C<ord()> will do the reverse: it turns a character into
223 a code point.
224
225 Note that C<\x..> (no C<{}> and only two hexadecimal digits), C<\x{...}>,
226 and C<chr(...)> for arguments less than C<0x100> (decimal 256)
227 generate an eight-bit character for backward compatibility with older
228 Perls.  For arguments of C<0x100> or more, Unicode characters are
229 always produced. If you want to force the production of Unicode
230 characters regardless of the numeric value, use C<pack("U", ...)>
231 instead of C<\x..>, C<\x{...}>, or C<chr()>.
232
233 You can also use the C<charnames> pragma to invoke characters
234 by name in double-quoted strings:
235
236     use charnames ':full';
237     my $arabic_alef = "\N{ARABIC LETTER ALEF}";
238
239 And, as mentioned above, you can also C<pack()> numbers into Unicode
240 characters:
241
242    my $georgian_an  = pack("U", 0x10a0);
243
244 Note that both C<\x{...}> and C<\N{...}> are compile-time string
245 constants: you cannot use variables in them.  if you want similar
246 run-time functionality, use C<chr()> and C<charnames::vianame()>.
247
248 If you want to force the result to Unicode characters, use the special
249 C<"U0"> prefix.  It consumes no arguments but causes the following bytes
250 to be interpreted as the UTF-8 encoding of Unicode characters:
251
252    my $chars = pack("U0W*", 0x80, 0x42);
253
254 Likewise, you can stop such UTF-8 interpretation by using the special
255 C<"C0"> prefix.
256
257 =head2 Handling Unicode
258
259 Handling Unicode is for the most part transparent: just use the
260 strings as usual.  Functions like C<index()>, C<length()>, and
261 C<substr()> will work on the Unicode characters; regular expressions
262 will work on the Unicode characters (see L<perlunicode> and L<perlretut>).
263
264 Note that Perl considers combining character sequences to be
265 separate characters, so for example
266
267     use charnames ':full';
268     print length("\N{LATIN CAPITAL LETTER A}\N{COMBINING ACUTE ACCENT}"), "\n";
269
270 will print 2, not 1.  The only exception is that regular expressions
271 have C<\X> for matching a combining character sequence.
272
273 Life is not quite so transparent, however, when working with legacy
274 encodings, I/O, and certain special cases:
275
276 =head2 Legacy Encodings
277
278 When you combine legacy data and Unicode the legacy data needs
279 to be upgraded to Unicode.  Normally ISO 8859-1 (or EBCDIC, if
280 applicable) is assumed.
281
282 The C<Encode> module knows about many encodings and has interfaces
283 for doing conversions between those encodings:
284
285     use Encode 'decode';
286     $data = decode("iso-8859-3", $data); # convert from legacy to utf-8
287
288 =head2 Unicode I/O
289
290 Normally, writing out Unicode data
291
292     print FH $some_string_with_unicode, "\n";
293
294 produces raw bytes that Perl happens to use to internally encode the
295 Unicode string.  Perl's internal encoding depends on the system as
296 well as what characters happen to be in the string at the time. If
297 any of the characters are at code points C<0x100> or above, you will get
298 a warning.  To ensure that the output is explicitly rendered in the
299 encoding you desire--and to avoid the warning--open the stream with
300 the desired encoding. Some examples:
301
302     open FH, ">:utf8", "file";
303
304     open FH, ">:encoding(ucs2)",      "file";
305     open FH, ">:encoding(UTF-8)",     "file";
306     open FH, ">:encoding(shift_jis)", "file";
307
308 and on already open streams, use C<binmode()>:
309
310     binmode(STDOUT, ":utf8");
311
312     binmode(STDOUT, ":encoding(ucs2)");
313     binmode(STDOUT, ":encoding(UTF-8)");
314     binmode(STDOUT, ":encoding(shift_jis)");
315
316 The matching of encoding names is loose: case does not matter, and
317 many encodings have several aliases.  Note that the C<:utf8> layer
318 must always be specified exactly like that; it is I<not> subject to
319 the loose matching of encoding names. Also note that C<:utf8> is unsafe for
320 input, because it accepts the data without validating that it is indeed valid
321 UTF8.
322
323 See L<PerlIO> for the C<:utf8> layer, L<PerlIO::encoding> and
324 L<Encode::PerlIO> for the C<:encoding()> layer, and
325 L<Encode::Supported> for many encodings supported by the C<Encode>
326 module.
327
328 Reading in a file that you know happens to be encoded in one of the
329 Unicode or legacy encodings does not magically turn the data into
330 Unicode in Perl's eyes.  To do that, specify the appropriate
331 layer when opening files
332
333     open(my $fh,'<:encoding(utf8)', 'anything');
334     my $line_of_unicode = <$fh>;
335
336     open(my $fh,'<:encoding(Big5)', 'anything');
337     my $line_of_unicode = <$fh>;
338
339 The I/O layers can also be specified more flexibly with
340 the C<open> pragma.  See L<open>, or look at the following example.
341
342     use open ':encoding(utf8)'; # input/output default encoding will be UTF-8
343     open X, ">file";
344     print X chr(0x100), "\n";
345     close X;
346     open Y, "<file";
347     printf "%#x\n", ord(<Y>); # this should print 0x100
348     close Y;
349
350 With the C<open> pragma you can use the C<:locale> layer
351
352     BEGIN { $ENV{LC_ALL} = $ENV{LANG} = 'ru_RU.KOI8-R' }
353     # the :locale will probe the locale environment variables like LC_ALL
354     use open OUT => ':locale'; # russki parusski
355     open(O, ">koi8");
356     print O chr(0x430); # Unicode CYRILLIC SMALL LETTER A = KOI8-R 0xc1
357     close O;
358     open(I, "<koi8");
359     printf "%#x\n", ord(<I>), "\n"; # this should print 0xc1
360     close I;
361
362 These methods install a transparent filter on the I/O stream that
363 converts data from the specified encoding when it is read in from the
364 stream.  The result is always Unicode.
365
366 The L<open> pragma affects all the C<open()> calls after the pragma by
367 setting default layers.  If you want to affect only certain
368 streams, use explicit layers directly in the C<open()> call.
369
370 You can switch encodings on an already opened stream by using
371 C<binmode()>; see L<perlfunc/binmode>.
372
373 The C<:locale> does not currently (as of Perl 5.8.0) work with
374 C<open()> and C<binmode()>, only with the C<open> pragma.  The
375 C<:utf8> and C<:encoding(...)> methods do work with all of C<open()>,
376 C<binmode()>, and the C<open> pragma.
377
378 Similarly, you may use these I/O layers on output streams to
379 automatically convert Unicode to the specified encoding when it is
380 written to the stream. For example, the following snippet copies the
381 contents of the file "text.jis" (encoded as ISO-2022-JP, aka JIS) to
382 the file "text.utf8", encoded as UTF-8:
383
384     open(my $nihongo, '<:encoding(iso-2022-jp)', 'text.jis');
385     open(my $unicode, '>:utf8',                  'text.utf8');
386     while (<$nihongo>) { print $unicode $_ }
387
388 The naming of encodings, both by the C<open()> and by the C<open>
389 pragma allows for flexible names: C<koi8-r> and C<KOI8R> will both be
390 understood.
391
392 Common encodings recognized by ISO, MIME, IANA, and various other
393 standardisation organisations are recognised; for a more detailed
394 list see L<Encode::Supported>.
395
396 C<read()> reads characters and returns the number of characters.
397 C<seek()> and C<tell()> operate on byte counts, as do C<sysread()>
398 and C<sysseek()>.
399
400 Notice that because of the default behaviour of not doing any
401 conversion upon input if there is no default layer,
402 it is easy to mistakenly write code that keeps on expanding a file
403 by repeatedly encoding the data:
404
405     # BAD CODE WARNING
406     open F, "file";
407     local $/; ## read in the whole file of 8-bit characters
408     $t = <F>;
409     close F;
410     open F, ">:encoding(utf8)", "file";
411     print F $t; ## convert to UTF-8 on output
412     close F;
413
414 If you run this code twice, the contents of the F<file> will be twice
415 UTF-8 encoded.  A C<use open ':encoding(utf8)'> would have avoided the
416 bug, or explicitly opening also the F<file> for input as UTF-8.
417
418 B<NOTE>: the C<:utf8> and C<:encoding> features work only if your
419 Perl has been built with the new PerlIO feature (which is the default
420 on most systems).
421
422 =head2 Displaying Unicode As Text
423
424 Sometimes you might want to display Perl scalars containing Unicode as
425 simple ASCII (or EBCDIC) text.  The following subroutine converts
426 its argument so that Unicode characters with code points greater than
427 255 are displayed as C<\x{...}>, control characters (like C<\n>) are
428 displayed as C<\x..>, and the rest of the characters as themselves:
429
430    sub nice_string {
431        join("",
432          map { $_ > 255 ?                  # if wide character...
433                sprintf("\\x{%04X}", $_) :  # \x{...}
434                chr($_) =~ /[[:cntrl:]]/ ?  # else if control character ...
435                sprintf("\\x%02X", $_) :    # \x..
436                quotemeta(chr($_))          # else quoted or as themselves
437          } unpack("W*", $_[0]));           # unpack Unicode characters
438    }
439
440 For example,
441
442    nice_string("foo\x{100}bar\n")
443
444 returns the string
445
446    'foo\x{0100}bar\x0A'
447
448 which is ready to be printed.
449
450 =head2 Special Cases
451
452 =over 4
453
454 =item *
455
456 Bit Complement Operator ~ And vec()
457
458 The bit complement operator C<~> may produce surprising results if
459 used on strings containing characters with ordinal values above
460 255. In such a case, the results are consistent with the internal
461 encoding of the characters, but not with much else. So don't do
462 that. Similarly for C<vec()>: you will be operating on the
463 internally-encoded bit patterns of the Unicode characters, not on
464 the code point values, which is very probably not what you want.
465
466 =item *
467
468 Peeking At Perl's Internal Encoding
469
470 Normal users of Perl should never care how Perl encodes any particular
471 Unicode string (because the normal ways to get at the contents of a
472 string with Unicode--via input and output--should always be via
473 explicitly-defined I/O layers). But if you must, there are two
474 ways of looking behind the scenes.
475
476 One way of peeking inside the internal encoding of Unicode characters
477 is to use C<unpack("C*", ...> to get the bytes of whatever the string
478 encoding happens to be, or C<unpack("U0..", ...)> to get the bytes of the
479 UTF-8 encoding:
480
481     # this prints  c4 80  for the UTF-8 bytes 0xc4 0x80
482     print join(" ", unpack("U0(H2)*", pack("U", 0x100))), "\n";
483
484 Yet another way would be to use the Devel::Peek module:
485
486     perl -MDevel::Peek -e 'Dump(chr(0x100))'
487
488 That shows the C<UTF8> flag in FLAGS and both the UTF-8 bytes
489 and Unicode characters in C<PV>.  See also later in this document
490 the discussion about the C<utf8::is_utf8()> function.
491
492 =back
493
494 =head2 Advanced Topics
495
496 =over 4
497
498 =item *
499
500 String Equivalence
501
502 The question of string equivalence turns somewhat complicated
503 in Unicode: what do you mean by "equal"?
504
505 (Is C<LATIN CAPITAL LETTER A WITH ACUTE> equal to
506 C<LATIN CAPITAL LETTER A>?)
507
508 The short answer is that by default Perl compares equivalence (C<eq>,
509 C<ne>) based only on code points of the characters.  In the above
510 case, the answer is no (because 0x00C1 != 0x0041).  But sometimes, any
511 CAPITAL LETTER As should be considered equal, or even As of any case.
512
513 The long answer is that you need to consider character normalization
514 and casing issues: see L<Unicode::Normalize>, Unicode Technical
515 Reports #15 and #21, I<Unicode Normalization Forms> and I<Case
516 Mappings>, L<http://www.unicode.org/unicode/reports/tr15/> and
517 L<http://www.unicode.org/unicode/reports/tr21/>
518
519 As of Perl 5.8.0, the "Full" case-folding of I<Case
520 Mappings/SpecialCasing> is implemented.
521
522 =item *
523
524 String Collation
525
526 People like to see their strings nicely sorted--or as Unicode
527 parlance goes, collated.  But again, what do you mean by collate?
528
529 (Does C<LATIN CAPITAL LETTER A WITH ACUTE> come before or after
530 C<LATIN CAPITAL LETTER A WITH GRAVE>?)
531
532 The short answer is that by default, Perl compares strings (C<lt>,
533 C<le>, C<cmp>, C<ge>, C<gt>) based only on the code points of the
534 characters.  In the above case, the answer is "after", since
535 C<0x00C1> > C<0x00C0>.
536
537 The long answer is that "it depends", and a good answer cannot be
538 given without knowing (at the very least) the language context.
539 See L<Unicode::Collate>, and I<Unicode Collation Algorithm>
540 L<http://www.unicode.org/unicode/reports/tr10/>
541
542 =back
543
544 =head2 Miscellaneous
545
546 =over 4
547
548 =item *
549
550 Character Ranges and Classes
551
552 Character ranges in regular expression character classes (C</[a-z]/>)
553 and in the C<tr///> (also known as C<y///>) operator are not magically
554 Unicode-aware.  What this means is that C<[A-Za-z]> will not magically start
555 to mean "all alphabetic letters"; not that it does mean that even for
556 8-bit characters, you should be using C</[[:alpha:]]/> in that case.
557
558 For specifying character classes like that in regular expressions,
559 you can use the various Unicode properties--C<\pL>, or perhaps
560 C<\p{Alphabetic}>, in this particular case.  You can use Unicode
561 code points as the end points of character ranges, but there is no
562 magic associated with specifying a certain range.  For further
563 information--there are dozens of Unicode character classes--see
564 L<perlunicode>.
565
566 =item *
567
568 String-To-Number Conversions
569
570 Unicode does define several other decimal--and numeric--characters
571 besides the familiar 0 to 9, such as the Arabic and Indic digits.
572 Perl does not support string-to-number conversion for digits other
573 than ASCII 0 to 9 (and ASCII a to f for hexadecimal).
574
575 =back
576
577 =head2 Questions With Answers
578
579 =over 4
580
581 =item *
582
583 Will My Old Scripts Break?
584
585 Very probably not.  Unless you are generating Unicode characters
586 somehow, old behaviour should be preserved.  About the only behaviour
587 that has changed and which could start generating Unicode is the old
588 behaviour of C<chr()> where supplying an argument more than 255
589 produced a character modulo 255.  C<chr(300)>, for example, was equal
590 to C<chr(45)> or "-" (in ASCII), now it is LATIN CAPITAL LETTER I WITH
591 BREVE.
592
593 =item *
594
595 How Do I Make My Scripts Work With Unicode?
596
597 Very little work should be needed since nothing changes until you
598 generate Unicode data.  The most important thing is getting input as
599 Unicode; for that, see the earlier I/O discussion.
600
601 =item *
602
603 How Do I Know Whether My String Is In Unicode?
604
605 You shouldn't have to care.  But you may, because currently the semantics of the
606 characters whose ordinals are in the range 128 to 255 is different depending on
607 whether the string they are contained within is in Unicode or not.
608 (See L<perlunicode>.) 
609
610 To determine if a string is in Unicode, use:
611
612     print utf8::is_utf8($string) ? 1 : 0, "\n";
613
614 But note that this doesn't mean that any of the characters in the
615 string are necessary UTF-8 encoded, or that any of the characters have
616 code points greater than 0xFF (255) or even 0x80 (128), or that the
617 string has any characters at all.  All the C<is_utf8()> does is to
618 return the value of the internal "utf8ness" flag attached to the
619 C<$string>.  If the flag is off, the bytes in the scalar are interpreted
620 as a single byte encoding.  If the flag is on, the bytes in the scalar
621 are interpreted as the (multi-byte, variable-length) UTF-8 encoded code
622 points of the characters.  Bytes added to an UTF-8 encoded string are
623 automatically upgraded to UTF-8.  If mixed non-UTF-8 and UTF-8 scalars
624 are merged (double-quoted interpolation, explicit concatenation, and
625 printf/sprintf parameter substitution), the result will be UTF-8 encoded
626 as if copies of the byte strings were upgraded to UTF-8: for example,
627
628     $a = "ab\x80c";
629     $b = "\x{100}";
630     print "$a = $b\n";
631
632 the output string will be UTF-8-encoded C<ab\x80c = \x{100}\n>, but
633 C<$a> will stay byte-encoded.
634
635 Sometimes you might really need to know the byte length of a string
636 instead of the character length. For that use either the
637 C<Encode::encode_utf8()> function or the C<bytes> pragma  and
638 the C<length()> function:
639
640     my $unicode = chr(0x100);
641     print length($unicode), "\n"; # will print 1
642     require Encode;
643     print length(Encode::encode_utf8($unicode)), "\n"; # will print 2
644     use bytes;
645     print length($unicode), "\n"; # will also print 2
646                                   # (the 0xC4 0x80 of the UTF-8)
647
648 =item *
649
650 How Do I Detect Data That's Not Valid In a Particular Encoding?
651
652 Use the C<Encode> package to try converting it.
653 For example,
654
655     use Encode 'decode_utf8';
656
657     if (eval { decode_utf8($string, Encode::FB_CROAK); 1 }) {
658         # $string is valid utf8
659     } else {
660         # $string is not valid utf8
661     }
662
663 Or use C<unpack> to try decoding it:
664
665     use warnings;
666     @chars = unpack("C0U*", $string_of_bytes_that_I_think_is_utf8);
667
668 If invalid, a C<Malformed UTF-8 character> warning is produced. The "C0" means
669 "process the string character per character".  Without that, the
670 C<unpack("U*", ...)> would work in C<U0> mode (the default if the format
671 string starts with C<U>) and it would return the bytes making up the UTF-8
672 encoding of the target string, something that will always work.
673
674 =item *
675
676 How Do I Convert Binary Data Into a Particular Encoding, Or Vice Versa?
677
678 This probably isn't as useful as you might think.
679 Normally, you shouldn't need to.
680
681 In one sense, what you are asking doesn't make much sense: encodings
682 are for characters, and binary data are not "characters", so converting
683 "data" into some encoding isn't meaningful unless you know in what
684 character set and encoding the binary data is in, in which case it's
685 not just binary data, now is it?
686
687 If you have a raw sequence of bytes that you know should be
688 interpreted via a particular encoding, you can use C<Encode>:
689
690     use Encode 'from_to';
691     from_to($data, "iso-8859-1", "utf-8"); # from latin-1 to utf-8
692
693 The call to C<from_to()> changes the bytes in C<$data>, but nothing
694 material about the nature of the string has changed as far as Perl is
695 concerned.  Both before and after the call, the string C<$data>
696 contains just a bunch of 8-bit bytes. As far as Perl is concerned,
697 the encoding of the string remains as "system-native 8-bit bytes".
698
699 You might relate this to a fictional 'Translate' module:
700
701    use Translate;
702    my $phrase = "Yes";
703    Translate::from_to($phrase, 'english', 'deutsch');
704    ## phrase now contains "Ja"
705
706 The contents of the string changes, but not the nature of the string.
707 Perl doesn't know any more after the call than before that the
708 contents of the string indicates the affirmative.
709
710 Back to converting data.  If you have (or want) data in your system's
711 native 8-bit encoding (e.g. Latin-1, EBCDIC, etc.), you can use
712 pack/unpack to convert to/from Unicode.
713
714     $native_string  = pack("W*", unpack("U*", $Unicode_string));
715     $Unicode_string = pack("U*", unpack("W*", $native_string));
716
717 If you have a sequence of bytes you B<know> is valid UTF-8,
718 but Perl doesn't know it yet, you can make Perl a believer, too:
719
720     use Encode 'decode_utf8';
721     $Unicode = decode_utf8($bytes);
722
723 or:
724
725     $Unicode = pack("U0a*", $bytes);
726
727 You can find the bytes that make up a UTF-8 sequence with
728
729         @bytes = unpack("C*", $Unicode_string)
730
731 and you can create well-formed Unicode with
732
733         $Unicode_string = pack("U*", 0xff, ...)
734
735 =item *
736
737 How Do I Display Unicode?  How Do I Input Unicode?
738
739 See L<http://www.alanwood.net/unicode/> and
740 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
741
742 =item *
743
744 How Does Unicode Work With Traditional Locales?
745
746 In Perl, not very well.  Avoid using locales through the C<locale>
747 pragma.  Use only one or the other.  But see L<perlrun> for the
748 description of the C<-C> switch and its environment counterpart,
749 C<$ENV{PERL_UNICODE}> to see how to enable various Unicode features,
750 for example by using locale settings.
751
752 =back
753
754 =head2 Hexadecimal Notation
755
756 The Unicode standard prefers using hexadecimal notation because
757 that more clearly shows the division of Unicode into blocks of 256 characters.
758 Hexadecimal is also simply shorter than decimal.  You can use decimal
759 notation, too, but learning to use hexadecimal just makes life easier
760 with the Unicode standard.  The C<U+HHHH> notation uses hexadecimal,
761 for example.
762
763 The C<0x> prefix means a hexadecimal number, the digits are 0-9 I<and>
764 a-f (or A-F, case doesn't matter).  Each hexadecimal digit represents
765 four bits, or half a byte.  C<print 0x..., "\n"> will show a
766 hexadecimal number in decimal, and C<printf "%x\n", $decimal> will
767 show a decimal number in hexadecimal.  If you have just the
768 "hex digits" of a hexadecimal number, you can use the C<hex()> function.
769
770     print 0x0009, "\n";    # 9
771     print 0x000a, "\n";    # 10
772     print 0x000f, "\n";    # 15
773     print 0x0010, "\n";    # 16
774     print 0x0011, "\n";    # 17
775     print 0x0100, "\n";    # 256
776
777     print 0x0041, "\n";    # 65
778
779     printf "%x\n",  65;    # 41
780     printf "%#x\n", 65;    # 0x41
781
782     print hex("41"), "\n"; # 65
783
784 =head2 Further Resources
785
786 =over 4
787
788 =item *
789
790 Unicode Consortium
791
792 L<http://www.unicode.org/>
793
794 =item *
795
796 Unicode FAQ
797
798 L<http://www.unicode.org/unicode/faq/>
799
800 =item *
801
802 Unicode Glossary
803
804 L<http://www.unicode.org/glossary/>
805
806 =item *
807
808 Unicode Useful Resources
809
810 L<http://www.unicode.org/unicode/onlinedat/resources.html>
811
812 =item *
813
814 Unicode and Multilingual Support in HTML, Fonts, Web Browsers and Other Applications
815
816 L<http://www.alanwood.net/unicode/>
817
818 =item *
819
820 UTF-8 and Unicode FAQ for Unix/Linux
821
822 L<http://www.cl.cam.ac.uk/~mgk25/unicode.html>
823
824 =item *
825
826 Legacy Character Sets
827
828 L<http://www.czyborra.com/>
829 L<http://www.eki.ee/letter/>
830
831 =item *
832
833 The Unicode support files live within the Perl installation in the
834 directory
835
836     $Config{installprivlib}/unicore
837
838 in Perl 5.8.0 or newer, and
839
840     $Config{installprivlib}/unicode
841
842 in the Perl 5.6 series.  (The renaming to F<lib/unicore> was done to
843 avoid naming conflicts with lib/Unicode in case-insensitive filesystems.)
844 The main Unicode data file is F<UnicodeData.txt> (or F<Unicode.301> in
845 Perl 5.6.1.)  You can find the C<$Config{installprivlib}> by
846
847     perl "-V:installprivlib"
848
849 You can explore various information from the Unicode data files using
850 the C<Unicode::UCD> module.
851
852 =back
853
854 =head1 UNICODE IN OLDER PERLS
855
856 If you cannot upgrade your Perl to 5.8.0 or later, you can still
857 do some Unicode processing by using the modules C<Unicode::String>,
858 C<Unicode::Map8>, and C<Unicode::Map>, available from CPAN.
859 If you have the GNU recode installed, you can also use the
860 Perl front-end C<Convert::Recode> for character conversions.
861
862 The following are fast conversions from ISO 8859-1 (Latin-1) bytes
863 to UTF-8 bytes and back, the code works even with older Perl 5 versions.
864
865     # ISO 8859-1 to UTF-8
866     s/([\x80-\xFF])/chr(0xC0|ord($1)>>6).chr(0x80|ord($1)&0x3F)/eg;
867
868     # UTF-8 to ISO 8859-1
869     s/([\xC2\xC3])([\x80-\xBF])/chr(ord($1)<<6&0xC0|ord($2)&0x3F)/eg;
870
871 =head1 SEE ALSO
872
873 L<perlunitut>, L<perlunicode>, L<Encode>, L<open>, L<utf8>, L<bytes>,
874 L<perlretut>, L<perlrun>, L<Unicode::Collate>, L<Unicode::Normalize>,
875 L<Unicode::UCD>
876
877 =head1 ACKNOWLEDGMENTS
878
879 Thanks to the kind readers of the perl5-porters@perl.org,
880 perl-unicode@perl.org, linux-utf8@nl.linux.org, and unicore@unicode.org
881 mailing lists for their valuable feedback.
882
883 =head1 AUTHOR, COPYRIGHT, AND LICENSE
884
885 Copyright 2001-2002 Jarkko Hietaniemi E<lt>jhi@iki.fiE<gt>
886
887 This document may be distributed under the same terms as Perl itself.