Bumped Math-BigInt, Math-BigInt-FastCalc and Math-BigRat versions for release per...
[perl.git] / dist / Math-BigInt / lib / Math / BigInt.pm
1 package Math::BigInt;
2
3 #
4 # "Mike had an infinite amount to do and a negative amount of time in which
5 # to do it." - Before and After
6 #
7
8 # The following hash values are used:
9 #   value: unsigned int with actual value (as a Math::BigInt::Calc or similar)
10 #   sign : +,-,NaN,+inf,-inf
11 #   _a   : accuracy
12 #   _p   : precision
13 #   _f   : flags, used by MBF to flag parts of a float as untouchable
14
15 # Remember not to take shortcuts ala $xs = $x->{value}; $CALC->foo($xs); since
16 # underlying lib might change the reference!
17
18 my $class = "Math::BigInt";
19 use 5.006002;
20
21 $VERSION = '1.99_03';
22
23 @ISA = qw(Exporter);
24 @EXPORT_OK = qw(objectify bgcd blcm); 
25
26 # _trap_inf and _trap_nan are internal and should never be accessed from the
27 # outside
28 use vars qw/$round_mode $accuracy $precision $div_scale $rnd_mode 
29             $upgrade $downgrade $_trap_nan $_trap_inf/;
30 use strict;
31
32 # Inside overload, the first arg is always an object. If the original code had
33 # it reversed (like $x = 2 * $y), then the third parameter is true.
34 # In some cases (like add, $x = $x + 2 is the same as $x = 2 + $x) this makes
35 # no difference, but in some cases it does.
36
37 # For overloaded ops with only one argument we simple use $_[0]->copy() to
38 # preserve the argument.
39
40 # Thus inheritance of overload operators becomes possible and transparent for
41 # our subclasses without the need to repeat the entire overload section there.
42
43 use overload
44 '='     =>      sub { $_[0]->copy(); },
45
46 # some shortcuts for speed (assumes that reversed order of arguments is routed
47 # to normal '+' and we thus can always modify first arg. If this is changed,
48 # this breaks and must be adjusted.)
49 '+='    =>      sub { $_[0]->badd($_[1]); },
50 '-='    =>      sub { $_[0]->bsub($_[1]); },
51 '*='    =>      sub { $_[0]->bmul($_[1]); },
52 '/='    =>      sub { scalar $_[0]->bdiv($_[1]); },
53 '%='    =>      sub { $_[0]->bmod($_[1]); },
54 '^='    =>      sub { $_[0]->bxor($_[1]); },
55 '&='    =>      sub { $_[0]->band($_[1]); },
56 '|='    =>      sub { $_[0]->bior($_[1]); },
57
58 '**='   =>      sub { $_[0]->bpow($_[1]); },
59 '<<='   =>      sub { $_[0]->blsft($_[1]); },
60 '>>='   =>      sub { $_[0]->brsft($_[1]); },
61
62 # not supported by Perl yet
63 '..'    =>      \&_pointpoint,
64
65 '<=>'   =>      sub { my $rc = $_[2] ?
66                       ref($_[0])->bcmp($_[1],$_[0]) : 
67                       $_[0]->bcmp($_[1]); 
68                       $rc = 1 unless defined $rc;
69                       $rc <=> 0;
70                 },
71 # we need '>=' to get things like "1 >= NaN" right:
72 '>='    =>      sub { my $rc = $_[2] ?
73                       ref($_[0])->bcmp($_[1],$_[0]) : 
74                       $_[0]->bcmp($_[1]);
75                       # if there was a NaN involved, return false
76                       return '' unless defined $rc;
77                       $rc >= 0;
78                 },
79 'cmp'   =>      sub {
80          $_[2] ? 
81                "$_[1]" cmp $_[0]->bstr() :
82                $_[0]->bstr() cmp "$_[1]" },
83
84 'cos'   =>      sub { $_[0]->copy->bcos(); }, 
85 'sin'   =>      sub { $_[0]->copy->bsin(); }, 
86 'atan2' =>      sub { $_[2] ?
87                         ref($_[0])->new($_[1])->batan2($_[0]) :
88                         $_[0]->copy()->batan2($_[1]) },
89
90 # are not yet overloadable
91 #'hex'  =>      sub { print "hex"; $_[0]; }, 
92 #'oct'  =>      sub { print "oct"; $_[0]; }, 
93
94 # log(N) is log(N, e), where e is Euler's number
95 'log'   =>      sub { $_[0]->copy()->blog($_[1], undef); }, 
96 'exp'   =>      sub { $_[0]->copy()->bexp($_[1]); }, 
97 'int'   =>      sub { $_[0]->copy(); }, 
98 'neg'   =>      sub { $_[0]->copy()->bneg(); }, 
99 'abs'   =>      sub { $_[0]->copy()->babs(); },
100 'sqrt'  =>      sub { $_[0]->copy()->bsqrt(); },
101 '~'     =>      sub { $_[0]->copy()->bnot(); },
102
103 # for subtract it's a bit tricky to not modify b: b-a => -a+b
104 '-'     =>      sub { my $c = $_[0]->copy; $_[2] ?
105                         $c->bneg()->badd( $_[1]) :
106                         $c->bsub( $_[1]) },
107 '+'     =>      sub { $_[0]->copy()->badd($_[1]); },
108 '*'     =>      sub { $_[0]->copy()->bmul($_[1]); },
109
110 '/'     =>      sub { 
111    $_[2] ? ref($_[0])->new($_[1])->bdiv($_[0]) : $_[0]->copy->bdiv($_[1]);
112   }, 
113 '%'     =>      sub { 
114    $_[2] ? ref($_[0])->new($_[1])->bmod($_[0]) : $_[0]->copy->bmod($_[1]);
115   }, 
116 '**'    =>      sub { 
117    $_[2] ? ref($_[0])->new($_[1])->bpow($_[0]) : $_[0]->copy->bpow($_[1]);
118   }, 
119 '<<'    =>      sub { 
120    $_[2] ? ref($_[0])->new($_[1])->blsft($_[0]) : $_[0]->copy->blsft($_[1]);
121   }, 
122 '>>'    =>      sub { 
123    $_[2] ? ref($_[0])->new($_[1])->brsft($_[0]) : $_[0]->copy->brsft($_[1]);
124   }, 
125 '&'     =>      sub { 
126    $_[2] ? ref($_[0])->new($_[1])->band($_[0]) : $_[0]->copy->band($_[1]);
127   }, 
128 '|'     =>      sub { 
129    $_[2] ? ref($_[0])->new($_[1])->bior($_[0]) : $_[0]->copy->bior($_[1]);
130   }, 
131 '^'     =>      sub { 
132    $_[2] ? ref($_[0])->new($_[1])->bxor($_[0]) : $_[0]->copy->bxor($_[1]);
133   }, 
134
135 # can modify arg of ++ and --, so avoid a copy() for speed, but don't
136 # use $_[0]->bone(), it would modify $_[0] to be 1!
137 '++'    =>      sub { $_[0]->binc() },
138 '--'    =>      sub { $_[0]->bdec() },
139
140 # if overloaded, O(1) instead of O(N) and twice as fast for small numbers
141 'bool'  =>      sub {
142   # this kludge is needed for perl prior 5.6.0 since returning 0 here fails :-/
143   # v5.6.1 dumps on this: return !$_[0]->is_zero() || undef;                :-(
144   my $t = undef;
145   $t = 1 if !$_[0]->is_zero();
146   $t;
147   },
148
149 # the original qw() does not work with the TIESCALAR below, why?
150 # Order of arguments unsignificant
151 '""' => sub { $_[0]->bstr(); },
152 '0+' => sub { $_[0]->numify(); }
153 ;
154
155 ##############################################################################
156 # global constants, flags and accessory
157
158 # These vars are public, but their direct usage is not recommended, use the
159 # accessor methods instead
160
161 $round_mode = 'even'; # one of 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
162 $accuracy   = undef;
163 $precision  = undef;
164 $div_scale  = 40;
165
166 $upgrade = undef;                       # default is no upgrade
167 $downgrade = undef;                     # default is no downgrade
168
169 # These are internally, and not to be used from the outside at all
170
171 $_trap_nan = 0;                         # are NaNs ok? set w/ config()
172 $_trap_inf = 0;                         # are infs ok? set w/ config()
173 my $nan = 'NaN';                        # constants for easier life
174
175 my $CALC = 'Math::BigInt::FastCalc';    # module to do the low level math
176                                         # default is FastCalc.pm
177 my $IMPORT = 0;                         # was import() called yet?
178                                         # used to make require work
179 my %WARN;                               # warn only once for low-level libs
180 my %CAN;                                # cache for $CALC->can(...)
181 my %CALLBACKS;                          # callbacks to notify on lib loads
182 my $EMU_LIB = 'Math/BigInt/CalcEmu.pm'; # emulate low-level math
183
184 ##############################################################################
185 # the old code had $rnd_mode, so we need to support it, too
186
187 $rnd_mode   = 'even';
188 sub TIESCALAR  { my ($class) = @_; bless \$round_mode, $class; }
189 sub FETCH      { return $round_mode; }
190 sub STORE      { $rnd_mode = $_[0]->round_mode($_[1]); }
191
192 BEGIN
193   { 
194   # tie to enable $rnd_mode to work transparently
195   tie $rnd_mode, 'Math::BigInt'; 
196
197   # set up some handy alias names
198   *as_int = \&as_number;
199   *is_pos = \&is_positive;
200   *is_neg = \&is_negative;
201   }
202
203 ############################################################################## 
204
205 sub round_mode
206   {
207   no strict 'refs';
208   # make Class->round_mode() work
209   my $self = shift;
210   my $class = ref($self) || $self || __PACKAGE__;
211   if (defined $_[0])
212     {
213     my $m = shift;
214     if ($m !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
215       {
216       require Carp; Carp::croak ("Unknown round mode '$m'");
217       }
218     return ${"${class}::round_mode"} = $m;
219     }
220   ${"${class}::round_mode"};
221   }
222
223 sub upgrade
224   {
225   no strict 'refs';
226   # make Class->upgrade() work
227   my $self = shift;
228   my $class = ref($self) || $self || __PACKAGE__;
229   # need to set new value?
230   if (@_ > 0)
231     {
232     return ${"${class}::upgrade"} = $_[0];
233     }
234   ${"${class}::upgrade"};
235   }
236
237 sub downgrade
238   {
239   no strict 'refs';
240   # make Class->downgrade() work
241   my $self = shift;
242   my $class = ref($self) || $self || __PACKAGE__;
243   # need to set new value?
244   if (@_ > 0)
245     {
246     return ${"${class}::downgrade"} = $_[0];
247     }
248   ${"${class}::downgrade"};
249   }
250
251 sub div_scale
252   {
253   no strict 'refs';
254   # make Class->div_scale() work
255   my $self = shift;
256   my $class = ref($self) || $self || __PACKAGE__;
257   if (defined $_[0])
258     {
259     if ($_[0] < 0)
260       {
261       require Carp; Carp::croak ('div_scale must be greater than zero');
262       }
263     ${"${class}::div_scale"} = $_[0];
264     }
265   ${"${class}::div_scale"};
266   }
267
268 sub accuracy
269   {
270   # $x->accuracy($a);           ref($x) $a
271   # $x->accuracy();             ref($x)
272   # Class->accuracy();          class
273   # Class->accuracy($a);        class $a
274
275   my $x = shift;
276   my $class = ref($x) || $x || __PACKAGE__;
277
278   no strict 'refs';
279   # need to set new value?
280   if (@_ > 0)
281     {
282     my $a = shift;
283     # convert objects to scalars to avoid deep recursion. If object doesn't
284     # have numify(), then hopefully it will have overloading for int() and
285     # boolean test without wandering into a deep recursion path...
286     $a = $a->numify() if ref($a) && $a->can('numify');
287
288     if (defined $a)
289       {
290       # also croak on non-numerical
291       if (!$a || $a <= 0)
292         {
293         require Carp;
294         Carp::croak ('Argument to accuracy must be greater than zero');
295         }
296       if (int($a) != $a)
297         {
298         require Carp;
299         Carp::croak ('Argument to accuracy must be an integer');
300         }
301       }
302     if (ref($x))
303       {
304       # $object->accuracy() or fallback to global
305       $x->bround($a) if $a;             # not for undef, 0
306       $x->{_a} = $a;                    # set/overwrite, even if not rounded
307       delete $x->{_p};                  # clear P
308       $a = ${"${class}::accuracy"} unless defined $a;   # proper return value
309       }
310     else
311       {
312       ${"${class}::accuracy"} = $a;     # set global A
313       ${"${class}::precision"} = undef; # clear global P
314       }
315     return $a;                          # shortcut
316     }
317
318   my $a;
319   # $object->accuracy() or fallback to global
320   $a = $x->{_a} if ref($x);
321   # but don't return global undef, when $x's accuracy is 0!
322   $a = ${"${class}::accuracy"} if !defined $a;
323   $a;
324   }
325
326 sub precision
327   {
328   # $x->precision($p);          ref($x) $p
329   # $x->precision();            ref($x)
330   # Class->precision();         class
331   # Class->precision($p);       class $p
332
333   my $x = shift;
334   my $class = ref($x) || $x || __PACKAGE__;
335
336   no strict 'refs';
337   if (@_ > 0)
338     {
339     my $p = shift;
340     # convert objects to scalars to avoid deep recursion. If object doesn't
341     # have numify(), then hopefully it will have overloading for int() and
342     # boolean test without wandering into a deep recursion path...
343     $p = $p->numify() if ref($p) && $p->can('numify');
344     if ((defined $p) && (int($p) != $p))
345       {
346       require Carp; Carp::croak ('Argument to precision must be an integer');
347       }
348     if (ref($x))
349       {
350       # $object->precision() or fallback to global
351       $x->bfround($p) if $p;            # not for undef, 0
352       $x->{_p} = $p;                    # set/overwrite, even if not rounded
353       delete $x->{_a};                  # clear A
354       $p = ${"${class}::precision"} unless defined $p;  # proper return value
355       }
356     else
357       {
358       ${"${class}::precision"} = $p;    # set global P
359       ${"${class}::accuracy"} = undef;  # clear global A
360       }
361     return $p;                          # shortcut
362     }
363
364   my $p;
365   # $object->precision() or fallback to global
366   $p = $x->{_p} if ref($x);
367   # but don't return global undef, when $x's precision is 0!
368   $p = ${"${class}::precision"} if !defined $p;
369   $p;
370   }
371
372 sub config
373   {
374   # return (or set) configuration data as hash ref
375   my $class = shift || 'Math::BigInt';
376
377   no strict 'refs';
378   if (@_ > 1 || (@_ == 1 && (ref($_[0]) eq 'HASH')))
379     {
380     # try to set given options as arguments from hash
381
382     my $args = $_[0];
383     if (ref($args) ne 'HASH')
384       {
385       $args = { @_ };
386       }
387     # these values can be "set"
388     my $set_args = {};
389     foreach my $key (
390      qw/trap_inf trap_nan
391         upgrade downgrade precision accuracy round_mode div_scale/
392      )
393       {
394       $set_args->{$key} = $args->{$key} if exists $args->{$key};
395       delete $args->{$key};
396       }
397     if (keys %$args > 0)
398       {
399       require Carp;
400       Carp::croak ("Illegal key(s) '",
401        join("','",keys %$args),"' passed to $class\->config()");
402       }
403     foreach my $key (keys %$set_args)
404       {
405       if ($key =~ /^trap_(inf|nan)\z/)
406         {
407         ${"${class}::_trap_$1"} = ($set_args->{"trap_$1"} ? 1 : 0);
408         next;
409         }
410       # use a call instead of just setting the $variable to check argument
411       $class->$key($set_args->{$key});
412       }
413     }
414
415   # now return actual configuration
416
417   my $cfg = {
418     lib => $CALC,
419     lib_version => ${"${CALC}::VERSION"},
420     class => $class,
421     trap_nan => ${"${class}::_trap_nan"},
422     trap_inf => ${"${class}::_trap_inf"},
423     version => ${"${class}::VERSION"},
424     };
425   foreach my $key (qw/
426      upgrade downgrade precision accuracy round_mode div_scale
427      /)
428     {
429     $cfg->{$key} = ${"${class}::$key"};
430     };
431   if (@_ == 1 && (ref($_[0]) ne 'HASH'))
432     {
433     # calls of the style config('lib') return just this value
434     return $cfg->{$_[0]};
435     }
436   $cfg;
437   }
438
439 sub _scale_a
440   { 
441   # select accuracy parameter based on precedence,
442   # used by bround() and bfround(), may return undef for scale (means no op)
443   my ($x,$scale,$mode) = @_;
444
445   $scale = $x->{_a} unless defined $scale;
446
447   no strict 'refs';
448   my $class = ref($x);
449
450   $scale = ${ $class . '::accuracy' } unless defined $scale;
451   $mode = ${ $class . '::round_mode' } unless defined $mode;
452
453   if (defined $scale)
454     {
455     $scale = $scale->can('numify') ? $scale->numify() : "$scale" if ref($scale);
456     $scale = int($scale);
457     }
458
459   ($scale,$mode);
460   }
461
462 sub _scale_p
463   { 
464   # select precision parameter based on precedence,
465   # used by bround() and bfround(), may return undef for scale (means no op)
466   my ($x,$scale,$mode) = @_;
467   
468   $scale = $x->{_p} unless defined $scale;
469
470   no strict 'refs';
471   my $class = ref($x);
472
473   $scale = ${ $class . '::precision' } unless defined $scale;
474   $mode = ${ $class . '::round_mode' } unless defined $mode;
475
476   if (defined $scale)
477     {
478     $scale = $scale->can('numify') ? $scale->numify() : "$scale" if ref($scale);
479     $scale = int($scale);
480     }
481
482   ($scale,$mode);
483   }
484
485 ##############################################################################
486 # constructors
487
488 sub copy
489   {
490   # if two arguments, the first one is the class to "swallow" subclasses
491   if (@_ > 1)
492     {
493     my  $self = bless {
494         sign => $_[1]->{sign}, 
495         value => $CALC->_copy($_[1]->{value}),
496     }, $_[0] if @_ > 1;
497
498     $self->{_a} = $_[1]->{_a} if defined $_[1]->{_a};
499     $self->{_p} = $_[1]->{_p} if defined $_[1]->{_p};
500     return $self;
501     }
502
503   my $self = bless {
504         sign => $_[0]->{sign}, 
505         value => $CALC->_copy($_[0]->{value}),
506         }, ref($_[0]);
507
508   $self->{_a} = $_[0]->{_a} if defined $_[0]->{_a};
509   $self->{_p} = $_[0]->{_p} if defined $_[0]->{_p};
510   $self;
511   }
512
513 sub new 
514   {
515   # create a new BigInt object from a string or another BigInt object. 
516   # see hash keys documented at top
517
518   # the argument could be an object, so avoid ||, && etc on it, this would
519   # cause costly overloaded code to be called. The only allowed ops are
520   # ref() and defined.
521
522   my ($class,$wanted,$a,$p,$r) = @_;
523  
524   # avoid numify-calls by not using || on $wanted!
525   return $class->bzero($a,$p) if !defined $wanted;      # default to 0
526   return $class->copy($wanted,$a,$p,$r)
527    if ref($wanted) && $wanted->isa($class);             # MBI or subclass
528
529   $class->import() if $IMPORT == 0;             # make require work
530   
531   my $self = bless {}, $class;
532
533   # shortcut for "normal" numbers
534   if ((!ref $wanted) && ($wanted =~ /^([+-]?)[1-9][0-9]*\z/))
535     {
536     $self->{sign} = $1 || '+';
537
538     if ($wanted =~ /^[+-]/)
539      {
540       # remove sign without touching wanted to make it work with constants
541       my $t = $wanted; $t =~ s/^[+-]//;
542       $self->{value} = $CALC->_new($t);
543       }
544     else
545       {
546       $self->{value} = $CALC->_new($wanted);
547       }
548     no strict 'refs';
549     if ( (defined $a) || (defined $p) 
550         || (defined ${"${class}::precision"})
551         || (defined ${"${class}::accuracy"}) 
552        )
553       {
554       $self->round($a,$p,$r) unless (@_ == 4 && !defined $a && !defined $p);
555       }
556     return $self;
557     }
558
559   # handle '+inf', '-inf' first
560   if ($wanted =~ /^[+-]?inf\z/)
561     {
562     $self->{sign} = $wanted;            # set a default sign for bstr()
563     return $self->binf($wanted);
564     }
565   # split str in m mantissa, e exponent, i integer, f fraction, v value, s sign
566   my ($mis,$miv,$mfv,$es,$ev) = _split($wanted);
567   if (!ref $mis)
568     {
569     if ($_trap_nan)
570       {
571       require Carp; Carp::croak("$wanted is not a number in $class");
572       }
573     $self->{value} = $CALC->_zero();
574     $self->{sign} = $nan;
575     return $self;
576     }
577   if (!ref $miv)
578     {
579     # _from_hex or _from_bin
580     $self->{value} = $mis->{value};
581     $self->{sign} = $mis->{sign};
582     return $self;       # throw away $mis
583     }
584   # make integer from mantissa by adjusting exp, then convert to bigint
585   $self->{sign} = $$mis;                        # store sign
586   $self->{value} = $CALC->_zero();              # for all the NaN cases
587   my $e = int("$$es$$ev");                      # exponent (avoid recursion)
588   if ($e > 0)
589     {
590     my $diff = $e - CORE::length($$mfv);
591     if ($diff < 0)                              # Not integer
592       {
593       if ($_trap_nan)
594         {
595         require Carp; Carp::croak("$wanted not an integer in $class");
596         }
597       #print "NOI 1\n";
598       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
599       $self->{sign} = $nan;
600       }
601     else                                        # diff >= 0
602       {
603       # adjust fraction and add it to value
604       #print "diff > 0 $$miv\n";
605       $$miv = $$miv . ($$mfv . '0' x $diff);
606       }
607     }
608   else
609     {
610     if ($$mfv ne '')                            # e <= 0
611       {
612       # fraction and negative/zero E => NOI
613       if ($_trap_nan)
614         {
615         require Carp; Carp::croak("$wanted not an integer in $class");
616         }
617       #print "NOI 2 \$\$mfv '$$mfv'\n";
618       return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
619       $self->{sign} = $nan;
620       }
621     elsif ($e < 0)
622       {
623       # xE-y, and empty mfv
624       #print "xE-y\n";
625       $e = abs($e);
626       if ($$miv !~ s/0{$e}$//)          # can strip so many zero's?
627         {
628         if ($_trap_nan)
629           {
630           require Carp; Carp::croak("$wanted not an integer in $class");
631           }
632         #print "NOI 3\n";
633         return $upgrade->new($wanted,$a,$p,$r) if defined $upgrade;
634         $self->{sign} = $nan;
635         }
636       }
637     }
638   $self->{sign} = '+' if $$miv eq '0';                  # normalize -0 => +0
639   $self->{value} = $CALC->_new($$miv) if $self->{sign} =~ /^[+-]$/;
640   # if any of the globals is set, use them to round and store them inside $self
641   # do not round for new($x,undef,undef) since that is used by MBF to signal
642   # no rounding
643   $self->round($a,$p,$r) unless @_ == 4 && !defined $a && !defined $p;
644   $self;
645   }
646
647 sub bnan
648   {
649   # create a bigint 'NaN', if given a BigInt, set it to 'NaN'
650   my $self = shift;
651   $self = $class if !defined $self;
652   if (!ref($self))
653     {
654     my $c = $self; $self = {}; bless $self, $c;
655     }
656   no strict 'refs';
657   if (${"${class}::_trap_nan"})
658     {
659     require Carp;
660     Carp::croak ("Tried to set $self to NaN in $class\::bnan()");
661     }
662   $self->import() if $IMPORT == 0;              # make require work
663   return if $self->modify('bnan');
664   if ($self->can('_bnan'))
665     {
666     # use subclass to initialize
667     $self->_bnan();
668     }
669   else
670     {
671     # otherwise do our own thing
672     $self->{value} = $CALC->_zero();
673     }
674   $self->{sign} = $nan;
675   delete $self->{_a}; delete $self->{_p};       # rounding NaN is silly
676   $self;
677   }
678
679 sub binf
680   {
681   # create a bigint '+-inf', if given a BigInt, set it to '+-inf'
682   # the sign is either '+', or if given, used from there
683   my $self = shift;
684   my $sign = shift; $sign = '+' if !defined $sign || $sign !~ /^-(inf)?$/;
685   $self = $class if !defined $self;
686   if (!ref($self))
687     {
688     my $c = $self; $self = {}; bless $self, $c;
689     }
690   no strict 'refs';
691   if (${"${class}::_trap_inf"})
692     {
693     require Carp;
694     Carp::croak ("Tried to set $self to +-inf in $class\::binf()");
695     }
696   $self->import() if $IMPORT == 0;              # make require work
697   return if $self->modify('binf');
698   if ($self->can('_binf'))
699     {
700     # use subclass to initialize
701     $self->_binf();
702     }
703   else
704     {
705     # otherwise do our own thing
706     $self->{value} = $CALC->_zero();
707     }
708   $sign = $sign . 'inf' if $sign !~ /inf$/;     # - => -inf
709   $self->{sign} = $sign;
710   ($self->{_a},$self->{_p}) = @_;               # take over requested rounding
711   $self;
712   }
713
714 sub bzero
715   {
716   # create a bigint '+0', if given a BigInt, set it to 0
717   my $self = shift;
718   $self = __PACKAGE__ if !defined $self;
719  
720   if (!ref($self))
721     {
722     my $c = $self; $self = {}; bless $self, $c;
723     }
724   $self->import() if $IMPORT == 0;              # make require work
725   return if $self->modify('bzero');
726   
727   if ($self->can('_bzero'))
728     {
729     # use subclass to initialize
730     $self->_bzero();
731     }
732   else
733     {
734     # otherwise do our own thing
735     $self->{value} = $CALC->_zero();
736     }
737   $self->{sign} = '+';
738   if (@_ > 0)
739     {
740     if (@_ > 3)
741       {
742       # call like: $x->bzero($a,$p,$r,$y);
743       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
744       }
745     else
746       {
747       $self->{_a} = $_[0]
748        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
749       $self->{_p} = $_[1]
750        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
751       }
752     }
753   $self;
754   }
755
756 sub bone
757   {
758   # create a bigint '+1' (or -1 if given sign '-'),
759   # if given a BigInt, set it to +1 or -1, respectively
760   my $self = shift;
761   my $sign = shift; $sign = '+' if !defined $sign || $sign ne '-';
762   $self = $class if !defined $self;
763
764   if (!ref($self))
765     {
766     my $c = $self; $self = {}; bless $self, $c;
767     }
768   $self->import() if $IMPORT == 0;              # make require work
769   return if $self->modify('bone');
770
771   if ($self->can('_bone'))
772     {
773     # use subclass to initialize
774     $self->_bone();
775     }
776   else
777     {
778     # otherwise do our own thing
779     $self->{value} = $CALC->_one();
780     }
781   $self->{sign} = $sign;
782   if (@_ > 0)
783     {
784     if (@_ > 3)
785       {
786       # call like: $x->bone($sign,$a,$p,$r,$y);
787       ($self,$self->{_a},$self->{_p}) = $self->_find_round_parameters(@_);
788       }
789     else
790       {
791       # call like: $x->bone($sign,$a,$p,$r);
792       $self->{_a} = $_[0]
793        if ( (!defined $self->{_a}) || (defined $_[0] && $_[0] > $self->{_a}));
794       $self->{_p} = $_[1]
795        if ( (!defined $self->{_p}) || (defined $_[1] && $_[1] > $self->{_p}));
796       }
797     }
798   $self;
799   }
800
801 ##############################################################################
802 # string conversion
803
804 sub bsstr
805   {
806   # (ref to BFLOAT or num_str ) return num_str
807   # Convert number from internal format to scientific string format.
808   # internal format is always normalized (no leading zeros, "-0E0" => "+0E0")
809   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_); 
810
811   if ($x->{sign} !~ /^[+-]$/)
812     {
813     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
814     return 'inf';                                       # +inf
815     }
816   my ($m,$e) = $x->parts();
817   #$m->bstr() . 'e+' . $e->bstr();      # e can only be positive in BigInt
818   # 'e+' because E can only be positive in BigInt
819   $m->bstr() . 'e+' . $CALC->_str($e->{value}); 
820   }
821
822 sub bstr 
823   {
824   # make a string from bigint object
825   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_); 
826
827   if ($x->{sign} !~ /^[+-]$/)
828     {
829     return $x->{sign} unless $x->{sign} eq '+inf';      # -inf, NaN
830     return 'inf';                                       # +inf
831     }
832   my $es = ''; $es = $x->{sign} if $x->{sign} eq '-';
833   $es.$CALC->_str($x->{value});
834   }
835
836 sub numify 
837   {
838   # Make a "normal" scalar from a BigInt object
839   my $x = shift; $x = $class->new($x) unless ref $x;
840
841   return $x->bstr() if $x->{sign} !~ /^[+-]$/;
842   my $num = $CALC->_num($x->{value});
843   return -$num if $x->{sign} eq '-';
844   $num;
845   }
846
847 ##############################################################################
848 # public stuff (usually prefixed with "b")
849
850 sub sign
851   {
852   # return the sign of the number: +/-/-inf/+inf/NaN
853   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_); 
854   
855   $x->{sign};
856   }
857
858 sub _find_round_parameters
859   {
860   # After any operation or when calling round(), the result is rounded by
861   # regarding the A & P from arguments, local parameters, or globals.
862
863   # !!!!!!! If you change this, remember to change round(), too! !!!!!!!!!!
864
865   # This procedure finds the round parameters, but it is for speed reasons
866   # duplicated in round. Otherwise, it is tested by the testsuite and used
867   # by fdiv().
868  
869   # returns ($self) or ($self,$a,$p,$r) - sets $self to NaN of both A and P
870   # were requested/defined (locally or globally or both)
871   
872   my ($self,$a,$p,$r,@args) = @_;
873   # $a accuracy, if given by caller
874   # $p precision, if given by caller
875   # $r round_mode, if given by caller
876   # @args all 'other' arguments (0 for unary, 1 for binary ops)
877
878   my $c = ref($self);                           # find out class of argument(s)
879   no strict 'refs';
880
881   # convert to normal scalar for speed and correctness in inner parts
882   $a = $a->can('numify') ? $a->numify() : "$a" if defined $a && ref($a);
883   $p = $p->can('numify') ? $p->numify() : "$p" if defined $p && ref($p);
884
885   # now pick $a or $p, but only if we have got "arguments"
886   if (!defined $a)
887     {
888     foreach ($self,@args)
889       {
890       # take the defined one, or if both defined, the one that is smaller
891       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
892       }
893     }
894   if (!defined $p)
895     {
896     # even if $a is defined, take $p, to signal error for both defined
897     foreach ($self,@args)
898       {
899       # take the defined one, or if both defined, the one that is bigger
900       # -2 > -3, and 3 > 2
901       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
902       }
903     }
904   # if still none defined, use globals (#2)
905   $a = ${"$c\::accuracy"} unless defined $a;
906   $p = ${"$c\::precision"} unless defined $p;
907
908   # A == 0 is useless, so undef it to signal no rounding
909   $a = undef if defined $a && $a == 0;
910  
911   # no rounding today? 
912   return ($self) unless defined $a || defined $p;               # early out
913
914   # set A and set P is an fatal error
915   return ($self->bnan()) if defined $a && defined $p;           # error
916
917   $r = ${"$c\::round_mode"} unless defined $r;
918   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
919     {
920     require Carp; Carp::croak ("Unknown round mode '$r'");
921     }
922
923   $a = int($a) if defined $a;
924   $p = int($p) if defined $p;
925
926   ($self,$a,$p,$r);
927   }
928
929 sub round
930   {
931   # Round $self according to given parameters, or given second argument's
932   # parameters or global defaults 
933
934   # for speed reasons, _find_round_parameters is embedded here:
935
936   my ($self,$a,$p,$r,@args) = @_;
937   # $a accuracy, if given by caller
938   # $p precision, if given by caller
939   # $r round_mode, if given by caller
940   # @args all 'other' arguments (0 for unary, 1 for binary ops)
941
942   my $c = ref($self);                           # find out class of argument(s)
943   no strict 'refs';
944
945   # now pick $a or $p, but only if we have got "arguments"
946   if (!defined $a)
947     {
948     foreach ($self,@args)
949       {
950       # take the defined one, or if both defined, the one that is smaller
951       $a = $_->{_a} if (defined $_->{_a}) && (!defined $a || $_->{_a} < $a);
952       }
953     }
954   if (!defined $p)
955     {
956     # even if $a is defined, take $p, to signal error for both defined
957     foreach ($self,@args)
958       {
959       # take the defined one, or if both defined, the one that is bigger
960       # -2 > -3, and 3 > 2
961       $p = $_->{_p} if (defined $_->{_p}) && (!defined $p || $_->{_p} > $p);
962       }
963     }
964   # if still none defined, use globals (#2)
965   $a = ${"$c\::accuracy"} unless defined $a;
966   $p = ${"$c\::precision"} unless defined $p;
967  
968   # A == 0 is useless, so undef it to signal no rounding
969   $a = undef if defined $a && $a == 0;
970   
971   # no rounding today? 
972   return $self unless defined $a || defined $p;         # early out
973
974   # set A and set P is an fatal error
975   return $self->bnan() if defined $a && defined $p;
976
977   $r = ${"$c\::round_mode"} unless defined $r;
978   if ($r !~ /^(even|odd|\+inf|\-inf|zero|trunc|common)$/)
979     {
980     require Carp; Carp::croak ("Unknown round mode '$r'");
981     }
982
983   # now round, by calling either fround or ffround:
984   if (defined $a)
985     {
986     $self->bround(int($a),$r) if !defined $self->{_a} || $self->{_a} >= $a;
987     }
988   else # both can't be undefined due to early out
989     {
990     $self->bfround(int($p),$r) if !defined $self->{_p} || $self->{_p} <= $p;
991     }
992   # bround() or bfround() already called bnorm() if nec.
993   $self;
994   }
995
996 sub bnorm
997   { 
998   # (numstr or BINT) return BINT
999   # Normalize number -- no-op here
1000   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1001   $x;
1002   }
1003
1004 sub babs 
1005   {
1006   # (BINT or num_str) return BINT
1007   # make number absolute, or return absolute BINT from string
1008   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1009
1010   return $x if $x->modify('babs');
1011   # post-normalized abs for internal use (does nothing for NaN)
1012   $x->{sign} =~ s/^-/+/;
1013   $x;
1014   }
1015
1016 sub bneg 
1017   { 
1018   # (BINT or num_str) return BINT
1019   # negate number or make a negated number from string
1020   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1021   
1022   return $x if $x->modify('bneg');
1023
1024   # for +0 dont negate (to have always normalized +0). Does nothing for 'NaN'
1025   $x->{sign} =~ tr/+-/-+/ unless ($x->{sign} eq '+' && $CALC->_is_zero($x->{value}));
1026   $x;
1027   }
1028
1029 sub bcmp 
1030   {
1031   # Compares 2 values.  Returns one of undef, <0, =0, >0. (suitable for sort)
1032   # (BINT or num_str, BINT or num_str) return cond_code
1033   
1034   # set up parameters
1035   my ($self,$x,$y) = (ref($_[0]),@_);
1036
1037   # objectify is costly, so avoid it 
1038   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1039     {
1040     ($self,$x,$y) = objectify(2,@_);
1041     }
1042
1043   return $upgrade->bcmp($x,$y) if defined $upgrade &&
1044     ((!$x->isa($self)) || (!$y->isa($self)));
1045
1046   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1047     {
1048     # handle +-inf and NaN
1049     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1050     return 0 if $x->{sign} eq $y->{sign} && $x->{sign} =~ /^[+-]inf$/;
1051     return +1 if $x->{sign} eq '+inf';
1052     return -1 if $x->{sign} eq '-inf';
1053     return -1 if $y->{sign} eq '+inf';
1054     return +1;
1055     }
1056   # check sign for speed first
1057   return 1 if $x->{sign} eq '+' && $y->{sign} eq '-';   # does also 0 <=> -y
1058   return -1 if $x->{sign} eq '-' && $y->{sign} eq '+';  # does also -x <=> 0 
1059
1060   # have same sign, so compare absolute values. Don't make tests for zero here
1061   # because it's actually slower than testin in Calc (especially w/ Pari et al)
1062
1063   # post-normalized compare for internal use (honors signs)
1064   if ($x->{sign} eq '+') 
1065     {
1066     # $x and $y both > 0
1067     return $CALC->_acmp($x->{value},$y->{value});
1068     }
1069
1070   # $x && $y both < 0
1071   $CALC->_acmp($y->{value},$x->{value});        # swaped acmp (lib returns 0,1,-1)
1072   }
1073
1074 sub bacmp 
1075   {
1076   # Compares 2 values, ignoring their signs. 
1077   # Returns one of undef, <0, =0, >0. (suitable for sort)
1078   # (BINT, BINT) return cond_code
1079   
1080   # set up parameters
1081   my ($self,$x,$y) = (ref($_[0]),@_);
1082   # objectify is costly, so avoid it 
1083   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1084     {
1085     ($self,$x,$y) = objectify(2,@_);
1086     }
1087
1088   return $upgrade->bacmp($x,$y) if defined $upgrade &&
1089     ((!$x->isa($self)) || (!$y->isa($self)));
1090
1091   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1092     {
1093     # handle +-inf and NaN
1094     return undef if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1095     return 0 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} =~ /^[+-]inf$/;
1096     return 1 if $x->{sign} =~ /^[+-]inf$/ && $y->{sign} !~ /^[+-]inf$/;
1097     return -1;
1098     }
1099   $CALC->_acmp($x->{value},$y->{value});        # lib does only 0,1,-1
1100   }
1101
1102 sub badd 
1103   {
1104   # add second arg (BINT or string) to first (BINT) (modifies first)
1105   # return result as BINT
1106
1107   # set up parameters
1108   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1109   # objectify is costly, so avoid it 
1110   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1111     {
1112     ($self,$x,$y,@r) = objectify(2,@_);
1113     }
1114
1115   return $x if $x->modify('badd');
1116   return $upgrade->badd($upgrade->new($x),$upgrade->new($y),@r) if defined $upgrade &&
1117     ((!$x->isa($self)) || (!$y->isa($self)));
1118
1119   $r[3] = $y;                           # no push!
1120   # inf and NaN handling
1121   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/))
1122     {
1123     # NaN first
1124     return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1125     # inf handling
1126     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1127       {
1128       # +inf++inf or -inf+-inf => same, rest is NaN
1129       return $x if $x->{sign} eq $y->{sign};
1130       return $x->bnan();
1131       }
1132     # +-inf + something => +inf
1133     # something +-inf => +-inf
1134     $x->{sign} = $y->{sign}, return $x if $y->{sign} =~ /^[+-]inf$/;
1135     return $x;
1136     }
1137     
1138   my ($sx, $sy) = ( $x->{sign}, $y->{sign} );           # get signs
1139
1140   if ($sx eq $sy)  
1141     {
1142     $x->{value} = $CALC->_add($x->{value},$y->{value}); # same sign, abs add
1143     }
1144   else 
1145     {
1146     my $a = $CALC->_acmp ($y->{value},$x->{value});     # absolute compare
1147     if ($a > 0)                           
1148       {
1149       $x->{value} = $CALC->_sub($y->{value},$x->{value},1); # abs sub w/ swap
1150       $x->{sign} = $sy;
1151       } 
1152     elsif ($a == 0)
1153       {
1154       # speedup, if equal, set result to 0
1155       $x->{value} = $CALC->_zero();
1156       $x->{sign} = '+';
1157       }
1158     else # a < 0
1159       {
1160       $x->{value} = $CALC->_sub($x->{value}, $y->{value}); # abs sub
1161       }
1162     }
1163   $x->round(@r);
1164   }
1165
1166 sub bsub 
1167   {
1168   # (BINT or num_str, BINT or num_str) return BINT
1169   # subtract second arg from first, modify first
1170   
1171   # set up parameters
1172   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1173
1174   # objectify is costly, so avoid it
1175   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1176     {
1177     ($self,$x,$y,@r) = objectify(2,@_);
1178     }
1179
1180   return $x if $x->modify('bsub');
1181
1182   return $upgrade->new($x)->bsub($upgrade->new($y),@r) if defined $upgrade &&
1183    ((!$x->isa($self)) || (!$y->isa($self)));
1184
1185   return $x->round(@r) if $y->is_zero();
1186
1187   # To correctly handle the lone special case $x->bsub($x), we note the sign
1188   # of $x, then flip the sign from $y, and if the sign of $x did change, too,
1189   # then we caught the special case:
1190   my $xsign = $x->{sign};
1191   $y->{sign} =~ tr/+\-/-+/;     # does nothing for NaN
1192   if ($xsign ne $x->{sign})
1193     {
1194     # special case of $x->bsub($x) results in 0
1195     return $x->bzero(@r) if $xsign =~ /^[+-]$/;
1196     return $x->bnan();          # NaN, -inf, +inf
1197     }
1198   $x->badd($y,@r);              # badd does not leave internal zeros
1199   $y->{sign} =~ tr/+\-/-+/;     # refix $y (does nothing for NaN)
1200   $x;                           # already rounded by badd() or no round nec.
1201   }
1202
1203 sub binc
1204   {
1205   # increment arg by one
1206   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1207   return $x if $x->modify('binc');
1208
1209   if ($x->{sign} eq '+')
1210     {
1211     $x->{value} = $CALC->_inc($x->{value});
1212     return $x->round($a,$p,$r);
1213     }
1214   elsif ($x->{sign} eq '-')
1215     {
1216     $x->{value} = $CALC->_dec($x->{value});
1217     $x->{sign} = '+' if $CALC->_is_zero($x->{value}); # -1 +1 => -0 => +0
1218     return $x->round($a,$p,$r);
1219     }
1220   # inf, nan handling etc
1221   $x->badd($self->bone(),$a,$p,$r);             # badd does round
1222   }
1223
1224 sub bdec
1225   {
1226   # decrement arg by one
1227   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1228   return $x if $x->modify('bdec');
1229   
1230   if ($x->{sign} eq '-')
1231     {
1232     # x already < 0
1233     $x->{value} = $CALC->_inc($x->{value});
1234     } 
1235   else
1236     {
1237     return $x->badd($self->bone('-'),@r) unless $x->{sign} eq '+';      # inf or NaN
1238     # >= 0
1239     if ($CALC->_is_zero($x->{value}))
1240       {
1241       # == 0
1242       $x->{value} = $CALC->_one(); $x->{sign} = '-';            # 0 => -1
1243       }
1244     else
1245       {
1246       # > 0
1247       $x->{value} = $CALC->_dec($x->{value});
1248       }
1249     }
1250   $x->round(@r);
1251   }
1252
1253 sub blog
1254   {
1255   # calculate $x = $a ** $base + $b and return $a (e.g. the log() to base
1256   # $base of $x)
1257
1258   # set up parameters
1259   my ($self,$x,$base,@r) = (undef,@_);
1260   # objectify is costly, so avoid it
1261   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1262     {
1263     ($self,$x,$base,@r) = objectify(2,@_);
1264     }
1265
1266   return $x if $x->modify('blog');
1267
1268   $base = $self->new($base) if defined $base && !ref $base;
1269
1270   # inf, -inf, NaN, <0 => NaN
1271   return $x->bnan()
1272    if $x->{sign} ne '+' || (defined $base && $base->{sign} ne '+');
1273
1274   return $upgrade->blog($upgrade->new($x),$base,@r) if 
1275     defined $upgrade;
1276
1277   # fix for bug #24969:
1278   # the default base is e (Euler's number) which is not an integer
1279   if (!defined $base)
1280     {
1281     require Math::BigFloat;
1282     my $u = Math::BigFloat->blog(Math::BigFloat->new($x))->as_int();
1283     # modify $x in place
1284     $x->{value} = $u->{value};
1285     $x->{sign} = $u->{sign};
1286     return $x;
1287     }
1288   
1289   my ($rc,$exact) = $CALC->_log_int($x->{value},$base->{value});
1290   return $x->bnan() unless defined $rc;         # not possible to take log?
1291   $x->{value} = $rc;
1292   $x->round(@r);
1293   }
1294
1295 sub bnok
1296   {
1297   # Calculate n over k (binomial coefficient or "choose" function) as integer.
1298   # set up parameters
1299   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1300
1301   # objectify is costly, so avoid it
1302   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1303     {
1304     ($self,$x,$y,@r) = objectify(2,@_);
1305     }
1306
1307   return $x if $x->modify('bnok');
1308   return $x->bnan() if $x->{sign} eq 'NaN' || $y->{sign} eq 'NaN';
1309   return $x->binf() if $x->{sign} eq '+inf';
1310
1311   # k > n or k < 0 => 0
1312   my $cmp = $x->bacmp($y);
1313   return $x->bzero() if $cmp < 0 || $y->{sign} =~ /^-/;
1314   # k == n => 1
1315   return $x->bone(@r) if $cmp == 0;
1316
1317   if ($CALC->can('_nok'))
1318     {
1319     $x->{value} = $CALC->_nok($x->{value},$y->{value});
1320     }
1321   else
1322     {
1323     # ( 7 )       7!       1*2*3*4 * 5*6*7   5 * 6 * 7       6   7
1324     # ( - ) = --------- =  --------------- = --------- = 5 * - * -
1325     # ( 3 )   (7-3)! 3!    1*2*3*4 * 1*2*3   1 * 2 * 3       2   3
1326
1327     if (!$y->is_zero())
1328       {
1329       my $z = $x - $y;
1330       $z->binc();
1331       my $r = $z->copy(); $z->binc();
1332       my $d = $self->new(2);
1333       while ($z->bacmp($x) <= 0)                # f <= x ?
1334         {
1335         $r->bmul($z); $r->bdiv($d);
1336         $z->binc(); $d->binc();
1337         }
1338       $x->{value} = $r->{value}; $x->{sign} = '+';
1339       }
1340     else { $x->bone(); }
1341     }
1342   $x->round(@r);
1343   }
1344
1345 sub bexp
1346   {
1347   # Calculate e ** $x (Euler's number to the power of X), truncated to
1348   # an integer value.
1349   my ($self,$x,@r) = ref($_[0]) ? (ref($_[0]),@_) : objectify(1,@_);
1350   return $x if $x->modify('bexp');
1351
1352   # inf, -inf, NaN, <0 => NaN
1353   return $x->bnan() if $x->{sign} eq 'NaN';
1354   return $x->bone() if $x->is_zero();
1355   return $x if $x->{sign} eq '+inf';
1356   return $x->bzero() if $x->{sign} eq '-inf';
1357
1358   my $u;
1359   {
1360     # run through Math::BigFloat unless told otherwise
1361     require Math::BigFloat unless defined $upgrade;
1362     local $upgrade = 'Math::BigFloat' unless defined $upgrade;
1363     # calculate result, truncate it to integer
1364     $u = $upgrade->bexp($upgrade->new($x),@r);
1365   }
1366
1367   if (!defined $upgrade)
1368     {
1369     $u = $u->as_int();
1370     # modify $x in place
1371     $x->{value} = $u->{value};
1372     $x->round(@r);
1373     }
1374   else { $x = $u; }
1375   }
1376
1377 sub blcm
1378   {
1379   # (BINT or num_str, BINT or num_str) return BINT
1380   # does not modify arguments, but returns new object
1381   # Lowest Common Multiple
1382
1383   my $y = shift; my ($x);
1384   if (ref($y))
1385     {
1386     $x = $y->copy();
1387     }
1388   else
1389     {
1390     $x = $class->new($y);
1391     }
1392   my $self = ref($x);
1393   while (@_) 
1394     {
1395     my $y = shift; $y = $self->new($y) if !ref ($y);
1396     $x = __lcm($x,$y);
1397     } 
1398   $x;
1399   }
1400
1401 sub bgcd 
1402   { 
1403   # (BINT or num_str, BINT or num_str) return BINT
1404   # does not modify arguments, but returns new object
1405   # GCD -- Euclid's algorithm, variant C (Knuth Vol 3, pg 341 ff)
1406
1407   my $y = shift;
1408   $y = $class->new($y) if !ref($y);
1409   my $self = ref($y);
1410   my $x = $y->copy()->babs();                   # keep arguments
1411   return $x->bnan() if $x->{sign} !~ /^[+-]$/;  # x NaN?
1412
1413   while (@_)
1414     {
1415     $y = shift; $y = $self->new($y) if !ref($y);
1416     return $x->bnan() if $y->{sign} !~ /^[+-]$/;        # y NaN?
1417     $x->{value} = $CALC->_gcd($x->{value},$y->{value});
1418     last if $CALC->_is_one($x->{value});
1419     }
1420   $x;
1421   }
1422
1423 sub bnot 
1424   {
1425   # (num_str or BINT) return BINT
1426   # represent ~x as twos-complement number
1427   # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1428   my ($self,$x,$a,$p,$r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1429  
1430   return $x if $x->modify('bnot');
1431   $x->binc()->bneg();                   # binc already does round
1432   }
1433
1434 ##############################################################################
1435 # is_foo test routines
1436 # we don't need $self, so undef instead of ref($_[0]) make it slightly faster
1437
1438 sub is_zero
1439   {
1440   # return true if arg (BINT or num_str) is zero (array '+', '0')
1441   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1442   
1443   return 0 if $x->{sign} !~ /^\+$/;                     # -, NaN & +-inf aren't
1444   $CALC->_is_zero($x->{value});
1445   }
1446
1447 sub is_nan
1448   {
1449   # return true if arg (BINT or num_str) is NaN
1450   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1451
1452   $x->{sign} eq $nan ? 1 : 0;
1453   }
1454
1455 sub is_inf
1456   {
1457   # return true if arg (BINT or num_str) is +-inf
1458   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1459
1460   if (defined $sign)
1461     {
1462     $sign = '[+-]inf' if $sign eq '';   # +- doesn't matter, only that's inf
1463     $sign = "[$1]inf" if $sign =~ /^([+-])(inf)?$/;     # extract '+' or '-'
1464     return $x->{sign} =~ /^$sign$/ ? 1 : 0;
1465     }
1466   $x->{sign} =~ /^[+-]inf$/ ? 1 : 0;            # only +-inf is infinity
1467   }
1468
1469 sub is_one
1470   {
1471   # return true if arg (BINT or num_str) is +1, or -1 if sign is given
1472   my ($self,$x,$sign) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1473     
1474   $sign = '+' if !defined $sign || $sign ne '-';
1475  
1476   return 0 if $x->{sign} ne $sign;      # -1 != +1, NaN, +-inf aren't either
1477   $CALC->_is_one($x->{value});
1478   }
1479
1480 sub is_odd
1481   {
1482   # return true when arg (BINT or num_str) is odd, false for even
1483   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1484
1485   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1486   $CALC->_is_odd($x->{value});
1487   }
1488
1489 sub is_even
1490   {
1491   # return true when arg (BINT or num_str) is even, false for odd
1492   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1493
1494   return 0 if $x->{sign} !~ /^[+-]$/;                   # NaN & +-inf aren't
1495   $CALC->_is_even($x->{value});
1496   }
1497
1498 sub is_positive
1499   {
1500   # return true when arg (BINT or num_str) is positive (> 0)
1501   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1502
1503   return 1 if $x->{sign} eq '+inf';                     # +inf is positive
1504
1505   # 0+ is neither positive nor negative
1506   ($x->{sign} eq '+' && !$x->is_zero()) ? 1 : 0;
1507   }
1508
1509 sub is_negative
1510   {
1511   # return true when arg (BINT or num_str) is negative (< 0)
1512   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1513   
1514   $x->{sign} =~ /^-/ ? 1 : 0;           # -inf is negative, but NaN is not
1515   }
1516
1517 sub is_int
1518   {
1519   # return true when arg (BINT or num_str) is an integer
1520   # always true for BigInt, but different for BigFloats
1521   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
1522   
1523   $x->{sign} =~ /^[+-]$/ ? 1 : 0;               # inf/-inf/NaN aren't
1524   }
1525
1526 ###############################################################################
1527
1528 sub bmul 
1529   { 
1530   # multiply the first number by the second number
1531   # (BINT or num_str, BINT or num_str) return BINT
1532
1533   # set up parameters
1534   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1535   # objectify is costly, so avoid it
1536   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1537     {
1538     ($self,$x,$y,@r) = objectify(2,@_);
1539     }
1540
1541   return $x if $x->modify('bmul');
1542
1543   return $x->bnan() if (($x->{sign} eq $nan) || ($y->{sign} eq $nan));
1544
1545   # inf handling
1546   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1547     {
1548     return $x->bnan() if $x->is_zero() || $y->is_zero();
1549     # result will always be +-inf:
1550     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1551     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1552     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/); 
1553     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/); 
1554     return $x->binf('-');
1555     }
1556
1557   return $upgrade->bmul($x,$upgrade->new($y),@r)
1558    if defined $upgrade && !$y->isa($self);
1559   
1560   $r[3] = $y;                           # no push here
1561
1562   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1563
1564   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1565   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1566
1567   $x->round(@r);
1568   }
1569
1570 sub bmuladd
1571   { 
1572   # multiply two numbers and then add the third to the result
1573   # (BINT or num_str, BINT or num_str, BINT or num_str) return BINT
1574
1575   # set up parameters
1576   my ($self,$x,$y,$z,@r) = (ref($_[0]),@_);
1577   # objectify is costly, so avoid it
1578   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1579     {
1580     ($self,$x,$y,$z,@r) = objectify(3,@_);
1581     }
1582
1583   return $x if $x->modify('bmuladd');
1584
1585   return $x->bnan() if  ($x->{sign} eq $nan) ||
1586                         ($y->{sign} eq $nan) ||
1587                         ($z->{sign} eq $nan);
1588
1589   # inf handling of x and y
1590   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1591     {
1592     return $x->bnan() if $x->is_zero() || $y->is_zero();
1593     # result will always be +-inf:
1594     # +inf * +/+inf => +inf, -inf * -/-inf => +inf
1595     # +inf * -/-inf => -inf, -inf * +/+inf => -inf
1596     return $x->binf() if ($x->{sign} =~ /^\+/ && $y->{sign} =~ /^\+/); 
1597     return $x->binf() if ($x->{sign} =~ /^-/ && $y->{sign} =~ /^-/); 
1598     return $x->binf('-');
1599     }
1600   # inf handling x*y and z
1601   if (($z->{sign} =~ /^[+-]inf$/))
1602     {
1603     # something +-inf => +-inf
1604     $x->{sign} = $z->{sign}, return $x if $z->{sign} =~ /^[+-]inf$/;
1605     }
1606
1607   return $upgrade->bmuladd($x,$upgrade->new($y),$upgrade->new($z),@r)
1608    if defined $upgrade && (!$y->isa($self) || !$z->isa($self) || !$x->isa($self));
1609  
1610   # TODO: what if $y and $z have A or P set?
1611   $r[3] = $z;                           # no push here
1612
1613   $x->{sign} = $x->{sign} eq $y->{sign} ? '+' : '-'; # +1 * +1 or -1 * -1 => +
1614
1615   $x->{value} = $CALC->_mul($x->{value},$y->{value});   # do actual math
1616   $x->{sign} = '+' if $CALC->_is_zero($x->{value});     # no -0
1617
1618   my ($sx, $sz) = ( $x->{sign}, $z->{sign} );           # get signs
1619
1620   if ($sx eq $sz)  
1621     {
1622     $x->{value} = $CALC->_add($x->{value},$z->{value}); # same sign, abs add
1623     }
1624   else 
1625     {
1626     my $a = $CALC->_acmp ($z->{value},$x->{value});     # absolute compare
1627     if ($a > 0)                           
1628       {
1629       $x->{value} = $CALC->_sub($z->{value},$x->{value},1); # abs sub w/ swap
1630       $x->{sign} = $sz;
1631       } 
1632     elsif ($a == 0)
1633       {
1634       # speedup, if equal, set result to 0
1635       $x->{value} = $CALC->_zero();
1636       $x->{sign} = '+';
1637       }
1638     else # a < 0
1639       {
1640       $x->{value} = $CALC->_sub($x->{value}, $z->{value}); # abs sub
1641       }
1642     }
1643   $x->round(@r);
1644   }
1645
1646 sub _div_inf
1647   {
1648   # helper function that handles +-inf cases for bdiv()/bmod() to reuse code
1649   my ($self,$x,$y) = @_;
1650
1651   # NaN if x == NaN or y == NaN or x==y==0
1652   return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan()
1653    if (($x->is_nan() || $y->is_nan())   ||
1654        ($x->is_zero() && $y->is_zero()));
1655  
1656   # +-inf / +-inf == NaN, remainder also NaN
1657   if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1658     {
1659     return wantarray ? ($x->bnan(),$self->bnan()) : $x->bnan();
1660     }
1661   # x / +-inf => 0, remainder x (works even if x == 0)
1662   if ($y->{sign} =~ /^[+-]inf$/)
1663     {
1664     my $t = $x->copy();         # bzero clobbers up $x
1665     return wantarray ? ($x->bzero(),$t) : $x->bzero()
1666     }
1667   
1668   # 5 / 0 => +inf, -6 / 0 => -inf
1669   # +inf / 0 = inf, inf,  and -inf / 0 => -inf, -inf 
1670   # exception:   -8 / 0 has remainder -8, not 8
1671   # exception: -inf / 0 has remainder -inf, not inf
1672   if ($y->is_zero())
1673     {
1674     # +-inf / 0 => special case for -inf
1675     return wantarray ?  ($x,$x->copy()) : $x if $x->is_inf();
1676     if (!$x->is_zero() && !$x->is_inf())
1677       {
1678       my $t = $x->copy();               # binf clobbers up $x
1679       return wantarray ?
1680        ($x->binf($x->{sign}),$t) : $x->binf($x->{sign})
1681       }
1682     }
1683   
1684   # last case: +-inf / ordinary number
1685   my $sign = '+inf';
1686   $sign = '-inf' if substr($x->{sign},0,1) ne $y->{sign};
1687   $x->{sign} = $sign;
1688   return wantarray ? ($x,$self->bzero()) : $x;
1689   }
1690
1691 sub bdiv 
1692   {
1693   # (dividend: BINT or num_str, divisor: BINT or num_str) return 
1694   # (BINT,BINT) (quo,rem) or BINT (only rem)
1695   
1696   # set up parameters
1697   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1698   # objectify is costly, so avoid it 
1699   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1700     {
1701     ($self,$x,$y,@r) = objectify(2,@_);
1702     } 
1703
1704   return $x if $x->modify('bdiv');
1705
1706   return $self->_div_inf($x,$y)
1707    if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero());
1708
1709   return $upgrade->bdiv($upgrade->new($x),$upgrade->new($y),@r)
1710    if defined $upgrade;
1711    
1712   $r[3] = $y;                                   # no push!
1713
1714   # calc new sign and in case $y == +/- 1, return $x
1715   my $xsign = $x->{sign};                               # keep
1716   $x->{sign} = ($x->{sign} ne $y->{sign} ? '-' : '+'); 
1717
1718   if (wantarray)
1719     {
1720     my $rem = $self->bzero(); 
1721     ($x->{value},$rem->{value}) = $CALC->_div($x->{value},$y->{value});
1722     $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1723     $rem->{_a} = $x->{_a};
1724     $rem->{_p} = $x->{_p};
1725     $x->round(@r);
1726     if (! $CALC->_is_zero($rem->{value}))
1727       {
1728       $rem->{sign} = $y->{sign};
1729       $rem = $y->copy()->bsub($rem) if $xsign ne $y->{sign}; # one of them '-'
1730       }
1731     else
1732       {
1733       $rem->{sign} = '+';                       # dont leave -0
1734       }
1735     $rem->round(@r);
1736     return ($x,$rem);
1737     }
1738
1739   $x->{value} = $CALC->_div($x->{value},$y->{value});
1740   $x->{sign} = '+' if $CALC->_is_zero($x->{value});
1741
1742   $x->round(@r);
1743   }
1744
1745 ###############################################################################
1746 # modulus functions
1747
1748 sub bmod 
1749   {
1750   # modulus (or remainder)
1751   # (BINT or num_str, BINT or num_str) return BINT
1752   
1753   # set up parameters
1754   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1755   # objectify is costly, so avoid it
1756   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1757     {
1758     ($self,$x,$y,@r) = objectify(2,@_);
1759     }
1760
1761   return $x if $x->modify('bmod');
1762   $r[3] = $y;                                   # no push!
1763   if (($x->{sign} !~ /^[+-]$/) || ($y->{sign} !~ /^[+-]$/) || $y->is_zero())
1764     {
1765     my ($d,$r) = $self->_div_inf($x,$y);
1766     $x->{sign} = $r->{sign};
1767     $x->{value} = $r->{value};
1768     return $x->round(@r);
1769     }
1770
1771   # calc new sign and in case $y == +/- 1, return $x
1772   $x->{value} = $CALC->_mod($x->{value},$y->{value});
1773   if (!$CALC->_is_zero($x->{value}))
1774     {
1775     $x->{value} = $CALC->_sub($y->{value},$x->{value},1)        # $y-$x
1776       if ($x->{sign} ne $y->{sign});
1777     $x->{sign} = $y->{sign};
1778     }
1779    else
1780     {
1781     $x->{sign} = '+';                           # dont leave -0
1782     }
1783   $x->round(@r);
1784   }
1785
1786 sub bmodinv
1787   {
1788   # Return modular multiplicative inverse: z is the modular inverse of x (mod
1789   # y) if and only if x*z (mod y) = 1 (mod y). If the modulus y is larger than
1790   # one, x and z are relative primes (i.e., their greatest common divisor is
1791   # one).
1792   #
1793   # If no modular multiplicative inverse exists, NaN is returned.
1794
1795   # set up parameters
1796   my ($self,$x,$y,@r) = (undef,@_);
1797   # objectify is costly, so avoid it
1798   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1799     {
1800     ($self,$x,$y,@r) = objectify(2,@_);
1801     }
1802
1803   return $x if $x->modify('bmodinv');
1804
1805   # Return NaN if one or both arguments is +inf, -inf, or nan.
1806
1807   return $x->bnan() if ($y->{sign} !~ /^[+-]$/ ||
1808                         $x->{sign} !~ /^[+-]$/);
1809
1810   # Return NaN if $y is zero; 1 % 0 makes no sense.
1811
1812   return $x->bnan() if $y->is_zero();
1813
1814   # Return 0 in the trivial case. $x % 1 or $x % -1 is zero for all finite
1815   # integers $x.
1816
1817   return $x->bzero() if ($y->is_one() ||
1818                          $y->is_one('-'));
1819
1820   # Return NaN if $x = 0, or $x modulo $y is zero. The only valid case when
1821   # $x = 0 is when $y = 1 or $y = -1, but that was covered above.
1822   #
1823   # Note that computing $x modulo $y here affects the value we'll feed to
1824   # $CALC->_modinv() below when $x and $y have opposite signs. E.g., if $x =
1825   # 5 and $y = 7, those two values are fed to _modinv(), but if $x = -5 and
1826   # $y = 7, the values fed to _modinv() are $x = 2 (= -5 % 7) and $y = 7.
1827   # The value if $x is affected only when $x and $y have opposite signs.
1828
1829   $x->bmod($y);
1830   return $x->bnan() if $x->is_zero();
1831
1832   # Compute the modular multiplicative inverse of the absolute values. We'll
1833   # correct for the signs of $x and $y later. Return NaN if no GCD is found.
1834
1835   ($x->{value}, $x->{sign}) = $CALC->_modinv($x->{value}, $y->{value});
1836   return $x->bnan() if !defined $x->{value};
1837
1838   # When one or both arguments are negative, we have the following
1839   # relations.  If x and y are positive:
1840   #
1841   #   modinv(-x, -y) = -modinv(x, y)
1842   #   modinv(-x,  y) = y - modinv(x, y)  = -modinv(x, y) (mod y)
1843   #   modinv( x, -y) = modinv(x, y) - y  =  modinv(x, y) (mod -y)
1844
1845   # We must swap the sign of the result if the original $x is negative.
1846   # However, we must compensate for ignoring the signs when computing the
1847   # inverse modulo. The net effect is that we must swap the sign of the
1848   # result if $y is negative.
1849
1850   $x -> bneg() if $y->{sign} eq '-';
1851
1852   # Compute $x modulo $y again after correcting the sign.
1853
1854   $x -> bmod($y) if $x->{sign} ne $y->{sign};
1855
1856   return $x;
1857   }
1858
1859 sub bmodpow
1860   {
1861   # takes a very large number to a very large exponent in a given very
1862   # large modulus, quickly, thanks to binary exponentiation. Supports
1863   # negative exponents.
1864   my ($self,$num,$exp,$mod,@r) = objectify(3,@_);
1865
1866   return $num if $num->modify('bmodpow');
1867
1868   # When the exponent 'e' is negative, use the following relation, which is
1869   # based on finding the multiplicative inverse 'd' of 'b' modulo 'm':
1870   #
1871   #    b^(-e) (mod m) = d^e (mod m) where b*d = 1 (mod m)
1872
1873   $num->bmodinv($mod) if ($exp->{sign} eq '-');
1874
1875   # Check for valid input. All operands must be finite, and the modulus must be
1876   # non-zero.
1877
1878   return $num->bnan() if ($num->{sign} =~ /NaN|inf/ ||  # NaN, -inf, +inf
1879                           $exp->{sign} =~ /NaN|inf/ ||  # NaN, -inf, +inf
1880                           $mod->{sign} =~ /NaN|inf/ ||  # NaN, -inf, +inf
1881                           $mod->is_zero());
1882
1883   # Compute 'a (mod m)', ignoring the signs on 'a' and 'm'. If the resulting
1884   # value is zero, the output is also zero, regardless of the signs on 'a' and
1885   # 'm'.
1886
1887   my $value = $CALC->_modpow($num->{value}, $exp->{value}, $mod->{value});
1888   my $sign  = '+';
1889
1890   # If the resulting value is non-zero, we have four special cases, depending
1891   # on the signs on 'a' and 'm'.
1892
1893   unless ($CALC->_is_zero($num->{value})) {
1894
1895       # There is a negative sign on 'a' (= $num**$exp) only if the number we
1896       # are exponentiating ($num) is negative and the exponent ($exp) is odd.
1897
1898       if ($num->{sign} eq '-' && $exp->is_odd()) {
1899
1900           # When both the number 'a' and the modulus 'm' have a negative sign,
1901           # use this relation:
1902           #
1903           #    -a (mod -m) = -(a (mod m))
1904
1905           if ($mod->{sign} eq '-') {
1906               $sign = '-';
1907           }
1908
1909           # When only the number 'a' has a negative sign, use this relation:
1910           #
1911           #    -a (mod m) = m - (a (mod m))
1912
1913           else {
1914               # Use copy of $mod since _sub() modifies the first argument.
1915               my $mod = $CALC->_copy($mod->{value});
1916               $value = $CALC->_sub($mod, $num->{value});
1917               $sign  = '+';
1918           }
1919
1920       } else {
1921
1922           # When only the modulus 'm' has a negative sign, use this relation:
1923           #
1924           #    a (mod -m) = (a (mod m)) - m
1925           #               = -(m - (a (mod m)))
1926
1927           if ($mod->{sign} eq '-') {
1928               my $mod = $CALC->_copy($mod->{value});
1929               $value = $CALC->_sub($mod, $num->{value});
1930               $sign  = '-';
1931           }
1932
1933           # When neither the number 'a' nor the modulus 'm' have a negative
1934           # sign, directly return the already computed value.
1935           #
1936           #    (a (mod m))
1937
1938       }
1939
1940   }
1941
1942   $num->{value} = $value;
1943   $num->{sign}  = $sign;
1944
1945   return $num;
1946   }
1947
1948 ###############################################################################
1949
1950 sub bfac
1951   {
1952   # (BINT or num_str, BINT or num_str) return BINT
1953   # compute factorial number from $x, modify $x in place
1954   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
1955
1956   return $x if $x->modify('bfac') || $x->{sign} eq '+inf';      # inf => inf
1957   return $x->bnan() if $x->{sign} ne '+';                       # NaN, <0 etc => NaN
1958
1959   $x->{value} = $CALC->_fac($x->{value});
1960   $x->round(@r);
1961   }
1962  
1963 sub bpow 
1964   {
1965   # (BINT or num_str, BINT or num_str) return BINT
1966   # compute power of two numbers -- stolen from Knuth Vol 2 pg 233
1967   # modifies first argument
1968
1969   # set up parameters
1970   my ($self,$x,$y,@r) = (ref($_[0]),@_);
1971   # objectify is costly, so avoid it
1972   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
1973     {
1974     ($self,$x,$y,@r) = objectify(2,@_);
1975     }
1976
1977   return $x if $x->modify('bpow');
1978
1979   return $x->bnan() if $x->{sign} eq $nan || $y->{sign} eq $nan;
1980
1981   # inf handling
1982   if (($x->{sign} =~ /^[+-]inf$/) || ($y->{sign} =~ /^[+-]inf$/))
1983     {
1984     if (($x->{sign} =~ /^[+-]inf$/) && ($y->{sign} =~ /^[+-]inf$/))
1985       {
1986       # +-inf ** +-inf
1987       return $x->bnan();
1988       }
1989     # +-inf ** Y
1990     if ($x->{sign} =~ /^[+-]inf/)
1991       {
1992       # +inf ** 0 => NaN
1993       return $x->bnan() if $y->is_zero();
1994       # -inf ** -1 => 1/inf => 0
1995       return $x->bzero() if $y->is_one('-') && $x->is_negative();
1996
1997       # +inf ** Y => inf
1998       return $x if $x->{sign} eq '+inf';
1999
2000       # -inf ** Y => -inf if Y is odd
2001       return $x if $y->is_odd();
2002       return $x->babs();
2003       }
2004     # X ** +-inf
2005
2006     # 1 ** +inf => 1
2007     return $x if $x->is_one();
2008     
2009     # 0 ** inf => 0
2010     return $x if $x->is_zero() && $y->{sign} =~ /^[+]/;
2011
2012     # 0 ** -inf => inf
2013     return $x->binf() if $x->is_zero();
2014
2015     # -1 ** -inf => NaN
2016     return $x->bnan() if $x->is_one('-') && $y->{sign} =~ /^[-]/;
2017
2018     # -X ** -inf => 0
2019     return $x->bzero() if $x->{sign} eq '-' && $y->{sign} =~ /^[-]/;
2020
2021     # -1 ** inf => NaN
2022     return $x->bnan() if $x->{sign} eq '-';
2023
2024     # X ** inf => inf
2025     return $x->binf() if $y->{sign} =~ /^[+]/;
2026     # X ** -inf => 0
2027     return $x->bzero();
2028     }
2029
2030   return $upgrade->bpow($upgrade->new($x),$y,@r)
2031    if defined $upgrade && (!$y->isa($self) || $y->{sign} eq '-');
2032
2033   $r[3] = $y;                                   # no push!
2034
2035   # cases 0 ** Y, X ** 0, X ** 1, 1 ** Y are handled by Calc or Emu
2036
2037   my $new_sign = '+';
2038   $new_sign = $y->is_odd() ? '-' : '+' if ($x->{sign} ne '+'); 
2039
2040   # 0 ** -7 => ( 1 / (0 ** 7)) => 1 / 0 => +inf 
2041   return $x->binf() 
2042     if $y->{sign} eq '-' && $x->{sign} eq '+' && $CALC->_is_zero($x->{value});
2043   # 1 ** -y => 1 / (1 ** |y|)
2044   # so do test for negative $y after above's clause
2045   return $x->bnan() if $y->{sign} eq '-' && !$CALC->_is_one($x->{value});
2046
2047   $x->{value} = $CALC->_pow($x->{value},$y->{value});
2048   $x->{sign} = $new_sign;
2049   $x->{sign} = '+' if $CALC->_is_zero($y->{value});
2050   $x->round(@r);
2051   }
2052
2053 sub blsft 
2054   {
2055   # (BINT or num_str, BINT or num_str) return BINT
2056   # compute x << y, base n, y >= 0
2057  
2058   # set up parameters
2059   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
2060   # objectify is costly, so avoid it
2061   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2062     {
2063     ($self,$x,$y,$n,@r) = objectify(2,@_);
2064     }
2065
2066   return $x if $x->modify('blsft');
2067   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2068   return $x->round(@r) if $y->is_zero();
2069
2070   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
2071
2072   $x->{value} = $CALC->_lsft($x->{value},$y->{value},$n);
2073   $x->round(@r);
2074   }
2075
2076 sub brsft 
2077   {
2078   # (BINT or num_str, BINT or num_str) return BINT
2079   # compute x >> y, base n, y >= 0
2080   
2081   # set up parameters
2082   my ($self,$x,$y,$n,@r) = (ref($_[0]),@_);
2083   # objectify is costly, so avoid it
2084   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2085     {
2086     ($self,$x,$y,$n,@r) = objectify(2,@_);
2087     }
2088
2089   return $x if $x->modify('brsft');
2090   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2091   return $x->round(@r) if $y->is_zero();
2092   return $x->bzero(@r) if $x->is_zero();                # 0 => 0
2093
2094   $n = 2 if !defined $n; return $x->bnan() if $n <= 0 || $y->{sign} eq '-';
2095
2096    # this only works for negative numbers when shifting in base 2
2097   if (($x->{sign} eq '-') && ($n == 2))
2098     {
2099     return $x->round(@r) if $x->is_one('-');    # -1 => -1
2100     if (!$y->is_one())
2101       {
2102       # although this is O(N*N) in calc (as_bin!) it is O(N) in Pari et al
2103       # but perhaps there is a better emulation for two's complement shift...
2104       # if $y != 1, we must simulate it by doing:
2105       # convert to bin, flip all bits, shift, and be done
2106       $x->binc();                       # -3 => -2
2107       my $bin = $x->as_bin();
2108       $bin =~ s/^-0b//;                 # strip '-0b' prefix
2109       $bin =~ tr/10/01/;                # flip bits
2110       # now shift
2111       if ($y >= CORE::length($bin))
2112         {
2113         $bin = '0';                     # shifting to far right creates -1
2114                                         # 0, because later increment makes 
2115                                         # that 1, attached '-' makes it '-1'
2116                                         # because -1 >> x == -1 !
2117         } 
2118       else
2119         {
2120         $bin =~ s/.{$y}$//;             # cut off at the right side
2121         $bin = '1' . $bin;              # extend left side by one dummy '1'
2122         $bin =~ tr/10/01/;              # flip bits back
2123         }
2124       my $res = $self->new('0b'.$bin);  # add prefix and convert back
2125       $res->binc();                     # remember to increment
2126       $x->{value} = $res->{value};      # take over value
2127       return $x->round(@r);             # we are done now, magic, isn't?
2128       }
2129     # x < 0, n == 2, y == 1
2130     $x->bdec();                         # n == 2, but $y == 1: this fixes it
2131     }
2132
2133   $x->{value} = $CALC->_rsft($x->{value},$y->{value},$n);
2134   $x->round(@r);
2135   }
2136
2137 sub band 
2138   {
2139   #(BINT or num_str, BINT or num_str) return BINT
2140   # compute x & y
2141  
2142   # set up parameters
2143   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2144   # objectify is costly, so avoid it
2145   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2146     {
2147     ($self,$x,$y,@r) = objectify(2,@_);
2148     }
2149   
2150   return $x if $x->modify('band');
2151
2152   $r[3] = $y;                           # no push!
2153
2154   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2155
2156   my $sx = $x->{sign} eq '+' ? 1 : -1;
2157   my $sy = $y->{sign} eq '+' ? 1 : -1;
2158   
2159   if ($sx == 1 && $sy == 1)
2160     {
2161     $x->{value} = $CALC->_and($x->{value},$y->{value});
2162     return $x->round(@r);
2163     }
2164   
2165   if ($CAN{signed_and})
2166     {
2167     $x->{value} = $CALC->_signed_and($x->{value},$y->{value},$sx,$sy);
2168     return $x->round(@r);
2169     }
2170  
2171   require $EMU_LIB;
2172   __emu_band($self,$x,$y,$sx,$sy,@r);
2173   }
2174
2175 sub bior 
2176   {
2177   #(BINT or num_str, BINT or num_str) return BINT
2178   # compute x | y
2179   
2180   # set up parameters
2181   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2182   # objectify is costly, so avoid it
2183   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2184     {
2185     ($self,$x,$y,@r) = objectify(2,@_);
2186     }
2187
2188   return $x if $x->modify('bior');
2189   $r[3] = $y;                           # no push!
2190
2191   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2192
2193   my $sx = $x->{sign} eq '+' ? 1 : -1;
2194   my $sy = $y->{sign} eq '+' ? 1 : -1;
2195
2196   # the sign of X follows the sign of X, e.g. sign of Y irrelevant for bior()
2197   
2198   # don't use lib for negative values
2199   if ($sx == 1 && $sy == 1)
2200     {
2201     $x->{value} = $CALC->_or($x->{value},$y->{value});
2202     return $x->round(@r);
2203     }
2204
2205   # if lib can do negative values, let it handle this
2206   if ($CAN{signed_or})
2207     {
2208     $x->{value} = $CALC->_signed_or($x->{value},$y->{value},$sx,$sy);
2209     return $x->round(@r);
2210     }
2211
2212   require $EMU_LIB;
2213   __emu_bior($self,$x,$y,$sx,$sy,@r);
2214   }
2215
2216 sub bxor 
2217   {
2218   #(BINT or num_str, BINT or num_str) return BINT
2219   # compute x ^ y
2220   
2221   # set up parameters
2222   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2223   # objectify is costly, so avoid it
2224   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
2225     {
2226     ($self,$x,$y,@r) = objectify(2,@_);
2227     }
2228
2229   return $x if $x->modify('bxor');
2230   $r[3] = $y;                           # no push!
2231
2232   return $x->bnan() if ($x->{sign} !~ /^[+-]$/ || $y->{sign} !~ /^[+-]$/);
2233   
2234   my $sx = $x->{sign} eq '+' ? 1 : -1;
2235   my $sy = $y->{sign} eq '+' ? 1 : -1;
2236
2237   # don't use lib for negative values
2238   if ($sx == 1 && $sy == 1)
2239     {
2240     $x->{value} = $CALC->_xor($x->{value},$y->{value});
2241     return $x->round(@r);
2242     }
2243   
2244   # if lib can do negative values, let it handle this
2245   if ($CAN{signed_xor})
2246     {
2247     $x->{value} = $CALC->_signed_xor($x->{value},$y->{value},$sx,$sy);
2248     return $x->round(@r);
2249     }
2250
2251   require $EMU_LIB;
2252   __emu_bxor($self,$x,$y,$sx,$sy,@r);
2253   }
2254
2255 sub length
2256   {
2257   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2258
2259   my $e = $CALC->_len($x->{value}); 
2260   wantarray ? ($e,0) : $e;
2261   }
2262
2263 sub digit
2264   {
2265   # return the nth decimal digit, negative values count backward, 0 is right
2266   my ($self,$x,$n) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2267
2268   $n = $n->numify() if ref($n);
2269   $CALC->_digit($x->{value},$n||0);
2270   }
2271
2272 sub _trailing_zeros
2273   {
2274   # return the amount of trailing zeros in $x (as scalar)
2275   my $x = shift;
2276   $x = $class->new($x) unless ref $x;
2277
2278   return 0 if $x->{sign} !~ /^[+-]$/;   # NaN, inf, -inf etc
2279
2280   $CALC->_zeros($x->{value});           # must handle odd values, 0 etc
2281   }
2282
2283 sub bsqrt
2284   {
2285   # calculate square root of $x
2286   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2287
2288   return $x if $x->modify('bsqrt');
2289
2290   return $x->bnan() if $x->{sign} !~ /^\+/;     # -x or -inf or NaN => NaN
2291   return $x if $x->{sign} eq '+inf';            # sqrt(+inf) == inf
2292
2293   return $upgrade->bsqrt($x,@r) if defined $upgrade;
2294
2295   $x->{value} = $CALC->_sqrt($x->{value});
2296   $x->round(@r);
2297   }
2298
2299 sub broot
2300   {
2301   # calculate $y'th root of $x
2302  
2303   # set up parameters
2304   my ($self,$x,$y,@r) = (ref($_[0]),@_);
2305
2306   $y = $self->new(2) unless defined $y;
2307
2308   # objectify is costly, so avoid it
2309   if ((!ref($x)) || (ref($x) ne ref($y)))
2310     {
2311     ($self,$x,$y,@r) = objectify(2,$self || $class,@_);
2312     }
2313
2314   return $x if $x->modify('broot');
2315
2316   # NaN handling: $x ** 1/0, x or y NaN, or y inf/-inf or y == 0
2317   return $x->bnan() if $x->{sign} !~ /^\+/ || $y->is_zero() ||
2318          $y->{sign} !~ /^\+$/;
2319
2320   return $x->round(@r)
2321     if $x->is_zero() || $x->is_one() || $x->is_inf() || $y->is_one();
2322
2323   return $upgrade->new($x)->broot($upgrade->new($y),@r) if defined $upgrade;
2324
2325   $x->{value} = $CALC->_root($x->{value},$y->{value});
2326   $x->round(@r);
2327   }
2328
2329 sub exponent
2330   {
2331   # return a copy of the exponent (here always 0, NaN or 1 for $m == 0)
2332   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2333  
2334   if ($x->{sign} !~ /^[+-]$/)
2335     {
2336     my $s = $x->{sign}; $s =~ s/^[+-]//;  # NaN, -inf,+inf => NaN or inf
2337     return $self->new($s);
2338     }
2339   return $self->bone() if $x->is_zero();
2340
2341   # 12300 => 2 trailing zeros => exponent is 2
2342   $self->new( $CALC->_zeros($x->{value}) );
2343   }
2344
2345 sub mantissa
2346   {
2347   # return the mantissa (compatible to Math::BigFloat, e.g. reduced)
2348   my ($self,$x) = ref($_[0]) ? (ref($_[0]),$_[0]) : objectify(1,@_);
2349
2350   if ($x->{sign} !~ /^[+-]$/)
2351     {
2352     # for NaN, +inf, -inf: keep the sign
2353     return $self->new($x->{sign});
2354     }
2355   my $m = $x->copy(); delete $m->{_p}; delete $m->{_a};
2356
2357   # that's a bit inefficient:
2358   my $zeros = $CALC->_zeros($m->{value});
2359   $m->brsft($zeros,10) if $zeros != 0;
2360   $m;
2361   }
2362
2363 sub parts
2364   {
2365   # return a copy of both the exponent and the mantissa
2366   my ($self,$x) = ref($_[0]) ? (undef,$_[0]) : objectify(1,@_);
2367
2368   ($x->mantissa(),$x->exponent());
2369   }
2370    
2371 ##############################################################################
2372 # rounding functions
2373
2374 sub bfround
2375   {
2376   # precision: round to the $Nth digit left (+$n) or right (-$n) from the '.'
2377   # $n == 0 || $n == 1 => round to integer
2378   my $x = shift; my $self = ref($x) || $x; $x = $self->new($x) unless ref $x;
2379
2380   my ($scale,$mode) = $x->_scale_p(@_);
2381
2382   return $x if !defined $scale || $x->modify('bfround');        # no-op
2383
2384   # no-op for BigInts if $n <= 0
2385   $x->bround( $x->length()-$scale, $mode) if $scale > 0;
2386
2387   delete $x->{_a};      # delete to save memory
2388   $x->{_p} = $scale;    # store new _p
2389   $x;
2390   }
2391
2392 sub _scan_for_nonzero
2393   {
2394   # internal, used by bround() to scan for non-zeros after a '5'
2395   my ($x,$pad,$xs,$len) = @_;
2396  
2397   return 0 if $len == 1;                # "5" is trailed by invisible zeros
2398   my $follow = $pad - 1;
2399   return 0 if $follow > $len || $follow < 1;
2400
2401   # use the string form to check whether only '0's follow or not
2402   substr ($xs,-$follow) =~ /[^0]/ ? 1 : 0;
2403   }
2404
2405 sub fround
2406   {
2407   # Exists to make life easier for switch between MBF and MBI (should we
2408   # autoload fxxx() like MBF does for bxxx()?)
2409   my $x = shift; $x = $class->new($x) unless ref $x;
2410   $x->bround(@_);
2411   }
2412
2413 sub bround
2414   {
2415   # accuracy: +$n preserve $n digits from left,
2416   #           -$n preserve $n digits from right (f.i. for 0.1234 style in MBF)
2417   # no-op for $n == 0
2418   # and overwrite the rest with 0's, return normalized number
2419   # do not return $x->bnorm(), but $x
2420
2421   my $x = shift; $x = $class->new($x) unless ref $x;
2422   my ($scale,$mode) = $x->_scale_a(@_);
2423   return $x if !defined $scale || $x->modify('bround'); # no-op
2424   
2425   if ($x->is_zero() || $scale == 0)
2426     {
2427     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2428     return $x;
2429     }
2430   return $x if $x->{sign} !~ /^[+-]$/;          # inf, NaN
2431
2432   # we have fewer digits than we want to scale to
2433   my $len = $x->length();
2434   # convert $scale to a scalar in case it is an object (put's a limit on the
2435   # number length, but this would already limited by memory constraints), makes
2436   # it faster
2437   $scale = $scale->numify() if ref ($scale);
2438
2439   # scale < 0, but > -len (not >=!)
2440   if (($scale < 0 && $scale < -$len-1) || ($scale >= $len))
2441     {
2442     $x->{_a} = $scale if !defined $x->{_a} || $x->{_a} > $scale; # 3 > 2
2443     return $x; 
2444     }
2445    
2446   # count of 0's to pad, from left (+) or right (-): 9 - +6 => 3, or |-6| => 6
2447   my ($pad,$digit_round,$digit_after);
2448   $pad = $len - $scale;
2449   $pad = abs($scale-1) if $scale < 0;
2450
2451   # do not use digit(), it is very costly for binary => decimal
2452   # getting the entire string is also costly, but we need to do it only once
2453   my $xs = $CALC->_str($x->{value});
2454   my $pl = -$pad-1;
2455
2456   # pad:   123: 0 => -1, at 1 => -2, at 2 => -3, at 3 => -4
2457   # pad+1: 123: 0 => 0,  at 1 => -1, at 2 => -2, at 3 => -3
2458   $digit_round = '0'; $digit_round = substr($xs,$pl,1) if $pad <= $len;
2459   $pl++; $pl ++ if $pad >= $len;
2460   $digit_after = '0'; $digit_after = substr($xs,$pl,1) if $pad > 0;
2461
2462   # in case of 01234 we round down, for 6789 up, and only in case 5 we look
2463   # closer at the remaining digits of the original $x, remember decision
2464   my $round_up = 1;                                     # default round up
2465   $round_up -- if
2466     ($mode eq 'trunc')                          ||      # trunc by round down
2467     ($digit_after =~ /[01234]/)                 ||      # round down anyway,
2468                                                         # 6789 => round up
2469     ($digit_after eq '5')                       &&      # not 5000...0000
2470     ($x->_scan_for_nonzero($pad,$xs,$len) == 0)         &&
2471     (
2472      ($mode eq 'even') && ($digit_round =~ /[24680]/) ||
2473      ($mode eq 'odd')  && ($digit_round =~ /[13579]/) ||
2474      ($mode eq '+inf') && ($x->{sign} eq '-')   ||
2475      ($mode eq '-inf') && ($x->{sign} eq '+')   ||
2476      ($mode eq 'zero')          # round down if zero, sign adjusted below
2477     );
2478   my $put_back = 0;                                     # not yet modified
2479         
2480   if (($pad > 0) && ($pad <= $len))
2481     {
2482     substr($xs,-$pad,$pad) = '0' x $pad;                # replace with '00...'
2483     $put_back = 1;                                      # need to put back
2484     }
2485   elsif ($pad > $len)
2486     {
2487     $x->bzero();                                        # round to '0'
2488     }
2489
2490   if ($round_up)                                        # what gave test above?
2491     {
2492     $put_back = 1;                                      # need to put back
2493     $pad = $len, $xs = '0' x $pad if $scale < 0;        # tlr: whack 0.51=>1.0  
2494
2495     # we modify directly the string variant instead of creating a number and
2496     # adding it, since that is faster (we already have the string)
2497     my $c = 0; $pad ++;                         # for $pad == $len case
2498     while ($pad <= $len)
2499       {
2500       $c = substr($xs,-$pad,1) + 1; $c = '0' if $c eq '10';
2501       substr($xs,-$pad,1) = $c; $pad++;
2502       last if $c != 0;                          # no overflow => early out
2503       }
2504     $xs = '1'.$xs if $c == 0;
2505
2506     }
2507   $x->{value} = $CALC->_new($xs) if $put_back == 1;     # put back, if needed
2508
2509   $x->{_a} = $scale if $scale >= 0;
2510   if ($scale < 0)
2511     {
2512     $x->{_a} = $len+$scale;
2513     $x->{_a} = 0 if $scale < -$len;
2514     }
2515   $x;
2516   }
2517
2518 sub bfloor
2519   {
2520   # return integer less or equal then number; no-op since it's already integer
2521   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2522
2523   $x->round(@r);
2524   }
2525
2526 sub bceil
2527   {
2528   # return integer greater or equal then number; no-op since it's already int
2529   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
2530
2531   $x->round(@r);
2532   }
2533
2534 sub as_number
2535   {
2536   # An object might be asked to return itself as bigint on certain overloaded
2537   # operations. This does exactly this, so that sub classes can simple inherit
2538   # it or override with their own integer conversion routine.
2539   $_[0]->copy();
2540   }
2541
2542 sub as_hex
2543   {
2544   # return as hex string, with prefixed 0x
2545   my $x = shift; $x = $class->new($x) if !ref($x);
2546
2547   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2548
2549   my $s = '';
2550   $s = $x->{sign} if $x->{sign} eq '-';
2551   $s . $CALC->_as_hex($x->{value});
2552   }
2553
2554 sub as_bin
2555   {
2556   # return as binary string, with prefixed 0b
2557   my $x = shift; $x = $class->new($x) if !ref($x);
2558
2559   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2560
2561   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2562   return $s . $CALC->_as_bin($x->{value});
2563   }
2564
2565 sub as_oct
2566   {
2567   # return as octal string, with prefixed 0
2568   my $x = shift; $x = $class->new($x) if !ref($x);
2569
2570   return $x->bstr() if $x->{sign} !~ /^[+-]$/;  # inf, nan etc
2571
2572   my $s = ''; $s = $x->{sign} if $x->{sign} eq '-';
2573   return $s . $CALC->_as_oct($x->{value});
2574   }
2575
2576 ##############################################################################
2577 # private stuff (internal use only)
2578
2579 sub objectify
2580   {
2581   # check for strings, if yes, return objects instead
2582  
2583   # the first argument is number of args objectify() should look at it will
2584   # return $count+1 elements, the first will be a classname. This is because
2585   # overloaded '""' calls bstr($object,undef,undef) and this would result in
2586   # useless objects being created and thrown away. So we cannot simple loop
2587   # over @_. If the given count is 0, all arguments will be used.
2588  
2589   # If the second arg is a ref, use it as class.
2590   # If not, try to use it as classname, unless undef, then use $class 
2591   # (aka Math::BigInt). The latter shouldn't happen,though.
2592
2593   # caller:                        gives us:
2594   # $x->badd(1);                => ref x, scalar y
2595   # Class->badd(1,2);           => classname x (scalar), scalar x, scalar y
2596   # Class->badd( Class->(1),2); => classname x (scalar), ref x, scalar y
2597   # Math::BigInt::badd(1,2);    => scalar x, scalar y
2598   # In the last case we check number of arguments to turn it silently into
2599   # $class,1,2. (We can not take '1' as class ;o)
2600   # badd($class,1) is not supported (it should, eventually, try to add undef)
2601   # currently it tries 'Math::BigInt' + 1, which will not work.
2602
2603   # some shortcut for the common cases
2604   # $x->unary_op();
2605   return (ref($_[1]),$_[1]) if (@_ == 2) && ($_[0]||0 == 1) && ref($_[1]);
2606
2607   my $count = abs(shift || 0);
2608   
2609   my (@a,$k,$d);                # resulting array, temp, and downgrade 
2610   if (ref $_[0])
2611     {
2612     # okay, got object as first
2613     $a[0] = ref $_[0];
2614     }
2615   else
2616     {
2617     # nope, got 1,2 (Class->xxx(1) => Class,1 and not supported)
2618     $a[0] = $class;
2619     $a[0] = shift if $_[0] =~ /^[A-Z].*::/;     # classname as first?
2620     }
2621
2622   no strict 'refs';
2623   # disable downgrading, because Math::BigFLoat->foo('1.0','2.0') needs floats
2624   if (defined ${"$a[0]::downgrade"})
2625     {
2626     $d = ${"$a[0]::downgrade"};
2627     ${"$a[0]::downgrade"} = undef;
2628     }
2629
2630   my $up = ${"$a[0]::upgrade"};
2631   # print STDERR "# Now in objectify, my class is today $a[0], count = $count\n";
2632   if ($count == 0)
2633     {
2634     while (@_)
2635       {
2636       $k = shift;
2637       if (!ref($k))
2638         {
2639         $k = $a[0]->new($k);
2640         }
2641       elsif (!defined $up && ref($k) ne $a[0])
2642         {
2643         # foreign object, try to convert to integer
2644         $k->can('as_number') ?  $k = $k->as_number() : $k = $a[0]->new($k);
2645         }
2646       push @a,$k;
2647       }
2648     }
2649   else
2650     {
2651     while ($count > 0)
2652       {
2653       $count--; 
2654       $k = shift;
2655       if (!ref($k))
2656         {
2657         $k = $a[0]->new($k);
2658         }
2659       elsif (ref($k) ne $a[0] and !defined $up || ref $k ne $up)
2660         {
2661         # foreign object, try to convert to integer
2662         $k->can('as_number') ? $k = $k->as_number() : $k = $a[0]->new($k);
2663         }
2664       push @a,$k;
2665       }
2666     push @a,@_;         # return other params, too
2667     }
2668   if (! wantarray)
2669     {
2670     require Carp; Carp::croak ("$class objectify needs list context");
2671     }
2672   ${"$a[0]::downgrade"} = $d;
2673   @a;
2674   }
2675
2676 sub _register_callback
2677   {
2678   my ($class,$callback) = @_;
2679
2680   if (ref($callback) ne 'CODE')
2681     { 
2682     require Carp;
2683     Carp::croak ("$callback is not a coderef");
2684     }
2685   $CALLBACKS{$class} = $callback;
2686   }
2687
2688 sub import 
2689   {
2690   my $self = shift;
2691
2692   $IMPORT++;                            # remember we did import()
2693   my @a; my $l = scalar @_;
2694   my $warn_or_die = 0;                  # 0 - no warn, 1 - warn, 2 - die
2695   for ( my $i = 0; $i < $l ; $i++ )
2696     {
2697     if ($_[$i] eq ':constant')
2698       {
2699       # this causes overlord er load to step in
2700       overload::constant 
2701         integer => sub { $self->new(shift) },
2702         binary => sub { $self->new(shift) };
2703       }
2704     elsif ($_[$i] eq 'upgrade')
2705       {
2706       # this causes upgrading
2707       $upgrade = $_[$i+1];              # or undef to disable
2708       $i++;
2709       }
2710     elsif ($_[$i] =~ /^(lib|try|only)\z/)
2711       {
2712       # this causes a different low lib to take care...
2713       $CALC = $_[$i+1] || '';
2714       # lib => 1 (warn on fallback), try => 0 (no warn), only => 2 (die on fallback)
2715       $warn_or_die = 1 if $_[$i] eq 'lib';
2716       $warn_or_die = 2 if $_[$i] eq 'only';
2717       $i++;
2718       }
2719     else
2720       {
2721       push @a, $_[$i];
2722       }
2723     }
2724   # any non :constant stuff is handled by our parent, Exporter
2725   if (@a > 0)
2726     {
2727     require Exporter;
2728  
2729     $self->SUPER::import(@a);                   # need it for subclasses
2730     $self->export_to_level(1,$self,@a);         # need it for MBF
2731     }
2732
2733   # try to load core math lib
2734   my @c = split /\s*,\s*/,$CALC;
2735   foreach (@c)
2736     {
2737     $_ =~ tr/a-zA-Z0-9://cd;                    # limit to sane characters
2738     }
2739   push @c, \'FastCalc', \'Calc'                 # if all fail, try these
2740     if $warn_or_die < 2;                        # but not for "only"
2741   $CALC = '';                                   # signal error
2742   foreach my $l (@c)
2743     {
2744     # fallback libraries are "marked" as \'string', extract string if nec.
2745     my $lib = $l; $lib = $$l if ref($l);
2746
2747     next if ($lib || '') eq '';
2748     $lib = 'Math::BigInt::'.$lib if $lib !~ /^Math::BigInt/i;
2749     $lib =~ s/\.pm$//;
2750     if ($] < 5.006)
2751       {
2752       # Perl < 5.6.0 dies with "out of memory!" when eval("") and ':constant' is
2753       # used in the same script, or eval("") inside import().
2754       my @parts = split /::/, $lib;             # Math::BigInt => Math BigInt
2755       my $file = pop @parts; $file .= '.pm';    # BigInt => BigInt.pm
2756       require File::Spec;
2757       $file = File::Spec->catfile (@parts, $file);
2758       eval { require "$file"; $lib->import( @c ); }
2759       }
2760     else
2761       {
2762       eval "use $lib qw/@c/;";
2763       }
2764     if ($@ eq '')
2765       {
2766       my $ok = 1;
2767       # loaded it ok, see if the api_version() is high enough
2768       if ($lib->can('api_version') && $lib->api_version() >= 1.0)
2769         {
2770         $ok = 0;
2771         # api_version matches, check if it really provides anything we need
2772         for my $method (qw/
2773                 one two ten
2774                 str num
2775                 add mul div sub dec inc
2776                 acmp len digit is_one is_zero is_even is_odd
2777                 is_two is_ten
2778                 zeros new copy check
2779                 from_hex from_oct from_bin as_hex as_bin as_oct
2780                 rsft lsft xor and or
2781                 mod sqrt root fac pow modinv modpow log_int gcd
2782          /)
2783           {
2784           if (!$lib->can("_$method"))
2785             {
2786             if (($WARN{$lib}||0) < 2)
2787               {
2788               require Carp;
2789               Carp::carp ("$lib is missing method '_$method'");
2790               $WARN{$lib} = 1;          # still warn about the lib
2791               }
2792             $ok++; last; 
2793             }
2794           }
2795         }
2796       if ($ok == 0)
2797         {
2798         $CALC = $lib;
2799         if ($warn_or_die > 0 && ref($l))
2800           {
2801           require Carp;
2802           my $msg = "Math::BigInt: couldn't load specified math lib(s), fallback to $lib";
2803           Carp::carp ($msg) if $warn_or_die == 1;
2804           Carp::croak ($msg) if $warn_or_die == 2;
2805           }
2806         last;                   # found a usable one, break
2807         }
2808       else
2809         {
2810         if (($WARN{$lib}||0) < 2)
2811           {
2812           my $ver = eval "\$$lib\::VERSION" || 'unknown';
2813           require Carp;
2814           Carp::carp ("Cannot load outdated $lib v$ver, please upgrade");
2815           $WARN{$lib} = 2;              # never warn again
2816           }
2817         }
2818       }
2819     }
2820   if ($CALC eq '')
2821     {
2822     require Carp;
2823     if ($warn_or_die == 2)
2824       {
2825       Carp::croak ("Couldn't load specified math lib(s) and fallback disallowed");
2826       }
2827     else
2828       {
2829       Carp::croak ("Couldn't load any math lib(s), not even fallback to Calc.pm");
2830       }
2831     }
2832
2833   # notify callbacks
2834   foreach my $class (keys %CALLBACKS)
2835     {
2836     &{$CALLBACKS{$class}}($CALC);
2837     }
2838
2839   # Fill $CAN with the results of $CALC->can(...) for emulating lower math lib
2840   # functions
2841
2842   %CAN = ();
2843   for my $method (qw/ signed_and signed_or signed_xor /)
2844     {
2845     $CAN{$method} = $CALC->can("_$method") ? 1 : 0;
2846     }
2847
2848   # import done
2849   }
2850
2851 sub from_hex
2852   {
2853   # create a bigint from a hexadecimal string
2854   my ($self, $hs) = @_;
2855
2856   my $rc = __from_hex($hs);
2857
2858   return $self->bnan() unless defined $rc;
2859
2860   $rc;
2861   }  
2862
2863 sub from_bin
2864   {
2865   # create a bigint from a hexadecimal string
2866   my ($self, $bs) = @_;
2867
2868   my $rc = __from_bin($bs);
2869
2870   return $self->bnan() unless defined $rc;
2871
2872   $rc;
2873   }  
2874
2875 sub from_oct
2876   {
2877   # create a bigint from a hexadecimal string
2878   my ($self, $os) = @_;
2879
2880   my $x = $self->bzero();
2881   
2882   # strip underscores
2883   $os =~ s/([0-7])_([0-7])/$1$2/g;      
2884   $os =~ s/([0-7])_([0-7])/$1$2/g;      
2885   
2886   return $x->bnan() if $os !~ /^[\-\+]?0[0-7]+\z/;
2887
2888   my $sign = '+'; $sign = '-' if $os =~ /^-/;
2889
2890   $os =~ s/^[+-]//;                                             # strip sign
2891   $x->{value} = $CALC->_from_oct($os);
2892   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2893   $x;
2894   }
2895
2896 sub __from_hex
2897   {
2898   # internal
2899   # convert a (ref to) big hex string to BigInt, return undef for error
2900   my $hs = shift;
2901
2902   my $x = Math::BigInt->bzero();
2903   
2904   # strip underscores
2905   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;  
2906   $hs =~ s/([0-9a-fA-F])_([0-9a-fA-F])/$1$2/g;  
2907   
2908   return $x->bnan() if $hs !~ /^[\-\+]?0x[0-9A-Fa-f]+$/;
2909
2910   my $sign = '+'; $sign = '-' if $hs =~ /^-/;
2911
2912   $hs =~ s/^[+-]//;                                             # strip sign
2913   $x->{value} = $CALC->_from_hex($hs);
2914   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2915   $x;
2916   }
2917
2918 sub __from_bin
2919   {
2920   # internal
2921   # convert a (ref to) big binary string to BigInt, return undef for error
2922   my $bs = shift;
2923
2924   my $x = Math::BigInt->bzero();
2925
2926   # strip underscores
2927   $bs =~ s/([01])_([01])/$1$2/g;        
2928   $bs =~ s/([01])_([01])/$1$2/g;        
2929   return $x->bnan() if $bs !~ /^[+-]?0b[01]+$/;
2930
2931   my $sign = '+'; $sign = '-' if $bs =~ /^\-/;
2932   $bs =~ s/^[+-]//;                                             # strip sign
2933
2934   $x->{value} = $CALC->_from_bin($bs);
2935   $x->{sign} = $sign unless $CALC->_is_zero($x->{value});       # no '-0'
2936   $x;
2937   }
2938
2939 sub _split
2940   {
2941   # input: num_str; output: undef for invalid or
2942   # (\$mantissa_sign,\$mantissa_value,\$mantissa_fraction,\$exp_sign,\$exp_value)
2943   # Internal, take apart a string and return the pieces.
2944   # Strip leading/trailing whitespace, leading zeros, underscore and reject
2945   # invalid input.
2946   my $x = shift;
2947
2948   # strip white space at front, also extraneous leading zeros
2949   $x =~ s/^\s*([-]?)0*([0-9])/$1$2/g;   # will not strip '  .2'
2950   $x =~ s/^\s+//;                       # but this will
2951   $x =~ s/\s+$//g;                      # strip white space at end
2952
2953   # shortcut, if nothing to split, return early
2954   if ($x =~ /^[+-]?[0-9]+\z/)
2955     {
2956     $x =~ s/^([+-])0*([0-9])/$2/; my $sign = $1 || '+';
2957     return (\$sign, \$x, \'', \'', \0);
2958     }
2959
2960   # invalid starting char?
2961   return if $x !~ /^[+-]?(\.?[0-9]|0b[0-1]|0x[0-9a-fA-F])/;
2962
2963   return __from_hex($x) if $x =~ /^[\-\+]?0x/;          # hex string
2964   return __from_bin($x) if $x =~ /^[\-\+]?0b/;          # binary string
2965   
2966   # strip underscores between digits
2967   $x =~ s/([0-9])_([0-9])/$1$2/g;
2968   $x =~ s/([0-9])_([0-9])/$1$2/g;               # do twice for 1_2_3
2969
2970   # some possible inputs: 
2971   # 2.1234 # 0.12        # 1          # 1E1 # 2.134E1 # 434E-10 # 1.02009E-2 
2972   # .2     # 1_2_3.4_5_6 # 1.4E1_2_3  # 1e3 # +.2     # 0e999   
2973
2974   my ($m,$e,$last) = split /[Ee]/,$x;
2975   return if defined $last;              # last defined => 1e2E3 or others
2976   $e = '0' if !defined $e || $e eq "";
2977
2978   # sign,value for exponent,mantint,mantfrac
2979   my ($es,$ev,$mis,$miv,$mfv);
2980   # valid exponent?
2981   if ($e =~ /^([+-]?)0*([0-9]+)$/)      # strip leading zeros
2982     {
2983     $es = $1; $ev = $2;
2984     # valid mantissa?
2985     return if $m eq '.' || $m eq '';
2986     my ($mi,$mf,$lastf) = split /\./,$m;
2987     return if defined $lastf;           # lastf defined => 1.2.3 or others
2988     $mi = '0' if !defined $mi;
2989     $mi .= '0' if $mi =~ /^[\-\+]?$/;
2990     $mf = '0' if !defined $mf || $mf eq '';
2991     if ($mi =~ /^([+-]?)0*([0-9]+)$/)           # strip leading zeros
2992       {
2993       $mis = $1||'+'; $miv = $2;
2994       return unless ($mf =~ /^([0-9]*?)0*$/);   # strip trailing zeros
2995       $mfv = $1;
2996       # handle the 0e999 case here
2997       $ev = 0 if $miv eq '0' && $mfv eq '';
2998       return (\$mis,\$miv,\$mfv,\$es,\$ev);
2999       }
3000     }
3001   return; # NaN, not a number
3002   }
3003
3004 ##############################################################################
3005 # internal calculation routines (others are in Math::BigInt::Calc etc)
3006
3007 sub __lcm 
3008   { 
3009   # (BINT or num_str, BINT or num_str) return BINT
3010   # does modify first argument
3011   # LCM
3012  
3013   my ($x,$ty) = @_;
3014   return $x->bnan() if ($x->{sign} eq $nan) || ($ty->{sign} eq $nan);
3015   my $method = ref($x) . '::bgcd';
3016   no strict 'refs';
3017   $x * $ty / &$method($x,$ty);
3018   }
3019
3020 ###############################################################################
3021 # trigonometric functions
3022
3023 sub bpi
3024   {
3025   # Calculate PI to N digits. Unless upgrading is in effect, returns the
3026   # result truncated to an integer, that is, always returns '3'.
3027   my ($self,$n) = @_;
3028   if (@_ == 1)
3029     {
3030     # called like Math::BigInt::bpi(10);
3031     $n = $self; $self = $class;
3032     }
3033   $self = ref($self) if ref($self);
3034
3035   return $upgrade->new($n) if defined $upgrade;
3036
3037   # hard-wired to "3"
3038   $self->new(3);
3039   }
3040
3041 sub bcos
3042   {
3043   # Calculate cosinus(x) to N digits. Unless upgrading is in effect, returns the
3044   # result truncated to an integer.
3045   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
3046
3047   return $x if $x->modify('bcos');
3048
3049   return $x->bnan() if $x->{sign} !~ /^[+-]\z/; # -inf +inf or NaN => NaN
3050
3051   return $upgrade->new($x)->bcos(@r) if defined $upgrade;
3052
3053   require Math::BigFloat;
3054   # calculate the result and truncate it to integer
3055   my $t = Math::BigFloat->new($x)->bcos(@r)->as_int();
3056
3057   $x->bone() if $t->is_one();
3058   $x->bzero() if $t->is_zero();
3059   $x->round(@r);
3060   }
3061
3062 sub bsin
3063   {
3064   # Calculate sinus(x) to N digits. Unless upgrading is in effect, returns the
3065   # result truncated to an integer.
3066   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
3067
3068   return $x if $x->modify('bsin');
3069
3070   return $x->bnan() if $x->{sign} !~ /^[+-]\z/; # -inf +inf or NaN => NaN
3071
3072   return $upgrade->new($x)->bsin(@r) if defined $upgrade;
3073
3074   require Math::BigFloat;
3075   # calculate the result and truncate it to integer
3076   my $t = Math::BigFloat->new($x)->bsin(@r)->as_int();
3077
3078   $x->bone() if $t->is_one();
3079   $x->bzero() if $t->is_zero();
3080   $x->round(@r);
3081   }
3082
3083 sub batan2
3084   { 
3085   # calculate arcus tangens of ($y/$x)
3086  
3087   # set up parameters
3088   my ($self,$y,$x,@r) = (ref($_[0]),@_);
3089   # objectify is costly, so avoid it
3090   if ((!ref($_[0])) || (ref($_[0]) ne ref($_[1])))
3091     {
3092     ($self,$y,$x,@r) = objectify(2,@_);
3093     }
3094
3095   return $y if $y->modify('batan2');
3096
3097   return $y->bnan() if ($y->{sign} eq $nan) || ($x->{sign} eq $nan);
3098
3099   # Y    X
3100   # != 0 -inf result is +- pi
3101   if ($x->is_inf() || $y->is_inf())
3102     {
3103     # upgrade to BigFloat etc.
3104     return $upgrade->new($y)->batan2($upgrade->new($x),@r) if defined $upgrade;
3105     if ($y->is_inf())
3106       {
3107       if ($x->{sign} eq '-inf')
3108         {
3109         # calculate 3 pi/4 => 2.3.. => 2
3110         $y->bone( substr($y->{sign},0,1) );
3111         $y->bmul($self->new(2));
3112         }
3113       elsif ($x->{sign} eq '+inf')
3114         {
3115         # calculate pi/4 => 0.7 => 0
3116         $y->bzero();
3117         }
3118       else
3119         {
3120         # calculate pi/2 => 1.5 => 1
3121         $y->bone( substr($y->{sign},0,1) );
3122         }
3123       }
3124     else
3125       {
3126       if ($x->{sign} eq '+inf')
3127         {
3128         # calculate pi/4 => 0.7 => 0
3129         $y->bzero();
3130         }
3131       else
3132         {
3133         # PI => 3.1415.. => 3
3134         $y->bone( substr($y->{sign},0,1) );
3135         $y->bmul($self->new(3));
3136         }
3137       }
3138     return $y;
3139     }
3140
3141   return $upgrade->new($y)->batan2($upgrade->new($x),@r) if defined $upgrade;
3142
3143   require Math::BigFloat;
3144   my $r = Math::BigFloat->new($y)->batan2(Math::BigFloat->new($x),@r)->as_int();
3145
3146   $x->{value} = $r->{value};
3147   $x->{sign} = $r->{sign};
3148
3149   $x;
3150   }
3151
3152 sub batan
3153   {
3154   # Calculate arcus tangens of x to N digits. Unless upgrading is in effect, returns the
3155   # result truncated to an integer.
3156   my ($self,$x,@r) = ref($_[0]) ? (undef,@_) : objectify(1,@_);
3157
3158   return $x if $x->modify('batan');
3159
3160   return $x->bnan() if $x->{sign} !~ /^[+-]\z/; # -inf +inf or NaN => NaN
3161
3162   return $upgrade->new($x)->batan(@r) if defined $upgrade;
3163
3164   # calculate the result and truncate it to integer
3165   my $t = Math::BigFloat->new($x)->batan(@r);
3166
3167   $x->{value} = $CALC->_new( $x->as_int()->bstr() );
3168   $x->round(@r);
3169   }
3170
3171 ###############################################################################
3172 # this method returns 0 if the object can be modified, or 1 if not.
3173 # We use a fast constant sub() here, to avoid costly calls. Subclasses
3174 # may override it with special code (f.i. Math::BigInt::Constant does so)
3175
3176 sub modify () { 0; }
3177
3178 1;
3179 __END__
3180
3181 =pod
3182
3183 =head1 NAME
3184
3185 Math::BigInt - Arbitrary size integer/float math package
3186
3187 =head1 SYNOPSIS
3188
3189   use Math::BigInt;
3190
3191   # or make it faster with huge numbers: install (optional)
3192   # Math::BigInt::GMP and always use (it will fall back to
3193   # pure Perl if the GMP library is not installed):
3194   # (See also the L<MATH LIBRARY> section!)
3195
3196   # will warn if Math::BigInt::GMP cannot be found
3197   use Math::BigInt lib => 'GMP';
3198
3199   # to suppress the warning use this:
3200   # use Math::BigInt try => 'GMP';
3201
3202   # dies if GMP cannot be loaded:
3203   # use Math::BigInt only => 'GMP';
3204
3205   my $str = '1234567890';
3206   my @values = (64,74,18);
3207   my $n = 1; my $sign = '-';
3208
3209   # Number creation     
3210   my $x = Math::BigInt->new($str);      # defaults to 0
3211   my $y = $x->copy();                   # make a true copy
3212   my $nan  = Math::BigInt->bnan();      # create a NotANumber
3213   my $zero = Math::BigInt->bzero();     # create a +0
3214   my $inf = Math::BigInt->binf();       # create a +inf
3215   my $inf = Math::BigInt->binf('-');    # create a -inf
3216   my $one = Math::BigInt->bone();       # create a +1
3217   my $mone = Math::BigInt->bone('-');   # create a -1
3218
3219   my $pi = Math::BigInt->bpi();         # returns '3'
3220                                         # see Math::BigFloat::bpi()
3221
3222   $h = Math::BigInt->new('0x123');      # from hexadecimal
3223   $b = Math::BigInt->new('0b101');      # from binary
3224   $o = Math::BigInt->from_oct('0101');  # from octal
3225
3226   # Testing (don't modify their arguments)
3227   # (return true if the condition is met, otherwise false)
3228
3229   $x->is_zero();        # if $x is +0
3230   $x->is_nan();         # if $x is NaN
3231   $x->is_one();         # if $x is +1
3232   $x->is_one('-');      # if $x is -1
3233   $x->is_odd();         # if $x is odd
3234   $x->is_even();        # if $x is even
3235   $x->is_pos();         # if $x > 0
3236   $x->is_neg();         # if $x < 0
3237   $x->is_inf($sign);    # if $x is +inf, or -inf (sign is default '+')
3238   $x->is_int();         # if $x is an integer (not a float)
3239
3240   # comparing and digit/sign extraction
3241   $x->bcmp($y);         # compare numbers (undef,<0,=0,>0)
3242   $x->bacmp($y);        # compare absolutely (undef,<0,=0,>0)
3243   $x->sign();           # return the sign, either +,- or NaN
3244   $x->digit($n);        # return the nth digit, counting from right
3245   $x->digit(-$n);       # return the nth digit, counting from left
3246
3247   # The following all modify their first argument. If you want to preserve
3248   # $x, use $z = $x->copy()->bXXX($y); See under L<CAVEATS> for why this is
3249   # necessary when mixing $a = $b assignments with non-overloaded math.
3250
3251   $x->bzero();          # set $x to 0
3252   $x->bnan();           # set $x to NaN
3253   $x->bone();           # set $x to +1
3254   $x->bone('-');        # set $x to -1
3255   $x->binf();           # set $x to inf
3256   $x->binf('-');        # set $x to -inf
3257
3258   $x->bneg();           # negation
3259   $x->babs();           # absolute value
3260   $x->bnorm();          # normalize (no-op in BigInt)
3261   $x->bnot();           # two's complement (bit wise not)
3262   $x->binc();           # increment $x by 1
3263   $x->bdec();           # decrement $x by 1
3264   
3265   $x->badd($y);         # addition (add $y to $x)
3266   $x->bsub($y);         # subtraction (subtract $y from $x)
3267   $x->bmul($y);         # multiplication (multiply $x by $y)
3268   $x->bdiv($y);         # divide, set $x to quotient
3269                         # return (quo,rem) or quo if scalar
3270
3271   $x->bmuladd($y,$z);   # $x = $x * $y + $z
3272
3273   $x->bmod($y);            # modulus (x % y)
3274   $x->bmodpow($y,$mod);    # modular exponentiation (($x ** $y) % $mod)
3275   $x->bmodinv($mod);       # modular multiplicative inverse
3276   $x->bpow($y);            # power of arguments (x ** y)
3277   $x->blsft($y);           # left shift in base 2
3278   $x->brsft($y);           # right shift in base 2
3279                            # returns (quo,rem) or quo if in scalar context
3280   $x->blsft($y,$n);        # left shift by $y places in base $n
3281   $x->brsft($y,$n);        # right shift by $y places in base $n
3282                            # returns (quo,rem) or quo if in scalar context
3283   
3284   $x->band($y);            # bitwise and
3285   $x->bior($y);            # bitwise inclusive or
3286   $x->bxor($y);            # bitwise exclusive or
3287   $x->bnot();              # bitwise not (two's complement)
3288
3289   $x->bsqrt();             # calculate square-root
3290   $x->broot($y);           # $y'th root of $x (e.g. $y == 3 => cubic root)
3291   $x->bfac();              # factorial of $x (1*2*3*4*..$x)
3292
3293   $x->bnok($y);            # x over y (binomial coefficient n over k)
3294
3295   $x->blog();              # logarithm of $x to base e (Euler's number)
3296   $x->blog($base);         # logarithm of $x to base $base (f.i. 2)
3297   $x->bexp();              # calculate e ** $x where e is Euler's number
3298   
3299   $x->round($A,$P,$mode);  # round to accuracy or precision using mode $mode
3300   $x->bround($n);          # accuracy: preserve $n digits
3301   $x->bfround($n);         # $n > 0: round $nth digits,
3302                            # $n < 0: round to the $nth digit after the
3303                            # dot, no-op for BigInts
3304
3305   # The following do not modify their arguments in BigInt (are no-ops),
3306   # but do so in BigFloat:
3307
3308   $x->bfloor();            # return integer less or equal than $x
3309   $x->bceil();             # return integer greater or equal than $x
3310
3311   # The following do not modify their arguments:
3312
3313   # greatest common divisor (no OO style)
3314   my $gcd = Math::BigInt::bgcd(@values);
3315   # lowest common multiple (no OO style)
3316   my $lcm = Math::BigInt::blcm(@values);
3317
3318   $x->length();            # return number of digits in number
3319   ($xl,$f) = $x->length(); # length of number and length of fraction part,
3320                            # latter is always 0 digits long for BigInts
3321
3322   $x->exponent();          # return exponent as BigInt
3323   $x->mantissa();          # return (signed) mantissa as BigInt
3324   $x->parts();             # return (mantissa,exponent) as BigInt
3325   $x->copy();              # make a true copy of $x (unlike $y = $x;)
3326   $x->as_int();            # return as BigInt (in BigInt: same as copy())
3327   $x->numify();            # return as scalar (might overflow!)
3328   
3329   # conversion to string (do not modify their argument)
3330   $x->bstr();              # normalized string (e.g. '3')
3331   $x->bsstr();             # norm. string in scientific notation (e.g. '3E0')
3332   $x->as_hex();            # as signed hexadecimal string with prefixed 0x
3333   $x->as_bin();            # as signed binary string with prefixed 0b
3334   $x->as_oct();            # as signed octal string with prefixed 0
3335
3336
3337   # precision and accuracy (see section about rounding for more)
3338   $x->precision();         # return P of $x (or global, if P of $x undef)
3339   $x->precision($n);       # set P of $x to $n
3340   $x->accuracy();          # return A of $x (or global, if A of $x undef)
3341   $x->accuracy($n);        # set A $x to $n
3342
3343   # Global methods
3344   Math::BigInt->precision();    # get/set global P for all BigInt objects
3345   Math::BigInt->accuracy();     # get/set global A for all BigInt objects
3346   Math::BigInt->round_mode();   # get/set global round mode, one of
3347                                 # 'even', 'odd', '+inf', '-inf', 'zero', 'trunc' or 'common'
3348   Math::BigInt->config();       # return hash containing configuration
3349
3350 =head1 DESCRIPTION
3351
3352 All operators (including basic math operations) are overloaded if you
3353 declare your big integers as
3354
3355   $i = new Math::BigInt '123_456_789_123_456_789';
3356
3357 Operations with overloaded operators preserve the arguments which is
3358 exactly what you expect.
3359
3360 =over 2
3361
3362 =item Input
3363
3364 Input values to these routines may be any string, that looks like a number
3365 and results in an integer, including hexadecimal and binary numbers.
3366
3367 Scalars holding numbers may also be passed, but note that non-integer numbers
3368 may already have lost precision due to the conversion to float. Quote
3369 your input if you want BigInt to see all the digits:
3370
3371         $x = Math::BigInt->new(12345678890123456789);   # bad
3372         $x = Math::BigInt->new('12345678901234567890'); # good
3373
3374 You can include one underscore between any two digits.
3375
3376 This means integer values like 1.01E2 or even 1000E-2 are also accepted.
3377 Non-integer values result in NaN.
3378
3379 Hexadecimal (prefixed with "0x") and binary numbers (prefixed with "0b")
3380 are accepted, too. Please note that octal numbers are not recognized
3381 by new(), so the following will print "123":
3382
3383         perl -MMath::BigInt -le 'print Math::BigInt->new("0123")'
3384         
3385 To convert an octal number, use from_oct();
3386
3387         perl -MMath::BigInt -le 'print Math::BigInt->from_oct("0123")'
3388
3389 Currently, Math::BigInt::new() defaults to 0, while Math::BigInt::new('')
3390 results in 'NaN'. This might change in the future, so use always the following
3391 explicit forms to get a zero or NaN:
3392
3393         $zero = Math::BigInt->bzero(); 
3394         $nan = Math::BigInt->bnan(); 
3395
3396 C<bnorm()> on a BigInt object is now effectively a no-op, since the numbers 
3397 are always stored in normalized form. If passed a string, creates a BigInt 
3398 object from the input.
3399
3400 =item Output
3401
3402 Output values are BigInt objects (normalized), except for the methods which
3403 return a string (see L<SYNOPSIS>).
3404
3405 Some routines (C<is_odd()>, C<is_even()>, C<is_zero()>, C<is_one()>,
3406 C<is_nan()>, etc.) return true or false, while others (C<bcmp()>, C<bacmp()>)
3407 return either undef (if NaN is involved), <0, 0 or >0 and are suited for sort.
3408
3409 =back
3410
3411 =head1 METHODS
3412
3413 Each of the methods below (except config(), accuracy() and precision())
3414 accepts three additional parameters. These arguments C<$A>, C<$P> and C<$R>
3415 are C<accuracy>, C<precision> and C<round_mode>. Please see the section about
3416 L<ACCURACY and PRECISION> for more information.
3417
3418 =head2 config()
3419
3420         use Data::Dumper;
3421
3422         print Dumper ( Math::BigInt->config() );
3423         print Math::BigInt->config()->{lib},"\n";
3424
3425 Returns a hash containing the configuration, e.g. the version number, lib
3426 loaded etc. The following hash keys are currently filled in with the
3427 appropriate information.
3428
3429         key             Description
3430                         Example
3431         ============================================================
3432         lib             Name of the low-level math library
3433                         Math::BigInt::Calc
3434         lib_version     Version of low-level math library (see 'lib')
3435                         0.30
3436         class           The class name of config() you just called
3437                         Math::BigInt
3438         upgrade         To which class math operations might be upgraded
3439                         Math::BigFloat
3440         downgrade       To which class math operations might be downgraded
3441                         undef
3442         precision       Global precision
3443                         undef
3444         accuracy        Global accuracy
3445                         undef
3446         round_mode      Global round mode
3447                         even
3448         version         version number of the class you used
3449                         1.61
3450         div_scale       Fallback accuracy for div
3451                         40
3452         trap_nan        If true, traps creation of NaN via croak()
3453                         1
3454         trap_inf        If true, traps creation of +inf/-inf via croak()
3455                         1
3456
3457 The following values can be set by passing C<config()> a reference to a hash:
3458
3459         trap_inf trap_nan
3460         upgrade downgrade precision accuracy round_mode div_scale
3461
3462 Example:
3463         
3464         $new_cfg = Math::BigInt->config( { trap_inf => 1, precision => 5 } );
3465
3466 =head2 accuracy()
3467
3468         $x->accuracy(5);                # local for $x
3469         CLASS->accuracy(5);             # global for all members of CLASS
3470                                         # Note: This also applies to new()!
3471
3472         $A = $x->accuracy();            # read out accuracy that affects $x
3473         $A = CLASS->accuracy();         # read out global accuracy
3474
3475 Set or get the global or local accuracy, aka how many significant digits the
3476 results have. If you set a global accuracy, then this also applies to new()!
3477
3478 Warning! The accuracy I<sticks>, e.g. once you created a number under the
3479 influence of C<< CLASS->accuracy($A) >>, all results from math operations with
3480 that number will also be rounded. 
3481
3482 In most cases, you should probably round the results explicitly using one of
3483 L<round()>, L<bround()> or L<bfround()> or by passing the desired accuracy
3484 to the math operation as additional parameter:
3485
3486         my $x = Math::BigInt->new(30000);
3487         my $y = Math::BigInt->new(7);
3488         print scalar $x->copy()->bdiv($y, 2);           # print 4300
3489         print scalar $x->copy()->bdiv($y)->bround(2);   # print 4300
3490
3491 Please see the section about L<ACCURACY and PRECISION> for further details.
3492
3493 Value must be greater than zero. Pass an undef value to disable it:
3494
3495         $x->accuracy(undef);
3496         Math::BigInt->accuracy(undef);
3497
3498 Returns the current accuracy. For C<< $x->accuracy() >> it will return either
3499 the local accuracy, or if not defined, the global. This means the return value
3500 represents the accuracy that will be in effect for $x:
3501
3502         $y = Math::BigInt->new(1234567);        # unrounded
3503         print Math::BigInt->accuracy(4),"\n";   # set 4, print 4
3504         $x = Math::BigInt->new(123456);         # $x will be automatically rounded!
3505         print "$x $y\n";                        # '123500 1234567'
3506         print $x->accuracy(),"\n";              # will be 4
3507         print $y->accuracy(),"\n";              # also 4, since global is 4
3508         print Math::BigInt->accuracy(5),"\n";   # set to 5, print 5
3509         print $x->accuracy(),"\n";              # still 4
3510         print $y->accuracy(),"\n";              # 5, since global is 5
3511
3512 Note: Works also for subclasses like Math::BigFloat. Each class has it's own
3513 globals separated from Math::BigInt, but it is possible to subclass
3514 Math::BigInt and make the globals of the subclass aliases to the ones from
3515 Math::BigInt.
3516
3517 =head2 precision()
3518
3519         $x->precision(-2);      # local for $x, round at the second digit right of the dot
3520         $x->precision(2);       # ditto, round at the second digit left of the dot
3521
3522         CLASS->precision(5);    # Global for all members of CLASS
3523                                 # This also applies to new()!
3524         CLASS->precision(-5);   # ditto
3525
3526         $P = CLASS->precision();        # read out global precision 
3527         $P = $x->precision();           # read out precision that affects $x
3528
3529 Note: You probably want to use L<accuracy()> instead. With L<accuracy> you
3530 set the number of digits each result should have, with L<precision> you
3531 set the place where to round!
3532
3533 C<precision()> sets or gets the global or local precision, aka at which digit
3534 before or after the dot to round all results. A set global precision also
3535 applies to all newly created numbers!
3536
3537 In Math::BigInt, passing a negative number precision has no effect since no
3538 numbers have digits after the dot. In L<Math::BigFloat>, it will round all
3539 results to P digits after the dot.
3540
3541 Please see the section about L<ACCURACY and PRECISION> for further details.
3542
3543 Pass an undef value to disable it:
3544
3545         $x->precision(undef);
3546         Math::BigInt->precision(undef);
3547
3548 Returns the current precision. For C<< $x->precision() >> it will return either
3549 the local precision of $x, or if not defined, the global. This means the return
3550 value represents the prevision that will be in effect for $x:
3551
3552         $y = Math::BigInt->new(1234567);        # unrounded
3553         print Math::BigInt->precision(4),"\n";  # set 4, print 4
3554         $x = Math::BigInt->new(123456);         # will be automatically rounded
3555         print $x;                               # print "120000"!
3556
3557 Note: Works also for subclasses like L<Math::BigFloat>. Each class has its
3558 own globals separated from Math::BigInt, but it is possible to subclass
3559 Math::BigInt and make the globals of the subclass aliases to the ones from
3560 Math::BigInt.
3561
3562 =head2 brsft()
3563
3564         $x->brsft($y,$n);               
3565
3566 Shifts $x right by $y in base $n. Default is base 2, used are usually 10 and
3567 2, but others work, too.
3568
3569 Right shifting usually amounts to dividing $x by $n ** $y and truncating the
3570 result:
3571
3572
3573         $x = Math::BigInt->new(10);
3574         $x->brsft(1);                   # same as $x >> 1: 5
3575         $x = Math::BigInt->new(1234);
3576         $x->brsft(2,10);                # result 12
3577
3578 There is one exception, and that is base 2 with negative $x:
3579
3580
3581         $x = Math::BigInt->new(-5);
3582         print $x->brsft(1);
3583
3584 This will print -3, not -2 (as it would if you divide -5 by 2 and truncate the
3585 result).
3586
3587 =head2 new()
3588
3589         $x = Math::BigInt->new($str,$A,$P,$R);
3590
3591 Creates a new BigInt object from a scalar or another BigInt object. The
3592 input is accepted as decimal, hex (with leading '0x') or binary (with leading
3593 '0b').
3594
3595 See L<Input> for more info on accepted input formats.
3596
3597 =head2 from_oct()
3598
3599         $x = Math::BigInt->from_oct("0775");    # input is octal
3600
3601 =head2 from_hex()
3602
3603         $x = Math::BigInt->from_hex("0xcafe");  # input is hexadecimal
3604
3605 =head2 from_bin()
3606
3607         $x = Math::BigInt->from_bin("0b10011"); # input is binary
3608
3609 =head2 bnan()
3610
3611         $x = Math::BigInt->bnan();
3612
3613 Creates a new BigInt object representing NaN (Not A Number).
3614 If used on an object, it will set it to NaN:
3615
3616         $x->bnan();
3617
3618 =head2 bzero()
3619
3620         $x = Math::BigInt->bzero();
3621
3622 Creates a new BigInt object representing zero.
3623 If used on an object, it will set it to zero:
3624
3625         $x->bzero();
3626
3627 =head2 binf()
3628
3629         $x = Math::BigInt->binf($sign);
3630
3631 Creates a new BigInt object representing infinity. The optional argument is
3632 either '-' or '+', indicating whether you want infinity or minus infinity.
3633 If used on an object, it will set it to infinity:
3634
3635         $x->binf();
3636         $x->binf('-');
3637
3638 =head2 bone()
3639
3640         $x = Math::BigInt->binf($sign);
3641
3642 Creates a new BigInt object representing one. The optional argument is
3643 either '-' or '+', indicating whether you want one or minus one.
3644 If used on an object, it will set it to one:
3645
3646         $x->bone();             # +1
3647         $x->bone('-');          # -1
3648
3649 =head2 is_one()/is_zero()/is_nan()/is_inf()
3650
3651   
3652         $x->is_zero();                  # true if arg is +0
3653         $x->is_nan();                   # true if arg is NaN
3654         $x->is_one();                   # true if arg is +1
3655         $x->is_one('-');                # true if arg is -1
3656         $x->is_inf();                   # true if +inf
3657         $x->is_inf('-');                # true if -inf (sign is default '+')
3658
3659 These methods all test the BigInt for being one specific value and return
3660 true or false depending on the input. These are faster than doing something
3661 like:
3662
3663         if ($x == 0)
3664
3665 =head2 is_pos()/is_neg()/is_positive()/is_negative()
3666         
3667         $x->is_pos();                   # true if > 0
3668         $x->is_neg();                   # true if < 0
3669
3670 The methods return true if the argument is positive or negative, respectively.
3671 C<NaN> is neither positive nor negative, while C<+inf> counts as positive, and
3672 C<-inf> is negative. A C<zero> is neither positive nor negative.
3673
3674 These methods are only testing the sign, and not the value.
3675
3676 C<is_positive()> and C<is_negative()> are aliases to C<is_pos()> and
3677 C<is_neg()>, respectively. C<is_positive()> and C<is_negative()> were
3678 introduced in v1.36, while C<is_pos()> and C<is_neg()> were only introduced
3679 in v1.68.
3680
3681 =head2 is_odd()/is_even()/is_int()
3682
3683         $x->is_odd();                   # true if odd, false for even
3684         $x->is_even();                  # true if even, false for odd
3685         $x->is_int();                   # true if $x is an integer
3686
3687 The return true when the argument satisfies the condition. C<NaN>, C<+inf>,
3688 C<-inf> are not integers and are neither odd nor even.
3689
3690 In BigInt, all numbers except C<NaN>, C<+inf> and C<-inf> are integers.
3691
3692 =head2 bcmp()
3693
3694         $x->bcmp($y);
3695
3696 Compares $x with $y and takes the sign into account.
3697 Returns -1, 0, 1 or undef.
3698
3699 =head2 bacmp()
3700
3701         $x->bacmp($y);
3702
3703 Compares $x with $y while ignoring their sign. Returns -1, 0, 1 or undef.
3704
3705 =head2 sign()
3706
3707         $x->sign();
3708
3709 Return the sign, of $x, meaning either C<+>, C<->, C<-inf>, C<+inf> or NaN.
3710
3711 If you want $x to have a certain sign, use one of the following methods:
3712
3713         $x->babs();             # '+'
3714         $x->babs()->bneg();     # '-'
3715         $x->bnan();             # 'NaN'
3716         $x->binf();             # '+inf'
3717         $x->binf('-');          # '-inf'
3718
3719 =head2 digit()
3720
3721         $x->digit($n);          # return the nth digit, counting from right
3722
3723 If C<$n> is negative, returns the digit counting from left.
3724
3725 =head2 bneg()
3726
3727         $x->bneg();
3728
3729 Negate the number, e.g. change the sign between '+' and '-', or between '+inf'
3730 and '-inf', respectively. Does nothing for NaN or zero.
3731
3732 =head2 babs()
3733
3734         $x->babs();
3735
3736 Set the number to its absolute value, e.g. change the sign from '-' to '+'
3737 and from '-inf' to '+inf', respectively. Does nothing for NaN or positive
3738 numbers.
3739
3740 =head2 bnorm()
3741
3742         $x->bnorm();                    # normalize (no-op)
3743
3744 =head2 bnot()
3745
3746         $x->bnot();                     
3747
3748 Two's complement (bitwise not). This is equivalent to
3749
3750         $x->binc()->bneg();
3751
3752 but faster.
3753
3754 =head2 binc()
3755
3756         $x->binc();                     # increment x by 1
3757
3758 =head2 bdec()
3759
3760         $x->bdec();                     # decrement x by 1
3761
3762 =head2 badd()
3763
3764         $x->badd($y);                   # addition (add $y to $x)
3765
3766 =head2 bsub()
3767
3768         $x->bsub($y);                   # subtraction (subtract $y from $x)
3769
3770 =head2 bmul()
3771
3772         $x->bmul($y);                   # multiplication (multiply $x by $y)
3773
3774 =head2 bmuladd()
3775
3776         $x->bmuladd($y,$z);
3777
3778 Multiply $x by $y, and then add $z to the result,
3779
3780 This method was added in v1.87 of Math::BigInt (June 2007).
3781
3782 =head2 bdiv()
3783
3784         $x->bdiv($y);                   # divide, set $x to quotient
3785                                         # return (quo,rem) or quo if scalar
3786
3787 =head2 bmod()
3788
3789         $x->bmod($y);                   # modulus (x % y)
3790
3791 =head2 bmodinv()
3792
3793         $x->bmodinv($mod);              # modular multiplicative inverse
3794
3795 Returns the multiplicative inverse of C<$x> modulo C<$mod>. If
3796
3797         $y = $x -> copy() -> bmodinv($mod)
3798
3799 then C<$y> is the number closest to zero, and with the same sign as C<$mod>,
3800 satisfying
3801
3802         ($x * $y) % $mod = 1 % $mod
3803
3804 If C<$x> and C<$y> are non-zero, they must be relative primes, i.e.,
3805 C<bgcd($y, $mod)==1>. 'C<NaN>' is returned when no modular multiplicative
3806 inverse exists.
3807
3808 =head2 bmodpow()
3809
3810         $num->bmodpow($exp,$mod);       # modular exponentiation
3811                                         # ($num**$exp % $mod)
3812
3813 Returns the value of C<$num> taken to the power C<$exp> in the modulus
3814 C<$mod> using binary exponentiation.  C<bmodpow> is far superior to
3815 writing
3816
3817         $num ** $exp % $mod
3818
3819 because it is much faster - it reduces internal variables into
3820 the modulus whenever possible, so it operates on smaller numbers.
3821
3822 C<bmodpow> also supports negative exponents.
3823
3824         bmodpow($num, -1, $mod)
3825
3826 is exactly equivalent to
3827
3828         bmodinv($num, $mod)
3829
3830 =head2 bpow()
3831
3832         $x->bpow($y);                   # power of arguments (x ** y)
3833
3834 =head2 blog()
3835
3836         $x->blog($base, $accuracy);     # logarithm of x to the base $base
3837
3838 If C<$base> is not defined, Euler's number (e) is used:
3839
3840         print $x->blog(undef, 100);     # log(x) to 100 digits
3841
3842 =head2 bexp()
3843
3844         $x->bexp($accuracy);            # calculate e ** X
3845
3846 Calculates the expression C<e ** $x> where C<e> is Euler's number.
3847
3848 This method was added in v1.82 of Math::BigInt (April 2007).
3849
3850 See also L<blog()>.
3851
3852 =head2 bnok()
3853
3854         $x->bnok($y);              # x over y (binomial coefficient n over k)
3855
3856 Calculates the binomial coefficient n over k, also called the "choose"
3857 function. The result is equivalent to:
3858
3859         ( n )      n!
3860         | - |  = -------
3861         ( k )    k!(n-k)!
3862
3863 This method was added in v1.84 of Math::BigInt (April 2007).
3864
3865 =head2 bpi()
3866
3867         print Math::BigInt->bpi(100), "\n";             # 3
3868
3869 Returns PI truncated to an integer, with the argument being ignored. This means
3870 under BigInt this always returns C<3>.
3871
3872 If upgrading is in effect, returns PI, rounded to N digits with the
3873 current rounding mode:
3874
3875         use Math::BigFloat;
3876         use Math::BigInt upgrade => Math::BigFloat;
3877         print Math::BigInt->bpi(3), "\n";               # 3.14
3878         print Math::BigInt->bpi(100), "\n";             # 3.1415....
3879
3880 This method was added in v1.87 of Math::BigInt (June 2007).
3881
3882 =head2 bcos()
3883
3884         my $x = Math::BigInt->new(1);
3885         print $x->bcos(100), "\n";
3886
3887 Calculate the cosinus of $x, modifying $x in place.
3888
3889 In BigInt, unless upgrading is in effect, the result is truncated to an
3890 integer.
3891
3892 This method was added in v1.87 of Math::BigInt (June 2007).
3893
3894 =head2 bsin()
3895
3896         my $x = Math::BigInt->new(1);
3897         print $x->bsin(100), "\n";
3898
3899 Calculate the sinus of $x, modifying $x in place.
3900
3901 In BigInt, unless upgrading is in effect, the result is truncated to an
3902 integer.
3903
3904 This method was added in v1.87 of Math::BigInt (June 2007).
3905
3906 =head2 batan2()
3907
3908         my $x = Math::BigInt->new(1);
3909         my $y = Math::BigInt->new(1);
3910         print $y->batan2($x), "\n";
3911
3912 Calculate the arcus tangens of C<$y> divided by C<$x>, modifying $y in place.
3913
3914 In BigInt, unless upgrading is in effect, the result is truncated to an
3915 integer.
3916
3917 This method was added in v1.87 of Math::BigInt (June 2007).
3918
3919 =head2 batan()
3920
3921         my $x = Math::BigFloat->new(0.5);
3922         print $x->batan(100), "\n";
3923
3924 Calculate the arcus tangens of $x, modifying $x in place.
3925
3926 In BigInt, unless upgrading is in effect, the result is truncated to an
3927 integer.
3928
3929 This method was added in v1.87 of Math::BigInt (June 2007).
3930
3931 =head2 blsft()
3932
3933         $x->blsft($y);          # left shift in base 2
3934         $x->blsft($y,$n);       # left shift, in base $n (like 10)
3935
3936 =head2 brsft()
3937
3938         $x->brsft($y);          # right shift in base 2
3939         $x->brsft($y,$n);       # right shift, in base $n (like 10)
3940
3941 =head2 band()
3942
3943         $x->band($y);                   # bitwise and
3944
3945 =head2 bior()
3946
3947         $x->bior($y);                   # bitwise inclusive or
3948
3949 =head2 bxor()
3950
3951         $x->bxor($y);                   # bitwise exclusive or
3952
3953 =head2 bnot()
3954
3955         $x->bnot();                     # bitwise not (two's complement)
3956
3957 =head2 bsqrt()
3958
3959         $x->bsqrt();                    # calculate square-root
3960
3961 =head2 broot()
3962
3963         $x->broot($N);
3964
3965 Calculates the N'th root of C<$x>.
3966
3967 =head2 bfac()
3968
3969         $x->bfac();                     # factorial of $x (1*2*3*4*..$x)
3970
3971 =head2 round()
3972
3973         $x->round($A,$P,$round_mode);
3974         
3975 Round $x to accuracy C<$A> or precision C<$P> using the round mode
3976 C<$round_mode>.
3977
3978 =head2 bround()
3979
3980         $x->bround($N);               # accuracy: preserve $N digits
3981
3982 =head2 bfround()
3983
3984         $x->bfround($N);
3985
3986 If N is > 0, rounds to the Nth digit from the left. If N < 0, rounds to
3987 the Nth digit after the dot. Since BigInts are integers, the case N < 0
3988 is a no-op for them.
3989
3990 Examples:
3991
3992         Input           N               Result
3993         ===================================================
3994         123456.123456   3               123500
3995         123456.123456   2               123450
3996         123456.123456   -2              123456.12
3997         123456.123456   -3              123456.123
3998
3999 =head2 bfloor()
4000
4001         $x->bfloor();                   
4002
4003 Set $x to the integer less or equal than $x. This is a no-op in BigInt, but
4004 does change $x in BigFloat.
4005
4006 =head2 bceil()
4007
4008         $x->bceil();
4009
4010 Set $x to the integer greater or equal than $x. This is a no-op in BigInt, but
4011 does change $x in BigFloat.
4012
4013 =head2 bgcd()
4014
4015         bgcd(@values);          # greatest common divisor (no OO style)
4016
4017 =head2 blcm()
4018
4019         blcm(@values);          # lowest common multiple (no OO style)
4020
4021 head2 length()
4022
4023         $x->length();
4024         ($xl,$fl) = $x->length();
4025
4026 Returns the number of digits in the decimal representation of the number.
4027 In list context, returns the length of the integer and fraction part. For
4028 BigInt's, the length of the fraction part will always be 0.
4029
4030 =head2 exponent()
4031
4032         $x->exponent();
4033
4034 Return the exponent of $x as BigInt.
4035
4036 =head2 mantissa()
4037
4038         $x->mantissa();
4039
4040 Return the signed mantissa of $x as BigInt.
4041
4042 =head2 parts()
4043
4044         $x->parts();            # return (mantissa,exponent) as BigInt
4045
4046 =head2 copy()
4047
4048         $x->copy();             # make a true copy of $x (unlike $y = $x;)
4049
4050 =head2 as_int()/as_number()
4051
4052         $x->as_int();   
4053
4054 Returns $x as a BigInt (truncated towards zero). In BigInt this is the same as
4055 C<copy()>. 
4056
4057 C<as_number()> is an alias to this method. C<as_number> was introduced in
4058 v1.22, while C<as_int()> was only introduced in v1.68.
4059   
4060 =head2 bstr()
4061
4062         $x->bstr();
4063
4064 Returns a normalized string representation of C<$x>.
4065
4066 =head2 bsstr()
4067
4068         $x->bsstr();            # normalized string in scientific notation
4069
4070 =head2 as_hex()
4071
4072         $x->as_hex();           # as signed hexadecimal string with prefixed 0x
4073
4074 =head2 as_bin()
4075
4076         $x->as_bin();           # as signed binary string with prefixed 0b
4077
4078 =head2 as_oct()
4079
4080         $x->as_oct();           # as signed octal string with prefixed 0
4081
4082 =head2 numify()
4083
4084         print $x->numify();
4085
4086 This returns a normal Perl scalar from $x. It is used automatically
4087 whenever a scalar is needed, for instance in array index operations.
4088
4089 This loses precision, to avoid this use L<as_int()> instead.
4090
4091 =head2 modify()
4092
4093         $x->modify('bpowd');
4094
4095 This method returns 0 if the object can be modified with the given
4096 operation, or 1 if not.
4097
4098 This is used for instance by L<Math::BigInt::Constant>.
4099
4100 =head2 upgrade()/downgrade()
4101
4102 Set/get the class for downgrade/upgrade operations. Thuis is used
4103 for instance by L<bignum>. The defaults are '', thus the following
4104 operation will create a BigInt, not a BigFloat:
4105
4106         my $i = Math::BigInt->new(123);
4107         my $f = Math::BigFloat->new('123.1');
4108
4109         print $i + $f,"\n";                     # print 246
4110
4111 =head2 div_scale()
4112
4113 Set/get the number of digits for the default precision in divide
4114 operations.
4115
4116 =head2 round_mode()
4117
4118 Set/get the current round mode.
4119
4120 =head1 ACCURACY and PRECISION
4121
4122 Since version v1.33, Math::BigInt and Math::BigFloat have full support for
4123 accuracy and precision based rounding, both automatically after every
4124 operation, as well as manually.
4125
4126 This section describes the accuracy/precision handling in Math::Big* as it
4127 used to be and as it is now, complete with an explanation of all terms and
4128 abbreviations.
4129
4130 Not yet implemented things (but with correct description) are marked with '!',
4131 things that need to be answered are marked with '?'.
4132
4133 In the next paragraph follows a short description of terms used here (because
4134 these may differ from terms used by others people or documentation).
4135
4136 During the rest of this document, the shortcuts A (for accuracy), P (for
4137 precision), F (fallback) and R (rounding mode) will be used.
4138
4139 =head2 Precision P
4140
4141 A fixed number of digits before (positive) or after (negative)
4142 the decimal point. For example, 123.45 has a precision of -2. 0 means an
4143 integer like 123 (or 120). A precision of 2 means two digits to the left
4144 of the decimal point are zero, so 123 with P = 1 becomes 120. Note that
4145 numbers with zeros before the decimal point may have different precisions,
4146 because 1200 can have p = 0, 1 or 2 (depending on what the initial value
4147 was). It could also have p < 0, when the digits after the decimal point
4148 are zero.
4149
4150 The string output (of floating point numbers) will be padded with zeros:
4151  
4152         Initial value   P       A       Result          String
4153         ------------------------------------------------------------
4154         1234.01         -3              1000            1000
4155         1234            -2              1200            1200
4156         1234.5          -1              1230            1230
4157         1234.001        1               1234            1234.0
4158         1234.01         0               1234            1234
4159         1234.01         2               1234.01         1234.01
4160         1234.01         5               1234.01         1234.01000
4161
4162 For BigInts, no padding occurs.
4163
4164 =head2 Accuracy A
4165
4166 Number of significant digits. Leading zeros are not counted. A
4167 number may have an accuracy greater than the non-zero digits
4168 when there are zeros in it or trailing zeros. For example, 123.456 has
4169 A of 6, 10203 has 5, 123.0506 has 7, 123.450000 has 8 and 0.000123 has 3.
4170
4171 The string output (of floating point numbers) will be padded with zeros:
4172
4173         Initial value   P       A       Result          String
4174         ------------------------------------------------------------
4175         1234.01                 3       1230            1230
4176         1234.01                 6       1234.01         1234.01
4177         1234.1                  8       1234.1          1234.1000
4178
4179 For BigInts, no padding occurs.
4180
4181 =head2 Fallback F
4182
4183 When both A and P are undefined, this is used as a fallback accuracy when
4184 dividing numbers.
4185
4186 =head2 Rounding mode R
4187
4188 When rounding a number, different 'styles' or 'kinds'
4189 of rounding are possible. (Note that random rounding, as in
4190 Math::Round, is not implemented.)
4191
4192 =over 2
4193
4194 =item 'trunc'
4195
4196 truncation invariably removes all digits following the
4197 rounding place, replacing them with zeros. Thus, 987.65 rounded
4198 to tens (P=1) becomes 980, and rounded to the fourth sigdig
4199 becomes 987.6 (A=4). 123.456 rounded to the second place after the
4200 decimal point (P=-2) becomes 123.46.
4201
4202 All other implemented styles of rounding attempt to round to the
4203 "nearest digit." If the digit D immediately to the right of the
4204 rounding place (skipping the decimal point) is greater than 5, the
4205 number is incremented at the rounding place (possibly causing a
4206 cascade of incrementation): e.g. when rounding to units, 0.9 rounds
4207 to 1, and -19.9 rounds to -20. If D < 5, the number is similarly
4208 truncated at the rounding place: e.g. when rounding to units, 0.4
4209 rounds to 0, and -19.4 rounds to -19.
4210
4211 However the results of other styles of rounding differ if the
4212 digit immediately to the right of the rounding place (skipping the
4213 decimal point) is 5 and if there are no digits, or no digits other
4214 than 0, after that 5. In such cases:
4215
4216 =item 'even'
4217
4218 rounds the digit at the rounding place to 0, 2, 4, 6, or 8
4219 if it is not already. E.g., when rounding to the first sigdig, 0.45
4220 becomes 0.4, -0.55 becomes -0.6, but 0.4501 becomes 0.5.
4221
4222 =item 'odd'
4223
4224 rounds the digit at the rounding place to 1, 3, 5, 7, or 9 if
4225 it is not already. E.g., when rounding to the first sigdig, 0.45
4226 becomes 0.5, -0.55 becomes -0.5, but 0.5501 becomes 0.6.
4227
4228 =item '+inf'
4229
4230 round to plus infinity, i.e. always round up. E.g., when
4231 rounding to the first sigdig, 0.45 becomes 0.5, -0.55 becomes -0.5,
4232 and 0.4501 also becomes 0.5.
4233
4234 =item '-inf'
4235
4236 round to minus infinity, i.e. always round down. E.g., when
4237 rounding to the first sigdig, 0.45 becomes 0.4, -0.55 becomes -0.6,
4238 but 0.4501 becomes 0.5.
4239
4240 =item 'zero'
4241
4242 round to zero, i.e. positive numbers down, negative ones up.
4243 E.g., when rounding to the first sigdig, 0.45 becomes 0.4, -0.55
4244 becomes -0.5, but 0.4501 becomes 0.5.
4245
4246 =item 'common'
4247
4248 round up if the digit immediately to the right of the rounding place
4249 is 5 or greater, otherwise round down. E.g., 0.15 becomes 0.2 and
4250 0.149 becomes 0.1.
4251
4252 =back
4253
4254 The handling of A & P in MBI/MBF (the old core code shipped with Perl
4255 versions <= 5.7.2) is like this:
4256
4257 =over 2
4258
4259 =item Precision
4260
4261   * ffround($p) is able to round to $p number of digits after the decimal
4262     point
4263   * otherwise P is unused
4264
4265 =item Accuracy (significant digits)
4266
4267   * fround($a) rounds to $a significant digits
4268   * only fdiv() and fsqrt() take A as (optional) parameter
4269     + other operations simply create the same number (fneg etc), or more (fmul)
4270       of digits
4271     + rounding/truncating is only done when explicitly calling one of fround
4272       or ffround, and never for BigInt (not implemented)
4273   * fsqrt() simply hands its accuracy argument over to fdiv.
4274   * the documentation and the comment in the code indicate two different ways
4275     on how fdiv() determines the maximum number of digits it should calculate,
4276     and the actual code does yet another thing
4277     POD:
4278       max($Math::BigFloat::div_scale,length(dividend)+length(divisor))
4279     Comment:
4280       result has at most max(scale, length(dividend), length(divisor)) digits
4281     Actual code:
4282       scale = max(scale, length(dividend)-1,length(divisor)-1);
4283       scale += length(divisor) - length(dividend);
4284     So for lx = 3, ly = 9, scale = 10, scale will actually be 16 (10+9-3).
4285     Actually, the 'difference' added to the scale is calculated from the
4286     number of "significant digits" in dividend and divisor, which is derived
4287     by looking at the length of the mantissa. Which is wrong, since it includes
4288     the + sign (oops) and actually gets 2 for '+100' and 4 for '+101'. Oops
4289     again. Thus 124/3 with div_scale=1 will get you '41.3' based on the strange
4290     assumption that 124 has 3 significant digits, while 120/7 will get you
4291     '17', not '17.1' since 120 is thought to have 2 significant digits.
4292     The rounding after the division then uses the remainder and $y to determine
4293     whether it must round up or down.
4294  ?  I have no idea which is the right way. That's why I used a slightly more
4295  ?  simple scheme and tweaked the few failing testcases to match it.
4296
4297 =back
4298
4299 This is how it works now:
4300
4301 =over 2
4302
4303 =item Setting/Accessing
4304
4305   * You can set the A global via C<< Math::BigInt->accuracy() >> or
4306     C<< Math::BigFloat->accuracy() >> or whatever class you are using.
4307   * You can also set P globally by using C<< Math::SomeClass->precision() >>
4308     likewise.
4309   * Globals are classwide, and not inherited by subclasses.
4310   * to undefine A, use C<< Math::SomeCLass->accuracy(undef); >>
4311   * to undefine P, use C<< Math::SomeClass->precision(undef); >>
4312   * Setting C<< Math::SomeClass->accuracy() >> clears automatically
4313     C<< Math::SomeClass->precision() >>, and vice versa.
4314   * To be valid, A must be > 0, P can have any value.
4315   * If P is negative, this means round to the P'th place to the right of the
4316     decimal point; positive values mean to the left of the decimal point.
4317     P of 0 means round to integer.
4318   * to find out the current global A, use C<< Math::SomeClass->accuracy() >>
4319   * to find out the current global P, use C<< Math::SomeClass->precision() >>
4320   * use C<< $x->accuracy() >> respective C<< $x->precision() >> for the local
4321     setting of C<< $x >>.
4322   * Please note that C<< $x->accuracy() >> respective C<< $x->precision() >>
4323     return eventually defined global A or P, when C<< $x >>'s A or P is not
4324     set.
4325
4326 =item Creating numbers
4327
4328   * When you create a number, you can give the desired A or P via:
4329     $x = Math::BigInt->new($number,$A,$P);
4330   * Only one of A or P can be defined, otherwise the result is NaN
4331   * If no A or P is give ($x = Math::BigInt->new($number) form), then the
4332     globals (if set) will be used. Thus changing the global defaults later on
4333     will not change the A or P of previously created numbers (i.e., A and P of
4334     $x will be what was in effect when $x was created)
4335   * If given undef for A and P, B<no> rounding will occur, and the globals will
4336     B<not> be used. This is used by subclasses to create numbers without
4337     suffering rounding in the parent. Thus a subclass is able to have its own
4338     globals enforced upon creation of a number by using
4339     C<< $x = Math::BigInt->new($number,undef,undef) >>:
4340
4341         use Math::BigInt::SomeSubclass;
4342         use Math::BigInt;
4343
4344         Math::BigInt->accuracy(2);
4345         Math::BigInt::SomeSubClass->accuracy(3);
4346         $x = Math::BigInt::SomeSubClass->new(1234);     
4347
4348     $x is now 1230, and not 1200. A subclass might choose to implement
4349     this otherwise, e.g. falling back to the parent's A and P.
4350
4351 =item Usage
4352
4353   * If A or P are enabled/defined, they are used to round the result of each
4354     operation according to the rules below
4355   * Negative P is ignored in Math::BigInt, since BigInts never have digits
4356     after the decimal point
4357   * Math::BigFloat uses Math::BigInt internally, but setting A or P inside
4358     Math::BigInt as globals does not tamper with the parts of a BigFloat.
4359     A flag is used to mark all Math::BigFloat numbers as 'never round'.
4360
4361 =item Precedence
4362
4363   * It only makes sense that a number has only one of A or P at a time.
4364     If you set either A or P on one object, or globally, the other one will
4365     be automatically cleared.
4366   * If two objects are involved in an operation, and one of them has A in
4367     effect, and the other P, this results in an error (NaN).
4368   * A takes precedence over P (Hint: A comes before P).
4369     If neither of them is defined, nothing is used, i.e. the result will have
4370     as many digits as it can (with an exception for fdiv/fsqrt) and will not
4371     be rounded.
4372   * There is another setting for fdiv() (and thus for fsqrt()). If neither of
4373     A or P is defined, fdiv() will use a fallback (F) of $div_scale digits.
4374     If either the dividend's or the divisor's mantissa has more digits than
4375     the value of F, the higher value will be used instead of F.
4376     This is to limit the digits (A) of the result (just consider what would
4377     happen with unlimited A and P in the case of 1/3 :-)
4378   * fdiv will calculate (at least) 4 more digits than required (determined by
4379     A, P or F), and, if F is not used, round the result
4380     (this will still fail in the case of a result like 0.12345000000001 with A
4381     or P of 5, but this can not be helped - or can it?)
4382   * Thus you can have the math done by on Math::Big* class in two modi:
4383     + never round (this is the default):
4384       This is done by setting A and P to undef. No math operation
4385       will round the result, with fdiv() and fsqrt() as exceptions to guard
4386       against overflows. You must explicitly call bround(), bfround() or
4387       round() (the latter with parameters).
4388       Note: Once you have rounded a number, the settings will 'stick' on it
4389       and 'infect' all other numbers engaged in math operations with it, since
4390       local settings have the highest precedence. So, to get SaferRound[tm],
4391       use a copy() before rounding like this:
4392
4393         $x = Math::BigFloat->new(12.34);
4394         $y = Math::BigFloat->new(98.76);
4395         $z = $x * $y;                           # 1218.6984
<