Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlvar.pod
1 =head1 NAME
2
3 perlvar - Perl predefined variables
4
5 =head1 DESCRIPTION
6
7 =head2 Predefined Names
8
9 The following names have special meaning to Perl.  Most 
10 punctuation names have reasonable mnemonics, or analogs in the
11 shells.  Nevertheless, if you wish to use long variable names,
12 you need only say
13
14     use English;
15
16 at the top of your program. This aliases all the short names to the long
17 names in the current package. Some even have medium names, generally
18 borrowed from B<awk>. In general, it's best to use the
19
20     use English '-no_match_vars';
21
22 invocation if you don't need $PREMATCH, $MATCH, or $POSTMATCH, as it avoids
23 a certain performance hit with the use of regular expressions. See
24 L<English>.
25
26 Variables that depend on the currently selected filehandle may be set by
27 calling an appropriate object method on the IO::Handle object, although
28 this is less efficient than using the regular built-in variables. (Summary
29 lines below for this contain the word HANDLE.) First you must say
30
31     use IO::Handle;
32
33 after which you may use either
34
35     method HANDLE EXPR
36
37 or more safely,
38
39     HANDLE->method(EXPR)
40
41 Each method returns the old value of the IO::Handle attribute.
42 The methods each take an optional EXPR, which, if supplied, specifies the
43 new value for the IO::Handle attribute in question.  If not supplied,
44 most methods do nothing to the current value--except for
45 autoflush(), which will assume a 1 for you, just to be different.
46
47 Because loading in the IO::Handle class is an expensive operation, you should
48 learn how to use the regular built-in variables.
49
50 A few of these variables are considered "read-only".  This means that if
51 you try to assign to this variable, either directly or indirectly through
52 a reference, you'll raise a run-time exception.
53
54 You should be very careful when modifying the default values of most
55 special variables described in this document. In most cases you want
56 to localize these variables before changing them, since if you don't,
57 the change may affect other modules which rely on the default values
58 of the special variables that you have changed. This is one of the
59 correct ways to read the whole file at once:
60
61     open my $fh, "foo" or die $!;
62     local $/; # enable localized slurp mode
63     my $content = <$fh>;
64     close $fh;
65
66 But the following code is quite bad:
67
68     open my $fh, "foo" or die $!;
69     undef $/; # enable slurp mode
70     my $content = <$fh>;
71     close $fh;
72
73 since some other module, may want to read data from some file in the
74 default "line mode", so if the code we have just presented has been
75 executed, the global value of C<$/> is now changed for any other code
76 running inside the same Perl interpreter.
77
78 Usually when a variable is localized you want to make sure that this
79 change affects the shortest scope possible. So unless you are already
80 inside some short C<{}> block, you should create one yourself. For
81 example:
82
83     my $content = '';
84     open my $fh, "foo" or die $!;
85     {
86         local $/;
87         $content = <$fh>;
88     }
89     close $fh;
90
91 Here is an example of how your own code can go broken:
92
93     for (1..5){
94         nasty_break();
95         print "$_ ";
96     }
97     sub nasty_break {
98         $_ = 5;
99         # do something with $_
100     }
101
102 You probably expect this code to print:
103
104     1 2 3 4 5
105
106 but instead you get:
107
108     5 5 5 5 5
109
110 Why? Because nasty_break() modifies C<$_> without localizing it
111 first. The fix is to add local():
112
113         local $_ = 5;
114
115 It's easy to notice the problem in such a short example, but in more
116 complicated code you are looking for trouble if you don't localize
117 changes to the special variables.
118
119 The following list is ordered by scalar variables first, then the
120 arrays, then the hashes.
121
122 =over 8
123
124 =item $ARG
125
126 =item $_
127
128 The default input and pattern-searching space.  The following pairs are
129 equivalent:
130
131     while (<>) {...}    # equivalent only in while!
132     while (defined($_ = <>)) {...}
133
134     /^Subject:/
135     $_ =~ /^Subject:/
136
137     tr/a-z/A-Z/
138     $_ =~ tr/a-z/A-Z/
139
140     chomp
141     chomp($_)
142
143 Here are the places where Perl will assume $_ even if you
144 don't use it:
145
146 =over 3
147
148 =item *
149
150 Various unary functions, including functions like ord() and int(), as well
151 as the all file tests (C<-f>, C<-d>) except for C<-t>, which defaults to
152 STDIN.
153
154 =item *
155
156 Various list functions like print() and unlink().
157
158 =item *
159
160 The pattern matching operations C<m//>, C<s///>, and C<tr///> when used
161 without an C<=~> operator.
162
163 =item *
164
165 The default iterator variable in a C<foreach> loop if no other
166 variable is supplied.
167
168 =item *
169
170 The implicit iterator variable in the grep() and map() functions.
171
172 =item *
173
174 The default place to put an input record when a C<< <FH> >>
175 operation's result is tested by itself as the sole criterion of a C<while>
176 test.  Outside a C<while> test, this will not happen.
177
178 =back
179
180 (Mnemonic: underline is understood in certain operations.)
181
182 =back
183
184 =over 8
185
186 =item $a
187
188 =item $b
189
190 Special package variables when using sort(), see L<perlfunc/sort>.
191 Because of this specialness $a and $b don't need to be declared
192 (using local(), use vars, or our()) even when using the strict
193 vars pragma.  Don't lexicalize them with C<my $a> or C<my $b>
194 if you want to be able to use them in the sort() comparison block
195 or function.
196
197 =back
198
199 =over 8
200
201 =item $<I<digits>>
202
203 Contains the subpattern from the corresponding set of capturing
204 parentheses from the last pattern match, not counting patterns
205 matched in nested blocks that have been exited already.  (Mnemonic:
206 like \digits.)  These variables are all read-only and dynamically
207 scoped to the current BLOCK.
208
209 =item $MATCH
210
211 =item $&
212
213 The string matched by the last successful pattern match (not counting
214 any matches hidden within a BLOCK or eval() enclosed by the current
215 BLOCK).  (Mnemonic: like & in some editors.)  This variable is read-only
216 and dynamically scoped to the current BLOCK.
217
218 The use of this variable anywhere in a program imposes a considerable
219 performance penalty on all regular expression matches.  See L</BUGS>.
220
221 =item $PREMATCH
222
223 =item $`
224
225 The string preceding whatever was matched by the last successful
226 pattern match (not counting any matches hidden within a BLOCK or eval
227 enclosed by the current BLOCK).  (Mnemonic: C<`> often precedes a quoted
228 string.)  This variable is read-only.
229
230 The use of this variable anywhere in a program imposes a considerable
231 performance penalty on all regular expression matches.  See L</BUGS>.
232
233 =item $POSTMATCH
234
235 =item $'
236
237 The string following whatever was matched by the last successful
238 pattern match (not counting any matches hidden within a BLOCK or eval()
239 enclosed by the current BLOCK).  (Mnemonic: C<'> often follows a quoted
240 string.)  Example:
241
242     local $_ = 'abcdefghi';
243     /def/;
244     print "$`:$&:$'\n";         # prints abc:def:ghi
245
246 This variable is read-only and dynamically scoped to the current BLOCK.
247
248 The use of this variable anywhere in a program imposes a considerable
249 performance penalty on all regular expression matches.  See L</BUGS>.
250
251 =item $LAST_PAREN_MATCH
252
253 =item $+
254
255 The text matched by the last bracket of the last successful search pattern.
256 This is useful if you don't know which one of a set of alternative patterns
257 matched. For example:
258
259     /Version: (.*)|Revision: (.*)/ && ($rev = $+);
260
261 (Mnemonic: be positive and forward looking.)
262 This variable is read-only and dynamically scoped to the current BLOCK.
263
264 =item $^N
265
266 The text matched by the used group most-recently closed (i.e. the group
267 with the rightmost closing parenthesis) of the last successful search
268 pattern.  (Mnemonic: the (possibly) Nested parenthesis that most
269 recently closed.)
270
271 This is primarily used inside C<(?{...})> blocks for examining text
272 recently matched. For example, to effectively capture text to a variable
273 (in addition to C<$1>, C<$2>, etc.), replace C<(...)> with
274
275      (?:(...)(?{ $var = $^N }))
276
277 By setting and then using C<$var> in this way relieves you from having to
278 worry about exactly which numbered set of parentheses they are.
279
280 This variable is dynamically scoped to the current BLOCK.
281
282 =item @LAST_MATCH_END
283
284 =item @+
285
286 This array holds the offsets of the ends of the last successful
287 submatches in the currently active dynamic scope.  C<$+[0]> is
288 the offset into the string of the end of the entire match.  This
289 is the same value as what the C<pos> function returns when called
290 on the variable that was matched against.  The I<n>th element
291 of this array holds the offset of the I<n>th submatch, so
292 C<$+[1]> is the offset past where $1 ends, C<$+[2]> the offset
293 past where $2 ends, and so on.  You can use C<$#+> to determine
294 how many subgroups were in the last successful match.  See the
295 examples given for the C<@-> variable.
296
297 =item $MULTILINE_MATCHING
298
299 =item $*
300
301 Set to a non-zero integer value to do multi-line matching within a
302 string, 0 (or undefined) to tell Perl that it can assume that strings
303 contain a single line, for the purpose of optimizing pattern matches.
304 Pattern matches on strings containing multiple newlines can produce
305 confusing results when C<$*> is 0 or undefined. Default is undefined.
306 (Mnemonic: * matches multiple things.) This variable influences the
307 interpretation of only C<^> and C<$>. A literal newline can be searched
308 for even when C<$* == 0>.
309
310 Use of C<$*> is deprecated in modern Perl, supplanted by 
311 the C</s> and C</m> modifiers on pattern matching.
312
313 Assigning a non-numerical value to C<$*> triggers a warning (and makes
314 C<$*> act if C<$* == 0>), while assigning a numerical value to C<$*>
315 makes that an implicit C<int> is applied on the value.
316
317 =item HANDLE->input_line_number(EXPR)
318
319 =item $INPUT_LINE_NUMBER
320
321 =item $NR
322
323 =item $.
324
325 Current line number for the last filehandle accessed. 
326
327 Each filehandle in Perl counts the number of lines that have been read
328 from it.  (Depending on the value of C<$/>, Perl's idea of what
329 constitutes a line may not match yours.)  When a line is read from a
330 filehandle (via readline() or C<< <> >>), or when tell() or seek() is
331 called on it, C<$.> becomes an alias to the line counter for that
332 filehandle.
333
334 You can adjust the counter by assigning to C<$.>, but this will not
335 actually move the seek pointer.  I<Localizing C<$.> will not localize
336 the filehandle's line count>.  Instead, it will localize perl's notion
337 of which filehandle C<$.> is currently aliased to.
338
339 C<$.> is reset when the filehandle is closed, but B<not> when an open
340 filehandle is reopened without an intervening close().  For more
341 details, see L<perlop/"IE<sol>O Operators">.  Because C<< <> >> never does
342 an explicit close, line numbers increase across ARGV files (but see
343 examples in L<perlfunc/eof>).
344
345 You can also use C<< HANDLE->input_line_number(EXPR) >> to access the
346 line counter for a given filehandle without having to worry about
347 which handle you last accessed.
348
349 (Mnemonic: many programs use "." to mean the current line number.)
350
351 =item IO::Handle->input_record_separator(EXPR)
352
353 =item $INPUT_RECORD_SEPARATOR
354
355 =item $RS
356
357 =item $/
358
359 The input record separator, newline by default.  This 
360 influences Perl's idea of what a "line" is.  Works like B<awk>'s RS
361 variable, including treating empty lines as a terminator if set to
362 the null string.  (An empty line cannot contain any spaces
363 or tabs.)  You may set it to a multi-character string to match a
364 multi-character terminator, or to C<undef> to read through the end
365 of file.  Setting it to C<"\n\n"> means something slightly
366 different than setting to C<"">, if the file contains consecutive
367 empty lines.  Setting to C<""> will treat two or more consecutive
368 empty lines as a single empty line.  Setting to C<"\n\n"> will
369 blindly assume that the next input character belongs to the next
370 paragraph, even if it's a newline.  (Mnemonic: / delimits
371 line boundaries when quoting poetry.)
372
373     local $/;           # enable "slurp" mode
374     local $_ = <FH>;    # whole file now here
375     s/\n[ \t]+/ /g;
376
377 Remember: the value of C<$/> is a string, not a regex.  B<awk> has to be
378 better for something. :-)
379
380 Setting C<$/> to a reference to an integer, scalar containing an integer, or
381 scalar that's convertible to an integer will attempt to read records
382 instead of lines, with the maximum record size being the referenced
383 integer.  So this:
384
385     local $/ = \32768; # or \"32768", or \$var_containing_32768
386     open my $fh, $myfile or die $!;
387     local $_ = <$fh>;
388
389 will read a record of no more than 32768 bytes from FILE.  If you're
390 not reading from a record-oriented file (or your OS doesn't have
391 record-oriented files), then you'll likely get a full chunk of data
392 with every read.  If a record is larger than the record size you've
393 set, you'll get the record back in pieces.
394
395 On VMS, record reads are done with the equivalent of C<sysread>,
396 so it's best not to mix record and non-record reads on the same
397 file.  (This is unlikely to be a problem, because any file you'd
398 want to read in record mode is probably unusable in line mode.)
399 Non-VMS systems do normal I/O, so it's safe to mix record and
400 non-record reads of a file.
401
402 See also L<perlport/"Newlines">.  Also see C<$.>.
403
404 =item HANDLE->autoflush(EXPR)
405
406 =item $OUTPUT_AUTOFLUSH
407
408 =item $|
409
410 If set to nonzero, forces a flush right away and after every write
411 or print on the currently selected output channel.  Default is 0
412 (regardless of whether the channel is really buffered by the
413 system or not; C<$|> tells you only whether you've asked Perl
414 explicitly to flush after each write).  STDOUT will
415 typically be line buffered if output is to the terminal and block
416 buffered otherwise.  Setting this variable is useful primarily when
417 you are outputting to a pipe or socket, such as when you are running
418 a Perl program under B<rsh> and want to see the output as it's
419 happening.  This has no effect on input buffering.  See L<perlfunc/getc>
420 for that.  (Mnemonic: when you want your pipes to be piping hot.)
421
422 =item IO::Handle->output_field_separator EXPR
423
424 =item $OUTPUT_FIELD_SEPARATOR
425
426 =item $OFS
427
428 =item $,
429
430 The output field separator for the print operator.  Ordinarily the
431 print operator simply prints out its arguments without further
432 adornment.  To get behavior more like B<awk>, set this variable as
433 you would set B<awk>'s OFS variable to specify what is printed
434 between fields.  (Mnemonic: what is printed when there is a "," in
435 your print statement.)
436
437 =item IO::Handle->output_record_separator EXPR
438
439 =item $OUTPUT_RECORD_SEPARATOR
440
441 =item $ORS
442
443 =item $\
444
445 The output record separator for the print operator.  Ordinarily the
446 print operator simply prints out its arguments as is, with no
447 trailing newline or other end-of-record string added.  To get
448 behavior more like B<awk>, set this variable as you would set
449 B<awk>'s ORS variable to specify what is printed at the end of the
450 print.  (Mnemonic: you set C<$\> instead of adding "\n" at the
451 end of the print.  Also, it's just like C<$/>, but it's what you
452 get "back" from Perl.)
453
454 =item $LIST_SEPARATOR
455
456 =item $"
457
458 This is like C<$,> except that it applies to array and slice values
459 interpolated into a double-quoted string (or similar interpreted
460 string).  Default is a space.  (Mnemonic: obvious, I think.)
461
462 =item $SUBSCRIPT_SEPARATOR
463
464 =item $SUBSEP
465
466 =item $;
467
468 The subscript separator for multidimensional array emulation.  If you
469 refer to a hash element as
470
471     $foo{$a,$b,$c}
472
473 it really means
474
475     $foo{join($;, $a, $b, $c)}
476
477 But don't put
478
479     @foo{$a,$b,$c}      # a slice--note the @
480
481 which means
482
483     ($foo{$a},$foo{$b},$foo{$c})
484
485 Default is "\034", the same as SUBSEP in B<awk>.  If your
486 keys contain binary data there might not be any safe value for C<$;>.
487 (Mnemonic: comma (the syntactic subscript separator) is a
488 semi-semicolon.  Yeah, I know, it's pretty lame, but C<$,> is already
489 taken for something more important.)
490
491 Consider using "real" multidimensional arrays as described
492 in L<perllol>.
493
494 =item $OFMT
495
496 =item $#
497
498 The output format for printed numbers.  This variable is a half-hearted
499 attempt to emulate B<awk>'s OFMT variable.  There are times, however,
500 when B<awk> and Perl have differing notions of what counts as 
501 numeric.  The initial value is "%.I<n>g", where I<n> is the value
502 of the macro DBL_DIG from your system's F<float.h>.  This is different from
503 B<awk>'s default OFMT setting of "%.6g", so you need to set C<$#>
504 explicitly to get B<awk>'s value.  (Mnemonic: # is the number sign.)
505
506 Use of C<$#> is deprecated.
507
508 =item HANDLE->format_page_number(EXPR)
509
510 =item $FORMAT_PAGE_NUMBER
511
512 =item $%
513
514 The current page number of the currently selected output channel.
515 Used with formats.
516 (Mnemonic: % is page number in B<nroff>.)
517
518 =item HANDLE->format_lines_per_page(EXPR)
519
520 =item $FORMAT_LINES_PER_PAGE
521
522 =item $=
523
524 The current page length (printable lines) of the currently selected
525 output channel.  Default is 60.  
526 Used with formats.
527 (Mnemonic: = has horizontal lines.)
528
529 =item HANDLE->format_lines_left(EXPR)
530
531 =item $FORMAT_LINES_LEFT
532
533 =item $-
534
535 The number of lines left on the page of the currently selected output
536 channel.  
537 Used with formats.
538 (Mnemonic: lines_on_page - lines_printed.)
539
540 =item @LAST_MATCH_START
541
542 =item @-
543
544 $-[0] is the offset of the start of the last successful match.
545 C<$-[>I<n>C<]> is the offset of the start of the substring matched by
546 I<n>-th subpattern, or undef if the subpattern did not match.
547
548 Thus after a match against $_, $& coincides with C<substr $_, $-[0],
549 $+[0] - $-[0]>.  Similarly, C<$>I<n> coincides with C<substr $_, $-[>I<n>C<],
550 $+[>I<n>C<] - $-[>I<n>C<]> if C<$-[>I<n>C<]> is defined, and $+ coincides with
551 C<substr $_, $-[$#-], $+[$#-]>.  One can use C<$#-> to find the last
552 matched subgroup in the last successful match.  Contrast with
553 C<$#+>, the number of subgroups in the regular expression.  Compare
554 with C<@+>.
555
556 This array holds the offsets of the beginnings of the last
557 successful submatches in the currently active dynamic scope.
558 C<$-[0]> is the offset into the string of the beginning of the
559 entire match.  The I<n>th element of this array holds the offset
560 of the I<n>th submatch, so C<$-[1]> is the offset where $1
561 begins, C<$-[2]> the offset where $2 begins, and so on.
562
563 After a match against some variable $var:
564
565 =over 5
566
567 =item C<$`> is the same as C<substr($var, 0, $-[0])>
568
569 =item C<$&> is the same as C<substr($var, $-[0], $+[0] - $-[0])>
570
571 =item C<$'> is the same as C<substr($var, $+[0])>
572
573 =item C<$1> is the same as C<substr($var, $-[1], $+[1] - $-[1])>  
574
575 =item C<$2> is the same as C<substr($var, $-[2], $+[2] - $-[2])>
576
577 =item C<$3> is the same as C<substr $var, $-[3], $+[3] - $-[3])>
578
579 =back
580
581 =item HANDLE->format_name(EXPR)
582
583 =item $FORMAT_NAME
584
585 =item $~
586
587 The name of the current report format for the currently selected output
588 channel.  Default is the name of the filehandle.  (Mnemonic: brother to
589 C<$^>.)
590
591 =item HANDLE->format_top_name(EXPR)
592
593 =item $FORMAT_TOP_NAME
594
595 =item $^
596
597 The name of the current top-of-page format for the currently selected
598 output channel.  Default is the name of the filehandle with _TOP
599 appended.  (Mnemonic: points to top of page.)
600
601 =item IO::Handle->format_line_break_characters EXPR
602
603 =item $FORMAT_LINE_BREAK_CHARACTERS
604
605 =item $:
606
607 The current set of characters after which a string may be broken to
608 fill continuation fields (starting with ^) in a format.  Default is
609 S<" \n-">, to break on whitespace or hyphens.  (Mnemonic: a "colon" in
610 poetry is a part of a line.)
611
612 =item IO::Handle->format_formfeed EXPR
613
614 =item $FORMAT_FORMFEED
615
616 =item $^L
617
618 What formats output as a form feed.  Default is \f.
619
620 =item $ACCUMULATOR
621
622 =item $^A
623
624 The current value of the write() accumulator for format() lines.  A format
625 contains formline() calls that put their result into C<$^A>.  After
626 calling its format, write() prints out the contents of C<$^A> and empties.
627 So you never really see the contents of C<$^A> unless you call
628 formline() yourself and then look at it.  See L<perlform> and
629 L<perlfunc/formline()>.
630
631 =item $CHILD_ERROR
632
633 =item $?
634
635 The status returned by the last pipe close, backtick (C<``>) command,
636 successful call to wait() or waitpid(), or from the system()
637 operator.  This is just the 16-bit status word returned by the
638 wait() system call (or else is made up to look like it).  Thus, the
639 exit value of the subprocess is really (C<<< $? >> 8 >>>), and
640 C<$? & 127> gives which signal, if any, the process died from, and
641 C<$? & 128> reports whether there was a core dump.  (Mnemonic:
642 similar to B<sh> and B<ksh>.)
643
644 Additionally, if the C<h_errno> variable is supported in C, its value
645 is returned via $? if any C<gethost*()> function fails.
646
647 If you have installed a signal handler for C<SIGCHLD>, the
648 value of C<$?> will usually be wrong outside that handler.
649
650 Inside an C<END> subroutine C<$?> contains the value that is going to be
651 given to C<exit()>.  You can modify C<$?> in an C<END> subroutine to
652 change the exit status of your program.  For example:
653
654     END {
655         $? = 1 if $? == 255;  # die would make it 255
656     } 
657
658 Under VMS, the pragma C<use vmsish 'status'> makes C<$?> reflect the
659 actual VMS exit status, instead of the default emulation of POSIX
660 status; see L<perlvms/$?> for details.
661
662 Also see L<Error Indicators>.
663
664 =item ${^ENCODING}
665
666 The I<object reference> to the Encode object that is used to convert
667 the source code to Unicode.  Thanks to this variable your perl script
668 does not have to be written in UTF-8.  Default is I<undef>.  The direct
669 manipulation of this variable is highly discouraged.  See L<encoding>
670 for more details.
671
672 =item $OS_ERROR
673
674 =item $ERRNO
675
676 =item $!
677
678 If used numerically, yields the current value of the C C<errno>
679 variable, or in other words, if a system or library call fails, it
680 sets this variable.  This means that the value of C<$!> is meaningful
681 only I<immediately> after a B<failure>:
682
683     if (open(FH, $filename)) {
684         # Here $! is meaningless.
685         ...
686     } else {
687         # ONLY here is $! meaningful.
688         ...
689         # Already here $! might be meaningless.
690     }
691     # Since here we might have either success or failure,
692     # here $! is meaningless.
693
694 In the above I<meaningless> stands for anything: zero, non-zero,
695 C<undef>.  A successful system or library call does B<not> set
696 the variable to zero.
697
698 If used an a string, yields the corresponding system error string.
699 You can assign a number to C<$!> to set I<errno> if, for instance,
700 you want C<"$!"> to return the string for error I<n>, or you want
701 to set the exit value for the die() operator.  (Mnemonic: What just
702 went bang?)
703
704 Also see L<Error Indicators>.
705
706 =item %!
707
708 Each element of C<%!> has a true value only if C<$!> is set to that
709 value.  For example, C<$!{ENOENT}> is true if and only if the current
710 value of C<$!> is C<ENOENT>; that is, if the most recent error was
711 "No such file or directory" (or its moral equivalent: not all operating
712 systems give that exact error, and certainly not all languages).
713 To check if a particular key is meaningful on your system, use
714 C<exists $!{the_key}>; for a list of legal keys, use C<keys %!>.
715 See L<Errno> for more information, and also see above for the
716 validity of C<$!>.
717
718 =item $EXTENDED_OS_ERROR
719
720 =item $^E
721
722 Error information specific to the current operating system.  At
723 the moment, this differs from C<$!> under only VMS, OS/2, and Win32
724 (and for MacPerl).  On all other platforms, C<$^E> is always just
725 the same as C<$!>.
726
727 Under VMS, C<$^E> provides the VMS status value from the last
728 system error.  This is more specific information about the last
729 system error than that provided by C<$!>.  This is particularly
730 important when C<$!> is set to B<EVMSERR>.
731
732 Under OS/2, C<$^E> is set to the error code of the last call to
733 OS/2 API either via CRT, or directly from perl.
734
735 Under Win32, C<$^E> always returns the last error information
736 reported by the Win32 call C<GetLastError()> which describes
737 the last error from within the Win32 API.  Most Win32-specific
738 code will report errors via C<$^E>.  ANSI C and Unix-like calls
739 set C<errno> and so most portable Perl code will report errors
740 via C<$!>. 
741
742 Caveats mentioned in the description of C<$!> generally apply to
743 C<$^E>, also.  (Mnemonic: Extra error explanation.)
744
745 Also see L<Error Indicators>.
746
747 =item $EVAL_ERROR
748
749 =item $@
750
751 The Perl syntax error message from the last eval() operator.
752 If $@ is the null string, the last eval() parsed and executed
753 correctly (although the operations you invoked may have failed in the
754 normal fashion).  (Mnemonic: Where was the syntax error "at"?)
755
756 Warning messages are not collected in this variable.  You can,
757 however, set up a routine to process warnings by setting C<$SIG{__WARN__}>
758 as described below.
759
760 Also see L<Error Indicators>.
761
762 =item $PROCESS_ID
763
764 =item $PID
765
766 =item $$
767
768 The process number of the Perl running this script.  You should
769 consider this variable read-only, although it will be altered
770 across fork() calls.  (Mnemonic: same as shells.)
771
772 Note for Linux users: on Linux, the C functions C<getpid()> and
773 C<getppid()> return different values from different threads. In order to
774 be portable, this behavior is not reflected by C<$$>, whose value remains
775 consistent across threads. If you want to call the underlying C<getpid()>,
776 you may use the CPAN module C<Linux::Pid>.
777
778 =item $REAL_USER_ID
779
780 =item $UID
781
782 =item $<
783
784 The real uid of this process.  (Mnemonic: it's the uid you came I<from>,
785 if you're running setuid.)  You can change both the real uid and
786 the effective uid at the same time by using POSIX::setuid().
787
788 =item $EFFECTIVE_USER_ID
789
790 =item $EUID
791
792 =item $>
793
794 The effective uid of this process.  Example:
795
796     $< = $>;            # set real to effective uid
797     ($<,$>) = ($>,$<);  # swap real and effective uid
798
799 You can change both the effective uid and the real uid at the same
800 time by using POSIX::setuid().
801
802 (Mnemonic: it's the uid you went I<to>, if you're running setuid.)
803 C<< $< >> and C<< $> >> can be swapped only on machines
804 supporting setreuid().
805
806 =item $REAL_GROUP_ID
807
808 =item $GID
809
810 =item $(
811
812 The real gid of this process.  If you are on a machine that supports
813 membership in multiple groups simultaneously, gives a space separated
814 list of groups you are in.  The first number is the one returned by
815 getgid(), and the subsequent ones by getgroups(), one of which may be
816 the same as the first number.
817
818 However, a value assigned to C<$(> must be a single number used to
819 set the real gid.  So the value given by C<$(> should I<not> be assigned
820 back to C<$(> without being forced numeric, such as by adding zero.
821
822 You can change both the real gid and the effective gid at the same
823 time by using POSIX::setgid().
824
825 (Mnemonic: parentheses are used to I<group> things.  The real gid is the
826 group you I<left>, if you're running setgid.)
827
828 =item $EFFECTIVE_GROUP_ID
829
830 =item $EGID
831
832 =item $)
833
834 The effective gid of this process.  If you are on a machine that
835 supports membership in multiple groups simultaneously, gives a space
836 separated list of groups you are in.  The first number is the one
837 returned by getegid(), and the subsequent ones by getgroups(), one of
838 which may be the same as the first number.
839
840 Similarly, a value assigned to C<$)> must also be a space-separated
841 list of numbers.  The first number sets the effective gid, and
842 the rest (if any) are passed to setgroups().  To get the effect of an
843 empty list for setgroups(), just repeat the new effective gid; that is,
844 to force an effective gid of 5 and an effectively empty setgroups()
845 list, say C< $) = "5 5" >.
846
847 You can change both the effective gid and the real gid at the same
848 time by using POSIX::setgid() (use only a single numeric argument).
849
850 (Mnemonic: parentheses are used to I<group> things.  The effective gid
851 is the group that's I<right> for you, if you're running setgid.)
852
853 C<< $< >>, C<< $> >>, C<$(> and C<$)> can be set only on
854 machines that support the corresponding I<set[re][ug]id()> routine.  C<$(>
855 and C<$)> can be swapped only on machines supporting setregid().
856
857 =item $PROGRAM_NAME
858
859 =item $0
860
861 Contains the name of the program being executed.  On some operating
862 systems assigning to C<$0> modifies the argument area that the B<ps>
863 program sees.  This is more useful as a way of indicating the current
864 program state than it is for hiding the program you're running.
865 (Mnemonic: same as B<sh> and B<ksh>.)
866
867 Note for BSD users: setting C<$0> does not completely remove "perl"
868 from the ps(1) output.  For example, setting C<$0> to C<"foobar"> will
869 result in C<"perl: foobar (perl)">.  This is an operating system
870 feature.
871
872 In multithreaded scripts Perl coordinates the threads so that any
873 thread may modify its copy of the C<$0> and the change becomes visible
874 to ps(1) (assuming the operating system plays along).
875
876 =item $[
877
878 The index of the first element in an array, and of the first character
879 in a substring.  Default is 0, but you could theoretically set it
880 to 1 to make Perl behave more like B<awk> (or Fortran) when
881 subscripting and when evaluating the index() and substr() functions.
882 (Mnemonic: [ begins subscripts.)
883
884 As of release 5 of Perl, assignment to C<$[> is treated as a compiler
885 directive, and cannot influence the behavior of any other file.
886 (That's why you can only assign compile-time constants to it.)
887 Its use is highly discouraged.
888
889 Note that, unlike other compile-time directives (such as L<strict>),
890 assignment to $[ can be seen from outer lexical scopes in the same file.
891 However, you can use local() on it to strictly bound its value to a
892 lexical block.
893
894 =item $]
895
896 The version + patchlevel / 1000 of the Perl interpreter.  This variable
897 can be used to determine whether the Perl interpreter executing a
898 script is in the right range of versions.  (Mnemonic: Is this version
899 of perl in the right bracket?)  Example:
900
901     warn "No checksumming!\n" if $] < 3.019;
902
903 See also the documentation of C<use VERSION> and C<require VERSION>
904 for a convenient way to fail if the running Perl interpreter is too old.
905
906 The floating point representation can sometimes lead to inaccurate
907 numeric comparisons.  See C<$^V> for a more modern representation of
908 the Perl version that allows accurate string comparisons.
909
910 =item $COMPILING
911
912 =item $^C
913
914 The current value of the flag associated with the B<-c> switch.
915 Mainly of use with B<-MO=...> to allow code to alter its behavior
916 when being compiled, such as for example to AUTOLOAD at compile
917 time rather than normal, deferred loading.  See L<perlcc>.  Setting
918 C<$^C = 1> is similar to calling C<B::minus_c>.
919
920 =item $DEBUGGING
921
922 =item $^D
923
924 The current value of the debugging flags.  (Mnemonic: value of B<-D>
925 switch.)
926
927 =item $SYSTEM_FD_MAX
928
929 =item $^F
930
931 The maximum system file descriptor, ordinarily 2.  System file
932 descriptors are passed to exec()ed processes, while higher file
933 descriptors are not.  Also, during an open(), system file descriptors are
934 preserved even if the open() fails.  (Ordinary file descriptors are
935 closed before the open() is attempted.)  The close-on-exec
936 status of a file descriptor will be decided according to the value of
937 C<$^F> when the corresponding file, pipe, or socket was opened, not the
938 time of the exec().
939
940 =item $^H
941
942 WARNING: This variable is strictly for internal use only.  Its availability,
943 behavior, and contents are subject to change without notice.
944
945 This variable contains compile-time hints for the Perl interpreter.  At the
946 end of compilation of a BLOCK the value of this variable is restored to the
947 value when the interpreter started to compile the BLOCK.
948
949 When perl begins to parse any block construct that provides a lexical scope
950 (e.g., eval body, required file, subroutine body, loop body, or conditional
951 block), the existing value of $^H is saved, but its value is left unchanged.
952 When the compilation of the block is completed, it regains the saved value.
953 Between the points where its value is saved and restored, code that
954 executes within BEGIN blocks is free to change the value of $^H.
955
956 This behavior provides the semantic of lexical scoping, and is used in,
957 for instance, the C<use strict> pragma.
958
959 The contents should be an integer; different bits of it are used for
960 different pragmatic flags.  Here's an example:
961
962     sub add_100 { $^H |= 0x100 }
963
964     sub foo {
965         BEGIN { add_100() }
966         bar->baz($boon);
967     }
968
969 Consider what happens during execution of the BEGIN block.  At this point
970 the BEGIN block has already been compiled, but the body of foo() is still
971 being compiled.  The new value of $^H will therefore be visible only while
972 the body of foo() is being compiled.
973
974 Substitution of the above BEGIN block with:
975
976     BEGIN { require strict; strict->import('vars') }
977
978 demonstrates how C<use strict 'vars'> is implemented.  Here's a conditional
979 version of the same lexical pragma:
980
981     BEGIN { require strict; strict->import('vars') if $condition }
982
983 =item %^H
984
985 WARNING: This variable is strictly for internal use only.  Its availability,
986 behavior, and contents are subject to change without notice.
987
988 The %^H hash provides the same scoping semantic as $^H.  This makes it
989 useful for implementation of lexically scoped pragmas.
990
991 =item $INPLACE_EDIT
992
993 =item $^I
994
995 The current value of the inplace-edit extension.  Use C<undef> to disable
996 inplace editing.  (Mnemonic: value of B<-i> switch.)
997
998 =item $^M
999
1000 By default, running out of memory is an untrappable, fatal error.
1001 However, if suitably built, Perl can use the contents of C<$^M>
1002 as an emergency memory pool after die()ing.  Suppose that your Perl
1003 were compiled with -DPERL_EMERGENCY_SBRK and used Perl's malloc.
1004 Then
1005
1006     $^M = 'a' x (1 << 16);
1007
1008 would allocate a 64K buffer for use in an emergency.  See the
1009 F<INSTALL> file in the Perl distribution for information on how to
1010 enable this option.  To discourage casual use of this advanced
1011 feature, there is no L<English|English> long name for this variable.
1012
1013 =item $OSNAME
1014
1015 =item $^O
1016
1017 The name of the operating system under which this copy of Perl was
1018 built, as determined during the configuration process.  The value
1019 is identical to C<$Config{'osname'}>.  See also L<Config> and the 
1020 B<-V> command-line switch documented in L<perlrun>.
1021
1022 In Windows platforms, $^O is not very helpful: since it is always
1023 C<MSWin32>, it doesn't tell the difference between
1024 95/98/ME/NT/2000/XP/CE/.NET.  Use Win32::GetOSName() or
1025 Win32::GetOSVersion() (see L<Win32> and L<perlport>) to distinguish
1026 between the variants.
1027
1028 =item ${^OPEN}
1029
1030 An internal variable used by PerlIO.  A string in two parts, separated
1031 by a C<\0> byte, the first part describes the input layers, the second
1032 part describes the output layers.
1033
1034 =item $PERLDB
1035
1036 =item $^P
1037
1038 The internal variable for debugging support.  The meanings of the
1039 various bits are subject to change, but currently indicate:
1040
1041 =over 6
1042
1043 =item 0x01
1044
1045 Debug subroutine enter/exit.
1046
1047 =item 0x02
1048
1049 Line-by-line debugging.
1050
1051 =item 0x04
1052
1053 Switch off optimizations.
1054
1055 =item 0x08
1056
1057 Preserve more data for future interactive inspections.
1058
1059 =item 0x10
1060
1061 Keep info about source lines on which a subroutine is defined.
1062
1063 =item 0x20
1064
1065 Start with single-step on.
1066
1067 =item 0x40
1068
1069 Use subroutine address instead of name when reporting.
1070
1071 =item 0x80
1072
1073 Report C<goto &subroutine> as well.
1074
1075 =item 0x100
1076
1077 Provide informative "file" names for evals based on the place they were compiled.
1078
1079 =item 0x200
1080
1081 Provide informative names to anonymous subroutines based on the place they
1082 were compiled.
1083
1084 =back
1085
1086 Some bits may be relevant at compile-time only, some at
1087 run-time only.  This is a new mechanism and the details may change.
1088
1089 =item $LAST_REGEXP_CODE_RESULT
1090
1091 =item $^R
1092
1093 The result of evaluation of the last successful C<(?{ code })>
1094 regular expression assertion (see L<perlre>).  May be written to.
1095
1096 =item $EXCEPTIONS_BEING_CAUGHT
1097
1098 =item $^S
1099
1100 Current state of the interpreter.
1101
1102     $^S         State
1103     ---------   -------------------
1104     undef       Parsing module/eval
1105     true (1)    Executing an eval
1106     false (0)   Otherwise
1107
1108 The first state may happen in $SIG{__DIE__} and $SIG{__WARN__} handlers.
1109
1110 =item $BASETIME
1111
1112 =item $^T
1113
1114 The time at which the program began running, in seconds since the
1115 epoch (beginning of 1970).  The values returned by the B<-M>, B<-A>,
1116 and B<-C> filetests are based on this value.
1117
1118 =item ${^TAINT}
1119
1120 Reflects if taint mode is on or off.  1 for on (the program was run with
1121 B<-T>), 0 for off, -1 when only taint warnings are enabled (i.e. with
1122 B<-t> or B<-TU>).  This variable is read-only.
1123
1124 =item ${^UNICODE}
1125
1126 Reflects certain Unicode settings of Perl.  See L<perlrun>
1127 documentation for the C<-C> switch for more information about
1128 the possible values. This variable is set during Perl startup
1129 and is thereafter read-only.
1130
1131 =item $PERL_VERSION
1132
1133 =item $^V
1134
1135 The revision, version, and subversion of the Perl interpreter, represented
1136 as a string composed of characters with those ordinals.  Thus in Perl v5.6.0
1137 it equals C<chr(5) . chr(6) . chr(0)> and will return true for
1138 C<$^V eq v5.6.0>.  Note that the characters in this string value can
1139 potentially be in Unicode range.
1140
1141 This can be used to determine whether the Perl interpreter executing a
1142 script is in the right range of versions.  (Mnemonic: use ^V for Version
1143 Control.)  Example:
1144
1145     warn "No \"our\" declarations!\n" if $^V and $^V lt v5.6.0;
1146
1147 To convert C<$^V> into its string representation use sprintf()'s
1148 C<"%vd"> conversion:
1149
1150     printf "version is v%vd\n", $^V;  # Perl's version
1151
1152 See the documentation of C<use VERSION> and C<require VERSION>
1153 for a convenient way to fail if the running Perl interpreter is too old.
1154
1155 See also C<$]> for an older representation of the Perl version.
1156
1157 =item $WARNING
1158
1159 =item $^W
1160
1161 The current value of the warning switch, initially true if B<-w>
1162 was used, false otherwise, but directly modifiable.  (Mnemonic:
1163 related to the B<-w> switch.)  See also L<warnings>.
1164
1165 =item ${^WARNING_BITS}
1166
1167 The current set of warning checks enabled by the C<use warnings> pragma.
1168 See the documentation of C<warnings> for more details.
1169
1170 =item $EXECUTABLE_NAME
1171
1172 =item $^X
1173
1174 The name used to execute the current copy of Perl, from C's
1175 C<argv[0]>.
1176
1177 Depending on the host operating system, the value of $^X may be
1178 a relative or absolute pathname of the perl program file, or may
1179 be the string used to invoke perl but not the pathname of the
1180 perl program file.  Also, most operating systems permit invoking
1181 programs that are not in the PATH environment variable, so there
1182 is no guarantee that the value of $^X is in PATH.  For VMS, the
1183 value may or may not include a version number.
1184
1185 You usually can use the value of $^X to re-invoke an independent
1186 copy of the same perl that is currently running, e.g.,
1187
1188   @first_run = `$^X -le "print int rand 100 for 1..100"`;
1189
1190 But recall that not all operating systems support forking or
1191 capturing of the output of commands, so this complex statement
1192 may not be portable.
1193
1194 It is not safe to use the value of $^X as a path name of a file,
1195 as some operating systems that have a mandatory suffix on
1196 executable files do not require use of the suffix when invoking
1197 a command.  To convert the value of $^X to a path name, use the
1198 following statements:
1199
1200 # Build up a set of file names (not command names).
1201   use Config;
1202   $this_perl = $^X;
1203   if ($^O ne 'VMS')
1204      {$this_perl .= $Config{_exe}
1205           unless $this_perl =~ m/$Config{_exe}$/i;}
1206
1207 Because many operating systems permit anyone with read access to
1208 the Perl program file to make a copy of it, patch the copy, and
1209 then execute the copy, the security-conscious Perl programmer
1210 should take care to invoke the installed copy of perl, not the
1211 copy referenced by $^X.  The following statements accomplish
1212 this goal, and produce a pathname that can be invoked as a
1213 command or referenced as a file.
1214
1215   use Config;
1216   $secure_perl_path = $Config{perlpath};
1217   if ($^O ne 'VMS')
1218      {$secure_perl_path .= $Config{_exe}
1219           unless $secure_perl_path =~ m/$Config{_exe}$/i;}
1220
1221 =item ARGV
1222
1223 The special filehandle that iterates over command-line filenames in
1224 C<@ARGV>. Usually written as the null filehandle in the angle operator
1225 C<< <> >>. Note that currently C<ARGV> only has its magical effect
1226 within the C<< <> >> operator; elsewhere it is just a plain filehandle
1227 corresponding to the last file opened by C<< <> >>. In particular,
1228 passing C<\*ARGV> as a parameter to a function that expects a filehandle
1229 may not cause your function to automatically read the contents of all the
1230 files in C<@ARGV>.
1231
1232 =item $ARGV
1233
1234 contains the name of the current file when reading from <>.
1235
1236 =item @ARGV
1237
1238 The array @ARGV contains the command-line arguments intended for
1239 the script.  C<$#ARGV> is generally the number of arguments minus
1240 one, because C<$ARGV[0]> is the first argument, I<not> the program's
1241 command name itself.  See C<$0> for the command name.
1242
1243 =item ARGVOUT
1244
1245 The special filehandle that points to the currently open output file
1246 when doing edit-in-place processing with B<-i>.  Useful when you have
1247 to do a lot of inserting and don't want to keep modifying $_.  See
1248 L<perlrun> for the B<-i> switch.
1249
1250 =item @F
1251
1252 The array @F contains the fields of each line read in when autosplit
1253 mode is turned on.  See L<perlrun> for the B<-a> switch.  This array
1254 is package-specific, and must be declared or given a full package name
1255 if not in package main when running under C<strict 'vars'>.
1256
1257 =item @INC
1258
1259 The array @INC contains the list of places that the C<do EXPR>,
1260 C<require>, or C<use> constructs look for their library files.  It
1261 initially consists of the arguments to any B<-I> command-line
1262 switches, followed by the default Perl library, probably
1263 F</usr/local/lib/perl>, followed by ".", to represent the current
1264 directory.  ("." will not be appended if taint checks are enabled, either by
1265 C<-T> or by C<-t>.)  If you need to modify this at runtime, you should use
1266 the C<use lib> pragma to get the machine-dependent library properly
1267 loaded also:
1268
1269     use lib '/mypath/libdir/';
1270     use SomeMod;
1271
1272 You can also insert hooks into the file inclusion system by putting Perl
1273 code directly into @INC.  Those hooks may be subroutine references, array
1274 references or blessed objects.  See L<perlfunc/require> for details.
1275
1276 =item @_
1277
1278 Within a subroutine the array @_ contains the parameters passed to that
1279 subroutine.  See L<perlsub>.
1280
1281 =item %INC
1282
1283 The hash %INC contains entries for each filename included via the
1284 C<do>, C<require>, or C<use> operators.  The key is the filename
1285 you specified (with module names converted to pathnames), and the
1286 value is the location of the file found.  The C<require>
1287 operator uses this hash to determine whether a particular file has
1288 already been included.
1289
1290 If the file was loaded via a hook (e.g. a subroutine reference, see
1291 L<perlfunc/require> for a description of these hooks), this hook is
1292 by default inserted into %INC in place of a filename.  Note, however,
1293 that the hook may have set the %INC entry by itself to provide some more
1294 specific info.
1295
1296 =item %ENV
1297
1298 =item $ENV{expr}
1299
1300 The hash %ENV contains your current environment.  Setting a
1301 value in C<ENV> changes the environment for any child processes
1302 you subsequently fork() off.
1303
1304 =item %SIG
1305
1306 =item $SIG{expr}
1307
1308 The hash %SIG contains signal handlers for signals.  For example:
1309
1310     sub handler {       # 1st argument is signal name
1311         my($sig) = @_;
1312         print "Caught a SIG$sig--shutting down\n";
1313         close(LOG);
1314         exit(0);
1315     }
1316
1317     $SIG{'INT'}  = \&handler;
1318     $SIG{'QUIT'} = \&handler;
1319     ...
1320     $SIG{'INT'}  = 'DEFAULT';   # restore default action
1321     $SIG{'QUIT'} = 'IGNORE';    # ignore SIGQUIT
1322
1323 Using a value of C<'IGNORE'> usually has the effect of ignoring the
1324 signal, except for the C<CHLD> signal.  See L<perlipc> for more about
1325 this special case.
1326
1327 Here are some other examples:
1328
1329     $SIG{"PIPE"} = "Plumber";   # assumes main::Plumber (not recommended)
1330     $SIG{"PIPE"} = \&Plumber;   # just fine; assume current Plumber
1331     $SIG{"PIPE"} = *Plumber;    # somewhat esoteric
1332     $SIG{"PIPE"} = Plumber();   # oops, what did Plumber() return??
1333
1334 Be sure not to use a bareword as the name of a signal handler,
1335 lest you inadvertently call it. 
1336
1337 If your system has the sigaction() function then signal handlers are
1338 installed using it.  This means you get reliable signal handling.  If
1339 your system has the SA_RESTART flag it is used when signals handlers are
1340 installed.  This means that system calls for which restarting is supported
1341 continue rather than returning when a signal arrives.  If you want your
1342 system calls to be interrupted by signal delivery then do something like
1343 this:
1344
1345     use POSIX ':signal_h';
1346
1347     my $alarm = 0;
1348     sigaction SIGALRM, new POSIX::SigAction sub { $alarm = 1 }
1349         or die "Error setting SIGALRM handler: $!\n";
1350
1351 See L<POSIX>.
1352
1353 The delivery policy of signals changed in Perl 5.8.0 from immediate
1354 (also known as "unsafe") to deferred, also known as "safe signals".
1355 See L<perlipc> for more information.
1356
1357 Certain internal hooks can be also set using the %SIG hash.  The
1358 routine indicated by C<$SIG{__WARN__}> is called when a warning message is
1359 about to be printed.  The warning message is passed as the first
1360 argument.  The presence of a __WARN__ hook causes the ordinary printing
1361 of warnings to STDERR to be suppressed.  You can use this to save warnings
1362 in a variable, or turn warnings into fatal errors, like this:
1363
1364     local $SIG{__WARN__} = sub { die $_[0] };
1365     eval $proggie;
1366
1367 The routine indicated by C<$SIG{__DIE__}> is called when a fatal exception
1368 is about to be thrown.  The error message is passed as the first
1369 argument.  When a __DIE__ hook routine returns, the exception
1370 processing continues as it would have in the absence of the hook,
1371 unless the hook routine itself exits via a C<goto>, a loop exit, or a die().
1372 The C<__DIE__> handler is explicitly disabled during the call, so that you
1373 can die from a C<__DIE__> handler.  Similarly for C<__WARN__>.
1374
1375 Due to an implementation glitch, the C<$SIG{__DIE__}> hook is called
1376 even inside an eval().  Do not use this to rewrite a pending exception
1377 in C<$@>, or as a bizarre substitute for overriding CORE::GLOBAL::die().
1378 This strange action at a distance may be fixed in a future release
1379 so that C<$SIG{__DIE__}> is only called if your program is about
1380 to exit, as was the original intent.  Any other use is deprecated.
1381
1382 C<__DIE__>/C<__WARN__> handlers are very special in one respect:
1383 they may be called to report (probable) errors found by the parser.
1384 In such a case the parser may be in inconsistent state, so any
1385 attempt to evaluate Perl code from such a handler will probably
1386 result in a segfault.  This means that warnings or errors that
1387 result from parsing Perl should be used with extreme caution, like
1388 this:
1389
1390     require Carp if defined $^S;
1391     Carp::confess("Something wrong") if defined &Carp::confess;
1392     die "Something wrong, but could not load Carp to give backtrace...
1393          To see backtrace try starting Perl with -MCarp switch";
1394
1395 Here the first line will load Carp I<unless> it is the parser who
1396 called the handler.  The second line will print backtrace and die if
1397 Carp was available.  The third line will be executed only if Carp was
1398 not available.
1399
1400 See L<perlfunc/die>, L<perlfunc/warn>, L<perlfunc/eval>, and
1401 L<warnings> for additional information.
1402
1403 =back
1404
1405 =head2 Error Indicators
1406
1407 The variables C<$@>, C<$!>, C<$^E>, and C<$?> contain information
1408 about different types of error conditions that may appear during
1409 execution of a Perl program.  The variables are shown ordered by
1410 the "distance" between the subsystem which reported the error and
1411 the Perl process.  They correspond to errors detected by the Perl
1412 interpreter, C library, operating system, or an external program,
1413 respectively.
1414
1415 To illustrate the differences between these variables, consider the 
1416 following Perl expression, which uses a single-quoted string:
1417
1418     eval q{
1419         open my $pipe, "/cdrom/install |" or die $!;
1420         my @res = <$pipe>;
1421         close $pipe or die "bad pipe: $?, $!";
1422     };
1423
1424 After execution of this statement all 4 variables may have been set.  
1425
1426 C<$@> is set if the string to be C<eval>-ed did not compile (this
1427 may happen if C<open> or C<close> were imported with bad prototypes),
1428 or if Perl code executed during evaluation die()d .  In these cases
1429 the value of $@ is the compile error, or the argument to C<die>
1430 (which will interpolate C<$!> and C<$?>!).  (See also L<Fatal>,
1431 though.)
1432
1433 When the eval() expression above is executed, open(), C<< <PIPE> >>,
1434 and C<close> are translated to calls in the C run-time library and
1435 thence to the operating system kernel.  C<$!> is set to the C library's
1436 C<errno> if one of these calls fails. 
1437
1438 Under a few operating systems, C<$^E> may contain a more verbose
1439 error indicator, such as in this case, "CDROM tray not closed."
1440 Systems that do not support extended error messages leave C<$^E>
1441 the same as C<$!>.
1442
1443 Finally, C<$?> may be set to non-0 value if the external program
1444 F</cdrom/install> fails.  The upper eight bits reflect specific
1445 error conditions encountered by the program (the program's exit()
1446 value).   The lower eight bits reflect mode of failure, like signal
1447 death and core dump information  See wait(2) for details.  In
1448 contrast to C<$!> and C<$^E>, which are set only if error condition
1449 is detected, the variable C<$?> is set on each C<wait> or pipe
1450 C<close>, overwriting the old value.  This is more like C<$@>, which
1451 on every eval() is always set on failure and cleared on success.
1452
1453 For more details, see the individual descriptions at C<$@>, C<$!>, C<$^E>,
1454 and C<$?>.
1455
1456 =head2 Technical Note on the Syntax of Variable Names
1457
1458 Variable names in Perl can have several formats.  Usually, they
1459 must begin with a letter or underscore, in which case they can be
1460 arbitrarily long (up to an internal limit of 251 characters) and
1461 may contain letters, digits, underscores, or the special sequence
1462 C<::> or C<'>.  In this case, the part before the last C<::> or
1463 C<'> is taken to be a I<package qualifier>; see L<perlmod>.
1464
1465 Perl variable names may also be a sequence of digits or a single
1466 punctuation or control character.  These names are all reserved for
1467 special uses by Perl; for example, the all-digits names are used
1468 to hold data captured by backreferences after a regular expression
1469 match.  Perl has a special syntax for the single-control-character
1470 names: It understands C<^X> (caret C<X>) to mean the control-C<X>
1471 character.  For example, the notation C<$^W> (dollar-sign caret
1472 C<W>) is the scalar variable whose name is the single character
1473 control-C<W>.  This is better than typing a literal control-C<W>
1474 into your program.
1475
1476 Finally, new in Perl 5.6, Perl variable names may be alphanumeric
1477 strings that begin with control characters (or better yet, a caret).
1478 These variables must be written in the form C<${^Foo}>; the braces
1479 are not optional.  C<${^Foo}> denotes the scalar variable whose
1480 name is a control-C<F> followed by two C<o>'s.  These variables are
1481 reserved for future special uses by Perl, except for the ones that
1482 begin with C<^_> (control-underscore or caret-underscore).  No
1483 control-character name that begins with C<^_> will acquire a special
1484 meaning in any future version of Perl; such names may therefore be
1485 used safely in programs.  C<$^_> itself, however, I<is> reserved.
1486
1487 Perl identifiers that begin with digits, control characters, or
1488 punctuation characters are exempt from the effects of the C<package>
1489 declaration and are always forced to be in package C<main>; they are
1490 also exempt from C<strict 'vars'> errors.  A few other names are also
1491 exempt in these ways:
1492
1493         ENV             STDIN
1494         INC             STDOUT
1495         ARGV            STDERR
1496         ARGVOUT         _
1497         SIG
1498
1499 In particular, the new special C<${^_XYZ}> variables are always taken
1500 to be in package C<main>, regardless of any C<package> declarations
1501 presently in scope.  
1502
1503 =head1 BUGS
1504
1505 Due to an unfortunate accident of Perl's implementation, C<use
1506 English> imposes a considerable performance penalty on all regular
1507 expression matches in a program, regardless of whether they occur
1508 in the scope of C<use English>.  For that reason, saying C<use
1509 English> in libraries is strongly discouraged.  See the
1510 Devel::SawAmpersand module documentation from CPAN
1511 ( http://www.cpan.org/modules/by-module/Devel/ )
1512 for more information.
1513
1514 Having to even think about the C<$^S> variable in your exception
1515 handlers is simply wrong.  C<$SIG{__DIE__}> as currently implemented
1516 invites grievous and difficult to track down errors.  Avoid it
1517 and use an C<END{}> or CORE::GLOBAL::die override instead.