skip the defined *+ and *- tests on miniperl
[perl.git] / t / op / magic.t
1 #!./perl
2
3 BEGIN {
4     $| = 1;
5     chdir 't' if -d 't';
6     @INC = '../lib';
7     require './test.pl';
8     plan (tests => 145);
9 }
10
11 # Test that defined() returns true for magic variables created on the fly,
12 # even before they have been created.
13 # This must come first, even before turning on warnings or setting up
14 # $SIG{__WARN__}, to avoid invalidating the tests.  warnings.pm currently
15 # does not mention any special variables, but that could easily change.
16 BEGIN {
17     # not available in miniperl
18     my %non_mini = map { $_ => 1 } qw(+ -);
19     for (qw(
20         SIG ^OPEN ^TAINT ^UNICODE ^UTF8LOCALE ^WARNING_BITS 1 2 3 4 5 6 7 8
21         9 42 & ` ' : ? ! _ - # [ ^ ~ = % . ( ) < > \ / $ | + ; ] ^A ^C ^D
22         ^E ^F ^H ^I ^L ^N ^O ^P ^S ^T ^V ^W
23     )) {
24         my $v = $_;
25         # avoid using any global vars here:
26         if ($v =~ s/^\^(?=.)//) {
27             for(substr $v, 0, 1) {
28                 $_ = chr ord() - 64;
29             }
30         }
31         SKIP:
32         {
33             skip_if_miniperl("the module for *$_ may not be available in "
34                              . "miniperl", 1) if $non_mini{$_};
35             ok defined *$v, "*$_ appears to be defined at the outset";
36         }
37     }
38 }
39
40 # This must be in a separate BEGIN block, as the mere mention of ${^TAINT}
41 # will invalidate the test for it.
42 BEGIN {
43     $ENV{PATH} = '/bin' if ${^TAINT};
44     $SIG{__WARN__} = sub { die "Dying on warning: ", @_ };
45 }
46
47 use warnings;
48 use Config;
49
50
51 $Is_MSWin32  = $^O eq 'MSWin32';
52 $Is_NetWare  = $^O eq 'NetWare';
53 $Is_VMS      = $^O eq 'VMS';
54 $Is_Dos      = $^O eq 'dos';
55 $Is_os2      = $^O eq 'os2';
56 $Is_Cygwin   = $^O eq 'cygwin';
57 $Is_MPE      = $^O eq 'mpeix';          
58 $Is_BeOS     = $^O eq 'beos';
59
60 $PERL = $ENV{PERL}
61     || ($Is_NetWare           ? 'perl'   :
62        $Is_VMS                ? $^X      :
63        $Is_MSWin32            ? '.\perl' :
64        './perl');
65
66 END {
67     # On VMS, environment variable changes are peristent after perl exits
68     delete $ENV{'FOO'} if $Is_VMS;
69 }
70
71 eval '$ENV{"FOO"} = "hi there";';       # check that ENV is inited inside eval
72 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
73 # -- Nikola Knezevic
74 if ($Is_MSWin32)  { like `set FOO`, qr/^(?:FOO=)?hi there$/; }
75 elsif ($Is_VMS)   { is `write sys\$output f\$trnlnm("FOO")`, "hi there\n"; }
76 else              { is `echo \$FOO`, "hi there\n"; }
77
78 unlink_all 'ajslkdfpqjsjfk';
79 $! = 0;
80 open(FOO,'ajslkdfpqjsjfk');
81 isnt($!, 0);
82 close FOO; # just mention it, squelch used-only-once
83
84 SKIP: {
85     skip('SIGINT not safe on this platform', 5)
86         if $Is_MSWin32 || $Is_NetWare || $Is_Dos || $Is_MPE;
87   # the next tests are done in a subprocess because sh spits out a
88   # newline onto stderr when a child process kills itself with SIGINT.
89   # We use a pipe rather than system() because the VMS command buffer
90   # would overflow with a command that long.
91
92     # For easy interpolation of test numbers:
93     $next_test = curr_test() - 1;
94     sub TIEARRAY {bless[]}
95     sub FETCH { $next_test + pop }
96     tie my @tn, __PACKAGE__;
97
98     open( CMDPIPE, "| $PERL");
99
100     print CMDPIPE "\$t1 = $tn[1]; \$t2 = $tn[2];\n", <<'END';
101
102     $| = 1;             # command buffering
103
104     $SIG{"INT"} = "ok1";     kill "INT",$$; sleep 1;
105     $SIG{"INT"} = "IGNORE";  kill "INT",$$; sleep 1; print "ok $t2\n";
106     $SIG{"INT"} = "DEFAULT"; kill "INT",$$; sleep 1; print" not ok $t2\n";
107
108     sub ok1 {
109         if (($x = pop(@_)) eq "INT") {
110             print "ok $t1\n";
111         }
112         else {
113             print "not ok $t1 ($x @_)\n";
114         }
115     }
116
117 END
118
119     close CMDPIPE;
120
121     open( CMDPIPE, "| $PERL");
122     print CMDPIPE "\$t3 = $tn[3];\n", <<'END';
123
124     { package X;
125         sub DESTROY {
126             kill "INT",$$;
127         }
128     }
129     sub x {
130         my $x=bless [], 'X';
131         return sub { $x };
132     }
133     $| = 1;             # command buffering
134     $SIG{"INT"} = "ok3";
135     {
136         local $SIG{"INT"}=x();
137         print ""; # Needed to expose failure in 5.8.0 (why?)
138     }
139     sleep 1;
140     delete $SIG{"INT"};
141     kill "INT",$$; sleep 1;
142     sub ok3 {
143         print "ok $t3\n";
144     }
145 END
146     close CMDPIPE;
147     $? >>= 8 if $^O eq 'VMS'; # POSIX status hiding in 2nd byte
148     my $todo = ($^O eq 'os2' ? ' # TODO: EMX v0.9d_fix4 bug: wrong nibble? ' : '');
149     print $? & 0xFF ? "ok $tn[4]$todo\n" : "not ok $tn[4]$todo\n";
150
151     open(CMDPIPE, "| $PERL");
152     print CMDPIPE <<'END';
153
154     sub PVBM () { 'foo' }
155     index 'foo', PVBM;
156     my $pvbm = PVBM;
157
158     sub foo { exit 0 }
159
160     $SIG{"INT"} = $pvbm;
161     kill "INT", $$; sleep 1;
162 END
163     close CMDPIPE;
164     $? >>= 8 if $^O eq 'VMS';
165     print $? ? "not ok $tn[5]\n" : "ok $tn[5]\n";
166
167     curr_test(curr_test() + 5);
168 }
169
170 # can we slice ENV?
171 @val1 = @ENV{keys(%ENV)};
172 @val2 = values(%ENV);
173 is join(':',@val1), join(':',@val2);
174 cmp_ok @val1, '>', 1;
175
176 # regex vars
177 'foobarbaz' =~ /b(a)r/;
178 is $`, 'foo';
179 is $&, 'bar';
180 is $', 'baz';
181 is $+, 'a';
182
183 # $"
184 @a = qw(foo bar baz);
185 is "@a", "foo bar baz";
186 {
187     local $" = ',';
188     is "@a", "foo,bar,baz";
189 }
190
191 # $;
192 %h = ();
193 $h{'foo', 'bar'} = 1;
194 is((keys %h)[0], "foo\034bar");
195 {
196     local $; = 'x';
197     %h = ();
198     $h{'foo', 'bar'} = 1;
199     is((keys %h)[0], 'fooxbar');
200 }
201
202 # $?, $@, $$
203 system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(0)"];
204 is $?, 0;
205 system qq[$PERL "-I../lib" -e "use vmsish qw(hushed); exit(1)"];
206 isnt $?, 0;
207
208 eval { die "foo\n" };
209 is $@, "foo\n";
210
211 cmp_ok($$, '>', 0);
212 my $pid = $$;
213 eval { $$ = 42 };
214 is $$, 42, '$$ can be modified';
215 SKIP: {
216     skip "no fork", 1 unless $Config{d_fork};
217     (my $kidpid = open my $fh, "-|") // skip "cannot fork: $!", 1;
218     if($kidpid) { # parent
219         my $kiddollars = <$fh>;
220         close $fh or die "cannot close pipe from kid proc: $!";
221         is $kiddollars, $kidpid, '$$ is reset on fork';
222     }
223     else { # child
224         print $$;
225         $::NO_ENDING = 1; # silence "Looks like you only ran..."
226         exit;
227     }
228 }
229 $$ = $pid; # Tests below use $$
230
231 # $^X and $0
232 {
233     if ($^O eq 'qnx') {
234         chomp($wd = `/usr/bin/fullpath -t`);
235     }
236     elsif($Is_Cygwin || $Config{'d_procselfexe'}) {
237        # Cygwin turns the symlink into the real file
238        chomp($wd = `pwd`);
239        $wd =~ s#/t$##;
240        $wd =~ /(.*)/; $wd = $1; # untaint
241        if ($Is_Cygwin) {
242            $wd = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($wd, 1));
243        }
244     }
245     elsif($Is_os2) {
246        $wd = Cwd::sys_cwd();
247     }
248     else {
249         $wd = '.';
250     }
251     my $perl = $Is_VMS || $Config{d_procselfexe} ? $^X : "$wd/perl";
252     my $headmaybe = '';
253     my $middlemaybe = '';
254     my $tailmaybe = '';
255     $script = "$wd/show-shebang";
256     if ($Is_MSWin32) {
257         chomp($wd = `cd`);
258         $wd =~ s|\\|/|g;
259         $perl = "$wd/perl.exe";
260         $script = "$wd/show-shebang.bat";
261         $headmaybe = <<EOH ;
262 \@rem ='
263 \@echo off
264 $perl -x \%0
265 goto endofperl
266 \@rem ';
267 EOH
268         $tailmaybe = <<EOT ;
269
270 __END__
271 :endofperl
272 EOT
273     }
274     elsif ($Is_os2) {
275       $script = "./show-shebang";
276     }
277     elsif ($Is_VMS) {
278       $script = "[]show-shebang";
279     }
280     elsif ($Is_Cygwin) {
281       $middlemaybe = <<'EOX'
282 $^X = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($^X, 1));
283 $0 = Cygwin::win_to_posix_path(Cygwin::posix_to_win_path($0, 1));
284 EOX
285     }
286     if ($^O eq 'os390' or $^O eq 'posix-bc' or $^O eq 'vmesa') {  # no shebang
287         $headmaybe = <<EOH ;
288     eval 'exec ./perl -S \$0 \${1+"\$\@"}'
289         if 0;
290 EOH
291     }
292     $s1 = "\$^X is $perl, \$0 is $script\n";
293     ok open(SCRIPT, ">$script") or diag "Can't write to $script: $!";
294     ok print(SCRIPT $headmaybe . <<EOB . $middlemaybe . <<'EOF' . $tailmaybe) or diag $!;
295 #!$perl
296 EOB
297 print "\$^X is $^X, \$0 is $0\n";
298 EOF
299     ok close(SCRIPT) or diag $!;
300     ok chmod(0755, $script) or diag $!;
301     $_ = $Is_VMS ? `$perl $script` : `$script`;
302     s/\.exe//i if $Is_Dos or $Is_Cygwin or $Is_os2;
303     s{./$script}{$script} if $Is_BeOS; # revert BeOS execvp() side-effect
304     s{is perl}{is $perl}; # for systems where $^X is only a basename
305     s{\\}{/}g;
306     if ($Is_MSWin32 || $Is_os2) {
307         is uc $_, uc $s1;
308     } else {
309         is $_, $s1;
310     }
311     $_ = `$perl $script`;
312     s/\.exe//i if $Is_Dos or $Is_os2 or $Is_Cygwin;
313     s{./$perl}{$perl} if $Is_BeOS; # revert BeOS execvp() side-effect
314     s{\\}{/}g;
315     if ($Is_MSWin32 || $Is_os2) {
316         is uc $_, uc $s1;
317     } else {
318         is $_, $s1;
319     }
320     ok unlink($script) or diag $!;
321     # CHECK
322     # Could this be replaced with:
323     # unlink_all($script);
324 }
325
326 # $], $^O, $^T
327 cmp_ok $], '>=', 5.00319;
328 ok $^O;
329 cmp_ok $^T, '>', 850000000;
330
331 # Test change 25062 is working
332 my $orig_osname = $^O;
333 {
334 local $^I = '.bak';
335 is $^O, $orig_osname, 'Assigning $^I does not clobber $^O';
336 }
337 $^O = $orig_osname;
338
339 {
340     #RT #72422
341     foreach my $p (0, 1) {
342         fresh_perl_is(<<"EOP", '2 4 8', undef, "test \$^P = $p");
343 \$DB::single = 2;
344 \$DB::trace = 4;
345 \$DB::signal = 8;
346 \$^P = $p;
347 print "\$DB::single \$DB::trace \$DB::signal";
348 EOP
349     }
350 }
351
352 # Check that assigning to $0 on Linux sets the process name with both
353 # argv[0] assignment and by calling prctl()
354 {
355   SKIP: {
356     skip "We don't have prctl() here", 2 unless $Config{d_prctl_set_name};
357
358     # We don't really need these tests. prctl() is tested in the
359     # Kernel, but test it anyway for our sanity. If something doesn't
360     # work (like if the system doesn't have a ps(1) for whatever
361     # reason) just bail out gracefully.
362     my $maybe_ps = sub {
363         my ($cmd) = @_;
364         local ($?, $!);
365
366         no warnings;
367         my $res = `$cmd`;
368         skip "Couldn't shell out to `$cmd', returned code $?", 2 if $?;
369         return $res;
370     };
371
372     my $name = "Good Morning, Dave";
373     $0 = $name;
374
375     chomp(my $argv0 = $maybe_ps->("ps h $$"));
376     chomp(my $prctl = $maybe_ps->("ps hc $$"));
377
378     like($argv0, $name, "Set process name through argv[0] ($argv0)");
379     like($prctl, substr($name, 0, 15), "Set process name through prctl() ($prctl)");
380   }
381 }
382
383 {
384     my $ok = 1;
385     my $warn = '';
386     local $SIG{'__WARN__'} = sub { $ok = 0; $warn = join '', @_; $warn =~ s/\n$//; };
387     $! = undef;
388     local $TODO = $Is_VMS ? "'\$!=undef' does throw a warning" : '';
389     ok($ok, $warn);
390 }
391
392 SKIP: {
393     skip_if_miniperl("miniperl can't rely on loading %Errno", 2);
394    no warnings 'void';
395
396 # Make sure Errno hasn't been prematurely autoloaded
397
398    ok !keys %Errno::;
399
400 # Test auto-loading of Errno when %! is used
401
402    ok scalar eval q{
403       %!;
404       scalar %Errno::;
405    }, $@;
406 }
407
408 SKIP:  {
409     skip_if_miniperl("miniperl can't rely on loading %Errno", 1);
410     # Make sure that Errno loading doesn't clobber $!
411
412     undef %Errno::;
413     delete $INC{"Errno.pm"};
414
415     open(FOO, "nonesuch"); # Generate ENOENT
416     my %errs = %{"!"}; # Cause Errno.pm to be loaded at run-time
417     ok ${"!"}{ENOENT};
418 }
419
420 # Check that we don't auto-load packages
421 SKIP: {
422     skip "staticly linked; may be preloaded", 4 unless $Config{usedl};
423     foreach (['powie::!', 'Errno'],
424              ['powie::+', 'Tie::Hash::NamedCapture']) {
425         my ($symbol, $package) = @$_;
426         foreach my $scalar_first ('', '$$symbol;') {
427             my $desc = qq{Referencing %{"$symbol"}};
428             $desc .= qq{ after mentioning \${"$symbol"}} if $scalar_first;
429             $desc .= " doesn't load $package";
430
431             fresh_perl_is(<<"EOP", 0, {}, $desc);
432 use strict qw(vars subs);
433 my \$symbol = '$symbol';
434 $scalar_first;
435 1 if %{\$symbol};
436 print scalar %${package}::;
437 EOP
438         }
439     }
440 }
441
442 is $^S, 0;
443 eval { is $^S,1 };
444 eval " BEGIN { ok ! defined \$^S } ";
445 is $^S, 0;
446
447 my $taint = ${^TAINT};
448 is ${^TAINT}, $taint;
449 eval { ${^TAINT} = 1 };
450 is ${^TAINT}, $taint;
451
452 # 5.6.1 had a bug: @+ and @- were not properly interpolated
453 # into double-quoted strings
454 # 20020414 mjd-perl-patch+@plover.com
455 "I like pie" =~ /(I) (like) (pie)/;
456 is "@-",  "0 0 2 7";
457 is "@+", "10 1 6 10";
458
459 # Tests for the magic get of $\
460 {
461     my $ok = 0;
462     # [perl #19330]
463     {
464         local $\ = undef;
465         $\++; $\++;
466         $ok = $\ eq 2;
467     }
468     ok $ok;
469     $ok = 0;
470     {
471         local $\ = "a\0b";
472         $ok = "a$\b" eq "aa\0bb";
473     }
474     ok $ok;
475 }
476
477 # Test for bug [perl #36434]
478 # Can not do this test on VMS, EPOC, and SYMBIAN according to comments
479 # in mg.c/Perl_magic_clear_all_env()
480 SKIP: {
481     skip('Can\'t make assignment to \%ENV on this system', 3) if $Is_VMS;
482
483     local @ISA;
484     local %ENV;
485     # This used to be __PACKAGE__, but that causes recursive
486     #  inheritance, which is detected earlier now and broke
487     #  this test
488     eval { push @ISA, __FILE__ };
489     is $@, '', 'Push a constant on a magic array';
490     $@ and print "# $@";
491     eval { %ENV = (PATH => __PACKAGE__) };
492     is $@, '', 'Assign a constant to a magic hash';
493     $@ and print "# $@";
494     eval { my %h = qw(A B); %ENV = (PATH => (keys %h)[0]) };
495     is $@, '', 'Assign a shared key to a magic hash';
496     $@ and print "# $@";
497 }
498
499 # Tests for Perl_magic_clearsig
500 foreach my $sig (qw(__WARN__ INT)) {
501     $SIG{$sig} = lc $sig;
502     is $SIG{$sig}, 'main::' . lc $sig, "Can assign to $sig";
503     is delete $SIG{$sig}, 'main::' . lc $sig, "Can delete from $sig";
504     is $SIG{$sig}, undef, "$sig is now gone";
505     is delete $SIG{$sig}, undef, "$sig remains gone";
506 }
507
508 # And now one which doesn't exist;
509 {
510     no warnings 'signal';
511     $SIG{HUNGRY} = 'mmm, pie';
512 }
513 is $SIG{HUNGRY}, 'mmm, pie', 'Can assign to HUNGRY';
514 is delete $SIG{HUNGRY}, 'mmm, pie', 'Can delete from HUNGRY';
515 is $SIG{HUNGRY}, undef, "HUNGRY is now gone";
516 is delete $SIG{HUNGRY}, undef, "HUNGRY remains gone";
517
518 # Test deleting signals that we never set
519 foreach my $sig (qw(__DIE__ _BOGUS_HOOK KILL THIRSTY)) {
520     is $SIG{$sig}, undef, "$sig is not present";
521     is delete $SIG{$sig}, undef, "delete of $sig returns undef";
522 }
523
524 {
525     $! = 9999;
526     is int $!, 9999, q{[perl #72850] Core dump in bleadperl from perl -e '$! = 9999; $a = $!;'};
527
528 }
529
530 # ^^^^^^^^^ New tests go here ^^^^^^^^^
531
532 SKIP: {
533     skip("%ENV manipulations fail or aren't safe on $^O", 4)
534         if $Is_VMS || $Is_Dos;
535
536  SKIP: {
537         skip("clearing \%ENV is not safe when running under valgrind")
538             if $ENV{PERL_VALGRIND};
539
540             $PATH = $ENV{PATH};
541             $PDL = $ENV{PERL_DESTRUCT_LEVEL} || 0;
542             $ENV{foo} = "bar";
543             %ENV = ();
544             $ENV{PATH} = $PATH;
545             $ENV{PERL_DESTRUCT_LEVEL} = $PDL || 0;
546             if ($Is_MSWin32) {
547                 is `set foo 2>NUL`, "";
548             } else {
549                 is `echo \$foo`, "\n";
550             }
551         }
552
553         $ENV{__NoNeSuCh} = "foo";
554         $0 = "bar";
555 # cmd.exe will echo 'variable=value' but 4nt will echo just the value
556 # -- Nikola Knezevic
557         if ($Is_MSWin32) {
558             like `set __NoNeSuCh`, qr/^(?:__NoNeSuCh=)?foo$/;
559         } else {
560             is `echo \$__NoNeSuCh`, "foo\n";
561         }
562     SKIP: {
563             skip("\$0 check only on Linux and FreeBSD", 2)
564                 unless $^O =~ /^(linux|freebsd)$/
565                     && open CMDLINE, "/proc/$$/cmdline";
566
567             chomp(my $line = scalar <CMDLINE>);
568             my $me = (split /\0/, $line)[0];
569             is $me, $0, 'altering $0 is effective (testing with /proc/)';
570             close CMDLINE;
571             # perlbug #22811
572             my $mydollarzero = sub {
573               my($arg) = shift;
574               $0 = $arg if defined $arg;
575               # In FreeBSD the ps -o command= will cause
576               # an empty header line, grab only the last line.
577               my $ps = (`ps -o command= -p $$`)[-1];
578               return if $?;
579               chomp $ps;
580               printf "# 0[%s]ps[%s]\n", $0, $ps;
581               $ps;
582             };
583             my $ps = $mydollarzero->("x");
584             ok(!$ps  # we allow that something goes wrong with the ps command
585                # In Linux 2.4 we would get an exact match ($ps eq 'x') but
586                # in Linux 2.2 there seems to be something funny going on:
587                # it seems as if the original length of the argv[] would
588                # be stored in the proc struct and then used by ps(1),
589                # no matter what characters we use to pad the argv[].
590                # (And if we use \0:s, they are shown as spaces.)  Sigh.
591                || $ps =~ /^x\s*$/
592                # FreeBSD cannot get rid of both the leading "perl :"
593                # and the trailing " (perl)": some FreeBSD versions
594                # can get rid of the first one.
595                || ($^O eq 'freebsd' && $ps =~ m/^(?:perl: )?x(?: \(perl\))?$/),
596                        'altering $0 is effective (testing with `ps`)');
597         }
598 }
599
600 # test case-insignificance of %ENV (these tests must be enabled only
601 # when perl is compiled with -DENV_IS_CASELESS)
602 SKIP: {
603     skip('no caseless %ENV support', 4) unless $Is_MSWin32 || $Is_NetWare;
604
605     %ENV = ();
606     $ENV{'Foo'} = 'bar';
607     $ENV{'fOo'} = 'baz';
608     is scalar(keys(%ENV)), 1;
609     ok exists $ENV{'FOo'};
610     is delete $ENV{'foO'}, 'baz';
611     is scalar(keys(%ENV)), 0;
612 }
613
614 __END__
615
616 # Put new tests before the various ENV tests, as they blow %ENV away.