[inseparable changes from match from perl-5.003_97b to perl-5.003_97c]
[perl.git] / lib / User / grent.pm
1 package User::grent;
2 use strict;
3
4 BEGIN { 
5     use Exporter   ();
6     use vars       qw(@EXPORT @EXPORT_OK %EXPORT_TAGS);
7     @EXPORT      = qw(getgrent getgrgid getgrnam getgr);
8     @EXPORT_OK   = qw($gr_name $gr_gid $gr_passwd $gr_mem @gr_members);
9     %EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
10 }
11 use vars      @EXPORT_OK;
12
13 # Class::Struct forbids use of @ISA
14 sub import { goto &Exporter::import }
15
16 use Class::Struct qw(struct);
17 struct 'User::grent' => [
18     name    => '$',
19     passwd  => '$',
20     gid     => '$',
21     members => '@',
22 ];
23
24 sub populate (@) {
25     return unless @_;
26     my $gob = new();
27     ($gr_name, $gr_passwd, $gr_gid) = @$gob[0,1,2] = @_[0,1,2];
28     @gr_members = @{$gob->[3]} = split ' ', $_[3];
29     return $gob;
30
31
32 sub getgrent ( ) { populate(CORE::getgrent()) } 
33 sub getgrnam ($) { populate(CORE::getgrnam(shift)) } 
34 sub getgrgid ($) { populate(CORE::getgrgid(shift)) } 
35 sub getgr    ($) { ($_[0] =~ /^\d+/) ? &getgrgid : &getgrnam } 
36
37 1;
38 __END__
39
40 =head1 NAME
41
42 User::grent - by-name interface to Perl's built-in getgr*() functions
43
44 =head1 SYNOPSIS
45
46  use User::grent;
47  $gr = getgrgid(0) or die "No group zero";
48  if ( $gr->name eq 'wheel' && @{$gr->members} > 1 ) {
49      print "gid zero name wheel, with other members";
50  } 
51
52  use User::grent qw(:FIELDS;
53  getgrgid(0) or die "No group zero";
54  if ( $gr_name eq 'wheel' && @gr_members > 1 ) {
55      print "gid zero name wheel, with other members";
56  } 
57
58  $gr = getgr($whoever);
59
60 =head1 DESCRIPTION
61
62 This module's default exports override the core getgrent(), getgruid(),
63 and getgrnam() functions, replacing them with versions that return
64 "User::grent" objects.  This object has methods that return the similarly
65 named structure field name from the C's passwd structure from F<grp.h>; 
66 namely name, passwd, gid, and members (not mem).  The first three
67 return scalars, the last an array reference.
68
69 You may also import all the structure fields directly into your namespace
70 as regular variables using the :FIELDS import tag.  (Note that this still
71 overrides your core functions.)  Access these fields as variables named
72 with a preceding C<gr_>.  Thus, C<$group_obj-E<gt>gid()> corresponds
73 to $gr_gid if you import the fields.  Array references are available as
74 regular array variables, so C<@{ $group_obj-E<gt>members() }> would be
75 simply @gr_members.
76
77 The getpw() funtion is a simple front-end that forwards
78 a numeric argument to getpwuid() and the rest to getpwnam().
79
80 To access this functionality without the core overrides,
81 pass the C<use> an empty import list, and then access
82 function functions with their full qualified names.
83 On the other hand, the built-ins are still available
84 via the C<CORE::> pseudo-package.
85
86 =head1 NOTE
87
88 While this class is currently implemented using the Class::Struct
89 module to build a struct-like class, you shouldn't rely upon this.
90
91 =head1 AUTHOR
92
93 Tom Christiansen