POSIX: bump version to 1.30
[perl.git] / pod / perlfunc.pod
1 =head1 NAME
2 X<function>
3
4 perlfunc - Perl builtin functions
5
6 =head1 DESCRIPTION
7
8 The functions in this section can serve as terms in an expression.
9 They fall into two major categories: list operators and named unary
10 operators.  These differ in their precedence relationship with a
11 following comma.  (See the precedence table in L<perlop>.)  List
12 operators take more than one argument, while unary operators can never
13 take more than one argument.  Thus, a comma terminates the argument of
14 a unary operator, but merely separates the arguments of a list
15 operator.  A unary operator generally provides scalar context to its
16 argument, while a list operator may provide either scalar or list
17 contexts for its arguments.  If it does both, scalar arguments 
18 come first and list argument follow, and there can only ever
19 be one such list argument.  For instance, splice() has three scalar
20 arguments followed by a list, whereas gethostbyname() has four scalar
21 arguments.
22
23 In the syntax descriptions that follow, list operators that expect a
24 list (and provide list context for elements of the list) are shown
25 with LIST as an argument.  Such a list may consist of any combination
26 of scalar arguments or list values; the list values will be included
27 in the list as if each individual element were interpolated at that
28 point in the list, forming a longer single-dimensional list value.
29 Commas should separate literal elements of the LIST.
30
31 Any function in the list below may be used either with or without
32 parentheses around its arguments.  (The syntax descriptions omit the
33 parentheses.)  If you use parentheses, the simple but occasionally 
34 surprising rule is this: It I<looks> like a function, therefore it I<is> a
35 function, and precedence doesn't matter.  Otherwise it's a list
36 operator or unary operator, and precedence does matter.  Whitespace
37 between the function and left parenthesis doesn't count, so sometimes
38 you need to be careful:
39
40     print 1+2+4;      # Prints 7.
41     print(1+2) + 4;   # Prints 3.
42     print (1+2)+4;    # Also prints 3!
43     print +(1+2)+4;   # Prints 7.
44     print ((1+2)+4);  # Prints 7.
45
46 If you run Perl with the B<-w> switch it can warn you about this.  For
47 example, the third line above produces:
48
49     print (...) interpreted as function at - line 1.
50     Useless use of integer addition in void context at - line 1.
51
52 A few functions take no arguments at all, and therefore work as neither
53 unary nor list operators.  These include such functions as C<time>
54 and C<endpwent>.  For example, C<time+86_400> always means
55 C<time() + 86_400>.
56
57 For functions that can be used in either a scalar or list context,
58 nonabortive failure is generally indicated in scalar context by
59 returning the undefined value, and in list context by returning the
60 empty list.
61
62 Remember the following important rule: There is B<no rule> that relates
63 the behavior of an expression in list context to its behavior in scalar
64 context, or vice versa.  It might do two totally different things.
65 Each operator and function decides which sort of value would be most
66 appropriate to return in scalar context.  Some operators return the
67 length of the list that would have been returned in list context.  Some
68 operators return the first value in the list.  Some operators return the
69 last value in the list.  Some operators return a count of successful
70 operations.  In general, they do what you want, unless you want
71 consistency.
72 X<context>
73
74 A named array in scalar context is quite different from what would at
75 first glance appear to be a list in scalar context.  You can't get a list
76 like C<(1,2,3)> into being in scalar context, because the compiler knows
77 the context at compile time.  It would generate the scalar comma operator
78 there, not the list construction version of the comma.  That means it
79 was never a list to start with.
80
81 In general, functions in Perl that serve as wrappers for system calls ("syscalls")
82 of the same name (like chown(2), fork(2), closedir(2), etc.) return
83 true when they succeed and C<undef> otherwise, as is usually mentioned
84 in the descriptions below.  This is different from the C interfaces,
85 which return C<-1> on failure.  Exceptions to this rule include C<wait>,
86 C<waitpid>, and C<syscall>.  System calls also set the special C<$!>
87 variable on failure.  Other functions do not, except accidentally.
88
89 Extension modules can also hook into the Perl parser to define new
90 kinds of keyword-headed expression.  These may look like functions, but
91 may also look completely different.  The syntax following the keyword
92 is defined entirely by the extension.  If you are an implementor, see
93 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
94 a module, see the module's documentation for details of the syntax that
95 it defines.
96
97 =head2 Perl Functions by Category
98 X<function>
99
100 Here are Perl's functions (including things that look like
101 functions, like some keywords and named operators)
102 arranged by category.  Some functions appear in more
103 than one place.
104
105 =over 4
106
107 =item Functions for SCALARs or strings
108 X<scalar> X<string> X<character>
109
110 C<chomp>, C<chop>, C<chr>, C<crypt>, C<fc>, C<hex>, C<index>, C<lc>,
111 C<lcfirst>, C<length>, C<oct>, C<ord>, C<pack>, C<q//>, C<qq//>, C<reverse>,
112 C<rindex>, C<sprintf>, C<substr>, C<tr///>, C<uc>, C<ucfirst>, C<y///>
113
114 C<fc> is available only if the C<"fc"> feature is enabled or if it is
115 prefixed with C<CORE::>.  The C<"fc"> feature is enabled automatically
116 with a C<use v5.16> (or higher) declaration in the current scope.
117
118
119 =item Regular expressions and pattern matching
120 X<regular expression> X<regex> X<regexp>
121
122 C<m//>, C<pos>, C<quotemeta>, C<s///>, C<split>, C<study>, C<qr//>
123
124 =item Numeric functions
125 X<numeric> X<number> X<trigonometric> X<trigonometry>
126
127 C<abs>, C<atan2>, C<cos>, C<exp>, C<hex>, C<int>, C<log>, C<oct>, C<rand>,
128 C<sin>, C<sqrt>, C<srand>
129
130 =item Functions for real @ARRAYs
131 X<array>
132
133 C<each>, C<keys>, C<pop>, C<push>, C<shift>, C<splice>, C<unshift>, C<values>
134
135 =item Functions for list data
136 X<list>
137
138 C<grep>, C<join>, C<map>, C<qw//>, C<reverse>, C<sort>, C<unpack>
139
140 =item Functions for real %HASHes
141 X<hash>
142
143 C<delete>, C<each>, C<exists>, C<keys>, C<values>
144
145 =item Input and output functions
146 X<I/O> X<input> X<output> X<dbm>
147
148 C<binmode>, C<close>, C<closedir>, C<dbmclose>, C<dbmopen>, C<die>, C<eof>,
149 C<fileno>, C<flock>, C<format>, C<getc>, C<print>, C<printf>, C<read>,
150 C<readdir>, C<rewinddir>, C<say>, C<seek>, C<seekdir>, C<select>, C<syscall>,
151 C<sysread>, C<sysseek>, C<syswrite>, C<tell>, C<telldir>, C<truncate>,
152 C<warn>, C<write>
153
154 C<say> is available only if the C<"say"> feature is enabled or if it is
155 prefixed with C<CORE::>.  The C<"say"> feature is enabled automatically
156 with a C<use v5.10> (or higher) declaration in the current scope.
157
158 =item Functions for fixed-length data or records
159
160 C<pack>, C<read>, C<syscall>, C<sysread>, C<syswrite>, C<unpack>, C<vec>
161
162 =item Functions for filehandles, files, or directories
163 X<file> X<filehandle> X<directory> X<pipe> X<link> X<symlink>
164
165 C<-I<X>>, C<chdir>, C<chmod>, C<chown>, C<chroot>, C<fcntl>, C<glob>,
166 C<ioctl>, C<link>, C<lstat>, C<mkdir>, C<open>, C<opendir>,
167 C<readlink>, C<rename>, C<rmdir>, C<stat>, C<symlink>, C<sysopen>,
168 C<umask>, C<unlink>, C<utime>
169
170 =item Keywords related to the control flow of your Perl program
171 X<control flow>
172
173 C<caller>, C<continue>, C<die>, C<do>,
174 C<dump>, C<eval>, C<evalbytes> C<exit>,
175 C<__FILE__>, C<goto>, C<last>, C<__LINE__>, C<next>, C<__PACKAGE__>,
176 C<redo>, C<return>, C<sub>, C<__SUB__>, C<wantarray>
177
178 C<evalbytes> is only available with with the C<"evalbytes"> feature (see
179 L<feature>) or if prefixed with C<CORE::>.  C<__SUB__> is only available
180 with with the C<"current_sub"> feature or if prefixed with C<CORE::>. Both
181 the C<"evalbytes"> and C<"current_sub"> features are enabled automatically
182 with a C<use v5.16> (or higher) declaration in the current scope.
183
184 =item Keywords related to the switch feature
185
186 C<break>, C<continue>, C<default>, C<given>, C<when>
187
188 Except for C<continue>, these are available only if you enable the
189 C<"switch"> feature or use the C<CORE::> prefix.  See L<feature> and
190 L<perlsyn/"Switch Statements">.  The C<"switch"> feature is enabled
191 automatically with a C<use v5.10> (or higher) declaration in the current
192 scope.  In Perl 5.14 and earlier, C<continue> required the C<"switch">
193 feature, like the other keywords.
194
195 =item Keywords related to scoping
196
197 C<caller>, C<import>, C<local>, C<my>, C<our>, C<package>, C<state>, C<use>
198
199 C<state> is available only if the C<"state"> feature is enabled or if it is
200 prefixed with C<CORE::>.  The C<"state"> feature is enabled automatically
201 with a C<use v5.10> (or higher) declaration in the current scope.
202
203 =item Miscellaneous functions
204
205 C<defined>, C<dump>, C<eval>, C<evalbytes>,
206 C<formline>, C<local>, C<my>, C<our>,
207 C<reset>, C<scalar>, C<state>, C<undef>, C<wantarray>
208
209 =item Functions for processes and process groups
210 X<process> X<pid> X<process id>
211
212 C<alarm>, C<exec>, C<fork>, C<getpgrp>, C<getppid>, C<getpriority>, C<kill>,
213 C<pipe>, C<qx//>, C<readpipe>, C<setpgrp>,
214 C<setpriority>, C<sleep>, C<system>,
215 C<times>, C<wait>, C<waitpid>
216
217 =item Keywords related to Perl modules
218 X<module>
219
220 C<do>, C<import>, C<no>, C<package>, C<require>, C<use>
221
222 =item Keywords related to classes and object-orientation
223 X<object> X<class> X<package>
224
225 C<bless>, C<dbmclose>, C<dbmopen>, C<package>, C<ref>, C<tie>, C<tied>,
226 C<untie>, C<use>
227
228 =item Low-level socket functions
229 X<socket> X<sock>
230
231 C<accept>, C<bind>, C<connect>, C<getpeername>, C<getsockname>,
232 C<getsockopt>, C<listen>, C<recv>, C<send>, C<setsockopt>, C<shutdown>,
233 C<socket>, C<socketpair>
234
235 =item System V interprocess communication functions
236 X<IPC> X<System V> X<semaphore> X<shared memory> X<memory> X<message>
237
238 C<msgctl>, C<msgget>, C<msgrcv>, C<msgsnd>, C<semctl>, C<semget>, C<semop>,
239 C<shmctl>, C<shmget>, C<shmread>, C<shmwrite>
240
241 =item Fetching user and group info
242 X<user> X<group> X<password> X<uid> X<gid>  X<passwd> X</etc/passwd>
243
244 C<endgrent>, C<endhostent>, C<endnetent>, C<endpwent>, C<getgrent>,
245 C<getgrgid>, C<getgrnam>, C<getlogin>, C<getpwent>, C<getpwnam>,
246 C<getpwuid>, C<setgrent>, C<setpwent>
247
248 =item Fetching network info
249 X<network> X<protocol> X<host> X<hostname> X<IP> X<address> X<service>
250
251 C<endprotoent>, C<endservent>, C<gethostbyaddr>, C<gethostbyname>,
252 C<gethostent>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
253 C<getprotobyname>, C<getprotobynumber>, C<getprotoent>,
254 C<getservbyname>, C<getservbyport>, C<getservent>, C<sethostent>,
255 C<setnetent>, C<setprotoent>, C<setservent>
256
257 =item Time-related functions
258 X<time> X<date>
259
260 C<gmtime>, C<localtime>, C<time>, C<times>
261
262 =item Non-function keywords
263
264 C<AUTOLOAD>, C<BEGIN>, C<CHECK>, C<CORE>, C<DESTROY>, C<END>, C<INIT>,
265 C<UNITCHECK>, C<__DATA__>, C<__END__>, C<and>, C<cmp>, C<else>, C<elseif>,
266 C<elsif>, C<eq>, C<for>, C<foreach>, C<ge>, C<gt>, C<if>, C<le>, C<lt>, C<ne>,
267 C<not>, C<or>, C<unless>, C<until>, C<while>, C<x>, C<xor>
268
269 =back
270
271 =head2 Portability
272 X<portability> X<Unix> X<portable>
273
274 Perl was born in Unix and can therefore access all common Unix
275 system calls.  In non-Unix environments, the functionality of some
276 Unix system calls may not be available or details of the available
277 functionality may differ slightly.  The Perl functions affected
278 by this are:
279
280 C<-X>, C<binmode>, C<chmod>, C<chown>, C<chroot>, C<crypt>,
281 C<dbmclose>, C<dbmopen>, C<dump>, C<endgrent>, C<endhostent>,
282 C<endnetent>, C<endprotoent>, C<endpwent>, C<endservent>, C<exec>,
283 C<fcntl>, C<flock>, C<fork>, C<getgrent>, C<getgrgid>, C<gethostbyname>,
284 C<gethostent>, C<getlogin>, C<getnetbyaddr>, C<getnetbyname>, C<getnetent>,
285 C<getppid>, C<getpgrp>, C<getpriority>, C<getprotobynumber>,
286 C<getprotoent>, C<getpwent>, C<getpwnam>, C<getpwuid>,
287 C<getservbyport>, C<getservent>, C<getsockopt>, C<glob>, C<ioctl>,
288 C<kill>, C<link>, C<lstat>, C<msgctl>, C<msgget>, C<msgrcv>,
289 C<msgsnd>, C<open>, C<pipe>, C<readlink>, C<rename>, C<select>, C<semctl>,
290 C<semget>, C<semop>, C<setgrent>, C<sethostent>, C<setnetent>,
291 C<setpgrp>, C<setpriority>, C<setprotoent>, C<setpwent>,
292 C<setservent>, C<setsockopt>, C<shmctl>, C<shmget>, C<shmread>,
293 C<shmwrite>, C<socket>, C<socketpair>,
294 C<stat>, C<symlink>, C<syscall>, C<sysopen>, C<system>,
295 C<times>, C<truncate>, C<umask>, C<unlink>,
296 C<utime>, C<wait>, C<waitpid>
297
298 For more information about the portability of these functions, see
299 L<perlport> and other available platform-specific documentation.
300
301 =head2 Alphabetical Listing of Perl Functions
302
303 =over 
304
305 =item -X FILEHANDLE
306 X<-r>X<-w>X<-x>X<-o>X<-R>X<-W>X<-X>X<-O>X<-e>X<-z>X<-s>X<-f>X<-d>X<-l>X<-p>
307 X<-S>X<-b>X<-c>X<-t>X<-u>X<-g>X<-k>X<-T>X<-B>X<-M>X<-A>X<-C>
308
309 =item -X EXPR
310
311 =item -X DIRHANDLE
312
313 =item -X
314
315 A file test, where X is one of the letters listed below.  This unary
316 operator takes one argument, either a filename, a filehandle, or a dirhandle, 
317 and tests the associated file to see if something is true about it.  If the
318 argument is omitted, tests C<$_>, except for C<-t>, which tests STDIN.
319 Unless otherwise documented, it returns C<1> for true and C<''> for false, or
320 the undefined value if the file doesn't exist.  Despite the funny
321 names, precedence is the same as any other named unary operator.  The
322 operator may be any of:
323
324     -r  File is readable by effective uid/gid.
325     -w  File is writable by effective uid/gid.
326     -x  File is executable by effective uid/gid.
327     -o  File is owned by effective uid.
328
329     -R  File is readable by real uid/gid.
330     -W  File is writable by real uid/gid.
331     -X  File is executable by real uid/gid.
332     -O  File is owned by real uid.
333
334     -e  File exists.
335     -z  File has zero size (is empty).
336     -s  File has nonzero size (returns size in bytes).
337
338     -f  File is a plain file.
339     -d  File is a directory.
340     -l  File is a symbolic link.
341     -p  File is a named pipe (FIFO), or Filehandle is a pipe.
342     -S  File is a socket.
343     -b  File is a block special file.
344     -c  File is a character special file.
345     -t  Filehandle is opened to a tty.
346
347     -u  File has setuid bit set.
348     -g  File has setgid bit set.
349     -k  File has sticky bit set.
350
351     -T  File is an ASCII text file (heuristic guess).
352     -B  File is a "binary" file (opposite of -T).
353
354     -M  Script start time minus file modification time, in days.
355     -A  Same for access time.
356     -C  Same for inode change time (Unix, may differ for other platforms)
357
358 Example:
359
360     while (<>) {
361         chomp;
362         next unless -f $_;  # ignore specials
363         #...
364     }
365
366 Note that C<-s/a/b/> does not do a negated substitution.  Saying
367 C<-exp($foo)> still works as expected, however: only single letters
368 following a minus are interpreted as file tests.
369
370 These operators are exempt from the "looks like a function rule" described
371 above.  That is, an opening parenthesis after the operator does not affect
372 how much of the following code constitutes the argument.  Put the opening
373 parentheses before the operator to separate it from code that follows (this
374 applies only to operators with higher precedence than unary operators, of
375 course):
376
377     -s($file) + 1024   # probably wrong; same as -s($file + 1024)
378     (-s $file) + 1024  # correct
379
380 The interpretation of the file permission operators C<-r>, C<-R>,
381 C<-w>, C<-W>, C<-x>, and C<-X> is by default based solely on the mode
382 of the file and the uids and gids of the user.  There may be other
383 reasons you can't actually read, write, or execute the file: for
384 example network filesystem access controls, ACLs (access control lists),
385 read-only filesystems, and unrecognized executable formats.  Note
386 that the use of these six specific operators to verify if some operation
387 is possible is usually a mistake, because it may be open to race
388 conditions.
389
390 Also note that, for the superuser on the local filesystems, the C<-r>,
391 C<-R>, C<-w>, and C<-W> tests always return 1, and C<-x> and C<-X> return 1
392 if any execute bit is set in the mode.  Scripts run by the superuser
393 may thus need to do a stat() to determine the actual mode of the file,
394 or temporarily set their effective uid to something else.
395
396 If you are using ACLs, there is a pragma called C<filetest> that may
397 produce more accurate results than the bare stat() mode bits.
398 When under C<use filetest 'access'> the above-mentioned filetests
399 test whether the permission can(not) be granted using the
400 access(2) family of system calls.  Also note that the C<-x> and C<-X> may
401 under this pragma return true even if there are no execute permission
402 bits set (nor any extra execute permission ACLs).  This strangeness is
403 due to the underlying system calls' definitions.  Note also that, due to
404 the implementation of C<use filetest 'access'>, the C<_> special
405 filehandle won't cache the results of the file tests when this pragma is
406 in effect.  Read the documentation for the C<filetest> pragma for more
407 information.
408
409 The C<-T> and C<-B> switches work as follows.  The first block or so of the
410 file is examined for odd characters such as strange control codes or
411 characters with the high bit set.  If too many strange characters (>30%)
412 are found, it's a C<-B> file; otherwise it's a C<-T> file.  Also, any file
413 containing a zero byte in the first block is considered a binary file.  If C<-T>
414 or C<-B> is used on a filehandle, the current IO buffer is examined
415 rather than the first block.  Both C<-T> and C<-B> return true on an empty
416 file, or a file at EOF when testing a filehandle.  Because you have to
417 read a file to do the C<-T> test, on most occasions you want to use a C<-f>
418 against the file first, as in C<next unless -f $file && -T $file>.
419
420 If any of the file tests (or either the C<stat> or C<lstat> operator) is given
421 the special filehandle consisting of a solitary underline, then the stat
422 structure of the previous file test (or stat operator) is used, saving
423 a system call.  (This doesn't work with C<-t>, and you need to remember
424 that lstat() and C<-l> leave values in the stat structure for the
425 symbolic link, not the real file.)  (Also, if the stat buffer was filled by
426 an C<lstat> call, C<-T> and C<-B> will reset it with the results of C<stat _>).
427 Example:
428
429     print "Can do.\n" if -r $a || -w _ || -x _;
430
431     stat($filename);
432     print "Readable\n" if -r _;
433     print "Writable\n" if -w _;
434     print "Executable\n" if -x _;
435     print "Setuid\n" if -u _;
436     print "Setgid\n" if -g _;
437     print "Sticky\n" if -k _;
438     print "Text\n" if -T _;
439     print "Binary\n" if -B _;
440
441 As of Perl 5.9.1, as a form of purely syntactic sugar, you can stack file
442 test operators, in a way that C<-f -w -x $file> is equivalent to
443 C<-x $file && -w _ && -f _>.  (This is only fancy fancy: if you use
444 the return value of C<-f $file> as an argument to another filetest
445 operator, no special magic will happen.)
446
447 Portability issues: L<perlport/-X>.
448
449 To avoid confusing would-be users of your code with mysterious
450 syntax errors, put something like this at the top of your script:
451
452     use 5.010;  # so filetest ops can stack
453
454 =item abs VALUE
455 X<abs> X<absolute>
456
457 =item abs
458
459 Returns the absolute value of its argument.
460 If VALUE is omitted, uses C<$_>.
461
462 =item accept NEWSOCKET,GENERICSOCKET
463 X<accept>
464
465 Accepts an incoming socket connect, just as accept(2) 
466 does.  Returns the packed address if it succeeded, false otherwise.
467 See the example in L<perlipc/"Sockets: Client/Server Communication">.
468
469 On systems that support a close-on-exec flag on files, the flag will
470 be set for the newly opened file descriptor, as determined by the
471 value of $^F.  See L<perlvar/$^F>.
472
473 =item alarm SECONDS
474 X<alarm>
475 X<SIGALRM>
476 X<timer>
477
478 =item alarm
479
480 Arranges to have a SIGALRM delivered to this process after the
481 specified number of wallclock seconds has elapsed.  If SECONDS is not
482 specified, the value stored in C<$_> is used.  (On some machines,
483 unfortunately, the elapsed time may be up to one second less or more
484 than you specified because of how seconds are counted, and process
485 scheduling may delay the delivery of the signal even further.)
486
487 Only one timer may be counting at once.  Each call disables the
488 previous timer, and an argument of C<0> may be supplied to cancel the
489 previous timer without starting a new one.  The returned value is the
490 amount of time remaining on the previous timer.
491
492 For delays of finer granularity than one second, the Time::HiRes module
493 (from CPAN, and starting from Perl 5.8 part of the standard
494 distribution) provides ualarm().  You may also use Perl's four-argument
495 version of select() leaving the first three arguments undefined, or you
496 might be able to use the C<syscall> interface to access setitimer(2) if
497 your system supports it.  See L<perlfaq8> for details.
498
499 It is usually a mistake to intermix C<alarm> and C<sleep> calls, because
500 C<sleep> may be internally implemented on your system with C<alarm>.
501
502 If you want to use C<alarm> to time out a system call you need to use an
503 C<eval>/C<die> pair.  You can't rely on the alarm causing the system call to
504 fail with C<$!> set to C<EINTR> because Perl sets up signal handlers to
505 restart system calls on some systems.  Using C<eval>/C<die> always works,
506 modulo the caveats given in L<perlipc/"Signals">.
507
508     eval {
509         local $SIG{ALRM} = sub { die "alarm\n" }; # NB: \n required
510         alarm $timeout;
511         $nread = sysread SOCKET, $buffer, $size;
512         alarm 0;
513     };
514     if ($@) {
515         die unless $@ eq "alarm\n";   # propagate unexpected errors
516         # timed out
517     }
518     else {
519         # didn't
520     }
521
522 For more information see L<perlipc>.
523
524 Portability issues: L<perlport/alarm>.
525
526 =item atan2 Y,X
527 X<atan2> X<arctangent> X<tan> X<tangent>
528
529 Returns the arctangent of Y/X in the range -PI to PI.
530
531 For the tangent operation, you may use the C<Math::Trig::tan>
532 function, or use the familiar relation:
533
534     sub tan { sin($_[0]) / cos($_[0])  }
535
536 The return value for C<atan2(0,0)> is implementation-defined; consult
537 your atan2(3) manpage for more information.
538
539 Portability issues: L<perlport/atan2>.
540
541 =item bind SOCKET,NAME
542 X<bind>
543
544 Binds a network address to a socket, just as bind(2)
545 does.  Returns true if it succeeded, false otherwise.  NAME should be a
546 packed address of the appropriate type for the socket.  See the examples in
547 L<perlipc/"Sockets: Client/Server Communication">.
548
549 =item binmode FILEHANDLE, LAYER
550 X<binmode> X<binary> X<text> X<DOS> X<Windows>
551
552 =item binmode FILEHANDLE
553
554 Arranges for FILEHANDLE to be read or written in "binary" or "text"
555 mode on systems where the run-time libraries distinguish between
556 binary and text files.  If FILEHANDLE is an expression, the value is
557 taken as the name of the filehandle.  Returns true on success,
558 otherwise it returns C<undef> and sets C<$!> (errno).
559
560 On some systems (in general, DOS- and Windows-based systems) binmode()
561 is necessary when you're not working with a text file.  For the sake
562 of portability it is a good idea always to use it when appropriate,
563 and never to use it when it isn't appropriate.  Also, people can
564 set their I/O to be by default UTF8-encoded Unicode, not bytes.
565
566 In other words: regardless of platform, use binmode() on binary data,
567 like images, for example.
568
569 If LAYER is present it is a single string, but may contain multiple
570 directives.  The directives alter the behaviour of the filehandle.
571 When LAYER is present, using binmode on a text file makes sense.
572
573 If LAYER is omitted or specified as C<:raw> the filehandle is made
574 suitable for passing binary data.  This includes turning off possible CRLF
575 translation and marking it as bytes (as opposed to Unicode characters).
576 Note that, despite what may be implied in I<"Programming Perl"> (the
577 Camel, 3rd edition) or elsewhere, C<:raw> is I<not> simply the inverse of C<:crlf>.
578 Other layers that would affect the binary nature of the stream are
579 I<also> disabled.  See L<PerlIO>, L<perlrun>, and the discussion about the
580 PERLIO environment variable.
581
582 The C<:bytes>, C<:crlf>, C<:utf8>, and any other directives of the
583 form C<:...>, are called I/O I<layers>.  The C<open> pragma can be used to
584 establish default I/O layers.  See L<open>.
585
586 I<The LAYER parameter of the binmode() function is described as "DISCIPLINE"
587 in "Programming Perl, 3rd Edition".  However, since the publishing of this
588 book, by many known as "Camel III", the consensus of the naming of this
589 functionality has moved from "discipline" to "layer".  All documentation
590 of this version of Perl therefore refers to "layers" rather than to
591 "disciplines".  Now back to the regularly scheduled documentation...>
592
593 To mark FILEHANDLE as UTF-8, use C<:utf8> or C<:encoding(UTF-8)>.
594 C<:utf8> just marks the data as UTF-8 without further checking,
595 while C<:encoding(UTF-8)> checks the data for actually being valid
596 UTF-8.  More details can be found in L<PerlIO::encoding>.
597
598 In general, binmode() should be called after open() but before any I/O
599 is done on the filehandle.  Calling binmode() normally flushes any
600 pending buffered output data (and perhaps pending input data) on the
601 handle.  An exception to this is the C<:encoding> layer that
602 changes the default character encoding of the handle; see L</open>.
603 The C<:encoding> layer sometimes needs to be called in
604 mid-stream, and it doesn't flush the stream.  The C<:encoding>
605 also implicitly pushes on top of itself the C<:utf8> layer because
606 internally Perl operates on UTF8-encoded Unicode characters.
607
608 The operating system, device drivers, C libraries, and Perl run-time
609 system all conspire to let the programmer treat a single
610 character (C<\n>) as the line terminator, irrespective of external
611 representation.  On many operating systems, the native text file
612 representation matches the internal representation, but on some
613 platforms the external representation of C<\n> is made up of more than
614 one character.
615
616 All variants of Unix, Mac OS (old and new), and Stream_LF files on VMS use
617 a single character to end each line in the external representation of text
618 (even though that single character is CARRIAGE RETURN on old, pre-Darwin
619 flavors of Mac OS, and is LINE FEED on Unix and most VMS files).  In other
620 systems like OS/2, DOS, and the various flavors of MS-Windows, your program
621 sees a C<\n> as a simple C<\cJ>, but what's stored in text files are the
622 two characters C<\cM\cJ>.  That means that if you don't use binmode() on
623 these systems, C<\cM\cJ> sequences on disk will be converted to C<\n> on
624 input, and any C<\n> in your program will be converted back to C<\cM\cJ> on
625 output.  This is what you want for text files, but it can be disastrous for
626 binary files.
627
628 Another consequence of using binmode() (on some systems) is that
629 special end-of-file markers will be seen as part of the data stream.
630 For systems from the Microsoft family this means that, if your binary
631 data contain C<\cZ>, the I/O subsystem will regard it as the end of
632 the file, unless you use binmode().
633
634 binmode() is important not only for readline() and print() operations,
635 but also when using read(), seek(), sysread(), syswrite() and tell()
636 (see L<perlport> for more details).  See the C<$/> and C<$\> variables
637 in L<perlvar> for how to manually set your input and output
638 line-termination sequences.
639
640 Portability issues: L<perlport/binmode>.
641
642 =item bless REF,CLASSNAME
643 X<bless>
644
645 =item bless REF
646
647 This function tells the thingy referenced by REF that it is now an object
648 in the CLASSNAME package.  If CLASSNAME is omitted, the current package
649 is used.  Because a C<bless> is often the last thing in a constructor,
650 it returns the reference for convenience.  Always use the two-argument
651 version if a derived class might inherit the function doing the blessing.
652 SeeL<perlobj> for more about the blessing (and blessings) of objects.
653
654 Consider always blessing objects in CLASSNAMEs that are mixed case.
655 Namespaces with all lowercase names are considered reserved for
656 Perl pragmata.  Builtin types have all uppercase names.  To prevent
657 confusion, you may wish to avoid such package names as well.  Make sure
658 that CLASSNAME is a true value.
659
660 See L<perlmod/"Perl Modules">.
661
662 =item break
663
664 Break out of a C<given()> block.
665
666 This keyword is enabled by the C<"switch"> feature: see
667 L<feature> for more information.  You can also access it by
668 prefixing it with C<CORE::>.  Alternately, include a C<use
669 v5.10> or later to the current scope.
670
671 =item caller EXPR
672 X<caller> X<call stack> X<stack> X<stack trace>
673
674 =item caller
675
676 Returns the context of the current subroutine call.  In scalar context,
677 returns the caller's package name if there I<is> a caller (that is, if
678 we're in a subroutine or C<eval> or C<require>) and the undefined value
679 otherwise.  In list context, returns
680
681     # 0         1          2
682     ($package, $filename, $line) = caller;
683
684 With EXPR, it returns some extra information that the debugger uses to
685 print a stack trace.  The value of EXPR indicates how many call frames
686 to go back before the current one.
687
688     #  0         1          2      3            4
689     ($package, $filename, $line, $subroutine, $hasargs,
690
691     #  5          6          7            8       9         10
692     $wantarray, $evaltext, $is_require, $hints, $bitmask, $hinthash)
693      = caller($i);
694
695 Here $subroutine may be C<(eval)> if the frame is not a subroutine
696 call, but an C<eval>.  In such a case additional elements $evaltext and
697 C<$is_require> are set: C<$is_require> is true if the frame is created by a
698 C<require> or C<use> statement, $evaltext contains the text of the
699 C<eval EXPR> statement.  In particular, for an C<eval BLOCK> statement,
700 $subroutine is C<(eval)>, but $evaltext is undefined.  (Note also that
701 each C<use> statement creates a C<require> frame inside an C<eval EXPR>
702 frame.)  $subroutine may also be C<(unknown)> if this particular
703 subroutine happens to have been deleted from the symbol table.
704 C<$hasargs> is true if a new instance of C<@_> was set up for the frame.
705 C<$hints> and C<$bitmask> contain pragmatic hints that the caller was
706 compiled with.  The C<$hints> and C<$bitmask> values are subject to change
707 between versions of Perl, and are not meant for external use.
708
709 C<$hinthash> is a reference to a hash containing the value of C<%^H> when the
710 caller was compiled, or C<undef> if C<%^H> was empty.  Do not modify the values
711 of this hash, as they are the actual values stored in the optree.
712
713 Furthermore, when called from within the DB package in
714 list context, and with an argument, caller returns more
715 detailed information: it sets the list variable C<@DB::args> to be the
716 arguments with which the subroutine was invoked.
717
718 Be aware that the optimizer might have optimized call frames away before
719 C<caller> had a chance to get the information.  That means that C<caller(N)>
720 might not return information about the call frame you expect it to, for
721 C<< N > 1 >>.  In particular, C<@DB::args> might have information from the
722 previous time C<caller> was called.
723
724 Be aware that setting C<@DB::args> is I<best effort>, intended for
725 debugging or generating backtraces, and should not be relied upon.  In
726 particular, as C<@_> contains aliases to the caller's arguments, Perl does
727 not take a copy of C<@_>, so C<@DB::args> will contain modifications the
728 subroutine makes to C<@_> or its contents, not the original values at call
729 time.  C<@DB::args>, like C<@_>, does not hold explicit references to its
730 elements, so under certain cases its elements may have become freed and
731 reallocated for other variables or temporary values.  Finally, a side effect
732 of the current implementation is that the effects of C<shift @_> can
733 I<normally> be undone (but not C<pop @_> or other splicing, I<and> not if a
734 reference to C<@_> has been taken, I<and> subject to the caveat about reallocated
735 elements), so C<@DB::args> is actually a hybrid of the current state and
736 initial state of C<@_>.  Buyer beware.
737
738 =item chdir EXPR
739 X<chdir>
740 X<cd>
741 X<directory, change>
742
743 =item chdir FILEHANDLE
744
745 =item chdir DIRHANDLE
746
747 =item chdir
748
749 Changes the working directory to EXPR, if possible.  If EXPR is omitted,
750 changes to the directory specified by C<$ENV{HOME}>, if set; if not,
751 changes to the directory specified by C<$ENV{LOGDIR}>.  (Under VMS, the
752 variable C<$ENV{SYS$LOGIN}> is also checked, and used if it is set.)  If
753 neither is set, C<chdir> does nothing.  It returns true on success,
754 false otherwise.  See the example under C<die>.
755
756 On systems that support fchdir(2), you may pass a filehandle or
757 directory handle as the argument.  On systems that don't support fchdir(2),
758 passing handles raises an exception.
759
760 =item chmod LIST
761 X<chmod> X<permission> X<mode>
762
763 Changes the permissions of a list of files.  The first element of the
764 list must be the numeric mode, which should probably be an octal
765 number, and which definitely should I<not> be a string of octal digits:
766 C<0644> is okay, but C<"0644"> is not.  Returns the number of files
767 successfully changed.  See also L</oct> if all you have is a string.
768
769     $cnt = chmod 0755, "foo", "bar";
770     chmod 0755, @executables;
771     $mode = "0644"; chmod $mode, "foo";      # !!! sets mode to
772                                              # --w----r-T
773     $mode = "0644"; chmod oct($mode), "foo"; # this is better
774     $mode = 0644;   chmod $mode, "foo";      # this is best
775
776 On systems that support fchmod(2), you may pass filehandles among the
777 files.  On systems that don't support fchmod(2), passing filehandles raises
778 an exception.  Filehandles must be passed as globs or glob references to be
779 recognized; barewords are considered filenames.
780
781     open(my $fh, "<", "foo");
782     my $perm = (stat $fh)[2] & 07777;
783     chmod($perm | 0600, $fh);
784
785 You can also import the symbolic C<S_I*> constants from the C<Fcntl>
786 module:
787
788     use Fcntl qw( :mode );
789     chmod S_IRWXU|S_IRGRP|S_IXGRP|S_IROTH|S_IXOTH, @executables;
790     # Identical to the chmod 0755 of the example above.
791
792 Portability issues: L<perlport/chmod>.
793
794 =item chomp VARIABLE
795 X<chomp> X<INPUT_RECORD_SEPARATOR> X<$/> X<newline> X<eol>
796
797 =item chomp( LIST )
798
799 =item chomp
800
801 This safer version of L</chop> removes any trailing string
802 that corresponds to the current value of C<$/> (also known as
803 $INPUT_RECORD_SEPARATOR in the C<English> module).  It returns the total
804 number of characters removed from all its arguments.  It's often used to
805 remove the newline from the end of an input record when you're worried
806 that the final record may be missing its newline.  When in paragraph
807 mode (C<$/ = "">), it removes all trailing newlines from the string.
808 When in slurp mode (C<$/ = undef>) or fixed-length record mode (C<$/> is
809 a reference to an integer or the like; see L<perlvar>) chomp() won't
810 remove anything.
811 If VARIABLE is omitted, it chomps C<$_>.  Example:
812
813     while (<>) {
814         chomp;  # avoid \n on last field
815         @array = split(/:/);
816         # ...
817     }
818
819 If VARIABLE is a hash, it chomps the hash's values, but not its keys.
820
821 You can actually chomp anything that's an lvalue, including an assignment:
822
823     chomp($cwd = `pwd`);
824     chomp($answer = <STDIN>);
825
826 If you chomp a list, each element is chomped, and the total number of
827 characters removed is returned.
828
829 Note that parentheses are necessary when you're chomping anything
830 that is not a simple variable.  This is because C<chomp $cwd = `pwd`;>
831 is interpreted as C<(chomp $cwd) = `pwd`;>, rather than as
832 C<chomp( $cwd = `pwd` )> which you might expect.  Similarly,
833 C<chomp $a, $b> is interpreted as C<chomp($a), $b> rather than
834 as C<chomp($a, $b)>.
835
836 =item chop VARIABLE
837 X<chop>
838
839 =item chop( LIST )
840
841 =item chop
842
843 Chops off the last character of a string and returns the character
844 chopped.  It is much more efficient than C<s/.$//s> because it neither
845 scans nor copies the string.  If VARIABLE is omitted, chops C<$_>.
846 If VARIABLE is a hash, it chops the hash's values, but not its keys.
847
848 You can actually chop anything that's an lvalue, including an assignment.
849
850 If you chop a list, each element is chopped.  Only the value of the
851 last C<chop> is returned.
852
853 Note that C<chop> returns the last character.  To return all but the last
854 character, use C<substr($string, 0, -1)>.
855
856 See also L</chomp>.
857
858 =item chown LIST
859 X<chown> X<owner> X<user> X<group>
860
861 Changes the owner (and group) of a list of files.  The first two
862 elements of the list must be the I<numeric> uid and gid, in that
863 order.  A value of -1 in either position is interpreted by most
864 systems to leave that value unchanged.  Returns the number of files
865 successfully changed.
866
867     $cnt = chown $uid, $gid, 'foo', 'bar';
868     chown $uid, $gid, @filenames;
869
870 On systems that support fchown(2), you may pass filehandles among the
871 files.  On systems that don't support fchown(2), passing filehandles raises
872 an exception.  Filehandles must be passed as globs or glob references to be
873 recognized; barewords are considered filenames.
874
875 Here's an example that looks up nonnumeric uids in the passwd file:
876
877     print "User: ";
878     chomp($user = <STDIN>);
879     print "Files: ";
880     chomp($pattern = <STDIN>);
881
882     ($login,$pass,$uid,$gid) = getpwnam($user)
883         or die "$user not in passwd file";
884
885     @ary = glob($pattern);  # expand filenames
886     chown $uid, $gid, @ary;
887
888 On most systems, you are not allowed to change the ownership of the
889 file unless you're the superuser, although you should be able to change
890 the group to any of your secondary groups.  On insecure systems, these
891 restrictions may be relaxed, but this is not a portable assumption.
892 On POSIX systems, you can detect this condition this way:
893
894     use POSIX qw(sysconf _PC_CHOWN_RESTRICTED);
895     $can_chown_giveaway = not sysconf(_PC_CHOWN_RESTRICTED);
896
897 Portability issues: L<perlport/chmod>.
898
899 =item chr NUMBER
900 X<chr> X<character> X<ASCII> X<Unicode>
901
902 =item chr
903
904 Returns the character represented by that NUMBER in the character set.
905 For example, C<chr(65)> is C<"A"> in either ASCII or Unicode, and
906 chr(0x263a) is a Unicode smiley face.  
907
908 Negative values give the Unicode replacement character (chr(0xfffd)),
909 except under the L<bytes> pragma, where the low eight bits of the value
910 (truncated to an integer) are used.
911
912 If NUMBER is omitted, uses C<$_>.
913
914 For the reverse, use L</ord>.
915
916 Note that characters from 128 to 255 (inclusive) are by default
917 internally not encoded as UTF-8 for backward compatibility reasons.
918
919 See L<perlunicode> for more about Unicode.
920
921 =item chroot FILENAME
922 X<chroot> X<root>
923
924 =item chroot
925
926 This function works like the system call by the same name: it makes the
927 named directory the new root directory for all further pathnames that
928 begin with a C</> by your process and all its children.  (It doesn't
929 change your current working directory, which is unaffected.)  For security
930 reasons, this call is restricted to the superuser.  If FILENAME is
931 omitted, does a C<chroot> to C<$_>.
932
933 Portability issues: L<perlport/chroot>.
934
935 =item close FILEHANDLE
936 X<close>
937
938 =item close
939
940 Closes the file or pipe associated with the filehandle, flushes the IO
941 buffers, and closes the system file descriptor.  Returns true if those
942 operations succeed and if no error was reported by any PerlIO
943 layer.  Closes the currently selected filehandle if the argument is
944 omitted.
945
946 You don't have to close FILEHANDLE if you are immediately going to do
947 another C<open> on it, because C<open> closes it for you.  (See
948 L<open|/open FILEHANDLE>.)  However, an explicit C<close> on an input file resets the line
949 counter (C<$.>), while the implicit close done by C<open> does not.
950
951 If the filehandle came from a piped open, C<close> returns false if one of
952 the other syscalls involved fails or if its program exits with non-zero
953 status.  If the only problem was that the program exited non-zero, C<$!>
954 will be set to C<0>.  Closing a pipe also waits for the process executing
955 on the pipe to exit--in case you wish to look at the output of the pipe
956 afterwards--and implicitly puts the exit status value of that command into
957 C<$?> and C<${^CHILD_ERROR_NATIVE}>.
958
959 If there are multiple threads running, C<close> on a filehandle from a
960 piped open returns true without waiting for the child process to terminate,
961 if the filehandle is still open in another thread.
962
963 Closing the read end of a pipe before the process writing to it at the
964 other end is done writing results in the writer receiving a SIGPIPE.  If
965 the other end can't handle that, be sure to read all the data before
966 closing the pipe.
967
968 Example:
969
970     open(OUTPUT, '|sort >foo')  # pipe to sort
971         or die "Can't start sort: $!";
972     #...                        # print stuff to output
973     close OUTPUT                # wait for sort to finish
974         or warn $! ? "Error closing sort pipe: $!"
975                    : "Exit status $? from sort";
976     open(INPUT, 'foo')          # get sort's results
977         or die "Can't open 'foo' for input: $!";
978
979 FILEHANDLE may be an expression whose value can be used as an indirect
980 filehandle, usually the real filehandle name or an autovivified handle.
981
982 =item closedir DIRHANDLE
983 X<closedir>
984
985 Closes a directory opened by C<opendir> and returns the success of that
986 system call.
987
988 =item connect SOCKET,NAME
989 X<connect>
990
991 Attempts to connect to a remote socket, just like connect(2).
992 Returns true if it succeeded, false otherwise.  NAME should be a
993 packed address of the appropriate type for the socket.  See the examples in
994 L<perlipc/"Sockets: Client/Server Communication">.
995
996 =item continue BLOCK
997 X<continue>
998
999 =item continue
1000
1001 When followed by a BLOCK, C<continue> is actually a
1002 flow control statement rather than a function.  If
1003 there is a C<continue> BLOCK attached to a BLOCK (typically in a C<while> or
1004 C<foreach>), it is always executed just before the conditional is about to
1005 be evaluated again, just like the third part of a C<for> loop in C.  Thus
1006 it can be used to increment a loop variable, even when the loop has been
1007 continued via the C<next> statement (which is similar to the C C<continue>
1008 statement).
1009
1010 C<last>, C<next>, or C<redo> may appear within a C<continue>
1011 block; C<last> and C<redo> behave as if they had been executed within
1012 the main block.  So will C<next>, but since it will execute a C<continue>
1013 block, it may be more entertaining.
1014
1015     while (EXPR) {
1016         ### redo always comes here
1017         do_something;
1018     } continue {
1019         ### next always comes here
1020         do_something_else;
1021         # then back the top to re-check EXPR
1022     }
1023     ### last always comes here
1024
1025 Omitting the C<continue> section is equivalent to using an
1026 empty one, logically enough, so C<next> goes directly back
1027 to check the condition at the top of the loop.
1028
1029 When there is no BLOCK, C<continue> is a function that
1030 falls through the current C<when> or C<default> block instead of iterating
1031 a dynamically enclosing C<foreach> or exiting a lexically enclosing C<given>.
1032 In Perl 5.14 and earlier, this form of C<continue> was
1033 only available when the C<"switch"> feature was enabled.
1034 See L<feature> and L<perlsyn/"Switch Statements"> for more
1035 information.
1036
1037 =item cos EXPR
1038 X<cos> X<cosine> X<acos> X<arccosine>
1039
1040 =item cos
1041
1042 Returns the cosine of EXPR (expressed in radians).  If EXPR is omitted,
1043 takes the cosine of C<$_>.
1044
1045 For the inverse cosine operation, you may use the C<Math::Trig::acos()>
1046 function, or use this relation:
1047
1048     sub acos { atan2( sqrt(1 - $_[0] * $_[0]), $_[0] ) }
1049
1050 =item crypt PLAINTEXT,SALT
1051 X<crypt> X<digest> X<hash> X<salt> X<plaintext> X<password>
1052 X<decrypt> X<cryptography> X<passwd> X<encrypt>
1053
1054 Creates a digest string exactly like the crypt(3) function in the C
1055 library (assuming that you actually have a version there that has not
1056 been extirpated as a potential munition).
1057
1058 crypt() is a one-way hash function.  The PLAINTEXT and SALT are turned
1059 into a short string, called a digest, which is returned.  The same
1060 PLAINTEXT and SALT will always return the same string, but there is no
1061 (known) way to get the original PLAINTEXT from the hash.  Small
1062 changes in the PLAINTEXT or SALT will result in large changes in the
1063 digest.
1064
1065 There is no decrypt function.  This function isn't all that useful for
1066 cryptography (for that, look for F<Crypt> modules on your nearby CPAN
1067 mirror) and the name "crypt" is a bit of a misnomer.  Instead it is
1068 primarily used to check if two pieces of text are the same without
1069 having to transmit or store the text itself.  An example is checking
1070 if a correct password is given.  The digest of the password is stored,
1071 not the password itself.  The user types in a password that is
1072 crypt()'d with the same salt as the stored digest.  If the two digests
1073 match, the password is correct.
1074
1075 When verifying an existing digest string you should use the digest as
1076 the salt (like C<crypt($plain, $digest) eq $digest>).  The SALT used
1077 to create the digest is visible as part of the digest.  This ensures
1078 crypt() will hash the new string with the same salt as the digest.
1079 This allows your code to work with the standard L<crypt|/crypt> and
1080 with more exotic implementations.  In other words, assume
1081 nothing about the returned string itself nor about how many bytes 
1082 of SALT may matter.
1083
1084 Traditionally the result is a string of 13 bytes: two first bytes of
1085 the salt, followed by 11 bytes from the set C<[./0-9A-Za-z]>, and only
1086 the first eight bytes of PLAINTEXT mattered.  But alternative
1087 hashing schemes (like MD5), higher level security schemes (like C2),
1088 and implementations on non-Unix platforms may produce different
1089 strings.
1090
1091 When choosing a new salt create a random two character string whose
1092 characters come from the set C<[./0-9A-Za-z]> (like C<join '', ('.',
1093 '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]>).  This set of
1094 characters is just a recommendation; the characters allowed in
1095 the salt depend solely on your system's crypt library, and Perl can't
1096 restrict what salts C<crypt()> accepts.
1097
1098 Here's an example that makes sure that whoever runs this program knows
1099 their password:
1100
1101     $pwd = (getpwuid($<))[1];
1102
1103     system "stty -echo";
1104     print "Password: ";
1105     chomp($word = <STDIN>);
1106     print "\n";
1107     system "stty echo";
1108
1109     if (crypt($word, $pwd) ne $pwd) {
1110         die "Sorry...\n";
1111     } else {
1112         print "ok\n";
1113     }
1114
1115 Of course, typing in your own password to whoever asks you
1116 for it is unwise.
1117
1118 The L<crypt|/crypt> function is unsuitable for hashing large quantities
1119 of data, not least of all because you can't get the information
1120 back.  Look at the L<Digest> module for more robust algorithms.
1121
1122 If using crypt() on a Unicode string (which I<potentially> has
1123 characters with codepoints above 255), Perl tries to make sense
1124 of the situation by trying to downgrade (a copy of)
1125 the string back to an eight-bit byte string before calling crypt()
1126 (on that copy).  If that works, good.  If not, crypt() dies with
1127 C<Wide character in crypt>.
1128
1129 Portability issues: L<perlport/crypt>.
1130
1131 =item dbmclose HASH
1132 X<dbmclose>
1133
1134 [This function has been largely superseded by the C<untie> function.]
1135
1136 Breaks the binding between a DBM file and a hash.
1137
1138 Portability issues: L<perlport/dbmclose>.
1139
1140 =item dbmopen HASH,DBNAME,MASK
1141 X<dbmopen> X<dbm> X<ndbm> X<sdbm> X<gdbm>
1142
1143 [This function has been largely superseded by the
1144 L<tie|/tie VARIABLE,CLASSNAME,LIST> function.]
1145
1146 This binds a dbm(3), ndbm(3), sdbm(3), gdbm(3), or Berkeley DB file to a
1147 hash.  HASH is the name of the hash.  (Unlike normal C<open>, the first
1148 argument is I<not> a filehandle, even though it looks like one).  DBNAME
1149 is the name of the database (without the F<.dir> or F<.pag> extension if
1150 any).  If the database does not exist, it is created with protection
1151 specified by MASK (as modified by the C<umask>).  To prevent creation of
1152 the database if it doesn't exist, you may specify a MODE
1153 of 0, and the function will return a false value if it
1154 can't find an existing database.  If your system supports
1155 only the older DBM functions, you may make only one C<dbmopen> call in your
1156 program.  In older versions of Perl, if your system had neither DBM nor
1157 ndbm, calling C<dbmopen> produced a fatal error; it now falls back to
1158 sdbm(3).
1159
1160 If you don't have write access to the DBM file, you can only read hash
1161 variables, not set them.  If you want to test whether you can write,
1162 either use file tests or try setting a dummy hash entry inside an C<eval> 
1163 to trap the error.
1164
1165 Note that functions such as C<keys> and C<values> may return huge lists
1166 when used on large DBM files.  You may prefer to use the C<each>
1167 function to iterate over large DBM files.  Example:
1168
1169     # print out history file offsets
1170     dbmopen(%HIST,'/usr/lib/news/history',0666);
1171     while (($key,$val) = each %HIST) {
1172         print $key, ' = ', unpack('L',$val), "\n";
1173     }
1174     dbmclose(%HIST);
1175
1176 See also L<AnyDBM_File> for a more general description of the pros and
1177 cons of the various dbm approaches, as well as L<DB_File> for a particularly
1178 rich implementation.
1179
1180 You can control which DBM library you use by loading that library
1181 before you call dbmopen():
1182
1183     use DB_File;
1184     dbmopen(%NS_Hist, "$ENV{HOME}/.netscape/history.db")
1185         or die "Can't open netscape history file: $!";
1186
1187 Portability issues: L<perlport/dbmopen>.
1188
1189 =item default BLOCK
1190
1191 Within a C<foreach> or a C<given>, a C<default> BLOCK acts like a C<when>
1192 that's always true.  Only available after Perl 5.10, and only if the
1193 C<switch> feature has been requested or if the keyword is prefixed with
1194 C<CORE::>.  See L</when>.
1195
1196 =item defined EXPR
1197 X<defined> X<undef> X<undefined>
1198
1199 =item defined
1200
1201 Returns a Boolean value telling whether EXPR has a value other than
1202 the undefined value C<undef>.  If EXPR is not present, C<$_> is
1203 checked.
1204
1205 Many operations return C<undef> to indicate failure, end of file,
1206 system error, uninitialized variable, and other exceptional
1207 conditions.  This function allows you to distinguish C<undef> from
1208 other values.  (A simple Boolean test will not distinguish among
1209 C<undef>, zero, the empty string, and C<"0">, which are all equally
1210 false.)  Note that since C<undef> is a valid scalar, its presence
1211 doesn't I<necessarily> indicate an exceptional condition: C<pop>
1212 returns C<undef> when its argument is an empty array, I<or> when the
1213 element to return happens to be C<undef>.
1214
1215 You may also use C<defined(&func)> to check whether subroutine C<&func>
1216 has ever been defined.  The return value is unaffected by any forward
1217 declarations of C<&func>.  A subroutine that is not defined
1218 may still be callable: its package may have an C<AUTOLOAD> method that
1219 makes it spring into existence the first time that it is called; see
1220 L<perlsub>.
1221
1222 Use of C<defined> on aggregates (hashes and arrays) is deprecated.  It
1223 used to report whether memory for that aggregate had ever been
1224 allocated.  This behavior may disappear in future versions of Perl.
1225 You should instead use a simple test for size:
1226
1227     if (@an_array) { print "has array elements\n" }
1228     if (%a_hash)   { print "has hash members\n"   }
1229
1230 When used on a hash element, it tells you whether the value is defined,
1231 not whether the key exists in the hash.  Use L</exists> for the latter
1232 purpose.
1233
1234 Examples:
1235
1236     print if defined $switch{D};
1237     print "$val\n" while defined($val = pop(@ary));
1238     die "Can't readlink $sym: $!"
1239         unless defined($value = readlink $sym);
1240     sub foo { defined &$bar ? &$bar(@_) : die "No bar"; }
1241     $debugging = 0 unless defined $debugging;
1242
1243 Note:  Many folks tend to overuse C<defined> and are then surprised to
1244 discover that the number C<0> and C<""> (the zero-length string) are, in fact,
1245 defined values.  For example, if you say
1246
1247     "ab" =~ /a(.*)b/;
1248
1249 The pattern match succeeds and C<$1> is defined, although it
1250 matched "nothing".  It didn't really fail to match anything.  Rather, it
1251 matched something that happened to be zero characters long.  This is all
1252 very above-board and honest.  When a function returns an undefined value,
1253 it's an admission that it couldn't give you an honest answer.  So you
1254 should use C<defined> only when questioning the integrity of what
1255 you're trying to do.  At other times, a simple comparison to C<0> or C<""> is
1256 what you want.
1257
1258 See also L</undef>, L</exists>, L</ref>.
1259
1260 =item delete EXPR
1261 X<delete>
1262
1263 Given an expression that specifies an element or slice of a hash, C<delete>
1264 deletes the specified elements from that hash so that exists() on that element
1265 no longer returns true.  Setting a hash element to the undefined value does
1266 not remove its key, but deleting it does; see L</exists>.
1267
1268 In list context, returns the value or values deleted, or the last such
1269 element in scalar context.  The return list's length always matches that of
1270 the argument list: deleting non-existent elements returns the undefined value
1271 in their corresponding positions.
1272
1273 delete() may also be used on arrays and array slices, but its behavior is less
1274 straightforward.  Although exists() will return false for deleted entries,
1275 deleting array elements never changes indices of existing values; use shift()
1276 or splice() for that.  However, if all deleted elements fall at the end of an
1277 array, the array's size shrinks to the position of the highest element that
1278 still tests true for exists(), or to 0 if none do.
1279
1280 B<WARNING:> Calling delete on array values is deprecated and likely to
1281 be removed in a future version of Perl.
1282
1283 Deleting from C<%ENV> modifies the environment.  Deleting from a hash tied to
1284 a DBM file deletes the entry from the DBM file.  Deleting from a C<tied> hash
1285 or array may not necessarily return anything; it depends on the implementation
1286 of the C<tied> package's DELETE method, which may do whatever it pleases.
1287
1288 The C<delete local EXPR> construct localizes the deletion to the current
1289 block at run time.  Until the block exits, elements locally deleted
1290 temporarily no longer exist.  See L<perlsub/"Localized deletion of elements
1291 of composite types">.
1292
1293     %hash = (foo => 11, bar => 22, baz => 33);
1294     $scalar = delete $hash{foo};             # $scalar is 11
1295     $scalar = delete @hash{qw(foo bar)};     # $scalar is 22
1296     @array  = delete @hash{qw(foo bar baz)}; # @array  is (undef,undef,33)
1297
1298 The following (inefficiently) deletes all the values of %HASH and @ARRAY:
1299
1300     foreach $key (keys %HASH) {
1301         delete $HASH{$key};
1302     }
1303
1304     foreach $index (0 .. $#ARRAY) {
1305         delete $ARRAY[$index];
1306     }
1307
1308 And so do these:
1309
1310     delete @HASH{keys %HASH};
1311
1312     delete @ARRAY[0 .. $#ARRAY];
1313
1314 But both are slower than assigning the empty list
1315 or undefining %HASH or @ARRAY, which is the customary 
1316 way to empty out an aggregate:
1317
1318     %HASH = ();     # completely empty %HASH
1319     undef %HASH;    # forget %HASH ever existed
1320
1321     @ARRAY = ();    # completely empty @ARRAY
1322     undef @ARRAY;   # forget @ARRAY ever existed
1323
1324 The EXPR can be arbitrarily complicated provided its
1325 final operation is an element or slice of an aggregate:
1326
1327     delete $ref->[$x][$y]{$key};
1328     delete @{$ref->[$x][$y]}{$key1, $key2, @morekeys};
1329
1330     delete $ref->[$x][$y][$index];
1331     delete @{$ref->[$x][$y]}[$index1, $index2, @moreindices];
1332
1333 =item die LIST
1334 X<die> X<throw> X<exception> X<raise> X<$@> X<abort>
1335
1336 C<die> raises an exception.  Inside an C<eval> the error message is stuffed
1337 into C<$@> and the C<eval> is terminated with the undefined value.
1338 If the exception is outside of all enclosing C<eval>s, then the uncaught
1339 exception prints LIST to C<STDERR> and exits with a non-zero value.  If you
1340 need to exit the process with a specific exit code, see L</exit>.
1341
1342 Equivalent examples:
1343
1344     die "Can't cd to spool: $!\n" unless chdir '/usr/spool/news';
1345     chdir '/usr/spool/news' or die "Can't cd to spool: $!\n"
1346
1347 If the last element of LIST does not end in a newline, the current
1348 script line number and input line number (if any) are also printed,
1349 and a newline is supplied.  Note that the "input line number" (also
1350 known as "chunk") is subject to whatever notion of "line" happens to
1351 be currently in effect, and is also available as the special variable
1352 C<$.>.  See L<perlvar/"$/"> and L<perlvar/"$.">.
1353
1354 Hint: sometimes appending C<", stopped"> to your message will cause it
1355 to make better sense when the string C<"at foo line 123"> is appended.
1356 Suppose you are running script "canasta".
1357
1358     die "/etc/games is no good";
1359     die "/etc/games is no good, stopped";
1360
1361 produce, respectively
1362
1363     /etc/games is no good at canasta line 123.
1364     /etc/games is no good, stopped at canasta line 123.
1365
1366 If the output is empty and C<$@> already contains a value (typically from a
1367 previous eval) that value is reused after appending C<"\t...propagated">.
1368 This is useful for propagating exceptions:
1369
1370     eval { ... };
1371     die unless $@ =~ /Expected exception/;
1372
1373 If the output is empty and C<$@> contains an object reference that has a
1374 C<PROPAGATE> method, that method will be called with additional file
1375 and line number parameters.  The return value replaces the value in
1376 C<$@>;  i.e., as if C<< $@ = eval { $@->PROPAGATE(__FILE__, __LINE__) }; >>
1377 were called.
1378
1379 If C<$@> is empty then the string C<"Died"> is used.
1380
1381 If an uncaught exception results in interpreter exit, the exit code is
1382 determined from the values of C<$!> and C<$?> with this pseudocode:
1383
1384     exit $! if $!;              # errno
1385     exit $? >> 8 if $? >> 8;    # child exit status
1386     exit 255;                   # last resort
1387
1388 The intent is to squeeze as much possible information about the likely cause
1389 into the limited space of the system exit
1390 code.  However, as C<$!> is the value
1391 of C's C<errno>, which can be set by any system call, this means that the value
1392 of the exit code used by C<die> can be non-predictable, so should not be relied
1393 upon, other than to be non-zero.
1394
1395 You can also call C<die> with a reference argument, and if this is trapped
1396 within an C<eval>, C<$@> contains that reference.  This permits more
1397 elaborate exception handling using objects that maintain arbitrary state
1398 about the exception.  Such a scheme is sometimes preferable to matching
1399 particular string values of C<$@> with regular expressions.  Because C<$@> 
1400 is a global variable and C<eval> may be used within object implementations,
1401 be careful that analyzing the error object doesn't replace the reference in
1402 the global variable.  It's easiest to make a local copy of the reference
1403 before any manipulations.  Here's an example:
1404
1405     use Scalar::Util "blessed";
1406
1407     eval { ... ; die Some::Module::Exception->new( FOO => "bar" ) };
1408     if (my $ev_err = $@) {
1409         if (blessed($ev_err) && $ev_err->isa("Some::Module::Exception")) {
1410             # handle Some::Module::Exception
1411         }
1412         else {
1413             # handle all other possible exceptions
1414         }
1415     }
1416
1417 Because Perl stringifies uncaught exception messages before display,
1418 you'll probably want to overload stringification operations on
1419 exception objects.  See L<overload> for details about that.
1420
1421 You can arrange for a callback to be run just before the C<die>
1422 does its deed, by setting the C<$SIG{__DIE__}> hook.  The associated
1423 handler is called with the error text and can change the error
1424 message, if it sees fit, by calling C<die> again.  See
1425 L<perlvar/%SIG> for details on setting C<%SIG> entries, and
1426 L<"eval BLOCK"> for some examples.  Although this feature was 
1427 to be run only right before your program was to exit, this is not
1428 currently so: the C<$SIG{__DIE__}> hook is currently called
1429 even inside eval()ed blocks/strings!  If one wants the hook to do
1430 nothing in such situations, put
1431
1432     die @_ if $^S;
1433
1434 as the first line of the handler (see L<perlvar/$^S>).  Because
1435 this promotes strange action at a distance, this counterintuitive
1436 behavior may be fixed in a future release.
1437
1438 See also exit(), warn(), and the Carp module.
1439
1440 =item do BLOCK
1441 X<do> X<block>
1442
1443 Not really a function.  Returns the value of the last command in the
1444 sequence of commands indicated by BLOCK.  When modified by the C<while> or
1445 C<until> loop modifier, executes the BLOCK once before testing the loop
1446 condition.  (On other statements the loop modifiers test the conditional
1447 first.)
1448
1449 C<do BLOCK> does I<not> count as a loop, so the loop control statements
1450 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1451 See L<perlsyn> for alternative strategies.
1452
1453 =item do SUBROUTINE(LIST)
1454 X<do>
1455
1456 This form of subroutine call is deprecated.  SUBROUTINE can be a bareword,
1457 a scalar variable or a subroutine beginning with C<&>.
1458
1459 =item do EXPR
1460 X<do>
1461
1462 Uses the value of EXPR as a filename and executes the contents of the
1463 file as a Perl script.
1464
1465     do 'stat.pl';
1466
1467 is just like
1468
1469     eval `cat stat.pl`;
1470
1471 except that it's more efficient and concise, keeps track of the current
1472 filename for error messages, searches the C<@INC> directories, and updates
1473 C<%INC> if the file is found.  See L<perlvar/@INC> and L<perlvar/%INC> for
1474 these variables.  It also differs in that code evaluated with C<do FILENAME>
1475 cannot see lexicals in the enclosing scope; C<eval STRING> does.  It's the
1476 same, however, in that it does reparse the file every time you call it,
1477 so you probably don't want to do this inside a loop.
1478
1479 If C<do> can read the file but cannot compile it, it returns C<undef> and sets
1480 an error message in C<$@>.  If C<do> cannot read the file, it returns undef
1481 and sets C<$!> to the error.  Always check C<$@> first, as compilation
1482 could fail in a way that also sets C<$!>.  If the file is successfully
1483 compiled, C<do> returns the value of the last expression evaluated.
1484
1485 Inclusion of library modules is better done with the
1486 C<use> and C<require> operators, which also do automatic error checking
1487 and raise an exception if there's a problem.
1488
1489 You might like to use C<do> to read in a program configuration
1490 file.  Manual error checking can be done this way:
1491
1492     # read in config files: system first, then user
1493     for $file ("/share/prog/defaults.rc",
1494                "$ENV{HOME}/.someprogrc")
1495     {
1496         unless ($return = do $file) {
1497             warn "couldn't parse $file: $@" if $@;
1498             warn "couldn't do $file: $!"    unless defined $return;
1499             warn "couldn't run $file"       unless $return;
1500         }
1501     }
1502
1503 =item dump LABEL
1504 X<dump> X<core> X<undump>
1505
1506 =item dump
1507
1508 This function causes an immediate core dump.  See also the B<-u>
1509 command-line switch in L<perlrun>, which does the same thing.
1510 Primarily this is so that you can use the B<undump> program (not
1511 supplied) to turn your core dump into an executable binary after
1512 having initialized all your variables at the beginning of the
1513 program.  When the new binary is executed it will begin by executing
1514 a C<goto LABEL> (with all the restrictions that C<goto> suffers).
1515 Think of it as a goto with an intervening core dump and reincarnation.
1516 If C<LABEL> is omitted, restarts the program from the top.
1517
1518 B<WARNING>: Any files opened at the time of the dump will I<not>
1519 be open any more when the program is reincarnated, with possible
1520 resulting confusion by Perl.
1521
1522 This function is now largely obsolete, mostly because it's very hard to
1523 convert a core file into an executable.  That's why you should now invoke
1524 it as C<CORE::dump()>, if you don't want to be warned against a possible
1525 typo.
1526
1527 Portability issues: L<perlport/dump>.
1528
1529 =item each HASH
1530 X<each> X<hash, iterator>
1531
1532 =item each ARRAY
1533 X<array, iterator>
1534
1535 =item each EXPR
1536
1537 When called on a hash in list context, returns a 2-element list
1538 consisting of the key and value for the next element of a hash.  In Perl
1539 5.12 and later only, it will also return the index and value for the next
1540 element of an array so that you can iterate over it; older Perls consider
1541 this a syntax error.  When called in scalar context, returns only the key
1542 (not the value) in a hash, or the index in an array.
1543
1544 Hash entries are returned in an apparently random order.  The actual random
1545 order is subject to change in future versions of Perl, but it is
1546 guaranteed to be in the same order as either the C<keys> or C<values>
1547 function would produce on the same (unmodified) hash.  Since Perl
1548 5.8.2 the ordering can be different even between different runs of Perl
1549 for security reasons (see L<perlsec/"Algorithmic Complexity Attacks">).
1550
1551 After C<each> has returned all entries from the hash or array, the next
1552 call to C<each> returns the empty list in list context and C<undef> in
1553 scalar context; the next call following I<that> one restarts iteration.
1554 Each hash or array has its own internal iterator, accessed by C<each>,
1555 C<keys>, and C<values>.  The iterator is implicitly reset when C<each> has
1556 reached the end as just described; it can be explicitly reset by calling
1557 C<keys> or C<values> on the hash or array.  If you add or delete a hash's
1558 elements while iterating over it, entries may be skipped or duplicated--so
1559 don't do that.  Exception: In the current implementation, it is always safe
1560 to delete the item most recently returned by C<each()>, so the following
1561 code works properly:
1562
1563         while (($key, $value) = each %hash) {
1564           print $key, "\n";
1565           delete $hash{$key};   # This is safe
1566         }
1567
1568 This prints out your environment like the printenv(1) program,
1569 but in a different order:
1570
1571     while (($key,$value) = each %ENV) {
1572         print "$key=$value\n";
1573     }
1574
1575 Starting with Perl 5.14, C<each> can take a scalar EXPR, which must hold
1576 reference to an unblessed hash or array.  The argument will be dereferenced
1577 automatically.  This aspect of C<each> is considered highly experimental.
1578 The exact behaviour may change in a future version of Perl.
1579
1580     while (($key,$value) = each $hashref) { ... }
1581
1582 To avoid confusing would-be users of your code who are running earlier
1583 versions of Perl with mysterious syntax errors, put this sort of thing at
1584 the top of your file to signal that your code will work I<only> on Perls of
1585 a recent vintage:
1586
1587     use 5.012;  # so keys/values/each work on arrays
1588     use 5.014;  # so keys/values/each work on scalars (experimental)
1589
1590 See also C<keys>, C<values>, and C<sort>.
1591
1592 =item eof FILEHANDLE
1593 X<eof>
1594 X<end of file>
1595 X<end-of-file>
1596
1597 =item eof ()
1598
1599 =item eof
1600
1601 Returns 1 if the next read on FILEHANDLE will return end of file I<or> if
1602 FILEHANDLE is not open.  FILEHANDLE may be an expression whose value
1603 gives the real filehandle.  (Note that this function actually
1604 reads a character and then C<ungetc>s it, so isn't useful in an
1605 interactive context.)  Do not read from a terminal file (or call
1606 C<eof(FILEHANDLE)> on it) after end-of-file is reached.  File types such
1607 as terminals may lose the end-of-file condition if you do.
1608
1609 An C<eof> without an argument uses the last file read.  Using C<eof()>
1610 with empty parentheses is different.  It refers to the pseudo file
1611 formed from the files listed on the command line and accessed via the
1612 C<< <> >> operator.  Since C<< <> >> isn't explicitly opened,
1613 as a normal filehandle is, an C<eof()> before C<< <> >> has been
1614 used will cause C<@ARGV> to be examined to determine if input is
1615 available.   Similarly, an C<eof()> after C<< <> >> has returned
1616 end-of-file will assume you are processing another C<@ARGV> list,
1617 and if you haven't set C<@ARGV>, will read input from C<STDIN>;
1618 see L<perlop/"I/O Operators">.
1619
1620 In a C<< while (<>) >> loop, C<eof> or C<eof(ARGV)> can be used to
1621 detect the end of each file, whereas C<eof()> will detect the end 
1622 of the very last file only.  Examples:
1623
1624     # reset line numbering on each input file
1625     while (<>) {
1626         next if /^\s*#/;  # skip comments
1627         print "$.\t$_";
1628     } continue {
1629         close ARGV if eof;  # Not eof()!
1630     }
1631
1632     # insert dashes just before last line of last file
1633     while (<>) {
1634         if (eof()) {  # check for end of last file
1635             print "--------------\n";
1636         }
1637         print;
1638         last if eof();      # needed if we're reading from a terminal
1639     }
1640
1641 Practical hint: you almost never need to use C<eof> in Perl, because the
1642 input operators typically return C<undef> when they run out of data or 
1643 encounter an error.
1644
1645 =item eval EXPR
1646 X<eval> X<try> X<catch> X<evaluate> X<parse> X<execute>
1647 X<error, handling> X<exception, handling>
1648
1649 =item eval BLOCK
1650
1651 =item eval
1652
1653 In the first form, the return value of EXPR is parsed and executed as if it
1654 were a little Perl program.  The value of the expression (which is itself
1655 determined within scalar context) is first parsed, and if there were no
1656 errors, executed as a block within the lexical context of the current Perl
1657 program.  This means, that in particular, any outer lexical variables are
1658 visible to it, and any package variable settings or subroutine and format
1659 definitions remain afterwards.
1660
1661 Note that the value is parsed every time the C<eval> executes.
1662 If EXPR is omitted, evaluates C<$_>.  This form is typically used to
1663 delay parsing and subsequent execution of the text of EXPR until run time.
1664
1665 If the C<unicode_eval> feature is enabled (which is the default under a
1666 C<use 5.16> or higher declaration), EXPR or C<$_> is treated as a string of
1667 characters, so C<use utf8> declarations have no effect, and source filters
1668 are forbidden.  In the absence of the C<unicode_eval> feature, the string
1669 will sometimes be treated as characters and sometimes as bytes, depending
1670 on the internal encoding, and source filters activated within the C<eval>
1671 exhibit the erratic, but historical, behaviour of affecting some outer file
1672 scope that is still compiling.  See also the L</evalbytes> keyword, which
1673 always treats its input as a byte stream and works properly with source
1674 filters, and the L<feature> pragma.
1675
1676 In the second form, the code within the BLOCK is parsed only once--at the
1677 same time the code surrounding the C<eval> itself was parsed--and executed
1678 within the context of the current Perl program.  This form is typically
1679 used to trap exceptions more efficiently than the first (see below), while
1680 also providing the benefit of checking the code within BLOCK at compile
1681 time.
1682
1683 The final semicolon, if any, may be omitted from the value of EXPR or within
1684 the BLOCK.
1685
1686 In both forms, the value returned is the value of the last expression
1687 evaluated inside the mini-program; a return statement may be also used, just
1688 as with subroutines.  The expression providing the return value is evaluated
1689 in void, scalar, or list context, depending on the context of the C<eval> 
1690 itself.  See L</wantarray> for more on how the evaluation context can be 
1691 determined.
1692
1693 If there is a syntax error or runtime error, or a C<die> statement is
1694 executed, C<eval> returns C<undef> in scalar context
1695 or an empty list in list context, and C<$@> is set to the error
1696 message.  (Prior to 5.16, a bug caused C<undef> to be returned
1697 in list context for syntax errors, but not for runtime errors.)
1698 If there was no error, C<$@> is set to the empty string.  A
1699 control flow operator like C<last> or C<goto> can bypass the setting of
1700 C<$@>.  Beware that using C<eval> neither silences Perl from printing
1701 warnings to STDERR, nor does it stuff the text of warning messages into C<$@>.
1702 To do either of those, you have to use the C<$SIG{__WARN__}> facility, or
1703 turn off warnings inside the BLOCK or EXPR using S<C<no warnings 'all'>>.
1704 See L</warn>, L<perlvar>, L<warnings> and L<perllexwarn>.
1705
1706 Note that, because C<eval> traps otherwise-fatal errors, it is useful for
1707 determining whether a particular feature (such as C<socket> or C<symlink>)
1708 is implemented.  It is also Perl's exception-trapping mechanism, where
1709 the die operator is used to raise exceptions.
1710
1711 If you want to trap errors when loading an XS module, some problems with
1712 the binary interface (such as Perl version skew) may be fatal even with
1713 C<eval> unless C<$ENV{PERL_DL_NONLAZY}> is set.  See L<perlrun>.
1714
1715 If the code to be executed doesn't vary, you may use the eval-BLOCK
1716 form to trap run-time errors without incurring the penalty of
1717 recompiling each time.  The error, if any, is still returned in C<$@>.
1718 Examples:
1719
1720     # make divide-by-zero nonfatal
1721     eval { $answer = $a / $b; }; warn $@ if $@;
1722
1723     # same thing, but less efficient
1724     eval '$answer = $a / $b'; warn $@ if $@;
1725
1726     # a compile-time error
1727     eval { $answer = }; # WRONG
1728
1729     # a run-time error
1730     eval '$answer =';   # sets $@
1731
1732 Using the C<eval{}> form as an exception trap in libraries does have some
1733 issues.  Due to the current arguably broken state of C<__DIE__> hooks, you
1734 may wish not to trigger any C<__DIE__> hooks that user code may have installed.
1735 You can use the C<local $SIG{__DIE__}> construct for this purpose,
1736 as this example shows:
1737
1738     # a private exception trap for divide-by-zero
1739     eval { local $SIG{'__DIE__'}; $answer = $a / $b; };
1740     warn $@ if $@;
1741
1742 This is especially significant, given that C<__DIE__> hooks can call
1743 C<die> again, which has the effect of changing their error messages:
1744
1745     # __DIE__ hooks may modify error messages
1746     {
1747        local $SIG{'__DIE__'} =
1748               sub { (my $x = $_[0]) =~ s/foo/bar/g; die $x };
1749        eval { die "foo lives here" };
1750        print $@ if $@;                # prints "bar lives here"
1751     }
1752
1753 Because this promotes action at a distance, this counterintuitive behavior
1754 may be fixed in a future release.
1755
1756 With an C<eval>, you should be especially careful to remember what's
1757 being looked at when:
1758
1759     eval $x;        # CASE 1
1760     eval "$x";      # CASE 2
1761
1762     eval '$x';      # CASE 3
1763     eval { $x };    # CASE 4
1764
1765     eval "\$$x++";  # CASE 5
1766     $$x++;          # CASE 6
1767
1768 Cases 1 and 2 above behave identically: they run the code contained in
1769 the variable $x.  (Although case 2 has misleading double quotes making
1770 the reader wonder what else might be happening (nothing is).)  Cases 3
1771 and 4 likewise behave in the same way: they run the code C<'$x'>, which
1772 does nothing but return the value of $x.  (Case 4 is preferred for
1773 purely visual reasons, but it also has the advantage of compiling at
1774 compile-time instead of at run-time.)  Case 5 is a place where
1775 normally you I<would> like to use double quotes, except that in this
1776 particular situation, you can just use symbolic references instead, as
1777 in case 6.
1778
1779 Before Perl 5.14, the assignment to C<$@> occurred before restoration 
1780 of localized variables, which means that for your code to run on older
1781 versions, a temporary is required if you want to mask some but not all
1782 errors:
1783
1784     # alter $@ on nefarious repugnancy only
1785     {
1786        my $e;
1787        {
1788           local $@; # protect existing $@
1789           eval { test_repugnancy() };
1790           # $@ =~ /nefarious/ and die $@; # Perl 5.14 and higher only
1791           $@ =~ /nefarious/ and $e = $@;
1792        }
1793        die $e if defined $e
1794     }
1795
1796 C<eval BLOCK> does I<not> count as a loop, so the loop control statements
1797 C<next>, C<last>, or C<redo> cannot be used to leave or restart the block.
1798
1799 An C<eval ''> executed within the C<DB> package doesn't see the usual
1800 surrounding lexical scope, but rather the scope of the first non-DB piece
1801 of code that called it.  You don't normally need to worry about this unless
1802 you are writing a Perl debugger.
1803
1804 =item evalbytes EXPR
1805 X<evalbytes>
1806
1807 =item evalbytes
1808
1809 This function is like L</eval> with a string argument, except it always
1810 parses its argument, or C<$_> if EXPR is omitted, as a string of bytes.  A
1811 string containing characters whose ordinal value exceeds 255 results in an
1812 error.  Source filters activated within the evaluated code apply to the
1813 code itself.
1814
1815 This function is only available under the C<evalbytes> feature, a
1816 C<use v5.16> (or higher) declaration, or with a C<CORE::> prefix.  See
1817 L<feature> for more information.
1818
1819 =item exec LIST
1820 X<exec> X<execute>
1821
1822 =item exec PROGRAM LIST
1823
1824 The C<exec> function executes a system command I<and never returns>;
1825 use C<system> instead of C<exec> if you want it to return.  It fails and
1826 returns false only if the command does not exist I<and> it is executed
1827 directly instead of via your system's command shell (see below).
1828
1829 Since it's a common mistake to use C<exec> instead of C<system>, Perl
1830 warns you if there is a following statement that isn't C<die>, C<warn>,
1831 or C<exit> (if C<-w> is set--but you always do that, right?).   If you
1832 I<really> want to follow an C<exec> with some other statement, you
1833 can use one of these styles to avoid the warning:
1834
1835     exec ('foo')   or print STDERR "couldn't exec foo: $!";
1836     { exec ('foo') }; print STDERR "couldn't exec foo: $!";
1837
1838 If there is more than one argument in LIST, or if LIST is an array
1839 with more than one value, calls execvp(3) with the arguments in LIST.
1840 If there is only one scalar argument or an array with one element in it,
1841 the argument is checked for shell metacharacters, and if there are any,
1842 the entire argument is passed to the system's command shell for parsing
1843 (this is C</bin/sh -c> on Unix platforms, but varies on other platforms).
1844 If there are no shell metacharacters in the argument, it is split into
1845 words and passed directly to C<execvp>, which is more efficient.
1846 Examples:
1847
1848     exec '/bin/echo', 'Your arguments are: ', @ARGV;
1849     exec "sort $outfile | uniq";
1850
1851 If you don't really want to execute the first argument, but want to lie
1852 to the program you are executing about its own name, you can specify
1853 the program you actually want to run as an "indirect object" (without a
1854 comma) in front of the LIST.  (This always forces interpretation of the
1855 LIST as a multivalued list, even if there is only a single scalar in
1856 the list.)  Example:
1857
1858     $shell = '/bin/csh';
1859     exec $shell '-sh';    # pretend it's a login shell
1860
1861 or, more directly,
1862
1863     exec {'/bin/csh'} '-sh';  # pretend it's a login shell
1864
1865 When the arguments get executed via the system shell, results are
1866 subject to its quirks and capabilities.  See L<perlop/"`STRING`">
1867 for details.
1868
1869 Using an indirect object with C<exec> or C<system> is also more
1870 secure.  This usage (which also works fine with system()) forces
1871 interpretation of the arguments as a multivalued list, even if the
1872 list had just one argument.  That way you're safe from the shell
1873 expanding wildcards or splitting up words with whitespace in them.
1874
1875     @args = ( "echo surprise" );
1876
1877     exec @args;               # subject to shell escapes
1878                                 # if @args == 1
1879     exec { $args[0] } @args;  # safe even with one-arg list
1880
1881 The first version, the one without the indirect object, ran the I<echo>
1882 program, passing it C<"surprise"> an argument.  The second version didn't;
1883 it tried to run a program named I<"echo surprise">, didn't find it, and set
1884 C<$?> to a non-zero value indicating failure.
1885
1886 Beginning with v5.6.0, Perl attempts to flush all files opened for
1887 output before the exec, but this may not be supported on some platforms
1888 (see L<perlport>).  To be safe, you may need to set C<$|> ($AUTOFLUSH
1889 in English) or call the C<autoflush()> method of C<IO::Handle> on any
1890 open handles to avoid lost output.
1891
1892 Note that C<exec> will not call your C<END> blocks, nor will it invoke
1893 C<DESTROY> methods on your objects.
1894
1895 Portability issues: L<perlport/exec>.
1896
1897 =item exists EXPR
1898 X<exists> X<autovivification>
1899
1900 Given an expression that specifies an element of a hash, returns true if the
1901 specified element in the hash has ever been initialized, even if the
1902 corresponding value is undefined.
1903
1904     print "Exists\n"    if exists $hash{$key};
1905     print "Defined\n"   if defined $hash{$key};
1906     print "True\n"      if $hash{$key};
1907
1908 exists may also be called on array elements, but its behavior is much less
1909 obvious and is strongly tied to the use of L</delete> on arrays.  B<Be aware>
1910 that calling exists on array values is deprecated and likely to be removed in
1911 a future version of Perl.
1912
1913     print "Exists\n"    if exists $array[$index];
1914     print "Defined\n"   if defined $array[$index];
1915     print "True\n"      if $array[$index];
1916
1917 A hash or array element can be true only if it's defined and defined only if
1918 it exists, but the reverse doesn't necessarily hold true.
1919
1920 Given an expression that specifies the name of a subroutine,
1921 returns true if the specified subroutine has ever been declared, even
1922 if it is undefined.  Mentioning a subroutine name for exists or defined
1923 does not count as declaring it.  Note that a subroutine that does not
1924 exist may still be callable: its package may have an C<AUTOLOAD>
1925 method that makes it spring into existence the first time that it is
1926 called; see L<perlsub>.
1927
1928     print "Exists\n"  if exists &subroutine;
1929     print "Defined\n" if defined &subroutine;
1930
1931 Note that the EXPR can be arbitrarily complicated as long as the final
1932 operation is a hash or array key lookup or subroutine name:
1933
1934     if (exists $ref->{A}->{B}->{$key})  { }
1935     if (exists $hash{A}{B}{$key})       { }
1936
1937     if (exists $ref->{A}->{B}->[$ix])   { }
1938     if (exists $hash{A}{B}[$ix])        { }
1939
1940     if (exists &{$ref->{A}{B}{$key}})   { }
1941
1942 Although the mostly deeply nested array or hash will not spring into
1943 existence just because its existence was tested, any intervening ones will.
1944 Thus C<< $ref->{"A"} >> and C<< $ref->{"A"}->{"B"} >> will spring
1945 into existence due to the existence test for the $key element above.
1946 This happens anywhere the arrow operator is used, including even here:
1947
1948     undef $ref;
1949     if (exists $ref->{"Some key"})    { }
1950     print $ref;  # prints HASH(0x80d3d5c)
1951
1952 This surprising autovivification in what does not at first--or even
1953 second--glance appear to be an lvalue context may be fixed in a future
1954 release.
1955
1956 Use of a subroutine call, rather than a subroutine name, as an argument
1957 to exists() is an error.
1958
1959     exists &sub;    # OK
1960     exists &sub();  # Error
1961
1962 =item exit EXPR
1963 X<exit> X<terminate> X<abort>
1964
1965 =item exit
1966
1967 Evaluates EXPR and exits immediately with that value.    Example:
1968
1969     $ans = <STDIN>;
1970     exit 0 if $ans =~ /^[Xx]/;
1971
1972 See also C<die>.  If EXPR is omitted, exits with C<0> status.  The only
1973 universally recognized values for EXPR are C<0> for success and C<1>
1974 for error; other values are subject to interpretation depending on the
1975 environment in which the Perl program is running.  For example, exiting
1976 69 (EX_UNAVAILABLE) from a I<sendmail> incoming-mail filter will cause
1977 the mailer to return the item undelivered, but that's not true everywhere.
1978
1979 Don't use C<exit> to abort a subroutine if there's any chance that
1980 someone might want to trap whatever error happened.  Use C<die> instead,
1981 which can be trapped by an C<eval>.
1982
1983 The exit() function does not always exit immediately.  It calls any
1984 defined C<END> routines first, but these C<END> routines may not
1985 themselves abort the exit.  Likewise any object destructors that need to
1986 be called are called before the real exit.  C<END> routines and destructors
1987 can change the exit status by modifying C<$?>.  If this is a problem, you
1988 can call C<POSIX:_exit($status)> to avoid END and destructor processing.
1989 See L<perlmod> for details.
1990
1991 Portability issues: L<perlport/exit>.
1992
1993 =item exp EXPR
1994 X<exp> X<exponential> X<antilog> X<antilogarithm> X<e>
1995
1996 =item exp
1997
1998 Returns I<e> (the natural logarithm base) to the power of EXPR.
1999 If EXPR is omitted, gives C<exp($_)>.
2000
2001 =item fc EXPR
2002 X<fc> X<foldcase> X<casefold> X<fold-case> X<case-fold>
2003
2004 =item fc
2005
2006 Returns the casefolded version of EXPR.  This is the internal function
2007 implementing the C<\F> escape in double-quoted strings.
2008
2009 Casefolding is the process of mapping strings to a form where case
2010 differences are erased; comparing two strings in their casefolded
2011 form is effectively a way of asking if two strings are equal,
2012 regardless of case.
2013
2014 Roughly, if you ever found yourself writing this
2015
2016     lc($this) eq lc($that)  # Wrong!
2017         # or
2018     uc($this) eq uc($that)  # Also wrong!
2019         # or
2020     $this =~ /\Q$that/i     # Right!
2021
2022 Now you can write
2023
2024     fc($this) eq fc($that)
2025
2026 And get the correct results.
2027
2028 Perl only implements the full form of casefolding.
2029 For further information on casefolding, refer to
2030 the Unicode Standard, specifically sections 3.13 C<Default Case Operations>,
2031 4.2 C<Case-Normative>, and 5.18 C<Case Mappings>,
2032 available at L<http://www.unicode.org/versions/latest/>, as well as the
2033 Case Charts available at L<http://www.unicode.org/charts/case/>.
2034
2035 If EXPR is omitted, uses C<$_>.
2036
2037 This function behaves the same way under various pragma, such as in a locale,
2038 as L</lc> does.
2039
2040 While the Unicode Standard defines two additional forms of casefolding,
2041 one for Turkic languages and one that never maps one character into multiple
2042 characters, these are not provided by the Perl core; However, the CPAN module
2043 C<Unicode::Casing> may be used to provide an implementation.
2044
2045 This keyword is available only when the C<"fc"> feature is enabled,
2046 or when prefixed with C<CORE::>; See L<feature>. Alternately,
2047 include a C<use v5.16> or later to the current scope.
2048
2049 =item fcntl FILEHANDLE,FUNCTION,SCALAR
2050 X<fcntl>
2051
2052 Implements the fcntl(2) function.  You'll probably have to say
2053
2054     use Fcntl;
2055
2056 first to get the correct constant definitions.  Argument processing and
2057 value returned work just like C<ioctl> below.
2058 For example:
2059
2060     use Fcntl;
2061     fcntl($filehandle, F_GETFL, $packed_return_buffer)
2062         or die "can't fcntl F_GETFL: $!";
2063
2064 You don't have to check for C<defined> on the return from C<fcntl>.
2065 Like C<ioctl>, it maps a C<0> return from the system call into
2066 C<"0 but true"> in Perl.  This string is true in boolean context and C<0>
2067 in numeric context.  It is also exempt from the normal B<-w> warnings
2068 on improper numeric conversions.
2069
2070 Note that C<fcntl> raises an exception if used on a machine that
2071 doesn't implement fcntl(2).  See the Fcntl module or your fcntl(2)
2072 manpage to learn what functions are available on your system.
2073
2074 Here's an example of setting a filehandle named C<REMOTE> to be
2075 non-blocking at the system level.  You'll have to negotiate C<$|>
2076 on your own, though.
2077
2078     use Fcntl qw(F_GETFL F_SETFL O_NONBLOCK);
2079
2080     $flags = fcntl(REMOTE, F_GETFL, 0)
2081                 or die "Can't get flags for the socket: $!\n";
2082
2083     $flags = fcntl(REMOTE, F_SETFL, $flags | O_NONBLOCK)
2084                 or die "Can't set flags for the socket: $!\n";
2085
2086 Portability issues: L<perlport/fcntl>.
2087
2088 =item __FILE__
2089 X<__FILE__>
2090
2091 A special token that returns the name of the file in which it occurs.
2092
2093 =item fileno FILEHANDLE
2094 X<fileno>
2095
2096 Returns the file descriptor for a filehandle, or undefined if the
2097 filehandle is not open.  If there is no real file descriptor at the OS
2098 level, as can happen with filehandles connected to memory objects via
2099 C<open> with a reference for the third argument, -1 is returned.
2100
2101 This is mainly useful for constructing
2102 bitmaps for C<select> and low-level POSIX tty-handling operations.
2103 If FILEHANDLE is an expression, the value is taken as an indirect
2104 filehandle, generally its name.
2105
2106 You can use this to find out whether two handles refer to the
2107 same underlying descriptor:
2108
2109     if (fileno(THIS) == fileno(THAT)) {
2110         print "THIS and THAT are dups\n";
2111     }
2112
2113 =item flock FILEHANDLE,OPERATION
2114 X<flock> X<lock> X<locking>
2115
2116 Calls flock(2), or an emulation of it, on FILEHANDLE.  Returns true
2117 for success, false on failure.  Produces a fatal error if used on a
2118 machine that doesn't implement flock(2), fcntl(2) locking, or lockf(3).
2119 C<flock> is Perl's portable file-locking interface, although it locks
2120 entire files only, not records.
2121
2122 Two potentially non-obvious but traditional C<flock> semantics are
2123 that it waits indefinitely until the lock is granted, and that its locks
2124 are B<merely advisory>.  Such discretionary locks are more flexible, but
2125 offer fewer guarantees.  This means that programs that do not also use
2126 C<flock> may modify files locked with C<flock>.  See L<perlport>, 
2127 your port's specific documentation, and your system-specific local manpages
2128 for details.  It's best to assume traditional behavior if you're writing
2129 portable programs.  (But if you're not, you should as always feel perfectly
2130 free to write for your own system's idiosyncrasies (sometimes called
2131 "features").  Slavish adherence to portability concerns shouldn't get
2132 in the way of your getting your job done.)
2133
2134 OPERATION is one of LOCK_SH, LOCK_EX, or LOCK_UN, possibly combined with
2135 LOCK_NB.  These constants are traditionally valued 1, 2, 8 and 4, but
2136 you can use the symbolic names if you import them from the L<Fcntl> module,
2137 either individually, or as a group using the C<:flock> tag.  LOCK_SH
2138 requests a shared lock, LOCK_EX requests an exclusive lock, and LOCK_UN
2139 releases a previously requested lock.  If LOCK_NB is bitwise-or'ed with
2140 LOCK_SH or LOCK_EX, then C<flock> returns immediately rather than blocking
2141 waiting for the lock; check the return status to see if you got it.
2142
2143 To avoid the possibility of miscoordination, Perl now flushes FILEHANDLE
2144 before locking or unlocking it.
2145
2146 Note that the emulation built with lockf(3) doesn't provide shared
2147 locks, and it requires that FILEHANDLE be open with write intent.  These
2148 are the semantics that lockf(3) implements.  Most if not all systems
2149 implement lockf(3) in terms of fcntl(2) locking, though, so the
2150 differing semantics shouldn't bite too many people.
2151
2152 Note that the fcntl(2) emulation of flock(3) requires that FILEHANDLE
2153 be open with read intent to use LOCK_SH and requires that it be open
2154 with write intent to use LOCK_EX.
2155
2156 Note also that some versions of C<flock> cannot lock things over the
2157 network; you would need to use the more system-specific C<fcntl> for
2158 that.  If you like you can force Perl to ignore your system's flock(2)
2159 function, and so provide its own fcntl(2)-based emulation, by passing
2160 the switch C<-Ud_flock> to the F<Configure> program when you configure
2161 and build a new Perl.
2162
2163 Here's a mailbox appender for BSD systems.
2164
2165     use Fcntl qw(:flock SEEK_END); # import LOCK_* and SEEK_END constants
2166
2167     sub lock {
2168         my ($fh) = @_;
2169         flock($fh, LOCK_EX) or die "Cannot lock mailbox - $!\n";
2170
2171         # and, in case someone appended while we were waiting...
2172         seek($fh, 0, SEEK_END) or die "Cannot seek - $!\n";
2173     }
2174
2175     sub unlock {
2176         my ($fh) = @_;
2177         flock($fh, LOCK_UN) or die "Cannot unlock mailbox - $!\n";
2178     }
2179
2180     open(my $mbox, ">>", "/usr/spool/mail/$ENV{'USER'}")
2181         or die "Can't open mailbox: $!";
2182
2183     lock($mbox);
2184     print $mbox $msg,"\n\n";
2185     unlock($mbox);
2186
2187 On systems that support a real flock(2), locks are inherited across fork()
2188 calls, whereas those that must resort to the more capricious fcntl(2)
2189 function lose their locks, making it seriously harder to write servers.
2190
2191 See also L<DB_File> for other flock() examples.
2192
2193 Portability issues: L<perlport/flock>.
2194
2195 =item fork
2196 X<fork> X<child> X<parent>
2197
2198 Does a fork(2) system call to create a new process running the
2199 same program at the same point.  It returns the child pid to the
2200 parent process, C<0> to the child process, or C<undef> if the fork is
2201 unsuccessful.  File descriptors (and sometimes locks on those descriptors)
2202 are shared, while everything else is copied.  On most systems supporting
2203 fork(), great care has gone into making it extremely efficient (for
2204 example, using copy-on-write technology on data pages), making it the
2205 dominant paradigm for multitasking over the last few decades.
2206
2207 Beginning with v5.6.0, Perl attempts to flush all files opened for
2208 output before forking the child process, but this may not be supported
2209 on some platforms (see L<perlport>).  To be safe, you may need to set
2210 C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method of
2211 C<IO::Handle> on any open handles to avoid duplicate output.
2212
2213 If you C<fork> without ever waiting on your children, you will
2214 accumulate zombies.  On some systems, you can avoid this by setting
2215 C<$SIG{CHLD}> to C<"IGNORE">.  See also L<perlipc> for more examples of
2216 forking and reaping moribund children.
2217
2218 Note that if your forked child inherits system file descriptors like
2219 STDIN and STDOUT that are actually connected by a pipe or socket, even
2220 if you exit, then the remote server (such as, say, a CGI script or a
2221 backgrounded job launched from a remote shell) won't think you're done.
2222 You should reopen those to F</dev/null> if it's any issue.
2223
2224 On some platforms such as Windows, where the fork() system call is not available,
2225 Perl can be built to emulate fork() in the Perl interpreter.
2226 The emulation is designed, at the level of the Perl program,
2227 to be as compatible as possible with the "Unix" fork().
2228 However it has limitations that have to be considered in code intended to be portable.
2229 See L<perlfork> for more details.
2230
2231 Portability issues: L<perlport/fork>.
2232
2233 =item format
2234 X<format>
2235
2236 Declare a picture format for use by the C<write> function.  For
2237 example:
2238
2239     format Something =
2240         Test: @<<<<<<<< @||||| @>>>>>
2241               $str,     $%,    '$' . int($num)
2242     .
2243
2244     $str = "widget";
2245     $num = $cost/$quantity;
2246     $~ = 'Something';
2247     write;
2248
2249 See L<perlform> for many details and examples.
2250
2251 =item formline PICTURE,LIST
2252 X<formline>
2253
2254 This is an internal function used by C<format>s, though you may call it,
2255 too.  It formats (see L<perlform>) a list of values according to the
2256 contents of PICTURE, placing the output into the format output
2257 accumulator, C<$^A> (or C<$ACCUMULATOR> in English).
2258 Eventually, when a C<write> is done, the contents of
2259 C<$^A> are written to some filehandle.  You could also read C<$^A>
2260 and then set C<$^A> back to C<"">.  Note that a format typically
2261 does one C<formline> per line of form, but the C<formline> function itself
2262 doesn't care how many newlines are embedded in the PICTURE.  This means
2263 that the C<~> and C<~~> tokens treat the entire PICTURE as a single line.
2264 You may therefore need to use multiple formlines to implement a single
2265 record format, just like the C<format> compiler.
2266
2267 Be careful if you put double quotes around the picture, because an C<@>
2268 character may be taken to mean the beginning of an array name.
2269 C<formline> always returns true.  See L<perlform> for other examples.
2270
2271 If you are trying to use this instead of C<write> to capture the output,
2272 you may find it easier to open a filehandle to a scalar
2273 (C<< open $fh, ">", \$output >>) and write to that instead.
2274
2275 =item getc FILEHANDLE
2276 X<getc> X<getchar> X<character> X<file, read>
2277
2278 =item getc
2279
2280 Returns the next character from the input file attached to FILEHANDLE,
2281 or the undefined value at end of file or if there was an error (in
2282 the latter case C<$!> is set).  If FILEHANDLE is omitted, reads from
2283 STDIN.  This is not particularly efficient.  However, it cannot be
2284 used by itself to fetch single characters without waiting for the user
2285 to hit enter.  For that, try something more like:
2286
2287     if ($BSD_STYLE) {
2288         system "stty cbreak </dev/tty >/dev/tty 2>&1";
2289     }
2290     else {
2291         system "stty", '-icanon', 'eol', "\001";
2292     }
2293
2294     $key = getc(STDIN);
2295
2296     if ($BSD_STYLE) {
2297         system "stty -cbreak </dev/tty >/dev/tty 2>&1";
2298     }
2299     else {
2300         system 'stty', 'icanon', 'eol', '^@'; # ASCII NUL
2301     }
2302     print "\n";
2303
2304 Determination of whether $BSD_STYLE should be set
2305 is left as an exercise to the reader.
2306
2307 The C<POSIX::getattr> function can do this more portably on
2308 systems purporting POSIX compliance.  See also the C<Term::ReadKey>
2309 module from your nearest CPAN site; details on CPAN can be found under
2310 L<perlmodlib/CPAN>.
2311
2312 =item getlogin
2313 X<getlogin> X<login>
2314
2315 This implements the C library function of the same name, which on most
2316 systems returns the current login from F</etc/utmp>, if any.  If it
2317 returns the empty string, use C<getpwuid>.
2318
2319     $login = getlogin || getpwuid($<) || "Kilroy";
2320
2321 Do not consider C<getlogin> for authentication: it is not as
2322 secure as C<getpwuid>.
2323
2324 Portability issues: L<perlport/getlogin>.
2325
2326 =item getpeername SOCKET
2327 X<getpeername> X<peer>
2328
2329 Returns the packed sockaddr address of the other end of the SOCKET
2330 connection.
2331
2332     use Socket;
2333     $hersockaddr    = getpeername(SOCK);
2334     ($port, $iaddr) = sockaddr_in($hersockaddr);
2335     $herhostname    = gethostbyaddr($iaddr, AF_INET);
2336     $herstraddr     = inet_ntoa($iaddr);
2337
2338 =item getpgrp PID
2339 X<getpgrp> X<group>
2340
2341 Returns the current process group for the specified PID.  Use
2342 a PID of C<0> to get the current process group for the
2343 current process.  Will raise an exception if used on a machine that
2344 doesn't implement getpgrp(2).  If PID is omitted, returns the process
2345 group of the current process.  Note that the POSIX version of C<getpgrp>
2346 does not accept a PID argument, so only C<PID==0> is truly portable.
2347
2348 Portability issues: L<perlport/getpgrp>.
2349
2350 =item getppid
2351 X<getppid> X<parent> X<pid>
2352
2353 Returns the process id of the parent process.
2354
2355 Note for Linux users: on Linux, the C functions C<getpid()> and
2356 C<getppid()> return different values from different threads.  In order to
2357 be portable, this behavior is not reflected by the Perl-level function
2358 C<getppid()>, that returns a consistent value across threads.  If you want
2359 to call the underlying C<getppid()>, you may use the CPAN module
2360 C<Linux::Pid>.
2361
2362 Portability issues: L<perlport/getppid>.
2363
2364 =item getpriority WHICH,WHO
2365 X<getpriority> X<priority> X<nice>
2366
2367 Returns the current priority for a process, a process group, or a user.
2368 (See L<getpriority(2)>.)  Will raise a fatal exception if used on a
2369 machine that doesn't implement getpriority(2).
2370
2371 Portability issues: L<perlport/getpriority>.
2372
2373 =item getpwnam NAME
2374 X<getpwnam> X<getgrnam> X<gethostbyname> X<getnetbyname> X<getprotobyname>
2375 X<getpwuid> X<getgrgid> X<getservbyname> X<gethostbyaddr> X<getnetbyaddr>
2376 X<getprotobynumber> X<getservbyport> X<getpwent> X<getgrent> X<gethostent>
2377 X<getnetent> X<getprotoent> X<getservent> X<setpwent> X<setgrent> X<sethostent>
2378 X<setnetent> X<setprotoent> X<setservent> X<endpwent> X<endgrent> X<endhostent>
2379 X<endnetent> X<endprotoent> X<endservent> 
2380
2381 =item getgrnam NAME
2382
2383 =item gethostbyname NAME
2384
2385 =item getnetbyname NAME
2386
2387 =item getprotobyname NAME
2388
2389 =item getpwuid UID
2390
2391 =item getgrgid GID
2392
2393 =item getservbyname NAME,PROTO
2394
2395 =item gethostbyaddr ADDR,ADDRTYPE
2396
2397 =item getnetbyaddr ADDR,ADDRTYPE
2398
2399 =item getprotobynumber NUMBER
2400
2401 =item getservbyport PORT,PROTO
2402
2403 =item getpwent
2404
2405 =item getgrent
2406
2407 =item gethostent
2408
2409 =item getnetent
2410
2411 =item getprotoent
2412
2413 =item getservent
2414
2415 =item setpwent
2416
2417 =item setgrent
2418
2419 =item sethostent STAYOPEN
2420
2421 =item setnetent STAYOPEN
2422
2423 =item setprotoent STAYOPEN
2424
2425 =item setservent STAYOPEN
2426
2427 =item endpwent
2428
2429 =item endgrent
2430
2431 =item endhostent
2432
2433 =item endnetent
2434
2435 =item endprotoent
2436
2437 =item endservent
2438
2439 These routines are the same as their counterparts in the
2440 system C library.  In list context, the return values from the
2441 various get routines are as follows:
2442
2443     ($name,$passwd,$uid,$gid,
2444        $quota,$comment,$gcos,$dir,$shell,$expire) = getpw*
2445     ($name,$passwd,$gid,$members) = getgr*
2446     ($name,$aliases,$addrtype,$length,@addrs) = gethost*
2447     ($name,$aliases,$addrtype,$net) = getnet*
2448     ($name,$aliases,$proto) = getproto*
2449     ($name,$aliases,$port,$proto) = getserv*
2450
2451 (If the entry doesn't exist you get an empty list.)
2452
2453 The exact meaning of the $gcos field varies but it usually contains
2454 the real name of the user (as opposed to the login name) and other
2455 information pertaining to the user.  Beware, however, that in many
2456 system users are able to change this information and therefore it
2457 cannot be trusted and therefore the $gcos is tainted (see
2458 L<perlsec>).  The $passwd and $shell, user's encrypted password and
2459 login shell, are also tainted, for the same reason.
2460
2461 In scalar context, you get the name, unless the function was a
2462 lookup by name, in which case you get the other thing, whatever it is.
2463 (If the entry doesn't exist you get the undefined value.)  For example:
2464
2465     $uid   = getpwnam($name);
2466     $name  = getpwuid($num);
2467     $name  = getpwent();
2468     $gid   = getgrnam($name);
2469     $name  = getgrgid($num);
2470     $name  = getgrent();
2471     #etc.
2472
2473 In I<getpw*()> the fields $quota, $comment, and $expire are special
2474 in that they are unsupported on many systems.  If the
2475 $quota is unsupported, it is an empty scalar.  If it is supported, it
2476 usually encodes the disk quota.  If the $comment field is unsupported,
2477 it is an empty scalar.  If it is supported it usually encodes some
2478 administrative comment about the user.  In some systems the $quota
2479 field may be $change or $age, fields that have to do with password
2480 aging.  In some systems the $comment field may be $class.  The $expire
2481 field, if present, encodes the expiration period of the account or the
2482 password.  For the availability and the exact meaning of these fields
2483 in your system, please consult getpwnam(3) and your system's 
2484 F<pwd.h> file.  You can also find out from within Perl what your
2485 $quota and $comment fields mean and whether you have the $expire field
2486 by using the C<Config> module and the values C<d_pwquota>, C<d_pwage>,
2487 C<d_pwchange>, C<d_pwcomment>, and C<d_pwexpire>.  Shadow password
2488 files are supported only if your vendor has implemented them in the
2489 intuitive fashion that calling the regular C library routines gets the
2490 shadow versions if you're running under privilege or if there exists
2491 the shadow(3) functions as found in System V (this includes Solaris
2492 and Linux).  Those systems that implement a proprietary shadow password
2493 facility are unlikely to be supported.
2494
2495 The $members value returned by I<getgr*()> is a space-separated list of
2496 the login names of the members of the group.
2497
2498 For the I<gethost*()> functions, if the C<h_errno> variable is supported in
2499 C, it will be returned to you via C<$?> if the function call fails.  The
2500 C<@addrs> value returned by a successful call is a list of raw
2501 addresses returned by the corresponding library call.  In the
2502 Internet domain, each address is four bytes long; you can unpack it
2503 by saying something like:
2504
2505     ($a,$b,$c,$d) = unpack('W4',$addr[0]);
2506
2507 The Socket library makes this slightly easier:
2508
2509     use Socket;
2510     $iaddr = inet_aton("127.1"); # or whatever address
2511     $name  = gethostbyaddr($iaddr, AF_INET);
2512
2513     # or going the other way
2514     $straddr = inet_ntoa($iaddr);
2515
2516 In the opposite way, to resolve a hostname to the IP address
2517 you can write this:
2518
2519     use Socket;
2520     $packed_ip = gethostbyname("www.perl.org");
2521     if (defined $packed_ip) {
2522         $ip_address = inet_ntoa($packed_ip);
2523     }
2524
2525 Make sure C<gethostbyname()> is called in SCALAR context and that
2526 its return value is checked for definedness.
2527
2528 The C<getprotobynumber> function, even though it only takes one argument,
2529 has the precedence of a list operator, so beware:
2530
2531     getprotobynumber $number eq 'icmp'   # WRONG
2532     getprotobynumber($number eq 'icmp')  # actually means this
2533     getprotobynumber($number) eq 'icmp'  # better this way
2534
2535 If you get tired of remembering which element of the return list
2536 contains which return value, by-name interfaces are provided
2537 in standard modules: C<File::stat>, C<Net::hostent>, C<Net::netent>,
2538 C<Net::protoent>, C<Net::servent>, C<Time::gmtime>, C<Time::localtime>,
2539 and C<User::grent>.  These override the normal built-ins, supplying
2540 versions that return objects with the appropriate names
2541 for each field.  For example:
2542
2543    use File::stat;
2544    use User::pwent;
2545    $is_his = (stat($filename)->uid == pwent($whoever)->uid);
2546
2547 Even though it looks as though they're the same method calls (uid),
2548 they aren't, because a C<File::stat> object is different from
2549 a C<User::pwent> object.
2550
2551 Portability issues: L<perlport/getpwnam> to L<perlport/endservent>.
2552
2553 =item getsockname SOCKET
2554 X<getsockname>
2555
2556 Returns the packed sockaddr address of this end of the SOCKET connection,
2557 in case you don't know the address because you have several different
2558 IPs that the connection might have come in on.
2559
2560     use Socket;
2561     $mysockaddr = getsockname(SOCK);
2562     ($port, $myaddr) = sockaddr_in($mysockaddr);
2563     printf "Connect to %s [%s]\n",
2564        scalar gethostbyaddr($myaddr, AF_INET),
2565        inet_ntoa($myaddr);
2566
2567 =item getsockopt SOCKET,LEVEL,OPTNAME
2568 X<getsockopt>
2569
2570 Queries the option named OPTNAME associated with SOCKET at a given LEVEL.
2571 Options may exist at multiple protocol levels depending on the socket
2572 type, but at least the uppermost socket level SOL_SOCKET (defined in the
2573 C<Socket> module) will exist.  To query options at another level the
2574 protocol number of the appropriate protocol controlling the option
2575 should be supplied.  For example, to indicate that an option is to be
2576 interpreted by the TCP protocol, LEVEL should be set to the protocol
2577 number of TCP, which you can get using C<getprotobyname>.
2578
2579 The function returns a packed string representing the requested socket
2580 option, or C<undef> on error, with the reason for the error placed in
2581 C<$!>.  Just what is in the packed string depends on LEVEL and OPTNAME;
2582 consult getsockopt(2) for details.  A common case is that the option is an
2583 integer, in which case the result is a packed integer, which you can decode
2584 using C<unpack> with the C<i> (or C<I>) format.
2585
2586 Here's an example to test whether Nagle's algorithm is enabled on a socket:
2587
2588     use Socket qw(:all);
2589
2590     defined(my $tcp = getprotobyname("tcp"))
2591         or die "Could not determine the protocol number for tcp";
2592     # my $tcp = IPPROTO_TCP; # Alternative
2593     my $packed = getsockopt($socket, $tcp, TCP_NODELAY)
2594         or die "getsockopt TCP_NODELAY: $!";
2595     my $nodelay = unpack("I", $packed);
2596     print "Nagle's algorithm is turned ", $nodelay ? "off\n" : "on\n";
2597
2598 Portability issues: L<perlport/getsockopt>.
2599
2600 =item given EXPR BLOCK
2601 X<given>
2602
2603 =item given BLOCK
2604
2605 C<given> is analogous to the C<switch>
2606 keyword in other languages.  C<given>
2607 and C<when> are used in Perl to implement C<switch>/C<case> like statements.
2608 Only available after Perl 5.10.  For example:
2609
2610     use v5.10;
2611     given ($fruit) {
2612         when (/apples?/) {
2613             print "I like apples."
2614         }
2615         when (/oranges?/) {
2616             print "I don't like oranges."
2617         }
2618         default {
2619             print "I don't like anything"
2620         }
2621     }
2622
2623 See L<perlsyn/"Switch Statements"> for detailed information.
2624
2625 =item glob EXPR
2626 X<glob> X<wildcard> X<filename, expansion> X<expand>
2627
2628 =item glob
2629
2630 In list context, returns a (possibly empty) list of filename expansions on
2631 the value of EXPR such as the standard Unix shell F</bin/csh> would do.  In
2632 scalar context, glob iterates through such filename expansions, returning
2633 undef when the list is exhausted.  This is the internal function
2634 implementing the C<< <*.c> >> operator, but you can use it directly.  If
2635 EXPR is omitted, C<$_> is used.  The C<< <*.c> >> operator is discussed in
2636 more detail in L<perlop/"I/O Operators">.
2637
2638 Note that C<glob> splits its arguments on whitespace and treats
2639 each segment as separate pattern.  As such, C<glob("*.c *.h")> 
2640 matches all files with a F<.c> or F<.h> extension.  The expression
2641 C<glob(".* *")> matches all files in the current working directory.
2642 If you want to glob filenames that might contain whitespace, you'll
2643 have to use extra quotes around the spacey filename to protect it.
2644 For example, to glob filenames that have an C<e> followed by a space
2645 followed by an C<f>, use either of:
2646
2647     @spacies = <"*e f*">;
2648     @spacies = glob '"*e f*"';
2649     @spacies = glob q("*e f*");
2650
2651 If you had to get a variable through, you could do this:
2652
2653     @spacies = glob "'*${var}e f*'";
2654     @spacies = glob qq("*${var}e f*");
2655
2656 If non-empty braces are the only wildcard characters used in the
2657 C<glob>, no filenames are matched, but potentially many strings
2658 are returned.  For example, this produces nine strings, one for
2659 each pairing of fruits and colors:
2660
2661     @many =  glob "{apple,tomato,cherry}={green,yellow,red}";
2662
2663 Beginning with v5.6.0, this operator is implemented using the standard
2664 C<File::Glob> extension.  See L<File::Glob> for details, including
2665 C<bsd_glob> which does not treat whitespace as a pattern separator.
2666
2667 Portability issues: L<perlport/glob>.
2668
2669 =item gmtime EXPR
2670 X<gmtime> X<UTC> X<Greenwich>
2671
2672 =item gmtime
2673
2674 Works just like L</localtime> but the returned values are
2675 localized for the standard Greenwich time zone.
2676
2677 Note: When called in list context, $isdst, the last value
2678 returned by gmtime, is always C<0>.  There is no
2679 Daylight Saving Time in GMT.
2680
2681 Portability issues: L<perlport/gmtime>.
2682
2683 =item goto LABEL
2684 X<goto> X<jump> X<jmp>
2685
2686 =item goto EXPR
2687
2688 =item goto &NAME
2689
2690 The C<goto-LABEL> form finds the statement labeled with LABEL and
2691 resumes execution there.  It can't be used to get out of a block or
2692 subroutine given to C<sort>.  It can be used to go almost anywhere
2693 else within the dynamic scope, including out of subroutines, but it's
2694 usually better to use some other construct such as C<last> or C<die>.
2695 The author of Perl has never felt the need to use this form of C<goto>
2696 (in Perl, that is; C is another matter).  (The difference is that C
2697 does not offer named loops combined with loop control.  Perl does, and
2698 this replaces most structured uses of C<goto> in other languages.)
2699
2700 The C<goto-EXPR> form expects a label name, whose scope will be resolved
2701 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
2702 necessarily recommended if you're optimizing for maintainability:
2703
2704     goto ("FOO", "BAR", "GLARCH")[$i];
2705
2706 As shown in this example, C<goto-EXPR> is exempt from the "looks like a
2707 function" rule.  A pair of parentheses following it does not (necessarily)
2708 delimit its argument.  C<goto("NE")."XT"> is equivalent to C<goto NEXT>.
2709
2710 Use of C<goto-LABEL> or C<goto-EXPR> to jump into a construct is
2711 deprecated and will issue a warning.  Even then, it may not be used to
2712 go into any construct that requires initialization, such as a
2713 subroutine or a C<foreach> loop.  It also can't be used to go into a
2714 construct that is optimized away.
2715
2716 The C<goto-&NAME> form is quite different from the other forms of
2717 C<goto>.  In fact, it isn't a goto in the normal sense at all, and
2718 doesn't have the stigma associated with other gotos.  Instead, it
2719 exits the current subroutine (losing any changes set by local()) and
2720 immediately calls in its place the named subroutine using the current
2721 value of @_.  This is used by C<AUTOLOAD> subroutines that wish to
2722 load another subroutine and then pretend that the other subroutine had
2723 been called in the first place (except that any modifications to C<@_>
2724 in the current subroutine are propagated to the other subroutine.)
2725 After the C<goto>, not even C<caller> will be able to tell that this
2726 routine was called first.
2727
2728 NAME needn't be the name of a subroutine; it can be a scalar variable
2729 containing a code reference or a block that evaluates to a code
2730 reference.
2731
2732 =item grep BLOCK LIST
2733 X<grep>
2734
2735 =item grep EXPR,LIST
2736
2737 This is similar in spirit to, but not the same as, grep(1) and its
2738 relatives.  In particular, it is not limited to using regular expressions.
2739
2740 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
2741 C<$_> to each element) and returns the list value consisting of those
2742 elements for which the expression evaluated to true.  In scalar
2743 context, returns the number of times the expression was true.
2744
2745     @foo = grep(!/^#/, @bar);    # weed out comments
2746
2747 or equivalently,
2748
2749     @foo = grep {!/^#/} @bar;    # weed out comments
2750
2751 Note that C<$_> is an alias to the list value, so it can be used to
2752 modify the elements of the LIST.  While this is useful and supported,
2753 it can cause bizarre results if the elements of LIST are not variables.
2754 Similarly, grep returns aliases into the original list, much as a for
2755 loop's index variable aliases the list elements.  That is, modifying an
2756 element of a list returned by grep (for example, in a C<foreach>, C<map>
2757 or another C<grep>) actually modifies the element in the original list.
2758 This is usually something to be avoided when writing clear code.
2759
2760 If C<$_> is lexical in the scope where the C<grep> appears (because it has
2761 been declared with C<my $_>) then, in addition to being locally aliased to
2762 the list elements, C<$_> keeps being lexical inside the block; i.e., it
2763 can't be seen from the outside, avoiding any potential side-effects.
2764
2765 See also L</map> for a list composed of the results of the BLOCK or EXPR.
2766
2767 =item hex EXPR
2768 X<hex> X<hexadecimal>
2769
2770 =item hex
2771
2772 Interprets EXPR as a hex string and returns the corresponding value.
2773 (To convert strings that might start with either C<0>, C<0x>, or C<0b>, see
2774 L</oct>.)  If EXPR is omitted, uses C<$_>.
2775
2776     print hex '0xAf'; # prints '175'
2777     print hex 'aF';   # same
2778
2779 Hex strings may only represent integers.  Strings that would cause
2780 integer overflow trigger a warning.  Leading whitespace is not stripped,
2781 unlike oct().  To present something as hex, look into L</printf>,
2782 L</sprintf>, and L</unpack>.
2783
2784 =item import LIST
2785 X<import>
2786
2787 There is no builtin C<import> function.  It is just an ordinary
2788 method (subroutine) defined (or inherited) by modules that wish to export
2789 names to another module.  The C<use> function calls the C<import> method
2790 for the package used.  See also L</use>, L<perlmod>, and L<Exporter>.
2791
2792 =item index STR,SUBSTR,POSITION
2793 X<index> X<indexOf> X<InStr>
2794
2795 =item index STR,SUBSTR
2796
2797 The index function searches for one string within another, but without
2798 the wildcard-like behavior of a full regular-expression pattern match.
2799 It returns the position of the first occurrence of SUBSTR in STR at
2800 or after POSITION.  If POSITION is omitted, starts searching from the
2801 beginning of the string.  POSITION before the beginning of the string
2802 or after its end is treated as if it were the beginning or the end,
2803 respectively.  POSITION and the return value are based at zero.
2804 If the substring is not found, C<index> returns -1.
2805
2806 =item int EXPR
2807 X<int> X<integer> X<truncate> X<trunc> X<floor>
2808
2809 =item int
2810
2811 Returns the integer portion of EXPR.  If EXPR is omitted, uses C<$_>.
2812 You should not use this function for rounding: one because it truncates
2813 towards C<0>, and two because machine representations of floating-point
2814 numbers can sometimes produce counterintuitive results.  For example,
2815 C<int(-6.725/0.025)> produces -268 rather than the correct -269; that's
2816 because it's really more like -268.99999999999994315658 instead.  Usually,
2817 the C<sprintf>, C<printf>, or the C<POSIX::floor> and C<POSIX::ceil>
2818 functions will serve you better than will int().
2819
2820 =item ioctl FILEHANDLE,FUNCTION,SCALAR
2821 X<ioctl>
2822
2823 Implements the ioctl(2) function.  You'll probably first have to say
2824
2825     require "sys/ioctl.ph";  # probably in $Config{archlib}/sys/ioctl.ph
2826
2827 to get the correct function definitions.  If F<sys/ioctl.ph> doesn't
2828 exist or doesn't have the correct definitions you'll have to roll your
2829 own, based on your C header files such as F<< <sys/ioctl.h> >>.
2830 (There is a Perl script called B<h2ph> that comes with the Perl kit that
2831 may help you in this, but it's nontrivial.)  SCALAR will be read and/or
2832 written depending on the FUNCTION; a C pointer to the string value of SCALAR
2833 will be passed as the third argument of the actual C<ioctl> call.  (If SCALAR
2834 has no string value but does have a numeric value, that value will be
2835 passed rather than a pointer to the string value.  To guarantee this to be
2836 true, add a C<0> to the scalar before using it.)  The C<pack> and C<unpack>
2837 functions may be needed to manipulate the values of structures used by
2838 C<ioctl>.
2839
2840 The return value of C<ioctl> (and C<fcntl>) is as follows:
2841
2842     if OS returns:      then Perl returns:
2843         -1               undefined value
2844          0              string "0 but true"
2845     anything else           that number
2846
2847 Thus Perl returns true on success and false on failure, yet you can
2848 still easily determine the actual value returned by the operating
2849 system:
2850
2851     $retval = ioctl(...) || -1;
2852     printf "System returned %d\n", $retval;
2853
2854 The special string C<"0 but true"> is exempt from B<-w> complaints
2855 about improper numeric conversions.
2856
2857 Portability issues: L<perlport/ioctl>.
2858
2859 =item join EXPR,LIST
2860 X<join>
2861
2862 Joins the separate strings of LIST into a single string with fields
2863 separated by the value of EXPR, and returns that new string.  Example:
2864
2865     $rec = join(':', $login,$passwd,$uid,$gid,$gcos,$home,$shell);
2866
2867 Beware that unlike C<split>, C<join> doesn't take a pattern as its
2868 first argument.  Compare L</split>.
2869
2870 =item keys HASH
2871 X<keys> X<key>
2872
2873 =item keys ARRAY
2874
2875 =item keys EXPR
2876
2877 Called in list context, returns a list consisting of all the keys of the
2878 named hash, or in Perl 5.12 or later only, the indices of an array.  Perl
2879 releases prior to 5.12 will produce a syntax error if you try to use an
2880 array argument.  In scalar context, returns the number of keys or indices.
2881
2882 The keys of a hash are returned in an apparently random order.  The actual
2883 random order is subject to change in future versions of Perl, but it
2884 is guaranteed to be the same order as either the C<values> or C<each>
2885 function produces (given that the hash has not been modified).  Since
2886 Perl 5.8.1 the ordering can be different even between different runs of
2887 Perl for security reasons (see L<perlsec/"Algorithmic Complexity
2888 Attacks">).
2889
2890 As a side effect, calling keys() resets the internal interator of the HASH or ARRAY
2891 (see L</each>).  In particular, calling keys() in void context resets
2892 the iterator with no other overhead.
2893
2894 Here is yet another way to print your environment:
2895
2896     @keys = keys %ENV;
2897     @values = values %ENV;
2898     while (@keys) {
2899         print pop(@keys), '=', pop(@values), "\n";
2900     }
2901
2902 or how about sorted by key:
2903
2904     foreach $key (sort(keys %ENV)) {
2905         print $key, '=', $ENV{$key}, "\n";
2906     }
2907
2908 The returned values are copies of the original keys in the hash, so
2909 modifying them will not affect the original hash.  Compare L</values>.
2910
2911 To sort a hash by value, you'll need to use a C<sort> function.
2912 Here's a descending numeric sort of a hash by its values:
2913
2914     foreach $key (sort { $hash{$b} <=> $hash{$a} } keys %hash) {
2915         printf "%4d %s\n", $hash{$key}, $key;
2916     }
2917
2918 Used as an lvalue, C<keys> allows you to increase the number of hash buckets
2919 allocated for the given hash.  This can gain you a measure of efficiency if
2920 you know the hash is going to get big.  (This is similar to pre-extending
2921 an array by assigning a larger number to $#array.)  If you say
2922
2923     keys %hash = 200;
2924
2925 then C<%hash> will have at least 200 buckets allocated for it--256 of them,
2926 in fact, since it rounds up to the next power of two.  These
2927 buckets will be retained even if you do C<%hash = ()>, use C<undef
2928 %hash> if you want to free the storage while C<%hash> is still in scope.
2929 You can't shrink the number of buckets allocated for the hash using
2930 C<keys> in this way (but you needn't worry about doing this by accident,
2931 as trying has no effect).  C<keys @array> in an lvalue context is a syntax
2932 error.
2933
2934 Starting with Perl 5.14, C<keys> can take a scalar EXPR, which must contain
2935 a reference to an unblessed hash or array.  The argument will be
2936 dereferenced automatically.  This aspect of C<keys> is considered highly
2937 experimental.  The exact behaviour may change in a future version of Perl.
2938
2939     for (keys $hashref) { ... }
2940     for (keys $obj->get_arrayref) { ... }
2941
2942 To avoid confusing would-be users of your code who are running earlier
2943 versions of Perl with mysterious syntax errors, put this sort of thing at
2944 the top of your file to signal that your code will work I<only> on Perls of
2945 a recent vintage:
2946
2947     use 5.012;  # so keys/values/each work on arrays
2948     use 5.014;  # so keys/values/each work on scalars (experimental)
2949
2950 See also C<each>, C<values>, and C<sort>.
2951
2952 =item kill SIGNAL, LIST
2953
2954 =item kill SIGNAL
2955 X<kill> X<signal>
2956
2957 Sends a signal to a list of processes.  Returns the number of
2958 processes successfully signaled (which is not necessarily the
2959 same as the number actually killed).
2960
2961     $cnt = kill 1, $child1, $child2;
2962     kill 9, @goners;
2963
2964 If SIGNAL is zero, no signal is sent to the process, but C<kill>
2965 checks whether it's I<possible> to send a signal to it (that
2966 means, to be brief, that the process is owned by the same user, or we are
2967 the super-user).  This is useful to check that a child process is still
2968 alive (even if only as a zombie) and hasn't changed its UID.  See
2969 L<perlport> for notes on the portability of this construct.
2970
2971 Unlike in the shell, if SIGNAL is negative, it kills process groups instead
2972 of processes.  That means you usually
2973 want to use positive not negative signals.
2974 You may also use a signal name in quotes.
2975
2976 The behavior of kill when a I<PROCESS> number is zero or negative depends on
2977 the operating system.  For example, on POSIX-conforming systems, zero will
2978 signal the current process group and -1 will signal all processes.
2979
2980 See L<perlipc/"Signals"> for more details.
2981
2982 On some platforms such as Windows where the fork() system call is not available.
2983 Perl can be built to emulate fork() at the interpreter level.
2984 This emulation has limitations related to kill that have to be considered,
2985 for code running on Windows and in code intended to be portable.
2986
2987 See L<perlfork> for more details.
2988
2989 If there is no I<LIST> of processes, no signal is sent, and the return
2990 value is 0.  This form is sometimes used, however, because it causes
2991 tainting checks to be run.  But see
2992 L<perlsec/Laundering and Detecting Tainted Data>.
2993
2994 Portability issues: L<perlport/kill>.
2995
2996 =item last LABEL
2997 X<last> X<break>
2998
2999 =item last
3000
3001 The C<last> command is like the C<break> statement in C (as used in
3002 loops); it immediately exits the loop in question.  If the LABEL is
3003 omitted, the command refers to the innermost enclosing loop.  The
3004 C<continue> block, if any, is not executed:
3005
3006     LINE: while (<STDIN>) {
3007         last LINE if /^$/;  # exit when done with header
3008         #...
3009     }
3010
3011 C<last> cannot be used to exit a block that returns a value such as
3012 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3013 a grep() or map() operation.
3014
3015 Note that a block by itself is semantically identical to a loop
3016 that executes once.  Thus C<last> can be used to effect an early
3017 exit out of such a block.
3018
3019 See also L</continue> for an illustration of how C<last>, C<next>, and
3020 C<redo> work.
3021
3022 =item lc EXPR
3023 X<lc> X<lowercase>
3024
3025 =item lc
3026
3027 Returns a lowercased version of EXPR.  This is the internal function
3028 implementing the C<\L> escape in double-quoted strings.
3029
3030 If EXPR is omitted, uses C<$_>.
3031
3032 What gets returned depends on several factors:
3033
3034 =over
3035
3036 =item If C<use bytes> is in effect:
3037
3038 =over
3039
3040 =item On EBCDIC platforms
3041
3042 The results are what the C language system call C<tolower()> returns.
3043
3044 =item On ASCII platforms
3045
3046 The results follow ASCII semantics.  Only characters C<A-Z> change, to C<a-z>
3047 respectively.
3048
3049 =back
3050
3051 =item Otherwise, if C<use locale> (but not C<use locale ':not_characters'>) is in effect:
3052
3053 Respects current LC_CTYPE locale for code points < 256; and uses Unicode
3054 semantics for the remaining code points (this last can only happen if
3055 the UTF8 flag is also set).  See L<perllocale>.
3056
3057 A deficiency in this is that case changes that cross the 255/256
3058 boundary are not well-defined.  For example, the lower case of LATIN CAPITAL
3059 LETTER SHARP S (U+1E9E) in Unicode semantics is U+00DF (on ASCII
3060 platforms).   But under C<use locale>, the lower case of U+1E9E is
3061 itself, because 0xDF may not be LATIN SMALL LETTER SHARP S in the
3062 current locale, and Perl has no way of knowing if that character even
3063 exists in the locale, much less what code point it is.  Perl returns
3064 the input character unchanged, for all instances (and there aren't
3065 many) where the 255/256 boundary would otherwise be crossed.
3066
3067 =item Otherwise, If EXPR has the UTF8 flag set:
3068
3069 Unicode semantics are used for the case change.
3070
3071 =item Otherwise, if C<use feature 'unicode_strings'> or C<use locale ':not_characters'>) is in effect:
3072
3073 Unicode semantics are used for the case change.
3074
3075 =item Otherwise:
3076
3077 =over
3078
3079 =item On EBCDIC platforms
3080
3081 The results are what the C language system call C<tolower()> returns.
3082
3083 =item On ASCII platforms
3084
3085 ASCII semantics are used for the case change.  The lowercase of any character
3086 outside the ASCII range is the character itself.
3087
3088 =back
3089
3090 =back
3091
3092 =item lcfirst EXPR
3093 X<lcfirst> X<lowercase>
3094
3095 =item lcfirst
3096
3097 Returns the value of EXPR with the first character lowercased.  This
3098 is the internal function implementing the C<\l> escape in
3099 double-quoted strings.
3100
3101 If EXPR is omitted, uses C<$_>.
3102
3103 This function behaves the same way under various pragmata, such as in a locale,
3104 as L</lc> does.
3105
3106 =item length EXPR
3107 X<length> X<size>
3108
3109 =item length
3110
3111 Returns the length in I<characters> of the value of EXPR.  If EXPR is
3112 omitted, returns the length of C<$_>.  If EXPR is undefined, returns
3113 C<undef>.
3114
3115 This function cannot be used on an entire array or hash to find out how
3116 many elements these have.  For that, use C<scalar @array> and C<scalar keys
3117 %hash>, respectively.
3118
3119 Like all Perl character operations, length() normally deals in logical
3120 characters, not physical bytes.  For how many bytes a string encoded as
3121 UTF-8 would take up, use C<length(Encode::encode_utf8(EXPR))> (you'll have
3122 to C<use Encode> first).  See L<Encode> and L<perlunicode>.
3123
3124 =item __LINE__
3125 X<__LINE__>
3126
3127 A special token that compiles to the current line number.
3128
3129 =item link OLDFILE,NEWFILE
3130 X<link>
3131
3132 Creates a new filename linked to the old filename.  Returns true for
3133 success, false otherwise.
3134
3135 Portability issues: L<perlport/link>.
3136
3137 =item listen SOCKET,QUEUESIZE
3138 X<listen>
3139
3140 Does the same thing that the listen(2) system call does.  Returns true if
3141 it succeeded, false otherwise.  See the example in
3142 L<perlipc/"Sockets: Client/Server Communication">.
3143
3144 =item local EXPR
3145 X<local>
3146
3147 You really probably want to be using C<my> instead, because C<local> isn't
3148 what most people think of as "local".  See
3149 L<perlsub/"Private Variables via my()"> for details.
3150
3151 A local modifies the listed variables to be local to the enclosing
3152 block, file, or eval.  If more than one value is listed, the list must
3153 be placed in parentheses.  See L<perlsub/"Temporary Values via local()">
3154 for details, including issues with tied arrays and hashes.
3155
3156 The C<delete local EXPR> construct can also be used to localize the deletion
3157 of array/hash elements to the current block.
3158 See L<perlsub/"Localized deletion of elements of composite types">.
3159
3160 =item localtime EXPR
3161 X<localtime> X<ctime>
3162
3163 =item localtime
3164
3165 Converts a time as returned by the time function to a 9-element list
3166 with the time analyzed for the local time zone.  Typically used as
3167 follows:
3168
3169     #  0    1    2     3     4    5     6     7     8
3170     ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) =
3171                                                 localtime(time);
3172
3173 All list elements are numeric and come straight out of the C `struct
3174 tm'.  C<$sec>, C<$min>, and C<$hour> are the seconds, minutes, and hours
3175 of the specified time.
3176
3177 C<$mday> is the day of the month and C<$mon> the month in
3178 the range C<0..11>, with 0 indicating January and 11 indicating December.
3179 This makes it easy to get a month name from a list:
3180
3181     my @abbr = qw( Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec );
3182     print "$abbr[$mon] $mday";
3183     # $mon=9, $mday=18 gives "Oct 18"
3184
3185 C<$year> contains the number of years since 1900.  To get a 4-digit
3186 year write:
3187
3188     $year += 1900;
3189
3190 To get the last two digits of the year (e.g., "01" in 2001) do:
3191
3192     $year = sprintf("%02d", $year % 100);
3193
3194 C<$wday> is the day of the week, with 0 indicating Sunday and 3 indicating
3195 Wednesday.  C<$yday> is the day of the year, in the range C<0..364>
3196 (or C<0..365> in leap years.)
3197
3198 C<$isdst> is true if the specified time occurs during Daylight Saving
3199 Time, false otherwise.
3200
3201 If EXPR is omitted, C<localtime()> uses the current time (as returned
3202 by time(3)).
3203
3204 In scalar context, C<localtime()> returns the ctime(3) value:
3205
3206     $now_string = localtime;  # e.g., "Thu Oct 13 04:54:34 1994"
3207
3208 The format of this scalar value is B<not> locale-dependent
3209 but built into Perl.  For GMT instead of local
3210 time use the L</gmtime> builtin.  See also the
3211 C<Time::Local> module (for converting seconds, minutes, hours, and such back to
3212 the integer value returned by time()), and the L<POSIX> module's strftime(3)
3213 and mktime(3) functions.
3214
3215 To get somewhat similar but locale-dependent date strings, set up your
3216 locale environment variables appropriately (please see L<perllocale>) and
3217 try for example:
3218
3219     use POSIX qw(strftime);
3220     $now_string = strftime "%a %b %e %H:%M:%S %Y", localtime;
3221     # or for GMT formatted appropriately for your locale:
3222     $now_string = strftime "%a %b %e %H:%M:%S %Y", gmtime;
3223
3224 Note that the C<%a> and C<%b>, the short forms of the day of the week
3225 and the month of the year, may not necessarily be three characters wide.
3226
3227 The L<Time::gmtime> and L<Time::localtime> modules provide a convenient,
3228 by-name access mechanism to the gmtime() and localtime() functions,
3229 respectively.
3230
3231 For a comprehensive date and time representation look at the
3232 L<DateTime> module on CPAN.
3233
3234 Portability issues: L<perlport/localtime>.
3235
3236 =item lock THING
3237 X<lock>
3238
3239 This function places an advisory lock on a shared variable or referenced
3240 object contained in I<THING> until the lock goes out of scope.
3241
3242 The value returned is the scalar itself, if the argument is a scalar, or a
3243 reference, if the argument is a hash, array or subroutine.
3244
3245 lock() is a "weak keyword" : this means that if you've defined a function
3246 by this name (before any calls to it), that function will be called
3247 instead.  If you are not under C<use threads::shared> this does nothing.
3248 See L<threads::shared>.
3249
3250 =item log EXPR
3251 X<log> X<logarithm> X<e> X<ln> X<base>
3252
3253 =item log
3254
3255 Returns the natural logarithm (base I<e>) of EXPR.  If EXPR is omitted,
3256 returns the log of C<$_>.  To get the
3257 log of another base, use basic algebra:
3258 The base-N log of a number is equal to the natural log of that number
3259 divided by the natural log of N.  For example:
3260
3261     sub log10 {
3262         my $n = shift;
3263         return log($n)/log(10);
3264     }
3265
3266 See also L</exp> for the inverse operation.
3267
3268 =item lstat FILEHANDLE
3269 X<lstat>
3270
3271 =item lstat EXPR
3272
3273 =item lstat DIRHANDLE
3274
3275 =item lstat
3276
3277 Does the same thing as the C<stat> function (including setting the
3278 special C<_> filehandle) but stats a symbolic link instead of the file
3279 the symbolic link points to.  If symbolic links are unimplemented on
3280 your system, a normal C<stat> is done.  For much more detailed
3281 information, please see the documentation for C<stat>.
3282
3283 If EXPR is omitted, stats C<$_>.
3284
3285 Portability issues: L<perlport/lstat>.
3286
3287 =item m//
3288
3289 The match operator.  See L<perlop/"Regexp Quote-Like Operators">.
3290
3291 =item map BLOCK LIST
3292 X<map>
3293
3294 =item map EXPR,LIST
3295
3296 Evaluates the BLOCK or EXPR for each element of LIST (locally setting
3297 C<$_> to each element) and returns the list value composed of the
3298 results of each such evaluation.  In scalar context, returns the
3299 total number of elements so generated.  Evaluates BLOCK or EXPR in
3300 list context, so each element of LIST may produce zero, one, or
3301 more elements in the returned value.
3302
3303     @chars = map(chr, @numbers);
3304
3305 translates a list of numbers to the corresponding characters.
3306
3307     my @squares = map { $_ * $_ } @numbers;
3308
3309 translates a list of numbers to their squared values.
3310
3311     my @squares = map { $_ > 5 ? ($_ * $_) : () } @numbers;
3312
3313 shows that number of returned elements can differ from the number of
3314 input elements.  To omit an element, return an empty list ().
3315 This could also be achieved by writing
3316
3317     my @squares = map { $_ * $_ } grep { $_ > 5 } @numbers;
3318
3319 which makes the intention more clear.
3320
3321 Map always returns a list, which can be
3322 assigned to a hash such that the elements
3323 become key/value pairs.  See L<perldata> for more details.
3324
3325     %hash = map { get_a_key_for($_) => $_ } @array;
3326
3327 is just a funny way to write
3328
3329     %hash = ();
3330     foreach (@array) {
3331         $hash{get_a_key_for($_)} = $_;
3332     }
3333
3334 Note that C<$_> is an alias to the list value, so it can be used to
3335 modify the elements of the LIST.  While this is useful and supported,
3336 it can cause bizarre results if the elements of LIST are not variables.
3337 Using a regular C<foreach> loop for this purpose would be clearer in
3338 most cases.  See also L</grep> for an array composed of those items of
3339 the original list for which the BLOCK or EXPR evaluates to true.
3340
3341 If C<$_> is lexical in the scope where the C<map> appears (because it has
3342 been declared with C<my $_>), then, in addition to being locally aliased to
3343 the list elements, C<$_> keeps being lexical inside the block; that is, it
3344 can't be seen from the outside, avoiding any potential side-effects.
3345
3346 C<{> starts both hash references and blocks, so C<map { ...> could be either
3347 the start of map BLOCK LIST or map EXPR, LIST.  Because Perl doesn't look
3348 ahead for the closing C<}> it has to take a guess at which it's dealing with
3349 based on what it finds just after the
3350 C<{>.  Usually it gets it right, but if it
3351 doesn't it won't realize something is wrong until it gets to the C<}> and
3352 encounters the missing (or unexpected) comma.  The syntax error will be
3353 reported close to the C<}>, but you'll need to change something near the C<{>
3354 such as using a unary C<+> to give Perl some help:
3355
3356     %hash = map {  "\L$_" => 1  } @array  # perl guesses EXPR.  wrong
3357     %hash = map { +"\L$_" => 1  } @array  # perl guesses BLOCK. right
3358     %hash = map { ("\L$_" => 1) } @array  # this also works
3359     %hash = map {  lc($_) => 1  } @array  # as does this.
3360     %hash = map +( lc($_) => 1 ), @array  # this is EXPR and works!
3361
3362     %hash = map  ( lc($_), 1 ),   @array  # evaluates to (1, @array)
3363
3364 or to force an anon hash constructor use C<+{>:
3365
3366    @hashes = map +{ lc($_) => 1 }, @array # EXPR, so needs comma at end
3367
3368 to get a list of anonymous hashes each with only one entry apiece.
3369
3370 =item mkdir FILENAME,MASK
3371 X<mkdir> X<md> X<directory, create>
3372
3373 =item mkdir FILENAME
3374
3375 =item mkdir
3376
3377 Creates the directory specified by FILENAME, with permissions
3378 specified by MASK (as modified by C<umask>).  If it succeeds it
3379 returns true; otherwise it returns false and sets C<$!> (errno).
3380 MASK defaults to 0777 if omitted, and FILENAME defaults
3381 to C<$_> if omitted.
3382
3383 In general, it is better to create directories with a permissive MASK
3384 and let the user modify that with their C<umask> than it is to supply
3385 a restrictive MASK and give the user no way to be more permissive.
3386 The exceptions to this rule are when the file or directory should be
3387 kept private (mail files, for instance).  The perlfunc(1) entry on
3388 C<umask> discusses the choice of MASK in more detail.
3389
3390 Note that according to the POSIX 1003.1-1996 the FILENAME may have any
3391 number of trailing slashes.  Some operating and filesystems do not get
3392 this right, so Perl automatically removes all trailing slashes to keep
3393 everyone happy.
3394
3395 To recursively create a directory structure, look at
3396 the C<mkpath> function of the L<File::Path> module.
3397
3398 =item msgctl ID,CMD,ARG
3399 X<msgctl>
3400
3401 Calls the System V IPC function msgctl(2).  You'll probably have to say
3402
3403     use IPC::SysV;
3404
3405 first to get the correct constant definitions.  If CMD is C<IPC_STAT>,
3406 then ARG must be a variable that will hold the returned C<msqid_ds>
3407 structure.  Returns like C<ioctl>: the undefined value for error,
3408 C<"0 but true"> for zero, or the actual return value otherwise.  See also
3409 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3410 C<IPC::Semaphore>.
3411
3412 Portability issues: L<perlport/msgctl>.
3413
3414 =item msgget KEY,FLAGS
3415 X<msgget>
3416
3417 Calls the System V IPC function msgget(2).  Returns the message queue
3418 id, or C<undef> on error.  See also
3419 L<perlipc/"SysV IPC"> and the documentation for C<IPC::SysV> and
3420 C<IPC::Msg>.
3421
3422 Portability issues: L<perlport/msgget>.
3423
3424 =item msgrcv ID,VAR,SIZE,TYPE,FLAGS
3425 X<msgrcv>
3426
3427 Calls the System V IPC function msgrcv to receive a message from
3428 message queue ID into variable VAR with a maximum message size of
3429 SIZE.  Note that when a message is received, the message type as a
3430 native long integer will be the first thing in VAR, followed by the
3431 actual message.  This packing may be opened with C<unpack("l! a*")>.
3432 Taints the variable.  Returns true if successful, false 
3433 on error.  See also L<perlipc/"SysV IPC"> and the documentation for
3434 C<IPC::SysV> and C<IPC::SysV::Msg>.
3435
3436 Portability issues: L<perlport/msgrcv>.
3437
3438 =item msgsnd ID,MSG,FLAGS
3439 X<msgsnd>
3440
3441 Calls the System V IPC function msgsnd to send the message MSG to the
3442 message queue ID.  MSG must begin with the native long integer message
3443 type, be followed by the length of the actual message, and then finally
3444 the message itself.  This kind of packing can be achieved with
3445 C<pack("l! a*", $type, $message)>.  Returns true if successful,
3446 false on error.  See also the C<IPC::SysV>
3447 and C<IPC::SysV::Msg> documentation.
3448
3449 Portability issues: L<perlport/msgsnd>.
3450
3451 =item my EXPR
3452 X<my>
3453
3454 =item my TYPE EXPR
3455
3456 =item my EXPR : ATTRS
3457
3458 =item my TYPE EXPR : ATTRS
3459
3460 A C<my> declares the listed variables to be local (lexically) to the
3461 enclosing block, file, or C<eval>.  If more than one value is listed,
3462 the list must be placed in parentheses.
3463
3464 The exact semantics and interface of TYPE and ATTRS are still
3465 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
3466 and attributes are handled using the C<attributes> pragma, or starting
3467 from Perl 5.8.0 also via the C<Attribute::Handlers> module.  See
3468 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
3469 L<attributes>, and L<Attribute::Handlers>.
3470
3471 =item next LABEL
3472 X<next> X<continue>
3473
3474 =item next
3475
3476 The C<next> command is like the C<continue> statement in C; it starts
3477 the next iteration of the loop:
3478
3479     LINE: while (<STDIN>) {
3480         next LINE if /^#/;  # discard comments
3481         #...
3482     }
3483
3484 Note that if there were a C<continue> block on the above, it would get
3485 executed even on discarded lines.  If LABEL is omitted, the command
3486 refers to the innermost enclosing loop.
3487
3488 C<next> cannot be used to exit a block which returns a value such as
3489 C<eval {}>, C<sub {}>, or C<do {}>, and should not be used to exit
3490 a grep() or map() operation.
3491
3492 Note that a block by itself is semantically identical to a loop
3493 that executes once.  Thus C<next> will exit such a block early.
3494
3495 See also L</continue> for an illustration of how C<last>, C<next>, and
3496 C<redo> work.
3497
3498 =item no MODULE VERSION LIST
3499 X<no declarations>
3500 X<unimporting>
3501
3502 =item no MODULE VERSION
3503
3504 =item no MODULE LIST
3505
3506 =item no MODULE
3507
3508 =item no VERSION
3509
3510 See the C<use> function, of which C<no> is the opposite.
3511
3512 =item oct EXPR
3513 X<oct> X<octal> X<hex> X<hexadecimal> X<binary> X<bin>
3514
3515 =item oct
3516
3517 Interprets EXPR as an octal string and returns the corresponding
3518 value.  (If EXPR happens to start off with C<0x>, interprets it as a
3519 hex string.  If EXPR starts off with C<0b>, it is interpreted as a
3520 binary string.  Leading whitespace is ignored in all three cases.)
3521 The following will handle decimal, binary, octal, and hex in standard
3522 Perl notation:
3523
3524     $val = oct($val) if $val =~ /^0/;
3525
3526 If EXPR is omitted, uses C<$_>.   To go the other way (produce a number
3527 in octal), use sprintf() or printf():
3528
3529     $dec_perms = (stat("filename"))[2] & 07777;
3530     $oct_perm_str = sprintf "%o", $perms;
3531
3532 The oct() function is commonly used when a string such as C<644> needs
3533 to be converted into a file mode, for example.  Although Perl 
3534 automatically converts strings into numbers as needed, this automatic
3535 conversion assumes base 10.
3536
3537 Leading white space is ignored without warning, as too are any trailing 
3538 non-digits, such as a decimal point (C<oct> only handles non-negative
3539 integers, not negative integers or floating point).
3540
3541 =item open FILEHANDLE,EXPR
3542 X<open> X<pipe> X<file, open> X<fopen>
3543
3544 =item open FILEHANDLE,MODE,EXPR
3545
3546 =item open FILEHANDLE,MODE,EXPR,LIST
3547
3548 =item open FILEHANDLE,MODE,REFERENCE
3549
3550 =item open FILEHANDLE
3551
3552 Opens the file whose filename is given by EXPR, and associates it with
3553 FILEHANDLE.
3554
3555 Simple examples to open a file for reading:
3556
3557     open(my $fh, "<", "input.txt") 
3558         or die "cannot open < input.txt: $!";
3559
3560 and for writing:
3561
3562     open(my $fh, ">", "output.txt") 
3563         or die "cannot open > output.txt: $!";
3564
3565 (The following is a comprehensive reference to open(): for a gentler
3566 introduction you may consider L<perlopentut>.)
3567
3568 If FILEHANDLE is an undefined scalar variable (or array or hash element), a
3569 new filehandle is autovivified, meaning that the variable is assigned a
3570 reference to a newly allocated anonymous filehandle.  Otherwise if
3571 FILEHANDLE is an expression, its value is the real filehandle.  (This is
3572 considered a symbolic reference, so C<use strict "refs"> should I<not> be
3573 in effect.)
3574
3575 If EXPR is omitted, the global (package) scalar variable of the same
3576 name as the FILEHANDLE contains the filename.  (Note that lexical 
3577 variables--those declared with C<my> or C<state>--will not work for this
3578 purpose; so if you're using C<my> or C<state>, specify EXPR in your
3579 call to open.)
3580
3581 If three (or more) arguments are specified, the open mode (including
3582 optional encoding) in the second argument are distinct from the filename in
3583 the third.  If MODE is C<< < >> or nothing, the file is opened for input.
3584 If MODE is C<< > >>, the file is opened for output, with existing files
3585 first being truncated ("clobbered") and nonexisting files newly created.
3586 If MODE is C<<< >> >>>, the file is opened for appending, again being
3587 created if necessary.
3588
3589 You can put a C<+> in front of the C<< > >> or C<< < >> to
3590 indicate that you want both read and write access to the file; thus
3591 C<< +< >> is almost always preferred for read/write updates--the 
3592 C<< +> >> mode would clobber the file first.  You can't usually use
3593 either read-write mode for updating textfiles, since they have
3594 variable-length records.  See the B<-i> switch in L<perlrun> for a
3595 better approach.  The file is created with permissions of C<0666>
3596 modified by the process's C<umask> value.
3597
3598 These various prefixes correspond to the fopen(3) modes of C<r>,
3599 C<r+>, C<w>, C<w+>, C<a>, and C<a+>.
3600
3601 In the one- and two-argument forms of the call, the mode and filename
3602 should be concatenated (in that order), preferably separated by white
3603 space.  You can--but shouldn't--omit the mode in these forms when that mode
3604 is C<< < >>.  It is always safe to use the two-argument form of C<open> if
3605 the filename argument is a known literal.
3606
3607 For three or more arguments if MODE is C<|->, the filename is
3608 interpreted as a command to which output is to be piped, and if MODE
3609 is C<-|>, the filename is interpreted as a command that pipes
3610 output to us.  In the two-argument (and one-argument) form, one should
3611 replace dash (C<->) with the command.
3612 See L<perlipc/"Using open() for IPC"> for more examples of this.
3613 (You are not allowed to C<open> to a command that pipes both in I<and>
3614 out, but see L<IPC::Open2>, L<IPC::Open3>, and
3615 L<perlipc/"Bidirectional Communication with Another Process"> for
3616 alternatives.)
3617
3618 In the form of pipe opens taking three or more arguments, if LIST is specified
3619 (extra arguments after the command name) then LIST becomes arguments
3620 to the command invoked if the platform supports it.  The meaning of
3621 C<open> with more than three arguments for non-pipe modes is not yet
3622 defined, but experimental "layers" may give extra LIST arguments
3623 meaning.
3624
3625 In the two-argument (and one-argument) form, opening C<< <- >> 
3626 or C<-> opens STDIN and opening C<< >- >> opens STDOUT.
3627
3628 You may (and usually should) use the three-argument form of open to specify
3629 I/O layers (sometimes referred to as "disciplines") to apply to the handle
3630 that affect how the input and output are processed (see L<open> and
3631 L<PerlIO> for more details).  For example:
3632
3633   open(my $fh, "<:encoding(UTF-8)", "filename")
3634     || die "can't open UTF-8 encoded filename: $!";
3635
3636 opens the UTF8-encoded file containing Unicode characters;
3637 see L<perluniintro>.  Note that if layers are specified in the
3638 three-argument form, then default layers stored in ${^OPEN} (see L<perlvar>;
3639 usually set by the B<open> pragma or the switch B<-CioD>) are ignored.
3640 Those layers will also be ignored if you specifying a colon with no name
3641 following it.  In that case the default layer for the operating system
3642 (:raw on Unix, :crlf on Windows) is used.
3643
3644 Open returns nonzero on success, the undefined value otherwise.  If
3645 the C<open> involved a pipe, the return value happens to be the pid of
3646 the subprocess.
3647
3648 If you're running Perl on a system that distinguishes between text
3649 files and binary files, then you should check out L</binmode> for tips
3650 for dealing with this.  The key distinction between systems that need
3651 C<binmode> and those that don't is their text file formats.  Systems
3652 like Unix, Mac OS, and Plan 9, that end lines with a single
3653 character and encode that character in C as C<"\n"> do not
3654 need C<binmode>.  The rest need it.
3655
3656 When opening a file, it's seldom a good idea to continue 
3657 if the request failed, so C<open> is frequently used with
3658 C<die>.  Even if C<die> won't do what you want (say, in a CGI script,
3659 where you want to format a suitable error message (but there are
3660 modules that can help with that problem)) always check
3661 the return value from opening a file.  
3662
3663 As a special case the three-argument form with a read/write mode and the third
3664 argument being C<undef>:
3665
3666     open(my $tmp, "+>", undef) or die ...
3667
3668 opens a filehandle to an anonymous temporary file.  Also using C<< +< >>
3669 works for symmetry, but you really should consider writing something
3670 to the temporary file first.  You will need to seek() to do the
3671 reading.
3672
3673 Since v5.8.0, Perl has built using PerlIO by default.  Unless you've
3674 changed this (such as building Perl with C<Configure -Uuseperlio>), you can
3675 open filehandles directly to Perl scalars via:
3676
3677     open($fh, ">", \$variable) || ..
3678
3679 To (re)open C<STDOUT> or C<STDERR> as an in-memory file, close it first:
3680
3681     close STDOUT;
3682     open(STDOUT, ">", \$variable)
3683         or die "Can't open STDOUT: $!";
3684
3685 General examples:
3686
3687     $ARTICLE = 100;
3688     open(ARTICLE) or die "Can't find article $ARTICLE: $!\n";
3689     while (<ARTICLE>) {...
3690
3691     open(LOG, ">>/usr/spool/news/twitlog");  # (log is reserved)
3692     # if the open fails, output is discarded
3693
3694     open(my $dbase, "+<", "dbase.mine")      # open for update
3695         or die "Can't open 'dbase.mine' for update: $!";
3696
3697     open(my $dbase, "+<dbase.mine")          # ditto
3698         or die "Can't open 'dbase.mine' for update: $!";
3699
3700     open(ARTICLE, "-|", "caesar <$article")  # decrypt article
3701         or die "Can't start caesar: $!";
3702
3703     open(ARTICLE, "caesar <$article |")      # ditto
3704         or die "Can't start caesar: $!";
3705
3706     open(EXTRACT, "|sort >Tmp$$")            # $$ is our process id
3707         or die "Can't start sort: $!";
3708
3709     # in-memory files
3710     open(MEMORY, ">", \$var)
3711         or die "Can't open memory file: $!";
3712     print MEMORY "foo!\n";                   # output will appear in $var
3713
3714     # process argument list of files along with any includes
3715
3716     foreach $file (@ARGV) {
3717         process($file, "fh00");
3718     }
3719
3720     sub process {
3721         my($filename, $input) = @_;
3722         $input++;    # this is a string increment
3723         unless (open($input, "<", $filename)) {
3724             print STDERR "Can't open $filename: $!\n";
3725             return;
3726         }
3727
3728         local $_;
3729         while (<$input>) {    # note use of indirection
3730             if (/^#include "(.*)"/) {
3731                 process($1, $input);
3732                 next;
3733             }
3734             #...          # whatever
3735         }
3736     }
3737
3738 See L<perliol> for detailed info on PerlIO.
3739
3740 You may also, in the Bourne shell tradition, specify an EXPR beginning
3741 with C<< >& >>, in which case the rest of the string is interpreted
3742 as the name of a filehandle (or file descriptor, if numeric) to be
3743 duped (as C<dup(2)>) and opened.  You may use C<&> after C<< > >>,
3744 C<<< >> >>>, C<< < >>, C<< +> >>, C<<< +>> >>>, and C<< +< >>.
3745 The mode you specify should match the mode of the original filehandle.
3746 (Duping a filehandle does not take into account any existing contents
3747 of IO buffers.)  If you use the three-argument
3748 form, then you can pass either a
3749 number, the name of a filehandle, or the normal "reference to a glob".
3750
3751 Here is a script that saves, redirects, and restores C<STDOUT> and
3752 C<STDERR> using various methods:
3753
3754     #!/usr/bin/perl
3755     open(my $oldout, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3756     open(OLDERR,     ">&", \*STDERR) or die "Can't dup STDERR: $!";
3757
3758     open(STDOUT, '>', "foo.out") or die "Can't redirect STDOUT: $!";
3759     open(STDERR, ">&STDOUT")     or die "Can't dup STDOUT: $!";
3760
3761     select STDERR; $| = 1;  # make unbuffered
3762     select STDOUT; $| = 1;  # make unbuffered
3763
3764     print STDOUT "stdout 1\n";  # this works for
3765     print STDERR "stderr 1\n";  # subprocesses too
3766
3767     open(STDOUT, ">&", $oldout) or die "Can't dup \$oldout: $!";
3768     open(STDERR, ">&OLDERR")    or die "Can't dup OLDERR: $!";
3769
3770     print STDOUT "stdout 2\n";
3771     print STDERR "stderr 2\n";
3772
3773 If you specify C<< '<&=X' >>, where C<X> is a file descriptor number
3774 or a filehandle, then Perl will do an equivalent of C's C<fdopen> of
3775 that file descriptor (and not call C<dup(2)>); this is more
3776 parsimonious of file descriptors.  For example:
3777
3778     # open for input, reusing the fileno of $fd
3779     open(FILEHANDLE, "<&=$fd")
3780
3781 or
3782
3783     open(FILEHANDLE, "<&=", $fd)
3784
3785 or
3786
3787     # open for append, using the fileno of OLDFH
3788     open(FH, ">>&=", OLDFH)
3789
3790 or
3791
3792     open(FH, ">>&=OLDFH")
3793
3794 Being parsimonious on filehandles is also useful (besides being
3795 parsimonious) for example when something is dependent on file
3796 descriptors, like for example locking using flock().  If you do just
3797 C<< open(A, ">>&B") >>, the filehandle A will not have the same file
3798 descriptor as B, and therefore flock(A) will not flock(B) nor vice
3799 versa.  But with C<< open(A, ">>&=B") >>, the filehandles will share
3800 the same underlying system file descriptor.
3801
3802 Note that under Perls older than 5.8.0, Perl uses the standard C library's'
3803 fdopen() to implement the C<=> functionality.  On many Unix systems,
3804 fdopen() fails when file descriptors exceed a certain value, typically 255.
3805 For Perls 5.8.0 and later, PerlIO is (most often) the default.
3806
3807 You can see whether your Perl was built with PerlIO by running C<perl -V>
3808 and looking for the C<useperlio=> line.  If C<useperlio> is C<define>, you
3809 have PerlIO; otherwise you don't.
3810
3811 If you open a pipe on the command C<-> (that is, specify either C<|-> or C<-|>
3812 with the one- or two-argument forms of C<open>), 
3813 an implicit C<fork> is done, so C<open> returns twice: in the parent
3814 process it returns the pid
3815 of the child process, and in the child process it returns (a defined) C<0>.
3816 Use C<defined($pid)> or C<//> to determine whether the open was successful.
3817
3818 For example, use either
3819
3820     $child_pid = open(FROM_KID, "-|")   // die "can't fork: $!";
3821
3822 or
3823     $child_pid = open(TO_KID,   "|-")   // die "can't fork: $!";
3824
3825 followed by 
3826
3827     if ($child_pid) {
3828         # am the parent:
3829         # either write TO_KID or else read FROM_KID
3830         ...
3831         wait $child_pid;
3832     } else {
3833         # am the child; use STDIN/STDOUT normally
3834         ...
3835         exit;
3836     } 
3837
3838 The filehandle behaves normally for the parent, but I/O to that
3839 filehandle is piped from/to the STDOUT/STDIN of the child process.
3840 In the child process, the filehandle isn't opened--I/O happens from/to
3841 the new STDOUT/STDIN.  Typically this is used like the normal
3842 piped open when you want to exercise more control over just how the
3843 pipe command gets executed, such as when running setuid and
3844 you don't want to have to scan shell commands for metacharacters.
3845
3846 The following blocks are more or less equivalent:
3847
3848     open(FOO, "|tr '[a-z]' '[A-Z]'");
3849     open(FOO, "|-", "tr '[a-z]' '[A-Z]'");
3850     open(FOO, "|-") || exec 'tr', '[a-z]', '[A-Z]';
3851     open(FOO, "|-", "tr", '[a-z]', '[A-Z]');
3852
3853     open(FOO, "cat -n '$file'|");
3854     open(FOO, "-|", "cat -n '$file'");
3855     open(FOO, "-|") || exec "cat", "-n", $file;
3856     open(FOO, "-|", "cat", "-n", $file);
3857
3858 The last two examples in each block show the pipe as "list form", which is
3859 not yet supported on all platforms.  A good rule of thumb is that if
3860 your platform has a real C<fork()> (in other words, if your platform is
3861 Unix, including Linux and MacOS X), you can use the list form.  You would 
3862 want to use the list form of the pipe so you can pass literal arguments
3863 to the command without risk of the shell interpreting any shell metacharacters
3864 in them.  However, this also bars you from opening pipes to commands
3865 that intentionally contain shell metacharacters, such as:
3866
3867     open(FOO, "|cat -n | expand -4 | lpr")
3868         // die "Can't open pipeline to lpr: $!";
3869
3870 See L<perlipc/"Safe Pipe Opens"> for more examples of this.
3871
3872 Beginning with v5.6.0, Perl will attempt to flush all files opened for
3873 output before any operation that may do a fork, but this may not be
3874 supported on some platforms (see L<perlport>).  To be safe, you may need
3875 to set C<$|> ($AUTOFLUSH in English) or call the C<autoflush()> method
3876 of C<IO::Handle> on any open handles.
3877
3878 On systems that support a close-on-exec flag on files, the flag will
3879 be set for the newly opened file descriptor as determined by the value
3880 of C<$^F>.  See L<perlvar/$^F>.
3881
3882 Closing any piped filehandle causes the parent process to wait for the
3883 child to finish, then returns the status value in C<$?> and
3884 C<${^CHILD_ERROR_NATIVE}>.
3885
3886 The filename passed to the one- and two-argument forms of open() will
3887 have leading and trailing whitespace deleted and normal
3888 redirection characters honored.  This property, known as "magic open",
3889 can often be used to good effect.  A user could specify a filename of
3890 F<"rsh cat file |">, or you could change certain filenames as needed:
3891
3892     $filename =~ s/(.*\.gz)\s*$/gzip -dc < $1|/;
3893     open(FH, $filename) or die "Can't open $filename: $!";
3894
3895 Use the three-argument form to open a file with arbitrary weird characters in it,
3896
3897     open(FOO, "<", $file)
3898         || die "can't open < $file: $!";
3899
3900 otherwise it's necessary to protect any leading and trailing whitespace:
3901
3902     $file =~ s#^(\s)#./$1#;
3903     open(FOO, "< $file\0")
3904         || die "open failed: $!";
3905
3906 (this may not work on some bizarre filesystems).  One should
3907 conscientiously choose between the I<magic> and I<three-argument> form
3908 of open():
3909
3910     open(IN, $ARGV[0]) || die "can't open $ARGV[0]: $!";
3911
3912 will allow the user to specify an argument of the form C<"rsh cat file |">,
3913 but will not work on a filename that happens to have a trailing space, while
3914
3915     open(IN, "<", $ARGV[0])
3916         || die "can't open < $ARGV[0]: $!";
3917
3918 will have exactly the opposite restrictions.
3919
3920 If you want a "real" C C<open> (see L<open(2)> on your system), then you
3921 should use the C<sysopen> function, which involves no such magic (but may
3922 use subtly different filemodes than Perl open(), which is mapped to C
3923 fopen()).  This is another way to protect your filenames from
3924 interpretation.  For example:
3925
3926     use IO::Handle;
3927     sysopen(HANDLE, $path, O_RDWR|O_CREAT|O_EXCL)
3928         or die "sysopen $path: $!";
3929     $oldfh = select(HANDLE); $| = 1; select($oldfh);
3930     print HANDLE "stuff $$\n";
3931     seek(HANDLE, 0, 0);
3932     print "File contains: ", <HANDLE>;
3933
3934 Using the constructor from the C<IO::Handle> package (or one of its
3935 subclasses, such as C<IO::File> or C<IO::Socket>), you can generate anonymous
3936 filehandles that have the scope of the variables used to hold them, then
3937 automatically (but silently) close once their reference counts become
3938 zero, typically at scope exit:
3939
3940     use IO::File;
3941     #...
3942     sub read_myfile_munged {
3943         my $ALL = shift;
3944         # or just leave it undef to autoviv
3945         my $handle = IO::File->new;
3946         open($handle, "<", "myfile") or die "myfile: $!";
3947         $first = <$handle>
3948             or return ();     # Automatically closed here.
3949         mung($first) or die "mung failed";  # Or here.
3950         return (first, <$handle>) if $ALL;  # Or here.
3951         return $first;                      # Or here.
3952     }
3953
3954 B<WARNING:> The previous example has a bug because the automatic
3955 close that happens when the refcount on C<handle> does not
3956 properly detect and report failures.  I<Always> close the handle
3957 yourself and inspect the return value.
3958
3959     close($handle) 
3960         || warn "close failed: $!";
3961
3962 See L</seek> for some details about mixing reading and writing.
3963
3964 Portability issues: L<perlport/open>.
3965
3966 =item opendir DIRHANDLE,EXPR
3967 X<opendir>
3968
3969 Opens a directory named EXPR for processing by C<readdir>, C<telldir>,
3970 C<seekdir>, C<rewinddir>, and C<closedir>.  Returns true if successful.
3971 DIRHANDLE may be an expression whose value can be used as an indirect
3972 dirhandle, usually the real dirhandle name.  If DIRHANDLE is an undefined
3973 scalar variable (or array or hash element), the variable is assigned a
3974 reference to a new anonymous dirhandle; that is, it's autovivified.
3975 DIRHANDLEs have their own namespace separate from FILEHANDLEs.
3976
3977 See the example at C<readdir>.
3978
3979 =item ord EXPR
3980 X<ord> X<encoding>
3981
3982 =item ord
3983
3984 Returns the numeric value of the first character of EXPR.
3985 If EXPR is an empty string, returns 0.  If EXPR is omitted, uses C<$_>.
3986 (Note I<character>, not byte.)
3987
3988 For the reverse, see L</chr>.
3989 See L<perlunicode> for more about Unicode.
3990
3991 =item our EXPR
3992 X<our> X<global>
3993
3994 =item our TYPE EXPR
3995
3996 =item our EXPR : ATTRS
3997
3998 =item our TYPE EXPR : ATTRS
3999
4000 C<our> associates a simple name with a package variable in the current
4001 package for use within the current scope.  When C<use strict 'vars'> is in
4002 effect, C<our> lets you use declared global variables without qualifying
4003 them with package names, within the lexical scope of the C<our> declaration.
4004 In this way C<our> differs from C<use vars>, which is package-scoped.
4005
4006 Unlike C<my> or C<state>, which allocates storage for a variable and
4007 associates a simple name with that storage for use within the current
4008 scope, C<our> associates a simple name with a package (read: global)
4009 variable in the current package, for use within the current lexical scope.
4010 In other words, C<our> has the same scoping rules as C<my> or C<state>, but
4011 does not necessarily create a variable.
4012
4013 If more than one value is listed, the list must be placed
4014 in parentheses.
4015
4016     our $foo;
4017     our($bar, $baz);
4018
4019 An C<our> declaration declares a global variable that will be visible
4020 across its entire lexical scope, even across package boundaries.  The
4021 package in which the variable is entered is determined at the point
4022 of the declaration, not at the point of use.  This means the following
4023 behavior holds:
4024
4025     package Foo;
4026     our $bar;      # declares $Foo::bar for rest of lexical scope
4027     $bar = 20;
4028
4029     package Bar;
4030     print $bar;    # prints 20, as it refers to $Foo::bar
4031
4032 Multiple C<our> declarations with the same name in the same lexical
4033 scope are allowed if they are in different packages.  If they happen
4034 to be in the same package, Perl will emit warnings if you have asked
4035 for them, just like multiple C<my> declarations.  Unlike a second
4036 C<my> declaration, which will bind the name to a fresh variable, a
4037 second C<our> declaration in the same package, in the same scope, is
4038 merely redundant.
4039
4040     use warnings;
4041     package Foo;
4042     our $bar;      # declares $Foo::bar for rest of lexical scope
4043     $bar = 20;
4044
4045     package Bar;
4046     our $bar = 30; # declares $Bar::bar for rest of lexical scope
4047     print $bar;    # prints 30
4048
4049     our $bar;      # emits warning but has no other effect
4050     print $bar;    # still prints 30
4051
4052 An C<our> declaration may also have a list of attributes associated
4053 with it.
4054
4055 The exact semantics and interface of TYPE and ATTRS are still
4056 evolving.  TYPE is currently bound to the use of the C<fields> pragma,
4057 and attributes are handled using the C<attributes> pragma, or, starting
4058 from Perl 5.8.0, also via the C<Attribute::Handlers> module.  See
4059 L<perlsub/"Private Variables via my()"> for details, and L<fields>,
4060 L<attributes>, and L<Attribute::Handlers>.
4061
4062 =item pack TEMPLATE,LIST
4063 X<pack>
4064
4065 Takes a LIST of values and converts it into a string using the rules
4066 given by the TEMPLATE.  The resulting string is the concatenation of
4067 the converted values.  Typically, each converted value looks
4068 like its machine-level representation.  For example, on 32-bit machines
4069 an integer may be represented by a sequence of 4 bytes, which  will in
4070 Perl be presented as a string that's 4 characters long. 
4071
4072 See L<perlpacktut> for an introduction to this function.
4073
4074 The TEMPLATE is a sequence of characters that give the order and type
4075 of values, as follows:
4076
4077     a  A string with arbitrary binary data, will be null padded.
4078     A  A text (ASCII) string, will be space padded.
4079     Z  A null-terminated (ASCIZ) string, will be null padded.
4080
4081     b  A bit string (ascending bit order inside each byte,
4082        like vec()).
4083     B  A bit string (descending bit order inside each byte).
4084     h  A hex string (low nybble first).
4085     H  A hex string (high nybble first).
4086
4087     c  A signed char (8-bit) value.
4088     C  An unsigned char (octet) value.
4089     W  An unsigned char value (can be greater than 255).
4090
4091     s  A signed short (16-bit) value.
4092     S  An unsigned short value.
4093
4094     l  A signed long (32-bit) value.
4095     L  An unsigned long value.
4096
4097     q  A signed quad (64-bit) value.
4098     Q  An unsigned quad value.
4099          (Quads are available only if your system supports 64-bit
4100           integer values _and_ if Perl has been compiled to support
4101           those.  Raises an exception otherwise.)
4102
4103     i  A signed integer value.
4104     I  A unsigned integer value.
4105          (This 'integer' is _at_least_ 32 bits wide.  Its exact
4106           size depends on what a local C compiler calls 'int'.)
4107
4108     n  An unsigned short (16-bit) in "network" (big-endian) order.
4109     N  An unsigned long (32-bit) in "network" (big-endian) order.
4110     v  An unsigned short (16-bit) in "VAX" (little-endian) order.
4111     V  An unsigned long (32-bit) in "VAX" (little-endian) order.
4112
4113     j  A Perl internal signed integer value (IV).
4114     J  A Perl internal unsigned integer value (UV).
4115
4116     f  A single-precision float in native format.
4117     d  A double-precision float in native format.
4118
4119     F  A Perl internal floating-point value (NV) in native format
4120     D  A float of long-double precision in native format.
4121          (Long doubles are available only if your system supports
4122           long double values _and_ if Perl has been compiled to
4123           support those.  Raises an exception otherwise.)
4124
4125     p  A pointer to a null-terminated string.
4126     P  A pointer to a structure (fixed-length string).
4127
4128     u  A uuencoded string.
4129     U  A Unicode character number.  Encodes to a character in char-
4130        acter mode and UTF-8 (or UTF-EBCDIC in EBCDIC platforms) in
4131        byte mode.
4132
4133     w  A BER compressed integer (not an ASN.1 BER, see perlpacktut
4134        for details).  Its bytes represent an unsigned integer in
4135        base 128, most significant digit first, with as few digits
4136        as possible.  Bit eight (the high bit) is set on each byte
4137        except the last.
4138
4139     x  A null byte (a.k.a ASCII NUL, "\000", chr(0))
4140     X  Back up a byte.
4141     @  Null-fill or truncate to absolute position, counted from the
4142        start of the innermost ()-group.
4143     .  Null-fill or truncate to absolute position specified by
4144        the value.
4145     (  Start of a ()-group.
4146
4147 One or more modifiers below may optionally follow certain letters in the
4148 TEMPLATE (the second column lists letters for which the modifier is valid):
4149
4150     !   sSlLiI     Forces native (short, long, int) sizes instead
4151                    of fixed (16-/32-bit) sizes.
4152
4153         xX         Make x and X act as alignment commands.
4154
4155         nNvV       Treat integers as signed instead of unsigned.
4156
4157         @.         Specify position as byte offset in the internal
4158                    representation of the packed string.  Efficient
4159                    but dangerous.
4160
4161     >   sSiIlLqQ   Force big-endian byte-order on the type.
4162         jJfFdDpP   (The "big end" touches the construct.)
4163
4164     <   sSiIlLqQ   Force little-endian byte-order on the type.
4165         jJfFdDpP   (The "little end" touches the construct.)
4166
4167 The C<< > >> and C<< < >> modifiers can also be used on C<()> groups 
4168 to force a particular byte-order on all components in that group, 
4169 including all its subgroups.
4170
4171 The following rules apply:
4172
4173 =over 
4174
4175 =item *
4176
4177 Each letter may optionally be followed by a number indicating the repeat
4178 count.  A numeric repeat count may optionally be enclosed in brackets, as
4179 in C<pack("C[80]", @arr)>.  The repeat count gobbles that many values from
4180 the LIST when used with all format types other than C<a>, C<A>, C<Z>, C<b>,
4181 C<B>, C<h>, C<H>, C<@>, C<.>, C<x>, C<X>, and C<P>, where it means
4182 something else, described below.  Supplying a C<*> for the repeat count
4183 instead of a number means to use however many items are left, except for:
4184
4185 =over 
4186
4187 =item * 
4188
4189 C<@>, C<x>, and C<X>, where it is equivalent to C<0>.
4190
4191 =item * 
4192
4193 <.>, where it means relative to the start of the string.
4194
4195 =item * 
4196
4197 C<u>, where it is equivalent to 1 (or 45, which here is equivalent).
4198
4199 =back 
4200
4201 One can replace a numeric repeat count with a template letter enclosed in
4202 brackets to use the packed byte length of the bracketed template for the
4203 repeat count.
4204
4205 For example, the template C<x[L]> skips as many bytes as in a packed long,
4206 and the template C<"$t X[$t] $t"> unpacks twice whatever $t (when
4207 variable-expanded) unpacks.  If the template in brackets contains alignment
4208 commands (such as C<x![d]>), its packed length is calculated as if the
4209 start of the template had the maximal possible alignment.
4210
4211 When used with C<Z>, a C<*> as the repeat count is guaranteed to add a
4212 trailing null byte, so the resulting string is always one byte longer than
4213 the byte length of the item itself.
4214
4215 When used with C<@>, the repeat count represents an offset from the start
4216 of the innermost C<()> group.
4217
4218 When used with C<.>, the repeat count determines the starting position to
4219 calculate the value offset as follows:
4220
4221 =over 
4222
4223 =item *
4224
4225 If the repeat count is C<0>, it's relative to the current position.
4226
4227 =item *
4228
4229 If the repeat count is C<*>, the offset is relative to the start of the
4230 packed string.
4231
4232 =item *
4233
4234 And if it's an integer I<n>, the offset is relative to the start of the
4235 I<n>th innermost C<( )> group, or to the start of the string if I<n> is
4236 bigger then the group level.
4237
4238 =back
4239
4240 The repeat count for C<u> is interpreted as the maximal number of bytes
4241 to encode per line of output, with 0, 1 and 2 replaced by 45.  The repeat 
4242 count should not be more than 65.
4243
4244 =item *
4245
4246 The C<a>, C<A>, and C<Z> types gobble just one value, but pack it as a
4247 string of length count, padding with nulls or spaces as needed.  When
4248 unpacking, C<A> strips trailing whitespace and nulls, C<Z> strips everything
4249 after the first null, and C<a> returns data with no stripping at all.
4250
4251 If the value to pack is too long, the result is truncated.  If it's too
4252 long and an explicit count is provided, C<Z> packs only C<$count-1> bytes,
4253 followed by a null byte.  Thus C<Z> always packs a trailing null, except
4254 when the count is 0.
4255
4256 =item *
4257
4258 Likewise, the C<b> and C<B> formats pack a string that's that many bits long.
4259 Each such format generates 1 bit of the result.  These are typically followed
4260 by a repeat count like C<B8> or C<B64>.
4261
4262 Each result bit is based on the least-significant bit of the corresponding
4263 input character, i.e., on C<ord($char)%2>.  In particular, characters C<"0">
4264 and C<"1"> generate bits 0 and 1, as do characters C<"\000"> and C<"\001">.
4265
4266 Starting from the beginning of the input string, each 8-tuple
4267 of characters is converted to 1 character of output.  With format C<b>,
4268 the first character of the 8-tuple determines the least-significant bit of a
4269 character; with format C<B>, it determines the most-significant bit of
4270 a character.
4271
4272 If the length of the input string is not evenly divisible by 8, the
4273 remainder is packed as if the input string were padded by null characters
4274 at the end.  Similarly during unpacking, "extra" bits are ignored.
4275
4276 If the input string is longer than needed, remaining characters are ignored.
4277
4278 A C<*> for the repeat count uses all characters of the input field.  
4279 On unpacking, bits are converted to a string of C<0>s and C<1>s.
4280
4281 =item *
4282
4283 The C<h> and C<H> formats pack a string that many nybbles (4-bit groups,
4284 representable as hexadecimal digits, C<"0".."9"> C<"a".."f">) long.
4285
4286 For each such format, pack() generates 4 bits of result.
4287 With non-alphabetical characters, the result is based on the 4 least-significant
4288 bits of the input character, i.e., on C<ord($char)%16>.  In particular,
4289 characters C<"0"> and C<"1"> generate nybbles 0 and 1, as do bytes
4290 C<"\000"> and C<"\001">.  For characters C<"a".."f"> and C<"A".."F">, the result
4291 is compatible with the usual hexadecimal digits, so that C<"a"> and
4292 C<"A"> both generate the nybble C<0xA==10>.  Use only these specific hex 
4293 characters with this format.
4294
4295 Starting from the beginning of the template to pack(), each pair
4296 of characters is converted to 1 character of output.  With format C<h>, the
4297 first character of the pair determines the least-significant nybble of the
4298 output character; with format C<H>, it determines the most-significant
4299 nybble.
4300
4301 If the length of the input string is not even, it behaves as if padded by
4302 a null character at the end.  Similarly, "extra" nybbles are ignored during
4303 unpacking.
4304
4305 If the input string is longer than needed, extra characters are ignored.
4306
4307 A C<*> for the repeat count uses all characters of the input field.  For
4308 unpack(), nybbles are converted to a string of hexadecimal digits.
4309
4310 =item *
4311
4312 The C<p> format packs a pointer to a null-terminated string.  You are
4313 responsible for ensuring that the string is not a temporary value, as that
4314 could potentially get deallocated before you got around to using the packed
4315 result.  The C<P> format packs a pointer to a structure of the size indicated
4316 by the length.  A null pointer is created if the corresponding value for
4317 C<p> or C<P> is C<undef>; similarly with unpack(), where a null pointer
4318 unpacks into C<undef>.
4319
4320 If your system has a strange pointer size--meaning a pointer is neither as
4321 big as an int nor as big as a long--it may not be possible to pack or
4322 unpack pointers in big- or little-endian byte order.  Attempting to do
4323 so raises an exception.
4324
4325 =item *
4326
4327 The C</> template character allows packing and unpacking of a sequence of
4328 items where the packed structure contains a packed item count followed by
4329 the packed items themselves.  This is useful when the structure you're
4330 unpacking has encoded the sizes or repeat counts for some of its fields
4331 within the structure itself as separate fields.
4332
4333 For C<pack>, you write I<length-item>C</>I<sequence-item>, and the
4334 I<length-item> describes how the length value is packed.  Formats likely
4335 to be of most use are integer-packing ones like C<n> for Java strings,
4336 C<w> for ASN.1 or SNMP, and C<N> for Sun XDR.
4337
4338 For C<pack>, I<sequence-item> may have a repeat count, in which case
4339 the minimum of that and the number of available items is used as the argument
4340 for I<length-item>.  If it has no repeat count or uses a '*', the number
4341 of available items is used.
4342
4343 For C<unpack>, an internal stack of integer arguments unpacked so far is
4344 used.  You write C</>I<sequence-item> and the repeat count is obtained by
4345 popping off the last element from the stack.  The I<sequence-item> must not
4346 have a repeat count.
4347
4348 If I<sequence-item> refers to a string type (C<"A">, C<"a">, or C<"Z">),
4349 the I<length-item> is the string length, not the number of strings.  With
4350 an explicit repeat count for pack, the packed string is adjusted to that
4351 length.  For example:
4352
4353  This code:                              gives this result:
4354  
4355   unpack("W/a", "\004Gurusamy")          ("Guru")
4356   unpack("a3/A A*", "007 Bond  J ")      (" Bond", "J")
4357   unpack("a3 x2 /A A*", "007: Bond, J.") ("Bond, J", ".")
4358
4359   pack("n/a* w/a","hello,","world")     "\000\006hello,\005world"
4360   pack("a/W2", ord("a") .. ord("z"))    "2ab"
4361
4362 The I<length-item> is not returned explicitly from C<unpack>.
4363
4364 Supplying a count to the I<length-item> format letter is only useful with
4365 C<A>, C<a>, or C<Z>.  Packing with a I<length-item> of C<a> or C<Z> may
4366 introduce C<"\000"> characters, which Perl does not regard as legal in
4367 numeric strings.
4368
4369 =item *
4370
4371 The integer types C<s>, C<S>, C<l>, and C<L> may be
4372 followed by a C<!> modifier to specify native shorts or
4373 longs.  As shown in the example above, a bare C<l> means
4374 exactly 32 bits, although the native C<long> as seen by the local C compiler
4375 may be larger.  This is mainly an issue on 64-bit platforms.  You can
4376 see whether using C<!> makes any difference this way:
4377
4378     printf "format s is %d, s! is %d\n", 
4379         length pack("s"), length pack("s!");
4380
4381     printf "format l is %d, l! is %d\n", 
4382         length pack("l"), length pack("l!");
4383
4384
4385 C<i!> and C<I!> are also allowed, but only for completeness' sake:
4386 they are identical to C<i> and C<I>.
4387
4388 The actual sizes (in bytes) of native shorts, ints, longs, and long
4389 longs on the platform where Perl was built are also available from
4390 the command line:
4391
4392     $ perl -V:{short,int,long{,long}}size
4393     shortsize='2';
4394     intsize='4';
4395     longsize='4';
4396     longlongsize='8';
4397
4398 or programmatically via the C<Config> module:
4399
4400        use Config;
4401        print $Config{shortsize},    "\n";
4402        print $Config{intsize},      "\n";
4403        print $Config{longsize},     "\n";
4404        print $Config{longlongsize}, "\n";
4405
4406 C<$Config{longlongsize}> is undefined on systems without 
4407 long long support.
4408
4409 =item *
4410
4411 The integer formats C<s>, C<S>, C<i>, C<I>, C<l>, C<L>, C<j>, and C<J> are
4412 inherently non-portable between processors and operating systems because
4413 they obey native byteorder and endianness.  For example, a 4-byte integer
4414 0x12345678 (305419896 decimal) would be ordered natively (arranged in and
4415 handled by the CPU registers) into bytes as
4416
4417     0x12 0x34 0x56 0x78  # big-endian
4418     0x78 0x56 0x34 0x12  # little-endian
4419
4420 Basically, Intel and VAX CPUs are little-endian, while everybody else,
4421 including Motorola m68k/88k, PPC, Sparc, HP PA, Power, and Cray, are
4422 big-endian.  Alpha and MIPS can be either: Digital/Compaq uses (well, used) 
4423 them in little-endian mode, but SGI/Cray uses them in big-endian mode.
4424
4425 The names I<big-endian> and I<little-endian> are comic references to the
4426 egg-eating habits of the little-endian Lilliputians and the big-endian
4427 Blefuscudians from the classic Jonathan Swift satire, I<Gulliver's Travels>.
4428 This entered computer lingo via the paper "On Holy Wars and a Plea for
4429 Peace" by Danny Cohen, USC/ISI IEN 137, April 1, 1980.
4430
4431 Some systems may have even weirder byte orders such as
4432
4433    0x56 0x78 0x12 0x34
4434    0x34 0x12 0x78 0x56
4435
4436 You can determine your system endianness with this incantation:
4437
4438    printf("%#02x ", $_) for unpack("W*", pack L=>0x12345678); 
4439
4440 The byteorder on the platform where Perl was built is also available
4441 via L<Config>:
4442
4443     use Config;
4444     print "$Config{byteorder}\n";
4445
4446 or from the command line:
4447
4448     $ perl -V:byteorder
4449
4450 Byteorders C<"1234"> and C<"12345678"> are little-endian; C<"4321">
4451 and C<"87654321"> are big-endian.
4452
4453 For portably packed integers, either use the formats C<n>, C<N>, C<v>, 
4454 and C<V> or else use the C<< > >> and C<< < >> modifiers described
4455 immediately below.  See also L<perlport>.
4456
4457 =item *
4458
4459 Starting with Perl 5.9.2, integer and floating-point formats, along with
4460 the C<p> and C<P> formats and C<()> groups, may all be followed by the 
4461 C<< > >> or C<< < >> endianness modifiers to respectively enforce big-
4462 or little-endian byte-order.  These modifiers are especially useful 
4463 given how C<n>, C<N>, C<v>, and C<V> don't cover signed integers, 
4464 64-bit integers, or floating-point values.
4465
4466 Here are some concerns to keep in mind when using an endianness modifier:
4467
4468 =over
4469
4470 =item * 
4471
4472 Exchanging signed integers between different platforms works only 
4473 when all platforms store them in the same format.  Most platforms store
4474 signed integers in two's-complement notation, so usually this is not an issue.
4475
4476 =item * 
4477
4478 The C<< > >> or C<< < >> modifiers can only be used on floating-point
4479 formats on big- or little-endian machines.  Otherwise, attempting to
4480 use them raises an exception.
4481
4482 =item * 
4483
4484 Forcing big- or little-endian byte-order on floating-point values for
4485 data exchange can work only if all platforms use the same
4486 binary representation such as IEEE floating-point.  Even if all
4487 platforms are using IEEE, there may still be subtle differences.  Being able
4488 to use C<< > >> or C<< < >> on floating-point values can be useful,
4489 but also dangerous if you don't know exactly what you're doing.
4490 It is not a general way to portably store floating-point values.
4491
4492 =item * 
4493
4494 When using C<< > >> or C<< < >> on a C<()> group, this affects
4495 all types inside the group that accept byte-order modifiers,
4496 including all subgroups.  It is silently ignored for all other
4497 types.  You are not allowed to override the byte-order within a group
4498 that already has a byte-order modifier suffix.
4499
4500 =back
4501
4502 =item *
4503
4504 Real numbers (floats and doubles) are in native machine format only.
4505 Due to the multiplicity of floating-point formats and the lack of a
4506 standard "network" representation for them, no facility for interchange has been
4507 made.  This means that packed floating-point data written on one machine
4508 may not be readable on another, even if both use IEEE floating-point
4509 arithmetic (because the endianness of the memory representation is not part
4510 of the IEEE spec).  See also L<perlport>.
4511
4512 If you know I<exactly> what you're doing, you can use the C<< > >> or C<< < >>
4513 modifiers to force big- or little-endian byte-order on floating-point values.
4514
4515 Because Perl uses doubles (or long doubles, if configured) internally for
4516 all numeric calculation, converting from double into float and thence 
4517 to double again loses precision, so C<unpack("f", pack("f", $foo)>)
4518 will not in general equal $foo.
4519
4520 =item *
4521
4522 Pack and unpack can operate in two modes: character mode (C<C0> mode) where
4523 the packed string is processed per character, and UTF-8 mode (C<U0> mode)
4524 where the packed string is processed in its UTF-8-encoded Unicode form on
4525 a byte-by-byte basis.  Character mode is the default
4526 unless the format string starts with C<U>.  You
4527 can always switch mode mid-format with an explicit 
4528 C<C0> or C<U0> in the format.  This mode remains in effect until the next 
4529 mode change, or until the end of the C<()> group it (directly) applies to.
4530
4531 Using C<C0> to get Unicode characters while using C<U0> to get I<non>-Unicode 
4532 bytes is not necessarily obvious.   Probably only the first of these
4533 is what you want:
4534
4535     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4536       perl -CS -ne 'printf "%v04X\n", $_ for unpack("C0A*", $_)'
4537     03B1.03C9
4538     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4539       perl -CS -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4540     CE.B1.CF.89
4541     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4542       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("C0A*", $_)'
4543     CE.B1.CF.89
4544     $ perl -CS -E 'say "\x{3B1}\x{3C9}"' | 
4545       perl -C0 -ne 'printf "%v02X\n", $_ for unpack("U0A*", $_)'
4546     C3.8E.C2.B1.C3.8F.C2.89
4547
4548 Those examples also illustrate that you should not try to use
4549 C<pack>/C<unpack> as a substitute for the L<Encode> module.
4550
4551 =item *
4552
4553 You must yourself do any alignment or padding by inserting, for example,
4554 enough C<"x">es while packing.  There is no way for pack() and unpack()
4555 to know where characters are going to or coming from, so they 
4556 handle their output and input as flat sequences of characters.
4557
4558 =item *
4559
4560 A C<()> group is a sub-TEMPLATE enclosed in parentheses.  A group may
4561 take a repeat count either as postfix, or for unpack(), also via the C</>
4562 template character.  Within each repetition of a group, positioning with
4563 C<@> starts over at 0.  Therefore, the result of
4564
4565     pack("@1A((@2A)@3A)", qw[X Y Z])
4566
4567 is the string C<"\0X\0\0YZ">.
4568
4569 =item *
4570
4571 C<x> and C<X> accept the C<!> modifier to act as alignment commands: they
4572 jump forward or back to the closest position aligned at a multiple of C<count>
4573 characters.  For example, to pack() or unpack() a C structure like
4574
4575     struct {
4576         char   c;    /* one signed, 8-bit character */
4577         double d; 
4578         char   cc[2];
4579     }
4580
4581 one may need to use the template C<c x![d] d c[2]>.  This assumes that
4582 doubles must be aligned to the size of double.
4583
4584 For alignment commands, a C<count> of 0 is equivalent to a C<count> of 1;
4585 both are no-ops.
4586
4587 =item *
4588
4589 C<n>, C<N>, C<v> and C<V> accept the C<!> modifier to
4590 represent signed 16-/32-bit integers in big-/little-endian order.
4591 This is portable only when all platforms sharing packed data use the
4592 same binary representation for signed integers; for example, when all
4593 platforms use two's-complement representation.
4594
4595 =item *
4596
4597 Comments can be embedded in a TEMPLATE using C<#> through the end of line.
4598 White space can separate pack codes from each other, but modifiers and
4599 repeat counts must follow immediately.  Breaking complex templates into
4600 individual line-by-line components, suitably annotated, can do as much to
4601 improve legibility and maintainability of pack/unpack formats as C</x> can
4602 for complicated pattern matches.
4603
4604 =item *
4605
4606 If TEMPLATE requires more arguments than pack() is given, pack()
4607 assumes additional C<""> arguments.  If TEMPLATE requires fewer arguments
4608 than given, extra arguments are ignored.
4609
4610 =back
4611
4612 Examples:
4613
4614     $foo = pack("WWWW",65,66,67,68);
4615     # foo eq "ABCD"
4616     $foo = pack("W4",65,66,67,68);
4617     # same thing
4618     $foo = pack("W4",0x24b6,0x24b7,0x24b8,0x24b9);
4619     # same thing with Unicode circled letters.
4620     $foo = pack("U4",0x24b6,0x24b7,0x24b8,0x24b9);
4621     # same thing with Unicode circled letters.  You don't get the
4622     # UTF-8 bytes because the U at the start of the format caused
4623     # a switch to U0-mode, so the UTF-8 bytes get joined into
4624     # characters
4625     $foo = pack("C0U4",0x24b6,0x24b7,0x24b8,0x24b9);
4626     # foo eq "\xe2\x92\xb6\xe2\x92\xb7\xe2\x92\xb8\xe2\x92\xb9"
4627     # This is the UTF-8 encoding of the string in the
4628     # previous example
4629
4630     $foo = pack("ccxxcc",65,66,67,68);
4631     # foo eq "AB\0\0CD"
4632
4633     # NOTE: The examples above featuring "W" and "c" are true
4634     # only on ASCII and ASCII-derived systems such as ISO Latin 1
4635     # and UTF-8.  On EBCDIC systems, the first example would be
4636     #      $foo = pack("WWWW",193,194,195,196);
4637
4638     $foo = pack("s2",1,2);
4639     # "\001\000\002\000" on little-endian
4640     # "\000\001\000\002" on big-endian
4641
4642     $foo = pack("a4","abcd","x","y","z");
4643     # "abcd"
4644
4645     $foo = pack("aaaa","abcd","x","y","z");
4646     # "axyz"
4647
4648     $foo = pack("a14","abcdefg");
4649     # "abcdefg\0\0\0\0\0\0\0"
4650
4651     $foo = pack("i9pl", gmtime);
4652     # a real struct tm (on my system anyway)
4653
4654     $utmp_template = "Z8 Z8 Z16 L";
4655     $utmp = pack($utmp_template, @utmp1);
4656     # a struct utmp (BSDish)
4657
4658     @utmp2 = unpack($utmp_template, $utmp);
4659     # "@utmp1" eq "@utmp2"
4660
4661     sub bintodec {
4662         unpack("N", pack("B32", substr("0" x 32 . shift, -32)));
4663     }
4664
4665     $foo = pack('sx2l', 12, 34);
4666     # short 12, two zero bytes padding, long 34
4667     $bar = pack('s@4l', 12, 34);
4668     # short 12, zero fill to position 4, long 34
4669     # $foo eq $bar
4670     $baz = pack('s.l', 12, 4, 34);
4671     # short 12, zero fill to position 4, long 34
4672
4673     $foo = pack('nN', 42, 4711);
4674     # pack big-endian 16- and 32-bit unsigned integers
4675     $foo = pack('S>L>', 42, 4711);
4676     # exactly the same
4677     $foo = pack('s<l<', -42, 4711);
4678     # pack little-endian 16- and 32-bit signed integers
4679     $foo = pack('(sl)<', -42, 4711);
4680     # exactly the same
4681
4682 The same template may generally also be used in unpack().
4683
4684 =item package NAMESPACE
4685
4686 =item package NAMESPACE VERSION
4687 X<package> X<module> X<namespace> X<version>
4688
4689 =item package NAMESPACE BLOCK
4690
4691 =item package NAMESPACE VERSION BLOCK
4692 X<package> X<module> X<namespace> X<version>
4693
4694 Declares the BLOCK or the rest of the compilation unit as being in the