Put a watchdog on openpid.t: it has been found to hang in some Win32 smokes.
[perl.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8 X<variable, name> X<variable name> X<data type> X<type>
9
10 Perl has three built-in data types: scalars, arrays of scalars, and
11 associative arrays of scalars, known as "hashes".  A scalar is a 
12 single string (of any size, limited only by the available memory),
13 number, or a reference to something (which will be discussed
14 in L<perlref>).  Normal arrays are ordered lists of scalars indexed
15 by number, starting with 0.  Hashes are unordered collections of scalar 
16 values indexed by their associated string key.
17
18 Values are usually referred to by name, or through a named reference.
19 The first character of the name tells you to what sort of data
20 structure it refers.  The rest of the name tells you the particular
21 value to which it refers.  Usually this name is a single I<identifier>,
22 that is, a string beginning with a letter or underscore, and
23 containing letters, underscores, and digits.  In some cases, it may
24 be a chain of identifiers, separated by C<::> (or by the slightly
25 archaic C<'>); all but the last are interpreted as names of packages,
26 to locate the namespace in which to look up the final identifier
27 (see L<perlmod/Packages> for details).  It's possible to substitute
28 for a simple identifier, an expression that produces a reference
29 to the value at runtime.   This is described in more detail below
30 and in L<perlref>.
31 X<identifier>
32
33 Perl also has its own built-in variables whose names don't follow
34 these rules.  They have strange names so they don't accidentally
35 collide with one of your normal variables.  Strings that match
36 parenthesized parts of a regular expression are saved under names
37 containing only digits after the C<$> (see L<perlop> and L<perlre>).
38 In addition, several special variables that provide windows into
39 the inner working of Perl have names containing punctuation characters
40 and control characters.  These are documented in L<perlvar>.
41 X<variable, built-in>
42
43 Scalar values are always named with '$', even when referring to a
44 scalar that is part of an array or a hash.  The '$' symbol works
45 semantically like the English word "the" in that it indicates a
46 single value is expected.
47 X<scalar>
48
49     $days               # the simple scalar value "days"
50     $days[28]           # the 29th element of array @days
51     $days{'Feb'}        # the 'Feb' value from hash %days
52     $#days              # the last index of array @days
53
54 Entire arrays (and slices of arrays and hashes) are denoted by '@',
55 which works much like the word "these" or "those" does in English,
56 in that it indicates multiple values are expected.
57 X<array>
58
59     @days               # ($days[0], $days[1],... $days[n])
60     @days[3,4,5]        # same as ($days[3],$days[4],$days[5])
61     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
62
63 Entire hashes are denoted by '%':
64 X<hash>
65
66     %days               # (key1, val1, key2, val2 ...)
67
68 In addition, subroutines are named with an initial '&', though this
69 is optional when unambiguous, just as the word "do" is often redundant
70 in English.  Symbol table entries can be named with an initial '*',
71 but you don't really care about that yet (if ever :-).
72
73 Every variable type has its own namespace, as do several
74 non-variable identifiers.  This means that you can, without fear
75 of conflict, use the same name for a scalar variable, an array, or
76 a hash--or, for that matter, for a filehandle, a directory handle, a
77 subroutine name, a format name, or a label.  This means that $foo
78 and @foo are two different variables.  It also means that C<$foo[1]>
79 is a part of @foo, not a part of $foo.  This may seem a bit weird,
80 but that's okay, because it is weird.
81 X<namespace>
82
83 Because variable references always start with '$', '@', or '%', the
84 "reserved" words aren't in fact reserved with respect to variable
85 names.  They I<are> reserved with respect to labels and filehandles,
86 however, which don't have an initial special character.  You can't
87 have a filehandle named "log", for instance.  Hint: you could say
88 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using
89 uppercase filehandles also improves readability and protects you
90 from conflict with future reserved words.  Case I<is> significant--"FOO",
91 "Foo", and "foo" are all different names.  Names that start with a
92 letter or underscore may also contain digits and underscores.
93 X<identifier, case sensitivity>
94 X<case>
95
96 It is possible to replace such an alphanumeric name with an expression
97 that returns a reference to the appropriate type.  For a description
98 of this, see L<perlref>.
99
100 Names that start with a digit may contain only more digits.  Names
101 that do not start with a letter, underscore, digit or a caret (i.e.
102 a control character) are limited to one character, e.g.,  C<$%> or
103 C<$$>.  (Most of these one character names have a predefined
104 significance to Perl.  For instance, C<$$> is the current process
105 id.)
106
107 =head2 Context
108 X<context> X<scalar context> X<list context>
109
110 The interpretation of operations and values in Perl sometimes depends
111 on the requirements of the context around the operation or value.
112 There are two major contexts: list and scalar.  Certain operations
113 return list values in contexts wanting a list, and scalar values
114 otherwise.  If this is true of an operation it will be mentioned in
115 the documentation for that operation.  In other words, Perl overloads
116 certain operations based on whether the expected return value is
117 singular or plural.  Some words in English work this way, like "fish"
118 and "sheep".
119
120 In a reciprocal fashion, an operation provides either a scalar or a
121 list context to each of its arguments.  For example, if you say
122
123     int( <STDIN> )
124
125 the integer operation provides scalar context for the <>
126 operator, which responds by reading one line from STDIN and passing it
127 back to the integer operation, which will then find the integer value
128 of that line and return that.  If, on the other hand, you say
129
130     sort( <STDIN> )
131
132 then the sort operation provides list context for <>, which
133 will proceed to read every line available up to the end of file, and
134 pass that list of lines back to the sort routine, which will then
135 sort those lines and return them as a list to whatever the context
136 of the sort was.
137
138 Assignment is a little bit special in that it uses its left argument
139 to determine the context for the right argument.  Assignment to a
140 scalar evaluates the right-hand side in scalar context, while
141 assignment to an array or hash evaluates the righthand side in list
142 context.  Assignment to a list (or slice, which is just a list
143 anyway) also evaluates the righthand side in list context.
144
145 When you use the C<use warnings> pragma or Perl's B<-w> command-line 
146 option, you may see warnings
147 about useless uses of constants or functions in "void context".
148 Void context just means the value has been discarded, such as a
149 statement containing only C<"fred";> or C<getpwuid(0);>.  It still
150 counts as scalar context for functions that care whether or not
151 they're being called in list context.
152
153 User-defined subroutines may choose to care whether they are being
154 called in a void, scalar, or list context.  Most subroutines do not
155 need to bother, though.  That's because both scalars and lists are
156 automatically interpolated into lists.  See L<perlfunc/wantarray>
157 for how you would dynamically discern your function's calling
158 context.
159
160 =head2 Scalar values
161 X<scalar> X<number> X<string> X<reference>
162
163 All data in Perl is a scalar, an array of scalars, or a hash of
164 scalars.  A scalar may contain one single value in any of three
165 different flavors: a number, a string, or a reference.  In general,
166 conversion from one form to another is transparent.  Although a
167 scalar may not directly hold multiple values, it may contain a
168 reference to an array or hash which in turn contains multiple values.
169
170 Scalars aren't necessarily one thing or another.  There's no place
171 to declare a scalar variable to be of type "string", type "number",
172 type "reference", or anything else.  Because of the automatic
173 conversion of scalars, operations that return scalars don't need
174 to care (and in fact, cannot care) whether their caller is looking
175 for a string, a number, or a reference.  Perl is a contextually
176 polymorphic language whose scalars can be strings, numbers, or
177 references (which includes objects).  Although strings and numbers
178 are considered pretty much the same thing for nearly all purposes,
179 references are strongly-typed, uncastable pointers with builtin
180 reference-counting and destructor invocation.
181
182 A scalar value is interpreted as TRUE in the Boolean sense if it is not
183 the null string or the number 0 (or its string equivalent, "0").  The
184 Boolean context is just a special kind of scalar context where no 
185 conversion to a string or a number is ever performed.
186 X<boolean> X<bool> X<true> X<false> X<truth>
187
188 There are actually two varieties of null strings (sometimes referred
189 to as "empty" strings), a defined one and an undefined one.  The
190 defined version is just a string of length zero, such as C<"">.
191 The undefined version is the value that indicates that there is
192 no real value for something, such as when there was an error, or
193 at end of file, or when you refer to an uninitialized variable or
194 element of an array or hash.  Although in early versions of Perl,
195 an undefined scalar could become defined when first used in a
196 place expecting a defined value, this no longer happens except for
197 rare cases of autovivification as explained in L<perlref>.  You can
198 use the defined() operator to determine whether a scalar value is
199 defined (this has no meaning on arrays or hashes), and the undef()
200 operator to produce an undefined value.
201 X<defined> X<undefined> X<undef> X<null> X<string, null>
202
203 To find out whether a given string is a valid non-zero number, it's
204 sometimes enough to test it against both numeric 0 and also lexical
205 "0" (although this will cause noises if warnings are on).  That's 
206 because strings that aren't numbers count as 0, just as they do in B<awk>:
207
208     if ($str == 0 && $str ne "0")  {
209         warn "That doesn't look like a number";
210     }
211
212 That method may be best because otherwise you won't treat IEEE
213 notations like C<NaN> or C<Infinity> properly.  At other times, you
214 might prefer to determine whether string data can be used numerically
215 by calling the POSIX::strtod() function or by inspecting your string
216 with a regular expression (as documented in L<perlre>).
217
218     warn "has nondigits"        if     /\D/;
219     warn "not a natural number" unless /^\d+$/;             # rejects -3
220     warn "not an integer"       unless /^-?\d+$/;           # rejects +3
221     warn "not an integer"       unless /^[+-]?\d+$/;
222     warn "not a decimal number" unless /^-?\d+\.?\d*$/;     # rejects .2
223     warn "not a decimal number" unless /^-?(?:\d+(?:\.\d*)?|\.\d+)$/;
224     warn "not a C float"
225         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
226
227 The length of an array is a scalar value.  You may find the length
228 of array @days by evaluating C<$#days>, as in B<csh>.  However, this
229 isn't the length of the array; it's the subscript of the last element,
230 which is a different value since there is ordinarily a 0th element.
231 Assigning to C<$#days> actually changes the length of the array.
232 Shortening an array this way destroys intervening values.  Lengthening
233 an array that was previously shortened does not recover values
234 that were in those elements.  (It used to do so in Perl 4, but we
235 had to break this to make sure destructors were called when expected.)
236 X<$#> X<array, length>
237
238 You can also gain some minuscule measure of efficiency by pre-extending
239 an array that is going to get big.  You can also extend an array
240 by assigning to an element that is off the end of the array.  You
241 can truncate an array down to nothing by assigning the null list
242 () to it.  The following are equivalent:
243
244     @whatever = ();
245     $#whatever = -1;
246
247 If you evaluate an array in scalar context, it returns the length
248 of the array.  (Note that this is not true of lists, which return
249 the last value, like the C comma operator, nor of built-in functions,
250 which return whatever they feel like returning.)  The following is
251 always true:
252 X<array, length>
253
254     scalar(@whatever) == $#whatever - $[ + 1;
255
256 Version 5 of Perl changed the semantics of C<$[>: files that don't set
257 the value of C<$[> no longer need to worry about whether another
258 file changed its value.  (In other words, use of C<$[> is deprecated.)
259 So in general you can assume that
260 X<$[>
261
262     scalar(@whatever) == $#whatever + 1;
263
264 Some programmers choose to use an explicit conversion so as to 
265 leave nothing to doubt:
266
267     $element_count = scalar(@whatever);
268
269 If you evaluate a hash in scalar context, it returns false if the
270 hash is empty.  If there are any key/value pairs, it returns true;
271 more precisely, the value returned is a string consisting of the
272 number of used buckets and the number of allocated buckets, separated
273 by a slash.  This is pretty much useful only to find out whether
274 Perl's internal hashing algorithm is performing poorly on your data
275 set.  For example, you stick 10,000 things in a hash, but evaluating
276 %HASH in scalar context reveals C<"1/16">, which means only one out
277 of sixteen buckets has been touched, and presumably contains all
278 10,000 of your items.  This isn't supposed to happen.  If a tied hash
279 is evaluated in scalar context, a fatal error will result, since this
280 bucket usage information is currently not available for tied hashes.
281 X<hash, scalar context> X<hash, bucket> X<bucket>
282
283 You can preallocate space for a hash by assigning to the keys() function.
284 This rounds up the allocated buckets to the next power of two:
285
286     keys(%users) = 1000;                # allocate 1024 buckets
287
288 =head2 Scalar value constructors
289 X<scalar, literal> X<scalar, constant>
290
291 Numeric literals are specified in any of the following floating point or
292 integer formats:
293
294     12345
295     12345.67
296     .23E-10             # a very small number
297     3.14_15_92          # a very important number
298     4_294_967_296       # underscore for legibility
299     0xff                # hex
300     0xdead_beef         # more hex   
301     0377                # octal (only numbers, begins with 0)
302     0b011011            # binary
303
304 You are allowed to use underscores (underbars) in numeric literals
305 between digits for legibility.  You could, for example, group binary
306 digits by threes (as for a Unix-style mode argument such as 0b110_100_100)
307 or by fours (to represent nibbles, as in 0b1010_0110) or in other groups.
308 X<number, literal>
309
310 String literals are usually delimited by either single or double
311 quotes.  They work much like quotes in the standard Unix shells:
312 double-quoted string literals are subject to backslash and variable
313 substitution; single-quoted strings are not (except for C<\'> and
314 C<\\>).  The usual C-style backslash rules apply for making
315 characters such as newline, tab, etc., as well as some more exotic
316 forms.  See L<perlop/"Quote and Quote-like Operators"> for a list.
317 X<string, literal>
318
319 Hexadecimal, octal, or binary, representations in string literals
320 (e.g. '0xff') are not automatically converted to their integer
321 representation.  The hex() and oct() functions make these conversions
322 for you.  See L<perlfunc/hex> and L<perlfunc/oct> for more details.
323
324 You can also embed newlines directly in your strings, i.e., they can end
325 on a different line than they begin.  This is nice, but if you forget
326 your trailing quote, the error will not be reported until Perl finds
327 another line containing the quote character, which may be much further
328 on in the script.  Variable substitution inside strings is limited to
329 scalar variables, arrays, and array or hash slices.  (In other words,
330 names beginning with $ or @, followed by an optional bracketed
331 expression as a subscript.)  The following code segment prints out "The
332 price is $Z<>100."
333 X<interpolation>
334
335     $Price = '$100';    # not interpolated
336     print "The price is $Price.\n";     # interpolated
337
338 There is no double interpolation in Perl, so the C<$100> is left as is.
339
340 By default floating point numbers substituted inside strings use the
341 dot (".")  as the decimal separator.  If C<use locale> is in effect,
342 and POSIX::setlocale() has been called, the character used for the
343 decimal separator is affected by the LC_NUMERIC locale.
344 See L<perllocale> and L<POSIX>.
345
346 As in some shells, you can enclose the variable name in braces to
347 disambiguate it from following alphanumerics (and underscores).
348 You must also do
349 this when interpolating a variable into a string to separate the
350 variable name from a following double-colon or an apostrophe, since
351 these would be otherwise treated as a package separator:
352 X<interpolation>
353
354     $who = "Larry";
355     print PASSWD "${who}::0:0:Superuser:/:/bin/perl\n";
356     print "We use ${who}speak when ${who}'s here.\n";
357
358 Without the braces, Perl would have looked for a $whospeak, a
359 C<$who::0>, and a C<$who's> variable.  The last two would be the
360 $0 and the $s variables in the (presumably) non-existent package
361 C<who>.
362
363 In fact, an identifier within such curlies is forced to be a string,
364 as is any simple identifier within a hash subscript.  Neither need
365 quoting.  Our earlier example, C<$days{'Feb'}> can be written as
366 C<$days{Feb}> and the quotes will be assumed automatically.  But
367 anything more complicated in the subscript will be interpreted as an
368 expression.  This means for example that C<$version{2.0}++> is
369 equivalent to C<$version{2}++>, not to C<$version{'2.0'}++>.
370
371 =head3 Version Strings
372 X<version string> X<vstring> X<v-string>
373
374 A literal of the form C<v1.20.300.4000> is parsed as a string composed
375 of characters with the specified ordinals.  This form, known as
376 v-strings, provides an alternative, more readable way to construct
377 strings, rather than use the somewhat less readable interpolation form
378 C<"\x{1}\x{14}\x{12c}\x{fa0}">.  This is useful for representing
379 Unicode strings, and for comparing version "numbers" using the string
380 comparison operators, C<cmp>, C<gt>, C<lt> etc.  If there are two or
381 more dots in the literal, the leading C<v> may be omitted.
382
383     print v9786;              # prints SMILEY, "\x{263a}"
384     print v102.111.111;       # prints "foo"
385     print 102.111.111;        # same
386
387 Such literals are accepted by both C<require> and C<use> for
388 doing a version check.  Note that using the v-strings for IPv4
389 addresses is not portable unless you also use the
390 inet_aton()/inet_ntoa() routines of the Socket package.
391
392 Note that since Perl 5.8.1 the single-number v-strings (like C<v65>)
393 are not v-strings before the C<< => >> operator (which is usually used
394 to separate a hash key from a hash value), instead they are interpreted
395 as literal strings ('v65').  They were v-strings from Perl 5.6.0 to
396 Perl 5.8.0, but that caused more confusion and breakage than good.
397 Multi-number v-strings like C<v65.66> and C<65.66.67> continue to
398 be v-strings always.
399
400 =head3 Special Literals
401 X<special literal> X<__END__> X<__DATA__> X<END> X<DATA>
402 X<end> X<data> X<^D> X<^Z>
403
404 The special literals __FILE__, __LINE__, and __PACKAGE__
405 represent the current filename, line number, and package name at that
406 point in your program.  They may be used only as separate tokens; they
407 will not be interpolated into strings.  If there is no current package
408 (due to an empty C<package;> directive), __PACKAGE__ is the undefined
409 value.
410 X<__FILE__> X<__LINE__> X<__PACKAGE__> X<line> X<file> X<package>
411
412 The two control characters ^D and ^Z, and the tokens __END__ and __DATA__
413 may be used to indicate the logical end of the script before the actual
414 end of file.  Any following text is ignored.
415
416 Text after __DATA__ may be read via the filehandle C<PACKNAME::DATA>,
417 where C<PACKNAME> is the package that was current when the __DATA__
418 token was encountered.  The filehandle is left open pointing to the
419 contents after __DATA__.  It is the program's responsibility to
420 C<close DATA> when it is done reading from it.  For compatibility with
421 older scripts written before __DATA__ was introduced, __END__ behaves
422 like __DATA__ in the top level script (but not in files loaded with
423 C<require> or C<do>) and leaves the remaining contents of the
424 file accessible via C<main::DATA>.
425
426 See L<SelfLoader> for more description of __DATA__, and
427 an example of its use.  Note that you cannot read from the DATA
428 filehandle in a BEGIN block: the BEGIN block is executed as soon
429 as it is seen (during compilation), at which point the corresponding
430 __DATA__ (or __END__) token has not yet been seen.
431
432 =head3 Barewords
433 X<bareword>
434
435 A word that has no other interpretation in the grammar will
436 be treated as if it were a quoted string.  These are known as
437 "barewords".  As with filehandles and labels, a bareword that consists
438 entirely of lowercase letters risks conflict with future reserved
439 words, and if you use the C<use warnings> pragma or the B<-w> switch, 
440 Perl will warn you about any such words.  Perl limits barewords (like
441 identifiers) to about 250 characters.  Future versions of Perl are likely
442 to eliminate these arbitrary limitations.
443
444 Some people may wish to outlaw barewords entirely.  If you
445 say
446
447     use strict 'subs';
448
449 then any bareword that would NOT be interpreted as a subroutine call
450 produces a compile-time error instead.  The restriction lasts to the
451 end of the enclosing block.  An inner block may countermand this
452 by saying C<no strict 'subs'>.
453
454 =head3 Array Joining Delimiter
455 X<array, interpolation> X<interpolation, array> X<$">
456
457 Arrays and slices are interpolated into double-quoted strings
458 by joining the elements with the delimiter specified in the C<$">
459 variable (C<$LIST_SEPARATOR> if "use English;" is specified), 
460 space by default.  The following are equivalent:
461
462     $temp = join($", @ARGV);
463     system "echo $temp";
464
465     system "echo @ARGV";
466
467 Within search patterns (which also undergo double-quotish substitution)
468 there is an unfortunate ambiguity:  Is C</$foo[bar]/> to be interpreted as
469 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
470 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
471 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
472 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
473 and is almost always right.  If it does guess wrong, or if you're just
474 plain paranoid, you can force the correct interpretation with curly
475 braces as above.
476
477 If you're looking for the information on how to use here-documents,
478 which used to be here, that's been moved to
479 L<perlop/Quote and Quote-like Operators>.
480
481 =head2 List value constructors
482 X<list>
483
484 List values are denoted by separating individual values by commas
485 (and enclosing the list in parentheses where precedence requires it):
486
487     (LIST)
488
489 In a context not requiring a list value, the value of what appears
490 to be a list literal is simply the value of the final element, as
491 with the C comma operator.  For example,
492
493     @foo = ('cc', '-E', $bar);
494
495 assigns the entire list value to array @foo, but
496
497     $foo = ('cc', '-E', $bar);
498
499 assigns the value of variable $bar to the scalar variable $foo.
500 Note that the value of an actual array in scalar context is the
501 length of the array; the following assigns the value 3 to $foo:
502
503     @foo = ('cc', '-E', $bar);
504     $foo = @foo;                # $foo gets 3
505
506 You may have an optional comma before the closing parenthesis of a
507 list literal, so that you can say:
508
509     @foo = (
510         1,
511         2,
512         3,
513     );
514
515 To use a here-document to assign an array, one line per element,
516 you might use an approach like this:
517
518     @sauces = <<End_Lines =~ m/(\S.*\S)/g;
519         normal tomato
520         spicy tomato
521         green chile
522         pesto
523         white wine
524     End_Lines
525
526 LISTs do automatic interpolation of sublists.  That is, when a LIST is
527 evaluated, each element of the list is evaluated in list context, and
528 the resulting list value is interpolated into LIST just as if each
529 individual element were a member of LIST.  Thus arrays and hashes lose their
530 identity in a LIST--the list
531
532     (@foo,@bar,&SomeSub,%glarch)
533
534 contains all the elements of @foo followed by all the elements of @bar,
535 followed by all the elements returned by the subroutine named SomeSub 
536 called in list context, followed by the key/value pairs of %glarch.
537 To make a list reference that does I<NOT> interpolate, see L<perlref>.
538
539 The null list is represented by ().  Interpolating it in a list
540 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
541 interpolating an array with no elements is the same as if no
542 array had been interpolated at that point.
543
544 This interpolation combines with the facts that the opening
545 and closing parentheses are optional (except when necessary for
546 precedence) and lists may end with an optional comma to mean that
547 multiple commas within lists are legal syntax. The list C<1,,3> is a
548 concatenation of two lists, C<1,> and C<3>, the first of which ends
549 with that optional comma.  C<1,,3> is C<(1,),(3)> is C<1,3> (And
550 similarly for C<1,,,3> is C<(1,),(,),3> is C<1,3> and so on.)  Not that
551 we'd advise you to use this obfuscation.
552
553 A list value may also be subscripted like a normal array.  You must
554 put the list in parentheses to avoid ambiguity.  For example:
555
556     # Stat returns list value.
557     $time = (stat($file))[8];
558
559     # SYNTAX ERROR HERE.
560     $time = stat($file)[8];  # OOPS, FORGOT PARENTHESES
561
562     # Find a hex digit.
563     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
564
565     # A "reverse comma operator".
566     return (pop(@foo),pop(@foo))[0];
567
568 Lists may be assigned to only when each element of the list
569 is itself legal to assign to:
570
571     ($a, $b, $c) = (1, 2, 3);
572
573     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
574
575 An exception to this is that you may assign to C<undef> in a list.
576 This is useful for throwing away some of the return values of a
577 function:
578
579     ($dev, $ino, undef, undef, $uid, $gid) = stat($file);
580
581 List assignment in scalar context returns the number of elements
582 produced by the expression on the right side of the assignment:
583
584     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
585     $x = (($foo,$bar) = f());           # set $x to f()'s return count
586
587 This is handy when you want to do a list assignment in a Boolean
588 context, because most list functions return a null list when finished,
589 which when assigned produces a 0, which is interpreted as FALSE.
590
591 It's also the source of a useful idiom for executing a function or
592 performing an operation in list context and then counting the number of
593 return values, by assigning to an empty list and then using that
594 assignment in scalar context. For example, this code:
595
596     $count = () = $string =~ /\d+/g;
597
598 will place into $count the number of digit groups found in $string.
599 This happens because the pattern match is in list context (since it
600 is being assigned to the empty list), and will therefore return a list
601 of all matching parts of the string. The list assignment in scalar
602 context will translate that into the number of elements (here, the
603 number of times the pattern matched) and assign that to $count. Note
604 that simply using
605
606     $count = $string =~ /\d+/g;
607
608 would not have worked, since a pattern match in scalar context will
609 only return true or false, rather than a count of matches.
610
611 The final element of a list assignment may be an array or a hash:
612
613     ($a, $b, @rest) = split;
614     my($a, $b, %rest) = @_;
615
616 You can actually put an array or hash anywhere in the list, but the first one
617 in the list will soak up all the values, and anything after it will become
618 undefined.  This may be useful in a my() or local().
619
620 A hash can be initialized using a literal list holding pairs of
621 items to be interpreted as a key and a value:
622
623     # same as map assignment above
624     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
625
626 While literal lists and named arrays are often interchangeable, that's
627 not the case for hashes.  Just because you can subscript a list value like
628 a normal array does not mean that you can subscript a list value as a
629 hash.  Likewise, hashes included as parts of other lists (including
630 parameters lists and return lists from functions) always flatten out into
631 key/value pairs.  That's why it's good to use references sometimes.
632
633 It is often more readable to use the C<< => >> operator between key/value
634 pairs.  The C<< => >> operator is mostly just a more visually distinctive
635 synonym for a comma, but it also arranges for its left-hand operand to be
636 interpreted as a string -- if it's a bareword that would be a legal simple
637 identifier (C<< => >> doesn't quote compound identifiers, that contain
638 double colons). This makes it nice for initializing hashes:
639
640     %map = (
641                  red   => 0x00f,
642                  blue  => 0x0f0,
643                  green => 0xf00,
644    );
645
646 or for initializing hash references to be used as records:
647
648     $rec = {
649                 witch => 'Mable the Merciless',
650                 cat   => 'Fluffy the Ferocious',
651                 date  => '10/31/1776',
652     };
653
654 or for using call-by-named-parameter to complicated functions:
655
656    $field = $query->radio_group(
657                name      => 'group_name',
658                values    => ['eenie','meenie','minie'],
659                default   => 'meenie',
660                linebreak => 'true',
661                labels    => \%labels
662    );
663
664 Note that just because a hash is initialized in that order doesn't
665 mean that it comes out in that order.  See L<perlfunc/sort> for examples
666 of how to arrange for an output ordering.
667
668 =head2 Subscripts
669
670 An array is subscripted by specifying a dollar sign (C<$>), then the
671 name of the array (without the leading C<@>), then the subscript inside
672 square brackets.  For example:
673
674     @myarray = (5, 50, 500, 5000);
675     print "The Third Element is", $myarray[2], "\n";
676
677 The array indices start with 0. A negative subscript retrieves its 
678 value from the end.  In our example, C<$myarray[-1]> would have been 
679 5000, and C<$myarray[-2]> would have been 500.
680
681 Hash subscripts are similar, only instead of square brackets curly brackets
682 are used. For example:
683
684     %scientists = 
685     (
686         "Newton" => "Isaac",
687         "Einstein" => "Albert",
688         "Darwin" => "Charles",
689         "Feynman" => "Richard",
690     );
691
692     print "Darwin's First Name is ", $scientists{"Darwin"}, "\n";
693
694 =head2 Slices
695 X<slice> X<array, slice> X<hash, slice>
696
697 A common way to access an array or a hash is one scalar element at a
698 time.  You can also subscript a list to get a single element from it.
699
700     $whoami = $ENV{"USER"};             # one element from the hash
701     $parent = $ISA[0];                  # one element from the array
702     $dir    = (getpwnam("daemon"))[7];  # likewise, but with list
703
704 A slice accesses several elements of a list, an array, or a hash
705 simultaneously using a list of subscripts.  It's more convenient
706 than writing out the individual elements as a list of separate
707 scalar values.
708
709     ($him, $her)   = @folks[0,-1];              # array slice
710     @them          = @folks[0 .. 3];            # array slice
711     ($who, $home)  = @ENV{"USER", "HOME"};      # hash slice
712     ($uid, $dir)   = (getpwnam("daemon"))[2,7]; # list slice
713
714 Since you can assign to a list of variables, you can also assign to
715 an array or hash slice.
716
717     @days[3..5]    = qw/Wed Thu Fri/;
718     @colors{'red','blue','green'} 
719                    = (0xff0000, 0x0000ff, 0x00ff00);
720     @folks[0, -1]  = @folks[-1, 0];
721
722 The previous assignments are exactly equivalent to
723
724     ($days[3], $days[4], $days[5]) = qw/Wed Thu Fri/;
725     ($colors{'red'}, $colors{'blue'}, $colors{'green'})
726                    = (0xff0000, 0x0000ff, 0x00ff00);
727     ($folks[0], $folks[-1]) = ($folks[-1], $folks[0]);
728
729 Since changing a slice changes the original array or hash that it's
730 slicing, a C<foreach> construct will alter some--or even all--of the
731 values of the array or hash.
732
733     foreach (@array[ 4 .. 10 ]) { s/peter/paul/ } 
734
735     foreach (@hash{qw[key1 key2]}) {
736         s/^\s+//;           # trim leading whitespace
737         s/\s+$//;           # trim trailing whitespace
738         s/(\w+)/\u\L$1/g;   # "titlecase" words
739     }
740
741 A slice of an empty list is still an empty list.  Thus:
742
743     @a = ()[1,0];           # @a has no elements
744     @b = (@a)[0,1];         # @b has no elements
745     @c = (0,1)[2,3];        # @c has no elements
746
747 But:
748
749     @a = (1)[1,0];          # @a has two elements
750     @b = (1,undef)[1,0,2];  # @b has three elements
751
752 This makes it easy to write loops that terminate when a null list
753 is returned:
754
755     while ( ($home, $user) = (getpwent)[7,0]) {
756         printf "%-8s %s\n", $user, $home;
757     }
758
759 As noted earlier in this document, the scalar sense of list assignment
760 is the number of elements on the right-hand side of the assignment.
761 The null list contains no elements, so when the password file is
762 exhausted, the result is 0, not 2.
763
764 If you're confused about why you use an '@' there on a hash slice
765 instead of a '%', think of it like this.  The type of bracket (square
766 or curly) governs whether it's an array or a hash being looked at.
767 On the other hand, the leading symbol ('$' or '@') on the array or
768 hash indicates whether you are getting back a singular value (a
769 scalar) or a plural one (a list).
770
771 =head2 Typeglobs and Filehandles
772 X<typeglob> X<filehandle> X<*>
773
774 Perl uses an internal type called a I<typeglob> to hold an entire
775 symbol table entry.  The type prefix of a typeglob is a C<*>, because
776 it represents all types.  This used to be the preferred way to
777 pass arrays and hashes by reference into a function, but now that
778 we have real references, this is seldom needed.  
779
780 The main use of typeglobs in modern Perl is create symbol table aliases.
781 This assignment:
782
783     *this = *that;
784
785 makes $this an alias for $that, @this an alias for @that, %this an alias
786 for %that, &this an alias for &that, etc.  Much safer is to use a reference.
787 This:
788
789     local *Here::blue = \$There::green;
790
791 temporarily makes $Here::blue an alias for $There::green, but doesn't
792 make @Here::blue an alias for @There::green, or %Here::blue an alias for
793 %There::green, etc.  See L<perlmod/"Symbol Tables"> for more examples
794 of this.  Strange though this may seem, this is the basis for the whole
795 module import/export system.
796
797 Another use for typeglobs is to pass filehandles into a function or
798 to create new filehandles.  If you need to use a typeglob to save away
799 a filehandle, do it this way:
800
801     $fh = *STDOUT;
802
803 or perhaps as a real reference, like this:
804
805     $fh = \*STDOUT;
806
807 See L<perlsub> for examples of using these as indirect filehandles
808 in functions.
809
810 Typeglobs are also a way to create a local filehandle using the local()
811 operator.  These last until their block is exited, but may be passed back.
812 For example:
813
814     sub newopen {
815         my $path = shift;
816         local  *FH;  # not my!
817         open   (FH, $path)          or  return undef;
818         return *FH;
819     }
820     $fh = newopen('/etc/passwd');
821
822 Now that we have the C<*foo{THING}> notation, typeglobs aren't used as much
823 for filehandle manipulations, although they're still needed to pass brand
824 new file and directory handles into or out of functions. That's because
825 C<*HANDLE{IO}> only works if HANDLE has already been used as a handle.
826 In other words, C<*FH> must be used to create new symbol table entries;
827 C<*foo{THING}> cannot.  When in doubt, use C<*FH>.
828
829 All functions that are capable of creating filehandles (open(),
830 opendir(), pipe(), socketpair(), sysopen(), socket(), and accept())
831 automatically create an anonymous filehandle if the handle passed to
832 them is an uninitialized scalar variable. This allows the constructs
833 such as C<open(my $fh, ...)> and C<open(local $fh,...)> to be used to
834 create filehandles that will conveniently be closed automatically when
835 the scope ends, provided there are no other references to them. This
836 largely eliminates the need for typeglobs when opening filehandles
837 that must be passed around, as in the following example:
838
839     sub myopen {
840         open my $fh, "@_"
841              or die "Can't open '@_': $!";
842         return $fh;
843     }
844
845     {
846         my $f = myopen("</etc/motd");
847         print <$f>;
848         # $f implicitly closed here
849     }
850
851 Note that if an initialized scalar variable is used instead the
852 result is different: C<my $fh='zzz'; open($fh, ...)> is equivalent
853 to C<open( *{'zzz'}, ...)>.
854 C<use strict 'refs'> forbids such practice.
855
856 Another way to create anonymous filehandles is with the Symbol
857 module or with the IO::Handle module and its ilk.  These modules
858 have the advantage of not hiding different types of the same name
859 during the local().  See the bottom of L<perlfunc/open()> for an
860 example.
861
862 =head1 SEE ALSO
863
864 See L<perlvar> for a description of Perl's built-in variables and
865 a discussion of legal variable names.  See L<perlref>, L<perlsub>,
866 and L<perlmod/"Symbol Tables"> for more discussion on typeglobs and
867 the C<*foo{THING}> syntax.