Put a watchdog on openpid.t: it has been found to hang in some Win32 smokes.
[perl.git] / pod / perlrebackslash.pod
1 =head1 NAME
2
3 perlrebackslash - Perl Regular Expression Backslash Sequences and Escapes
4
5 =head1 DESCRIPTION
6
7 The top level documentation about Perl regular expressions
8 is found in L<perlre>.
9
10 This document describes all backslash and escape sequences. After
11 explaining the role of the backslash, it lists all the sequences that have
12 a special meaning in Perl regular expressions (in alphabetical order),
13 then describes each of them.
14
15 Most sequences are described in detail in different documents; the primary
16 purpose of this document is to have a quick reference guide describing all
17 backslash and escape sequences.
18
19
20 =head2 The backslash
21
22 In a regular expression, the backslash can perform one of two tasks:
23 it either takes away the special meaning of the character following it
24 (for instance, C<\|> matches a vertical bar, it's not an alternation),
25 or it is the start of a backslash or escape sequence.
26
27 The rules determining what it is are quite simple: if the character
28 following the backslash is a punctuation (non-word) character (that is,
29 anything that is not a letter, digit or underscore), then the backslash
30 just takes away the special meaning (if any) of the character following
31 it.
32
33 If the character following the backslash is a letter or a digit, then the
34 sequence may be special; if so, it's listed below. A few letters have not
35 been used yet, and escaping them with a backslash is safe for now, but a
36 future version of Perl may assign a special meaning to it. However, if you
37 have warnings turned on, Perl will issue a warning if you use such a sequence.
38 [1].
39
40 It is however guaranteed that backslash or escape sequences never have a
41 punctuation character following the backslash, not now, and not in a future
42 version of Perl 5. So it is safe to put a backslash in front of a non-word
43 character.
44
45 Note that the backslash itself is special; if you want to match a backslash,
46 you have to escape the backslash with a backslash: C</\\/> matches a single
47 backslash.
48
49 =over 4
50
51 =item [1]
52
53 There is one exception. If you use an alphanumerical character as the
54 delimiter of your pattern (which you probably shouldn't do for readability
55 reasons), you will have to escape the delimiter if you want to match
56 it. Perl won't warn then. See also L<perlop/Gory details of parsing
57 quoted constructs>.
58
59 =back
60
61
62 =head2 All the sequences and escapes
63
64  \000              Octal escape sequence.
65  \1                Absolute backreference.
66  \a                Alarm or bell.
67  \A                Beginning of string.
68  \b                Word/non-word boundary. (Backspace in a char class).
69  \B                Not a word/non-word boundary.
70  \cX               Control-X (X can be any ASCII character).
71  \C                Single octet, even under UTF-8.
72  \d                Character class for digits.
73  \D                Character class for non-digits.
74  \e                Escape character.
75  \E                Turn off \Q, \L and \U processing.
76  \f                Form feed.
77  \g{}, \g1         Named, absolute or relative backreference.
78  \G                Pos assertion.
79  \h                Character class for horizontal white space.
80  \H                Character class for non horizontal white space.
81  \k{}, \k<>, \k''  Named backreference.
82  \K                Keep the stuff left of \K.
83  \l                Lowercase next character.
84  \L                Lowercase till \E.
85  \n                (Logical) newline character.
86  \N                Any character but newline.
87  \N{}              Named (Unicode) character.
88  \p{}, \pP         Character with a Unicode property.
89  \P{}, \PP         Character without a Unicode property.
90  \Q                Quotemeta till \E.
91  \r                Return character.
92  \R                Generic new line.
93  \s                Character class for white space.
94  \S                Character class for non white space.
95  \t                Tab character.
96  \u                Titlecase next character.
97  \U                Uppercase till \E.
98  \v                Character class for vertical white space.
99  \V                Character class for non vertical white space.
100  \w                Character class for word characters.
101  \W                Character class for non-word characters.
102  \x{}, \x00        Hexadecimal escape sequence.
103  \X                Extended Unicode "combining character sequence".
104  \z                End of string.
105  \Z                End of string.
106
107 =head2 Character Escapes
108
109 =head3  Fixed characters
110
111 A handful of characters have a dedicated I<character escape>. The following
112 table shows them, along with their code points (in decimal and hex), their
113 ASCII name, the control escape (see below) and a short description.
114
115  Seq.  Code Point  ASCII   Cntr    Description.
116        Dec    Hex
117   \a     7     07    BEL    \cG    alarm or bell
118   \b     8     08     BS    \cH    backspace [1]
119   \e    27     1B    ESC    \c[    escape character
120   \f    12     0C     FF    \cL    form feed
121   \n    10     0A     LF    \cJ    line feed [2]
122   \r    13     0D     CR    \cM    carriage return
123   \t     9     09    TAB    \cI    tab
124
125 =over 4
126
127 =item [1]
128
129 C<\b> is only the backspace character inside a character class. Outside a
130 character class, C<\b> is a word/non-word boundary.
131
132 =item [2]
133
134 C<\n> matches a logical newline. Perl will convert between C<\n> and your
135 OSses native newline character when reading from or writing to text files.
136
137 =back
138
139 =head4 Example
140
141  $str =~ /\t/;   # Matches if $str contains a (horizontal) tab.
142
143 =head3 Control characters
144
145 C<\c> is used to denote a control character; the character following C<\c>
146 is the name of the control character. For instance, C</\cM/> matches the
147 character I<control-M> (a carriage return, code point 13). The case of the
148 character following C<\c> doesn't matter: C<\cM> and C<\cm> match the same
149 character.
150
151 Mnemonic: I<c>ontrol character.
152
153 =head4 Example
154
155  $str =~ /\cK/;  # Matches if $str contains a vertical tab (control-K).
156
157 =head3 Named characters
158
159 All Unicode characters have a Unicode name, and characters in various scripts
160 have names as well. It is even possible to give your own names to characters.
161 You can use a character by name by using the C<\N{}> construct; the name of
162 the character goes between the curly braces. You do have to C<use charnames>
163 to load the names of the characters, otherwise Perl will complain you use
164 a name it doesn't know about. For more details, see L<charnames>.
165
166 Mnemonic: I<N>amed character.
167
168 =head4 Example
169
170  use charnames ':full';               # Loads the Unicode names.
171  $str =~ /\N{THAI CHARACTER SO SO}/;  # Matches the Thai SO SO character
172
173  use charnames 'Cyrillic';            # Loads Cyrillic names.
174  $str =~ /\N{ZHE}\N{KA}/;             # Match "ZHE" followed by "KA".
175
176 =head3 Octal escapes
177
178 Octal escapes consist of a backslash followed by two or three octal digits
179 matching the code point of the character you want to use. This allows for
180 512 characters (C<\00> up to C<\777>) that can be expressed this way.
181 Enough in pre-Unicode days, but most Unicode characters cannot be escaped
182 this way.
183
184 Note that a character that is expressed as an octal escape is considered
185 as a character without special meaning by the regex engine, and will match
186 "as is".
187
188 =head4 Examples
189
190  $str = "Perl";
191  $str =~ /\120/;    # Match, "\120" is "P".
192  $str =~ /\120+/;   # Match, "\120" is "P", it is repeated at least once.
193  $str =~ /P\053/;   # No match, "\053" is "+" and taken literally.
194
195 =head4 Caveat
196
197 Octal escapes potentially clash with backreferences. They both consist
198 of a backslash followed by numbers. So Perl has to use heuristics to
199 determine whether it is a backreference or an octal escape. Perl uses
200 the following rules:
201
202 =over 4
203
204 =item 1
205
206 If the backslash is followed by a single digit, it's a backreference.
207
208 =item 2
209
210 If the first digit following the backslash is a 0, it's an octal escape.
211
212 =item 3
213
214 If the number following the backslash is N (decimal), and Perl already has
215 seen N capture groups, Perl will consider this to be a backreference.
216 Otherwise, it will consider it to be an octal escape. Note that if N > 999,
217 Perl only takes the first three digits for the octal escape; the rest is
218 matched as is.
219
220  my $pat  = "(" x 999;
221     $pat .= "a";
222     $pat .= ")" x 999;
223  /^($pat)\1000$/;   #  Matches 'aa'; there are 1000 capture groups.
224  /^$pat\1000$/;     #  Matches 'a@0'; there are 999 capture groups
225                     #    and \1000 is seen as \100 (a '@') and a '0'.
226
227 =back
228
229 =head3 Hexadecimal escapes
230
231 Hexadecimal escapes start with C<\x> and are then either followed by
232 two digit hexadecimal number, or a hexadecimal number of arbitrary length
233 surrounded by curly braces. The hexadecimal number is the code point of
234 the character you want to express.
235
236 Note that a character that is expressed as a hexadecimal escape is considered
237 as a character without special meaning by the regex engine, and will match
238 "as is".
239
240 Mnemonic: heI<x>adecimal.
241
242 =head4 Examples
243
244  $str = "Perl";
245  $str =~ /\x50/;    # Match, "\x50" is "P".
246  $str =~ /\x50+/;   # Match, "\x50" is "P", it is repeated at least once.
247  $str =~ /P\x2B/;   # No match, "\x2B" is "+" and taken literally.
248
249  /\x{2603}\x{2602}/ # Snowman with an umbrella.
250                     # The Unicode character 2603 is a snowman,
251                     # the Unicode character 2602 is an umbrella.
252  /\x{263B}/         # Black smiling face.
253  /\x{263b}/         # Same, the hex digits A - F are case insensitive.
254
255 =head2 Modifiers
256
257 A number of backslash sequences have to do with changing the character,
258 or characters following them. C<\l> will lowercase the character following
259 it, while C<\u> will uppercase (or, more accurately, titlecase) the
260 character following it. (They perform similar functionality as the
261 functions C<lcfirst> and C<ucfirst>).
262
263 To uppercase or lowercase several characters, one might want to use
264 C<\L> or C<\U>, which will lowercase/uppercase all characters following
265 them, until either the end of the pattern, or the next occurrence of
266 C<\E>, whatever comes first. They perform similar functionality as the
267 functions C<lc> and C<uc> do.
268
269 C<\Q> is used to escape all characters following, up to the next C<\E>
270 or the end of the pattern. C<\Q> adds a backslash to any character that
271 isn't a letter, digit or underscore. This will ensure that any character
272 between C<\Q> and C<\E> is matched literally, and will not be interpreted
273 by the regexp engine.
274
275 Mnemonic: I<L>owercase, I<U>ppercase, I<Q>uotemeta, I<E>nd.
276
277 =head4 Examples
278
279  $sid     = "sid";
280  $greg    = "GrEg";
281  $miranda = "(Miranda)";
282  $str     =~ /\u$sid/;        # Matches 'Sid'
283  $str     =~ /\L$greg/;       # Matches 'greg'
284  $str     =~ /\Q$miranda\E/;  # Matches '(Miranda)', as if the pattern
285                               #   had been written as /\(Miranda\)/
286
287 =head2 Character classes
288
289 Perl regular expressions have a large range of character classes. Some of
290 the character classes are written as a backslash sequence. We will briefly
291 discuss those here; full details of character classes can be found in
292 L<perlrecharclass>.
293
294 C<\w> is a character class that matches any I<word> character (letters,
295 digits, underscore). C<\d> is a character class that matches any digit,
296 while the character class C<\s> matches any white space character.
297 New in perl 5.10.0 are the classes C<\h> and C<\v> which match horizontal
298 and vertical white space characters.
299
300 The uppercase variants (C<\W>, C<\D>, C<\S>, C<\H>, and C<\V>) are
301 character classes that match any character that isn't a word character,
302 digit, white space, horizontal white space or vertical white space.
303
304 Mnemonics: I<w>ord, I<d>igit, I<s>pace, I<h>orizontal, I<v>ertical.
305
306 =head3 Unicode classes
307
308 C<\pP> (where C<P> is a single letter) and C<\p{Property}> are used to
309 match a character that matches the given Unicode property; properties
310 include things like "letter", or "thai character". Capitalizing the
311 sequence to C<\PP> and C<\P{Property}> make the sequence match a character
312 that doesn't match the given Unicode property. For more details, see
313 L<perlrecharclass/Backslashed sequences> and
314 L<perlunicode/Unicode Character Properties>.
315
316 Mnemonic: I<p>roperty.
317
318
319 =head2 Referencing
320
321 If capturing parenthesis are used in a regular expression, we can refer
322 to the part of the source string that was matched, and match exactly the
323 same thing. There are three ways of referring to such I<backreference>:
324 absolutely, relatively, and by name.
325
326 =for later add link to perlrecapture
327
328 =head3 Absolute referencing
329
330 A backslash sequence that starts with a backslash and is followed by a
331 number is an absolute reference (but be aware of the caveat mentioned above).
332 If the number is I<N>, it refers to the Nth set of parenthesis - whatever
333 has been matched by that set of parenthesis has to be matched by the C<\N>
334 as well.
335
336 =head4 Examples
337
338  /(\w+) \1/;    # Finds a duplicated word, (e.g. "cat cat").
339  /(.)(.)\2\1/;  # Match a four letter palindrome (e.g. "ABBA").
340
341
342 =head3 Relative referencing
343
344 New in perl 5.10.0 is a different way of referring to capture buffers: C<\g>.
345 C<\g> takes a number as argument, with the number in curly braces (the
346 braces are optional). If the number (N) does not have a sign, it's a reference
347 to the Nth capture group (so C<\g{2}> is equivalent to C<\2> - except that
348 C<\g> always refers to a capture group and will never be seen as an octal
349 escape). If the number is negative, the reference is relative, referring to
350 the Nth group before the C<\g{-N}>.
351
352 The big advantage of C<\g{-N}> is that it makes it much easier to write
353 patterns with references that can be interpolated in larger patterns,
354 even if the larger pattern also contains capture groups.
355
356 Mnemonic: I<g>roup.
357
358 =head4 Examples
359
360  /(A)        # Buffer 1
361   (          # Buffer 2
362     (B)      # Buffer 3
363     \g{-1}   # Refers to buffer 3 (B)
364     \g{-3}   # Refers to buffer 1 (A)
365   )
366  /x;         # Matches "ABBA".
367
368  my $qr = qr /(.)(.)\g{-2}\g{-1}/;  # Matches 'abab', 'cdcd', etc.
369  /$qr$qr/                           # Matches 'ababcdcd'.
370
371 =head3 Named referencing
372
373 Also new in perl 5.10.0 is the use of named capture buffers, which can be
374 referred to by name. This is done with C<\g{name}>, which is a
375 backreference to the capture buffer with the name I<name>.
376
377 To be compatible with .Net regular expressions, C<\g{name}> may also be
378 written as C<\k{name}>, C<< \k<name> >> or C<\k'name'>.
379
380 Note that C<\g{}> has the potential to be ambiguous, as it could be a named
381 reference, or an absolute or relative reference (if its argument is numeric).
382 However, names are not allowed to start with digits, nor are allowed to
383 contain a hyphen, so there is no ambiguity.
384
385 =head4 Examples
386
387  /(?<word>\w+) \g{word}/ # Finds duplicated word, (e.g. "cat cat")
388  /(?<word>\w+) \k{word}/ # Same.
389  /(?<word>\w+) \k<word>/ # Same.
390  /(?<letter1>.)(?<letter2>.)\g{letter2}\g{letter1}/
391                          # Match a four letter palindrome (e.g. "ABBA")
392
393 =head2 Assertions
394
395 Assertions are conditions that have to be true -- they don't actually
396 match parts of the substring. There are six assertions that are written as
397 backslash sequences.
398
399 =over 4
400
401 =item \A
402
403 C<\A> only matches at the beginning of the string. If the C</m> modifier
404 isn't used, then C</\A/> is equivalent with C</^/>. However, if the C</m>
405 modifier is used, then C</^/> matches internal newlines, but the meaning
406 of C</\A/> isn't changed by the C</m> modifier. C<\A> matches at the beginning
407 of the string regardless whether the C</m> modifier is used.
408
409 =item \z, \Z
410
411 C<\z> and C<\Z> match at the end of the string. If the C</m> modifier isn't
412 used, then C</\Z/> is equivalent with C</$/>, that is, it matches at the
413 end of the string, or before the newline at the end of the string. If the
414 C</m> modifier is used, then C</$/> matches at internal newlines, but the
415 meaning of C</\Z/> isn't changed by the C</m> modifier. C<\Z> matches at
416 the end of the string (or just before a trailing newline) regardless whether
417 the C</m> modifier is used.
418
419 C<\z> is just like C<\Z>, except that it will not match before a trailing
420 newline. C<\z> will only match at the end of the string - regardless of the
421 modifiers used, and not before a newline.
422
423 =item \G
424
425 C<\G> is usually only used in combination with the C</g> modifier. If the
426 C</g> modifier is used (and the match is done in scalar context), Perl will
427 remember where in the source string the last match ended, and the next time,
428 it will start the match from where it ended the previous time.
429
430 C<\G> matches the point where the previous match ended, or the beginning
431 of the string if there was no previous match.
432
433 =for later add link to perlremodifiers
434
435 Mnemonic: I<G>lobal.
436
437 =item \b, \B
438
439 C<\b> matches at any place between a word and a non-word character; C<\B>
440 matches at any place between characters where C<\b> doesn't match. C<\b>
441 and C<\B> assume there's a non-word character before the beginning and after
442 the end of the source string; so C<\b> will match at the beginning (or end)
443 of the source string if the source string begins (or ends) with a word
444 character. Otherwise, C<\B> will match.
445
446 Mnemonic: I<b>oundary.
447
448 =back
449
450 =head4 Examples
451
452   "cat"   =~ /\Acat/;     # Match.
453   "cat"   =~ /cat\Z/;     # Match.
454   "cat\n" =~ /cat\Z/;     # Match.
455   "cat\n" =~ /cat\z/;     # No match.
456
457   "cat"   =~ /\bcat\b/;   # Matches.
458   "cats"  =~ /\bcat\b/;   # No match.
459   "cat"   =~ /\bcat\B/;   # No match.
460   "cats"  =~ /\bcat\B/;   # Match.
461
462   while ("cat dog" =~ /(\w+)/g) {
463       print $1;           # Prints 'catdog'
464   }
465   while ("cat dog" =~ /\G(\w+)/g) {
466       print $1;           # Prints 'cat'
467   }
468
469 =head2 Misc
470
471 Here we document the backslash sequences that don't fall in one of the
472 categories above. They are:
473
474 =over 4
475
476 =item \C
477
478 C<\C> always matches a single octet, even if the source string is encoded
479 in UTF-8 format, and the character to be matched is a multi-octet character.
480 C<\C> was introduced in perl 5.6.
481
482 Mnemonic: oI<C>tet.
483
484 =item \K
485
486 This is new in perl 5.10.0. Anything that is matched left of C<\K> is
487 not included in C<$&> - and will not be replaced if the pattern is
488 used in a substitution. This will allow you to write C<s/PAT1 \K PAT2/REPL/x>
489 instead of C<s/(PAT1) PAT2/${1}REPL/x> or C<s/(?<=PAT1) PAT2/REPL/x>.
490
491 Mnemonic: I<K>eep.
492
493 =item \R
494
495 C<\R> matches a I<generic newline>, that is, anything that is considered
496 a newline by Unicode. This includes all characters matched by C<\v>
497 (vertical white space), and the multi character sequence C<"\x0D\x0A">
498 (carriage return followed by a line feed, aka the network newline, or
499 the newline used in Windows text files). C<\R> is equivalent with
500 C<< (?>\x0D\x0A)|\v) >>. Since C<\R> can match a more than one character,
501 it cannot be put inside a bracketed character class; C</[\R]/> is an error.
502 C<\R> was introduced in perl 5.10.0.
503
504 Mnemonic: none really. C<\R> was picked because PCRE already uses C<\R>,
505 and more importantly because Unicode recommends such a regular expression
506 metacharacter, and suggests C<\R> as the notation.
507
508 =item \X
509
510 This matches an extended Unicode I<combining character sequence>, and
511 is equivalent to C<< (?>\PM\pM*) >>. C<\PM> matches any character that is
512 not considered a Unicode mark character, while C<\pM> matches any character
513 that is considered a Unicode mark character; so C<\X> matches any non
514 mark character followed by zero or more mark characters. Mark characters
515 include (but are not restricted to) I<combining characters> and
516 I<vowel signs>.
517
518 C<\X> matches quite well what normal (non-Unicode-programmer) usage
519 would consider a single character: for example a base character
520 (the C<\PM> above), for example a letter, followed by zero or more
521 diacritics, which are I<combining characters> (the C<\pM*> above).
522
523 Mnemonic: eI<X>tended Unicode character.
524
525 =back
526
527 =head4 Examples
528
529  "\x{256}" =~ /^\C\C$/;    # Match as chr (256) takes 2 octets in UTF-8.
530
531  $str =~ s/foo\Kbar/baz/g; # Change any 'bar' following a 'foo' to 'baz'.
532  $str =~ s/(.)\K\1//g;     # Delete duplicated characters.
533
534  "\n"   =~ /^\R$/;         # Match, \n   is a generic newline.
535  "\r"   =~ /^\R$/;         # Match, \r   is a generic newline.
536  "\r\n" =~ /^\R$/;         # Match, \r\n is a generic newline.
537
538  "P\x{0307}" =~ /^\X$/     # \X matches a P with a dot above.
539
540 =cut