984ba3b5b1d0cae5809102b66ff46d09f94e6116
[perl.git] / pod / perltrap.pod
1 =head1 NAME
2
3 perltrap - Perl traps for the unwary
4
5 =head1 DESCRIPTION
6
7 The biggest trap of all is forgetting to use the B<-w> switch; see
8 L<perlrun>.  The second biggest trap is not making your entire program
9 runnable under C<use strict>.
10
11 =head2 Awk Traps
12
13 Accustomed B<awk> users should take special note of the following:
14
15 =over 4
16
17 =item *
18
19 The English module, loaded via
20
21     use English;
22
23 allows you to refer to special variables (like $RS) as 
24 though they were in B<awk>; see L<perlvar> for details.
25
26 =item *
27
28 Semicolons are required after all simple statements in Perl (except
29 at the end of a block).  Newline is not a statement delimiter.
30
31 =item *
32
33 Curly brackets are required on C<if>s and C<while>s.
34
35 =item *
36
37 Variables begin with "$" or "@" in Perl.
38
39 =item *
40
41 Arrays index from 0.  Likewise string positions in substr() and
42 index().
43
44 =item *
45
46 You have to decide whether your array has numeric or string indices.
47
48 =item *
49
50 Associative array values do not spring into existence upon mere
51 reference.
52
53 =item *
54
55 You have to decide whether you want to use string or numeric
56 comparisons.
57
58 =item *
59
60 Reading an input line does not split it for you.  You get to split it
61 yourself to an array.  And the split() operator has different
62 arguments.
63
64 =item *
65
66 The current input line is normally in $_, not $0.  It generally does
67 not have the newline stripped.  ($0 is the name of the program
68 executed.)  See L<perlvar>.
69
70 =item *
71
72 $<I<digit>> does not refer to fields--it refers to substrings matched by
73 the last match pattern.
74
75 =item *
76
77 The print() statement does not add field and record separators unless
78 you set C<$,> and C<$.>.  You can set $OFS and $ORS if you're using
79 the English module.
80
81 =item *
82
83 You must open your files before you print to them.
84
85 =item *
86
87 The range operator is "..", not comma.  The comma operator works as in
88 C.
89
90 =item *
91
92 The match operator is "=~", not "~".  ("~" is the one's complement
93 operator, as in C.)
94
95 =item *
96
97 The exponentiation operator is "**", not "^".  "^" is the XOR
98 operator, as in C.  (You know, one could get the feeling that B<awk> is
99 basically incompatible with C.)
100
101 =item *
102
103 The concatenation operator is ".", not the null string.  (Using the
104 null string would render C</pat/ /pat/> unparsable, since the third slash
105 would be interpreted as a division operator--the tokener is in fact
106 slightly context sensitive for operators like "/", "?", and ">".
107 And in fact, "." itself can be the beginning of a number.)
108
109 =item *
110
111 The C<next>, C<exit>, and C<continue> keywords work differently.
112
113 =item *
114
115
116 The following variables work differently:
117
118       Awk       Perl
119       ARGC      $#ARGV or scalar @ARGV
120       ARGV[0]   $0
121       FILENAME  $ARGV
122       FNR       $. - something
123       FS        (whatever you like)
124       NF        $#Fld, or some such
125       NR        $.
126       OFMT      $#
127       OFS       $,
128       ORS       $\
129       RLENGTH   length($&)
130       RS        $/
131       RSTART    length($`)
132       SUBSEP    $;
133
134 =item *
135
136 You cannot set $RS to a pattern, only a string.
137
138 =item *
139
140 When in doubt, run the B<awk> construct through B<a2p> and see what it
141 gives you.
142
143 =back
144
145 =head2 C Traps
146
147 Cerebral C programmers should take note of the following:
148
149 =over 4
150
151 =item *
152
153 Curly brackets are required on C<if>'s and C<while>'s.
154
155 =item *
156
157 You must use C<elsif> rather than C<else if>.
158
159 =item *
160
161 The C<break> and C<continue> keywords from C become in 
162 Perl C<last> and C<next>, respectively.
163 Unlike in C, these do I<NOT> work within a C<do { } while> construct.
164
165 =item *
166
167 There's no switch statement.  (But it's easy to build one on the fly.)
168
169 =item *
170
171 Variables begin with "$" or "@" in Perl.
172
173 =item *
174
175 C<printf()> does not implement the "*" format for interpolating
176 field widths, but it's trivial to use interpolation of double-quoted
177 strings to achieve the same effect.
178
179 =item *
180
181 Comments begin with "#", not "/*".
182
183 =item *
184
185 You can't take the address of anything, although a similar operator
186 in Perl 5 is the backslash, which creates a reference.
187
188 =item *
189
190 C<ARGV> must be capitalized.  C<$ARGV[0]> is C's C<argv[1]>, and C<argv[0]>
191 ends up in C<$0>.
192
193 =item *
194
195 System calls such as link(), unlink(), rename(), etc. return nonzero for
196 success, not 0.
197
198 =item *
199
200 Signal handlers deal with signal names, not numbers.  Use C<kill -l>
201 to find their names on your system.
202
203 =back
204
205 =head2 Sed Traps
206
207 Seasoned B<sed> programmers should take note of the following:
208
209 =over 4
210
211 =item *
212
213 Backreferences in substitutions use "$" rather than "\".
214
215 =item *
216
217 The pattern matching metacharacters "(", ")", and "|" do not have backslashes
218 in front.
219
220 =item *
221
222 The range operator is C<...>, rather than comma.
223
224 =back
225
226 =head2 Shell Traps
227
228 Sharp shell programmers should take note of the following:
229
230 =over 4
231
232 =item *
233
234 The backtick operator does variable interpolation without regard to
235 the presence of single quotes in the command.
236
237 =item *
238
239 The backtick operator does no translation of the return value, unlike B<csh>.
240
241 =item *
242
243 Shells (especially B<csh>) do several levels of substitution on each
244 command line.  Perl does substitution only in certain constructs
245 such as double quotes, backticks, angle brackets, and search patterns.
246
247 =item *
248
249 Shells interpret scripts a little bit at a time.  Perl compiles the
250 entire program before executing it (except for C<BEGIN> blocks, which
251 execute at compile time).
252
253 =item *
254
255 The arguments are available via @ARGV, not $1, $2, etc.
256
257 =item *
258
259 The environment is not automatically made available as separate scalar
260 variables.
261
262 =back
263
264 =head2 Perl Traps
265
266 Practicing Perl Programmers should take note of the following:
267
268 =over 4
269
270 =item *
271
272 Remember that many operations behave differently in a list
273 context than they do in a scalar one.  See L<perldata> for details.
274
275 =item *
276
277 Avoid barewords if you can, especially all lower-case ones.
278 You can't tell just by looking at it whether a bareword is 
279 a function or a string.  By using quotes on strings and 
280 parens on function calls, you won't ever get them confused.
281
282 =item *
283
284 You cannot discern from mere inspection which built-ins
285 are unary operators (like chop() and chdir()) 
286 and which are list operators (like print() and unlink()).
287 (User-defined subroutines can B<only> be list operators, never
288 unary ones.)  See L<perlop>.
289
290 =item *
291
292 People have a hard time remembering that some functions
293 default to $_, or @ARGV, or whatever, but that others which
294 you might expect to do not.  
295
296 =item *
297
298 The <FH> construct is not the name of the filehandle, it is a readline
299 operation on that handle.  The data read is only assigned to $_ if the
300 file read is the sole condition in a while loop:
301
302     while (<FH>)      { }
303     while ($_ = <FH>) { }..
304     <FH>;  # data discarded!
305
306 =item *
307
308 Remember not to use "C<=>" when you need "C<=~>";
309 these two constructs are quite different:
310
311     $x =  /foo/;
312     $x =~ /foo/;
313
314 =item *
315
316 The C<do {}> construct isn't a real loop that you can use 
317 loop control on.
318
319 =item *
320
321 Use C<my()> for local variables whenever you can get away with 
322 it (but see L<perlform> for where you can't).  
323 Using C<local()> actually gives a local value to a global 
324 variable, which leaves you open to unforeseen side-effects
325 of dynamic scoping.
326
327 =item *
328
329 If you localize an exported variable in a module, its exported value will
330 not change.  The local name becomes an alias to a new value but the
331 external name is still an alias for the original.
332
333 =back
334
335 =head2 Perl4 to Perl5  Traps
336
337 Practicing Perl4 Programmers should take note of the following 
338 Perl4-to-Perl5 specific traps.
339
340 They're crudely ordered according to the following list:
341
342 =over 4
343
344 =item Discontinuance, Deprecation, and BugFix traps
345
346 Anything that's been fixed as a perl4 bug, removed as a perl4 feature
347 or deprecated as a perl4 feature with the intent to encourage usage of
348 some other perl5 feature.
349
350 =item Parsing Traps
351
352 Traps that appear to stem from the new parser.
353
354 =item Numerical Traps
355
356 Traps having to do with numerical or mathematical operators.
357
358 =item General data type traps
359
360 Traps involving perl standard data types.
361
362 =item Context Traps - scalar, list contexts
363
364 Traps related to context within lists, scalar statements/declarations.
365
366 =item Precedence Traps
367
368 Traps related to the precedence of parsing, evaluation, and execution of
369 code.
370
371 =item General Regular Expression Traps using s///, etc.
372
373 Traps related to the use of pattern matching.
374
375 =item Subroutine, Signal, Sorting Traps
376
377 Traps related to the use of signals and signal handlers, general subroutines,
378 and sorting, along with sorting subroutines.
379
380 =item OS Traps
381
382 OS-specific traps.
383
384 =item DBM Traps
385
386 Traps specific to the use of C<dbmopen()>, and specific dbm implementations.
387
388 =item Unclassified Traps
389
390 Everything else.
391
392 =back
393
394 If you find an example of a conversion trap that is not listed here,
395 please submit it to Bill Middleton F<wjm@best.com> for inclusion.
396 Also note that at least some of these can be caught with C<-w>.
397
398 =head2 Discontinuance, Deprecation, and BugFix traps
399
400 Anything that has been discontinued, deprecated, or fixed as
401 a bug from perl4.  
402
403 =over 4
404
405 =item * Discontinuance 
406
407 Symbols starting with "_" are no longer forced into package main, except
408 for C<$_> itself (and C<@_>, etc.).
409
410     package test;
411     $_legacy = 1;
412
413     package main;
414     print "\$_legacy is ",$_legacy,"\n";
415  
416     # perl4 prints: $_legacy is 1
417     # perl5 prints: $_legacy is
418
419 =item * Deprecation 
420
421 Double-colon is now a valid package separator in a variable name.  Thus these
422 behave differently in perl4 vs. perl5, since the packages don't exist.
423
424     $a=1;$b=2;$c=3;$var=4;
425     print "$a::$b::$c ";
426     print "$var::abc::xyz\n";
427  
428     # perl4 prints: 1::2::3 4::abc::xyz
429     # perl5 prints: 3
430
431 Given that C<::> is now the preferred package delimiter, it is debatable
432 whether this should be classed as a bug or not.
433 (The older package delimiter, ' ,is used here)
434
435     $x = 10 ;
436     print "x=${'x}\n" ;
437  
438     # perl4 prints: x=10
439     # perl5 prints: Can't find string terminator "'" anywhere before EOF
440
441 Also see precedence traps, for parsing C<$:>. 
442
443 =item * BugFix
444
445 The second and third arguments of C<splice()> are now evaluated in scalar
446 context (as the Camel says) rather than list context.
447
448     sub sub1{return(0,2) }          # return a 2-elem array
449     sub sub2{ return(1,2,3)}        # return a 3-elem array
450     @a1 = ("a","b","c","d","e"); 
451     @a2 = splice(@a1,&sub1,&sub2);
452     print join(' ',@a2),"\n";
453  
454     # perl4 prints: a b
455     # perl5 prints: c d e 
456
457 =item * Discontinuance 
458
459 You can't do a C<goto> into a block that is optimized away.  Darn.
460
461     goto marker1;
462
463     for(1){         
464     marker1:
465         print "Here I is!\n";
466     } 
467  
468     # perl4 prints: Here I is!
469     # perl5 dumps core (SEGV)
470
471 =item * Discontinuance 
472
473 It is no longer syntactically legal to use whitespace as the name
474 of a variable, or as a delimiter for any kind of quote construct.
475 Double darn. 
476
477     $a = ("foo bar");
478     $b = q baz ;
479     print "a is $a, b is $b\n";
480  
481     # perl4 prints: a is foo bar, b is baz
482     # perl5 errors: Bare word found where operator expected
483
484 =item * Discontinuance
485
486 The archaic while/if BLOCK BLOCK syntax is no longer supported.
487
488     if { 1 } {
489         print "True!";
490     }
491     else {
492         print "False!";
493     }
494  
495     # perl4 prints: True!
496     # perl5 errors: syntax error at test.pl line 1, near "if {"
497
498 =item * BugFix
499
500 The C<**> operator now binds more tightly than unary minus.
501 It was documented to work this way before, but didn't.
502
503     print -4**2,"\n";
504  
505     # perl4 prints: 16
506     # perl5 prints: -16
507
508 =item * Discontinuance 
509
510 The meaning of C<foreach{}> has changed slightly when it is iterating over a
511 list which is not an array.  This used to assign the list to a
512 temporary array, but no longer does so (for efficiency).  This means
513 that you'll now be iterating over the actual values, not over copies of
514 the values.  Modifications to the loop variable can change the original
515 values.
516
517     @list = ('ab','abc','bcd','def');
518     foreach $var (grep(/ab/,@list)){
519         $var = 1;
520     }
521     print (join(':',@list));
522  
523     # perl4 prints: ab:abc:bcd:def
524     # perl5 prints: 1:1:bcd:def
525
526 To retain Perl4 semantics you need to assign your list
527 explicitly to a temporary array and then iterate over that.  For 
528 example, you might need to change
529
530     foreach $var (grep(/ab/,@list)){
531
532 to
533
534     foreach $var (@tmp = grep(/ab/,@list)){
535
536 Otherwise changing $var will clobber the values of @list.  (This most often
537 happens when you use C<$_> for the loop variable, and call subroutines in
538 the loop that don't properly localize C<$_>.)
539
540 =item * Discontinuance
541
542 C<split> with no arguments now behaves like C<split ' '> (which doesn't
543 return an initial null field if $_ starts with whitespace), it used to
544 behave like C<split /\s+/> (which does).
545
546     $_ = ' hi mom';
547     print join(':', split);
548
549     # perl4 prints: :hi:mom
550     # perl5 prints: hi:mom
551
552 =item * Deprecation
553
554 Some error messages will be different.
555
556 =item * Discontinuance 
557
558 Some bugs may have been inadvertently removed.  :-)
559
560 =back
561
562 =head2 Parsing Traps
563
564 Perl4-to-Perl5 traps from having to do with parsing.
565
566 =over 4
567
568 =item * Parsing
569
570 Note the space between . and =
571
572     $string . = "more string";
573     print $string;
574  
575     # perl4 prints: more string
576     # perl5 prints: syntax error at - line 1, near ". ="
577
578 =item * Parsing
579
580 Better parsing in perl 5
581
582     sub foo {}
583     &foo
584     print("hello, world\n");
585  
586     # perl4 prints: hello, world
587     # perl5 prints: syntax error
588
589 =item * Parsing
590
591 "if it looks like a function, it is a function" rule.
592
593   print
594     ($foo == 1) ? "is one\n" : "is zero\n";
595  
596     # perl4 prints: is zero
597     # perl5 warns: "Useless use of a constant in void context" if using -w
598
599 =back
600
601 =head2 Numerical Traps
602
603 Perl4-to-Perl5 traps having to do with numerical operators,
604 operands, or output from same.
605
606 =over 5
607
608 =item * Numerical
609
610 Formatted output and significant digits
611
612     print 7.373504 - 0, "\n";
613     printf "%20.18f\n", 7.373504 - 0; 
614  
615     # Perl4 prints:
616     7.375039999999996141
617     7.37503999999999614
618  
619     # Perl5 prints:
620     7.373504
621     7.37503999999999614
622
623 =item * Numerical
624
625 This specific item has been deleted.  It demonstrated how the autoincrement
626 operator would not catch when a number went over the signed int limit.  Fixed
627 in 5.003_04.  But always be wary when using large ints.  If in doubt:
628
629    use Math::BigInt;
630
631 =item * Numerical  
632
633 Assignment of return values from numeric equality tests
634 does not work in perl5 when the test evaluates to false (0).
635 Logical tests now return an null, instead of 0
636  
637     $p = ($test == 1);
638     print $p,"\n";
639   
640     # perl4 prints: 0
641     # perl5 prints:
642
643 Also see the L<General Regular Expression Traps> tests for another example 
644 of this new feature...
645
646 =back
647
648 =head2 General data type traps
649
650 Perl4-to-Perl5 traps involving most data-types, and their usage
651 within certain expressions and/or context.
652
653 =over 5
654
655 =item * (Arrays)
656
657 Negative array subscripts now count from the end of the array.
658
659     @a = (1, 2, 3, 4, 5);
660     print "The third element of the array is $a[3] also expressed as $a[-2] \n";
661   
662     # perl4 prints: The third element of the array is 4 also expressed as
663     # perl5 prints: The third element of the array is 4 also expressed as 4
664
665 =item * (Arrays)
666
667 Setting C<$#array> lower now discards array elements, and makes them
668 impossible to recover.
669
670     @a = (a,b,c,d,e); 
671     print "Before: ",join('',@a);
672     $#a =1; 
673     print ", After: ",join('',@a);
674     $#a =3;
675     print ", Recovered: ",join('',@a),"\n";
676   
677     # perl4 prints: Before: abcde, After: ab, Recovered: abcd
678     # perl5 prints: Before: abcde, After: ab, Recovered: ab
679
680 =item * (Hashes)
681
682 Hashes get defined before use
683
684     local($s,@a,%h); 
685     die "scalar \$s defined" if defined($s);
686     die "array \@a defined" if defined(@a);
687     die "hash \%h defined" if defined(%h);
688  
689     # perl4 prints:
690     # perl5 dies: hash %h defined
691
692 =item * (Globs)
693
694 glob assignment from variable to variable will fail if the assigned
695 variable is localized subsequent to the assignment
696
697     @a = ("This is Perl 4");
698     *b = *a;
699     local(@a);
700     print @b,"\n";
701  
702     # perl4 prints: This is Perl 4
703     # perl5 prints:
704  
705     # Another example
706  
707     *fred = *barney; # fred is aliased to barney
708     @barney = (1, 2, 4);
709     # @fred;
710     print "@fred";  # should print "1, 2, 4"
711  
712     # perl4 prints: 1 2 4
713     # perl5 prints: Literal @fred now requires backslash 
714
715 =item * (Scalar String)
716
717 Changes in unary negation (of strings)
718 This change effects both the return value and what it
719 does to auto(magic)increment.
720
721     $x = "aaa";
722     print ++$x," : ";
723     print -$x," : ";
724     print ++$x,"\n";
725  
726     # perl4 prints: aab : -0 : 1
727     # perl5 prints: aab : -aab : aac
728
729 =item * (Constants)
730
731 perl 4 lets you modify constants:
732
733     $foo = "x";
734     &mod($foo);
735     for ($x = 0; $x < 3; $x++) {
736         &mod("a");
737     }
738     sub mod {
739         print "before: $_[0]";
740         $_[0] = "m";
741         print "  after: $_[0]\n";
742     }
743  
744     # perl4:
745     # before: x  after: m
746     # before: a  after: m
747     # before: m  after: m
748     # before: m  after: m
749  
750     # Perl5:
751     # before: x  after: m
752     # Modification of a read-only value attempted at foo.pl line 12.
753     # before: a
754
755 =item * (Scalars)
756
757 The behavior is slightly different for:
758
759     print "$x", defined $x
760   
761     # perl 4: 1
762     # perl 5: <no output, $x is not called into existence>
763
764 =item * (Variable Suicide)
765
766 Variable suicide behavior is more consistent under Perl 5.
767 Perl5 exhibits the same behavior for associative arrays and scalars,
768 that perl4 exhibits only for scalars.
769
770     $aGlobal{ "aKey" } = "global value";
771     print "MAIN:", $aGlobal{"aKey"}, "\n";
772     $GlobalLevel = 0;
773     &test( *aGlobal );
774
775     sub test {
776         local( *theArgument ) = @_;
777         local( %aNewLocal ); # perl 4 != 5.001l,m
778         $aNewLocal{"aKey"} = "this should never appear";  
779         print "SUB: ", $theArgument{"aKey"}, "\n";
780         $aNewLocal{"aKey"} = "level $GlobalLevel";   # what should print
781         $GlobalLevel++;
782         if( $GlobalLevel<4 ) {
783             &test( *aNewLocal );
784         }
785     }
786  
787     # Perl4:
788     # MAIN:global value
789     # SUB: global value
790     # SUB: level 0
791     # SUB: level 1
792     # SUB: level 2
793  
794     # Perl5:
795     # MAIN:global value
796     # SUB: global value
797     # SUB: this should never appear
798     # SUB: this should never appear
799     # SUB: this should never appear
800
801 =back
802
803 =head2 Context Traps - scalar, list contexts
804
805 =over 5
806
807 =item * (list context)
808
809 The elements of argument lists for formats are now evaluated in list
810 context.  This means you can interpolate list values now.
811
812     @fmt = ("foo","bar","baz");
813     format STDOUT=
814     @<<<<< @||||| @>>>>>
815     @fmt;
816     .
817     write;  
818  
819     # perl4 errors:  Please use commas to separate fields in file
820     # perl5 prints: foo     bar      baz
821
822 =item * (scalar context)
823
824 The C<caller()> function now returns a false value in a scalar context 
825 if there is no caller.  This lets library files determine if they're 
826 being required.
827
828     caller() ? (print "You rang?\n") : (print "Got a 0\n");
829   
830     # perl4 errors: There is no caller
831     # perl5 prints: Got a 0
832
833 =item * (scalar context)
834
835 The comma operator in a scalar context is now guaranteed to give a
836 scalar context to its arguments.
837
838     @y= ('a','b','c');
839     $x = (1, 2, @y);
840     print "x = $x\n";
841  
842     # Perl4 prints:  x = c   # Thinks list context interpolates list
843     # Perl5 prints:  x = 3   # Knows scalar uses length of list
844
845 =item * (list, builtin)
846
847 C<sprintf()> funkiness (array argument converted to scalar array count)
848 This test could be added to t/op/sprintf.t
849
850     @z = ('%s%s', 'foo', 'bar');
851     $x = sprintf(@z);
852     if ($x eq 'foobar') {print "ok 2\n";} else {print "not ok 2 '$x'\n";}
853  
854     # perl4 prints: ok 2
855     # perl5 prints: not ok 2
856
857 C<printf()> works fine, though:
858
859     printf STDOUT (@z);
860     print "\n"; 
861  
862     # perl4 prints: foobar
863     # perl5 prints: foobar
864
865 Probably a bug.
866
867 =back
868
869 =head2 Precedence Traps
870
871 Perl4-to-Perl5 traps involving precedence order.
872
873 =over 5
874
875 =item * Precedence
876
877 LHS vs. RHS when both sides are getting an op.
878
879     @arr = ( 'left', 'right' );
880     $a{shift @arr} = shift @arr;
881     print join( ' ', keys %a );
882
883     # perl4 prints: left
884     # perl5 prints: right
885
886 =item * Precedence
887
888 These are now semantic errors because of precedence:
889
890     @list = (1,2,3,4,5);
891     %map = ("a",1,"b",2,"c",3,"d",4);
892     $n = shift @list + 2;   # first item in list plus 2
893     print "n is $n, ";
894     $m = keys %map + 2;     # number of items in hash plus 2
895     print "m is $m\n";
896  
897     # perl4 prints: n is 3, m is 6
898     # perl5 errors and fails to compile
899
900 =item * Precedence
901
902 The precedence of assignment operators is now the same as the precedence
903 of assignment.  Perl 4 mistakenly gave them the precedence of the associated
904 operator.  So you now must parenthesize them in expressions like
905
906     /foo/ ? ($a += 2) : ($a -= 2);
907     
908 Otherwise
909
910     /foo/ ? $a += 2 : $a -= 2
911
912 would be erroneously parsed as
913
914     (/foo/ ? $a += 2 : $a) -= 2;
915
916 On the other hand,
917
918     $a += /foo/ ? 1 : 2; 
919
920 now works as a C programmer would expect.
921
922 =item * Precedence
923
924     open FOO || die;
925
926 is now incorrect.  You need parens around the filehandle.
927 Otherwise, perl5 leaves the statement as it's default precedence:
928
929     open(FOO || die);
930  
931     # perl4 opens or dies
932     # perl5 errors: Precedence problem: open FOO should be open(FOO)
933
934 =item * Precedence
935
936 perl4 gives the special variable, C<$:> precedence, where perl5
937 treats C<$::> as main C<package>
938
939     $a = "x"; print "$::a";
940      
941     # perl 4 prints: -:a
942     # perl 5 prints: x
943
944 =item * Precedence
945
946 concatenation precedence over filetest operator?  
947
948     -e $foo .= "q" 
949   
950     # perl4 prints: no output
951     # perl5 prints: Can't modify -e in concatenation
952
953 =item * Precedence
954
955 Assignment to value takes precedence over assignment to key in
956 perl5 when using the shift operator on both sides.
957
958     @arr = ( 'left', 'right' );
959     $a{shift @arr} = shift @arr;
960     print join( ' ', keys %a );
961
962     # perl4 prints: left
963     # perl5 prints: right
964
965 =back
966
967 =head2 General Regular Expression Traps using s///, etc.
968
969 All types of RE traps.
970
971 =over 5
972
973 =item * Regular Expression
974
975 C<s'$lhs'$rhs'> now does no interpolation on either side.  It used to
976 interpolate C<$lhs> but not C<$rhs>.  (And still does not match a literal 
977 '$' in string)
978
979     $a=1;$b=2;
980     $string = '1 2 $a $b';
981     $string =~ s'$a'$b';
982     print $string,"\n";
983  
984     # perl4 prints: $b 2 $a $b
985     # perl5 prints: 1 2 $a $b
986
987 =item * Regular Expression
988
989 C<m//g> now attaches its state to the searched string rather than the
990 regular expression.  (Once the scope of a block is left for the sub, the
991 state of the searched string is lost)
992
993     $_ = "ababab";
994     while(m/ab/g){
995         &doit("blah");
996     }
997     sub doit{local($_) = shift; print "Got $_ "}
998  
999     # perl4 prints: blah blah blah
1000     # perl5 prints: infinite loop blah...
1001
1002 =item * Regular Expression
1003
1004 If no parentheses are used in a match, Perl4 sets C<$+> to
1005 the whole match, just like C<$&>. Perl5 does not.
1006
1007     "abcdef" =~ /b.*e/;
1008     print "\$+ = $+\n";
1009  
1010     # perl4 prints: bcde
1011     # perl5 prints:
1012
1013 =item * Regular Expression
1014
1015 substitution now returns the null string if it fails
1016
1017     $string = "test";
1018     $value = ($string =~ s/foo//);
1019     print $value, "\n";
1020  
1021     # perl4 prints: 0
1022     # perl5 prints:
1023
1024 Also see L<Numerical Traps> for another example of this new feature.
1025
1026 =item * Regular Expression
1027
1028 C<s`lhs`rhs`> (using backticks) is now a normal substitution, with no 
1029 backtick expansion
1030
1031     $string = "";
1032     $string =~ s`^`hostname`;
1033     print $string, "\n";
1034  
1035     # perl4 prints: <the local hostname>
1036     # perl5 prints: hostname
1037
1038 =item * Regular Expression
1039
1040 Stricter parsing of variables used in regular expressions
1041
1042     s/^([^$grpc]*$grpc[$opt$plus$rep]?)//o;
1043  
1044     # perl4: compiles w/o error
1045     # perl5: with Scalar found where operator expected ..., near "$opt$plus"
1046
1047 an added component of this example, apparently from the same script, is
1048 the actual value of the s'd string after the substitution.
1049 C<[$opt]> is a character class in perl4 and an array subscript in perl5
1050
1051     $grpc = 'a'; 
1052     $opt  = 'r';
1053     $_ = 'bar';
1054     s/^([^$grpc]*$grpc[$opt]?)/foo/;
1055     print ;
1056  
1057     # perl4 prints: foo
1058     # perl5 prints: foobar
1059
1060 =item * Regular Expression
1061
1062 Under perl5, C<m?x?> matches only once, like C<?x?>. Under perl4, it matched
1063 repeatedly, like C</x/> or C<m!x!>.
1064
1065     $test = "once";
1066     sub match { $test =~ m?once?; }
1067     &match();
1068     if( &match() ) {
1069         # m?x? matches more then once
1070         print "perl4\n";
1071     } else { 
1072         # m?x? matches only once
1073         print "perl5\n"; 
1074     }
1075  
1076     # perl4 prints: perl4
1077     # perl5 prints: perl5
1078
1079
1080 =back
1081
1082 =head2 Subroutine, Signal, Sorting Traps
1083
1084 The general group of Perl4-to-Perl5 traps having to do with
1085 Signals, Sorting, and their related subroutines, as well as
1086 general subroutine traps.  Includes some OS-Specific traps.
1087
1088 =over 5
1089
1090 =item * (Signals)
1091
1092 Barewords that used to look like strings to Perl will now look like subroutine
1093 calls if a subroutine by that name is defined before the compiler sees them.
1094
1095     sub SeeYa { warn"Hasta la vista, baby!" }
1096     $SIG{'TERM'} = SeeYa;
1097     print "SIGTERM is now $SIG{'TERM'}\n";
1098  
1099     # perl4 prints: SIGTERM is main'SeeYa
1100     # perl5 prints: SIGTERM is now main::1
1101
1102 Use B<-w> to catch this one
1103
1104 =item * (Sort Subroutine)
1105
1106 reverse is no longer allowed as the name of a sort subroutine.
1107
1108     sub reverse{ print "yup "; $a <=> $b }
1109     print sort reverse a,b,c;  
1110  
1111     # perl4 prints: yup yup yup yup abc
1112     # perl5 prints: abc 
1113
1114 =item * warn() specifically implies STDERR
1115
1116     warn STDERR "Foo!";
1117
1118     # perl4 prints: Foo!
1119     # perl5 prints: String found where operator expected 
1120
1121 =back
1122
1123 =head2 OS Traps
1124
1125 =over 5
1126
1127 =item * (SysV)
1128
1129 Under HPUX, and some other SysV OS's, one had to reset any signal handler, 
1130 within  the signal handler function, each time a signal was handled with 
1131 perl4.  With perl5, the reset is now done correctly.  Any code relying 
1132 on the handler _not_ being reset will have to be reworked.
1133
1134 5.002 and beyond uses sigaction() under SysV
1135
1136     sub gotit {
1137         print "Got @_... "; 
1138     }  
1139     $SIG{'INT'} = 'gotit';
1140    
1141     $| = 1;
1142     $pid = fork;
1143     if ($pid) {
1144         kill('INT', $pid);
1145         sleep(1);
1146         kill('INT', $pid);
1147     } else { 
1148         while (1) {sleep(10);}
1149     } 
1150  
1151     # perl4 (HPUX) prints: Got INT...
1152     # perl5 (HPUX) prints: Got INT... Got INT...
1153
1154 =item * (SysV)
1155
1156 Under SysV OS's, C<seek()> on a file opened to append C<E<gt>E<gt>> now does 
1157 the right thing w.r.t. the fopen() man page. e.g. - When a file is opened
1158 for append,  it  is  impossible to overwrite information already in
1159 the file.
1160
1161     open(TEST,">>seek.test");
1162     $start = tell TEST ;  
1163     foreach(1 .. 9){
1164         print TEST "$_ ";
1165     }
1166     $end = tell TEST ;
1167     seek(TEST,$start,0);
1168     print TEST "18 characters here";
1169  
1170     # perl4 (solaris) seek.test has: 18 characters here
1171     # perl5 (solaris) seek.test has: 1 2 3 4 5 6 7 8 9 18 characters here
1172
1173
1174
1175 =back
1176
1177 =head2 Interpolation Traps
1178
1179 =over 5
1180
1181 =item * Interpolation
1182
1183 @ now always interpolates an array in double-quotish strings.
1184
1185     print "To: someone@somewhere.com\n"; 
1186  
1187     # perl4 prints: To:someone@somewhere.com
1188     # perl5 errors : Literal @somewhere now requires backslash
1189
1190 =item * Interpolation
1191
1192 Perl4-to-Perl5 traps having to do with how things get interpolated
1193 within certain expressions, statements, contexts, or whatever.
1194
1195 Double-quoted strings may no longer end with an unescaped $ or @.
1196
1197     $foo = "foo$";
1198     $bar = "bar@";
1199     print "foo is $foo, bar is $bar\n";
1200      
1201     # perl4 prints: foo is foo$, bar is bar@
1202     # perl5 errors: Final $ should be \$ or $name
1203
1204 Note: perl5 DOES NOT error on the terminating @ in $bar
1205
1206 =item * Interpolation
1207
1208 The construct "this is $$x" used to interpolate the pid at that
1209 point, but now apparently tries to dereference C<$x>.  C<$$> by itself still
1210 works fine, however.
1211
1212     print "this is $$x\n";
1213
1214     # perl4 prints: this is XXXx   (XXX is the current pid)
1215     # perl5 prints: this is
1216
1217 =item * Interpolation
1218
1219 Creation of hashes on the fly with C<eval "EXPR"> now requires either both 
1220 C<$>'s to be protected in the specification of the hash name, or both curlies 
1221 to be protected.  If both curlies are protected, the result will be compatible
1222 with perl4 and perl5.  This is a very common practice, and should be changed
1223 to use the block form of C<eval{}>  if possible.
1224
1225     $hashname = "foobar";
1226     $key = "baz";
1227     $value = 1234;
1228     eval "\$$hashname{'$key'} = q|$value|";
1229     (defined($foobar{'baz'})) ?  (print "Yup") : (print "Nope");
1230
1231     # perl4 prints: Yup
1232     # perl5 prints: Nope
1233
1234 Changing
1235
1236     eval "\$$hashname{'$key'} = q|$value|";
1237
1238 to
1239
1240     eval "\$\$hashname{'$key'} = q|$value|";
1241
1242 causes the following result:
1243
1244     # perl4 prints: Nope
1245     # perl5 prints: Yup
1246
1247 or, changing to
1248
1249     eval "\$$hashname\{'$key'\} = q|$value|";
1250
1251 causes the following result:
1252
1253     # perl4 prints: Yup
1254     # perl5 prints: Yup
1255     # and is compatible for both versions
1256
1257
1258 =item * Interpolation
1259
1260 perl4 programs which unconsciously rely on the bugs in earlier perl versions.
1261
1262     perl -e '$bar=q/not/; print "This is $foo{$bar} perl5"'
1263      
1264     # perl4 prints: This is not perl5
1265     # perl5 prints: This is perl5
1266
1267 =item * Interpolation
1268
1269 You also have to be careful about array references.  
1270
1271     print "$foo{"
1272
1273     perl 4 prints: {
1274     perl 5 prints: syntax error
1275
1276 =item * Interpolation
1277
1278 Similarly, watch out for:
1279
1280     $foo = "array";
1281     print "\$$foo{bar}\n";
1282   
1283     # perl4 prints: $array{bar}
1284     # perl5 prints: $
1285
1286 Perl 5 is looking for C<$array{bar}> which doesn't exist, but perl 4 is
1287 happy just to expand $foo to "array" by itself.  Watch out for this
1288 especially in C<eval>'s.
1289
1290 =item * Interpolation
1291
1292 C<qq()> string passed to C<eval>
1293
1294     eval qq(
1295         foreach \$y (keys %\$x\) {
1296             \$count++;
1297         }
1298     );
1299   
1300     # perl4 runs this ok
1301     # perl5 prints: Can't find string terminator ")" 
1302
1303 =back
1304
1305 =head2 DBM Traps
1306
1307 General DBM traps.
1308
1309 =over 5
1310
1311 =item * DBM
1312
1313 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1314 may cause the same script, run under perl5, to fail.  The build of perl5
1315 must have been linked with the same dbm/ndbm as the default for C<dbmopen()>
1316 to function properly without C<tie>'ing to an extension dbm implementation.
1317
1318     dbmopen (%dbm, "file", undef);
1319     print "ok\n";
1320
1321     # perl4 prints: ok
1322     # perl5 prints: ok (IFF linked with -ldbm or -lndbm)
1323
1324
1325 =item * DBM
1326
1327 Existing dbm databases created under perl4 (or any other dbm/ndbm tool)
1328 may cause the same script, run under perl5, to fail.  The error generated
1329 when exceeding the limit on the key/value size will cause perl5 to exit
1330 immediately.
1331
1332     dbmopen(DB, "testdb",0600) || die "couldn't open db! $!";
1333     $DB{'trap'} = "x" x 1024;  # value too large for most dbm/ndbm
1334     print "YUP\n";
1335
1336     # perl4 prints:
1337     dbm store returned -1, errno 28, key "trap" at - line 3.
1338     YUP
1339
1340     # perl5 prints:
1341     dbm store returned -1, errno 28, key "trap" at - line 3.
1342
1343 =back
1344
1345 =head2 Unclassified Traps
1346
1347 Everything else.
1348
1349 =over 5
1350
1351 =item * Unclassified
1352
1353 C<require>/C<do> trap using returned value
1354
1355 If the file doit.pl has:
1356
1357     sub foo {
1358         $rc = do "./do.pl";
1359         return 8;
1360     } 
1361     print &foo, "\n";
1362
1363 And the do.pl file has the following single line:
1364
1365     return 3;
1366
1367 Running doit.pl gives the following:
1368
1369     # perl 4 prints: 3 (aborts the subroutine early)
1370     # perl 5 prints: 8 
1371
1372 Same behavior if you replace C<do> with C<require>.
1373
1374 =back
1375
1376 As always, if any of these are ever officially declared as bugs, 
1377 they'll be fixed and removed.
1378