Win32 pacifying from mjd.
[perl.git] / lib / AutoSplit.pm
1 package AutoSplit;
2
3 use 5.006_001;
4 use Exporter ();
5 use Config qw(%Config);
6 use Carp qw(carp);
7 use File::Basename ();
8 use File::Path qw(mkpath);
9 use File::Spec::Functions qw(curdir catfile catdir);
10 use strict;
11 our($VERSION, @ISA, @EXPORT, @EXPORT_OK, $Verbose, $Keep, $Maxlen,
12     $CheckForAutoloader, $CheckModTime);
13
14 $VERSION = "1.0307";
15 @ISA = qw(Exporter);
16 @EXPORT = qw(&autosplit &autosplit_lib_modules);
17 @EXPORT_OK = qw($Verbose $Keep $Maxlen $CheckForAutoloader $CheckModTime);
18
19 =head1 NAME
20
21 AutoSplit - split a package for autoloading
22
23 =head1 SYNOPSIS
24
25  autosplit($file, $dir, $keep, $check, $modtime);
26
27  autosplit_lib_modules(@modules);
28
29 =head1 DESCRIPTION
30
31 This function will split up your program into files that the AutoLoader
32 module can handle. It is used by both the standard perl libraries and by
33 the MakeMaker utility, to automatically configure libraries for autoloading.
34
35 The C<autosplit> interface splits the specified file into a hierarchy 
36 rooted at the directory C<$dir>. It creates directories as needed to reflect
37 class hierarchy, and creates the file F<autosplit.ix>. This file acts as
38 both forward declaration of all package routines, and as timestamp for the
39 last update of the hierarchy.
40
41 The remaining three arguments to C<autosplit> govern other options to
42 the autosplitter.
43
44 =over 2
45
46 =item $keep
47
48 If the third argument, I<$keep>, is false, then any
49 pre-existing C<*.al> files in the autoload directory are removed if
50 they are no longer part of the module (obsoleted functions).
51 $keep defaults to 0.
52
53 =item $check
54
55 The
56 fourth argument, I<$check>, instructs C<autosplit> to check the module
57 currently being split to ensure that it includes a C<use>
58 specification for the AutoLoader module, and skips the module if
59 AutoLoader is not detected.
60 $check defaults to 1.
61
62 =item $modtime
63
64 Lastly, the I<$modtime> argument specifies
65 that C<autosplit> is to check the modification time of the module
66 against that of the C<autosplit.ix> file, and only split the module if
67 it is newer.
68 $modtime defaults to 1.
69
70 =back
71
72 Typical use of AutoSplit in the perl MakeMaker utility is via the command-line
73 with:
74
75  perl -e 'use AutoSplit; autosplit($ARGV[0], $ARGV[1], 0, 1, 1)'
76
77 Defined as a Make macro, it is invoked with file and directory arguments;
78 C<autosplit> will split the specified file into the specified directory and
79 delete obsolete C<.al> files, after checking first that the module does use
80 the AutoLoader, and ensuring that the module is not already currently split
81 in its current form (the modtime test).
82
83 The C<autosplit_lib_modules> form is used in the building of perl. It takes
84 as input a list of files (modules) that are assumed to reside in a directory
85 B<lib> relative to the current directory. Each file is sent to the 
86 autosplitter one at a time, to be split into the directory B<lib/auto>.
87
88 In both usages of the autosplitter, only subroutines defined following the
89 perl I<__END__> token are split out into separate files. Some
90 routines may be placed prior to this marker to force their immediate loading
91 and parsing.
92
93 =head2 Multiple packages
94
95 As of version 1.01 of the AutoSplit module it is possible to have
96 multiple packages within a single file. Both of the following cases
97 are supported:
98
99    package NAME;
100    __END__
101    sub AAA { ... }
102    package NAME::option1;
103    sub BBB { ... }
104    package NAME::option2;
105    sub BBB { ... }
106
107    package NAME;
108    __END__
109    sub AAA { ... }
110    sub NAME::option1::BBB { ... }
111    sub NAME::option2::BBB { ... }
112
113 =head1 DIAGNOSTICS
114
115 C<AutoSplit> will inform the user if it is necessary to create the
116 top-level directory specified in the invocation. It is preferred that
117 the script or installation process that invokes C<AutoSplit> have
118 created the full directory path ahead of time. This warning may
119 indicate that the module is being split into an incorrect path.
120
121 C<AutoSplit> will warn the user of all subroutines whose name causes
122 potential file naming conflicts on machines with drastically limited
123 (8 characters or less) file name length. Since the subroutine name is
124 used as the file name, these warnings can aid in portability to such
125 systems.
126
127 Warnings are issued and the file skipped if C<AutoSplit> cannot locate
128 either the I<__END__> marker or a "package Name;"-style specification.
129
130 C<AutoSplit> will also emit general diagnostics for inability to
131 create directories or files.
132
133 =cut
134
135 # for portability warn about names longer than $maxlen
136 $Maxlen  = 8;   # 8 for dos, 11 (14-".al") for SYSVR3
137 $Verbose = 1;   # 0=none, 1=minimal, 2=list .al files
138 $Keep    = 0;
139 $CheckForAutoloader = 1;
140 $CheckModTime = 1;
141
142 my $IndexFile = "autosplit.ix"; # file also serves as timestamp
143 my $maxflen = 255;
144 $maxflen = 14 if $Config{'d_flexfnam'} ne 'define';
145 if (defined (&Dos::UseLFN)) {
146      $maxflen = Dos::UseLFN() ? 255 : 11;
147 }
148 my $Is_VMS = ($^O eq 'VMS');
149
150 # allow checking for valid ': attrlist' attachments
151 my $nested;
152 $nested = qr{ \( (?: (?> [^()]+ ) | (??{ $nested }) )* \) }x;
153 my $one_attr = qr{ (?> (?! \d) \w+ (?:$nested)? ) (?:\s*\:\s*|\s+(?!\:)) }x;
154 my $attr_list = qr{ \s* : \s* (?: $one_attr )* }x;
155
156
157
158 sub autosplit{
159     my($file, $autodir,  $keep, $ckal, $ckmt) = @_;
160     # $file    - the perl source file to be split (after __END__)
161     # $autodir - the ".../auto" dir below which to write split subs
162     # Handle optional flags:
163     $keep = $Keep unless defined $keep;
164     $ckal = $CheckForAutoloader unless defined $ckal;
165     $ckmt = $CheckModTime unless defined $ckmt;
166     autosplit_file($file, $autodir, $keep, $ckal, $ckmt);
167 }
168
169
170 # This function is used during perl building/installation
171 # ./miniperl -e 'use AutoSplit; autosplit_lib_modules(@ARGV)' ...
172
173 sub autosplit_lib_modules{
174     my(@modules) = @_; # list of Module names
175
176     while(defined($_ = shift @modules)){
177         while (m#(.*?[^:])::([^:].*)#) { # in case specified as ABC::XYZ
178             $_ = catfile($1, $2);
179         }
180         s|\\|/|g;               # bug in ksh OS/2
181         s#^lib/##s; # incase specified as lib/*.pm
182         my($lib) = catfile(curdir(), "lib");
183         if ($Is_VMS) { # may need to convert VMS-style filespecs
184             $lib =~ s#^\[\]#.\/#;
185         }
186         s#^$lib\W+##s; # incase specified as ./lib/*.pm
187         if ($Is_VMS && /[:>\]]/) { # may need to convert VMS-style filespecs
188             my ($dir,$name) = (/(.*])(.*)/s);
189             $dir =~ s/.*lib[\.\]]//s;
190             $dir =~ s#[\.\]]#/#g;
191             $_ = $dir . $name;
192         }
193         autosplit_file(catfile($lib, $_), catfile($lib, "auto"),
194                        $Keep, $CheckForAutoloader, $CheckModTime);
195     }
196     0;
197 }
198
199
200 # private functions
201
202 my $self_mod_time = (stat __FILE__)[9];
203
204 sub autosplit_file {
205     my($filename, $autodir, $keep, $check_for_autoloader, $check_mod_time)
206         = @_;
207     my(@outfiles);
208     local($_);
209     local($/) = "\n";
210
211     # where to write output files
212     $autodir ||= catfile(curdir(), "lib", "auto");
213     if ($Is_VMS) {
214         ($autodir = VMS::Filespec::unixpath($autodir)) =~ s|/\z||;
215         $filename = VMS::Filespec::unixify($filename); # may have dirs
216     }
217     unless (-d $autodir){
218         mkpath($autodir,0,0755);
219         # We should never need to create the auto dir
220         # here. installperl (or similar) should have done
221         # it. Expecting it to exist is a valuable sanity check against
222         # autosplitting into some random directory by mistake.
223         print "Warning: AutoSplit had to create top-level " .
224             "$autodir unexpectedly.\n";
225     }
226
227     # allow just a package name to be used
228     $filename .= ".pm" unless ($filename =~ m/\.pm\z/);
229
230     open(IN, "<$filename") or die "AutoSplit: Can't open $filename: $!\n";
231     my($pm_mod_time) = (stat($filename))[9];
232     my($autoloader_seen) = 0;
233     my($in_pod) = 0;
234     my($def_package,$last_package,$this_package,$fnr);
235     while (<IN>) {
236         # Skip pod text.
237         $fnr++;
238         $in_pod = 1 if /^=\w/;
239         $in_pod = 0 if /^=cut/;
240         next if ($in_pod || /^=cut/);
241         next if /^\s*#/;
242
243         # record last package name seen
244         $def_package = $1 if (m/^\s*package\s+([\w:]+)\s*;/);
245         ++$autoloader_seen if m/^\s*(use|require)\s+AutoLoader\b/;
246         ++$autoloader_seen if m/\bISA\s*=.*\bAutoLoader\b/;
247         last if /^__END__/;
248     }
249     if ($check_for_autoloader && !$autoloader_seen){
250         print "AutoSplit skipped $filename: no AutoLoader used\n"
251             if ($Verbose>=2);
252         return 0;
253     }
254     $_ or die "Can't find __END__ in $filename\n";
255
256     $def_package or die "Can't find 'package Name;' in $filename\n";
257
258     my($modpname) = _modpname($def_package); 
259
260     # this _has_ to match so we have a reasonable timestamp file
261     die "Package $def_package ($modpname.pm) does not ".
262         "match filename $filename"
263             unless ($filename =~ m/\Q$modpname.pm\E$/ or
264                     ($^O eq 'dos') or ($^O eq 'MSWin32') or ($^O eq 'NetWare') or
265                     $Is_VMS && $filename =~ m/$modpname.pm/i);
266
267     my($al_idx_file) = catfile($autodir, $modpname, $IndexFile);
268
269     if ($check_mod_time){
270         my($al_ts_time) = (stat("$al_idx_file"))[9] || 1;
271         if ($al_ts_time >= $pm_mod_time and
272             $al_ts_time >= $self_mod_time){
273             print "AutoSplit skipped ($al_idx_file newer than $filename)\n"
274                 if ($Verbose >= 2);
275             return undef;       # one undef, not a list
276         }
277     }
278
279     my($modnamedir) = catdir($autodir, $modpname);
280     print "AutoSplitting $filename ($modnamedir)\n"
281         if $Verbose;
282
283     unless (-d $modnamedir){
284         mkpath($modnamedir,0,0777);
285     }
286
287     # We must try to deal with some SVR3 systems with a limit of 14
288     # characters for file names. Sadly we *cannot* simply truncate all
289     # file names to 14 characters on these systems because we *must*
290     # create filenames which exactly match the names used by AutoLoader.pm.
291     # This is a problem because some systems silently truncate the file
292     # names while others treat long file names as an error.
293
294     my $Is83 = $maxflen==11;  # plain, case INSENSITIVE dos filenames
295
296     my(@subnames, $subname, %proto, %package);
297     my @cache = ();
298     my $caching = 1;
299     $last_package = '';
300     while (<IN>) {
301         $fnr++;
302         $in_pod = 1 if /^=\w/;
303         $in_pod = 0 if /^=cut/;
304         next if ($in_pod || /^=cut/);
305         # the following (tempting) old coding gives big troubles if a
306         # cut is forgotten at EOF:
307         # next if /^=\w/ .. /^=cut/;
308         if (/^package\s+([\w:]+)\s*;/) {
309             $this_package = $def_package = $1;
310         }
311         if (/^sub\s+([\w:]+)(\s*(?:\(.*?\))?(?:$attr_list)?)/) {
312             print OUT "# end of $last_package\::$subname\n1;\n"
313                 if $last_package;
314             $subname = $1;
315             my $proto = $2 || '';
316             if ($subname =~ s/(.*):://){
317                 $this_package = $1;
318             } else {
319                 $this_package = $def_package;
320             }
321             my $fq_subname = "$this_package\::$subname";
322             $package{$fq_subname} = $this_package;
323             $proto{$fq_subname} = $proto;
324             push(@subnames, $fq_subname);
325             my($lname, $sname) = ($subname, substr($subname,0,$maxflen-3));
326             $modpname = _modpname($this_package);
327             my($modnamedir) = catdir($autodir, $modpname);
328             mkpath($modnamedir,0,0777);
329             my($lpath) = catfile($modnamedir, "$lname.al");
330             my($spath) = catfile($modnamedir, "$sname.al");
331             my $path;
332             if (!$Is83 and open(OUT, ">$lpath")){
333                 $path=$lpath;
334                 print "  writing $lpath\n" if ($Verbose>=2);
335             } else {
336                 open(OUT, ">$spath") or die "Can't create $spath: $!\n";
337                 $path=$spath;
338                 print "  writing $spath (with truncated name)\n"
339                         if ($Verbose>=1);
340             }
341             push(@outfiles, $path);
342             my $lineno = $fnr - @cache;
343             print OUT <<EOT;
344 # NOTE: Derived from $filename.
345 # Changes made here will be lost when autosplit is run again.
346 # See AutoSplit.pm.
347 package $this_package;
348
349 #line $lineno "$filename (autosplit into $path)"
350 EOT
351             print OUT @cache;
352             @cache = ();
353             $caching = 0;
354         }
355         if($caching) {
356             push(@cache, $_) if @cache || /\S/;
357         } else {
358             print OUT $_;
359         }
360         if(/^\}/) {
361             if($caching) {
362                 print OUT @cache;
363                 @cache = ();
364             }
365             print OUT "\n";
366             $caching = 1;
367         }
368         $last_package = $this_package if defined $this_package;
369     }
370     if ($subname) {
371         print OUT @cache,"1;\n# end of $last_package\::$subname\n";
372         close(OUT);
373     }
374     close(IN);
375     
376     if (!$keep){  # don't keep any obsolete *.al files in the directory
377         my(%outfiles);
378         # @outfiles{@outfiles} = @outfiles;
379         # perl downcases all filenames on VMS (which upcases all filenames) so
380         # we'd better downcase the sub name list too, or subs with upper case
381         # letters in them will get their .al files deleted right after they're
382         # created. (The mixed case sub name won't match the all-lowercase
383         # filename, and so be cleaned up as a scrap file)
384         if ($Is_VMS or $Is83) {
385             %outfiles = map {lc($_) => lc($_) } @outfiles;
386         } else {
387             @outfiles{@outfiles} = @outfiles;
388         }  
389         my(%outdirs,@outdirs);
390         for (@outfiles) {
391             $outdirs{File::Basename::dirname($_)}||=1;
392         }
393         for my $dir (keys %outdirs) {
394             opendir(OUTDIR,$dir);
395             foreach (sort readdir(OUTDIR)){
396                 next unless /\.al\z/;
397                 my($file) = catfile($dir, $_);
398                 $file = lc $file if $Is83 or $Is_VMS;
399                 next if $outfiles{$file};
400                 print "  deleting $file\n" if ($Verbose>=2);
401                 my($deleted,$thistime);  # catch all versions on VMS
402                 do { $deleted += ($thistime = unlink $file) } while ($thistime);
403                 carp "Unable to delete $file: $!" unless $deleted;
404             }
405             closedir(OUTDIR);
406         }
407     }
408
409     open(TS,">$al_idx_file") or
410         carp "AutoSplit: unable to create timestamp file ($al_idx_file): $!";
411     print TS "# Index created by AutoSplit for $filename\n";
412     print TS "#    (file acts as timestamp)\n";
413     $last_package = '';
414     for my $fqs (@subnames) {
415         my($subname) = $fqs;
416         $subname =~ s/.*:://;
417         print TS "package $package{$fqs};\n"
418             unless $last_package eq $package{$fqs};
419         print TS "sub $subname $proto{$fqs};\n";
420         $last_package = $package{$fqs};
421     }
422     print TS "1;\n";
423     close(TS);
424
425     _check_unique($filename, $Maxlen, 1, @outfiles);
426
427     @outfiles;
428 }
429
430 sub _modpname ($) {
431     my($package) = @_;
432     my $modpname = $package;
433     if ($^O eq 'MSWin32') {
434         $modpname =~ s#::#\\#g; 
435     } else {
436         my @modpnames = ();
437         while ($modpname =~ m#(.*?[^:])::([^:].*)#) {
438                push @modpnames, $1;
439                $modpname = $2;
440          }
441         $modpname = catfile(@modpnames, $modpname);
442     }
443     if ($Is_VMS) {
444         $modpname = VMS::Filespec::unixify($modpname); # may have dirs
445     }
446     $modpname;
447 }
448
449 sub _check_unique {
450     my($filename, $maxlen, $warn, @outfiles) = @_;
451     my(%notuniq) = ();
452     my(%shorts)  = ();
453     my(@toolong) = grep(
454                         length(File::Basename::basename($_))
455                         > $maxlen,
456                         @outfiles
457                        );
458
459     foreach (@toolong){
460         my($dir) = File::Basename::dirname($_);
461         my($file) = File::Basename::basename($_);
462         my($trunc) = substr($file,0,$maxlen);
463         $notuniq{$dir}{$trunc} = 1 if $shorts{$dir}{$trunc};
464         $shorts{$dir}{$trunc} = $shorts{$dir}{$trunc} ?
465             "$shorts{$dir}{$trunc}, $file" : $file;
466     }
467     if (%notuniq && $warn){
468         print "$filename: some names are not unique when " .
469             "truncated to $maxlen characters:\n";
470         foreach my $dir (sort keys %notuniq){
471             print " directory $dir:\n";
472             foreach my $trunc (sort keys %{$notuniq{$dir}}) {
473                 print "  $shorts{$dir}{$trunc} truncate to $trunc\n";
474             }
475         }
476     }
477 }
478
479 1;
480 __END__
481
482 # test functions so AutoSplit.pm can be applied to itself:
483 sub test1 ($)   { "test 1\n"; }
484 sub test2 ($$)  { "test 2\n"; }
485 sub test3 ($$$) { "test 3\n"; }
486 sub testtesttesttest4_1  { "test 4\n"; }
487 sub testtesttesttest4_2  { "duplicate test 4\n"; }
488 sub Just::Another::test5 { "another test 5\n"; }
489 sub test6       { return join ":", __FILE__,__LINE__; }
490 package Yet::Another::AutoSplit;
491 sub testtesttesttest4_1 ($)  { "another test 4\n"; }
492 sub testtesttesttest4_2 ($$) { "another duplicate test 4\n"; }
493 package Yet::More::Attributes;
494 sub test_a1 ($) : locked :locked { 1; }
495 sub test_a2 : locked { 1; }