Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlobj.pod
1 =head1 NAME
2
3 perlobj - Perl objects
4
5 =head1 DESCRIPTION
6
7 First you need to understand what references are in Perl.
8 See L<perlref> for that.  Second, if you still find the following
9 reference work too complicated, a tutorial on object-oriented programming
10 in Perl can be found in L<perltoot> and L<perltooc>.
11
12 If you're still with us, then
13 here are three very simple definitions that you should find reassuring.
14
15 =over 4
16
17 =item 1.
18
19 An object is simply a reference that happens to know which class it
20 belongs to.
21
22 =item 2.
23
24 A class is simply a package that happens to provide methods to deal
25 with object references.
26
27 =item 3.
28
29 A method is simply a subroutine that expects an object reference (or
30 a package name, for class methods) as the first argument.
31
32 =back
33
34 We'll cover these points now in more depth.
35
36 =head2 An Object is Simply a Reference
37
38 Unlike say C++, Perl doesn't provide any special syntax for
39 constructors.  A constructor is merely a subroutine that returns a
40 reference to something "blessed" into a class, generally the
41 class that the subroutine is defined in.  Here is a typical
42 constructor:
43
44     package Critter;
45     sub new { bless {} }
46
47 That word C<new> isn't special.  You could have written
48 a construct this way, too:
49
50     package Critter;
51     sub spawn { bless {} }
52
53 This might even be preferable, because the C++ programmers won't
54 be tricked into thinking that C<new> works in Perl as it does in C++.
55 It doesn't.  We recommend that you name your constructors whatever
56 makes sense in the context of the problem you're solving.  For example,
57 constructors in the Tk extension to Perl are named after the widgets
58 they create.
59
60 One thing that's different about Perl constructors compared with those in
61 C++ is that in Perl, they have to allocate their own memory.  (The other
62 things is that they don't automatically call overridden base-class
63 constructors.)  The C<{}> allocates an anonymous hash containing no
64 key/value pairs, and returns it  The bless() takes that reference and
65 tells the object it references that it's now a Critter, and returns
66 the reference.  This is for convenience, because the referenced object
67 itself knows that it has been blessed, and the reference to it could
68 have been returned directly, like this:
69
70     sub new {
71         my $self = {};
72         bless $self;
73         return $self;
74     }
75
76 You often see such a thing in more complicated constructors
77 that wish to call methods in the class as part of the construction:
78
79     sub new {
80         my $self = {};
81         bless $self;
82         $self->initialize();
83         return $self;
84     }
85
86 If you care about inheritance (and you should; see
87 L<perlmodlib/"Modules: Creation, Use, and Abuse">),
88 then you want to use the two-arg form of bless
89 so that your constructors may be inherited:
90
91     sub new {
92         my $class = shift;
93         my $self = {};
94         bless $self, $class;
95         $self->initialize();
96         return $self;
97     }
98
99 Or if you expect people to call not just C<< CLASS->new() >> but also
100 C<< $obj->new() >>, then use something like this.  The initialize()
101 method used will be of whatever $class we blessed the
102 object into:
103
104     sub new {
105         my $this = shift;
106         my $class = ref($this) || $this;
107         my $self = {};
108         bless $self, $class;
109         $self->initialize();
110         return $self;
111     }
112
113 Within the class package, the methods will typically deal with the
114 reference as an ordinary reference.  Outside the class package,
115 the reference is generally treated as an opaque value that may
116 be accessed only through the class's methods.
117
118 Although a constructor can in theory re-bless a referenced object
119 currently belonging to another class, this is almost certainly going
120 to get you into trouble.  The new class is responsible for all
121 cleanup later.  The previous blessing is forgotten, as an object
122 may belong to only one class at a time.  (Although of course it's
123 free to inherit methods from many classes.)  If you find yourself
124 having to do this, the parent class is probably misbehaving, though.
125
126 A clarification:  Perl objects are blessed.  References are not.  Objects
127 know which package they belong to.  References do not.  The bless()
128 function uses the reference to find the object.  Consider
129 the following example:
130
131     $a = {};
132     $b = $a;
133     bless $a, BLAH;
134     print "\$b is a ", ref($b), "\n";
135
136 This reports $b as being a BLAH, so obviously bless()
137 operated on the object and not on the reference.
138
139 =head2 A Class is Simply a Package
140
141 Unlike say C++, Perl doesn't provide any special syntax for class
142 definitions.  You use a package as a class by putting method
143 definitions into the class.
144
145 There is a special array within each package called @ISA, which says
146 where else to look for a method if you can't find it in the current
147 package.  This is how Perl implements inheritance.  Each element of the
148 @ISA array is just the name of another package that happens to be a
149 class package.  The classes are searched (depth first) for missing
150 methods in the order that they occur in @ISA.  The classes accessible
151 through @ISA are known as base classes of the current class.
152
153 All classes implicitly inherit from class C<UNIVERSAL> as their
154 last base class.  Several commonly used methods are automatically
155 supplied in the UNIVERSAL class; see L<"Default UNIVERSAL methods"> for
156 more details.
157
158 If a missing method is found in a base class, it is cached
159 in the current class for efficiency.  Changing @ISA or defining new
160 subroutines invalidates the cache and causes Perl to do the lookup again.
161
162 If neither the current class, its named base classes, nor the UNIVERSAL
163 class contains the requested method, these three places are searched
164 all over again, this time looking for a method named AUTOLOAD().  If an
165 AUTOLOAD is found, this method is called on behalf of the missing method,
166 setting the package global $AUTOLOAD to be the fully qualified name of
167 the method that was intended to be called.
168
169 If none of that works, Perl finally gives up and complains.
170
171 If you want to stop the AUTOLOAD inheritance say simply
172
173         sub AUTOLOAD;
174
175 and the call will die using the name of the sub being called.
176
177 Perl classes do method inheritance only.  Data inheritance is left up
178 to the class itself.  By and large, this is not a problem in Perl,
179 because most classes model the attributes of their object using an
180 anonymous hash, which serves as its own little namespace to be carved up
181 by the various classes that might want to do something with the object.
182 The only problem with this is that you can't sure that you aren't using
183 a piece of the hash that isn't already used.  A reasonable workaround
184 is to prepend your fieldname in the hash with the package name.
185
186     sub bump {
187         my $self = shift;
188         $self->{ __PACKAGE__ . ".count"}++;
189     } 
190
191 =head2 A Method is Simply a Subroutine
192
193 Unlike say C++, Perl doesn't provide any special syntax for method
194 definition.  (It does provide a little syntax for method invocation
195 though.  More on that later.)  A method expects its first argument
196 to be the object (reference) or package (string) it is being invoked
197 on.  There are two ways of calling methods, which we'll call class
198 methods and instance methods.  
199
200 A class method expects a class name as the first argument.  It
201 provides functionality for the class as a whole, not for any
202 individual object belonging to the class.  Constructors are often
203 class methods, but see L<perltoot> and L<perltooc> for alternatives.
204 Many class methods simply ignore their first argument, because they
205 already know what package they're in and don't care what package
206 they were invoked via.  (These aren't necessarily the same, because
207 class methods follow the inheritance tree just like ordinary instance
208 methods.)  Another typical use for class methods is to look up an
209 object by name:
210
211     sub find {
212         my ($class, $name) = @_;
213         $objtable{$name};
214     }
215
216 An instance method expects an object reference as its first argument.
217 Typically it shifts the first argument into a "self" or "this" variable,
218 and then uses that as an ordinary reference.
219
220     sub display {
221         my $self = shift;
222         my @keys = @_ ? @_ : sort keys %$self;
223         foreach $key (@keys) {
224             print "\t$key => $self->{$key}\n";
225         }
226     }
227
228 =head2 Method Invocation
229
230 For various historical and other reasons, Perl offers two equivalent
231 ways to write a method call.  The simpler and more common way is to use
232 the arrow notation:
233
234     my $fred = Critter->find("Fred");
235     $fred->display("Height", "Weight");
236
237 You should already be familiar with the use of the C<< -> >> operator with
238 references.  In fact, since C<$fred> above is a reference to an object,
239 you could think of the method call as just another form of
240 dereferencing.
241
242 Whatever is on the left side of the arrow, whether a reference or a
243 class name, is passed to the method subroutine as its first argument.
244 So the above code is mostly equivalent to:
245
246     my $fred = Critter::find("Critter", "Fred");
247     Critter::display($fred, "Height", "Weight");
248
249 How does Perl know which package the subroutine is in?  By looking at
250 the left side of the arrow, which must be either a package name or a
251 reference to an object, i.e. something that has been blessed to a
252 package.  Either way, that's the package where Perl starts looking.  If
253 that package has no subroutine with that name, Perl starts looking for
254 it in any base classes of that package, and so on.
255
256 If you need to, you I<can> force Perl to start looking in some other package:
257
258     my $barney = MyCritter->Critter::find("Barney");
259     $barney->Critter::display("Height", "Weight");
260
261 Here C<MyCritter> is presumably a subclass of C<Critter> that defines
262 its own versions of find() and display().  We haven't specified what
263 those methods do, but that doesn't matter above since we've forced Perl
264 to start looking for the subroutines in C<Critter>.
265
266 As a special case of the above, you may use the C<SUPER> pseudo-class to
267 tell Perl to start looking for the method in the packages named in the
268 current class's C<@ISA> list.  
269
270     package MyCritter;
271     use base 'Critter';    # sets @MyCritter::ISA = ('Critter');
272
273     sub display { 
274         my ($self, @args) = @_;
275         $self->SUPER::display("Name", @args);
276     }
277
278 Instead of a class name or an object reference, you can also use any
279 expression that returns either of those on the left side of the arrow.
280 So the following statement is valid:
281
282     Critter->find("Fred")->display("Height", "Weight");
283
284 and so is the following:
285
286     my $fred = (reverse "rettirC")->find(reverse "derF");
287
288 =head2 Indirect Object Syntax
289
290 The other way to invoke a method is by using the so-called "indirect
291 object" notation.  This syntax was available in Perl 4 long before
292 objects were introduced, and is still used with filehandles like this:
293
294    print STDERR "help!!!\n";
295
296 The same syntax can be used to call either object or class methods.
297
298    my $fred = find Critter "Fred";
299    display $fred "Height", "Weight";
300
301 Notice that there is no comma between the object or class name and the
302 parameters.  This is how Perl can tell you want an indirect method call
303 instead of an ordinary subroutine call.
304
305 But what if there are no arguments?  In that case, Perl must guess what
306 you want.  Even worse, it must make that guess I<at compile time>.
307 Usually Perl gets it right, but when it doesn't you get a function
308 call compiled as a method, or vice versa.  This can introduce subtle bugs
309 that are hard to detect.
310
311 For example, a call to a method C<new> in indirect notation -- as C++
312 programmers are wont to make -- can be miscompiled into a subroutine
313 call if there's already a C<new> function in scope.  You'd end up
314 calling the current package's C<new> as a subroutine, rather than the
315 desired class's method.  The compiler tries to cheat by remembering
316 bareword C<require>s, but the grief when it messes up just isn't worth the
317 years of debugging it will take you to track down such subtle bugs.
318
319 There is another problem with this syntax: the indirect object is
320 limited to a name, a scalar variable, or a block, because it would have
321 to do too much lookahead otherwise, just like any other postfix
322 dereference in the language.  (These are the same quirky rules as are
323 used for the filehandle slot in functions like C<print> and C<printf>.)
324 This can lead to horribly confusing precedence problems, as in these
325 next two lines:
326
327     move $obj->{FIELD};                 # probably wrong!
328     move $ary[$i];                      # probably wrong!
329
330 Those actually parse as the very surprising:
331
332     $obj->move->{FIELD};                # Well, lookee here
333     $ary->move([$i]);                   # Didn't expect this one, eh?
334
335 Rather than what you might have expected:
336
337     $obj->{FIELD}->move();              # You should be so lucky.
338     $ary[$i]->move;                     # Yeah, sure.
339
340 To get the correct behavior with indirect object syntax, you would have
341 to use a block around the indirect object:
342
343     move {$obj->{FIELD}};
344     move {$ary[$i]};
345
346 Even then, you still have the same potential problem if there happens to
347 be a function named C<move> in the current package.  B<The C<< -> >>
348 notation suffers from neither of these disturbing ambiguities, so we
349 recommend you use it exclusively.>  However, you may still end up having
350 to read code using the indirect object notation, so it's important to be
351 familiar with it.
352
353 =head2 Default UNIVERSAL methods
354
355 The C<UNIVERSAL> package automatically contains the following methods that
356 are inherited by all other classes:
357
358 =over 4
359
360 =item isa(CLASS)
361
362 C<isa> returns I<true> if its object is blessed into a subclass of C<CLASS>
363
364 You can also call C<UNIVERSAL::isa> as a subroutine with two arguments.
365 The first does not need to be an object or even a reference.  This
366 allows you to check what a reference points to, or whether
367 something is a reference of a given type. Example
368
369     if(UNIVERSAL::isa($ref, 'ARRAY')) {
370         #...
371     }
372
373 To determine if a reference is a blessed object, you can write
374
375     print "It's an object\n" if UNIVERSAL::isa($val, 'UNIVERSAL');
376
377 =item can(METHOD)
378
379 C<can> checks to see if its object has a method called C<METHOD>,
380 if it does then a reference to the sub is returned, if it does not then
381 I<undef> is returned.
382
383 C<UNIVERSAL::can> can also be called as a subroutine with two arguments.
384 It'll always return I<undef> if its first argument isn't an object or a
385 class name.    So here's another way to check if a reference is a
386 blessed object
387
388     print "It's still an object\n" if UNIVERSAL::can($val, 'can');
389
390 You can also use the C<blessed> function of Scalar::Util:
391
392     use Scalar::Util 'blessed';
393
394     my $blessing = blessed $suspected_object;
395
396 C<blessed> returns the name of the package the argument has been
397 blessed into, or C<undef>.
398
399 =item VERSION( [NEED] )
400
401 C<VERSION> returns the version number of the class (package).  If the
402 NEED argument is given then it will check that the current version (as
403 defined by the $VERSION variable in the given package) not less than
404 NEED; it will die if this is not the case.  This method is normally
405 called as a class method.  This method is called automatically by the
406 C<VERSION> form of C<use>.
407
408     use A 1.2 qw(some imported subs);
409     # implies:
410     A->VERSION(1.2);
411
412 =back
413
414 B<NOTE:> C<can> directly uses Perl's internal code for method lookup, and
415 C<isa> uses a very similar method and cache-ing strategy. This may cause
416 strange effects if the Perl code dynamically changes @ISA in any package.
417
418 You may add other methods to the UNIVERSAL class via Perl or XS code.
419 You do not need to C<use UNIVERSAL> to make these methods
420 available to your program (and you should not do so).
421
422 =head2 Destructors
423
424 When the last reference to an object goes away, the object is
425 automatically destroyed.  (This may even be after you exit, if you've
426 stored references in global variables.)  If you want to capture control
427 just before the object is freed, you may define a DESTROY method in
428 your class.  It will automatically be called at the appropriate moment,
429 and you can do any extra cleanup you need to do.  Perl passes a reference
430 to the object under destruction as the first (and only) argument.  Beware
431 that the reference is a read-only value, and cannot be modified by
432 manipulating C<$_[0]> within the destructor.  The object itself (i.e.
433 the thingy the reference points to, namely C<${$_[0]}>, C<@{$_[0]}>, 
434 C<%{$_[0]}> etc.) is not similarly constrained.
435
436 If you arrange to re-bless the reference before the destructor returns,
437 perl will again call the DESTROY method for the re-blessed object after
438 the current one returns.  This can be used for clean delegation of
439 object destruction, or for ensuring that destructors in the base classes
440 of your choosing get called.  Explicitly calling DESTROY is also possible,
441 but is usually never needed.
442
443 Do not confuse the previous discussion with how objects I<CONTAINED> in the current
444 one are destroyed.  Such objects will be freed and destroyed automatically
445 when the current object is freed, provided no other references to them exist
446 elsewhere.
447
448 =head2 Summary
449
450 That's about all there is to it.  Now you need just to go off and buy a
451 book about object-oriented design methodology, and bang your forehead
452 with it for the next six months or so.
453
454 =head2 Two-Phased Garbage Collection
455
456 For most purposes, Perl uses a fast and simple, reference-based
457 garbage collection system.  That means there's an extra
458 dereference going on at some level, so if you haven't built
459 your Perl executable using your C compiler's C<-O> flag, performance
460 will suffer.  If you I<have> built Perl with C<cc -O>, then this
461 probably won't matter.
462
463 A more serious concern is that unreachable memory with a non-zero
464 reference count will not normally get freed.  Therefore, this is a bad
465 idea:
466
467     {
468         my $a;
469         $a = \$a;
470     }
471
472 Even thought $a I<should> go away, it can't.  When building recursive data
473 structures, you'll have to break the self-reference yourself explicitly
474 if you don't care to leak.  For example, here's a self-referential
475 node such as one might use in a sophisticated tree structure:
476
477     sub new_node {
478         my $self = shift;
479         my $class = ref($self) || $self;
480         my $node = {};
481         $node->{LEFT} = $node->{RIGHT} = $node;
482         $node->{DATA} = [ @_ ];
483         return bless $node => $class;
484     }
485
486 If you create nodes like that, they (currently) won't go away unless you
487 break their self reference yourself.  (In other words, this is not to be
488 construed as a feature, and you shouldn't depend on it.)
489
490 Almost.
491
492 When an interpreter thread finally shuts down (usually when your program
493 exits), then a rather costly but complete mark-and-sweep style of garbage
494 collection is performed, and everything allocated by that thread gets
495 destroyed.  This is essential to support Perl as an embedded or a
496 multithreadable language.  For example, this program demonstrates Perl's
497 two-phased garbage collection:
498
499     #!/usr/bin/perl
500     package Subtle;
501
502     sub new {
503         my $test;
504         $test = \$test;
505         warn "CREATING " . \$test;
506         return bless \$test;
507     }
508
509     sub DESTROY {
510         my $self = shift;
511         warn "DESTROYING $self";
512     }
513
514     package main;
515
516     warn "starting program";
517     {
518         my $a = Subtle->new;
519         my $b = Subtle->new;
520         $$a = 0;  # break selfref
521         warn "leaving block";
522     }
523
524     warn "just exited block";
525     warn "time to die...";
526     exit;
527
528 When run as F</tmp/test>, the following output is produced:
529
530     starting program at /tmp/test line 18.
531     CREATING SCALAR(0x8e5b8) at /tmp/test line 7.
532     CREATING SCALAR(0x8e57c) at /tmp/test line 7.
533     leaving block at /tmp/test line 23.
534     DESTROYING Subtle=SCALAR(0x8e5b8) at /tmp/test line 13.
535     just exited block at /tmp/test line 26.
536     time to die... at /tmp/test line 27.
537     DESTROYING Subtle=SCALAR(0x8e57c) during global destruction.
538
539 Notice that "global destruction" bit there?  That's the thread
540 garbage collector reaching the unreachable.
541
542 Objects are always destructed, even when regular refs aren't.  Objects
543 are destructed in a separate pass before ordinary refs just to 
544 prevent object destructors from using refs that have been themselves
545 destructed.  Plain refs are only garbage-collected if the destruct level
546 is greater than 0.  You can test the higher levels of global destruction
547 by setting the PERL_DESTRUCT_LEVEL environment variable, presuming
548 C<-DDEBUGGING> was enabled during perl build time.
549 See L<perlhack/PERL_DESTRUCT_LEVEL> for more information.
550
551 A more complete garbage collection strategy will be implemented
552 at a future date.
553
554 In the meantime, the best solution is to create a non-recursive container
555 class that holds a pointer to the self-referential data structure.
556 Define a DESTROY method for the containing object's class that manually
557 breaks the circularities in the self-referential structure.
558
559 =head1 SEE ALSO
560
561 A kinder, gentler tutorial on object-oriented programming in Perl can
562 be found in L<perltoot>, L<perlboot> and L<perltooc>.  You should
563 also check out L<perlbot> for other object tricks, traps, and tips, as
564 well as L<perlmodlib> for some style guides on constructing both
565 modules and classes.