Documentation patch for overload
[perl.git] / lib / overload.pm
1 package overload;
2
3 our $VERSION = '1.04';
4
5 $overload::hint_bits = 0x20000; # HINT_LOCALIZE_HH
6
7 sub nil {}
8
9 sub OVERLOAD {
10   $package = shift;
11   my %arg = @_;
12   my ($sub, $fb);
13   $ {$package . "::OVERLOAD"}{dummy}++; # Register with magic by touching.
14   *{$package . "::()"} = \&nil; # Make it findable via fetchmethod.
15   for (keys %arg) {
16     if ($_ eq 'fallback') {
17       $fb = $arg{$_};
18     } else {
19       $sub = $arg{$_};
20       if (not ref $sub and $sub !~ /::/) {
21         $ {$package . "::(" . $_} = $sub;
22         $sub = \&nil;
23       }
24       #print STDERR "Setting `$ {'package'}::\cO$_' to \\&`$sub'.\n";
25       *{$package . "::(" . $_} = \&{ $sub };
26     }
27   }
28   ${$package . "::()"} = $fb; # Make it findable too (fallback only).
29 }
30
31 sub import {
32   $package = (caller())[0];
33   # *{$package . "::OVERLOAD"} = \&OVERLOAD;
34   shift;
35   $package->overload::OVERLOAD(@_);
36 }
37
38 sub unimport {
39   $package = (caller())[0];
40   ${$package . "::OVERLOAD"}{dummy}++; # Upgrade the table
41   shift;
42   for (@_) {
43     if ($_ eq 'fallback') {
44       undef $ {$package . "::()"};
45     } else {
46       delete $ {$package . "::"}{"(" . $_};
47     }
48   }
49 }
50
51 sub Overloaded {
52   my $package = shift;
53   $package = ref $package if ref $package;
54   $package->can('()');
55 }
56
57 sub ov_method {
58   my $globref = shift;
59   return undef unless $globref;
60   my $sub = \&{*$globref};
61   return $sub if $sub ne \&nil;
62   return shift->can($ {*$globref});
63 }
64
65 sub OverloadedStringify {
66   my $package = shift;
67   $package = ref $package if ref $package;
68   #$package->can('(""')
69   ov_method mycan($package, '(""'), $package
70     or ov_method mycan($package, '(0+'), $package
71     or ov_method mycan($package, '(bool'), $package
72     or ov_method mycan($package, '(nomethod'), $package;
73 }
74
75 sub Method {
76   my $package = shift;
77   $package = ref $package if ref $package;
78   #my $meth = $package->can('(' . shift);
79   ov_method mycan($package, '(' . shift), $package;
80   #return $meth if $meth ne \&nil;
81   #return $ {*{$meth}};
82 }
83
84 sub AddrRef {
85   my $package = ref $_[0];
86   return "$_[0]" unless $package;
87
88         require Scalar::Util;
89         my $class = Scalar::Util::blessed($_[0]);
90         my $class_prefix = defined($class) ? "$class=" : "";
91         my $type = Scalar::Util::reftype($_[0]);
92         my $addr = Scalar::Util::refaddr($_[0]);
93         return sprintf("$class_prefix$type(0x%x)", $addr);
94 }
95
96 *StrVal = *AddrRef;
97
98 sub mycan {                             # Real can would leave stubs.
99   my ($package, $meth) = @_;
100   return \*{$package . "::$meth"} if defined &{$package . "::$meth"};
101   my $p;
102   foreach $p (@{$package . "::ISA"}) {
103     my $out = mycan($p, $meth);
104     return $out if $out;
105   }
106   return undef;
107 }
108
109 %constants = (
110               'integer'   =>  0x1000, # HINT_NEW_INTEGER
111               'float'     =>  0x2000, # HINT_NEW_FLOAT
112               'binary'    =>  0x4000, # HINT_NEW_BINARY
113               'q'         =>  0x8000, # HINT_NEW_STRING
114               'qr'        => 0x10000, # HINT_NEW_RE
115              );
116
117 %ops = ( with_assign      => "+ - * / % ** << >> x .",
118          assign           => "+= -= *= /= %= **= <<= >>= x= .=",
119          num_comparison   => "< <= >  >= == !=",
120          '3way_comparison'=> "<=> cmp",
121          str_comparison   => "lt le gt ge eq ne",
122          binary           => "& | ^",
123          unary            => "neg ! ~",
124          mutators         => '++ --',
125          func             => "atan2 cos sin exp abs log sqrt int",
126          conversion       => 'bool "" 0+',
127          iterators        => '<>',
128          dereferencing    => '${} @{} %{} &{} *{}',
129          special          => 'nomethod fallback =');
130
131 use warnings::register;
132 sub constant {
133   # Arguments: what, sub
134   while (@_) {
135     if (@_ == 1) {
136         warnings::warnif ("Odd number of arguments for overload::constant");
137         last;
138     }
139     elsif (!exists $constants {$_ [0]}) {
140         warnings::warnif ("`$_[0]' is not an overloadable type");
141     }
142     elsif (!ref $_ [1] || "$_[1]" !~ /CODE\(0x[\da-f]+\)$/) {
143         # Can't use C<ref $_[1] eq "CODE"> above as code references can be
144         # blessed, and C<ref> would return the package the ref is blessed into.
145         if (warnings::enabled) {
146             $_ [1] = "undef" unless defined $_ [1];
147             warnings::warn ("`$_[1]' is not a code reference");
148         }
149     }
150     else {
151         $^H{$_[0]} = $_[1];
152         $^H |= $constants{$_[0]} | $overload::hint_bits;
153     }
154     shift, shift;
155   }
156 }
157
158 sub remove_constant {
159   # Arguments: what, sub
160   while (@_) {
161     delete $^H{$_[0]};
162     $^H &= ~ $constants{$_[0]};
163     shift, shift;
164   }
165 }
166
167 1;
168
169 __END__
170
171 =head1 NAME
172
173 overload - Package for overloading Perl operations
174
175 =head1 SYNOPSIS
176
177     package SomeThing;
178
179     use overload
180         '+' => \&myadd,
181         '-' => \&mysub;
182         # etc
183     ...
184
185     package main;
186     $a = new SomeThing 57;
187     $b=5+$a;
188     ...
189     if (overload::Overloaded $b) {...}
190     ...
191     $strval = overload::StrVal $b;
192
193 =head1 DESCRIPTION
194
195 =head2 Declaration of overloaded functions
196
197 The compilation directive
198
199     package Number;
200     use overload
201         "+" => \&add,
202         "*=" => "muas";
203
204 declares function Number::add() for addition, and method muas() in
205 the "class" C<Number> (or one of its base classes)
206 for the assignment form C<*=> of multiplication.
207
208 Arguments of this directive come in (key, value) pairs.  Legal values
209 are values legal inside a C<&{ ... }> call, so the name of a
210 subroutine, a reference to a subroutine, or an anonymous subroutine
211 will all work.  Note that values specified as strings are
212 interpreted as methods, not subroutines.  Legal keys are listed below.
213
214 The subroutine C<add> will be called to execute C<$a+$b> if $a
215 is a reference to an object blessed into the package C<Number>, or if $a is
216 not an object from a package with defined mathemagic addition, but $b is a
217 reference to a C<Number>.  It can also be called in other situations, like
218 C<$a+=7>, or C<$a++>.  See L<MAGIC AUTOGENERATION>.  (Mathemagical
219 methods refer to methods triggered by an overloaded mathematical
220 operator.)
221
222 Since overloading respects inheritance via the @ISA hierarchy, the
223 above declaration would also trigger overloading of C<+> and C<*=> in
224 all the packages which inherit from C<Number>.
225
226 =head2 Calling Conventions for Binary Operations
227
228 The functions specified in the C<use overload ...> directive are called
229 with three (in one particular case with four, see L<Last Resort>)
230 arguments.  If the corresponding operation is binary, then the first
231 two arguments are the two arguments of the operation.  However, due to
232 general object calling conventions, the first argument should always be
233 an object in the package, so in the situation of C<7+$a>, the
234 order of the arguments is interchanged.  It probably does not matter
235 when implementing the addition method, but whether the arguments
236 are reversed is vital to the subtraction method.  The method can
237 query this information by examining the third argument, which can take
238 three different values:
239
240 =over 7
241
242 =item FALSE
243
244 the order of arguments is as in the current operation.
245
246 =item TRUE
247
248 the arguments are reversed.
249
250 =item C<undef>
251
252 the current operation is an assignment variant (as in
253 C<$a+=7>), but the usual function is called instead.  This additional
254 information can be used to generate some optimizations.  Compare
255 L<Calling Conventions for Mutators>.
256
257 =back
258
259 =head2 Calling Conventions for Unary Operations
260
261 Unary operation are considered binary operations with the second
262 argument being C<undef>.  Thus the functions that overloads C<{"++"}>
263 is called with arguments C<($a,undef,'')> when $a++ is executed.
264
265 =head2 Calling Conventions for Mutators
266
267 Two types of mutators have different calling conventions:
268
269 =over
270
271 =item C<++> and C<-->
272
273 The routines which implement these operators are expected to actually
274 I<mutate> their arguments.  So, assuming that $obj is a reference to a
275 number,
276
277   sub incr { my $n = $ {$_[0]}; ++$n; $_[0] = bless \$n}
278
279 is an appropriate implementation of overloaded C<++>.  Note that
280
281   sub incr { ++$ {$_[0]} ; shift }
282
283 is OK if used with preincrement and with postincrement. (In the case
284 of postincrement a copying will be performed, see L<Copy Constructor>.)
285
286 =item C<x=> and other assignment versions
287
288 There is nothing special about these methods.  They may change the
289 value of their arguments, and may leave it as is.  The result is going
290 to be assigned to the value in the left-hand-side if different from
291 this value.
292
293 This allows for the same method to be used as overloaded C<+=> and
294 C<+>.  Note that this is I<allowed>, but not recommended, since by the
295 semantic of L<"Fallback"> Perl will call the method for C<+> anyway,
296 if C<+=> is not overloaded.
297
298 =back
299
300 B<Warning.>  Due to the presence of assignment versions of operations,
301 routines which may be called in assignment context may create
302 self-referential structures.  Currently Perl will not free self-referential
303 structures until cycles are C<explicitly> broken.  You may get problems
304 when traversing your structures too.
305
306 Say,
307
308   use overload '+' => sub { bless [ \$_[0], \$_[1] ] };
309
310 is asking for trouble, since for code C<$obj += $foo> the subroutine
311 is called as C<$obj = add($obj, $foo, undef)>, or C<$obj = [\$obj,
312 \$foo]>.  If using such a subroutine is an important optimization, one
313 can overload C<+=> explicitly by a non-"optimized" version, or switch
314 to non-optimized version if C<not defined $_[2]> (see
315 L<Calling Conventions for Binary Operations>).
316
317 Even if no I<explicit> assignment-variants of operators are present in
318 the script, they may be generated by the optimizer.  Say, C<",$obj,"> or
319 C<',' . $obj . ','> may be both optimized to
320
321   my $tmp = ',' . $obj;    $tmp .= ',';
322
323 =head2 Overloadable Operations
324
325 The following symbols can be specified in C<use overload> directive:
326
327 =over 5
328
329 =item * I<Arithmetic operations>
330
331     "+", "+=", "-", "-=", "*", "*=", "/", "/=", "%", "%=",
332     "**", "**=", "<<", "<<=", ">>", ">>=", "x", "x=", ".", ".=",
333
334 For these operations a substituted non-assignment variant can be called if
335 the assignment variant is not available.  Methods for operations C<+>,
336 C<->, C<+=>, and C<-=> can be called to automatically generate
337 increment and decrement methods.  The operation C<-> can be used to
338 autogenerate missing methods for unary minus or C<abs>.
339
340 See L<"MAGIC AUTOGENERATION">, L<"Calling Conventions for Mutators"> and
341 L<"Calling Conventions for Binary Operations">) for details of these
342 substitutions.
343
344 =item * I<Comparison operations>
345
346     "<",  "<=", ">",  ">=", "==", "!=", "<=>",
347     "lt", "le", "gt", "ge", "eq", "ne", "cmp",
348
349 If the corresponding "spaceship" variant is available, it can be
350 used to substitute for the missing operation.  During C<sort>ing
351 arrays, C<cmp> is used to compare values subject to C<use overload>.
352
353 =item * I<Bit operations>
354
355     "&", "^", "|", "neg", "!", "~",
356
357 C<neg> stands for unary minus.  If the method for C<neg> is not
358 specified, it can be autogenerated using the method for
359 subtraction. If the method for C<!> is not specified, it can be
360 autogenerated using the methods for C<bool>, or C<"">, or C<0+>.
361
362 =item * I<Increment and decrement>
363
364     "++", "--",
365
366 If undefined, addition and subtraction methods can be
367 used instead.  These operations are called both in prefix and
368 postfix form.
369
370 =item * I<Transcendental functions>
371
372     "atan2", "cos", "sin", "exp", "abs", "log", "sqrt", "int"
373
374 If C<abs> is unavailable, it can be autogenerated using methods
375 for "E<lt>" or "E<lt>=E<gt>" combined with either unary minus or subtraction.
376
377 Note that traditionally the Perl function L<int> rounds to 0, thus for
378 floating-point-like types one should follow the same semantic.  If
379 C<int> is unavailable, it can be autogenerated using the overloading of
380 C<0+>.
381
382 =item * I<Boolean, string and numeric conversion>
383
384     'bool', '""', '0+',
385
386 If one or two of these operations are not overloaded, the remaining ones can
387 be used instead.  C<bool> is used in the flow control operators
388 (like C<while>) and for the ternary C<?:> operation.  These functions can
389 return any arbitrary Perl value.  If the corresponding operation for this value
390 is overloaded too, that operation will be called again with this value.
391
392 As a special case if the overload returns the object itself then it will
393 be used directly. An overloaded conversion returning the object is
394 probably a bug, because you're likely to get something that looks like
395 C<YourPackage=HASH(0x8172b34)>.
396
397 =item * I<Iteration>
398
399     "<>"
400
401 If not overloaded, the argument will be converted to a filehandle or
402 glob (which may require a stringification).  The same overloading
403 happens both for the I<read-filehandle> syntax C<E<lt>$varE<gt>> and
404 I<globbing> syntax C<E<lt>${var}E<gt>>.
405
406 B<BUGS> Even in list context, the iterator is currently called only
407 once and with scalar context.
408
409 =item * I<Dereferencing>
410
411     '${}', '@{}', '%{}', '&{}', '*{}'.
412
413 If not overloaded, the argument will be dereferenced I<as is>, thus
414 should be of correct type.  These functions should return a reference
415 of correct type, or another object with overloaded dereferencing.
416
417 As a special case if the overload returns the object itself then it
418 will be used directly (provided it is the correct type).
419
420 The dereference operators must be specified explicitly they will not be passed to
421 "nomethod".
422
423 =item * I<Special>
424
425     "nomethod", "fallback", "=", "~~",
426
427 see L<SPECIAL SYMBOLS FOR C<use overload>>.
428
429 =back
430
431 See L<"Fallback"> for an explanation of when a missing method can be
432 autogenerated.
433
434 A computer-readable form of the above table is available in the hash
435 %overload::ops, with values being space-separated lists of names:
436
437  with_assign      => '+ - * / % ** << >> x .',
438  assign           => '+= -= *= /= %= **= <<= >>= x= .=',
439  num_comparison   => '< <= > >= == !=',
440  '3way_comparison'=> '<=> cmp',
441  str_comparison   => 'lt le gt ge eq ne',
442  binary           => '& | ^',
443  unary            => 'neg ! ~',
444  mutators         => '++ --',
445  func             => 'atan2 cos sin exp abs log sqrt',
446  conversion       => 'bool "" 0+',
447  iterators        => '<>',
448  dereferencing    => '${} @{} %{} &{} *{}',
449  special          => 'nomethod fallback ='
450
451 =head2 Inheritance and overloading
452
453 Inheritance interacts with overloading in two ways.
454
455 =over
456
457 =item Strings as values of C<use overload> directive
458
459 If C<value> in
460
461   use overload key => value;
462
463 is a string, it is interpreted as a method name.
464
465 =item Overloading of an operation is inherited by derived classes
466
467 Any class derived from an overloaded class is also overloaded.  The
468 set of overloaded methods is the union of overloaded methods of all
469 the ancestors. If some method is overloaded in several ancestor, then
470 which description will be used is decided by the usual inheritance
471 rules:
472
473 If C<A> inherits from C<B> and C<C> (in this order), C<B> overloads
474 C<+> with C<\&D::plus_sub>, and C<C> overloads C<+> by C<"plus_meth">,
475 then the subroutine C<D::plus_sub> will be called to implement
476 operation C<+> for an object in package C<A>.
477
478 =back
479
480 Note that since the value of the C<fallback> key is not a subroutine,
481 its inheritance is not governed by the above rules.  In the current
482 implementation, the value of C<fallback> in the first overloaded
483 ancestor is used, but this is accidental and subject to change.
484
485 =head1 SPECIAL SYMBOLS FOR C<use overload>
486
487 Three keys are recognized by Perl that are not covered by the above
488 description.
489
490 =head2 Last Resort
491
492 C<"nomethod"> should be followed by a reference to a function of four
493 parameters.  If defined, it is called when the overloading mechanism
494 cannot find a method for some operation.  The first three arguments of
495 this function coincide with the arguments for the corresponding method if
496 it were found, the fourth argument is the symbol
497 corresponding to the missing method.  If several methods are tried,
498 the last one is used.  Say, C<1-$a> can be equivalent to
499
500         &nomethodMethod($a,1,1,"-")
501
502 if the pair C<"nomethod" =E<gt> "nomethodMethod"> was specified in the
503 C<use overload> directive.
504
505 The C<"nomethod"> mechanism is I<not> used for the dereference operators
506 ( ${} @{} %{} &{} *{} ).
507
508
509 If some operation cannot be resolved, and there is no function
510 assigned to C<"nomethod">, then an exception will be raised via die()--
511 unless C<"fallback"> was specified as a key in C<use overload> directive.
512
513
514 =head2 Fallback
515
516 The key C<"fallback"> governs what to do if a method for a particular
517 operation is not found.  Three different cases are possible depending on
518 the value of C<"fallback">:
519
520 =head2 Smart Match
521
522 The key C<"~~"> allows you to override the smart matching used by
523 the switch construct. See L<feature>.
524
525 =over 16
526
527 =item * C<undef>
528
529 Perl tries to use a
530 substituted method (see L<MAGIC AUTOGENERATION>).  If this fails, it
531 then tries to calls C<"nomethod"> value; if missing, an exception
532 will be raised.
533
534 =item * TRUE
535
536 The same as for the C<undef> value, but no exception is raised.  Instead,
537 it silently reverts to what it would have done were there no C<use overload>
538 present.
539
540 =item * defined, but FALSE
541
542 No autogeneration is tried.  Perl tries to call
543 C<"nomethod"> value, and if this is missing, raises an exception.
544
545 =back
546
547 B<Note.> C<"fallback"> inheritance via @ISA is not carved in stone
548 yet, see L<"Inheritance and overloading">.
549
550 =head2 Copy Constructor
551
552 The value for C<"="> is a reference to a function with three
553 arguments, i.e., it looks like the other values in C<use
554 overload>. However, it does not overload the Perl assignment
555 operator. This would go against Camel hair.
556
557 This operation is called in the situations when a mutator is applied
558 to a reference that shares its object with some other reference, such
559 as
560
561         $a=$b;
562         ++$a;
563
564 To make this change $a and not change $b, a copy of C<$$a> is made,
565 and $a is assigned a reference to this new object.  This operation is
566 done during execution of the C<++$a>, and not during the assignment,
567 (so before the increment C<$$a> coincides with C<$$b>).  This is only
568 done if C<++> is expressed via a method for C<'++'> or C<'+='> (or
569 C<nomethod>).  Note that if this operation is expressed via C<'+'>
570 a nonmutator, i.e., as in
571
572         $a=$b;
573         $a=$a+1;
574
575 then C<$a> does not reference a new copy of C<$$a>, since $$a does not
576 appear as lvalue when the above code is executed.
577
578 If the copy constructor is required during the execution of some mutator,
579 but a method for C<'='> was not specified, it can be autogenerated as a
580 string copy if the object is a plain scalar.
581
582 =over 5
583
584 =item B<Example>
585
586 The actually executed code for
587
588         $a=$b;
589         Something else which does not modify $a or $b....
590         ++$a;
591
592 may be
593
594         $a=$b;
595         Something else which does not modify $a or $b....
596         $a = $a->clone(undef,"");
597         $a->incr(undef,"");
598
599 if $b was mathemagical, and C<'++'> was overloaded with C<\&incr>,
600 C<'='> was overloaded with C<\&clone>.
601
602 =back
603
604 Same behaviour is triggered by C<$b = $a++>, which is consider a synonym for
605 C<$b = $a; ++$a>.
606
607 =head1 MAGIC AUTOGENERATION
608
609 If a method for an operation is not found, and the value for  C<"fallback"> is
610 TRUE or undefined, Perl tries to autogenerate a substitute method for
611 the missing operation based on the defined operations.  Autogenerated method
612 substitutions are possible for the following operations:
613
614 =over 16
615
616 =item I<Assignment forms of arithmetic operations>
617
618 C<$a+=$b> can use the method for C<"+"> if the method for C<"+=">
619 is not defined.
620
621 =item I<Conversion operations>
622
623 String, numeric, and boolean conversion are calculated in terms of one
624 another if not all of them are defined.
625
626 =item I<Increment and decrement>
627
628 The C<++$a> operation can be expressed in terms of C<$a+=1> or C<$a+1>,
629 and C<$a--> in terms of C<$a-=1> and C<$a-1>.
630
631 =item C<abs($a)>
632
633 can be expressed in terms of C<$aE<lt>0> and C<-$a> (or C<0-$a>).
634
635 =item I<Unary minus>
636
637 can be expressed in terms of subtraction.
638
639 =item I<Negation>
640
641 C<!> and C<not> can be expressed in terms of boolean conversion, or
642 string or numerical conversion.
643
644 =item I<Concatenation>
645
646 can be expressed in terms of string conversion.
647
648 =item I<Comparison operations>
649
650 can be expressed in terms of its "spaceship" counterpart: either
651 C<E<lt>=E<gt>> or C<cmp>:
652
653     <, >, <=, >=, ==, !=        in terms of <=>
654     lt, gt, le, ge, eq, ne      in terms of cmp
655
656 =item I<Iterator>
657
658     <>                          in terms of builtin operations
659
660 =item I<Dereferencing>
661
662     ${} @{} %{} &{} *{}         in terms of builtin operations
663
664 =item I<Copy operator>
665
666 can be expressed in terms of an assignment to the dereferenced value, if this
667 value is a scalar and not a reference.
668
669 =back
670
671 =head1 Minimal set of overloaded operations
672
673 Since some operations can be automatically generated from others, there is
674 a minimal set of operations that need to be overloaded in order to have
675 the complete set of overloaded operations at one's disposal. This minimal
676 set is:
677
678     + - * / % ** << >> x
679     <=> cmp
680     & | ^ ~
681     atan2 cos sin exp log sqrt int
682
683 Additionally, you need to define at least one of string, boolean or
684 numeric conversions. The string conversion can also be used to
685 emulate concatenation, so we'll assume string conversion is defined.
686 It usually makes sense to explicitly overload all conversion
687 operations.
688
689 =head1 Losing overloading
690
691 The restriction for the comparison operation is that even if, for example,
692 `C<cmp>' should return a blessed reference, the autogenerated `C<lt>'
693 function will produce only a standard logical value based on the
694 numerical value of the result of `C<cmp>'.  In particular, a working
695 numeric conversion is needed in this case (possibly expressed in terms of
696 other conversions).
697
698 Similarly, C<.=>  and C<x=> operators lose their mathemagical properties
699 if the string conversion substitution is applied.
700
701 When you chop() a mathemagical object it is promoted to a string and its
702 mathemagical properties are lost.  The same can happen with other
703 operations as well.
704
705 =head1 Run-time Overloading
706
707 Since all C<use> directives are executed at compile-time, the only way to
708 change overloading during run-time is to
709
710     eval 'use overload "+" => \&addmethod';
711
712 You can also use
713
714     eval 'no overload "+", "--", "<="';
715
716 though the use of these constructs during run-time is questionable.
717
718 =head1 Public functions
719
720 Package C<overload.pm> provides the following public functions:
721
722 =over 5
723
724 =item overload::StrVal(arg)
725
726 Gives string value of C<arg> as in absence of stringify overloading. If you
727 are using this to get the address of a reference (useful for checking if two
728 references point to the same thing) then you may be better off using
729 C<Scalar::Util::refaddr()>, which is faster.
730
731 =item overload::Overloaded(arg)
732
733 Returns true if C<arg> is subject to overloading of some operations.
734
735 =item overload::Method(obj,op)
736
737 Returns C<undef> or a reference to the method that implements C<op>.
738
739 =back
740
741 =head1 Overloading constants
742
743 For some applications, the Perl parser mangles constants too much.
744 It is possible to hook into this process via C<overload::constant()>
745 and C<overload::remove_constant()> functions.
746
747 These functions take a hash as an argument.  The recognized keys of this hash
748 are:
749
750 =over 8
751
752 =item integer
753
754 to overload integer constants,
755
756 =item float
757
758 to overload floating point constants,
759
760 =item binary
761
762 to overload octal and hexadecimal constants,
763
764 =item q
765
766 to overload C<q>-quoted strings, constant pieces of C<qq>- and C<qx>-quoted
767 strings and here-documents,
768
769 =item qr
770
771 to overload constant pieces of regular expressions.
772
773 =back
774
775 The corresponding values are references to functions which take three arguments:
776 the first one is the I<initial> string form of the constant, the second one
777 is how Perl interprets this constant, the third one is how the constant is used.
778 Note that the initial string form does not
779 contain string delimiters, and has backslashes in backslash-delimiter
780 combinations stripped (thus the value of delimiter is not relevant for
781 processing of this string).  The return value of this function is how this
782 constant is going to be interpreted by Perl.  The third argument is undefined
783 unless for overloaded C<q>- and C<qr>- constants, it is C<q> in single-quote
784 context (comes from strings, regular expressions, and single-quote HERE
785 documents), it is C<tr> for arguments of C<tr>/C<y> operators,
786 it is C<s> for right-hand side of C<s>-operator, and it is C<qq> otherwise.
787
788 Since an expression C<"ab$cd,,"> is just a shortcut for C<'ab' . $cd . ',,'>,
789 it is expected that overloaded constant strings are equipped with reasonable
790 overloaded catenation operator, otherwise absurd results will result.
791 Similarly, negative numbers are considered as negations of positive constants.
792
793 Note that it is probably meaningless to call the functions overload::constant()
794 and overload::remove_constant() from anywhere but import() and unimport() methods.
795 From these methods they may be called as
796
797         sub import {
798           shift;
799           return unless @_;
800           die "unknown import: @_" unless @_ == 1 and $_[0] eq ':constant';
801           overload::constant integer => sub {Math::BigInt->new(shift)};
802         }
803
804 =head1 IMPLEMENTATION
805
806 What follows is subject to change RSN.
807
808 The table of methods for all operations is cached in magic for the
809 symbol table hash for the package.  The cache is invalidated during
810 processing of C<use overload>, C<no overload>, new function
811 definitions, and changes in @ISA. However, this invalidation remains
812 unprocessed until the next C<bless>ing into the package. Hence if you
813 want to change overloading structure dynamically, you'll need an
814 additional (fake) C<bless>ing to update the table.
815
816 (Every SVish thing has a magic queue, and magic is an entry in that
817 queue.  This is how a single variable may participate in multiple
818 forms of magic simultaneously.  For instance, environment variables
819 regularly have two forms at once: their %ENV magic and their taint
820 magic. However, the magic which implements overloading is applied to
821 the stashes, which are rarely used directly, thus should not slow down
822 Perl.)
823
824 If an object belongs to a package using overload, it carries a special
825 flag.  Thus the only speed penalty during arithmetic operations without
826 overloading is the checking of this flag.
827
828 In fact, if C<use overload> is not present, there is almost no overhead
829 for overloadable operations, so most programs should not suffer
830 measurable performance penalties.  A considerable effort was made to
831 minimize the overhead when overload is used in some package, but the
832 arguments in question do not belong to packages using overload.  When
833 in doubt, test your speed with C<use overload> and without it.  So far
834 there have been no reports of substantial speed degradation if Perl is
835 compiled with optimization turned on.
836
837 There is no size penalty for data if overload is not used. The only
838 size penalty if overload is used in some package is that I<all> the
839 packages acquire a magic during the next C<bless>ing into the
840 package. This magic is three-words-long for packages without
841 overloading, and carries the cache table if the package is overloaded.
842
843 Copying (C<$a=$b>) is shallow; however, a one-level-deep copying is
844 carried out before any operation that can imply an assignment to the
845 object $a (or $b) refers to, like C<$a++>.  You can override this
846 behavior by defining your own copy constructor (see L<"Copy Constructor">).
847
848 It is expected that arguments to methods that are not explicitly supposed
849 to be changed are constant (but this is not enforced).
850
851 =head1 Metaphor clash
852
853 One may wonder why the semantic of overloaded C<=> is so counter intuitive.
854 If it I<looks> counter intuitive to you, you are subject to a metaphor
855 clash.
856
857 Here is a Perl object metaphor:
858
859 I<  object is a reference to blessed data>
860
861 and an arithmetic metaphor:
862
863 I<  object is a thing by itself>.
864
865 The I<main> problem of overloading C<=> is the fact that these metaphors
866 imply different actions on the assignment C<$a = $b> if $a and $b are
867 objects.  Perl-think implies that $a becomes a reference to whatever
868 $b was referencing.  Arithmetic-think implies that the value of "object"
869 $a is changed to become the value of the object $b, preserving the fact
870 that $a and $b are separate entities.
871
872 The difference is not relevant in the absence of mutators.  After
873 a Perl-way assignment an operation which mutates the data referenced by $a
874 would change the data referenced by $b too.  Effectively, after
875 C<$a = $b> values of $a and $b become I<indistinguishable>.
876
877 On the other hand, anyone who has used algebraic notation knows the
878 expressive power of the arithmetic metaphor.  Overloading works hard
879 to enable this metaphor while preserving the Perlian way as far as
880 possible.  Since it is not possible to freely mix two contradicting
881 metaphors, overloading allows the arithmetic way to write things I<as
882 far as all the mutators are called via overloaded access only>.  The
883 way it is done is described in L<Copy Constructor>.
884
885 If some mutator methods are directly applied to the overloaded values,
886 one may need to I<explicitly unlink> other values which references the
887 same value:
888
889     $a = new Data 23;
890     ...
891     $b = $a;            # $b is "linked" to $a
892     ...
893     $a = $a->clone;     # Unlink $b from $a
894     $a->increment_by(4);
895
896 Note that overloaded access makes this transparent:
897
898     $a = new Data 23;
899     $b = $a;            # $b is "linked" to $a
900     $a += 4;            # would unlink $b automagically
901
902 However, it would not make
903
904     $a = new Data 23;
905     $a = 4;             # Now $a is a plain 4, not 'Data'
906
907 preserve "objectness" of $a.  But Perl I<has> a way to make assignments
908 to an object do whatever you want.  It is just not the overload, but
909 tie()ing interface (see L<perlfunc/tie>).  Adding a FETCH() method
910 which returns the object itself, and STORE() method which changes the
911 value of the object, one can reproduce the arithmetic metaphor in its
912 completeness, at least for variables which were tie()d from the start.
913
914 (Note that a workaround for a bug may be needed, see L<"BUGS">.)
915
916 =head1 Cookbook
917
918 Please add examples to what follows!
919
920 =head2 Two-face scalars
921
922 Put this in F<two_face.pm> in your Perl library directory:
923
924   package two_face;             # Scalars with separate string and
925                                 # numeric values.
926   sub new { my $p = shift; bless [@_], $p }
927   use overload '""' => \&str, '0+' => \&num, fallback => 1;
928   sub num {shift->[1]}
929   sub str {shift->[0]}
930
931 Use it as follows:
932
933   require two_face;
934   my $seven = new two_face ("vii", 7);
935   printf "seven=$seven, seven=%d, eight=%d\n", $seven, $seven+1;
936   print "seven contains `i'\n" if $seven =~ /i/;
937
938 (The second line creates a scalar which has both a string value, and a
939 numeric value.)  This prints:
940
941   seven=vii, seven=7, eight=8
942   seven contains `i'
943
944 =head2 Two-face references
945
946 Suppose you want to create an object which is accessible as both an
947 array reference and a hash reference.
948
949   package two_refs;
950   use overload '%{}' => \&gethash, '@{}' => sub { $ {shift()} };
951   sub new {
952     my $p = shift;
953     bless \ [@_], $p;
954   }
955   sub gethash {
956     my %h;
957     my $self = shift;
958     tie %h, ref $self, $self;
959     \%h;
960   }
961
962   sub TIEHASH { my $p = shift; bless \ shift, $p }
963   my %fields;
964   my $i = 0;
965   $fields{$_} = $i++ foreach qw{zero one two three};
966   sub STORE {
967     my $self = ${shift()};
968     my $key = $fields{shift()};
969     defined $key or die "Out of band access";
970     $$self->[$key] = shift;
971   }
972   sub FETCH {
973     my $self = ${shift()};
974     my $key = $fields{shift()};
975     defined $key or die "Out of band access";
976     $$self->[$key];
977   }
978
979 Now one can access an object using both the array and hash syntax:
980
981   my $bar = new two_refs 3,4,5,6;
982   $bar->[2] = 11;
983   $bar->{two} == 11 or die 'bad hash fetch';
984
985 Note several important features of this example.  First of all, the
986 I<actual> type of $bar is a scalar reference, and we do not overload
987 the scalar dereference.  Thus we can get the I<actual> non-overloaded
988 contents of $bar by just using C<$$bar> (what we do in functions which
989 overload dereference).  Similarly, the object returned by the
990 TIEHASH() method is a scalar reference.
991
992 Second, we create a new tied hash each time the hash syntax is used.
993 This allows us not to worry about a possibility of a reference loop,
994 which would lead to a memory leak.
995
996 Both these problems can be cured.  Say, if we want to overload hash
997 dereference on a reference to an object which is I<implemented> as a
998 hash itself, the only problem one has to circumvent is how to access
999 this I<actual> hash (as opposed to the I<virtual> hash exhibited by the
1000 overloaded dereference operator).  Here is one possible fetching routine:
1001
1002   sub access_hash {
1003     my ($self, $key) = (shift, shift);
1004     my $class = ref $self;
1005     bless $self, 'overload::dummy'; # Disable overloading of %{}
1006     my $out = $self->{$key};
1007     bless $self, $class;        # Restore overloading
1008     $out;
1009   }
1010
1011 To remove creation of the tied hash on each access, one may an extra
1012 level of indirection which allows a non-circular structure of references:
1013
1014   package two_refs1;
1015   use overload '%{}' => sub { ${shift()}->[1] },
1016                '@{}' => sub { ${shift()}->[0] };
1017   sub new {
1018     my $p = shift;
1019     my $a = [@_];
1020     my %h;
1021     tie %h, $p, $a;
1022     bless \ [$a, \%h], $p;
1023   }
1024   sub gethash {
1025     my %h;
1026     my $self = shift;
1027     tie %h, ref $self, $self;
1028     \%h;
1029   }
1030
1031   sub TIEHASH { my $p = shift; bless \ shift, $p }
1032   my %fields;
1033   my $i = 0;
1034   $fields{$_} = $i++ foreach qw{zero one two three};
1035   sub STORE {
1036     my $a = ${shift()};
1037     my $key = $fields{shift()};
1038     defined $key or die "Out of band access";
1039     $a->[$key] = shift;
1040   }
1041   sub FETCH {
1042     my $a = ${shift()};
1043     my $key = $fields{shift()};
1044     defined $key or die "Out of band access";
1045     $a->[$key];
1046   }
1047
1048 Now if $baz is overloaded like this, then C<$baz> is a reference to a
1049 reference to the intermediate array, which keeps a reference to an
1050 actual array, and the access hash.  The tie()ing object for the access
1051 hash is a reference to a reference to the actual array, so
1052
1053 =over
1054
1055 =item *
1056
1057 There are no loops of references.
1058
1059 =item *
1060
1061 Both "objects" which are blessed into the class C<two_refs1> are
1062 references to a reference to an array, thus references to a I<scalar>.
1063 Thus the accessor expression C<$$foo-E<gt>[$ind]> involves no
1064 overloaded operations.
1065
1066 =back
1067
1068 =head2 Symbolic calculator
1069
1070 Put this in F<symbolic.pm> in your Perl library directory:
1071
1072   package symbolic;             # Primitive symbolic calculator
1073   use overload nomethod => \&wrap;
1074
1075   sub new { shift; bless ['n', @_] }
1076   sub wrap {
1077     my ($obj, $other, $inv, $meth) = @_;
1078     ($obj, $other) = ($other, $obj) if $inv;
1079     bless [$meth, $obj, $other];
1080   }
1081
1082 This module is very unusual as overloaded modules go: it does not
1083 provide any usual overloaded operators, instead it provides the L<Last
1084 Resort> operator C<nomethod>.  In this example the corresponding
1085 subroutine returns an object which encapsulates operations done over
1086 the objects: C<new symbolic 3> contains C<['n', 3]>, C<2 + new
1087 symbolic 3> contains C<['+', 2, ['n', 3]]>.
1088
1089 Here is an example of the script which "calculates" the side of
1090 circumscribed octagon using the above package:
1091
1092   require symbolic;
1093   my $iter = 1;                 # 2**($iter+2) = 8
1094   my $side = new symbolic 1;
1095   my $cnt = $iter;
1096
1097   while ($cnt--) {
1098     $side = (sqrt(1 + $side**2) - 1)/$side;
1099   }
1100   print "OK\n";
1101
1102 The value of $side is
1103
1104   ['/', ['-', ['sqrt', ['+', 1, ['**', ['n', 1], 2]],
1105                        undef], 1], ['n', 1]]
1106
1107 Note that while we obtained this value using a nice little script,
1108 there is no simple way to I<use> this value.  In fact this value may
1109 be inspected in debugger (see L<perldebug>), but ony if
1110 C<bareStringify> B<O>ption is set, and not via C<p> command.
1111
1112 If one attempts to print this value, then the overloaded operator
1113 C<""> will be called, which will call C<nomethod> operator.  The
1114 result of this operator will be stringified again, but this result is
1115 again of type C<symbolic>, which will lead to an infinite loop.
1116
1117 Add a pretty-printer method to the module F<symbolic.pm>:
1118
1119   sub pretty {
1120     my ($meth, $a, $b) = @{+shift};
1121     $a = 'u' unless defined $a;
1122     $b = 'u' unless defined $b;
1123     $a = $a->pretty if ref $a;
1124     $b = $b->pretty if ref $b;
1125     "[$meth $a $b]";
1126   }
1127
1128 Now one can finish the script by
1129
1130   print "side = ", $side->pretty, "\n";
1131
1132 The method C<pretty> is doing object-to-string conversion, so it
1133 is natural to overload the operator C<""> using this method.  However,
1134 inside such a method it is not necessary to pretty-print the
1135 I<components> $a and $b of an object.  In the above subroutine
1136 C<"[$meth $a $b]"> is a catenation of some strings and components $a
1137 and $b.  If these components use overloading, the catenation operator
1138 will look for an overloaded operator C<.>; if not present, it will
1139 look for an overloaded operator C<"">.  Thus it is enough to use
1140
1141   use overload nomethod => \&wrap, '""' => \&str;
1142   sub str {
1143     my ($meth, $a, $b) = @{+shift};
1144     $a = 'u' unless defined $a;
1145     $b = 'u' unless defined $b;
1146     "[$meth $a $b]";
1147   }
1148
1149 Now one can change the last line of the script to
1150
1151   print "side = $side\n";
1152
1153 which outputs
1154
1155   side = [/ [- [sqrt [+ 1 [** [n 1 u] 2]] u] 1] [n 1 u]]
1156
1157 and one can inspect the value in debugger using all the possible
1158 methods.
1159
1160 Something is still amiss: consider the loop variable $cnt of the
1161 script.  It was a number, not an object.  We cannot make this value of
1162 type C<symbolic>, since then the loop will not terminate.
1163
1164 Indeed, to terminate the cycle, the $cnt should become false.
1165 However, the operator C<bool> for checking falsity is overloaded (this
1166 time via overloaded C<"">), and returns a long string, thus any object
1167 of type C<symbolic> is true.  To overcome this, we need a way to
1168 compare an object to 0.  In fact, it is easier to write a numeric
1169 conversion routine.
1170
1171 Here is the text of F<symbolic.pm> with such a routine added (and
1172 slightly modified str()):
1173
1174   package symbolic;             # Primitive symbolic calculator
1175   use overload
1176     nomethod => \&wrap, '""' => \&str, '0+' => \&num;
1177
1178   sub new { shift; bless ['n', @_] }
1179   sub wrap {
1180     my ($obj, $other, $inv, $meth) = @_;
1181     ($obj, $other) = ($other, $obj) if $inv;
1182     bless [$meth, $obj, $other];
1183   }
1184   sub str {
1185     my ($meth, $a, $b) = @{+shift};
1186     $a = 'u' unless defined $a;
1187     if (defined $b) {
1188       "[$meth $a $b]";
1189     } else {
1190       "[$meth $a]";
1191     }
1192   }
1193   my %subr = ( n => sub {$_[0]},
1194                sqrt => sub {sqrt $_[0]},
1195                '-' => sub {shift() - shift()},
1196                '+' => sub {shift() + shift()},
1197                '/' => sub {shift() / shift()},
1198                '*' => sub {shift() * shift()},
1199                '**' => sub {shift() ** shift()},
1200              );
1201   sub num {
1202     my ($meth, $a, $b) = @{+shift};
1203     my $subr = $subr{$meth}
1204       or die "Do not know how to ($meth) in symbolic";
1205     $a = $a->num if ref $a eq __PACKAGE__;
1206     $b = $b->num if ref $b eq __PACKAGE__;
1207     $subr->($a,$b);
1208   }
1209
1210 All the work of numeric conversion is done in %subr and num().  Of
1211 course, %subr is not complete, it contains only operators used in the
1212 example below.  Here is the extra-credit question: why do we need an
1213 explicit recursion in num()?  (Answer is at the end of this section.)
1214
1215 Use this module like this:
1216
1217   require symbolic;
1218   my $iter = new symbolic 2;    # 16-gon
1219   my $side = new symbolic 1;
1220   my $cnt = $iter;
1221
1222   while ($cnt) {
1223     $cnt = $cnt - 1;            # Mutator `--' not implemented
1224     $side = (sqrt(1 + $side**2) - 1)/$side;
1225   }
1226   printf "%s=%f\n", $side, $side;
1227   printf "pi=%f\n", $side*(2**($iter+2));
1228
1229 It prints (without so many line breaks)
1230
1231   [/ [- [sqrt [+ 1 [** [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1]
1232                           [n 1]] 2]]] 1]
1233      [/ [- [sqrt [+ 1 [** [n 1] 2]]] 1] [n 1]]]=0.198912
1234   pi=3.182598
1235
1236 The above module is very primitive.  It does not implement
1237 mutator methods (C<++>, C<-=> and so on), does not do deep copying
1238 (not required without mutators!), and implements only those arithmetic
1239 operations which are used in the example.
1240
1241 To implement most arithmetic operations is easy; one should just use
1242 the tables of operations, and change the code which fills %subr to
1243
1244   my %subr = ( 'n' => sub {$_[0]} );
1245   foreach my $op (split " ", $overload::ops{with_assign}) {
1246     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1247   }
1248   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1249   foreach my $op (split " ", "@overload::ops{ @bins }") {
1250     $subr{$op} = eval "sub {shift() $op shift()}";
1251   }
1252   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1253     print "defining `$op'\n";
1254     $subr{$op} = eval "sub {$op shift()}";
1255   }
1256
1257 Due to L<Calling Conventions for Mutators>, we do not need anything
1258 special to make C<+=> and friends work, except filling C<+=> entry of
1259 %subr, and defining a copy constructor (needed since Perl has no
1260 way to know that the implementation of C<'+='> does not mutate
1261 the argument, compare L<Copy Constructor>).
1262
1263 To implement a copy constructor, add C<< '=' => \&cpy >> to C<use overload>
1264 line, and code (this code assumes that mutators change things one level
1265 deep only, so recursive copying is not needed):
1266
1267   sub cpy {
1268     my $self = shift;
1269     bless [@$self], ref $self;
1270   }
1271
1272 To make C<++> and C<--> work, we need to implement actual mutators,
1273 either directly, or in C<nomethod>.  We continue to do things inside
1274 C<nomethod>, thus add
1275
1276     if ($meth eq '++' or $meth eq '--') {
1277       @$obj = ($meth, (bless [@$obj]), 1); # Avoid circular reference
1278       return $obj;
1279     }
1280
1281 after the first line of wrap().  This is not a most effective
1282 implementation, one may consider
1283
1284   sub inc { $_[0] = bless ['++', shift, 1]; }
1285
1286 instead.
1287
1288 As a final remark, note that one can fill %subr by
1289
1290   my %subr = ( 'n' => sub {$_[0]} );
1291   foreach my $op (split " ", $overload::ops{with_assign}) {
1292     $subr{$op} = $subr{"$op="} = eval "sub {shift() $op shift()}";
1293   }
1294   my @bins = qw(binary 3way_comparison num_comparison str_comparison);
1295   foreach my $op (split " ", "@overload::ops{ @bins }") {
1296     $subr{$op} = eval "sub {shift() $op shift()}";
1297   }
1298   foreach my $op (split " ", "@overload::ops{qw(unary func)}") {
1299     $subr{$op} = eval "sub {$op shift()}";
1300   }
1301   $subr{'++'} = $subr{'+'};
1302   $subr{'--'} = $subr{'-'};
1303
1304 This finishes implementation of a primitive symbolic calculator in
1305 50 lines of Perl code.  Since the numeric values of subexpressions
1306 are not cached, the calculator is very slow.
1307
1308 Here is the answer for the exercise: In the case of str(), we need no
1309 explicit recursion since the overloaded C<.>-operator will fall back
1310 to an existing overloaded operator C<"">.  Overloaded arithmetic
1311 operators I<do not> fall back to numeric conversion if C<fallback> is
1312 not explicitly requested.  Thus without an explicit recursion num()
1313 would convert C<['+', $a, $b]> to C<$a + $b>, which would just rebuild
1314 the argument of num().
1315
1316 If you wonder why defaults for conversion are different for str() and
1317 num(), note how easy it was to write the symbolic calculator.  This
1318 simplicity is due to an appropriate choice of defaults.  One extra
1319 note: due to the explicit recursion num() is more fragile than sym():
1320 we need to explicitly check for the type of $a and $b.  If components
1321 $a and $b happen to be of some related type, this may lead to problems.
1322
1323 =head2 I<Really> symbolic calculator
1324
1325 One may wonder why we call the above calculator symbolic.  The reason
1326 is that the actual calculation of the value of expression is postponed
1327 until the value is I<used>.
1328
1329 To see it in action, add a method
1330
1331   sub STORE {
1332     my $obj = shift;
1333     $#$obj = 1;
1334     @$obj->[0,1] = ('=', shift);
1335   }
1336
1337 to the package C<symbolic>.  After this change one can do
1338
1339   my $a = new symbolic 3;
1340   my $b = new symbolic 4;
1341   my $c = sqrt($a**2 + $b**2);
1342
1343 and the numeric value of $c becomes 5.  However, after calling
1344
1345   $a->STORE(12);  $b->STORE(5);
1346
1347 the numeric value of $c becomes 13.  There is no doubt now that the module
1348 symbolic provides a I<symbolic> calculator indeed.
1349
1350 To hide the rough edges under the hood, provide a tie()d interface to the
1351 package C<symbolic> (compare with L<Metaphor clash>).  Add methods
1352
1353   sub TIESCALAR { my $pack = shift; $pack->new(@_) }
1354   sub FETCH { shift }
1355   sub nop {  }          # Around a bug
1356
1357 (the bug is described in L<"BUGS">).  One can use this new interface as
1358
1359   tie $a, 'symbolic', 3;
1360   tie $b, 'symbolic', 4;
1361   $a->nop;  $b->nop;    # Around a bug
1362
1363   my $c = sqrt($a**2 + $b**2);
1364
1365 Now numeric value of $c is 5.  After C<$a = 12; $b = 5> the numeric value
1366 of $c becomes 13.  To insulate the user of the module add a method
1367
1368   sub vars { my $p = shift; tie($_, $p), $_->nop foreach @_; }
1369
1370 Now
1371
1372   my ($a, $b);
1373   symbolic->vars($a, $b);
1374   my $c = sqrt($a**2 + $b**2);
1375
1376   $a = 3; $b = 4;
1377   printf "c5  %s=%f\n", $c, $c;
1378
1379   $a = 12; $b = 5;
1380   printf "c13  %s=%f\n", $c, $c;
1381
1382 shows that the numeric value of $c follows changes to the values of $a
1383 and $b.
1384
1385 =head1 AUTHOR
1386
1387 Ilya Zakharevich E<lt>F<ilya@math.mps.ohio-state.edu>E<gt>.
1388
1389 =head1 DIAGNOSTICS
1390
1391 When Perl is run with the B<-Do> switch or its equivalent, overloading
1392 induces diagnostic messages.
1393
1394 Using the C<m> command of Perl debugger (see L<perldebug>) one can
1395 deduce which operations are overloaded (and which ancestor triggers
1396 this overloading). Say, if C<eq> is overloaded, then the method C<(eq>
1397 is shown by debugger. The method C<()> corresponds to the C<fallback>
1398 key (in fact a presence of this method shows that this package has
1399 overloading enabled, and it is what is used by the C<Overloaded>
1400 function of module C<overload>).
1401
1402 The module might issue the following warnings:
1403
1404 =over 4
1405
1406 =item Odd number of arguments for overload::constant
1407
1408 (W) The call to overload::constant contained an odd number of arguments.
1409 The arguments should come in pairs.
1410
1411 =item `%s' is not an overloadable type
1412
1413 (W) You tried to overload a constant type the overload package is unaware of.
1414
1415 =item `%s' is not a code reference
1416
1417 (W) The second (fourth, sixth, ...) argument of overload::constant needs
1418 to be a code reference. Either an anonymous subroutine, or a reference
1419 to a subroutine.
1420
1421 =back
1422
1423 =head1 BUGS
1424
1425 Because it is used for overloading, the per-package hash %OVERLOAD now
1426 has a special meaning in Perl. The symbol table is filled with names
1427 looking like line-noise.
1428
1429 For the purpose of inheritance every overloaded package behaves as if
1430 C<fallback> is present (possibly undefined). This may create
1431 interesting effects if some package is not overloaded, but inherits
1432 from two overloaded packages.
1433
1434 Relation between overloading and tie()ing is broken.  Overloading is
1435 triggered or not basing on the I<previous> class of tie()d value.
1436
1437 This happens because the presence of overloading is checked too early,
1438 before any tie()d access is attempted.  If the FETCH()ed class of the
1439 tie()d value does not change, a simple workaround is to access the value
1440 immediately after tie()ing, so that after this call the I<previous> class
1441 coincides with the current one.
1442
1443 B<Needed:> a way to fix this without a speed penalty.
1444
1445 Barewords are not covered by overloaded string constants.
1446
1447 This document is confusing.  There are grammos and misleading language
1448 used in places.  It would seem a total rewrite is needed.
1449
1450 =cut
1451