Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlfaq5.pod
1 =head1 NAME
2
3 perlfaq5 - Files and Formats ($Revision: 1.28 $, $Date: 2003/01/26 17:45:46 $)
4
5 =head1 DESCRIPTION
6
7 This section deals with I/O and the "f" issues: filehandles, flushing,
8 formats, and footers.
9
10 =head2 How do I flush/unbuffer an output filehandle?  Why must I do this?
11
12 Perl does not support truly unbuffered output (except
13 insofar as you can C<syswrite(OUT, $char, 1)>), although it
14 does support is "command buffering", in which a physical
15 write is performed after every output command.
16
17 The C standard I/O library (stdio) normally buffers
18 characters sent to devices so that there isn't a system call
19 for each byte. In most stdio implementations, the type of
20 output buffering and the size of the buffer varies according
21 to the type of device. Perl's print() and write() functions
22 normally buffer output, while syswrite() bypasses buffering
23 all together.
24
25 If you want your output to be sent immediately when you
26 execute print() or write() (for instance, for some network
27 protocols), you must set the handle's autoflush flag. This
28 flag is the Perl variable $| and when it is set to a true
29 value, Perl will flush the handle's buffer after each
30 print() or write(). Setting $| affects buffering only for
31 the currently selected default file handle. You choose this
32 handle with the one argument select() call (see
33 L<perlvar/$E<verbar>> and L<perlfunc/select>).
34
35 Use select() to choose the desired handle, then set its
36 per-filehandle variables.
37
38     $old_fh = select(OUTPUT_HANDLE);
39     $| = 1;
40     select($old_fh);
41
42 Some idioms can handle this in a single statement:
43
44     select((select(OUTPUT_HANDLE), $| = 1)[0]);
45
46     $| = 1, select $_ for select OUTPUT_HANDLE;
47
48 Some modules offer object-oriented access to handles and their
49 variables, although they may be overkill if this is the only
50 thing you do with them.  You can use IO::Handle:
51
52     use IO::Handle;
53     open(DEV, ">/dev/printer");   # but is this?
54     DEV->autoflush(1);
55
56 or IO::Socket:
57
58     use IO::Socket;               # this one is kinda a pipe?
59         my $sock = IO::Socket::INET->new( 'www.example.com:80' ) ;
60
61     $sock->autoflush();
62
63 =head2 How do I change one line in a file/delete a line in a file/insert a line in the middle of a file/append to the beginning of a file?
64
65 Use the Tie::File module, which is included in the standard
66 distribution since Perl 5.8.0.
67
68 =head2 How do I count the number of lines in a file?
69
70 One fairly efficient way is to count newlines in the file. The
71 following program uses a feature of tr///, as documented in L<perlop>.
72 If your text file doesn't end with a newline, then it's not really a
73 proper text file, so this may report one fewer line than you expect.
74
75     $lines = 0;
76     open(FILE, $filename) or die "Can't open `$filename': $!";
77     while (sysread FILE, $buffer, 4096) {
78         $lines += ($buffer =~ tr/\n//);
79     }
80     close FILE;
81
82 This assumes no funny games with newline translations.
83
84 =head2 How can I use Perl's C<-i> option from within a program?
85
86 C<-i> sets the value of Perl's C<$^I> variable, which in turn affects
87 the behavior of C<< <> >>; see L<perlrun> for more details.  By
88 modifying the appropriate variables directly, you can get the same
89 behavior within a larger program.  For example:
90
91      # ...
92      {
93         local($^I, @ARGV) = ('.orig', glob("*.c"));
94         while (<>) {
95            if ($. == 1) {
96                print "This line should appear at the top of each file\n";
97            }
98            s/\b(p)earl\b/${1}erl/i;        # Correct typos, preserving case
99            print;
100            close ARGV if eof;              # Reset $.
101         }
102      }
103      # $^I and @ARGV return to their old values here
104
105 This block modifies all the C<.c> files in the current directory,
106 leaving a backup of the original data from each file in a new
107 C<.c.orig> file.
108
109 =head2 How do I make a temporary file name?
110
111 Use the File::Temp module, see L<File::Temp> for more information.
112
113   use File::Temp qw/ tempfile tempdir /;
114
115   $dir = tempdir( CLEANUP => 1 );
116   ($fh, $filename) = tempfile( DIR => $dir );
117
118   # or if you don't need to know the filename
119
120   $fh = tempfile( DIR => $dir );
121
122 The File::Temp has been a standard module since Perl 5.6.1.  If you
123 don't have a modern enough Perl installed, use the C<new_tmpfile>
124 class method from the IO::File module to get a filehandle opened for
125 reading and writing.  Use it if you don't need to know the file's name:
126
127     use IO::File;
128     $fh = IO::File->new_tmpfile()
129         or die "Unable to make new temporary file: $!";
130
131 If you're committed to creating a temporary file by hand, use the
132 process ID and/or the current time-value.  If you need to have many
133 temporary files in one process, use a counter:
134
135     BEGIN {
136         use Fcntl;
137         my $temp_dir = -d '/tmp' ? '/tmp' : $ENV{TMPDIR} || $ENV{TEMP};
138         my $base_name = sprintf("%s/%d-%d-0000", $temp_dir, $$, time());
139         sub temp_file {
140             local *FH;
141             my $count = 0;
142             until (defined(fileno(FH)) || $count++ > 100) {
143                 $base_name =~ s/-(\d+)$/"-" . (1 + $1)/e;
144                 sysopen(FH, $base_name, O_WRONLY|O_EXCL|O_CREAT);
145             }
146             if (defined(fileno(FH))
147                 return (*FH, $base_name);
148             } else {
149                 return ();
150             }
151         }
152     }
153
154 =head2 How can I manipulate fixed-record-length files?
155
156 The most efficient way is using pack() and unpack().  This is faster than
157 using substr() when taking many, many strings.  It is slower for just a few.
158
159 Here is a sample chunk of code to break up and put back together again
160 some fixed-format input lines, in this case from the output of a normal,
161 Berkeley-style ps:
162
163     # sample input line:
164     #   15158 p5  T      0:00 perl /home/tchrist/scripts/now-what
165     $PS_T = 'A6 A4 A7 A5 A*';
166     open(PS, "ps|");
167     print scalar <PS>;
168     while (<PS>) {
169         ($pid, $tt, $stat, $time, $command) = unpack($PS_T, $_);
170         for $var (qw!pid tt stat time command!) {
171             print "$var: <$$var>\n";
172         }
173         print 'line=', pack($PS_T, $pid, $tt, $stat, $time, $command),
174                 "\n";
175     }
176
177 We've used C<$$var> in a way that forbidden by C<use strict 'refs'>.
178 That is, we've promoted a string to a scalar variable reference using
179 symbolic references.  This is okay in small programs, but doesn't scale
180 well.   It also only works on global variables, not lexicals.
181
182 =head2 How can I make a filehandle local to a subroutine?  How do I pass filehandles between subroutines?  How do I make an array of filehandles?
183
184 As of perl5.6, open() autovivifies file and directory handles
185 as references if you pass it an uninitialized scalar variable.
186 You can then pass these references just like any other scalar,
187 and use them in the place of named handles.
188
189         open my    $fh, $file_name;
190
191         open local $fh, $file_name;
192
193         print $fh "Hello World!\n";
194
195         process_file( $fh );
196
197 Before perl5.6, you had to deal with various typeglob idioms
198 which you may see in older code.
199
200         open FILE, "> $filename";
201         process_typeglob(   *FILE );
202         process_reference( \*FILE );
203
204         sub process_typeglob  { local *FH = shift; print FH  "Typeglob!" }
205         sub process_reference { local $fh = shift; print $fh "Reference!" }
206
207 If you want to create many anonymous handles, you should
208 check out the Symbol or IO::Handle modules.
209
210 =head2 How can I use a filehandle indirectly?
211
212 An indirect filehandle is using something other than a symbol
213 in a place that a filehandle is expected.  Here are ways
214 to get indirect filehandles:
215
216     $fh =   SOME_FH;       # bareword is strict-subs hostile
217     $fh =  "SOME_FH";      # strict-refs hostile; same package only
218     $fh =  *SOME_FH;       # typeglob
219     $fh = \*SOME_FH;       # ref to typeglob (bless-able)
220     $fh =  *SOME_FH{IO};   # blessed IO::Handle from *SOME_FH typeglob
221
222 Or, you can use the C<new> method from one of the IO::* modules to
223 create an anonymous filehandle, store that in a scalar variable,
224 and use it as though it were a normal filehandle.
225
226     use IO::Handle;                     # 5.004 or higher
227     $fh = IO::Handle->new();
228
229 Then use any of those as you would a normal filehandle.  Anywhere that
230 Perl is expecting a filehandle, an indirect filehandle may be used
231 instead. An indirect filehandle is just a scalar variable that contains
232 a filehandle.  Functions like C<print>, C<open>, C<seek>, or
233 the C<< <FH> >> diamond operator will accept either a named filehandle
234 or a scalar variable containing one:
235
236     ($ifh, $ofh, $efh) = (*STDIN, *STDOUT, *STDERR);
237     print $ofh "Type it: ";
238     $got = <$ifh>
239     print $efh "What was that: $got";
240
241 If you're passing a filehandle to a function, you can write
242 the function in two ways:
243
244     sub accept_fh {
245         my $fh = shift;
246         print $fh "Sending to indirect filehandle\n";
247     }
248
249 Or it can localize a typeglob and use the filehandle directly:
250
251     sub accept_fh {
252         local *FH = shift;
253         print  FH "Sending to localized filehandle\n";
254     }
255
256 Both styles work with either objects or typeglobs of real filehandles.
257 (They might also work with strings under some circumstances, but this
258 is risky.)
259
260     accept_fh(*STDOUT);
261     accept_fh($handle);
262
263 In the examples above, we assigned the filehandle to a scalar variable
264 before using it.  That is because only simple scalar variables, not
265 expressions or subscripts of hashes or arrays, can be used with
266 built-ins like C<print>, C<printf>, or the diamond operator.  Using
267 something other than a simple scalar variable as a filehandle is
268 illegal and won't even compile:
269
270     @fd = (*STDIN, *STDOUT, *STDERR);
271     print $fd[1] "Type it: ";                           # WRONG
272     $got = <$fd[0]>                                     # WRONG
273     print $fd[2] "What was that: $got";                 # WRONG
274
275 With C<print> and C<printf>, you get around this by using a block and
276 an expression where you would place the filehandle:
277
278     print  { $fd[1] } "funny stuff\n";
279     printf { $fd[1] } "Pity the poor %x.\n", 3_735_928_559;
280     # Pity the poor deadbeef.
281
282 That block is a proper block like any other, so you can put more
283 complicated code there.  This sends the message out to one of two places:
284
285     $ok = -x "/bin/cat";
286     print { $ok ? $fd[1] : $fd[2] } "cat stat $ok\n";
287     print { $fd[ 1+ ($ok || 0) ]  } "cat stat $ok\n";
288
289 This approach of treating C<print> and C<printf> like object methods
290 calls doesn't work for the diamond operator.  That's because it's a
291 real operator, not just a function with a comma-less argument.  Assuming
292 you've been storing typeglobs in your structure as we did above, you
293 can use the built-in function named C<readline> to read a record just
294 as C<< <> >> does.  Given the initialization shown above for @fd, this
295 would work, but only because readline() requires a typeglob.  It doesn't
296 work with objects or strings, which might be a bug we haven't fixed yet.
297
298     $got = readline($fd[0]);
299
300 Let it be noted that the flakiness of indirect filehandles is not
301 related to whether they're strings, typeglobs, objects, or anything else.
302 It's the syntax of the fundamental operators.  Playing the object
303 game doesn't help you at all here.
304
305 =head2 How can I set up a footer format to be used with write()?
306
307 There's no builtin way to do this, but L<perlform> has a couple of
308 techniques to make it possible for the intrepid hacker.
309
310 =head2 How can I write() into a string?
311
312 See L<perlform/"Accessing Formatting Internals"> for an swrite() function.
313
314 =head2 How can I output my numbers with commas added?
315
316 This subroutine will add commas to your number:
317
318         sub commify {
319            local $_  = shift;
320            1 while s/^([-+]?\d+)(\d{3})/$1,$2/;
321            return $_;
322            }
323
324 This regex from Benjamin Goldberg will add commas to numbers:
325
326    s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
327
328 It is easier to see with comments:
329
330    s/(
331        ^[-+]?            # beginning of number.
332        \d{1,3}?          # first digits before first comma
333        (?=               # followed by, (but not included in the match) :
334           (?>(?:\d{3})+) # some positive multiple of three digits.
335           (?!\d)         # an *exact* multiple, not x * 3 + 1 or whatever.
336        )
337       |                  # or:
338        \G\d{3}           # after the last group, get three digits
339        (?=\d)            # but they have to have more digits after them.
340    )/$1,/xg;
341
342 =head2 How can I translate tildes (~) in a filename?
343
344 Use the <> (glob()) operator, documented in L<perlfunc>.  Older
345 versions of Perl require that you have a shell installed that groks
346 tildes.  Recent perl versions have this feature built in. The
347 File::KGlob module (available from CPAN) gives more portable glob
348 functionality.
349
350 Within Perl, you may use this directly:
351
352         $filename =~ s{
353           ^ ~             # find a leading tilde
354           (               # save this in $1
355               [^/]        # a non-slash character
356                     *     # repeated 0 or more times (0 means me)
357           )
358         }{
359           $1
360               ? (getpwnam($1))[7]
361               : ( $ENV{HOME} || $ENV{LOGDIR} )
362         }ex;
363
364 =head2 How come when I open a file read-write it wipes it out?
365
366 Because you're using something like this, which truncates the file and
367 I<then> gives you read-write access:
368
369     open(FH, "+> /path/name");          # WRONG (almost always)
370
371 Whoops.  You should instead use this, which will fail if the file
372 doesn't exist.
373
374     open(FH, "+< /path/name");          # open for update
375
376 Using ">" always clobbers or creates.  Using "<" never does
377 either.  The "+" doesn't change this.
378
379 Here are examples of many kinds of file opens.  Those using sysopen()
380 all assume
381
382     use Fcntl;
383
384 To open file for reading:
385
386     open(FH, "< $path")                                 || die $!;
387     sysopen(FH, $path, O_RDONLY)                        || die $!;
388
389 To open file for writing, create new file if needed or else truncate old file:
390
391     open(FH, "> $path") || die $!;
392     sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT)        || die $!;
393     sysopen(FH, $path, O_WRONLY|O_TRUNC|O_CREAT, 0666)  || die $!;
394
395 To open file for writing, create new file, file must not exist:
396
397     sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT)         || die $!;
398     sysopen(FH, $path, O_WRONLY|O_EXCL|O_CREAT, 0666)   || die $!;
399
400 To open file for appending, create if necessary:
401
402     open(FH, ">> $path") || die $!;
403     sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT)       || die $!;
404     sysopen(FH, $path, O_WRONLY|O_APPEND|O_CREAT, 0666) || die $!;
405
406 To open file for appending, file must exist:
407
408     sysopen(FH, $path, O_WRONLY|O_APPEND)               || die $!;
409
410 To open file for update, file must exist:
411
412     open(FH, "+< $path")                                || die $!;
413     sysopen(FH, $path, O_RDWR)                          || die $!;
414
415 To open file for update, create file if necessary:
416
417     sysopen(FH, $path, O_RDWR|O_CREAT)                  || die $!;
418     sysopen(FH, $path, O_RDWR|O_CREAT, 0666)            || die $!;
419
420 To open file for update, file must not exist:
421
422     sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT)           || die $!;
423     sysopen(FH, $path, O_RDWR|O_EXCL|O_CREAT, 0666)     || die $!;
424
425 To open a file without blocking, creating if necessary:
426
427     sysopen(FH, "/tmp/somefile", O_WRONLY|O_NDELAY|O_CREAT)
428             or die "can't open /tmp/somefile: $!":
429
430 Be warned that neither creation nor deletion of files is guaranteed to
431 be an atomic operation over NFS.  That is, two processes might both
432 successfully create or unlink the same file!  Therefore O_EXCL
433 isn't as exclusive as you might wish.
434
435 See also the new L<perlopentut> if you have it (new for 5.6).
436
437 =head2 Why do I sometimes get an "Argument list too long" when I use E<lt>*E<gt>?
438
439 The C<< <> >> operator performs a globbing operation (see above).
440 In Perl versions earlier than v5.6.0, the internal glob() operator forks
441 csh(1) to do the actual glob expansion, but
442 csh can't handle more than 127 items and so gives the error message
443 C<Argument list too long>.  People who installed tcsh as csh won't
444 have this problem, but their users may be surprised by it.
445
446 To get around this, either upgrade to Perl v5.6.0 or later, do the glob
447 yourself with readdir() and patterns, or use a module like File::KGlob,
448 one that doesn't use the shell to do globbing.
449
450 =head2 Is there a leak/bug in glob()?
451
452 Due to the current implementation on some operating systems, when you
453 use the glob() function or its angle-bracket alias in a scalar
454 context, you may cause a memory leak and/or unpredictable behavior.  It's
455 best therefore to use glob() only in list context.
456
457 =head2 How can I open a file with a leading ">" or trailing blanks?
458
459 Normally perl ignores trailing blanks in filenames, and interprets
460 certain leading characters (or a trailing "|") to mean something
461 special.
462
463 The three argument form of open() lets you specify the mode
464 separately from the filename.  The open() function treats
465 special mode characters and whitespace in the filename as
466 literals
467
468         open FILE, "<", "  file  ";  # filename is "   file   "
469         open FILE, ">", ">file";     # filename is ">file"
470
471 It may be a lot clearer to use sysopen(), though:
472
473     use Fcntl;
474     $badpath = "<<<something really wicked   ";
475     sysopen (FH, $badpath, O_WRONLY | O_CREAT | O_TRUNC)
476         or die "can't open $badpath: $!";
477
478 =head2 How can I reliably rename a file?
479
480 If your operating system supports a proper mv(1) utility or its
481 functional equivalent, this works:
482
483     rename($old, $new) or system("mv", $old, $new);
484
485 It may be more portable to use the File::Copy module instead.
486 You just copy to the new file to the new name (checking return
487 values), then delete the old one.  This isn't really the same
488 semantically as a rename(), which preserves meta-information like
489 permissions, timestamps, inode info, etc.
490
491 Newer versions of File::Copy export a move() function.
492
493 =head2 How can I lock a file?
494
495 Perl's builtin flock() function (see L<perlfunc> for details) will call
496 flock(2) if that exists, fcntl(2) if it doesn't (on perl version 5.004 and
497 later), and lockf(3) if neither of the two previous system calls exists.
498 On some systems, it may even use a different form of native locking.
499 Here are some gotchas with Perl's flock():
500
501 =over 4
502
503 =item 1
504
505 Produces a fatal error if none of the three system calls (or their
506 close equivalent) exists.
507
508 =item 2
509
510 lockf(3) does not provide shared locking, and requires that the
511 filehandle be open for writing (or appending, or read/writing).
512
513 =item 3
514
515 Some versions of flock() can't lock files over a network (e.g. on NFS file
516 systems), so you'd need to force the use of fcntl(2) when you build Perl.
517 But even this is dubious at best.  See the flock entry of L<perlfunc>
518 and the F<INSTALL> file in the source distribution for information on
519 building Perl to do this.
520
521 Two potentially non-obvious but traditional flock semantics are that
522 it waits indefinitely until the lock is granted, and that its locks are
523 I<merely advisory>.  Such discretionary locks are more flexible, but
524 offer fewer guarantees.  This means that files locked with flock() may
525 be modified by programs that do not also use flock().  Cars that stop
526 for red lights get on well with each other, but not with cars that don't
527 stop for red lights.  See the perlport manpage, your port's specific
528 documentation, or your system-specific local manpages for details.  It's
529 best to assume traditional behavior if you're writing portable programs.
530 (If you're not, you should as always feel perfectly free to write
531 for your own system's idiosyncrasies (sometimes called "features").
532 Slavish adherence to portability concerns shouldn't get in the way of
533 your getting your job done.)
534
535 For more information on file locking, see also
536 L<perlopentut/"File Locking"> if you have it (new for 5.6).
537
538 =back
539
540 =head2 Why can't I just open(FH, "E<gt>file.lock")?
541
542 A common bit of code B<NOT TO USE> is this:
543
544     sleep(3) while -e "file.lock";      # PLEASE DO NOT USE
545     open(LCK, "> file.lock");           # THIS BROKEN CODE
546
547 This is a classic race condition: you take two steps to do something
548 which must be done in one.  That's why computer hardware provides an
549 atomic test-and-set instruction.   In theory, this "ought" to work:
550
551     sysopen(FH, "file.lock", O_WRONLY|O_EXCL|O_CREAT)
552                 or die "can't open  file.lock: $!":
553
554 except that lamentably, file creation (and deletion) is not atomic
555 over NFS, so this won't work (at least, not every time) over the net.
556 Various schemes involving link() have been suggested, but
557 these tend to involve busy-wait, which is also subdesirable.
558
559 =head2 I still don't get locking.  I just want to increment the number in the file.  How can I do this?
560
561 Didn't anyone ever tell you web-page hit counters were useless?
562 They don't count number of hits, they're a waste of time, and they serve
563 only to stroke the writer's vanity.  It's better to pick a random number;
564 they're more realistic.
565
566 Anyway, this is what you can do if you can't help yourself.
567
568     use Fcntl qw(:DEFAULT :flock);
569     sysopen(FH, "numfile", O_RDWR|O_CREAT)       or die "can't open numfile: $!";
570     flock(FH, LOCK_EX)                           or die "can't flock numfile: $!";
571     $num = <FH> || 0;
572     seek(FH, 0, 0)                               or die "can't rewind numfile: $!";
573     truncate(FH, 0)                              or die "can't truncate numfile: $!";
574     (print FH $num+1, "\n")                      or die "can't write numfile: $!";
575     close FH                                     or die "can't close numfile: $!";
576
577 Here's a much better web-page hit counter:
578
579     $hits = int( (time() - 850_000_000) / rand(1_000) );
580
581 If the count doesn't impress your friends, then the code might.  :-)
582
583 =head2 All I want to do is append a small amount of text to the end of a file.  Do I still have to use locking?
584
585 If you are on a system that correctly implements flock() and you use the
586 example appending code from "perldoc -f flock" everything will be OK
587 even if the OS you are on doesn't implement append mode correctly (if
588 such a system exists.) So if you are happy to restrict yourself to OSs
589 that implement flock() (and that's not really much of a restriction)
590 then that is what you should do.
591
592 If you know you are only going to use a system that does correctly
593 implement appending (i.e. not Win32) then you can omit the seek() from
594 the above code.
595
596 If you know you are only writing code to run on an OS and filesystem that
597 does implement append mode correctly (a local filesystem on a modern
598 Unix for example), and you keep the file in block-buffered mode and you
599 write less than one buffer-full of output between each manual flushing
600 of the buffer then each bufferload is almost guaranteed to be written to
601 the end of the file in one chunk without getting intermingled with
602 anyone else's output. You can also use the syswrite() function which is
603 simply a wrapper around your systems write(2) system call.
604
605 There is still a small theoretical chance that a signal will interrupt
606 the system level write() operation before completion.  There is also a
607 possibility that some STDIO implementations may call multiple system
608 level write()s even if the buffer was empty to start.  There may be some
609 systems where this probability is reduced to zero.
610
611 =head2 How do I randomly update a binary file?
612
613 If you're just trying to patch a binary, in many cases something as
614 simple as this works:
615
616     perl -i -pe 's{window manager}{window mangler}g' /usr/bin/emacs
617
618 However, if you have fixed sized records, then you might do something more
619 like this:
620
621     $RECSIZE = 220; # size of record, in bytes
622     $recno   = 37;  # which record to update
623     open(FH, "+<somewhere") || die "can't update somewhere: $!";
624     seek(FH, $recno * $RECSIZE, 0);
625     read(FH, $record, $RECSIZE) == $RECSIZE || die "can't read record $recno: $!";
626     # munge the record
627     seek(FH, -$RECSIZE, 1);
628     print FH $record;
629     close FH;
630
631 Locking and error checking are left as an exercise for the reader.
632 Don't forget them or you'll be quite sorry.
633
634 =head2 How do I get a file's timestamp in perl?
635
636 If you want to retrieve the time at which the file was last
637 read, written, or had its meta-data (owner, etc) changed,
638 you use the B<-M>, B<-A>, or B<-C> file test operations as
639 documented in L<perlfunc>.  These retrieve the age of the
640 file (measured against the start-time of your program) in
641 days as a floating point number. Some platforms may not have
642 all of these times.  See L<perlport> for details. To
643 retrieve the "raw" time in seconds since the epoch, you
644 would call the stat function, then use localtime(),
645 gmtime(), or POSIX::strftime() to convert this into
646 human-readable form.
647
648 Here's an example:
649
650     $write_secs = (stat($file))[9];
651     printf "file %s updated at %s\n", $file,
652         scalar localtime($write_secs);
653
654 If you prefer something more legible, use the File::stat module
655 (part of the standard distribution in version 5.004 and later):
656
657     # error checking left as an exercise for reader.
658     use File::stat;
659     use Time::localtime;
660     $date_string = ctime(stat($file)->mtime);
661     print "file $file updated at $date_string\n";
662
663 The POSIX::strftime() approach has the benefit of being,
664 in theory, independent of the current locale.  See L<perllocale>
665 for details.
666
667 =head2 How do I set a file's timestamp in perl?
668
669 You use the utime() function documented in L<perlfunc/utime>.
670 By way of example, here's a little program that copies the
671 read and write times from its first argument to all the rest
672 of them.
673
674     if (@ARGV < 2) {
675         die "usage: cptimes timestamp_file other_files ...\n";
676     }
677     $timestamp = shift;
678     ($atime, $mtime) = (stat($timestamp))[8,9];
679     utime $atime, $mtime, @ARGV;
680
681 Error checking is, as usual, left as an exercise for the reader.
682
683 Note that utime() currently doesn't work correctly with Win95/NT
684 ports.  A bug has been reported.  Check it carefully before using
685 utime() on those platforms.
686
687 =head2 How do I print to more than one file at once?
688
689 To connect one filehandle to several output filehandles,
690 you can use the IO::Tee or Tie::FileHandle::Multiplex modules.
691
692 If you only have to do this once, you can print individually
693 to each filehandle.
694
695     for $fh (FH1, FH2, FH3) { print $fh "whatever\n" }
696
697 =head2 How can I read in an entire file all at once?
698
699 You can use the File::Slurp module to do it in one step.
700
701         use File::Slurp;
702
703         $all_of_it = read_file($filename); # entire file in scalar
704     @all_lines = read_file($filename); # one line perl element
705
706 The customary Perl approach for processing all the lines in a file is to
707 do so one line at a time:
708
709     open (INPUT, $file)         || die "can't open $file: $!";
710     while (<INPUT>) {
711         chomp;
712         # do something with $_
713     }
714     close(INPUT)                || die "can't close $file: $!";
715
716 This is tremendously more efficient than reading the entire file into
717 memory as an array of lines and then processing it one element at a time,
718 which is often--if not almost always--the wrong approach.  Whenever
719 you see someone do this:
720
721     @lines = <INPUT>;
722
723 you should think long and hard about why you need everything loaded at
724 once.  It's just not a scalable solution.  You might also find it more
725 fun to use the standard Tie::File module, or the DB_File module's
726 $DB_RECNO bindings, which allow you to tie an array to a file so that
727 accessing an element the array actually accesses the corresponding
728 line in the file.
729
730 You can read the entire filehandle contents into a scalar.
731
732     {
733         local(*INPUT, $/);
734         open (INPUT, $file)     || die "can't open $file: $!";
735         $var = <INPUT>;
736     }
737
738 That temporarily undefs your record separator, and will automatically
739 close the file at block exit.  If the file is already open, just use this:
740
741     $var = do { local $/; <INPUT> };
742
743 For ordinary files you can also use the read function.
744
745         read( INPUT, $var, -s INPUT );
746
747 The third argument tests the byte size of the data on the INPUT filehandle
748 and reads that many bytes into the buffer $var.
749
750 =head2 How can I read in a file by paragraphs?
751
752 Use the C<$/> variable (see L<perlvar> for details).  You can either
753 set it to C<""> to eliminate empty paragraphs (C<"abc\n\n\n\ndef">,
754 for instance, gets treated as two paragraphs and not three), or
755 C<"\n\n"> to accept empty paragraphs.
756
757 Note that a blank line must have no blanks in it.  Thus
758 S<C<"fred\n \nstuff\n\n">> is one paragraph, but C<"fred\n\nstuff\n\n"> is two.
759
760 =head2 How can I read a single character from a file?  From the keyboard?
761
762 You can use the builtin C<getc()> function for most filehandles, but
763 it won't (easily) work on a terminal device.  For STDIN, either use
764 the Term::ReadKey module from CPAN or use the sample code in
765 L<perlfunc/getc>.
766
767 If your system supports the portable operating system programming
768 interface (POSIX), you can use the following code, which you'll note
769 turns off echo processing as well.
770
771     #!/usr/bin/perl -w
772     use strict;
773     $| = 1;
774     for (1..4) {
775         my $got;
776         print "gimme: ";
777         $got = getone();
778         print "--> $got\n";
779     }
780     exit;
781
782     BEGIN {
783         use POSIX qw(:termios_h);
784
785         my ($term, $oterm, $echo, $noecho, $fd_stdin);
786
787         $fd_stdin = fileno(STDIN);
788
789         $term     = POSIX::Termios->new();
790         $term->getattr($fd_stdin);
791         $oterm     = $term->getlflag();
792
793         $echo     = ECHO | ECHOK | ICANON;
794         $noecho   = $oterm & ~$echo;
795
796         sub cbreak {
797             $term->setlflag($noecho);
798             $term->setcc(VTIME, 1);
799             $term->setattr($fd_stdin, TCSANOW);
800         }
801
802         sub cooked {
803             $term->setlflag($oterm);
804             $term->setcc(VTIME, 0);
805             $term->setattr($fd_stdin, TCSANOW);
806         }
807
808         sub getone {
809             my $key = '';
810             cbreak();
811             sysread(STDIN, $key, 1);
812             cooked();
813             return $key;
814         }
815
816     }
817
818     END { cooked() }
819
820 The Term::ReadKey module from CPAN may be easier to use.  Recent versions
821 include also support for non-portable systems as well.
822
823     use Term::ReadKey;
824     open(TTY, "</dev/tty");
825     print "Gimme a char: ";
826     ReadMode "raw";
827     $key = ReadKey 0, *TTY;
828     ReadMode "normal";
829     printf "\nYou said %s, char number %03d\n",
830         $key, ord $key;
831
832 =head2 How can I tell whether there's a character waiting on a filehandle?
833
834 The very first thing you should do is look into getting the Term::ReadKey
835 extension from CPAN.  As we mentioned earlier, it now even has limited
836 support for non-portable (read: not open systems, closed, proprietary,
837 not POSIX, not Unix, etc) systems.
838
839 You should also check out the Frequently Asked Questions list in
840 comp.unix.* for things like this: the answer is essentially the same.
841 It's very system dependent.  Here's one solution that works on BSD
842 systems:
843
844     sub key_ready {
845         my($rin, $nfd);
846         vec($rin, fileno(STDIN), 1) = 1;
847         return $nfd = select($rin,undef,undef,0);
848     }
849
850 If you want to find out how many characters are waiting, there's
851 also the FIONREAD ioctl call to be looked at.  The I<h2ph> tool that
852 comes with Perl tries to convert C include files to Perl code, which
853 can be C<require>d.  FIONREAD ends up defined as a function in the
854 I<sys/ioctl.ph> file:
855
856     require 'sys/ioctl.ph';
857
858     $size = pack("L", 0);
859     ioctl(FH, FIONREAD(), $size)    or die "Couldn't call ioctl: $!\n";
860     $size = unpack("L", $size);
861
862 If I<h2ph> wasn't installed or doesn't work for you, you can
863 I<grep> the include files by hand:
864
865     % grep FIONREAD /usr/include/*/*
866     /usr/include/asm/ioctls.h:#define FIONREAD      0x541B
867
868 Or write a small C program using the editor of champions:
869
870     % cat > fionread.c
871     #include <sys/ioctl.h>
872     main() {
873         printf("%#08x\n", FIONREAD);
874     }
875     ^D
876     % cc -o fionread fionread.c
877     % ./fionread
878     0x4004667f
879
880 And then hard code it, leaving porting as an exercise to your successor.
881
882     $FIONREAD = 0x4004667f;         # XXX: opsys dependent
883
884     $size = pack("L", 0);
885     ioctl(FH, $FIONREAD, $size)     or die "Couldn't call ioctl: $!\n";
886     $size = unpack("L", $size);
887
888 FIONREAD requires a filehandle connected to a stream, meaning that sockets,
889 pipes, and tty devices work, but I<not> files.
890
891 =head2 How do I do a C<tail -f> in perl?
892
893 First try
894
895     seek(GWFILE, 0, 1);
896
897 The statement C<seek(GWFILE, 0, 1)> doesn't change the current position,
898 but it does clear the end-of-file condition on the handle, so that the
899 next <GWFILE> makes Perl try again to read something.
900
901 If that doesn't work (it relies on features of your stdio implementation),
902 then you need something more like this:
903
904         for (;;) {
905           for ($curpos = tell(GWFILE); <GWFILE>; $curpos = tell(GWFILE)) {
906             # search for some stuff and put it into files
907           }
908           # sleep for a while
909           seek(GWFILE, $curpos, 0);  # seek to where we had been
910         }
911
912 If this still doesn't work, look into the POSIX module.  POSIX defines
913 the clearerr() method, which can remove the end of file condition on a
914 filehandle.  The method: read until end of file, clearerr(), read some
915 more.  Lather, rinse, repeat.
916
917 There's also a File::Tail module from CPAN.
918
919 =head2 How do I dup() a filehandle in Perl?
920
921 If you check L<perlfunc/open>, you'll see that several of the ways
922 to call open() should do the trick.  For example:
923
924     open(LOG, ">>/tmp/logfile");
925     open(STDERR, ">&LOG");
926
927 Or even with a literal numeric descriptor:
928
929    $fd = $ENV{MHCONTEXTFD};
930    open(MHCONTEXT, "<&=$fd");   # like fdopen(3S)
931
932 Note that "<&STDIN" makes a copy, but "<&=STDIN" make
933 an alias.  That means if you close an aliased handle, all
934 aliases become inaccessible.  This is not true with
935 a copied one.
936
937 Error checking, as always, has been left as an exercise for the reader.
938
939 =head2 How do I close a file descriptor by number?
940
941 This should rarely be necessary, as the Perl close() function is to be
942 used for things that Perl opened itself, even if it was a dup of a
943 numeric descriptor as with MHCONTEXT above.  But if you really have
944 to, you may be able to do this:
945
946     require 'sys/syscall.ph';
947     $rc = syscall(&SYS_close, $fd + 0);  # must force numeric
948     die "can't sysclose $fd: $!" unless $rc == -1;
949
950 Or, just use the fdopen(3S) feature of open():
951
952     {
953         local *F;
954         open F, "<&=$fd" or die "Cannot reopen fd=$fd: $!";
955         close F;
956     }
957
958 =head2 Why can't I use "C:\temp\foo" in DOS paths?  Why doesn't `C:\temp\foo.exe` work?
959
960 Whoops!  You just put a tab and a formfeed into that filename!
961 Remember that within double quoted strings ("like\this"), the
962 backslash is an escape character.  The full list of these is in
963 L<perlop/Quote and Quote-like Operators>.  Unsurprisingly, you don't
964 have a file called "c:(tab)emp(formfeed)oo" or
965 "c:(tab)emp(formfeed)oo.exe" on your legacy DOS filesystem.
966
967 Either single-quote your strings, or (preferably) use forward slashes.
968 Since all DOS and Windows versions since something like MS-DOS 2.0 or so
969 have treated C</> and C<\> the same in a path, you might as well use the
970 one that doesn't clash with Perl--or the POSIX shell, ANSI C and C++,
971 awk, Tcl, Java, or Python, just to mention a few.  POSIX paths
972 are more portable, too.
973
974 =head2 Why doesn't glob("*.*") get all the files?
975
976 Because even on non-Unix ports, Perl's glob function follows standard
977 Unix globbing semantics.  You'll need C<glob("*")> to get all (non-hidden)
978 files.  This makes glob() portable even to legacy systems.  Your
979 port may include proprietary globbing functions as well.  Check its
980 documentation for details.
981
982 =head2 Why does Perl let me delete read-only files?  Why does C<-i> clobber protected files?  Isn't this a bug in Perl?
983
984 This is elaborately and painstakingly described in the
985 F<file-dir-perms> article in the "Far More Than You Ever Wanted To
986 Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz .
987
988 The executive summary: learn how your filesystem works.  The
989 permissions on a file say what can happen to the data in that file.
990 The permissions on a directory say what can happen to the list of
991 files in that directory.  If you delete a file, you're removing its
992 name from the directory (so the operation depends on the permissions
993 of the directory, not of the file).  If you try to write to the file,
994 the permissions of the file govern whether you're allowed to.
995
996 =head2 How do I select a random line from a file?
997
998 Here's an algorithm from the Camel Book:
999
1000     srand;
1001     rand($.) < 1 && ($line = $_) while <>;
1002
1003 This has a significant advantage in space over reading the whole file
1004 in.  You can find a proof of this method in I<The Art of Computer
1005 Programming>, Volume 2, Section 3.4.2, by Donald E. Knuth.
1006
1007 You can use the File::Random module which provides a function
1008 for that algorithm:
1009
1010         use File::Random qw/random_line/;
1011         my $line = random_line($filename);
1012
1013 Another way is to use the Tie::File module, which treats the entire
1014 file as an array.  Simply access a random array element.
1015
1016 =head2 Why do I get weird spaces when I print an array of lines?
1017
1018 Saying
1019
1020     print "@lines\n";
1021
1022 joins together the elements of C<@lines> with a space between them.
1023 If C<@lines> were C<("little", "fluffy", "clouds")> then the above
1024 statement would print
1025
1026     little fluffy clouds
1027
1028 but if each element of C<@lines> was a line of text, ending a newline
1029 character C<("little\n", "fluffy\n", "clouds\n")> then it would print:
1030
1031     little
1032      fluffy
1033      clouds
1034
1035 If your array contains lines, just print them:
1036
1037     print @lines;
1038
1039 =head1 AUTHOR AND COPYRIGHT
1040
1041 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
1042 All rights reserved.
1043
1044 This documentation is free; you can redistribute it and/or modify it
1045 under the same terms as Perl itself.
1046
1047 Irrespective of its distribution, all code examples here are in the public
1048 domain.  You are permitted and encouraged to use this code and any
1049 derivatives thereof in your own programs for fun or for profit as you
1050 see fit.  A simple comment in the code giving credit to the FAQ would
1051 be courteous but is not required.