85fb134236b7b6abba78407fdcb2ef078b4d8359
[perl.git] / utils / perlbug.PL
1 #!/usr/local/bin/perl
2
3 use Config;
4 use File::Basename qw(&basename &dirname);
5 use Cwd;
6 use File::Spec::Functions;
7
8 # List explicitly here the variables you want Configure to
9 # generate.  Metaconfig only looks for shell variables, so you
10 # have to mention them as if they were shell variables, not
11 # %Config entries.  Thus you write
12 #  $startperl
13 # to ensure Configure will look for $Config{startperl}.
14 #  $perlpath
15
16 # This forces PL files to create target in same directory as PL file.
17 # This is so that make depend always knows where to find PL derivatives.
18 $origdir = cwd;
19 chdir dirname($0);
20 $file = basename($0, '.PL');
21 $file .= '.com' if $^O eq 'VMS';
22
23 open OUT, ">$file" or die "Can't create $file: $!";
24
25 # get patchlevel.h timestamp
26
27 -e catfile(updir, "patchlevel.h")
28     or die "Can't find patchlevel.h: $!";
29
30 my $patchlevel_date = (stat _)[9];
31
32 # TO DO (perhaps): store/embed $Config::config_sh into perlbug. When perlbug is
33 # used, compare $Config::config_sh with the stored version. If they differ then
34 # append a list of individual differences to the bug report.
35
36
37 print "Extracting $file (with variable substitutions)\n";
38
39 # In this section, perl variables will be expanded during extraction.
40 # You can use $Config{...} to use Configure variables.
41
42 my $extract_version = sprintf("%vd", $^V);
43
44 print OUT <<"!GROK!THIS!";
45 $Config{startperl}
46     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
47         if \$running_under_some_shell;
48
49 my \$config_tag1 = '$extract_version - $Config{cf_time}';
50
51 my \$patchlevel_date = $patchlevel_date;
52 !GROK!THIS!
53
54 # In the following, perl variables are not expanded during extraction.
55
56 print OUT <<'!NO!SUBS!';
57 my @patches = Config::local_patches();
58 my $patch_tags = join "", map /(\S+)/ ? "+$1 " : (), @patches;
59
60 use warnings;
61 use strict;
62 use Config;
63 use File::Spec;         # keep perlbug Perl 5.005 compatible
64 use Getopt::Std;
65 use File::Basename 'basename';
66
67 sub paraprint;
68
69 BEGIN {
70     eval { require Mail::Send;};
71     $::HaveSend = ($@ eq "");
72     eval { require Mail::Util; } ;
73     $::HaveUtil = ($@ eq "");
74     # use secure tempfiles wherever possible
75     eval { require File::Temp; };
76     $::HaveTemp = ($@ eq "");
77     eval { require Module::CoreList; };
78     $::HaveCoreList = ($@ eq "");
79 };
80
81 my $Version = "1.40";
82
83 #TODO:
84 #       make sure failure (transmission-wise) of Mail::Send is accounted for.
85 #       (This may work now. Unsure of the original author's issue -JESSE 2008-06-08)
86 #       - Test -b option
87
88 my( $file, $usefile, $cc, $address, $bugaddress, $testaddress, $thanksaddress,
89     $filename, $messageid, $domain, $subject, $from, $verbose, $ed, $outfile,
90     $fh, $me, $body, $andcc, %REP, $ok, $thanks, $progname,
91     $Is_MSWin32, $Is_Linux, $Is_VMS, $Is_OpenBSD,
92     $report_about_module, $category, $severity,
93     %opt, $have_attachment, $attachments, $has_patch, $mime_boundary
94 );
95
96 my $perl_version = $^V ? sprintf("%vd", $^V) : $];
97
98 my $config_tag2 = "$perl_version - $Config{cf_time}";
99
100 Init();
101
102 if ($opt{h}) { Help(); exit; }
103 if ($opt{d}) { Dump(*STDOUT); exit; }
104 if (!-t STDIN && !($ok and not $opt{n})) {
105     paraprint <<"EOF";
106 Please use $progname interactively. If you want to
107 include a file, you can use the -f switch.
108 EOF
109     die "\n";
110 }
111
112 Query();
113 Edit() unless $usefile || ($ok and not $opt{n});
114 NowWhat();
115 if ($outfile) {
116     save_message_to_disk($outfile);
117 } else {
118     Send();
119     if ($thanks) {
120         print "\nThank you for taking the time to send a thank-you message!\n\n";
121
122         paraprint <<EOF
123 Please note that mailing lists are moderated, your message may take a while to
124 show up.
125 EOF
126     } else {
127         print "\nThank you for taking the time to file a bug report!\n\n";
128
129         paraprint <<EOF
130 Please note that mailing lists are moderated, your message may take a while to
131 show up. If you do not receive an automated response acknowledging your message
132 within a few hours (check your SPAM folder and outgoing mail) please consider
133 sending an email directly from your mail client to perlbug\@perl.org.
134 EOF
135     }
136
137 }
138
139 exit;
140
141 sub ask_for_alternatives { # (category|severity)
142     my $name = shift;
143     my %alts = (
144         'category' => {
145             'default' => 'core',
146             'ok'      => 'install',
147             # Inevitably some of these will end up in RT whatever we do:
148             'thanks'  => 'thanks',
149             'opts'    => [qw(core docs install library utilities)], # patch, notabug
150         },
151         'severity' => {
152             'default' => 'low',
153             'ok'      => 'none',
154             'thanks'  => 'none',
155             'opts'    => [qw(critical high medium low wishlist none)], # zero
156         },
157     );
158     die "Invalid alternative ($name) requested\n" unless grep(/^$name$/, keys %alts);
159     my $alt = "";
160     my $what = $ok || $thanks;
161     if ($what) {
162         $alt = $alts{$name}{$what};
163     } else {
164         my @alts = @{$alts{$name}{'opts'}};
165     print "\n\n";
166         paraprint <<EOF;
167 Please pick a $name from the following list:
168
169     @alts
170 EOF
171         my $err = 0;
172         do {
173             if ($err++ > 5) {
174                 die "Invalid $name: aborting.\n";
175             }
176         $alt = _prompt('', "\u$name", $alts{$name}{'default'});
177                 $alt ||= $alts{$name}{'default'};
178         } while !((($alt) = grep(/^$alt/i, @alts)));
179     }
180     lc $alt;
181 }
182
183 sub Init {
184     # -------- Setup --------
185
186     $Is_MSWin32 = $^O eq 'MSWin32';
187     $Is_VMS = $^O eq 'VMS';
188     $Is_Linux = lc($^O) eq 'linux';
189     $Is_OpenBSD = lc($^O) eq 'openbsd';
190
191     if (!getopts("Adhva:s:b:f:F:r:e:SCc:to:n:T:p:", \%opt)) { Help(); exit; };
192
193     # This comment is needed to notify metaconfig that we are
194     # using the $perladmin, $cf_by, and $cf_time definitions.
195
196     # -------- Configuration ---------
197
198     # perlbug address
199     $bugaddress = 'perlbug@perl.org';
200
201     # Test address
202     $testaddress = 'perlbug-test@perl.org';
203
204     # Thanks address
205     $thanksaddress = 'perl-thanks@perl.org';
206
207     if (basename ($0) =~ /^perlthanks/i) {
208         # invoked as perlthanks
209         $opt{T} = 1;
210         $opt{C} = 1; # don't send a copy to the local admin
211     }
212
213     if ($opt{T}) {
214         $thanks = 'thanks';
215     }
216     
217     $progname = $thanks ? 'perlthanks' : 'perlbug';
218     # Target address
219     $address = $opt{a} || ($opt{t} ? $testaddress
220                             : $thanks ? $thanksaddress : $bugaddress);
221
222     # Users address, used in message and in From and Reply-To headers
223     $from = $opt{r} || "";
224
225     # Include verbose configuration information
226     $verbose = $opt{v} || 0;
227
228     # Subject of bug-report message
229     $subject = $opt{s} || "";
230
231     # Send a file
232     $usefile = ($opt{f} || 0);
233
234     # File to send as report
235     $file = $opt{f} || "";
236
237     # We have one or more attachments
238     $have_attachment = ($opt{p} || 0);
239     $mime_boundary = ('-' x 12) . "$Version.perlbug" if $have_attachment;
240
241     # Comma-separated list of attachments
242     $attachments = $opt{p} || "";
243     $has_patch = 0; # TBD based on file type
244
245     for my $attachment (split /\s*,\s*/, $attachments) {
246         unless (-f $attachment && -r $attachment) {
247             die "The attachment $attachment is not a readable file: $!\n";
248         }
249         $has_patch = 1 if $attachment =~ m/\.(patch|diff)$/;
250     }
251
252     # File to output to
253     $outfile = $opt{F} || "";
254
255     # Body of report
256     $body = $opt{b} || "";
257         
258     # Editor
259     $ed = $opt{e} || $ENV{VISUAL} || $ENV{EDITOR} || $ENV{EDIT}
260         || ($Is_VMS && "edit/tpu")
261         || ($Is_MSWin32 && "notepad")
262         || "vi";
263
264     # Not OK - provide build failure template by finessing OK report
265     if ($opt{n}) {
266         if (substr($opt{n}, 0, 2) eq 'ok' )     {
267             $opt{o} = substr($opt{n}, 1);
268         } else {
269             Help();
270             exit();
271         }
272     }
273
274     # OK - send "OK" report for build on this system
275     $ok = '';
276     if ($opt{o}) {
277         if ($opt{o} eq 'k' or $opt{o} eq 'kay') {
278             my $age = time - $patchlevel_date;
279             if ($opt{o} eq 'k' and $age > 60 * 24 * 60 * 60 ) {
280                 my $date = localtime $patchlevel_date;
281                 print <<"EOF";
282 "perlbug -ok" and "perlbug -nok" do not report on Perl versions which
283 are more than 60 days old.  This Perl version was constructed on
284 $date.  If you really want to report this, use
285 "perlbug -okay" or "perlbug -nokay".
286 EOF
287                 exit();
288             }
289             # force these options
290             unless ($opt{n}) {
291                 $opt{S} = 1; # don't prompt for send
292                 $opt{b} = 1; # we have a body
293                 $body = "Perl reported to build OK on this system.\n";
294             }
295             $opt{C} = 1; # don't send a copy to the local admin
296             $opt{s} = 1; # we have a subject line
297             $subject = ($opt{n} ? 'Not ' : '')
298                     . "OK: perl $perl_version ${patch_tags}on"
299                     ." $::Config{'archname'} $::Config{'osvers'} $subject";
300             $ok = 'ok';
301         } else {
302             Help();
303             exit();
304         }
305     }
306
307     # Possible administrator addresses, in order of confidence
308     # (Note that cf_email is not mentioned to metaconfig, since
309     # we don't really want it. We'll just take it if we have to.)
310     #
311     # This has to be after the $ok stuff above because of the way
312     # that $opt{C} is forced.
313     $cc = $opt{C} ? "" : (
314         $opt{c} || $::Config{'perladmin'}
315         || $::Config{'cf_email'} || $::Config{'cf_by'}
316     );
317
318     if ($::HaveUtil) {
319                 $domain = Mail::Util::maildomain();
320     } elsif ($Is_MSWin32) {
321                 $domain = $ENV{'USERDOMAIN'};
322     } else {
323                 require Sys::Hostname;
324                 $domain = Sys::Hostname::hostname();
325     }
326
327     # Message-Id - rjsf
328     $messageid = "<$::Config{'version'}_${$}_".time."\@$domain>"; 
329
330     # My username
331     $me = $Is_MSWin32 ? $ENV{'USERNAME'}
332             : $^O eq 'os2' ? $ENV{'USER'} || $ENV{'LOGNAME'}
333             : eval { getpwuid($<) };    # May be missing
334
335     $from = $::Config{'cf_email'}
336        if !$from && $::Config{'cf_email'} && $::Config{'cf_by'} && $me &&
337                ($me eq $::Config{'cf_by'});
338 } # sub Init
339
340 sub Query {
341     # Explain what perlbug is
342     unless ($ok) {
343         if ($thanks) {
344             paraprint <<'EOF';
345 This program provides an easy way to send a thank-you message back to the
346 authors and maintainers of perl.
347
348 If you wish to submit a bug report, please run it without the -T flag
349 (or run the program perlbug rather than perlthanks)
350 EOF
351         } else {
352             paraprint <<"EOF";
353 This program provides an easy way to create a message reporting a
354 bug in the core perl distribution (along with tests or patches)
355 to the volunteers who maintain perl at $address.  To send a thank-you
356 note to $thanksaddress instead of a bug report, please run 'perlthanks'.
357
358 Please do not use $0 to send test messages, test whether perl
359 works, or to report bugs in perl modules from CPAN.
360
361 Suggestions for how to find help using Perl can be found at
362 http://perldoc.perl.org/perlcommunity.html
363 EOF
364         }
365     }
366
367     # Prompt for subject of message, if needed
368     
369     if ($subject && TrivialSubject($subject)) {
370         $subject = '';
371     }
372
373     unless ($subject) {
374             print 
375 "First of all, please provide a subject for the message.\n";
376         if ( not $thanks)  {
377             paraprint <<EOF;
378 This should be a concise description of your bug or problem
379 which will help the volunteers working to improve perl to categorize
380 and resolve the issue.  Be as specific and descriptive as
381 you can. A subject like "perl bug" or "perl problem" will make it
382 much less likely that your issue gets the attention it deserves.
383 EOF
384         }
385
386         my $err = 0;
387         do {
388         $subject = _prompt('','Subject');
389             if ($err++ == 5) {
390                 if ($thanks) {
391                     $subject = 'Thanks for Perl';
392                 } else {
393                     die "Aborting.\n";
394                 }
395             }
396         } while (TrivialSubject($subject));
397     }
398     $subject = '[PATCH] ' . $subject
399         if $has_patch && ($subject !~ m/^\[PATCH/i);
400
401     # Prompt for return address, if needed
402     unless ($opt{r}) {
403         # Try and guess return address
404         my $guess;
405
406         $guess = $ENV{'REPLY-TO'} || $ENV{'REPLYTO'} || $ENV{'EMAIL'}
407             || $from || '';
408
409         unless ($guess) {
410                 # move $domain to where we can use it elsewhere 
411         if ($domain) {
412                 if ($Is_VMS && !$::Config{'d_socket'}) {
413                     $guess = "$domain\:\:$me";
414                 } else {
415                     $guess = "$me\@$domain" if $domain;
416                 }
417             }
418         }
419
420         if ($guess) {
421             unless ($ok) {
422                 paraprint <<EOF;
423 Perl's developers may need your email address to contact you for
424 further information about your issue or to inform you when it is
425 resolved.  If the default shown is not your email address, please
426 correct it.
427 EOF
428             }
429         } else {
430             paraprint <<EOF;
431 Please enter your full internet email address so that Perl's
432 developers can contact you with questions about your issue or to
433 inform you that it has been resolved.
434 EOF
435         }
436
437         if ($ok && $guess) {
438             # use it
439             $from = $guess;
440         } else {
441             # verify it
442         $from = _prompt('','Your address',$guess);
443             $from = $guess if $from eq '';
444         }
445     }
446
447     if ($from eq $cc or $me eq $cc) {
448         # Try not to copy ourselves
449         $cc = "yourself";
450     }
451
452     # Prompt for administrator address, unless an override was given
453     if( !$opt{C} and !$opt{c} ) {
454         my $description =  <<EOF;
455 $0 can send a copy of this report to your local perl
456 administrator.  If the address below is wrong, please correct it,
457 or enter 'none' or 'yourself' to not send a copy.
458 EOF
459         my $entry = _prompt($description, "Local perl administrator", $cc);
460
461         if ($entry ne "") {
462             $cc = $entry;
463             $cc = '' if $me eq $cc;
464         }
465     }
466
467     $cc = '' if $cc =~ /^(none|yourself|me|myself|ourselves)$/i;
468     if ($cc) { 
469         $andcc = " and $cc" 
470     } else {
471         $andcc = ''
472     }
473
474     # Prompt for editor, if no override is given
475 editor:
476     unless ($opt{e} || $opt{f} || $opt{b}) {
477
478     my $description;
479
480         chomp (my $common_end = <<"EOF");
481 You will probably want to use a text editor to enter the body of
482 your report. If "$ed" is the editor you want to use, then just press
483 Enter, otherwise type in the name of the editor you would like to
484 use.
485
486 If you have already composed the body of your report, you may enter
487 "file", and $0 will prompt you to enter the name of the file
488 containing your report.
489 EOF
490
491         if ($thanks) {
492             $description = <<"EOF";
493 It's now time to compose your thank-you message.
494
495 Some information about your local perl configuration will automatically
496 be included at the end of your message, because we're curious about
497 the different ways that people build and use perl. If you'd rather
498 not share this information, you're welcome to delete it.
499
500 $common_end
501 EOF
502         } else {
503             $description =  <<"EOF";
504 It's now time to compose your bug report. Try to make the report
505 concise but descriptive. Please include any detail which you think
506 might be relevant or might help the volunteers working to improve
507 perl. If you are reporting something that does not work as you think
508 it should, please try to include examples of the actual result and of
509 what you expected.
510
511 Some information about your local perl configuration will automatically
512 be included at the end of your report. If you are using an unusual
513 version of perl, it would be useful if you could confirm that you
514 can replicate the problem on a standard build of perl as well.
515
516 $common_end
517 EOF
518         }
519
520     my $entry = _prompt($description, "Editor", $ed);
521         $usefile = 0;
522         if ($entry eq "file") {
523             $usefile = 1;
524         } elsif ($entry ne "") {
525             $ed = $entry;
526         }
527     }
528     if ($::HaveCoreList && !$ok && !$thanks) {
529         my $description =  <<EOF;
530 If your bug is about a Perl module rather than a core language
531 feature, please enter its name here. If it's not, just hit Enter
532 to skip this question.
533 EOF
534
535     my $entry = '';
536         while ($entry eq '') {
537         $entry = _prompt($description, 'Module');
538             my $first_release = Module::CoreList->first_release($entry);
539             if ($entry and not $first_release) {
540                 paraprint <<EOF;
541 $entry is not a "core" Perl module. Please check that you entered
542 its name correctly. If it is correct, quit this program, try searching
543 for $entry on http://rt.cpan.org, and report your issue there.
544 EOF
545
546             $entry = '';
547         } elsif (my $bug_tracker = $Module::CoreList::bug_tracker{$entry}) {
548                 paraprint <<"EOF";
549 $entry included with core Perl is copied directly from the CPAN distribution.
550 Please report bugs in $entry directly to its maintainers using $bug_tracker
551 EOF
552             $entry = '';
553         } elsif ($entry) {
554                 $category ||= 'library';
555                 $report_about_module = $entry;
556             last;
557         } else {
558             last;
559         }
560         }
561     }
562
563     # Prompt for category of bug
564     $category ||= ask_for_alternatives('category');
565
566     # Prompt for severity of bug
567     $severity ||= ask_for_alternatives('severity');
568
569     # Generate scratch file to edit report in
570     $filename = filename();
571
572     # Prompt for file to read report from, if needed
573     if ($usefile and !$file) {
574 filename:
575         my $description = <<EOF;
576 What is the name of the file that contains your report?
577 EOF
578         my $entry = _prompt($description, "Filename");
579
580         if ($entry eq "") {
581             paraprint <<EOF;
582 It seems you didn't enter a filename. Please choose to use a text
583 editor or enter a filename.
584 EOF
585             goto editor;
586         }
587
588         unless (-f $entry and -r $entry) {
589             paraprint <<EOF;
590 '$entry' doesn't seem to be a readable file.  You may have mistyped
591 its name or may not have permission to read it.
592
593 If you don't want to use a file as the content of your report, just
594 hit Enter and you'll be able to select a text editor instead.
595 EOF
596             goto filename;
597         }
598         $file = $entry;
599     }
600
601     # Generate report
602     open(REP, '>:raw', $filename) or die "Unable to create report file '$filename': $!\n";
603     my $reptype = !$ok ? ($thanks ? 'thank-you' : 'bug')
604         : $opt{n} ? "build failure" : "success";
605
606     print REP <<EOF;
607 This is a $reptype report for perl from $from,
608 generated with the help of perlbug $Version running under perl $perl_version.
609
610 EOF
611
612     if ($body) {
613         print REP $body;
614     } elsif ($usefile) {
615         open(F, '<:raw', $file)
616                 or die "Unable to read report file from '$file': $!\n";
617         while (<F>) {
618             print REP $_
619         }
620         close(F) or die "Error closing '$file': $!";
621     } else {
622         if ($thanks) {
623             print REP <<'EOF';
624
625 -----------------------------------------------------------------
626 [Please enter your thank-you message here]
627
628
629
630 [You're welcome to delete anything below this line]
631 -----------------------------------------------------------------
632 EOF
633         } else {
634             print REP <<'EOF';
635
636 -----------------------------------------------------------------
637 [Please describe your issue here]
638
639
640
641 [Please do not change anything below this line]
642 -----------------------------------------------------------------
643 EOF
644         }
645     }
646     Dump(*REP);
647     close(REP) or die "Error closing report file: $!";
648
649     # Set up an initial report fingerprint so we can compare it later
650     _fingerprint_lines_in_report();
651
652 } # sub Query
653
654 sub Dump {
655     local(*OUT) = @_;
656
657     # these won't have been set if run with -d
658     $category ||= 'core';
659     $severity ||= 'low';
660
661     print OUT <<EFF;
662 ---
663 Flags:
664     category=$category
665     severity=$severity
666 EFF
667
668     if ($has_patch) {
669         print OUT <<EFF;
670     Type=Patch
671     PatchStatus=HasPatch
672 EFF
673     }
674
675     if ($report_about_module ) { 
676         print OUT <<EFF;
677     module=$report_about_module
678 EFF
679     }
680     if ($opt{A}) {
681         print OUT <<EFF;
682     ack=no
683 EFF
684     }
685     print OUT <<EFF;
686 ---
687 EFF
688     print OUT "This perlbug was built using Perl $config_tag1\n",
689             "It is being executed now by  Perl $config_tag2.\n\n"
690         if $config_tag2 ne $config_tag1;
691
692     print OUT <<EOF;
693 Site configuration information for perl $perl_version:
694
695 EOF
696     if ($::Config{cf_by} and $::Config{cf_time}) {
697         print OUT "Configured by $::Config{cf_by} at $::Config{cf_time}.\n\n";
698     }
699     print OUT Config::myconfig;
700
701     if (@patches) {
702         print OUT join "\n    ", "Locally applied patches:", @patches;
703         print OUT "\n";
704     };
705
706     print OUT <<EOF;
707
708 ---
709 \@INC for perl $perl_version:
710 EOF
711     for my $i (@INC) {
712         print OUT "    $i\n";
713     }
714
715     print OUT <<EOF;
716
717 ---
718 Environment for perl $perl_version:
719 EOF
720     my @env =
721         qw(PATH LD_LIBRARY_PATH LANG PERL_BADLANG SHELL HOME LOGDIR LANGUAGE);
722     push @env, $Config{ldlibpthname} if $Config{ldlibpthname} ne '';
723     push @env, grep /^(?:PERL|LC_|LANG|CYGWIN)/, keys %ENV;
724     my %env;
725     @env{@env} = @env;
726     for my $env (sort keys %env) {
727         print OUT "    $env",
728                 exists $ENV{$env} ? "=$ENV{$env}" : ' (unset)',
729                 "\n";
730     }
731     if ($verbose) {
732         print OUT "\nComplete configuration data for perl $perl_version:\n\n";
733         my $value;
734         foreach (sort keys %::Config) {
735             $value = $::Config{$_};
736             $value = '' unless defined $value;
737             $value =~ s/'/\\'/g;
738             print OUT "$_='$value'\n";
739         }
740     }
741 } # sub Dump
742
743 sub Edit {
744     # Edit the report
745     if ($usefile || $body) {
746         my $description = "Please make sure that the name of the editor you want to use is correct.";
747         my $entry = _prompt($description, 'Editor', $ed);
748         $ed = $entry unless $entry eq '';
749     }
750
751     _edit_file($ed);
752 }
753
754 sub _edit_file {
755     my $editor = shift;
756
757     my $report_written = 0;
758
759     while ( !$report_written ) {
760         my $exit_status = system("$editor $filename");
761         if ($exit_status) {
762             my $desc = <<EOF;
763 The editor you chose ('$editor') could not be run!
764
765 If you mistyped its name, please enter it now, otherwise just press Enter.
766 EOF
767             my $entry = _prompt( $desc, 'Editor', $editor );
768             if ( $entry ne "" ) {
769                 $editor = $entry;
770                 next;
771             } else {
772                 paraprint <<EOF;
773 You may want to save your report to a file, so you can edit and
774 mail it later.
775 EOF
776                 return;
777             }
778         }
779         return if ( $ok and not $opt{n} ) || $body;
780
781         # Check that we have a report that has some, eh, report in it.
782
783         unless ( _fingerprint_lines_in_report() ) {
784             my $description = <<EOF;
785 It looks like you didn't enter a report. You may [r]etry your edit
786 or [c]ancel this report.
787 EOF
788             my $action = _prompt( $description, "Action (Retry/Cancel) " );
789             if ( $action =~ /^[re]/i ) {    # <R>etry <E>dit
790                 next;
791             } elsif ( $action =~ /^[cq]/i ) {    # <C>ancel, <Q>uit
792                 Cancel();                        # cancel exits
793             }
794         }
795         # Ok. the user did what they needed to;
796         return;
797
798     }
799 }
800
801
802 sub Cancel {
803     1 while unlink($filename);  # remove all versions under VMS
804     print "\nQuitting without sending your message.\n";
805     exit(0);
806 }
807
808 sub NowWhat {
809     # Report is done, prompt for further action
810     if( !$opt{S} ) {
811         while(1) {
812             my $menu = <<EOF;
813
814
815 You have finished composing your message. At this point, you have 
816 a few options. You can:
817
818     * [Se]nd the message to $address$andcc, 
819     * [D]isplay the message on the screen,
820     * [R]e-edit the message
821     * Display or change the message's [su]bject
822     * Save the message to a [f]ile to mail at another time
823     * [Q]uit without sending a message
824
825 EOF
826       retry:
827         print $menu;
828             my $action =  _prompt('', "Action (Send/Display/Edit/Subject/Save to File)");;
829         print "\n";
830             if ($action =~ /^(f|sa)/i) { # <F>ile/<Sa>ve
831             if ( SaveMessage() ) { exit }
832             } elsif ($action =~ /^(d|l|sh)/i ) { # <D>isplay, <L>ist, <Sh>ow
833                 # Display the message
834                 open(REP, '<:raw', $filename) or die "Couldn't open file '$filename': $!\n";
835                 while (<REP>) { print $_ }
836                 close(REP) or die "Error closing report file '$filename': $!";
837                 if ($have_attachment) {
838                     print "\n\n---\nAttachment(s):\n";
839                     for my $att (split /\s*,\s*/, $attachments) { print "    $att\n"; }
840                 }
841             } elsif ($action =~ /^su/i) { # <Su>bject
842                 my $reply = _prompt( "Subject: $subject", "If the above subject is fine, press Enter. Otherwise, type a replacement now\nSubject");
843                 if ($reply ne '') {
844                     unless (TrivialSubject($reply)) {
845                         $subject = $reply;
846                         print "Subject: $subject\n";
847                     }
848                 }
849             } elsif ($action =~ /^se/i) { # <S>end
850                 # Send the message
851                 my $reply =  _prompt( "Are you certain you want to send this message?", 'Please type "yes" if you are','no');
852                 if ($reply =~ /^yes$/) {
853                     last;
854                 } else {
855                     paraprint <<EOF;
856 You didn't type "yes", so your message has not yet been sent.
857 EOF
858                 }
859             } elsif ($action =~ /^[er]/i) { # <E>dit, <R>e-edit
860                 # edit the message
861                 Edit();
862             } elsif ($action =~ /^[qc]/i) { # <C>ancel, <Q>uit
863                 Cancel();
864             } elsif ($action =~ /^s/i) {
865                 paraprint <<EOF;
866 The command you entered was ambiguous. Please type "send", "save" or "subject".
867 EOF
868             }
869         }
870     }
871 } # sub NowWhat
872
873 sub TrivialSubject {
874     my $subject = shift;
875     if ($subject =~
876         /^(y(es)?|no?|help|perl( (bug|problem))?|bug|problem)$/i ||
877         length($subject) < 4 ||
878         $subject !~ /\s/) {
879         print "\nThe subject you entered wasn't very descriptive. Please try again.\n\n";
880         return 1;
881     } else {
882         return 0;
883     }
884 }
885
886 sub SaveMessage {
887     my $file_save = $outfile || "$progname.rep";
888     my $file = _prompt( '', "Name of file to save message in", $file_save );
889     save_message_to_disk($file) || return undef;
890     print "\n";
891     paraprint <<EOF;
892 A copy of your message has been saved in '$file' for you to
893 send to '$address' with your normal mail client.
894 EOF
895 }
896
897 sub Send {
898
899     # Message has been accepted for transmission -- Send the message
900
901     # on linux certain "mail" implementations won't accept the subject
902     # as "~s subject" and thus the Subject header will be corrupted
903     # so don't use Mail::Send to be safe
904     eval {
905         if ( $::HaveSend && !$Is_Linux && !$Is_OpenBSD ) {
906             _send_message_mailsend();
907         } elsif ($Is_VMS) {
908             _send_message_vms();
909         } else {
910             _send_message_sendmail();
911         }
912     };
913
914     if ( my $error = $@ ) {
915         paraprint <<EOF;
916 $0 has detected an error while trying to send your message: $error.
917
918 Your message may not have been sent. You will now have a chance to save a copy to disk.
919 EOF
920         SaveMessage();
921         return;
922     }
923
924     1 while unlink($filename);    # remove all versions under VMS
925 }    # sub Send
926
927 sub Help {
928     print <<EOF;
929
930 This program is designed to help you generate and send bug reports
931 (and thank-you notes) about perl5 and the modules which ship with it.
932
933 In most cases, you can just run "$0" interactively from a command
934 line without any special arguments and follow the prompts.
935
936 Advanced usage:
937
938 $0  [-v] [-a address] [-s subject] [-b body | -f inpufile ] [ -F outputfile ]
939     [-r returnaddress] [-e editor] [-c adminaddress | -C] [-S] [-t] [-h]
940     [-p patchfile ]
941 $0  [-v] [-r returnaddress] [-A] [-ok | -okay | -nok | -nokay]
942
943
944 Options:
945
946   -v    Include Verbose configuration data in the report
947   -f    File containing the body of the report. Use this to
948         quickly send a prepared message.
949   -p    File containing a patch or other text attachment. Separate
950         multiple files with commas.
951   -F    File to output the resulting mail message to, instead of mailing.
952   -S    Send without asking for confirmation.
953   -a    Address to send the report to. Defaults to '$address'.
954   -c    Address to send copy of report to. Defaults to '$cc'.
955   -C    Don't send copy to administrator.
956   -s    Subject to include with the message. You will be prompted
957         if you don't supply one on the command line.
958   -b    Body of the report. If not included on the command line, or
959         in a file with -f, you will get a chance to edit the message.
960   -r    Your return address. The program will ask you to confirm
961         this if you don't give it here.
962   -e    Editor to use.
963   -t    Test mode. The target address defaults to '$testaddress'.
964   -T    Thank-you mode. The target address defaults to '$thanksaddress'.
965   -d    Data mode.  This prints out your configuration data, without mailing
966         anything. You can use this with -v to get more complete data.
967   -A    Don't send a bug received acknowledgement to the return address.
968   -ok   Report successful build on this system to perl porters
969         (use alone or with -v). Only use -ok if *everything* was ok:
970         if there were *any* problems at all, use -nok.
971   -okay As -ok but allow report from old builds.
972   -nok  Report unsuccessful build on this system to perl porters
973         (use alone or with -v). You must describe what went wrong
974         in the body of the report which you will be asked to edit.
975   -nokay As -nok but allow report from old builds.
976   -h    Print this help message.
977
978 EOF
979 }
980
981 sub filename {
982     if ($::HaveTemp) {
983         # Good. Use a secure temp file
984         my ($fh, $filename) = File::Temp::tempfile(UNLINK => 1);
985         close($fh);
986         return $filename;
987     } else {
988         # Bah. Fall back to doing things less securely.
989         my $dir = File::Spec->tmpdir();
990         $filename = "bugrep0$$";
991         $filename++ while -e File::Spec->catfile($dir, $filename);
992         $filename = File::Spec->catfile($dir, $filename);
993     }
994 }
995
996 sub paraprint {
997     my @paragraphs = split /\n{2,}/, "@_";
998     for (@paragraphs) {   # implicit local $_
999         s/(\S)\s*\n/$1 /g;
1000         write;
1001         print "\n";
1002     }
1003 }
1004
1005 sub _prompt {
1006     my ($explanation, $prompt, $default) = (@_);
1007     if ($explanation) {
1008         print "\n\n";
1009         paraprint $explanation;
1010     }
1011     print $prompt. ($default ? " [$default]" :''). ": ";
1012         my $result = scalar(<>);
1013     chomp($result);
1014         $result =~ s/^\s*(.*?)\s*$/$1/s;
1015     if ($default && $result eq '') {
1016         return $default;
1017     } else {
1018         return $result;
1019     }
1020 }
1021
1022 sub _build_header {
1023     my %attr = (@_);
1024
1025     my $head = '';
1026     for my $header (keys %attr) {
1027         $head .= "$header: ".$attr{$header}."\n";
1028     }
1029     return $head;
1030 }
1031
1032 sub _message_headers {
1033     my %headers = ( To => $address, Subject => $subject );
1034     $headers{'Cc'}         = $cc        if ($cc);
1035     $headers{'Message-Id'} = $messageid if ($messageid);
1036     $headers{'Reply-To'}   = $from      if ($from);
1037     $headers{'From'}       = $from      if ($from);
1038     if ($have_attachment) {
1039         $headers{'MIME-Version'} = '1.0';
1040         $headers{'Content-Type'} = qq{multipart/mixed; boundary=\"$mime_boundary\"};
1041     }
1042     return \%headers;
1043 }
1044
1045 sub _add_body_start {
1046     my $body_start = <<"BODY_START";
1047 This is a multi-part message in MIME format.
1048 --$mime_boundary
1049 Content-Type: text/plain; format=fixed
1050 Content-Transfer-Encoding: 8bit
1051
1052 BODY_START
1053     return $body_start;
1054 }
1055
1056 sub _add_attachments {
1057     my $attach = '';
1058     for my $attachment (split /\s*,\s*/, $attachments) {
1059         my $attach_file = basename($attachment);
1060         $attach .= <<"ATTACHMENT";
1061
1062 --$mime_boundary
1063 Content-Type: text/x-patch; name="$attach_file"
1064 Content-Transfer-Encoding: 8bit
1065 Content-Disposition: attachment; filename="$attach_file"
1066
1067 ATTACHMENT
1068
1069         open my $attach_fh, '<:raw', $attachment
1070             or die "Couldn't open attachment '$attachment': $!\n";
1071         while (<$attach_fh>) { $attach .= $_; }
1072         close($attach_fh) or die "Error closing attachment '$attachment': $!";
1073     }
1074
1075     $attach .= "\n--$mime_boundary--\n";
1076     return $attach;
1077 }
1078
1079 sub build_complete_message {
1080     my $content = _build_header(%{_message_headers()}) . "\n\n";
1081     $content .= _add_body_start() if $have_attachment;
1082     open( REP, "<:raw", $filename ) or die "Couldn't open file '$filename': $!\n";
1083     while (<REP>) { $content .= $_; }
1084     close(REP) or die "Error closing report file '$filename': $!";
1085     $content .= _add_attachments() if $have_attachment;
1086     return $content;
1087 }
1088
1089 sub save_message_to_disk {
1090     my $file = shift;
1091
1092         open OUTFILE, '>:raw', $file or do { warn  "Couldn't open '$file': $!\n"; return undef};
1093         print OUTFILE build_complete_message();
1094         close(OUTFILE) or do { warn  "Error closing $file: $!"; return undef };
1095             print "\nMessage saved.\n";
1096         return 1;
1097 }
1098
1099 sub _send_message_vms {
1100
1101     my $mail_from  = $from;
1102     my $rcpt_to_to = $address;
1103     my $rcpt_to_cc = $cc;
1104
1105     map { $_ =~ s/^[^<]*<//;
1106           $_ =~ s/>[^>]*//; } ($mail_from, $rcpt_to_to, $rcpt_to_cc);
1107
1108     if ( open my $sff_fh, '|-:raw', 'MCR TCPIP$SYSTEM:TCPIP$SMTP_SFF.EXE SYS$INPUT:' ) {
1109         print $sff_fh "MAIL FROM:<$mail_from>\n";
1110         print $sff_fh "RCPT TO:<$rcpt_to_to>\n";
1111         print $sff_fh "RCPT TO:<$rcpt_to_cc>\n" if $rcpt_to_cc;
1112         print $sff_fh "DATA\n";
1113         print $sff_fh build_complete_message();
1114         my $success = close $sff_fh;
1115         if ($success ) {
1116             print "\nMessage sent\n";
1117             return;
1118         }
1119     }
1120     die "Mail transport failed (leaving bug report in $filename): $^E\n";
1121 }
1122
1123 sub _send_message_mailsend {
1124     my $msg = Mail::Send->new();
1125     my %headers = %{_message_headers()};
1126     for my $key ( keys %headers) {
1127         $msg->add($key => $headers{$key});
1128     }
1129
1130     $fh = $msg->open;
1131     binmode($fh, ':raw');
1132     print $fh _add_body_start() if $have_attachment;
1133     open(REP, "<:raw", $filename) or die "Couldn't open '$filename': $!\n";
1134     while (<REP>) { print $fh $_ }
1135     close(REP) or die "Error closing $filename: $!";
1136     print $fh _add_attachments() if $have_attachment;
1137     $fh->close or die "Error sending mail: $!";
1138
1139     print "\nMessage sent.\n";
1140 }
1141
1142 sub _probe_for_sendmail {
1143     my $sendmail = "";
1144     for (qw(/usr/lib/sendmail /usr/sbin/sendmail /usr/ucblib/sendmail)) {
1145         $sendmail = $_, last if -e $_;
1146     }
1147     if ( $^O eq 'os2' and $sendmail eq "" ) {
1148         my $path = $ENV{PATH};
1149         $path =~ s:\\:/:;
1150         my @path = split /$Config{'path_sep'}/, $path;
1151         for (@path) {
1152             $sendmail = "$_/sendmail",     last if -e "$_/sendmail";
1153             $sendmail = "$_/sendmail.exe", last if -e "$_/sendmail.exe";
1154         }
1155     }
1156     return $sendmail;
1157 }
1158
1159 sub _send_message_sendmail {
1160     my $sendmail = _probe_for_sendmail();
1161     unless ($sendmail) {
1162         my $message_start = !$Is_Linux && !$Is_OpenBSD ? <<'EOT' : <<'EOT';
1163 It appears that there is no program which looks like "sendmail" on
1164 your system and that the Mail::Send library from CPAN isn't available.
1165 EOT
1166 It appears that there is no program which looks like "sendmail" on
1167 your system.
1168 EOT
1169         paraprint(<<"EOF"), die "\n";
1170 $message_start
1171 Because of this, there's no easy way to automatically send your
1172 message.
1173
1174 A copy of your message has been saved in '$filename' for you to
1175 send to '$address' with your normal mail client.
1176 EOF
1177     }
1178
1179     open( SENDMAIL, "|-:raw", $sendmail, "-t", "-oi", "-f", $from )
1180         || die "'|$sendmail -t -oi -f $from' failed: $!";
1181     print SENDMAIL build_complete_message();
1182     if ( close(SENDMAIL) ) {
1183         print "\nMessage sent\n";
1184     } else {
1185         warn "\nSendmail returned status '", $? >> 8, "'\n";
1186     }
1187 }
1188
1189
1190
1191 # a strange way to check whether any significant editing
1192 # has been done: check whether any new non-empty lines
1193 # have been added.
1194
1195 sub _fingerprint_lines_in_report {
1196     my $new_lines = 0;
1197     # read in the report template once so that
1198     # we can track whether the user does any editing.
1199     # yes, *all* whitespace is ignored.
1200
1201     open(REP, '<:raw', $filename) or die "Unable to open report file '$filename': $!\n";
1202     while (my $line = <REP>) {
1203         $line =~ s/\s+//g;
1204         $new_lines++ if (!$REP{$line});
1205
1206     }
1207     close(REP) or die "Error closing report file '$filename': $!";
1208     # returns the number of lines with content that wasn't there when last we looked
1209     return $new_lines;
1210 }
1211
1212
1213
1214 format STDOUT =
1215 ^<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<< ~~
1216 $_
1217 .
1218
1219 __END__
1220
1221 =head1 NAME
1222
1223 perlbug - how to submit bug reports on Perl
1224
1225 =head1 SYNOPSIS
1226
1227 B<perlbug>
1228
1229 B<perlbug> S<[ B<-v> ]> S<[ B<-a> I<address> ]> S<[ B<-s> I<subject> ]>
1230 S<[ B<-b> I<body> | B<-f> I<inputfile> ]> S<[ B<-F> I<outputfile> ]>
1231 S<[ B<-r> I<returnaddress> ]>
1232 S<[ B<-e> I<editor> ]> S<[ B<-c> I<adminaddress> | B<-C> ]>
1233 S<[ B<-S> ]> S<[ B<-t> ]>  S<[ B<-d> ]>  S<[ B<-A> ]>  S<[ B<-h> ]> S<[ B<-T> ]>
1234
1235 B<perlbug> S<[ B<-v> ]> S<[ B<-r> I<returnaddress> ]>
1236  S<[ B<-A> ]> S<[ B<-ok> | B<-okay> | B<-nok> | B<-nokay> ]>
1237
1238 B<perlthanks>
1239
1240 =head1 DESCRIPTION
1241
1242
1243 This program is designed to help you generate and send bug reports
1244 (and thank-you notes) about perl5 and the modules which ship with it.
1245
1246 In most cases, you can just run it interactively from a command
1247 line without any special arguments and follow the prompts.
1248
1249 If you have found a bug with a non-standard port (one that was not
1250 part of the I<standard distribution>), a binary distribution, or a
1251 non-core module (such as Tk, DBI, etc), then please see the
1252 documentation that came with that distribution to determine the
1253 correct place to report bugs.
1254
1255 If you are unable to send your report using B<perlbug> (most likely
1256 because your system doesn't have a way to send mail that perlbug
1257 recognizes), you may be able to use this tool to compose your report
1258 and save it to a file which you can then send to B<perlbug@perl.org>
1259 using your regular mail client.
1260
1261 In extreme cases, B<perlbug> may not work well enough on your system
1262 to guide you through composing a bug report. In those cases, you
1263 may be able to use B<perlbug -d> to get system configuration
1264 information to include in a manually composed bug report to
1265 B<perlbug@perl.org>.
1266
1267
1268 When reporting a bug, please run through this checklist:
1269
1270 =over 4
1271
1272 =item What version of Perl you are running?
1273
1274 Type C<perl -v> at the command line to find out.
1275
1276 =item Are you running the latest released version of perl?
1277
1278 Look at http://www.perl.org/ to find out.  If you are not using the
1279 latest released version, please try to replicate your bug on the
1280 latest stable release.
1281
1282 Note that reports about bugs in old versions of Perl, especially
1283 those which indicate you haven't also tested the current stable
1284 release of Perl, are likely to receive less attention from the
1285 volunteers who build and maintain Perl than reports about bugs in
1286 the current release.
1287
1288 This tool isn't appropriate for reporting bugs in any version
1289 prior to Perl 5.0.
1290
1291 =item Are you sure what you have is a bug?
1292
1293 A significant number of the bug reports we get turn out to be
1294 documented features in Perl.  Make sure the issue you've run into
1295 isn't intentional by glancing through the documentation that comes
1296 with the Perl distribution.
1297
1298 Given the sheer volume of Perl documentation, this isn't a trivial
1299 undertaking, but if you can point to documentation that suggests
1300 the behaviour you're seeing is I<wrong>, your issue is likely to
1301 receive more attention. You may want to start with B<perldoc>
1302 L<perltrap> for pointers to common traps that new (and experienced)
1303 Perl programmers run into.
1304
1305 If you're unsure of the meaning of an error message you've run
1306 across, B<perldoc> L<perldiag> for an explanation.  If the message
1307 isn't in perldiag, it probably isn't generated by Perl.  You may
1308 have luck consulting your operating system documentation instead.
1309
1310 If you are on a non-UNIX platform B<perldoc> L<perlport>, as some
1311 features may be unimplemented or work differently.
1312
1313 You may be able to figure out what's going wrong using the Perl
1314 debugger.  For information about how to use the debugger B<perldoc>
1315 L<perldebug>.
1316
1317 =item Do you have a proper test case?
1318
1319 The easier it is to reproduce your bug, the more likely it will be
1320 fixed -- if nobody can duplicate your problem, it probably won't be 
1321 addressed.
1322
1323 A good test case has most of these attributes: short, simple code;
1324 few dependencies on external commands, modules, or libraries; no
1325 platform-dependent code (unless it's a platform-specific bug);
1326 clear, simple documentation.
1327
1328 A good test case is almost always a good candidate to be included in
1329 Perl's test suite.  If you have the time, consider writing your test case so
1330 that it can be easily included into the standard test suite.
1331
1332 =item Have you included all relevant information?
1333
1334 Be sure to include the B<exact> error messages, if any.
1335 "Perl gave an error" is not an exact error message.
1336
1337 If you get a core dump (or equivalent), you may use a debugger
1338 (B<dbx>, B<gdb>, etc) to produce a stack trace to include in the bug
1339 report.  
1340
1341 NOTE: unless your Perl has been compiled with debug info
1342 (often B<-g>), the stack trace is likely to be somewhat hard to use
1343 because it will most probably contain only the function names and not
1344 their arguments.  If possible, recompile your Perl with debug info and
1345 reproduce the crash and the stack trace.
1346
1347 =item Can you describe the bug in plain English?
1348
1349 The easier it is to understand a reproducible bug, the more likely
1350 it will be fixed.  Any insight you can provide into the problem
1351 will help a great deal.  In other words, try to analyze the problem
1352 (to the extent you can) and report your discoveries.
1353
1354 =item Can you fix the bug yourself?
1355
1356 If so, that's great news; bug reports with patches are likely to
1357 receive significantly more attention and interest than those without
1358 patches.  Please attach your patch to the report using the C<-p> option.
1359 When sending a patch, create it using C<git format-patch> if possible,
1360 though a unified diff created with C<diff -pu> will do nearly as well.
1361
1362 Your patch may be returned with requests for changes, or requests for more
1363 detailed explanations about your fix.
1364
1365 Here are a few hints for creating high-quality patches:
1366
1367 Make sure the patch is not reversed (the first argument to diff is
1368 typically the original file, the second argument your changed file).
1369 Make sure you test your patch by applying it with C<git am> or the
1370 C<patch> program before you send it on its way.  Try to follow the
1371 same style as the code you are trying to patch.  Make sure your patch
1372 really does work (C<make test>, if the thing you're patching is covered
1373 by Perl's test suite).
1374
1375 =item Can you use C<perlbug> to submit the report?
1376
1377 B<perlbug> will, amongst other things, ensure your report includes
1378 crucial information about your version of perl.  If C<perlbug> is
1379 unable to mail your report after you have typed it in, you may have
1380 to compose the message yourself, add the output produced by C<perlbug
1381 -d> and email it to B<perlbug@perl.org>.  If, for some reason, you
1382 cannot run C<perlbug> at all on your system, be sure to include the
1383 entire output produced by running C<perl -V> (note the uppercase V).
1384
1385 Whether you use C<perlbug> or send the email manually, please make
1386 your Subject line informative.  "a bug" is not informative.  Neither
1387 is "perl crashes" nor is "HELP!!!".  These don't help.  A compact
1388 description of what's wrong is fine.
1389
1390 =item Can you use C<perlbug> to submit a thank-you note?
1391
1392 Yes, you can do this by either using the C<-T> option, or by invoking
1393 the program as C<perlthanks>. Thank-you notes are good. It makes people
1394 smile. 
1395
1396 =back
1397
1398 Having done your bit, please be prepared to wait, to be told the
1399 bug is in your code, or possibly to get no reply at all.  The
1400 volunteers who maintain Perl are busy folks, so if your problem is
1401 an obvious bug in your own code, is difficult to understand or is
1402 a duplicate of an existing report, you may not receive a personal
1403 reply.
1404
1405 If it is important to you that your bug be fixed, do monitor the
1406 perl5-porters@perl.org mailing list (mailing lists are moderated, your
1407 message may take a while to show up) and the commit logs to development
1408 versions of Perl, and encourage the maintainers with kind words or
1409 offers of frosty beverages.  (Please do be kind to the maintainers.
1410 Harassing or flaming them is likely to have the opposite effect of the
1411 one you want.)
1412
1413 Feel free to update the ticket about your bug on http://rt.perl.org
1414 if a new version of Perl is released and your bug is still present.
1415
1416 =head1 OPTIONS
1417
1418 =over 8
1419
1420 =item B<-a>
1421
1422 Address to send the report to.  Defaults to B<perlbug@perl.org>.
1423
1424 =item B<-A>
1425
1426 Don't send a bug received acknowledgement to the reply address.
1427 Generally it is only a sensible to use this option if you are a
1428 perl maintainer actively watching perl porters for your message to
1429 arrive.
1430
1431 =item B<-b>
1432
1433 Body of the report.  If not included on the command line, or
1434 in a file with B<-f>, you will get a chance to edit the message.
1435
1436 =item B<-C>
1437
1438 Don't send copy to administrator.
1439
1440 =item B<-c>
1441
1442 Address to send copy of report to.  Defaults to the address of the
1443 local perl administrator (recorded when perl was built).
1444
1445 =item B<-d>
1446
1447 Data mode (the default if you redirect or pipe output).  This prints out
1448 your configuration data, without mailing anything.  You can use this
1449 with B<-v> to get more complete data.
1450
1451 =item B<-e>
1452
1453 Editor to use.
1454
1455 =item B<-f>
1456
1457 File containing the body of the report.  Use this to quickly send a
1458 prepared message.
1459
1460 =item B<-F>
1461
1462 File to output the results to instead of sending as an email. Useful
1463 particularly when running perlbug on a machine with no direct internet
1464 connection.
1465
1466 =item B<-h>
1467
1468 Prints a brief summary of the options.
1469
1470 =item B<-ok>
1471
1472 Report successful build on this system to perl porters. Forces B<-S>
1473 and B<-C>. Forces and supplies values for B<-s> and B<-b>. Only
1474 prompts for a return address if it cannot guess it (for use with
1475 B<make>). Honors return address specified with B<-r>.  You can use this
1476 with B<-v> to get more complete data.   Only makes a report if this
1477 system is less than 60 days old.
1478
1479 =item B<-okay>
1480
1481 As B<-ok> except it will report on older systems.
1482
1483 =item B<-nok>
1484
1485 Report unsuccessful build on this system.  Forces B<-C>.  Forces and
1486 supplies a value for B<-s>, then requires you to edit the report
1487 and say what went wrong.  Alternatively, a prepared report may be
1488 supplied using B<-f>.  Only prompts for a return address if it
1489 cannot guess it (for use with B<make>). Honors return address
1490 specified with B<-r>.  You can use this with B<-v> to get more
1491 complete data.  Only makes a report if this system is less than 60
1492 days old.
1493
1494 =item B<-nokay>
1495
1496 As B<-nok> except it will report on older systems.
1497
1498 =item B<-p>
1499
1500 The names of one or more patch files or other text attachments to be
1501 included with the report.  Multiple files must be separated with commas.
1502
1503 =item B<-r>
1504
1505 Your return address.  The program will ask you to confirm its default
1506 if you don't use this option.
1507
1508 =item B<-S>
1509
1510 Send without asking for confirmation.
1511
1512 =item B<-s>
1513
1514 Subject to include with the message.  You will be prompted if you don't
1515 supply one on the command line.
1516
1517 =item B<-t>
1518
1519 Test mode.  The target address defaults to B<perlbug-test@perl.org>.
1520
1521 =item B<-T>
1522
1523 Send a thank-you note instead of a bug report. 
1524
1525 =item B<-v>
1526
1527 Include verbose configuration data in the report.
1528
1529 =back
1530
1531 =head1 AUTHORS
1532
1533 Kenneth Albanowski (E<lt>kjahds@kjahds.comE<gt>), subsequently
1534 I<doc>tored by Gurusamy Sarathy (E<lt>gsar@activestate.comE<gt>),
1535 Tom Christiansen (E<lt>tchrist@perl.comE<gt>), Nathan Torkington
1536 (E<lt>gnat@frii.comE<gt>), Charles F. Randall (E<lt>cfr@pobox.comE<gt>),
1537 Mike Guy (E<lt>mjtg@cam.ac.ukE<gt>), Dominic Dunlop
1538 (E<lt>domo@computer.orgE<gt>), Hugo van der Sanden (E<lt>hv@crypt.orgE<gt>),
1539 Jarkko Hietaniemi (E<lt>jhi@iki.fiE<gt>), Chris Nandor
1540 (E<lt>pudge@pobox.comE<gt>), Jon Orwant (E<lt>orwant@media.mit.eduE<gt>,
1541 Richard Foley (E<lt>richard.foley@rfi.netE<gt>), Jesse Vincent
1542 (E<lt>jesse@bestpractical.comE<gt>), and Craig A. Berry (E<lt>craigberry@mac.comE<gt>).
1543
1544 =head1 SEE ALSO
1545
1546 perl(1), perldebug(1), perldiag(1), perlport(1), perltrap(1),
1547 diff(1), patch(1), dbx(1), gdb(1)
1548
1549 =head1 BUGS
1550
1551 None known (guess what must have been used to report them?)
1552
1553 =cut
1554
1555 !NO!SUBS!
1556
1557 close OUT or die "Can't close $file: $!";
1558 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
1559 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
1560 chdir $origdir;