Added the git tag step for releases from Yves
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.08';
4
5 sub nil {}
6
7 sub OVERLOAD {
8   $package = shift;
9   my %arg = @_;
10   my ($sub, $fb);
11   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
12   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
13   for (keys %arg) {
14     if ($_ eq 'fallback') {
15       $fb = $arg{$_};
16     } else {
17       $sub = $arg{$_};
18       if (not ref $sub and $sub !~ /::/) {
19         $ {$package . "::(" . $_} = $sub;
20         $sub = \&nil;
21       }
22       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
23       *{$package . "::(" . $_} = \&{ $sub };
24     }
25   }
26   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
27 }
28
29 sub import {
30   $package = (caller())[0];
31   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
32   shift;
33   $package->overload::OVERLOAD(@_);
34 }
35
36 sub unimport {
37   $package = (caller())[0];
38   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
39   shift;
40   for (@_) {
41     if ($_ eq 'fallback') {
42       undef $ {$package . "::()"};
43     } else {
44       delete $ {$package . "::"}{"(" . $_};
45     }
46   }
47 }
48
49 sub Overloaded {
50   my $package = shift;
51   $package = ref $package if ref $package;
52   $package->can('()');
53 }
54
55 sub ov_method {
56   my $globref = shift;
57   return undef unless $globref;
58   my $sub = \&{*$globref};
59   return $sub if $sub ne \&nil;
60   return shift->can($ {*$globref});
61 }
62
63 sub OverloadedStringify {
64   my $package = shift;
65   $package = ref $package if ref $package;
66   #$package->can('(""')
67   ov_method mycan($package, '(""'), $package
68     or ov_method mycan($package, '(0+'), $package
69     or ov_method mycan($package, '(bool'), $package
70     or ov_method mycan($package, '(nomethod'), $package;
71 }
72
73 sub Method {
74   my $package = shift;
75   if(ref $package) {
76     local $@;
77     local $!;
78     require Scalar::Util;
79     $package = Scalar::Util::blessed($package);
80     return undef if !defined $package;
81   }
82   #my $meth = $package->can('(' . shift);
83   ov_method mycan($package, '(' . shift), $package;
84   #return $meth if $meth ne \&nil;
85   #return $ {*{$meth}};
86 }
87
88 sub AddrRef {
89   my $package = ref $_[0];
90   return "$_[0]" unless $package;
91
92   local $@;
93   local $!;
94   require Scalar::Util;
95   my $class = Scalar::Util::blessed($_[0]);
96   my $class_prefix = defined($class) ? "$class=" : "";
97   my $type = Scalar::Util::reftype($_[0]);
98   my $addr = Scalar::Util::refaddr($_[0]);
99   return sprintf("$class_prefix$type(0x%x)", $addr);
100 }
101
102 *StrVal = *AddrRef;
103
104 sub mycan {                             # Real can would leave stubs.
105   my ($package, $meth) = @_;
106
107   local $@;
108   local $!;
109   require mro;
110
111   my $mro = mro::get_linear_isa($package);
112   foreach my $p (@$mro) {
113     my $fqmeth = $p . q{::} . $meth;
114     return \*{$fqmeth} if defined &{$fqmeth};
115   }
116
117   return undef;
118 }
119
120 %constants = (
121               'integer'   =>  0x1000, # HINT_NEW_INTEGER
122               'float'     =>  0x2000, # HINT_NEW_FLOAT
123               'binary'    =>  0x4000, # HINT_NEW_BINARY
124               'q'         =>  0x8000, # HINT_NEW_STRING
125               'qr'        => 0x10000, # HINT_NEW_RE
126              );
127
128 %ops = ( with_assign      => "+ - * / % ** << >> x .",
129          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
130          num_comparison   => "< <= >  >= == !=",
131          '3way_comparison'=> "<=> cmp",
132          str_comparison   => "lt le gt ge eq ne",
133          binary           => '& &= | |= ^ ^=',
134          unary            => "neg ! ~",
135          mutators         => '++ --',
136          func             => "atan2 cos sin exp abs log sqrt int",
137          conversion       => 'bool "" 0+',
138          iterators        => '<>',
139          filetest         => "-X",
140          dereferencing    => '${} @{} %{} &{} *{}',
141          matching         => '~~',
142          special          => 'nomethod fallback =');
143
144 use warnings::register;
145 sub constant {
146   # Arguments: what, sub
147   while (@_) {
148     if (@_ == 1) {
149         warnings::warnif ("Odd number of arguments for overload::constant");
150         last;
151     }
152     elsif (!exists $constants {$_ [0]}) {
153         warnings::warnif ("`$_[0]' is not an overloadable type");
154     }
155     elsif (!ref $_ [1] || "$_[1]" !~ /(^|=)CODE\(0x[0-9a-f]+\)$/) {
156         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
157         # blessed, and C<ref> would return the package the ref is blessed into.
158         if (warnings::enabled) {
159             $_ [1] = "undef" unless defined $_ [1];
160             warnings::warn ("`$_[1]' is not a code reference");
161         }
162     }
163     else {
164         $^H{$_[0]} = $_[1];
165         $^H |= $constants{$_[0]};
166     }
167     shift, shift;
168   }
169 }
170
171 sub remove_constant {
172   # Arguments: what, sub
173   while (@_) {
174     delete $^H{$_[0]};
175     $^H &= ~ $constants{$_[0]};
176     shift, shift;
177   }
178 }
179
180 1;
181
182 __END__
183
184 =head1 NAME
185
186 overload - Package for overloading Perl operations
187
188 =head1 SYNOPSIS
189
190     package SomeThing;
191
192     use overload
193         '+' => \&myadd,
194         '-' => \&mysub;
195         # etc
196     ...
197
198     package main;
199     $a = SomeThing->new( 57 );
200     $b=5+$a;
201     ...
202     if (overload::Overloaded $b) {...}
203     ...
204     $strval = overload::StrVal $b;
205
206 =head1 DESCRIPTION
207
208 This pragma allows overloading of Perl's operators for a class.
209 To overload built-in functions, see L<perlsub/Overriding Built-in Functions> instead.
210
211 =head2 Declaration of overloaded functions
212
213 The compilation directive
214
215     package Number;
216     use overload
217         "+" => \&add,
218         "*=" => "muas";
219
220 declares function Number::add() for addition, and method muas() in
221 the "class" C<Number> (or one of its base classes)
222 for the assignment form C<*=> of multiplication.
223
224 Arguments of this directive come in (key, value) pairs.  Legal values
225 are values legal inside a C<&{ ... }> call, so the name of a
226 subroutine, a reference to a subroutine, or an anonymous subroutine
227 will all work.  Note that values specified as strings are
228 interpreted as methods, not subroutines.  Legal keys are listed below.
229
230 The subroutine C<add> will be called to execute C<$a+$b> if $a
231 is a reference to an object blessed into the package C<Number>, or if $a is
232 not an object from a package with defined mathemagic addition, but $b is a
233 reference to a C<Number>.  It can also be called in other situations, like
234 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
235 methods refer to methods triggered by an overloaded mathematical
236 operator.)
237
238 Since overloading respects inheritance via the @ISA hierarchy, the
239 above declaration would also trigger overloading of C<+> and C<*=> in
240 all the packages which inherit from C<Number>.
241
242 =head2 Calling Conventions for Binary Operations
243
244 The functions specified in the C<use overload ...> directive are called
245 with three (in one particular case with four, see L<Last Resort>)
246 arguments.  If the corresponding operation is binary, then the first
247 two arguments are the two arguments of the operation.  However, due to
248 general object calling conventions, the first argument should always be
249 an object in the package, so in the situation of C<7+$a>, the
250 order of the arguments is interchanged.  It probably does not matter
251 when implementing the addition method, but whether the arguments
252 are reversed is vital to the subtraction method.  The method can
253 query this information by examining the third argument, which can take
254 three different values:
255
256 =over 7
257
258 =item FALSE
259
260 the order of arguments is as in the current operation.
261
262 =item TRUE
263
264 the arguments are reversed.
265
266 =item C<undef>
267
268 the current operation is an assignment variant (as in
269 C<$a+=7>), but the usual function is called instead.  This additional
270 information can be used to generate some optimizations.  Compare
271 L<Calling Conventions for Mutators>.
272
273 =back
274
275 =head2 Calling Conventions for Unary Operations
276
277 Unary operation are considered binary operations with the second
278 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
279 is called with arguments C<($a,undef,'')> when $a++ is executed.
280
281 =head2 Calling Conventions for Mutators
282
283 Two types of mutators have different calling conventions:
284
285 =over
286
287 =item C<++> and C<-->
288
289 The routines which implement these operators are expected to actually
290 I<mutate> their arguments.  So, assuming that $obj is a reference to a
291 number,
292
293   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
294
295 is an appropriate implementation of overloaded C<++>.  Note that
296
297   sub incr { ++$ {$_[0]} ; shift }
298
299 is OK if used with preincrement and with postincrement. (In the case
300 of postincrement a copying will be performed, see L<Copy Constructor>.)
301
302 =item C<x=> and other assignment versions
303
304 There is nothing special about these methods.  They may change the
305 value of their arguments, and may leave it as is.  The result is going
306 to be assigned to the value in the left-hand-side if different from
307 this value.
308
309 This allows for the same method to be used as overloaded C<+=> and
310 C<+>.  Note that this is I<allowed>, but not recommended, since by the
311 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
312 if C<+=> is not overloaded.
313
314 =back
315
316 B<Warning.>  Due to the presence of assignment versions of operations,
317 routines which may be called in assignment context may create
318 self-referential structures.  Currently Perl will not free self-referential
319 structures until cycles are C<explicitly> broken.  You may get problems
320 when traversing your structures too.
321
322 Say,
323
324   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
325
326 is asking for trouble, since for code C<$obj += $foo> the subroutine
327 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
328 \$foo]>.  If using such a subroutine is an important optimization, one
329 can overload C<+=> explicitly by a non-"optimized" version, or switch
330 to non-optimized version if C<not defined $_[2]> (see
331 L<Calling Conventions for Binary Operations>).
332
333 Even if no I<explicit> assignment-variants of operators are present in
334 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
335 C<',' . $obj . ','> may be both optimized to
336
337   my $tmp = ',' . $obj;    $tmp .= ',';
338
339 =head2 Overloadable Operations
340
341 The following symbols can be specified in C<use overload> directive:
342
343 =over 5
344
345 =item * I<Arithmetic operations>
346
347     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
348     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
349
350 For these operations a substituted non-assignment variant can be called if
351 the assignment variant is not available.  Methods for operations C<+>,
352 C<->, C<+=>, and C<-=> can be called to automatically generate
353 increment and decrement methods.  The operation C<-> can be used to
354 autogenerate missing methods for unary minus or C<abs>.
355
356 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
357 L<"Calling Conventions for Binary Operations">) for details of these
358 substitutions.
359
360 =item * I<Comparison operations>
361
362     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
363     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
364
365 If the corresponding "spaceship" variant is available, it can be
366 used to substitute for the missing operation.  During C<sort>ing
367 arrays, C<cmp> is used to compare values subject to C<use overload>.
368
369 =item * I<Bit operations>
370
371     "&", "&=", "^", "^=", "|", "|=", "neg", "!", "~",
372
373 C<neg> stands for unary minus.  If the method for C<neg> is not
374 specified, it can be autogenerated using the method for
375 subtraction. If the method for C<!> is not specified, it can be
376 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
377
378 The same remarks in L<"Arithmetic operations"> about
379 assignment-variants and autogeneration apply for
380 bit operations C<"&">, C<"^">, and C<"|"> as well.
381
382 =item * I<Increment and decrement>
383
384     "++", "--",
385
386 If undefined, addition and subtraction methods can be
387 used instead.  These operations are called both in prefix and
388 postfix form.
389
390 =item * I<Transcendental functions>
391
392     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
393
394 If C<abs> is unavailable, it can be autogenerated using methods
395 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
396
397 Note that traditionally the Perl function L<int> rounds to 0, thus for
398 floating-point-like types one should follow the same semantic.  If
399 C<int> is unavailable, it can be autogenerated using the overloading of
400 C<0+>.
401
402 =item * I<Boolean, string and numeric conversion>
403
404     'bool', '""', '0+',
405
406 If one or two of these operations are not overloaded, the remaining ones can
407 be used instead.  C<bool> is used in the flow control operators
408 (like C<while>) and for the ternary C<?:> operation.  These functions can
409 return any arbitrary Perl value.  If the corresponding operation for this value
410 is overloaded too, that operation will be called again with this value.
411
412 As a special case if the overload returns the object itself then it will
413 be used directly. An overloaded conversion returning the object is
414 probably a bug, because you're likely to get something that looks like
415 C<YourPackage=HASH(0x8172b34)>.
416
417 =item * I<Iteration>
418
419     "<>"
420
421 If not overloaded, the argument will be converted to a filehandle or
422 glob (which may require a stringification).  The same overloading
423 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
424 I<globbing> syntax C<E<lt>${var}E<gt>>.
425
426 B<BUGS> Even in list context, the iterator is currently called only
427 once and with scalar context.
428
429 =item * I<File tests>
430
431     "-X"
432
433 This overload is used for all the filetest operators (C<-f>, C<-x> and
434 so on: see L<perlfunc/-X> for the full list). Even though these are
435 unary operators, the method will be called with a second argument which
436 is a single letter indicating which test was performed. Note that the
437 overload key is the literal string C<"-X">: you can't provide separate
438 overloads for the different tests.
439
440 Calling an overloaded filetest operator does not affect the stat value
441 associated with the special filehandle C<_>. It still refers to the
442 result of the last C<stat>, C<lstat> or unoverloaded filetest.
443
444 If not overloaded, these operators will fall back to the default
445 behaviour even without C<< fallback => 1 >>. This means that if the
446 object is a blessed glob or blessed IO ref it will be treated as a
447 filehandle, otherwise string overloading will be invoked and the result
448 treated as a filename.
449
450 This overload was introduced in perl 5.12.
451
452 =item * I<Matching>
453
454 The key C<"~~"> allows you to override the smart matching logic used by
455 the C<~~> operator and the switch construct (C<given>/C<when>).  See
456 L<perlsyn/switch> and L<feature>.
457
458 Unusually, overloading of the smart match operator does not automatically
459 take precedence over normal smart match behaviour. In particular, in the
460 following code:
461
462     package Foo;
463     use overload '~~' => 'match';
464
465     my $obj =  Foo->new();
466     $obj ~~ [ 1,2,3 ];
467
468 the smart match does I<not> invoke the method call like this:
469
470     $obj->match([1,2,3],0);
471
472 rather, the smart match distributive rule takes precedence, so $obj is
473 smart matched against each array element in turn until a match is found,
474 so you may see between one and three of these calls instead:
475
476     $obj->match(1,0);
477     $obj->match(2,0);
478     $obj->match(3,0);
479
480 Consult the match table in  L<perlsyn/"Smart matching in detail"> for
481 details of when overloading is invoked.
482
483 =item * I<Dereferencing>
484
485     '${}', '@{}', '%{}', '&{}', '*{}'.
486
487 If not overloaded, the argument will be dereferenced I<as is>, thus
488 should be of correct type.  These functions should return a reference
489 of correct type, or another object with overloaded dereferencing.
490
491 As a special case if the overload returns the object itself then it
492 will be used directly (provided it is the correct type).
493
494 The dereference operators must be specified explicitly they will not be passed to
495 "nomethod".
496
497 =item * I<Special>
498
499     "nomethod", "fallback", "=".
500
501 see L<SPECIAL SYMBOLS FOR C<use overload>>.
502
503 =back
504
505 See L<"Fallback"> for an explanation of when a missing method can be
506 autogenerated.
507
508 A computer-readable form of the above table is available in the hash
509 %overload::ops, with values being space-separated lists of names:
510
511  with_assign      => '+ - * / % ** << >> x .',
512  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
513  num_comparison   => '< <= > >= == !=',
514  '3way_comparison'=> '<=> cmp',
515  str_comparison   => 'lt le gt ge eq ne',
516  binary           => '& &= | |= ^ ^=',
517  unary            => 'neg ! ~',
518  mutators         => '++ --',
519  func             => 'atan2 cos sin exp abs log sqrt',
520  conversion       => 'bool "" 0+',
521  iterators        => '<>',
522  filetest         => '-X',
523  dereferencing    => '${} @{} %{} &{} *{}',
524  matching         => '~~',
525  special          => 'nomethod fallback ='
526
527 =head2 Inheritance and overloading
528
529 Inheritance interacts with overloading in two ways.
530
531 =over
532
533 =item Strings as values of C<use overload> directive
534
535 If C<value> in
536
537   use overload key => value;
538
539 is a string, it is interpreted as a method name.
540
541 =item Overloading of an operation is inherited by derived classes
542
543 Any class derived from an overloaded class is also overloaded.  The
544 set of overloaded methods is the union of overloaded methods of all
545 the ancestors. If some method is overloaded in several ancestor, then
546 which description will be used is decided by the usual inheritance
547 rules:
548
549 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
550 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
551 then the subroutine C<D::plus_sub> will be called to implement
552 operation C<+> for an object in package C<A>.
553
554 =back
555
556 Note that since the value of the C<fallback> key is not a subroutine,
557 its inheritance is not governed by the above rules.  In the current
558 implementation, the value of C<fallback> in the first overloaded
559 ancestor is used, but this is accidental and subject to change.
560
561 =head1 SPECIAL SYMBOLS FOR C<use overload>
562
563 Three keys are recognized by Perl that are not covered by the above
564 description.
565
566 =head2 Last Resort
567
568 C<"nomethod"> should be followed by a reference to a function of four
569 parameters.  If defined, it is called when the overloading mechanism
570 cannot find a method for some operation.  The first three arguments of
571 this function coincide with the arguments for the corresponding method if
572 it were found, the fourth argument is the symbol
573 corresponding to the missing method.  If several methods are tried,
574 the last one is used.  Say, C<1-$a> can be equivalent to
575
576         &nomethodMethod($a,1,1,"-")
577
578 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
579 C<use overload> directive.
580
581 The C<"nomethod"> mechanism is I<not> used for the dereference operators
582 ( ${} @{} %{} &{} *{} ).
583
584
585 If some operation cannot be resolved, and there is no function
586 assigned to C<"nomethod">, then an exception will be raised via die()--
587 unless C<"fallback"> was specified as a key in C<use overload> directive.
588
589
590 =head2 Fallback
591
592 The key C<"fallback"> governs what to do if a method for a particular
593 operation is not found.  Three different cases are possible depending on
594 the value of C<"fallback">:
595
596 =over 16
597
598 =item * C<undef>
599
600 Perl tries to use a
601 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
602 then tries to calls C<"nomethod"> value; if missing, an exception
603 will be raised.
604
605 =item * TRUE
606
607 The same as for the C<undef> value, but no exception is raised.  Instead,
608 it silently reverts to what it would have done were there no C<use overload>
609 present.
610
611 =item * defined, but FALSE
612
613 No autogeneration is tried.  Perl tries to call
614 C<"nomethod"> value, and if this is missing, raises an exception.
615
616 =back
617
618 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
619 yet, see L<"Inheritance and overloading">.
620
621 =head2 Copy Constructor
622
623 The value for C<"="> is a reference to a function with three
624 arguments, i.e., it looks like the other values in C<use
625 overload>. However, it does not overload the Perl assignment
626 operator. This would go against Camel hair.
627
628 This operation is called in the situations when a mutator is applied
629 to a reference that shares its object with some other reference, such
630 as
631
632         $a=$b;
633         ++$a;
634
635 To make this change $a and not change $b, a copy of C<$$a> is made,
636 and $a is assigned a reference to this new object.  This operation is
637 done during execution of the C<++$a>, and not during the assignment,
638 (so before the increment C<$$a> coincides with C<$$b>).  This is only
639 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
640 C<nomethod>).  Note that if this operation is expressed via C<'+'>
641 a nonmutator, i.e., as in
642
643         $a=$b;
644         $a=$a+1;
645
646 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
647 appear as lvalue when the above code is executed.
648
649 If the copy constructor is required during the execution of some mutator,
650 but a method for C<'='> was not specified, it can be autogenerated as a
651 string copy if the object is a plain scalar or a simple assignment if it
652 is not.
653
654 =over 5
655
656 =item B<Example>
657
658 The actually executed code for
659
660         $a=$b;
661         Something else which does not modify $a or $b....
662         ++$a;
663
664 may be
665
666         $a=$b;
667         Something else which does not modify $a or $b....
668         $a = $a->clone(undef,"");
669         $a->incr(undef,"");
670
671 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
672 C<'='> was overloaded with C<\&clone>.
673
674 =back
675
676 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
677 C<$b = $a; ++$a>.
678
679 =head1 MAGIC AUTOGENERATION
680
681 If a method for an operation is not found, and the value for  C<"fallback"> is
682 TRUE or undefined, Perl tries to autogenerate a substitute method for
683 the missing operation based on the defined operations.  Autogenerated method
684 substitutions are possible for the following operations:
685
686 =over 16
687
688 =item I<Assignment forms of arithmetic operations>
689
690 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
691 is not defined.
692
693 =item I<Conversion operations>
694
695 String, numeric, and boolean conversion are calculated in terms of one
696 another if not all of them are defined.
697
698 =item I<Increment and decrement>
699
700 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
701 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
702
703 =item C<abs($a)>
704
705 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
706
707 =item I<Unary minus>
708
709 can be expressed in terms of subtraction.
710
711 =item I<Negation>
712
713 C<!> and C<not> can be expressed in terms of boolean conversion, or
714 string or numerical conversion.
715
716 =item I<Concatenation>
717
718 can be expressed in terms of string conversion.
719
720 =item I<Comparison operations>
721
722 can be expressed in terms of its "spaceship" counterpart: either
723 C<E<lt>=E<gt>> or C<cmp>:
724
725     <, >, <=, >=, ==, !=        in terms of <=>
726     lt, gt, le, ge, eq, ne      in terms of cmp
727
728 =item I<Iterator>
729
730     <>                          in terms of builtin operations
731
732 =item I<Dereferencing>
733
734     ${} @{} %{} &{} *{}         in terms of builtin operations
735
736 =item I<Copy operator>
737
738 can be expressed in terms of an assignment to the dereferenced value, if this
739 value is a scalar and not a reference, or simply a reference assignment
740 otherwise.
741
742 =back
743
744 =head1 Minimal set of overloaded operations
745
746 Since some operations can be automatically generated from others, there is
747 a minimal set of operations that need to be overloaded in order to have
748 the complete set of overloaded operations at one's disposal.
749 Of course, the autogenerated operations may not do exactly what the user
750 expects. See L<MAGIC AUTOGENERATION> above. The minimal set is:
751
752     + - * / % ** << >> x
753     <=> cmp
754     & | ^ ~
755     atan2 cos sin exp log sqrt int
756
757 Additionally, you need to define at least one of string, boolean or
758 numeric conversions because any one can be used to emulate the others.
759 The string conversion can also be used to emulate concatenation.
760
761 =head1 Losing overloading
762
763 The restriction for the comparison operation is that even if, for example,
764 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
765 function will produce only a standard logical value based on the
766 numerical value of the result of `C<cmp>'.  In particular, a working
767 numeric conversion is needed in this case (possibly expressed in terms of
768 other conversions).
769
770 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
771 if the string conversion substitution is applied.
772
773 When you chop() a mathemagical object it is promoted to a string and its
774 mathemagical properties are lost.  The same can happen with other
775 operations as well.
776
777 =head1 Run-time Overloading
778
779 Since all C<use> directives are executed at compile-time, the only way to
780 change overloading during run-time is to
781
782     eval 'use overload "+" => \&addmethod';
783
784 You can also use
785
786     eval 'no overload "+", "--", "<="';
787
788 though the use of these constructs during run-time is questionable.
789
790 =head1 Public functions
791
792 Package C<overload.pm> provides the following public functions:
793
794 =over 5
795
796 =item overload::StrVal(arg)
797
798 Gives string value of C<arg> as in absence of stringify overloading. If you
799 are using this to get the address of a reference (useful for checking if two
800 references point to the same thing) then you may be better off using
801 C<Scalar::Util::refaddr()>, which is faster.
802
803 =item overload::Overloaded(arg)
804
805 Returns true if C<arg> is subject to overloading of some operations.
806
807 =item overload::Method(obj,op)
808
809 Returns C<undef> or a reference to the method that implements C<op>.
810
811 =back
812
813 =head1 Overloading constants
814
815 For some applications, the Perl parser mangles constants too much.
816 It is possible to hook into this process via C<overload::constant()>
817 and C<overload::remove_constant()> functions.
818
819 These functions take a hash as an argument.  The recognized keys of this hash
820 are:
821
822 =over 8
823
824 =item integer
825
826 to overload integer constants,
827
828 =item float
829
830 to overload floating point constants,
831
832 =item binary
833
834 to overload octal and hexadecimal constants,
835
836 =item q
837
838 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
839 strings and here-documents,
840
841 =item qr
842
843 to overload constant pieces of regular expressions.
844
845 =back
846
847 The corresponding values are references to functions which take three arguments:
848 the first one is the I<initial> string form of the constant, the second one
849 is how Perl interprets this constant, the third one is how the constant is used.
850 Note that the initial string form does not
851 contain string delimiters, and has backslashes in backslash-delimiter
852 combinations stripped (thus the value of delimiter is not relevant for
853 processing of this string).  The return value of this function is how this
854 constant is going to be interpreted by Perl.  The third argument is undefined
855 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
856 context (comes from strings, regular expressions, and single-quote HERE
857 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
858 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
859
860 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
861 it is expected that overloaded constant strings are equipped with reasonable
862 overloaded catenation operator, otherwise absurd results will result.
863 Similarly, negative numbers are considered as negations of positive constants.
864
865 Note that it is probably meaningless to call the functions overload::constant()
866 and overload::remove_constant() from anywhere but import() and unimport() methods.
867 From these methods they may be called as
868
869         sub import {
870           shift;
871           return unless @_;
872           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
873           overload::constant integer => sub {Math::BigInt->new(shift)};
874         }
875
876 =head1 IMPLEMENTATION
877
878 What follows is subject to change RSN.
879
880 The table of methods for all operations is cached in magic for the
881 symbol table hash for the package.  The cache is invalidated during
882 processing of C<use overload>, C<no overload>, new function
883 definitions, and changes in @ISA. However, this invalidation remains
884 unprocessed until the next C<bless>ing into the package. Hence if you
885 want to change overloading structure dynamically, you'll need an
886 additional (fake) C<bless>ing to update the table.
887
888 (Every SVish thing has a magic queue, and magic is an entry in that
889 queue.  This is how a single variable may participate in multiple
890 forms of magic simultaneously.  For instance, environment variables
891 regularly have two forms at once: their %ENV magic and their taint
892 magic. However, the magic which implements overloading is applied to
893 the stashes, which are rarely used directly, thus should not slow down
894 Perl.)
895
896 If an object belongs to a package using overload, it carries a special
897 flag.  Thus the only speed penalty during arithmetic operations without
898 overloading is the checking of this flag.
899
900 In fact, if C<use overload> is not present, there is almost no overhead
901 for overloadable operations, so most programs should not suffer
902 measurable performance penalties.  A considerable effort was made to
903 minimize the overhead when overload is used in some package, but the
904 arguments in question do not belong to packages using overload.  When
905 in doubt, test your speed with C<use overload> and without it.  So far
906 there have been no reports of substantial speed degradation if Perl is
907 compiled with optimization turned on.
908
909 There is no size penalty for data if overload is not used. The only
910 size penalty if overload is used in some package is that I<all> the
911 packages acquire a magic during the next C<bless>ing into the
912 package. This magic is three-words-long for packages without
913 overloading, and carries the cache table if the package is overloaded.
914
915 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
916 carried out before any operation that can imply an assignment to the
917 object $a (or $b) refers to, like C<$a++>.  You can override this
918 behavior by defining your own copy constructor (see L<"Copy Constructor">).
919
920 It is expected that arguments to methods that are not explicitly supposed
921 to be changed are constant (but this is not enforced).
922
923 =head1 Metaphor clash
924
925 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
926 If it I<looks> counter intuitive to you, you are subject to a metaphor
927 clash.
928
929 Here is a Perl object metaphor:
930
931 I<  object is a reference to blessed data>
932
933 and an arithmetic metaphor:
934
935 I<  object is a thing by itself>.
936
937 The I<main> problem of overloading C<=> is the fact that these metaphors
938 imply different actions on the assignment C<$a = $b> if $a and $b are
939 objects.  Perl-think implies that $a becomes a reference to whatever
940 $b was referencing.  Arithmetic-think implies that the value of "object"
941 $a is changed to become the value of the object $b, preserving the fact
942 that $a and $b are separate entities.
943
944 The difference is not relevant in the absence of mutators.  After
945 a Perl-way assignment an operation which mutates the data referenced by $a
946 would change the data referenced by $b too.  Effectively, after
947 C<$a = $b> values of $a and $b become I<indistinguishable>.
948
949 On the other hand, anyone who has used algebraic notation knows the
950 expressive power of the arithmetic metaphor.  Overloading works hard
951 to enable this metaphor while preserving the Perlian way as far as
952 possible.  Since it is not possible to freely mix two contradicting
953 metaphors, overloading allows the arithmetic way to write things I<as
954 far as all the mutators are called via overloaded access only>.  The
955 way it is done is described in L<Copy Constructor>.
956
957 If some mutator methods are directly applied to the overloaded values,
958 one may need to I<explicitly unlink> other values which references the
959 same value:
960
961     $a = Data->new(23);
962     ...
963     $b = $a;            # $b is "linked" to $a
964     ...
965     $a = $a->clone;     # Unlink $b from $a
966     $a->increment_by(4);
967
968 Note that overloaded access makes this transparent:
969
970     $a = Data->new(23);
971     $b = $a;            # $b is "linked" to $a
972     $a += 4;            # would unlink $b automagically
973
974 However, it would not make
975
976     $a = Data->new(23);
977     $a = 4;             # Now $a is a plain 4, not 'Data'
978
979 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
980 to an object do whatever you want.  It is just not the overload, but
981 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
982 which returns the object itself, and STORE() method which changes the
983 value of the object, one can reproduce the arithmetic metaphor in its
984 completeness, at least for variables which were tie()d from the start.
985
986 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
987
988 =head1 Cookbook
989
990 Please add examples to what follows!
991
992 =head2 Two-face scalars
993
994 Put this in F<two_face.pm> in your Perl library directory:
995
996   package two_face;             # Scalars with separate string and
997                                 # numeric values.
998   sub new { my $p = shift; bless [@_], $p }
999   use overload '""' => \&str, '0+' => \&num, fallback => 1;
1000   sub num {shift->[1]}
1001   sub str {shift->[0]}
1002
1003 Use it as follows:
1004
1005   require two_face;
1006   my $seven = two_face->new("vii", 7);
1007   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
1008   print "seven contains `i'\n" if $seven =~ /i/;
1009
1010 (The second line creates a scalar which has both a string value, and a
1011 numeric value.)  This prints:
1012
1013   seven=vii, seven=7, eight=8
1014   seven contains `i'
1015
1016 =head2 Two-face references
1017
1018 Suppose you want to create an object which is accessible as both an
1019 array reference and a hash reference.
1020
1021   package two_refs;
1022   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
1023   sub new {
1024     my $p = shift;
1025     bless \ [@_], $p;
1026   }
1027   sub gethash {
1028     my %h;
1029     my $self = shift;
1030     tie %h, ref $self, $self;
1031     \%h;
1032   }
1033
1034   sub TIEHASH { my $p = shift; bless \ shift, $p }
1035   my %fields;
1036   my $i = 0;
1037   $fields{$_} = $i++ foreach qw{zero one two three};
1038   sub STORE {
1039     my $self = ${shift()};
1040     my $key = $fields{shift()};
1041     defined $key or die "Out of band access";
1042     $$self->[$key] = shift;
1043   }
1044   sub FETCH {
1045     my $self = ${shift()};
1046     my $key = $fields{shift()};
1047     defined $key or die "Out of band access";
1048     $$self->[$key];
1049   }
1050
1051 Now one can access an object using both the array and hash syntax:
1052
1053   my $bar = two_refs->new(3,4,5,6);
1054   $bar->[2] = 11;
1055   $bar->{two} == 11 or die 'bad hash fetch';
1056
1057 Note several important features of this example.  First of all, the
1058 I<actual> type of $bar is a scalar reference, and we do not overload
1059 the scalar dereference.  Thus we can get the I<actual> non-overloaded
1060 contents of $bar by just using C<$$bar> (what we do in functions which
1061 overload dereference).  Similarly, the object returned by the
1062 TIEHASH() method is a scalar reference.
1063
1064 Second, we create a new tied hash each time the hash syntax is used.
1065 This allows us not to worry about a possibility of a reference loop,
1066 which would lead to a memory leak.
1067
1068 Both these problems can be cured.  Say, if we want to overload hash
1069 dereference on a reference to an object which is I<implemented> as a
1070 hash itself, the only problem one has to circumvent is how to access
1071 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1072 overloaded dereference operator).  Here is one possible fetching routine:
1073
1074   sub access_hash {
1075     my ($self, $key) = (shift, shift);
1076     my $class = ref $self;
1077     bless $self, 'overload::dummy'; # Disable overloading of %{}
1078     my $out = $self->{$key};
1079     bless $self, $class;        # Restore overloading
1080     $out;
1081   }
1082
1083 To remove creation of the tied hash on each access, one may an extra
1084 level of indirection which allows a non-circular structure of references:
1085
1086   package two_refs1;
1087   use overload '%{}' => sub { ${shift()}->[1] },
1088                '@{}' => sub { ${shift()}->[0] };
1089   sub new {
1090     my $p = shift;
1091     my $a = [@_];
1092     my %h;
1093     tie %h, $p, $a;
1094     bless \ [$a, \%h], $p;
1095   }
1096   sub gethash {
1097     my %h;
1098     my $self = shift;
1099     tie %h, ref $self, $self;
1100     \%h;
1101   }
1102
1103   sub TIEHASH { my $p = shift; bless \ shift, $p }
1104   my %fields;
1105   my $i = 0;
1106   $fields{$_} = $i++ foreach qw{zero one two three};
1107   sub STORE {
1108     my $a = ${shift()};
1109     my $key = $fields{shift()};
1110     defined $key or die "Out of band access";
1111     $a->[$key] = shift;
1112   }
1113   sub FETCH {
1114     my $a = ${shift()};
1115     my $key = $fields{shift()};
1116     defined $key or die "Out of band access";
1117     $a->[$key];
1118   }
1119
1120 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1121 reference to the intermediate array, which keeps a reference to an
1122 actual array, and the access hash.  The tie()ing object for the access
1123 hash is a reference to a reference to the actual array, so
1124
1125 =over
1126
1127 =item *
1128
1129 There are no loops of references.
1130
1131 =item *
1132
1133 Both "objects" which are blessed into the class C<two_refs1> are
1134 references to a reference to an array, thus references to a I<scalar>.
1135 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1136 overloaded operations.
1137
1138 =back
1139
1140 =head2 Symbolic calculator
1141
1142 Put this in F<symbolic.pm> in your Perl library directory:
1143
1144   package symbolic;             # Primitive symbolic calculator
1145   use overload nomethod => \&wrap;
1146
1147   sub new { shift; bless ['n', @_] }
1148   sub wrap {
1149     my ($obj, $other, $inv, $meth) = @_;
1150     ($obj, $other) = ($other, $obj) if $inv;
1151     bless [$meth, $obj, $other];
1152   }
1153
1154 This module is very unusual as overloaded modules go: it does not
1155 provide any usual overloaded operators, instead it provides the L<Last
1156 Resort> operator C<nomethod>.  In this example the corresponding
1157 subroutine returns an object which encapsulates operations done over
1158 the objects: C<< symbolic->new(3) >> contains C<['n', 3]>, C<< 2 +
1159 symbolic->new(3) >> contains C<['+', 2, ['n', 3]]>.
1160
1161 Here is an example of the script which "calculates" the side of
1162 circumscribed octagon using the above package:
1163
1164   require symbolic;
1165   my $iter = 1;                 # 2**($iter+2) = 8
1166   my $side = symbolic->new(1);
1167   my $cnt = $iter;
1168
1169   while ($cnt--) {
1170     $side = (sqrt(1 + $side**2) - 1)/$side;
1171   }
1172   print "OK\n";
1173
1174 The value of $side is
1175
1176   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1177                        undef], 1], ['n', 1]]
1178
1179 Note that while we obtained this value using a nice little script,
1180 there is no simple way to I<use> this value.  In fact this value may
1181 be inspected in debugger (see L<perldebug>), but only if
1182 C<bareStringify> B<O>ption is set, and not via C<p> command.
1183
1184 If one attempts to print this value, then the overloaded operator
1185 C<""> will be called, which will call C<nomethod> operator.  The
1186 result of this operator will be stringified again, but this result is
1187 again of type C<symbolic>, which will lead to an infinite loop.
1188
1189 Add a pretty-printer method to the module F<symbolic.pm>:
1190
1191   sub pretty {
1192     my ($meth, $a, $b) = @{+shift};
1193     $a = 'u' unless defined $a;
1194     $b = 'u' unless defined $b;
1195     $a = $a->pretty if ref $a;
1196     $b = $b->pretty if ref $b;
1197     "[$meth $a $b]";
1198   }
1199
1200 Now one can finish the script by
1201
1202   print "side = ", $side->pretty, "\n";
1203
1204 The method C<pretty> is doing object-to-string conversion, so it
1205 is natural to overload the operator C<""> using this method.  However,
1206 inside such a method it is not necessary to pretty-print the
1207 I<components> $a and $b of an object.  In the above subroutine
1208 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1209 and $b.  If these components use overloading, the catenation operator
1210 will look for an overloaded operator C<.>; if not present, it will
1211 look for an overloaded operator C<"">.  Thus it is enough to use
1212
1213   use overload nomethod => \&wrap, '""' => \&str;
1214   sub str {
1215     my ($meth, $a, $b) = @{+shift};
1216     $a = 'u' unless defined $a;
1217     $b = 'u' unless defined $b;
1218     "[$meth $a $b]";
1219   }
1220
1221 Now one can change the last line of the script to
1222
1223   print "side = $side\n";
1224
1225 which outputs
1226
1227   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1228
1229 and one can inspect the value in debugger using all the possible
1230 methods.
1231
1232 Something is still amiss: consider the loop variable $cnt of the
1233 script.  It was a number, not an object.  We cannot make this value of
1234 type C<symbolic>, since then the loop will not terminate.
1235
1236 Indeed, to terminate the cycle, the $cnt should become false.
1237 However, the operator C<bool> for checking falsity is overloaded (this
1238 time via overloaded C<"">), and returns a long string, thus any object
1239 of type C<symbolic> is true.  To overcome this, we need a way to
1240 compare an object to 0.  In fact, it is easier to write a numeric
1241 conversion routine.
1242
1243 Here is the text of F<symbolic.pm> with such a routine added (and
1244 slightly modified str()):
1245
1246   package symbolic;             # Primitive symbolic calculator
1247   use overload
1248     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1249
1250   sub new { shift; bless ['n', @_] }
1251   sub wrap {
1252     my ($obj, $other, $inv, $meth) = @_;
1253     ($obj, $other) = ($other, $obj) if $inv;
1254     bless [$meth, $obj, $other];
1255   }
1256   sub str {
1257     my ($meth, $a, $b) = @{+shift};
1258     $a = 'u' unless defined $a;
1259     if (defined $b) {
1260       "[$meth $a $b]";
1261     } else {
1262       "[$meth $a]";
1263     }
1264   }
1265   my %subr = ( n => sub {$_[0]},
1266                sqrt => sub {sqrt $_[0]},
1267                '-' => sub {shift() - shift()},
1268                '+' => sub {shift() + shift()},
1269                '/' => sub {shift() / shift()},
1270                '*' => sub {shift() * shift()},
1271                '**' => sub {shift() ** shift()},
1272              );
1273   sub num {
1274     my ($meth, $a, $b) = @{+shift};
1275     my $subr = $subr{$meth}
1276       or die "Do not know how to ($meth) in symbolic";
1277     $a = $a->num if ref $a eq __PACKAGE__;
1278     $b = $b->num if ref $b eq __PACKAGE__;
1279     $subr->($a,$b);
1280   }
1281
1282 All the work of numeric conversion is done in %subr and num().  Of
1283 course, %subr is not complete, it contains only operators used in the
1284 example below.  Here is the extra-credit question: why do we need an
1285 explicit recursion in num()?  (Answer is at the end of this section.)
1286
1287 Use this module like this:
1288
1289   require symbolic;
1290   my $iter = symbolic->new(2);  # 16-gon
1291   my $side = symbolic->new(1);
1292   my $cnt = $iter;
1293
1294   while ($cnt) {
1295     $cnt = $cnt - 1;            # Mutator `--' not implemented
1296     $side = (sqrt(1 + $side**2) - 1)/$side;
1297   }
1298   printf "%s=%f\n", $side, $side;
1299   printf "pi=%f\n", $side*(2**($iter+2));
1300
1301 It prints (without so many line breaks)
1302
1303   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1304                           [n 1]] 2]]] 1]
1305      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1306   pi=3.182598
1307
1308 The above module is very primitive.  It does not implement
1309 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1310 (not required without mutators!), and implements only those arithmetic
1311 operations which are used in the example.
1312
1313 To implement most arithmetic operations is easy; one should just use
1314 the tables of operations, and change the code which fills %subr to
1315
1316   my %subr = ( 'n' => sub {$_[0]} );
1317   foreach my $op (split " ", $overload::ops{with_assign}) {
1318     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1319   }
1320   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1321   foreach my $op (split " ", "@overload::ops{ @bins }") {
1322     $subr{$op} = eval "sub {shift() $op shift()}";
1323   }
1324   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1325     print "defining `$op'\n";
1326     $subr{$op} = eval "sub {$op shift()}";
1327   }
1328
1329 Due to L<Calling Conventions for Mutators>, we do not need anything
1330 special to make C<+=> and friends work, except filling C<+=> entry of
1331 %subr, and defining a copy constructor (needed since Perl has no
1332 way to know that the implementation of C<'+='> does not mutate
1333 the argument, compare L<Copy Constructor>).
1334
1335 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1336 line, and code (this code assumes that mutators change things one level
1337 deep only, so recursive copying is not needed):
1338
1339   sub cpy {
1340     my $self = shift;
1341     bless [@$self], ref $self;
1342   }
1343
1344 To make C<++> and C<--> work, we need to implement actual mutators,
1345 either directly, or in C<nomethod>.  We continue to do things inside
1346 C<nomethod>, thus add
1347
1348     if ($meth eq '++' or $meth eq '--') {
1349       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1350       return $obj;
1351     }
1352
1353 after the first line of wrap().  This is not a most effective
1354 implementation, one may consider
1355
1356   sub inc { $_[0] = bless ['++', shift, 1]; }
1357
1358 instead.
1359
1360 As a final remark, note that one can fill %subr by
1361
1362   my %subr = ( 'n' => sub {$_[0]} );
1363   foreach my $op (split " ", $overload::ops{with_assign}) {
1364     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1365   }
1366   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1367   foreach my $op (split " ", "@overload::ops{ @bins }") {
1368     $subr{$op} = eval "sub {shift() $op shift()}";
1369   }
1370   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1371     $subr{$op} = eval "sub {$op shift()}";
1372   }
1373   $subr{'++'} = $subr{'+'};
1374   $subr{'--'} = $subr{'-'};
1375
1376 This finishes implementation of a primitive symbolic calculator in
1377 50 lines of Perl code.  Since the numeric values of subexpressions
1378 are not cached, the calculator is very slow.
1379
1380 Here is the answer for the exercise: In the case of str(), we need no
1381 explicit recursion since the overloaded C<.>-operator will fall back
1382 to an existing overloaded operator C<"">.  Overloaded arithmetic
1383 operators I<do not> fall back to numeric conversion if C<fallback> is
1384 not explicitly requested.  Thus without an explicit recursion num()
1385 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1386 the argument of num().
1387
1388 If you wonder why defaults for conversion are different for str() and
1389 num(), note how easy it was to write the symbolic calculator.  This
1390 simplicity is due to an appropriate choice of defaults.  One extra
1391 note: due to the explicit recursion num() is more fragile than sym():
1392 we need to explicitly check for the type of $a and $b.  If components
1393 $a and $b happen to be of some related type, this may lead to problems.
1394
1395 =head2 I<Really> symbolic calculator
1396
1397 One may wonder why we call the above calculator symbolic.  The reason
1398 is that the actual calculation of the value of expression is postponed
1399 until the value is I<used>.
1400
1401 To see it in action, add a method
1402
1403   sub STORE {
1404     my $obj = shift;
1405     $#$obj = 1;
1406     @$obj->[0,1] = ('=', shift);
1407   }
1408
1409 to the package C<symbolic>.  After this change one can do
1410
1411   my $a = symbolic->new(3);
1412   my $b = symbolic->new(4);
1413   my $c = sqrt($a**2 + $b**2);
1414
1415 and the numeric value of $c becomes 5.  However, after calling
1416
1417   $a->STORE(12);  $b->STORE(5);
1418
1419 the numeric value of $c becomes 13.  There is no doubt now that the module
1420 symbolic provides a I<symbolic> calculator indeed.
1421
1422 To hide the rough edges under the hood, provide a tie()d interface to the
1423 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1424
1425   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1426   sub FETCH { shift }
1427   sub nop {  }          # Around a bug
1428
1429 (the bug is described in L<"BUGS">).  One can use this new interface as
1430
1431   tie $a, 'symbolic', 3;
1432   tie $b, 'symbolic', 4;
1433   $a->nop;  $b->nop;    # Around a bug
1434
1435   my $c = sqrt($a**2 + $b**2);
1436
1437 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1438 of $c becomes 13.  To insulate the user of the module add a method
1439
1440   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1441
1442 Now
1443
1444   my ($a, $b);
1445   symbolic->vars($a, $b);
1446   my $c = sqrt($a**2 + $b**2);
1447
1448   $a = 3; $b = 4;
1449   printf "c5  %s=%f\n", $c, $c;
1450
1451   $a = 12; $b = 5;
1452   printf "c13  %s=%f\n", $c, $c;
1453
1454 shows that the numeric value of $c follows changes to the values of $a
1455 and $b.
1456
1457 =head1 AUTHOR
1458
1459 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1460
1461 =head1 SEE ALSO
1462
1463 The L<overloading> pragma can be used to enable or disable overloaded
1464 operations within a lexical scope.
1465
1466 =head1 DIAGNOSTICS
1467
1468 When Perl is run with the B<-Do> switch or its equivalent, overloading
1469 induces diagnostic messages.
1470
1471 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1472 deduce which operations are overloaded (and which ancestor triggers
1473 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1474 is shown by debugger. The method C<()> corresponds to the C<fallback>
1475 key (in fact a presence of this method shows that this package has
1476 overloading enabled, and it is what is used by the C<Overloaded>
1477 function of module C<overload>).
1478
1479 The module might issue the following warnings:
1480
1481 =over 4
1482
1483 =item Odd number of arguments for overload::constant
1484
1485 (W) The call to overload::constant contained an odd number of arguments.
1486 The arguments should come in pairs.
1487
1488 =item `%s' is not an overloadable type
1489
1490 (W) You tried to overload a constant type the overload package is unaware of.
1491
1492 =item `%s' is not a code reference
1493
1494 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1495 to be a code reference. Either an anonymous subroutine, or a reference
1496 to a subroutine.
1497
1498 =back
1499
1500 =head1 BUGS
1501
1502 Because it is used for overloading, the per-package hash %OVERLOAD now
1503 has a special meaning in Perl. The symbol table is filled with names
1504 looking like line-noise.
1505
1506 For the purpose of inheritance every overloaded package behaves as if
1507 C<fallback> is present (possibly undefined). This may create
1508 interesting effects if some package is not overloaded, but inherits
1509 from two overloaded packages.
1510
1511 Relation between overloading and tie()ing is broken.  Overloading is
1512 triggered or not basing on the I<previous> class of tie()d value.
1513
1514 This happens because the presence of overloading is checked too early,
1515 before any tie()d access is attempted.  If the FETCH()ed class of the
1516 tie()d value does not change, a simple workaround is to access the value
1517 immediately after tie()ing, so that after this call the I<previous> class
1518 coincides with the current one.
1519
1520 B<Needed:> a way to fix this without a speed penalty.
1521
1522 Barewords are not covered by overloaded string constants.
1523
1524 This document is confusing.  There are grammos and misleading language
1525 used in places.  It would seem a total rewrite is needed.
1526
1527 =cut
1528