Merge branch 'vincent/rvalue_stmt_given' into blead
[perl.git] / pod / perlsyn.pod
1 =head1 NAME
2 X<syntax>
3
4 perlsyn - Perl syntax
5
6 =head1 DESCRIPTION
7
8 A Perl program consists of a sequence of declarations and statements
9 which run from the top to the bottom.  Loops, subroutines and other
10 control structures allow you to jump around within the code.
11
12 Perl is a B<free-form> language, you can format and indent it however
13 you like.  Whitespace mostly serves to separate tokens, unlike
14 languages like Python where it is an important part of the syntax.
15
16 Many of Perl's syntactic elements are B<optional>.  Rather than
17 requiring you to put parentheses around every function call and
18 declare every variable, you can often leave such explicit elements off
19 and Perl will figure out what you meant.  This is known as B<Do What I
20 Mean>, abbreviated B<DWIM>.  It allows programmers to be B<lazy> and to
21 code in a style with which they are comfortable.
22
23 Perl B<borrows syntax> and concepts from many languages: awk, sed, C,
24 Bourne Shell, Smalltalk, Lisp and even English.  Other
25 languages have borrowed syntax from Perl, particularly its regular
26 expression extensions.  So if you have programmed in another language
27 you will see familiar pieces in Perl.  They often work the same, but
28 see L<perltrap> for information about how they differ.
29
30 =head2 Declarations
31 X<declaration> X<undef> X<undefined> X<uninitialized>
32
33 The only things you need to declare in Perl are report formats and
34 subroutines (and sometimes not even subroutines).  A variable holds
35 the undefined value (C<undef>) until it has been assigned a defined
36 value, which is anything other than C<undef>.  When used as a number,
37 C<undef> is treated as C<0>; when used as a string, it is treated as
38 the empty string, C<"">; and when used as a reference that isn't being
39 assigned to, it is treated as an error.  If you enable warnings,
40 you'll be notified of an uninitialized value whenever you treat
41 C<undef> as a string or a number.  Well, usually.  Boolean contexts,
42 such as:
43
44     my $a;
45     if ($a) {}
46
47 are exempt from warnings (because they care about truth rather than
48 definedness).  Operators such as C<++>, C<-->, C<+=>,
49 C<-=>, and C<.=>, that operate on undefined left values such as:
50
51     my $a;
52     $a++;
53
54 are also always exempt from such warnings.
55
56 A declaration can be put anywhere a statement can, but has no effect on
57 the execution of the primary sequence of statements--declarations all
58 take effect at compile time.  Typically all the declarations are put at
59 the beginning or the end of the script.  However, if you're using
60 lexically-scoped private variables created with C<my()>, you'll
61 have to make sure
62 your format or subroutine definition is within the same block scope
63 as the my if you expect to be able to access those private variables.
64
65 Declaring a subroutine allows a subroutine name to be used as if it were a
66 list operator from that point forward in the program.  You can declare a
67 subroutine without defining it by saying C<sub name>, thus:
68 X<subroutine, declaration>
69
70     sub myname;
71     $me = myname $0             or die "can't get myname";
72
73 Note that myname() functions as a list operator, not as a unary operator;
74 so be careful to use C<or> instead of C<||> in this case.  However, if
75 you were to declare the subroutine as C<sub myname ($)>, then
76 C<myname> would function as a unary operator, so either C<or> or
77 C<||> would work.
78
79 Subroutines declarations can also be loaded up with the C<require> statement
80 or both loaded and imported into your namespace with a C<use> statement.
81 See L<perlmod> for details on this.
82
83 A statement sequence may contain declarations of lexically-scoped
84 variables, but apart from declaring a variable name, the declaration acts
85 like an ordinary statement, and is elaborated within the sequence of
86 statements as if it were an ordinary statement.  That means it actually
87 has both compile-time and run-time effects.
88
89 =head2 Comments
90 X<comment> X<#>
91
92 Text from a C<"#"> character until the end of the line is a comment,
93 and is ignored.  Exceptions include C<"#"> inside a string or regular
94 expression.
95
96 =head2 Simple Statements
97 X<statement> X<semicolon> X<expression> X<;>
98
99 The only kind of simple statement is an expression evaluated for its
100 side effects.  Every simple statement must be terminated with a
101 semicolon, unless it is the final statement in a block, in which case
102 the semicolon is optional.  (A semicolon is still encouraged if the
103 block takes up more than one line, because you may eventually add
104 another line.)  Note that there are some operators like C<eval {}> and
105 C<do {}> that look like compound statements, but aren't (they're just
106 TERMs in an expression), and thus need an explicit termination if used
107 as the last item in a statement.
108
109 =head2 Truth and Falsehood
110 X<truth> X<falsehood> X<true> X<false> X<!> X<not> X<negation> X<0>
111
112 The number 0, the strings C<'0'> and C<''>, the empty list C<()>, and
113 C<undef> are all false in a boolean context. All other values are true.
114 Negation of a true value by C<!> or C<not> returns a special false value.
115 When evaluated as a string it is treated as C<''>, but as a number, it
116 is treated as 0.
117
118 =head2 Statement Modifiers
119 X<statement modifier> X<modifier> X<if> X<unless> X<while>
120 X<until> X<when> X<foreach> X<for>
121
122 Any simple statement may optionally be followed by a I<SINGLE> modifier,
123 just before the terminating semicolon (or block ending).  The possible
124 modifiers are:
125
126     if EXPR
127     unless EXPR
128     while EXPR
129     until EXPR
130     when EXPR
131     for LIST
132     foreach LIST
133
134 The C<EXPR> following the modifier is referred to as the "condition".
135 Its truth or falsehood determines how the modifier will behave.
136
137 C<if> executes the statement once I<if> and only if the condition is
138 true.  C<unless> is the opposite, it executes the statement I<unless>
139 the condition is true (i.e., if the condition is false).
140
141     print "Basset hounds got long ears" if length $ear >= 10;
142     go_outside() and play() unless $is_raining;
143
144 C<when> executes the statement I<when> C<$_> smart matches C<EXPR>, and
145 then either C<break>s out if it's enclosed in a C<given> scope or skips
146 to the C<next> element when it lies directly inside a C<for> loop.
147 See also L</"Switch statements">.
148
149     given ($something) {
150         $abc    = 1 when /^abc/;
151         $just_a = 1 when /^a/;
152         $other  = 1;
153     }
154
155     for (@names) {
156         admin($_)   when [ qw/Alice Bob/ ];
157         regular($_) when [ qw/Chris David Ellen/ ];
158     }
159
160 The C<foreach> modifier is an iterator: it executes the statement once
161 for each item in the LIST (with C<$_> aliased to each item in turn).
162
163     print "Hello $_!\n" foreach qw(world Dolly nurse);
164
165 C<while> repeats the statement I<while> the condition is true.
166 C<until> does the opposite, it repeats the statement I<until> the
167 condition is true (or while the condition is false):
168
169     # Both of these count from 0 to 10.
170     print $i++ while $i <= 10;
171     print $j++ until $j >  10;
172
173 The C<while> and C<until> modifiers have the usual "C<while> loop"
174 semantics (conditional evaluated first), except when applied to a
175 C<do>-BLOCK (or to the deprecated C<do>-SUBROUTINE statement), in
176 which case the block executes once before the conditional is
177 evaluated.  This is so that you can write loops like:
178
179     do {
180         $line = <STDIN>;
181         ...
182     } until $line  eq ".\n";
183
184 See L<perlfunc/do>.  Note also that the loop control statements described
185 later will I<NOT> work in this construct, because modifiers don't take
186 loop labels.  Sorry.  You can always put another block inside of it
187 (for C<next>) or around it (for C<last>) to do that sort of thing.
188 For C<next>, just double the braces:
189 X<next> X<last> X<redo>
190
191     do {{
192         next if $x == $y;
193         # do something here
194     }} until $x++ > $z;
195
196 For C<last>, you have to be more elaborate:
197 X<last>
198
199     LOOP: { 
200             do {
201                 last if $x = $y**2;
202                 # do something here
203             } while $x++ <= $z;
204     }
205
206 B<NOTE:> The behaviour of a C<my> statement modified with a statement
207 modifier conditional or loop construct (e.g. C<my $x if ...>) is
208 B<undefined>.  The value of the C<my> variable may be C<undef>, any
209 previously assigned value, or possibly anything else.  Don't rely on
210 it.  Future versions of perl might do something different from the
211 version of perl you try it out on.  Here be dragons.
212 X<my>
213
214 =head2 Compound Statements
215 X<statement, compound> X<block> X<bracket, curly> X<curly bracket> X<brace>
216 X<{> X<}> X<if> X<unless> X<while> X<until> X<foreach> X<for> X<continue>
217
218 In Perl, a sequence of statements that defines a scope is called a block.
219 Sometimes a block is delimited by the file containing it (in the case
220 of a required file, or the program as a whole), and sometimes a block
221 is delimited by the extent of a string (in the case of an eval).
222
223 But generally, a block is delimited by curly brackets, also known as braces.
224 We will call this syntactic construct a BLOCK.
225
226 The following compound statements may be used to control flow:
227
228     if (EXPR) BLOCK
229     if (EXPR) BLOCK else BLOCK
230     if (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
231     unless (EXPR) BLOCK
232     unless (EXPR) BLOCK else BLOCK
233     unless (EXPR) BLOCK elsif (EXPR) BLOCK ... else BLOCK
234     LABEL while (EXPR) BLOCK
235     LABEL while (EXPR) BLOCK continue BLOCK
236     LABEL until (EXPR) BLOCK
237     LABEL until (EXPR) BLOCK continue BLOCK
238     LABEL for (EXPR; EXPR; EXPR) BLOCK
239     LABEL foreach VAR (LIST) BLOCK
240     LABEL foreach VAR (LIST) BLOCK continue BLOCK
241     LABEL BLOCK continue BLOCK
242
243 Note that, unlike C and Pascal, these are defined in terms of BLOCKs,
244 not statements.  This means that the curly brackets are I<required>--no
245 dangling statements allowed.  If you want to write conditionals without
246 curly brackets there are several other ways to do it.  The following
247 all do the same thing:
248
249     if (!open(FOO)) { die "Can't open $FOO: $!"; }
250     die "Can't open $FOO: $!" unless open(FOO);
251     open(FOO) or die "Can't open $FOO: $!";     # FOO or bust!
252     open(FOO) ? 'hi mom' : die "Can't open $FOO: $!";
253                         # a bit exotic, that last one
254
255 The C<if> statement is straightforward.  Because BLOCKs are always
256 bounded by curly brackets, there is never any ambiguity about which
257 C<if> an C<else> goes with.  If you use C<unless> in place of C<if>,
258 the sense of the test is reversed. Like C<if>, C<unless> can be followed
259 by C<else>. C<unless> can even be followed by one or more C<elsif>
260 statements, though you may want to think twice before using that particular
261 language construct, as everyone reading your code will have to think at least
262 twice before they can understand what's going on.
263
264 The C<while> statement executes the block as long as the expression is
265 L<true|/"Truth and Falsehood">.
266 The C<until> statement executes the block as long as the expression is
267 false.
268 The LABEL is optional, and if present, consists of an identifier followed
269 by a colon.  The LABEL identifies the loop for the loop control
270 statements C<next>, C<last>, and C<redo>.
271 If the LABEL is omitted, the loop control statement
272 refers to the innermost enclosing loop.  This may include dynamically
273 looking back your call-stack at run time to find the LABEL.  Such
274 desperate behavior triggers a warning if you use the C<use warnings>
275 pragma or the B<-w> flag.
276
277 If there is a C<continue> BLOCK, it is always executed just before the
278 conditional is about to be evaluated again.  Thus it can be used to
279 increment a loop variable, even when the loop has been continued via
280 the C<next> statement.
281
282 Extension modules can also hook into the Perl parser to define new
283 kinds of compound statement.  These are introduced by a keyword which
284 the extension recognises, and the syntax following the keyword is
285 defined entirely by the extension.  If you are an implementor, see
286 L<perlapi/PL_keyword_plugin> for the mechanism.  If you are using such
287 a module, see the module's documentation for details of the syntax that
288 it defines.
289
290 =head2 Loop Control
291 X<loop control> X<loop, control> X<next> X<last> X<redo> X<continue>
292
293 The C<next> command starts the next iteration of the loop:
294
295     LINE: while (<STDIN>) {
296         next LINE if /^#/;      # discard comments
297         ...
298     }
299
300 The C<last> command immediately exits the loop in question.  The
301 C<continue> block, if any, is not executed:
302
303     LINE: while (<STDIN>) {
304         last LINE if /^$/;      # exit when done with header
305         ...
306     }
307
308 The C<redo> command restarts the loop block without evaluating the
309 conditional again.  The C<continue> block, if any, is I<not> executed.
310 This command is normally used by programs that want to lie to themselves
311 about what was just input.
312
313 For example, when processing a file like F</etc/termcap>.
314 If your input lines might end in backslashes to indicate continuation, you
315 want to skip ahead and get the next record.
316
317     while (<>) {
318         chomp;
319         if (s/\\$//) {
320             $_ .= <>;
321             redo unless eof();
322         }
323         # now process $_
324     }
325
326 which is Perl short-hand for the more explicitly written version:
327
328     LINE: while (defined($line = <ARGV>)) {
329         chomp($line);
330         if ($line =~ s/\\$//) {
331             $line .= <ARGV>;
332             redo LINE unless eof(); # not eof(ARGV)!
333         }
334         # now process $line
335     }
336
337 Note that if there were a C<continue> block on the above code, it would
338 get executed only on lines discarded by the regex (since redo skips the
339 continue block). A continue block is often used to reset line counters
340 or C<?pat?> one-time matches:
341
342     # inspired by :1,$g/fred/s//WILMA/
343     while (<>) {
344         ?(fred)?    && s//WILMA $1 WILMA/;
345         ?(barney)?  && s//BETTY $1 BETTY/;
346         ?(homer)?   && s//MARGE $1 MARGE/;
347     } continue {
348         print "$ARGV $.: $_";
349         close ARGV  if eof();           # reset $.
350         reset       if eof();           # reset ?pat?
351     }
352
353 If the word C<while> is replaced by the word C<until>, the sense of the
354 test is reversed, but the conditional is still tested before the first
355 iteration.
356
357 The loop control statements don't work in an C<if> or C<unless>, since
358 they aren't loops.  You can double the braces to make them such, though.
359
360     if (/pattern/) {{
361         last if /fred/;
362         next if /barney/; # same effect as "last", but doesn't document as well
363         # do something here
364     }}
365
366 This is caused by the fact that a block by itself acts as a loop that
367 executes once, see L<"Basic BLOCKs">.
368
369 The form C<while/if BLOCK BLOCK>, available in Perl 4, is no longer
370 available.   Replace any occurrence of C<if BLOCK> by C<if (do BLOCK)>.
371
372 =head2 For Loops
373 X<for> X<foreach>
374
375 Perl's C-style C<for> loop works like the corresponding C<while> loop;
376 that means that this:
377
378     for ($i = 1; $i < 10; $i++) {
379         ...
380     }
381
382 is the same as this:
383
384     $i = 1;
385     while ($i < 10) {
386         ...
387     } continue {
388         $i++;
389     }
390
391 There is one minor difference: if variables are declared with C<my>
392 in the initialization section of the C<for>, the lexical scope of
393 those variables is exactly the C<for> loop (the body of the loop
394 and the control sections).
395 X<my>
396
397 Besides the normal array index looping, C<for> can lend itself
398 to many other interesting applications.  Here's one that avoids the
399 problem you get into if you explicitly test for end-of-file on
400 an interactive file descriptor causing your program to appear to
401 hang.
402 X<eof> X<end-of-file> X<end of file>
403
404     $on_a_tty = -t STDIN && -t STDOUT;
405     sub prompt { print "yes? " if $on_a_tty }
406     for ( prompt(); <STDIN>; prompt() ) {
407         # do something
408     }
409
410 Using C<readline> (or the operator form, C<< <EXPR> >>) as the
411 conditional of a C<for> loop is shorthand for the following.  This
412 behaviour is the same as a C<while> loop conditional.
413 X<readline> X<< <> >>
414
415     for ( prompt(); defined( $_ = <STDIN> ); prompt() ) {
416         # do something
417     }
418
419 =head2 Foreach Loops
420 X<for> X<foreach>
421
422 The C<foreach> loop iterates over a normal list value and sets the
423 variable VAR to be each element of the list in turn.  If the variable
424 is preceded with the keyword C<my>, then it is lexically scoped, and
425 is therefore visible only within the loop.  Otherwise, the variable is
426 implicitly local to the loop and regains its former value upon exiting
427 the loop.  If the variable was previously declared with C<my>, it uses
428 that variable instead of the global one, but it's still localized to
429 the loop.  This implicit localisation occurs I<only> in a C<foreach>
430 loop.
431 X<my> X<local>
432
433 The C<foreach> keyword is actually a synonym for the C<for> keyword, so
434 you can use C<foreach> for readability or C<for> for brevity.  (Or because
435 the Bourne shell is more familiar to you than I<csh>, so writing C<for>
436 comes more naturally.)  If VAR is omitted, C<$_> is set to each value.
437 X<$_>
438
439 If any element of LIST is an lvalue, you can modify it by modifying
440 VAR inside the loop.  Conversely, if any element of LIST is NOT an
441 lvalue, any attempt to modify that element will fail.  In other words,
442 the C<foreach> loop index variable is an implicit alias for each item
443 in the list that you're looping over.
444 X<alias>
445
446 If any part of LIST is an array, C<foreach> will get very confused if
447 you add or remove elements within the loop body, for example with
448 C<splice>.   So don't do that.
449 X<splice>
450
451 C<foreach> probably won't do what you expect if VAR is a tied or other
452 special variable.   Don't do that either.
453
454 Examples:
455
456     for (@ary) { s/foo/bar/ }
457
458     for my $elem (@elements) {
459         $elem *= 2;
460     }
461
462     for $count (10,9,8,7,6,5,4,3,2,1,'BOOM') {
463         print $count, "\n"; sleep(1);
464     }
465
466     for (1..15) { print "Merry Christmas\n"; }
467
468     foreach $item (split(/:[\\\n:]*/, $ENV{TERMCAP})) {
469         print "Item: $item\n";
470     }
471
472 Here's how a C programmer might code up a particular algorithm in Perl:
473
474     for (my $i = 0; $i < @ary1; $i++) {
475         for (my $j = 0; $j < @ary2; $j++) {
476             if ($ary1[$i] > $ary2[$j]) {
477                 last; # can't go to outer :-(
478             }
479             $ary1[$i] += $ary2[$j];
480         }
481         # this is where that last takes me
482     }
483
484 Whereas here's how a Perl programmer more comfortable with the idiom might
485 do it:
486
487     OUTER: for my $wid (@ary1) {
488     INNER:   for my $jet (@ary2) {
489                 next OUTER if $wid > $jet;
490                 $wid += $jet;
491              }
492           }
493
494 See how much easier this is?  It's cleaner, safer, and faster.  It's
495 cleaner because it's less noisy.  It's safer because if code gets added
496 between the inner and outer loops later on, the new code won't be
497 accidentally executed.  The C<next> explicitly iterates the other loop
498 rather than merely terminating the inner one.  And it's faster because
499 Perl executes a C<foreach> statement more rapidly than it would the
500 equivalent C<for> loop.
501
502 =head2 Basic BLOCKs
503 X<block>
504
505 A BLOCK by itself (labeled or not) is semantically equivalent to a
506 loop that executes once.  Thus you can use any of the loop control
507 statements in it to leave or restart the block.  (Note that this is
508 I<NOT> true in C<eval{}>, C<sub{}>, or contrary to popular belief
509 C<do{}> blocks, which do I<NOT> count as loops.)  The C<continue>
510 block is optional.
511
512 The BLOCK construct can be used to emulate case structures.
513
514     SWITCH: {
515         if (/^abc/) { $abc = 1; last SWITCH; }
516         if (/^def/) { $def = 1; last SWITCH; }
517         if (/^xyz/) { $xyz = 1; last SWITCH; }
518         $nothing = 1;
519     }
520
521 Such constructs are quite frequently used, because older versions
522 of Perl had no official C<switch> statement.
523
524 =head2 Switch statements
525 X<switch> X<case> X<given> X<when> X<default>
526
527 Starting from Perl 5.10, you can say
528
529     use feature "switch";
530
531 which enables a switch feature that is closely based on the
532 Perl 6 proposal.
533
534 The keywords C<given> and C<when> are analogous
535 to C<switch> and C<case> in other languages, so the code
536 above could be written as
537
538     given($_) {
539         when (/^abc/) { $abc = 1; }
540         when (/^def/) { $def = 1; }
541         when (/^xyz/) { $xyz = 1; }
542         default { $nothing = 1; }
543     }
544
545 This construct is very flexible and powerful. For example:
546
547     use feature ":5.10";
548     given($foo) {
549         when (undef) {
550             say '$foo is undefined';
551         }
552         when ("foo") {
553             say '$foo is the string "foo"';
554         }
555         when ([1,3,5,7,9]) {
556             say '$foo is an odd digit';
557             continue; # Fall through
558         }
559         when ($_ < 100) {
560             say '$foo is numerically less than 100';
561         }
562         when (\&complicated_check) {
563             say 'a complicated check for $foo is true';
564         }
565         default {
566             die q(I don't know what to do with $foo);
567         }
568     }
569
570 C<given(EXPR)> will assign the value of EXPR to C<$_>
571 within the lexical scope of the block, so it's similar to
572
573         do { my $_ = EXPR; ... }
574
575 except that the block is automatically broken out of by a
576 successful C<when> or an explicit C<break>.
577
578 Most of the power comes from implicit smart matching:
579
580         when($foo)
581
582 is exactly equivalent to
583
584         when($_ ~~ $foo)
585
586 Most of the time, C<when(EXPR)> is treated as an implicit smart match of
587 C<$_>, i.e. C<$_ ~~ EXPR>. (See L</"Smart matching in detail"> for more
588 information on smart matching.) But when EXPR is one of the below
589 exceptional cases, it is used directly as a boolean:
590
591 =over 4
592
593 =item *
594
595 a subroutine or method call
596
597 =item *
598
599 a regular expression match, i.e. C</REGEX/> or C<$foo =~ /REGEX/>,
600 or a negated regular expression match (C<!/REGEX/> or C<$foo !~ /REGEX/>).
601
602 =item *
603
604 a comparison such as C<$_ E<lt> 10> or C<$x eq "abc">
605 (or of course C<$_ ~~ $c>)
606
607 =item *
608
609 C<defined(...)>, C<exists(...)>, or C<eof(...)>
610
611 =item *
612
613 a negated expression C<!(...)> or C<not (...)>, or a logical
614 exclusive-or C<(...) xor (...)>.
615
616 =item *
617
618 a filetest operator, with the exception of C<-s>, C<-M>, C<-A>, and C<-C>,
619 that return numerical values, not boolean ones.
620
621 =item *
622
623 the C<..> and C<...> flip-flop operators.
624
625 =back
626
627 In those cases the value of EXPR is used directly as a boolean.
628
629 Furthermore:
630
631 =over 4
632
633 =item *
634
635 If EXPR is C<... && ...> or C<... and ...>, the test
636 is applied recursively to both arguments. If I<both>
637 arguments pass the test, then the argument is treated
638 as boolean.
639
640 =item *
641
642 If EXPR is C<... || ...>, C<... // ...> or C<... or ...>, the test
643 is applied recursively to the first argument.
644
645 =back
646
647 These rules look complicated, but usually they will do what
648 you want. For example you could write:
649
650     when (/^\d+$/ && $_ < 75) { ... }
651
652 Another useful shortcut is that, if you use a literal array
653 or hash as the argument to C<given>, it is turned into a
654 reference. So C<given(@foo)> is the same as C<given(\@foo)>,
655 for example.
656
657 C<default> behaves exactly like C<when(1 == 1)>, which is
658 to say that it always matches.
659
660 =head3 Breaking out
661
662 You can use the C<break> keyword to break out of the enclosing
663 C<given> block.  Every C<when> block is implicitly ended with
664 a C<break>.
665
666 =head3 Fall-through
667
668 You can use the C<continue> keyword to fall through from one
669 case to the next:
670
671     given($foo) {
672         when (/x/) { say '$foo contains an x'; continue }
673         when (/y/) { say '$foo contains a y' }
674         default    { say '$foo does not contain a y' }
675     }
676
677 =head3 Return value
678
679 When a C<given> statement is also a valid expression (e.g.
680 when it's the last statement of a block), it returns :
681
682 =over 4
683
684 =item *
685
686 An empty list as soon as an explicit C<break> is encountered.
687
688 =item *
689
690 The value of the last evaluated expression of the successful
691 C<when>/C<default> clause, if there's one.
692
693 =item *
694
695 The value of the last evaluated expression of the C<given> block if no
696 condition was true.
697
698 =back
699
700 Note that, unlike C<if> and C<unless>, both C<when> and C<default> always
701 themselves return an empty list.
702
703     my $price = do { given ($item) {
704         when ([ 'pear', 'apple' ]) { 1 }
705         break when 'vote';      # My vote cannot be bought
706         1e10  when /Mona Lisa/;
707         'unknown';
708     } };
709
710 C<given> blocks can't currently be used as proper expressions. This
711 may be addressed in a future version of perl.
712
713 =head3 Switching in a loop
714
715 Instead of using C<given()>, you can use a C<foreach()> loop.
716 For example, here's one way to count how many times a particular
717 string occurs in an array:
718
719     my $count = 0;
720     for (@array) {
721         when ("foo") { ++$count }
722     }
723     print "\@array contains $count copies of 'foo'\n";
724
725 At the end of all C<when> blocks, there is an implicit C<next>.
726 You can override that with an explicit C<last> if you're only
727 interested in the first match.
728
729 This doesn't work if you explicitly specify a loop variable,
730 as in C<for $item (@array)>. You have to use the default
731 variable C<$_>. (You can use C<for my $_ (@array)>.)
732
733 =head3 Smart matching in detail
734
735 The behaviour of a smart match depends on what type of thing its arguments
736 are. The behaviour is determined by the following table: the first row
737 that applies determines the match behaviour (which is thus mostly
738 determined by the type of the right operand). Note that the smart match
739 implicitly dereferences any non-blessed hash or array ref, so the "Hash"
740 and "Array" entries apply in those cases. (For blessed references, the
741 "Object" entries apply.)
742
743 Note that the "Matching Code" column is not always an exact rendition.  For
744 example, the smart match operator short-circuits whenever possible, but
745 C<grep> does not.
746
747     $a      $b        Type of Match Implied    Matching Code
748     ======  =====     =====================    =============
749     Any     undef     undefined                !defined $a
750
751     Any     Object    invokes ~~ overloading on $object, or dies
752
753     Hash    CodeRef   sub truth for each key[1] !grep { !$b->($_) } keys %$a
754     Array   CodeRef   sub truth for each elt[1] !grep { !$b->($_) } @$a
755     Any     CodeRef   scalar sub truth          $b->($a)
756
757     Hash    Hash      hash keys identical (every key is found in both hashes)
758     Array   Hash      hash keys intersection   grep { exists $b->{$_} } @$a
759     Regex   Hash      hash key grep            grep /$a/, keys %$b
760     undef   Hash      always false (undef can't be a key)
761     Any     Hash      hash entry existence     exists $b->{$a}
762
763     Hash    Array     hash keys intersection   grep { exists $a->{$_} } @$b
764     Array   Array     arrays are comparable[2]
765     Regex   Array     array grep               grep /$a/, @$b
766     undef   Array     array contains undef     grep !defined, @$b
767     Any     Array     match against an array element[3]
768                                                grep $a ~~ $_, @$b
769
770     Hash    Regex     hash key grep            grep /$b/, keys %$a
771     Array   Regex     array grep               grep /$b/, @$a
772     Any     Regex     pattern match            $a =~ /$b/
773
774     Object  Any       invokes ~~ overloading on $object, or falls back:
775     Any     Num       numeric equality         $a == $b
776     Num     numish[4] numeric equality         $a == $b
777     undef   Any       undefined                !defined($b)
778     Any     Any       string equality          $a eq $b
779
780  1 - empty hashes or arrays will match.
781  2 - that is, each element smart-matches the element of same index in the
782      other array. [3]
783  3 - If a circular reference is found, we fall back to referential equality.
784  4 - either a real number, or a string that looks like a number
785
786 =head3 Custom matching via overloading
787
788 You can change the way that an object is matched by overloading
789 the C<~~> operator. This may alter the usual smart match semantics.
790
791 It should be noted that C<~~> will refuse to work on objects that
792 don't overload it (in order to avoid relying on the object's
793 underlying structure).
794
795 Note also that smart match's matching rules take precedence over
796 overloading, so if C<$obj> has smart match overloading, then
797
798     $obj ~~ X
799
800 will not automatically invoke the overload method with X as an argument;
801 instead the table above is consulted as normal, and based in the type of X,
802 overloading may or may not be invoked.
803
804 See L<overload>.
805
806 =head3 Differences from Perl 6
807
808 The Perl 5 smart match and C<given>/C<when> constructs are not
809 absolutely identical to their Perl 6 analogues. The most visible
810 difference is that, in Perl 5, parentheses are required around
811 the argument to C<given()> and C<when()> (except when this last
812 one is used as a statement modifier). Parentheses in Perl 6
813 are always optional in a control construct such as C<if()>,
814 C<while()>, or C<when()>; they can't be made optional in Perl
815 5 without a great deal of potential confusion, because Perl 5
816 would parse the expression
817
818   given $foo {
819     ...
820   }
821
822 as though the argument to C<given> were an element of the hash
823 C<%foo>, interpreting the braces as hash-element syntax.
824
825 The table of smart matches is not identical to that proposed by the
826 Perl 6 specification, mainly due to the differences between Perl 6's
827 and Perl 5's data models.
828
829 In Perl 6, C<when()> will always do an implicit smart match
830 with its argument, whilst it is convenient in Perl 5 to
831 suppress this implicit smart match in certain situations,
832 as documented above. (The difference is largely because Perl 5
833 does not, even internally, have a boolean type.)
834
835 =head2 Goto
836 X<goto>
837
838 Although not for the faint of heart, Perl does support a C<goto>
839 statement.  There are three forms: C<goto>-LABEL, C<goto>-EXPR, and
840 C<goto>-&NAME.  A loop's LABEL is not actually a valid target for
841 a C<goto>; it's just the name of the loop.
842
843 The C<goto>-LABEL form finds the statement labeled with LABEL and resumes
844 execution there.  It may not be used to go into any construct that
845 requires initialization, such as a subroutine or a C<foreach> loop.  It
846 also can't be used to go into a construct that is optimized away.  It
847 can be used to go almost anywhere else within the dynamic scope,
848 including out of subroutines, but it's usually better to use some other
849 construct such as C<last> or C<die>.  The author of Perl has never felt the
850 need to use this form of C<goto> (in Perl, that is--C is another matter).
851
852 The C<goto>-EXPR form expects a label name, whose scope will be resolved
853 dynamically.  This allows for computed C<goto>s per FORTRAN, but isn't
854 necessarily recommended if you're optimizing for maintainability:
855
856     goto(("FOO", "BAR", "GLARCH")[$i]);
857
858 The C<goto>-&NAME form is highly magical, and substitutes a call to the
859 named subroutine for the currently running subroutine.  This is used by
860 C<AUTOLOAD()> subroutines that wish to load another subroutine and then
861 pretend that the other subroutine had been called in the first place
862 (except that any modifications to C<@_> in the current subroutine are
863 propagated to the other subroutine.)  After the C<goto>, not even C<caller()>
864 will be able to tell that this routine was called first.
865
866 In almost all cases like this, it's usually a far, far better idea to use the
867 structured control flow mechanisms of C<next>, C<last>, or C<redo> instead of
868 resorting to a C<goto>.  For certain applications, the catch and throw pair of
869 C<eval{}> and die() for exception processing can also be a prudent approach.
870
871 =head2 PODs: Embedded Documentation
872 X<POD> X<documentation>
873
874 Perl has a mechanism for intermixing documentation with source code.
875 While it's expecting the beginning of a new statement, if the compiler
876 encounters a line that begins with an equal sign and a word, like this
877
878     =head1 Here There Be Pods!
879
880 Then that text and all remaining text up through and including a line
881 beginning with C<=cut> will be ignored.  The format of the intervening
882 text is described in L<perlpod>.
883
884 This allows you to intermix your source code
885 and your documentation text freely, as in
886
887     =item snazzle($)
888
889     The snazzle() function will behave in the most spectacular
890     form that you can possibly imagine, not even excepting
891     cybernetic pyrotechnics.
892
893     =cut back to the compiler, nuff of this pod stuff!
894
895     sub snazzle($) {
896         my $thingie = shift;
897         .........
898     }
899
900 Note that pod translators should look at only paragraphs beginning
901 with a pod directive (it makes parsing easier), whereas the compiler
902 actually knows to look for pod escapes even in the middle of a
903 paragraph.  This means that the following secret stuff will be
904 ignored by both the compiler and the translators.
905
906     $a=3;
907     =secret stuff
908      warn "Neither POD nor CODE!?"
909     =cut back
910     print "got $a\n";
911
912 You probably shouldn't rely upon the C<warn()> being podded out forever.
913 Not all pod translators are well-behaved in this regard, and perhaps
914 the compiler will become pickier.
915
916 One may also use pod directives to quickly comment out a section
917 of code.
918
919 =head2 Plain Old Comments (Not!)
920 X<comment> X<line> X<#> X<preprocessor> X<eval>
921
922 Perl can process line directives, much like the C preprocessor.  Using
923 this, one can control Perl's idea of filenames and line numbers in
924 error or warning messages (especially for strings that are processed
925 with C<eval()>).  The syntax for this mechanism is the same as for most
926 C preprocessors: it matches the regular expression
927
928     # example: '# line 42 "new_filename.plx"'
929     /^\#   \s*
930       line \s+ (\d+)   \s*
931       (?:\s("?)([^"]+)\2)? \s*
932      $/x
933
934 with C<$1> being the line number for the next line, and C<$3> being
935 the optional filename (specified with or without quotes).
936
937 There is a fairly obvious gotcha included with the line directive:
938 Debuggers and profilers will only show the last source line to appear
939 at a particular line number in a given file.  Care should be taken not
940 to cause line number collisions in code you'd like to debug later.
941
942 Here are some examples that you should be able to type into your command
943 shell:
944
945     % perl
946     # line 200 "bzzzt"
947     # the `#' on the previous line must be the first char on line
948     die 'foo';
949     __END__
950     foo at bzzzt line 201.
951
952     % perl
953     # line 200 "bzzzt"
954     eval qq[\n#line 2001 ""\ndie 'foo']; print $@;
955     __END__
956     foo at - line 2001.
957
958     % perl
959     eval qq[\n#line 200 "foo bar"\ndie 'foo']; print $@;
960     __END__
961     foo at foo bar line 200.
962
963     % perl
964     # line 345 "goop"
965     eval "\n#line " . __LINE__ . ' "' . __FILE__ ."\"\ndie 'foo'";
966     print $@;
967     __END__
968     foo at goop line 345.
969
970 =cut