Make t/porting/authors.t pass under LC_ALL=en_GB.UTF-8 PERL_UNICODE=""
[perl.git] / Porting / cmpVERSION.pl
1 #!/usr/bin/perl -w
2
3 #
4 # cmpVERSION - compare the current Perl source tree and a given tag
5 # for modules that have identical version numbers but different contents.
6 #
7 # with -d option, output the diffs too
8 # with -x option, exclude dual-life modules (after all, there are tools
9 #                 like core-cpan-diff that can already deal with them)
10 #                 With this option, one of the directories must be '.'.
11 #
12 # Original by slaven@rezic.de, modified by jhi and matt.w.johnson@gmail.com.
13 #
14
15 use strict;
16
17 use ExtUtils::MakeMaker;
18 use File::Compare;
19 use File::Find;
20 use File::Spec::Functions qw(rel2abs abs2rel catfile catdir curdir);
21 use Getopt::Std;
22
23 use lib 'Porting';
24 use Maintainers;
25
26 sub usage {
27 die <<"EOF";
28 usage: $0 [ -d -x ] source_dir tag_to_compare
29 EOF
30 }
31
32 my %opts;
33 getopts('dx', \%opts) or usage;
34 @ARGV == 2 or usage;
35
36 my ($source_dir, $tag_to_compare) = @ARGV[0,1];
37 die "$0: '$source_dir' does not look like a Perl directory\n"
38     unless -f catfile($source_dir, "perl.h") && -d catdir($source_dir, "Porting");
39 die "$0: '$source_dir' is a Perl directory but does not look like Git working directory\n"
40     unless -d catdir($source_dir, ".git");
41
42 my $tag_exists = `git --no-pager tag -l $tag_to_compare 2>/dev/null`;
43 chomp $tag_exists;
44
45 die "$0: '$tag_to_compare' is not a known Git tag\n"
46     unless $tag_exists eq $tag_to_compare;
47
48 my %dual_files;
49 if ($opts{x}) {
50     die "With -x, the directory must be '.'\n"
51         unless $source_dir eq '.';
52     for my $m (grep $Maintainers::Modules{$_}{CPAN},
53                                 keys %Maintainers::Modules)
54     {
55
56         $dual_files{$_} = 1 for Maintainers::get_module_files($m);
57     }
58 }
59
60 chdir $source_dir or die "$0: chdir '$source_dir' failed: $!\n";
61
62 # Files to skip from the check for one reason or another,
63 # usually because they pull in their version from some other file.
64 my %skip;
65 @skip{
66     'lib/Carp/Heavy.pm',
67     'lib/Config.pm',            # no version number but contents will vary
68     'lib/Exporter/Heavy.pm',
69     'win32/FindExt.pm',
70 } = ();
71 my $skip_dirs = qr|^t/lib|;
72
73 my @all_diffs = `git --no-pager diff --name-only $tag_to_compare`;
74 chomp @all_diffs;
75
76 my @module_diffs = grep {
77     my $this_dir;
78     $this_dir = $1 if m/^(.*)\//;
79     /\.pm$/ &&
80     (!defined($this_dir) || ($this_dir !~ $skip_dirs)) &&
81     !exists $skip{$_} &&
82     !exists $dual_files{$_}
83 } @all_diffs;
84
85 my (@output_files, @output_diffs);
86
87 foreach my $pm_file (@module_diffs) {
88     (my $xs_file = $pm_file) =~ s/\.pm$/.xs/;
89     my $pm_eq = compare_git_file($pm_file, $tag_to_compare);
90     next unless defined $pm_eq;
91     my $xs_eq = 1;
92     if (-e $xs_file) {
93         $xs_eq = compare_git_file($xs_file, $tag_to_compare);
94         next unless defined $xs_eq;
95     }
96     next if ($pm_eq && $xs_eq);
97     my $pm_version = eval {MM->parse_version($pm_file)};
98     my $orig_pm_content = get_file_from_git($pm_file, $tag_to_compare);
99     my $orig_pm_version = eval {MM->parse_version(\$orig_pm_content)};
100     next if ( ! defined $pm_version || ! defined $orig_pm_version );
101     next if ( $pm_version eq 'undef' || $orig_pm_version eq 'undef' ); # sigh
102     next if $pm_version ne $orig_pm_version;
103     push @output_files, $pm_file;
104     push @output_diffs, $pm_file unless $pm_eq;
105     push @output_diffs, $xs_file unless $xs_eq;
106 }
107
108 sub compare_git_file {
109     my ($file, $tag) = @_;
110     open(my $orig_fh, "-|", "git --no-pager show $tag:$file 2>/dev/null");
111     return undef if eof($orig_fh);
112     my $is_eq = compare($file, $orig_fh) == 0;
113     close($orig_fh);
114     return $is_eq;
115 }
116
117 sub get_file_from_git {
118     my ($file, $tag) = @_;
119     local $/ = undef;
120     my $file_content = `git --no-pager show $tag:$file 2>/dev/null`;
121     return $file_content;
122 }
123
124 for (sort @output_files) {
125     print "$_\n";
126 }
127
128 exit unless $opts{d};
129
130 for (sort @output_diffs) {
131     print "\n";
132     system "git --no-pager diff $tag_to_compare '$_'";
133 }
134