Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlsec.pod
1 =head1 NAME
2
3 perlsec - Perl security
4
5 =head1 DESCRIPTION
6
7 Perl is designed to make it easy to program securely even when running
8 with extra privileges, like setuid or setgid programs.  Unlike most
9 command line shells, which are based on multiple substitution passes on
10 each line of the script, Perl uses a more conventional evaluation scheme
11 with fewer hidden snags.  Additionally, because the language has more
12 builtin functionality, it can rely less upon external (and possibly
13 untrustworthy) programs to accomplish its purposes.
14
15 Perl automatically enables a set of special security checks, called I<taint
16 mode>, when it detects its program running with differing real and effective
17 user or group IDs.  The setuid bit in Unix permissions is mode 04000, the
18 setgid bit mode 02000; either or both may be set.  You can also enable taint
19 mode explicitly by using the B<-T> command line flag. This flag is
20 I<strongly> suggested for server programs and any program run on behalf of
21 someone else, such as a CGI script. Once taint mode is on, it's on for
22 the remainder of your script.
23
24 While in this mode, Perl takes special precautions called I<taint
25 checks> to prevent both obvious and subtle traps.  Some of these checks
26 are reasonably simple, such as verifying that path directories aren't
27 writable by others; careful programmers have always used checks like
28 these.  Other checks, however, are best supported by the language itself,
29 and it is these checks especially that contribute to making a set-id Perl
30 program more secure than the corresponding C program.
31
32 You may not use data derived from outside your program to affect
33 something else outside your program--at least, not by accident.  All
34 command line arguments, environment variables, locale information (see
35 L<perllocale>), results of certain system calls (readdir(),
36 readlink(), the variable of shmread(), the messages returned by
37 msgrcv(), the password, gcos and shell fields returned by the
38 getpwxxx() calls), and all file input are marked as "tainted".
39 Tainted data may not be used directly or indirectly in any command
40 that invokes a sub-shell, nor in any command that modifies files,
41 directories, or processes, B<with the following exceptions>:
42
43 =over 4
44
45 =item *
46
47 Arguments to C<print> and C<syswrite> are B<not> checked for taintedness.
48
49 =item *
50
51 Symbolic methods
52
53     $obj->$method(@args);
54
55 and symbolic sub references
56
57     &{$foo}(@args);
58     $foo->(@args);
59
60 are not checked for taintedness.  This requires extra carefulness
61 unless you want external data to affect your control flow.  Unless
62 you carefully limit what these symbolic values are, people are able
63 to call functions B<outside> your Perl code, such as POSIX::system,
64 in which case they are able to run arbitrary external code.
65
66 =back
67
68 The value of an expression containing tainted data will itself be
69 tainted, even if it is logically impossible for the tainted data to
70 affect the value.
71
72 Because taintedness is associated with each scalar value, some
73 elements of an array can be tainted and others not.
74
75 For example:
76
77     $arg = shift;               # $arg is tainted
78     $hid = $arg, 'bar';         # $hid is also tainted
79     $line = <>;                 # Tainted
80     $line = <STDIN>;            # Also tainted
81     open FOO, "/home/me/bar" or die $!;
82     $line = <FOO>;              # Still tainted
83     $path = $ENV{'PATH'};       # Tainted, but see below
84     $data = 'abc';              # Not tainted
85
86     system "echo $arg";         # Insecure
87     system "/bin/echo", $arg;   # Considered insecure
88                                 # (Perl doesn't know about /bin/echo)
89     system "echo $hid";         # Insecure
90     system "echo $data";        # Insecure until PATH set
91
92     $path = $ENV{'PATH'};       # $path now tainted
93
94     $ENV{'PATH'} = '/bin:/usr/bin';
95     delete @ENV{'IFS', 'CDPATH', 'ENV', 'BASH_ENV'};
96
97     $path = $ENV{'PATH'};       # $path now NOT tainted
98     system "echo $data";        # Is secure now!
99
100     open(FOO, "< $arg");        # OK - read-only file
101     open(FOO, "> $arg");        # Not OK - trying to write
102
103     open(FOO,"echo $arg|");     # Not OK
104     open(FOO,"-|")
105         or exec 'echo', $arg;   # Also not OK
106
107     $shout = `echo $arg`;       # Insecure, $shout now tainted
108
109     unlink $data, $arg;         # Insecure
110     umask $arg;                 # Insecure
111
112     exec "echo $arg";           # Insecure
113     exec "echo", $arg;          # Insecure
114     exec "sh", '-c', $arg;      # Very insecure!
115
116     @files = <*.c>;             # insecure (uses readdir() or similar)
117     @files = glob('*.c');       # insecure (uses readdir() or similar)
118
119     # In Perl releases older than 5.6.0 the <*.c> and glob('*.c') would
120     # have used an external program to do the filename expansion; but in
121     # either case the result is tainted since the list of filenames comes
122     # from outside of the program.
123
124     $bad = ($arg, 23);          # $bad will be tainted
125     $arg, `true`;               # Insecure (although it isn't really)
126
127 If you try to do something insecure, you will get a fatal error saying
128 something like "Insecure dependency" or "Insecure $ENV{PATH}".
129
130 =head2 Laundering and Detecting Tainted Data
131
132 To test whether a variable contains tainted data, and whose use would
133 thus trigger an "Insecure dependency" message, you can use the
134 tainted() function of the Scalar::Util module, available in your
135 nearby CPAN mirror, and included in Perl starting from the release 5.8.0.
136 Or you may be able to use the following I<is_tainted()> function.
137
138     sub is_tainted {
139         return ! eval { eval("#" . substr(join("", @_), 0, 0)); 1 };
140     }
141
142 This function makes use of the fact that the presence of tainted data
143 anywhere within an expression renders the entire expression tainted.  It
144 would be inefficient for every operator to test every argument for
145 taintedness.  Instead, the slightly more efficient and conservative
146 approach is used that if any tainted value has been accessed within the
147 same expression, the whole expression is considered tainted.
148
149 But testing for taintedness gets you only so far.  Sometimes you have just
150 to clear your data's taintedness.  The only way to bypass the tainting
151 mechanism is by referencing subpatterns from a regular expression match.
152 Perl presumes that if you reference a substring using $1, $2, etc., that
153 you knew what you were doing when you wrote the pattern.  That means using
154 a bit of thought--don't just blindly untaint anything, or you defeat the
155 entire mechanism.  It's better to verify that the variable has only good
156 characters (for certain values of "good") rather than checking whether it
157 has any bad characters.  That's because it's far too easy to miss bad
158 characters that you never thought of.
159
160 Here's a test to make sure that the data contains nothing but "word"
161 characters (alphabetics, numerics, and underscores), a hyphen, an at sign,
162 or a dot.
163
164     if ($data =~ /^([-\@\w.]+)$/) {
165         $data = $1;                     # $data now untainted
166     } else {
167         die "Bad data in '$data'";      # log this somewhere
168     }
169
170 This is fairly secure because C</\w+/> doesn't normally match shell
171 metacharacters, nor are dot, dash, or at going to mean something special
172 to the shell.  Use of C</.+/> would have been insecure in theory because
173 it lets everything through, but Perl doesn't check for that.  The lesson
174 is that when untainting, you must be exceedingly careful with your patterns.
175 Laundering data using regular expression is the I<only> mechanism for
176 untainting dirty data, unless you use the strategy detailed below to fork
177 a child of lesser privilege.
178
179 The example does not untaint $data if C<use locale> is in effect,
180 because the characters matched by C<\w> are determined by the locale.
181 Perl considers that locale definitions are untrustworthy because they
182 contain data from outside the program.  If you are writing a
183 locale-aware program, and want to launder data with a regular expression
184 containing C<\w>, put C<no locale> ahead of the expression in the same
185 block.  See L<perllocale/SECURITY> for further discussion and examples.
186
187 =head2 Switches On the "#!" Line
188
189 When you make a script executable, in order to make it usable as a
190 command, the system will pass switches to perl from the script's #!
191 line.  Perl checks that any command line switches given to a setuid
192 (or setgid) script actually match the ones set on the #! line.  Some
193 Unix and Unix-like environments impose a one-switch limit on the #!
194 line, so you may need to use something like C<-wU> instead of C<-w -U>
195 under such systems.  (This issue should arise only in Unix or
196 Unix-like environments that support #! and setuid or setgid scripts.)
197
198 =head2 Cleaning Up Your Path
199
200 For "Insecure C<$ENV{PATH}>" messages, you need to set C<$ENV{'PATH'}> to a
201 known value, and each directory in the path must be non-writable by others
202 than its owner and group.  You may be surprised to get this message even
203 if the pathname to your executable is fully qualified.  This is I<not>
204 generated because you didn't supply a full path to the program; instead,
205 it's generated because you never set your PATH environment variable, or
206 you didn't set it to something that was safe.  Because Perl can't
207 guarantee that the executable in question isn't itself going to turn
208 around and execute some other program that is dependent on your PATH, it
209 makes sure you set the PATH.
210
211 The PATH isn't the only environment variable which can cause problems.
212 Because some shells may use the variables IFS, CDPATH, ENV, and
213 BASH_ENV, Perl checks that those are either empty or untainted when
214 starting subprocesses. You may wish to add something like this to your
215 setid and taint-checking scripts.
216
217     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};   # Make %ENV safer
218
219 It's also possible to get into trouble with other operations that don't
220 care whether they use tainted values.  Make judicious use of the file
221 tests in dealing with any user-supplied filenames.  When possible, do
222 opens and such B<after> properly dropping any special user (or group!)
223 privileges. Perl doesn't prevent you from opening tainted filenames for reading,
224 so be careful what you print out.  The tainting mechanism is intended to
225 prevent stupid mistakes, not to remove the need for thought.
226
227 Perl does not call the shell to expand wild cards when you pass B<system>
228 and B<exec> explicit parameter lists instead of strings with possible shell
229 wildcards in them.  Unfortunately, the B<open>, B<glob>, and
230 backtick functions provide no such alternate calling convention, so more
231 subterfuge will be required.
232
233 Perl provides a reasonably safe way to open a file or pipe from a setuid
234 or setgid program: just create a child process with reduced privilege who
235 does the dirty work for you.  First, fork a child using the special
236 B<open> syntax that connects the parent and child by a pipe.  Now the
237 child resets its ID set and any other per-process attributes, like
238 environment variables, umasks, current working directories, back to the
239 originals or known safe values.  Then the child process, which no longer
240 has any special permissions, does the B<open> or other system call.
241 Finally, the child passes the data it managed to access back to the
242 parent.  Because the file or pipe was opened in the child while running
243 under less privilege than the parent, it's not apt to be tricked into
244 doing something it shouldn't.
245
246 Here's a way to do backticks reasonably safely.  Notice how the B<exec> is
247 not called with a string that the shell could expand.  This is by far the
248 best way to call something that might be subjected to shell escapes: just
249 never call the shell at all.  
250
251         use English '-no_match_vars';
252         die "Can't fork: $!" unless defined($pid = open(KID, "-|"));
253         if ($pid) {           # parent
254             while (<KID>) {
255                 # do something
256             }
257             close KID;
258         } else {
259             my @temp     = ($EUID, $EGID);
260             my $orig_uid = $UID;
261             my $orig_gid = $GID;
262             $EUID = $UID;
263             $EGID = $GID;
264             # Drop privileges
265             $UID  = $orig_uid;
266             $GID  = $orig_gid;
267             # Make sure privs are really gone
268             ($EUID, $EGID) = @temp;
269             die "Can't drop privileges"
270                 unless $UID == $EUID  && $GID eq $EGID;
271             $ENV{PATH} = "/bin:/usr/bin"; # Minimal PATH.
272             # Consider sanitizing the environment even more.
273             exec 'myprog', 'arg1', 'arg2'
274                 or die "can't exec myprog: $!";
275         }
276
277 A similar strategy would work for wildcard expansion via C<glob>, although
278 you can use C<readdir> instead.
279
280 Taint checking is most useful when although you trust yourself not to have
281 written a program to give away the farm, you don't necessarily trust those
282 who end up using it not to try to trick it into doing something bad.  This
283 is the kind of security checking that's useful for set-id programs and
284 programs launched on someone else's behalf, like CGI programs.
285
286 This is quite different, however, from not even trusting the writer of the
287 code not to try to do something evil.  That's the kind of trust needed
288 when someone hands you a program you've never seen before and says, "Here,
289 run this."  For that kind of safety, check out the Safe module,
290 included standard in the Perl distribution.  This module allows the
291 programmer to set up special compartments in which all system operations
292 are trapped and namespace access is carefully controlled.
293
294 =head2 Security Bugs
295
296 Beyond the obvious problems that stem from giving special privileges to
297 systems as flexible as scripts, on many versions of Unix, set-id scripts
298 are inherently insecure right from the start.  The problem is a race
299 condition in the kernel.  Between the time the kernel opens the file to
300 see which interpreter to run and when the (now-set-id) interpreter turns
301 around and reopens the file to interpret it, the file in question may have
302 changed, especially if you have symbolic links on your system.
303
304 Fortunately, sometimes this kernel "feature" can be disabled.
305 Unfortunately, there are two ways to disable it.  The system can simply
306 outlaw scripts with any set-id bit set, which doesn't help much.
307 Alternately, it can simply ignore the set-id bits on scripts.  If the
308 latter is true, Perl can emulate the setuid and setgid mechanism when it
309 notices the otherwise useless setuid/gid bits on Perl scripts.  It does
310 this via a special executable called B<suidperl> that is automatically
311 invoked for you if it's needed.
312
313 However, if the kernel set-id script feature isn't disabled, Perl will
314 complain loudly that your set-id script is insecure.  You'll need to
315 either disable the kernel set-id script feature, or put a C wrapper around
316 the script.  A C wrapper is just a compiled program that does nothing
317 except call your Perl program.   Compiled programs are not subject to the
318 kernel bug that plagues set-id scripts.  Here's a simple wrapper, written
319 in C:
320
321     #define REAL_PATH "/path/to/script"
322     main(ac, av)
323         char **av;
324     {
325         execv(REAL_PATH, av);
326     }
327
328 Compile this wrapper into a binary executable and then make I<it> rather
329 than your script setuid or setgid.
330
331 In recent years, vendors have begun to supply systems free of this
332 inherent security bug.  On such systems, when the kernel passes the name
333 of the set-id script to open to the interpreter, rather than using a
334 pathname subject to meddling, it instead passes I</dev/fd/3>.  This is a
335 special file already opened on the script, so that there can be no race
336 condition for evil scripts to exploit.  On these systems, Perl should be
337 compiled with C<-DSETUID_SCRIPTS_ARE_SECURE_NOW>.  The B<Configure>
338 program that builds Perl tries to figure this out for itself, so you
339 should never have to specify this yourself.  Most modern releases of
340 SysVr4 and BSD 4.4 use this approach to avoid the kernel race condition.
341
342 Prior to release 5.6.1 of Perl, bugs in the code of B<suidperl> could
343 introduce a security hole.
344
345 =head2 Protecting Your Programs
346
347 There are a number of ways to hide the source to your Perl programs,
348 with varying levels of "security".
349
350 First of all, however, you I<can't> take away read permission, because
351 the source code has to be readable in order to be compiled and
352 interpreted.  (That doesn't mean that a CGI script's source is
353 readable by people on the web, though.)  So you have to leave the
354 permissions at the socially friendly 0755 level.  This lets 
355 people on your local system only see your source.
356
357 Some people mistakenly regard this as a security problem.  If your program does
358 insecure things, and relies on people not knowing how to exploit those
359 insecurities, it is not secure.  It is often possible for someone to
360 determine the insecure things and exploit them without viewing the
361 source.  Security through obscurity, the name for hiding your bugs
362 instead of fixing them, is little security indeed.
363
364 You can try using encryption via source filters (Filter::* from CPAN,
365 or Filter::Util::Call and Filter::Simple since Perl 5.8).
366 But crackers might be able to decrypt it.  You can try using the byte
367 code compiler and interpreter described below, but crackers might be
368 able to de-compile it.  You can try using the native-code compiler
369 described below, but crackers might be able to disassemble it.  These
370 pose varying degrees of difficulty to people wanting to get at your
371 code, but none can definitively conceal it (this is true of every
372 language, not just Perl).
373
374 If you're concerned about people profiting from your code, then the
375 bottom line is that nothing but a restrictive licence will give you
376 legal security.  License your software and pepper it with threatening
377 statements like "This is unpublished proprietary software of XYZ Corp.
378 Your access to it does not give you permission to use it blah blah
379 blah."  You should see a lawyer to be sure your licence's wording will
380 stand up in court.
381
382 =head2 Unicode
383
384 Unicode is a new and complex technology and one may easily overlook
385 certain security pitfalls.  See L<perluniintro> for an overview and
386 L<perlunicode> for details, and L<perlunicode/"Security Implications
387 of Unicode"> for security implications in particular.
388
389 =head1 SEE ALSO
390
391 L<perlrun> for its description of cleaning up environment variables.