924c5f40af75ad16c4830ac4c1cbd33dd7b67ca5
[perl.git] / t / op / stat.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     require './test.pl';        # for which_perl() etc
7 }
8
9 use Config;
10 use File::Spec;
11
12 plan tests => 82;
13
14 my $Perl = which_perl();
15
16 $Is_Amiga   = $^O eq 'amigaos';
17 $Is_Cygwin  = $^O eq 'cygwin';
18 $Is_Darwin  = $^O eq 'darwin';
19 $Is_Dos     = $^O eq 'dos';
20 $Is_MacOS   = $^O eq 'MacOS';
21 $Is_MPE     = $^O eq 'mpeix';
22 $Is_MSWin32 = $^O eq 'MSWin32';
23 $Is_NetWare = $^O eq 'NetWare';
24 $Is_OS2     = $^O eq 'os2';
25 $Is_Solaris = $^O eq 'solaris';
26 $Is_VMS     = $^O eq 'VMS';
27 $Is_DGUX    = $^O eq 'dgux';
28 $Is_MPRAS   = $^O =~ /svr4/ && -f '/etc/.relid';
29 $Is_Rhapsody= $^O eq 'rhapsody';
30
31 $Is_Dosish  = $Is_Dos || $Is_OS2 || $Is_MSWin32 || $Is_NetWare || $Is_Cygwin;
32
33 $Is_UFS     = $Is_Darwin && (() = `df -t ufs .`) == 2;
34
35 my($DEV, $INO, $MODE, $NLINK, $UID, $GID, $RDEV, $SIZE,
36    $ATIME, $MTIME, $CTIME, $BLKSIZE, $BLOCKS) = (0..12);
37
38 my $Curdir = File::Spec->curdir;
39
40
41 my $tmpfile = 'Op_stat.tmp';
42 my $tmpfile_link = $tmpfile.'2';
43
44
45 1 while unlink $tmpfile;
46 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
47 close FOO;
48
49 open(FOO, ">$tmpfile") || DIE("Can't open temp test file: $!");
50
51 my($nlink, $mtime, $ctime) = (stat(FOO))[$NLINK, $MTIME, $CTIME];
52 SKIP: {
53     skip "No link count", 1 if $Is_VMS;
54
55     is($nlink, 1, 'nlink on regular file');
56 }
57
58 SKIP: {
59   skip "mtime and ctime not reliable", 2
60     if $Is_MSWin32 or $Is_NetWare or $Is_Cygwin or $Is_Dos or $Is_MacOS;
61
62   ok( $mtime,           'mtime' );
63   is( $mtime, $ctime,   'mtime == ctime' );
64 }
65
66
67 # Cygwin seems to have a 3 second granularity on its timestamps.
68 my $funky_FAT_timestamps = $Is_Cygwin;
69 sleep 3 if $funky_FAT_timestamps;
70
71 print FOO "Now is the time for all good men to come to.\n";
72 close(FOO);
73
74 sleep 2;
75
76
77 SKIP: {
78     unlink $tmpfile_link;
79     my $lnk_result = eval { link $tmpfile, $tmpfile_link };
80     skip "link() unimplemented", 6 if $@ =~ /unimplemented/;
81
82     is( $@, '',         'link() implemented' );
83     ok( $lnk_result,    'linked tmp testfile' );
84     ok( chmod(0644, $tmpfile),             'chmoded tmp testfile' );
85
86     my($nlink, $mtime, $ctime) = (stat($tmpfile))[$NLINK, $MTIME, $CTIME];
87
88     SKIP: {
89         skip "No link count", 1 if $Config{dont_use_nlink};
90         skip "Cygwin9X fakes hard links by copying", 1
91           if $Config{myuname} =~ /^cygwin_(?:9\d|me)\b/i;
92
93         is($nlink, 2,     'Link count on hard linked file' );
94     }
95
96     SKIP: {
97         my $cwd = File::Spec->rel2abs($Curdir);
98         skip "Solaris tmpfs has different mtime/ctime link semantics", 2
99                                      if $Is_Solaris and $cwd =~ m#^/tmp# and
100                                         $mtime && $mtime == $ctime;
101         skip "AFS has different mtime/ctime link semantics", 2
102                                      if $cwd =~ m#$Config{'afsroot'}/#;
103         skip "AmigaOS has different mtime/ctime link semantics", 2
104                                      if $Is_Amiga;
105         # Win32 could pass $mtime test but as FAT and NTFS have
106         # no ctime concept $ctime is ALWAYS == $mtime
107         # expect netware to be the same ...
108         skip "No ctime concept on this OS", 2
109                                      if $Is_MSWin32 || 
110                                         ($Is_Darwin && $Is_UFS);
111
112         if( !ok($mtime, 'hard link mtime') ||
113             !isnt($mtime, $ctime, 'hard link ctime != mtime') ) {
114             print STDERR <<DIAG;
115 # Check if you are on a tmpfs of some sort.  Building in /tmp sometimes
116 # has this problem.  Building on the ClearCase VOBS filesystem may also
117 # cause this failure.
118 #
119 # Darwin's UFS doesn't have a ctime concept, and thus is expected to fail
120 # this test.
121 DIAG
122         }
123     }
124
125 }
126
127 # truncate and touch $tmpfile.
128 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
129 close F;
130
131 ok(-z $tmpfile,     '-z on empty file');
132 ok(! -s $tmpfile,   '   and -s');
133
134 open(F, ">$tmpfile") || DIE("Can't open temp test file: $!");
135 print F "hi\n";
136 close F;
137
138 ok(! -z $tmpfile,   '-z on non-empty file');
139 ok(-s $tmpfile,     '   and -s');
140
141
142 # Strip all access rights from the file.
143 ok( chmod(0000, $tmpfile),     'chmod 0000' );
144
145 SKIP: {
146     skip "-r, -w and -x have different meanings on VMS", 3 if $Is_VMS;
147
148     SKIP: {
149         # Going to try to switch away from root.  Might not work.
150         my $olduid = $>;
151         eval { $> = 1; };
152         skip "Can't test -r or -w meaningfully if you're superuser", 2
153           if $> == 0;
154
155         SKIP: {
156             skip "Can't test -r meaningfully?", 1 if $Is_Dos || $Is_Cygwin;
157             ok(!-r $tmpfile,    "   -r");
158         }
159
160         ok(!-w $tmpfile,    "   -w");
161
162         # switch uid back (may not be implemented)
163         eval { $> = $olduid; };
164     }
165
166     ok(! -x $tmpfile,   '   -x');
167 }
168
169
170
171 ok(chmod(0700,$tmpfile),    'chmod 0700');
172 ok(-r $tmpfile,     '   -r');
173 ok(-w $tmpfile,     '   -w');
174
175 SKIP: {
176     skip "-x simply determines if a file ends in an executable suffix", 1
177       if $Is_Dosish || $Is_MacOS;
178
179     ok(-x $tmpfile,     '   -x');
180 }
181
182 ok(  -f $tmpfile,   '   -f');
183 ok(! -d $tmpfile,   '   !-d');
184
185 # Is this portable?
186 ok(  -d $Curdir,          '-d cwd' );
187 ok(! -f $Curdir,          '!-f cwd' );
188
189
190 SKIP: {
191     unlink($tmpfile_link);
192     my $symlink_rslt = eval { symlink $tmpfile, $tmpfile_link };
193     skip "symlink not implemented", 3 if $@ =~ /unimplemented/;
194
195     is( $@, '',     'symlink() implemented' );
196     ok( $symlink_rslt,      'symlink() ok' );
197     ok(-l $tmpfile_link,    '-l');
198 }
199
200 ok(-o $tmpfile,     '-o');
201
202 ok(-e $tmpfile,     '-e');
203
204 unlink($tmpfile_link);
205 ok(! -e $tmpfile_link,  '   -e on unlinked file');
206
207 SKIP: {
208     skip "No character, socket or block special files", 6
209       if $Is_MSWin32 || $Is_NetWare || $Is_Dos;
210     skip "/dev isn't available to test against", 6
211       unless -d '/dev' && -r '/dev' && -x '/dev';
212     skip "Skipping: unexpected ls output in MP-RAS", 6
213       if $Is_MPRAS;
214
215     my $LS  = $Config{d_readlink} ? "ls -lL" : "ls -l";
216     my $CMD = "$LS /dev 2>/dev/null";
217     my $DEV = qx($CMD);
218
219     skip "$CMD failed", 6 if $DEV eq '';
220
221     my @DEV = do { my $dev; opendir($dev, "/dev") ? readdir($dev) : () };
222
223     skip "opendir failed: $!", 6 if @DEV == 0;
224
225     # /dev/stdout might be either character special or a named pipe,
226     # or a symlink, or a socket, depending on which OS and how are
227     # you running the test, so let's censor that one away.
228     # Similar remarks hold for stderr.
229     $DEV =~ s{^[cpls].+?\sstdout$}{}m;
230     @DEV =  grep { $_ ne 'stdout' } @DEV;
231     $DEV =~ s{^[cpls].+?\sstderr$}{}m;
232     @DEV =  grep { $_ ne 'stderr' } @DEV;
233
234     # /dev/printer is also naughty: in IRIX it shows up as
235     # Srwx-----, not srwx------.
236     $DEV =~ s{^.+?\sprinter$}{}m;
237     @DEV =  grep { $_ ne 'printer' } @DEV;
238
239     # If running as root, we will see .files in the ls result,
240     # and readdir() will see them always.  Potential for conflict,
241     # so let's weed them out.
242     $DEV =~ s{^.+?\s\..+?$}{}m;
243     @DEV =  grep { ! m{^\..+$} } @DEV;
244
245     # Irix ls -l marks sockets with 'S' while 's' is a 'XENIX semaphore'.
246     if ($^O eq 'irix') {
247         $DEV =~ s{^S(.+?)}{s$1}mg;
248     }
249
250     my $try = sub {
251         my @c1 = eval qq[\$DEV =~ /^$_[0].*/mg];
252         my @c2 = eval qq[grep { $_[1] "/dev/\$_" } \@DEV];
253         my $c1 = scalar @c1;
254         my $c2 = scalar @c2;
255         is($c1, $c2, "ls and $_[1] agreeing on /dev ($c1 $c2)");
256     };
257
258 SKIP: {
259     skip("DG/UX ls -L broken", 3) if $Is_DGUX;
260
261     $try->('b', '-b');
262     $try->('c', '-c');
263     $try->('s', '-S');
264
265 }
266
267 ok(! -b $Curdir,    '!-b cwd');
268 ok(! -c $Curdir,    '!-c cwd');
269 ok(! -S $Curdir,    '!-S cwd');
270
271 }
272
273 SKIP: {
274     my($cnt, $uid);
275     $cnt = $uid = 0;
276
277     # Find a set of directories that's very likely to have setuid files
278     # but not likely to be *all* setuid files.
279     my @bin = grep {-d && -r && -x} qw(/sbin /usr/sbin /bin /usr/bin);
280     skip "Can't find a setuid file to test with", 3 unless @bin;
281
282     for my $bin (@bin) {
283         opendir BIN, $bin or die "Can't opendir $bin: $!";
284         while (defined($_ = readdir BIN)) {
285             $_ = "$bin/$_";
286             $cnt++;
287             $uid++ if -u;
288             last if $uid && $uid < $cnt;
289         }
290     }
291     closedir BIN;
292
293     skip "No setuid programs", 3 if $uid == 0;
294
295     isnt($cnt, 0,    'found some programs');
296     isnt($uid, 0,    '  found some setuid programs');
297     ok($uid < $cnt,  "    they're not all setuid");
298 }
299
300
301 # To assist in automated testing when a controlling terminal (/dev/tty)
302 # may not be available (at, cron  rsh etc), the PERL_SKIP_TTY_TEST env var
303 # can be set to skip the tests that need a tty.
304 SKIP: {
305     skip "These tests require a TTY", 4 if $ENV{PERL_SKIP_TTY_TEST};
306
307     my $TTY = $Is_Rhapsody ? "/dev/ttyp0" : "/dev/tty";
308
309     SKIP: {
310         skip "Test uses unixisms", 2 if $Is_MSWin32 || $Is_NetWare;
311         skip "No TTY to test -t with", 2 unless -e $TTY;
312
313         open(TTY, $TTY) ||
314           warn "Can't open $TTY--run t/TEST outside of make.\n";
315         ok(-t TTY,  '-t');
316         ok(-c TTY,  'tty is -c');
317         close(TTY);
318     }
319     ok(! -t TTY,    '!-t on closed TTY filehandle');
320
321     {
322         local $TODO = 'STDIN not a tty when output is to pipe' if $Is_VMS;
323         ok(-t,          '-t on STDIN');
324     }
325 }
326
327 my $Null = File::Spec->devnull;
328 SKIP: {
329     skip "No null device to test with", 1 unless -e $Null;
330     skip "We know Win32 thinks '$Null' is a TTY", 1 if $Is_MSWin32;
331
332     open(NULL, $Null) or DIE("Can't open $Null: $!");
333     ok(! -t NULL,   'null device is not a TTY');
334     close(NULL);
335 }
336
337
338 # These aren't strictly "stat" calls, but so what?
339 my $statfile = File::Spec->catfile($Curdir, 'op', 'stat.t');
340 ok(  -T $statfile,    '-T');
341 ok(! -B $statfile,    '!-B');
342
343 SKIP: {
344      skip("DG/UX", 1) if $Is_DGUX;
345 ok(-B $Perl,      '-B');
346 }
347
348 ok(! -T $Perl,    '!-T');
349
350 open(FOO,$statfile);
351 SKIP: {
352     eval { -T FOO; };
353     skip "-T/B on filehandle not implemented", 15 if $@ =~ /not implemented/;
354
355     is( $@, '',     '-T on filehandle causes no errors' );
356
357     ok(-T FOO,      '   -T');
358     ok(! -B FOO,    '   !-B');
359
360     $_ = <FOO>;
361     like($_, qr/perl/, 'after readline');
362     ok(-T FOO,      '   still -T');
363     ok(! -B FOO,    '   still -B');
364     close(FOO);
365
366     open(FOO,$statfile);
367     $_ = <FOO>;
368     like($_, qr/perl/,      'reopened and after readline');
369     ok(-T FOO,      '   still -T');
370     ok(! -B FOO,    '   still !-B');
371
372     ok(seek(FOO,0,0),   'after seek');
373     ok(-T FOO,          '   still -T');
374     ok(! -B FOO,        '   still !-B');
375
376     # It's documented this way in perlfunc *shrug*
377     () = <FOO>;
378     ok(eof FOO,         'at EOF');
379     ok(-T FOO,          '   still -T');
380     ok(-B FOO,          '   now -B');
381 }
382 close(FOO);
383
384
385 SKIP: {
386     skip "No null device to test with", 2 unless -e $Null;
387
388     ok(-T $Null,  'null device is -T');
389     ok(-B $Null,  '    and -B');
390 }
391
392
393 # and now, a few parsing tests:
394 $_ = $tmpfile;
395 ok(-f,      'bare -f   uses $_');
396 ok(-f(),    '     -f() "');
397
398 unlink $tmpfile or print "# unlink failed: $!\n";
399
400 # bug id 20011101.069
401 my @r = \stat($Curdir);
402 is(scalar @r, 13,   'stat returns full 13 elements');
403
404 stat $0;
405 eval { lstat _ };
406 like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
407     'lstat _ croaks after stat' );
408 eval { -l _ };
409 like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
410     '-l _ croaks after stat' );
411
412 lstat $0;
413 eval { lstat _ };
414 is( "$@", "", "lstat _ ok after lstat" );
415 eval { -l _ };
416 is( "$@", "", "-l _ ok after lstat" );
417   
418 SKIP: {
419     skip "No lstat", 2 unless $Config{d_lstat};
420
421     # bug id 20020124.004
422     # If we have d_lstat, we should have symlink()
423     my $linkname = 'dolzero';
424     symlink $0, $linkname or die "# Can't symlink $0: $!";
425     lstat $linkname;
426     -T _;
427     eval { lstat _ };
428     like( $@, qr/^The stat preceding lstat\(\) wasn't an lstat/,
429         'lstat croaks after -T _' );
430     eval { -l _ };
431     like( $@, qr/^The stat preceding -l _ wasn't an lstat/,
432         '-l _ croaks after -T _' );
433     unlink $linkname or print "# unlink $linkname failed: $!\n";
434 }
435
436 print "# Zzz...\n";
437 sleep(3);
438 my $f = 'tstamp.tmp';
439 unlink $f;
440 ok (open(S, "> $f"), 'can create tmp file');
441 close S or die;
442 my @a = stat $f;
443 print "# time=$^T, stat=(@a)\n";
444 my @b = (-M _, -A _, -C _);
445 print "# -MAC=(@b)\n";
446 ok( (-M _) < 0, 'negative -M works');
447 ok( (-A _) < 0, 'negative -A works');
448 ok( (-C _) < 0, 'negative -C works');
449 ok(unlink($f), 'unlink tmp file');
450
451 {
452     ok(open(F, ">", $tmpfile), 'can create temp file');
453     close F;
454     chmod 0077, $tmpfile;
455     my @a = stat($tmpfile);
456     my $s1 = -s _;
457     -T _;
458     my $s2 = -s _;
459     is($s1, $s2, q(-T _ doesn't break the statbuffer));
460     unlink $tmpfile;
461 }
462
463 END {
464     1 while unlink $tmpfile;
465 }