Re: [MacOS X] consider useshrplib='false' by default
[perl.git] / pod / perlfaq4.pod
1 =head1 NAME
2
3 perlfaq4 - Data Manipulation ($Revision: 1.43 $, $Date: 2003/02/23 20:25:09 $)
4
5 =head1 DESCRIPTION
6
7 This section of the FAQ answers questions related to manipulating
8 numbers, dates, strings, arrays, hashes, and miscellaneous data issues.
9
10 =head1 Data: Numbers
11
12 =head2 Why am I getting long decimals (eg, 19.9499999999999) instead of the numbers I should be getting (eg, 19.95)?
13
14 Internally, your computer represents floating-point numbers
15 in binary. Digital (as in powers of two) computers cannot
16 store all numbers exactly.  Some real numbers lose precision
17 in the process.  This is a problem with how computers store
18 numbers and affects all computer languages, not just Perl.
19
20 L<perlnumber> show the gory details of number
21 representations and conversions.
22
23 To limit the number of decimal places in your numbers, you
24 can use the printf or sprintf function.  See the
25 L<"Floating Point Arithmetic"|perlop> for more details.
26
27         printf "%.2f", 10/3;
28
29         my $number = sprintf "%.2f", 10/3;
30
31 =head2 Why isn't my octal data interpreted correctly?
32
33 Perl only understands octal and hex numbers as such when they occur as
34 literals in your program.  Octal literals in perl must start with a
35 leading "0" and hexadecimal literals must start with a leading "0x".
36 If they are read in from somewhere and assigned, no automatic
37 conversion takes place.  You must explicitly use oct() or hex() if you
38 want the values converted to decimal.  oct() interprets hex ("0x350"),
39 octal ("0350" or even without the leading "0", like "377") and binary
40 ("0b1010") numbers, while hex() only converts hexadecimal ones, with
41 or without a leading "0x", like "0x255", "3A", "ff", or "deadbeef".
42 The inverse mapping from decimal to octal can be done with either the
43 "%o" or "%O" sprintf() formats.
44
45 This problem shows up most often when people try using chmod(), mkdir(),
46 umask(), or sysopen(), which by widespread tradition typically take
47 permissions in octal.
48
49     chmod(644,  $file); # WRONG
50     chmod(0644, $file); # right
51
52 Note the mistake in the first line was specifying the decimal literal
53 644, rather than the intended octal literal 0644.  The problem can
54 be seen with:
55
56     printf("%#o",644); # prints 01204
57
58 Surely you had not intended C<chmod(01204, $file);> - did you?  If you
59 want to use numeric literals as arguments to chmod() et al. then please
60 try to express them as octal constants, that is with a leading zero and
61 with the following digits restricted to the set 0..7.
62
63 =head2 Does Perl have a round() function?  What about ceil() and floor()?  Trig functions?
64
65 Remember that int() merely truncates toward 0.  For rounding to a
66 certain number of digits, sprintf() or printf() is usually the easiest
67 route.
68
69     printf("%.3f", 3.1415926535);       # prints 3.142
70
71 The POSIX module (part of the standard Perl distribution) implements
72 ceil(), floor(), and a number of other mathematical and trigonometric
73 functions.
74
75     use POSIX;
76     $ceil   = ceil(3.5);                        # 4
77     $floor  = floor(3.5);                       # 3
78
79 In 5.000 to 5.003 perls, trigonometry was done in the Math::Complex
80 module.  With 5.004, the Math::Trig module (part of the standard Perl
81 distribution) implements the trigonometric functions. Internally it
82 uses the Math::Complex module and some functions can break out from
83 the real axis into the complex plane, for example the inverse sine of
84 2.
85
86 Rounding in financial applications can have serious implications, and
87 the rounding method used should be specified precisely.  In these
88 cases, it probably pays not to trust whichever system rounding is
89 being used by Perl, but to instead implement the rounding function you
90 need yourself.
91
92 To see why, notice how you'll still have an issue on half-way-point
93 alternation:
94
95     for ($i = 0; $i < 1.01; $i += 0.05) { printf "%.1f ",$i}
96
97     0.0 0.1 0.1 0.2 0.2 0.2 0.3 0.3 0.4 0.4 0.5 0.5 0.6 0.7 0.7
98     0.8 0.8 0.9 0.9 1.0 1.0
99
100 Don't blame Perl.  It's the same as in C.  IEEE says we have to do this.
101 Perl numbers whose absolute values are integers under 2**31 (on 32 bit
102 machines) will work pretty much like mathematical integers.  Other numbers
103 are not guaranteed.
104
105 =head2 How do I convert between numeric representations?
106
107 As always with Perl there is more than one way to do it.  Below
108 are a few examples of approaches to making common conversions
109 between number representations.  This is intended to be representational
110 rather than exhaustive.
111
112 Some of the examples below use the Bit::Vector module from CPAN.
113 The reason you might choose Bit::Vector over the perl built in
114 functions is that it works with numbers of ANY size, that it is
115 optimized for speed on some operations, and for at least some
116 programmers the notation might be familiar.
117
118 =over 4
119
120 =item How do I convert hexadecimal into decimal
121
122 Using perl's built in conversion of 0x notation:
123
124     $int = 0xDEADBEEF;
125     $dec = sprintf("%d", $int);
126
127 Using the hex function:
128
129     $int = hex("DEADBEEF");
130     $dec = sprintf("%d", $int);
131
132 Using pack:
133
134     $int = unpack("N", pack("H8", substr("0" x 8 . "DEADBEEF", -8)));
135     $dec = sprintf("%d", $int);
136
137 Using the CPAN module Bit::Vector:
138
139     use Bit::Vector;
140     $vec = Bit::Vector->new_Hex(32, "DEADBEEF");
141     $dec = $vec->to_Dec();
142
143 =item How do I convert from decimal to hexadecimal
144
145 Using sprintf:
146
147     $hex = sprintf("%X", 3735928559);
148
149 Using unpack
150
151     $hex = unpack("H*", pack("N", 3735928559));
152
153 Using Bit::Vector
154
155     use Bit::Vector;
156     $vec = Bit::Vector->new_Dec(32, -559038737);
157     $hex = $vec->to_Hex();
158
159 And Bit::Vector supports odd bit counts:
160
161     use Bit::Vector;
162     $vec = Bit::Vector->new_Dec(33, 3735928559);
163     $vec->Resize(32); # suppress leading 0 if unwanted
164     $hex = $vec->to_Hex();
165
166 =item How do I convert from octal to decimal
167
168 Using Perl's built in conversion of numbers with leading zeros:
169
170     $int = 033653337357; # note the leading 0!
171     $dec = sprintf("%d", $int);
172
173 Using the oct function:
174
175     $int = oct("33653337357");
176     $dec = sprintf("%d", $int);
177
178 Using Bit::Vector:
179
180     use Bit::Vector;
181     $vec = Bit::Vector->new(32);
182     $vec->Chunk_List_Store(3, split(//, reverse "33653337357"));
183     $dec = $vec->to_Dec();
184
185 =item How do I convert from decimal to octal
186
187 Using sprintf:
188
189     $oct = sprintf("%o", 3735928559);
190
191 Using Bit::Vector
192
193     use Bit::Vector;
194     $vec = Bit::Vector->new_Dec(32, -559038737);
195     $oct = reverse join('', $vec->Chunk_List_Read(3));
196
197 =item How do I convert from binary to decimal
198
199 Perl 5.6 lets you write binary numbers directly with
200 the 0b notation:
201
202         $number = 0b10110110;
203
204 Using pack and ord
205
206     $decimal = ord(pack('B8', '10110110'));
207
208 Using pack and unpack for larger strings
209
210     $int = unpack("N", pack("B32",
211         substr("0" x 32 . "11110101011011011111011101111", -32)));
212     $dec = sprintf("%d", $int);
213
214     # substr() is used to left pad a 32 character string with zeros.
215
216 Using Bit::Vector:
217
218     $vec = Bit::Vector->new_Bin(32, "11011110101011011011111011101111");
219     $dec = $vec->to_Dec();
220
221 =item How do I convert from decimal to binary
222
223 Using unpack;
224
225     $bin = unpack("B*", pack("N", 3735928559));
226
227 Using Bit::Vector:
228
229     use Bit::Vector;
230     $vec = Bit::Vector->new_Dec(32, -559038737);
231     $bin = $vec->to_Bin();
232
233 The remaining transformations (e.g. hex -> oct, bin -> hex, etc.)
234 are left as an exercise to the inclined reader.
235
236 =back
237
238 =head2 Why doesn't & work the way I want it to?
239
240 The behavior of binary arithmetic operators depends on whether they're
241 used on numbers or strings.  The operators treat a string as a series
242 of bits and work with that (the string C<"3"> is the bit pattern
243 C<00110011>).  The operators work with the binary form of a number
244 (the number C<3> is treated as the bit pattern C<00000011>).
245
246 So, saying C<11 & 3> performs the "and" operation on numbers (yielding
247 C<3>).  Saying C<"11" & "3"> performs the "and" operation on strings
248 (yielding C<"1">).
249
250 Most problems with C<&> and C<|> arise because the programmer thinks
251 they have a number but really it's a string.  The rest arise because
252 the programmer says:
253
254     if ("\020\020" & "\101\101") {
255         # ...
256     }
257
258 but a string consisting of two null bytes (the result of C<"\020\020"
259 & "\101\101">) is not a false value in Perl.  You need:
260
261     if ( ("\020\020" & "\101\101") !~ /[^\000]/) {
262         # ...
263     }
264
265 =head2 How do I multiply matrices?
266
267 Use the Math::Matrix or Math::MatrixReal modules (available from CPAN)
268 or the PDL extension (also available from CPAN).
269
270 =head2 How do I perform an operation on a series of integers?
271
272 To call a function on each element in an array, and collect the
273 results, use:
274
275     @results = map { my_func($_) } @array;
276
277 For example:
278
279     @triple = map { 3 * $_ } @single;
280
281 To call a function on each element of an array, but ignore the
282 results:
283
284     foreach $iterator (@array) {
285         some_func($iterator);
286     }
287
288 To call a function on each integer in a (small) range, you B<can> use:
289
290     @results = map { some_func($_) } (5 .. 25);
291
292 but you should be aware that the C<..> operator creates an array of
293 all integers in the range.  This can take a lot of memory for large
294 ranges.  Instead use:
295
296     @results = ();
297     for ($i=5; $i < 500_005; $i++) {
298         push(@results, some_func($i));
299     }
300
301 This situation has been fixed in Perl5.005. Use of C<..> in a C<for>
302 loop will iterate over the range, without creating the entire range.
303
304     for my $i (5 .. 500_005) {
305         push(@results, some_func($i));
306     }
307
308 will not create a list of 500,000 integers.
309
310 =head2 How can I output Roman numerals?
311
312 Get the http://www.cpan.org/modules/by-module/Roman module.
313
314 =head2 Why aren't my random numbers random?
315
316 If you're using a version of Perl before 5.004, you must call C<srand>
317 once at the start of your program to seed the random number generator.
318
319          BEGIN { srand() if $] < 5.004 }
320
321 5.004 and later automatically call C<srand> at the beginning.  Don't
322 call C<srand> more than once---you make your numbers less random, rather
323 than more.
324
325 Computers are good at being predictable and bad at being random
326 (despite appearances caused by bugs in your programs :-).  see the
327 F<random> article in the "Far More Than You Ever Wanted To Know"
328 collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz , courtesy of
329 Tom Phoenix, talks more about this.  John von Neumann said, ``Anyone
330 who attempts to generate random numbers by deterministic means is, of
331 course, living in a state of sin.''
332
333 If you want numbers that are more random than C<rand> with C<srand>
334 provides, you should also check out the Math::TrulyRandom module from
335 CPAN.  It uses the imperfections in your system's timer to generate
336 random numbers, but this takes quite a while.  If you want a better
337 pseudorandom generator than comes with your operating system, look at
338 ``Numerical Recipes in C'' at http://www.nr.com/ .
339
340 =head2 How do I get a random number between X and Y?
341
342 Use the following simple function.  It selects a random integer between
343 (and possibly including!) the two given integers, e.g.,
344 C<random_int_in(50,120)>
345
346    sub random_int_in ($$) {
347      my($min, $max) = @_;
348       # Assumes that the two arguments are integers themselves!
349      return $min if $min == $max;
350      ($min, $max) = ($max, $min)  if  $min > $max;
351      return $min + int rand(1 + $max - $min);
352    }
353
354 =head1 Data: Dates
355
356 =head2 How do I find the day or week of the year?
357
358 The localtime function returns the day of the week.  Without an
359 argument localtime uses the current time.
360
361     $day_of_year = (localtime)[7];
362     
363 The POSIX module can also format a date as the day of the year or
364 week of the year.
365
366         use POSIX qw/strftime/;
367         my $day_of_year  = strftime "%j", localtime;
368         my $week_of_year = strftime "%W", localtime;
369
370 To get the day of year for any date, use the Time::Local module to get
371 a time in epoch seconds for the argument to localtime.
372         
373         use POSIX qw/strftime/;
374         use Time::Local;
375         my $week_of_year = strftime "%W", 
376                 localtime( timelocal( 0, 0, 0, 18, 11, 1987 ) );
377
378 The Date::Calc module provides two functions for to calculate these.
379
380         use Date::Calc;
381         my $day_of_year  = Day_of_Year(  1987, 12, 18 );
382         my $week_of_year = Week_of_Year( 1987, 12, 18 );
383         
384 =head2 How do I find the current century or millennium?
385
386 Use the following simple functions:
387
388     sub get_century    {
389         return int((((localtime(shift || time))[5] + 1999))/100);
390     }
391     sub get_millennium {
392         return 1+int((((localtime(shift || time))[5] + 1899))/1000);
393     }
394
395 You can also use the POSIX strftime() function which may be a bit
396 slower but is easier to read and maintain.
397
398         use POSIX qw/strftime/;
399
400         my $week_of_the_year = strftime "%W", localtime;
401         my $day_of_the_year  = strftime "%j", localtime;
402
403 On some systems, the POSIX module's strftime() function has
404 been extended in a non-standard way to use a C<%C> format,
405 which they sometimes claim is the "century".  It isn't,
406 because on most such systems, this is only the first two
407 digits of the four-digit year, and thus cannot be used to
408 reliably determine the current century or millennium.
409
410 =head2 How can I compare two dates and find the difference?
411
412 If you're storing your dates as epoch seconds then simply subtract one
413 from the other.  If you've got a structured date (distinct year, day,
414 month, hour, minute, seconds values), then for reasons of accessibility,
415 simplicity, and efficiency, merely use either timelocal or timegm (from
416 the Time::Local module in the standard distribution) to reduce structured
417 dates to epoch seconds.  However, if you don't know the precise format of
418 your dates, then you should probably use either of the Date::Manip and
419 Date::Calc modules from CPAN before you go hacking up your own parsing
420 routine to handle arbitrary date formats.
421
422 =head2 How can I take a string and turn it into epoch seconds?
423
424 If it's a regular enough string that it always has the same format,
425 you can split it up and pass the parts to C<timelocal> in the standard
426 Time::Local module.  Otherwise, you should look into the Date::Calc
427 and Date::Manip modules from CPAN.
428
429 =head2 How can I find the Julian Day?
430
431 Use the Time::JulianDay module (part of the Time-modules bundle
432 available from CPAN.)
433
434 Before you immerse yourself too deeply in this, be sure to verify that
435 it is the I<Julian> Day you really want.  Are you interested in a way
436 of getting serial days so that you just can tell how many days they
437 are apart or so that you can do also other date arithmetic?  If you
438 are interested in performing date arithmetic, this can be done using
439 modules Date::Manip or Date::Calc.
440
441 There is too many details and much confusion on this issue to cover in
442 this FAQ, but the term is applied (correctly) to a calendar now
443 supplanted by the Gregorian Calendar, with the Julian Calendar failing
444 to adjust properly for leap years on centennial years (among other
445 annoyances).  The term is also used (incorrectly) to mean: [1] days in
446 the Gregorian Calendar; and [2] days since a particular starting time
447 or `epoch', usually 1970 in the Unix world and 1980 in the
448 MS-DOS/Windows world.  If you find that it is not the first meaning
449 that you really want, then check out the Date::Manip and Date::Calc
450 modules.  (Thanks to David Cassell for most of this text.)
451
452 =head2 How do I find yesterday's date?
453
454 If you only need to find the date (and not the same time), you
455 can use the Date::Calc module.
456
457         use Date::Calc qw(Today Add_Delta_Days);
458
459         my @date = Add_Delta_Days( Today(), -1 );
460
461         print "@date\n";
462
463 Most people try to use the time rather than the calendar to
464 figure out dates, but that assumes that your days are
465 twenty-four hours each.  For most people, there are two days
466 a year when they aren't: the switch to and from summer time
467 throws this off. Russ Allbery offers this solution.
468
469     sub yesterday {
470                 my $now  = defined $_[0] ? $_[0] : time;
471                 my $then = $now - 60 * 60 * 24;
472                 my $ndst = (localtime $now)[8] > 0;
473                 my $tdst = (localtime $then)[8] > 0;
474                 $then - ($tdst - $ndst) * 60 * 60;
475                 }
476
477 Should give you "this time yesterday" in seconds since epoch relative to
478 the first argument or the current time if no argument is given and
479 suitable for passing to localtime or whatever else you need to do with
480 it.  $ndst is whether we're currently in daylight savings time; $tdst is
481 whether the point 24 hours ago was in daylight savings time.  If $tdst
482 and $ndst are the same, a boundary wasn't crossed, and the correction
483 will subtract 0.  If $tdst is 1 and $ndst is 0, subtract an hour more
484 from yesterday's time since we gained an extra hour while going off
485 daylight savings time.  If $tdst is 0 and $ndst is 1, subtract a
486 negative hour (add an hour) to yesterday's time since we lost an hour.
487
488 All of this is because during those days when one switches off or onto
489 DST, a "day" isn't 24 hours long; it's either 23 or 25.
490
491 The explicit settings of $ndst and $tdst are necessary because localtime
492 only says it returns the system tm struct, and the system tm struct at
493 least on Solaris doesn't guarantee any particular positive value (like,
494 say, 1) for isdst, just a positive value.  And that value can
495 potentially be negative, if DST information isn't available (this sub
496 just treats those cases like no DST).
497
498 Note that between 2am and 3am on the day after the time zone switches
499 off daylight savings time, the exact hour of "yesterday" corresponding
500 to the current hour is not clearly defined.  Note also that if used
501 between 2am and 3am the day after the change to daylight savings time,
502 the result will be between 3am and 4am of the previous day; it's
503 arguable whether this is correct.
504
505 This sub does not attempt to deal with leap seconds (most things don't).
506
507
508
509 =head2 Does Perl have a Year 2000 problem?  Is Perl Y2K compliant?
510
511 Short answer: No, Perl does not have a Year 2000 problem.  Yes, Perl is
512 Y2K compliant (whatever that means).  The programmers you've hired to
513 use it, however, probably are not.
514
515 Long answer: The question belies a true understanding of the issue.
516 Perl is just as Y2K compliant as your pencil--no more, and no less.
517 Can you use your pencil to write a non-Y2K-compliant memo?  Of course
518 you can.  Is that the pencil's fault?  Of course it isn't.
519
520 The date and time functions supplied with Perl (gmtime and localtime)
521 supply adequate information to determine the year well beyond 2000
522 (2038 is when trouble strikes for 32-bit machines).  The year returned
523 by these functions when used in a list context is the year minus 1900.
524 For years between 1910 and 1999 this I<happens> to be a 2-digit decimal
525 number. To avoid the year 2000 problem simply do not treat the year as
526 a 2-digit number.  It isn't.
527
528 When gmtime() and localtime() are used in scalar context they return
529 a timestamp string that contains a fully-expanded year.  For example,
530 C<$timestamp = gmtime(1005613200)> sets $timestamp to "Tue Nov 13 01:00:00
531 2001".  There's no year 2000 problem here.
532
533 That doesn't mean that Perl can't be used to create non-Y2K compliant
534 programs.  It can.  But so can your pencil.  It's the fault of the user,
535 not the language.  At the risk of inflaming the NRA: ``Perl doesn't
536 break Y2K, people do.''  See http://language.perl.com/news/y2k.html for
537 a longer exposition.
538
539 =head1 Data: Strings
540
541 =head2 How do I validate input?
542
543 The answer to this question is usually a regular expression, perhaps
544 with auxiliary logic.  See the more specific questions (numbers, mail
545 addresses, etc.) for details.
546
547 =head2 How do I unescape a string?
548
549 It depends just what you mean by ``escape''.  URL escapes are dealt
550 with in L<perlfaq9>.  Shell escapes with the backslash (C<\>)
551 character are removed with
552
553     s/\\(.)/$1/g;
554
555 This won't expand C<"\n"> or C<"\t"> or any other special escapes.
556
557 =head2 How do I remove consecutive pairs of characters?
558
559 To turn C<"abbcccd"> into C<"abccd">:
560
561     s/(.)\1/$1/g;       # add /s to include newlines
562
563 Here's a solution that turns "abbcccd" to "abcd":
564
565     y///cs;     # y == tr, but shorter :-)
566
567 =head2 How do I expand function calls in a string?
568
569 This is documented in L<perlref>.  In general, this is fraught with
570 quoting and readability problems, but it is possible.  To interpolate
571 a subroutine call (in list context) into a string:
572
573     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
574
575 See also ``How can I expand variables in text strings?'' in this
576 section of the FAQ.
577
578 =head2 How do I find matching/nesting anything?
579
580 This isn't something that can be done in one regular expression, no
581 matter how complicated.  To find something between two single
582 characters, a pattern like C</x([^x]*)x/> will get the intervening
583 bits in $1. For multiple ones, then something more like
584 C</alpha(.*?)omega/> would be needed.  But none of these deals with
585 nested patterns.  For balanced expressions using C<(>, C<{>, C<[>
586 or C<< < >> as delimiters, use the CPAN module Regexp::Common, or see
587 L<perlre/(??{ code })>.  For other cases, you'll have to write a parser.
588
589 If you are serious about writing a parser, there are a number of
590 modules or oddities that will make your life a lot easier.  There are
591 the CPAN modules Parse::RecDescent, Parse::Yapp, and Text::Balanced;
592 and the byacc program.   Starting from perl 5.8 the Text::Balanced
593 is part of the standard distribution.
594
595 One simple destructive, inside-out approach that you might try is to
596 pull out the smallest nesting parts one at a time:
597
598     while (s/BEGIN((?:(?!BEGIN)(?!END).)*)END//gs) {
599         # do something with $1
600     }
601
602 A more complicated and sneaky approach is to make Perl's regular
603 expression engine do it for you.  This is courtesy Dean Inada, and
604 rather has the nature of an Obfuscated Perl Contest entry, but it
605 really does work:
606
607     # $_ contains the string to parse
608     # BEGIN and END are the opening and closing markers for the
609     # nested text.
610
611     @( = ('(','');
612     @) = (')','');
613     ($re=$_)=~s/((BEGIN)|(END)|.)/$)[!$3]\Q$1\E$([!$2]/gs;
614     @$ = (eval{/$re/},$@!~/unmatched/i);
615     print join("\n",@$[0..$#$]) if( $$[-1] );
616
617 =head2 How do I reverse a string?
618
619 Use reverse() in scalar context, as documented in
620 L<perlfunc/reverse>.
621
622     $reversed = reverse $string;
623
624 =head2 How do I expand tabs in a string?
625
626 You can do it yourself:
627
628     1 while $string =~ s/\t+/' ' x (length($&) * 8 - length($`) % 8)/e;
629
630 Or you can just use the Text::Tabs module (part of the standard Perl
631 distribution).
632
633     use Text::Tabs;
634     @expanded_lines = expand(@lines_with_tabs);
635
636 =head2 How do I reformat a paragraph?
637
638 Use Text::Wrap (part of the standard Perl distribution):
639
640     use Text::Wrap;
641     print wrap("\t", '  ', @paragraphs);
642
643 The paragraphs you give to Text::Wrap should not contain embedded
644 newlines.  Text::Wrap doesn't justify the lines (flush-right).
645
646 Or use the CPAN module Text::Autoformat.  Formatting files can be easily
647 done by making a shell alias, like so:
648
649     alias fmt="perl -i -MText::Autoformat -n0777 \
650         -e 'print autoformat $_, {all=>1}' $*"
651
652 See the documentation for Text::Autoformat to appreciate its many
653 capabilities.
654
655 =head2 How can I access or change N characters of a string?
656
657 You can access the first characters of a string with substr().
658 To get the first character, for example, start at position 0
659 and grab the string of length 1.
660
661
662         $string = "Just another Perl Hacker";
663     $first_char = substr( $string, 0, 1 );  #  'J'
664
665 To change part of a string, you can use the optional fourth
666 argument which is the replacement string.
667
668     substr( $string, 13, 4, "Perl 5.8.0" );
669
670 You can also use substr() as an lvalue.
671
672     substr( $string, 13, 4 ) =  "Perl 5.8.0";
673
674 =head2 How do I change the Nth occurrence of something?
675
676 You have to keep track of N yourself.  For example, let's say you want
677 to change the fifth occurrence of C<"whoever"> or C<"whomever"> into
678 C<"whosoever"> or C<"whomsoever">, case insensitively.  These
679 all assume that $_ contains the string to be altered.
680
681     $count = 0;
682     s{((whom?)ever)}{
683         ++$count == 5           # is it the 5th?
684             ? "${2}soever"      # yes, swap
685             : $1                # renege and leave it there
686     }ige;
687
688 In the more general case, you can use the C</g> modifier in a C<while>
689 loop, keeping count of matches.
690
691     $WANT = 3;
692     $count = 0;
693     $_ = "One fish two fish red fish blue fish";
694     while (/(\w+)\s+fish\b/gi) {
695         if (++$count == $WANT) {
696             print "The third fish is a $1 one.\n";
697         }
698     }
699
700 That prints out: C<"The third fish is a red one.">  You can also use a
701 repetition count and repeated pattern like this:
702
703     /(?:\w+\s+fish\s+){2}(\w+)\s+fish/i;
704
705 =head2 How can I count the number of occurrences of a substring within a string?
706
707 There are a number of ways, with varying efficiency.  If you want a
708 count of a certain single character (X) within a string, you can use the
709 C<tr///> function like so:
710
711     $string = "ThisXlineXhasXsomeXx'sXinXit";
712     $count = ($string =~ tr/X//);
713     print "There are $count X characters in the string";
714
715 This is fine if you are just looking for a single character.  However,
716 if you are trying to count multiple character substrings within a
717 larger string, C<tr///> won't work.  What you can do is wrap a while()
718 loop around a global pattern match.  For example, let's count negative
719 integers:
720
721     $string = "-9 55 48 -2 23 -76 4 14 -44";
722     while ($string =~ /-\d+/g) { $count++ }
723     print "There are $count negative numbers in the string";
724
725 Another version uses a global match in list context, then assigns the
726 result to a scalar, producing a count of the number of matches.
727
728         $count = () = $string =~ /-\d+/g;
729
730 =head2 How do I capitalize all the words on one line?
731
732 To make the first letter of each word upper case:
733
734         $line =~ s/\b(\w)/\U$1/g;
735
736 This has the strange effect of turning "C<don't do it>" into "C<Don'T
737 Do It>".  Sometimes you might want this.  Other times you might need a
738 more thorough solution (Suggested by brian d foy):
739
740     $string =~ s/ (
741                  (^\w)    #at the beginning of the line
742                    |      # or
743                  (\s\w)   #preceded by whitespace
744                    )
745                 /\U$1/xg;
746     $string =~ /([\w']+)/\u\L$1/g;
747
748 To make the whole line upper case:
749
750         $line = uc($line);
751
752 To force each word to be lower case, with the first letter upper case:
753
754         $line =~ s/(\w+)/\u\L$1/g;
755
756 You can (and probably should) enable locale awareness of those
757 characters by placing a C<use locale> pragma in your program.
758 See L<perllocale> for endless details on locales.
759
760 This is sometimes referred to as putting something into "title
761 case", but that's not quite accurate.  Consider the proper
762 capitalization of the movie I<Dr. Strangelove or: How I Learned to
763 Stop Worrying and Love the Bomb>, for example.
764
765 =head2 How can I split a [character] delimited string except when inside [character]?
766
767 Several modules can handle this sort of pasing---Text::Balanced,
768 Text::CVS, Text::CVS_XS, and Text::ParseWords, among others.
769
770 Take the example case of trying to split a string that is
771 comma-separated into its different fields. You can't use C<split(/,/)>
772 because you shouldn't split if the comma is inside quotes.  For
773 example, take a data line like this:
774
775     SAR001,"","Cimetrix, Inc","Bob Smith","CAM",N,8,1,0,7,"Error, Core Dumped"
776
777 Due to the restriction of the quotes, this is a fairly complex
778 problem.  Thankfully, we have Jeffrey Friedl, author of
779 I<Mastering Regular Expressions>, to handle these for us.  He
780 suggests (assuming your string is contained in $text):
781
782      @new = ();
783      push(@new, $+) while $text =~ m{
784          "([^\"\\]*(?:\\.[^\"\\]*)*)",?  # groups the phrase inside the quotes
785        | ([^,]+),?
786        | ,
787      }gx;
788      push(@new, undef) if substr($text,-1,1) eq ',';
789
790 If you want to represent quotation marks inside a
791 quotation-mark-delimited field, escape them with backslashes (eg,
792 C<"like \"this\"">.
793
794 Alternatively, the Text::ParseWords module (part of the standard Perl
795 distribution) lets you say:
796
797     use Text::ParseWords;
798     @new = quotewords(",", 0, $text);
799
800 There's also a Text::CSV (Comma-Separated Values) module on CPAN.
801
802 =head2 How do I strip blank space from the beginning/end of a string?
803
804 Although the simplest approach would seem to be
805
806     $string =~ s/^\s*(.*?)\s*$/$1/;
807
808 not only is this unnecessarily slow and destructive, it also fails with
809 embedded newlines.  It is much faster to do this operation in two steps:
810
811     $string =~ s/^\s+//;
812     $string =~ s/\s+$//;
813
814 Or more nicely written as:
815
816     for ($string) {
817         s/^\s+//;
818         s/\s+$//;
819     }
820
821 This idiom takes advantage of the C<foreach> loop's aliasing
822 behavior to factor out common code.  You can do this
823 on several strings at once, or arrays, or even the
824 values of a hash if you use a slice:
825
826     # trim whitespace in the scalar, the array,
827     # and all the values in the hash
828     foreach ($scalar, @array, @hash{keys %hash}) {
829         s/^\s+//;
830         s/\s+$//;
831     }
832
833 =head2 How do I pad a string with blanks or pad a number with zeroes?
834
835 In the following examples, C<$pad_len> is the length to which you wish
836 to pad the string, C<$text> or C<$num> contains the string to be padded,
837 and C<$pad_char> contains the padding character. You can use a single
838 character string constant instead of the C<$pad_char> variable if you
839 know what it is in advance. And in the same way you can use an integer in
840 place of C<$pad_len> if you know the pad length in advance.
841
842 The simplest method uses the C<sprintf> function. It can pad on the left
843 or right with blanks and on the left with zeroes and it will not
844 truncate the result. The C<pack> function can only pad strings on the
845 right with blanks and it will truncate the result to a maximum length of
846 C<$pad_len>.
847
848     # Left padding a string with blanks (no truncation):
849         $padded = sprintf("%${pad_len}s", $text);
850         $padded = sprintf("%*s", $pad_len, $text);  # same thing
851
852     # Right padding a string with blanks (no truncation):
853         $padded = sprintf("%-${pad_len}s", $text);
854         $padded = sprintf("%-*s", $pad_len, $text); # same thing
855
856     # Left padding a number with 0 (no truncation):
857         $padded = sprintf("%0${pad_len}d", $num);
858         $padded = sprintf("%0*d", $pad_len, $num); # same thing
859
860     # Right padding a string with blanks using pack (will truncate):
861     $padded = pack("A$pad_len",$text);
862
863 If you need to pad with a character other than blank or zero you can use
864 one of the following methods.  They all generate a pad string with the
865 C<x> operator and combine that with C<$text>. These methods do
866 not truncate C<$text>.
867
868 Left and right padding with any character, creating a new string:
869
870     $padded = $pad_char x ( $pad_len - length( $text ) ) . $text;
871     $padded = $text . $pad_char x ( $pad_len - length( $text ) );
872
873 Left and right padding with any character, modifying C<$text> directly:
874
875     substr( $text, 0, 0 ) = $pad_char x ( $pad_len - length( $text ) );
876     $text .= $pad_char x ( $pad_len - length( $text ) );
877
878 =head2 How do I extract selected columns from a string?
879
880 Use substr() or unpack(), both documented in L<perlfunc>.
881 If you prefer thinking in terms of columns instead of widths,
882 you can use this kind of thing:
883
884     # determine the unpack format needed to split Linux ps output
885     # arguments are cut columns
886     my $fmt = cut2fmt(8, 14, 20, 26, 30, 34, 41, 47, 59, 63, 67, 72);
887
888     sub cut2fmt {
889         my(@positions) = @_;
890         my $template  = '';
891         my $lastpos   = 1;
892         for my $place (@positions) {
893             $template .= "A" . ($place - $lastpos) . " ";
894             $lastpos   = $place;
895         }
896         $template .= "A*";
897         return $template;
898     }
899
900 =head2 How do I find the soundex value of a string?
901
902 Use the standard Text::Soundex module distributed with Perl.
903 Before you do so, you may want to determine whether `soundex' is in
904 fact what you think it is.  Knuth's soundex algorithm compresses words
905 into a small space, and so it does not necessarily distinguish between
906 two words which you might want to appear separately.  For example, the
907 last names `Knuth' and `Kant' are both mapped to the soundex code K530.
908 If Text::Soundex does not do what you are looking for, you might want
909 to consider the String::Approx module available at CPAN.
910
911 =head2 How can I expand variables in text strings?
912
913 Let's assume that you have a string like:
914
915     $text = 'this has a $foo in it and a $bar';
916
917 If those were both global variables, then this would
918 suffice:
919
920     $text =~ s/\$(\w+)/${$1}/g;  # no /e needed
921
922 But since they are probably lexicals, or at least, they could
923 be, you'd have to do this:
924
925     $text =~ s/(\$\w+)/$1/eeg;
926     die if $@;                  # needed /ee, not /e
927
928 It's probably better in the general case to treat those
929 variables as entries in some special hash.  For example:
930
931     %user_defs = (
932         foo  => 23,
933         bar  => 19,
934     );
935     $text =~ s/\$(\w+)/$user_defs{$1}/g;
936
937 See also ``How do I expand function calls in a string?'' in this section
938 of the FAQ.
939
940 =head2 What's wrong with always quoting "$vars"?
941
942 The problem is that those double-quotes force stringification--
943 coercing numbers and references into strings--even when you
944 don't want them to be strings.  Think of it this way: double-quote
945 expansion is used to produce new strings.  If you already
946 have a string, why do you need more?
947
948 If you get used to writing odd things like these:
949
950     print "$var";       # BAD
951     $new = "$old";      # BAD
952     somefunc("$var");   # BAD
953
954 You'll be in trouble.  Those should (in 99.8% of the cases) be
955 the simpler and more direct:
956
957     print $var;
958     $new = $old;
959     somefunc($var);
960
961 Otherwise, besides slowing you down, you're going to break code when
962 the thing in the scalar is actually neither a string nor a number, but
963 a reference:
964
965     func(\@array);
966     sub func {
967         my $aref = shift;
968         my $oref = "$aref";  # WRONG
969     }
970
971 You can also get into subtle problems on those few operations in Perl
972 that actually do care about the difference between a string and a
973 number, such as the magical C<++> autoincrement operator or the
974 syscall() function.
975
976 Stringification also destroys arrays.
977
978     @lines = `command`;
979     print "@lines";             # WRONG - extra blanks
980     print @lines;               # right
981
982 =head2 Why don't my E<lt>E<lt>HERE documents work?
983
984 Check for these three things:
985
986 =over 4
987
988 =item There must be no space after the E<lt>E<lt> part.
989
990 =item There (probably) should be a semicolon at the end.
991
992 =item You can't (easily) have any space in front of the tag.
993
994 =back
995
996 If you want to indent the text in the here document, you
997 can do this:
998
999     # all in one
1000     ($VAR = <<HERE_TARGET) =~ s/^\s+//gm;
1001         your text
1002         goes here
1003     HERE_TARGET
1004
1005 But the HERE_TARGET must still be flush against the margin.
1006 If you want that indented also, you'll have to quote
1007 in the indentation.
1008
1009     ($quote = <<'    FINIS') =~ s/^\s+//gm;
1010             ...we will have peace, when you and all your works have
1011             perished--and the works of your dark master to whom you
1012             would deliver us. You are a liar, Saruman, and a corrupter
1013             of men's hearts.  --Theoden in /usr/src/perl/taint.c
1014         FINIS
1015     $quote =~ s/\s+--/\n--/;
1016
1017 A nice general-purpose fixer-upper function for indented here documents
1018 follows.  It expects to be called with a here document as its argument.
1019 It looks to see whether each line begins with a common substring, and
1020 if so, strips that substring off.  Otherwise, it takes the amount of leading
1021 whitespace found on the first line and removes that much off each
1022 subsequent line.
1023
1024     sub fix {
1025         local $_ = shift;
1026         my ($white, $leader);  # common whitespace and common leading string
1027         if (/^\s*(?:([^\w\s]+)(\s*).*\n)(?:\s*\1\2?.*\n)+$/) {
1028             ($white, $leader) = ($2, quotemeta($1));
1029         } else {
1030             ($white, $leader) = (/^(\s+)/, '');
1031         }
1032         s/^\s*?$leader(?:$white)?//gm;
1033         return $_;
1034     }
1035
1036 This works with leading special strings, dynamically determined:
1037
1038     $remember_the_main = fix<<'    MAIN_INTERPRETER_LOOP';
1039         @@@ int
1040         @@@ runops() {
1041         @@@     SAVEI32(runlevel);
1042         @@@     runlevel++;
1043         @@@     while ( op = (*op->op_ppaddr)() );
1044         @@@     TAINT_NOT;
1045         @@@     return 0;
1046         @@@ }
1047     MAIN_INTERPRETER_LOOP
1048
1049 Or with a fixed amount of leading whitespace, with remaining
1050 indentation correctly preserved:
1051
1052     $poem = fix<<EVER_ON_AND_ON;
1053        Now far ahead the Road has gone,
1054           And I must follow, if I can,
1055        Pursuing it with eager feet,
1056           Until it joins some larger way
1057        Where many paths and errands meet.
1058           And whither then? I cannot say.
1059                 --Bilbo in /usr/src/perl/pp_ctl.c
1060     EVER_ON_AND_ON
1061
1062 =head1 Data: Arrays
1063
1064 =head2 What is the difference between a list and an array?
1065
1066 An array has a changeable length.  A list does not.  An array is something
1067 you can push or pop, while a list is a set of values.  Some people make
1068 the distinction that a list is a value while an array is a variable.
1069 Subroutines are passed and return lists, you put things into list
1070 context, you initialize arrays with lists, and you foreach() across
1071 a list.  C<@> variables are arrays, anonymous arrays are arrays, arrays
1072 in scalar context behave like the number of elements in them, subroutines
1073 access their arguments through the array C<@_>, and push/pop/shift only work
1074 on arrays.
1075
1076 As a side note, there's no such thing as a list in scalar context.
1077 When you say
1078
1079     $scalar = (2, 5, 7, 9);
1080
1081 you're using the comma operator in scalar context, so it uses the scalar
1082 comma operator.  There never was a list there at all!  This causes the
1083 last value to be returned: 9.
1084
1085 =head2 What is the difference between $array[1] and @array[1]?
1086
1087 The former is a scalar value; the latter an array slice, making
1088 it a list with one (scalar) value.  You should use $ when you want a
1089 scalar value (most of the time) and @ when you want a list with one
1090 scalar value in it (very, very rarely; nearly never, in fact).
1091
1092 Sometimes it doesn't make a difference, but sometimes it does.
1093 For example, compare:
1094
1095     $good[0] = `some program that outputs several lines`;
1096
1097 with
1098
1099     @bad[0]  = `same program that outputs several lines`;
1100
1101 The C<use warnings> pragma and the B<-w> flag will warn you about these
1102 matters.
1103
1104 =head2 How can I remove duplicate elements from a list or array?
1105
1106 There are several possible ways, depending on whether the array is
1107 ordered and whether you wish to preserve the ordering.
1108
1109 =over 4
1110
1111 =item a)
1112
1113 If @in is sorted, and you want @out to be sorted:
1114 (this assumes all true values in the array)
1115
1116     $prev = "not equal to $in[0]";
1117     @out = grep($_ ne $prev && ($prev = $_, 1), @in);
1118
1119 This is nice in that it doesn't use much extra memory, simulating
1120 uniq(1)'s behavior of removing only adjacent duplicates.  The ", 1"
1121 guarantees that the expression is true (so that grep picks it up)
1122 even if the $_ is 0, "", or undef.
1123
1124 =item b)
1125
1126 If you don't know whether @in is sorted:
1127
1128     undef %saw;
1129     @out = grep(!$saw{$_}++, @in);
1130
1131 =item c)
1132
1133 Like (b), but @in contains only small integers:
1134
1135     @out = grep(!$saw[$_]++, @in);
1136
1137 =item d)
1138
1139 A way to do (b) without any loops or greps:
1140
1141     undef %saw;
1142     @saw{@in} = ();
1143     @out = sort keys %saw;  # remove sort if undesired
1144
1145 =item e)
1146
1147 Like (d), but @in contains only small positive integers:
1148
1149     undef @ary;
1150     @ary[@in] = @in;
1151     @out = grep {defined} @ary;
1152
1153 =back
1154
1155 But perhaps you should have been using a hash all along, eh?
1156
1157 =head2 How can I tell whether a certain element is contained in a list or array?
1158
1159 Hearing the word "in" is an I<in>dication that you probably should have
1160 used a hash, not a list or array, to store your data.  Hashes are
1161 designed to answer this question quickly and efficiently.  Arrays aren't.
1162
1163 That being said, there are several ways to approach this.  If you
1164 are going to make this query many times over arbitrary string values,
1165 the fastest way is probably to invert the original array and maintain a
1166 hash whose keys are the first array's values.
1167
1168     @blues = qw/azure cerulean teal turquoise lapis-lazuli/;
1169     %is_blue = ();
1170     for (@blues) { $is_blue{$_} = 1 }
1171
1172 Now you can check whether $is_blue{$some_color}.  It might have been a
1173 good idea to keep the blues all in a hash in the first place.
1174
1175 If the values are all small integers, you could use a simple indexed
1176 array.  This kind of an array will take up less space:
1177
1178     @primes = (2, 3, 5, 7, 11, 13, 17, 19, 23, 29, 31);
1179     @is_tiny_prime = ();
1180     for (@primes) { $is_tiny_prime[$_] = 1 }
1181     # or simply  @istiny_prime[@primes] = (1) x @primes;
1182
1183 Now you check whether $is_tiny_prime[$some_number].
1184
1185 If the values in question are integers instead of strings, you can save
1186 quite a lot of space by using bit strings instead:
1187
1188     @articles = ( 1..10, 150..2000, 2017 );
1189     undef $read;
1190     for (@articles) { vec($read,$_,1) = 1 }
1191
1192 Now check whether C<vec($read,$n,1)> is true for some C<$n>.
1193
1194 Please do not use
1195
1196     ($is_there) = grep $_ eq $whatever, @array;
1197
1198 or worse yet
1199
1200     ($is_there) = grep /$whatever/, @array;
1201
1202 These are slow (checks every element even if the first matches),
1203 inefficient (same reason), and potentially buggy (what if there are
1204 regex characters in $whatever?).  If you're only testing once, then
1205 use:
1206
1207     $is_there = 0;
1208     foreach $elt (@array) {
1209         if ($elt eq $elt_to_find) {
1210             $is_there = 1;
1211             last;
1212         }
1213     }
1214     if ($is_there) { ... }
1215
1216 =head2 How do I compute the difference of two arrays?  How do I compute the intersection of two arrays?
1217
1218 Use a hash.  Here's code to do both and more.  It assumes that
1219 each element is unique in a given array:
1220
1221     @union = @intersection = @difference = ();
1222     %count = ();
1223     foreach $element (@array1, @array2) { $count{$element}++ }
1224     foreach $element (keys %count) {
1225         push @union, $element;
1226         push @{ $count{$element} > 1 ? \@intersection : \@difference }, $element;
1227     }
1228
1229 Note that this is the I<symmetric difference>, that is, all elements in
1230 either A or in B but not in both.  Think of it as an xor operation.
1231
1232 =head2 How do I test whether two arrays or hashes are equal?
1233
1234 The following code works for single-level arrays.  It uses a stringwise
1235 comparison, and does not distinguish defined versus undefined empty
1236 strings.  Modify if you have other needs.
1237
1238     $are_equal = compare_arrays(\@frogs, \@toads);
1239
1240     sub compare_arrays {
1241         my ($first, $second) = @_;
1242         no warnings;  # silence spurious -w undef complaints
1243         return 0 unless @$first == @$second;
1244         for (my $i = 0; $i < @$first; $i++) {
1245             return 0 if $first->[$i] ne $second->[$i];
1246         }
1247         return 1;
1248     }
1249
1250 For multilevel structures, you may wish to use an approach more
1251 like this one.  It uses the CPAN module FreezeThaw:
1252
1253     use FreezeThaw qw(cmpStr);
1254     @a = @b = ( "this", "that", [ "more", "stuff" ] );
1255
1256     printf "a and b contain %s arrays\n",
1257         cmpStr(\@a, \@b) == 0
1258             ? "the same"
1259             : "different";
1260
1261 This approach also works for comparing hashes.  Here
1262 we'll demonstrate two different answers:
1263
1264     use FreezeThaw qw(cmpStr cmpStrHard);
1265
1266     %a = %b = ( "this" => "that", "extra" => [ "more", "stuff" ] );
1267     $a{EXTRA} = \%b;
1268     $b{EXTRA} = \%a;
1269
1270     printf "a and b contain %s hashes\n",
1271         cmpStr(\%a, \%b) == 0 ? "the same" : "different";
1272
1273     printf "a and b contain %s hashes\n",
1274         cmpStrHard(\%a, \%b) == 0 ? "the same" : "different";
1275
1276
1277 The first reports that both those the hashes contain the same data,
1278 while the second reports that they do not.  Which you prefer is left as
1279 an exercise to the reader.
1280
1281 =head2 How do I find the first array element for which a condition is true?
1282
1283 To find the first array element which satisfies a condition, you can
1284 use the first() function in the List::Util module, which comes with
1285 Perl 5.8.  This example finds the first element that contains "Perl".
1286
1287         use List::Util qw(first);
1288
1289         my $element = first { /Perl/ } @array;
1290
1291 If you cannot use List::Util, you can make your own loop to do the
1292 same thing.  Once you find the element, you stop the loop with last.
1293
1294         my $found;
1295         foreach my $element ( @array )
1296                 {
1297                 if( /Perl/ ) { $found = $element; last }
1298                 }
1299
1300 If you want the array index, you can iterate through the indices
1301 and check the array element at each index until you find one
1302 that satisfies the condition.
1303
1304         my( $found, $index ) = ( undef, -1 );
1305     for( $i = 0; $i < @array; $i++ )
1306         {
1307         if( $array[$i] =~ /Perl/ )
1308                 {
1309                 $found = $array[$i];
1310                 $index = $i;
1311                 last;
1312                 }
1313         }
1314
1315 =head2 How do I handle linked lists?
1316
1317 In general, you usually don't need a linked list in Perl, since with
1318 regular arrays, you can push and pop or shift and unshift at either end,
1319 or you can use splice to add and/or remove arbitrary number of elements at
1320 arbitrary points.  Both pop and shift are both O(1) operations on Perl's
1321 dynamic arrays.  In the absence of shifts and pops, push in general
1322 needs to reallocate on the order every log(N) times, and unshift will
1323 need to copy pointers each time.
1324
1325 If you really, really wanted, you could use structures as described in
1326 L<perldsc> or L<perltoot> and do just what the algorithm book tells you
1327 to do.  For example, imagine a list node like this:
1328
1329     $node = {
1330         VALUE => 42,
1331         LINK  => undef,
1332     };
1333
1334 You could walk the list this way:
1335
1336     print "List: ";
1337     for ($node = $head;  $node; $node = $node->{LINK}) {
1338         print $node->{VALUE}, " ";
1339     }
1340     print "\n";
1341
1342 You could add to the list this way:
1343
1344     my ($head, $tail);
1345     $tail = append($head, 1);       # grow a new head
1346     for $value ( 2 .. 10 ) {
1347         $tail = append($tail, $value);
1348     }
1349
1350     sub append {
1351         my($list, $value) = @_;
1352         my $node = { VALUE => $value };
1353         if ($list) {
1354             $node->{LINK} = $list->{LINK};
1355             $list->{LINK} = $node;
1356         } else {
1357             $_[0] = $node;      # replace caller's version
1358         }
1359         return $node;
1360     }
1361
1362 But again, Perl's built-in are virtually always good enough.
1363
1364 =head2 How do I handle circular lists?
1365
1366 Circular lists could be handled in the traditional fashion with linked
1367 lists, or you could just do something like this with an array:
1368
1369     unshift(@array, pop(@array));  # the last shall be first
1370     push(@array, shift(@array));   # and vice versa
1371
1372 =head2 How do I shuffle an array randomly?
1373
1374 If you either have Perl 5.8.0 or later installed, or if you have
1375 Scalar-List-Utils 1.03 or later installed, you can say:
1376
1377     use List::Util 'shuffle';
1378
1379         @shuffled = shuffle(@list);
1380
1381 If not, you can use a Fisher-Yates shuffle.
1382
1383     sub fisher_yates_shuffle {
1384         my $deck = shift;  # $deck is a reference to an array
1385         my $i = @$deck;
1386         while ($i--) {
1387             my $j = int rand ($i+1);
1388             @$deck[$i,$j] = @$deck[$j,$i];
1389         }
1390     }
1391
1392     # shuffle my mpeg collection
1393     #
1394     my @mpeg = <audio/*/*.mp3>;
1395     fisher_yates_shuffle( \@mpeg );    # randomize @mpeg in place
1396     print @mpeg;
1397
1398 Note that the above implementation shuffles an array in place,
1399 unlike the List::Util::shuffle() which takes a list and returns
1400 a new shuffled list.
1401
1402 You've probably seen shuffling algorithms that work using splice,
1403 randomly picking another element to swap the current element with
1404
1405     srand;
1406     @new = ();
1407     @old = 1 .. 10;  # just a demo
1408     while (@old) {
1409         push(@new, splice(@old, rand @old, 1));
1410     }
1411
1412 This is bad because splice is already O(N), and since you do it N times,
1413 you just invented a quadratic algorithm; that is, O(N**2).  This does
1414 not scale, although Perl is so efficient that you probably won't notice
1415 this until you have rather largish arrays.
1416
1417 =head2 How do I process/modify each element of an array?
1418
1419 Use C<for>/C<foreach>:
1420
1421     for (@lines) {
1422         s/foo/bar/;     # change that word
1423         y/XZ/ZX/;       # swap those letters
1424     }
1425
1426 Here's another; let's compute spherical volumes:
1427
1428     for (@volumes = @radii) {   # @volumes has changed parts
1429         $_ **= 3;
1430         $_ *= (4/3) * 3.14159;  # this will be constant folded
1431     }
1432
1433 which can also be done with map() which is made to transform
1434 one list into another:
1435
1436         @volumes = map {$_ ** 3 * (4/3) * 3.14159} @radii;
1437
1438 If you want to do the same thing to modify the values of the
1439 hash, you can use the C<values> function.  As of Perl 5.6
1440 the values are not copied, so if you modify $orbit (in this
1441 case), you modify the value.
1442
1443     for $orbit ( values %orbits ) {
1444         ($orbit **= 3) *= (4/3) * 3.14159;
1445     }
1446
1447 Prior to perl 5.6 C<values> returned copies of the values,
1448 so older perl code often contains constructions such as
1449 C<@orbits{keys %orbits}> instead of C<values %orbits> where
1450 the hash is to be modified.
1451
1452 =head2 How do I select a random element from an array?
1453
1454 Use the rand() function (see L<perlfunc/rand>):
1455
1456     # at the top of the program:
1457     srand;                      # not needed for 5.004 and later
1458
1459     # then later on
1460     $index   = rand @array;
1461     $element = $array[$index];
1462
1463 Make sure you I<only call srand once per program, if then>.
1464 If you are calling it more than once (such as before each
1465 call to rand), you're almost certainly doing something wrong.
1466
1467 =head2 How do I permute N elements of a list?
1468
1469 Use the List::Permutor module on CPAN.  If the list is
1470 actually an array, try the Algorithm::Permute module (also
1471 on CPAN).  It's written in XS code and is very efficient.
1472
1473         use Algorithm::Permute;
1474         my @array = 'a'..'d';
1475         my $p_iterator = Algorithm::Permute->new ( \@array );
1476         while (my @perm = $p_iterator->next) {
1477            print "next permutation: (@perm)\n";
1478         }
1479
1480 For even faster execution, you could do:
1481
1482    use Algorithm::Permute;
1483    my @array = 'a'..'d';
1484    Algorithm::Permute::permute {
1485       print "next permutation: (@array)\n";
1486    } @array;
1487
1488 Here's a little program that generates all permutations of
1489 all the words on each line of input. The algorithm embodied
1490 in the permute() function is discussed in Volume 4 (still
1491 unpublished) of Knuth's I<The Art of Computer Programming>
1492 and will work on any list:
1493
1494         #!/usr/bin/perl -n
1495         # Fischer-Kause ordered permutation generator
1496
1497         sub permute (&@) {
1498                 my $code = shift;
1499                 my @idx = 0..$#_;
1500                 while ( $code->(@_[@idx]) ) {
1501                         my $p = $#idx;
1502                         --$p while $idx[$p-1] > $idx[$p];
1503                         my $q = $p or return;
1504                         push @idx, reverse splice @idx, $p;
1505                         ++$q while $idx[$p-1] > $idx[$q];
1506                         @idx[$p-1,$q]=@idx[$q,$p-1];
1507                 }
1508         }
1509
1510         permute {print"@_\n"} split;
1511
1512 =head2 How do I sort an array by (anything)?
1513
1514 Supply a comparison function to sort() (described in L<perlfunc/sort>):
1515
1516     @list = sort { $a <=> $b } @list;
1517
1518 The default sort function is cmp, string comparison, which would
1519 sort C<(1, 2, 10)> into C<(1, 10, 2)>.  C<< <=> >>, used above, is
1520 the numerical comparison operator.
1521
1522 If you have a complicated function needed to pull out the part you
1523 want to sort on, then don't do it inside the sort function.  Pull it
1524 out first, because the sort BLOCK can be called many times for the
1525 same element.  Here's an example of how to pull out the first word
1526 after the first number on each item, and then sort those words
1527 case-insensitively.
1528
1529     @idx = ();
1530     for (@data) {
1531         ($item) = /\d+\s*(\S+)/;
1532         push @idx, uc($item);
1533     }
1534     @sorted = @data[ sort { $idx[$a] cmp $idx[$b] } 0 .. $#idx ];
1535
1536 which could also be written this way, using a trick
1537 that's come to be known as the Schwartzian Transform:
1538
1539     @sorted = map  { $_->[0] }
1540               sort { $a->[1] cmp $b->[1] }
1541               map  { [ $_, uc( (/\d+\s*(\S+)/)[0]) ] } @data;
1542
1543 If you need to sort on several fields, the following paradigm is useful.
1544
1545     @sorted = sort { field1($a) <=> field1($b) ||
1546                      field2($a) cmp field2($b) ||
1547                      field3($a) cmp field3($b)
1548                    }     @data;
1549
1550 This can be conveniently combined with precalculation of keys as given
1551 above.
1552
1553 See the F<sort> artitcle article in the "Far More Than You Ever Wanted
1554 To Know" collection in http://www.cpan.org/misc/olddoc/FMTEYEWTK.tgz for
1555 more about this approach.
1556
1557 See also the question below on sorting hashes.
1558
1559 =head2 How do I manipulate arrays of bits?
1560
1561 Use pack() and unpack(), or else vec() and the bitwise operations.
1562
1563 For example, this sets $vec to have bit N set if $ints[N] was set:
1564
1565     $vec = '';
1566     foreach(@ints) { vec($vec,$_,1) = 1 }
1567
1568 Here's how, given a vector in $vec, you can
1569 get those bits into your @ints array:
1570
1571     sub bitvec_to_list {
1572         my $vec = shift;
1573         my @ints;
1574         # Find null-byte density then select best algorithm
1575         if ($vec =~ tr/\0// / length $vec > 0.95) {
1576             use integer;
1577             my $i;
1578             # This method is faster with mostly null-bytes
1579             while($vec =~ /[^\0]/g ) {
1580                 $i = -9 + 8 * pos $vec;
1581                 push @ints, $i if vec($vec, ++$i, 1);
1582                 push @ints, $i if vec($vec, ++$i, 1);
1583                 push @ints, $i if vec($vec, ++$i, 1);
1584                 push @ints, $i if vec($vec, ++$i, 1);
1585                 push @ints, $i if vec($vec, ++$i, 1);
1586                 push @ints, $i if vec($vec, ++$i, 1);
1587                 push @ints, $i if vec($vec, ++$i, 1);
1588                 push @ints, $i if vec($vec, ++$i, 1);
1589             }
1590         } else {
1591             # This method is a fast general algorithm
1592             use integer;
1593             my $bits = unpack "b*", $vec;
1594             push @ints, 0 if $bits =~ s/^(\d)// && $1;
1595             push @ints, pos $bits while($bits =~ /1/g);
1596         }
1597         return \@ints;
1598     }
1599
1600 This method gets faster the more sparse the bit vector is.
1601 (Courtesy of Tim Bunce and Winfried Koenig.)
1602
1603 You can make the while loop a lot shorter with this suggestion
1604 from Benjamin Goldberg:
1605
1606         while($vec =~ /[^\0]+/g ) {
1607            push @ints, grep vec($vec, $_, 1), $-[0] * 8 .. $+[0] * 8;
1608         }
1609
1610 Or use the CPAN module Bit::Vector:
1611
1612     $vector = Bit::Vector->new($num_of_bits);
1613     $vector->Index_List_Store(@ints);
1614     @ints = $vector->Index_List_Read();
1615
1616 Bit::Vector provides efficient methods for bit vector, sets of small integers
1617 and "big int" math.
1618
1619 Here's a more extensive illustration using vec():
1620
1621     # vec demo
1622     $vector = "\xff\x0f\xef\xfe";
1623     print "Ilya's string \\xff\\x0f\\xef\\xfe represents the number ",
1624         unpack("N", $vector), "\n";
1625     $is_set = vec($vector, 23, 1);
1626     print "Its 23rd bit is ", $is_set ? "set" : "clear", ".\n";
1627     pvec($vector);
1628
1629     set_vec(1,1,1);
1630     set_vec(3,1,1);
1631     set_vec(23,1,1);
1632
1633     set_vec(3,1,3);
1634     set_vec(3,2,3);
1635     set_vec(3,4,3);
1636     set_vec(3,4,7);
1637     set_vec(3,8,3);
1638     set_vec(3,8,7);
1639
1640     set_vec(0,32,17);
1641     set_vec(1,32,17);
1642
1643     sub set_vec {
1644         my ($offset, $width, $value) = @_;
1645         my $vector = '';
1646         vec($vector, $offset, $width) = $value;
1647         print "offset=$offset width=$width value=$value\n";
1648         pvec($vector);
1649     }
1650
1651     sub pvec {
1652         my $vector = shift;
1653         my $bits = unpack("b*", $vector);
1654         my $i = 0;
1655         my $BASE = 8;
1656
1657         print "vector length in bytes: ", length($vector), "\n";
1658         @bytes = unpack("A8" x length($vector), $bits);
1659         print "bits are: @bytes\n\n";
1660     }
1661
1662 =head2 Why does defined() return true on empty arrays and hashes?
1663
1664 The short story is that you should probably only use defined on scalars or
1665 functions, not on aggregates (arrays and hashes).  See L<perlfunc/defined>
1666 in the 5.004 release or later of Perl for more detail.
1667
1668 =head1 Data: Hashes (Associative Arrays)
1669
1670 =head2 How do I process an entire hash?
1671
1672 Use the each() function (see L<perlfunc/each>) if you don't care
1673 whether it's sorted:
1674
1675     while ( ($key, $value) = each %hash) {
1676         print "$key = $value\n";
1677     }
1678
1679 If you want it sorted, you'll have to use foreach() on the result of
1680 sorting the keys as shown in an earlier question.
1681
1682 =head2 What happens if I add or remove keys from a hash while iterating over it?
1683
1684 Don't do that. :-)
1685
1686 [lwall] In Perl 4, you were not allowed to modify a hash at all while
1687 iterating over it.  In Perl 5 you can delete from it, but you still
1688 can't add to it, because that might cause a doubling of the hash table,
1689 in which half the entries get copied up to the new top half of the
1690 table, at which point you've totally bamboozled the iterator code.
1691 Even if the table doesn't double, there's no telling whether your new
1692 entry will be inserted before or after the current iterator position.
1693
1694 Either treasure up your changes and make them after the iterator finishes
1695 or use keys to fetch all the old keys at once, and iterate over the list
1696 of keys.
1697
1698 =head2 How do I look up a hash element by value?
1699
1700 Create a reverse hash:
1701
1702     %by_value = reverse %by_key;
1703     $key = $by_value{$value};
1704
1705 That's not particularly efficient.  It would be more space-efficient
1706 to use:
1707
1708     while (($key, $value) = each %by_key) {
1709         $by_value{$value} = $key;
1710     }
1711
1712 If your hash could have repeated values, the methods above will only find
1713 one of the associated keys.   This may or may not worry you.  If it does
1714 worry you, you can always reverse the hash into a hash of arrays instead:
1715
1716      while (($key, $value) = each %by_key) {
1717          push @{$key_list_by_value{$value}}, $key;
1718      }
1719
1720 =head2 How can I know how many entries are in a hash?
1721
1722 If you mean how many keys, then all you have to do is
1723 use the keys() function in a scalar context:
1724
1725     $num_keys = keys %hash;
1726
1727 The keys() function also resets the iterator, which means that you may
1728 see strange results if you use this between uses of other hash operators
1729 such as each().
1730
1731 =head2 How do I sort a hash (optionally by value instead of key)?
1732
1733 Internally, hashes are stored in a way that prevents you from imposing
1734 an order on key-value pairs.  Instead, you have to sort a list of the
1735 keys or values:
1736
1737     @keys = sort keys %hash;    # sorted by key
1738     @keys = sort {
1739                     $hash{$a} cmp $hash{$b}
1740             } keys %hash;       # and by value
1741
1742 Here we'll do a reverse numeric sort by value, and if two keys are
1743 identical, sort by length of key, or if that fails, by straight ASCII
1744 comparison of the keys (well, possibly modified by your locale--see
1745 L<perllocale>).
1746
1747     @keys = sort {
1748                 $hash{$b} <=> $hash{$a}
1749                           ||
1750                 length($b) <=> length($a)
1751                           ||
1752                       $a cmp $b
1753     } keys %hash;
1754
1755 =head2 How can I always keep my hash sorted?
1756
1757 You can look into using the DB_File module and tie() using the
1758 $DB_BTREE hash bindings as documented in L<DB_File/"In Memory Databases">.
1759 The Tie::IxHash module from CPAN might also be instructive.
1760
1761 =head2 What's the difference between "delete" and "undef" with hashes?
1762
1763 Hashes contain pairs of scalars: the first is the key, the
1764 second is the value.  The key will be coerced to a string,
1765 although the value can be any kind of scalar: string,
1766 number, or reference.  If a key $key is present in
1767 %hash, C<exists($hash{$key})> will return true.  The value
1768 for a given key can be C<undef>, in which case
1769 C<$hash{$key}> will be C<undef> while C<exists $hash{$key}>
1770 will return true.  This corresponds to (C<$key>, C<undef>)
1771 being in the hash.
1772
1773 Pictures help...  here's the %hash table:
1774
1775           keys  values
1776         +------+------+
1777         |  a   |  3   |
1778         |  x   |  7   |
1779         |  d   |  0   |
1780         |  e   |  2   |
1781         +------+------+
1782
1783 And these conditions hold
1784
1785         $hash{'a'}                       is true
1786         $hash{'d'}                       is false
1787         defined $hash{'d'}               is true
1788         defined $hash{'a'}               is true
1789         exists $hash{'a'}                is true (Perl5 only)
1790         grep ($_ eq 'a', keys %hash)     is true
1791
1792 If you now say
1793
1794         undef $hash{'a'}
1795
1796 your table now reads:
1797
1798
1799           keys  values
1800         +------+------+
1801         |  a   | undef|
1802         |  x   |  7   |
1803         |  d   |  0   |
1804         |  e   |  2   |
1805         +------+------+
1806
1807 and these conditions now hold; changes in caps:
1808
1809         $hash{'a'}                       is FALSE
1810         $hash{'d'}                       is false
1811         defined $hash{'d'}               is true
1812         defined $hash{'a'}               is FALSE
1813         exists $hash{'a'}                is true (Perl5 only)
1814         grep ($_ eq 'a', keys %hash)     is true
1815
1816 Notice the last two: you have an undef value, but a defined key!
1817
1818 Now, consider this:
1819
1820         delete $hash{'a'}
1821
1822 your table now reads:
1823
1824           keys  values
1825         +------+------+
1826         |  x   |  7   |
1827         |  d   |  0   |
1828         |  e   |  2   |
1829         +------+------+
1830
1831 and these conditions now hold; changes in caps:
1832
1833         $hash{'a'}                       is false
1834         $hash{'d'}                       is false
1835         defined $hash{'d'}               is true
1836         defined $hash{'a'}               is false
1837         exists $hash{'a'}                is FALSE (Perl5 only)
1838         grep ($_ eq 'a', keys %hash)     is FALSE
1839
1840 See, the whole entry is gone!
1841
1842 =head2 Why don't my tied hashes make the defined/exists distinction?
1843
1844 This depends on the tied hash's implementation of EXISTS().
1845 For example, there isn't the concept of undef with hashes
1846 that are tied to DBM* files. It also means that exists() and
1847 defined() do the same thing with a DBM* file, and what they
1848 end up doing is not what they do with ordinary hashes.
1849
1850 =head2 How do I reset an each() operation part-way through?
1851
1852 Using C<keys %hash> in scalar context returns the number of keys in
1853 the hash I<and> resets the iterator associated with the hash.  You may
1854 need to do this if you use C<last> to exit a loop early so that when you
1855 re-enter it, the hash iterator has been reset.
1856
1857 =head2 How can I get the unique keys from two hashes?
1858
1859 First you extract the keys from the hashes into lists, then solve
1860 the "removing duplicates" problem described above.  For example:
1861
1862     %seen = ();
1863     for $element (keys(%foo), keys(%bar)) {
1864         $seen{$element}++;
1865     }
1866     @uniq = keys %seen;
1867
1868 Or more succinctly:
1869
1870     @uniq = keys %{{%foo,%bar}};
1871
1872 Or if you really want to save space:
1873
1874     %seen = ();
1875     while (defined ($key = each %foo)) {
1876         $seen{$key}++;
1877     }
1878     while (defined ($key = each %bar)) {
1879         $seen{$key}++;
1880     }
1881     @uniq = keys %seen;
1882
1883 =head2 How can I store a multidimensional array in a DBM file?
1884
1885 Either stringify the structure yourself (no fun), or else
1886 get the MLDBM (which uses Data::Dumper) module from CPAN and layer
1887 it on top of either DB_File or GDBM_File.
1888
1889 =head2 How can I make my hash remember the order I put elements into it?
1890
1891 Use the Tie::IxHash from CPAN.
1892
1893     use Tie::IxHash;
1894     tie my %myhash, 'Tie::IxHash';
1895     for (my $i=0; $i<20; $i++) {
1896         $myhash{$i} = 2*$i;
1897     }
1898     my @keys = keys %myhash;
1899     # @keys = (0,1,2,3,...)
1900
1901 =head2 Why does passing a subroutine an undefined element in a hash create it?
1902
1903 If you say something like:
1904
1905     somefunc($hash{"nonesuch key here"});
1906
1907 Then that element "autovivifies"; that is, it springs into existence
1908 whether you store something there or not.  That's because functions
1909 get scalars passed in by reference.  If somefunc() modifies C<$_[0]>,
1910 it has to be ready to write it back into the caller's version.
1911
1912 This has been fixed as of Perl5.004.
1913
1914 Normally, merely accessing a key's value for a nonexistent key does
1915 I<not> cause that key to be forever there.  This is different than
1916 awk's behavior.
1917
1918 =head2 How can I make the Perl equivalent of a C structure/C++ class/hash or array of hashes or arrays?
1919
1920 Usually a hash ref, perhaps like this:
1921
1922     $record = {
1923         NAME   => "Jason",
1924         EMPNO  => 132,
1925         TITLE  => "deputy peon",
1926         AGE    => 23,
1927         SALARY => 37_000,
1928         PALS   => [ "Norbert", "Rhys", "Phineas"],
1929     };
1930
1931 References are documented in L<perlref> and the upcoming L<perlreftut>.
1932 Examples of complex data structures are given in L<perldsc> and
1933 L<perllol>.  Examples of structures and object-oriented classes are
1934 in L<perltoot>.
1935
1936 =head2 How can I use a reference as a hash key?
1937
1938 You can't do this directly, but you could use the standard Tie::RefHash
1939 module distributed with Perl.
1940
1941 =head1 Data: Misc
1942
1943 =head2 How do I handle binary data correctly?
1944
1945 Perl is binary clean, so this shouldn't be a problem.  For example,
1946 this works fine (assuming the files are found):
1947
1948     if (`cat /vmunix` =~ /gzip/) {
1949         print "Your kernel is GNU-zip enabled!\n";
1950     }
1951
1952 On less elegant (read: Byzantine) systems, however, you have
1953 to play tedious games with "text" versus "binary" files.  See
1954 L<perlfunc/"binmode"> or L<perlopentut>.
1955
1956 If you're concerned about 8-bit ASCII data, then see L<perllocale>.
1957
1958 If you want to deal with multibyte characters, however, there are
1959 some gotchas.  See the section on Regular Expressions.
1960
1961 =head2 How do I determine whether a scalar is a number/whole/integer/float?
1962
1963 Assuming that you don't care about IEEE notations like "NaN" or
1964 "Infinity", you probably just want to use a regular expression.
1965
1966    if (/\D/)            { print "has nondigits\n" }
1967    if (/^\d+$/)         { print "is a whole number\n" }
1968    if (/^-?\d+$/)       { print "is an integer\n" }
1969    if (/^[+-]?\d+$/)    { print "is a +/- integer\n" }
1970    if (/^-?\d+\.?\d*$/) { print "is a real number\n" }
1971    if (/^-?(?:\d+(?:\.\d*)?|\.\d+)$/) { print "is a decimal number\n" }
1972    if (/^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/)
1973                         { print "a C float\n" }
1974
1975 You can also use the L<Data::Types|Data::Types> module on
1976 the CPAN, which exports functions that validate data types
1977 using these and other regular expressions, or you can use
1978 the C<Regexp::Common> module from CPAN which has regular
1979 expressions to match various types of numbers.
1980
1981 If you're on a POSIX system, Perl's supports the C<POSIX::strtod>
1982 function.  Its semantics are somewhat cumbersome, so here's a C<getnum>
1983 wrapper function for more convenient access.  This function takes
1984 a string and returns the number it found, or C<undef> for input that
1985 isn't a C float.  The C<is_numeric> function is a front end to C<getnum>
1986 if you just want to say, ``Is this a float?''
1987
1988     sub getnum {
1989         use POSIX qw(strtod);
1990         my $str = shift;
1991         $str =~ s/^\s+//;
1992         $str =~ s/\s+$//;
1993         $! = 0;
1994         my($num, $unparsed) = strtod($str);
1995         if (($str eq '') || ($unparsed != 0) || $!) {
1996             return undef;
1997         } else {
1998             return $num;
1999         }
2000     }
2001
2002     sub is_numeric { defined getnum($_[0]) }
2003
2004 Or you could check out the L<String::Scanf|String::Scanf> module on the CPAN
2005 instead. The POSIX module (part of the standard Perl distribution) provides
2006 the C<strtod> and C<strtol> for converting strings to double and longs,
2007 respectively.
2008
2009 =head2 How do I keep persistent data across program calls?
2010
2011 For some specific applications, you can use one of the DBM modules.
2012 See L<AnyDBM_File>.  More generically, you should consult the FreezeThaw
2013 or Storable modules from CPAN.  Starting from Perl 5.8 Storable is part
2014 of the standard distribution.  Here's one example using Storable's C<store>
2015 and C<retrieve> functions:
2016
2017     use Storable;
2018     store(\%hash, "filename");
2019
2020     # later on...
2021     $href = retrieve("filename");        # by ref
2022     %hash = %{ retrieve("filename") };   # direct to hash
2023
2024 =head2 How do I print out or copy a recursive data structure?
2025
2026 The Data::Dumper module on CPAN (or the 5.005 release of Perl) is great
2027 for printing out data structures.  The Storable module, found on CPAN,
2028 provides a function called C<dclone> that recursively copies its argument.
2029
2030     use Storable qw(dclone);
2031     $r2 = dclone($r1);
2032
2033 Where $r1 can be a reference to any kind of data structure you'd like.
2034 It will be deeply copied.  Because C<dclone> takes and returns references,
2035 you'd have to add extra punctuation if you had a hash of arrays that
2036 you wanted to copy.
2037
2038     %newhash = %{ dclone(\%oldhash) };
2039
2040 =head2 How do I define methods for every class/object?
2041
2042 Use the UNIVERSAL class (see L<UNIVERSAL>).
2043
2044 =head2 How do I verify a credit card checksum?
2045
2046 Get the Business::CreditCard module from CPAN.
2047
2048 =head2 How do I pack arrays of doubles or floats for XS code?
2049
2050 The kgbpack.c code in the PGPLOT module on CPAN does just this.
2051 If you're doing a lot of float or double processing, consider using
2052 the PDL module from CPAN instead--it makes number-crunching easy.
2053
2054 =head1 AUTHOR AND COPYRIGHT
2055
2056 Copyright (c) 1997-2002 Tom Christiansen and Nathan Torkington.
2057 All rights reserved.
2058
2059 This documentation is free; you can redistribute it and/or modify it
2060 under the same terms as Perl itself.
2061
2062 Irrespective of its distribution, all code examples in this file
2063 are hereby placed into the public domain.  You are permitted and
2064 encouraged to use this code in your own programs for fun
2065 or for profit as you see fit.  A simple comment in the code giving
2066 credit would be courteous but is not required.