Check return values in the test programs run by syslfs.t and lfs.t
[perl.git] / ext / Fcntl / t / syslfs.t
1 # NOTE: this file tests how large files (>2GB) work with raw system IO.
2 # stdio: open(), tell(), seek(), print(), read() is tested in t/op/lfs.t.
3 # If you modify/add tests here, remember to update also t/op/lfs.t.
4
5 BEGIN {
6         require Config; import Config;
7         # Don't bother if there are no quad offsets.
8         if ($Config{lseeksize} < 8) {
9                 print "1..0 # Skip: no 64-bit file offsets\n";
10                 exit(0);
11         }
12         require Fcntl; import Fcntl qw(/^O_/ /^SEEK_/);
13 }
14
15 use strict;
16
17 $| = 1;
18
19 our @s;
20 our $fail;
21
22 sub zap {
23     close(BIG);
24     unlink("big");
25     unlink("big1");
26     unlink("big2");
27 }
28
29 sub bye {
30     zap(); 
31     exit(0);
32 }
33
34 my $explained;
35
36 sub explain {
37     unless ($explained++) {
38         print <<EOM;
39 #
40 # If the lfs (large file support: large meaning larger than two
41 # gigabytes) tests are skipped or fail, it may mean either that your
42 # process (or process group) is not allowed to write large files
43 # (resource limits) or that the file system (the network filesystem?)
44 # you are running the tests on doesn't let your user/group have large
45 # files (quota) or the filesystem simply doesn't support large files.
46 # You may even need to reconfigure your kernel.  (This is all very
47 # operating system and site-dependent.)
48 #
49 # Perl may still be able to support large files, once you have
50 # such a process, enough quota, and such a (file) system.
51 # It is just that the test failed now.
52 #
53 EOM
54     }
55     print "1..0 # Skip: @_\n" if @_;
56 }
57
58 print "# checking whether we have sparse files...\n";
59
60 # Known have-nots.
61 if ($^O eq 'MSWin32' || $^O eq 'NetWare' || $^O eq 'VMS') {
62     print "1..0 # Skip: no sparse files in $^O\n";
63     bye();
64 }
65
66 # Known haves that have problems running this test
67 # (for example because they do not support sparse files, like UNICOS)
68 if ($^O eq 'unicos') {
69     print "1..0 # Skip: no sparse files in $^0, unable to test large files\n";
70     bye();
71 }
72
73 # Then try heuristically to deduce whether we have sparse files.
74
75 # We'll start off by creating a one megabyte file which has
76 # only three "true" bytes.  If we have sparseness, we should
77 # consume less blocks than one megabyte (assuming nobody has
78 # one megabyte blocks...)
79
80 sysopen(BIG, "big1", O_WRONLY|O_CREAT|O_TRUNC) or
81     do { warn "sysopen big1 failed: $!\n"; bye };
82 sysseek(BIG, 1_000_000, SEEK_SET) or
83     do { warn "sysseek big1 failed: $!\n"; bye };
84 syswrite(BIG, "big") or
85     do { warn "syswrite big1 failed; $!\n"; bye };
86 close(BIG) or
87     do { warn "close big1 failed: $!\n"; bye };
88
89 my @s1 = stat("big1");
90
91 print "# s1 = @s1\n";
92
93 sysopen(BIG, "big2", O_WRONLY|O_CREAT|O_TRUNC) or
94     do { warn "sysopen big2 failed: $!\n"; bye };
95 sysseek(BIG, 2_000_000, SEEK_SET) or
96     do { warn "sysseek big2 failed: $!\n"; bye };
97 syswrite(BIG, "big") or
98     do { warn "syswrite big2 failed; $!\n"; bye };
99 close(BIG) or
100     do { warn "close big2 failed: $!\n"; bye };
101
102 my @s2 = stat("big2");
103
104 print "# s2 = @s2\n";
105
106 zap();
107
108 unless ($s1[7] == 1_000_003 && $s2[7] == 2_000_003 &&
109         $s1[11] == $s2[11] && $s1[12] == $s2[12] &&
110         $s1[12] > 0) {
111         print "1..0 # Skip: no sparse files?\n";
112         bye;
113 }
114
115 print "# we seem to have sparse files...\n";
116
117 # By now we better be sure that we do have sparse files:
118 # if we are not, the following will hog 5 gigabytes of disk.  Ooops.
119 # This may fail by producing some signal; run in a subprocess first for safety
120
121 $ENV{LC_ALL} = "C";
122
123 my $perl = '../../perl';
124 unless (-x $perl) {
125     print "1..1\nnot ok 1 - can't find perl: expected $perl\n";
126     exit 0;
127 }
128 my $r = system $perl, '-I../lib', '-e', <<'EOF';
129 use Fcntl qw(/^O_/ /^SEEK_/);
130 sysopen $big, "big", O_WRONLY|O_CREAT|O_TRUNC or die qq{sysopen big $!};
131 sysseek $big, 5_000_000_000, SEEK_SET or die qq{sysseek big $!};
132 syswrite $big, "big" or die qq{syswrite big $!};
133 close $big or die qq{close big: $!};
134 exit 0;
135 EOF
136
137
138 sysopen(BIG, "big", O_WRONLY|O_CREAT|O_TRUNC) or
139         do { warn "sysopen 'big' failed: $!\n"; bye };
140 my $sysseek = sysseek(BIG, 5_000_000_000, SEEK_SET);
141 unless (! $r && defined $sysseek && $sysseek == 5_000_000_000) {
142     $sysseek = 'undef' unless defined $sysseek;
143     explain("seeking past 2GB failed: ",
144             $r ? 'signal '.($r & 0x7f) : "$! (sysseek returned $sysseek)");
145     bye();
146 }
147
148 # The syswrite will fail if there are are filesize limitations (process or fs).
149 my $syswrite = syswrite(BIG, "big");
150 print "# syswrite failed: $! (syswrite returned ",
151       defined $syswrite ? $syswrite : 'undef', ")\n"
152     unless defined $syswrite && $syswrite == 3;
153 my $close     = close BIG;
154 print "# close failed: $!\n" unless $close;
155 unless($syswrite && $close) {
156     if ($! =~/too large/i) {
157         explain("writing past 2GB failed: process limits?");
158     } elsif ($! =~ /quota/i) {
159         explain("filesystem quota limits?");
160     } else {
161         explain("error: $!");
162     }
163     bye();
164 }
165
166 @s = stat("big");
167
168 print "# @s\n";
169
170 unless ($s[7] == 5_000_000_003) {
171     explain("kernel/fs not configured to use large files?");
172     bye();
173 }
174
175 sub fail () {
176     print "not ";
177     $fail++;
178 }
179
180 sub offset ($$) {
181     my ($offset_will_be, $offset_want) = @_;
182     my $offset_is = eval $offset_will_be;
183     unless ($offset_is == $offset_want) {
184         print "# bad offset $offset_is, want $offset_want\n";
185         my ($offset_func) = ($offset_will_be =~ /^(\w+)/);
186         if (unpack("L", pack("L", $offset_want)) == $offset_is) {
187             print "# 32-bit wraparound suspected in $offset_func() since\n";
188             print "# $offset_want cast into 32 bits equals $offset_is.\n";
189         } elsif ($offset_want - unpack("L", pack("L", $offset_want)) - 1
190                  == $offset_is) {
191             print "# 32-bit wraparound suspected in $offset_func() since\n";
192             printf "# %s - unpack('L', pack('L', %s)) - 1 equals %s.\n",
193                 $offset_want,
194                 $offset_want,
195                 $offset_is;
196         }
197         fail;
198     }
199 }
200
201 print "1..17\n";
202
203 $fail = 0;
204
205 fail unless $s[7] == 5_000_000_003;     # exercizes pp_stat
206 print "ok 1\n";
207
208 fail unless -s "big" == 5_000_000_003;  # exercizes pp_ftsize
209 print "ok 2\n";
210
211 fail unless -e "big";
212 print "ok 3\n";
213
214 fail unless -f "big";
215 print "ok 4\n";
216
217 sysopen(BIG, "big", O_RDONLY) or do { warn "sysopen failed: $!\n"; bye };
218
219 offset('sysseek(BIG, 4_500_000_000, SEEK_SET)', 4_500_000_000);
220 print "ok 5\n";
221
222 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_000);
223 print "ok 6\n";
224
225 offset('sysseek(BIG, 1, SEEK_CUR)', 4_500_000_001);
226 print "ok 7\n";
227
228 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_001);
229 print "ok 8\n";
230
231 offset('sysseek(BIG, -1, SEEK_CUR)', 4_500_000_000);
232 print "ok 9\n";
233
234 offset('sysseek(BIG, 0, SEEK_CUR)', 4_500_000_000);
235 print "ok 10\n";
236
237 offset('sysseek(BIG, -3, SEEK_END)', 5_000_000_000);
238 print "ok 11\n";
239
240 offset('sysseek(BIG, 0, SEEK_CUR)', 5_000_000_000);
241 print "ok 12\n";
242
243 my $big;
244
245 fail unless sysread(BIG, $big, 3) == 3;
246 print "ok 13\n";
247
248 fail unless $big eq "big";
249 print "ok 14\n";
250
251 # 705_032_704 = (I32)5_000_000_000
252 # See that we don't have "big" in the 705_... spot:
253 # that would mean that we have a wraparound.
254 fail unless sysseek(BIG, 705_032_704, SEEK_SET);
255 print "ok 15\n";
256
257 my $zero;
258
259 fail unless read(BIG, $zero, 3) == 3;
260 print "ok 16\n";
261
262 fail unless $zero eq "\0\0\0";
263 print "ok 17\n";
264
265 explain() if $fail;
266
267 bye(); # does the necessary cleanup
268
269 END {
270     # unlink may fail if applied directly to a large file
271     # be paranoid about leaving 5 gig files lying around
272     open(BIG, ">big"); # truncate
273     close(BIG);
274     1 while unlink "big"; # standard portable idiom
275 }
276
277 # eof