POSIX: bump version to 1.30
[perl.git] / pod / perlre.pod
1 =head1 NAME
2 X<regular expression> X<regex> X<regexp>
3
4 perlre - Perl regular expressions
5
6 =head1 DESCRIPTION
7
8 This page describes the syntax of regular expressions in Perl.
9
10 If you haven't used regular expressions before, a quick-start
11 introduction is available in L<perlrequick>, and a longer tutorial
12 introduction is available in L<perlretut>.
13
14 For reference on how regular expressions are used in matching
15 operations, plus various examples of the same, see discussions of
16 C<m//>, C<s///>, C<qr//> and C<??> in L<perlop/"Regexp Quote-Like
17 Operators">.
18
19
20 =head2 Modifiers
21
22 Matching operations can have various modifiers.  Modifiers
23 that relate to the interpretation of the regular expression inside
24 are listed below.  Modifiers that alter the way a regular expression
25 is used by Perl are detailed in L<perlop/"Regexp Quote-Like Operators"> and
26 L<perlop/"Gory details of parsing quoted constructs">.
27
28 =over 4
29
30 =item m
31 X</m> X<regex, multiline> X<regexp, multiline> X<regular expression, multiline>
32
33 Treat string as multiple lines.  That is, change "^" and "$" from matching
34 the start or end of the string to matching the start or end of any
35 line anywhere within the string.
36
37 =item s
38 X</s> X<regex, single-line> X<regexp, single-line>
39 X<regular expression, single-line>
40
41 Treat string as single line.  That is, change "." to match any character
42 whatsoever, even a newline, which normally it would not match.
43
44 Used together, as C</ms>, they let the "." match any character whatsoever,
45 while still allowing "^" and "$" to match, respectively, just after
46 and just before newlines within the string.
47
48 =item i
49 X</i> X<regex, case-insensitive> X<regexp, case-insensitive>
50 X<regular expression, case-insensitive>
51
52 Do case-insensitive pattern matching.
53
54 If locale matching rules are in effect, the case map is taken from the
55 current
56 locale for code points less than 255, and from Unicode rules for larger
57 code points.  However, matches that would cross the Unicode
58 rules/non-Unicode rules boundary (ords 255/256) will not succeed.  See
59 L<perllocale>.
60
61 There are a number of Unicode characters that match multiple characters
62 under C</i>.  For example, C<LATIN SMALL LIGATURE FI>
63 should match the sequence C<fi>.  Perl is not
64 currently able to do this when the multiple characters are in the pattern and
65 are split between groupings, or when one or more are quantified.  Thus
66
67  "\N{LATIN SMALL LIGATURE FI}" =~ /fi/i;          # Matches
68  "\N{LATIN SMALL LIGATURE FI}" =~ /[fi][fi]/i;    # Doesn't match!
69  "\N{LATIN SMALL LIGATURE FI}" =~ /fi*/i;         # Doesn't match!
70
71  # The below doesn't match, and it isn't clear what $1 and $2 would
72  # be even if it did!!
73  "\N{LATIN SMALL LIGATURE FI}" =~ /(f)(i)/i;      # Doesn't match!
74
75 Perl doesn't match multiple characters in an inverted bracketed
76 character class, which otherwise could be highly confusing.  See
77 L<perlrecharclass/Negation>.
78
79 Another bug involves character classes that match both a sequence of
80 multiple characters, and an initial sub-string of that sequence.  For
81 example,
82
83  /[s\xDF]/i
84
85 should match both a single and a double "s", since C<\xDF> (on ASCII
86 platforms) matches "ss".  However, this bug
87 (L<[perl #89774]|https://rt.perl.org/rt3/Ticket/Display.html?id=89774>)
88 causes it to only match a single "s", even if the final larger match
89 fails, and matching the double "ss" would have succeeded.
90
91 Also, Perl matching doesn't fully conform to the current Unicode C</i>
92 recommendations, which ask that the matching be made upon the NFD
93 (Normalization Form Decomposed) of the text.  However, Unicode is
94 in the process of reconsidering and revising their recommendations.
95
96 =item x
97 X</x>
98
99 Extend your pattern's legibility by permitting whitespace and comments.
100 Details in L</"/x">
101
102 =item p
103 X</p> X<regex, preserve> X<regexp, preserve>
104
105 Preserve the string matched such that ${^PREMATCH}, ${^MATCH}, and
106 ${^POSTMATCH} are available for use after matching.
107
108 =item g and c
109 X</g> X</c>
110
111 Global matching, and keep the Current position after failed matching.
112 Unlike i, m, s and x, these two flags affect the way the regex is used
113 rather than the regex itself. See
114 L<perlretut/"Using regular expressions in Perl"> for further explanation
115 of the g and c modifiers.
116
117 =item a, d, l and u
118 X</a> X</d> X</l> X</u>
119
120 These modifiers, all new in 5.14, affect which character-set semantics
121 (Unicode, etc.) are used, as described below in
122 L</Character set modifiers>.
123
124 =back
125
126 Regular expression modifiers are usually written in documentation
127 as e.g., "the C</x> modifier", even though the delimiter
128 in question might not really be a slash.  The modifiers C</imsxadlup>
129 may also be embedded within the regular expression itself using
130 the C<(?...)> construct, see L</Extended Patterns> below.
131
132 =head3 /x
133
134 C</x> tells
135 the regular expression parser to ignore most whitespace that is neither
136 backslashed nor within a character class.  You can use this to break up
137 your regular expression into (slightly) more readable parts.  The C<#>
138 character is also treated as a metacharacter introducing a comment,
139 just as in ordinary Perl code.  This also means that if you want real
140 whitespace or C<#> characters in the pattern (outside a character
141 class, where they are unaffected by C</x>), then you'll either have to
142 escape them (using backslashes or C<\Q...\E>) or encode them using octal,
143 hex, or C<\N{}> escapes.  Taken together, these features go a long way towards
144 making Perl's regular expressions more readable.  Note that you have to
145 be careful not to include the pattern delimiter in the comment--perl has
146 no way of knowing you did not intend to close the pattern early.  See
147 the C-comment deletion code in L<perlop>.  Also note that anything inside
148 a C<\Q...\E> stays unaffected by C</x>.  And note that C</x> doesn't affect
149 space interpretation within a single multi-character construct.  For
150 example in C<\x{...}>, regardless of the C</x> modifier, there can be no
151 spaces.  Same for a L<quantifier|/Quantifiers> such as C<{3}> or
152 C<{5,}>.  Similarly, C<(?:...)> can't have a space between the C<?> and C<:>,
153 but can between the C<(> and C<?>.  Within any delimiters for such a
154 construct, allowed spaces are not affected by C</x>, and depend on the
155 construct.  For example, C<\x{...}> can't have spaces because hexadecimal
156 numbers don't have spaces in them.  But, Unicode properties can have spaces, so
157 in C<\p{...}> there can be spaces that follow the Unicode rules, for which see
158 L<perluniprops/Properties accessible through \p{} and \P{}>.
159 X</x>
160
161 =head3 Character set modifiers
162
163 C</d>, C</u>, C</a>, and C</l>, available starting in 5.14, are called
164 the character set modifiers; they affect the character set semantics
165 used for the regular expression.
166
167 The C</d>, C</u>, and C</l> modifiers are not likely to be of much use
168 to you, and so you need not worry about them very much.  They exist for
169 Perl's internal use, so that complex regular expression data structures
170 can be automatically serialized and later exactly reconstituted,
171 including all their nuances.  But, since Perl can't keep a secret, and
172 there may be rare instances where they are useful, they are documented
173 here.
174
175 The C</a> modifier, on the other hand, may be useful.  Its purpose is to
176 allow code that is to work mostly on ASCII data to not have to concern
177 itself with Unicode.
178
179 Briefly, C</l> sets the character set to that of whatever B<L>ocale is in
180 effect at the time of the execution of the pattern match.
181
182 C</u> sets the character set to B<U>nicode.
183
184 C</a> also sets the character set to Unicode, BUT adds several
185 restrictions for B<A>SCII-safe matching.
186
187 C</d> is the old, problematic, pre-5.14 B<D>efault character set
188 behavior.  Its only use is to force that old behavior.
189
190 At any given time, exactly one of these modifiers is in effect.  Their
191 existence allows Perl to keep the originally compiled behavior of a
192 regular expression, regardless of what rules are in effect when it is
193 actually executed.  And if it is interpolated into a larger regex, the
194 original's rules continue to apply to it, and only it.
195
196 The C</l> and C</u> modifiers are automatically selected for
197 regular expressions compiled within the scope of various pragmas,
198 and we recommend that in general, you use those pragmas instead of
199 specifying these modifiers explicitly.  For one thing, the modifiers
200 affect only pattern matching, and do not extend to even any replacement
201 done, whereas using the pragmas give consistent results for all
202 appropriate operations within their scopes.  For example,
203
204  s/foo/\Ubar/il
205
206 will match "foo" using the locale's rules for case-insensitive matching,
207 but the C</l> does not affect how the C<\U> operates.  Most likely you
208 want both of them to use locale rules.  To do this, instead compile the
209 regular expression within the scope of C<use locale>.  This both
210 implicitly adds the C</l> and applies locale rules to the C<\U>.   The
211 lesson is to C<use locale> and not C</l> explicitly.
212
213 Similarly, it would be better to use C<use feature 'unicode_strings'>
214 instead of,
215
216  s/foo/\Lbar/iu
217
218 to get Unicode rules, as the C<\L> in the former (but not necessarily
219 the latter) would also use Unicode rules.
220
221 More detail on each of the modifiers follows.  Most likely you don't
222 need to know this detail for C</l>, C</u>, and C</d>, and can skip ahead
223 to L<E<sol>a|/E<sol>a (and E<sol>aa)>.
224
225 =head4 /l
226
227 means to use the current locale's rules (see L<perllocale>) when pattern
228 matching.  For example, C<\w> will match the "word" characters of that
229 locale, and C<"/i"> case-insensitive matching will match according to
230 the locale's case folding rules.  The locale used will be the one in
231 effect at the time of execution of the pattern match.  This may not be
232 the same as the compilation-time locale, and can differ from one match
233 to another if there is an intervening call of the
234 L<setlocale() function|perllocale/The setlocale function>.
235
236 Perl only supports single-byte locales.  This means that code points
237 above 255 are treated as Unicode no matter what locale is in effect.
238 Under Unicode rules, there are a few case-insensitive matches that cross
239 the 255/256 boundary.  These are disallowed under C</l>.  For example,
240 0xFF (on ASCII platforms) does not caselessly match the character at
241 0x178, C<LATIN CAPITAL LETTER Y WITH DIAERESIS>, because 0xFF may not be
242 C<LATIN SMALL LETTER Y WITH DIAERESIS> in the current locale, and Perl
243 has no way of knowing if that character even exists in the locale, much
244 less what code point it is.
245
246 This modifier may be specified to be the default by C<use locale>, but
247 see L</Which character set modifier is in effect?>.
248 X</l>
249
250 =head4 /u
251
252 means to use Unicode rules when pattern matching.  On ASCII platforms,
253 this means that the code points between 128 and 255 take on their
254 Latin-1 (ISO-8859-1) meanings (which are the same as Unicode's).
255 (Otherwise Perl considers their meanings to be undefined.)  Thus,
256 under this modifier, the ASCII platform effectively becomes a Unicode
257 platform; and hence, for example, C<\w> will match any of the more than
258 100_000 word characters in Unicode.
259
260 Unlike most locales, which are specific to a language and country pair,
261 Unicode classifies all the characters that are letters I<somewhere> in
262 the world as
263 C<\w>.  For example, your locale might not think that C<LATIN SMALL
264 LETTER ETH> is a letter (unless you happen to speak Icelandic), but
265 Unicode does.  Similarly, all the characters that are decimal digits
266 somewhere in the world will match C<\d>; this is hundreds, not 10,
267 possible matches.  And some of those digits look like some of the 10
268 ASCII digits, but mean a different number, so a human could easily think
269 a number is a different quantity than it really is.  For example,
270 C<BENGALI DIGIT FOUR> (U+09EA) looks very much like an
271 C<ASCII DIGIT EIGHT> (U+0038).  And, C<\d+>, may match strings of digits
272 that are a mixture from different writing systems, creating a security
273 issue.  L<Unicode::UCD/num()> can be used to sort
274 this out.  Or the C</a> modifier can be used to force C<\d> to match
275 just the ASCII 0 through 9.
276
277 Also, under this modifier, case-insensitive matching works on the full
278 set of Unicode
279 characters.  The C<KELVIN SIGN>, for example matches the letters "k" and
280 "K"; and C<LATIN SMALL LIGATURE FF> matches the sequence "ff", which,
281 if you're not prepared, might make it look like a hexadecimal constant,
282 presenting another potential security issue.  See
283 L<http://unicode.org/reports/tr36> for a detailed discussion of Unicode
284 security issues.
285
286 On the EBCDIC platforms that Perl handles, the native character set is
287 equivalent to Latin-1.  Thus this modifier changes behavior only when
288 the C<"/i"> modifier is also specified, and it turns out it affects only
289 two characters, giving them full Unicode semantics: the C<MICRO SIGN>
290 will match the Greek capital and small letters C<MU>, otherwise not; and
291 the C<LATIN CAPITAL LETTER SHARP S> will match any of C<SS>, C<Ss>,
292 C<sS>, and C<ss>, otherwise not.
293
294 This modifier may be specified to be the default by C<use feature
295 'unicode_strings>, C<use locale ':not_characters'>, or
296 C<L<use 5.012|perlfunc/use VERSION>> (or higher),
297 but see L</Which character set modifier is in effect?>.
298 X</u>
299
300 =head4 /d
301
302 This modifier means to use the "Default" native rules of the platform
303 except when there is cause to use Unicode rules instead, as follows:
304
305 =over 4
306
307 =item 1
308
309 the target string is encoded in UTF-8; or
310
311 =item 2
312
313 the pattern is encoded in UTF-8; or
314
315 =item 3
316
317 the pattern explicitly mentions a code point that is above 255 (say by
318 C<\x{100}>); or
319
320 =item 4
321
322 the pattern uses a Unicode name (C<\N{...}>);  or
323
324 =item 5
325
326 the pattern uses a Unicode property (C<\p{...}>)
327
328 =back
329
330 Another mnemonic for this modifier is "Depends", as the rules actually
331 used depend on various things, and as a result you can get unexpected
332 results.  See L<perlunicode/The "Unicode Bug">.  The Unicode Bug has
333 become rather infamous, leading to yet another (printable) name for this
334 modifier, "Dodgy".
335
336 On ASCII platforms, the native rules are ASCII, and on EBCDIC platforms
337 (at least the ones that Perl handles), they are Latin-1.
338
339 Here are some examples of how that works on an ASCII platform:
340
341  $str =  "\xDF";      # $str is not in UTF-8 format.
342  $str =~ /^\w/;       # No match, as $str isn't in UTF-8 format.
343  $str .= "\x{0e0b}";  # Now $str is in UTF-8 format.
344  $str =~ /^\w/;       # Match! $str is now in UTF-8 format.
345  chop $str;
346  $str =~ /^\w/;       # Still a match! $str remains in UTF-8 format.
347
348 This modifier is automatically selected by default when none of the
349 others are, so yet another name for it is "Default".
350
351 Because of the unexpected behaviors associated with this modifier, you
352 probably should only use it to maintain weird backward compatibilities.
353
354 =head4 /a (and /aa)
355
356 This modifier stands for ASCII-restrict (or ASCII-safe).  This modifier,
357 unlike the others, may be doubled-up to increase its effect.
358
359 When it appears singly, it causes the sequences C<\d>, C<\s>, C<\w>, and
360 the Posix character classes to match only in the ASCII range.  They thus
361 revert to their pre-5.6, pre-Unicode meanings.  Under C</a>,  C<\d>
362 always means precisely the digits C<"0"> to C<"9">; C<\s> means the five
363 characters C<[ \f\n\r\t]>; C<\w> means the 63 characters
364 C<[A-Za-z0-9_]>; and likewise, all the Posix classes such as
365 C<[[:print:]]> match only the appropriate ASCII-range characters.
366
367 This modifier is useful for people who only incidentally use Unicode,
368 and who do not wish to be burdened with its complexities and security
369 concerns.
370
371 With C</a>, one can write C<\d> with confidence that it will only match
372 ASCII characters, and should the need arise to match beyond ASCII, you
373 can instead use C<\p{Digit}> (or C<\p{Word}> for C<\w>).  There are
374 similar C<\p{...}> constructs that can match beyond ASCII both white
375 space (see L<perlrecharclass/Whitespace>), and Posix classes (see
376 L<perlrecharclass/POSIX Character Classes>).  Thus, this modifier
377 doesn't mean you can't use Unicode, it means that to get Unicode
378 matching you must explicitly use a construct (C<\p{}>, C<\P{}>) that
379 signals Unicode.
380
381 As you would expect, this modifier causes, for example, C<\D> to mean
382 the same thing as C<[^0-9]>; in fact, all non-ASCII characters match
383 C<\D>, C<\S>, and C<\W>.  C<\b> still means to match at the boundary
384 between C<\w> and C<\W>, using the C</a> definitions of them (similarly
385 for C<\B>).
386
387 Otherwise, C</a> behaves like the C</u> modifier, in that
388 case-insensitive matching uses Unicode semantics; for example, "k" will
389 match the Unicode C<\N{KELVIN SIGN}> under C</i> matching, and code
390 points in the Latin1 range, above ASCII will have Unicode rules when it
391 comes to case-insensitive matching.
392
393 To forbid ASCII/non-ASCII matches (like "k" with C<\N{KELVIN SIGN}>),
394 specify the "a" twice, for example C</aai> or C</aia>.  (The first
395 occurrence of "a" restricts the C<\d>, etc., and the second occurrence
396 adds the C</i> restrictions.)  But, note that code points outside the
397 ASCII range will use Unicode rules for C</i> matching, so the modifier
398 doesn't really restrict things to just ASCII; it just forbids the
399 intermixing of ASCII and non-ASCII.
400
401 To summarize, this modifier provides protection for applications that
402 don't wish to be exposed to all of Unicode.  Specifying it twice
403 gives added protection.
404
405 This modifier may be specified to be the default by C<use re '/a'>
406 or C<use re '/aa'>.  If you do so, you may actually have occasion to use
407 the C</u> modifier explictly if there are a few regular expressions
408 where you do want full Unicode rules (but even here, it's best if
409 everything were under feature C<"unicode_strings">, along with the
410 C<use re '/aa'>).  Also see L</Which character set modifier is in
411 effect?>.
412 X</a>
413 X</aa>
414
415 =head4 Which character set modifier is in effect?
416
417 Which of these modifiers is in effect at any given point in a regular
418 expression depends on a fairly complex set of interactions.  These have
419 been designed so that in general you don't have to worry about it, but
420 this section gives the gory details.  As
421 explained below in L</Extended Patterns> it is possible to explicitly
422 specify modifiers that apply only to portions of a regular expression.
423 The innermost always has priority over any outer ones, and one applying
424 to the whole expression has priority over any of the default settings that are
425 described in the remainder of this section.
426
427 The C<L<use re 'E<sol>foo'|re/"'/flags' mode">> pragma can be used to set
428 default modifiers (including these) for regular expressions compiled
429 within its scope.  This pragma has precedence over the other pragmas
430 listed below that also change the defaults.
431
432 Otherwise, C<L<use locale|perllocale>> sets the default modifier to C</l>;
433 and C<L<use feature 'unicode_strings|feature>>, or
434 C<L<use 5.012|perlfunc/use VERSION>> (or higher) set the default to
435 C</u> when not in the same scope as either C<L<use locale|perllocale>>
436 or C<L<use bytes|bytes>>.
437 (C<L<use locale ':not_characters'|perllocale/Unicode and UTF-8>> also
438 sets the default to C</u>, overriding any plain C<use locale>.)
439 Unlike the mechanisms mentioned above, these
440 affect operations besides regular expressions pattern matching, and so
441 give more consistent results with other operators, including using
442 C<\U>, C<\l>, etc. in substitution replacements.
443
444 If none of the above apply, for backwards compatibility reasons, the
445 C</d> modifier is the one in effect by default.  As this can lead to
446 unexpected results, it is best to specify which other rule set should be
447 used.
448
449 =head4 Character set modifier behavior prior to Perl 5.14
450
451 Prior to 5.14, there were no explicit modifiers, but C</l> was implied
452 for regexes compiled within the scope of C<use locale>, and C</d> was
453 implied otherwise.  However, interpolating a regex into a larger regex
454 would ignore the original compilation in favor of whatever was in effect
455 at the time of the second compilation.  There were a number of
456 inconsistencies (bugs) with the C</d> modifier, where Unicode rules
457 would be used when inappropriate, and vice versa.  C<\p{}> did not imply
458 Unicode rules, and neither did all occurrences of C<\N{}>, until 5.12.
459
460 =head2 Regular Expressions
461
462 =head3 Metacharacters
463
464 The patterns used in Perl pattern matching evolved from those supplied in
465 the Version 8 regex routines.  (The routines are derived
466 (distantly) from Henry Spencer's freely redistributable reimplementation
467 of the V8 routines.)  See L<Version 8 Regular Expressions> for
468 details.
469
470 In particular the following metacharacters have their standard I<egrep>-ish
471 meanings:
472 X<metacharacter>
473 X<\> X<^> X<.> X<$> X<|> X<(> X<()> X<[> X<[]>
474
475
476     \        Quote the next metacharacter
477     ^        Match the beginning of the line
478     .        Match any character (except newline)
479     $        Match the end of the line (or before newline at the end)
480     |        Alternation
481     ()       Grouping
482     []       Bracketed Character class
483
484 By default, the "^" character is guaranteed to match only the
485 beginning of the string, the "$" character only the end (or before the
486 newline at the end), and Perl does certain optimizations with the
487 assumption that the string contains only one line.  Embedded newlines
488 will not be matched by "^" or "$".  You may, however, wish to treat a
489 string as a multi-line buffer, such that the "^" will match after any
490 newline within the string (except if the newline is the last character in
491 the string), and "$" will match before any newline.  At the
492 cost of a little more overhead, you can do this by using the /m modifier
493 on the pattern match operator.  (Older programs did this by setting C<$*>,
494 but this option was removed in perl 5.9.)
495 X<^> X<$> X</m>
496
497 To simplify multi-line substitutions, the "." character never matches a
498 newline unless you use the C</s> modifier, which in effect tells Perl to pretend
499 the string is a single line--even if it isn't.
500 X<.> X</s>
501
502 =head3 Quantifiers
503
504 The following standard quantifiers are recognized:
505 X<metacharacter> X<quantifier> X<*> X<+> X<?> X<{n}> X<{n,}> X<{n,m}>
506
507     *           Match 0 or more times
508     +           Match 1 or more times
509     ?           Match 1 or 0 times
510     {n}         Match exactly n times
511     {n,}        Match at least n times
512     {n,m}       Match at least n but not more than m times
513
514 (If a curly bracket occurs in any other context and does not form part of
515 a backslashed sequence like C<\x{...}>, it is treated
516 as a regular character.  In particular, the lower bound
517 is not optional.)  The "*" quantifier is equivalent to C<{0,}>, the "+"
518 quantifier to C<{1,}>, and the "?" quantifier to C<{0,1}>.  n and m are limited
519 to non-negative integral values less than a preset limit defined when perl is built.
520 This is usually 32766 on the most common platforms.  The actual limit can
521 be seen in the error message generated by code such as this:
522
523     $_ **= $_ , / {$_} / for 2 .. 42;
524
525 By default, a quantified subpattern is "greedy", that is, it will match as
526 many times as possible (given a particular starting location) while still
527 allowing the rest of the pattern to match.  If you want it to match the
528 minimum number of times possible, follow the quantifier with a "?".  Note
529 that the meanings don't change, just the "greediness":
530 X<metacharacter> X<greedy> X<greediness>
531 X<?> X<*?> X<+?> X<??> X<{n}?> X<{n,}?> X<{n,m}?>
532
533     *?        Match 0 or more times, not greedily
534     +?        Match 1 or more times, not greedily
535     ??        Match 0 or 1 time, not greedily
536     {n}?      Match exactly n times, not greedily (redundant)
537     {n,}?     Match at least n times, not greedily
538     {n,m}?    Match at least n but not more than m times, not greedily
539
540 By default, when a quantified subpattern does not allow the rest of the
541 overall pattern to match, Perl will backtrack. However, this behaviour is
542 sometimes undesirable. Thus Perl provides the "possessive" quantifier form
543 as well.
544
545  *+     Match 0 or more times and give nothing back
546  ++     Match 1 or more times and give nothing back
547  ?+     Match 0 or 1 time and give nothing back
548  {n}+   Match exactly n times and give nothing back (redundant)
549  {n,}+  Match at least n times and give nothing back
550  {n,m}+ Match at least n but not more than m times and give nothing back
551
552 For instance,
553
554    'aaaa' =~ /a++a/
555
556 will never match, as the C<a++> will gobble up all the C<a>'s in the
557 string and won't leave any for the remaining part of the pattern. This
558 feature can be extremely useful to give perl hints about where it
559 shouldn't backtrack. For instance, the typical "match a double-quoted
560 string" problem can be most efficiently performed when written as:
561
562    /"(?:[^"\\]++|\\.)*+"/
563
564 as we know that if the final quote does not match, backtracking will not
565 help. See the independent subexpression
566 L</C<< (?>pattern) >>> for more details;
567 possessive quantifiers are just syntactic sugar for that construct. For
568 instance the above example could also be written as follows:
569
570    /"(?>(?:(?>[^"\\]+)|\\.)*)"/
571
572 =head3 Escape sequences
573
574 Because patterns are processed as double-quoted strings, the following
575 also work:
576
577  \t          tab                   (HT, TAB)
578  \n          newline               (LF, NL)
579  \r          return                (CR)
580  \f          form feed             (FF)
581  \a          alarm (bell)          (BEL)
582  \e          escape (think troff)  (ESC)
583  \cK         control char          (example: VT)
584  \x{}, \x00  character whose ordinal is the given hexadecimal number
585  \N{name}    named Unicode character or character sequence
586  \N{U+263D}  Unicode character     (example: FIRST QUARTER MOON)
587  \o{}, \000  character whose ordinal is the given octal number
588  \l          lowercase next char (think vi)
589  \u          uppercase next char (think vi)
590  \L          lowercase till \E (think vi)
591  \U          uppercase till \E (think vi)
592  \Q          quote (disable) pattern metacharacters till \E
593  \E          end either case modification or quoted section, think vi
594
595 Details are in L<perlop/Quote and Quote-like Operators>.
596
597 =head3 Character Classes and other Special Escapes
598
599 In addition, Perl defines the following:
600 X<\g> X<\k> X<\K> X<backreference>
601
602  Sequence   Note    Description
603   [...]     [1]  Match a character according to the rules of the
604                    bracketed character class defined by the "...".
605                    Example: [a-z] matches "a" or "b" or "c" ... or "z"
606   [[:...:]] [2]  Match a character according to the rules of the POSIX
607                    character class "..." within the outer bracketed
608                    character class.  Example: [[:upper:]] matches any
609                    uppercase character.
610   \w        [3]  Match a "word" character (alphanumeric plus "_", plus
611                    other connector punctuation chars plus Unicode
612                    marks)
613   \W        [3]  Match a non-"word" character
614   \s        [3]  Match a whitespace character
615   \S        [3]  Match a non-whitespace character
616   \d        [3]  Match a decimal digit character
617   \D        [3]  Match a non-digit character
618   \pP       [3]  Match P, named property.  Use \p{Prop} for longer names
619   \PP       [3]  Match non-P
620   \X        [4]  Match Unicode "eXtended grapheme cluster"
621   \C             Match a single C-language char (octet) even if that is
622                    part of a larger UTF-8 character.  Thus it breaks up
623                    characters into their UTF-8 bytes, so you may end up
624                    with malformed pieces of UTF-8.  Unsupported in
625                    lookbehind.
626   \1        [5]  Backreference to a specific capture group or buffer.
627                    '1' may actually be any positive integer.
628   \g1       [5]  Backreference to a specific or previous group,
629   \g{-1}    [5]  The number may be negative indicating a relative
630                    previous group and may optionally be wrapped in
631                    curly brackets for safer parsing.
632   \g{name}  [5]  Named backreference
633   \k<name>  [5]  Named backreference
634   \K        [6]  Keep the stuff left of the \K, don't include it in $&
635   \N        [7]  Any character but \n (experimental).  Not affected by
636                    /s modifier
637   \v        [3]  Vertical whitespace
638   \V        [3]  Not vertical whitespace
639   \h        [3]  Horizontal whitespace
640   \H        [3]  Not horizontal whitespace
641   \R        [4]  Linebreak
642
643 =over 4
644
645 =item [1]
646
647 See L<perlrecharclass/Bracketed Character Classes> for details.
648
649 =item [2]
650
651 See L<perlrecharclass/POSIX Character Classes> for details.
652
653 =item [3]
654
655 See L<perlrecharclass/Backslash sequences> for details.
656
657 =item [4]
658
659 See L<perlrebackslash/Misc> for details.
660
661 =item [5]
662
663 See L</Capture groups> below for details.
664
665 =item [6]
666
667 See L</Extended Patterns> below for details.
668
669 =item [7]
670
671 Note that C<\N> has two meanings.  When of the form C<\N{NAME}>, it matches the
672 character or character sequence whose name is C<NAME>; and similarly
673 when of the form C<\N{U+I<hex>}>, it matches the character whose Unicode
674 code point is I<hex>.  Otherwise it matches any character but C<\n>.
675
676 =back
677
678 =head3 Assertions
679
680 Perl defines the following zero-width assertions:
681 X<zero-width assertion> X<assertion> X<regex, zero-width assertion>
682 X<regexp, zero-width assertion>
683 X<regular expression, zero-width assertion>
684 X<\b> X<\B> X<\A> X<\Z> X<\z> X<\G>
685
686     \b  Match a word boundary
687     \B  Match except at a word boundary
688     \A  Match only at beginning of string
689     \Z  Match only at end of string, or before newline at the end
690     \z  Match only at end of string
691     \G  Match only at pos() (e.g. at the end-of-match position
692         of prior m//g)
693
694 A word boundary (C<\b>) is a spot between two characters
695 that has a C<\w> on one side of it and a C<\W> on the other side
696 of it (in either order), counting the imaginary characters off the
697 beginning and end of the string as matching a C<\W>.  (Within
698 character classes C<\b> represents backspace rather than a word
699 boundary, just as it normally does in any double-quoted string.)
700 The C<\A> and C<\Z> are just like "^" and "$", except that they
701 won't match multiple times when the C</m> modifier is used, while
702 "^" and "$" will match at every internal line boundary.  To match
703 the actual end of the string and not ignore an optional trailing
704 newline, use C<\z>.
705 X<\b> X<\A> X<\Z> X<\z> X</m>
706
707 The C<\G> assertion can be used to chain global matches (using
708 C<m//g>), as described in L<perlop/"Regexp Quote-Like Operators">.
709 It is also useful when writing C<lex>-like scanners, when you have
710 several patterns that you want to match against consequent substrings
711 of your string; see the previous reference.  The actual location
712 where C<\G> will match can also be influenced by using C<pos()> as
713 an lvalue: see L<perlfunc/pos>. Note that the rule for zero-length
714 matches (see L</"Repeated Patterns Matching a Zero-length Substring">)
715 is modified somewhat, in that contents to the left of C<\G> are
716 not counted when determining the length of the match. Thus the following
717 will not match forever:
718 X<\G>
719
720      my $string = 'ABC';
721      pos($string) = 1;
722      while ($string =~ /(.\G)/g) {
723          print $1;
724      }
725
726 It will print 'A' and then terminate, as it considers the match to
727 be zero-width, and thus will not match at the same position twice in a
728 row.
729
730 It is worth noting that C<\G> improperly used can result in an infinite
731 loop. Take care when using patterns that include C<\G> in an alternation.
732
733 =head3 Capture groups
734
735 The bracketing construct C<( ... )> creates capture groups (also referred to as
736 capture buffers). To refer to the current contents of a group later on, within
737 the same pattern, use C<\g1> (or C<\g{1}>) for the first, C<\g2> (or C<\g{2}>)
738 for the second, and so on.
739 This is called a I<backreference>.
740 X<regex, capture buffer> X<regexp, capture buffer>
741 X<regex, capture group> X<regexp, capture group>
742 X<regular expression, capture buffer> X<backreference>
743 X<regular expression, capture group> X<backreference>
744 X<\g{1}> X<\g{-1}> X<\g{name}> X<relative backreference> X<named backreference>
745 X<named capture buffer> X<regular expression, named capture buffer>
746 X<named capture group> X<regular expression, named capture group>
747 X<%+> X<$+{name}> X<< \k<name> >>
748 There is no limit to the number of captured substrings that you may use.
749 Groups are numbered with the leftmost open parenthesis being number 1, etc.  If
750 a group did not match, the associated backreference won't match either. (This
751 can happen if the group is optional, or in a different branch of an
752 alternation.)
753 You can omit the C<"g">, and write C<"\1">, etc, but there are some issues with
754 this form, described below.
755
756 You can also refer to capture groups relatively, by using a negative number, so
757 that C<\g-1> and C<\g{-1}> both refer to the immediately preceding capture
758 group, and C<\g-2> and C<\g{-2}> both refer to the group before it.  For
759 example:
760
761         /
762          (Y)            # group 1
763          (              # group 2
764             (X)         # group 3
765             \g{-1}      # backref to group 3
766             \g{-3}      # backref to group 1
767          )
768         /x
769
770 would match the same as C</(Y) ( (X) \g3 \g1 )/x>.  This allows you to
771 interpolate regexes into larger regexes and not have to worry about the
772 capture groups being renumbered.
773
774 You can dispense with numbers altogether and create named capture groups.
775 The notation is C<(?E<lt>I<name>E<gt>...)> to declare and C<\g{I<name>}> to
776 reference.  (To be compatible with .Net regular expressions, C<\g{I<name>}> may
777 also be written as C<\k{I<name>}>, C<\kE<lt>I<name>E<gt>> or C<\k'I<name>'>.)
778 I<name> must not begin with a number, nor contain hyphens.
779 When different groups within the same pattern have the same name, any reference
780 to that name assumes the leftmost defined group.  Named groups count in
781 absolute and relative numbering, and so can also be referred to by those
782 numbers.
783 (It's possible to do things with named capture groups that would otherwise
784 require C<(??{})>.)
785
786 Capture group contents are dynamically scoped and available to you outside the
787 pattern until the end of the enclosing block or until the next successful
788 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
789 You can refer to them by absolute number (using C<"$1"> instead of C<"\g1">,
790 etc); or by name via the C<%+> hash, using C<"$+{I<name>}">.
791
792 Braces are required in referring to named capture groups, but are optional for
793 absolute or relative numbered ones.  Braces are safer when creating a regex by
794 concatenating smaller strings.  For example if you have C<qr/$a$b/>, and C<$a>
795 contained C<"\g1">, and C<$b> contained C<"37">, you would get C</\g137/> which
796 is probably not what you intended.
797
798 The C<\g> and C<\k> notations were introduced in Perl 5.10.0.  Prior to that
799 there were no named nor relative numbered capture groups.  Absolute numbered
800 groups were referred to using C<\1>,
801 C<\2>, etc., and this notation is still
802 accepted (and likely always will be).  But it leads to some ambiguities if
803 there are more than 9 capture groups, as C<\10> could mean either the tenth
804 capture group, or the character whose ordinal in octal is 010 (a backspace in
805 ASCII).  Perl resolves this ambiguity by interpreting C<\10> as a backreference
806 only if at least 10 left parentheses have opened before it.  Likewise C<\11> is
807 a backreference only if at least 11 left parentheses have opened before it.
808 And so on.  C<\1> through C<\9> are always interpreted as backreferences.
809 There are several examples below that illustrate these perils.  You can avoid
810 the ambiguity by always using C<\g{}> or C<\g> if you mean capturing groups;
811 and for octal constants always using C<\o{}>, or for C<\077> and below, using 3
812 digits padded with leading zeros, since a leading zero implies an octal
813 constant.
814
815 The C<\I<digit>> notation also works in certain circumstances outside
816 the pattern.  See L</Warning on \1 Instead of $1> below for details.
817
818 Examples:
819
820     s/^([^ ]*) *([^ ]*)/$2 $1/;     # swap first two words
821
822     /(.)\g1/                        # find first doubled char
823          and print "'$1' is the first doubled character\n";
824
825     /(?<char>.)\k<char>/            # ... a different way
826          and print "'$+{char}' is the first doubled character\n";
827
828     /(?'char'.)\g1/                 # ... mix and match
829          and print "'$1' is the first doubled character\n";
830
831     if (/Time: (..):(..):(..)/) {   # parse out values
832         $hours = $1;
833         $minutes = $2;
834         $seconds = $3;
835     }
836
837     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\g10/   # \g10 is a backreference
838     /(.)(.)(.)(.)(.)(.)(.)(.)(.)\10/    # \10 is octal
839     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\10/  # \10 is a backreference
840     /((.)(.)(.)(.)(.)(.)(.)(.)(.))\010/ # \010 is octal
841
842     $a = '(.)\1';        # Creates problems when concatenated.
843     $b = '(.)\g{1}';     # Avoids the problems.
844     "aa" =~ /${a}/;      # True
845     "aa" =~ /${b}/;      # True
846     "aa0" =~ /${a}0/;    # False!
847     "aa0" =~ /${b}0/;    # True
848     "aa\x08" =~ /${a}0/;  # True!
849     "aa\x08" =~ /${b}0/;  # False
850
851 Several special variables also refer back to portions of the previous
852 match.  C<$+> returns whatever the last bracket match matched.
853 C<$&> returns the entire matched string.  (At one point C<$0> did
854 also, but now it returns the name of the program.)  C<$`> returns
855 everything before the matched string.  C<$'> returns everything
856 after the matched string. And C<$^N> contains whatever was matched by
857 the most-recently closed group (submatch). C<$^N> can be used in
858 extended patterns (see below), for example to assign a submatch to a
859 variable.
860 X<$+> X<$^N> X<$&> X<$`> X<$'>
861
862 These special variables, like the C<%+> hash and the numbered match variables
863 (C<$1>, C<$2>, C<$3>, etc.) are dynamically scoped
864 until the end of the enclosing block or until the next successful
865 match, whichever comes first.  (See L<perlsyn/"Compound Statements">.)
866 X<$+> X<$^N> X<$&> X<$`> X<$'>
867 X<$1> X<$2> X<$3> X<$4> X<$5> X<$6> X<$7> X<$8> X<$9>
868
869 B<NOTE>: Failed matches in Perl do not reset the match variables,
870 which makes it easier to write code that tests for a series of more
871 specific cases and remembers the best match.
872
873 B<WARNING>: Once Perl sees that you need one of C<$&>, C<$`>, or
874 C<$'> anywhere in the program, it has to provide them for every
875 pattern match.  This may substantially slow your program.  Perl
876 uses the same mechanism to produce C<$1>, C<$2>, etc, so you also pay a
877 price for each pattern that contains capturing parentheses.  (To
878 avoid this cost while retaining the grouping behaviour, use the
879 extended regular expression C<(?: ... )> instead.)  But if you never
880 use C<$&>, C<$`> or C<$'>, then patterns I<without> capturing
881 parentheses will not be penalized.  So avoid C<$&>, C<$'>, and C<$`>
882 if you can, but if you can't (and some algorithms really appreciate
883 them), once you've used them once, use them at will, because you've
884 already paid the price.  As of 5.005, C<$&> is not so costly as the
885 other two.
886 X<$&> X<$`> X<$'>
887
888 As a workaround for this problem, Perl 5.10.0 introduces C<${^PREMATCH}>,
889 C<${^MATCH}> and C<${^POSTMATCH}>, which are equivalent to C<$`>, C<$&>
890 and C<$'>, B<except> that they are only guaranteed to be defined after a
891 successful match that was executed with the C</p> (preserve) modifier.
892 The use of these variables incurs no global performance penalty, unlike
893 their punctuation char equivalents, however at the trade-off that you
894 have to tell perl when you want to use them.
895 X</p> X<p modifier>
896
897 =head2 Quoting metacharacters
898
899 Backslashed metacharacters in Perl are alphanumeric, such as C<\b>,
900 C<\w>, C<\n>.  Unlike some other regular expression languages, there
901 are no backslashed symbols that aren't alphanumeric.  So anything
902 that looks like \\, \(, \), \<, \>, \{, or \} is always
903 interpreted as a literal character, not a metacharacter.  This was
904 once used in a common idiom to disable or quote the special meanings
905 of regular expression metacharacters in a string that you want to
906 use for a pattern. Simply quote all non-"word" characters:
907
908     $pattern =~ s/(\W)/\\$1/g;
909
910 (If C<use locale> is set, then this depends on the current locale.)
911 Today it is more common to use the quotemeta() function or the C<\Q>
912 metaquoting escape sequence to disable all metacharacters' special
913 meanings like this:
914
915     /$unquoted\Q$quoted\E$unquoted/
916
917 Beware that if you put literal backslashes (those not inside
918 interpolated variables) between C<\Q> and C<\E>, double-quotish
919 backslash interpolation may lead to confusing results.  If you
920 I<need> to use literal backslashes within C<\Q...\E>,
921 consult L<perlop/"Gory details of parsing quoted constructs">.
922
923 =head2 Extended Patterns
924
925 Perl also defines a consistent extension syntax for features not
926 found in standard tools like B<awk> and
927 B<lex>.  The syntax for most of these is a
928 pair of parentheses with a question mark as the first thing within
929 the parentheses.  The character after the question mark indicates
930 the extension.
931
932 The stability of these extensions varies widely.  Some have been
933 part of the core language for many years.  Others are experimental
934 and may change without warning or be completely removed.  Check
935 the documentation on an individual feature to verify its current
936 status.
937
938 A question mark was chosen for this and for the minimal-matching
939 construct because 1) question marks are rare in older regular
940 expressions, and 2) whenever you see one, you should stop and
941 "question" exactly what is going on.  That's psychology....
942
943 =over 4
944
945 =item C<(?#text)>
946 X<(?#)>
947
948 A comment.  The text is ignored.  If the C</x> modifier enables
949 whitespace formatting, a simple C<#> will suffice.  Note that Perl closes
950 the comment as soon as it sees a C<)>, so there is no way to put a literal
951 C<)> in the comment.
952
953 =item C<(?adlupimsx-imsx)>
954
955 =item C<(?^alupimsx)>
956 X<(?)> X<(?^)>
957
958 One or more embedded pattern-match modifiers, to be turned on (or
959 turned off, if preceded by C<->) for the remainder of the pattern or
960 the remainder of the enclosing pattern group (if any).
961
962 This is particularly useful for dynamic patterns, such as those read in from a
963 configuration file, taken from an argument, or specified in a table
964 somewhere.  Consider the case where some patterns want to be
965 case-sensitive and some do not:  The case-insensitive ones merely need to
966 include C<(?i)> at the front of the pattern.  For example:
967
968     $pattern = "foobar";
969     if ( /$pattern/i ) { }
970
971     # more flexible:
972
973     $pattern = "(?i)foobar";
974     if ( /$pattern/ ) { }
975
976 These modifiers are restored at the end of the enclosing group. For example,
977
978     ( (?i) blah ) \s+ \g1
979
980 will match C<blah> in any case, some spaces, and an exact (I<including the case>!)
981 repetition of the previous word, assuming the C</x> modifier, and no C</i>
982 modifier outside this group.
983
984 These modifiers do not carry over into named subpatterns called in the
985 enclosing group. In other words, a pattern such as C<((?i)(?&NAME))> does not
986 change the case-sensitivity of the "NAME" pattern.
987
988 Any of these modifiers can be set to apply globally to all regular
989 expressions compiled within the scope of a C<use re>.  See
990 L<re/"'/flags' mode">.
991
992 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
993 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Flags (except
994 C<"d">) may follow the caret to override it.
995 But a minus sign is not legal with it.
996
997 Note that the C<a>, C<d>, C<l>, C<p>, and C<u> modifiers are special in
998 that they can only be enabled, not disabled, and the C<a>, C<d>, C<l>, and
999 C<u> modifiers are mutually exclusive: specifying one de-specifies the
1000 others, and a maximum of one (or two C<a>'s) may appear in the
1001 construct.  Thus, for
1002 example, C<(?-p)> will warn when compiled under C<use warnings>;
1003 C<(?-d:...)> and C<(?dl:...)> are fatal errors.
1004
1005 Note also that the C<p> modifier is special in that its presence
1006 anywhere in a pattern has a global effect.
1007
1008 =item C<(?:pattern)>
1009 X<(?:)>
1010
1011 =item C<(?adluimsx-imsx:pattern)>
1012
1013 =item C<(?^aluimsx:pattern)>
1014 X<(?^:)>
1015
1016 This is for clustering, not capturing; it groups subexpressions like
1017 "()", but doesn't make backreferences as "()" does.  So
1018
1019     @fields = split(/\b(?:a|b|c)\b/)
1020
1021 is like
1022
1023     @fields = split(/\b(a|b|c)\b/)
1024
1025 but doesn't spit out extra fields.  It's also cheaper not to capture
1026 characters if you don't need to.
1027
1028 Any letters between C<?> and C<:> act as flags modifiers as with
1029 C<(?adluimsx-imsx)>.  For example,
1030
1031     /(?s-i:more.*than).*million/i
1032
1033 is equivalent to the more verbose
1034
1035     /(?:(?s-i)more.*than).*million/i
1036
1037 Starting in Perl 5.14, a C<"^"> (caret or circumflex accent) immediately
1038 after the C<"?"> is a shorthand equivalent to C<d-imsx>.  Any positive
1039 flags (except C<"d">) may follow the caret, so
1040
1041     (?^x:foo)
1042
1043 is equivalent to
1044
1045     (?x-ims:foo)
1046
1047 The caret tells Perl that this cluster doesn't inherit the flags of any
1048 surrounding pattern, but uses the system defaults (C<d-imsx>),
1049 modified by any flags specified.
1050
1051 The caret allows for simpler stringification of compiled regular
1052 expressions.  These look like
1053
1054     (?^:pattern)
1055
1056 with any non-default flags appearing between the caret and the colon.
1057 A test that looks at such stringification thus doesn't need to have the
1058 system default flags hard-coded in it, just the caret.  If new flags are
1059 added to Perl, the meaning of the caret's expansion will change to include
1060 the default for those flags, so the test will still work, unchanged.
1061
1062 Specifying a negative flag after the caret is an error, as the flag is
1063 redundant.
1064
1065 Mnemonic for C<(?^...)>:  A fresh beginning since the usual use of a caret is
1066 to match at the beginning.
1067
1068 =item C<(?|pattern)>
1069 X<(?|)> X<Branch reset>
1070
1071 This is the "branch reset" pattern, which has the special property
1072 that the capture groups are numbered from the same starting point
1073 in each alternation branch. It is available starting from perl 5.10.0.
1074
1075 Capture groups are numbered from left to right, but inside this
1076 construct the numbering is restarted for each branch.
1077
1078 The numbering within each branch will be as normal, and any groups
1079 following this construct will be numbered as though the construct
1080 contained only one branch, that being the one with the most capture
1081 groups in it.
1082
1083 This construct is useful when you want to capture one of a
1084 number of alternative matches.
1085
1086 Consider the following pattern.  The numbers underneath show in
1087 which group the captured content will be stored.
1088
1089
1090     # before  ---------------branch-reset----------- after        
1091     / ( a )  (?| x ( y ) z | (p (q) r) | (t) u (v) ) ( z ) /x
1092     # 1            2         2  3        2     3     4  
1093
1094 Be careful when using the branch reset pattern in combination with 
1095 named captures. Named captures are implemented as being aliases to 
1096 numbered groups holding the captures, and that interferes with the
1097 implementation of the branch reset pattern. If you are using named
1098 captures in a branch reset pattern, it's best to use the same names,
1099 in the same order, in each of the alternations:
1100
1101    /(?|  (?<a> x ) (?<b> y )
1102       |  (?<a> z ) (?<b> w )) /x
1103
1104 Not doing so may lead to surprises:
1105
1106   "12" =~ /(?| (?<a> \d+ ) | (?<b> \D+))/x;
1107   say $+ {a};   # Prints '12'
1108   say $+ {b};   # *Also* prints '12'.
1109
1110 The problem here is that both the group named C<< a >> and the group
1111 named C<< b >> are aliases for the group belonging to C<< $1 >>.
1112
1113 =item Look-Around Assertions
1114 X<look-around assertion> X<lookaround assertion> X<look-around> X<lookaround>
1115
1116 Look-around assertions are zero-width patterns which match a specific
1117 pattern without including it in C<$&>. Positive assertions match when
1118 their subpattern matches, negative assertions match when their subpattern
1119 fails. Look-behind matches text up to the current match position,
1120 look-ahead matches text following the current match position.
1121
1122 =over 4
1123
1124 =item C<(?=pattern)>
1125 X<(?=)> X<look-ahead, positive> X<lookahead, positive>
1126
1127 A zero-width positive look-ahead assertion.  For example, C</\w+(?=\t)/>
1128 matches a word followed by a tab, without including the tab in C<$&>.
1129
1130 =item C<(?!pattern)>
1131 X<(?!)> X<look-ahead, negative> X<lookahead, negative>
1132
1133 A zero-width negative look-ahead assertion.  For example C</foo(?!bar)/>
1134 matches any occurrence of "foo" that isn't followed by "bar".  Note
1135 however that look-ahead and look-behind are NOT the same thing.  You cannot
1136 use this for look-behind.
1137
1138 If you are looking for a "bar" that isn't preceded by a "foo", C</(?!foo)bar/>
1139 will not do what you want.  That's because the C<(?!foo)> is just saying that
1140 the next thing cannot be "foo"--and it's not, it's a "bar", so "foobar" will
1141 match.  Use look-behind instead (see below).
1142
1143 =item C<(?<=pattern)> C<\K>
1144 X<(?<=)> X<look-behind, positive> X<lookbehind, positive> X<\K>
1145
1146 A zero-width positive look-behind assertion.  For example, C</(?<=\t)\w+/>
1147 matches a word that follows a tab, without including the tab in C<$&>.
1148 Works only for fixed-width look-behind.
1149
1150 There is a special form of this construct, called C<\K>, which causes the
1151 regex engine to "keep" everything it had matched prior to the C<\K> and
1152 not include it in C<$&>. This effectively provides variable-length
1153 look-behind. The use of C<\K> inside of another look-around assertion
1154 is allowed, but the behaviour is currently not well defined.
1155
1156 For various reasons C<\K> may be significantly more efficient than the
1157 equivalent C<< (?<=...) >> construct, and it is especially useful in
1158 situations where you want to efficiently remove something following
1159 something else in a string. For instance
1160
1161   s/(foo)bar/$1/g;
1162
1163 can be rewritten as the much more efficient
1164
1165   s/foo\Kbar//g;
1166
1167 =item C<(?<!pattern)>
1168 X<(?<!)> X<look-behind, negative> X<lookbehind, negative>
1169
1170 A zero-width negative look-behind assertion.  For example C</(?<!bar)foo/>
1171 matches any occurrence of "foo" that does not follow "bar".  Works
1172 only for fixed-width look-behind.
1173
1174 =back
1175
1176 =item C<(?'NAME'pattern)>
1177
1178 =item C<< (?<NAME>pattern) >>
1179 X<< (?<NAME>) >> X<(?'NAME')> X<named capture> X<capture>
1180
1181 A named capture group. Identical in every respect to normal capturing
1182 parentheses C<()> but for the additional fact that the group
1183 can be referred to by name in various regular expression
1184 constructs (like C<\g{NAME}>) and can be accessed by name
1185 after a successful match via C<%+> or C<%->. See L<perlvar>
1186 for more details on the C<%+> and C<%-> hashes.
1187
1188 If multiple distinct capture groups have the same name then the
1189 $+{NAME} will refer to the leftmost defined group in the match.
1190
1191 The forms C<(?'NAME'pattern)> and C<< (?<NAME>pattern) >> are equivalent.
1192
1193 B<NOTE:> While the notation of this construct is the same as the similar
1194 function in .NET regexes, the behavior is not. In Perl the groups are
1195 numbered sequentially regardless of being named or not. Thus in the
1196 pattern
1197
1198   /(x)(?<foo>y)(z)/
1199
1200 $+{foo} will be the same as $2, and $3 will contain 'z' instead of
1201 the opposite which is what a .NET regex hacker might expect.
1202
1203 Currently NAME is restricted to simple identifiers only.
1204 In other words, it must match C</^[_A-Za-z][_A-Za-z0-9]*\z/> or
1205 its Unicode extension (see L<utf8>),
1206 though it isn't extended by the locale (see L<perllocale>).
1207
1208 B<NOTE:> In order to make things easier for programmers with experience
1209 with the Python or PCRE regex engines, the pattern C<< (?PE<lt>NAMEE<gt>pattern) >>
1210 may be used instead of C<< (?<NAME>pattern) >>; however this form does not
1211 support the use of single quotes as a delimiter for the name.
1212
1213 =item C<< \k<NAME> >>
1214
1215 =item C<< \k'NAME' >>
1216
1217 Named backreference. Similar to numeric backreferences, except that
1218 the group is designated by name and not number. If multiple groups
1219 have the same name then it refers to the leftmost defined group in
1220 the current match.
1221
1222 It is an error to refer to a name not defined by a C<< (?<NAME>) >>
1223 earlier in the pattern.
1224
1225 Both forms are equivalent.
1226
1227 B<NOTE:> In order to make things easier for programmers with experience
1228 with the Python or PCRE regex engines, the pattern C<< (?P=NAME) >>
1229 may be used instead of C<< \k<NAME> >>.
1230
1231 =item C<(?{ code })>
1232 X<(?{})> X<regex, code in> X<regexp, code in> X<regular expression, code in>
1233
1234 B<WARNING>: This extended regular expression feature is considered
1235 experimental, and may be changed without notice. Code executed that
1236 has side effects may not perform identically from version to version
1237 due to the effect of future optimisations in the regex engine.
1238
1239 This zero-width assertion evaluates any embedded Perl code.  It
1240 always succeeds, and its C<code> is not interpolated.  Currently,
1241 the rules to determine where the C<code> ends are somewhat convoluted.
1242
1243 This feature can be used together with the special variable C<$^N> to
1244 capture the results of submatches in variables without having to keep
1245 track of the number of nested parentheses. For example:
1246
1247   $_ = "The brown fox jumps over the lazy dog";
1248   /the (\S+)(?{ $color = $^N }) (\S+)(?{ $animal = $^N })/i;
1249   print "color = $color, animal = $animal\n";
1250
1251 Inside the C<(?{...})> block, C<$_> refers to the string the regular
1252 expression is matching against. You can also use C<pos()> to know what is
1253 the current position of matching within this string.
1254
1255 The C<code> is properly scoped in the following sense: If the assertion
1256 is backtracked (compare L<"Backtracking">), all changes introduced after
1257 C<local>ization are undone, so that
1258
1259   $_ = 'a' x 8;
1260   m<
1261      (?{ $cnt = 0 })               # Initialize $cnt.
1262      (
1263        a
1264        (?{
1265            local $cnt = $cnt + 1;  # Update $cnt,
1266                                    # backtracking-safe.
1267        })
1268      )*
1269      aaaa
1270      (?{ $res = $cnt })            # On success copy to
1271                                    # non-localized location.
1272    >x;
1273
1274 will set C<$res = 4>.  Note that after the match, C<$cnt> returns to the globally
1275 introduced value, because the scopes that restrict C<local> operators
1276 are unwound.
1277
1278 This assertion may be used as a C<(?(condition)yes-pattern|no-pattern)>
1279 switch.  If I<not> used in this way, the result of evaluation of
1280 C<code> is put into the special variable C<$^R>.  This happens
1281 immediately, so C<$^R> can be used from other C<(?{ code })> assertions
1282 inside the same regular expression.
1283
1284 The assignment to C<$^R> above is properly localized, so the old
1285 value of C<$^R> is restored if the assertion is backtracked; compare
1286 L<"Backtracking">.
1287
1288 For reasons of security, this construct is forbidden if the regular
1289 expression involves run-time interpolation of variables, unless the
1290 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1291 variables contain results of the C<qr//> operator (see
1292 L<perlop/"qr/STRINGE<sol>msixpodual">).
1293
1294 This restriction is due to the wide-spread and remarkably convenient
1295 custom of using run-time determined strings as patterns.  For example:
1296
1297     $re = <>;
1298     chomp $re;
1299     $string =~ /$re/;
1300
1301 Before Perl knew how to execute interpolated code within a pattern,
1302 this operation was completely safe from a security point of view,
1303 although it could raise an exception from an illegal pattern.  If
1304 you turn on the C<use re 'eval'>, though, it is no longer secure,
1305 so you should only do so if you are also using taint checking.
1306 Better yet, use the carefully constrained evaluation within a Safe
1307 compartment.  See L<perlsec> for details about both these mechanisms.
1308
1309 B<WARNING>: Use of lexical (C<my>) variables in these blocks is
1310 broken. The result is unpredictable and will make perl unstable. The
1311 workaround is to use global (C<our>) variables.
1312
1313 B<WARNING>: In perl 5.12.x and earlier, the regex engine
1314 was not re-entrant, so interpolated code could not
1315 safely invoke the regex engine either directly with
1316 C<m//> or C<s///>), or indirectly with functions such as
1317 C<split>. Invoking the regex engine in these blocks would make perl
1318 unstable.
1319
1320 =item C<(??{ code })>
1321 X<(??{})>
1322 X<regex, postponed> X<regexp, postponed> X<regular expression, postponed>
1323
1324 B<WARNING>: This extended regular expression feature is considered
1325 experimental, and may be changed without notice. Code executed that
1326 has side effects may not perform identically from version to version
1327 due to the effect of future optimisations in the regex engine.
1328
1329 This is a "postponed" regular subexpression.  The C<code> is evaluated
1330 at run time, at the moment this subexpression may match.  The result
1331 of evaluation is considered a regular expression and matched as
1332 if it were inserted instead of this construct.  Note that this means
1333 that the contents of capture groups defined inside an eval'ed pattern
1334 are not available outside of the pattern, and vice versa, there is no
1335 way for the inner pattern returned from the code block to refer to a
1336 capture group defined outside.  (The code block itself can use C<$1>, etc.,
1337 to refer to the enclosing pattern's capture groups.)  Thus,
1338
1339     ('a' x 100)=~/(??{'(.)' x 100})/
1340
1341 B<will> match, it will B<not> set $1.
1342
1343 The C<code> is not interpolated.  As before, the rules to determine
1344 where the C<code> ends are currently somewhat convoluted.
1345
1346 The following pattern matches a parenthesized group:
1347
1348  $re = qr{
1349             \(
1350             (?:
1351                (?> [^()]+ )  # Non-parens without backtracking
1352              |
1353                (??{ $re })   # Group with matching parens
1354             )*
1355             \)
1356          }x;
1357
1358 See also C<(?PARNO)> for a different, more efficient way to accomplish
1359 the same task.
1360
1361 For reasons of security, this construct is forbidden if the regular
1362 expression involves run-time interpolation of variables, unless the
1363 perilous C<use re 'eval'> pragma has been used (see L<re>), or the
1364 variables contain results of the C<qr//> operator (see
1365 L<perlop/"qrE<sol>STRINGE<sol>msixpodual">).
1366
1367 In perl 5.12.x and earlier, because the regex engine was not re-entrant,
1368 delayed code could not safely invoke the regex engine either directly with
1369 C<m//> or C<s///>), or indirectly with functions such as C<split>.
1370
1371 Recursing deeper than 50 times without consuming any input string will
1372 result in a fatal error.  The maximum depth is compiled into perl, so
1373 changing it requires a custom build.
1374
1375 =item C<(?PARNO)> C<(?-PARNO)> C<(?+PARNO)> C<(?R)> C<(?0)>
1376 X<(?PARNO)> X<(?1)> X<(?R)> X<(?0)> X<(?-1)> X<(?+1)> X<(?-PARNO)> X<(?+PARNO)>
1377 X<regex, recursive> X<regexp, recursive> X<regular expression, recursive>
1378 X<regex, relative recursion>
1379
1380 Similar to C<(??{ code })> except it does not involve compiling any code,
1381 instead it treats the contents of a capture group as an independent
1382 pattern that must match at the current position.  Capture groups
1383 contained by the pattern will have the value as determined by the
1384 outermost recursion.
1385
1386 PARNO is a sequence of digits (not starting with 0) whose value reflects
1387 the paren-number of the capture group to recurse to. C<(?R)> recurses to
1388 the beginning of the whole pattern. C<(?0)> is an alternate syntax for
1389 C<(?R)>. If PARNO is preceded by a plus or minus sign then it is assumed
1390 to be relative, with negative numbers indicating preceding capture groups
1391 and positive ones following. Thus C<(?-1)> refers to the most recently
1392 declared group, and C<(?+1)> indicates the next group to be declared.
1393 Note that the counting for relative recursion differs from that of
1394 relative backreferences, in that with recursion unclosed groups B<are>
1395 included.
1396
1397 The following pattern matches a function foo() which may contain
1398 balanced parentheses as the argument.
1399
1400   $re = qr{ (                   # paren group 1 (full function)
1401               foo
1402               (                 # paren group 2 (parens)
1403                 \(
1404                   (             # paren group 3 (contents of parens)
1405                   (?:
1406                    (?> [^()]+ ) # Non-parens without backtracking
1407                   |
1408                    (?2)         # Recurse to start of paren group 2
1409                   )*
1410                   )
1411                 \)
1412               )
1413             )
1414           }x;
1415
1416 If the pattern was used as follows
1417
1418     'foo(bar(baz)+baz(bop))'=~/$re/
1419         and print "\$1 = $1\n",
1420                   "\$2 = $2\n",
1421                   "\$3 = $3\n";
1422
1423 the output produced should be the following:
1424
1425     $1 = foo(bar(baz)+baz(bop))
1426     $2 = (bar(baz)+baz(bop))
1427     $3 = bar(baz)+baz(bop)
1428
1429 If there is no corresponding capture group defined, then it is a
1430 fatal error.  Recursing deeper than 50 times without consuming any input
1431 string will also result in a fatal error.  The maximum depth is compiled
1432 into perl, so changing it requires a custom build.
1433
1434 The following shows how using negative indexing can make it
1435 easier to embed recursive patterns inside of a C<qr//> construct
1436 for later use:
1437
1438     my $parens = qr/(\((?:[^()]++|(?-1))*+\))/;
1439     if (/foo $parens \s+ + \s+ bar $parens/x) {
1440        # do something here...
1441     }
1442
1443 B<Note> that this pattern does not behave the same way as the equivalent
1444 PCRE or Python construct of the same form. In Perl you can backtrack into
1445 a recursed group, in PCRE and Python the recursed into group is treated
1446 as atomic. Also, modifiers are resolved at compile time, so constructs
1447 like (?i:(?1)) or (?:(?i)(?1)) do not affect how the sub-pattern will
1448 be processed.
1449
1450 =item C<(?&NAME)>
1451 X<(?&NAME)>
1452
1453 Recurse to a named subpattern. Identical to C<(?PARNO)> except that the
1454 parenthesis to recurse to is determined by name. If multiple parentheses have
1455 the same name, then it recurses to the leftmost.
1456
1457 It is an error to refer to a name that is not declared somewhere in the
1458 pattern.
1459
1460 B<NOTE:> In order to make things easier for programmers with experience
1461 with the Python or PCRE regex engines the pattern C<< (?P>NAME) >>
1462 may be used instead of C<< (?&NAME) >>.
1463
1464 =item C<(?(condition)yes-pattern|no-pattern)>
1465 X<(?()>
1466
1467 =item C<(?(condition)yes-pattern)>
1468
1469 Conditional expression. Matches C<yes-pattern> if C<condition> yields
1470 a true value, matches C<no-pattern> otherwise. A missing pattern always
1471 matches.
1472
1473 C<(condition)> should be either an integer in
1474 parentheses (which is valid if the corresponding pair of parentheses
1475 matched), a look-ahead/look-behind/evaluate zero-width assertion, a
1476 name in angle brackets or single quotes (which is valid if a group
1477 with the given name matched), or the special symbol (R) (true when
1478 evaluated inside of recursion or eval). Additionally the R may be
1479 followed by a number, (which will be true when evaluated when recursing
1480 inside of the appropriate group), or by C<&NAME>, in which case it will
1481 be true only when evaluated during recursion in the named group.
1482
1483 Here's a summary of the possible predicates:
1484
1485 =over 4
1486
1487 =item (1) (2) ...
1488
1489 Checks if the numbered capturing group has matched something.
1490
1491 =item (<NAME>) ('NAME')
1492
1493 Checks if a group with the given name has matched something.
1494
1495 =item (?=...) (?!...) (?<=...) (?<!...)
1496
1497 Checks whether the pattern matches (or does not match, for the '!'
1498 variants).
1499
1500 =item (?{ CODE })
1501
1502 Treats the return value of the code block as the condition.
1503
1504 =item (R)
1505
1506 Checks if the expression has been evaluated inside of recursion.
1507
1508 =item (R1) (R2) ...
1509
1510 Checks if the expression has been evaluated while executing directly
1511 inside of the n-th capture group. This check is the regex equivalent of
1512
1513   if ((caller(0))[3] eq 'subname') { ... }
1514
1515 In other words, it does not check the full recursion stack.
1516
1517 =item (R&NAME)
1518
1519 Similar to C<(R1)>, this predicate checks to see if we're executing
1520 directly inside of the leftmost group with a given name (this is the same
1521 logic used by C<(?&NAME)> to disambiguate). It does not check the full
1522 stack, but only the name of the innermost active recursion.
1523
1524 =item (DEFINE)
1525
1526 In this case, the yes-pattern is never directly executed, and no
1527 no-pattern is allowed. Similar in spirit to C<(?{0})> but more efficient.
1528 See below for details.
1529
1530 =back
1531
1532 For example:
1533
1534     m{ ( \( )?
1535        [^()]+
1536        (?(1) \) )
1537      }x
1538
1539 matches a chunk of non-parentheses, possibly included in parentheses
1540 themselves.
1541
1542 A special form is the C<(DEFINE)> predicate, which never executes its
1543 yes-pattern directly, and does not allow a no-pattern. This allows one to
1544 define subpatterns which will be executed only by the recursion mechanism.
1545 This way, you can define a set of regular expression rules that can be
1546 bundled into any pattern you choose.
1547
1548 It is recommended that for this usage you put the DEFINE block at the
1549 end of the pattern, and that you name any subpatterns defined within it.
1550
1551 Also, it's worth noting that patterns defined this way probably will
1552 not be as efficient, as the optimiser is not very clever about
1553 handling them.
1554
1555 An example of how this might be used is as follows:
1556
1557   /(?<NAME>(?&NAME_PAT))(?<ADDR>(?&ADDRESS_PAT))
1558    (?(DEFINE)
1559      (?<NAME_PAT>....)
1560      (?<ADRESS_PAT>....)
1561    )/x
1562
1563 Note that capture groups matched inside of recursion are not accessible
1564 after the recursion returns, so the extra layer of capturing groups is
1565 necessary. Thus C<$+{NAME_PAT}> would not be defined even though
1566 C<$+{NAME}> would be.
1567
1568 Finally, keep in mind that subpatterns created inside a DEFINE block
1569 count towards the absolute and relative number of captures, so this:
1570
1571     my @captures = "a" =~ /(.)                  # First capture
1572                            (?(DEFINE)
1573                                (?<EXAMPLE> 1 )  # Second capture
1574                            )/x;
1575     say scalar @captures;
1576
1577 Will output 2, not 1. This is particularly important if you intend to
1578 compile the definitions with the C<qr//> operator, and later
1579 interpolate them in another pattern.
1580
1581 =item C<< (?>pattern) >>
1582 X<backtrack> X<backtracking> X<atomic> X<possessive>
1583
1584 An "independent" subexpression, one which matches the substring
1585 that a I<standalone> C<pattern> would match if anchored at the given
1586 position, and it matches I<nothing other than this substring>.  This
1587 construct is useful for optimizations of what would otherwise be
1588 "eternal" matches, because it will not backtrack (see L<"Backtracking">).
1589 It may also be useful in places where the "grab all you can, and do not
1590 give anything back" semantic is desirable.
1591
1592 For example: C<< ^(?>a*)ab >> will never match, since C<< (?>a*) >>
1593 (anchored at the beginning of string, as above) will match I<all>
1594 characters C<a> at the beginning of string, leaving no C<a> for
1595 C<ab> to match.  In contrast, C<a*ab> will match the same as C<a+b>,
1596 since the match of the subgroup C<a*> is influenced by the following
1597 group C<ab> (see L<"Backtracking">).  In particular, C<a*> inside
1598 C<a*ab> will match fewer characters than a standalone C<a*>, since
1599 this makes the tail match.
1600
1601 C<< (?>pattern) >> does not disable backtracking altogether once it has
1602 matched. It is still possible to backtrack past the construct, but not
1603 into it. So C<< ((?>a*)|(?>b*))ar >> will still match "bar".
1604
1605 An effect similar to C<< (?>pattern) >> may be achieved by writing
1606 C<(?=(pattern))\g{-1}>.  This matches the same substring as a standalone
1607 C<a+>, and the following C<\g{-1}> eats the matched string; it therefore
1608 makes a zero-length assertion into an analogue of C<< (?>...) >>.
1609 (The difference between these two constructs is that the second one
1610 uses a capturing group, thus shifting ordinals of backreferences
1611 in the rest of a regular expression.)
1612
1613 Consider this pattern:
1614
1615     m{ \(
1616           (
1617             [^()]+           # x+
1618           |
1619             \( [^()]* \)
1620           )+
1621        \)
1622      }x
1623
1624 That will efficiently match a nonempty group with matching parentheses
1625 two levels deep or less.  However, if there is no such group, it
1626 will take virtually forever on a long string.  That's because there
1627 are so many different ways to split a long string into several
1628 substrings.  This is what C<(.+)+> is doing, and C<(.+)+> is similar
1629 to a subpattern of the above pattern.  Consider how the pattern
1630 above detects no-match on C<((()aaaaaaaaaaaaaaaaaa> in several
1631 seconds, but that each extra letter doubles this time.  This
1632 exponential performance will make it appear that your program has
1633 hung.  However, a tiny change to this pattern
1634
1635     m{ \(
1636           (
1637             (?> [^()]+ )        # change x+ above to (?> x+ )
1638           |
1639             \( [^()]* \)
1640           )+
1641        \)
1642      }x
1643
1644 which uses C<< (?>...) >> matches exactly when the one above does (verifying
1645 this yourself would be a productive exercise), but finishes in a fourth
1646 the time when used on a similar string with 1000000 C<a>s.  Be aware,
1647 however, that, when this construct is followed by a
1648 quantifier, it currently triggers a warning message under
1649 the C<use warnings> pragma or B<-w> switch saying it
1650 C<"matches null string many times in regex">.
1651
1652 On simple groups, such as the pattern C<< (?> [^()]+ ) >>, a comparable
1653 effect may be achieved by negative look-ahead, as in C<[^()]+ (?! [^()] )>.
1654 This was only 4 times slower on a string with 1000000 C<a>s.
1655
1656 The "grab all you can, and do not give anything back" semantic is desirable
1657 in many situations where on the first sight a simple C<()*> looks like
1658 the correct solution.  Suppose we parse text with comments being delimited
1659 by C<#> followed by some optional (horizontal) whitespace.  Contrary to
1660 its appearance, C<#[ \t]*> I<is not> the correct subexpression to match
1661 the comment delimiter, because it may "give up" some whitespace if
1662 the remainder of the pattern can be made to match that way.  The correct
1663 answer is either one of these:
1664
1665     (?>#[ \t]*)
1666     #[ \t]*(?![ \t])
1667
1668 For example, to grab non-empty comments into $1, one should use either
1669 one of these:
1670
1671     / (?> \# [ \t]* ) (        .+ ) /x;
1672     /     \# [ \t]*   ( [^ \t] .* ) /x;
1673
1674 Which one you pick depends on which of these expressions better reflects
1675 the above specification of comments.
1676
1677 In some literature this construct is called "atomic matching" or
1678 "possessive matching".
1679
1680 Possessive quantifiers are equivalent to putting the item they are applied
1681 to inside of one of these constructs. The following equivalences apply:
1682
1683     Quantifier Form     Bracketing Form
1684     ---------------     ---------------
1685     PAT*+               (?>PAT*)
1686     PAT++               (?>PAT+)
1687     PAT?+               (?>PAT?)
1688     PAT{min,max}+       (?>PAT{min,max})
1689
1690 =back
1691
1692 =head2 Special Backtracking Control Verbs
1693
1694 B<WARNING:> These patterns are experimental and subject to change or
1695 removal in a future version of Perl. Their usage in production code should
1696 be noted to avoid problems during upgrades.
1697
1698 These special patterns are generally of the form C<(*VERB:ARG)>. Unless
1699 otherwise stated the ARG argument is optional; in some cases, it is
1700 forbidden.
1701
1702 Any pattern containing a special backtracking verb that allows an argument
1703 has the special behaviour that when executed it sets the current package's
1704 C<$REGERROR> and C<$REGMARK> variables. When doing so the following
1705 rules apply:
1706
1707 On failure, the C<$REGERROR> variable will be set to the ARG value of the
1708 verb pattern, if the verb was involved in the failure of the match. If the
1709 ARG part of the pattern was omitted, then C<$REGERROR> will be set to the
1710 name of the last C<(*MARK:NAME)> pattern executed, or to TRUE if there was
1711 none. Also, the C<$REGMARK> variable will be set to FALSE.
1712
1713 On a successful match, the C<$REGERROR> variable will be set to FALSE, and
1714 the C<$REGMARK> variable will be set to the name of the last
1715 C<(*MARK:NAME)> pattern executed.  See the explanation for the
1716 C<(*MARK:NAME)> verb below for more details.
1717
1718 B<NOTE:> C<$REGERROR> and C<$REGMARK> are not magic variables like C<$1>
1719 and most other regex-related variables. They are not local to a scope, nor
1720 readonly, but instead are volatile package variables similar to C<$AUTOLOAD>.
1721 Use C<local> to localize changes to them to a specific scope if necessary.
1722
1723 If a pattern does not contain a special backtracking verb that allows an
1724 argument, then C<$REGERROR> and C<$REGMARK> are not touched at all.
1725
1726 =over 3
1727
1728 =item Verbs that take an argument
1729
1730 =over 4
1731
1732 =item C<(*PRUNE)> C<(*PRUNE:NAME)>
1733 X<(*PRUNE)> X<(*PRUNE:NAME)>
1734
1735 This zero-width pattern prunes the backtracking tree at the current point
1736 when backtracked into on failure. Consider the pattern C<A (*PRUNE) B>,
1737 where A and B are complex patterns. Until the C<(*PRUNE)> verb is reached,
1738 A may backtrack as necessary to match. Once it is reached, matching
1739 continues in B, which may also backtrack as necessary; however, should B
1740 not match, then no further backtracking will take place, and the pattern
1741 will fail outright at the current starting position.
1742
1743 The following example counts all the possible matching strings in a
1744 pattern (without actually matching any of them).
1745
1746     'aaab' =~ /a+b?(?{print "$&\n"; $count++})(*FAIL)/;
1747     print "Count=$count\n";
1748
1749 which produces:
1750
1751     aaab
1752     aaa
1753     aa
1754     a
1755     aab
1756     aa
1757     a
1758     ab
1759     a
1760     Count=9
1761
1762 If we add a C<(*PRUNE)> before the count like the following
1763
1764     'aaab' =~ /a+b?(*PRUNE)(?{print "$&\n"; $count++})(*FAIL)/;
1765     print "Count=$count\n";
1766
1767 we prevent backtracking and find the count of the longest matching string
1768 at each matching starting point like so:
1769
1770     aaab
1771     aab
1772     ab
1773     Count=3
1774
1775 Any number of C<(*PRUNE)> assertions may be used in a pattern.
1776
1777 See also C<< (?>pattern) >> and possessive quantifiers for other ways to
1778 control backtracking. In some cases, the use of C<(*PRUNE)> can be
1779 replaced with a C<< (?>pattern) >> with no functional difference; however,
1780 C<(*PRUNE)> can be used to handle cases that cannot be expressed using a
1781 C<< (?>pattern) >> alone.
1782
1783 =item C<(*SKIP)> C<(*SKIP:NAME)>
1784 X<(*SKIP)>
1785
1786 This zero-width pattern is similar to C<(*PRUNE)>, except that on
1787 failure it also signifies that whatever text that was matched leading up
1788 to the C<(*SKIP)> pattern being executed cannot be part of I<any> match
1789 of this pattern. This effectively means that the regex engine "skips" forward
1790 to this position on failure and tries to match again, (assuming that
1791 there is sufficient room to match).
1792
1793 The name of the C<(*SKIP:NAME)> pattern has special significance. If a
1794 C<(*MARK:NAME)> was encountered while matching, then it is that position
1795 which is used as the "skip point". If no C<(*MARK)> of that name was
1796 encountered, then the C<(*SKIP)> operator has no effect. When used
1797 without a name the "skip point" is where the match point was when
1798 executing the (*SKIP) pattern.
1799
1800 Compare the following to the examples in C<(*PRUNE)>; note the string
1801 is twice as long:
1802
1803  'aaabaaab' =~ /a+b?(*SKIP)(?{print "$&\n"; $count++})(*FAIL)/;
1804  print "Count=$count\n";
1805
1806 outputs
1807
1808     aaab
1809     aaab
1810     Count=2
1811
1812 Once the 'aaab' at the start of the string has matched, and the C<(*SKIP)>
1813 executed, the next starting point will be where the cursor was when the
1814 C<(*SKIP)> was executed.
1815
1816 =item C<(*MARK:NAME)> C<(*:NAME)>
1817 X<(*MARK)> X<(*MARK:NAME)> X<(*:NAME)>
1818
1819 This zero-width pattern can be used to mark the point reached in a string
1820 when a certain part of the pattern has been successfully matched. This
1821 mark may be given a name. A later C<(*SKIP)> pattern will then skip
1822 forward to that point if backtracked into on failure. Any number of
1823 C<(*MARK)> patterns are allowed, and the NAME portion may be duplicated.
1824
1825 In addition to interacting with the C<(*SKIP)> pattern, C<(*MARK:NAME)>
1826 can be used to "label" a pattern branch, so that after matching, the
1827 program can determine which branches of the pattern were involved in the
1828 match.
1829
1830 When a match is successful, the C<$REGMARK> variable will be set to the
1831 name of the most recently executed C<(*MARK:NAME)> that was involved
1832 in the match.
1833
1834 This can be used to determine which branch of a pattern was matched
1835 without using a separate capture group for each branch, which in turn
1836 can result in a performance improvement, as perl cannot optimize
1837 C</(?:(x)|(y)|(z))/> as efficiently as something like
1838 C</(?:x(*MARK:x)|y(*MARK:y)|z(*MARK:z))/>.
1839
1840 When a match has failed, and unless another verb has been involved in
1841 failing the match and has provided its own name to use, the C<$REGERROR>
1842 variable will be set to the name of the most recently executed
1843 C<(*MARK:NAME)>.
1844
1845 See L</(*SKIP)> for more details.
1846
1847 As a shortcut C<(*MARK:NAME)> can be written C<(*:NAME)>.
1848
1849 =item C<(*THEN)> C<(*THEN:NAME)>
1850
1851 This is similar to the "cut group" operator C<::> from Perl 6.  Like
1852 C<(*PRUNE)>, this verb always matches, and when backtracked into on
1853 failure, it causes the regex engine to try the next alternation in the
1854 innermost enclosing group (capturing or otherwise) that has alternations.
1855 The two branches of a C<(?(condition)yes-pattern|no-pattern)> do not
1856 count as an alternation, as far as C<(*THEN)> is concerned.
1857
1858 Its name comes from the observation that this operation combined with the
1859 alternation operator (C<|>) can be used to create what is essentially a
1860 pattern-based if/then/else block:
1861
1862   ( COND (*THEN) FOO | COND2 (*THEN) BAR | COND3 (*THEN) BAZ )
1863
1864 Note that if this operator is used and NOT inside of an alternation then
1865 it acts exactly like the C<(*PRUNE)> operator.
1866
1867   / A (*PRUNE) B /
1868
1869 is the same as
1870
1871   / A (*THEN) B /
1872
1873 but
1874
1875   / ( A (*THEN) B | C (*THEN) D ) /
1876
1877 is not the same as
1878
1879   / ( A (*PRUNE) B | C (*PRUNE) D ) /
1880
1881 as after matching the A but failing on the B the C<(*THEN)> verb will
1882 backtrack and try C; but the C<(*PRUNE)> verb will simply fail.
1883
1884 =back
1885
1886 =item Verbs without an argument
1887
1888 =over 4
1889
1890 =item C<(*COMMIT)>
1891 X<(*COMMIT)>
1892
1893 This is the Perl 6 "commit pattern" C<< <commit> >> or C<:::>. It's a
1894 zero-width pattern similar to C<(*SKIP)>, except that when backtracked
1895 into on failure it causes the match to fail outright. No further attempts
1896 to find a valid match by advancing the start pointer will occur again.
1897 For example,
1898
1899  'aaabaaab' =~ /a+b?(*COMMIT)(?{print "$&\n"; $count++})(*FAIL)/;
1900  print "Count=$count\n";
1901
1902 outputs
1903
1904     aaab
1905     Count=1
1906
1907 In other words, once the C<(*COMMIT)> has been entered, and if the pattern
1908 does not match, the regex engine will not try any further matching on the
1909 rest of the string.
1910
1911 =item C<(*FAIL)> C<(*F)>
1912 X<(*FAIL)> X<(*F)>
1913
1914 This pattern matches nothing and always fails. It can be used to force the
1915 engine to backtrack. It is equivalent to C<(?!)>, but easier to read. In
1916 fact, C<(?!)> gets optimised into C<(*FAIL)> internally.
1917
1918 It is probably useful only when combined with C<(?{})> or C<(??{})>.
1919
1920 =item C<(*ACCEPT)>
1921 X<(*ACCEPT)>
1922
1923 B<WARNING:> This feature is highly experimental. It is not recommended
1924 for production code.
1925
1926 This pattern matches nothing and causes the end of successful matching at
1927 the point at which the C<(*ACCEPT)> pattern was encountered, regardless of
1928 whether there is actually more to match in the string. When inside of a
1929 nested pattern, such as recursion, or in a subpattern dynamically generated
1930 via C<(??{})>, only the innermost pattern is ended immediately.
1931
1932 If the C<(*ACCEPT)> is inside of capturing groups then the groups are
1933 marked as ended at the point at which the C<(*ACCEPT)> was encountered.
1934 For instance:
1935
1936   'AB' =~ /(A (A|B(*ACCEPT)|C) D)(E)/x;
1937
1938 will match, and C<$1> will be C<AB> and C<$2> will be C<B>, C<$3> will not
1939 be set. If another branch in the inner parentheses was matched, such as in the
1940 string 'ACDE', then the C<D> and C<E> would have to be matched as well.
1941
1942 =back
1943
1944 =back
1945
1946 =head2 Backtracking
1947 X<backtrack> X<backtracking>
1948
1949 NOTE: This section presents an abstract approximation of regular
1950 expression behavior.  For a more rigorous (and complicated) view of
1951 the rules involved in selecting a match among possible alternatives,
1952 see L<Combining RE Pieces>.
1953
1954 A fundamental feature of regular expression matching involves the
1955 notion called I<backtracking>, which is currently used (when needed)
1956 by all regular non-possessive expression quantifiers, namely C<*>, C<*?>, C<+>,
1957 C<+?>, C<{n,m}>, and C<{n,m}?>.  Backtracking is often optimized
1958 internally, but the general principle outlined here is valid.
1959
1960 For a regular expression to match, the I<entire> regular expression must
1961 match, not just part of it.  So if the beginning of a pattern containing a
1962 quantifier succeeds in a way that causes later parts in the pattern to
1963 fail, the matching engine backs up and recalculates the beginning
1964 part--that's why it's called backtracking.
1965
1966 Here is an example of backtracking:  Let's say you want to find the
1967 word following "foo" in the string "Food is on the foo table.":
1968
1969     $_ = "Food is on the foo table.";
1970     if ( /\b(foo)\s+(\w+)/i ) {
1971         print "$2 follows $1.\n";
1972     }
1973
1974 When the match runs, the first part of the regular expression (C<\b(foo)>)
1975 finds a possible match right at the beginning of the string, and loads up
1976 $1 with "Foo".  However, as soon as the matching engine sees that there's
1977 no whitespace following the "Foo" that it had saved in $1, it realizes its
1978 mistake and starts over again one character after where it had the
1979 tentative match.  This time it goes all the way until the next occurrence
1980 of "foo". The complete regular expression matches this time, and you get
1981 the expected output of "table follows foo."
1982
1983 Sometimes minimal matching can help a lot.  Imagine you'd like to match
1984 everything between "foo" and "bar".  Initially, you write something
1985 like this:
1986
1987     $_ =  "The food is under the bar in the barn.";
1988     if ( /foo(.*)bar/ ) {
1989         print "got <$1>\n";
1990     }
1991
1992 Which perhaps unexpectedly yields:
1993
1994   got <d is under the bar in the >
1995
1996 That's because C<.*> was greedy, so you get everything between the
1997 I<first> "foo" and the I<last> "bar".  Here it's more effective
1998 to use minimal matching to make sure you get the text between a "foo"
1999 and the first "bar" thereafter.
2000
2001     if ( /foo(.*?)bar/ ) { print "got <$1>\n" }
2002   got <d is under the >
2003
2004 Here's another example. Let's say you'd like to match a number at the end
2005 of a string, and you also want to keep the preceding part of the match.
2006 So you write this:
2007
2008     $_ = "I have 2 numbers: 53147";
2009     if ( /(.*)(\d*)/ ) {                                # Wrong!
2010         print "Beginning is <$1>, number is <$2>.\n";
2011     }
2012
2013 That won't work at all, because C<.*> was greedy and gobbled up the
2014 whole string. As C<\d*> can match on an empty string the complete
2015 regular expression matched successfully.
2016
2017     Beginning is <I have 2 numbers: 53147>, number is <>.
2018
2019 Here are some variants, most of which don't work:
2020
2021     $_ = "I have 2 numbers: 53147";
2022     @pats = qw{
2023         (.*)(\d*)
2024         (.*)(\d+)
2025         (.*?)(\d*)
2026         (.*?)(\d+)
2027         (.*)(\d+)$
2028         (.*?)(\d+)$
2029         (.*)\b(\d+)$
2030         (.*\D)(\d+)$
2031     };
2032
2033     for $pat (@pats) {
2034         printf "%-12s ", $pat;
2035         if ( /$pat/ ) {
2036             print "<$1> <$2>\n";
2037         } else {
2038             print "FAIL\n";
2039         }
2040     }
2041
2042 That will print out:
2043
2044     (.*)(\d*)    <I have 2 numbers: 53147> <>
2045     (.*)(\d+)    <I have 2 numbers: 5314> <7>
2046     (.*?)(\d*)   <> <>
2047     (.*?)(\d+)   <I have > <2>
2048     (.*)(\d+)$   <I have 2 numbers: 5314> <7>
2049     (.*?)(\d+)$  <I have 2 numbers: > <53147>
2050     (.*)\b(\d+)$ <I have 2 numbers: > <53147>
2051     (.*\D)(\d+)$ <I have 2 numbers: > <53147>
2052
2053 As you see, this can be a bit tricky.  It's important to realize that a
2054 regular expression is merely a set of assertions that gives a definition
2055 of success.  There may be 0, 1, or several different ways that the
2056 definition might succeed against a particular string.  And if there are
2057 multiple ways it might succeed, you need to understand backtracking to
2058 know which variety of success you will achieve.
2059
2060 When using look-ahead assertions and negations, this can all get even
2061 trickier.  Imagine you'd like to find a sequence of non-digits not
2062 followed by "123".  You might try to write that as
2063
2064     $_ = "ABC123";
2065     if ( /^\D*(?!123)/ ) {                # Wrong!
2066         print "Yup, no 123 in $_\n";
2067     }
2068
2069 But that isn't going to match; at least, not the way you're hoping.  It
2070 claims that there is no 123 in the string.  Here's a clearer picture of
2071 why that pattern matches, contrary to popular expectations:
2072
2073     $x = 'ABC123';
2074     $y = 'ABC445';
2075
2076     print "1: got $1\n" if $x =~ /^(ABC)(?!123)/;
2077     print "2: got $1\n" if $y =~ /^(ABC)(?!123)/;
2078
2079     print "3: got $1\n" if $x =~ /^(\D*)(?!123)/;
2080     print "4: got $1\n" if $y =~ /^(\D*)(?!123)/;
2081
2082 This prints
2083
2084     2: got ABC
2085     3: got AB
2086     4: got ABC
2087
2088 You might have expected test 3 to fail because it seems to a more
2089 general purpose version of test 1.  The important difference between
2090 them is that test 3 contains a quantifier (C<\D*>) and so can use
2091 backtracking, whereas test 1 will not.  What's happening is
2092 that you've asked "Is it true that at the start of $x, following 0 or more
2093 non-digits, you have something that's not 123?"  If the pattern matcher had
2094 let C<\D*> expand to "ABC", this would have caused the whole pattern to
2095 fail.
2096
2097 The search engine will initially match C<\D*> with "ABC".  Then it will
2098 try to match C<(?!123)> with "123", which fails.  But because
2099 a quantifier (C<\D*>) has been used in the regular expression, the
2100 search engine can backtrack and retry the match differently
2101 in the hope of matching the complete regular expression.
2102
2103 The pattern really, I<really> wants to succeed, so it uses the
2104 standard pattern back-off-and-retry and lets C<\D*> expand to just "AB" this
2105 time.  Now there's indeed something following "AB" that is not
2106 "123".  It's "C123", which suffices.
2107
2108 We can deal with this by using both an assertion and a negation.
2109 We'll say that the first part in $1 must be followed both by a digit
2110 and by something that's not "123".  Remember that the look-aheads
2111 are zero-width expressions--they only look, but don't consume any
2112 of the string in their match.  So rewriting this way produces what
2113 you'd expect; that is, case 5 will fail, but case 6 succeeds:
2114
2115     print "5: got $1\n" if $x =~ /^(\D*)(?=\d)(?!123)/;
2116     print "6: got $1\n" if $y =~ /^(\D*)(?=\d)(?!123)/;
2117
2118     6: got ABC
2119
2120 In other words, the two zero-width assertions next to each other work as though
2121 they're ANDed together, just as you'd use any built-in assertions:  C</^$/>
2122 matches only if you're at the beginning of the line AND the end of the
2123 line simultaneously.  The deeper underlying truth is that juxtaposition in
2124 regular expressions always means AND, except when you write an explicit OR
2125 using the vertical bar.  C</ab/> means match "a" AND (then) match "b",
2126 although the attempted matches are made at different positions because "a"
2127 is not a zero-width assertion, but a one-width assertion.
2128
2129 B<WARNING>: Particularly complicated regular expressions can take
2130 exponential time to solve because of the immense number of possible
2131 ways they can use backtracking to try for a match.  For example, without
2132 internal optimizations done by the regular expression engine, this will
2133 take a painfully long time to run:
2134
2135     'aaaaaaaaaaaa' =~ /((a{0,5}){0,5})*[c]/
2136
2137 And if you used C<*>'s in the internal groups instead of limiting them
2138 to 0 through 5 matches, then it would take forever--or until you ran
2139 out of stack space.  Moreover, these internal optimizations are not
2140 always applicable.  For example, if you put C<{0,5}> instead of C<*>
2141 on the external group, no current optimization is applicable, and the
2142 match takes a long time to finish.
2143
2144 A powerful tool for optimizing such beasts is what is known as an
2145 "independent group",
2146 which does not backtrack (see L</C<< (?>pattern) >>>).  Note also that
2147 zero-length look-ahead/look-behind assertions will not backtrack to make
2148 the tail match, since they are in "logical" context: only
2149 whether they match is considered relevant.  For an example
2150 where side-effects of look-ahead I<might> have influenced the
2151 following match, see L</C<< (?>pattern) >>>.
2152
2153 =head2 Version 8 Regular Expressions
2154 X<regular expression, version 8> X<regex, version 8> X<regexp, version 8>
2155
2156 In case you're not familiar with the "regular" Version 8 regex
2157 routines, here are the pattern-matching rules not described above.
2158
2159 Any single character matches itself, unless it is a I<metacharacter>
2160 with a special meaning described here or above.  You can cause
2161 characters that normally function as metacharacters to be interpreted
2162 literally by prefixing them with a "\" (e.g., "\." matches a ".", not any
2163 character; "\\" matches a "\"). This escape mechanism is also required
2164 for the character used as the pattern delimiter.
2165
2166 A series of characters matches that series of characters in the target
2167 string, so the pattern C<blurfl> would match "blurfl" in the target
2168 string.
2169
2170 You can specify a character class, by enclosing a list of characters
2171 in C<[]>, which will match any character from the list.  If the
2172 first character after the "[" is "^", the class matches any character not
2173 in the list.  Within a list, the "-" character specifies a
2174 range, so that C<a-z> represents all characters between "a" and "z",
2175 inclusive.  If you want either "-" or "]" itself to be a member of a
2176 class, put it at the start of the list (possibly after a "^"), or
2177 escape it with a backslash.  "-" is also taken literally when it is
2178 at the end of the list, just before the closing "]".  (The
2179 following all specify the same class of three characters: C<[-az]>,
2180 C<[az-]>, and C<[a\-z]>.  All are different from C<[a-z]>, which
2181 specifies a class containing twenty-six characters, even on EBCDIC-based
2182 character sets.)  Also, if you try to use the character
2183 classes C<\w>, C<\W>, C<\s>, C<\S>, C<\d>, or C<\D> as endpoints of
2184 a range, the "-" is understood literally.
2185
2186 Note also that the whole range idea is rather unportable between
2187 character sets--and even within character sets they may cause results
2188 you probably didn't expect.  A sound principle is to use only ranges
2189 that begin from and end at either alphabetics of equal case ([a-e],
2190 [A-E]), or digits ([0-9]).  Anything else is unsafe.  If in doubt,
2191 spell out the character sets in full.
2192
2193 Characters may be specified using a metacharacter syntax much like that
2194 used in C: "\n" matches a newline, "\t" a tab, "\r" a carriage return,
2195 "\f" a form feed, etc.  More generally, \I<nnn>, where I<nnn> is a string
2196 of three octal digits, matches the character whose coded character set value
2197 is I<nnn>.  Similarly, \xI<nn>, where I<nn> are hexadecimal digits,
2198 matches the character whose ordinal is I<nn>. The expression \cI<x>
2199 matches the character control-I<x>.  Finally, the "." metacharacter
2200 matches any character except "\n" (unless you use C</s>).
2201
2202 You can specify a series of alternatives for a pattern using "|" to
2203 separate them, so that C<fee|fie|foe> will match any of "fee", "fie",
2204 or "foe" in the target string (as would C<f(e|i|o)e>).  The
2205 first alternative includes everything from the last pattern delimiter
2206 ("(", "(?:", etc. or the beginning of the pattern) up to the first "|", and
2207 the last alternative contains everything from the last "|" to the next
2208 closing pattern delimiter.  That's why it's common practice to include
2209 alternatives in parentheses: to minimize confusion about where they
2210 start and end.
2211
2212 Alternatives are tried from left to right, so the first
2213 alternative found for which the entire expression matches, is the one that
2214 is chosen. This means that alternatives are not necessarily greedy. For
2215 example: when matching C<foo|foot> against "barefoot", only the "foo"
2216 part will match, as that is the first alternative tried, and it successfully
2217 matches the target string. (This might not seem important, but it is
2218 important when you are capturing matched text using parentheses.)
2219
2220 Also remember that "|" is interpreted as a literal within square brackets,
2221 so if you write C<[fee|fie|foe]> you're really only matching C<[feio|]>.
2222
2223 Within a pattern, you may designate subpatterns for later reference
2224 by enclosing them in parentheses, and you may refer back to the
2225 I<n>th subpattern later in the pattern using the metacharacter
2226 \I<n> or \gI<n>.  Subpatterns are numbered based on the left to right order
2227 of their opening parenthesis.  A backreference matches whatever
2228 actually matched the subpattern in the string being examined, not
2229 the rules for that subpattern.  Therefore, C<(0|0x)\d*\s\g1\d*> will
2230 match "0x1234 0x4321", but not "0x1234 01234", because subpattern
2231 1 matched "0x", even though the rule C<0|0x> could potentially match
2232 the leading 0 in the second number.
2233
2234 =head2 Warning on \1 Instead of $1
2235
2236 Some people get too used to writing things like:
2237
2238     $pattern =~ s/(\W)/\\\1/g;
2239
2240 This is grandfathered (for \1 to \9) for the RHS of a substitute to avoid
2241 shocking the
2242 B<sed> addicts, but it's a dirty habit to get into.  That's because in
2243 PerlThink, the righthand side of an C<s///> is a double-quoted string.  C<\1> in
2244 the usual double-quoted string means a control-A.  The customary Unix
2245 meaning of C<\1> is kludged in for C<s///>.  However, if you get into the habit
2246 of doing that, you get yourself into trouble if you then add an C</e>
2247 modifier.
2248
2249     s/(\d+)/ \1 + 1 /eg;            # causes warning under -w
2250
2251 Or if you try to do
2252
2253     s/(\d+)/\1000/;
2254
2255 You can't disambiguate that by saying C<\{1}000>, whereas you can fix it with
2256 C<${1}000>.  The operation of interpolation should not be confused
2257 with the operation of matching a backreference.  Certainly they mean two
2258 different things on the I<left> side of the C<s///>.
2259
2260 =head2 Repeated Patterns Matching a Zero-length Substring
2261
2262 B<WARNING>: Difficult material (and prose) ahead.  This section needs a rewrite.
2263
2264 Regular expressions provide a terse and powerful programming language.  As
2265 with most other power tools, power comes together with the ability
2266 to wreak havoc.
2267
2268 A common abuse of this power stems from the ability to make infinite
2269 loops using regular expressions, with something as innocuous as:
2270
2271     'foo' =~ m{ ( o? )* }x;
2272
2273 The C<o?> matches at the beginning of C<'foo'>, and since the position
2274 in the string is not moved by the match, C<o?> would match again and again
2275 because of the C<*> quantifier.  Another common way to create a similar cycle
2276 is with the looping modifier C<//g>:
2277
2278     @matches = ( 'foo' =~ m{ o? }xg );
2279
2280 or
2281
2282     print "match: <$&>\n" while 'foo' =~ m{ o? }xg;
2283
2284 or the loop implied by split().
2285
2286 However, long experience has shown that many programming tasks may
2287 be significantly simplified by using repeated subexpressions that
2288 may match zero-length substrings.  Here's a simple example being:
2289
2290     @chars = split //, $string;           # // is not magic in split
2291     ($whitewashed = $string) =~ s/()/ /g; # parens avoid magic s// /
2292
2293 Thus Perl allows such constructs, by I<forcefully breaking
2294 the infinite loop>.  The rules for this are different for lower-level
2295 loops given by the greedy quantifiers C<*+{}>, and for higher-level
2296 ones like the C</g> modifier or split() operator.
2297
2298 The lower-level loops are I<interrupted> (that is, the loop is
2299 broken) when Perl detects that a repeated expression matched a
2300 zero-length substring.   Thus
2301
2302    m{ (?: NON_ZERO_LENGTH | ZERO_LENGTH )* }x;
2303
2304 is made equivalent to
2305
2306    m{ (?: NON_ZERO_LENGTH )* (?: ZERO_LENGTH )? }x;
2307
2308 For example, this program
2309
2310    #!perl -l
2311    "aaaaab" =~ /
2312      (?:
2313         a                 # non-zero
2314         |                 # or
2315        (?{print "hello"}) # print hello whenever this
2316                           #    branch is tried
2317        (?=(b))            # zero-width assertion
2318      )*  # any number of times
2319     /x;
2320    print $&;
2321    print $1;
2322
2323 prints
2324
2325    hello
2326    aaaaa
2327    b
2328
2329 Notice that "hello" is only printed once, as when Perl sees that the sixth
2330 iteration of the outermost C<(?:)*> matches a zero-length string, it stops
2331 the C<*>.
2332
2333 The higher-level loops preserve an additional state between iterations:
2334 whether the last match was zero-length.  To break the loop, the following
2335 match after a zero-length match is prohibited to have a length of zero.
2336 This prohibition interacts with backtracking (see L<"Backtracking">),
2337 and so the I<second best> match is chosen if the I<best> match is of
2338 zero length.
2339
2340 For example:
2341
2342     $_ = 'bar';
2343     s/\w??/<$&>/g;
2344
2345 results in C<< <><b><><a><><r><> >>.  At each position of the string the best
2346 match given by non-greedy C<??> is the zero-length match, and the I<second
2347 best> match is what is matched by C<\w>.  Thus zero-length matches
2348 alternate with one-character-long matches.
2349
2350 Similarly, for repeated C<m/()/g> the second-best match is the match at the
2351 position one notch further in the string.
2352
2353 The additional state of being I<matched with zero-length> is associated with
2354 the matched string, and is reset by each assignment to pos().
2355 Zero-length matches at the end of the previous match are ignored
2356 during C<split>.
2357
2358 =head2 Combining RE Pieces
2359
2360 Each of the elementary pieces of regular expressions which were described
2361 before (such as C<ab> or C<\Z>) could match at most one substring
2362 at the given position of the input string.  However, in a typical regular
2363 expression these elementary pieces are combined into more complicated
2364 patterns using combining operators C<ST>, C<S|T>, C<S*> etc.
2365 (in these examples C<S> and C<T> are regular subexpressions).
2366
2367 Such combinations can include alternatives, leading to a problem of choice:
2368 if we match a regular expression C<a|ab> against C<"abc">, will it match
2369 substring C<"a"> or C<"ab">?  One way to describe which substring is
2370 actually matched is the concept of backtracking (see L<"Backtracking">).
2371 However, this description is too low-level and makes you think
2372 in terms of a particular implementation.
2373
2374 Another description starts with notions of "better"/"worse".  All the
2375 substrings which may be matched by the given regular expression can be
2376 sorted from the "best" match to the "worst" match, and it is the "best"
2377 match which is chosen.  This substitutes the question of "what is chosen?"
2378 by the question of "which matches are better, and which are worse?".
2379
2380 Again, for elementary pieces there is no such question, since at most
2381 one match at a given position is possible.  This section describes the
2382 notion of better/worse for combining operators.  In the description
2383 below C<S> and C<T> are regular subexpressions.
2384
2385 =over 4
2386
2387 =item C<ST>
2388
2389 Consider two possible matches, C<AB> and C<A'B'>, C<A> and C<A'> are
2390 substrings which can be matched by C<S>, C<B> and C<B'> are substrings
2391 which can be matched by C<T>.
2392
2393 If C<A> is a better match for C<S> than C<A'>, C<AB> is a better
2394 match than C<A'B'>.
2395
2396 If C<A> and C<A'> coincide: C<AB> is a better match than C<AB'> if
2397 C<B> is a better match for C<T> than C<B'>.
2398
2399 =item C<S|T>
2400
2401 When C<S> can match, it is a better match than when only C<T> can match.
2402
2403 Ordering of two matches for C<S> is the same as for C<S>.  Similar for
2404 two matches for C<T>.
2405
2406 =item C<S{REPEAT_COUNT}>
2407
2408 Matches as C<SSS...S> (repeated as many times as necessary).
2409
2410 =item C<S{min,max}>
2411
2412 Matches as C<S{max}|S{max-1}|...|S{min+1}|S{min}>.
2413
2414 =item C<S{min,max}?>
2415
2416 Matches as C<S{min}|S{min+1}|...|S{max-1}|S{max}>.
2417
2418 =item C<S?>, C<S*>, C<S+>
2419
2420 Same as C<S{0,1}>, C<S{0,BIG_NUMBER}>, C<S{1,BIG_NUMBER}> respectively.
2421
2422 =item C<S??>, C<S*?>, C<S+?>
2423
2424 Same as C<S{0,1}?>, C<S{0,BIG_NUMBER}?>, C<S{1,BIG_NUMBER}?> respectively.
2425
2426 =item C<< (?>S) >>
2427
2428 Matches the best match for C<S> and only that.
2429
2430 =item C<(?=S)>, C<(?<=S)>
2431
2432 Only the best match for C<S> is considered.  (This is important only if
2433 C<S> has capturing parentheses, and backreferences are used somewhere
2434 else in the whole regular expression.)
2435
2436 =item C<(?!S)>, C<(?<!S)>
2437
2438 For this grouping operator there is no need to describe the ordering, since
2439 only whether or not C<S> can match is important.
2440
2441 =item C<(??{ EXPR })>, C<(?PARNO)>
2442
2443 The ordering is the same as for the regular expression which is
2444 the result of EXPR, or the pattern contained by capture group PARNO.
2445
2446 =item C<(?(condition)yes-pattern|no-pattern)>
2447
2448 Recall that which of C<yes-pattern> or C<no-pattern> actually matches is
2449 already determined.  The ordering of the matches is the same as for the
2450 chosen subexpression.
2451
2452 =back
2453
2454 The above recipes describe the ordering of matches I<at a given position>.
2455 One more rule is needed to understand how a match is determined for the
2456 whole regular expression: a match at an earlier position is always better
2457 than a match at a later position.
2458
2459 =head2 Creating Custom RE Engines
2460
2461 As of Perl 5.10.0, one can create custom regular expression engines.  This
2462 is not for the faint of heart, as they have to plug in at the C level.  See
2463 L<perlreapi> for more details.
2464
2465 As an alternative, overloaded constants (see L<overload>) provide a simple
2466 way to extend the functionality of the RE engine, by substituting one
2467 pattern for another.
2468
2469 Suppose that we want to enable a new RE escape-sequence C<\Y|> which
2470 matches at a boundary between whitespace characters and non-whitespace
2471 characters.  Note that C<(?=\S)(?<!\S)|(?!\S)(?<=\S)> matches exactly
2472 at these positions, so we want to have each C<\Y|> in the place of the
2473 more complicated version.  We can create a module C<customre> to do
2474 this:
2475
2476     package customre;
2477     use overload;
2478
2479     sub import {
2480       shift;
2481       die "No argument to customre::import allowed" if @_;
2482       overload::constant 'qr' => \&convert;
2483     }
2484
2485     sub invalid { die "/$_[0]/: invalid escape '\\$_[1]'"}
2486
2487     # We must also take care of not escaping the legitimate \\Y|
2488     # sequence, hence the presence of '\\' in the conversion rules.
2489     my %rules = ( '\\' => '\\\\',
2490                   'Y|' => qr/(?=\S)(?<!\S)|(?!\S)(?<=\S)/ );
2491     sub convert {
2492       my $re = shift;
2493       $re =~ s{
2494                 \\ ( \\ | Y . )
2495               }
2496               { $rules{$1} or invalid($re,$1) }sgex;
2497       return $re;
2498     }
2499
2500 Now C<use customre> enables the new escape in constant regular
2501 expressions, i.e., those without any runtime variable interpolations.
2502 As documented in L<overload>, this conversion will work only over
2503 literal parts of regular expressions.  For C<\Y|$re\Y|> the variable
2504 part of this regular expression needs to be converted explicitly
2505 (but only if the special meaning of C<\Y|> should be enabled inside $re):
2506
2507     use customre;
2508     $re = <>;
2509     chomp $re;
2510     $re = customre::convert $re;
2511     /\Y|$re\Y|/;
2512
2513 =head2 PCRE/Python Support
2514
2515 As of Perl 5.10.0, Perl supports several Python/PCRE-specific extensions
2516 to the regex syntax. While Perl programmers are encouraged to use the
2517 Perl-specific syntax, the following are also accepted:
2518
2519 =over 4
2520
2521 =item C<< (?PE<lt>NAMEE<gt>pattern) >>
2522
2523 Define a named capture group. Equivalent to C<< (?<NAME>pattern) >>.
2524
2525 =item C<< (?P=NAME) >>
2526
2527 Backreference to a named capture group. Equivalent to C<< \g{NAME} >>.
2528
2529 =item C<< (?P>NAME) >>
2530
2531 Subroutine call to a named capture group. Equivalent to C<< (?&NAME) >>.
2532
2533 =back
2534
2535 =head1 BUGS
2536
2537 Many regular expression constructs don't work on EBCDIC platforms.
2538
2539 There are a number of issues with regard to case-insensitive matching
2540 in Unicode rules.  See C<i> under L</Modifiers> above.
2541
2542 This document varies from difficult to understand to completely
2543 and utterly opaque.  The wandering prose riddled with jargon is
2544 hard to fathom in several places.
2545
2546 This document needs a rewrite that separates the tutorial content
2547 from the reference content.
2548
2549 =head1 SEE ALSO
2550
2551 L<perlrequick>.
2552
2553 L<perlretut>.
2554
2555 L<perlop/"Regexp Quote-Like Operators">.
2556
2557 L<perlop/"Gory details of parsing quoted constructs">.
2558
2559 L<perlfaq6>.
2560
2561 L<perlfunc/pos>.
2562
2563 L<perllocale>.
2564
2565 L<perlebcdic>.
2566
2567 I<Mastering Regular Expressions> by Jeffrey Friedl, published
2568 by O'Reilly and Associates.