Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / pod2man.PL
1 #!/usr/local/bin/perl
2
3 use Config;
4 use File::Basename qw(&basename &dirname);
5 use Cwd;
6
7 # List explicitly here the variables you want Configure to
8 # generate.  Metaconfig only looks for shell variables, so you
9 # have to mention them as if they were shell variables, not
10 # %Config entries.  Thus you write
11 #  $startperl
12 # to ensure Configure will look for $Config{startperl}.
13
14 # This forces PL files to create target in same directory as PL file.
15 # This is so that make depend always knows where to find PL derivatives.
16 $origdir = cwd;
17 chdir dirname($0);
18 $file = basename($0, '.PL');
19 $file .= '.com' if $^O eq 'VMS';
20
21 open OUT,">$file" or die "Can't create $file: $!";
22
23 print "Extracting $file (with variable substitutions)\n";
24
25 # In this section, perl variables will be expanded during extraction.
26 # You can use $Config{...} to use Configure variables.
27
28 print OUT <<"!GROK!THIS!";
29 $Config{startperl}
30     eval 'exec $Config{perlpath} -S \$0 \${1+"\$@"}'
31         if \$running_under_some_shell;
32 !GROK!THIS!
33
34 # In the following, perl variables are not expanded during extraction.
35
36 print OUT <<'!NO!SUBS!';
37
38 # pod2man -- Convert POD data to formatted *roff input.
39 # $Id: pod2man.PL,v 1.10 2002/07/15 05:45:56 eagle Exp $
40 #
41 # Copyright 1999, 2000, 2001 by Russ Allbery <rra@stanford.edu>
42 #
43 # This program is free software; you may redistribute it and/or modify it
44 # under the same terms as Perl itself.
45
46 require 5.004;
47
48 use Getopt::Long qw(GetOptions);
49 use Pod::Man ();
50 use Pod::Usage qw(pod2usage);
51
52 use strict;
53
54 # Silence -w warnings.
55 use vars qw($running_under_some_shell);
56
57 # Insert -- into @ARGV before any single dash argument to hide it from
58 # Getopt::Long; we want to interpret it as meaning stdin (which Pod::Parser
59 # does correctly).
60 my $stdin;
61 @ARGV = map { $_ eq '-' && !$stdin++ ? ('--', $_) : $_ } @ARGV;
62
63 # Parse our options, trying to retain backwards compatibility with pod2man but
64 # allowing short forms as well.  --lax is currently ignored.
65 my %options;
66 Getopt::Long::config ('bundling_override');
67 GetOptions (\%options, 'section|s=s', 'release|r=s', 'center|c=s',
68             'date|d=s', 'fixed=s', 'fixedbold=s', 'fixeditalic=s',
69             'fixedbolditalic=s', 'name|n=s', 'official|o', 'quotes|q=s',
70             'lax|l', 'help|h', 'verbose|v') or exit 1;
71 pod2usage (0) if $options{help};
72
73 # Official sets --center, but don't override things explicitly set.
74 if ($options{official} && !defined $options{center}) {
75     $options{center} = 'Perl Programmers Reference Guide';
76 }
77
78 # Verbose is only our flag, not a Pod::Man flag.
79 my $verbose = $options{verbose};
80 delete $options{verbose};
81
82 # This isn't a valid Pod::Man option and is only accepted for backwards
83 # compatibility.
84 delete $options{lax};
85
86 # Initialize and run the formatter, pulling a pair of input and output off at
87 # a time.
88 my $parser = Pod::Man->new (%options);
89 my @files;
90 do {
91     @files = splice (@ARGV, 0, 2);
92     print "  $files[1]\n" if $verbose;
93     $parser->parse_from_file (@files);
94 } while (@ARGV);
95
96 __END__
97
98 =head1 NAME
99
100 pod2man - Convert POD data to formatted *roff input
101
102 =head1 SYNOPSIS
103
104 pod2man [B<--section>=I<manext>] [B<--release>=I<version>]
105 [B<--center>=I<string>] [B<--date>=I<string>] [B<--fixed>=I<font>]
106 [B<--fixedbold>=I<font>] [B<--fixeditalic>=I<font>]
107 [B<--fixedbolditalic>=I<font>] [B<--name>=I<name>] [B<--official>]
108 [B<--lax>] [B<--quotes>=I<quotes>] [B<--verbose>]
109 [I<input> [I<output>] ...]
110
111 pod2man B<--help>
112
113 =head1 DESCRIPTION
114
115 B<pod2man> is a front-end for Pod::Man, using it to generate *roff input
116 from POD source.  The resulting *roff code is suitable for display on a
117 terminal using nroff(1), normally via man(1), or printing using troff(1).
118
119 I<input> is the file to read for POD source (the POD can be embedded in
120 code).  If I<input> isn't given, it defaults to STDIN.  I<output>, if given,
121 is the file to which to write the formatted output.  If I<output> isn't
122 given, the formatted output is written to STDOUT.  Several POD files can be
123 processed in the same B<pod2man> invocation (saving module load and compile
124 times) by providing multiple pairs of I<input> and I<output> files on the
125 command line.
126
127 B<--section>, B<--release>, B<--center>, B<--date>, and B<--official> can be
128 used to set the headers and footers to use; if not given, Pod::Man will
129 assume various defaults.  See below or L<Pod::Man> for details.
130
131 B<pod2man> assumes that your *roff formatters have a fixed-width font named
132 CW.  If yours is called something else (like CR), use B<--fixed> to specify
133 it.  This generally only matters for troff output for printing.  Similarly,
134 you can set the fonts used for bold, italic, and bold italic fixed-width
135 output.
136
137 Besides the obvious pod conversions, Pod::Man, and therefore pod2man also
138 takes care of formatting func(), func(n), and simple variable references
139 like $foo or @bar so you don't have to use code escapes for them; complex
140 expressions like C<$fred{'stuff'}> will still need to be escaped, though.
141 It also translates dashes that aren't used as hyphens into en dashes, makes
142 long dashes--like this--into proper em dashes, fixes "paired quotes," and
143 takes care of several other troff-specific tweaks.  See L<Pod::Man> for
144 complete information.
145
146 =head1 OPTIONS
147
148 =over 4
149
150 =item B<-c> I<string>, B<--center>=I<string>
151
152 Sets the centered page header to I<string>.  The default is "User
153 Contributed Perl Documentation", but also see B<--official> below.
154
155 =item B<-d> I<string>, B<--date>=I<string>
156
157 Set the left-hand footer string to this value.  By default, the modification
158 date of the input file will be used, or the current date if input comes from
159 STDIN.
160
161 =item B<--fixed>=I<font>
162
163 The fixed-width font to use for vertabim text and code.  Defaults to CW.
164 Some systems may want CR instead.  Only matters for troff(1) output.
165
166 =item B<--fixedbold>=I<font>
167
168 Bold version of the fixed-width font.  Defaults to CB.  Only matters for
169 troff(1) output.
170
171 =item B<--fixeditalic>=I<font>
172
173 Italic version of the fixed-width font (actually, something of a misnomer,
174 since most fixed-width fonts only have an oblique version, not an italic
175 version).  Defaults to CI.  Only matters for troff(1) output.
176
177 =item B<--fixedbolditalic>=I<font>
178
179 Bold italic (probably actually oblique) version of the fixed-width font.
180 Pod::Man doesn't assume you have this, and defaults to CB.  Some systems
181 (such as Solaris) have this font available as CX.  Only matters for troff(1)
182 output.
183
184 =item B<-h>, B<--help>
185
186 Print out usage information.
187
188 =item B<-l>, B<--lax>
189
190 No longer used.  B<pod2man> used to check its input for validity as a manual
191 page, but this should now be done by L<podchecker(1)> instead.  Accepted for
192 backwards compatibility; this option no longer does anything.
193
194 =item B<-n> I<name>, B<--name>=I<name>
195
196 Set the name of the manual page to I<name>.  Without this option, the manual
197 name is set to the uppercased base name of the file being converted unless
198 the manual section is 3, in which case the path is parsed to see if it is a
199 Perl module path.  If it is, a path like C<.../lib/Pod/Man.pm> is converted
200 into a name like C<Pod::Man>.  This option, if given, overrides any
201 automatic determination of the name.
202
203 Note that this option is probably not useful when converting multiple POD
204 files at once.  The convention for Unix man pages for commands is for the
205 man page title to be in all-uppercase even if the command isn't.
206
207 =item B<-o>, B<--official>
208
209 Set the default header to indicate that this page is part of the standard
210 Perl release, if B<--center> is not also given.
211
212 =item B<-q> I<quotes>, B<--quotes>=I<quotes>
213
214 Sets the quote marks used to surround CE<lt>> text to I<quotes>.  If
215 I<quotes> is a single character, it is used as both the left and right
216 quote; if I<quotes> is two characters, the first character is used as the
217 left quote and the second as the right quoted; and if I<quotes> is four
218 characters, the first two are used as the left quote and the second two as
219 the right quote.
220
221 I<quotes> may also be set to the special value C<none>, in which case no
222 quote marks are added around CE<lt>> text (but the font is still changed for
223 troff output).
224
225 =item B<-r>, B<--release>
226
227 Set the centered footer.  By default, this is the version of Perl you run
228 B<pod2man> under.  Note that some system an macro sets assume that the
229 centered footer will be a modification date and will prepend something like
230 "Last modified: "; if this is the case, you may want to set B<--release> to
231 the last modified date and B<--date> to the version number.
232
233 =item B<-s>, B<--section>
234
235 Set the section for the C<.TH> macro.  The standard section numbering
236 convention is to use 1 for user commands, 2 for system calls, 3 for
237 functions, 4 for devices, 5 for file formats, 6 for games, 7 for
238 miscellaneous information, and 8 for administrator commands.  There is a lot
239 of variation here, however; some systems (like Solaris) use 4 for file
240 formats, 5 for miscellaneous information, and 7 for devices.  Still others
241 use 1m instead of 8, or some mix of both.  About the only section numbers
242 that are reliably consistent are 1, 2, and 3.
243
244 By default, section 1 will be used unless the file ends in .pm in which case
245 section 3 will be selected.
246
247 =item B<-v>, B<--verbose>
248
249 Print out the name of each output file as it is being generated.
250
251 =back
252
253 =head1 DIAGNOSTICS
254
255 If B<pod2man> fails with errors, see L<Pod::Man> and L<Pod::Parser> for
256 information about what those errors might mean.
257
258 =head1 EXAMPLES
259
260     pod2man program > program.1
261     pod2man SomeModule.pm /usr/perl/man/man3/SomeModule.3
262     pod2man --section=7 note.pod > note.7
263
264 If you would like to print out a lot of man page continuously, you probably
265 want to set the C and D registers to set contiguous page numbering and
266 even/odd paging, at least on some versions of man(7).
267
268     troff -man -rC1 -rD1 perl.1 perldata.1 perlsyn.1 ...
269
270 To get index entries on stderr, turn on the F register, as in:
271
272     troff -man -rF1 perl.1
273
274 The indexing merely outputs messages via C<.tm> for each major page,
275 section, subsection, item, and any C<XE<lt>E<gt>> directives.  See
276 L<Pod::Man> for more details.
277
278 =head1 BUGS
279
280 Lots of this documentation is duplicated from L<Pod::Man>.
281
282 =head1 NOTES
283
284 For those not sure of the proper layout of a man page, here are some notes
285 on writing a proper man page.
286
287 The name of the program being documented is conventionally written in bold
288 (using BE<lt>E<gt>) wherever it occurs, as are all program options.
289 Arguments should be written in italics (IE<lt>E<gt>).  Functions are
290 traditionally written in italics; if you write a function as function(),
291 Pod::Man will take care of this for you.  Literal code or commands should
292 be in CE<lt>E<gt>.  References to other man pages should be in the form
293 C<manpage(section)>, and Pod::Man will automatically format those
294 appropriately.  As an exception, it's traditional not to use this form when
295 referring to module documentation; use C<LE<lt>Module::NameE<gt>> instead.
296
297 References to other programs or functions are normally in the form of man
298 page references so that cross-referencing tools can provide the user with
299 links and the like.  It's possible to overdo this, though, so be careful not
300 to clutter your documentation with too much markup.
301
302 The major headers should be set out using a C<=head1> directive, and are
303 historically written in the rather startling ALL UPPER CASE format, although
304 this is not mandatory.  Minor headers may be included using C<=head2>, and
305 are typically in mixed case.
306
307 The standard sections of a manual page are:
308
309 =over 4
310
311 =item NAME
312
313 Mandatory section; should be a comma-separated list of programs or functions
314 documented by this podpage, such as:
315
316     foo, bar - programs to do something
317
318 Manual page indexers are often extremely picky about the format of this
319 section, so don't put anything in it except this line.  A single dash, and
320 only a single dash, should separate the list of programs or functions from
321 the description.  Functions should not be qualified with C<()> or the like.
322 The description should ideally fit on a single line, even if a man program
323 replaces the dash with a few tabs.
324
325 =item SYNOPSIS
326
327 A short usage summary for programs and functions.  This section is mandatory
328 for section 3 pages.
329
330 =item DESCRIPTION
331
332 Extended description and discussion of the program or functions, or the body
333 of the documentation for man pages that document something else.  If
334 particularly long, it's a good idea to break this up into subsections
335 C<=head2> directives like:
336
337     =head2 Normal Usage
338
339     =head2 Advanced Features
340
341     =head2 Writing Configuration Files
342
343 or whatever is appropriate for your documentation.
344
345 =item OPTIONS
346
347 Detailed description of each of the command-line options taken by the
348 program.  This should be separate from the description for the use of things
349 like L<Pod::Usage|Pod::Usage>.  This is normally presented as a list, with
350 each option as a separate C<=item>.  The specific option string should be
351 enclosed in BE<lt>E<gt>.  Any values that the option takes should be
352 enclosed in IE<lt>E<gt>.  For example, the section for the option
353 B<--section>=I<manext> would be introduced with:
354
355     =item B<--section>=I<manext>
356
357 Synonymous options (like both the short and long forms) are separated by a
358 comma and a space on the same C<=item> line, or optionally listed as their
359 own item with a reference to the canonical name.  For example, since
360 B<--section> can also be written as B<-s>, the above would be:
361
362     =item B<-s> I<manext>, B<--section>=I<manext>
363
364 (Writing the short option first is arguably easier to read, since the long
365 option is long enough to draw the eye to it anyway and the short option can
366 otherwise get lost in visual noise.)
367
368 =item RETURN VALUE
369
370 What the program or function returns, if successful.  This section can be
371 omitted for programs whose precise exit codes aren't important, provided
372 they return 0 on success as is standard.  It should always be present for
373 functions.
374
375 =item ERRORS
376
377 Exceptions, error return codes, exit statuses, and errno settings.
378 Typically used for function documentation; program documentation uses
379 DIAGNOSTICS instead.  The general rule of thumb is that errors printed to
380 STDOUT or STDERR and intended for the end user are documented in DIAGNOSTICS
381 while errors passed internal to the calling program and intended for other
382 programmers are documented in ERRORS.  When documenting a function that sets
383 errno, a full list of the possible errno values should be given here.
384
385 =item DIAGNOSTICS
386
387 All possible messages the program can print out--and what they mean.  You
388 may wish to follow the same documentation style as the Perl documentation;
389 see perldiag(1) for more details (and look at the POD source as well).
390
391 If applicable, please include details on what the user should do to correct
392 the error; documenting an error as indicating "the input buffer is too
393 small" without telling the user how to increase the size of the input buffer
394 (or at least telling them that it isn't possible) aren't very useful.
395
396 =item EXAMPLES
397
398 Give some example uses of the program or function.  Don't skimp; users often
399 find this the most useful part of the documentation.  The examples are
400 generally given as verbatim paragraphs.
401
402 Don't just present an example without explaining what it does.  Adding a
403 short paragraph saying what the example will do can increase the value of
404 the example immensely.
405
406 =item ENVIRONMENT
407
408 Environment variables that the program cares about, normally presented as a
409 list using C<=over>, C<=item>, and C<=back>.  For example:
410
411     =over 6
412
413     =item HOME
414
415     Used to determine the user's home directory.  F<.foorc> in this
416     directory is read for configuration details, if it exists.
417
418     =back
419
420 Since environment variables are normally in all uppercase, no additional
421 special formatting is generally needed; they're glaring enough as it is.
422
423 =item FILES
424
425 All files used by the program or function, normally presented as a list, and
426 what it uses them for.  File names should be enclosed in FE<lt>E<gt>.  It's
427 particularly important to document files that will be potentially modified.
428
429 =item CAVEATS
430
431 Things to take special care with, sometimes called WARNINGS.
432
433 =item BUGS
434
435 Things that are broken or just don't work quite right.
436
437 =item RESTRICTIONS
438
439 Bugs you don't plan to fix.  :-)
440
441 =item NOTES
442
443 Miscellaneous commentary.
444
445 =item SEE ALSO
446
447 Other man pages to check out, like man(1), man(7), makewhatis(8), or
448 catman(8).  Normally a simple list of man pages separated by commas, or a
449 paragraph giving the name of a reference work.  Man page references, if they
450 use the standard C<name(section)> form, don't have to be enclosed in
451 LE<lt>E<gt> (although it's recommended), but other things in this section
452 probably should be when appropriate.
453
454 If the package has a mailing list, include a URL or subscription
455 instructions here.
456
457 If the package has a web site, include a URL here.
458
459 =item AUTHOR
460
461 Who wrote it (use AUTHORS for multiple people).  Including your current
462 e-mail address (or some e-mail address to which bug reports should be sent)
463 so that users have a way of contacting you is a good idea.  Remember that
464 program documentation tends to roam the wild for far longer than you expect
465 and pick an e-mail address that's likely to last if possible.
466
467 =item COPYRIGHT AND LICENSE
468
469 For copyright
470
471     Copyright YEAR(s) by YOUR NAME(s)
472
473 (No, (C) is not needed.  No, "all rights reserved" is not needed.)
474
475 For licensing the easiest way is to use the same licensing as Perl itself:
476
477     This library is free software; you may redistribute it and/or modify
478     it under the same terms as Perl itself.
479
480 This makes it easy for people to use your module with Perl.  Note that
481 this licensing is neither an endorsement or a requirement, you are of
482 course free to choose any licensing.
483
484 =item HISTORY
485
486 Programs derived from other sources sometimes have this, or you might keep
487 a modification log here.  If the log gets overly long or detailed,
488 consider maintaining it in a separate file, though.
489
490 =back
491
492 In addition, some systems use CONFORMING TO to note conformance to relevant
493 standards and MT-LEVEL to note safeness for use in threaded programs or
494 signal handlers.  These headings are primarily useful when documenting parts
495 of a C library.  Documentation of object-oriented libraries or modules may
496 use CONSTRUCTORS and METHODS sections for detailed documentation of the
497 parts of the library and save the DESCRIPTION section for an overview; other
498 large modules may use FUNCTIONS for similar reasons.  Some people use
499 OVERVIEW to summarize the description if it's quite long.
500
501 Section ordering varies, although NAME should I<always> be the first section
502 (you'll break some man page systems otherwise), and NAME, SYNOPSIS,
503 DESCRIPTION, and OPTIONS generally always occur first and in that order if
504 present.  In general, SEE ALSO, AUTHOR, and similar material should be left
505 for last.  Some systems also move WARNINGS and NOTES to last.  The order
506 given above should be reasonable for most purposes.
507
508 Finally, as a general note, try not to use an excessive amount of markup.
509 As documented here and in L<Pod::Man>, you can safely leave Perl variables,
510 function names, man page references, and the like unadorned by markup and
511 the POD translators will figure it out for you.  This makes it much easier
512 to later edit the documentation.  Note that many existing translators
513 (including this one currently) will do the wrong thing with e-mail addresses
514 or URLs when wrapped in LE<lt>E<gt>, so don't do that.
515
516 For additional information that may be more accurate for your specific
517 system, see either L<man(5)> or L<man(7)> depending on your system manual
518 section numbering conventions.
519
520 =head1 SEE ALSO
521
522 L<Pod::Man>, L<Pod::Parser>, L<man(1)>, L<nroff(1)>, L<podchecker(1)>,
523 L<troff(1)>, L<man(7)>
524
525 The man page documenting the an macro set may be L<man(5)> instead of
526 L<man(7)> on your system.
527
528 The current version of this script is always available from its web site at
529 L<http://www.eyrie.org/~eagle/software/podlators/>.  It is also part of the
530 Perl core distribution as of 5.6.0.
531
532 =head1 AUTHOR
533
534 Russ Allbery <rra@stanford.edu>, based I<very> heavily on the original
535 B<pod2man> by Larry Wall and Tom Christiansen.  Large portions of this
536 documentation, particularly the sections on the anatomy of a proper man
537 page, are taken from the B<pod2man> documentation by Tom.
538
539 =head1 COPYRIGHT AND LICENSE
540
541 Copyright 1999, 2000, 2001 by Russ Allbery <rra@stanford.edu>.
542
543 This program is free software; you may redistribute it and/or modify it
544 under the same terms as Perl itself.
545
546 =cut
547 !NO!SUBS!
548 #'# (cperl-mode)
549
550 close OUT or die "Can't close $file: $!";
551 chmod 0755, $file or die "Can't reset permissions for $file: $!\n";
552 exec("$Config{'eunicefix'} $file") if $Config{'eunicefix'} ne ':';
553 chdir $origdir;