Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlfaq9.pod
1 =head1 NAME
2
3 perlfaq9 - Networking ($Revision: 1.15 $, $Date: 2003/01/31 17:36:57 $)
4
5 =head1 DESCRIPTION
6
7 This section deals with questions related to networking, the internet,
8 and a few on the web.
9
10 =head2 What is the correct form of response from a CGI script?
11
12 (Alan Flavell <flavell+www@a5.ph.gla.ac.uk> answers...)
13
14 The Common Gateway Interface (CGI) specifies a software interface between
15 a program ("CGI script") and a web server (HTTPD). It is not specific
16 to Perl, and has its own FAQs and tutorials, and usenet group,
17 comp.infosystems.www.authoring.cgi
18
19 The original CGI specification is at: http://hoohoo.ncsa.uiuc.edu/cgi/
20
21 Current best-practice RFC draft at: http://CGI-Spec.Golux.Com/
22
23 Other relevant documentation listed in: http://www.perl.org/CGI_MetaFAQ.html
24
25 These Perl FAQs very selectively cover some CGI issues. However, Perl
26 programmers are strongly advised to use the CGI.pm module, to take care
27 of the details for them.
28
29 The similarity between CGI response headers (defined in the CGI
30 specification) and HTTP response headers (defined in the HTTP
31 specification, RFC2616) is intentional, but can sometimes be confusing.
32
33 The CGI specification defines two kinds of script: the "Parsed Header"
34 script, and the "Non Parsed Header" (NPH) script. Check your server
35 documentation to see what it supports. "Parsed Header" scripts are
36 simpler in various respects. The CGI specification allows any of the
37 usual newline representations in the CGI response (it's the server's
38 job to create an accurate HTTP response based on it). So "\n" written in
39 text mode is technically correct, and recommended. NPH scripts are more
40 tricky: they must put out a complete and accurate set of HTTP
41 transaction response headers; the HTTP specification calls for records
42 to be terminated with carriage-return and line-feed, i.e ASCII \015\012
43 written in binary mode.
44
45 Using CGI.pm gives excellent platform independence, including EBCDIC
46 systems. CGI.pm selects an appropriate newline representation
47 ($CGI::CRLF) and sets binmode as appropriate.
48
49 =head2 My CGI script runs from the command line but not the browser.  (500 Server Error)
50
51 Several things could be wrong.  You can go through the "Troubleshooting
52 Perl CGI scripts" guide at
53
54         http://www.perl.org/troubleshooting_CGI.html
55
56 If, after that, you can demonstrate that you've read the FAQs and that
57 your problem isn't something simple that can be easily answered, you'll
58 probably receive a courteous and useful reply to your question if you
59 post it on comp.infosystems.www.authoring.cgi (if it's something to do
60 with HTTP or the CGI protocols).  Questions that appear to be Perl
61 questions but are really CGI ones that are posted to comp.lang.perl.misc
62 are not so well received.
63
64 The useful FAQs, related documents, and troubleshooting guides are
65 listed in the CGI Meta FAQ:
66
67         http://www.perl.org/CGI_MetaFAQ.html
68
69
70 =head2 How can I get better error messages from a CGI program?
71
72 Use the CGI::Carp module.  It replaces C<warn> and C<die>, plus the
73 normal Carp modules C<carp>, C<croak>, and C<confess> functions with
74 more verbose and safer versions.  It still sends them to the normal
75 server error log.
76
77     use CGI::Carp;
78     warn "This is a complaint";
79     die "But this one is serious";
80
81 The following use of CGI::Carp also redirects errors to a file of your choice,
82 placed in a BEGIN block to catch compile-time warnings as well:
83
84     BEGIN {
85         use CGI::Carp qw(carpout);
86         open(LOG, ">>/var/local/cgi-logs/mycgi-log")
87             or die "Unable to append to mycgi-log: $!\n";
88         carpout(*LOG);
89     }
90
91 You can even arrange for fatal errors to go back to the client browser,
92 which is nice for your own debugging, but might confuse the end user.
93
94     use CGI::Carp qw(fatalsToBrowser);
95     die "Bad error here";
96
97 Even if the error happens before you get the HTTP header out, the module
98 will try to take care of this to avoid the dreaded server 500 errors.
99 Normal warnings still go out to the server error log (or wherever
100 you've sent them with C<carpout>) with the application name and date
101 stamp prepended.
102
103 =head2 How do I remove HTML from a string?
104
105 The most correct way (albeit not the fastest) is to use HTML::Parser
106 from CPAN.  Another mostly correct
107 way is to use HTML::FormatText which not only removes HTML but also
108 attempts to do a little simple formatting of the resulting plain text.
109
110 Many folks attempt a simple-minded regular expression approach, like
111 C<< s/<.*?>//g >>, but that fails in many cases because the tags
112 may continue over line breaks, they may contain quoted angle-brackets,
113 or HTML comment may be present.  Plus, folks forget to convert
114 entities--like C<&lt;> for example.
115
116 Here's one "simple-minded" approach, that works for most files:
117
118     #!/usr/bin/perl -p0777
119     s/<(?:[^>'"]*|(['"]).*?\1)*>//gs
120
121 If you want a more complete solution, see the 3-stage striphtml
122 program in
123 http://www.cpan.org/authors/Tom_Christiansen/scripts/striphtml.gz
124 .
125
126 Here are some tricky cases that you should think about when picking
127 a solution:
128
129     <IMG SRC = "foo.gif" ALT = "A > B">
130
131     <IMG SRC = "foo.gif"
132          ALT = "A > B">
133
134     <!-- <A comment> -->
135
136     <script>if (a<b && a>c)</script>
137
138     <# Just data #>
139
140     <![INCLUDE CDATA [ >>>>>>>>>>>> ]]>
141
142 If HTML comments include other tags, those solutions would also break
143 on text like this:
144
145     <!-- This section commented out.
146         <B>You can't see me!</B>
147     -->
148
149 =head2 How do I extract URLs?
150
151 You can easily extract all sorts of URLs from HTML with
152 C<HTML::SimpleLinkExtor> which handles anchors, images, objects,
153 frames, and many other tags that can contain a URL.  If you need
154 anything more complex, you can create your own subclass of
155 C<HTML::LinkExtor> or C<HTML::Parser>.  You might even use
156 C<HTML::SimpleLinkExtor> as an example for something specifically
157 suited to your needs.
158
159 You can use URI::Find to extract URLs from an arbitrary text document.
160
161 Less complete solutions involving regular expressions can save
162 you a lot of processing time if you know that the input is simple.  One
163 solution from Tom Christiansen runs 100 times faster than most
164 module based approaches but only extracts URLs from anchors where the first
165 attribute is HREF and there are no other attributes.
166
167         #!/usr/bin/perl -n00
168         # qxurl - tchrist@perl.com
169         print "$2\n" while m{
170             < \s*
171               A \s+ HREF \s* = \s* (["']) (.*?) \1
172             \s* >
173         }gsix;
174
175
176 =head2 How do I download a file from the user's machine?  How do I open a file on another machine?
177
178 In this case, download means to use the file upload feature of HTML
179 forms.  You allow the web surfer to specify a file to send to your web
180 server.  To you it looks like a download, and to the user it looks
181 like an upload.  No matter what you call it, you do it with what's
182 known as B<multipart/form-data> encoding.  The CGI.pm module (which
183 comes with Perl as part of the Standard Library) supports this in the
184 start_multipart_form() method, which isn't the same as the startform()
185 method.
186
187 See the section in the CGI.pm documentation on file uploads for code
188 examples and details.
189
190 =head2 How do I make a pop-up menu in HTML?
191
192 Use the B<< <SELECT> >> and B<< <OPTION> >> tags.  The CGI.pm
193 module (available from CPAN) supports this widget, as well as many
194 others, including some that it cleverly synthesizes on its own.
195
196 =head2 How do I fetch an HTML file?
197
198 One approach, if you have the lynx text-based HTML browser installed
199 on your system, is this:
200
201     $html_code = `lynx -source $url`;
202     $text_data = `lynx -dump $url`;
203
204 The libwww-perl (LWP) modules from CPAN provide a more powerful way
205 to do this.  They don't require lynx, but like lynx, can still work
206 through proxies:
207
208     # simplest version
209     use LWP::Simple;
210     $content = get($URL);
211
212     # or print HTML from a URL
213     use LWP::Simple;
214     getprint "http://www.linpro.no/lwp/";
215
216     # or print ASCII from HTML from a URL
217     # also need HTML-Tree package from CPAN
218     use LWP::Simple;
219     use HTML::Parser;
220     use HTML::FormatText;
221     my ($html, $ascii);
222     $html = get("http://www.perl.com/");
223     defined $html
224         or die "Can't fetch HTML from http://www.perl.com/";
225     $ascii = HTML::FormatText->new->format(parse_html($html));
226     print $ascii;
227
228 =head2 How do I automate an HTML form submission?
229
230 If you're submitting values using the GET method, create a URL and encode
231 the form using the C<query_form> method:
232
233     use LWP::Simple;
234     use URI::URL;
235
236     my $url = url('http://www.perl.com/cgi-bin/cpan_mod');
237     $url->query_form(module => 'DB_File', readme => 1);
238     $content = get($url);
239
240 If you're using the POST method, create your own user agent and encode
241 the content appropriately.
242
243     use HTTP::Request::Common qw(POST);
244     use LWP::UserAgent;
245
246     $ua = LWP::UserAgent->new();
247     my $req = POST 'http://www.perl.com/cgi-bin/cpan_mod',
248                    [ module => 'DB_File', readme => 1 ];
249     $content = $ua->request($req)->as_string;
250
251 =head2 How do I decode or create those %-encodings on the web?
252
253
254 If you are writing a CGI script, you should be using the CGI.pm module
255 that comes with perl, or some other equivalent module.  The CGI module
256 automatically decodes queries for you, and provides an escape()
257 function to handle encoding.
258
259
260 The best source of detailed information on URI encoding is RFC 2396.
261 Basically, the following substitutions do it:
262
263     s/([^\w()'*~!.-])/sprintf '%%%02x', ord $1/eg;   # encode
264
265     s/%([A-Fa-f\d]{2})/chr hex $1/eg;            # decode
266
267 However, you should only apply them to individual URI components, not
268 the entire URI, otherwise you'll lose information and generally mess
269 things up.  If that didn't explain it, don't worry.  Just go read
270 section 2 of the RFC, it's probably the best explanation there is.
271
272 RFC 2396 also contains a lot of other useful information, including a
273 regexp for breaking any arbitrary URI into components (Appendix B).
274
275 =head2 How do I redirect to another page?
276
277 Specify the complete URL of the destination (even if it is on the same
278 server). This is one of the two different kinds of CGI "Location:"
279 responses which are defined in the CGI specification for a Parsed Headers
280 script. The other kind (an absolute URLpath) is resolved internally to
281 the server without any HTTP redirection. The CGI specifications do not
282 allow relative URLs in either case.
283
284 Use of CGI.pm is strongly recommended.  This example shows redirection
285 with a complete URL. This redirection is handled by the web browser.
286
287       use CGI qw/:standard/;
288
289       my $url = 'http://www.cpan.org/';
290       print redirect($url);
291
292
293 This example shows a redirection with an absolute URLpath.  This
294 redirection is handled by the local web server.
295
296       my $url = '/CPAN/index.html';
297       print redirect($url);
298
299
300 But if coded directly, it could be as follows (the final "\n" is
301 shown separately, for clarity), using either a complete URL or
302 an absolute URLpath.
303
304       print "Location: $url\n";   # CGI response header
305       print "\n";                 # end of headers
306
307
308 =head2 How do I put a password on my web pages?
309
310 To enable authentication for your web server, you need to configure
311 your web server.  The configuration is different for different sorts
312 of web servers---apache does it differently from iPlanet which does
313 it differently from IIS.  Check your web server documentation for
314 the details for your particular server.
315
316 =head2 How do I edit my .htpasswd and .htgroup files with Perl?
317
318 The HTTPD::UserAdmin and HTTPD::GroupAdmin modules provide a
319 consistent OO interface to these files, regardless of how they're
320 stored.  Databases may be text, dbm, Berkeley DB or any database with
321 a DBI compatible driver.  HTTPD::UserAdmin supports files used by the
322 `Basic' and `Digest' authentication schemes.  Here's an example:
323
324     use HTTPD::UserAdmin ();
325     HTTPD::UserAdmin
326           ->new(DB => "/foo/.htpasswd")
327           ->add($username => $password);
328
329 =head2 How do I make sure users can't enter values into a form that cause my CGI script to do bad things?
330
331 See the security references listed in the CGI Meta FAQ
332
333         http://www.perl.org/CGI_MetaFAQ.html
334
335 =head2 How do I parse a mail header?
336
337 For a quick-and-dirty solution, try this solution derived
338 from L<perlfunc/split>:
339
340     $/ = '';
341     $header = <MSG>;
342     $header =~ s/\n\s+/ /g;      # merge continuation lines
343     %head = ( UNIX_FROM_LINE, split /^([-\w]+):\s*/m, $header );
344
345 That solution doesn't do well if, for example, you're trying to
346 maintain all the Received lines.  A more complete approach is to use
347 the Mail::Header module from CPAN (part of the MailTools package).
348
349 =head2 How do I decode a CGI form?
350
351 You use a standard module, probably CGI.pm.  Under no circumstances
352 should you attempt to do so by hand!
353
354 You'll see a lot of CGI programs that blindly read from STDIN the number
355 of bytes equal to CONTENT_LENGTH for POSTs, or grab QUERY_STRING for
356 decoding GETs.  These programs are very poorly written.  They only work
357 sometimes.  They typically forget to check the return value of the read()
358 system call, which is a cardinal sin.  They don't handle HEAD requests.
359 They don't handle multipart forms used for file uploads.  They don't deal
360 with GET/POST combinations where query fields are in more than one place.
361 They don't deal with keywords in the query string.
362
363 In short, they're bad hacks.  Resist them at all costs.  Please do not be
364 tempted to reinvent the wheel.  Instead, use the CGI.pm or CGI_Lite.pm
365 (available from CPAN), or if you're trapped in the module-free land
366 of perl1 .. perl4, you might look into cgi-lib.pl (available from
367 http://cgi-lib.stanford.edu/cgi-lib/ ).
368
369 Make sure you know whether to use a GET or a POST in your form.
370 GETs should only be used for something that doesn't update the server.
371 Otherwise you can get mangled databases and repeated feedback mail
372 messages.  The fancy word for this is ``idempotency''.  This simply
373 means that there should be no difference between making a GET request
374 for a particular URL once or multiple times.  This is because the
375 HTTP protocol definition says that a GET request may be cached by the
376 browser, or server, or an intervening proxy.  POST requests cannot be
377 cached, because each request is independent and matters.  Typically,
378 POST requests change or depend on state on the server (query or update
379 a database, send mail, or purchase a computer).
380
381 =head2 How do I check a valid mail address?
382
383 You can't, at least, not in real time.  Bummer, eh?
384
385 Without sending mail to the address and seeing whether there's a human
386 on the other hand to answer you, you cannot determine whether a mail
387 address is valid.  Even if you apply the mail header standard, you
388 can have problems, because there are deliverable addresses that aren't
389 RFC-822 (the mail header standard) compliant, and addresses that aren't
390 deliverable which are compliant.
391
392 You can use the Email::Valid or RFC::RFC822::Address which check
393 the format of the address, although they cannot actually tell you
394 if it is a deliverable address (i.e. that mail to the address
395 will not bounce).  Modules like Mail::CheckUser and Mail::EXPN
396 try to interact with the domain name system or particular
397 mail servers to learn even more, but their methods do not
398 work everywhere---especially for security conscious administrators.
399
400 Many are tempted to try to eliminate many frequently-invalid
401 mail addresses with a simple regex, such as
402 C</^[\w.-]+\@(?:[\w-]+\.)+\w+$/>.  It's a very bad idea.  However,
403 this also throws out many valid ones, and says nothing about
404 potential deliverability, so it is not suggested.  Instead, see
405 http://www.cpan.org/authors/Tom_Christiansen/scripts/ckaddr.gz ,
406 which actually checks against the full RFC spec (except for nested
407 comments), looks for addresses you may not wish to accept mail to
408 (say, Bill Clinton or your postmaster), and then makes sure that the
409 hostname given can be looked up in the DNS MX records.  It's not fast,
410 but it works for what it tries to do.
411
412 Our best advice for verifying a person's mail address is to have them
413 enter their address twice, just as you normally do to change a password.
414 This usually weeds out typos.  If both versions match, send
415 mail to that address with a personal message that looks somewhat like:
416
417     Dear someuser@host.com,
418
419     Please confirm the mail address you gave us Wed May  6 09:38:41
420     MDT 1998 by replying to this message.  Include the string
421     "Rumpelstiltskin" in that reply, but spelled in reverse; that is,
422     start with "Nik...".  Once this is done, your confirmed address will
423     be entered into our records.
424
425 If you get the message back and they've followed your directions,
426 you can be reasonably assured that it's real.
427
428 A related strategy that's less open to forgery is to give them a PIN
429 (personal ID number).  Record the address and PIN (best that it be a
430 random one) for later processing.  In the mail you send, ask them to
431 include the PIN in their reply.  But if it bounces, or the message is
432 included via a ``vacation'' script, it'll be there anyway.  So it's
433 best to ask them to mail back a slight alteration of the PIN, such as
434 with the characters reversed, one added or subtracted to each digit, etc.
435
436 =head2 How do I decode a MIME/BASE64 string?
437
438 The MIME-Base64 package (available from CPAN) handles this as well as
439 the MIME/QP encoding.  Decoding BASE64 becomes as simple as:
440
441     use MIME::Base64;
442     $decoded = decode_base64($encoded);
443
444 The MIME-Tools package (available from CPAN) supports extraction with
445 decoding of BASE64 encoded attachments and content directly from email
446 messages.
447
448 If the string to decode is short (less than 84 bytes long)
449 a more direct approach is to use the unpack() function's "u"
450 format after minor transliterations:
451
452     tr#A-Za-z0-9+/##cd;                   # remove non-base64 chars
453     tr#A-Za-z0-9+/# -_#;                  # convert to uuencoded format
454     $len = pack("c", 32 + 0.75*length);   # compute length byte
455     print unpack("u", $len . $_);         # uudecode and print
456
457 =head2 How do I return the user's mail address?
458
459 On systems that support getpwuid, the $< variable, and the
460 Sys::Hostname module (which is part of the standard perl distribution),
461 you can probably try using something like this:
462
463     use Sys::Hostname;
464     $address = sprintf('%s@%s', scalar getpwuid($<), hostname);
465
466 Company policies on mail address can mean that this generates addresses
467 that the company's mail system will not accept, so you should ask for
468 users' mail addresses when this matters.  Furthermore, not all systems
469 on which Perl runs are so forthcoming with this information as is Unix.
470
471 The Mail::Util module from CPAN (part of the MailTools package) provides a
472 mailaddress() function that tries to guess the mail address of the user.
473 It makes a more intelligent guess than the code above, using information
474 given when the module was installed, but it could still be incorrect.
475 Again, the best way is often just to ask the user.
476
477 =head2 How do I send mail?
478
479 Use the C<sendmail> program directly:
480
481     open(SENDMAIL, "|/usr/lib/sendmail -oi -t -odq")
482                         or die "Can't fork for sendmail: $!\n";
483     print SENDMAIL <<"EOF";
484     From: User Originating Mail <me\@host>
485     To: Final Destination <you\@otherhost>
486     Subject: A relevant subject line
487
488     Body of the message goes here after the blank line
489     in as many lines as you like.
490     EOF
491     close(SENDMAIL)     or warn "sendmail didn't close nicely";
492
493 The B<-oi> option prevents sendmail from interpreting a line consisting
494 of a single dot as "end of message".  The B<-t> option says to use the
495 headers to decide who to send the message to, and B<-odq> says to put
496 the message into the queue.  This last option means your message won't
497 be immediately delivered, so leave it out if you want immediate
498 delivery.
499
500 Alternate, less convenient approaches include calling mail (sometimes
501 called mailx) directly or simply opening up port 25 have having an
502 intimate conversation between just you and the remote SMTP daemon,
503 probably sendmail.
504
505 Or you might be able use the CPAN module Mail::Mailer:
506
507     use Mail::Mailer;
508
509     $mailer = Mail::Mailer->new();
510     $mailer->open({ From    => $from_address,
511                     To      => $to_address,
512                     Subject => $subject,
513                   })
514         or die "Can't open: $!\n";
515     print $mailer $body;
516     $mailer->close();
517
518 The Mail::Internet module uses Net::SMTP which is less Unix-centric than
519 Mail::Mailer, but less reliable.  Avoid raw SMTP commands.  There
520 are many reasons to use a mail transport agent like sendmail.  These
521 include queuing, MX records, and security.
522
523 =head2 How do I use MIME to make an attachment to a mail message?
524
525 This answer is extracted directly from the MIME::Lite documentation.
526 Create a multipart message (i.e., one with attachments).
527
528     use MIME::Lite;
529
530     ### Create a new multipart message:
531     $msg = MIME::Lite->new(
532                  From    =>'me@myhost.com',
533                  To      =>'you@yourhost.com',
534                  Cc      =>'some@other.com, some@more.com',
535                  Subject =>'A message with 2 parts...',
536                  Type    =>'multipart/mixed'
537                  );
538
539     ### Add parts (each "attach" has same arguments as "new"):
540     $msg->attach(Type     =>'TEXT',
541                  Data     =>"Here's the GIF file you wanted"
542                  );
543     $msg->attach(Type     =>'image/gif',
544                  Path     =>'aaa000123.gif',
545                  Filename =>'logo.gif'
546                  );
547
548     $text = $msg->as_string;
549
550 MIME::Lite also includes a method for sending these things.
551
552     $msg->send;
553
554 This defaults to using L<sendmail> but can be customized to use
555 SMTP via L<Net::SMTP>.
556
557 =head2 How do I read mail?
558
559 While you could use the Mail::Folder module from CPAN (part of the
560 MailFolder package) or the Mail::Internet module from CPAN (part
561 of the MailTools package), often a module is overkill.  Here's a
562 mail sorter.
563
564     #!/usr/bin/perl
565
566     my(@msgs, @sub);
567     my $msgno = -1;
568     $/ = '';                    # paragraph reads
569     while (<>) {
570         if (/^From /m) {
571             /^Subject:\s*(?:Re:\s*)*(.*)/mi;
572             $sub[++$msgno] = lc($1) || '';
573         }
574         $msgs[$msgno] .= $_;
575     }
576     for my $i (sort { $sub[$a] cmp $sub[$b] || $a <=> $b } (0 .. $#msgs)) {
577         print $msgs[$i];
578     }
579
580 Or more succinctly,
581
582     #!/usr/bin/perl -n00
583     # bysub2 - awkish sort-by-subject
584     BEGIN { $msgno = -1 }
585     $sub[++$msgno] = (/^Subject:\s*(?:Re:\s*)*(.*)/mi)[0] if /^From/m;
586     $msg[$msgno] .= $_;
587     END { print @msg[ sort { $sub[$a] cmp $sub[$b] || $a <=> $b } (0 .. $#msg) ] }
588
589 =head2 How do I find out my hostname/domainname/IP address?
590
591 The normal way to find your own hostname is to call the C<`hostname`>
592 program.  While sometimes expedient, this has some problems, such as
593 not knowing whether you've got the canonical name or not.  It's one of
594 those tradeoffs of convenience versus portability.
595
596 The Sys::Hostname module (part of the standard perl distribution) will
597 give you the hostname after which you can find out the IP address
598 (assuming you have working DNS) with a gethostbyname() call.
599
600     use Socket;
601     use Sys::Hostname;
602     my $host = hostname();
603     my $addr = inet_ntoa(scalar gethostbyname($host || 'localhost'));
604
605 Probably the simplest way to learn your DNS domain name is to grok
606 it out of /etc/resolv.conf, at least under Unix.  Of course, this
607 assumes several things about your resolv.conf configuration, including
608 that it exists.
609
610 (We still need a good DNS domain name-learning method for non-Unix
611 systems.)
612
613 =head2 How do I fetch a news article or the active newsgroups?
614
615 Use the Net::NNTP or News::NNTPClient modules, both available from CPAN.
616 This can make tasks like fetching the newsgroup list as simple as
617
618     perl -MNews::NNTPClient
619       -e 'print News::NNTPClient->new->list("newsgroups")'
620
621 =head2 How do I fetch/put an FTP file?
622
623 LWP::Simple (available from CPAN) can fetch but not put.  Net::FTP (also
624 available from CPAN) is more complex but can put as well as fetch.
625
626 =head2 How can I do RPC in Perl?
627
628 A DCE::RPC module is being developed (but is not yet available) and
629 will be released as part of the DCE-Perl package (available from
630 CPAN).  The rpcgen suite, available from CPAN/authors/id/JAKE/, is
631 an RPC stub generator and includes an RPC::ONC module.
632
633 =head1 AUTHOR AND COPYRIGHT
634
635 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
636 All rights reserved.
637
638 This documentation is free; you can redistribute it and/or modify it
639 under the same terms as Perl itself.
640
641 Irrespective of its distribution, all code examples in this file
642 are hereby placed into the public domain.  You are permitted and
643 encouraged to use this code in your own programs for fun
644 or for profit as you see fit.  A simple comment in the code giving
645 credit would be courteous but is not required.