Put a watchdog on openpid.t: it has been found to hang in some Win32 smokes.
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as /ms, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If C<use locale> is in effect, the case map is taken from the current
55 locale.  See L<perllocale>.
56
57 =item x
58 X</x>
59
60 Extend your pattern's legibility by permitting whitespace and comments.
61
62 =item p
63 X</p> X<regex, preserve> X<regexp, preserve>
64
65 Preserve the string matched such that ${^PREMATCH}, {$^MATCH}, and
66 ${^POSTMATCH} are available for use after matching.
67
68 =item g and c
69 X</g> X</c>
70
71 Global matching, and keep the Current position after failed matching.
72 Unlike i, m, s and x, these two flags affect the way the regex is used
73 rather than the regex itself. See
74 L<perlretut/"Using regular expressions in Perl"> for further explanation
75 of the g and c modifiers.
76
77 =back
78
79 These are usually written as "the C</x> modifier", even though the delimiter
80 in question might not really be a slash.  Any of these
81 modifiers may also be embedded within the regular expression itself using
82 the C<(?...)> construct.  See below.
83
84 The C</x> modifier itself needs a little more explanation.  It tells
85 the regular expression parser to ignore whitespace that is neither
86 backslashed nor within a character class.  You can use this to break up
87 your regular expression into (slightly) more readable parts.  The C<#>
88 character is also treated as a metacharacter introducing a comment,
89 just as in ordinary Perl code.  This also means that if you want real
90 whitespace or C<#> characters in the pattern (outside a character
91 class, where they are unaffected by C</x>), then you'll either have to
92 escape them (using backslashes or C<\Q...\E>) or encode them using octal
93 or hex escapes.  Taken together, these features go a long way towards
94 making Perl's regular expressions more readable.  Note that you have to
95 be careful not to include the pattern delimiter in the comment--perl has
96 no way of knowing you did not intend to close the pattern early.  See
97 the C-comment deletion code in L<perlop>.  Also note that anything inside
98 a C<\Q...\E> stays unaffected by C</x>.
99 X</x>
100
101 =head2 Regular Expressions
102
103 =head3 Metacharacters
104
105 The patterns used in Perl pattern matching evolved from those supplied in
106 the Version 8 regex routines.  (The routines are derived
107 (distantly) from Henry Spencer's freely redistributable reimplementation
108 of the V8 routines.)  See L<Version 8 Regular Expressions> for
109 details.
110
111 In particular the following metacharacters have their standard I<egrep>-ish
112 meanings:
113 X<metacharacter>
114 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
115
116
117     \   Quote the next metacharacter
118     ^   Match the beginning of the line
119     .   Match any character (except newline)
120     $   Match the end of the line (or before newline at the end)
121     |   Alternation
122     ()  Grouping
123     []  Character class
124
125 By default, the "^" character is guaranteed to match only the
126 beginning of the string, the "$" character only the end (or before the
127 newline at the end), and Perl does certain optimizations with the
128 assumption that the string contains only one line.  Embedded newlines
129 will not be matched by "^" or "$".  You may, however, wish to treat a
130 string as a multi-line buffer, such that the "^" will match after any
131 newline within the string (except if the newline is the last character in
132 the string), and "$" will match before any newline.  At the
133 cost of a little more overhead, you can do this by using the /m modifier
134 on the pattern match operator.  (Older programs did this by setting C<$*>,
135 but this practice has been removed in perl 5.9.)
136 X<^> X<$> X</m>
137
138 To simplify multi-line substitutions, the "." character never matches a
139 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
140 the string is a single line--even if it isn't.
141 X<.> X</s>
142
143 =head3 Quantifiers
144
145 The following standard quantifiers are recognized:
146 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
147
148     *      Match 0 or more times
149     +      Match 1 or more times
150     ?      Match 1 or 0 times
151     {n}    Match exactly n times
152     {n,}   Match at least n times
153     {n,m}  Match at least n but not more than m times
154
155 (If a curly bracket occurs in any other context, it is treated
156 as a regular character.  In particular, the lower bound
157 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
158 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
159 to integral values less than a preset limit defined when perl is built.
160 This is usually 32766 on the most common platforms.  The actual limit can
161 be seen in the error message generated by code such as this:
162
163     $_ **= $_ , / {$_} / for 2 .. 42;
164
165 By default, a quantified subpattern is "greedy", that is, it will match as
166 many times as possible (given a particular starting location) while still
167 allowing the rest of the pattern to match.  If you want it to match the
168 minimum number of times possible, follow the quantifier with a "?".  Note
169 that the meanings don't change, just the "greediness":
170 X<metacharacter> X<greedy> X<greediness>
171 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
172
173     *?     Match 0 or more times, not greedily
174     +?     Match 1 or more times, not greedily
175     ??     Match 0 or 1 time, not greedily
176     {n}?   Match exactly n times, not greedily
177     {n,}?  Match at least n times, not greedily
178     {n,m}? Match at least n but not more than m times, not greedily
179
180 By default, when a quantified subpattern does not allow the rest of the
181 overall pattern to match, Perl will backtrack. However, this behaviour is
182 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
183 as well.
184
185     *+     Match 0 or more times and give nothing back
186     ++     Match 1 or more times and give nothing back
187     ?+     Match 0 or 1 time and give nothing back
188     {n}+   Match exactly n times and give nothing back (redundant)
189     {n,}+  Match at least n times and give nothing back
190     {n,m}+ Match at least n but not more than m times and give nothing back
191
192 For instance,
193
194    'aaaa' =~ /a++a/
195
196 will never match, as the C<a++> will gobble up all the C<a>'s in the
197 string and won't leave any for the remaining part of the pattern. This
198 feature can be extremely useful to give perl hints about where it
199 shouldn't backtrack. For instance, the typical "match a double-quoted
200 string" problem can be most efficiently performed when written as:
201
202    /"(?:[^"\\]++|\\.)*+"/
203
204 as we know that if the final quote does not match, backtracking will not
205 help. See the independent subexpression C<< (?>...) >> for more details;
206 possessive quantifiers are just syntactic sugar for that construct. For
207 instance the above example could also be written as follows:
208
209    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
210
211 =head3 Escape sequences
212
213 Because patterns are processed as double quoted strings, the following
214 also work:
215 X<\t> X<\n> X<\r> X<\f> X<\e> X<\a> X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q>
216 X<\0> X<\c> X<\N> X<\x>
217
218     \t          tab                   (HT, TAB)
219     \n          newline               (LF, NL)
220     \r          return                (CR)
221     \f          form feed             (FF)
222     \a          alarm (bell)          (BEL)
223     \e          escape (think troff)  (ESC)
224     \033        octal char            (example: ESC)
225     \x1B        hex char              (example: ESC)
226     \x{263a}    long hex char         (example: Unicode SMILEY)
227     \cK         control char          (example: VT)
228     \N{name}    named Unicode character
229     \l          lowercase next char (think vi)
230     \u          uppercase next char (think vi)
231     \L          lowercase till \E (think vi)
232     \U          uppercase till \E (think vi)
233     \E          end case modification (think vi)
234     \Q          quote (disable) pattern metacharacters till \E
235
236 If C<use locale> is in effect, the case map used by C<\l>, C<\L>, C<\u>
237 and C<\U> is taken from the current locale.  See L<perllocale>.  For
238 documentation of C<\N{name}>, see L<charnames>.
239
240 You cannot include a literal C<$> or C<@> within a C<\Q> sequence.
241 An unescaped C<$> or C<@> interpolates the corresponding variable,
242 while escaping will cause the literal string C<\$> to be matched.
243 You'll need to write something like C<m/\Quser\E\@\Qhost/>.
244
245 =head3 Character Classes and other Special Escapes
246
247 In addition, Perl defines the following:
248 X<\w> X<\W> X<\s> X<\S> X<\d> X<\D> X<\X> X<\p> X<\P> X<\C>
249 X<\g> X<\k> X<\N> X<\K> X<\v> X<\V> X<\h> X<\H>
250 X<word> X<whitespace> X<character class> X<backreference>
251
252     \w       Match a "word" character (alphanumeric plus "_")
253     \W       Match a non-"word" character
254     \s       Match a whitespace character
255     \S       Match a non-whitespace character
256     \d       Match a digit character
257     \D       Match a non-digit character
258     \pP      Match P, named property.  Use \p{Prop} for longer names.
259     \PP      Match non-P
260     \X       Match eXtended Unicode "combining character sequence",
261              equivalent to (?>\PM\pM*)
262     \C       Match a single C char (octet) even under Unicode.
263              NOTE: breaks up characters into their UTF-8 bytes,
264              so you may end up with malformed pieces of UTF-8.
265              Unsupported in lookbehind.
266     \1       Backreference to a specific group.
267              '1' may actually be any positive integer.
268     \g1      Backreference to a specific or previous group,
269     \g{-1}   number may be negative indicating a previous buffer and may
270              optionally be wrapped in curly brackets for safer parsing.
271     \g{name} Named backreference
272     \k<name> Named backreference
273     \K       Keep the stuff left of the \K, don't include it in $&
274     \N       Any character but \n
275     \v       Vertical whitespace
276     \V       Not vertical whitespace
277     \h       Horizontal whitespace
278     \H       Not horizontal whitespace
279     \R       Linebreak
280
281 A C<\w> matches a single alphanumeric character (an alphabetic
282 character, or a decimal digit) or C<_>, not a whole word.  Use C<\w+>
283 to match a string of Perl-identifier characters (which isn't the same
284 as matching an English word).  If C<use locale> is in effect, the list
285 of alphabetic characters generated by C<\w> is taken from the current
286 locale.  See L<perllocale>.  You may use C<\w>, C<\W>, C<\s>, C<\S>,
287 C<\d>, and C<\D> within character classes, but they aren't usable
288 as either end of a range. If any of them precedes or follows a "-",
289 the "-" is understood literally. If Unicode is in effect, C<\s> matches
290 also "\x{85}", "\x{2028}", and "\x{2029}". See L<perlunicode> for more
291 details about C<\pP>, C<\PP>, C<\X> and the possibility of defining
292 your own C<\p> and C<\P> properties, and L<perluniintro> about Unicode
293 in general.
294 X<\w> X<\W> X<word>
295
296 C<\R> will atomically match a linebreak, including the network line-ending
297 "\x0D\x0A".  Specifically, X<\R> is exactly equivalent to
298
299   (?>\x0D\x0A?|[\x0A-\x0C\x85\x{2028}\x{2029}])
300
301 B<Note:> C<\R> has no special meaning inside of a character class;
302 use C<\v> instead (vertical whitespace).
303 X<\R>
304
305 The POSIX character class syntax
306 X<character class>
307
308     [:class:]
309
310 is also available.  Note that the C<[> and C<]> brackets are I<literal>;
311 they must always be used within a character class expression.
312
313     # this is correct:
314     $string =~ /[[:alpha:]]/;
315
316     # this is not, and will generate a warning:
317     $string =~ /[:alpha:]/;
318
319 The following table shows the mapping of POSIX character class
320 names, common escapes, literal escape sequences and their equivalent
321 Unicode style property names.
322 X<character class> X<\p> X<\p{}>
323 X<alpha> X<alnum> X<ascii> X<blank> X<cntrl> X<digit> X<graph>
324 X<lower> X<print> X<punct> X<space> X<upper> X<word> X<xdigit>
325
326 B<Note:> up to Perl 5.10 the property names used were shared with
327 standard Unicode properties, this was changed in Perl 5.11, see
328 L<perl5110delta> for details.
329
330     POSIX  Esc  Class               Property            Note
331     --------------------------------------------------------
332     alnum       [0-9A-Za-z]         IsPosixAlnum
333     alpha       [A-Za-z]            IsPosixAlpha
334     ascii       [\000-\177]         IsASCII
335     blank       [\011 ]             IsPosixBlank        [1]
336     cntrl       [\0-\37\177]        IsPosixCntrl
337     digit   \d  [0-9]               IsPosixDigit
338     graph       [!-~]               IsPosixGraph
339     lower       [a-z]               IsPosixLower
340     print       [ -~]               IsPosixPrint
341     punct       [!-/:-@[-`{-~]      IsPosixPunct
342     space       [\11-\15 ]          IsPosixSpace        [2]
343             \s  [\11\12\14\15 ]     IsPerlSpace         [2]
344     upper       [A-Z]               IsPosixUpper
345     word    \w  [0-9A-Z_a-z]        IsPerlWord          [3]
346     xdigit      [0-9A-Fa-f]         IsXDigit
347
348 =over
349
350 =item [1]
351
352 A GNU extension equivalent to C<[ \t]>, "all horizontal whitespace".
353
354 =item [2]
355
356 Note that C<\s> and C<[[:space:]]> are B<not> equivalent as C<[[:space:]]>
357 includes also the (very rare) "vertical tabulator", "\cK" or chr(11) in
358 ASCII.
359
360 =item [3]
361
362 A Perl extension, see above.
363
364 =back
365
366 For example use C<[:upper:]> to match all the uppercase characters.
367 Note that the C<[]> are part of the C<[::]> construct, not part of the
368 whole character class.  For example:
369
370     [01[:alpha:]%]
371
372 matches zero, one, any alphabetic character, and the percent sign.
373
374 =item C<$>
375
376 Currency symbol
377
378 =item C<+> C<< < >> C<=> C<< > >> C<|> C<~>
379
380 Mathematical symbols
381
382 =item C<^> C<`>
383
384 Modifier symbols (accents)
385
386 =back
387
388 =back
389
390 The other named classes are:
391
392 =over 4
393
394 =item cntrl
395 X<cntrl>
396
397 Any control character.  Usually characters that don't produce output as
398 such but instead control the terminal somehow: for example newline and
399 backspace are control characters.  All characters with ord() less than
400 32 are usually classified as control characters (assuming ASCII,
401 the ISO Latin character sets, and Unicode), as is the character with
402 the ord() value of 127 (C<DEL>).
403
404 =item graph
405 X<graph>
406
407 Any alphanumeric or punctuation (special) character.
408
409 =item print
410 X<print>
411
412 Any alphanumeric or punctuation (special) character or the space character.
413
414 =item punct
415 X<punct>
416
417 Any punctuation (special) character.
418
419 =item xdigit
420 X<xdigit>
421
422 Any hexadecimal digit.  Though this may feel silly ([0-9A-Fa-f] would
423 work just fine) it is included for completeness.
424
425 =back
426
427 You can negate the [::] character classes by prefixing the class name
428 with a '^'. This is a Perl extension.  For example:
429 X<character class, negation>
430
431     POSIX         traditional  Unicode
432
433     [[:^digit:]]    \D         \P{IsPosixDigit}
434     [[:^space:]]    \S         \P{IsPosixSpace}
435     [[:^word:]]     \W         \P{IsPerlWord}
436
437 Perl respects the POSIX standard in that POSIX character classes are
438 only supported within a character class.  The POSIX character classes
439 [.cc.] and [=cc=] are recognized but B<not> supported and trying to
440 use them will cause an error.
441
442 =head3 Assertions
443
444 Perl defines the following zero-width assertions:
445 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
446 X<regexp, zero-width assertion>
447 X<regular expression, zero-width assertion>
448 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
449
450     \b  Match a word boundary
451     \B  Match except at a word boundary
452     \A  Match only at beginning of string
453     \Z  Match only at end of string, or before newline at the end
454     \z  Match only at end of string
455     \G  Match only at pos() (e.g. at the end-of-match position
456         of prior m//g)
457
458 A word boundary (C<\b>) is a spot between two characters
459 that has a C<\w> on one side of it and a C<\W> on the other side
460 of it (in either order), counting the imaginary characters off the
461 beginning and end of the string as matching a C<\W>.  (Within
462 character classes C<\b> represents backspace rather than a word
463 boundary, just as it normally does in any double-quoted string.)
464 The C<\A> and C<\Z> are just like "^" and "$", except that they
465 won't match multiple times when the C</m> modifier is used, while
466 "^" and "$" will match at every internal line boundary.  To match
467 the actual end of the string and not ignore an optional trailing
468 newline, use C<\z>.
469 X<\b> X<\A> X<\Z> X<\z> X</m>
470
471 The C<\G> assertion can be used to chain global matches (using
472 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
473 It is also useful when writing C<lex>-like scanners, when you have
474 several patterns that you want to match against consequent substrings
475 of your string, see the previous reference.  The actual location
476 where C<\G> will match can also be influenced by using C<pos()> as
477 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
478 matches is modified somewhat, in that contents to the left of C<\G> is
479 not counted when determining the length of the match. Thus the following
480 will not match forever:
481 X<\G>
482
483     $str = 'ABC';
484     pos($str) = 1;
485     while (/.\G/g) {
486         print $&;
487     }
488
489 It will print 'A' and then terminate, as it considers the match to
490 be zero-width, and thus will not match at the same position twice in a
491 row.
492
493 It is worth noting that C<\G> improperly used can result in an infinite
494 loop. Take care when using patterns that include C<\G> in an alternation.
495
496 =head3 Capture buffers
497
498 The bracketing construct C<( ... )> creates capture buffers. To refer
499 to the current contents of a buffer later on, within the same pattern,
500 use \1 for the first, \2 for the second, and so on.
501 Outside the match use "$" instead of "\".  (The
502 \<digit> notation works in certain circumstances outside
503 the match.  See the warning below about \1 vs $1 for details.)
504 Referring back to another part of the match is called a
505 I<backreference>.
506 X<regex, capture buffer> X<regexp, capture buffer>
507 X<regular expression, capture buffer> X<backreference>
508
509 There is no limit to the number of captured substrings that you may
510 use.  However Perl also uses \10, \11, etc. as aliases for \010,
511 \011, etc.  (Recall that 0 means octal, so \011 is the character at
512 number 9 in your coded character set; which would be the 10th character,
513 a horizontal tab under ASCII.)  Perl resolves this
514 ambiguity by interpreting \10 as a backreference only if at least 10
515 left parentheses have opened before it.  Likewise \11 is a
516 backreference only if at least 11 left parentheses have opened
517 before it.  And so on.  \1 through \9 are always interpreted as
518 backreferences.
519
520 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
521 In order to provide a safer and easier way to construct patterns using
522 backreferences, Perl provides the C<\g{N}> notation (starting with perl
523 5.10.0). The curly brackets are optional, however omitting them is less
524 safe as the meaning of the pattern can be changed by text (such as digits)
525 following it. When N is a positive integer the C<\g{N}> notation is
526 exactly equivalent to using normal backreferences. When N is a negative
527 integer then it is a relative backreference referring to the previous N'th
528 capturing group. When the bracket form is used and N is not an integer, it
529 is treated as a reference to a named buffer.
530
531 Thus C<\g{-1}> refers to the last buffer, C<\g{-2}> refers to the
532 buffer before that. For example:
533
534         /
535          (Y)            # buffer 1
536          (              # buffer 2
537             (X)         # buffer 3
538             \g{-1}      # backref to buffer 3
539             \g{-3}      # backref to buffer 1
540          )
541         /x
542
543 and would match the same as C</(Y) ( (X) \3 \1 )/x>.
544
545 Additionally, as of Perl 5.10.0 you may use named capture buffers and named
546 backreferences. The notation is C<< (?<name>...) >> to declare and C<< \k<name> >>
547 to reference. You may also use apostrophes instead of angle brackets to delimit the
548 name; and you may use the bracketed C<< \g{name} >> backreference syntax.
549 It's possible to refer to a named capture buffer by absolute and relative number as well.
550 Outside the pattern, a named capture buffer is available via the C<%+> hash.
551 When different buffers within the same pattern have the same name, C<$+{name}>
552 and C<< \k<name> >> refer to the leftmost defined group. (Thus it's possible
553 to do things with named capture buffers that would otherwise require C<(??{})>
554 code to accomplish.)
555 X<named capture buffer> X<regular expression, named capture buffer>
556 X<%+> X<$+{name}> X<< \k<name> >>
557
558 Examples:
559
560     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
561
562     /(.)\1/                         # find first doubled char
563          and print "'$1' is the first doubled character\n";
564
565     /(?<char>.)\k<char>/            # ... a different way
566          and print "'$+{char}' is the first doubled character\n";
567
568     /(?'char'.)\1/                  # ... mix and match
569          and print "'$1' is the first doubled character\n";
570
571     if (/Time: (..):(..):(..)/) {   # parse out values
572         $hours = $1;
573         $minutes = $2;
574         $seconds = $3;
575     }
576
577 Several special variables also refer back to portions of the previous
578 match.  C<$+> returns whatever the last bracket match matched.
579 C<$&> returns the entire matched string.  (At one point C<$0> did
580 also, but now it returns the name of the program.)  C<$`> returns
581 everything before the matched string.  C<$'> returns everything
582 after the matched string. And C<$^N> contains whatever was matched by
583 the most-recently closed group (submatch). C<$^N> can be used in
584 extended patterns (see below), for example to assign a submatch to a
585 variable.
586 X<$+> X<$^N> X<$&> X<$`> X<$'>
587
588 The numbered match variables ($1, $2, $3, etc.) and the related punctuation
589 set (C<$+>, C<$&>, C<$`>, C<$'>, and C<$^N>) are all dynamically scoped
590 until the end of the enclosing block or until the next successful
591 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
592 X<$+> X<$^N> X<$&> X<$`> X<$'>
593 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
594
595
596 B<NOTE>: Failed matches in Perl do not reset the match variables,
597 which makes it easier to write code that tests for a series of more
598 specific cases and remembers the best match.
599
600 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
601 C<$'> anywhere in the program, it has to provide them for every
602 pattern match.  This may substantially slow your program.  Perl
603 uses the same mechanism to produce $1, $2, etc, so you also pay a
604 price for each pattern that contains capturing parentheses.  (To
605 avoid this cost while retaining the grouping behaviour, use the
606 extended regular expression C<(?: ... )> instead.)  But if you never
607 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
608 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
609 if you can, but if you can't (and some algorithms really appreciate
610 them), once you've used them once, use them at will, because you've
611 already paid the price.  As of 5.005, C<$&> is not so costly as the
612 other two.
613 X<$&> X<$`> X<$'>
614
615 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
616 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
617 and C<$'>, B<except> that they are only guaranteed to be defined after a
618 successful match that was executed with the C</p> (preserve) modifier.
619 The use of these variables incurs no global performance penalty, unlike
620 their punctuation char equivalents, however at the trade-off that you
621 have to tell perl when you want to use them.
622 X</p> X<p modifier>
623
624 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
625 C<\w>, C<\n>.  Unlike some other regular expression languages, there
626 are no backslashed symbols that aren't alphanumeric.  So anything
627 that looks like \\, \(, \), \<, \>, \{, or \} is always
628 interpreted as a literal character, not a metacharacter.  This was
629 once used in a common idiom to disable or quote the special meanings
630 of regular expression metacharacters in a string that you want to
631 use for a pattern. Simply quote all non-"word" characters:
632
633     $pattern =~ s/(\W)/\\$1/g;
634
635 (If C<use locale> is set, then this depends on the current locale.)
636 Today it is more common to use the quotemeta() function or the C<\Q>
637 metaquoting escape sequence to disable all metacharacters' special
638 meanings like this:
639
640     /$unquoted\Q$quoted\E$unquoted/
641
642 Beware that if you put literal backslashes (those not inside
643 interpolated variables) between C<\Q> and C<\E>, double-quotish
644 backslash interpolation may lead to confusing results.  If you
645 I<need> to use literal backslashes within C<\Q...\E>,
646 consult L<perlop/"Gory details of parsing quoted constructs">.
647
648 =head2 Extended Patterns
649
650 Perl also defines a consistent extension syntax for features not
651 found in standard tools like B<awk> and B<lex>.  The syntax is a
652 pair of parentheses with a question mark as the first thing within
653 the parentheses.  The character after the question mark indicates
654 the extension.
655
656 The stability of these extensions varies widely.  Some have been
657 part of the core language for many years.  Others are experimental
658 and may change without warning or be completely removed.  Check
659 the documentation on an individual feature to verify its current
660 status.
661
662 A question mark was chosen for this and for the minimal-matching
663 construct because 1) question marks are rare in older regular
664 expressions, and 2) whenever you see one, you should stop and
665 "question" exactly what is going on.  That's psychology...
666
667 =over 10
668
669 =item C<(?#text)>
670 X<(?#)>
671
672 A comment.  The text is ignored.  If the C</x> modifier enables
673 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
674 the comment as soon as it sees a C<)>, so there is no way to put a literal
675 C<)> in the comment.
676
677 =item C<(?pimsx-imsx)>
678 X<(?)>
679
680 One or more embedded pattern-match modifiers, to be turned on (or
681 turned off, if preceded by C<->) for the remainder of the pattern or
682 the remainder of the enclosing pattern group (if any). This is
683 particularly useful for dynamic patterns, such as those read in from a
684 configuration file, taken from an argument, or specified in a table
685 somewhere.  Consider the case where some patterns want to be case
686 sensitive and some do not:  The case insensitive ones merely need to
687 include C<(?i)> at the front of the pattern.  For example:
688
689     $pattern = "foobar";
690     if ( /$pattern/i ) { }
691
692     # more flexible:
693
694     $pattern = "(?i)foobar";
695     if ( /$pattern/ ) { }
696
697 These modifiers are restored at the end of the enclosing group. For example,
698
699     ( (?i) blah ) \s+ \1
700
701 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
702 repetition of the previous word, assuming the C</x> modifier, and no C</i>
703 modifier outside this group.
704
705 Note that the C<p> modifier is special in that it can only be enabled,
706 not disabled, and that its presence anywhere in a pattern has a global
707 effect. Thus C<(?-p)> and C<(?-p:...)> are meaningless and will warn
708 when executed under C<use warnings>.
709
710 =item C<(?:pattern)>
711 X<(?:)>
712
713 =item C<(?imsx-imsx:pattern)>
714
715 This is for clustering, not capturing; it groups subexpressions like
716 "()", but doesn't make backreferences as "()" does.  So
717
718     @fields = split(/\b(?:a|b|c)\b/)
719
720 is like
721
722     @fields = split(/\b(a|b|c)\b/)
723
724 but doesn't spit out extra fields.  It's also cheaper not to capture
725 characters if you don't need to.
726
727 Any letters between C<?> and C<:> act as flags modifiers as with
728 C<(?imsx-imsx)>.  For example,
729
730     /(?s-i:more.*than).*million/i
731
732 is equivalent to the more verbose
733
734     /(?:(?s-i)more.*than).*million/i
735
736 =item C<(?|pattern)>
737 X<(?|)> X<Branch reset>
738
739 This is the "branch reset" pattern, which has the special property
740 that the capture buffers are numbered from the same starting point
741 in each alternation branch. It is available starting from perl 5.10.0.
742
743 Capture buffers are numbered from left to right, but inside this
744 construct the numbering is restarted for each branch.
745
746 The numbering within each branch will be as normal, and any buffers
747 following this construct will be numbered as though the construct
748 contained only one branch, that being the one with the most capture
749 buffers in it.
750
751 This construct will be useful when you want to capture one of a
752 number of alternative matches.
753
754 Consider the following pattern.  The numbers underneath show in
755 which buffer the captured content will be stored.
756
757
758     # before  ---------------branch-reset----------- after        
759     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
760     # 1            2         2  3        2     3     4  
761
762 Note: as of Perl 5.10.0, branch resets interfere with the contents of
763 the C<%+> hash, that holds named captures. Consider using C<%-> instead.
764
765 =item Look-Around Assertions
766 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
767
768 Look-around assertions are zero width patterns which match a specific
769 pattern without including it in C<$&>. Positive assertions match when
770 their subpattern matches, negative assertions match when their subpattern
771 fails. Look-behind matches text up to the current match position,
772 look-ahead matches text following the current match position.
773
774 =over 4
775
776 =item C<(?=pattern)>
777 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
778
779 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
780 matches a word followed by a tab, without including the tab in C<$&>.
781
782 =item C<(?!pattern)>
783 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
784
785 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
786 matches any occurrence of "foo" that isn't followed by "bar".  Note
787 however that look-ahead and look-behind are NOT the same thing.  You cannot
788 use this for look-behind.
789
790 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
791 will not do what you want.  That's because the C<(?!foo)> is just saying that
792 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
793 match.  You would have to do something like C</(?!foo)...bar/> for that.   We
794 say "like" because there's the case of your "bar" not having three characters
795 before it.  You could cover that this way: C</(?:(?!foo)...|^.{0,2})bar/>.
796 Sometimes it's still easier just to say:
797
798     if (/bar/ && $` !~ /foo$/)
799
800 For look-behind see below.
801
802 =item C<(?<=pattern)> C<\K>
803 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
804
805 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
806 matches a word that follows a tab, without including the tab in C<$&>.
807 Works only for fixed-width look-behind.
808
809 There is a special form of this construct, called C<\K>, which causes the
810 regex engine to "keep" everything it had matched prior to the C<\K> and
811 not include it in C<$&>. This effectively provides variable length
812 look-behind. The use of C<\K> inside of another look-around assertion
813 is allowed, but the behaviour is currently not well defined.
814
815 For various reasons C<\K> may be significantly more efficient than the
816 equivalent C<< (?<=...) >> construct, and it is especially useful in
817 situations where you want to efficiently remove something following
818 something else in a string. For instance
819
820   s/(foo)bar/$1/g;
821
822 can be rewritten as the much more efficient
823
824   s/foo\Kbar//g;
825
826 =item C<(?<!pattern)>
827 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
828
829 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
830 matches any occurrence of "foo" that does not follow "bar".  Works
831 only for fixed-width look-behind.
832
833 =back
834
835 =item C<(?'NAME'pattern)>
836
837 =item C<< (?<NAME>pattern) >>
838 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
839
840 A named capture buffer. Identical in every respect to normal capturing
841 parentheses C<()> but for the additional fact that C<%+> or C<%-> may be
842 used after a successful match to refer to a named buffer. See C<perlvar>
843 for more details on the C<%+> and C<%-> hashes.
844
845 If multiple distinct capture buffers have the same name then the
846 $+{NAME} will refer to the leftmost defined buffer in the match.
847
848 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
849
850 B<NOTE:> While the notation of this construct is the same as the similar
851 function in .NET regexes, the behavior is not. In Perl the buffers are
852 numbered sequentially regardless of being named or not. Thus in the
853 pattern
854
855   /(x)(?<foo>y)(z)/
856
857 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
858 the opposite which is what a .NET regex hacker might expect.
859
860 Currently NAME is restricted to simple identifiers only.
861 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
862 its Unicode extension (see L<utf8>),
863 though it isn't extended by the locale (see L<perllocale>).
864
865 B<NOTE:> In order to make things easier for programmers with experience
866 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
867 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
868 support the use of single quotes as a delimiter for the name.
869
870 =item C<< \k<NAME> >>
871
872 =item C<< \k'NAME' >>
873
874 Named backreference. Similar to numeric backreferences, except that
875 the group is designated by name and not number. If multiple groups
876 have the same name then it refers to the leftmost defined group in
877 the current match.
878
879 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
880 earlier in the pattern.
881
882 Both forms are equivalent.
883
884 B<NOTE:> In order to make things easier for programmers with experience
885 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
886 may be used instead of C<< \k<NAME> >>.
887
888 =item C<(?{ code })>
889 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
890
891 B<WARNING>: This extended regular expression feature is considered
892 experimental, and may be changed without notice. Code executed that
893 has side effects may not perform identically from version to version
894 due to the effect of future optimisations in the regex engine.
895
896 This zero-width assertion evaluates any embedded Perl code.  It
897 always succeeds, and its C<code> is not interpolated.  Currently,
898 the rules to determine where the C<code> ends are somewhat convoluted.
899
900 This feature can be used together with the special variable C<$^N> to
901 capture the results of submatches in variables without having to keep
902 track of the number of nested parentheses. For example:
903
904   $_ = "The brown fox jumps over the lazy dog";
905   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
906   print "color = $color, animal = $animal\n";
907
908 Inside the C<(?{...})> block, C<$_> refers to the string the regular
909 expression is matching against. You can also use C<pos()> to know what is
910 the current position of matching within this string.
911
912 The C<code> is properly scoped in the following sense: If the assertion
913 is backtracked (compare L<"Backtracking">), all changes introduced after
914 C<local>ization are undone, so that
915
916   $_ = 'a' x 8;
917   m<
918      (?{ $cnt = 0 })                    # Initialize $cnt.
919      (
920        a
921        (?{
922            local $cnt = $cnt + 1;       # Update $cnt, backtracking-safe.
923        })
924      )*
925      aaaa
926      (?{ $res = $cnt })                 # On success copy to non-localized
927                                         # location.
928    >x;
929
930 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
931 introduced value, because the scopes that restrict C<local> operators
932 are unwound.
933
934 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
935 switch.  If I<not> used in this way, the result of evaluation of
936 C<code> is put into the special variable C<$^R>.  This happens
937 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
938 inside the same regular expression.
939
940 The assignment to C<$^R> above is properly localized, so the old
941 value of C<$^R> is restored if the assertion is backtracked; compare
942 L<"Backtracking">.
943
944 Due to an unfortunate implementation issue, the Perl code contained in these
945 blocks is treated as a compile time closure that can have seemingly bizarre
946 consequences when used with lexically scoped variables inside of subroutines
947 or loops.  There are various workarounds for this, including simply using
948 global variables instead.  If you are using this construct and strange results
949 occur then check for the use of lexically scoped variables.
950
951 For reasons of security, this construct is forbidden if the regular
952 expression involves run-time interpolation of variables, unless the
953 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
954 variables contain results of C<qr//> operator (see
955 L<perlop/"qr/STRING/imosx">).
956
957 This restriction is due to the wide-spread and remarkably convenient
958 custom of using run-time determined strings as patterns.  For example:
959
960     $re = <>;
961     chomp $re;
962     $string =~ /$re/;
963
964 Before Perl knew how to execute interpolated code within a pattern,
965 this operation was completely safe from a security point of view,
966 although it could raise an exception from an illegal pattern.  If
967 you turn on the C<use re 'eval'>, though, it is no longer secure,
968 so you should only do so if you are also using taint checking.
969 Better yet, use the carefully constrained evaluation within a Safe
970 compartment.  See L<perlsec> for details about both these mechanisms.
971
972 Because Perl's regex engine is currently not re-entrant, interpolated
973 code may not invoke the regex engine either directly with C<m//> or C<s///>),
974 or indirectly with functions such as C<split>.
975
976 =item C<(??{ code })>
977 X<(??{})>
978 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
979
980 B<WARNING>: This extended regular expression feature is considered
981 experimental, and may be changed without notice. Code executed that
982 has side effects may not perform identically from version to version
983 due to the effect of future optimisations in the regex engine.
984
985 This is a "postponed" regular subexpression.  The C<code> is evaluated
986 at run time, at the moment this subexpression may match.  The result
987 of evaluation is considered as a regular expression and matched as
988 if it were inserted instead of this construct.  Note that this means
989 that the contents of capture buffers defined inside an eval'ed pattern
990 are not available outside of the pattern, and vice versa, there is no
991 way for the inner pattern to refer to a capture buffer defined outside.
992 Thus,
993
994     ('a' x 100)=~/(??{'(.)' x 100})/
995
996 B<will> match, it will B<not> set $1.
997
998 The C<code> is not interpolated.  As before, the rules to determine
999 where the C<code> ends are currently somewhat convoluted.
1000
1001 The following pattern matches a parenthesized group:
1002
1003   $re = qr{
1004              \(
1005              (?:
1006                 (?> [^()]+ )    # Non-parens without backtracking
1007               |
1008                 (??{ $re })     # Group with matching parens
1009              )*
1010              \)
1011           }x;
1012
1013 See also C<(?PARNO)> for a different, more efficient way to accomplish
1014 the same task.
1015
1016 Because perl's regex engine is not currently re-entrant, delayed
1017 code may not invoke the regex engine either directly with C<m//> or C<s///>),
1018 or indirectly with functions such as C<split>.
1019
1020 Recursing deeper than 50 times without consuming any input string will
1021 result in a fatal error.  The maximum depth is compiled into perl, so
1022 changing it requires a custom build.
1023
1024 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1025 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1026 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1027 X<regex, relative recursion>
1028
1029 Similar to C<(??{ code })> except it does not involve compiling any code,
1030 instead it treats the contents of a capture buffer as an independent
1031 pattern that must match at the current position.  Capture buffers
1032 contained by the pattern will have the value as determined by the
1033 outermost recursion.
1034
1035 PARNO is a sequence of digits (not starting with 0) whose value reflects
1036 the paren-number of the capture buffer to recurse to. C<(?R)> recurses to
1037 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1038 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1039 to be relative, with negative numbers indicating preceding capture buffers
1040 and positive ones following. Thus C<(?-1)> refers to the most recently
1041 declared buffer, and C<(?+1)> indicates the next buffer to be declared.
1042 Note that the counting for relative recursion differs from that of
1043 relative backreferences, in that with recursion unclosed buffers B<are>
1044 included.
1045
1046 The following pattern matches a function foo() which may contain
1047 balanced parentheses as the argument.
1048
1049   $re = qr{ (                    # paren group 1 (full function)
1050               foo
1051               (                  # paren group 2 (parens)
1052                 \(
1053                   (              # paren group 3 (contents of parens)
1054                   (?:
1055                    (?> [^()]+ )  # Non-parens without backtracking
1056                   |
1057                    (?2)          # Recurse to start of paren group 2
1058                   )*
1059                   )
1060                 \)
1061               )
1062             )
1063           }x;
1064
1065 If the pattern was used as follows
1066
1067     'foo(bar(baz)+baz(bop))'=~/$re/
1068         and print "\$1 = $1\n",
1069                   "\$2 = $2\n",
1070                   "\$3 = $3\n";
1071
1072 the output produced should be the following:
1073
1074     $1 = foo(bar(baz)+baz(bop))
1075     $2 = (bar(baz)+baz(bop))
1076     $3 = bar(baz)+baz(bop)
1077
1078 If there is no corresponding capture buffer defined, then it is a
1079 fatal error.  Recursing deeper than 50 times without consuming any input
1080 string will also result in a fatal error.  The maximum depth is compiled
1081 into perl, so changing it requires a custom build.
1082
1083 The following shows how using negative indexing can make it
1084 easier to embed recursive patterns inside of a C<qr//> construct
1085 for later use:
1086
1087     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1088     if (/foo $parens \s+ + \s+ bar $parens/x) {
1089        # do something here...
1090     }
1091
1092 B<Note> that this pattern does not behave the same way as the equivalent
1093 PCRE or Python construct of the same form. In Perl you can backtrack into
1094 a recursed group, in PCRE and Python the recursed into group is treated
1095 as atomic. Also, modifiers are resolved at compile time, so constructs
1096 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1097 be processed.
1098
1099 =item C<(?&NAME)>
1100 X<(?&NAME)>
1101
1102 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1103 parenthesis to recurse to is determined by name. If multiple parentheses have
1104 the same name, then it recurses to the leftmost.
1105
1106 It is an error to refer to a name that is not declared somewhere in the
1107 pattern.
1108
1109 B<NOTE:> In order to make things easier for programmers with experience
1110 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1111 may be used instead of C<< (?&NAME) >>.
1112
1113 =item C<(?(condition)yes-pattern|no-pattern)>
1114 X<(?()>
1115
1116 =item C<(?(condition)yes-pattern)>
1117
1118 Conditional expression.  C<(condition)> should be either an integer in
1119 parentheses (which is valid if the corresponding pair of parentheses
1120 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1121 name in angle brackets or single quotes (which is valid if a buffer
1122 with the given name matched), or the special symbol (R) (true when
1123 evaluated inside of recursion or eval). Additionally the R may be
1124 followed by a number, (which will be true when evaluated when recursing
1125 inside of the appropriate group), or by C<&NAME>, in which case it will
1126 be true only when evaluated during recursion in the named group.
1127
1128 Here's a summary of the possible predicates:
1129
1130 =over 4
1131
1132 =item (1) (2) ...
1133
1134 Checks if the numbered capturing buffer has matched something.
1135
1136 =item (<NAME>) ('NAME')
1137
1138 Checks if a buffer with the given name has matched something.
1139
1140 =item (?{ CODE })
1141
1142 Treats the code block as the condition.
1143
1144 =item (R)
1145
1146 Checks if the expression has been evaluated inside of recursion.
1147
1148 =item (R1) (R2) ...
1149
1150 Checks if the expression has been evaluated while executing directly
1151 inside of the n-th capture group. This check is the regex equivalent of
1152
1153   if ((caller(0))[3] eq 'subname') { ... }
1154
1155 In other words, it does not check the full recursion stack.
1156
1157 =item (R&NAME)
1158
1159 Similar to C<(R1)>, this predicate checks to see if we're executing
1160 directly inside of the leftmost group with a given name (this is the same
1161 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1162 stack, but only the name of the innermost active recursion.
1163
1164 =item (DEFINE)
1165
1166 In this case, the yes-pattern is never directly executed, and no
1167 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1168 See below for details.
1169
1170 =back
1171
1172 For example:
1173
1174     m{ ( \( )?
1175        [^()]+
1176        (?(1) \) )
1177      }x
1178
1179 matches a chunk of non-parentheses, possibly included in parentheses
1180 themselves.
1181
1182 A special form is the C<(DEFINE)> predicate, which never executes directly
1183 its yes-pattern, and does not allow a no-pattern. This allows to define
1184 subpatterns which will be executed only by using the recursion mechanism.
1185 This way, you can define a set of regular expression rules that can be
1186 bundled into any pattern you choose.
1187
1188 It is recommended that for this usage you put the DEFINE block at the
1189 end of the pattern, and that you name any subpatterns defined within it.
1190
1191 Also, it's worth noting that patterns defined this way probably will
1192 not be as efficient, as the optimiser is not very clever about
1193 handling them.
1194
1195 An example of how this might be used is as follows:
1196
1197   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1198    (?(DEFINE)
1199      (?<NAME_PAT>....)
1200      (?<ADRESS_PAT>....)
1201    )/x
1202
1203 Note that capture buffers matched inside of recursion are not accessible
1204 after the recursion returns, so the extra layer of capturing buffers is
1205 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1206 C<$+{NAME}> would be.
1207
1208 =item C<< (?>pattern) >>
1209 X<backtrack> X<backtracking> X<atomic> X<possessive>
1210
1211 An "independent" subexpression, one which matches the substring
1212 that a I<standalone> C<pattern> would match if anchored at the given
1213 position, and it matches I<nothing other than this substring>.  This
1214 construct is useful for optimizations of what would otherwise be
1215 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1216 It may also be useful in places where the "grab all you can, and do not
1217 give anything back" semantic is desirable.
1218
1219 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1220 (anchored at the beginning of string, as above) will match I<all>
1221 characters C<a> at the beginning of string, leaving no C<a> for
1222 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1223 since the match of the subgroup C<a*> is influenced by the following
1224 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1225 C<a*ab> will match fewer characters than a standalone C<a*>, since
1226 this makes the tail match.
1227
1228 An effect similar to C<< (?>pattern) >> may be achieved by writing
1229 C<(?=(pattern))\1>.  This matches the same substring as a standalone
1230 C<a+>, and the following C<\1> eats the matched string; it therefore
1231 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1232 (The difference between these two constructs is that the second one
1233 uses a capturing group, thus shifting ordinals of backreferences
1234 in the rest of a regular expression.)
1235
1236 Consider this pattern:
1237
1238     m{ \(
1239           (
1240             [^()]+              # x+
1241           |
1242             \( [^()]* \)
1243           )+
1244        \)
1245      }x
1246
1247 That will efficiently match a nonempty group with matching parentheses
1248 two levels deep or less.  However, if there is no such group, it
1249 will take virtually forever on a long string.  That's because there
1250 are so many different ways to split a long string into several
1251 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1252 to a subpattern of the above pattern.  Consider how the pattern
1253 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1254 seconds, but that each extra letter doubles this time.  This
1255 exponential performance will make it appear that your program has
1256 hung.  However, a tiny change to this pattern
1257
1258     m{ \(
1259           (
1260             (?> [^()]+ )        # change x+ above to (?> x+ )
1261           |
1262             \( [^()]* \)
1263           )+
1264        \)
1265      }x
1266
1267 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1268 this yourself would be a productive exercise), but finishes in a fourth
1269 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1270 however, that this pattern currently triggers a warning message under
1271 the C<use warnings> pragma or B<-w> switch saying it
1272 C<"matches null string many times in regex">.
1273
1274 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1275 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1276 This was only 4 times slower on a string with 1000000 C<a>s.
1277
1278 The "grab all you can, and do not give anything back" semantic is desirable
1279 in many situations where on the first sight a simple C<()*> looks like
1280 the correct solution.  Suppose we parse text with comments being delimited
1281 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1282 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1283 the comment delimiter, because it may "give up" some whitespace if
1284 the remainder of the pattern can be made to match that way.  The correct
1285 answer is either one of these:
1286
1287     (?>#[ \t]*)
1288     #[ \t]*(?![ \t])
1289
1290 For example, to grab non-empty comments into $1, one should use either
1291 one of these:
1292
1293     / (?> \# [ \t]* ) (        .+ ) /x;
1294     /     \# [ \t]*   ( [^ \t] .* ) /x;
1295
1296 Which one you pick depends on which of these expressions better reflects
1297 the above specification of comments.
1298
1299 In some literature this construct is called "atomic matching" or
1300 "possessive matching".
1301
1302 Possessive quantifiers are equivalent to putting the item they are applied
1303 to inside of one of these constructs. The following equivalences apply:
1304
1305     Quantifier Form     Bracketing Form
1306     ---------------     ---------------
1307     PAT*+               (?>PAT*)
1308     PAT++               (?>PAT+)
1309     PAT?+               (?>PAT?)
1310     PAT{min,max}+       (?>PAT{min,max})
1311
1312 =back
1313
1314 =head2 Special Backtracking Control Verbs
1315
1316 B<WARNING:> These patterns are experimental and subject to change or
1317 removal in a future version of Perl. Their usage in production code should
1318 be noted to avoid problems during upgrades.
1319
1320 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1321 otherwise stated the ARG argument is optional; in some cases, it is
1322 forbidden.
1323
1324 Any pattern containing a special backtracking verb that allows an argument
1325 has the special behaviour that when executed it sets the current packages'
1326 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1327 rules apply:
1328
1329 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1330 verb pattern, if the verb was involved in the failure of the match. If the
1331 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1332 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1333 none. Also, the C<$REGMARK> variable will be set to FALSE.
1334
1335 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1336 the C<$REGMARK> variable will be set to the name of the last
1337 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1338 C<(*MARK:NAME)> verb below for more details.
1339
1340 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1341 and most other regex related variables. They are not local to a scope, nor
1342 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1343 Use C<local> to localize changes to them to a specific scope if necessary.
1344
1345 If a pattern does not contain a special backtracking verb that allows an
1346 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1347
1348 =over 4
1349
1350 =item Verbs that take an argument
1351
1352 =over 4
1353
1354 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1355 X<(*PRUNE)> X<(*PRUNE:NAME)>
1356
1357 This zero-width pattern prunes the backtracking tree at the current point
1358 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1359 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1360 A may backtrack as necessary to match. Once it is reached, matching
1361 continues in B, which may also backtrack as necessary; however, should B
1362 not match, then no further backtracking will take place, and the pattern
1363 will fail outright at the current starting position.
1364
1365 The following example counts all the possible matching strings in a
1366 pattern (without actually matching any of them).
1367
1368     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1369     print "Count=$count\n";
1370
1371 which produces:
1372
1373     aaab
1374     aaa
1375     aa
1376     a
1377     aab
1378     aa
1379     a
1380     ab
1381     a
1382     Count=9
1383
1384 If we add a C<(*PRUNE)> before the count like the following
1385
1386     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1387     print "Count=$count\n";
1388
1389 we prevent backtracking and find the count of the longest matching
1390 at each matching starting point like so:
1391
1392     aaab
1393     aab
1394     ab
1395     Count=3
1396
1397 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1398
1399 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1400 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1401 replaced with a C<< (?>pattern) >> with no functional difference; however,
1402 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1403 C<< (?>pattern) >> alone.
1404
1405
1406 =item C<(*SKIP)> C<(*SKIP:NAME)>
1407 X<(*SKIP)>
1408
1409 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1410 failure it also signifies that whatever text that was matched leading up
1411 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1412 of this pattern. This effectively means that the regex engine "skips" forward
1413 to this position on failure and tries to match again, (assuming that
1414 there is sufficient room to match).
1415
1416 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1417 C<(*MARK:NAME)> was encountered while matching, then it is that position
1418 which is used as the "skip point". If no C<(*MARK)> of that name was
1419 encountered, then the C<(*SKIP)> operator has no effect. When used
1420 without a name the "skip point" is where the match point was when
1421 executing the (*SKIP) pattern.
1422
1423 Compare the following to the examples in C<(*PRUNE)>, note the string
1424 is twice as long:
1425
1426     'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1427     print "Count=$count\n";
1428
1429 outputs
1430
1431     aaab
1432     aaab
1433     Count=2
1434
1435 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1436 executed, the next starting point will be where the cursor was when the
1437 C<(*SKIP)> was executed.
1438
1439 =item C<(*MARK:NAME)> C<(*:NAME)>
1440 X<(*MARK)> C<(*MARK:NAME)> C<(*:NAME)>
1441
1442 This zero-width pattern can be used to mark the point reached in a string
1443 when a certain part of the pattern has been successfully matched. This
1444 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1445 forward to that point if backtracked into on failure. Any number of
1446 C<(*MARK)> patterns are allowed, and the NAME portion is optional and may
1447 be duplicated.
1448
1449 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1450 can be used to "label" a pattern branch, so that after matching, the
1451 program can determine which branches of the pattern were involved in the
1452 match.
1453
1454 When a match is successful, the C<$REGMARK> variable will be set to the
1455 name of the most recently executed C<(*MARK:NAME)> that was involved
1456 in the match.
1457
1458 This can be used to determine which branch of a pattern was matched
1459 without using a separate capture buffer for each branch, which in turn
1460 can result in a performance improvement, as perl cannot optimize
1461 C</(?:(x)|(y)|(z))/> as efficiently as something like
1462 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1463
1464 When a match has failed, and unless another verb has been involved in
1465 failing the match and has provided its own name to use, the C<$REGERROR>
1466 variable will be set to the name of the most recently executed
1467 C<(*MARK:NAME)>.
1468
1469 See C<(*SKIP)> for more details.
1470
1471 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1472
1473 =item C<(*THEN)> C<(*THEN:NAME)>
1474
1475 This is similar to the "cut group" operator C<::> from Perl 6. Like
1476 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1477 failure, it causes the regex engine to try the next alternation in the
1478 innermost enclosing group (capturing or otherwise).
1479
1480 Its name comes from the observation that this operation combined with the
1481 alternation operator (C<|>) can be used to create what is essentially a
1482 pattern-based if/then/else block:
1483
1484   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1485
1486 Note that if this operator is used and NOT inside of an alternation then
1487 it acts exactly like the C<(*PRUNE)> operator.
1488
1489   / A (*PRUNE) B /
1490
1491 is the same as
1492
1493   / A (*THEN) B /
1494
1495 but
1496
1497   / ( A (*THEN) B | C (*THEN) D ) /
1498
1499 is not the same as
1500
1501   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1502
1503 as after matching the A but failing on the B the C<(*THEN)> verb will
1504 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1505
1506 =item C<(*COMMIT)>
1507 X<(*COMMIT)>
1508
1509 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1510 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1511 into on failure it causes the match to fail outright. No further attempts
1512 to find a valid match by advancing the start pointer will occur again.
1513 For example,
1514
1515     'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1516     print "Count=$count\n";
1517
1518 outputs
1519
1520     aaab
1521     Count=1
1522
1523 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1524 does not match, the regex engine will not try any further matching on the
1525 rest of the string.
1526
1527 =back
1528
1529 =item Verbs without an argument
1530
1531 =over 4
1532
1533 =item C<(*FAIL)> C<(*F)>
1534 X<(*FAIL)> X<(*F)>
1535
1536 This pattern matches nothing and always fails. It can be used to force the
1537 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1538 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1539
1540 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1541
1542 =item C<(*ACCEPT)>
1543 X<(*ACCEPT)>
1544
1545 B<WARNING:> This feature is highly experimental. It is not recommended
1546 for production code.
1547
1548 This pattern matches nothing and causes the end of successful matching at
1549 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1550 whether there is actually more to match in the string. When inside of a
1551 nested pattern, such as recursion, or in a subpattern dynamically generated
1552 via C<(??{})>, only the innermost pattern is ended immediately.
1553
1554 If the C<(*ACCEPT)> is inside of capturing buffers then the buffers are
1555 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1556 For instance:
1557
1558   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1559
1560 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1561 be set. If another branch in the inner parentheses were matched, such as in the
1562 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1563
1564 =back
1565
1566 =back
1567
1568 =head2 Backtracking
1569 X<backtrack> X<backtracking>
1570
1571 NOTE: This section presents an abstract approximation of regular
1572 expression behavior.  For a more rigorous (and complicated) view of
1573 the rules involved in selecting a match among possible alternatives,
1574 see L<Combining RE Pieces>.
1575
1576 A fundamental feature of regular expression matching involves the
1577 notion called I<backtracking>, which is currently used (when needed)
1578 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1579 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1580 internally, but the general principle outlined here is valid.
1581
1582 For a regular expression to match, the I<entire> regular expression must
1583 match, not just part of it.  So if the beginning of a pattern containing a
1584 quantifier succeeds in a way that causes later parts in the pattern to
1585 fail, the matching engine backs up and recalculates the beginning
1586 part--that's why it's called backtracking.
1587
1588 Here is an example of backtracking:  Let's say you want to find the
1589 word following "foo" in the string "Food is on the foo table.":
1590
1591     $_ = "Food is on the foo table.";
1592     if ( /\b(foo)\s+(\w+)/i ) {
1593         print "$2 follows $1.\n";
1594     }
1595
1596 When the match runs, the first part of the regular expression (C<\b(foo)>)
1597 finds a possible match right at the beginning of the string, and loads up
1598 $1 with "Foo".  However, as soon as the matching engine sees that there's
1599 no whitespace following the "Foo" that it had saved in $1, it realizes its
1600 mistake and starts over again one character after where it had the
1601 tentative match.  This time it goes all the way until the next occurrence
1602 of "foo". The complete regular expression matches this time, and you get
1603 the expected output of "table follows foo."
1604
1605 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1606 everything between "foo" and "bar".  Initially, you write something
1607 like this:
1608
1609     $_ =  "The food is under the bar in the barn.";
1610     if ( /foo(.*)bar/ ) {
1611         print "got <$1>\n";
1612     }
1613
1614 Which perhaps unexpectedly yields:
1615
1616   got <d is under the bar in the >
1617
1618 That's because C<.*> was greedy, so you get everything between the
1619 I<first> "foo" and the I<last> "bar".  Here it's more effective
1620 to use minimal matching to make sure you get the text between a "foo"
1621 and the first "bar" thereafter.
1622
1623     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
1624   got <d is under the >
1625
1626 Here's another example. Let's say you'd like to match a number at the end
1627 of a string, and you also want to keep the preceding part of the match.
1628 So you write this:
1629
1630     $_ = "I have 2 numbers: 53147";
1631     if ( /(.*)(\d*)/ ) {                                # Wrong!
1632         print "Beginning is <$1>, number is <$2>.\n";
1633     }
1634
1635 That won't work at all, because C<.*> was greedy and gobbled up the
1636 whole string. As C<\d*> can match on an empty string the complete
1637 regular expression matched successfully.
1638
1639     Beginning is <I have 2 numbers: 53147>, number is <>.
1640
1641 Here are some variants, most of which don't work:
1642
1643     $_ = "I have 2 numbers: 53147";
1644     @pats = qw{
1645         (.*)(\d*)
1646         (.*)(\d+)
1647         (.*?)(\d*)
1648         (.*?)(\d+)
1649         (.*)(\d+)$
1650         (.*?)(\d+)$
1651         (.*)\b(\d+)$
1652         (.*\D)(\d+)$
1653     };
1654
1655     for $pat (@pats) {
1656         printf "%-12s ", $pat;
1657         if ( /$pat/ ) {
1658             print "<$1> <$2>\n";
1659         } else {
1660             print "FAIL\n";
1661         }
1662     }
1663
1664 That will print out:
1665
1666     (.*)(\d*)    <I have 2 numbers: 53147> <>
1667     (.*)(\d+)    <I have 2 numbers: 5314> <7>
1668     (.*?)(\d*)   <> <>
1669     (.*?)(\d+)   <I have > <2>
1670     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
1671     (.*?)(\d+)$  <I have 2 numbers: > <53147>
1672     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
1673     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
1674
1675 As you see, this can be a bit tricky.  It's important to realize that a
1676 regular expression is merely a set of assertions that gives a definition
1677 of success.  There may be 0, 1, or several different ways that the
1678 definition might succeed against a particular string.  And if there are
1679 multiple ways it might succeed, you need to understand backtracking to
1680 know which variety of success you will achieve.
1681
1682 When using look-ahead assertions and negations, this can all get even
1683 trickier.  Imagine you'd like to find a sequence of non-digits not
1684 followed by "123".  You might try to write that as
1685
1686     $_ = "ABC123";
1687     if ( /^\D*(?!123)/ ) {              # Wrong!
1688         print "Yup, no 123 in $_\n";
1689     }
1690
1691 But that isn't going to match; at least, not the way you're hoping.  It
1692 claims that there is no 123 in the string.  Here's a clearer picture of
1693 why that pattern matches, contrary to popular expectations:
1694
1695     $x = 'ABC123';
1696     $y = 'ABC445';
1697
1698     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
1699     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
1700
1701     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
1702     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
1703
1704 This prints
1705
1706     2: got ABC
1707     3: got AB
1708     4: got ABC
1709
1710 You might have expected test 3 to fail because it seems to a more
1711 general purpose version of test 1.  The important difference between
1712 them is that test 3 contains a quantifier (C<\D*>) and so can use
1713 backtracking, whereas test 1 will not.  What's happening is
1714 that you've asked "Is it true that at the start of $x, following 0 or more
1715 non-digits, you have something that's not 123?"  If the pattern matcher had
1716 let C<\D*> expand to "ABC", this would have caused the whole pattern to
1717 fail.
1718
1719 The search engine will initially match C<\D*> with "ABC".  Then it will
1720 try to match C<(?!123> with "123", which fails.  But because
1721 a quantifier (C<\D*>) has been used in the regular expression, the
1722 search engine can backtrack and retry the match differently
1723 in the hope of matching the complete regular expression.
1724
1725 The pattern really, I<really> wants to succeed, so it uses the
1726 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
1727 time.  Now there's indeed something following "AB" that is not
1728 "123".  It's "C123", which suffices.
1729
1730 We can deal with this by using both an assertion and a negation.
1731 We'll say that the first part in $1 must be followed both by a digit
1732 and by something that's not "123".  Remember that the look-aheads
1733 are zero-width expressions--they only look, but don't consume any
1734 of the string in their match.  So rewriting this way produces what
1735 you'd expect; that is, case 5 will fail, but case 6 succeeds:
1736
1737     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
1738     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
1739
1740     6: got ABC
1741
1742 In other words, the two zero-width assertions next to each other work as though
1743 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
1744 matches only if you're at the beginning of the line AND the end of the
1745 line simultaneously.  The deeper underlying truth is that juxtaposition in
1746 regular expressions always means AND, except when you write an explicit OR
1747 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
1748 although the attempted matches are made at different positions because "a"
1749 is not a zero-width assertion, but a one-width assertion.
1750
1751 B<WARNING>: Particularly complicated regular expressions can take
1752 exponential time to solve because of the immense number of possible
1753 ways they can use backtracking to try for a match.  For example, without
1754 internal optimizations done by the regular expression engine, this will
1755 take a painfully long time to run:
1756
1757     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
1758
1759 And if you used C<*>'s in the internal groups instead of limiting them
1760 to 0 through 5 matches, then it would take forever--or until you ran
1761 out of stack space.  Moreover, these internal optimizations are not
1762 always applicable.  For example, if you put C<{0,5}> instead of C<*>
1763 on the external group, no current optimization is applicable, and the
1764 match takes a long time to finish.
1765
1766 A powerful tool for optimizing such beasts is what is known as an
1767 "independent group",
1768 which does not backtrack (see L<C<< (?>pattern) >>>).  Note also that
1769 zero-length look-ahead/look-behind assertions will not backtrack to make
1770 the tail match, since they are in "logical" context: only
1771 whether they match is considered relevant.  For an example
1772 where side-effects of look-ahead I<might> have influenced the
1773 following match, see L<C<< (?>pattern) >>>.
1774
1775 =head2 Version 8 Regular Expressions
1776 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
1777
1778 In case you're not familiar with the "regular" Version 8 regex
1779 routines, here are the pattern-matching rules not described above.
1780
1781 Any single character matches itself, unless it is a I<metacharacter>
1782 with a special meaning described here or above.  You can cause
1783 characters that normally function as metacharacters to be interpreted
1784 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
1785 character; "\\" matches a "\"). This escape mechanism is also required
1786 for the character used as the pattern delimiter.
1787
1788 A series of characters matches that series of characters in the target
1789 string, so the pattern  C<blurfl> would match "blurfl" in the target
1790 string.
1791
1792 You can specify a character class, by enclosing a list of characters
1793 in C<[]>, which will match any character from the list.  If the
1794 first character after the "[" is "^", the class matches any character not
1795 in the list.  Within a list, the "-" character specifies a
1796 range, so that C<a-z> represents all characters between "a" and "z",
1797 inclusive.  If you want either "-" or "]" itself to be a member of a
1798 class, put it at the start of the list (possibly after a "^"), or
1799 escape it with a backslash.  "-" is also taken literally when it is
1800 at the end of the list, just before the closing "]".  (The
1801 following all specify the same class of three characters: C<[-az]>,
1802 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
1803 specifies a class containing twenty-six characters, even on EBCDIC-based
1804 character sets.)  Also, if you try to use the character
1805 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
1806 a range, the "-" is understood literally.
1807
1808 Note also that the whole range idea is rather unportable between
1809 character sets--and even within character sets they may cause results
1810 you probably didn't expect.  A sound principle is to use only ranges
1811 that begin from and end at either alphabetics of equal case ([a-e],
1812 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
1813 spell out the character sets in full.
1814
1815 Characters may be specified using a metacharacter syntax much like that
1816 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
1817 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
1818 of octal digits, matches the character whose coded character set value
1819 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
1820 matches the character whose numeric value is I<nn>. The expression \cI<x>
1821 matches the character control-I<x>.  Finally, the "." metacharacter
1822 matches any character except "\n" (unless you use C</s>).
1823
1824 You can specify a series of alternatives for a pattern using "|" to
1825 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
1826 or "foe" in the target string (as would C<f(e|i|o)e>).  The
1827 first alternative includes everything from the last pattern delimiter
1828 ("(", "[", or the beginning of the pattern) up to the first "|", and
1829 the last alternative contains everything from the last "|" to the next
1830 pattern delimiter.  That's why it's common practice to include
1831 alternatives in parentheses: to minimize confusion about where they
1832 start and end.
1833
1834 Alternatives are tried from left to right, so the first
1835 alternative found for which the entire expression matches, is the one that
1836 is chosen. This means that alternatives are not necessarily greedy. For
1837 example: when matching C<foo|foot> against "barefoot", only the "foo"
1838 part will match, as that is the first alternative tried, and it successfully
1839 matches the target string. (This might not seem important, but it is
1840 important when you are capturing matched text using parentheses.)
1841
1842 Also remember that "|" is interpreted as a literal within square brackets,
1843 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
1844
1845 Within a pattern, you may designate subpatterns for later reference
1846 by enclosing them in parentheses, and you may refer back to the
1847 I<n>th subpattern later in the pattern using the metacharacter
1848 \I<n>.  Subpatterns are numbered based on the left to right order
1849 of their opening parenthesis.  A backreference matches whatever
1850 actually matched the subpattern in the string being examined, not
1851 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\1\d*> will
1852 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
1853 1 matched "0x", even though the rule C<0|0x> could potentially match
1854 the leading 0 in the second number.
1855
1856 =head2 Warning on \1 Instead of $1
1857
1858 Some people get too used to writing things like:
1859
1860     $pattern =~ s/(\W)/\\\1/g;
1861
1862 This is grandfathered for the RHS of a substitute to avoid shocking the
1863 B<sed> addicts, but it's a dirty habit to get into.  That's because in
1864 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
1865 the usual double-quoted string means a control-A.  The customary Unix
1866 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
1867 of doing that, you get yourself into trouble if you then add an C</e>
1868 modifier.
1869
1870     s/(\d+)/ \1 + 1 /eg;        # causes warning under -w
1871
1872 Or if you try to do
1873
1874     s/(\d+)/\1000/;
1875
1876 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
1877 C<${1}000>.  The operation of interpolation should not be confused
1878 with the operation of matching a backreference.  Certainly they mean two
1879 different things on the I<left> side of the C<s///>.
1880
1881 =head2 Repeated Patterns Matching a Zero-length Substring
1882
1883 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
1884
1885 Regular expressions provide a terse and powerful programming language.  As
1886 with most other power tools, power comes together with the ability
1887 to wreak havoc.
1888
1889 A common abuse of this power stems from the ability to make infinite
1890 loops using regular expressions, with something as innocuous as:
1891
1892     'foo' =~ m{ ( o? )* }x;
1893
1894 The C<o?> matches at the beginning of C<'foo'>, and since the position
1895 in the string is not moved by the match, C<o?> would match again and again
1896 because of the C<*> quantifier.  Another common way to create a similar cycle
1897 is with the looping modifier C<//g>:
1898
1899     @matches = ( 'foo' =~ m{ o? }xg );
1900
1901 or
1902
1903     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
1904
1905 or the loop implied by split().
1906
1907 However, long experience has shown that many programming tasks may
1908 be significantly simplified by using repeated subexpressions that
1909 may match zero-length substrings.  Here's a simple example being:
1910
1911     @chars = split //, $string;           # // is not magic in split
1912     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
1913
1914 Thus Perl allows such constructs, by I<forcefully breaking
1915 the infinite loop>.  The rules for this are different for lower-level
1916 loops given by the greedy quantifiers C<*+{}>, and for higher-level
1917 ones like the C</g> modifier or split() operator.
1918
1919 The lower-level loops are I<interrupted> (that is, the loop is
1920 broken) when Perl detects that a repeated expression matched a
1921 zero-length substring.   Thus
1922
1923    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
1924
1925 is made equivalent to
1926
1927    m{   (?: NON_ZERO_LENGTH )*
1928       |
1929         (?: ZERO_LENGTH )?
1930     }x;
1931
1932 The higher level-loops preserve an additional state between iterations:
1933 whether the last match was zero-length.  To break the loop, the following
1934 match after a zero-length match is prohibited to have a length of zero.
1935 This prohibition interacts with backtracking (see L<"Backtracking">),
1936 and so the I<second best> match is chosen if the I<best> match is of
1937 zero length.
1938
1939 For example:
1940
1941     $_ = 'bar';
1942     s/\w??/<$&>/g;
1943
1944 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
1945 match given by non-greedy C<??> is the zero-length match, and the I<second
1946 best> match is what is matched by C<\w>.  Thus zero-length matches
1947 alternate with one-character-long matches.
1948
1949 Similarly, for repeated C<m/()/g> the second-best match is the match at the
1950 position one notch further in the string.
1951
1952 The additional state of being I<matched with zero-length> is associated with
1953 the matched string, and is reset by each assignment to pos().
1954 Zero-length matches at the end of the previous match are ignored
1955 during C<split>.
1956
1957 =head2 Combining RE Pieces
1958
1959 Each of the elementary pieces of regular expressions which were described
1960 before (such as C<ab> or C<\Z>) could match at most one substring
1961 at the given position of the input string.  However, in a typical regular
1962 expression these elementary pieces are combined into more complicated
1963 patterns using combining operators C<ST>, C<S|T>, C<S*> etc
1964 (in these examples C<S> and C<T> are regular subexpressions).
1965
1966 Such combinations can include alternatives, leading to a problem of choice:
1967 if we match a regular expression C<a|ab> against C<"abc">, will it match
1968 substring C<"a"> or C<"ab">?  One way to describe which substring is
1969 actually matched is the concept of backtracking (see L<"Backtracking">).
1970 However, this description is too low-level and makes you think
1971 in terms of a particular implementation.
1972
1973 Another description starts with notions of "better"/"worse".  All the
1974 substrings which may be matched by the given regular expression can be
1975 sorted from the "best" match to the "worst" match, and it is the "best"
1976 match which is chosen.  This substitutes the question of "what is chosen?"
1977 by the question of "which matches are better, and which are worse?".
1978
1979 Again, for elementary pieces there is no such question, since at most
1980 one match at a given position is possible.  This section describes the
1981 notion of better/worse for combining operators.  In the description
1982 below C<S> and C<T> are regular subexpressions.
1983
1984 =over 4
1985
1986 =item C<ST>
1987
1988 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
1989 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
1990 which can be matched by C<T>.
1991
1992 If C<A> is better match for C<S> than C<A'>, C<AB> is a better
1993 match than C<A'B'>.
1994
1995 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
1996 C<B> is better match for C<T> than C<B'>.
1997
1998 =item C<S|T>
1999
2000 When C<S> can match, it is a better match than when only C<T> can match.
2001
2002 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2003 two matches for C<T>.
2004
2005 =item C<S{REPEAT_COUNT}>
2006
2007 Matches as C<SSS...S> (repeated as many times as necessary).
2008
2009 =item C<S{min,max}>
2010
2011 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2012
2013 =item C<S{min,max}?>
2014
2015 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2016
2017 =item C<S?>, C<S*>, C<S+>
2018
2019 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2020
2021 =item C<S??>, C<S*?>, C<S+?>
2022
2023 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2024
2025 =item C<< (?>S) >>
2026
2027 Matches the best match for C<S> and only that.
2028
2029 =item C<(?=S)>, C<(?<=S)>
2030
2031 Only the best match for C<S> is considered.  (This is important only if
2032 C<S> has capturing parentheses, and backreferences are used somewhere
2033 else in the whole regular expression.)
2034
2035 =item C<(?!S)>, C<(?<!S)>
2036
2037 For this grouping operator there is no need to describe the ordering, since
2038 only whether or not C<S> can match is important.
2039
2040 =item C<(??{ EXPR })>, C<(?PARNO)>
2041
2042 The ordering is the same as for the regular expression which is
2043 the result of EXPR, or the pattern contained by capture buffer PARNO.
2044
2045 =item C<(?(condition)yes-pattern|no-pattern)>
2046
2047 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2048 already determined.  The ordering of the matches is the same as for the
2049 chosen subexpression.
2050
2051 =back
2052
2053 The above recipes describe the ordering of matches I<at a given position>.
2054 One more rule is needed to understand how a match is determined for the
2055 whole regular expression: a match at an earlier position is always better
2056 than a match at a later position.
2057
2058 =head2 Creating Custom RE Engines
2059
2060 Overloaded constants (see L<overload>) provide a simple way to extend
2061 the functionality of the RE engine.
2062
2063 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2064 matches at a boundary between whitespace characters and non-whitespace
2065 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2066 at these positions, so we want to have each C<\Y|> in the place of the
2067 more complicated version.  We can create a module C<customre> to do
2068 this:
2069
2070     package customre;
2071     use overload;
2072
2073     sub import {
2074       shift;
2075       die "No argument to customre::import allowed" if @_;
2076       overload::constant 'qr' => \&convert;
2077     }
2078
2079     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2080
2081     # We must also take care of not escaping the legitimate \\Y|
2082     # sequence, hence the presence of '\\' in the conversion rules.
2083     my %rules = ( '\\' => '\\\\',
2084                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2085     sub convert {
2086       my $re = shift;
2087       $re =~ s{
2088                 \\ ( \\ | Y . )
2089               }
2090               { $rules{$1} or invalid($re,$1) }sgex;
2091       return $re;
2092     }
2093
2094 Now C<use customre> enables the new escape in constant regular
2095 expressions, i.e., those without any runtime variable interpolations.
2096 As documented in L<overload>, this conversion will work only over
2097 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2098 part of this regular expression needs to be converted explicitly
2099 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2100
2101     use customre;
2102     $re = <>;
2103     chomp $re;
2104     $re = customre::convert $re;
2105     /\Y|$re\Y|/;
2106
2107 =head1 PCRE/Python Support
2108
2109 As of Perl 5.10.0, Perl supports several Python/PCRE specific extensions
2110 to the regex syntax. While Perl programmers are encouraged to use the
2111 Perl specific syntax, the following are also accepted:
2112
2113 =over 4
2114
2115 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2116
2117 Define a named capture buffer. Equivalent to C<< (?<NAME>pattern) >>.
2118
2119 =item C<< (?P=NAME) >>
2120
2121 Backreference to a named capture buffer. Equivalent to C<< \g{NAME} >>.
2122
2123 =item C<< (?P>NAME) >>
2124
2125 Subroutine call to a named capture buffer. Equivalent to C<< (?&NAME) >>.
2126
2127 =back
2128
2129 =head1 BUGS
2130
2131 This document varies from difficult to understand to completely
2132 and utterly opaque.  The wandering prose riddled with jargon is
2133 hard to fathom in several places.
2134
2135 This document needs a rewrite that separates the tutorial content
2136 from the reference content.
2137
2138 =head1 SEE ALSO
2139
2140 L<perlrequick>.
2141
2142 L<perlretut>.
2143
2144 L<perlop/"Regexp Quote-Like Operators">.
2145
2146 L<perlop/"Gory details of parsing quoted constructs">.
2147
2148 L<perlfaq6>.
2149
2150 L<perlfunc/pos>.
2151
2152 L<perllocale>.
2153
2154 L<perlebcdic>.
2155
2156 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2157 by O'Reilly and Associates.