81b770a6a3c61c72af6379dc28571354af3c60f5
[perl.git] / lib / perl5db.pl
1
2 =head1 NAME
3
4 perl5db.pl - the perl debugger
5
6 =head1 SYNOPSIS
7
8     perl -d  your_Perl_script
9
10 =head1 DESCRIPTION
11
12 C<perl5db.pl> is the perl debugger. It is loaded automatically by Perl when
13 you invoke a script with C<perl -d>. This documentation tries to outline the
14 structure and services provided by C<perl5db.pl>, and to describe how you
15 can use them.
16
17 =head1 GENERAL NOTES
18
19 The debugger can look pretty forbidding to many Perl programmers. There are
20 a number of reasons for this, many stemming out of the debugger's history.
21
22 When the debugger was first written, Perl didn't have a lot of its nicer
23 features - no references, no lexical variables, no closures, no object-oriented
24 programming. So a lot of the things one would normally have done using such
25 features was done using global variables, globs and the C<local()> operator
26 in creative ways.
27
28 Some of these have survived into the current debugger; a few of the more
29 interesting and still-useful idioms are noted in this section, along with notes
30 on the comments themselves.
31
32 =head2 Why not use more lexicals?
33
34 Experienced Perl programmers will note that the debugger code tends to use
35 mostly package globals rather than lexically-scoped variables. This is done
36 to allow a significant amount of control of the debugger from outside the
37 debugger itself.
38
39 Unfortunately, though the variables are accessible, they're not well
40 documented, so it's generally been a decision that hasn't made a lot of
41 difference to most users. Where appropriate, comments have been added to
42 make variables more accessible and usable, with the understanding that these
43 I<are> debugger internals, and are therefore subject to change. Future
44 development should probably attempt to replace the globals with a well-defined
45 API, but for now, the variables are what we've got.
46
47 =head2 Automated variable stacking via C<local()>
48
49 As you may recall from reading C<perlfunc>, the C<local()> operator makes a
50 temporary copy of a variable in the current scope. When the scope ends, the
51 old copy is restored. This is often used in the debugger to handle the
52 automatic stacking of variables during recursive calls:
53
54      sub foo {
55         local $some_global++;
56
57         # Do some stuff, then ...
58         return;
59      }
60
61 What happens is that on entry to the subroutine, C<$some_global> is localized,
62 then altered. When the subroutine returns, Perl automatically undoes the
63 localization, restoring the previous value. Voila, automatic stack management.
64
65 The debugger uses this trick a I<lot>. Of particular note is C<DB::eval>,
66 which lets the debugger get control inside of C<eval>'ed code. The debugger
67 localizes a saved copy of C<$@> inside the subroutine, which allows it to
68 keep C<$@> safe until it C<DB::eval> returns, at which point the previous
69 value of C<$@> is restored. This makes it simple (well, I<simpler>) to keep
70 track of C<$@> inside C<eval>s which C<eval> other C<eval's>.
71
72 In any case, watch for this pattern. It occurs fairly often.
73
74 =head2 The C<^> trick
75
76 This is used to cleverly reverse the sense of a logical test depending on
77 the value of an auxiliary variable. For instance, the debugger's C<S>
78 (search for subroutines by pattern) allows you to negate the pattern
79 like this:
80
81    # Find all non-'foo' subs:
82    S !/foo/
83
84 Boolean algebra states that the truth table for XOR looks like this:
85
86 =over 4
87
88 =item * 0 ^ 0 = 0
89
90 (! not present and no match) --> false, don't print
91
92 =item * 0 ^ 1 = 1
93
94 (! not present and matches) --> true, print
95
96 =item * 1 ^ 0 = 1
97
98 (! present and no match) --> true, print
99
100 =item * 1 ^ 1 = 0
101
102 (! present and matches) --> false, don't print
103
104 =back
105
106 As you can see, the first pair applies when C<!> isn't supplied, and
107 the second pair applies when it is. The XOR simply allows us to
108 compact a more complicated if-then-elseif-else into a more elegant
109 (but perhaps overly clever) single test. After all, it needed this
110 explanation...
111
112 =head2 FLAGS, FLAGS, FLAGS
113
114 There is a certain C programming legacy in the debugger. Some variables,
115 such as C<$single>, C<$trace>, and C<$frame>, have I<magical> values composed
116 of 1, 2, 4, etc. (powers of 2) OR'ed together. This allows several pieces
117 of state to be stored independently in a single scalar.
118
119 A test like
120
121     if ($scalar & 4) ...
122
123 is checking to see if the appropriate bit is on. Since each bit can be
124 "addressed" independently in this way, C<$scalar> is acting sort of like
125 an array of bits. Obviously, since the contents of C<$scalar> are just a
126 bit-pattern, we can save and restore it easily (it will just look like
127 a number).
128
129 The problem, is of course, that this tends to leave magic numbers scattered
130 all over your program whenever a bit is set, cleared, or checked. So why do
131 it?
132
133 =over 4
134
135 =item *
136
137 First, doing an arithmetical or bitwise operation on a scalar is
138 just about the fastest thing you can do in Perl: C<use constant> actually
139 creates a subroutine call, and array and hash lookups are much slower. Is
140 this over-optimization at the expense of readability? Possibly, but the
141 debugger accesses these  variables a I<lot>. Any rewrite of the code will
142 probably have to benchmark alternate implementations and see which is the
143 best balance of readability and speed, and then document how it actually
144 works.
145
146 =item *
147
148 Second, it's very easy to serialize a scalar number. This is done in
149 the restart code; the debugger state variables are saved in C<%ENV> and then
150 restored when the debugger is restarted. Having them be just numbers makes
151 this trivial.
152
153 =item *
154
155 Third, some of these variables are being shared with the Perl core
156 smack in the middle of the interpreter's execution loop. It's much faster for
157 a C program (like the interpreter) to check a bit in a scalar than to access
158 several different variables (or a Perl array).
159
160 =back
161
162 =head2 What are those C<XXX> comments for?
163
164 Any comment containing C<XXX> means that the comment is either somewhat
165 speculative - it's not exactly clear what a given variable or chunk of
166 code is doing, or that it is incomplete - the basics may be clear, but the
167 subtleties are not completely documented.
168
169 Send in a patch if you can clear up, fill out, or clarify an C<XXX>.
170
171 =head1 DATA STRUCTURES MAINTAINED BY CORE
172
173 There are a number of special data structures provided to the debugger by
174 the Perl interpreter.
175
176 The array C<@{$main::{'_<'.$filename}}> (aliased locally to C<@dbline>
177 via glob assignment) contains the text from C<$filename>, with each
178 element corresponding to a single line of C<$filename>. Additionally,
179 breakable lines will be dualvars with the numeric component being the
180 memory address of a COP node. Non-breakable lines are dualvar to 0.
181
182 The hash C<%{'_<'.$filename}> (aliased locally to C<%dbline> via glob
183 assignment) contains breakpoints and actions.  The keys are line numbers;
184 you can set individual values, but not the whole hash. The Perl interpreter
185 uses this hash to determine where breakpoints have been set. Any true value is
186 considered to be a breakpoint; C<perl5db.pl> uses C<$break_condition\0$action>.
187 Values are magical in numeric context: 1 if the line is breakable, 0 if not.
188
189 The scalar C<${"_<$filename"}> simply contains the string C<<< _<$filename> >>>.
190 This is also the case for evaluated strings that contain subroutines, or
191 which are currently being executed.  The $filename for C<eval>ed strings looks
192 like C<(eval 34).
193
194 =head1 DEBUGGER STARTUP
195
196 When C<perl5db.pl> starts, it reads an rcfile (C<perl5db.ini> for
197 non-interactive sessions, C<.perldb> for interactive ones) that can set a number
198 of options. In addition, this file may define a subroutine C<&afterinit>
199 that will be executed (in the debugger's context) after the debugger has
200 initialized itself.
201
202 Next, it checks the C<PERLDB_OPTS> environment variable and treats its
203 contents as the argument of a C<o> command in the debugger.
204
205 =head2 STARTUP-ONLY OPTIONS
206
207 The following options can only be specified at startup.
208 To set them in your rcfile, add a call to
209 C<&parse_options("optionName=new_value")>.
210
211 =over 4
212
213 =item * TTY
214
215 the TTY to use for debugging i/o.
216
217 =item * noTTY
218
219 if set, goes in NonStop mode.  On interrupt, if TTY is not set,
220 uses the value of noTTY or F<$HOME/.perldbtty$$> to find TTY using
221 Term::Rendezvous.  Current variant is to have the name of TTY in this
222 file.
223
224 =item * ReadLine
225
226 if false, a dummy ReadLine is used, so you can debug
227 ReadLine applications.
228
229 =item * NonStop
230
231 if true, no i/o is performed until interrupt.
232
233 =item * LineInfo
234
235 file or pipe to print line number info to.  If it is a
236 pipe, a short "emacs like" message is used.
237
238 =item * RemotePort
239
240 host:port to connect to on remote host for remote debugging.
241
242 =item * HistFile
243
244 file to store session history to. There is no default and so no
245 history file is written unless this variable is explicitly set.
246
247 =item * HistSize
248
249 number of commands to store to the file specified in C<HistFile>.
250 Default is 100.
251
252 =back
253
254 =head3 SAMPLE RCFILE
255
256  &parse_options("NonStop=1 LineInfo=db.out");
257   sub afterinit { $trace = 1; }
258
259 The script will run without human intervention, putting trace
260 information into C<db.out>.  (If you interrupt it, you had better
261 reset C<LineInfo> to something I<interactive>!)
262
263 =head1 INTERNALS DESCRIPTION
264
265 =head2 DEBUGGER INTERFACE VARIABLES
266
267 Perl supplies the values for C<%sub>.  It effectively inserts
268 a C<&DB::DB();> in front of each place that can have a
269 breakpoint. At each subroutine call, it calls C<&DB::sub> with
270 C<$DB::sub> set to the called subroutine. It also inserts a C<BEGIN
271 {require 'perl5db.pl'}> before the first line.
272
273 After each C<require>d file is compiled, but before it is executed, a
274 call to C<&DB::postponed($main::{'_<'.$filename})> is done. C<$filename>
275 is the expanded name of the C<require>d file (as found via C<%INC>).
276
277 =head3 IMPORTANT INTERNAL VARIABLES
278
279 =head4 C<$CreateTTY>
280
281 Used to control when the debugger will attempt to acquire another TTY to be
282 used for input.
283
284 =over
285
286 =item * 1 -  on C<fork()>
287
288 =item * 2 - debugger is started inside debugger
289
290 =item * 4 -  on startup
291
292 =back
293
294 =head4 C<$doret>
295
296 The value -2 indicates that no return value should be printed.
297 Any other positive value causes C<DB::sub> to print return values.
298
299 =head4 C<$evalarg>
300
301 The item to be eval'ed by C<DB::eval>. Used to prevent messing with the current
302 contents of C<@_> when C<DB::eval> is called.
303
304 =head4 C<$frame>
305
306 Determines what messages (if any) will get printed when a subroutine (or eval)
307 is entered or exited.
308
309 =over 4
310
311 =item * 0 -  No enter/exit messages
312
313 =item * 1 - Print I<entering> messages on subroutine entry
314
315 =item * 2 - Adds exit messages on subroutine exit. If no other flag is on, acts like 1+2.
316
317 =item * 4 - Extended messages: C<< <in|out> I<context>=I<fully-qualified sub name> from I<file>:I<line> >>. If no other flag is on, acts like 1+4.
318
319 =item * 8 - Adds parameter information to messages, and overloaded stringify and tied FETCH is enabled on the printed arguments. Ignored if C<4> is not on.
320
321 =item * 16 - Adds C<I<context> return from I<subname>: I<value>> messages on subroutine/eval exit. Ignored if C<4> is is not on.
322
323 =back
324
325 To get everything, use C<$frame=30> (or C<o f=30> as a debugger command).
326 The debugger internally juggles the value of C<$frame> during execution to
327 protect external modules that the debugger uses from getting traced.
328
329 =head4 C<$level>
330
331 Tracks current debugger nesting level. Used to figure out how many
332 C<E<lt>E<gt>> pairs to surround the line number with when the debugger
333 outputs a prompt. Also used to help determine if the program has finished
334 during command parsing.
335
336 =head4 C<$onetimeDump>
337
338 Controls what (if anything) C<DB::eval()> will print after evaluating an
339 expression.
340
341 =over 4
342
343 =item * C<undef> - don't print anything
344
345 =item * C<dump> - use C<dumpvar.pl> to display the value returned
346
347 =item * C<methods> - print the methods callable on the first item returned
348
349 =back
350
351 =head4 C<$onetimeDumpDepth>
352
353 Controls how far down C<dumpvar.pl> will go before printing C<...> while
354 dumping a structure. Numeric. If C<undef>, print all levels.
355
356 =head4 C<$signal>
357
358 Used to track whether or not an C<INT> signal has been detected. C<DB::DB()>,
359 which is called before every statement, checks this and puts the user into
360 command mode if it finds C<$signal> set to a true value.
361
362 =head4 C<$single>
363
364 Controls behavior during single-stepping. Stacked in C<@stack> on entry to
365 each subroutine; popped again at the end of each subroutine.
366
367 =over 4
368
369 =item * 0 - run continuously.
370
371 =item * 1 - single-step, go into subs. The C<s> command.
372
373 =item * 2 - single-step, don't go into subs. The C<n> command.
374
375 =item * 4 - print current sub depth (turned on to force this when C<too much
376 recursion> occurs.
377
378 =back
379
380 =head4 C<$trace>
381
382 Controls the output of trace information.
383
384 =over 4
385
386 =item * 1 - The C<t> command was entered to turn on tracing (every line executed is printed)
387
388 =item * 2 - watch expressions are active
389
390 =item * 4 - user defined a C<watchfunction()> in C<afterinit()>
391
392 =back
393
394 =head4 C<$slave_editor>
395
396 1 if C<LINEINFO> was directed to a pipe; 0 otherwise.
397
398 =head4 C<@cmdfhs>
399
400 Stack of filehandles that C<DB::readline()> will read commands from.
401 Manipulated by the debugger's C<source> command and C<DB::readline()> itself.
402
403 =head4 C<@dbline>
404
405 Local alias to the magical line array, C<@{$main::{'_<'.$filename}}> ,
406 supplied by the Perl interpreter to the debugger. Contains the source.
407
408 =head4 C<@old_watch>
409
410 Previous values of watch expressions. First set when the expression is
411 entered; reset whenever the watch expression changes.
412
413 =head4 C<@saved>
414
415 Saves important globals (C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W>)
416 so that the debugger can substitute safe values while it's running, and
417 restore them when it returns control.
418
419 =head4 C<@stack>
420
421 Saves the current value of C<$single> on entry to a subroutine.
422 Manipulated by the C<c> command to turn off tracing in all subs above the
423 current one.
424
425 =head4 C<@to_watch>
426
427 The 'watch' expressions: to be evaluated before each line is executed.
428
429 =head4 C<@typeahead>
430
431 The typeahead buffer, used by C<DB::readline>.
432
433 =head4 C<%alias>
434
435 Command aliases. Stored as character strings to be substituted for a command
436 entered.
437
438 =head4 C<%break_on_load>
439
440 Keys are file names, values are 1 (break when this file is loaded) or undef
441 (don't break when it is loaded).
442
443 =head4 C<%dbline>
444
445 Keys are line numbers, values are C<condition\0action>. If used in numeric
446 context, values are 0 if not breakable, 1 if breakable, no matter what is
447 in the actual hash entry.
448
449 =head4 C<%had_breakpoints>
450
451 Keys are file names; values are bitfields:
452
453 =over 4
454
455 =item * 1 - file has a breakpoint in it.
456
457 =item * 2 - file has an action in it.
458
459 =back
460
461 A zero or undefined value means this file has neither.
462
463 =head4 C<%option>
464
465 Stores the debugger options. These are character string values.
466
467 =head4 C<%postponed>
468
469 Saves breakpoints for code that hasn't been compiled yet.
470 Keys are subroutine names, values are:
471
472 =over 4
473
474 =item * C<compile> - break when this sub is compiled
475
476 =item * C<< break +0 if <condition> >> - break (conditionally) at the start of this routine. The condition will be '1' if no condition was specified.
477
478 =back
479
480 =head4 C<%postponed_file>
481
482 This hash keeps track of breakpoints that need to be set for files that have
483 not yet been compiled. Keys are filenames; values are references to hashes.
484 Each of these hashes is keyed by line number, and its values are breakpoint
485 definitions (C<condition\0action>).
486
487 =head1 DEBUGGER INITIALIZATION
488
489 The debugger's initialization actually jumps all over the place inside this
490 package. This is because there are several BEGIN blocks (which of course
491 execute immediately) spread through the code. Why is that?
492
493 The debugger needs to be able to change some things and set some things up
494 before the debugger code is compiled; most notably, the C<$deep> variable that
495 C<DB::sub> uses to tell when a program has recursed deeply. In addition, the
496 debugger has to turn off warnings while the debugger code is compiled, but then
497 restore them to their original setting before the program being debugged begins
498 executing.
499
500 The first C<BEGIN> block simply turns off warnings by saving the current
501 setting of C<$^W> and then setting it to zero. The second one initializes
502 the debugger variables that are needed before the debugger begins executing.
503 The third one puts C<$^X> back to its former value.
504
505 We'll detail the second C<BEGIN> block later; just remember that if you need
506 to initialize something before the debugger starts really executing, that's
507 where it has to go.
508
509 =cut
510
511 package DB;
512
513 use strict;
514
515 BEGIN {eval 'use IO::Handle'}; # Needed for flush only? breaks under miniperl
516
517 BEGIN {
518     require feature;
519     $^V =~ /^v(\d+\.\d+)/;
520     feature->import(":$1");
521 }
522
523 # Debugger for Perl 5.00x; perl5db.pl patch level:
524 use vars qw($VERSION $header);
525
526 $VERSION = '1.39_05';
527
528 $header = "perl5db.pl version $VERSION";
529
530 =head1 DEBUGGER ROUTINES
531
532 =head2 C<DB::eval()>
533
534 This function replaces straight C<eval()> inside the debugger; it simplifies
535 the process of evaluating code in the user's context.
536
537 The code to be evaluated is passed via the package global variable
538 C<$DB::evalarg>; this is done to avoid fiddling with the contents of C<@_>.
539
540 Before we do the C<eval()>, we preserve the current settings of C<$trace>,
541 C<$single>, C<$^D> and C<$usercontext>.  The latter contains the
542 preserved values of C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>, C<$\>, C<$^W> and the
543 user's current package, grabbed when C<DB::DB> got control.  This causes the
544 proper context to be used when the eval is actually done.  Afterward, we
545 restore C<$trace>, C<$single>, and C<$^D>.
546
547 Next we need to handle C<$@> without getting confused. We save C<$@> in a
548 local lexical, localize C<$saved[0]> (which is where C<save()> will put
549 C<$@>), and then call C<save()> to capture C<$@>, C<$!>, C<$^E>, C<$,>,
550 C<$/>, C<$\>, and C<$^W>) and set C<$,>, C<$/>, C<$\>, and C<$^W> to values
551 considered sane by the debugger. If there was an C<eval()> error, we print
552 it on the debugger's output. If C<$onetimedump> is defined, we call
553 C<dumpit> if it's set to 'dump', or C<methods> if it's set to
554 'methods'. Setting it to something else causes the debugger to do the eval
555 but not print the result - handy if you want to do something else with it
556 (the "watch expressions" code does this to get the value of the watch
557 expression but not show it unless it matters).
558
559 In any case, we then return the list of output from C<eval> to the caller,
560 and unwinding restores the former version of C<$@> in C<@saved> as well
561 (the localization of C<$saved[0]> goes away at the end of this scope).
562
563 =head3 Parameters and variables influencing execution of DB::eval()
564
565 C<DB::eval> isn't parameterized in the standard way; this is to keep the
566 debugger's calls to C<DB::eval()> from mucking with C<@_>, among other things.
567 The variables listed below influence C<DB::eval()>'s execution directly.
568
569 =over 4
570
571 =item C<$evalarg> - the thing to actually be eval'ed
572
573 =item C<$trace> - Current state of execution tracing
574
575 =item C<$single> - Current state of single-stepping
576
577 =item C<$onetimeDump> - what is to be displayed after the evaluation
578
579 =item C<$onetimeDumpDepth> - how deep C<dumpit()> should go when dumping results
580
581 =back
582
583 The following variables are altered by C<DB::eval()> during its execution. They
584 are "stacked" via C<local()>, enabling recursive calls to C<DB::eval()>.
585
586 =over 4
587
588 =item C<@res> - used to capture output from actual C<eval>.
589
590 =item C<$otrace> - saved value of C<$trace>.
591
592 =item C<$osingle> - saved value of C<$single>.
593
594 =item C<$od> - saved value of C<$^D>.
595
596 =item C<$saved[0]> - saved value of C<$@>.
597
598 =item $\ - for output of C<$@> if there is an evaluation error.
599
600 =back
601
602 =head3 The problem of lexicals
603
604 The context of C<DB::eval()> presents us with some problems. Obviously,
605 we want to be 'sandboxed' away from the debugger's internals when we do
606 the eval, but we need some way to control how punctuation variables and
607 debugger globals are used.
608
609 We can't use local, because the code inside C<DB::eval> can see localized
610 variables; and we can't use C<my> either for the same reason. The code
611 in this routine compromises and uses C<my>.
612
613 After this routine is over, we don't have user code executing in the debugger's
614 context, so we can use C<my> freely.
615
616 =cut
617
618 ############################################## Begin lexical danger zone
619
620 # 'my' variables used here could leak into (that is, be visible in)
621 # the context that the code being evaluated is executing in. This means that
622 # the code could modify the debugger's variables.
623 #
624 # Fiddling with the debugger's context could be Bad. We insulate things as
625 # much as we can.
626
627 use vars qw(
628     @args
629     %break_on_load
630     $CommandSet
631     $CreateTTY
632     $DBGR
633     @dbline
634     $dbline
635     %dbline
636     $dieLevel
637     $filename
638     $histfile
639     $histsize
640     $IN
641     $inhibit_exit
642     @ini_INC
643     $ini_warn
644     $maxtrace
645     $od
646     $onetimedumpDepth
647     @options
648     $osingle
649     $otrace
650     $pager
651     $post
652     %postponed
653     $prc
654     $pre
655     $pretype
656     $psh
657     @RememberOnROptions
658     $remoteport
659     @res
660     $rl
661     @saved
662     $signalLevel
663     $sub
664     $term
665     $usercontext
666     $warnLevel
667 );
668
669 our (
670     @cmdfhs,
671     $evalarg,
672     $frame,
673     $hist,
674     $ImmediateStop,
675     $line,
676     $onetimeDump,
677     %option,
678     $OUT,
679     $packname,
680     $signal,
681     $single,
682     $start,
683     %sub,
684     $subname,
685     $trace,
686     $window,
687 );
688
689 # Used to save @ARGV and extract any debugger-related flags.
690 use vars qw(@ARGS);
691
692 # Used to prevent multiple entries to diesignal()
693 # (if for instance diesignal() itself dies)
694 use vars qw($panic);
695
696 # Used to prevent the debugger from running nonstop
697 # after a restart
698 our ($second_time);
699
700 sub _calc_usercontext {
701     my ($package) = @_;
702
703     # Cancel strict completely for the evaluated code, so the code
704     # the user evaluates won't be affected by it. (Shlomi Fish)
705     return 'no strict; ($@, $!, $^E, $,, $/, $\, $^W) = @DB::saved;'
706     . "package $package;";    # this won't let them modify, alas
707 }
708
709 sub eval {
710
711     # 'my' would make it visible from user code
712     #    but so does local! --tchrist
713     # Remember: this localizes @DB::res, not @main::res.
714     local @res;
715     {
716
717         # Try to keep the user code from messing  with us. Save these so that
718         # even if the eval'ed code changes them, we can put them back again.
719         # Needed because the user could refer directly to the debugger's
720         # package globals (and any 'my' variables in this containing scope)
721         # inside the eval(), and we want to try to stay safe.
722         local $otrace  = $trace;
723         local $osingle = $single;
724         local $od      = $^D;
725
726         # Untaint the incoming eval() argument.
727         { ($evalarg) = $evalarg =~ /(.*)/s; }
728
729         # $usercontext built in DB::DB near the comment
730         # "set up the context for DB::eval ..."
731         # Evaluate and save any results.
732         @res = eval "$usercontext $evalarg;\n";  # '\n' for nice recursive debug
733
734         # Restore those old values.
735         $trace  = $otrace;
736         $single = $osingle;
737         $^D     = $od;
738     }
739
740     # Save the current value of $@, and preserve it in the debugger's copy
741     # of the saved precious globals.
742     my $at = $@;
743
744     # Since we're only saving $@, we only have to localize the array element
745     # that it will be stored in.
746     local $saved[0];    # Preserve the old value of $@
747     eval { DB::save() };
748
749     # Now see whether we need to report an error back to the user.
750     if ($at) {
751         local $\ = '';
752         print $OUT $at;
753     }
754
755     # Display as required by the caller. $onetimeDump and $onetimedumpDepth
756     # are package globals.
757     elsif ($onetimeDump) {
758         if ( $onetimeDump eq 'dump' ) {
759             local $option{dumpDepth} = $onetimedumpDepth
760               if defined $onetimedumpDepth;
761             dumpit( $OUT, \@res );
762         }
763         elsif ( $onetimeDump eq 'methods' ) {
764             methods( $res[0] );
765         }
766     } ## end elsif ($onetimeDump)
767     @res;
768 } ## end sub eval
769
770 ############################################## End lexical danger zone
771
772 # After this point it is safe to introduce lexicals.
773 # The code being debugged will be executing in its own context, and
774 # can't see the inside of the debugger.
775 #
776 # However, one should not overdo it: leave as much control from outside as
777 # possible. If you make something a lexical, it's not going to be addressable
778 # from outside the debugger even if you know its name.
779
780 # This file is automatically included if you do perl -d.
781 # It's probably not useful to include this yourself.
782 #
783 # Before venturing further into these twisty passages, it is
784 # wise to read the perldebguts man page or risk the ire of dragons.
785 #
786 # (It should be noted that perldebguts will tell you a lot about
787 # the underlying mechanics of how the debugger interfaces into the
788 # Perl interpreter, but not a lot about the debugger itself. The new
789 # comments in this code try to address this problem.)
790
791 # Note that no subroutine call is possible until &DB::sub is defined
792 # (for subroutines defined outside of the package DB). In fact the same is
793 # true if $deep is not defined.
794
795 # Enhanced by ilya@math.ohio-state.edu (Ilya Zakharevich)
796
797 # modified Perl debugger, to be run from Emacs in perldb-mode
798 # Ray Lischner (uunet!mntgfx!lisch) as of 5 Nov 1990
799 # Johan Vromans -- upgrade to 4.0 pl 10
800 # Ilya Zakharevich -- patches after 5.001 (and some before ;-)
801 ########################################################################
802
803 =head1 DEBUGGER INITIALIZATION
804
805 The debugger starts up in phases.
806
807 =head2 BASIC SETUP
808
809 First, it initializes the environment it wants to run in: turning off
810 warnings during its own compilation, defining variables which it will need
811 to avoid warnings later, setting itself up to not exit when the program
812 terminates, and defaulting to printing return values for the C<r> command.
813
814 =cut
815
816 # Needed for the statement after exec():
817 #
818 # This BEGIN block is simply used to switch off warnings during debugger
819 # compilation. Probably it would be better practice to fix the warnings,
820 # but this is how it's done at the moment.
821
822 BEGIN {
823     $ini_warn = $^W;
824     $^W       = 0;
825 }    # Switch compilation warnings off until another BEGIN.
826
827 local ($^W) = 0;    # Switch run-time warnings off during init.
828
829 =head2 THREADS SUPPORT
830
831 If we are running under a threaded Perl, we require threads and threads::shared
832 if the environment variable C<PERL5DB_THREADED> is set, to enable proper
833 threaded debugger control.  C<-dt> can also be used to set this.
834
835 Each new thread will be announced and the debugger prompt will always inform
836 you of each new thread created.  It will also indicate the thread id in which
837 we are currently running within the prompt like this:
838
839     [tid] DB<$i>
840
841 Where C<[tid]> is an integer thread id and C<$i> is the familiar debugger
842 command prompt.  The prompt will show: C<[0]> when running under threads, but
843 not actually in a thread.  C<[tid]> is consistent with C<gdb> usage.
844
845 While running under threads, when you set or delete a breakpoint (etc.), this
846 will apply to all threads, not just the currently running one.  When you are
847 in a currently executing thread, you will stay there until it completes.  With
848 the current implementation it is not currently possible to hop from one thread
849 to another.
850
851 The C<e> and C<E> commands are currently fairly minimal - see C<h e> and C<h E>.
852
853 Note that threading support was built into the debugger as of Perl version
854 C<5.8.6> and debugger version C<1.2.8>.
855
856 =cut
857
858 BEGIN {
859     # ensure we can share our non-threaded variables or no-op
860     if ($ENV{PERL5DB_THREADED}) {
861         require threads;
862         require threads::shared;
863         import threads::shared qw(share);
864         $DBGR;
865         share(\$DBGR);
866         lock($DBGR);
867         print "Threads support enabled\n";
868     } else {
869         *lock  = sub(*) {};
870         *share = sub(*) {};
871     }
872 }
873
874 # These variables control the execution of 'dumpvar.pl'.
875 {
876     package dumpvar;
877     use vars qw(
878     $hashDepth
879     $arrayDepth
880     $dumpDBFiles
881     $dumpPackages
882     $quoteHighBit
883     $printUndef
884     $globPrint
885     $usageOnly
886     );
887 }
888
889 # used to control die() reporting in diesignal()
890 {
891     package Carp;
892     use vars qw($CarpLevel);
893 }
894
895 # without threads, $filename is not defined until DB::DB is called
896 foreach my $k (keys (%INC)) {
897     share(\$main::{'_<'.$filename}) if defined $filename;
898 };
899
900 # Command-line + PERLLIB:
901 # Save the contents of @INC before they are modified elsewhere.
902 @ini_INC = @INC;
903
904 # This was an attempt to clear out the previous values of various
905 # trapped errors. Apparently it didn't help. XXX More info needed!
906 # $prevwarn = $prevdie = $prevbus = $prevsegv = ''; # Does not help?!
907
908 # We set these variables to safe values. We don't want to blindly turn
909 # off warnings, because other packages may still want them.
910 $trace = $signal = $single = 0;    # Uninitialized warning suppression
911                                    # (local $^W cannot help - other packages!).
912
913 # Default to not exiting when program finishes; print the return
914 # value when the 'r' command is used to return from a subroutine.
915 $inhibit_exit = $option{PrintRet} = 1;
916
917 use vars qw($trace_to_depth);
918
919 # Default to 1E9 so it won't be limited to a certain recursion depth.
920 $trace_to_depth = 1E9;
921
922 =head1 OPTION PROCESSING
923
924 The debugger's options are actually spread out over the debugger itself and
925 C<dumpvar.pl>; some of these are variables to be set, while others are
926 subs to be called with a value. To try to make this a little easier to
927 manage, the debugger uses a few data structures to define what options
928 are legal and how they are to be processed.
929
930 First, the C<@options> array defines the I<names> of all the options that
931 are to be accepted.
932
933 =cut
934
935 @options = qw(
936   CommandSet   HistFile      HistSize
937   hashDepth    arrayDepth    dumpDepth
938   DumpDBFiles  DumpPackages  DumpReused
939   compactDump  veryCompact   quote
940   HighBit      undefPrint    globPrint
941   PrintRet     UsageOnly     frame
942   AutoTrace    TTY           noTTY
943   ReadLine     NonStop       LineInfo
944   maxTraceLen  recallCommand ShellBang
945   pager        tkRunning     ornaments
946   signalLevel  warnLevel     dieLevel
947   inhibit_exit ImmediateStop bareStringify
948   CreateTTY    RemotePort    windowSize
949   DollarCaretP
950 );
951
952 @RememberOnROptions = qw(DollarCaretP);
953
954 =pod
955
956 Second, C<optionVars> lists the variables that each option uses to save its
957 state.
958
959 =cut
960
961 use vars qw(%optionVars);
962
963 %optionVars = (
964     hashDepth     => \$dumpvar::hashDepth,
965     arrayDepth    => \$dumpvar::arrayDepth,
966     CommandSet    => \$CommandSet,
967     DumpDBFiles   => \$dumpvar::dumpDBFiles,
968     DumpPackages  => \$dumpvar::dumpPackages,
969     DumpReused    => \$dumpvar::dumpReused,
970     HighBit       => \$dumpvar::quoteHighBit,
971     undefPrint    => \$dumpvar::printUndef,
972     globPrint     => \$dumpvar::globPrint,
973     UsageOnly     => \$dumpvar::usageOnly,
974     CreateTTY     => \$CreateTTY,
975     bareStringify => \$dumpvar::bareStringify,
976     frame         => \$frame,
977     AutoTrace     => \$trace,
978     inhibit_exit  => \$inhibit_exit,
979     maxTraceLen   => \$maxtrace,
980     ImmediateStop => \$ImmediateStop,
981     RemotePort    => \$remoteport,
982     windowSize    => \$window,
983     HistFile      => \$histfile,
984     HistSize      => \$histsize,
985 );
986
987 =pod
988
989 Third, C<%optionAction> defines the subroutine to be called to process each
990 option.
991
992 =cut
993
994 use vars qw(%optionAction);
995
996 %optionAction = (
997     compactDump   => \&dumpvar::compactDump,
998     veryCompact   => \&dumpvar::veryCompact,
999     quote         => \&dumpvar::quote,
1000     TTY           => \&TTY,
1001     noTTY         => \&noTTY,
1002     ReadLine      => \&ReadLine,
1003     NonStop       => \&NonStop,
1004     LineInfo      => \&LineInfo,
1005     recallCommand => \&recallCommand,
1006     ShellBang     => \&shellBang,
1007     pager         => \&pager,
1008     signalLevel   => \&signalLevel,
1009     warnLevel     => \&warnLevel,
1010     dieLevel      => \&dieLevel,
1011     tkRunning     => \&tkRunning,
1012     ornaments     => \&ornaments,
1013     RemotePort    => \&RemotePort,
1014     DollarCaretP  => \&DollarCaretP,
1015 );
1016
1017 =pod
1018
1019 Last, the C<%optionRequire> notes modules that must be C<require>d if an
1020 option is used.
1021
1022 =cut
1023
1024 # Note that this list is not complete: several options not listed here
1025 # actually require that dumpvar.pl be loaded for them to work, but are
1026 # not in the table. A subsequent patch will correct this problem; for
1027 # the moment, we're just recommenting, and we are NOT going to change
1028 # function.
1029 use vars qw(%optionRequire);
1030
1031 %optionRequire = (
1032     compactDump => 'dumpvar.pl',
1033     veryCompact => 'dumpvar.pl',
1034     quote       => 'dumpvar.pl',
1035 );
1036
1037 =pod
1038
1039 There are a number of initialization-related variables which can be set
1040 by putting code to set them in a BEGIN block in the C<PERL5DB> environment
1041 variable. These are:
1042
1043 =over 4
1044
1045 =item C<$rl> - readline control XXX needs more explanation
1046
1047 =item C<$warnLevel> - whether or not debugger takes over warning handling
1048
1049 =item C<$dieLevel> - whether or not debugger takes over die handling
1050
1051 =item C<$signalLevel> - whether or not debugger takes over signal handling
1052
1053 =item C<$pre> - preprompt actions (array reference)
1054
1055 =item C<$post> - postprompt actions (array reference)
1056
1057 =item C<$pretype>
1058
1059 =item C<$CreateTTY> - whether or not to create a new TTY for this debugger
1060
1061 =item C<$CommandSet> - which command set to use (defaults to new, documented set)
1062
1063 =back
1064
1065 =cut
1066
1067 # These guys may be defined in $ENV{PERL5DB} :
1068 $rl          = 1     unless defined $rl;
1069 $warnLevel   = 1     unless defined $warnLevel;
1070 $dieLevel    = 1     unless defined $dieLevel;
1071 $signalLevel = 1     unless defined $signalLevel;
1072 $pre         = []    unless defined $pre;
1073 $post        = []    unless defined $post;
1074 $pretype     = []    unless defined $pretype;
1075 $CreateTTY   = 3     unless defined $CreateTTY;
1076 $CommandSet  = '580' unless defined $CommandSet;
1077
1078 share($rl);
1079 share($warnLevel);
1080 share($dieLevel);
1081 share($signalLevel);
1082 share($pre);
1083 share($post);
1084 share($pretype);
1085 share($rl);
1086 share($CreateTTY);
1087 share($CommandSet);
1088
1089 =pod
1090
1091 The default C<die>, C<warn>, and C<signal> handlers are set up.
1092
1093 =cut
1094
1095 warnLevel($warnLevel);
1096 dieLevel($dieLevel);
1097 signalLevel($signalLevel);
1098
1099 =pod
1100
1101 The pager to be used is needed next. We try to get it from the
1102 environment first.  If it's not defined there, we try to find it in
1103 the Perl C<Config.pm>.  If it's not there, we default to C<more>. We
1104 then call the C<pager()> function to save the pager name.
1105
1106 =cut
1107
1108 # This routine makes sure $pager is set up so that '|' can use it.
1109 pager(
1110
1111     # If PAGER is defined in the environment, use it.
1112     defined $ENV{PAGER}
1113     ? $ENV{PAGER}
1114
1115       # If not, see if Config.pm defines it.
1116     : eval { require Config }
1117       && defined $Config::Config{pager}
1118     ? $Config::Config{pager}
1119
1120       # If not, fall back to 'more'.
1121     : 'more'
1122   )
1123   unless defined $pager;
1124
1125 =pod
1126
1127 We set up the command to be used to access the man pages, the command
1128 recall character (C<!> unless otherwise defined) and the shell escape
1129 character (C<!> unless otherwise defined). Yes, these do conflict, and
1130 neither works in the debugger at the moment.
1131
1132 =cut
1133
1134 setman();
1135
1136 # Set up defaults for command recall and shell escape (note:
1137 # these currently don't work in linemode debugging).
1138 recallCommand("!") unless defined $prc;
1139 shellBang("!")     unless defined $psh;
1140
1141 =pod
1142
1143 We then set up the gigantic string containing the debugger help.
1144 We also set the limit on the number of arguments we'll display during a
1145 trace.
1146
1147 =cut
1148
1149 sethelp();
1150
1151 # If we didn't get a default for the length of eval/stack trace args,
1152 # set it here.
1153 $maxtrace = 400 unless defined $maxtrace;
1154
1155 =head2 SETTING UP THE DEBUGGER GREETING
1156
1157 The debugger I<greeting> helps to inform the user how many debuggers are
1158 running, and whether the current debugger is the primary or a child.
1159
1160 If we are the primary, we just hang onto our pid so we'll have it when
1161 or if we start a child debugger. If we are a child, we'll set things up
1162 so we'll have a unique greeting and so the parent will give us our own
1163 TTY later.
1164
1165 We save the current contents of the C<PERLDB_PIDS> environment variable
1166 because we mess around with it. We'll also need to hang onto it because
1167 we'll need it if we restart.
1168
1169 Child debuggers make a label out of the current PID structure recorded in
1170 PERLDB_PIDS plus the new PID. They also mark themselves as not having a TTY
1171 yet so the parent will give them one later via C<resetterm()>.
1172
1173 =cut
1174
1175 # Save the current contents of the environment; we're about to
1176 # much with it. We'll need this if we have to restart.
1177 use vars qw($ini_pids);
1178 $ini_pids = $ENV{PERLDB_PIDS};
1179
1180 use vars qw ($pids $term_pid);
1181
1182 if ( defined $ENV{PERLDB_PIDS} ) {
1183
1184     # We're a child. Make us a label out of the current PID structure
1185     # recorded in PERLDB_PIDS plus our (new) PID. Mark us as not having
1186     # a term yet so the parent will give us one later via resetterm().
1187
1188     my $env_pids = $ENV{PERLDB_PIDS};
1189     $pids = "[$env_pids]";
1190
1191     # Unless we are on OpenVMS, all programs under the DCL shell run under
1192     # the same PID.
1193
1194     if (($^O eq 'VMS') && ($env_pids =~ /\b$$\b/)) {
1195         $term_pid         = $$;
1196     }
1197     else {
1198         $ENV{PERLDB_PIDS} .= "->$$";
1199         $term_pid = -1;
1200     }
1201
1202 } ## end if (defined $ENV{PERLDB_PIDS...
1203 else {
1204
1205     # We're the parent PID. Initialize PERLDB_PID in case we end up with a
1206     # child debugger, and mark us as the parent, so we'll know to set up
1207     # more TTY's is we have to.
1208     $ENV{PERLDB_PIDS} = "$$";
1209     $pids             = "[pid=$$]";
1210     $term_pid         = $$;
1211 }
1212
1213 use vars qw($pidprompt);
1214 $pidprompt = '';
1215
1216 # Sets up $emacs as a synonym for $slave_editor.
1217 our ($slave_editor);
1218 *emacs = $slave_editor if $slave_editor;    # May be used in afterinit()...
1219
1220 =head2 READING THE RC FILE
1221
1222 The debugger will read a file of initialization options if supplied. If
1223 running interactively, this is C<.perldb>; if not, it's C<perldb.ini>.
1224
1225 =cut
1226
1227 # As noted, this test really doesn't check accurately that the debugger
1228 # is running at a terminal or not.
1229
1230 use vars qw($rcfile);
1231 {
1232     my $dev_tty = (($^O eq 'VMS') ? 'TT:' : '/dev/tty');
1233     # this is the wrong metric!
1234     $rcfile = ((-e $dev_tty) ? ".perldb" : "perldb.ini");
1235 }
1236
1237 =pod
1238
1239 The debugger does a safety test of the file to be read. It must be owned
1240 either by the current user or root, and must only be writable by the owner.
1241
1242 =cut
1243
1244 # This wraps a safety test around "do" to read and evaluate the init file.
1245 #
1246 # This isn't really safe, because there's a race
1247 # between checking and opening.  The solution is to
1248 # open and fstat the handle, but then you have to read and
1249 # eval the contents.  But then the silly thing gets
1250 # your lexical scope, which is unfortunate at best.
1251 sub safe_do {
1252     my $file = shift;
1253
1254     # Just exactly what part of the word "CORE::" don't you understand?
1255     local $SIG{__WARN__};
1256     local $SIG{__DIE__};
1257
1258     unless ( is_safe_file($file) ) {
1259         CORE::warn <<EO_GRIPE;
1260 perldb: Must not source insecure rcfile $file.
1261         You or the superuser must be the owner, and it must not
1262         be writable by anyone but its owner.
1263 EO_GRIPE
1264         return;
1265     } ## end unless (is_safe_file($file...
1266
1267     do $file;
1268     CORE::warn("perldb: couldn't parse $file: $@") if $@;
1269 } ## end sub safe_do
1270
1271 # This is the safety test itself.
1272 #
1273 # Verifies that owner is either real user or superuser and that no
1274 # one but owner may write to it.  This function is of limited use
1275 # when called on a path instead of upon a handle, because there are
1276 # no guarantees that filename (by dirent) whose file (by ino) is
1277 # eventually accessed is the same as the one tested.
1278 # Assumes that the file's existence is not in doubt.
1279 sub is_safe_file {
1280     my $path = shift;
1281     stat($path) || return;    # mysteriously vaporized
1282     my ( $dev, $ino, $mode, $nlink, $uid, $gid ) = stat(_);
1283
1284     return 0 if $uid != 0 && $uid != $<;
1285     return 0 if $mode & 022;
1286     return 1;
1287 } ## end sub is_safe_file
1288
1289 # If the rcfile (whichever one we decided was the right one to read)
1290 # exists, we safely do it.
1291 if ( -f $rcfile ) {
1292     safe_do("./$rcfile");
1293 }
1294
1295 # If there isn't one here, try the user's home directory.
1296 elsif ( defined $ENV{HOME} && -f "$ENV{HOME}/$rcfile" ) {
1297     safe_do("$ENV{HOME}/$rcfile");
1298 }
1299
1300 # Else try the login directory.
1301 elsif ( defined $ENV{LOGDIR} && -f "$ENV{LOGDIR}/$rcfile" ) {
1302     safe_do("$ENV{LOGDIR}/$rcfile");
1303 }
1304
1305 # If the PERLDB_OPTS variable has options in it, parse those out next.
1306 if ( defined $ENV{PERLDB_OPTS} ) {
1307     parse_options( $ENV{PERLDB_OPTS} );
1308 }
1309
1310 =pod
1311
1312 The last thing we do during initialization is determine which subroutine is
1313 to be used to obtain a new terminal when a new debugger is started. Right now,
1314 the debugger only handles TCP sockets, X11, OS/2, amd Mac OS X
1315 (darwin).
1316
1317 =cut
1318
1319 # Set up the get_fork_TTY subroutine to be aliased to the proper routine.
1320 # Works if you're running an xterm or xterm-like window, or you're on
1321 # OS/2, or on Mac OS X. This may need some expansion.
1322
1323 if (not defined &get_fork_TTY)       # only if no routine exists
1324 {
1325     if ( defined $remoteport ) {
1326                                                  # Expect an inetd-like server
1327         *get_fork_TTY = \&socket_get_fork_TTY;   # to listen to us
1328     }
1329     elsif (defined $ENV{TERM}                    # If we know what kind
1330                                                  # of terminal this is,
1331         and $ENV{TERM} eq 'xterm'                # and it's an xterm,
1332         and defined $ENV{DISPLAY}                # and what display it's on,
1333       )
1334     {
1335         *get_fork_TTY = \&xterm_get_fork_TTY;    # use the xterm version
1336     }
1337     elsif ( $^O eq 'os2' ) {                     # If this is OS/2,
1338         *get_fork_TTY = \&os2_get_fork_TTY;      # use the OS/2 version
1339     }
1340     elsif ( $^O eq 'darwin'                      # If this is Mac OS X
1341             and defined $ENV{TERM_PROGRAM}       # and we're running inside
1342             and $ENV{TERM_PROGRAM}
1343                 eq 'Apple_Terminal'              # Terminal.app
1344             )
1345     {
1346         *get_fork_TTY = \&macosx_get_fork_TTY;   # use the Mac OS X version
1347     }
1348 } ## end if (not defined &get_fork_TTY...
1349
1350 # untaint $^O, which may have been tainted by the last statement.
1351 # see bug [perl #24674]
1352 $^O =~ m/^(.*)\z/;
1353 $^O = $1;
1354
1355 # Here begin the unreadable code.  It needs fixing.
1356
1357 =head2 RESTART PROCESSING
1358
1359 This section handles the restart command. When the C<R> command is invoked, it
1360 tries to capture all of the state it can into environment variables, and
1361 then sets C<PERLDB_RESTART>. When we start executing again, we check to see
1362 if C<PERLDB_RESTART> is there; if so, we reload all the information that
1363 the R command stuffed into the environment variables.
1364
1365   PERLDB_RESTART   - flag only, contains no restart data itself.
1366   PERLDB_HIST      - command history, if it's available
1367   PERLDB_ON_LOAD   - breakpoints set by the rc file
1368   PERLDB_POSTPONE  - subs that have been loaded/not executed, and have actions
1369   PERLDB_VISITED   - files that had breakpoints
1370   PERLDB_FILE_...  - breakpoints for a file
1371   PERLDB_OPT       - active options
1372   PERLDB_INC       - the original @INC
1373   PERLDB_PRETYPE   - preprompt debugger actions
1374   PERLDB_PRE       - preprompt Perl code
1375   PERLDB_POST      - post-prompt Perl code
1376   PERLDB_TYPEAHEAD - typeahead captured by readline()
1377
1378 We chug through all these variables and plug the values saved in them
1379 back into the appropriate spots in the debugger.
1380
1381 =cut
1382
1383 use vars qw(%postponed_file @typeahead);
1384
1385 our (@hist, @truehist);
1386
1387 sub _restore_shared_globals_after_restart
1388 {
1389     @hist          = get_list('PERLDB_HIST');
1390     %break_on_load = get_list("PERLDB_ON_LOAD");
1391     %postponed     = get_list("PERLDB_POSTPONE");
1392
1393     share(@hist);
1394     share(@truehist);
1395     share(%break_on_load);
1396     share(%postponed);
1397 }
1398
1399 sub _restore_breakpoints_and_actions {
1400
1401     my @had_breakpoints = get_list("PERLDB_VISITED");
1402
1403     for my $file_idx ( 0 .. $#had_breakpoints ) {
1404         my $filename = $had_breakpoints[$file_idx];
1405         my %pf = get_list("PERLDB_FILE_$file_idx");
1406         $postponed_file{ $filename } = \%pf if %pf;
1407         my @lines = sort {$a <=> $b} keys(%pf);
1408         my @enabled_statuses = get_list("PERLDB_FILE_ENABLED_$file_idx");
1409         for my $line_idx (0 .. $#lines) {
1410             _set_breakpoint_enabled_status(
1411                 $filename,
1412                 $lines[$line_idx],
1413                 ($enabled_statuses[$line_idx] ? 1 : ''),
1414             );
1415         }
1416     }
1417
1418     return;
1419 }
1420
1421 sub _restore_options_after_restart
1422 {
1423     my %options_map = get_list("PERLDB_OPT");
1424
1425     while ( my ( $opt, $val ) = each %options_map ) {
1426         $val =~ s/[\\\']/\\$1/g;
1427         parse_options("$opt'$val'");
1428     }
1429
1430     return;
1431 }
1432
1433 sub _restore_globals_after_restart
1434 {
1435     # restore original @INC
1436     @INC     = get_list("PERLDB_INC");
1437     @ini_INC = @INC;
1438
1439     # return pre/postprompt actions and typeahead buffer
1440     $pretype   = [ get_list("PERLDB_PRETYPE") ];
1441     $pre       = [ get_list("PERLDB_PRE") ];
1442     $post      = [ get_list("PERLDB_POST") ];
1443     @typeahead = get_list( "PERLDB_TYPEAHEAD", @typeahead );
1444
1445     return;
1446 }
1447
1448
1449 if ( exists $ENV{PERLDB_RESTART} ) {
1450
1451     # We're restarting, so we don't need the flag that says to restart anymore.
1452     delete $ENV{PERLDB_RESTART};
1453
1454     # $restart = 1;
1455     _restore_shared_globals_after_restart();
1456
1457     _restore_breakpoints_and_actions();
1458
1459     # restore options
1460     _restore_options_after_restart();
1461
1462     _restore_globals_after_restart();
1463 } ## end if (exists $ENV{PERLDB_RESTART...
1464
1465 =head2 SETTING UP THE TERMINAL
1466
1467 Now, we'll decide how the debugger is going to interact with the user.
1468 If there's no TTY, we set the debugger to run non-stop; there's not going
1469 to be anyone there to enter commands.
1470
1471 =cut
1472
1473 use vars qw($notty $console $tty $LINEINFO);
1474 use vars qw($lineinfo $doccmd);
1475
1476 our ($runnonstop);
1477
1478 if ($notty) {
1479     $runnonstop = 1;
1480     share($runnonstop);
1481 }
1482
1483 =pod
1484
1485 If there is a TTY, we have to determine who it belongs to before we can
1486 proceed. If this is a slave editor or graphical debugger (denoted by
1487 the first command-line switch being '-emacs'), we shift this off and
1488 set C<$rl> to 0 (XXX ostensibly to do straight reads).
1489
1490 =cut
1491
1492 else {
1493
1494     # Is Perl being run from a slave editor or graphical debugger?
1495     # If so, don't use readline, and set $slave_editor = 1.
1496     if ($slave_editor = ( @main::ARGV && ( $main::ARGV[0] eq '-emacs' ) )) {
1497         $rl = 0;
1498         shift(@main::ARGV);
1499     }
1500
1501     #require Term::ReadLine;
1502
1503 =pod
1504
1505 We then determine what the console should be on various systems:
1506
1507 =over 4
1508
1509 =item * Cygwin - We use C<stdin> instead of a separate device.
1510
1511 =cut
1512
1513     if ( $^O eq 'cygwin' ) {
1514
1515         # /dev/tty is binary. use stdin for textmode
1516         undef $console;
1517     }
1518
1519 =item * Unix - use C</dev/tty>.
1520
1521 =cut
1522
1523     elsif ( -e "/dev/tty" ) {
1524         $console = "/dev/tty";
1525     }
1526
1527 =item * Windows or MSDOS - use C<con>.
1528
1529 =cut
1530
1531     elsif ( $^O eq 'dos' or -e "con" or $^O eq 'MSWin32' ) {
1532         $console = "con";
1533     }
1534
1535 =item * VMS - use C<sys$command>.
1536
1537 =cut
1538
1539     else {
1540
1541         # everything else is ...
1542         $console = "sys\$command";
1543     }
1544
1545 =pod
1546
1547 =back
1548
1549 Several other systems don't use a specific console. We C<undef $console>
1550 for those (Windows using a slave editor/graphical debugger, NetWare, OS/2
1551 with a slave editor, Epoc).
1552
1553 =cut
1554
1555     if ( ( $^O eq 'MSWin32' ) and ( $slave_editor or defined $ENV{EMACS} ) ) {
1556
1557         # /dev/tty is binary. use stdin for textmode
1558         $console = undef;
1559     }
1560
1561     if ( $^O eq 'NetWare' ) {
1562
1563         # /dev/tty is binary. use stdin for textmode
1564         $console = undef;
1565     }
1566
1567     # In OS/2, we need to use STDIN to get textmode too, even though
1568     # it pretty much looks like Unix otherwise.
1569     if ( defined $ENV{OS2_SHELL} and ( $slave_editor or $ENV{WINDOWID} ) )
1570     {    # In OS/2
1571         $console = undef;
1572     }
1573
1574     # EPOC also falls into the 'got to use STDIN' camp.
1575     if ( $^O eq 'epoc' ) {
1576         $console = undef;
1577     }
1578
1579 =pod
1580
1581 If there is a TTY hanging around from a parent, we use that as the console.
1582
1583 =cut
1584
1585     $console = $tty if defined $tty;
1586
1587 =head2 SOCKET HANDLING
1588
1589 The debugger is capable of opening a socket and carrying out a debugging
1590 session over the socket.
1591
1592 If C<RemotePort> was defined in the options, the debugger assumes that it
1593 should try to start a debugging session on that port. It builds the socket
1594 and then tries to connect the input and output filehandles to it.
1595
1596 =cut
1597
1598     # Handle socket stuff.
1599
1600     if ( defined $remoteport ) {
1601
1602         # If RemotePort was defined in the options, connect input and output
1603         # to the socket.
1604         $IN = $OUT = connect_remoteport();
1605     } ## end if (defined $remoteport)
1606
1607 =pod
1608
1609 If no C<RemotePort> was defined, and we want to create a TTY on startup,
1610 this is probably a situation where multiple debuggers are running (for example,
1611 a backticked command that starts up another debugger). We create a new IN and
1612 OUT filehandle, and do the necessary mojo to create a new TTY if we know how
1613 and if we can.
1614
1615 =cut
1616
1617     # Non-socket.
1618     else {
1619
1620         # Two debuggers running (probably a system or a backtick that invokes
1621         # the debugger itself under the running one). create a new IN and OUT
1622         # filehandle, and do the necessary mojo to create a new tty if we
1623         # know how, and we can.
1624         create_IN_OUT(4) if $CreateTTY & 4;
1625         if ($console) {
1626
1627             # If we have a console, check to see if there are separate ins and
1628             # outs to open. (They are assumed identical if not.)
1629
1630             my ( $i, $o ) = split /,/, $console;
1631             $o = $i unless defined $o;
1632
1633             # read/write on in, or just read, or read on STDIN.
1634             open( IN,      "+<$i" )
1635               || open( IN, "<$i" )
1636               || open( IN, "<&STDIN" );
1637
1638             # read/write/create/clobber out, or write/create/clobber out,
1639             # or merge with STDERR, or merge with STDOUT.
1640                  open( OUT, "+>$o" )
1641               || open( OUT, ">$o" )
1642               || open( OUT, ">&STDERR" )
1643               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1644
1645         } ## end if ($console)
1646         elsif ( not defined $console ) {
1647
1648             # No console. Open STDIN.
1649             open( IN, "<&STDIN" );
1650
1651             # merge with STDERR, or with STDOUT.
1652             open( OUT,      ">&STDERR" )
1653               || open( OUT, ">&STDOUT" );    # so we don't dongle stdout
1654             $console = 'STDIN/OUT';
1655         } ## end elsif (not defined $console)
1656
1657         # Keep copies of the filehandles so that when the pager runs, it
1658         # can close standard input without clobbering ours.
1659         if ($console or (not defined($console))) {
1660             $IN = \*IN;
1661             $OUT = \*OUT;
1662         }
1663     } ## end elsif (from if(defined $remoteport))
1664
1665     # Unbuffer DB::OUT. We need to see responses right away.
1666     $OUT->autoflush(1);
1667
1668     # Line info goes to debugger output unless pointed elsewhere.
1669     # Pointing elsewhere makes it possible for slave editors to
1670     # keep track of file and position. We have both a filehandle
1671     # and a I/O description to keep track of.
1672     $LINEINFO = $OUT     unless defined $LINEINFO;
1673     $lineinfo = $console unless defined $lineinfo;
1674     # share($LINEINFO); # <- unable to share globs
1675     share($lineinfo);   #
1676
1677 =pod
1678
1679 To finish initialization, we show the debugger greeting,
1680 and then call the C<afterinit()> subroutine if there is one.
1681
1682 =cut
1683
1684     # Show the debugger greeting.
1685     $header =~ s/.Header: ([^,]+),v(\s+\S+\s+\S+).*$/$1$2/;
1686     unless ($runnonstop) {
1687         local $\ = '';
1688         local $, = '';
1689         if ( $term_pid eq '-1' ) {
1690             print $OUT "\nDaughter DB session started...\n";
1691         }
1692         else {
1693             print $OUT "\nLoading DB routines from $header\n";
1694             print $OUT (
1695                 "Editor support ",
1696                 $slave_editor ? "enabled" : "available", ".\n"
1697             );
1698             print $OUT
1699 "\nEnter h or 'h h' for help, or '$doccmd perldebug' for more help.\n\n";
1700         } ## end else [ if ($term_pid eq '-1')
1701     } ## end unless ($runnonstop)
1702 } ## end else [ if ($notty)
1703
1704 # XXX This looks like a bug to me.
1705 # Why copy to @ARGS and then futz with @args?
1706 @ARGS = @ARGV;
1707 # for (@args) {
1708     # Make sure backslashes before single quotes are stripped out, and
1709     # keep args unless they are numeric (XXX why?)
1710     # s/\'/\\\'/g;                      # removed while not justified understandably
1711     # s/(.*)/'$1'/ unless /^-?[\d.]+$/; # ditto
1712 # }
1713
1714 # If there was an afterinit() sub defined, call it. It will get
1715 # executed in our scope, so it can fiddle with debugger globals.
1716 if ( defined &afterinit ) {    # May be defined in $rcfile
1717     afterinit();
1718 }
1719
1720 # Inform us about "Stack dump during die enabled ..." in dieLevel().
1721 use vars qw($I_m_init);
1722
1723 $I_m_init = 1;
1724
1725 ############################################################ Subroutines
1726
1727 =head1 SUBROUTINES
1728
1729 =head2 DB
1730
1731 This gigantic subroutine is the heart of the debugger. Called before every
1732 statement, its job is to determine if a breakpoint has been reached, and
1733 stop if so; read commands from the user, parse them, and execute
1734 them, and then send execution off to the next statement.
1735
1736 Note that the order in which the commands are processed is very important;
1737 some commands earlier in the loop will actually alter the C<$cmd> variable
1738 to create other commands to be executed later. This is all highly I<optimized>
1739 but can be confusing. Check the comments for each C<$cmd ... && do {}> to
1740 see what's happening in any given command.
1741
1742 =cut
1743
1744 # $cmd cannot be an our() variable unfortunately (possible perl bug?).
1745
1746 use vars qw(
1747     $action
1748     $cmd
1749     $fall_off_end
1750     $file
1751     $filename_ini
1752     $finished
1753     %had_breakpoints
1754     $level
1755     $max
1756     $package
1757     $sh
1758     $try
1759 );
1760
1761 our (
1762     %alias,
1763     $doret,
1764     $end,
1765     $incr,
1766     $laststep,
1767     $rc,
1768     $stack_depth,
1769     @stack,
1770     @to_watch,
1771     @old_watch,
1772 );
1773
1774 sub _DB__determine_if_we_should_break
1775 {
1776     # if we have something here, see if we should break.
1777     # $stop is lexical and local to this block - $action on the other hand
1778     # is global.
1779     my $stop;
1780
1781     if ( $dbline{$line}
1782         && _is_breakpoint_enabled($filename, $line)
1783         && (( $stop, $action ) = split( /\0/, $dbline{$line} ) ) )
1784     {
1785
1786         # Stop if the stop criterion says to just stop.
1787         if ( $stop eq '1' ) {
1788             $signal |= 1;
1789         }
1790
1791         # It's a conditional stop; eval it in the user's context and
1792         # see if we should stop. If so, remove the one-time sigil.
1793         elsif ($stop) {
1794             $evalarg = "\$DB::signal |= 1 if do {$stop}";
1795             DB::eval();
1796             # If the breakpoint is temporary, then delete its enabled status.
1797             if ($dbline{$line} =~ s/;9($|\0)/$1/) {
1798                 _cancel_breakpoint_temp_enabled_status($filename, $line);
1799             }
1800         }
1801     } ## end if ($dbline{$line} && ...
1802 }
1803
1804 sub _DB__is_finished {
1805     if ($finished and $level <= 1) {
1806         end_report();
1807         return 1;
1808     }
1809     else {
1810         return;
1811     }
1812 }
1813
1814 sub _DB__read_next_cmd
1815 {
1816     my ($tid) = @_;
1817
1818     # We have a terminal, or can get one ...
1819     if (!$term) {
1820         setterm();
1821     }
1822
1823     # ... and it belogs to this PID or we get one for this PID ...
1824     if ($term_pid != $$) {
1825         resetterm(1);
1826     }
1827
1828     # ... and we got a line of command input ...
1829     $cmd = DB::readline(
1830         "$pidprompt $tid DB"
1831         . ( '<' x $level )
1832         . ( $#hist + 1 )
1833         . ( '>' x $level ) . " "
1834     );
1835
1836     return defined($cmd);
1837 }
1838
1839 sub _DB__trim_command_and_return_first_component {
1840     $cmd =~ s/\A\s+//s;    # trim annoying leading whitespace
1841     $cmd =~ s/\s+\z//s;    # trim annoying trailing whitespace
1842
1843     $cmd =~ m{\A(\S*)};
1844     return $1;
1845 }
1846
1847 sub _DB__handle_f_command {
1848     if (($file) = $cmd =~ /\Af\b\s*(.*)/) {
1849         $file =~ s/\s+$//;
1850
1851         # help for no arguments (old-style was return from sub).
1852         if ( !$file ) {
1853             print $OUT
1854             "The old f command is now the r command.\n";    # hint
1855             print $OUT "The new f command switches filenames.\n";
1856             next CMD;
1857         } ## end if (!$file)
1858
1859         # if not in magic file list, try a close match.
1860         if ( !defined $main::{ '_<' . $file } ) {
1861             if ( ($try) = grep( m#^_<.*$file#, keys %main:: ) ) {
1862                 {
1863                     $try = substr( $try, 2 );
1864                     print $OUT "Choosing $try matching '$file':\n";
1865                     $file = $try;
1866                 }
1867             } ## end if (($try) = grep(m#^_<.*$file#...
1868         } ## end if (!defined $main::{ ...
1869
1870         # If not successfully switched now, we failed.
1871         if ( !defined $main::{ '_<' . $file } ) {
1872             print $OUT "No file matching '$file' is loaded.\n";
1873             next CMD;
1874         }
1875
1876         # We switched, so switch the debugger internals around.
1877         elsif ( $file ne $filename ) {
1878             *dbline   = $main::{ '_<' . $file };
1879             $max      = $#dbline;
1880             $filename = $file;
1881             $start    = 1;
1882             $cmd      = "l";
1883         } ## end elsif ($file ne $filename)
1884
1885         # We didn't switch; say we didn't.
1886         else {
1887             print $OUT "Already in $file.\n";
1888             next CMD;
1889         }
1890     }
1891
1892     return;
1893 }
1894
1895 sub _DB__handle_dot_command {
1896     my ($obj) = @_;
1897
1898     # . command.
1899     if ($cmd eq '.') {
1900         $incr = -1;    # stay at current line
1901
1902         # Reset everything to the old location.
1903         $start    = $line;
1904         $filename = $filename_ini;
1905         *dbline   = $main::{ '_<' . $filename };
1906         $max      = $#dbline;
1907
1908         # Now where are we?
1909         print_lineinfo($obj->position());
1910         next CMD;
1911     }
1912
1913     return;
1914 }
1915
1916 sub _DB__handle_y_command {
1917     my ($obj) = @_;
1918
1919     if (my ($match_level, $match_vars)
1920         = $cmd =~ /^y(?:\s+(\d*)\s*(.*))?$/) {
1921
1922         # See if we've got the necessary support.
1923         if (!eval { require PadWalker; PadWalker->VERSION(0.08) }) {
1924             my $Err = $@;
1925             DB::warn(
1926                 $Err =~ /locate/
1927                 ? "PadWalker module not found - please install\n"
1928                 : $Err
1929             );
1930             next CMD;
1931         }
1932
1933         # Load up dumpvar if we don't have it. If we can, that is.
1934         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
1935         defined &main::dumpvar
1936             or print $OUT "dumpvar.pl not available.\n"
1937             and next CMD;
1938
1939         # Got all the modules we need. Find them and print them.
1940         my @vars = split( ' ', $match_vars || '' );
1941
1942         # Find the pad.
1943         my $h = eval { PadWalker::peek_my( ( $match_level || 0 ) + 1 ) };
1944
1945         # Oops. Can't find it.
1946         if (my $Err = $@) {
1947             $Err =~ s/ at .*//;
1948             DB::warn($Err);
1949             next CMD;
1950         }
1951
1952         # Show the desired vars with dumplex().
1953         my $savout = select($OUT);
1954
1955         # Have dumplex dump the lexicals.
1956         foreach my $key (sort keys %$h) {
1957             dumpvar::dumplex( $key, $h->{$key},
1958                 defined $option{dumpDepth} ? $option{dumpDepth} : -1,
1959                 @vars );
1960         }
1961         select($savout);
1962         next CMD;
1963     }
1964 }
1965
1966 sub _DB__handle_c_command {
1967     my ($obj) = @_;
1968
1969     if (my ($new_i) = $cmd =~ m#\Ac\b\s*([\w:]*)\s*\z#) {
1970
1971         $obj->i_cmd($new_i);
1972
1973         # Hey, show's over. The debugged program finished
1974         # executing already.
1975         next CMD if _DB__is_finished();
1976
1977         # Capture the place to put a one-time break.
1978         $subname = $obj->i_cmd;
1979
1980         #  Probably not needed, since we finish an interactive
1981         #  sub-session anyway...
1982         # local $filename = $filename;
1983         # local *dbline = *dbline; # XXX Would this work?!
1984         #
1985         # The above question wonders if localizing the alias
1986         # to the magic array works or not. Since it's commented
1987         # out, we'll just leave that to speculation for now.
1988
1989         # If the "subname" isn't all digits, we'll assume it
1990         # is a subroutine name, and try to find it.
1991         if ( $subname =~ /\D/ ) {    # subroutine name
1992             # Qualify it to the current package unless it's
1993             # already qualified.
1994             $subname = $package . "::" . $subname
1995             unless $subname =~ /::/;
1996
1997             # find_sub will return "file:line_number" corresponding
1998             # to where the subroutine is defined; we call find_sub,
1999             # break up the return value, and assign it in one
2000             # operation.
2001             ( $file, $new_i ) = ( find_sub($subname) =~ /^(.*):(.*)$/ );
2002
2003             # Force the line number to be numeric.
2004             $obj->i_cmd($new_i + 0);
2005
2006             # If we got a line number, we found the sub.
2007             if ($obj->i_cmd) {
2008
2009                 # Switch all the debugger's internals around so
2010                 # we're actually working with that file.
2011                 $filename = $file;
2012                 *dbline   = $main::{ '_<' . $filename };
2013
2014                 # Mark that there's a breakpoint in this file.
2015                 $had_breakpoints{$filename} |= 1;
2016
2017                 # Scan forward to the first executable line
2018                 # after the 'sub whatever' line.
2019                 $max = $#dbline;
2020                 my $ii = $obj->i_cmd;
2021                 ++$ii while $dbline[$ii] == 0 && $ii < $max;
2022                 $obj->i_cmd($ii);
2023             } ## end if ($i)
2024
2025             # We didn't find a sub by that name.
2026             else {
2027                 print $OUT "Subroutine $subname not found.\n";
2028                 next CMD;
2029             }
2030         } ## end if ($subname =~ /\D/)
2031
2032         # At this point, either the subname was all digits (an
2033         # absolute line-break request) or we've scanned through
2034         # the code following the definition of the sub, looking
2035         # for an executable, which we may or may not have found.
2036         #
2037         # If $i (which we set $subname from) is non-zero, we
2038         # got a request to break at some line somewhere. On
2039         # one hand, if there wasn't any real subroutine name
2040         # involved, this will be a request to break in the current
2041         # file at the specified line, so we have to check to make
2042         # sure that the line specified really is breakable.
2043         #
2044         # On the other hand, if there was a subname supplied, the
2045         # preceding block has moved us to the proper file and
2046         # location within that file, and then scanned forward
2047         # looking for the next executable line. We have to make
2048         # sure that one was found.
2049         #
2050         # On the gripping hand, we can't do anything unless the
2051         # current value of $i points to a valid breakable line.
2052         # Check that.
2053         if ($obj->i_cmd) {
2054
2055             # Breakable?
2056             if ( $dbline[$obj->i_cmd] == 0 ) {
2057                 print $OUT "Line " . $obj->i_cmd . " not breakable.\n";
2058                 next CMD;
2059             }
2060
2061             # Yes. Set up the one-time-break sigil.
2062             $dbline{$obj->i_cmd} =~ s/($|\0)/;9$1/;  # add one-time-only b.p.
2063             _enable_breakpoint_temp_enabled_status($filename, $obj->i_cmd);
2064         } ## end if ($i)
2065
2066         # Turn off stack tracing from here up.
2067         for my $i (0 .. $stack_depth) {
2068             $stack[ $i ] &= ~1;
2069         }
2070         last CMD;
2071     }
2072
2073     return;
2074 }
2075
2076 sub _DB__handle_forward_slash_command {
2077     my ($obj) = @_;
2078
2079     # The pattern as a string.
2080     use vars qw($inpat);
2081
2082     if (($inpat) = $cmd =~ m#\A/(.*)\z#) {
2083
2084         # Remove the final slash.
2085         $inpat =~ s:([^\\])/$:$1:;
2086
2087         # If the pattern isn't null ...
2088         if ( $inpat ne "" ) {
2089
2090             # Turn of warn and die procesing for a bit.
2091             local $SIG{__DIE__};
2092             local $SIG{__WARN__};
2093
2094             # Create the pattern.
2095             eval 'no strict q/vars/; $inpat =~ m' . "\a$inpat\a";
2096             if ( $@ ne "" ) {
2097
2098                 # Oops. Bad pattern. No biscuit.
2099                 # Print the eval error and go back for more
2100                 # commands.
2101                 print $OUT "$@";
2102                 next CMD;
2103             }
2104             $obj->pat($inpat);
2105         } ## end if ($inpat ne "")
2106
2107         # Set up to stop on wrap-around.
2108         $end = $start;
2109
2110         # Don't move off the current line.
2111         $incr = -1;
2112
2113         my $pat = $obj->pat;
2114
2115         # Done in eval so nothing breaks if the pattern
2116         # does something weird.
2117         eval
2118         {
2119             no strict q/vars/;
2120             for (;;) {
2121                 # Move ahead one line.
2122                 ++$start;
2123
2124                 # Wrap if we pass the last line.
2125                 $start = 1 if ($start > $max);
2126
2127                 # Stop if we have gotten back to this line again,
2128                 last if ($start == $end);
2129
2130                 # A hit! (Note, though, that we are doing
2131                 # case-insensitive matching. Maybe a qr//
2132                 # expression would be better, so the user could
2133                 # do case-sensitive matching if desired.
2134                 if ($dbline[$start] =~ m/$pat/i) {
2135                     if ($slave_editor) {
2136                         # Handle proper escaping in the slave.
2137                         print $OUT "\032\032$filename:$start:0\n";
2138                     }
2139                     else {
2140                         # Just print the line normally.
2141                         print $OUT "$start:\t",$dbline[$start],"\n";
2142                     }
2143                     # And quit since we found something.
2144                     last;
2145                 }
2146             }
2147         };
2148
2149         if ($@) {
2150             warn $@;
2151         }
2152
2153         # If we wrapped, there never was a match.
2154         if ( $start == $end ) {
2155             print {$OUT} "/$pat/: not found\n";
2156         }
2157         next CMD;
2158     }
2159
2160     return;
2161 }
2162
2163 sub _DB__handle_question_mark_command {
2164     my ($obj) = @_;
2165
2166     # ? - backward pattern search.
2167     if (my ($inpat) = $cmd =~ m#\A\?(.*)\z#) {
2168
2169         # Get the pattern, remove trailing question mark.
2170         $inpat =~ s:([^\\])\?$:$1:;
2171
2172         # If we've got one ...
2173         if ( $inpat ne "" ) {
2174
2175             # Turn off die & warn handlers.
2176             local $SIG{__DIE__};
2177             local $SIG{__WARN__};
2178             eval '$inpat =~ m' . "\a$inpat\a";
2179
2180             if ( $@ ne "" ) {
2181
2182                 # Ouch. Not good. Print the error.
2183                 print $OUT $@;
2184                 next CMD;
2185             }
2186             $obj->pat($inpat);
2187         } ## end if ($inpat ne "")
2188
2189         # Where we are now is where to stop after wraparound.
2190         $end = $start;
2191
2192         # Don't move away from this line.
2193         $incr = -1;
2194
2195         my $pat = $obj->pat;
2196         # Search inside the eval to prevent pattern badness
2197         # from killing us.
2198         eval {
2199             no strict q/vars/;
2200             for (;;) {
2201                 # Back up a line.
2202                 --$start;
2203
2204                 # Wrap if we pass the first line.
2205
2206                 $start = $max if ($start <= 0);
2207
2208                 # Quit if we get back where we started,
2209                 last if ($start == $end);
2210
2211                 # Match?
2212                 if ($dbline[$start] =~ m/$pat/i) {
2213                     if ($slave_editor) {
2214                         # Yep, follow slave editor requirements.
2215                         print $OUT "\032\032$filename:$start:0\n";
2216                     }
2217                     else {
2218                         # Yep, just print normally.
2219                         print $OUT "$start:\t",$dbline[$start],"\n";
2220                     }
2221
2222                     # Found, so done.
2223                     last;
2224                 }
2225             }
2226         };
2227
2228         # Say we failed if the loop never found anything,
2229         if ( $start == $end ) {
2230             print {$OUT} "?$pat?: not found\n";
2231         }
2232         next CMD;
2233     }
2234
2235     return;
2236 }
2237
2238 sub _DB__handle_restart_and_rerun_commands {
2239     my ($obj) = @_;
2240
2241     # R - restart execution.
2242     # rerun - controlled restart execution.
2243     if (my ($cmd_cmd, $cmd_params) =
2244         $cmd =~ /\A((?:R)|(?:rerun\s*(.*)))\z/) {
2245         my @args = ($cmd_cmd eq 'R' ? restart() : rerun($cmd_params));
2246
2247         # Close all non-system fds for a clean restart.  A more
2248         # correct method would be to close all fds that were not
2249         # open when the process started, but this seems to be
2250         # hard.  See "debugger 'R'estart and open database
2251         # connections" on p5p.
2252
2253         my $max_fd = 1024; # default if POSIX can't be loaded
2254         if (eval { require POSIX }) {
2255             eval { $max_fd = POSIX::sysconf(POSIX::_SC_OPEN_MAX()) };
2256         }
2257
2258         if (defined $max_fd) {
2259             foreach ($^F+1 .. $max_fd-1) {
2260                 next unless open FD_TO_CLOSE, "<&=$_";
2261                 close(FD_TO_CLOSE);
2262             }
2263         }
2264
2265         # And run Perl again.  We use exec() to keep the
2266         # PID stable (and that way $ini_pids is still valid).
2267         exec(@args) or print {$OUT} "exec failed: $!\n";
2268
2269         last CMD;
2270     }
2271
2272     return;
2273 }
2274
2275 sub _DB__handle_run_command_in_pager_command {
2276     my ($obj) = @_;
2277
2278     if ($cmd =~ m#\A\|\|?\s*[^|]#) {
2279         if ( $pager =~ /^\|/ ) {
2280
2281             # Default pager is into a pipe. Redirect I/O.
2282             open( SAVEOUT, ">&STDOUT" )
2283             || DB::warn("Can't save STDOUT");
2284             open( STDOUT, ">&OUT" )
2285             || DB::warn("Can't redirect STDOUT");
2286         } ## end if ($pager =~ /^\|/)
2287         else {
2288
2289             # Not into a pipe. STDOUT is safe.
2290             open( SAVEOUT, ">&OUT" ) || &warn("Can't save DB::OUT");
2291         }
2292
2293         # Fix up environment to record we have less if so.
2294         fix_less();
2295
2296         unless ( $obj->piped(scalar ( open( OUT, $pager ) ) ) ) {
2297
2298             # Couldn't open pipe to pager.
2299             DB::warn("Can't pipe output to '$pager'");
2300             if ( $pager =~ /^\|/ ) {
2301
2302                 # Redirect I/O back again.
2303                 open( OUT, ">&STDOUT" )    # XXX: lost message
2304                 || DB::warn("Can't restore DB::OUT");
2305                 open( STDOUT, ">&SAVEOUT" )
2306                 || DB::warn("Can't restore STDOUT");
2307                 close(SAVEOUT);
2308             } ## end if ($pager =~ /^\|/)
2309             else {
2310
2311                 # Redirect I/O. STDOUT already safe.
2312                 open( OUT, ">&STDOUT" )    # XXX: lost message
2313                 || DB::warn("Can't restore DB::OUT");
2314             }
2315             next CMD;
2316         } ## end unless ($piped = open(OUT,...
2317
2318         # Set up broken-pipe handler if necessary.
2319         $SIG{PIPE} = \&DB::catch
2320         if $pager =~ /^\|/
2321         && ( "" eq $SIG{PIPE} || "DEFAULT" eq $SIG{PIPE} );
2322
2323         OUT->autoflush(1);
2324         # Save current filehandle, and put it back.
2325         $obj->selected(scalar( select(OUT) ));
2326         # Don't put it back if pager was a pipe.
2327         if ($cmd !~ /\A\|\|/)
2328         {
2329             select($obj->selected());
2330             $obj->selected("");
2331         }
2332
2333         # Trim off the pipe symbols and run the command now.
2334         $cmd =~ s#\A\|+\s*##;
2335         redo PIPE;
2336     }
2337
2338     return;
2339 }
2340
2341
2342 sub DB {
2343
2344     # lock the debugger and get the thread id for the prompt
2345     lock($DBGR);
2346     my $tid;
2347     my $position;
2348     my ($prefix, $after, $infix);
2349     my $pat;
2350     my $explicit_stop;
2351     my $piped;
2352     my $selected;
2353
2354     if ($ENV{PERL5DB_THREADED}) {
2355         $tid = eval { "[".threads->tid."]" };
2356     }
2357
2358     my $i;
2359
2360     my $obj = DB::Obj->new(
2361         {
2362             position => \$position,
2363             prefix => \$prefix,
2364             after => \$after,
2365             explicit_stop => \$explicit_stop,
2366             infix => \$infix,
2367             i_cmd => \$i,
2368             pat => \$pat,
2369             piped => \$piped,
2370             selected => \$selected,
2371         },
2372     );
2373
2374     $obj->_DB_on_init__initialize_globals(@_);
2375
2376     # Preserve current values of $@, $!, $^E, $,, $/, $\, $^W.
2377     # The code being debugged may have altered them.
2378     &save;
2379
2380     # Since DB::DB gets called after every line, we can use caller() to
2381     # figure out where we last were executing. Sneaky, eh? This works because
2382     # caller is returning all the extra information when called from the
2383     # debugger.
2384     local ( $package, $filename, $line ) = caller;
2385     $filename_ini = $filename;
2386
2387     # set up the context for DB::eval, so it can properly execute
2388     # code on behalf of the user. We add the package in so that the
2389     # code is eval'ed in the proper package (not in the debugger!).
2390     local $usercontext = _calc_usercontext($package);
2391
2392     # Create an alias to the active file magical array to simplify
2393     # the code here.
2394     local (*dbline) = $main::{ '_<' . $filename };
2395
2396     # Last line in the program.
2397     $max = $#dbline;
2398
2399     _DB__determine_if_we_should_break(@_);
2400
2401     # Preserve the current stop-or-not, and see if any of the W
2402     # (watch expressions) has changed.
2403     my $was_signal = $signal;
2404
2405     # If we have any watch expressions ...
2406     $obj->_DB__handle_watch_expressions(@_);
2407
2408 =head2 C<watchfunction()>
2409
2410 C<watchfunction()> is a function that can be defined by the user; it is a
2411 function which will be run on each entry to C<DB::DB>; it gets the
2412 current package, filename, and line as its parameters.
2413
2414 The watchfunction can do anything it likes; it is executing in the
2415 debugger's context, so it has access to all of the debugger's internal
2416 data structures and functions.
2417
2418 C<watchfunction()> can control the debugger's actions. Any of the following
2419 will cause the debugger to return control to the user's program after
2420 C<watchfunction()> executes:
2421
2422 =over 4
2423
2424 =item *
2425
2426 Returning a false value from the C<watchfunction()> itself.
2427
2428 =item *
2429
2430 Altering C<$single> to a false value.
2431
2432 =item *
2433
2434 Altering C<$signal> to a false value.
2435
2436 =item *
2437
2438 Turning off the C<4> bit in C<$trace> (this also disables the
2439 check for C<watchfunction()>. This can be done with
2440
2441     $trace &= ~4;
2442
2443 =back
2444
2445 =cut
2446
2447     # If there's a user-defined DB::watchfunction, call it with the
2448     # current package, filename, and line. The function executes in
2449     # the DB:: package.
2450     if ( $trace & 4 ) {    # User-installed watch
2451         return
2452           if watchfunction( $package, $filename, $line )
2453           and not $single
2454           and not $was_signal
2455           and not( $trace & ~4 );
2456     } ## end if ($trace & 4)
2457
2458     # Pick up any alteration to $signal in the watchfunction, and
2459     # turn off the signal now.
2460     $was_signal = $signal;
2461     $signal     = 0;
2462
2463 =head2 GETTING READY TO EXECUTE COMMANDS
2464
2465 The debugger decides to take control if single-step mode is on, the
2466 C<t> command was entered, or the user generated a signal. If the program
2467 has fallen off the end, we set things up so that entering further commands
2468 won't cause trouble, and we say that the program is over.
2469
2470 =cut
2471
2472     # Make sure that we always print if asked for explicitly regardless
2473     # of $trace_to_depth .
2474     $explicit_stop = ($single || $was_signal);
2475
2476     # Check to see if we should grab control ($single true,
2477     # trace set appropriately, or we got a signal).
2478     if ( $explicit_stop || ( $trace & 1 ) ) {
2479         $obj->_DB__grab_control(@_);
2480     } ## end if ($single || ($trace...
2481
2482 =pod
2483
2484 If there's an action to be executed for the line we stopped at, execute it.
2485 If there are any preprompt actions, execute those as well.
2486
2487 =cut
2488
2489     # If there's an action, do it now.
2490     if ($action) {
2491         $evalarg = $action;
2492         DB::eval();
2493     }
2494
2495     # Are we nested another level (e.g., did we evaluate a function
2496     # that had a breakpoint in it at the debugger prompt)?
2497     if ( $single || $was_signal ) {
2498
2499         # Yes, go down a level.
2500         local $level = $level + 1;
2501
2502         # Do any pre-prompt actions.
2503         foreach $evalarg (@$pre) {
2504             DB::eval();
2505         }
2506
2507         # Complain about too much recursion if we passed the limit.
2508         if ($single & 4) {
2509             print $OUT $stack_depth . " levels deep in subroutine calls!\n";
2510         }
2511
2512         # The line we're currently on. Set $incr to -1 to stay here
2513         # until we get a command that tells us to advance.
2514         $start = $line;
2515         $incr  = -1;      # for backward motion.
2516
2517         # Tack preprompt debugger actions ahead of any actual input.
2518         @typeahead = ( @$pretype, @typeahead );
2519
2520 =head2 WHERE ARE WE?
2521
2522 XXX Relocate this section?
2523
2524 The debugger normally shows the line corresponding to the current line of
2525 execution. Sometimes, though, we want to see the next line, or to move elsewhere
2526 in the file. This is done via the C<$incr>, C<$start>, and C<$max> variables.
2527
2528 C<$incr> controls by how many lines the I<current> line should move forward
2529 after a command is executed. If set to -1, this indicates that the I<current>
2530 line shouldn't change.
2531
2532 C<$start> is the I<current> line. It is used for things like knowing where to
2533 move forwards or backwards from when doing an C<L> or C<-> command.
2534
2535 C<$max> tells the debugger where the last line of the current file is. It's
2536 used to terminate loops most often.
2537
2538 =head2 THE COMMAND LOOP
2539
2540 Most of C<DB::DB> is actually a command parsing and dispatch loop. It comes
2541 in two parts:
2542
2543 =over 4
2544
2545 =item *
2546
2547 The outer part of the loop, starting at the C<CMD> label. This loop
2548 reads a command and then executes it.
2549
2550 =item *
2551
2552 The inner part of the loop, starting at the C<PIPE> label. This part
2553 is wholly contained inside the C<CMD> block and only executes a command.
2554 Used to handle commands running inside a pager.
2555
2556 =back
2557
2558 So why have two labels to restart the loop? Because sometimes, it's easier to
2559 have a command I<generate> another command and then re-execute the loop to do
2560 the new command. This is faster, but perhaps a bit more convoluted.
2561
2562 =cut
2563
2564         # The big command dispatch loop. It keeps running until the
2565         # user yields up control again.
2566         #
2567         # If we have a terminal for input, and we get something back
2568         # from readline(), keep on processing.
2569
2570       CMD:
2571         while (_DB__read_next_cmd($tid))
2572         {
2573
2574             share($cmd);
2575             # ... try to execute the input as debugger commands.
2576
2577             # Don't stop running.
2578             $single = 0;
2579
2580             # No signal is active.
2581             $signal = 0;
2582
2583             # Handle continued commands (ending with \):
2584             if ($cmd =~ s/\\\z/\n/) {
2585                 $cmd .= DB::readline("  cont: ");
2586                 redo CMD;
2587             }
2588
2589 =head4 The null command
2590
2591 A newline entered by itself means I<re-execute the last command>. We grab the
2592 command out of C<$laststep> (where it was recorded previously), and copy it
2593 back into C<$cmd> to be executed below. If there wasn't any previous command,
2594 we'll do nothing below (no command will match). If there was, we also save it
2595 in the command history and fall through to allow the command parsing to pick
2596 it up.
2597
2598 =cut
2599
2600             # Empty input means repeat the last command.
2601             if ($cmd eq '') {
2602                 $cmd = $laststep;
2603             }
2604             chomp($cmd);    # get rid of the annoying extra newline
2605             if (length($cmd) >= 2) {
2606                 push( @hist, $cmd );
2607             }
2608             push( @truehist, $cmd );
2609             share(@hist);
2610             share(@truehist);
2611
2612             # This is a restart point for commands that didn't arrive
2613             # via direct user input. It allows us to 'redo PIPE' to
2614             # re-execute command processing without reading a new command.
2615           PIPE: {
2616                 $i = _DB__trim_command_and_return_first_component();
2617
2618 =head3 COMMAND ALIASES
2619
2620 The debugger can create aliases for commands (these are stored in the
2621 C<%alias> hash). Before a command is executed, the command loop looks it up
2622 in the alias hash and substitutes the contents of the alias for the command,
2623 completely replacing it.
2624
2625 =cut
2626
2627                 # See if there's an alias for the command, and set it up if so.
2628                 if ( $alias{$i} ) {
2629
2630                     # Squelch signal handling; we want to keep control here
2631                     # if something goes loco during the alias eval.
2632                     local $SIG{__DIE__};
2633                     local $SIG{__WARN__};
2634
2635                     # This is a command, so we eval it in the DEBUGGER's
2636                     # scope! Otherwise, we can't see the special debugger
2637                     # variables, or get to the debugger's subs. (Well, we
2638                     # _could_, but why make it even more complicated?)
2639                     eval "\$cmd =~ $alias{$i}";
2640                     if ($@) {
2641                         local $\ = '';
2642                         print $OUT "Couldn't evaluate '$i' alias: $@";
2643                         next CMD;
2644                     }
2645                 } ## end if ($alias{$i})
2646
2647 =head3 MAIN-LINE COMMANDS
2648
2649 All of these commands work up to and after the program being debugged has
2650 terminated.
2651
2652 =head4 C<q> - quit
2653
2654 Quit the debugger. This entails setting the C<$fall_off_end> flag, so we don't
2655 try to execute further, cleaning any restart-related stuff out of the
2656 environment, and executing with the last value of C<$?>.
2657
2658 =cut
2659
2660                 if ($cmd eq 'q') {
2661                     $fall_off_end = 1;
2662                     clean_ENV();
2663                     exit $?;
2664                 }
2665
2666 =head4 C<t> - trace [n]
2667
2668 Turn tracing on or off. Inverts the appropriate bit in C<$trace> (q.v.).
2669 If level is specified, set C<$trace_to_depth>.
2670
2671 =cut
2672
2673                 $obj->_handle_t_command;
2674
2675 =head4 C<S> - list subroutines matching/not matching a pattern
2676
2677 Walks through C<%sub>, checking to see whether or not to print the name.
2678
2679 =cut
2680
2681                 $obj->_handle_S_command;
2682
2683 =head4 C<X> - list variables in current package
2684
2685 Since the C<V> command actually processes this, just change this to the
2686 appropriate C<V> command and fall through.
2687
2688 =head4 C<V> - list variables
2689
2690 Uses C<dumpvar.pl> to dump out the current values for selected variables.
2691
2692 =cut
2693
2694                 $obj->_handle_V_command_and_X_command;
2695
2696 =head4 C<x> - evaluate and print an expression
2697
2698 Hands the expression off to C<DB::eval>, setting it up to print the value
2699 via C<dumpvar.pl> instead of just printing it directly.
2700
2701 =cut
2702
2703                 if ($cmd =~ s#\Ax\b# #) {    # Remainder gets done by DB::eval()
2704                     $onetimeDump = 'dump';    # main::dumpvar shows the output
2705
2706                     # handle special  "x 3 blah" syntax XXX propagate
2707                     # doc back to special variables.
2708                     if ( $cmd =~ s#\A\s*(\d+)(?=\s)# #) {
2709                         $onetimedumpDepth = $1;
2710                     }
2711                 }
2712
2713 =head4 C<m> - print methods
2714
2715 Just uses C<DB::methods> to determine what methods are available.
2716
2717 =cut
2718
2719                 if ($cmd =~ s#\Am\s+([\w:]+)\s*\z# #) {
2720                     methods($1);
2721                     next CMD;
2722                 }
2723
2724                 # m expr - set up DB::eval to do the work
2725                 if ($cmd =~ s#\Am\b# #) {    # Rest gets done by DB::eval()
2726                     $onetimeDump = 'methods';   #  method output gets used there
2727                 }
2728
2729 =head4 C<f> - switch files
2730
2731 =cut
2732
2733                 _DB__handle_f_command();
2734
2735 =head4 C<.> - return to last-executed line.
2736
2737 We set C<$incr> to -1 to indicate that the debugger shouldn't move ahead,
2738 and then we look up the line in the magical C<%dbline> hash.
2739
2740 =cut
2741
2742         _DB__handle_dot_command($obj);
2743
2744 =head4 C<-> - back one window
2745
2746 We change C<$start> to be one window back; if we go back past the first line,
2747 we set it to be the first line. We ser C<$incr> to put us back at the
2748 currently-executing line, and then put a C<l $start +> (list one window from
2749 C<$start>) in C<$cmd> to be executed later.
2750
2751 =cut
2752
2753                 # - - back a window.
2754                 $obj->_handle_dash_command;
2755
2756 =head3 PRE-580 COMMANDS VS. NEW COMMANDS: C<a, A, b, B, h, l, L, M, o, O, P, v, w, W, E<lt>, E<lt>E<lt>, E<0x7B>, E<0x7B>E<0x7B>>
2757
2758 In Perl 5.8.0, a realignment of the commands was done to fix up a number of
2759 problems, most notably that the default case of several commands destroying
2760 the user's work in setting watchpoints, actions, etc. We wanted, however, to
2761 retain the old commands for those who were used to using them or who preferred
2762 them. At this point, we check for the new commands and call C<cmd_wrapper> to
2763 deal with them instead of processing them in-line.
2764
2765 =cut
2766
2767                 # All of these commands were remapped in perl 5.8.0;
2768                 # we send them off to the secondary dispatcher (see below).
2769                 if (my ($cmd_letter, $my_arg) = $cmd =~ /\A([aAbBeEhilLMoOPvwW]\b|[<>\{]{1,2})\s*(.*)/so) {
2770                     &cmd_wrapper( $cmd_letter, $my_arg, $line );
2771                     next CMD;
2772                 }
2773
2774 =head4 C<y> - List lexicals in higher scope
2775
2776 Uses C<PadWalker> to find the lexicals supplied as arguments in a scope
2777 above the current one and then displays then using C<dumpvar.pl>.
2778
2779 =cut
2780
2781                 _DB__handle_y_command($obj);
2782
2783 =head3 COMMANDS NOT WORKING AFTER PROGRAM ENDS
2784
2785 All of the commands below this point don't work after the program being
2786 debugged has ended. All of them check to see if the program has ended; this
2787 allows the commands to be relocated without worrying about a 'line of
2788 demarcation' above which commands can be entered anytime, and below which
2789 they can't.
2790
2791 =head4 C<n> - single step, but don't trace down into subs
2792
2793 Done by setting C<$single> to 2, which forces subs to execute straight through
2794 when entered (see C<DB::sub>). We also save the C<n> command in C<$laststep>,
2795 so a null command knows what to re-execute.
2796
2797 =cut
2798
2799                 # n - next
2800                 $obj->_handle_n_command;
2801
2802 =head4 C<s> - single-step, entering subs
2803
2804 Sets C<$single> to 1, which causes C<DB::sub> to continue tracing inside
2805 subs. Also saves C<s> as C<$lastcmd>.
2806
2807 =cut
2808
2809                 $obj->_handle_s_command;
2810
2811 =head4 C<c> - run continuously, setting an optional breakpoint
2812
2813 Most of the code for this command is taken up with locating the optional
2814 breakpoint, which is either a subroutine name or a line number. We set
2815 the appropriate one-time-break in C<@dbline> and then turn off single-stepping
2816 in this and all call levels above this one.
2817
2818 =cut
2819
2820                 # c - start continuous execution.
2821                 _DB__handle_c_command($obj);
2822
2823 =head4 C<r> - return from a subroutine
2824
2825 For C<r> to work properly, the debugger has to stop execution again
2826 immediately after the return is executed. This is done by forcing
2827 single-stepping to be on in the call level above the current one. If
2828 we are printing return values when a C<r> is executed, set C<$doret>
2829 appropriately, and force us out of the command loop.
2830
2831 =cut
2832
2833                 # r - return from the current subroutine.
2834                 $obj->_handle_r_command;
2835
2836 =head4 C<T> - stack trace
2837
2838 Just calls C<DB::print_trace>.
2839
2840 =cut
2841
2842                 $obj->_handle_T_command;
2843
2844 =head4 C<w> - List window around current line.
2845
2846 Just calls C<DB::cmd_w>.
2847
2848 =cut
2849
2850                 $obj->_handle_w_command;
2851
2852 =head4 C<W> - watch-expression processing.
2853
2854 Just calls C<DB::cmd_W>.
2855
2856 =cut
2857
2858                 $obj->_handle_W_command;
2859
2860 =head4 C</> - search forward for a string in the source
2861
2862 We take the argument and treat it as a pattern. If it turns out to be a
2863 bad one, we return the error we got from trying to C<eval> it and exit.
2864 If not, we create some code to do the search and C<eval> it so it can't
2865 mess us up.
2866
2867 =cut
2868
2869                 _DB__handle_forward_slash_command($obj);
2870
2871 =head4 C<?> - search backward for a string in the source
2872
2873 Same as for C</>, except the loop runs backwards.
2874
2875 =cut
2876
2877                 _DB__handle_question_mark_command($obj);
2878
2879 =head4 C<$rc> - Recall command
2880
2881 Manages the commands in C<@hist> (which is created if C<Term::ReadLine> reports
2882 that the terminal supports history). It find the the command required, puts it
2883 into C<$cmd>, and redoes the loop to execute it.
2884
2885 =cut
2886
2887                 # $rc - recall command.
2888                 $obj->_handle_rc_recall_command;
2889
2890 =head4 C<$sh$sh> - C<system()> command
2891
2892 Calls the C<DB::system()> to handle the command. This keeps the C<STDIN> and
2893 C<STDOUT> from getting messed up.
2894
2895 =cut
2896
2897                 # $sh$sh - run a shell command (if it's all ASCII).
2898                 # Can't run shell commands with Unicode in the debugger, hmm.
2899                 if (my ($arg) = $cmd =~ m#\A$sh$sh\s*(.*)#ms) {
2900
2901                     # System it.
2902                     DB::system($arg);
2903                     next CMD;
2904                 }
2905
2906 =head4 C<$rc I<pattern> $rc> - Search command history
2907
2908 Another command to manipulate C<@hist>: this one searches it with a pattern.
2909 If a command is found, it is placed in C<$cmd> and executed via C<redo>.
2910
2911 =cut
2912
2913                 $obj->_handle_rc_search_history_command;
2914
2915 =head4 C<$sh> - Invoke a shell
2916
2917 Uses C<DB::system> to invoke a shell.
2918
2919 =cut
2920
2921                 # $sh - start a shell.
2922                 if ($cmd =~ /\A$sh\z/) {
2923
2924                     # Run the user's shell. If none defined, run Bourne.
2925                     # We resume execution when the shell terminates.
2926                     &system( $ENV{SHELL} || "/bin/sh" );
2927                     next CMD;
2928                 }
2929
2930 =head4 C<$sh I<command>> - Force execution of a command in a shell
2931
2932 Like the above, but the command is passed to the shell. Again, we use
2933 C<DB::system> to avoid problems with C<STDIN> and C<STDOUT>.
2934
2935 =cut
2936
2937                 # $sh command - start a shell and run a command in it.
2938                 if (my ($arg) = $cmd =~ m#\A$sh\s*(.*)#ms) {
2939
2940                     # XXX: using csh or tcsh destroys sigint retvals!
2941                     #&system($1);  # use this instead
2942
2943                     # use the user's shell, or Bourne if none defined.
2944                     &system( $ENV{SHELL} || "/bin/sh", "-c", $arg );
2945                     next CMD;
2946                 }
2947
2948 =head4 C<H> - display commands in history
2949
2950 Prints the contents of C<@hist> (if any).
2951
2952 =cut
2953
2954                 $obj->_handle_H_command;
2955
2956 =head4 C<man, doc, perldoc> - look up documentation
2957
2958 Just calls C<runman()> to print the appropriate document.
2959
2960 =cut
2961
2962                 $obj->_handle_doc_command;
2963
2964 =head4 C<p> - print
2965
2966 Builds a C<print EXPR> expression in the C<$cmd>; this will get executed at
2967 the bottom of the loop.
2968
2969 =cut
2970
2971                 $obj->_handle_p_command;
2972
2973 =head4 C<=> - define command alias
2974
2975 Manipulates C<%alias> to add or list command aliases.
2976
2977 =cut
2978
2979                 # = - set up a command alias.
2980                 $obj->_handle_equal_sign_command;
2981
2982 =head4 C<source> - read commands from a file.
2983
2984 Opens a lexical filehandle and stacks it on C<@cmdfhs>; C<DB::readline> will
2985 pick it up.
2986
2987 =cut
2988
2989                 $obj->_handle_source_command;
2990
2991 =head4 C<enable> C<disable> - enable or disable breakpoints
2992
2993 This enables or disables breakpoints.
2994
2995 =cut
2996
2997                 $obj->_handle_enable_disable_commands;
2998
2999 =head4 C<save> - send current history to a file
3000
3001 Takes the complete history, (not the shrunken version you see with C<H>),
3002 and saves it to the given filename, so it can be replayed using C<source>.
3003
3004 Note that all C<^(save|source)>'s are commented out with a view to minimise recursion.
3005
3006 =cut
3007
3008                 # save source - write commands to a file for later use
3009                 $obj->_handle_save_command;
3010
3011 =head4 C<R> - restart
3012
3013 Restart the debugger session.
3014
3015 =head4 C<rerun> - rerun the current session
3016
3017 Return to any given position in the B<true>-history list
3018
3019 =cut
3020
3021                 # R - restart execution.
3022                 # rerun - controlled restart execution.
3023                 _DB__handle_restart_and_rerun_commands($obj);
3024
3025 =head4 C<|, ||> - pipe output through the pager.
3026
3027 For C<|>, we save C<OUT> (the debugger's output filehandle) and C<STDOUT>
3028 (the program's standard output). For C<||>, we only save C<OUT>. We open a
3029 pipe to the pager (restoring the output filehandles if this fails). If this
3030 is the C<|> command, we also set up a C<SIGPIPE> handler which will simply
3031 set C<$signal>, sending us back into the debugger.
3032
3033 We then trim off the pipe symbols and C<redo> the command loop at the
3034 C<PIPE> label, causing us to evaluate the command in C<$cmd> without
3035 reading another.
3036
3037 =cut
3038
3039                 # || - run command in the pager, with output to DB::OUT.
3040                 _DB__handle_run_command_in_pager_command($obj);
3041
3042 =head3 END OF COMMAND PARSING
3043
3044 Anything left in C<$cmd> at this point is a Perl expression that we want to
3045 evaluate. We'll always evaluate in the user's context, and fully qualify
3046 any variables we might want to address in the C<DB> package.
3047
3048 =cut
3049
3050                 # s - single-step. Remember the last command was 's'.
3051                 if ($cmd =~ s/\As\s/\$DB::single = 1;\n/) {
3052                     $laststep = 's';
3053                 }
3054
3055                 # n - single-step, but not into subs. Remember last command
3056                 # was 'n'.
3057                 if ($cmd =~ s#\An\s#\$DB::single = 2;\n#) {
3058                     $laststep = 'n';
3059                 }
3060
3061             }    # PIPE:
3062
3063             # Make sure the flag that says "the debugger's running" is
3064             # still on, to make sure we get control again.
3065             $evalarg = "\$^D = \$^D | \$DB::db_stop;\n$cmd";
3066
3067             # Run *our* eval that executes in the caller's context.
3068             DB::eval();
3069
3070             # Turn off the one-time-dump stuff now.
3071             if ($onetimeDump) {
3072                 $onetimeDump      = undef;
3073                 $onetimedumpDepth = undef;
3074             }
3075             elsif ( $term_pid == $$ ) {
3076                 eval { # May run under miniperl, when not available...
3077                     STDOUT->flush();
3078                     STDERR->flush();
3079                 };
3080
3081                 # XXX If this is the master pid, print a newline.
3082                 print {$OUT} "\n";
3083             }
3084         } ## end while (($term || &setterm...
3085
3086 =head3 POST-COMMAND PROCESSING
3087
3088 After each command, we check to see if the command output was piped anywhere.
3089 If so, we go through the necessary code to unhook the pipe and go back to
3090 our standard filehandles for input and output.
3091
3092 =cut
3093
3094         continue {    # CMD:
3095
3096             # At the end of every command:
3097             if ($piped) {
3098
3099                 # Unhook the pipe mechanism now.
3100                 if ( $pager =~ /^\|/ ) {
3101
3102                     # No error from the child.
3103                     $? = 0;
3104
3105                     # we cannot warn here: the handle is missing --tchrist
3106                     close(OUT) || print SAVEOUT "\nCan't close DB::OUT\n";
3107
3108                     # most of the $? crud was coping with broken cshisms
3109                     # $? is explicitly set to 0, so this never runs.
3110                     if ($?) {
3111                         print SAVEOUT "Pager '$pager' failed: ";
3112                         if ( $? == -1 ) {
3113                             print SAVEOUT "shell returned -1\n";
3114                         }
3115                         elsif ( $? >> 8 ) {
3116                             print SAVEOUT ( $? & 127 )
3117                               ? " (SIG#" . ( $? & 127 ) . ")"
3118                               : "", ( $? & 128 ) ? " -- core dumped" : "", "\n";
3119                         }
3120                         else {
3121                             print SAVEOUT "status ", ( $? >> 8 ), "\n";
3122                         }
3123                     } ## end if ($?)
3124
3125                     # Reopen filehandle for our output (if we can) and
3126                     # restore STDOUT (if we can).
3127                     open( OUT, ">&STDOUT" ) || &warn("Can't restore DB::OUT");
3128                     open( STDOUT, ">&SAVEOUT" )
3129                       || &warn("Can't restore STDOUT");
3130
3131                     # Turn off pipe exception handler if necessary.
3132                     $SIG{PIPE} = "DEFAULT" if $SIG{PIPE} eq \&DB::catch;
3133
3134                     # Will stop ignoring SIGPIPE if done like nohup(1)
3135                     # does SIGINT but Perl doesn't give us a choice.
3136                 } ## end if ($pager =~ /^\|/)
3137                 else {
3138
3139                     # Non-piped "pager". Just restore STDOUT.
3140                     open( OUT, ">&SAVEOUT" ) || &warn("Can't restore DB::OUT");
3141                 }
3142
3143                 # Close filehandle pager was using, restore the normal one
3144                 # if necessary,
3145                 close(SAVEOUT);
3146                 select($selected), $selected = "" unless $selected eq "";
3147
3148                 # No pipes now.
3149                 $piped = "";
3150             } ## end if ($piped)
3151         }    # CMD:
3152
3153 =head3 COMMAND LOOP TERMINATION
3154
3155 When commands have finished executing, we come here. If the user closed the
3156 input filehandle, we turn on C<$fall_off_end> to emulate a C<q> command. We
3157 evaluate any post-prompt items. We restore C<$@>, C<$!>, C<$^E>, C<$,>, C<$/>,
3158 C<$\>, and C<$^W>, and return a null list as expected by the Perl interpreter.
3159 The interpreter will then execute the next line and then return control to us
3160 again.
3161
3162 =cut
3163
3164         # No more commands? Quit.
3165         $fall_off_end = 1 unless defined $cmd;    # Emulate 'q' on EOF
3166
3167         # Evaluate post-prompt commands.
3168         foreach $evalarg (@$post) {
3169             DB::eval();
3170         }
3171     }    # if ($single || $signal)
3172
3173     # Put the user's globals back where you found them.
3174     ( $@, $!, $^E, $,, $/, $\, $^W ) = @saved;
3175     ();
3176 } ## end sub DB
3177
3178 package DB::Obj;
3179
3180 sub new {
3181     my $class = shift;
3182
3183     my $self = bless {}, $class;
3184
3185     $self->_init(@_);
3186
3187     return $self;
3188 }
3189
3190 sub _init {
3191     my ($self, $args) = @_;
3192
3193     %{$self} = (%$self, %$args);
3194
3195     return;
3196 }
3197
3198 {
3199     no strict 'refs';
3200     foreach my $slot_name (qw(
3201         after explicit_stop infix pat piped position prefix selected i_cmd
3202         )) {
3203         my $slot = $slot_name;
3204         *{$slot} = sub {
3205             my $self = shift;
3206
3207             if (@_) {
3208                 ${ $self->{$slot} } = shift;
3209             }
3210
3211             return ${ $self->{$slot} };
3212         };
3213
3214         *{"append_to_$slot"} = sub {
3215             my $self = shift;
3216             my $s = shift;
3217
3218             return $self->$slot($self->$slot . $s);
3219         };
3220     }
3221 }
3222
3223 sub _DB_on_init__initialize_globals
3224 {
3225     my $self = shift;
3226
3227     # Check for whether we should be running continuously or not.
3228     # _After_ the perl program is compiled, $single is set to 1:
3229     if ( $single and not $second_time++ ) {
3230
3231         # Options say run non-stop. Run until we get an interrupt.
3232         if ($runnonstop) {    # Disable until signal
3233                 # If there's any call stack in place, turn off single
3234                 # stepping into subs throughout the stack.
3235             for my $i (0 .. $stack_depth) {
3236                 $stack[ $i ] &= ~1;
3237             }
3238
3239             # And we are now no longer in single-step mode.
3240             $single = 0;
3241
3242             # If we simply returned at this point, we wouldn't get
3243             # the trace info. Fall on through.
3244             # return;
3245         } ## end if ($runnonstop)
3246
3247         elsif ($ImmediateStop) {
3248
3249             # We are supposed to stop here; XXX probably a break.
3250             $ImmediateStop = 0;    # We've processed it; turn it off
3251             $signal        = 1;    # Simulate an interrupt to force
3252                                    # us into the command loop
3253         }
3254     } ## end if ($single and not $second_time...
3255
3256     # If we're in single-step mode, or an interrupt (real or fake)
3257     # has occurred, turn off non-stop mode.
3258     $runnonstop = 0 if $single or $signal;
3259
3260     return;
3261 }
3262
3263 sub _DB__handle_watch_expressions
3264 {
3265     my $self = shift;
3266
3267     if ( $trace & 2 ) {
3268         for my $n (0 .. $#to_watch) {
3269             $evalarg = $to_watch[$n];
3270             local $onetimeDump;    # Tell DB::eval() to not output results
3271
3272             # Fix context DB::eval() wants to return an array, but
3273             # we need a scalar here.
3274             my ($val) = join( "', '", DB::eval() );
3275             $val = ( ( defined $val ) ? "'$val'" : 'undef' );
3276
3277             # Did it change?
3278             if ( $val ne $old_watch[$n] ) {
3279
3280                 # Yep! Show the difference, and fake an interrupt.
3281                 $signal = 1;
3282                 print {$OUT} <<EOP;
3283 Watchpoint $n:\t$to_watch[$n] changed:
3284     old value:\t$old_watch[$n]
3285     new value:\t$val
3286 EOP
3287                 $old_watch[$n] = $val;
3288             } ## end if ($val ne $old_watch...
3289         } ## end for my $n (0 ..
3290     } ## end if ($trace & 2)
3291
3292     return;
3293 }
3294
3295 sub _my_print_lineinfo
3296 {
3297     my ($self, $i, $incr_pos) = @_;
3298
3299     if ($frame) {
3300         # Print it indented if tracing is on.
3301         DB::print_lineinfo( ' ' x $stack_depth,
3302             "$i:\t$DB::dbline[$i]" . $self->after );
3303     }
3304     else {
3305         DB::depth_print_lineinfo($self->explicit_stop, $incr_pos);
3306     }
3307 }
3308
3309 sub _curr_line {
3310     return $DB::dbline[$line];
3311 }
3312
3313 sub _DB__grab_control
3314 {
3315     my $self = shift;
3316
3317     # Yes, grab control.
3318     if ($slave_editor) {
3319
3320         # Tell the editor to update its position.
3321         $self->position("\032\032${DB::filename}:$line:0\n");
3322         DB::print_lineinfo($self->position());
3323     }
3324
3325 =pod
3326
3327 Special check: if we're in package C<DB::fake>, we've gone through the
3328 C<END> block at least once. We set up everything so that we can continue
3329 to enter commands and have a valid context to be in.
3330
3331 =cut
3332
3333     elsif ( $DB::package eq 'DB::fake' ) {
3334
3335         # Fallen off the end already.
3336         if (!$DB::term) {
3337             DB::setterm();
3338         }
3339
3340         DB::print_help(<<EOP);
3341 Debugged program terminated.  Use B<q> to quit or B<R> to restart,
3342 use B<o> I<inhibit_exit> to avoid stopping after program termination,
3343 B<h q>, B<h R> or B<h o> to get additional info.
3344 EOP
3345
3346         # Set the DB::eval context appropriately.
3347         $DB::package     = 'main';
3348         $DB::usercontext = DB::_calc_usercontext($DB::package);
3349     } ## end elsif ($package eq 'DB::fake')
3350
3351 =pod
3352
3353 If the program hasn't finished executing, we scan forward to the
3354 next executable line, print that out, build the prompt from the file and line
3355 number information, and print that.
3356
3357 =cut
3358
3359     else {
3360
3361
3362         # Still somewhere in the midst of execution. Set up the
3363         #  debugger prompt.
3364         $DB::sub =~ s/\'/::/;    # Swap Perl 4 package separators (') to
3365                              # Perl 5 ones (sorry, we don't print Klingon
3366                              #module names)
3367
3368         $self->prefix($DB::sub =~ /::/ ? "" : ($DB::package . '::'));
3369         $self->append_to_prefix( "$DB::sub(${DB::filename}:" );
3370         $self->after( $self->_curr_line =~ /\n$/ ? '' : "\n" );
3371
3372         # Break up the prompt if it's really long.
3373         if ( length($self->prefix()) > 30 ) {
3374             $self->position($self->prefix . "$line):\n$line:\t" . $self->_curr_line . $self->after);
3375             $self->prefix("");
3376             $self->infix(":\t");
3377         }
3378         else {
3379             $self->infix("):\t");
3380             $self->position(
3381                 $self->prefix . $line. $self->infix
3382                 . $self->_curr_line . $self->after
3383             );
3384         }
3385
3386         # Print current line info, indenting if necessary.
3387         $self->_my_print_lineinfo($line, $self->position);
3388
3389         my $i;
3390         my $line_i = sub { return $DB::dbline[$i]; };
3391
3392         # Scan forward, stopping at either the end or the next
3393         # unbreakable line.
3394         for ( $i = $line + 1 ; $i <= $DB::max && $line_i->() == 0 ; ++$i )
3395         {    #{ vi
3396
3397             # Drop out on null statements, block closers, and comments.
3398             last if $line_i->() =~ /^\s*[\;\}\#\n]/;
3399
3400             # Drop out if the user interrupted us.
3401             last if $signal;
3402
3403             # Append a newline if the line doesn't have one. Can happen
3404             # in eval'ed text, for instance.
3405             $self->after( $line_i->() =~ /\n$/ ? '' : "\n" );
3406
3407             # Next executable line.
3408             my $incr_pos = $self->prefix . $i . $self->infix . $line_i->()
3409                 . $self->after;
3410             $self->append_to_position($incr_pos);
3411             $self->_my_print_lineinfo($i, $incr_pos);
3412         } ## end for ($i = $line + 1 ; $i...
3413     } ## end else [ if ($slave_editor)
3414
3415     return;
3416 }
3417
3418 sub _handle_t_command {
3419     if (my ($levels) = $DB::cmd =~ /\At(?:\s+(\d+))?\z/) {
3420         $trace ^= 1;
3421         local $\ = '';
3422         $DB::trace_to_depth = $levels ? $stack_depth + $levels : 1E9;
3423         print {$OUT} "Trace = "
3424         . ( ( $trace & 1 )
3425             ? ( $levels ? "on (to level $DB::trace_to_depth)" : "on" )
3426             : "off" ) . "\n";
3427         next CMD;
3428     }
3429
3430     return;
3431 }
3432
3433
3434 sub _handle_S_command {
3435     if (my ($print_all_subs, $should_reverse, $Spatt)
3436         = $DB::cmd =~ /\AS(\s+(!)?(.+))?\z/) {
3437         # $Spatt is the pattern (if any) to use.
3438         # Reverse scan?
3439         my $Srev     = defined $should_reverse;
3440         # No args - print all subs.
3441         my $Snocheck = !defined $print_all_subs;
3442
3443         # Need to make these sane here.
3444         local $\ = '';
3445         local $, = '';
3446
3447         # Search through the debugger's magical hash of subs.
3448         # If $nocheck is true, just print the sub name.
3449         # Otherwise, check it against the pattern. We then use
3450         # the XOR trick to reverse the condition as required.
3451         foreach $subname ( sort( keys %sub ) ) {
3452             if ( $Snocheck or $Srev ^ ( $subname =~ /$Spatt/ ) ) {
3453                 print $OUT $subname, "\n";
3454             }
3455         }
3456         next CMD;
3457     }
3458
3459     return;
3460 }
3461
3462 sub _handle_V_command_and_X_command {
3463
3464     $DB::cmd =~ s/^X\b/V $DB::package/;
3465
3466     # Bare V commands get the currently-being-debugged package
3467     # added.
3468     if ($DB::cmd eq "V") {
3469         $DB::cmd = "V $DB::package";
3470     }
3471
3472     # V - show variables in package.
3473     if (my ($new_packname, $new_vars_str) =
3474         $DB::cmd =~ /\AV\b\s*(\S+)\s*(.*)/) {
3475
3476         # Save the currently selected filehandle and
3477         # force output to debugger's filehandle (dumpvar
3478         # just does "print" for output).
3479         my $savout = select($OUT);
3480
3481         # Grab package name and variables to dump.
3482         $packname = $new_packname;
3483         my @vars     = split( ' ', $new_vars_str );
3484
3485         # If main::dumpvar isn't here, get it.
3486         do 'dumpvar.pl' || die $@ unless defined &main::dumpvar;
3487         if ( defined &main::dumpvar ) {
3488
3489             # We got it. Turn off subroutine entry/exit messages
3490             # for the moment, along with return values.
3491             local $frame = 0;
3492             local $doret = -2;
3493
3494             # must detect sigpipe failures  - not catching
3495             # then will cause the debugger to die.
3496             eval {
3497                 &main::dumpvar(
3498                     $packname,
3499                     defined $option{dumpDepth}
3500                     ? $option{dumpDepth}
3501                     : -1,    # assume -1 unless specified
3502                     @vars
3503                 );
3504             };
3505
3506             # The die doesn't need to include the $@, because
3507             # it will automatically get propagated for us.
3508             if ($@) {
3509                 die unless $@ =~ /dumpvar print failed/;
3510             }
3511         } ## end if (defined &main::dumpvar)
3512         else {
3513
3514             # Couldn't load dumpvar.
3515             print $OUT "dumpvar.pl not available.\n";
3516         }
3517
3518         # Restore the output filehandle, and go round again.
3519         select($savout);
3520         next CMD;
3521     }
3522
3523     return;
3524 }
3525
3526 sub _handle_dash_command {
3527
3528     if ($DB::cmd eq '-') {
3529
3530         # back up by a window; go to 1 if back too far.
3531         $start -= $incr + $window + 1;
3532         $start = 1 if $start <= 0;
3533         $incr  = $window - 1;
3534
3535         # Generate and execute a "l +" command (handled below).
3536         $DB::cmd = 'l ' . ($start) . '+';
3537     }
3538     return;
3539 }
3540
3541 sub _n_or_s_commands_generic {
3542     my ($self, $new_val) = @_;
3543     # n - next
3544     next CMD if DB::_DB__is_finished();
3545
3546     # Single step, but don't enter subs.
3547     $single = $new_val;
3548
3549     # Save for empty command (repeat last).
3550     $laststep = $DB::cmd;
3551     last CMD;
3552 }
3553
3554 sub _n_or_s {
3555     my ($self, $letter, $new_val) = @_;
3556
3557     if ($DB::cmd eq $letter) {
3558         $self->_n_or_s_commands_generic($new_val);
3559     }
3560
3561     return;
3562 }
3563
3564 sub _handle_n_command {
3565     my $self = shift;
3566
3567     return $self->_n_or_s('n', 2);
3568 }
3569
3570 sub _handle_s_command {
3571     my $self = shift;
3572
3573     return $self->_n_or_s('s', 1);
3574 }
3575
3576 sub _handle_r_command {
3577     my $self = shift;
3578     # r - return from the current subroutine.
3579     if ($DB::cmd eq 'r') {
3580
3581         # Can't do anything if the program's over.
3582         next CMD if DB::_DB__is_finished();
3583
3584         # Turn on stack trace.
3585         $stack[$stack_depth] |= 1;
3586
3587         # Print return value unless the stack is empty.
3588         $doret = $option{PrintRet} ? $stack_depth - 1 : -2;
3589         last CMD;
3590     }
3591
3592     return;
3593 }
3594
3595 sub _handle_T_command {
3596     if ($DB::cmd eq 'T') {
3597         DB::print_trace( $OUT, 1 );    # skip DB
3598         next CMD;
3599     }
3600
3601     return;
3602 }
3603
3604 sub _handle_w_command {
3605     if (my ($arg) = $DB::cmd =~ /\Aw\b\s*(.*)/s) {
3606         DB::cmd_w( 'w', $arg );
3607         next CMD;
3608     }
3609
3610     return;
3611 }
3612
3613 sub _handle_W_command {
3614     if (my ($arg) = $DB::cmd =~ /\AW\b\s*(.*)/s) {
3615         DB::cmd_W( 'W', $arg );
3616         next CMD;
3617     }
3618
3619     return;
3620 }
3621
3622 sub _handle_rc_recall_command {
3623     my $self = shift;
3624
3625     # $rc - recall command.
3626     if (my ($minus, $arg) = $DB::cmd =~ m#\A$rc+\s*(-)?(\d+)?\z#) {
3627
3628         # No arguments, take one thing off history.
3629         pop(@hist) if length($DB::cmd) > 1;
3630
3631         # Relative (- found)?
3632         #  Y - index back from most recent (by 1 if bare minus)
3633         #  N - go to that particular command slot or the last
3634         #      thing if nothing following.
3635         my $new_i = $minus ? ( $#hist - ( $arg || 1 ) ) : ( $arg || $#hist );
3636
3637         $self->i_cmd($new_i);
3638
3639         # Pick out the command desired.
3640         $DB::cmd = $hist[$self->i_cmd];
3641
3642         # Print the command to be executed and restart the loop
3643         # with that command in the buffer.
3644         print {$OUT} $DB::cmd, "\n";
3645         redo CMD;
3646     }
3647
3648     return;
3649 }
3650
3651 sub _handle_rc_search_history_command {
3652     my $self = shift;
3653
3654     # $rc pattern $rc - find a command in the history.
3655     if (my ($arg) = $DB::cmd =~ /\A$rc([^$rc].*)\z/) {
3656
3657         # Create the pattern to use.
3658         my $pat = "^$arg";
3659         $self->pat($pat);
3660
3661         # Toss off last entry if length is >1 (and it always is).
3662         pop(@hist) if length($DB::cmd) > 1;
3663
3664         my $i = $self->i_cmd;
3665
3666         # Look backward through the history.
3667         SEARCH_HIST:
3668         for ( $i = $#hist ; $i ; --$i ) {
3669             # Stop if we find it.
3670             last SEARCH_HIST if $hist[$i] =~ /$pat/;
3671         }
3672
3673         $self->i_cmd($i);
3674
3675         if ( !$self->i_cmd ) {
3676
3677             # Never found it.
3678             print $OUT "No such command!\n\n";
3679             next CMD;
3680         }
3681
3682         # Found it. Put it in the buffer, print it, and process it.
3683         $DB::cmd = $hist[$self->i_cmd];
3684         print $OUT $DB::cmd, "\n";
3685         redo CMD;
3686     }
3687
3688     return;
3689 }
3690
3691 sub _handle_H_command {
3692     my $self = shift;
3693
3694     if ($DB::cmd =~ /\AH\b\s*\*/) {
3695         @hist = @truehist = ();
3696         print $OUT "History cleansed\n";
3697         next CMD;
3698     }
3699
3700     if (my ($num)
3701         = $DB::cmd =~ /\AH\b\s*(?:-(\d+))?/) {
3702
3703         # Anything other than negative numbers is ignored by
3704         # the (incorrect) pattern, so this test does nothing.
3705         $end = $num ? ( $#hist - $num ) : 0;
3706
3707         # Set to the minimum if less than zero.
3708         $hist = 0 if $hist < 0;
3709
3710         # Start at the end of the array.
3711         # Stay in while we're still above the ending value.
3712         # Tick back by one each time around the loop.
3713         my $i;
3714
3715         for ( $i = $#hist ; $i > $end ; $i-- ) {
3716
3717             # Print the command  unless it has no arguments.
3718             print $OUT "$i: ", $hist[$i], "\n"
3719             unless $hist[$i] =~ /^.?$/;
3720         }
3721
3722         $self->i_cmd($i);
3723
3724         next CMD;
3725     }
3726
3727     return;
3728 }
3729
3730 sub _handle_doc_command {
3731     my $self = shift;
3732
3733     # man, perldoc, doc - show manual pages.
3734     if (my ($man_page)
3735         = $DB::cmd =~ /\A(?:man|(?:perl)?doc)\b(?:\s+([^(]*))?\z/) {
3736         runman($man_page);
3737         next CMD;
3738     }
3739
3740     return;
3741 }
3742
3743 sub _handle_p_command {
3744     my $self = shift;
3745
3746     my $print_cmd = 'print {$DB::OUT} ';
3747     # p - print (no args): print $_.
3748     if ($DB::cmd eq 'p') {
3749         $DB::cmd = $print_cmd . '$_';
3750     }
3751
3752     # p - print the given expression.
3753     $DB::cmd =~ s/\Ap\b/$print_cmd /;
3754
3755     return;
3756 }
3757
3758 sub _handle_equal_sign_command {
3759     my $self = shift;
3760
3761     if ($DB::cmd =~ s/\A=\s*//) {
3762         my @keys;
3763         if ( length $DB::cmd == 0 ) {
3764
3765             # No args, get current aliases.
3766             @keys = sort keys %alias;
3767         }
3768         elsif ( my ( $k, $v ) = ( $DB::cmd =~ /^(\S+)\s+(\S.*)/ ) ) {
3769
3770             # Creating a new alias. $k is alias name, $v is
3771             # alias value.
3772
3773             # can't use $_ or kill //g state
3774             for my $x ( $k, $v ) {
3775
3776                 # Escape "alarm" characters.
3777                 $x =~ s/\a/\\a/g;
3778             }
3779
3780             # Substitute key for value, using alarm chars
3781             # as separators (which is why we escaped them in
3782             # the command).
3783             $alias{$k} = "s\a$k\a$v\a";
3784
3785             # Turn off standard warn and die behavior.
3786             local $SIG{__DIE__};
3787             local $SIG{__WARN__};
3788
3789             # Is it valid Perl?
3790             unless ( eval "sub { s\a$k\a$v\a }; 1" ) {
3791
3792                 # Nope. Bad alias. Say so and get out.
3793                 print $OUT "Can't alias $k to $v: $@\n";
3794                 delete $alias{$k};
3795                 next CMD;
3796             }
3797
3798             # We'll only list the new one.
3799             @keys = ($k);
3800         } ## end elsif (my ($k, $v) = ($DB::cmd...
3801
3802         # The argument is the alias to list.
3803         else {
3804             @keys = ($DB::cmd);
3805         }
3806
3807         # List aliases.
3808         for my $k (@keys) {
3809
3810             # Messy metaquoting: Trim the substitution code off.
3811             # We use control-G as the delimiter because it's not
3812             # likely to appear in the alias.
3813             if ( ( my $v = $alias{$k} ) =~ s\as\a$k\a(.*)\a$\a1\a ) {
3814
3815                 # Print the alias.
3816                 print $OUT "$k\t= $1\n";
3817             }
3818             elsif ( defined $alias{$k} ) {
3819
3820                 # Couldn't trim it off; just print the alias code.
3821                 print $OUT "$k\t$alias{$k}\n";
3822             }
3823             else {
3824
3825                 # No such, dude.
3826                 print "No alias for $k\n";
3827             }
3828         } ## end for my $k (@keys)
3829         next CMD;
3830     }
3831
3832     return;
3833 }
3834
3835 sub _handle_source_command {
3836     my $self = shift;
3837
3838     # source - read commands from a file (or pipe!) and execute.
3839     if (my ($sourced_fn) = $DB::cmd =~ /\Asource\s+(.*\S)/) {
3840         if ( open my $fh, $sourced_fn ) {
3841
3842             # Opened OK; stick it in the list of file handles.
3843             push @cmdfhs, $fh;
3844         }
3845         else {
3846
3847             # Couldn't open it.
3848             DB::warn("Can't execute '$sourced_fn': $!\n");
3849         }
3850         next CMD;
3851     }
3852
3853     return;
3854 }
3855
3856 sub _handle_enable_disable_commands {
3857     my $self = shift;
3858
3859     if (my ($which_cmd, $position)
3860         = $DB::cmd =~ /\A(enable|disable)\s+(\S+)\s*\z/) {
3861
3862         my ($fn, $line_num);
3863         if ($position =~ m{\A\d+\z})
3864         {
3865             $fn = $DB::filename;
3866             $line_num = $position;
3867         }
3868         elsif (my ($new_fn, $new_line_num)
3869             = $position =~ m{\A(.*):(\d+)\z}) {
3870             ($fn, $line_num) = ($new_fn, $new_line_num);
3871         }
3872         else
3873         {
3874             DB::warn("Wrong spec for enable/disable argument.\n");
3875         }
3876
3877         if (defined($fn)) {
3878             if (DB::_has_breakpoint_data_ref($fn, $line_num)) {
3879                 DB::_set_breakpoint_enabled_status($fn, $line_num,
3880                     ($which_cmd eq 'enable' ? 1 : '')
3881                 );
3882             }
3883             else {
3884                 DB::warn("No breakpoint set at ${fn}:${line_num}\n");
3885             }
3886         }
3887
3888         next CMD;
3889     }
3890
3891     return;
3892 }
3893
3894 sub _handle_save_command {
3895     my $self = shift;
3896
3897     if (my ($new_fn) = $DB::cmd =~ /\Asave\s*(.*)\z/) {
3898         my $filename = $new_fn || '.perl5dbrc';    # default?
3899         if ( open my $fh, '>', $filename ) {
3900
3901             # chomp to remove extraneous newlines from source'd files
3902             chomp( my @truelist =
3903                 map { m/\A\s*(save|source)/ ? "#$_" : $_ }
3904                 @truehist );
3905             print {$fh} join( "\n", @truelist );
3906             print "commands saved in $filename\n";
3907         }
3908         else {
3909             DB::warn("Can't save debugger commands in '$new_fn': $!\n");
3910         }
3911         next CMD;
3912     }
3913
3914     return;
3915 }
3916
3917 package DB;
3918
3919 # The following code may be executed now:
3920 # BEGIN {warn 4}
3921
3922 =head2 sub
3923
3924 C<sub> is called whenever a subroutine call happens in the program being
3925 debugged. The variable C<$DB::sub> contains the name of the subroutine
3926 being called.
3927
3928 The core function of this subroutine is to actually call the sub in the proper
3929 context, capturing its output. This of course causes C<DB::DB> to get called
3930 again, repeating until the subroutine ends and returns control to C<DB::sub>
3931 again. Once control returns, C<DB::sub> figures out whether or not to dump the
3932 return value, and returns its captured copy of the return value as its own
3933 return value. The value then feeds back into the program being debugged as if
3934 C<DB::sub> hadn't been there at all.
3935
3936 C<sub> does all the work of printing the subroutine entry and exit messages
3937 enabled by setting C<$frame>. It notes what sub the autoloader got called for,
3938 and also prints the return value if needed (for the C<r> command and if
3939 the 16 bit is set in C<$frame>).
3940
3941 It also tracks the subroutine call depth by saving the current setting of
3942 C<$single> in the C<@stack> package global; if this exceeds the value in
3943 C<$deep>, C<sub> automatically turns on printing of the current depth by
3944 setting the C<4> bit in C<$single>. In any case, it keeps the current setting
3945 of stop/don't stop on entry to subs set as it currently is set.
3946
3947 =head3 C<caller()> support
3948
3949 If C<caller()> is called from the package C<DB>, it provides some
3950 additional data, in the following order:
3951
3952 =over 4
3953
3954 =item * C<$package>
3955
3956 The package name the sub was in
3957
3958 =item * C<$filename>
3959
3960 The filename it was defined in
3961
3962 =item * C<$line>
3963
3964 The line number it was defined on
3965
3966 =item * C<$subroutine>
3967
3968 The subroutine name; C<(eval)> if an C<eval>().
3969
3970 =item * C<$hasargs>
3971
3972 1 if it has arguments, 0 if not
3973
3974 =item * C<$wantarray>
3975
3976 1 if array context, 0 if scalar context
3977
3978 =item * C<$evaltext>
3979
3980 The C<eval>() text, if any (undefined for C<eval BLOCK>)
3981
3982 =item * C<$is_require>
3983
3984 frame was created by a C<use> or C<require> statement
3985
3986 =item * C<$hints>
3987
3988 pragma information; subject to change between versions
3989
3990 =item * C<$bitmask>
3991
3992 pragma information; subject to change between versions
3993
3994 =item * C<@DB::args>
3995
3996 arguments with which the subroutine was invoked
3997
3998 =back
3999
4000 =cut
4001
4002 use vars qw($deep);
4003
4004 # We need to fully qualify the name ("DB::sub") to make "use strict;"
4005 # happy. -- Shlomi Fish
4006 sub DB::sub {
4007     # Do not use a regex in this subroutine -> results in corrupted memory
4008     # See: [perl #66110]
4009
4010     # lock ourselves under threads
4011     lock($DBGR);
4012
4013     # Whether or not the autoloader was running, a scalar to put the
4014     # sub's return value in (if needed), and an array to put the sub's
4015     # return value in (if needed).
4016     my ( $al, $ret, @ret ) = "";
4017     if ($sub eq 'threads::new' && $ENV{PERL5DB_THREADED}) {
4018         print "creating new thread\n";
4019     }
4020
4021     # If the last ten characters are '::AUTOLOAD', note we've traced
4022     # into AUTOLOAD for $sub.
4023     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4024         no strict 'refs';
4025         $al = " for $$sub" if defined $$sub;
4026     }
4027
4028     # We stack the stack pointer and then increment it to protect us
4029     # from a situation that might unwind a whole bunch of call frames
4030     # at once. Localizing the stack pointer means that it will automatically
4031     # unwind the same amount when multiple stack frames are unwound.
4032     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4033
4034     # Expand @stack.
4035     $#stack = $stack_depth;
4036
4037     # Save current single-step setting.
4038     $stack[-1] = $single;
4039
4040     # Turn off all flags except single-stepping.
4041     $single &= 1;
4042
4043     # If we've gotten really deeply recursed, turn on the flag that will
4044     # make us stop with the 'deep recursion' message.
4045     $single |= 4 if $stack_depth == $deep;
4046
4047     # If frame messages are on ...
4048     (
4049         $frame & 4    # Extended frame entry message
4050         ? (
4051             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4052
4053             # Why -1? But it works! :-(
4054             # Because print_trace will call add 1 to it and then call
4055             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4056             # in dump_trace.
4057             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4058           )
4059         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4060
4061           # standard frame entry message
4062       )
4063       if $frame;
4064
4065     # Determine the sub's return type, and capture appropriately.
4066     if (wantarray) {
4067
4068         # Called in array context. call sub and capture output.
4069         # DB::DB will recursively get control again if appropriate; we'll come
4070         # back here when the sub is finished.
4071         {
4072             no strict 'refs';
4073             @ret = &$sub;
4074         }
4075
4076         # Pop the single-step value back off the stack.
4077         $single |= $stack[ $stack_depth-- ];
4078
4079         # Check for exit trace messages...
4080         (
4081             $frame & 4    # Extended exit message
4082             ? (
4083                 print_lineinfo( ' ' x $stack_depth, "out " ),
4084                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4085               )
4086             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4087
4088               # Standard exit message
4089           )
4090           if $frame & 2;
4091
4092         # Print the return info if we need to.
4093         if ( $doret eq $stack_depth or $frame & 16 ) {
4094
4095             # Turn off output record separator.
4096             local $\ = '';
4097             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4098
4099             # Indent if we're printing because of $frame tracing.
4100             print $fh ' ' x $stack_depth if $frame & 16;
4101
4102             # Print the return value.
4103             print $fh "list context return from $sub:\n";
4104             dumpit( $fh, \@ret );
4105
4106             # And don't print it again.
4107             $doret = -2;
4108         } ## end if ($doret eq $stack_depth...
4109             # And we have to return the return value now.
4110         @ret;
4111     } ## end if (wantarray)
4112
4113     # Scalar context.
4114     else {
4115         if ( defined wantarray ) {
4116             no strict 'refs';
4117             # Save the value if it's wanted at all.
4118             $ret = &$sub;
4119         }
4120         else {
4121             no strict 'refs';
4122             # Void return, explicitly.
4123             &$sub;
4124             undef $ret;
4125         }
4126
4127         # Pop the single-step value off the stack.
4128         $single |= $stack[ $stack_depth-- ];
4129
4130         # If we're doing exit messages...
4131         (
4132             $frame & 4    # Extended messages
4133             ? (
4134                 print_lineinfo( ' ' x $stack_depth, "out " ),
4135                 print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4136               )
4137             : print_lineinfo( ' ' x $stack_depth, "exited $sub$al\n" )
4138
4139               # Standard messages
4140           )
4141           if $frame & 2;
4142
4143         # If we are supposed to show the return value... same as before.
4144         if ( $doret eq $stack_depth or $frame & 16 and defined wantarray ) {
4145             local $\ = '';
4146             my $fh = ( $doret eq $stack_depth ? $OUT : $LINEINFO );
4147             print $fh ( ' ' x $stack_depth ) if $frame & 16;
4148             print $fh (
4149                 defined wantarray
4150                 ? "scalar context return from $sub: "
4151                 : "void context return from $sub\n"
4152             );
4153             dumpit( $fh, $ret ) if defined wantarray;
4154             $doret = -2;
4155         } ## end if ($doret eq $stack_depth...
4156
4157         # Return the appropriate scalar value.
4158         $ret;
4159     } ## end else [ if (wantarray)
4160 } ## end sub _sub
4161
4162 sub lsub : lvalue {
4163
4164     no strict 'refs';
4165
4166     # lock ourselves under threads
4167     lock($DBGR);
4168
4169     # Whether or not the autoloader was running, a scalar to put the
4170     # sub's return value in (if needed), and an array to put the sub's
4171     # return value in (if needed).
4172     my ( $al, $ret, @ret ) = "";
4173     if ($sub =~ /^threads::new$/ && $ENV{PERL5DB_THREADED}) {
4174         print "creating new thread\n";
4175     }
4176
4177     # If the last ten characters are C'::AUTOLOAD', note we've traced
4178     # into AUTOLOAD for $sub.
4179     if ( length($sub) > 10 && substr( $sub, -10, 10 ) eq '::AUTOLOAD' ) {
4180         $al = " for $$sub";
4181     }
4182
4183     # We stack the stack pointer and then increment it to protect us
4184     # from a situation that might unwind a whole bunch of call frames
4185     # at once. Localizing the stack pointer means that it will automatically
4186     # unwind the same amount when multiple stack frames are unwound.
4187     local $stack_depth = $stack_depth + 1;    # Protect from non-local exits
4188
4189     # Expand @stack.
4190     $#stack = $stack_depth;
4191
4192     # Save current single-step setting.
4193     $stack[-1] = $single;
4194
4195     # Turn off all flags except single-stepping.
4196     $single &= 1;
4197
4198     # If we've gotten really deeply recursed, turn on the flag that will
4199     # make us stop with the 'deep recursion' message.
4200     $single |= 4 if $stack_depth == $deep;
4201
4202     # If frame messages are on ...
4203     (
4204         $frame & 4    # Extended frame entry message
4205         ? (
4206             print_lineinfo( ' ' x ( $stack_depth - 1 ), "in  " ),
4207
4208             # Why -1? But it works! :-(
4209             # Because print_trace will call add 1 to it and then call
4210             # dump_trace; this results in our skipping -1+1 = 0 stack frames
4211             # in dump_trace.
4212             print_trace( $LINEINFO, -1, 1, 1, "$sub$al" )
4213           )
4214         : print_lineinfo( ' ' x ( $stack_depth - 1 ), "entering $sub$al\n" )
4215
4216           # standard frame entry message
4217       )
4218       if $frame;
4219
4220     # Pop the single-step value back off the stack.
4221     $single |= $stack[ $stack_depth-- ];
4222
4223     # call the original lvalue sub.
4224     &$sub;
4225 }
4226
4227 # Abstracting common code from multiple places elsewhere:
4228 sub depth_print_lineinfo {
4229     my $always_print = shift;
4230
4231     print_lineinfo( @_ ) if ($always_print or $stack_depth < $trace_to_depth);
4232 }
4233
4234 =head1 EXTENDED COMMAND HANDLING AND THE COMMAND API
4235
4236 In Perl 5.8.0, there was a major realignment of the commands and what they did,
4237 Most of the changes were to systematize the command structure and to eliminate
4238 commands that threw away user input without checking.
4239
4240 The following sections describe the code added to make it easy to support
4241 multiple command sets with conflicting command names. This section is a start
4242 at unifying all command processing to make it simpler to develop commands.
4243
4244 Note that all the cmd_[a-zA-Z] subroutines require the command name, a line
4245 number, and C<$dbline> (the current line) as arguments.
4246
4247 Support functions in this section which have multiple modes of failure C<die>
4248 on error; the rest simply return a false value.
4249
4250 The user-interface functions (all of the C<cmd_*> functions) just output
4251 error messages.
4252
4253 =head2 C<%set>
4254
4255 The C<%set> hash defines the mapping from command letter to subroutine
4256 name suffix.
4257
4258 C<%set> is a two-level hash, indexed by set name and then by command name.
4259 Note that trying to set the CommandSet to C<foobar> simply results in the
4260 5.8.0 command set being used, since there's no top-level entry for C<foobar>.
4261
4262 =cut
4263
4264 ### The API section
4265
4266 my %set = (    #
4267     'pre580' => {
4268         'a' => 'pre580_a',
4269         'A' => 'pre580_null',
4270         'b' => 'pre580_b',
4271         'B' => 'pre580_null',
4272         'd' => 'pre580_null',
4273         'D' => 'pre580_D',
4274         'h' => 'pre580_h',
4275         'M' => 'pre580_null',
4276         'O' => 'o',
4277         'o' => 'pre580_null',
4278         'v' => 'M',
4279         'w' => 'v',
4280         'W' => 'pre580_W',
4281     },
4282     'pre590' => {
4283         '<'  => 'pre590_prepost',
4284         '<<' => 'pre590_prepost',
4285         '>'  => 'pre590_prepost',
4286         '>>' => 'pre590_prepost',
4287         '{'  => 'pre590_prepost',
4288         '{{' => 'pre590_prepost',
4289     },
4290 );
4291
4292 my %breakpoints_data;
4293
4294 sub _has_breakpoint_data_ref {
4295     my ($filename, $line) = @_;
4296
4297     return (
4298         exists( $breakpoints_data{$filename} )
4299             and
4300         exists( $breakpoints_data{$filename}{$line} )
4301     );
4302 }
4303
4304 sub _get_breakpoint_data_ref {
4305     my ($filename, $line) = @_;
4306
4307     return ($breakpoints_data{$filename}{$line} ||= +{});
4308 }
4309
4310 sub _delete_breakpoint_data_ref {
4311     my ($filename, $line) = @_;
4312
4313     delete($breakpoints_data{$filename}{$line});
4314     if (! scalar(keys( %{$breakpoints_data{$filename}} )) ) {
4315         delete($breakpoints_data{$filename});
4316     }
4317
4318     return;
4319 }
4320
4321 sub _set_breakpoint_enabled_status {
4322     my ($filename, $line, $status) = @_;
4323
4324     _get_breakpoint_data_ref($filename, $line)->{'enabled'} =
4325         ($status ? 1 : '')
4326         ;
4327
4328     return;
4329 }
4330
4331 sub _enable_breakpoint_temp_enabled_status {
4332     my ($filename, $line) = @_;
4333
4334     _get_breakpoint_data_ref($filename, $line)->{'temp_enabled'} = 1;
4335
4336     return;
4337 }
4338
4339 sub _cancel_breakpoint_temp_enabled_status {
4340     my ($filename, $line) = @_;
4341
4342     my $ref = _get_breakpoint_data_ref($filename, $line);
4343
4344     delete ($ref->{'temp_enabled'});
4345
4346     if (! %$ref) {
4347         _delete_breakpoint_data_ref($filename, $line);
4348     }
4349
4350     return;
4351 }
4352
4353 sub _is_breakpoint_enabled {
4354     my ($filename, $line) = @_;
4355
4356     my $data_ref = _get_breakpoint_data_ref($filename, $line);
4357     return ($data_ref->{'enabled'} || $data_ref->{'temp_enabled'});
4358 }
4359
4360 =head2 C<cmd_wrapper()> (API)
4361
4362 C<cmd_wrapper()> allows the debugger to switch command sets
4363 depending on the value of the C<CommandSet> option.
4364
4365 It tries to look up the command in the C<%set> package-level I<lexical>
4366 (which means external entities can't fiddle with it) and create the name of
4367 the sub to call based on the value found in the hash (if it's there). I<All>
4368 of the commands to be handled in a set have to be added to C<%set>; if they
4369 aren't found, the 5.8.0 equivalent is called (if there is one).
4370
4371 This code uses symbolic references.
4372
4373 =cut
4374
4375 sub cmd_wrapper {
4376     my $cmd      = shift;
4377     my $line     = shift;
4378     my $dblineno = shift;
4379
4380     # Assemble the command subroutine's name by looking up the
4381     # command set and command name in %set. If we can't find it,
4382     # default to the older version of the command.
4383     my $call = 'cmd_'
4384       . ( $set{$CommandSet}{$cmd}
4385           || ( $cmd =~ /^[<>{]+/o ? 'prepost' : $cmd ) );
4386
4387     # Call the command subroutine, call it by name.
4388     return __PACKAGE__->can($call)->( $cmd, $line, $dblineno );
4389 } ## end sub cmd_wrapper
4390
4391 =head3 C<cmd_a> (command)
4392
4393 The C<a> command handles pre-execution actions. These are associated with a
4394 particular line, so they're stored in C<%dbline>. We default to the current
4395 line if none is specified.
4396
4397 =cut
4398
4399 sub cmd_a {
4400     my $cmd    = shift;
4401     my $line   = shift || '';    # [.|line] expr
4402     my $dbline = shift;
4403
4404     # If it's dot (here), or not all digits,  use the current line.
4405     $line =~ s/\A\./$dbline/;
4406
4407     # Should be a line number followed by an expression.
4408     if ( my ($lineno, $expr) = $line =~ /^\s*(\d*)\s*(\S.+)/ ) {
4409
4410         if (! length($lineno)) {
4411             $lineno = $dbline;
4412         }
4413
4414         # If we have an expression ...
4415         if ( length $expr ) {
4416
4417             # ... but the line isn't breakable, complain.
4418             if ( $dbline[$lineno] == 0 ) {
4419                 print $OUT
4420                   "Line $lineno($dbline[$lineno]) does not have an action?\n";
4421             }
4422             else {
4423
4424                 # It's executable. Record that the line has an action.
4425                 $had_breakpoints{$filename} |= 2;
4426
4427                 # Remove any action, temp breakpoint, etc.
4428                 $dbline{$lineno} =~ s/\0[^\0]*//;
4429
4430                 # Add the action to the line.
4431                 $dbline{$lineno} .= "\0" . action($expr);
4432
4433                 _set_breakpoint_enabled_status($filename, $lineno, 1);
4434             }
4435         } ## end if (length $expr)
4436     } ## end if ($line =~ /^\s*(\d*)\s*(\S.+)/)
4437     else {
4438
4439         # Syntax wrong.
4440         print $OUT
4441           "Adding an action requires an optional lineno and an expression\n"
4442           ;    # hint
4443     }
4444 } ## end sub cmd_a
4445
4446 =head3 C<cmd_A> (command)
4447
4448 Delete actions. Similar to above, except the delete code is in a separate
4449 subroutine, C<delete_action>.
4450
4451 =cut
4452
4453 sub cmd_A {
4454     my $cmd    = shift;
4455     my $line   = shift || '';
4456     my $dbline = shift;
4457
4458     # Dot is this line.
4459     $line =~ s/^\./$dbline/;
4460
4461     # Call delete_action with a null param to delete them all.
4462     # The '1' forces the eval to be true. It'll be false only
4463     # if delete_action blows up for some reason, in which case
4464     # we print $@ and get out.
4465     if ( $line eq '*' ) {
4466         if (! eval { _delete_all_actions(); 1 }) {
4467             print {$OUT} $@;
4468             return;
4469         }
4470     }
4471
4472     # There's a real line  number. Pass it to delete_action.
4473     # Error trapping is as above.
4474     elsif ( $line =~ /^(\S.*)/ ) {
4475         if (! eval { delete_action($1); 1 }) {
4476             print {$OUT} $@;
4477             return;
4478         }
4479     }
4480
4481     # Swing and a miss. Bad syntax.
4482     else {
4483         print $OUT
4484           "Deleting an action requires a line number, or '*' for all\n" ; # hint
4485     }
4486 } ## end sub cmd_A
4487
4488 =head3 C<delete_action> (API)
4489
4490 C<delete_action> accepts either a line number or C<undef>. If a line number
4491 is specified, we check for the line being executable (if it's not, it
4492 couldn't have had an  action). If it is, we just take the action off (this
4493 will get any kind of an action, including breakpoints).
4494
4495 =cut
4496
4497 sub _remove_action_from_dbline {
4498     my $i = shift;
4499
4500     $dbline{$i} =~ s/\0[^\0]*//;    # \^a
4501     delete $dbline{$i} if $dbline{$i} eq '';
4502
4503     return;
4504 }
4505
4506 sub _delete_all_actions {
4507     print {$OUT} "Deleting all actions...\n";
4508
4509     for my $file ( keys %had_breakpoints ) {
4510         local *dbline = $main::{ '_<' . $file };
4511         $max = $#dbline;
4512         my $was;
4513         for my $i (1 .. $max) {
4514             if ( defined $dbline{$i} ) {
4515                 _remove_action_from_dbline($i);
4516             }
4517         }
4518
4519         unless ( $had_breakpoints{$file} &= ~2 ) {
4520             delete $had_breakpoints{$file};
4521         }
4522     }
4523
4524     return;
4525 }
4526
4527 sub delete_action {
4528     my $i = shift;
4529
4530     if ( defined($i) ) {
4531         # Can there be one?
4532         die "Line $i has no action .\n" if $dbline[$i] == 0;
4533
4534         # Nuke whatever's there.
4535         _remove_action_from_dbline($i);
4536     }
4537     else {
4538         _delete_all_actions();
4539     }
4540 }
4541
4542 =head3 C<cmd_b> (command)
4543
4544 Set breakpoints. Since breakpoints can be set in so many places, in so many
4545 ways, conditionally or not, the breakpoint code is kind of complex. Mostly,
4546 we try to parse the command type, and then shuttle it off to an appropriate
4547 subroutine to actually do the work of setting the breakpoint in the right
4548 place.
4549
4550 =cut
4551
4552 sub cmd_b {
4553     my $cmd    = shift;
4554     my $line   = shift;    # [.|line] [cond]
4555     my $dbline = shift;
4556
4557     my $default_cond = sub {
4558         my $cond = shift;
4559         return length($cond) ? $cond : '1';
4560     };
4561
4562     # Make . the current line number if it's there..
4563     $line =~ s/^\.(\s|\z)/$dbline$1/;
4564
4565     # No line number, no condition. Simple break on current line.
4566     if ( $line =~ /^\s*$/ ) {
4567         cmd_b_line( $dbline, 1 );
4568     }
4569
4570     # Break on load for a file.
4571     elsif ( my ($file) = $line =~ /^load\b\s*(.*)/ ) {
4572         $file =~ s/\s+\z//;
4573         cmd_b_load($file);
4574     }
4575
4576     # b compile|postpone <some sub> [<condition>]
4577     # The interpreter actually traps this one for us; we just put the
4578     # necessary condition in the %postponed hash.
4579     elsif ( my ($action, $subname, $cond)
4580         = $line =~ /^(postpone|compile)\b\s*([':A-Za-z_][':\w]*)\s*(.*)/ ) {
4581
4582         # De-Perl4-ify the name - ' separators to ::.
4583         $subname =~ s/'/::/g;
4584
4585         # Qualify it into the current package unless it's already qualified.
4586         $subname = "${package}::" . $subname unless $subname =~ /::/;
4587
4588         # Add main if it starts with ::.
4589         $subname = "main" . $subname if substr( $subname, 0, 2 ) eq "::";
4590
4591         # Save the break type for this sub.
4592         $postponed{$subname} = (($action eq 'postpone')
4593             ? ( "break +0 if " . $default_cond->($cond) )
4594             : "compile");
4595     } ## end elsif ($line =~ ...
4596     # b <filename>:<line> [<condition>]
4597     elsif (my ($filename, $line_num, $cond)
4598         = $line =~ /\A(\S+[^:]):(\d+)\s*(.*)/ms) {
4599         cmd_b_filename_line(
4600             $filename,
4601             $line_num,
4602             (length($cond) ? $cond : '1'),
4603         );
4604     }
4605     # b <sub name> [<condition>]
4606     elsif ( my ($new_subname, $new_cond) =
4607         $line =~ /^([':A-Za-z_][':\w]*(?:\[.*\])?)\s*(.*)/ ) {
4608
4609         #
4610         $subname = $new_subname;
4611         cmd_b_sub( $subname, $default_cond->($new_cond) );
4612     }
4613
4614     # b <line> [<condition>].
4615     elsif ( my ($line_n, $cond) = $line =~ /^(\d*)\s*(.*)/ ) {
4616
4617         # Capture the line. If none, it's the current line.
4618         $line = $line_n || $dbline;
4619
4620         # Break on line.
4621         cmd_b_line( $line, $default_cond->($cond) );
4622     }
4623
4624     # Line didn't make sense.
4625     else {
4626         print "confused by line($line)?\n";
4627     }
4628
4629     return;
4630 } ## end sub cmd_b
4631
4632 =head3 C<break_on_load> (API)
4633
4634 We want to break when this file is loaded. Mark this file in the
4635 C<%break_on_load> hash, and note that it has a breakpoint in
4636 C<%had_breakpoints>.
4637
4638 =cut
4639
4640 sub break_on_load {
4641     my $file = shift;
4642     $break_on_load{$file} = 1;
4643     $had_breakpoints{$file} |= 1;
4644 }
4645
4646 =head3 C<report_break_on_load> (API)
4647
4648 Gives us an array of filenames that are set to break on load. Note that
4649 only files with break-on-load are in here, so simply showing the keys
4650 suffices.
4651
4652 =cut
4653
4654 sub report_break_on_load {
4655     sort keys %break_on_load;
4656 }
4657
4658 =head3 C<cmd_b_load> (command)
4659
4660 We take the file passed in and try to find it in C<%INC> (which maps modules
4661 to files they came from). We mark those files for break-on-load via
4662 C<break_on_load> and then report that it was done.
4663
4664 =cut
4665
4666 sub cmd_b_load {
4667     my $file = shift;
4668     my @files;
4669
4670     # This is a block because that way we can use a redo inside it
4671     # even without there being any looping structure at all outside it.
4672     {
4673
4674         # Save short name and full path if found.
4675         push @files, $file;
4676         push @files, $::INC{$file} if $::INC{$file};
4677
4678         # Tack on .pm and do it again unless there was a '.' in the name
4679         # already.
4680         $file .= '.pm', redo unless $file =~ /\./;
4681     }
4682
4683     # Do the real work here.
4684     break_on_load($_) for @files;
4685
4686     # All the files that have break-on-load breakpoints.
4687     @files = report_break_on_load;
4688
4689     # Normalize for the purposes of our printing this.
4690     local $\ = '';
4691     local $" = ' ';
4692     print $OUT "Will stop on load of '@files'.\n";
4693 } ## end sub cmd_b_load
4694
4695 =head3 C<$filename_error> (API package global)
4696
4697 Several of the functions we need to implement in the API need to work both
4698 on the current file and on other files. We don't want to duplicate code, so
4699 C<$filename_error> is used to contain the name of the file that's being
4700 worked on (if it's not the current one).
4701
4702 We can now build functions in pairs: the basic function works on the current
4703 file, and uses C<$filename_error> as part of its error message. Since this is
4704 initialized to C<"">, no filename will appear when we are working on the
4705 current file.
4706
4707 The second function is a wrapper which does the following:
4708
4709 =over 4
4710
4711 =item *
4712
4713 Localizes C<$filename_error> and sets it to the name of the file to be processed.
4714
4715 =item *
4716
4717 Localizes the C<*dbline> glob and reassigns it to point to the file we want to process.
4718
4719 =item *
4720
4721 Calls the first function.
4722
4723 The first function works on the I<current> file (i.e., the one we changed to),
4724 and prints C<$filename_error> in the error message (the name of the other file)
4725 if it needs to. When the functions return, C<*dbline> is restored to point
4726 to the actual current file (the one we're executing in) and
4727 C<$filename_error> is restored to C<"">. This restores everything to
4728 the way it was before the second function was called at all.
4729
4730 See the comments in C<breakable_line> and C<breakable_line_in_file> for more
4731 details.
4732
4733 =back
4734
4735 =cut
4736
4737 use vars qw($filename_error);
4738 $filename_error = '';
4739
4740 =head3 breakable_line(from, to) (API)
4741
4742 The subroutine decides whether or not a line in the current file is breakable.
4743 It walks through C<@dbline> within the range of lines specified, looking for
4744 the first line that is breakable.
4745
4746 If C<$to> is greater than C<$from>, the search moves forwards, finding the
4747 first line I<after> C<$to> that's breakable, if there is one.
4748
4749 If C<$from> is greater than C<$to>, the search goes I<backwards>, finding the
4750 first line I<before> C<$to> that's breakable, if there is one.
4751
4752 =cut
4753
4754 sub breakable_line {
4755
4756     my ( $from, $to ) = @_;
4757
4758     # $i is the start point. (Where are the FORTRAN programs of yesteryear?)
4759     my $i = $from;
4760
4761     # If there are at least 2 arguments, we're trying to search a range.
4762     if ( @_ >= 2 ) {
4763
4764         # $delta is positive for a forward search, negative for a backward one.
4765         my $delta = $from < $to ? +1 : -1;
4766
4767         # Keep us from running off the ends of the file.
4768         my $limit = $delta > 0 ? $#dbline : 1;
4769
4770         # Clever test. If you're a mathematician, it's obvious why this
4771         # test works. If not:
4772         # If $delta is positive (going forward), $limit will be $#dbline.
4773         #    If $to is less than $limit, ($limit - $to) will be positive, times
4774         #    $delta of 1 (positive), so the result is > 0 and we should use $to
4775         #    as the stopping point.
4776         #
4777         #    If $to is greater than $limit, ($limit - $to) is negative,
4778         #    times $delta of 1 (positive), so the result is < 0 and we should
4779         #    use $limit ($#dbline) as the stopping point.
4780         #
4781         # If $delta is negative (going backward), $limit will be 1.
4782         #    If $to is zero, ($limit - $to) will be 1, times $delta of -1
4783         #    (negative) so the result is > 0, and we use $to as the stopping
4784         #    point.
4785         #
4786         #    If $to is less than zero, ($limit - $to) will be positive,
4787         #    times $delta of -1 (negative), so the result is not > 0, and
4788         #    we use $limit (1) as the stopping point.
4789         #
4790         #    If $to is 1, ($limit - $to) will zero, times $delta of -1
4791         #    (negative), still giving zero; the result is not > 0, and
4792         #    we use $limit (1) as the stopping point.
4793         #
4794         #    if $to is >1, ($limit - $to) will be negative, times $delta of -1
4795         #    (negative), giving a positive (>0) value, so we'll set $limit to
4796         #    $to.
4797
4798         $limit = $to if ( $limit - $to ) * $delta > 0;
4799
4800         # The real search loop.
4801         # $i starts at $from (the point we want to start searching from).
4802         # We move through @dbline in the appropriate direction (determined
4803         # by $delta: either -1 (back) or +1 (ahead).
4804         # We stay in as long as we haven't hit an executable line
4805         # ($dbline[$i] == 0 means not executable) and we haven't reached
4806         # the limit yet (test similar to the above).
4807         $i += $delta while $dbline[$i] == 0 and ( $limit - $i ) * $delta > 0;
4808
4809     } ## end if (@_ >= 2)
4810
4811     # If $i points to a line that is executable, return that.
4812     return $i unless $dbline[$i] == 0;
4813
4814     # Format the message and print it: no breakable lines in range.
4815     my ( $pl, $upto ) = ( '', '' );
4816     ( $pl, $upto ) = ( 's', "..$to" ) if @_ >= 2 and $from != $to;
4817
4818     # If there's a filename in filename_error, we'll see it.
4819     # If not, not.
4820     die "Line$pl $from$upto$filename_error not breakable\n";
4821 } ## end sub breakable_line
4822
4823 =head3 breakable_line_in_filename(file, from, to) (API)
4824
4825 Like C<breakable_line>, but look in another file.
4826
4827 =cut
4828
4829 sub breakable_line_in_filename {
4830
4831     # Capture the file name.
4832     my ($f) = shift;
4833
4834     # Swap the magic line array over there temporarily.
4835     local *dbline = $main::{ '_<' . $f };
4836
4837     # If there's an error, it's in this other file.
4838