Clarify VMS-specific handling of $/ = \N.
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 The Syntax of Variable Names
8
9 Variable names in Perl can have several formats.  Usually, they
10 must begin with a letter or underscore, in which case they can be
11 arbitrarily long (up to an internal limit of 251 characters) and
12 may contain letters, digits, underscores, or the special sequence
13 C<::> or C<'>.  In this case, the part before the last C<::> or
14 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
15
16 Perl variable names may also be a sequence of digits or a single
17 punctuation or control character.  These names are all reserved for
18 special uses by Perl; for example, the all-digits names are used
19 to hold data captured by backreferences after a regular expression
20 match.  Perl has a special syntax for the single-control-character
21 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
22 character.  For example, the notation C<$^W> (dollar-sign caret
23 C<W>) is the scalar variable whose name is the single character
24 control-C<W>.  This is better than typing a literal control-C<W>
25 into your program.
26
27 Since Perl 5.6, Perl variable names may be alphanumeric
28 strings that begin with control characters (or better yet, a caret).
29 These variables must be written in the form C<${^Foo}>; the braces
30 are not optional.  C<${^Foo}> denotes the scalar variable whose
31 name is a control-C<F> followed by two C<o>'s.  These variables are
32 reserved for future special uses by Perl, except for the ones that
33 begin with C<^_> (control-underscore or caret-underscore).  No
34 control-character name that begins with C<^_> will acquire a special
35 meaning in any future version of Perl; such names may therefore be
36 used safely in programs.  C<$^_> itself, however, I<is> reserved.
37
38 Perl identifiers that begin with digits, control characters, or
39 punctuation characters are exempt from the effects of the C<package>
40 declaration and are always forced to be in package C<main>; they are
41 also exempt from C<strict 'vars'> errors.  A few other names are also
42 exempt in these ways:
43
44     ENV      STDIN
45     INC      STDOUT
46     ARGV     STDERR
47     ARGVOUT
48     SIG
49
50 In particular, the special C<${^_XYZ}> variables are always taken
51 to be in package C<main>, regardless of any C<package> declarations
52 presently in scope.
53
54 =head1 SPECIAL VARIABLES
55
56 The following names have special meaning to Perl.  Most punctuation
57 names have reasonable mnemonics, or analogs in the shells.
58 Nevertheless, if you wish to use long variable names, you need only say:
59
60     use English;
61
62 at the top of your program.  This aliases all the short names to the long
63 names in the current package.  Some even have medium names, generally
64 borrowed from B<awk>.  To avoid a performance hit, if you don't need the
65 C<$PREMATCH>, C<$MATCH>, or C<$POSTMATCH> it's best to use the C<English>
66 module without them:
67
68     use English '-no_match_vars';
69
70 Before you continue, note the sort order for variables.  In general, we
71 first list the variables in case-insensitive, almost-lexigraphical
72 order (ignoring the C<{> or C<^> preceding words, as in C<${^UNICODE}>
73 or C<$^T>), although C<$_> and C<@_> move up to the top of the pile.
74 For variables with the same identifier, we list it in order of scalar,
75 array, hash, and bareword.
76
77 =head2 General Variables
78
79 =over 8
80
81 =item $ARG
82
83 =item $_
84 X<$_> X<$ARG>
85
86 The default input and pattern-searching space.  The following pairs are
87 equivalent:
88
89     while (<>) {...}    # equivalent only in while!
90     while (defined($_ = <>)) {...}
91
92     /^Subject:/
93     $_ =~ /^Subject:/
94
95     tr/a-z/A-Z/
96     $_ =~ tr/a-z/A-Z/
97
98     chomp
99     chomp($_)
100
101 Here are the places where Perl will assume C<$_> even if you don't use it:
102
103 =over 3
104
105 =item *
106
107 The following functions use C<$_> as a default argument:
108
109 abs, alarm, chomp, chop, chr, chroot,
110 cos, defined, eval, evalbytes, exp, glob,
111 hex, int, lc, lcfirst, length, log, lstat, mkdir, oct, ord, pos, print,
112 quotemeta, readlink, readpipe, ref, require, reverse (in scalar context only),
113 rmdir, sin, split (on its second argument), sqrt, stat, study, uc, ucfirst,
114 unlink, unpack.
115
116 =item *
117
118 All file tests (C<-f>, C<-d>) except for C<-t>, which defaults to STDIN.
119 See L<perlfunc/-X>
120
121 =item *
122
123 The pattern matching operations C<m//>, C<s///> and C<tr///> (aka C<y///>)
124 when used without an C<=~> operator.
125
126 =item *
127
128 The default iterator variable in a C<foreach> loop if no other
129 variable is supplied.
130
131 =item *
132
133 The implicit iterator variable in the C<grep()> and C<map()> functions.
134
135 =item *
136
137 The implicit variable of C<given()>.
138
139 =item *
140
141 The default place to put an input record when a C<< <FH> >>
142 operation's result is tested by itself as the sole criterion of a C<while>
143 test.  Outside a C<while> test, this will not happen.
144
145 =back
146
147 As C<$_> is a global variable, this may lead in some cases to unwanted
148 side-effects.  As of perl 5.10, you can now use a lexical version of
149 C<$_> by declaring it in a file or in a block with C<my>.  Moreover,
150 declaring C<our $_> restores the global C<$_> in the current scope.
151
152 Mnemonic: underline is understood in certain operations.
153
154 =item @ARG
155
156 =item @_
157 X<@_> X<@ARG>
158
159 Within a subroutine the array C<@_> contains the parameters passed to
160 that subroutine.  Inside a subroutine, C<@_> is the default array for
161 the array operators C<push>, C<pop>, C<shift>, and C<unshift>.
162
163 See L<perlsub>.
164
165 =item $LIST_SEPARATOR
166
167 =item $"
168 X<$"> X<$LIST_SEPARATOR>
169
170 When an array or an array slice is interpolated into a double-quoted
171 string or a similar context such as C</.../>, its elements are
172 separated by this value.  Default is a space.  For example, this:
173
174     print "The array is: @array\n";
175
176 is equivalent to this:
177
178     print "The array is: " . join($", @array) . "\n";
179
180 Mnemonic: works in double-quoted context.
181
182 =item $PROCESS_ID
183
184 =item $PID
185
186 =item $$
187 X<$$> X<$PID> X<$PROCESS_ID>
188
189 The process number of the Perl running this script.  Though you I<can> set
190 this variable, doing so is generally discouraged, although it can be
191 invaluable for some testing purposes.  It will be reset automatically
192 across C<fork()> calls.
193
194 Note for Linux and Debian GNU/kFreeBSD users: Before Perl v5.16.0 perl
195 would emulate POSIX semantics on Linux systems using LinuxThreads, a
196 partial implementation of POSIX Threads that has since been superseded
197 by the Native POSIX Thread Library (NPTL).
198
199 LinuxThreads is now obsolete on Linux, and and caching C<getpid()>
200 like this made embedding perl unnecessarily complex (since you'd have
201 to manually update the value of $$), so now C<$$> and C<getppid()>
202 will always return the same values as the underlying C library.
203
204 Debian GNU/kFreeBSD systems also used LinuxThreads up until and
205 including the 6.0 release, but after that moved to FreeBSD thread
206 semantics, which are POSIX-like.
207
208 To see if your system is affected by this discrepancy check if
209 C<getconf GNU_LIBPTHREAD_VERSION | grep -q NPTL> returns a false
210 value. NTPL threads preserve the POSIX semantics.
211
212 Mnemonic: same as shells.
213
214 =item $PROGRAM_NAME
215
216 =item $0
217 X<$0> X<$PROGRAM_NAME>
218
219 Contains the name of the program being executed.
220
221 On some (but not all) operating systems assigning to C<$0> modifies
222 the argument area that the C<ps> program sees.  On some platforms you
223 may have to use special C<ps> options or a different C<ps> to see the
224 changes.  Modifying the C<$0> is more useful as a way of indicating the
225 current program state than it is for hiding the program you're
226 running.
227
228 Note that there are platform-specific limitations on the maximum
229 length of C<$0>.  In the most extreme case it may be limited to the
230 space occupied by the original C<$0>.
231
232 In some platforms there may be arbitrary amount of padding, for
233 example space characters, after the modified name as shown by C<ps>.
234 In some platforms this padding may extend all the way to the original
235 length of the argument area, no matter what you do (this is the case
236 for example with Linux 2.2).
237
238 Note for BSD users: setting C<$0> does not completely remove "perl"
239 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> may
240 result in C<"perl: foobar (perl)"> (whether both the C<"perl: "> prefix
241 and the " (perl)" suffix are shown depends on your exact BSD variant
242 and version).  This is an operating system feature, Perl cannot help it.
243
244 In multithreaded scripts Perl coordinates the threads so that any
245 thread may modify its copy of the C<$0> and the change becomes visible
246 to ps(1) (assuming the operating system plays along).  Note that
247 the view of C<$0> the other threads have will not change since they
248 have their own copies of it.
249
250 If the program has been given to perl via the switches C<-e> or C<-E>,
251 C<$0> will contain the string C<"-e">.
252
253 On Linux as of perl 5.14 the legacy process name will be set with
254 C<prctl(2)>, in addition to altering the POSIX name via C<argv[0]> as
255 perl has done since version 4.000.  Now system utilities that read the
256 legacy process name such as ps, top and killall will recognize the
257 name you set when assigning to C<$0>.  The string you supply will be
258 cut off at 16 bytes, this is a limitation imposed by Linux.
259
260 Mnemonic: same as B<sh> and B<ksh>.
261
262 =item $REAL_GROUP_ID
263
264 =item $GID
265
266 =item $(
267 X<$(> X<$GID> X<$REAL_GROUP_ID>
268
269 The real gid of this process.  If you are on a machine that supports
270 membership in multiple groups simultaneously, gives a space separated
271 list of groups you are in.  The first number is the one returned by
272 C<getgid()>, and the subsequent ones by C<getgroups()>, one of which may be
273 the same as the first number.
274
275 However, a value assigned to C<$(> must be a single number used to
276 set the real gid.  So the value given by C<$(> should I<not> be assigned
277 back to C<$(> without being forced numeric, such as by adding zero.  Note
278 that this is different to the effective gid (C<$)>) which does take a
279 list.
280
281 You can change both the real gid and the effective gid at the same
282 time by using C<POSIX::setgid()>.  Changes
283 to C<$(> require a check to C<$!>
284 to detect any possible errors after an attempted change.
285
286 Mnemonic: parentheses are used to I<group> things.  The real gid is the
287 group you I<left>, if you're running setgid.
288
289 =item $EFFECTIVE_GROUP_ID
290
291 =item $EGID
292
293 =item $)
294 X<$)> X<$EGID> X<$EFFECTIVE_GROUP_ID>
295
296 The effective gid of this process.  If you are on a machine that
297 supports membership in multiple groups simultaneously, gives a space
298 separated list of groups you are in.  The first number is the one
299 returned by C<getegid()>, and the subsequent ones by C<getgroups()>,
300 one of which may be the same as the first number.
301
302 Similarly, a value assigned to C<$)> must also be a space-separated
303 list of numbers.  The first number sets the effective gid, and
304 the rest (if any) are passed to C<setgroups()>.  To get the effect of an
305 empty list for C<setgroups()>, just repeat the new effective gid; that is,
306 to force an effective gid of 5 and an effectively empty C<setgroups()>
307 list, say C< $) = "5 5" >.
308
309 You can change both the effective gid and the real gid at the same
310 time by using C<POSIX::setgid()> (use only a single numeric argument).
311 Changes to C<$)> require a check to C<$!> to detect any possible errors
312 after an attempted change.
313
314 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
315 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
316 and C<$)> can be swapped only on machines supporting C<setregid()>.
317
318 Mnemonic: parentheses are used to I<group> things.  The effective gid
319 is the group that's I<right> for you, if you're running setgid.
320
321 =item $REAL_USER_ID
322
323 =item $UID
324
325 =item $<
326 X<< $< >> X<$UID> X<$REAL_USER_ID>
327
328 The real uid of this process.  You can change both the real uid and the
329 effective uid at the same time by using C<POSIX::setuid()>.  Since
330 changes to C<< $< >> require a system call, check C<$!> after a change
331 attempt to detect any possible errors.
332
333 Mnemonic: it's the uid you came I<from>, if you're running setuid.
334
335 =item $EFFECTIVE_USER_ID
336
337 =item $EUID
338
339 =item $>
340 X<< $> >> X<$EUID> X<$EFFECTIVE_USER_ID>
341
342 The effective uid of this process.  For example:
343
344     $< = $>;            # set real to effective uid
345     ($<,$>) = ($>,$<);  # swap real and effective uids
346
347 You can change both the effective uid and the real uid at the same
348 time by using C<POSIX::setuid()>.  Changes to C<< $> >> require a check
349 to C<$!> to detect any possible errors after an attempted change.
350
351 C<< $< >> and C<< $> >> can be swapped only on machines
352 supporting C<setreuid()>.
353
354 Mnemonic: it's the uid you went I<to>, if you're running setuid.
355
356 =item $SUBSCRIPT_SEPARATOR
357
358 =item $SUBSEP
359
360 =item $;
361 X<$;> X<$SUBSEP> X<SUBSCRIPT_SEPARATOR>
362
363 The subscript separator for multidimensional array emulation.  If you
364 refer to a hash element as
365
366     $foo{$a,$b,$c}
367
368 it really means
369
370     $foo{join($;, $a, $b, $c)}
371
372 But don't put
373
374     @foo{$a,$b,$c}      # a slice--note the @
375
376 which means
377
378     ($foo{$a},$foo{$b},$foo{$c})
379
380 Default is "\034", the same as SUBSEP in B<awk>.  If your keys contain
381 binary data there might not be any safe value for C<$;>.
382
383 Consider using "real" multidimensional arrays as described
384 in L<perllol>.
385
386 Mnemonic: comma (the syntactic subscript separator) is a semi-semicolon.
387
388 =item $a
389
390 =item $b
391 X<$a> X<$b>
392
393 Special package variables when using C<sort()>, see L<perlfunc/sort>.
394 Because of this specialness C<$a> and C<$b> don't need to be declared
395 (using C<use vars>, or C<our()>) even when using the C<strict 'vars'>
396 pragma.  Don't lexicalize them with C<my $a> or C<my $b> if you want to
397 be able to use them in the C<sort()> comparison block or function.
398
399 =item %ENV
400 X<%ENV>
401
402 The hash C<%ENV> contains your current environment.  Setting a
403 value in C<ENV> changes the environment for any child processes
404 you subsequently C<fork()> off.
405
406 =item $SYSTEM_FD_MAX
407
408 =item $^F
409 X<$^F> X<$SYSTEM_FD_MAX>
410
411 The maximum system file descriptor, ordinarily 2.  System file
412 descriptors are passed to C<exec()>ed processes, while higher file
413 descriptors are not.  Also, during an
414 C<open()>, system file descriptors are
415 preserved even if the C<open()> fails (ordinary file descriptors are
416 closed before the C<open()> is attempted).  The close-on-exec
417 status of a file descriptor will be decided according to the value of
418 C<$^F> when the corresponding file, pipe, or socket was opened, not the
419 time of the C<exec()>.
420
421 =item @F
422 X<@F>
423
424 The array C<@F> contains the fields of each line read in when autosplit
425 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
426 is package-specific, and must be declared or given a full package name
427 if not in package main when running under C<strict 'vars'>.
428
429 =item @INC
430 X<@INC>
431
432 The array C<@INC> contains the list of places that the C<do EXPR>,
433 C<require>, or C<use> constructs look for their library files.  It
434 initially consists of the arguments to any B<-I> command-line
435 switches, followed by the default Perl library, probably
436 F</usr/local/lib/perl>, followed by ".", to represent the current
437 directory.  ("." will not be appended if taint checks are enabled,
438 either by C<-T> or by C<-t>.)  If you need to modify this at runtime,
439 you should use the C<use lib> pragma to get the machine-dependent
440 library properly loaded also:
441
442     use lib '/mypath/libdir/';
443     use SomeMod;
444
445 You can also insert hooks into the file inclusion system by putting Perl
446 code directly into C<@INC>.  Those hooks may be subroutine references,
447 array references or blessed objects.  See L<perlfunc/require> for details.
448
449 =item %INC
450 X<%INC>
451
452 The hash C<%INC> contains entries for each filename included via the
453 C<do>, C<require>, or C<use> operators.  The key is the filename
454 you specified (with module names converted to pathnames), and the
455 value is the location of the file found.  The C<require>
456 operator uses this hash to determine whether a particular file has
457 already been included.
458
459 If the file was loaded via a hook (e.g. a subroutine reference, see
460 L<perlfunc/require> for a description of these hooks), this hook is
461 by default inserted into C<%INC> in place of a filename.  Note, however,
462 that the hook may have set the C<%INC> entry by itself to provide some more
463 specific info.
464
465 =item $INPLACE_EDIT
466
467 =item $^I
468 X<$^I> X<$INPLACE_EDIT>
469
470 The current value of the inplace-edit extension.  Use C<undef> to disable
471 inplace editing.
472
473 Mnemonic: value of B<-i> switch.
474
475 =item $^M
476 X<$^M>
477
478 By default, running out of memory is an untrappable, fatal error.
479 However, if suitably built, Perl can use the contents of C<$^M>
480 as an emergency memory pool after C<die()>ing.  Suppose that your Perl
481 were compiled with C<-DPERL_EMERGENCY_SBRK> and used Perl's malloc.
482 Then
483
484     $^M = 'a' x (1 << 16);
485
486 would allocate a 64K buffer for use in an emergency.  See the
487 F<INSTALL> file in the Perl distribution for information on how to
488 add custom C compilation flags when compiling perl.  To discourage casual
489 use of this advanced feature, there is no L<English|English> long name for
490 this variable.
491
492 This variable was added in Perl 5.004.
493
494 =item $OSNAME
495
496 =item $^O
497 X<$^O> X<$OSNAME>
498
499 The name of the operating system under which this copy of Perl was
500 built, as determined during the configuration process.  For examples
501 see L<perlport/PLATFORMS>.
502
503 The value is identical to C<$Config{'osname'}>.  See also L<Config>
504 and the B<-V> command-line switch documented in L<perlrun>.
505
506 In Windows platforms, C<$^O> is not very helpful: since it is always
507 C<MSWin32>, it doesn't tell the difference between
508 95/98/ME/NT/2000/XP/CE/.NET.  Use C<Win32::GetOSName()> or
509 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
510 between the variants.
511
512 This variable was added in Perl 5.003.
513
514 =item %SIG
515 X<%SIG>
516
517 The hash C<%SIG> contains signal handlers for signals.  For example:
518
519     sub handler {   # 1st argument is signal name
520         my($sig) = @_;
521         print "Caught a SIG$sig--shutting down\n";
522         close(LOG);
523         exit(0);
524         }
525
526     $SIG{'INT'}  = \&handler;
527     $SIG{'QUIT'} = \&handler;
528     ...
529     $SIG{'INT'}  = 'DEFAULT';   # restore default action
530     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
531
532 Using a value of C<'IGNORE'> usually has the effect of ignoring the
533 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
534 this special case.
535
536 Here are some other examples:
537
538     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not
539                                 # recommended)
540     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current
541                                 # Plumber
542     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
543     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber()
544                                 # return??
545
546 Be sure not to use a bareword as the name of a signal handler,
547 lest you inadvertently call it.
548
549 If your system has the C<sigaction()> function then signal handlers
550 are installed using it.  This means you get reliable signal handling.
551
552 The default delivery policy of signals changed in Perl 5.8.0 from
553 immediate (also known as "unsafe") to deferred, also known as "safe
554 signals".  See L<perlipc> for more information.
555
556 Certain internal hooks can be also set using the C<%SIG> hash.  The
557 routine indicated by C<$SIG{__WARN__}> is called when a warning
558 message is about to be printed.  The warning message is passed as the
559 first argument.  The presence of a C<__WARN__> hook causes the
560 ordinary printing of warnings to C<STDERR> to be suppressed.  You can
561 use this to save warnings in a variable, or turn warnings into fatal
562 errors, like this:
563
564     local $SIG{__WARN__} = sub { die $_[0] };
565     eval $proggie;
566
567 As the C<'IGNORE'> hook is not supported by C<__WARN__>, you can
568 disable warnings using the empty subroutine:
569
570     local $SIG{__WARN__} = sub {};
571
572 The routine indicated by C<$SIG{__DIE__}> is called when a fatal
573 exception is about to be thrown.  The error message is passed as the
574 first argument.  When a C<__DIE__> hook routine returns, the exception
575 processing continues as it would have in the absence of the hook,
576 unless the hook routine itself exits via a C<goto &sub>, a loop exit,
577 or a C<die()>.  The C<__DIE__> handler is explicitly disabled during
578 the call, so that you can die from a C<__DIE__> handler.  Similarly
579 for C<__WARN__>.
580
581 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
582 even inside an C<eval()>.  Do not use this to rewrite a pending
583 exception in C<$@>, or as a bizarre substitute for overriding
584 C<CORE::GLOBAL::die()>.  This strange action at a distance may be fixed
585 in a future release so that C<$SIG{__DIE__}> is only called if your
586 program is about to exit, as was the original intent.  Any other use is
587 deprecated.
588
589 C<__DIE__>/C<__WARN__> handlers are very special in one respect: they
590 may be called to report (probable) errors found by the parser.  In such
591 a case the parser may be in inconsistent state, so any attempt to
592 evaluate Perl code from such a handler will probably result in a
593 segfault.  This means that warnings or errors that result from parsing
594 Perl should be used with extreme caution, like this:
595
596     require Carp if defined $^S;
597     Carp::confess("Something wrong") if defined &Carp::confess;
598     die "Something wrong, but could not load Carp to give "
599       . "backtrace...\n\t"
600       . "To see backtrace try starting Perl with -MCarp switch";
601
602 Here the first line will load C<Carp> I<unless> it is the parser who
603 called the handler.  The second line will print backtrace and die if
604 C<Carp> was available.  The third line will be executed only if C<Carp> was
605 not available.
606
607 Having to even think about the C<$^S> variable in your exception
608 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
609 invites grievous and difficult to track down errors.  Avoid it
610 and use an C<END{}> or CORE::GLOBAL::die override instead.
611
612 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
613 L<warnings> for additional information.
614
615 =item $BASETIME
616
617 =item $^T
618 X<$^T> X<$BASETIME>
619
620 The time at which the program began running, in seconds since the
621 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
622 and B<-C> filetests are based on this value.
623
624 =item $PERL_VERSION
625
626 =item $^V
627 X<$^V> X<$PERL_VERSION>
628
629 The revision, version, and subversion of the Perl interpreter,
630 represented as a C<version> object.
631
632 This variable first appeared in perl 5.6.0; earlier versions of perl
633 will see an undefined value.  Before perl 5.10.0 C<$^V> was represented
634 as a v-string.
635
636 C<$^V> can be used to determine whether the Perl interpreter executing
637 a script is in the right range of versions.  For example:
638
639     warn "Hashes not randomized!\n" if !$^V or $^V lt v5.8.1
640
641 To convert C<$^V> into its string representation use C<sprintf()>'s
642 C<"%vd"> conversion:
643
644     printf "version is v%vd\n", $^V;  # Perl's version
645
646 See the documentation of C<use VERSION> and C<require VERSION>
647 for a convenient way to fail if the running Perl interpreter is too old.
648
649 See also C<$]> for an older representation of the Perl version.
650
651 This variable was added in Perl 5.6.
652
653 Mnemonic: use ^V for Version Control.
654
655 =item ${^WIN32_SLOPPY_STAT}
656 X<${^WIN32_SLOPPY_STAT}> X<sitecustomize> X<sitecustomize.pl>
657
658 If this variable is set to a true value, then C<stat()> on Windows will
659 not try to open the file.  This means that the link count cannot be
660 determined and file attributes may be out of date if additional
661 hardlinks to the file exist.  On the other hand, not opening the file
662 is considerably faster, especially for files on network drives.
663
664 This variable could be set in the F<sitecustomize.pl> file to
665 configure the local Perl installation to use "sloppy" C<stat()> by
666 default.  See the documentation for B<-f> in
667 L<perlrun|perlrun/"Command Switches"> for more information about site
668 customization.
669
670 This variable was added in Perl 5.10.
671
672 =item $EXECUTABLE_NAME
673
674 =item $^X
675 X<$^X> X<$EXECUTABLE_NAME>
676
677 The name used to execute the current copy of Perl, from C's
678 C<argv[0]> or (where supported) F</proc/self/exe>.
679
680 Depending on the host operating system, the value of C<$^X> may be
681 a relative or absolute pathname of the perl program file, or may
682 be the string used to invoke perl but not the pathname of the
683 perl program file.  Also, most operating systems permit invoking
684 programs that are not in the PATH environment variable, so there
685 is no guarantee that the value of C<$^X> is in PATH.  For VMS, the
686 value may or may not include a version number.
687
688 You usually can use the value of C<$^X> to re-invoke an independent
689 copy of the same perl that is currently running, e.g.,
690
691     @first_run = `$^X -le "print int rand 100 for 1..100"`;
692
693 But recall that not all operating systems support forking or
694 capturing of the output of commands, so this complex statement
695 may not be portable.
696
697 It is not safe to use the value of C<$^X> as a path name of a file,
698 as some operating systems that have a mandatory suffix on
699 executable files do not require use of the suffix when invoking
700 a command.  To convert the value of C<$^X> to a path name, use the
701 following statements:
702
703     # Build up a set of file names (not command names).
704     use Config;
705     my $this_perl = $^X;
706     if ($^O ne 'VMS') {
707         $this_perl .= $Config{_exe}
708           unless $this_perl =~ m/$Config{_exe}$/i;
709         }
710
711 Because many operating systems permit anyone with read access to
712 the Perl program file to make a copy of it, patch the copy, and
713 then execute the copy, the security-conscious Perl programmer
714 should take care to invoke the installed copy of perl, not the
715 copy referenced by C<$^X>.  The following statements accomplish
716 this goal, and produce a pathname that can be invoked as a
717 command or referenced as a file.
718
719     use Config;
720     my $secure_perl_path = $Config{perlpath};
721     if ($^O ne 'VMS') {
722         $secure_perl_path .= $Config{_exe}
723             unless $secure_perl_path =~ m/$Config{_exe}$/i;
724         }
725
726 =back
727
728 =head2 Variables related to regular expressions
729
730 Most of the special variables related to regular expressions are side
731 effects.  Perl sets these variables when it has a successful match, so
732 you should check the match result before using them.  For instance:
733
734     if( /P(A)TT(ER)N/ ) {
735         print "I found $1 and $2\n";
736         }
737
738 These variables are read-only and dynamically-scoped, unless we note
739 otherwise.
740
741 The dynamic nature of the regular expression variables means that
742 their value is limited to the block that they are in, as demonstrated
743 by this bit of code:
744
745     my $outer = 'Wallace and Grommit';
746     my $inner = 'Mutt and Jeff';
747
748     my $pattern = qr/(\S+) and (\S+)/;
749
750     sub show_n { print "\$1 is $1; \$2 is $2\n" }
751
752     {
753     OUTER:
754         show_n() if $outer =~ m/$pattern/;
755
756         INNER: {
757             show_n() if $inner =~ m/$pattern/;
758             }
759
760         show_n();
761     }
762
763 The output shows that while in the C<OUTER> block, the values of C<$1>
764 and C<$2> are from the match against C<$outer>.  Inside the C<INNER>
765 block, the values of C<$1> and C<$2> are from the match against
766 C<$inner>, but only until the end of the block (i.e. the dynamic
767 scope).  After the C<INNER> block completes, the values of C<$1> and
768 C<$2> return to the values for the match against C<$outer> even though
769 we have not made another match:
770
771     $1 is Wallace; $2 is Grommit
772     $1 is Mutt; $2 is Jeff
773     $1 is Wallace; $2 is Grommit
774
775 Due to an unfortunate accident of Perl's implementation, C<use
776 English> imposes a considerable performance penalty on all regular
777 expression matches in a program because it uses the C<$`>, C<$&>, and
778 C<$'>, regardless of whether they occur in the scope of C<use
779 English>.  For that reason, saying C<use English> in libraries is
780 strongly discouraged unless you import it without the match variables:
781
782     use English '-no_match_vars'
783
784 The C<Devel::NYTProf> and C<Devel::FindAmpersand>
785 modules can help you find uses of these
786 problematic match variables in your code.
787
788 Since Perl 5.10, you can use the C</p> match operator flag and the
789 C<${^PREMATCH}>, C<${^MATCH}>, and C<${^POSTMATCH}> variables instead
790 so you only suffer the performance penalties.
791
792 =over 8
793
794 =item $<I<digits>> ($1, $2, ...)
795 X<$1> X<$2> X<$3>
796
797 Contains the subpattern from the corresponding set of capturing
798 parentheses from the last successful pattern match, not counting patterns
799 matched in nested blocks that have been exited already.
800
801 These variables are read-only and dynamically-scoped.
802
803 Mnemonic: like \digits.
804
805 =item $MATCH
806
807 =item $&
808 X<$&> X<$MATCH>
809
810 The string matched by the last successful pattern match (not counting
811 any matches hidden within a BLOCK or C<eval()> enclosed by the current
812 BLOCK).
813
814 The use of this variable anywhere in a program imposes a considerable
815 performance penalty on all regular expression matches.  To avoid this
816 penalty, you can extract the same substring by using L</@->.  Starting
817 with Perl 5.10, you can use the C</p> match flag and the C<${^MATCH}>
818 variable to do the same thing for particular match operations.
819
820 This variable is read-only and dynamically-scoped.
821
822 Mnemonic: like C<&> in some editors.
823
824 =item ${^MATCH}
825 X<${^MATCH}>
826
827 This is similar to C<$&> (C<$MATCH>) except that it does not incur the
828 performance penalty associated with that variable, and is only guaranteed
829 to return a defined value when the pattern was compiled or executed with
830 the C</p> modifier.
831
832 This variable was added in Perl 5.10.
833
834 This variable is read-only and dynamically-scoped.
835
836 =item $PREMATCH
837
838 =item $`
839 X<$`> X<$PREMATCH> X<${^PREMATCH}>
840
841 The string preceding whatever was matched by the last successful
842 pattern match, not counting any matches hidden within a BLOCK or C<eval>
843 enclosed by the current BLOCK.
844
845 The use of this variable anywhere in a program imposes a considerable
846 performance penalty on all regular expression matches.  To avoid this
847 penalty, you can extract the same substring by using L</@->.  Starting
848 with Perl 5.10, you can use the C</p> match flag and the
849 C<${^PREMATCH}> variable to do the same thing for particular match
850 operations.
851
852 This variable is read-only and dynamically-scoped.
853
854 Mnemonic: C<`> often precedes a quoted string.
855
856 =item ${^PREMATCH}
857 X<$`> X<${^PREMATCH}>
858
859 This is similar to C<$`> ($PREMATCH) except that it does not incur the
860 performance penalty associated with that variable, and is only guaranteed
861 to return a defined value when the pattern was compiled or executed with
862 the C</p> modifier.
863
864 This variable was added in Perl 5.10
865
866 This variable is read-only and dynamically-scoped.
867
868 =item $POSTMATCH
869
870 =item $'
871 X<$'> X<$POSTMATCH> X<${^POSTMATCH}> X<@->
872
873 The string following whatever was matched by the last successful
874 pattern match (not counting any matches hidden within a BLOCK or C<eval()>
875 enclosed by the current BLOCK).  Example:
876
877     local $_ = 'abcdefghi';
878     /def/;
879     print "$`:$&:$'\n";         # prints abc:def:ghi
880
881 The use of this variable anywhere in a program imposes a considerable
882 performance penalty on all regular expression matches.
883 To avoid this penalty, you can extract the same substring by
884 using L</@->.  Starting with Perl 5.10, you can use the C</p> match flag
885 and the C<${^POSTMATCH}> variable to do the same thing for particular
886 match operations.
887
888 This variable is read-only and dynamically-scoped.
889
890 Mnemonic: C<'> often follows a quoted string.
891
892 =item ${^POSTMATCH}
893 X<${^POSTMATCH}> X<$'> X<$POSTMATCH>
894
895 This is similar to C<$'> (C<$POSTMATCH>) except that it does not incur the
896 performance penalty associated with that variable, and is only guaranteed
897 to return a defined value when the pattern was compiled or executed with
898 the C</p> modifier.
899
900 This variable was added in Perl 5.10.
901
902 This variable is read-only and dynamically-scoped.
903
904 =item $LAST_PAREN_MATCH
905
906 =item $+
907 X<$+> X<$LAST_PAREN_MATCH>
908
909 The text matched by the last bracket of the last successful search pattern.
910 This is useful if you don't know which one of a set of alternative patterns
911 matched.  For example:
912
913     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
914
915 This variable is read-only and dynamically-scoped.
916
917 Mnemonic: be positive and forward looking.
918
919 =item $LAST_SUBMATCH_RESULT
920
921 =item $^N
922 X<$^N> X<$LAST_SUBMATCH_RESULT>
923
924 The text matched by the used group most-recently closed (i.e. the group
925 with the rightmost closing parenthesis) of the last successful search
926 pattern.
927
928 This is primarily used inside C<(?{...})> blocks for examining text
929 recently matched.  For example, to effectively capture text to a variable
930 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
931
932     (?:(...)(?{ $var = $^N }))
933
934 By setting and then using C<$var> in this way relieves you from having to
935 worry about exactly which numbered set of parentheses they are.
936
937 This variable was added in Perl 5.8.
938
939 Mnemonic: the (possibly) Nested parenthesis that most recently closed.
940
941 =item @LAST_MATCH_END
942
943 =item @+
944 X<@+> X<@LAST_MATCH_END>
945
946 This array holds the offsets of the ends of the last successful
947 submatches in the currently active dynamic scope.  C<$+[0]> is
948 the offset into the string of the end of the entire match.  This
949 is the same value as what the C<pos> function returns when called
950 on the variable that was matched against.  The I<n>th element
951 of this array holds the offset of the I<n>th submatch, so
952 C<$+[1]> is the offset past where C<$1> ends, C<$+[2]> the offset
953 past where C<$2> ends, and so on.  You can use C<$#+> to determine
954 how many subgroups were in the last successful match.  See the
955 examples given for the C<@-> variable.
956
957 This variable was added in Perl 5.6.
958
959 =item %LAST_PAREN_MATCH
960
961 =item %+
962 X<%+> X<%LAST_PAREN_MATCH>
963
964 Similar to C<@+>, the C<%+> hash allows access to the named capture
965 buffers, should they exist, in the last successful match in the
966 currently active dynamic scope.
967
968 For example, C<$+{foo}> is equivalent to C<$1> after the following match:
969
970     'foo' =~ /(?<foo>foo)/;
971
972 The keys of the C<%+> hash list only the names of buffers that have
973 captured (and that are thus associated to defined values).
974
975 The underlying behaviour of C<%+> is provided by the
976 L<Tie::Hash::NamedCapture> module.
977
978 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
979 associated with the last successful regular expression.  Therefore mixing
980 iterative access to them via C<each> may have unpredictable results.
981 Likewise, if the last successful match changes, then the results may be
982 surprising.
983
984 This variable was added in Perl 5.10.
985
986 This variable is read-only and dynamically-scoped.
987
988 =item @LAST_MATCH_START
989
990 =item @-
991 X<@-> X<@LAST_MATCH_START>
992
993 C<$-[0]> is the offset of the start of the last successful match.
994 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
995 I<n>-th subpattern, or undef if the subpattern did not match.
996
997 Thus, after a match against C<$_>, C<$&> coincides with C<substr $_, $-[0],
998 $+[0] - $-[0]>.  Similarly, $I<n> coincides with C<substr $_, $-[n],
999 $+[n] - $-[n]> if C<$-[n]> is defined, and $+ coincides with
1000 C<substr $_, $-[$#-], $+[$#-] - $-[$#-]>.  One can use C<$#-> to find the
1001 last matched subgroup in the last successful match.  Contrast with
1002 C<$#+>, the number of subgroups in the regular expression.  Compare
1003 with C<@+>.
1004
1005 This array holds the offsets of the beginnings of the last
1006 successful submatches in the currently active dynamic scope.
1007 C<$-[0]> is the offset into the string of the beginning of the
1008 entire match.  The I<n>th element of this array holds the offset
1009 of the I<n>th submatch, so C<$-[1]> is the offset where C<$1>
1010 begins, C<$-[2]> the offset where C<$2> begins, and so on.
1011
1012 After a match against some variable C<$var>:
1013
1014 =over 5
1015
1016 =item C<$`> is the same as C<substr($var, 0, $-[0])>
1017
1018 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
1019
1020 =item C<$'> is the same as C<substr($var, $+[0])>
1021
1022 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>
1023
1024 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
1025
1026 =item C<$3> is the same as C<substr($var, $-[3], $+[3] - $-[3])>
1027
1028 =back
1029
1030 This variable was added in Perl 5.6.
1031
1032 =item %LAST_MATCH_START
1033
1034 =item %-
1035 X<%-> X<%LAST_MATCH_START>
1036
1037 Similar to C<%+>, this variable allows access to the named capture groups
1038 in the last successful match in the currently active dynamic scope.  To
1039 each capture group name found in the regular expression, it associates a
1040 reference to an array containing the list of values captured by all
1041 buffers with that name (should there be several of them), in the order
1042 where they appear.
1043
1044 Here's an example:
1045
1046     if ('1234' =~ /(?<A>1)(?<B>2)(?<A>3)(?<B>4)/) {
1047         foreach my $bufname (sort keys %-) {
1048             my $ary = $-{$bufname};
1049             foreach my $idx (0..$#$ary) {
1050                 print "\$-{$bufname}[$idx] : ",
1051                       (defined($ary->[$idx])
1052                           ? "'$ary->[$idx]'"
1053                           : "undef"),
1054                       "\n";
1055             }
1056         }
1057     }
1058
1059 would print out:
1060
1061     $-{A}[0] : '1'
1062     $-{A}[1] : '3'
1063     $-{B}[0] : '2'
1064     $-{B}[1] : '4'
1065
1066 The keys of the C<%-> hash correspond to all buffer names found in
1067 the regular expression.
1068
1069 The behaviour of C<%-> is implemented via the
1070 L<Tie::Hash::NamedCapture> module.
1071
1072 B<Note:> C<%-> and C<%+> are tied views into a common internal hash
1073 associated with the last successful regular expression.  Therefore mixing
1074 iterative access to them via C<each> may have unpredictable results.
1075 Likewise, if the last successful match changes, then the results may be
1076 surprising.
1077
1078 This variable was added in Perl 5.10
1079
1080 This variable is read-only and dynamically-scoped.
1081
1082 =item $LAST_REGEXP_CODE_RESULT
1083
1084 =item $^R
1085 X<$^R> X<$LAST_REGEXP_CODE_RESULT>
1086
1087 The result of evaluation of the last successful C<(?{ code })>
1088 regular expression assertion (see L<perlre>).  May be written to.
1089
1090 This variable was added in Perl 5.005.
1091
1092 =item ${^RE_DEBUG_FLAGS}
1093 X<${^RE_DEBUG_FLAGS}>
1094
1095 The current value of the regex debugging flags.  Set to 0 for no debug output
1096 even when the C<re 'debug'> module is loaded.  See L<re> for details.
1097
1098 This variable was added in Perl 5.10.
1099
1100 =item ${^RE_TRIE_MAXBUF}
1101 X<${^RE_TRIE_MAXBUF}>
1102
1103 Controls how certain regex optimisations are applied and how much memory they
1104 utilize.  This value by default is 65536 which corresponds to a 512kB
1105 temporary cache.  Set this to a higher value to trade
1106 memory for speed when matching large alternations.  Set
1107 it to a lower value if you want the optimisations to
1108 be as conservative of memory as possible but still occur, and set it to a
1109 negative value to prevent the optimisation and conserve the most memory.
1110 Under normal situations this variable should be of no interest to you.
1111
1112 This variable was added in Perl 5.10.
1113
1114 =back
1115
1116 =head2 Variables related to filehandles
1117
1118 Variables that depend on the currently selected filehandle may be set
1119 by calling an appropriate object method on the C<IO::Handle> object,
1120 although this is less efficient than using the regular built-in
1121 variables.  (Summary lines below for this contain the word HANDLE.)
1122 First you must say
1123
1124     use IO::Handle;
1125
1126 after which you may use either
1127
1128     method HANDLE EXPR
1129
1130 or more safely,
1131
1132     HANDLE->method(EXPR)
1133
1134 Each method returns the old value of the C<IO::Handle> attribute.  The
1135 methods each take an optional EXPR, which, if supplied, specifies the
1136 new value for the C<IO::Handle> attribute in question.  If not
1137 supplied, most methods do nothing to the current value--except for
1138 C<autoflush()>, which will assume a 1 for you, just to be different.
1139
1140 Because loading in the C<IO::Handle> class is an expensive operation,
1141 you should learn how to use the regular built-in variables.
1142
1143 A few of these variables are considered "read-only".  This means that
1144 if you try to assign to this variable, either directly or indirectly
1145 through a reference, you'll raise a run-time exception.
1146
1147 You should be very careful when modifying the default values of most
1148 special variables described in this document.  In most cases you want
1149 to localize these variables before changing them, since if you don't,
1150 the change may affect other modules which rely on the default values
1151 of the special variables that you have changed.  This is one of the
1152 correct ways to read the whole file at once:
1153
1154     open my $fh, "<", "foo" or die $!;
1155     local $/; # enable localized slurp mode
1156     my $content = <$fh>;
1157     close $fh;
1158
1159 But the following code is quite bad:
1160
1161     open my $fh, "<", "foo" or die $!;
1162     undef $/; # enable slurp mode
1163     my $content = <$fh>;
1164     close $fh;
1165
1166 since some other module, may want to read data from some file in the
1167 default "line mode", so if the code we have just presented has been
1168 executed, the global value of C<$/> is now changed for any other code
1169 running inside the same Perl interpreter.
1170
1171 Usually when a variable is localized you want to make sure that this
1172 change affects the shortest scope possible.  So unless you are already
1173 inside some short C<{}> block, you should create one yourself.  For
1174 example:
1175
1176     my $content = '';
1177     open my $fh, "<", "foo" or die $!;
1178     {
1179         local $/;
1180         $content = <$fh>;
1181     }
1182     close $fh;
1183
1184 Here is an example of how your own code can go broken:
1185
1186     for ( 1..3 ){
1187         $\ = "\r\n";
1188         nasty_break();
1189         print "$_";
1190     }
1191
1192     sub nasty_break {
1193         $\ = "\f";
1194         # do something with $_
1195     }
1196
1197 You probably expect this code to print the equivalent of
1198
1199     "1\r\n2\r\n3\r\n"
1200
1201 but instead you get:
1202
1203     "1\f2\f3\f"
1204
1205 Why? Because C<nasty_break()> modifies C<$\> without localizing it
1206 first.  The value you set in  C<nasty_break()> is still there when you
1207 return.  The fix is to add C<local()> so the value doesn't leak out of
1208 C<nasty_break()>:
1209
1210     local $\ = "\f";
1211
1212 It's easy to notice the problem in such a short example, but in more
1213 complicated code you are looking for trouble if you don't localize
1214 changes to the special variables.
1215
1216 =over 8
1217
1218 =item $ARGV
1219 X<$ARGV>
1220
1221 Contains the name of the current file when reading from C<< <> >>.
1222
1223 =item @ARGV
1224 X<@ARGV>
1225
1226 The array C<@ARGV> contains the command-line arguments intended for
1227 the script.  C<$#ARGV> is generally the number of arguments minus
1228 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1229 command name itself.  See L</$0> for the command name.
1230
1231 =item ARGV
1232 X<ARGV>
1233
1234 The special filehandle that iterates over command-line filenames in
1235 C<@ARGV>.  Usually written as the null filehandle in the angle operator
1236 C<< <> >>.  Note that currently C<ARGV> only has its magical effect
1237 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1238 corresponding to the last file opened by C<< <> >>.  In particular,
1239 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1240 may not cause your function to automatically read the contents of all the
1241 files in C<@ARGV>.
1242
1243 =item ARGVOUT
1244 X<ARGVOUT>
1245
1246 The special filehandle that points to the currently open output file
1247 when doing edit-in-place processing with B<-i>.  Useful when you have
1248 to do a lot of inserting and don't want to keep modifying C<$_>.  See
1249 L<perlrun> for the B<-i> switch.
1250
1251 =item Handle->output_field_separator( EXPR )
1252
1253 =item $OUTPUT_FIELD_SEPARATOR
1254
1255 =item $OFS
1256
1257 =item $,
1258 X<$,> X<$OFS> X<$OUTPUT_FIELD_SEPARATOR>
1259
1260 The output field separator for the print operator.  If defined, this
1261 value is printed between each of print's arguments.  Default is C<undef>.
1262
1263 Mnemonic: what is printed when there is a "," in your print statement.
1264
1265 =item HANDLE->input_line_number( EXPR )
1266
1267 =item $INPUT_LINE_NUMBER
1268
1269 =item $NR
1270
1271 =item $.
1272 X<$.> X<$NR> X<$INPUT_LINE_NUMBER> X<line number>
1273
1274 Current line number for the last filehandle accessed.
1275
1276 Each filehandle in Perl counts the number of lines that have been read
1277 from it.  (Depending on the value of C<$/>, Perl's idea of what
1278 constitutes a line may not match yours.)  When a line is read from a
1279 filehandle (via C<readline()> or C<< <> >>), or when C<tell()> or
1280 C<seek()> is called on it, C<$.> becomes an alias to the line counter
1281 for that filehandle.
1282
1283 You can adjust the counter by assigning to C<$.>, but this will not
1284 actually move the seek pointer.  I<Localizing C<$.> will not localize
1285 the filehandle's line count>.  Instead, it will localize perl's notion
1286 of which filehandle C<$.> is currently aliased to.
1287
1288 C<$.> is reset when the filehandle is closed, but B<not> when an open
1289 filehandle is reopened without an intervening C<close()>.  For more
1290 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
1291 an explicit close, line numbers increase across C<ARGV> files (but see
1292 examples in L<perlfunc/eof>).
1293
1294 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
1295 line counter for a given filehandle without having to worry about
1296 which handle you last accessed.
1297
1298 Mnemonic: many programs use "." to mean the current line number.
1299
1300 =item HANDLE->input_record_separator( EXPR )
1301
1302 =item $INPUT_RECORD_SEPARATOR
1303
1304 =item $RS
1305
1306 =item $/
1307 X<$/> X<$RS> X<$INPUT_RECORD_SEPARATOR>
1308
1309 The input record separator, newline by default.  This influences Perl's
1310 idea of what a "line" is.  Works like B<awk>'s RS variable, including
1311 treating empty lines as a terminator if set to the null string (an
1312 empty line cannot contain any spaces or tabs).  You may set it to a
1313 multi-character string to match a multi-character terminator, or to
1314 C<undef> to read through the end of file.  Setting it to C<"\n\n">
1315 means something slightly different than setting to C<"">, if the file
1316 contains consecutive empty lines.  Setting to C<""> will treat two or
1317 more consecutive empty lines as a single empty line.  Setting to
1318 C<"\n\n"> will blindly assume that the next input character belongs to
1319 the next paragraph, even if it's a newline.
1320
1321     local $/;           # enable "slurp" mode
1322     local $_ = <FH>;    # whole file now here
1323     s/\n[ \t]+/ /g;
1324
1325 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to
1326 be better for something. :-)
1327
1328 Setting C<$/> to a reference to an integer, scalar containing an
1329 integer, or scalar that's convertible to an integer will attempt to
1330 read records instead of lines, with the maximum record size being the
1331 referenced integer.  So this:
1332
1333     local $/ = \32768; # or \"32768", or \$var_containing_32768
1334     open my $fh, "<", $myfile or die $!;
1335     local $_ = <$fh>;
1336
1337 will read a record of no more than 32768 bytes from FILE.  If you're
1338 not reading from a record-oriented file (or your OS doesn't have
1339 record-oriented files), then you'll likely get a full chunk of data
1340 with every read.  If a record is larger than the record size you've
1341 set, you'll get the record back in pieces.  Trying to set the record
1342 size to zero or less will cause reading in the (rest of the) whole file.
1343
1344 On VMS only, record reads bypass PerlIO layers and any associated
1345 buffering,so you must not mix record and non-record reads on the
1346 same filehandle.  Record mode mixes with line mode only when the
1347 same buffering layer is in use for both modes.
1348
1349 If you perform a record read on a FILE with an encoding layer such as
1350 C<:encoding(latin1)> or C<:utf8>, you may get an invalid string as a
1351 result, may leave the FILE positioned between characters in the stream
1352 and may not be reading the number of bytes from the underlying file
1353 that you specified.  This behaviour may change without warning in a
1354 future version of perl.
1355
1356 See also L<perlport/"Newlines">. Also see L</$.>.
1357
1358 Mnemonic: / delimits line boundaries when quoting poetry.
1359
1360 =item Handle->output_record_separator( EXPR )
1361
1362 =item $OUTPUT_RECORD_SEPARATOR
1363
1364 =item $ORS
1365
1366 =item $\
1367 X<$\> X<$ORS> X<$OUTPUT_RECORD_SEPARATOR>
1368
1369 The output record separator for the print operator.  If defined, this
1370 value is printed after the last of print's arguments.  Default is C<undef>.
1371
1372 Mnemonic: you set C<$\> instead of adding "\n" at the end of the print.
1373 Also, it's just like C<$/>, but it's what you get "back" from Perl.
1374
1375 =item HANDLE->autoflush( EXPR )
1376
1377 =item $OUTPUT_AUTOFLUSH
1378
1379 =item $|
1380 X<$|> X<autoflush> X<flush> X<$OUTPUT_AUTOFLUSH>
1381
1382 If set to nonzero, forces a flush right away and after every write or
1383 print on the currently selected output channel.  Default is 0
1384 (regardless of whether the channel is really buffered by the system or
1385 not; C<$|> tells you only whether you've asked Perl explicitly to
1386 flush after each write).  STDOUT will typically be line buffered if
1387 output is to the terminal and block buffered otherwise.  Setting this
1388 variable is useful primarily when you are outputting to a pipe or
1389 socket, such as when you are running a Perl program under B<rsh> and
1390 want to see the output as it's happening.  This has no effect on input
1391 buffering.  See L<perlfunc/getc> for that.  See L<perlfunc/select> on
1392 how to select the output channel.  See also L<IO::Handle>.
1393
1394 Mnemonic: when you want your pipes to be piping hot.
1395
1396 =back
1397
1398 =head3 Variables related to formats
1399
1400 The special variables for formats are a subset of those for
1401 filehandles.  See L<perlform> for more information about Perl's
1402 formats.
1403
1404 =over 8
1405
1406 =item $ACCUMULATOR
1407
1408 =item $^A
1409 X<$^A> X<$ACCUMULATOR>
1410
1411 The current value of the C<write()> accumulator for C<format()> lines.
1412 A format contains C<formline()> calls that put their result into
1413 C<$^A>.  After calling its format, C<write()> prints out the contents
1414 of C<$^A> and empties.  So you never really see the contents of C<$^A>
1415 unless you call C<formline()> yourself and then look at it.  See
1416 L<perlform> and L<perlfunc/"formline PICTURE,LIST">.
1417
1418 =item HANDLE->format_formfeed(EXPR)
1419
1420 =item $FORMAT_FORMFEED
1421
1422 =item $^L
1423 X<$^L> X<$FORMAT_FORMFEED>
1424
1425 What formats output as a form feed.  The default is C<\f>.
1426
1427 =item HANDLE->format_page_number(EXPR)
1428
1429 =item $FORMAT_PAGE_NUMBER
1430
1431 =item $%
1432 X<$%> X<$FORMAT_PAGE_NUMBER>
1433
1434 The current page number of the currently selected output channel.
1435
1436 Mnemonic: C<%> is page number in B<nroff>.
1437
1438 =item HANDLE->format_lines_left(EXPR)
1439
1440 =item $FORMAT_LINES_LEFT
1441
1442 =item $-
1443 X<$-> X<$FORMAT_LINES_LEFT>
1444
1445 The number of lines left on the page of the currently selected output
1446 channel.
1447
1448 Mnemonic: lines_on_page - lines_printed.
1449
1450 =item Handle->format_line_break_characters EXPR
1451
1452 =item $FORMAT_LINE_BREAK_CHARACTERS
1453
1454 =item $:
1455 X<$:> X<FORMAT_LINE_BREAK_CHARACTERS>
1456
1457 The current set of characters after which a string may be broken to
1458 fill continuation fields (starting with C<^>) in a format.  The default is
1459 S<" \n-">, to break on a space, newline, or a hyphen.
1460
1461 Mnemonic: a "colon" in poetry is a part of a line.
1462
1463 =item HANDLE->format_lines_per_page(EXPR)
1464
1465 =item $FORMAT_LINES_PER_PAGE
1466
1467 =item $=
1468 X<$=> X<$FORMAT_LINES_PER_PAGE>
1469
1470 The current page length (printable lines) of the currently selected
1471 output channel.  The default is 60.
1472
1473 Mnemonic: = has horizontal lines.
1474
1475 =item HANDLE->format_top_name(EXPR)
1476
1477 =item $FORMAT_TOP_NAME
1478
1479 =item $^
1480 X<$^> X<$FORMAT_TOP_NAME>
1481
1482 The name of the current top-of-page format for the currently selected
1483 output channel.  The default is the name of the filehandle with C<_TOP>
1484 appended.  For example, the default format top name for the C<STDOUT>
1485 filehandle is C<STDOUT_TOP>.
1486
1487 Mnemonic: points to top of page.
1488
1489 =item HANDLE->format_name(EXPR)
1490
1491 =item $FORMAT_NAME
1492
1493 =item $~
1494 X<$~> X<$FORMAT_NAME>
1495
1496 The name of the current report format for the currently selected
1497 output channel.  The default format name is the same as the filehandle
1498 name.  For example, the default format name for the C<STDOUT>
1499 filehandle is just C<STDOUT>.
1500
1501 Mnemonic: brother to C<$^>.
1502
1503 =back
1504
1505 =head2 Error Variables
1506 X<error> X<exception>
1507
1508 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1509 about different types of error conditions that may appear during
1510 execution of a Perl program.  The variables are shown ordered by
1511 the "distance" between the subsystem which reported the error and
1512 the Perl process.  They correspond to errors detected by the Perl
1513 interpreter, C library, operating system, or an external program,
1514 respectively.
1515
1516 To illustrate the differences between these variables, consider the
1517 following Perl expression, which uses a single-quoted string.  After
1518 execution of this statement, perl may have set all four special error
1519 variables:
1520
1521     eval q{
1522         open my $pipe, "/cdrom/install |" or die $!;
1523         my @res = <$pipe>;
1524         close $pipe or die "bad pipe: $?, $!";
1525     };
1526
1527 When perl executes the C<eval()> expression, it translates the
1528 C<open()>, C<< <PIPE> >>, and C<close> calls in the C run-time library
1529 and thence to the operating system kernel.  perl sets C<$!> to
1530 the C library's C<errno> if one of these calls fails.
1531
1532 C<$@> is set if the string to be C<eval>-ed did not compile (this may
1533 happen if C<open> or C<close> were imported with bad prototypes), or
1534 if Perl code executed during evaluation C<die()>d.  In these cases the
1535 value of C<$@> is the compile error, or the argument to C<die> (which
1536 will interpolate C<$!> and C<$?>).  (See also L<Fatal>, though.)
1537
1538 Under a few operating systems, C<$^E> may contain a more verbose error
1539 indicator, such as in this case, "CDROM tray not closed."  Systems that
1540 do not support extended error messages leave C<$^E> the same as C<$!>.
1541
1542 Finally, C<$?> may be set to non-0 value if the external program
1543 F</cdrom/install> fails.  The upper eight bits reflect specific error
1544 conditions encountered by the program (the program's C<exit()> value).
1545 The lower eight bits reflect mode of failure, like signal death and
1546 core dump information.  See L<wait(2)> for details.  In contrast to
1547 C<$!> and C<$^E>, which are set only if error condition is detected,
1548 the variable C<$?> is set on each C<wait> or pipe C<close>,
1549 overwriting the old value.  This is more like C<$@>, which on every
1550 C<eval()> is always set on failure and cleared on success.
1551
1552 For more details, see the individual descriptions at C<$@>, C<$!>,
1553 C<$^E>, and C<$?>.
1554
1555 =over 8
1556
1557 =item ${^CHILD_ERROR_NATIVE}
1558 X<$^CHILD_ERROR_NATIVE>
1559
1560 The native status returned by the last pipe close, backtick (C<``>)
1561 command, successful call to C<wait()> or C<waitpid()>, or from the
1562 C<system()> operator.  On POSIX-like systems this value can be decoded
1563 with the WIFEXITED, WEXITSTATUS, WIFSIGNALED, WTERMSIG, WIFSTOPPED,
1564 WSTOPSIG and WIFCONTINUED functions provided by the L<POSIX> module.
1565
1566 Under VMS this reflects the actual VMS exit status; i.e. it is the
1567 same as C<$?> when the pragma C<use vmsish 'status'> is in effect.
1568
1569 This variable was added in Perl 5.8.9.
1570
1571 =item $EXTENDED_OS_ERROR
1572
1573 =item $^E
1574 X<$^E> X<$EXTENDED_OS_ERROR>
1575
1576 Error information specific to the current operating system.  At the
1577 moment, this differs from C<$!> under only VMS, OS/2, and Win32 (and
1578 for MacPerl).  On all other platforms, C<$^E> is always just the same
1579 as C<$!>.
1580
1581 Under VMS, C<$^E> provides the VMS status value from the last system
1582 error.  This is more specific information about the last system error
1583 than that provided by C<$!>.  This is particularly important when C<$!>
1584 is set to B<EVMSERR>.
1585
1586 Under OS/2, C<$^E> is set to the error code of the last call to OS/2
1587 API either via CRT, or directly from perl.
1588
1589 Under Win32, C<$^E> always returns the last error information reported
1590 by the Win32 call C<GetLastError()> which describes the last error
1591 from within the Win32 API.  Most Win32-specific code will report errors
1592 via C<$^E>.  ANSI C and Unix-like calls set C<errno> and so most
1593 portable Perl code will report errors via C<$!>.
1594
1595 Caveats mentioned in the description of C<$!> generally apply to
1596 C<$^E>, also.
1597
1598 This variable was added in Perl 5.003.
1599
1600 Mnemonic: Extra error explanation.
1601
1602 =item $EXCEPTIONS_BEING_CAUGHT
1603
1604 =item $^S
1605 X<$^S> X<$EXCEPTIONS_BEING_CAUGHT>
1606
1607 Current state of the interpreter.
1608
1609         $^S         State
1610         ---------   -------------------
1611         undef       Parsing module/eval
1612         true (1)    Executing an eval
1613         false (0)   Otherwise
1614
1615 The first state may happen in C<$SIG{__DIE__}> and C<$SIG{__WARN__}>
1616 handlers.
1617
1618 This variable was added in Perl 5.004.
1619
1620 =item $WARNING
1621
1622 =item $^W
1623 X<$^W> X<$WARNING>
1624
1625 The current value of the warning switch, initially true if B<-w> was
1626 used, false otherwise, but directly modifiable.
1627
1628 See also L<warnings>.
1629
1630 Mnemonic: related to the B<-w> switch.
1631
1632 =item ${^WARNING_BITS}
1633 X<${^WARNING_BITS}>
1634
1635 The current set of warning checks enabled by the C<use warnings> pragma.
1636 It has the same scoping as the C<$^H> and C<%^H> variables.  The exact
1637 values are considered internal to the L<warnings> pragma and may change
1638 between versions of Perl.
1639
1640 This variable was added in Perl 5.6.
1641
1642 =item $OS_ERROR
1643
1644 =item $ERRNO
1645
1646 =item $!
1647 X<$!> X<$ERRNO> X<$OS_ERROR>
1648
1649 When referenced, C<$!> retrieves the current value
1650 of the C C<errno> integer variable.
1651 If C<$!> is assigned a numerical value, that value is stored in C<errno>.
1652 When referenced as a string, C<$!> yields the system error string
1653 corresponding to C<errno>.
1654
1655 Many system or library calls set C<errno> if they fail,
1656 to indicate the cause of failure.  They usually do B<not>
1657 set C<errno> to zero if they succeed.  This means C<errno>,
1658 hence C<$!>, is meaningful only I<immediately> after a B<failure>:
1659
1660     if (open my $fh, "<", $filename) {
1661                 # Here $! is meaningless.
1662                 ...
1663     }
1664     else {
1665                 # ONLY here is $! meaningful.
1666                 ...
1667                 # Already here $! might be meaningless.
1668     }
1669     # Since here we might have either success or failure,
1670     # $! is meaningless.
1671
1672 Here, I<meaningless> means that C<$!> may be unrelated to the outcome
1673 of the C<open()> operator.  Assignment to C<$!> is similarly ephemeral.
1674 It can be used immediately before invoking the C<die()> operator,
1675 to set the exit value, or to inspect the system error string
1676 corresponding to error I<n>, or to restore C<$!> to a meaningful state.
1677
1678 Mnemonic: What just went bang?
1679
1680 =item %OS_ERROR
1681
1682 =item %ERRNO
1683
1684 =item %!
1685 X<%!> X<%OS_ERROR> X<%ERRNO>
1686
1687 Each element of C<%!> has a true value only if C<$!> is set to that
1688 value.  For example, C<$!{ENOENT}> is true if and only if the current
1689 value of C<$!> is C<ENOENT>; that is, if the most recent error was "No
1690 such file or directory" (or its moral equivalent: not all operating
1691 systems give that exact error, and certainly not all languages).  To
1692 check if a particular key is meaningful on your system, use C<exists
1693 $!{the_key}>; for a list of legal keys, use C<keys %!>.  See L<Errno>
1694 for more information, and also see L</$!>.
1695
1696 This variable was added in Perl 5.005.
1697
1698 =item $CHILD_ERROR
1699
1700 =item $?
1701 X<$?> X<$CHILD_ERROR>
1702
1703 The status returned by the last pipe close, backtick (C<``>) command,
1704 successful call to C<wait()> or C<waitpid()>, or from the C<system()>
1705 operator.  This is just the 16-bit status word returned by the
1706 traditional Unix C<wait()> system call (or else is made up to look
1707 like it).  Thus, the exit value of the subprocess is really (C<<< $? >>
1708 8 >>>), and C<$? & 127> gives which signal, if any, the process died
1709 from, and C<$? & 128> reports whether there was a core dump.
1710
1711 Additionally, if the C<h_errno> variable is supported in C, its value
1712 is returned via C<$?> if any C<gethost*()> function fails.
1713
1714 If you have installed a signal handler for C<SIGCHLD>, the
1715 value of C<$?> will usually be wrong outside that handler.
1716
1717 Inside an C<END> subroutine C<$?> contains the value that is going to be
1718 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
1719 change the exit status of your program.  For example:
1720
1721     END {
1722         $? = 1 if $? == 255;  # die would make it 255
1723     }
1724
1725 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
1726 actual VMS exit status, instead of the default emulation of POSIX
1727 status; see L<perlvms/$?> for details.
1728
1729 Mnemonic: similar to B<sh> and B<ksh>.
1730
1731 =item $EVAL_ERROR
1732
1733 =item $@
1734 X<$@> X<$EVAL_ERROR>
1735
1736 The Perl syntax error message from the
1737 last C<eval()> operator.  If C<$@> is
1738 the null string, the last C<eval()> parsed and executed correctly
1739 (although the operations you invoked may have failed in the normal
1740 fashion).
1741
1742 Warning messages are not collected in this variable.  You can, however,
1743 set up a routine to process warnings by setting C<$SIG{__WARN__}> as
1744 described in L</%SIG>.
1745
1746 Mnemonic: Where was the syntax error "at"?
1747
1748 =back
1749
1750 =head2 Variables related to the interpreter state
1751
1752 These variables provide information about the current interpreter state.
1753
1754 =over 8
1755
1756 =item $COMPILING
1757
1758 =item $^C
1759 X<$^C> X<$COMPILING>
1760
1761 The current value of the flag associated with the B<-c> switch.
1762 Mainly of use with B<-MO=...> to allow code to alter its behavior
1763 when being compiled, such as for example to C<AUTOLOAD> at compile
1764 time rather than normal, deferred loading.  Setting
1765 C<$^C = 1> is similar to calling C<B::minus_c>.
1766
1767 This variable was added in Perl 5.6.
1768
1769 =item $DEBUGGING
1770
1771 =item $^D
1772 X<$^D> X<$DEBUGGING>
1773
1774 The current value of the debugging flags.  May be read or set.  Like its
1775 command-line equivalent, you can use numeric or symbolic values, eg
1776 C<$^D = 10> or C<$^D = "st">.
1777
1778 Mnemonic: value of B<-D> switch.
1779
1780 =item ${^ENCODING}
1781 X<${^ENCODING}>
1782
1783 The I<object reference> to the C<Encode> object that is used to convert
1784 the source code to Unicode.  Thanks to this variable your Perl script
1785 does not have to be written in UTF-8.  Default is I<undef>.  The direct
1786 manipulation of this variable is highly discouraged.
1787
1788 This variable was added in Perl 5.8.2.
1789
1790 =item ${^GLOBAL_PHASE}
1791 X<${^GLOBAL_PHASE}>
1792
1793 The current phase of the perl interpreter.
1794
1795 Possible values are:
1796
1797 =over 8
1798
1799 =item CONSTRUCT
1800
1801 The C<PerlInterpreter*> is being constructed via C<perl_construct>.  This
1802 value is mostly there for completeness and for use via the
1803 underlying C variable C<PL_phase>.  It's not really possible for Perl
1804 code to be executed unless construction of the interpreter is
1805 finished.
1806
1807 =item START
1808
1809 This is the global compile-time.  That includes, basically, every
1810 C<BEGIN> block executed directly or indirectly from during the
1811 compile-time of the top-level program.
1812
1813 This phase is not called "BEGIN" to avoid confusion with
1814 C<BEGIN>-blocks, as those are executed during compile-time of any
1815 compilation unit, not just the top-level program.  A new, localised
1816 compile-time entered at run-time, for example by constructs as
1817 C<eval "use SomeModule"> are not global interpreter phases, and
1818 therefore aren't reflected by C<${^GLOBAL_PHASE}>.
1819
1820 =item CHECK
1821
1822 Execution of any C<CHECK> blocks.
1823
1824 =item INIT
1825
1826 Similar to "CHECK", but for C<INIT>-blocks, not C<CHECK> blocks.
1827
1828 =item RUN
1829
1830 The main run-time, i.e. the execution of C<PL_main_root>.
1831
1832 =item END
1833
1834 Execution of any C<END> blocks.
1835
1836 =item DESTRUCT
1837
1838 Global destruction.
1839
1840 =back
1841
1842 Also note that there's no value for UNITCHECK-blocks.  That's because
1843 those are run for each compilation unit individually, and therefore is
1844 not a global interpreter phase.
1845
1846 Not every program has to go through each of the possible phases, but
1847 transition from one phase to another can only happen in the order
1848 described in the above list.
1849
1850 An example of all of the phases Perl code can see:
1851
1852     BEGIN { print "compile-time: ${^GLOBAL_PHASE}\n" }
1853
1854     INIT  { print "init-time: ${^GLOBAL_PHASE}\n" }
1855
1856     CHECK { print "check-time: ${^GLOBAL_PHASE}\n" }
1857
1858     {
1859         package Print::Phase;
1860
1861         sub new {
1862             my ($class, $time) = @_;
1863             return bless \$time, $class;
1864         }
1865
1866         sub DESTROY {
1867             my $self = shift;
1868             print "$$self: ${^GLOBAL_PHASE}\n";
1869         }
1870     }
1871
1872     print "run-time: ${^GLOBAL_PHASE}\n";
1873
1874     my $runtime = Print::Phase->new(
1875         "lexical variables are garbage collected before END"
1876     );
1877
1878     END   { print "end-time: ${^GLOBAL_PHASE}\n" }
1879
1880     our $destruct = Print::Phase->new(
1881         "package variables are garbage collected after END"
1882     );
1883
1884 This will print out
1885
1886     compile-time: START
1887     check-time: CHECK
1888     init-time: INIT
1889     run-time: RUN
1890     lexical variables are garbage collected before END: RUN
1891     end-time: END
1892     package variables are garbage collected after END: DESTRUCT
1893
1894 This variable was added in Perl 5.14.0.
1895
1896 =item $^H
1897 X<$^H>
1898
1899 WARNING: This variable is strictly for
1900 internal use only.  Its availability,
1901 behavior, and contents are subject to change without notice.
1902
1903 This variable contains compile-time hints for the Perl interpreter.  At the
1904 end of compilation of a BLOCK the value of this variable is restored to the
1905 value when the interpreter started to compile the BLOCK.
1906
1907 When perl begins to parse any block construct that provides a lexical scope
1908 (e.g., eval body, required file, subroutine body, loop body, or conditional
1909 block), the existing value of C<$^H> is saved, but its value is left unchanged.
1910 When the compilation of the block is completed, it regains the saved value.
1911 Between the points where its value is saved and restored, code that
1912 executes within BEGIN blocks is free to change the value of C<$^H>.
1913
1914 This behavior provides the semantic of lexical scoping, and is used in,
1915 for instance, the C<use strict> pragma.
1916
1917 The contents should be an integer; different bits of it are used for
1918 different pragmatic flags.  Here's an example:
1919
1920     sub add_100 { $^H |= 0x100 }
1921
1922     sub foo {
1923         BEGIN { add_100() }
1924         bar->baz($boon);
1925     }
1926
1927 Consider what happens during execution of the BEGIN block.  At this point
1928 the BEGIN block has already been compiled, but the body of C<foo()> is still
1929 being compiled.  The new value of C<$^H>
1930 will therefore be visible only while
1931 the body of C<foo()> is being compiled.
1932
1933 Substitution of C<BEGIN { add_100() }> block with:
1934
1935     BEGIN { require strict; strict->import('vars') }
1936
1937 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
1938 version of the same lexical pragma:
1939
1940     BEGIN {
1941         require strict; strict->import('vars') if $condition
1942     }
1943
1944 This variable was added in Perl 5.003.
1945
1946 =item %^H
1947 X<%^H>
1948
1949 The C<%^H> hash provides the same scoping semantic as C<$^H>.  This makes
1950 it useful for implementation of lexically scoped pragmas.  See
1951 L<perlpragma>.
1952
1953 When putting items into C<%^H>, in order to avoid conflicting with other
1954 users of the hash there is a convention regarding which keys to use.
1955 A module should use only keys that begin with the module's name (the
1956 name of its main package) and a "/" character.  For example, a module
1957 C<Foo::Bar> should use keys such as C<Foo::Bar/baz>.
1958
1959 This variable was added in Perl 5.6.
1960
1961 =item ${^OPEN}
1962 X<${^OPEN}>
1963
1964 An internal variable used by PerlIO.  A string in two parts, separated
1965 by a C<\0> byte, the first part describes the input layers, the second
1966 part describes the output layers.
1967
1968 This variable was added in Perl 5.8.0.
1969
1970 =item $PERLDB
1971
1972 =item $^P
1973 X<$^P> X<$PERLDB>
1974
1975 The internal variable for debugging support.  The meanings of the
1976 various bits are subject to change, but currently indicate:
1977
1978 =over 6
1979
1980 =item 0x01
1981
1982 Debug subroutine enter/exit.
1983
1984 =item 0x02
1985
1986 Line-by-line debugging.  Causes C<DB::DB()> subroutine to be called for
1987 each statement executed.  Also causes saving source code lines (like
1988 0x400).
1989
1990 =item 0x04
1991
1992 Switch off optimizations.
1993
1994 =item 0x08
1995
1996 Preserve more data for future interactive inspections.
1997
1998 =item 0x10
1999
2000 Keep info about source lines on which a subroutine is defined.
2001
2002 =item 0x20
2003
2004 Start with single-step on.
2005
2006 =item 0x40
2007
2008 Use subroutine address instead of name when reporting.
2009
2010 =item 0x80
2011
2012 Report C<goto &subroutine> as well.
2013
2014 =item 0x100
2015
2016 Provide informative "file" names for evals based on the place they were compiled.
2017
2018 =item 0x200
2019
2020 Provide informative names to anonymous subroutines based on the place they
2021 were compiled.
2022
2023 =item 0x400
2024
2025 Save source code lines into C<@{"_<$filename"}>.
2026
2027 =back
2028
2029 Some bits may be relevant at compile-time only, some at
2030 run-time only.  This is a new mechanism and the details may change.
2031 See also L<perldebguts>.
2032
2033 =item ${^TAINT}
2034 X<${^TAINT}>
2035
2036 Reflects if taint mode is on or off.  1 for on (the program was run with
2037 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
2038 B<-t> or B<-TU>).
2039
2040 This variable is read-only.
2041
2042 This variable was added in Perl 5.8.
2043
2044 =item ${^UNICODE}
2045 X<${^UNICODE}>
2046
2047 Reflects certain Unicode settings of Perl.  See L<perlrun>
2048 documentation for the C<-C> switch for more information about
2049 the possible values.
2050
2051 This variable is set during Perl startup and is thereafter read-only.
2052
2053 This variable was added in Perl 5.8.2.
2054
2055 =item ${^UTF8CACHE}
2056 X<${^UTF8CACHE}>
2057
2058 This variable controls the state of the internal UTF-8 offset caching code.
2059 1 for on (the default), 0 for off, -1 to debug the caching code by checking
2060 all its results against linear scans, and panicking on any discrepancy.
2061
2062 This variable was added in Perl 5.8.9.
2063
2064 =item ${^UTF8LOCALE}
2065 X<${^UTF8LOCALE}>
2066
2067 This variable indicates whether a UTF-8 locale was detected by perl at
2068 startup.  This information is used by perl when it's in
2069 adjust-utf8ness-to-locale mode (as when run with the C<-CL> command-line
2070 switch); see L<perlrun> for more info on this.
2071
2072 This variable was added in Perl 5.8.8.
2073
2074 =back
2075
2076 =head2 Deprecated and removed variables
2077
2078 Deprecating a variable announces the intent of the perl maintainers to
2079 eventually remove the variable from the language.  It may still be
2080 available despite its status.  Using a deprecated variable triggers
2081 a warning.
2082
2083 Once a variable is removed, its use triggers an error telling you
2084 the variable is unsupported.
2085
2086 See L<perldiag> for details about error messages.
2087
2088 =over 8
2089
2090 =item $OFMT
2091
2092 =item $#
2093 X<$#> X<$OFMT>
2094
2095 C<$#> was a variable that could be used to format printed numbers.
2096 After a deprecation cycle, its magic was removed in Perl 5.10 and
2097 using it now triggers a warning: C<$# is no longer supported>.
2098
2099 This is not the sigil you use in front of an array name to get the
2100 last index, like C<$#array>.  That's still how you get the last index
2101 of an array in Perl.  The two have nothing to do with each other.
2102
2103 Deprecated in Perl 5.
2104
2105 Removed in Perl 5.10.
2106
2107 =item $*
2108 X<$*>
2109
2110 C<$*> was a variable that you could use to enable multiline matching.
2111 After a deprecation cycle, its magic was removed in Perl 5.10.
2112 Using it now triggers a warning: C<$* is no longer supported>.
2113 You should use the C</s> and C</m> regexp modifiers instead.
2114
2115 Deprecated in Perl 5.
2116
2117 Removed in Perl 5.10.
2118
2119 =item $ARRAY_BASE
2120
2121 =item $[
2122 X<$[> X<$ARRAY_BASE>
2123
2124 This variable stores the index of the first element in an array, and
2125 of the first character in a substring.  The default is 0, but you could
2126 theoretically set it to 1 to make Perl behave more like B<awk> (or Fortran)
2127 when subscripting and when evaluating the index() and substr() functions.
2128
2129 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
2130 directive, and cannot influence the behavior of any other file.
2131 (That's why you can only assign compile-time constants to it.)
2132 Its use is highly discouraged.
2133
2134 Prior to Perl 5.10, assignment to C<$[> could be seen from outer lexical
2135 scopes in the same file, unlike other compile-time directives (such as
2136 L<strict>).  Using local() on it would bind its value strictly to a lexical
2137 block.  Now it is always lexically scoped.
2138
2139 As of Perl 5.16, it is implemented by the L<arybase> module.  See
2140 L<arybase> for more details on its behaviour.
2141
2142 Under C<use v5.16>, or C<no feature "array_base">, C<$[> no longer has any
2143 effect, and always contains 0.  Assigning 0 to it is permitted, but any
2144 other value will produce an error.
2145
2146 Mnemonic: [ begins subscripts.
2147
2148 Deprecated in Perl 5.12.
2149
2150 =item $OLD_PERL_VERSION
2151
2152 =item $]
2153 X<$]> X<$OLD_PERL_VERSION>
2154
2155 See L</$^V> for a more modern representation of the Perl version that allows
2156 accurate string comparisons.
2157
2158 The version + patchlevel / 1000 of the Perl interpreter.  This variable
2159 can be used to determine whether the Perl interpreter executing a
2160 script is in the right range of versions:
2161
2162     warn "No checksumming!\n" if $] < 3.019;
2163
2164 The floating point representation can sometimes lead to inaccurate
2165 numeric comparisons.
2166
2167 See also the documentation of C<use VERSION> and C<require VERSION>
2168 for a convenient way to fail if the running Perl interpreter is too old.
2169
2170 Mnemonic: Is this version of perl in the right bracket?
2171
2172 =back
2173
2174 =cut