*glob{FILEHANDLE} is no longer deprecated
[perl.git] / pod / perlref.pod
1 =head1 NAME
2 X<reference> X<pointer> X<data structure> X<structure> X<struct>
3
4 perlref - Perl references and nested data structures
5
6 =head1 NOTE
7
8 This is complete documentation about all aspects of references.
9 For a shorter, tutorial introduction to just the essential features,
10 see L<perlreftut>.
11
12 =head1 DESCRIPTION
13
14 Before release 5 of Perl it was difficult to represent complex data
15 structures, because all references had to be symbolic--and even then
16 it was difficult to refer to a variable instead of a symbol table entry.
17 Perl now not only makes it easier to use symbolic references to variables,
18 but also lets you have "hard" references to any piece of data or code.
19 Any scalar may hold a hard reference.  Because arrays and hashes contain
20 scalars, you can now easily build arrays of arrays, arrays of hashes,
21 hashes of arrays, arrays of hashes of functions, and so on.
22
23 Hard references are smart--they keep track of reference counts for you,
24 automatically freeing the thing referred to when its reference count goes
25 to zero.  (Reference counts for values in self-referential or
26 cyclic data structures may not go to zero without a little help; see
27 L</"Circular References"> for a detailed explanation.)
28 If that thing happens to be an object, the object is destructed.  See
29 L<perlobj> for more about objects.  (In a sense, everything in Perl is an
30 object, but we usually reserve the word for references to objects that
31 have been officially "blessed" into a class package.)
32
33 Symbolic references are names of variables or other objects, just as a
34 symbolic link in a Unix filesystem contains merely the name of a file.
35 The C<*glob> notation is something of a symbolic reference.  (Symbolic
36 references are sometimes called "soft references", but please don't call
37 them that; references are confusing enough without useless synonyms.)
38 X<reference, symbolic> X<reference, soft>
39 X<symbolic reference> X<soft reference>
40
41 In contrast, hard references are more like hard links in a Unix file
42 system: They are used to access an underlying object without concern for
43 what its (other) name is.  When the word "reference" is used without an
44 adjective, as in the following paragraph, it is usually talking about a
45 hard reference.
46 X<reference, hard> X<hard reference>
47
48 References are easy to use in Perl.  There is just one overriding
49 principle: in general, Perl does no implicit referencing or dereferencing.
50 When a scalar is holding a reference, it always behaves as a simple scalar.
51 It doesn't magically start being an array or hash or subroutine; you have to
52 tell it explicitly to do so, by dereferencing it.
53
54 That said, be aware that Perl version 5.14 introduces an exception
55 to the rule, for syntactic convenience.  Experimental array and hash container
56 function behavior allows array and hash references to be handled by Perl as
57 if they had been explicitly syntactically dereferenced.  See
58 L<perl5140delta/"Syntactical Enhancements">
59 and L<perlfunc> for details.
60
61 =head2 Making References
62 X<reference, creation> X<referencing>
63
64 References can be created in several ways.
65
66 =over 4
67
68 =item 1.
69 X<\> X<backslash>
70
71 By using the backslash operator on a variable, subroutine, or value.
72 (This works much like the & (address-of) operator in C.)
73 This typically creates I<another> reference to a variable, because
74 there's already a reference to the variable in the symbol table.  But
75 the symbol table reference might go away, and you'll still have the
76 reference that the backslash returned.  Here are some examples:
77
78     $scalarref = \$foo;
79     $arrayref  = \@ARGV;
80     $hashref   = \%ENV;
81     $coderef   = \&handler;
82     $globref   = \*foo;
83
84 It isn't possible to create a true reference to an IO handle (filehandle
85 or dirhandle) using the backslash operator.  The most you can get is a
86 reference to a typeglob, which is actually a complete symbol table entry.
87 But see the explanation of the C<*foo{THING}> syntax below.  However,
88 you can still use type globs and globrefs as though they were IO handles.
89
90 =item 2.
91 X<array, anonymous> X<[> X<[]> X<square bracket>
92 X<bracket, square> X<arrayref> X<array reference> X<reference, array>
93
94 A reference to an anonymous array can be created using square
95 brackets:
96
97     $arrayref = [1, 2, ['a', 'b', 'c']];
98
99 Here we've created a reference to an anonymous array of three elements
100 whose final element is itself a reference to another anonymous array of three
101 elements.  (The multidimensional syntax described later can be used to
102 access this.  For example, after the above, C<< $arrayref->[2][1] >> would have
103 the value "b".)
104
105 Taking a reference to an enumerated list is not the same
106 as using square brackets--instead it's the same as creating
107 a list of references!
108
109     @list = (\$a, \@b, \%c);
110     @list = \($a, @b, %c);      # same thing!
111
112 As a special case, C<\(@foo)> returns a list of references to the contents
113 of C<@foo>, not a reference to C<@foo> itself.  Likewise for C<%foo>,
114 except that the key references are to copies (since the keys are just
115 strings rather than full-fledged scalars).
116
117 =item 3.
118 X<hash, anonymous> X<{> X<{}> X<curly bracket>
119 X<bracket, curly> X<brace> X<hashref> X<hash reference> X<reference, hash>
120
121 A reference to an anonymous hash can be created using curly
122 brackets:
123
124     $hashref = {
125         'Adam'  => 'Eve',
126         'Clyde' => 'Bonnie',
127     };
128
129 Anonymous hash and array composers like these can be intermixed freely to
130 produce as complicated a structure as you want.  The multidimensional
131 syntax described below works for these too.  The values above are
132 literals, but variables and expressions would work just as well, because
133 assignment operators in Perl (even within local() or my()) are executable
134 statements, not compile-time declarations.
135
136 Because curly brackets (braces) are used for several other things
137 including BLOCKs, you may occasionally have to disambiguate braces at the
138 beginning of a statement by putting a C<+> or a C<return> in front so
139 that Perl realizes the opening brace isn't starting a BLOCK.  The economy and
140 mnemonic value of using curlies is deemed worth this occasional extra
141 hassle.
142
143 For example, if you wanted a function to make a new hash and return a
144 reference to it, you have these options:
145
146     sub hashem {        { @_ } }   # silently wrong
147     sub hashem {       +{ @_ } }   # ok
148     sub hashem { return { @_ } }   # ok
149
150 On the other hand, if you want the other meaning, you can do this:
151
152     sub showem {        { @_ } }   # ambiguous (currently ok,
153                                    # but may change)
154     sub showem {       {; @_ } }   # ok
155     sub showem { { return @_ } }   # ok
156
157 The leading C<+{> and C<{;> always serve to disambiguate
158 the expression to mean either the HASH reference, or the BLOCK.
159
160 =item 4.
161 X<subroutine, anonymous> X<subroutine, reference> X<reference, subroutine>
162 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
163
164 A reference to an anonymous subroutine can be created by using
165 C<sub> without a subname:
166
167     $coderef = sub { print "Boink!\n" };
168
169 Note the semicolon.  Except for the code
170 inside not being immediately executed, a C<sub {}> is not so much a
171 declaration as it is an operator, like C<do{}> or C<eval{}>.  (However, no
172 matter how many times you execute that particular line (unless you're in an
173 C<eval("...")>), $coderef will still have a reference to the I<same>
174 anonymous subroutine.)
175
176 Anonymous subroutines act as closures with respect to my() variables,
177 that is, variables lexically visible within the current scope.  Closure
178 is a notion out of the Lisp world that says if you define an anonymous
179 function in a particular lexical context, it pretends to run in that
180 context even when it's called outside the context.
181
182 In human terms, it's a funny way of passing arguments to a subroutine when
183 you define it as well as when you call it.  It's useful for setting up
184 little bits of code to run later, such as callbacks.  You can even
185 do object-oriented stuff with it, though Perl already provides a different
186 mechanism to do that--see L<perlobj>.
187
188 You might also think of closure as a way to write a subroutine
189 template without using eval().  Here's a small example of how
190 closures work:
191
192     sub newprint {
193         my $x = shift;
194         return sub { my $y = shift; print "$x, $y!\n"; };
195     }
196     $h = newprint("Howdy");
197     $g = newprint("Greetings");
198
199     # Time passes...
200
201     &$h("world");
202     &$g("earthlings");
203
204 This prints
205
206     Howdy, world!
207     Greetings, earthlings!
208
209 Note particularly that $x continues to refer to the value passed
210 into newprint() I<despite> "my $x" having gone out of scope by the
211 time the anonymous subroutine runs.  That's what a closure is all
212 about.
213
214 This applies only to lexical variables, by the way.  Dynamic variables
215 continue to work as they have always worked.  Closure is not something
216 that most Perl programmers need trouble themselves about to begin with.
217
218 =item 5.
219 X<constructor> X<new>
220
221 References are often returned by special subroutines called constructors.  Perl
222 objects are just references to a special type of object that happens to know
223 which package it's associated with.  Constructors are just special subroutines
224 that know how to create that association.  They do so by starting with an
225 ordinary reference, and it remains an ordinary reference even while it's also
226 being an object.  Constructors are often named C<new()>.  You I<can> call them
227 indirectly:
228
229     $objref = new Doggie( Tail => 'short', Ears => 'long' );
230
231 But that can produce ambiguous syntax in certain cases, so it's often
232 better to use the direct method invocation approach:
233
234     $objref   = Doggie->new(Tail => 'short', Ears => 'long');
235
236     use Term::Cap;
237     $terminal = Term::Cap->Tgetent( { OSPEED => 9600 });
238
239     use Tk;
240     $main    = MainWindow->new();
241     $menubar = $main->Frame(-relief              => "raised",
242                             -borderwidth         => 2)
243
244 =item 6.
245 X<autovivification>
246
247 References of the appropriate type can spring into existence if you
248 dereference them in a context that assumes they exist.  Because we haven't
249 talked about dereferencing yet, we can't show you any examples yet.
250
251 =item 7.
252 X<*foo{THING}> X<*>
253
254 A reference can be created by using a special syntax, lovingly known as
255 the *foo{THING} syntax.  *foo{THING} returns a reference to the THING
256 slot in *foo (which is the symbol table entry which holds everything
257 known as foo).
258
259     $scalarref = *foo{SCALAR};
260     $arrayref  = *ARGV{ARRAY};
261     $hashref   = *ENV{HASH};
262     $coderef   = *handler{CODE};
263     $ioref     = *STDIN{IO};
264     $globref   = *foo{GLOB};
265     $formatref = *foo{FORMAT};
266     $globname  = *foo{NAME};    # "foo"
267     $pkgname   = *foo{PACKAGE}; # "main"
268
269 Most of these are self-explanatory, but C<*foo{IO}>
270 deserves special attention.  It returns
271 the IO handle, used for file handles (L<perlfunc/open>), sockets
272 (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory
273 handles (L<perlfunc/opendir>).  For compatibility with previous
274 versions of Perl, C<*foo{FILEHANDLE}> is a synonym for C<*foo{IO}>, though it
275 is discouraged, to encourage a consistent use of one name: IO.  On perls
276 between v5.8 and v5.22, it will issue a deprecation warning, but this
277 deprecation has since been rescinded.
278
279 C<*foo{THING}> returns undef if that particular THING hasn't been used yet,
280 except in the case of scalars.  C<*foo{SCALAR}> returns a reference to an
281 anonymous scalar if $foo hasn't been used yet.  This might change in a
282 future release.
283
284 C<*foo{NAME}> and C<*foo{PACKAGE}> are the exception, in that they return
285 strings, rather than references.  These return the package and name of the
286 typeglob itself, rather than one that has been assigned to it.  So, after
287 C<*foo=*Foo::bar>, C<*foo> will become "*Foo::bar" when used as a string,
288 but C<*foo{PACKAGE}> and C<*foo{NAME}> will continue to produce "main" and
289 "foo", respectively.
290
291 C<*foo{IO}> is an alternative to the C<*HANDLE> mechanism given in
292 L<perldata/"Typeglobs and Filehandles"> for passing filehandles
293 into or out of subroutines, or storing into larger data structures.
294 Its disadvantage is that it won't create a new filehandle for you.
295 Its advantage is that you have less risk of clobbering more than
296 you want to with a typeglob assignment.  (It still conflates file
297 and directory handles, though.)  However, if you assign the incoming
298 value to a scalar instead of a typeglob as we do in the examples
299 below, there's no risk of that happening.
300
301     splutter(*STDOUT);          # pass the whole glob
302     splutter(*STDOUT{IO});      # pass both file and dir handles
303
304     sub splutter {
305         my $fh = shift;
306         print $fh "her um well a hmmm\n";
307     }
308
309     $rec = get_rec(*STDIN);     # pass the whole glob
310     $rec = get_rec(*STDIN{IO}); # pass both file and dir handles
311
312     sub get_rec {
313         my $fh = shift;
314         return scalar <$fh>;
315     }
316
317 =back
318
319 =head2 Using References
320 X<reference, use> X<dereferencing> X<dereference>
321
322 That's it for creating references.  By now you're probably dying to
323 know how to use references to get back to your long-lost data.  There
324 are several basic methods.
325
326 =over 4
327
328 =item 1.
329
330 Anywhere you'd put an identifier (or chain of identifiers) as part
331 of a variable or subroutine name, you can replace the identifier with
332 a simple scalar variable containing a reference of the correct type:
333
334     $bar = $$scalarref;
335     push(@$arrayref, $filename);
336     $$arrayref[0] = "January";
337     $$hashref{"KEY"} = "VALUE";
338     &$coderef(1,2,3);
339     print $globref "output\n";
340
341 It's important to understand that we are specifically I<not> dereferencing
342 C<$arrayref[0]> or C<$hashref{"KEY"}> there.  The dereference of the
343 scalar variable happens I<before> it does any key lookups.  Anything more
344 complicated than a simple scalar variable must use methods 2 or 3 below.
345 However, a "simple scalar" includes an identifier that itself uses method
346 1 recursively.  Therefore, the following prints "howdy".
347
348     $refrefref = \\\"howdy";
349     print $$$$refrefref;
350
351 =item 2.
352
353 Anywhere you'd put an identifier (or chain of identifiers) as part of a
354 variable or subroutine name, you can replace the identifier with a
355 BLOCK returning a reference of the correct type.  In other words, the
356 previous examples could be written like this:
357
358     $bar = ${$scalarref};
359     push(@{$arrayref}, $filename);
360     ${$arrayref}[0] = "January";
361     ${$hashref}{"KEY"} = "VALUE";
362     &{$coderef}(1,2,3);
363     $globref->print("output\n");  # iff IO::Handle is loaded
364
365 Admittedly, it's a little silly to use the curlies in this case, but
366 the BLOCK can contain any arbitrary expression, in particular,
367 subscripted expressions:
368
369     &{ $dispatch{$index} }(1,2,3);      # call correct routine
370
371 Because of being able to omit the curlies for the simple case of C<$$x>,
372 people often make the mistake of viewing the dereferencing symbols as
373 proper operators, and wonder about their precedence.  If they were,
374 though, you could use parentheses instead of braces.  That's not the case.
375 Consider the difference below; case 0 is a short-hand version of case 1,
376 I<not> case 2:
377
378     $$hashref{"KEY"}   = "VALUE";       # CASE 0
379     ${$hashref}{"KEY"} = "VALUE";       # CASE 1
380     ${$hashref{"KEY"}} = "VALUE";       # CASE 2
381     ${$hashref->{"KEY"}} = "VALUE";     # CASE 3
382
383 Case 2 is also deceptive in that you're accessing a variable
384 called %hashref, not dereferencing through $hashref to the hash
385 it's presumably referencing.  That would be case 3.
386
387 =item 3.
388
389 Subroutine calls and lookups of individual array elements arise often
390 enough that it gets cumbersome to use method 2.  As a form of
391 syntactic sugar, the examples for method 2 may be written:
392
393     $arrayref->[0] = "January";   # Array element
394     $hashref->{"KEY"} = "VALUE";  # Hash element
395     $coderef->(1,2,3);            # Subroutine call
396
397 The left side of the arrow can be any expression returning a reference,
398 including a previous dereference.  Note that C<$array[$x]> is I<not> the
399 same thing as C<< $array->[$x] >> here:
400
401     $array[$x]->{"foo"}->[0] = "January";
402
403 This is one of the cases we mentioned earlier in which references could
404 spring into existence when in an lvalue context.  Before this
405 statement, C<$array[$x]> may have been undefined.  If so, it's
406 automatically defined with a hash reference so that we can look up
407 C<{"foo"}> in it.  Likewise C<< $array[$x]->{"foo"} >> will automatically get
408 defined with an array reference so that we can look up C<[0]> in it.
409 This process is called I<autovivification>.
410
411 One more thing here.  The arrow is optional I<between> brackets
412 subscripts, so you can shrink the above down to
413
414     $array[$x]{"foo"}[0] = "January";
415
416 Which, in the degenerate case of using only ordinary arrays, gives you
417 multidimensional arrays just like C's:
418
419     $score[$x][$y][$z] += 42;
420
421 Well, okay, not entirely like C's arrays, actually.  C doesn't know how
422 to grow its arrays on demand.  Perl does.
423
424 =item 4.
425
426 If a reference happens to be a reference to an object, then there are
427 probably methods to access the things referred to, and you should probably
428 stick to those methods unless you're in the class package that defines the
429 object's methods.  In other words, be nice, and don't violate the object's
430 encapsulation without a very good reason.  Perl does not enforce
431 encapsulation.  We are not totalitarians here.  We do expect some basic
432 civility though.
433
434 =back
435
436 Using a string or number as a reference produces a symbolic reference,
437 as explained above.  Using a reference as a number produces an
438 integer representing its storage location in memory.  The only
439 useful thing to be done with this is to compare two references
440 numerically to see whether they refer to the same location.
441 X<reference, numeric context>
442
443     if ($ref1 == $ref2) {  # cheap numeric compare of references
444         print "refs 1 and 2 refer to the same thing\n";
445     }
446
447 Using a reference as a string produces both its referent's type,
448 including any package blessing as described in L<perlobj>, as well
449 as the numeric address expressed in hex.  The ref() operator returns
450 just the type of thing the reference is pointing to, without the
451 address.  See L<perlfunc/ref> for details and examples of its use.
452 X<reference, string context>
453
454 The bless() operator may be used to associate the object a reference
455 points to with a package functioning as an object class.  See L<perlobj>.
456
457 A typeglob may be dereferenced the same way a reference can, because
458 the dereference syntax always indicates the type of reference desired.
459 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
460
461 Here's a trick for interpolating a subroutine call into a string:
462
463     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
464
465 The way it works is that when the C<@{...}> is seen in the double-quoted
466 string, it's evaluated as a block.  The block creates a reference to an
467 anonymous array containing the results of the call to C<mysub(1,2,3)>.  So
468 the whole block returns a reference to an array, which is then
469 dereferenced by C<@{...}> and stuck into the double-quoted string. This
470 chicanery is also useful for arbitrary expressions:
471
472     print "That yields @{[$n + 5]} widgets\n";
473
474 Similarly, an expression that returns a reference to a scalar can be
475 dereferenced via C<${...}>. Thus, the above expression may be written
476 as:
477
478     print "That yields ${\($n + 5)} widgets\n";
479
480 =head2 Circular References
481 X<circular reference> X<reference, circular>
482
483 It is possible to create a "circular reference" in Perl, which can lead
484 to memory leaks. A circular reference occurs when two references
485 contain a reference to each other, like this:
486
487     my $foo = {};
488     my $bar = { foo => $foo };
489     $foo->{bar} = $bar;
490
491 You can also create a circular reference with a single variable:
492
493     my $foo;
494     $foo = \$foo;
495
496 In this case, the reference count for the variables will never reach 0,
497 and the references will never be garbage-collected. This can lead to
498 memory leaks.
499
500 Because objects in Perl are implemented as references, it's possible to
501 have circular references with objects as well. Imagine a TreeNode class
502 where each node references its parent and child nodes. Any node with a
503 parent will be part of a circular reference.
504
505 You can break circular references by creating a "weak reference". A
506 weak reference does not increment the reference count for a variable,
507 which means that the object can go out of scope and be destroyed. You
508 can weaken a reference with the C<weaken> function exported by the
509 L<Scalar::Util> module.
510
511 Here's how we can make the first example safer:
512
513     use Scalar::Util 'weaken';
514
515     my $foo = {};
516     my $bar = { foo => $foo };
517     $foo->{bar} = $bar;
518
519     weaken $foo->{bar};
520
521 The reference from C<$foo> to C<$bar> has been weakened. When the
522 C<$bar> variable goes out of scope, it will be garbage-collected. The
523 next time you look at the value of the C<< $foo->{bar} >> key, it will
524 be C<undef>.
525
526 This action at a distance can be confusing, so you should be careful
527 with your use of weaken. You should weaken the reference in the
528 variable that will go out of scope I<first>. That way, the longer-lived
529 variable will contain the expected reference until it goes out of
530 scope.
531
532 =head2 Symbolic references
533 X<reference, symbolic> X<reference, soft>
534 X<symbolic reference> X<soft reference>
535
536 We said that references spring into existence as necessary if they are
537 undefined, but we didn't say what happens if a value used as a
538 reference is already defined, but I<isn't> a hard reference.  If you
539 use it as a reference, it'll be treated as a symbolic
540 reference.  That is, the value of the scalar is taken to be the I<name>
541 of a variable, rather than a direct link to a (possibly) anonymous
542 value.
543
544 People frequently expect it to work like this.  So it does.
545
546     $name = "foo";
547     $$name = 1;                 # Sets $foo
548     ${$name} = 2;               # Sets $foo
549     ${$name x 2} = 3;           # Sets $foofoo
550     $name->[0] = 4;             # Sets $foo[0]
551     @$name = ();                # Clears @foo
552     &$name();                   # Calls &foo()
553     $pack = "THAT";
554     ${"${pack}::$name"} = 5;    # Sets $THAT::foo without eval
555
556 This is powerful, and slightly dangerous, in that it's possible
557 to intend (with the utmost sincerity) to use a hard reference, and
558 accidentally use a symbolic reference instead.  To protect against
559 that, you can say
560
561     use strict 'refs';
562
563 and then only hard references will be allowed for the rest of the enclosing
564 block.  An inner block may countermand that with
565
566     no strict 'refs';
567
568 Only package variables (globals, even if localized) are visible to
569 symbolic references.  Lexical variables (declared with my()) aren't in
570 a symbol table, and thus are invisible to this mechanism.  For example:
571
572     local $value = 10;
573     $ref = "value";
574     {
575         my $value = 20;
576         print $$ref;
577     }
578
579 This will still print 10, not 20.  Remember that local() affects package
580 variables, which are all "global" to the package.
581
582 =head2 Not-so-symbolic references
583
584 Brackets around a symbolic reference can simply
585 serve to isolate an identifier or variable name from the rest of an
586 expression, just as they always have within a string.  For example,
587
588     $push = "pop on ";
589     print "${push}over";
590
591 has always meant to print "pop on over", even though push is
592 a reserved word.  This is generalized to work the same
593 without the enclosing double quotes, so that
594
595     print ${push} . "over";
596
597 and even
598
599     print ${ push } . "over";
600
601 will have the same effect.  This
602 construct is I<not> considered to be a symbolic reference when you're
603 using strict refs:
604
605     use strict 'refs';
606     ${ bareword };      # Okay, means $bareword.
607     ${ "bareword" };    # Error, symbolic reference.
608
609 Similarly, because of all the subscripting that is done using single words,
610 the same rule applies to any bareword that is used for subscripting a hash.
611 So now, instead of writing
612
613     $array{ "aaa" }{ "bbb" }{ "ccc" }
614
615 you can write just
616
617     $array{ aaa }{ bbb }{ ccc }
618
619 and not worry about whether the subscripts are reserved words.  In the
620 rare event that you do wish to do something like
621
622     $array{ shift }
623
624 you can force interpretation as a reserved word by adding anything that
625 makes it more than a bareword:
626
627     $array{ shift() }
628     $array{ +shift }
629     $array{ shift @_ }
630
631 The C<use warnings> pragma or the B<-w> switch will warn you if it
632 interprets a reserved word as a string.
633 But it will no longer warn you about using lowercase words, because the
634 string is effectively quoted.
635
636 =head2 Pseudo-hashes: Using an array as a hash
637 X<pseudo-hash> X<pseudo hash> X<pseudohash>
638
639 Pseudo-hashes have been removed from Perl.  The 'fields' pragma
640 remains available.
641
642 =head2 Function Templates
643 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
644 X<subroutine, nested> X<sub, nested> X<subroutine, local> X<sub, local>
645
646 As explained above, an anonymous function with access to the lexical
647 variables visible when that function was compiled, creates a closure.  It
648 retains access to those variables even though it doesn't get run until
649 later, such as in a signal handler or a Tk callback.
650
651 Using a closure as a function template allows us to generate many functions
652 that act similarly.  Suppose you wanted functions named after the colors
653 that generated HTML font changes for the various colors:
654
655     print "Be ", red("careful"), "with that ", green("light");
656
657 The red() and green() functions would be similar.  To create these,
658 we'll assign a closure to a typeglob of the name of the function we're
659 trying to build.
660
661     @colors = qw(red blue green yellow orange purple violet);
662     for my $name (@colors) {
663         no strict 'refs';       # allow symbol table manipulation
664         *$name = *{uc $name} = sub { "<FONT COLOR='$name'>@_</FONT>" };
665     }
666
667 Now all those different functions appear to exist independently.  You can
668 call red(), RED(), blue(), BLUE(), green(), etc.  This technique saves on
669 both compile time and memory use, and is less error-prone as well, since
670 syntax checks happen at compile time.  It's critical that any variables in
671 the anonymous subroutine be lexicals in order to create a proper closure.
672 That's the reasons for the C<my> on the loop iteration variable.
673
674 This is one of the only places where giving a prototype to a closure makes
675 much sense.  If you wanted to impose scalar context on the arguments of
676 these functions (probably not a wise idea for this particular example),
677 you could have written it this way instead:
678
679     *$name = sub ($) { "<FONT COLOR='$name'>$_[0]</FONT>" };
680
681 However, since prototype checking happens at compile time, the assignment
682 above happens too late to be of much use.  You could address this by
683 putting the whole loop of assignments within a BEGIN block, forcing it
684 to occur during compilation.
685
686 Access to lexicals that change over time--like those in the C<for> loop
687 above, basically aliases to elements from the surrounding lexical scopes--
688 only works with anonymous subs, not with named subroutines. Generally
689 said, named subroutines do not nest properly and should only be declared
690 in the main package scope.
691
692 This is because named subroutines are created at compile time so their
693 lexical variables get assigned to the parent lexicals from the first
694 execution of the parent block. If a parent scope is entered a second
695 time, its lexicals are created again, while the nested subs still
696 reference the old ones.
697
698 Anonymous subroutines get to capture each time you execute the C<sub>
699 operator, as they are created on the fly. If you are accustomed to using
700 nested subroutines in other programming languages with their own private
701 variables, you'll have to work at it a bit in Perl.  The intuitive coding
702 of this type of thing incurs mysterious warnings about "will not stay
703 shared" due to the reasons explained above.
704 For example, this won't work:
705
706     sub outer {
707         my $x = $_[0] + 35;
708         sub inner { return $x * 19 }   # WRONG
709         return $x + inner();
710     }
711
712 A work-around is the following:
713
714     sub outer {
715         my $x = $_[0] + 35;
716         local *inner = sub { return $x * 19 };
717         return $x + inner();
718     }
719
720 Now inner() can only be called from within outer(), because of the
721 temporary assignments of the anonymous subroutine. But when it does,
722 it has normal access to the lexical variable $x from the scope of
723 outer() at the time outer is invoked.
724
725 This has the interesting effect of creating a function local to another
726 function, something not normally supported in Perl.
727
728 =head1 WARNING
729 X<reference, string context> X<reference, use as hash key>
730
731 You may not (usefully) use a reference as the key to a hash.  It will be
732 converted into a string:
733
734     $x{ \$a } = $a;
735
736 If you try to dereference the key, it won't do a hard dereference, and
737 you won't accomplish what you're attempting.  You might want to do something
738 more like
739
740     $r = \@a;
741     $x{ $r } = $r;
742
743 And then at least you can use the values(), which will be
744 real refs, instead of the keys(), which won't.
745
746 The standard Tie::RefHash module provides a convenient workaround to this.
747
748 =head1 Postfix Dereference Syntax
749
750 Beginning in v5.20.0, a postfix syntax for using references is
751 available.  It behaves as described in L</Using References>, but instead
752 of a prefixed sigil, a postfixed sigil-and-star is used.
753
754 For example:
755
756     $r = \@a;
757     @b = $r->@*; # equivalent to @$r or @{ $r }
758
759     $r = [ 1, [ 2, 3 ], 4 ];
760     $r->[1]->@*;  # equivalent to @{ $r->[1] }
761
762 In Perl 5.20 and 5.22, this syntax must be enabled with C<use feature
763 'postderef'>. As of Perl 5.24, no feature declarations are required to make
764 it available.
765
766 Postfix dereference should work in all circumstances where block
767 (circumfix) dereference worked, and should be entirely equivalent.  This
768 syntax allows dereferencing to be written and read entirely
769 left-to-right.  The following equivalencies are defined:
770
771   $sref->$*;  # same as  ${ $sref }
772   $aref->@*;  # same as  @{ $aref }
773   $aref->$#*; # same as $#{ $aref }
774   $href->%*;  # same as  %{ $href }
775   $cref->&*;  # same as  &{ $cref }
776   $gref->**;  # same as  *{ $gref }
777
778 Note especially that C<< $cref->&* >> is I<not> equivalent to C<<
779 $cref->() >>, and can serve different purposes.
780
781 Glob elements can be extracted through the postfix dereferencing feature:
782
783   $gref->*{SCALAR}; # same as *{ $gref }{SCALAR}
784
785 Postfix array and scalar dereferencing I<can> be used in interpolating
786 strings (double quotes or the C<qq> operator), but only if the
787 C<postderef_qq> feature is enabled.
788
789 =head2 Postfix Reference Slicing
790
791 Value slices of arrays and hashes may also be taken with postfix
792 dereferencing notation, with the following equivalencies:
793
794   $aref->@[ ... ];  # same as @$aref[ ... ]
795   $href->@{ ... };  # same as @$href{ ... }
796
797 Postfix key/value pair slicing, added in 5.20.0 and documented in
798 L<the KeyE<sol>Value Hash Slices section of perldata|perldata/"Key/Value Hash
799 Slices">, also behaves as expected:
800
801   $aref->%[ ... ];  # same as %$aref[ ... ]
802   $href->%{ ... };  # same as %$href{ ... }
803
804 As with postfix array, postfix value slice dereferencing I<can> be used
805 in interpolating strings (double quotes or the C<qq> operator), but only
806 if the C<postderef_qq> L<feature> is enabled.
807
808 =head1 Assigning to References
809
810 Beginning in v5.22.0, the referencing operator can be assigned to.  It
811 performs an aliasing operation, so that the variable name referenced on the
812 left-hand side becomes an alias for the thing referenced on the right-hand
813 side:
814
815     \$a = \$b; # $a and $b now point to the same scalar
816     \&foo = \&bar; # foo() now means bar()
817
818 This syntax must be enabled with C<use feature 'refaliasing'>.  It is
819 experimental, and will warn by default unless C<no warnings
820 'experimental::refaliasing'> is in effect.
821
822 These forms may be assigned to, and cause the right-hand side to be
823 evaluated in scalar context:
824
825     \$scalar
826     \@array
827     \%hash
828     \&sub
829     \my $scalar
830     \my @array
831     \my %hash
832     \state $scalar # or @array, etc.
833     \our $scalar   # etc.
834     \local $scalar # etc.
835     \local our $scalar # etc.
836     \$some_array[$index]
837     \$some_hash{$key}
838     \local $some_array[$index]
839     \local $some_hash{$key}
840     condition ? \$this : \$that[0] # etc.
841
842 Slicing operations and parentheses cause
843 the right-hand side to be evaluated in
844 list context:
845
846     \@array[5..7]
847     (\@array[5..7])
848     \(@array[5..7])
849     \@hash{'foo','bar'}
850     (\@hash{'foo','bar'})
851     \(@hash{'foo','bar'})
852     (\$scalar)
853     \($scalar)
854     \(my $scalar)
855     \my($scalar)
856     (\@array)
857     (\%hash)
858     (\&sub)
859     \(&sub)
860     \($foo, @bar, %baz)
861     (\$foo, \@bar, \%baz)
862
863 Each element on the right-hand side must be a reference to a datum of the
864 right type.  Parentheses immediately surrounding an array (and possibly
865 also C<my>/C<state>/C<our>/C<local>) will make each element of the array an
866 alias to the corresponding scalar referenced on the right-hand side:
867
868     \(@a) = \(@b); # @a and @b now have the same elements
869     \my(@a) = \(@b); # likewise
870     \(my @a) = \(@b); # likewise
871     push @a, 3; # but now @a has an extra element that @b lacks
872     \(@a) = (\$a, \$b, \$c); # @a now contains $a, $b, and $c
873
874 Combining that form with C<local> and putting parentheses immediately
875 around a hash are forbidden (because it is not clear what they should do):
876
877     \local(@array) = foo(); # WRONG
878     \(%hash)       = bar(); # wRONG
879
880 Assignment to references and non-references may be combined in lists and
881 conditional ternary expressions, as long as the values on the right-hand
882 side are the right type for each element on the left, though this may make
883 for obfuscated code:
884
885     (my $tom, \my $dick, \my @harry) = (\1, \2, [1..3]);
886     # $tom is now \1
887     # $dick is now 2 (read-only)
888     # @harry is (1,2,3)
889
890     my $type = ref $thingy;
891     ($type ? $type eq 'ARRAY' ? \@foo : \$bar : $baz) = $thingy;
892
893 The C<foreach> loop can also take a reference constructor for its loop
894 variable, though the syntax is limited to one of the following, with an
895 optional C<my>, C<state>, or C<our> after the backslash:
896
897     \$s
898     \@a
899     \%h
900     \&c
901
902 No parentheses are permitted.  This feature is particularly useful for
903 arrays-of-arrays, or arrays-of-hashes:
904
905     foreach \my @a (@array_of_arrays) {
906         frobnicate($a[0], $a[-1]);
907     }
908
909     foreach \my %h (@array_of_hashes) {
910         $h{gelastic}++ if $h{type} eq 'funny';
911     }
912
913 B<CAVEAT:> Aliasing does not work correctly with closures.  If you try to
914 alias lexical variables from an inner subroutine or C<eval>, the aliasing
915 will only be visible within that inner sub, and will not affect the outer
916 subroutine where the variables are declared.  This bizarre behavior is
917 subject to change.
918
919 =head1 SEE ALSO
920
921 Besides the obvious documents, source code can be instructive.
922 Some pathological examples of the use of references can be found
923 in the F<t/op/ref.t> regression test in the Perl source directory.
924
925 See also L<perldsc> and L<perllol> for how to use references to create
926 complex data structures, and L<perlootut> and L<perlobj>
927 for how to use them to create objects.