Bump Module::Build version to 0.340201
[perl.git] / lib / Module / Build / Base.pm
1 # -*- mode: cperl; tab-width: 8; indent-tabs-mode: nil; basic-offset: 2 -*-
2 # vim:ts=8:sw=2:et:sta:sts=2
3 package Module::Build::Base;
4
5 use strict;
6 use vars qw($VERSION);
7 $VERSION = '0.340201';
8 $VERSION = eval $VERSION;
9 BEGIN { require 5.00503 }
10
11 use Carp;
12 use Cwd ();
13 use File::Copy ();
14 use File::Find ();
15 use File::Path ();
16 use File::Basename ();
17 use File::Spec 0.82 ();
18 use File::Compare ();
19 use Module::Build::Dumper ();
20 use IO::File ();
21 use Text::ParseWords ();
22
23 use Module::Build::ModuleInfo;
24 use Module::Build::Notes;
25 use Module::Build::Config;
26
27
28 #################### Constructors ###########################
29 sub new {
30   my $self = shift()->_construct(@_);
31
32   $self->{invoked_action} = $self->{action} ||= 'Build_PL';
33   $self->cull_args(@ARGV);
34   
35   die "Too early to specify a build action '$self->{action}'.  Do 'Build $self->{action}' instead.\n"
36     if $self->{action} && $self->{action} ne 'Build_PL';
37
38   $self->check_manifest;
39   $self->check_prereq;
40   $self->check_autofeatures;
41
42   $self->dist_name;
43   $self->dist_version;
44
45   $self->_set_install_paths;
46   $self->_find_nested_builds;
47
48   return $self;
49 }
50
51 sub resume {
52   my $package = shift;
53   my $self = $package->_construct(@_);
54   $self->read_config;
55
56   # If someone called Module::Build->current() or
57   # Module::Build->new_from_context() and the correct class to use is
58   # actually a *subclass* of Module::Build, we may need to load that
59   # subclass here and re-delegate the resume() method to it.
60   unless ( UNIVERSAL::isa($package, $self->build_class) ) {
61     my $build_class = $self->build_class;
62     my $config_dir = $self->config_dir || '_build';
63     my $build_lib = File::Spec->catdir( $config_dir, 'lib' );
64     unshift( @INC, $build_lib );
65     unless ( $build_class->can('new') ) {
66       eval "require $build_class; 1" or die "Failed to re-load '$build_class': $@";
67     }
68     return $build_class->resume(@_);
69   }
70
71   unless ($self->_perl_is_same($self->{properties}{perl})) {
72     my $perl = $self->find_perl_interpreter;
73     $self->log_warn(" * WARNING: Configuration was initially created with '$self->{properties}{perl}',\n".
74                     "   but we are now using '$perl'.\n");
75   }
76   
77   $self->cull_args(@ARGV);
78
79   unless ($self->allow_mb_mismatch) {
80     my $mb_version = $Module::Build::VERSION;
81     die(" * ERROR: Configuration was initially created with Module::Build version '$self->{properties}{mb_version}',\n".
82         "   but we are now using version '$mb_version'.  Please re-run the Build.PL or Makefile.PL script,\n".
83         "   or use --allow_mb_mismatch 1 to skip this version check.\n")
84     if $mb_version ne $self->{properties}{mb_version};
85   }
86   
87   $self->{invoked_action} = $self->{action} ||= 'build';
88
89   $self->_set_install_paths;
90   
91   return $self;
92 }
93
94 sub new_from_context {
95   my ($package, %args) = @_;
96   
97   # XXX Read the META.yml and see whether we need to run the Build.PL?
98   
99   # Run the Build.PL.  We use do() rather than run_perl_script() so
100   # that it runs in this process rather than a subprocess, because we
101   # need to make sure that the environment is the same during Build.PL
102   # as it is during resume() (and thereafter).
103   {
104     local @ARGV = $package->unparse_args(\%args);
105     do './Build.PL';
106     die $@ if $@;
107   }
108   return $package->resume;
109 }
110
111 sub current {
112   # hmm, wonder what the right thing to do here is
113   local @ARGV;
114   return shift()->resume;
115 }
116
117 sub _construct {
118   my ($package, %input) = @_;
119
120   my $args   = delete $input{args}   || {};
121   my $config = delete $input{config} || {};
122
123   my $self = bless {
124                     args => {%$args},
125                     config => Module::Build::Config->new(values => $config),
126                     properties => {
127                                    base_dir        => $package->cwd,
128                                    mb_version      => $Module::Build::VERSION,
129                                    %input,
130                                   },
131                     phash => {},
132                     stash => {}, # temporary caching, not stored in _build
133                    }, $package;
134
135   $self->_set_defaults;
136   my ($p, $ph) = ($self->{properties}, $self->{phash});
137
138   foreach (qw(notes config_data features runtime_params cleanup auto_features)) {
139     my $file = File::Spec->catfile($self->config_dir, $_);
140     $ph->{$_} = Module::Build::Notes->new(file => $file);
141     $ph->{$_}->restore if -e $file;
142     if (exists $p->{$_}) {
143       my $vals = delete $p->{$_};
144       while (my ($k, $v) = each %$vals) {
145         $self->$_($k, $v);
146       }
147     }
148   }
149
150   # The following warning could be unnecessary if the user is running
151   # an embedded perl, but there aren't too many of those around, and
152   # embedded perls aren't usually used to install modules, and the
153   # installation process sometimes needs to run external scripts
154   # (e.g. to run tests).
155   $p->{perl} = $self->find_perl_interpreter
156     or $self->log_warn("Warning: Can't locate your perl binary");
157
158   my $blibdir = sub { File::Spec->catdir($p->{blib}, @_) };
159   $p->{bindoc_dirs} ||= [ $blibdir->("script") ];
160   $p->{libdoc_dirs} ||= [ $blibdir->("lib"), $blibdir->("arch") ];
161
162   $p->{dist_author} = [ $p->{dist_author} ] if defined $p->{dist_author} and not ref $p->{dist_author};
163
164   # Synonyms
165   $p->{requires} = delete $p->{prereq} if defined $p->{prereq};
166   $p->{script_files} = delete $p->{scripts} if defined $p->{scripts};
167
168   # Convert to from shell strings to arrays
169   for ('extra_compiler_flags', 'extra_linker_flags') {
170     $p->{$_} = [ $self->split_like_shell($p->{$_}) ] if exists $p->{$_};
171   }
172
173   # Convert to arrays
174   for ('include_dirs') {
175     $p->{$_} = [ $p->{$_} ] if exists $p->{$_} && !ref $p->{$_}
176   }
177
178   $self->add_to_cleanup( @{delete $p->{add_to_cleanup}} )
179     if $p->{add_to_cleanup};
180
181   return $self;
182 }
183
184 ################## End constructors #########################
185
186 sub log_info {
187   my $self = shift;
188   print @_ unless(ref($self) and $self->quiet);
189 }
190 sub log_verbose {
191   my $self = shift;
192   $self->log_info(@_) if(ref($self) and $self->verbose);
193 }
194 sub log_debug {
195   my $self = shift;
196   print @_ if ref $self && $self->debug;
197 }
198
199 sub log_warn {
200   # Try to make our call stack invisible
201   shift;
202   if (@_ and $_[-1] !~ /\n$/) {
203     my (undef, $file, $line) = caller();
204     warn @_, " at $file line $line.\n";
205   } else {
206     warn @_;
207   }
208 }
209
210
211 sub _set_install_paths {
212   my $self = shift;
213   my $c = $self->{config};
214   my $p = $self->{properties};
215
216   my @libstyle = $c->get('installstyle') ?
217       File::Spec->splitdir($c->get('installstyle')) : qw(lib perl5);
218   my $arch     = $c->get('archname');
219   my $version  = $c->get('version');
220
221   my $bindoc  = $c->get('installman1dir') || undef;
222   my $libdoc  = $c->get('installman3dir') || undef;
223
224   my $binhtml = $c->get('installhtml1dir') || $c->get('installhtmldir') || undef;
225   my $libhtml = $c->get('installhtml3dir') || $c->get('installhtmldir') || undef;
226
227   $p->{install_sets} =
228     {
229      core   => {
230                 lib     => $c->get('installprivlib'),
231                 arch    => $c->get('installarchlib'),
232                 bin     => $c->get('installbin'),
233                 script  => $c->get('installscript'),
234                 bindoc  => $bindoc,
235                 libdoc  => $libdoc,
236                 binhtml => $binhtml,
237                 libhtml => $libhtml,
238                },
239      site   => {
240                 lib     => $c->get('installsitelib'),
241                 arch    => $c->get('installsitearch'),
242                 bin     => $c->get('installsitebin') || $c->get('installbin'),
243                 script  => $c->get('installsitescript') ||
244                            $c->get('installsitebin') || $c->get('installscript'),
245                 bindoc  => $c->get('installsiteman1dir') || $bindoc,
246                 libdoc  => $c->get('installsiteman3dir') || $libdoc,
247                 binhtml => $c->get('installsitehtml1dir') || $binhtml,
248                 libhtml => $c->get('installsitehtml3dir') || $libhtml,
249                },
250      vendor => {
251                 lib     => $c->get('installvendorlib'),
252                 arch    => $c->get('installvendorarch'),
253                 bin     => $c->get('installvendorbin') || $c->get('installbin'),
254                 script  => $c->get('installvendorscript') ||
255                            $c->get('installvendorbin') || $c->get('installscript'),
256                 bindoc  => $c->get('installvendorman1dir') || $bindoc,
257                 libdoc  => $c->get('installvendorman3dir') || $libdoc,
258                 binhtml => $c->get('installvendorhtml1dir') || $binhtml,
259                 libhtml => $c->get('installvendorhtml3dir') || $libhtml,
260                },
261     };
262
263   $p->{original_prefix} =
264     {
265      core   => $c->get('installprefixexp') || $c->get('installprefix') ||
266                $c->get('prefixexp')        || $c->get('prefix') || '',
267      site   => $c->get('siteprefixexp'),
268      vendor => $c->get('usevendorprefix') ? $c->get('vendorprefixexp') : '',
269     };
270   $p->{original_prefix}{site} ||= $p->{original_prefix}{core};
271
272   # Note: you might be tempted to use $Config{installstyle} here
273   # instead of hard-coding lib/perl5, but that's been considered and
274   # (at least for now) rejected.  `perldoc Config` has some wisdom
275   # about it.
276   $p->{install_base_relpaths} =
277     {
278      lib     => ['lib', 'perl5'],
279      arch    => ['lib', 'perl5', $arch],
280      bin     => ['bin'],
281      script  => ['bin'],
282      bindoc  => ['man', 'man1'],
283      libdoc  => ['man', 'man3'],
284      binhtml => ['html'],
285      libhtml => ['html'],
286     };
287
288   $p->{prefix_relpaths} =
289     {
290      core => {
291               lib        => [@libstyle],
292               arch       => [@libstyle, $version, $arch],
293               bin        => ['bin'],
294               script     => ['bin'],
295               bindoc     => ['man', 'man1'],
296               libdoc     => ['man', 'man3'],
297               binhtml    => ['html'],
298               libhtml    => ['html'],
299              },
300      vendor => {
301                 lib        => [@libstyle],
302                 arch       => [@libstyle, $version, $arch],
303                 bin        => ['bin'],
304                 script     => ['bin'],
305                 bindoc     => ['man', 'man1'],
306                 libdoc     => ['man', 'man3'],
307                 binhtml    => ['html'],
308                 libhtml    => ['html'],
309                },
310      site => {
311               lib        => [@libstyle, 'site_perl'],
312               arch       => [@libstyle, 'site_perl', $version, $arch],
313               bin        => ['bin'],
314               script     => ['bin'],
315               bindoc     => ['man', 'man1'],
316               libdoc     => ['man', 'man3'],
317               binhtml    => ['html'],
318               libhtml    => ['html'],
319              },
320     };
321
322 }
323
324 sub _find_nested_builds {
325   my $self = shift;
326   my $r = $self->recurse_into or return;
327
328   my ($file, @r);
329   if (!ref($r) && $r eq 'auto') {
330     local *DH;
331     opendir DH, $self->base_dir
332       or die "Can't scan directory " . $self->base_dir . " for nested builds: $!";
333     while (defined($file = readdir DH)) {
334       my $subdir = File::Spec->catdir( $self->base_dir, $file );
335       next unless -d $subdir;
336       push @r, $subdir if -e File::Spec->catfile( $subdir, 'Build.PL' );
337     }
338   }
339
340   $self->recurse_into(\@r);
341 }
342
343 sub cwd {
344   return Cwd::cwd();
345 }
346
347 sub _quote_args {
348   # Returns a string that can become [part of] a command line with
349   # proper quoting so that the subprocess sees this same list of args.
350   my ($self, @args) = @_;
351
352   my @quoted;
353
354   for (@args) {
355     if ( /^[^\s*?!\$<>;\\|'"\[\]\{\}]+$/ ) {
356       # Looks pretty safe
357       push @quoted, $_;
358     } else {
359       # XXX this will obviously have to improve - is there already a
360       # core module lying around that does proper quoting?
361       s/('+)/'"$1"'/g;
362       push @quoted, qq('$_');
363     }
364   }
365
366   return join " ", @quoted;
367 }
368
369 sub _backticks {
370   my ($self, @cmd) = @_;
371   if ($self->have_forkpipe) {
372     local *FH;
373     my $pid = open *FH, "-|";
374     if ($pid) {
375       return wantarray ? <FH> : join '', <FH>;
376     } else {
377       die "Can't execute @cmd: $!\n" unless defined $pid;
378       exec { $cmd[0] } @cmd;
379     }
380   } else {
381     my $cmd = $self->_quote_args(@cmd);
382     return `$cmd`;
383   }
384 }
385
386 # Tells us whether the construct open($fh, '-|', @command) is
387 # supported.  It would probably be better to dynamically sense this.
388 sub have_forkpipe { 1 }
389
390 # Determine whether a given binary is the same as the perl
391 # (configuration) that started this process.
392 sub _perl_is_same {
393   my ($self, $perl) = @_;
394
395   my @cmd = ($perl);
396
397   # When run from the perl core, @INC will include the directories
398   # where perl is yet to be installed. We need to reference the
399   # absolute path within the source distribution where it can find
400   # it's Config.pm This also prevents us from picking up a Config.pm
401   # from a different configuration that happens to be already
402   # installed in @INC.
403   if ($ENV{PERL_CORE}) {
404     push @cmd, '-I' . File::Spec->catdir(File::Basename::dirname($perl), 'lib');
405   }
406
407   push @cmd, qw(-MConfig=myconfig -e print -e myconfig);
408   return $self->_backticks(@cmd) eq Config->myconfig;
409 }
410
411 # cache _discover_perl_interpreter() results
412 {
413   my $known_perl;
414   sub find_perl_interpreter {
415     my $self = shift;
416
417     return $known_perl if defined($known_perl);
418     return $known_perl = $self->_discover_perl_interpreter;
419   }
420 }
421
422 # Returns the absolute path of the perl interpreter used to invoke
423 # this process. The path is derived from $^X or $Config{perlpath}. On
424 # some platforms $^X contains the complete absolute path of the
425 # interpreter, on other it may contain a relative path, or simply
426 # 'perl'. This can also vary depending on whether a path was supplied
427 # when perl was invoked. Additionally, the value in $^X may omit the
428 # executable extension on platforms that use one. It's a fatal error
429 # if the interpreter can't be found because it can result in undefined
430 # behavior by routines that depend on it (generating errors or
431 # invoking the wrong perl.)
432 sub _discover_perl_interpreter {
433   my $proto = shift;
434   my $c     = ref($proto) ? $proto->{config} : 'Module::Build::Config';
435
436   my $perl  = $^X;
437   my $perl_basename = File::Basename::basename($perl);
438
439   my @potential_perls;
440
441   # Try 1, Check $^X for absolute path
442   push( @potential_perls, $perl )
443       if File::Spec->file_name_is_absolute($perl);
444
445   # Try 2, Check $^X for a valid relative path
446   my $abs_perl = File::Spec->rel2abs($perl);
447   push( @potential_perls, $abs_perl );
448
449   # Try 3, Last ditch effort: These two option use hackery to try to locate
450   # a suitable perl. The hack varies depending on whether we are running
451   # from an installed perl or an uninstalled perl in the perl source dist.
452   if ($ENV{PERL_CORE}) {
453
454     # Try 3.A, If we are in a perl source tree, running an uninstalled
455     # perl, we can keep moving up the directory tree until we find our
456     # binary. We wouldn't do this under any other circumstances.
457
458     # CBuilder is also in the core, so it should be available here
459     require ExtUtils::CBuilder;
460     my $perl_src = Cwd::realpath( ExtUtils::CBuilder->perl_src );
461     if ( defined($perl_src) && length($perl_src) ) {
462       my $uninstperl =
463         File::Spec->rel2abs(File::Spec->catfile( $perl_src, $perl_basename ));
464       push( @potential_perls, $uninstperl );
465     }
466
467   } else {
468
469     # Try 3.B, First look in $Config{perlpath}, then search the user's
470     # PATH. We do not want to do either if we are running from an
471     # uninstalled perl in a perl source tree.
472
473     push( @potential_perls, $c->get('perlpath') );
474
475     push( @potential_perls,
476           map File::Spec->catfile($_, $perl_basename), File::Spec->path() );
477   }
478
479   # Now that we've enumerated the potential perls, it's time to test
480   # them to see if any of them match our configuration, returning the
481   # absolute path of the first successful match.
482   my $exe = $c->get('exe_ext');
483   foreach my $thisperl ( @potential_perls ) {
484
485     if (defined $exe) {
486       $thisperl .= $exe unless $thisperl =~ m/$exe$/i;
487     }
488
489     if ( -f $thisperl && $proto->_perl_is_same($thisperl) ) {
490       return $thisperl;
491     }
492   }
493
494   # We've tried all alternatives, and didn't find a perl that matches
495   # our configuration. Throw an exception, and list alternatives we tried.
496   my @paths = map File::Basename::dirname($_), @potential_perls;
497   die "Can't locate the perl binary used to run this script " .
498       "in (@paths)\n";
499 }
500
501 sub _is_interactive {
502   return -t STDIN && (-t STDOUT || !(-f STDOUT || -c STDOUT)) ;   # Pipe?
503 }
504
505 # NOTE this is a blocking operation if(-t STDIN)
506 sub _is_unattended {
507   my $self = shift;
508   return $ENV{PERL_MM_USE_DEFAULT} ||
509     ( !$self->_is_interactive && eof STDIN );
510 }
511
512 sub _readline {
513   my $self = shift;
514   return undef if $self->_is_unattended;
515
516   my $answer = <STDIN>;
517   chomp $answer if defined $answer;
518   return $answer;
519 }
520
521 sub prompt {
522   my $self = shift;
523   my $mess = shift
524     or die "prompt() called without a prompt message";
525
526   # use a list to distinguish a default of undef() from no default
527   my @def;
528   @def = (shift) if @_;
529   # use dispdef for output
530   my @dispdef = scalar(@def) ?
531     ('[', (defined($def[0]) ? $def[0] . ' ' : ''), ']') :
532     (' ', '');
533
534   local $|=1;
535   print "$mess ", @dispdef;
536
537   if ( $self->_is_unattended && !@def ) {
538     die <<EOF;
539 ERROR: This build seems to be unattended, but there is no default value
540 for this question.  Aborting.
541 EOF
542   }
543
544   my $ans = $self->_readline();
545
546   if ( !defined($ans)        # Ctrl-D or unattended
547        or !length($ans) ) {  # User hit return
548     print "$dispdef[1]\n";
549     $ans = scalar(@def) ? $def[0] : '';
550   }
551
552   return $ans;
553 }
554
555 sub y_n {
556   my $self = shift;
557   my ($mess, $def)  = @_;
558
559   die "y_n() called without a prompt message" unless $mess;
560   die "Invalid default value: y_n() default must be 'y' or 'n'"
561     if $def && $def !~ /^[yn]/i;
562
563   my $answer;
564   while (1) { # XXX Infinite or a large number followed by an exception ?
565     $answer = $self->prompt(@_);
566     return 1 if $answer =~ /^y/i;
567     return 0 if $answer =~ /^n/i;
568     local $|=1;
569     print "Please answer 'y' or 'n'.\n";
570   }
571 }
572
573 sub current_action { shift->{action} }
574 sub invoked_action { shift->{invoked_action} }
575
576 sub notes        { shift()->{phash}{notes}->access(@_) }
577 sub config_data  { shift()->{phash}{config_data}->access(@_) }
578 sub runtime_params { shift->{phash}{runtime_params}->read( @_ ? shift : () ) }  # Read-only
579 sub auto_features  { shift()->{phash}{auto_features}->access(@_) }
580
581 sub features     {
582   my $self = shift;
583   my $ph = $self->{phash};
584
585   if (@_) {
586     my $key = shift;
587     if ($ph->{features}->exists($key)) {
588       return $ph->{features}->access($key, @_);
589     }
590
591     if (my $info = $ph->{auto_features}->access($key)) {
592       my $failures = $self->prereq_failures($info);
593       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
594                            keys %$failures ) ? 1 : 0;
595       return !$disabled;
596     }
597
598     return $ph->{features}->access($key, @_);
599   }
600
601   # No args - get the auto_features & overlay the regular features
602   my %features;
603   my %auto_features = $ph->{auto_features}->access();
604   while (my ($name, $info) = each %auto_features) {
605     my $failures = $self->prereq_failures($info);
606     my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
607                          keys %$failures ) ? 1 : 0;
608     $features{$name} = $disabled ? 0 : 1;
609   }
610   %features = (%features, $ph->{features}->access());
611
612   return wantarray ? %features : \%features;
613 }
614 BEGIN { *feature = \&features } # Alias
615
616 sub _mb_feature {
617   my $self = shift;
618   
619   if (($self->module_name || '') eq 'Module::Build') {
620     # We're building Module::Build itself, so ...::ConfigData isn't
621     # valid, but $self->features() should be.
622     return $self->feature(@_);
623   } else {
624     require Module::Build::ConfigData;
625     return Module::Build::ConfigData->feature(@_);
626   }
627 }
628
629
630 sub add_build_element {
631     my ($self, $elem) = @_;
632     my $elems = $self->build_elements;
633     push @$elems, $elem unless grep { $_ eq $elem } @$elems;
634 }
635
636 sub ACTION_config_data {
637   my $self = shift;
638   return unless $self->has_config_data;
639   
640   my $module_name = $self->module_name
641     or die "The config_data feature requires that 'module_name' be set";
642   my $notes_name = $module_name . '::ConfigData'; # TODO: Customize name ???
643   my $notes_pm = File::Spec->catfile($self->blib, 'lib', split /::/, "$notes_name.pm");
644
645   return if $self->up_to_date(['Build.PL',
646                                $self->config_file('config_data'),
647                                $self->config_file('features')
648                               ], $notes_pm);
649
650   $self->log_info("Writing config notes to $notes_pm\n");
651   File::Path::mkpath(File::Basename::dirname($notes_pm));
652
653   Module::Build::Notes->write_config_data
654       (
655        file => $notes_pm,
656        module => $module_name,
657        config_module => $notes_name,
658        config_data => scalar $self->config_data,
659        feature => scalar $self->{phash}{features}->access(),
660        auto_features => scalar $self->auto_features,
661       );
662 }
663
664 ########################################################################
665 { # enclosing these lexicals -- TODO 
666   my %valid_properties = ( __PACKAGE__,  {} );
667   my %additive_properties;
668
669   sub _mb_classes {
670     my $class = ref($_[0]) || $_[0];
671     return ($class, $class->mb_parents);
672   }
673
674   sub valid_property {
675     my ($class, $prop) = @_;
676     return grep exists( $valid_properties{$_}{$prop} ), $class->_mb_classes;
677   }
678
679   sub valid_properties {
680     return keys %{ shift->valid_properties_defaults() };
681   }
682
683   sub valid_properties_defaults {
684     my %out;
685     for (reverse shift->_mb_classes) {
686       @out{ keys %{ $valid_properties{$_} } } = map {
687         $_->()
688       } values %{ $valid_properties{$_} };
689     }
690     return \%out;
691   }
692
693   sub array_properties {
694     for (shift->_mb_classes) {
695       return @{$additive_properties{$_}->{ARRAY}}
696         if exists $additive_properties{$_}->{ARRAY};
697     }
698   }
699
700   sub hash_properties {
701     for (shift->_mb_classes) {
702       return @{$additive_properties{$_}->{'HASH'}}
703         if exists $additive_properties{$_}->{'HASH'};
704     }
705   }
706
707   sub add_property {
708     my ($class, $property) = (shift, shift);
709     die "Property '$property' already exists"
710       if $class->valid_property($property);
711     my %p = @_ == 1 ? ( default => shift ) : @_;
712
713     my $type = ref $p{default};
714     $valid_properties{$class}{$property} = $type eq 'CODE'
715       ? $p{default}
716       : sub { $p{default} };
717
718     push @{$additive_properties{$class}->{$type}}, $property
719       if $type;
720
721     unless ($class->can($property)) {
722       # TODO probably should put these in a util package
723       my $sub = $type eq 'HASH'
724         ? _make_hash_accessor($property, \%p)
725         : _make_accessor($property, \%p);
726       no strict 'refs';
727       *{"$class\::$property"} = $sub;
728     }
729
730     return $class;
731   }
732
733     sub property_error {
734       my $self = shift;
735       die 'ERROR: ', @_;
736     }
737
738   sub _set_defaults {
739     my $self = shift;
740
741     # Set the build class.
742     $self->{properties}{build_class} ||= ref $self;
743
744     # If there was no orig_dir, set to the same as base_dir
745     $self->{properties}{orig_dir} ||= $self->{properties}{base_dir};
746
747     my $defaults = $self->valid_properties_defaults;
748
749     foreach my $prop (keys %$defaults) {
750       $self->{properties}{$prop} = $defaults->{$prop}
751         unless exists $self->{properties}{$prop};
752     }
753
754     # Copy defaults for arrays any arrays.
755     for my $prop ($self->array_properties) {
756       $self->{properties}{$prop} = [@{$defaults->{$prop}}]
757         unless exists $self->{properties}{$prop};
758     }
759     # Copy defaults for arrays any hashes.
760     for my $prop ($self->hash_properties) {
761       $self->{properties}{$prop} = {%{$defaults->{$prop}}}
762         unless exists $self->{properties}{$prop};
763     }
764   }
765
766 } # end closure
767 ########################################################################
768 sub _make_hash_accessor {
769   my ($property, $p) = @_;
770   my $check = $p->{check} || sub { 1 };
771
772   return sub {
773     my $self = shift;
774
775     # This is only here to deprecate the historic accident of calling
776     # properties as class methods - I suspect it only happens in our
777     # test suite.
778     unless(ref($self)) {
779       carp("\n$property not a class method (@_)");
780       return;
781     }
782
783     my $x = $self->{properties};
784     return $x->{$property} unless @_;
785
786     my $prop = $x->{$property};
787     if ( defined $_[0] && !ref $_[0] ) {
788       if ( @_ == 1 ) {
789         return exists $prop->{$_[0]} ? $prop->{$_[0]} : undef;
790       } elsif ( @_ % 2 == 0 ) {
791         my %new = (%{ $prop }, @_);
792         local $_ = \%new;
793         $x->{$property} = \%new if $check->($self);
794         return $x->{$property};
795       } else {
796         die "Unexpected arguments for property '$property'\n";
797       }
798     } else {
799       die "Unexpected arguments for property '$property'\n"
800           if defined $_[0] && ref $_[0] ne 'HASH';
801       local $_ = $_[0];
802       $x->{$property} = shift if $check->($self);
803     }
804   };
805 }
806 ########################################################################
807 sub _make_accessor {
808   my ($property, $p) = @_;
809   my $check = $p->{check} || sub { 1 };
810
811   return sub {
812     my $self = shift;
813
814     # This is only here to deprecate the historic accident of calling
815     # properties as class methods - I suspect it only happens in our
816     # test suite.
817     unless(ref($self)) {
818       carp("\n$property not a class method (@_)");
819       return;
820     }
821
822     my $x = $self->{properties};
823     return $x->{$property} unless @_;
824     local $_ = $_[0];
825     $x->{$property} = shift if $check->($self);
826     return $x->{$property};
827   };
828 }
829 ########################################################################
830
831 # Add the default properties.
832 __PACKAGE__->add_property(auto_configure_requires => 1);
833 __PACKAGE__->add_property(blib => 'blib');
834 __PACKAGE__->add_property(build_class => 'Module::Build');
835 __PACKAGE__->add_property(build_elements => [qw(PL support pm xs pod script)]);
836 __PACKAGE__->add_property(build_script => 'Build');
837 __PACKAGE__->add_property(build_bat => 0);
838 __PACKAGE__->add_property(config_dir => '_build');
839 __PACKAGE__->add_property(include_dirs => []);
840 __PACKAGE__->add_property(metafile => 'META.yml');
841 __PACKAGE__->add_property(recurse_into => []);
842 __PACKAGE__->add_property(use_rcfile => 1);
843 __PACKAGE__->add_property(create_packlist => 1);
844 __PACKAGE__->add_property(allow_mb_mismatch => 0);
845 __PACKAGE__->add_property(config => undef);
846 __PACKAGE__->add_property(test_file_exts => ['.t']);
847 __PACKAGE__->add_property(use_tap_harness => 0);
848 __PACKAGE__->add_property(tap_harness_args => {});
849 __PACKAGE__->add_property(
850   'installdirs',
851   default => 'site',
852   check   => sub {
853     return 1 if /^(core|site|vendor)$/;
854     return shift->property_error(
855       $_ eq 'perl'
856       ? 'Perhaps you meant installdirs to be "core" rather than "perl"?'
857       : 'installdirs must be one of "core", "site", or "vendor"'
858     );
859     return shift->property_error("Perhaps you meant 'core'?") if $_ eq 'perl';
860     return 0;
861   },
862 );
863
864 {
865   my $Is_ActivePerl = eval {require ActivePerl::DocTools};
866   __PACKAGE__->add_property(html_css => $Is_ActivePerl ? 'Active.css' : '');
867 }
868
869 {
870   my @prereq_action_types = qw(requires build_requires conflicts recommends);
871   foreach my $type (@prereq_action_types) {
872     __PACKAGE__->add_property($type => {});
873   }
874   __PACKAGE__->add_property(prereq_action_types => \@prereq_action_types);
875 }
876
877 __PACKAGE__->add_property($_ => {}) for qw(
878   get_options
879   install_base_relpaths
880   install_path
881   install_sets
882   meta_add
883   meta_merge
884   original_prefix
885   prefix_relpaths
886   configure_requires
887 );
888
889 __PACKAGE__->add_property($_) for qw(
890   PL_files
891   autosplit
892   base_dir
893   bindoc_dirs
894   c_source
895   create_license
896   create_makefile_pl
897   create_readme
898   debugger
899   destdir
900   dist_abstract
901   dist_author
902   dist_name
903   dist_version
904   dist_version_from
905   extra_compiler_flags
906   extra_linker_flags
907   has_config_data
908   install_base
909   libdoc_dirs
910   license
911   magic_number
912   mb_version
913   module_name
914   orig_dir
915   perl
916   pm_files
917   pod_files
918   pollute
919   prefix
920   program_name
921   quiet
922   recursive_test_files
923   script_files
924   scripts
925   sign
926   test_files
927   verbose
928   debug
929   xs_files
930 );
931
932 sub config {
933   my $self = shift;
934   my $c = ref($self) ? $self->{config} : 'Module::Build::Config';
935   return $c->all_config unless @_;
936
937   my $key = shift;
938   return $c->get($key) unless @_;
939
940   my $val = shift;
941   return $c->set($key => $val);
942 }
943
944 sub mb_parents {
945     # Code borrowed from Class::ISA.
946     my @in_stack = (shift);
947     my %seen = ($in_stack[0] => 1);
948
949     my ($current, @out);
950     while (@in_stack) {
951         next unless defined($current = shift @in_stack)
952           && $current->isa('Module::Build::Base');
953         push @out, $current;
954         next if $current eq 'Module::Build::Base';
955         no strict 'refs';
956         unshift @in_stack,
957           map {
958               my $c = $_; # copy, to avoid being destructive
959               substr($c,0,2) = "main::" if substr($c,0,2) eq '::';
960               # Canonize the :: -> main::, ::foo -> main::foo thing.
961               # Should I ever canonize the Foo'Bar = Foo::Bar thing?
962               $seen{$c}++ ? () : $c;
963           } @{"$current\::ISA"};
964
965         # I.e., if this class has any parents (at least, ones I've never seen
966         # before), push them, in order, onto the stack of classes I need to
967         # explore.
968     }
969     shift @out;
970     return @out;
971 }
972
973 sub extra_linker_flags   { shift->_list_accessor('extra_linker_flags',   @_) }
974 sub extra_compiler_flags { shift->_list_accessor('extra_compiler_flags', @_) }
975
976 sub _list_accessor {
977   (my $self, local $_) = (shift, shift);
978   my $p = $self->{properties};
979   $p->{$_} = [@_] if @_;
980   $p->{$_} = [] unless exists $p->{$_};
981   return ref($p->{$_}) ? $p->{$_} : [$p->{$_}];
982 }
983
984 # XXX Problem - if Module::Build is loaded from a different directory,
985 # it'll look for (and perhaps destroy/create) a _build directory.
986 sub subclass {
987   my ($pack, %opts) = @_;
988
989   my $build_dir = '_build'; # XXX The _build directory is ostensibly settable by the user.  Shouldn't hard-code here.
990   $pack->delete_filetree($build_dir) if -e $build_dir;
991
992   die "Must provide 'code' or 'class' option to subclass()\n"
993     unless $opts{code} or $opts{class};
994
995   $opts{code}  ||= '';
996   $opts{class} ||= 'MyModuleBuilder';
997   
998   my $filename = File::Spec->catfile($build_dir, 'lib', split '::', $opts{class}) . '.pm';
999   my $filedir  = File::Basename::dirname($filename);
1000   $pack->log_info("Creating custom builder $filename in $filedir\n");
1001   
1002   File::Path::mkpath($filedir);
1003   die "Can't create directory $filedir: $!" unless -d $filedir;
1004   
1005   my $fh = IO::File->new("> $filename") or die "Can't create $filename: $!";
1006   print $fh <<EOF;
1007 package $opts{class};
1008 use $pack;
1009 \@ISA = qw($pack);
1010 $opts{code}
1011 1;
1012 EOF
1013   close $fh;
1014   
1015   unshift @INC, File::Spec->catdir(File::Spec->rel2abs($build_dir), 'lib');
1016   eval "use $opts{class}";
1017   die $@ if $@;
1018
1019   return $opts{class};
1020 }
1021
1022 sub dist_name {
1023   my $self = shift;
1024   my $p = $self->{properties};
1025   return $p->{dist_name} if defined $p->{dist_name};
1026   
1027   die "Can't determine distribution name, must supply either 'dist_name' or 'module_name' parameter"
1028     unless $self->module_name;
1029   
1030   ($p->{dist_name} = $self->module_name) =~ s/::/-/g;
1031   
1032   return $p->{dist_name};
1033 }
1034
1035 sub dist_version_from {
1036   my ($self) = @_;
1037   my $p = $self->{properties};
1038   if ($self->module_name) {
1039     $p->{dist_version_from} ||=
1040         join( '/', 'lib', split(/::/, $self->module_name) ) . '.pm';
1041   }
1042   return $p->{dist_version_from} || undef;
1043 }
1044
1045 sub dist_version {
1046   my ($self) = @_;
1047   my $p = $self->{properties};
1048
1049   return $p->{dist_version} if defined $p->{dist_version};
1050
1051   if ( my $dist_version_from = $self->dist_version_from ) {
1052     my $version_from = File::Spec->catfile( split( qr{/}, $dist_version_from ) );
1053     my $pm_info = Module::Build::ModuleInfo->new_from_file( $version_from )
1054       or die "Can't find file $version_from to determine version";
1055     $p->{dist_version} = $self->normalize_version( $pm_info->version() );
1056   }
1057
1058   die ("Can't determine distribution version, must supply either 'dist_version',\n".
1059        "'dist_version_from', or 'module_name' parameter")
1060     unless defined $p->{dist_version};
1061
1062   return $p->{dist_version};
1063 }
1064
1065 sub dist_author   { shift->_pod_parse('author')   }
1066 sub dist_abstract { shift->_pod_parse('abstract') }
1067
1068 sub _pod_parse {
1069   my ($self, $part) = @_;
1070   my $p = $self->{properties};
1071   my $member = "dist_$part";
1072   return $p->{$member} if defined $p->{$member};
1073   
1074   my $docfile = $self->_main_docfile
1075     or return;
1076   my $fh = IO::File->new($docfile)
1077     or return;
1078   
1079   require Module::Build::PodParser;
1080   my $parser = Module::Build::PodParser->new(fh => $fh);
1081   my $method = "get_$part";
1082   return $p->{$member} = $parser->$method();
1083 }
1084
1085 sub version_from_file { # Method provided for backwards compatibility
1086   return Module::Build::ModuleInfo->new_from_file($_[1])->version();
1087 }
1088
1089 sub find_module_by_name { # Method provided for backwards compatibility
1090   return Module::Build::ModuleInfo->find_module_by_name(@_[1,2]);
1091 }
1092
1093 sub add_to_cleanup {
1094   my $self = shift;
1095   my %files = map {$self->localize_file_path($_), 1} @_;
1096   $self->{phash}{cleanup}->write(\%files);
1097 }
1098
1099 sub cleanup {
1100   my $self = shift;
1101   my $all = $self->{phash}{cleanup}->read;
1102   return keys %$all;
1103 }
1104
1105 sub config_file {
1106   my $self = shift;
1107   return unless -d $self->config_dir;
1108   return File::Spec->catfile($self->config_dir, @_);
1109 }
1110
1111 sub read_config {
1112   my ($self) = @_;
1113   
1114   my $file = $self->config_file('build_params')
1115     or die "Can't find 'build_params' in " . $self->config_dir;
1116   my $fh = IO::File->new($file) or die "Can't read '$file': $!";
1117   my $ref = eval do {local $/; <$fh>};
1118   die if $@;
1119   my $c;
1120   ($self->{args}, $c, $self->{properties}) = @$ref;
1121   $self->{config} = Module::Build::Config->new(values => $c);
1122   close $fh;
1123 }
1124
1125 sub has_config_data {
1126   my $self = shift;
1127   return scalar grep $self->{phash}{$_}->has_data(), qw(config_data features auto_features);
1128 }
1129
1130 sub _write_data {
1131   my ($self, $filename, $data) = @_;
1132   
1133   my $file = $self->config_file($filename);
1134   my $fh = IO::File->new("> $file") or die "Can't create '$file': $!";
1135   unless (ref($data)) {  # e.g. magicnum
1136     print $fh $data;
1137     return;
1138   }
1139
1140   print {$fh} Module::Build::Dumper->_data_dump($data);
1141 }
1142
1143 sub write_config {
1144   my ($self) = @_;
1145   
1146   File::Path::mkpath($self->{properties}{config_dir});
1147   -d $self->{properties}{config_dir} or die "Can't mkdir $self->{properties}{config_dir}: $!";
1148   
1149   my @items = @{ $self->prereq_action_types };
1150   $self->_write_data('prereqs', { map { $_, $self->$_() } @items });
1151   $self->_write_data('build_params', [$self->{args}, $self->{config}->values_set, $self->{properties}]);
1152
1153   # Set a new magic number and write it to a file
1154   $self->_write_data('magicnum', $self->magic_number(int rand 1_000_000));
1155
1156   $self->{phash}{$_}->write() foreach qw(notes cleanup features auto_features config_data runtime_params);
1157 }
1158
1159 sub check_autofeatures {
1160   my ($self) = @_;
1161   my $features = $self->auto_features;
1162   
1163   return unless %$features;
1164
1165   $self->log_info("Checking features:\n");
1166
1167   # TODO refactor into ::Util
1168   my $longest = sub {
1169     my @str = @_ or croak("no strings given");
1170
1171     my @len = map({length($_)} @str);
1172     my $max = 0;
1173     my $longest;
1174     for my $i (0..$#len) {
1175       ($max, $longest) = ($len[$i], $str[$i]) if($len[$i] > $max);
1176     }
1177     return($longest);
1178   };
1179   my $max_name_len = length($longest->(keys %$features));
1180
1181   while (my ($name, $info) = each %$features) {
1182     $self->log_info("  $name" . '.' x ($max_name_len - length($name) + 4));
1183
1184     if ( my $failures = $self->prereq_failures($info) ) {
1185       my $disabled = grep( /^(?:\w+_)?(?:requires|conflicts)$/,
1186                            keys %$failures ) ? 1 : 0;
1187       $self->log_info( $disabled ? "disabled\n" : "enabled\n" );
1188
1189       my $log_text;
1190       while (my ($type, $prereqs) = each %$failures) {
1191         while (my ($module, $status) = each %$prereqs) {
1192           my $required =
1193             ($type =~ /^(?:\w+_)?(?:requires|conflicts)$/) ? 1 : 0;
1194           my $prefix = ($required) ? '-' : '*';
1195           $log_text .= "    $prefix $status->{message}\n";
1196         }
1197       }
1198       $self->log_warn("$log_text") unless $self->quiet;
1199     } else {
1200       $self->log_info("enabled\n");
1201     }
1202   }
1203
1204   $self->log_warn("\n") unless $self->quiet;
1205 }
1206
1207 sub prereq_failures {
1208   my ($self, $info) = @_;
1209
1210   my @types = @{ $self->prereq_action_types };
1211   $info ||= {map {$_, $self->$_()} @types};
1212
1213   my $out;
1214
1215   foreach my $type (@types) {
1216     my $prereqs = $info->{$type};
1217     while ( my ($modname, $spec) = each %$prereqs ) {
1218       my $status = $self->check_installed_status($modname, $spec);
1219
1220       if ($type =~ /^(?:\w+_)?conflicts$/) {
1221         next if !$status->{ok};
1222         $status->{conflicts} = delete $status->{need};
1223         $status->{message} = "$modname ($status->{have}) conflicts with this distribution";
1224
1225       } elsif ($type =~ /^(?:\w+_)?recommends$/) {
1226         next if $status->{ok};
1227         $status->{message} = (!ref($status->{have}) && $status->{have} eq '<none>'
1228                               ? "Optional prerequisite $modname is not installed"
1229                               : "$modname ($status->{have}) is installed, but we prefer to have $spec");
1230       } else {
1231         next if $status->{ok};
1232       }
1233
1234       $out->{$type}{$modname} = $status;
1235     }
1236   }
1237
1238   return $out;
1239 }
1240
1241 # returns a hash of defined prerequisites; i.e. only prereq types with values
1242 sub _enum_prereqs {
1243   my $self = shift;
1244   my %prereqs;
1245   foreach my $type ( @{ $self->prereq_action_types } ) {
1246     if ( $self->can( $type ) ) {
1247       my $prereq = $self->$type() || {};
1248       $prereqs{$type} = $prereq if %$prereq;
1249     }
1250   }
1251   return \%prereqs;
1252 }
1253
1254 sub check_prereq {
1255   my $self = shift;
1256
1257   # If we have XS files, make sure we can process them.
1258   my $xs_files = $self->find_xs_files;
1259   if (keys %$xs_files && !$self->_mb_feature('C_support')) {
1260     $self->log_warn("Warning: this distribution contains XS files, ".
1261                     "but Module::Build is not configured with C_support.  ".
1262                     "Please install ExtUtils::CBuilder to enable C_support.\n");
1263   }
1264
1265   # Check to see if there are any prereqs to check
1266   my $info = $self->_enum_prereqs;
1267   return 1 unless $info;
1268
1269   $self->log_info("Checking prerequisites...\n");
1270
1271   my $failures = $self->prereq_failures($info);
1272
1273   if ( $failures ) {
1274
1275     while (my ($type, $prereqs) = each %$failures) {
1276       while (my ($module, $status) = each %$prereqs) {
1277         my $prefix = ($type =~ /^(?:\w+_)?recommends$/) ? '*' : '- ERROR:';
1278         $self->log_warn(" $prefix $status->{message}\n");
1279       }
1280     }
1281
1282     $self->log_warn(<<EOF);
1283
1284 ERRORS/WARNINGS FOUND IN PREREQUISITES.  You may wish to install the versions
1285 of the modules indicated above before proceeding with this installation
1286
1287 EOF
1288     return 0;
1289
1290   } else {
1291
1292     $self->log_info("Looks good\n\n");
1293     return 1;
1294
1295   }
1296 }
1297
1298 sub perl_version {
1299   my ($self) = @_;
1300   # Check the current perl interpreter
1301   # It's much more convenient to use $] here than $^V, but 'man
1302   # perlvar' says I'm not supposed to.  Bloody tyrant.
1303   return $^V ? $self->perl_version_to_float(sprintf "%vd", $^V) : $];
1304 }
1305
1306 sub perl_version_to_float {
1307   my ($self, $version) = @_;
1308   return $version if grep( /\./, $version ) < 2;
1309   $version =~ s/\./../;
1310   $version =~ s/\.(\d+)/sprintf '%03d', $1/eg;
1311   return $version;
1312 }
1313
1314 sub _parse_conditions {
1315   my ($self, $spec) = @_;
1316
1317   if ($spec =~ /^\s*([\w.]+)\s*$/) { # A plain number, maybe with dots, letters, and underscores
1318     return (">= $spec");
1319   } else {
1320     return split /\s*,\s*/, $spec;
1321   }
1322 }
1323
1324 sub check_installed_status {
1325   my ($self, $modname, $spec) = @_;
1326   my %status = (need => $spec);
1327   
1328   if ($modname eq 'perl') {
1329     $status{have} = $self->perl_version;
1330   
1331   } elsif (eval { no strict; $status{have} = ${"${modname}::VERSION"} }) {
1332     # Don't try to load if it's already loaded
1333     
1334   } else {
1335     my $pm_info = Module::Build::ModuleInfo->new_from_module( $modname );
1336     unless (defined( $pm_info )) {
1337       @status{ qw(have message) } = ('<none>', "$modname is not installed");
1338       return \%status;
1339     }
1340     
1341     $status{have} = $pm_info->version();
1342     if ($spec and !defined($status{have})) {
1343       @status{ qw(have message) } = (undef, "Couldn't find a \$VERSION in prerequisite $modname");
1344       return \%status;
1345     }
1346   }
1347   
1348   my @conditions = $self->_parse_conditions($spec);
1349   
1350   foreach (@conditions) {
1351     my ($op, $version) = /^\s*  (<=?|>=?|==|!=)  \s*  ([\w.]+)  \s*$/x
1352       or die "Invalid prerequisite condition '$_' for $modname";
1353     
1354     $version = $self->perl_version_to_float($version)
1355       if $modname eq 'perl';
1356     
1357     next if $op eq '>=' and !$version;  # Module doesn't have to actually define a $VERSION
1358     
1359     unless ($self->compare_versions( $status{have}, $op, $version )) {
1360       $status{message} = "$modname ($status{have}) is installed, but we need version $op $version";
1361       return \%status;
1362     }
1363   }
1364   
1365   $status{ok} = 1;
1366   return \%status;
1367 }
1368
1369 sub compare_versions {
1370   my $self = shift;
1371   my ($v1, $op, $v2) = @_;
1372   $v1 = Module::Build::Version->new($v1) 
1373     unless UNIVERSAL::isa($v1,'Module::Build::Version');
1374
1375   my $eval_str = "\$v1 $op \$v2";
1376   my $result   = eval $eval_str;
1377   $self->log_warn("error comparing versions: '$eval_str' $@") if $@;
1378
1379   return $result;
1380 }
1381
1382 # I wish I could set $! to a string, but I can't, so I use $@
1383 sub check_installed_version {
1384   my ($self, $modname, $spec) = @_;
1385   
1386   my $status = $self->check_installed_status($modname, $spec);
1387   
1388   if ($status->{ok}) {
1389     return $status->{have} if $status->{have} and "$status->{have}" ne '<none>';
1390     return '0 but true';
1391   }
1392   
1393   $@ = $status->{message};
1394   return 0;
1395 }
1396
1397 sub make_executable {
1398   # Perl's chmod() is mapped to useful things on various non-Unix
1399   # platforms, so we use it in the base class even though it looks
1400   # Unixish.
1401
1402   my $self = shift;
1403   foreach (@_) {
1404     my $current_mode = (stat $_)[2];
1405     chmod $current_mode | oct(111), $_;
1406   }
1407 }
1408
1409 sub is_executable {
1410   # We assume this does the right thing on generic platforms, though
1411   # we do some other more specific stuff on Unixish platforms.
1412   my ($self, $file) = @_;
1413   return -x $file;
1414 }
1415
1416 sub _startperl { shift()->config('startperl') }
1417
1418 # Return any directories in @INC which are not in the default @INC for
1419 # this perl.  For example, stuff passed in with -I or loaded with "use lib".
1420 sub _added_to_INC {
1421   my $self = shift;
1422
1423   my %seen;
1424   $seen{$_}++ foreach $self->_default_INC;
1425   return grep !$seen{$_}++, @INC;
1426 }
1427
1428 # Determine the default @INC for this Perl
1429 {
1430   my @default_inc; # Memoize
1431   sub _default_INC {
1432     my $self = shift;
1433     return @default_inc if @default_inc;
1434     
1435     local $ENV{PERL5LIB};  # this is not considered part of the default.
1436     
1437     my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
1438     
1439     my @inc = $self->_backticks($perl, '-le', 'print for @INC');
1440     chomp @inc;
1441     
1442     return @default_inc = @inc;
1443   }
1444 }
1445
1446 sub print_build_script {
1447   my ($self, $fh) = @_;
1448   
1449   my $build_package = $self->build_class;
1450   
1451   my $closedata="";
1452
1453   my %q = map {$_, $self->$_()} qw(config_dir base_dir);
1454
1455   my $case_tolerant = 0+(File::Spec->can('case_tolerant')
1456                          && File::Spec->case_tolerant);
1457   $q{base_dir} = uc $q{base_dir} if $case_tolerant;
1458   $q{base_dir} = Win32::GetShortPathName($q{base_dir}) if $self->is_windowsish;
1459
1460   $q{magic_numfile} = $self->config_file('magicnum');
1461
1462   my @myINC = $self->_added_to_INC;
1463   for (@myINC, values %q) {
1464     $_ = File::Spec->canonpath( $_ );
1465     s/([\\\'])/\\$1/g;
1466   }
1467
1468   my $quoted_INC = join ",\n", map "     '$_'", @myINC;
1469   my $shebang = $self->_startperl;
1470   my $magic_number = $self->magic_number;
1471
1472   print $fh <<EOF;
1473 $shebang
1474
1475 use strict;
1476 use Cwd;
1477 use File::Basename;
1478 use File::Spec;
1479
1480 sub magic_number_matches {
1481   return 0 unless -e '$q{magic_numfile}';
1482   local *FH;
1483   open FH, '$q{magic_numfile}' or return 0;
1484   my \$filenum = <FH>;
1485   close FH;
1486   return \$filenum == $magic_number;
1487 }
1488
1489 my \$progname;
1490 my \$orig_dir;
1491 BEGIN {
1492   \$^W = 1;  # Use warnings
1493   \$progname = basename(\$0);
1494   \$orig_dir = Cwd::cwd();
1495   my \$base_dir = '$q{base_dir}';
1496   if (!magic_number_matches()) {
1497     unless (chdir(\$base_dir)) {
1498       die ("Couldn't chdir(\$base_dir), aborting\\n");
1499     }
1500     unless (magic_number_matches()) {
1501       die ("Configuration seems to be out of date, please re-run 'perl Build.PL' again.\\n");
1502     }
1503   }
1504   unshift \@INC,
1505     (
1506 $quoted_INC
1507     );
1508 }
1509
1510 close(*DATA) unless eof(*DATA); # ensure no open handles to this script
1511
1512 use $build_package;
1513
1514 # Some platforms have problems setting \$^X in shebang contexts, fix it up here
1515 \$^X = Module::Build->find_perl_interpreter;
1516
1517 if (-e 'Build.PL' and not $build_package->up_to_date('Build.PL', \$progname)) {
1518    warn "Warning: Build.PL has been altered.  You may need to run 'perl Build.PL' again.\\n";
1519 }
1520
1521 # This should have just enough arguments to be able to bootstrap the rest.
1522 my \$build = $build_package->resume (
1523   properties => {
1524     config_dir => '$q{config_dir}',
1525     orig_dir => \$orig_dir,
1526   },
1527 );
1528
1529 \$build->dispatch;
1530 EOF
1531 }
1532
1533 sub create_build_script {
1534   my ($self) = @_;
1535   $self->write_config;
1536   
1537   my ($build_script, $dist_name, $dist_version)
1538     = map $self->$_(), qw(build_script dist_name dist_version);
1539   
1540   if ( $self->delete_filetree($build_script) ) {
1541     $self->log_info("Removed previous script '$build_script'\n\n");
1542   }
1543
1544   $self->log_info("Creating new '$build_script' script for ",
1545                   "'$dist_name' version '$dist_version'\n");
1546   my $fh = IO::File->new(">$build_script") or die "Can't create '$build_script': $!";
1547   $self->print_build_script($fh);
1548   close $fh;
1549   
1550   $self->make_executable($build_script);
1551
1552   return 1;
1553 }
1554
1555 sub check_manifest {
1556   my $self = shift;
1557   return unless -e 'MANIFEST';
1558   
1559   # Stolen nearly verbatim from MakeMaker.  But ExtUtils::Manifest
1560   # could easily be re-written into a modern Perl dialect.
1561
1562   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
1563   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
1564   
1565   $self->log_info("Checking whether your kit is complete...\n");
1566   if (my @missed = ExtUtils::Manifest::manicheck()) {
1567     $self->log_warn("WARNING: the following files are missing in your kit:\n",
1568                     "\t", join("\n\t", @missed), "\n",
1569                     "Please inform the author.\n\n");
1570   } else {
1571     $self->log_info("Looks good\n\n");
1572   }
1573 }
1574
1575 sub dispatch {
1576   my $self = shift;
1577   local $self->{_completed_actions} = {};
1578
1579   if (@_) {
1580     my ($action, %p) = @_;
1581     my $args = $p{args} ? delete($p{args}) : {};
1582
1583     local $self->{invoked_action} = $action;
1584     local $self->{args} = {%{$self->{args}}, %$args};
1585     local $self->{properties} = {%{$self->{properties}}, %p};
1586     return $self->_call_action($action);
1587   }
1588
1589   die "No build action specified" unless $self->{action};
1590   local $self->{invoked_action} = $self->{action};
1591   $self->_call_action($self->{action});
1592 }
1593
1594 sub _call_action {
1595   my ($self, $action) = @_;
1596
1597   return if $self->{_completed_actions}{$action}++;
1598
1599   local $self->{action} = $action;
1600   my $method = $self->can_action( $action );
1601   die "No action '$action' defined, try running the 'help' action.\n" unless $method;
1602   $self->log_debug("Starting ACTION_$action\n");
1603   my $rc = $self->$method();
1604   $self->log_debug("Finished ACTION_$action\n");
1605   return $rc;
1606 }
1607
1608 sub can_action {
1609   my ($self, $action) = @_;
1610   return $self->can( "ACTION_$action" );
1611 }
1612
1613 # cuts the user-specified options out of the command-line args
1614 sub cull_options {
1615     my $self = shift;
1616     my (@argv) = @_;
1617
1618     # XXX is it even valid to call this as a class method?
1619     return({}, @argv) unless(ref($self)); # no object
1620
1621     my $specs = $self->get_options;
1622     return({}, @argv) unless($specs and %$specs); # no user options
1623
1624     require Getopt::Long;
1625     # XXX Should we let Getopt::Long handle M::B's options? That would
1626     # be easy-ish to add to @specs right here, but wouldn't handle options
1627     # passed without "--" as M::B currently allows. We might be able to
1628     # get around this by setting the "prefix_pattern" Configure option.
1629     my @specs;
1630     my $args = {};
1631     # Construct the specifications for GetOptions.
1632     while (my ($k, $v) = each %$specs) {
1633         # Throw an error if specs conflict with our own.
1634         die "Option specification '$k' conflicts with a " . ref $self
1635           . " option of the same name"
1636           if $self->valid_property($k);
1637         push @specs, $k . (defined $v->{type} ? $v->{type} : '');
1638         push @specs, $v->{store} if exists $v->{store};
1639         $args->{$k} = $v->{default} if exists $v->{default};
1640     }
1641
1642     local @ARGV = @argv; # No other way to dupe Getopt::Long
1643
1644     # Get the options values and return them.
1645     # XXX Add option to allow users to set options?
1646     if ( @specs ) {
1647       Getopt::Long::Configure('pass_through');
1648       Getopt::Long::GetOptions($args, @specs);
1649     }
1650
1651     return $args, @ARGV;
1652 }
1653
1654 sub unparse_args {
1655   my ($self, $args) = @_;
1656   my @out;
1657   while (my ($k, $v) = each %$args) {
1658     push @out, (UNIVERSAL::isa($v, 'HASH')  ? map {+"--$k", "$_=$v->{$_}"} keys %$v :
1659                 UNIVERSAL::isa($v, 'ARRAY') ? map {+"--$k", $_} @$v :
1660                 ("--$k", $v));
1661   }
1662   return @out;
1663 }
1664
1665 sub args {
1666     my $self = shift;
1667     return wantarray ? %{ $self->{args} } : $self->{args} unless @_;
1668     my $key = shift;
1669     $self->{args}{$key} = shift if @_;
1670     return $self->{args}{$key};
1671 }
1672
1673 # allows select parameters (with underscores) to be spoken with dashes
1674 # when used as command-line options
1675 sub _translate_option {
1676   my $self = shift;
1677   my $opt  = shift;
1678
1679   (my $tr_opt = $opt) =~ tr/-/_/;
1680
1681   return $tr_opt if grep $tr_opt =~ /^(?:no_?)?$_$/, qw(
1682     create_license
1683     create_makefile_pl
1684     create_readme
1685     extra_compiler_flags
1686     extra_linker_flags
1687     html_css
1688     install_base
1689     install_path
1690     meta_add
1691     meta_merge
1692     test_files
1693     use_rcfile
1694     use_tap_harness
1695     tap_harness_args
1696   ); # normalize only selected option names
1697
1698   return $opt;
1699 }
1700
1701 sub _read_arg {
1702   my ($self, $args, $key, $val) = @_;
1703
1704   $key = $self->_translate_option($key);
1705
1706   if ( exists $args->{$key} ) {
1707     $args->{$key} = [ $args->{$key} ] unless ref $args->{$key};
1708     push @{$args->{$key}}, $val;
1709   } else {
1710     $args->{$key} = $val;
1711   }
1712 }
1713
1714 # decide whether or not an option requires/has an operand
1715 sub _optional_arg {
1716   my $self = shift;
1717   my $opt  = shift;
1718   my $argv = shift;
1719
1720   $opt = $self->_translate_option($opt);
1721
1722   my @bool_opts = qw(
1723     build_bat
1724     create_license
1725     create_readme
1726     pollute
1727     quiet
1728     uninst
1729     use_rcfile
1730     verbose
1731     debug
1732     sign
1733     use_tap_harness
1734   );
1735
1736   # inverted boolean options; eg --noverbose or --no-verbose
1737   # converted to proper name & returned with false value (verbose, 0)
1738   if ( grep $opt =~ /^no[-_]?$_$/, @bool_opts ) {
1739     $opt =~ s/^no-?//;
1740     return ($opt, 0);
1741   }
1742
1743   # non-boolean option; return option unchanged along with its argument
1744   return ($opt, shift(@$argv)) unless grep $_ eq $opt, @bool_opts;
1745
1746   # we're punting a bit here, if an option appears followed by a digit
1747   # we take the digit as the argument for the option. If there is
1748   # nothing that looks like a digit, we pretend the option is a flag
1749   # that is being set and has no argument.
1750   my $arg = 1;
1751   $arg = shift(@$argv) if @$argv && $argv->[0] =~ /^\d+$/;
1752
1753   return ($opt, $arg);
1754 }
1755
1756 sub read_args {
1757   my $self = shift;
1758
1759   (my $args, @_) = $self->cull_options(@_);
1760   my %args = %$args;
1761
1762   my $opt_re = qr/[\w\-]+/;
1763
1764   my ($action, @argv);
1765   while (@_) {
1766     local $_ = shift;
1767     if ( /^(?:--)?($opt_re)=(.*)$/ ) {
1768       $self->_read_arg(\%args, $1, $2);
1769     } elsif ( /^--($opt_re)$/ ) {
1770       my($opt, $arg) = $self->_optional_arg($1, \@_);
1771       $self->_read_arg(\%args, $opt, $arg);
1772     } elsif ( /^($opt_re)$/ and !defined($action)) {
1773       $action = $1;
1774     } else {
1775       push @argv, $_;
1776     }
1777   }
1778   $args{ARGV} = \@argv;
1779
1780   for ('extra_compiler_flags', 'extra_linker_flags') {
1781     $args{$_} = [ $self->split_like_shell($args{$_}) ] if exists $args{$_};
1782   }
1783
1784   # Convert to arrays
1785   for ('include_dirs') {
1786     $args{$_} = [ $args{$_} ] if exists $args{$_} && !ref $args{$_}
1787   }
1788
1789   # Hashify these parameters
1790   for ($self->hash_properties, 'config') {
1791     next unless exists $args{$_};
1792     my %hash;
1793     $args{$_} ||= [];
1794     $args{$_} = [ $args{$_} ] unless ref $args{$_};
1795     foreach my $arg ( @{$args{$_}} ) {
1796       $arg =~ /(\w+)=(.*)/
1797         or die "Malformed '$_' argument: '$arg' should be something like 'foo=bar'";
1798       $hash{$1} = $2;
1799     }
1800     $args{$_} = \%hash;
1801   }
1802
1803   # De-tilde-ify any path parameters
1804   for my $key (qw(prefix install_base destdir)) {
1805     next if !defined $args{$key};
1806     $args{$key} = $self->_detildefy($args{$key});
1807   }
1808
1809   for my $key (qw(install_path)) {
1810     next if !defined $args{$key};
1811
1812     for my $subkey (keys %{$args{$key}}) {
1813       next if !defined $args{$key}{$subkey};
1814       my $subkey_ext = $self->_detildefy($args{$key}{$subkey});
1815       if ( $subkey eq 'html' ) { # translate for compatibility
1816         $args{$key}{binhtml} = $subkey_ext;
1817         $args{$key}{libhtml} = $subkey_ext;
1818       } else {
1819         $args{$key}{$subkey} = $subkey_ext;
1820       }
1821     }
1822   }
1823
1824   if ($args{makefile_env_macros}) {
1825     require Module::Build::Compat;
1826     %args = (%args, Module::Build::Compat->makefile_to_build_macros);
1827   }
1828   
1829   return \%args, $action;
1830 }
1831
1832 # Default: do nothing.  Overridden for Unix & Windows.
1833 sub _detildefy {}
1834
1835
1836 # merge Module::Build argument lists that have already been parsed
1837 # by read_args(). Takes two references to option hashes and merges
1838 # the contents, giving priority to the first.
1839 sub _merge_arglist {
1840   my( $self, $opts1, $opts2 ) = @_;
1841
1842   my %new_opts = %$opts1;
1843   while (my ($key, $val) = each %$opts2) {
1844     if ( exists( $opts1->{$key} ) ) {
1845       if ( ref( $val ) eq 'HASH' ) {
1846         while (my ($k, $v) = each %$val) {
1847           $new_opts{$key}{$k} = $v unless exists( $opts1->{$key}{$k} );
1848         }
1849       }
1850     } else {
1851       $new_opts{$key} = $val
1852     }
1853   }
1854
1855   return %new_opts;
1856 }
1857
1858 # Look for a home directory on various systems.
1859 sub _home_dir {
1860   my @home_dirs;
1861   push( @home_dirs, $ENV{HOME} ) if $ENV{HOME};
1862
1863   push( @home_dirs, File::Spec->catpath($ENV{HOMEDRIVE}, $ENV{HOMEPATH}, '') )
1864       if $ENV{HOMEDRIVE} && $ENV{HOMEPATH};
1865
1866   my @other_home_envs = qw( USERPROFILE APPDATA WINDIR SYS$LOGIN );
1867   push( @home_dirs, map $ENV{$_}, grep $ENV{$_}, @other_home_envs );
1868
1869   my @real_home_dirs = grep -d, @home_dirs;
1870
1871   return wantarray ? @real_home_dirs : shift( @real_home_dirs );
1872 }
1873
1874 sub _find_user_config {
1875   my $self = shift;
1876   my $file = shift;
1877   foreach my $dir ( $self->_home_dir ) {
1878     my $path = File::Spec->catfile( $dir, $file );
1879     return $path if -e $path;
1880   }
1881   return undef;
1882 }
1883
1884 # read ~/.modulebuildrc returning global options '*' and
1885 # options specific to the currently executing $action.
1886 sub read_modulebuildrc {
1887   my( $self, $action ) = @_;
1888
1889   return () unless $self->use_rcfile;
1890
1891   my $modulebuildrc;
1892   if ( exists($ENV{MODULEBUILDRC}) && $ENV{MODULEBUILDRC} eq 'NONE' ) {
1893     return ();
1894   } elsif ( exists($ENV{MODULEBUILDRC}) && -e $ENV{MODULEBUILDRC} ) {
1895     $modulebuildrc = $ENV{MODULEBUILDRC};
1896   } elsif ( exists($ENV{MODULEBUILDRC}) ) {
1897     $self->log_warn("WARNING: Can't find resource file " .
1898                     "'$ENV{MODULEBUILDRC}' defined in environment.\n" .
1899                     "No options loaded\n");
1900     return ();
1901   } else {
1902     $modulebuildrc = $self->_find_user_config( '.modulebuildrc' );
1903     return () unless $modulebuildrc;
1904   }
1905
1906   my $fh = IO::File->new( $modulebuildrc )
1907       or die "Can't open $modulebuildrc: $!";
1908
1909   my %options; my $buffer = '';
1910   while (defined( my $line = <$fh> )) {
1911     chomp( $line );
1912     $line =~ s/#.*$//;
1913     next unless length( $line );
1914
1915     if ( $line =~ /^\S/ ) {
1916       if ( $buffer ) {
1917         my( $action, $options ) = split( /\s+/, $buffer, 2 );
1918         $options{$action} .= $options . ' ';
1919         $buffer = '';
1920       }
1921       $buffer = $line;
1922     } else {
1923       $buffer .= $line;
1924     }
1925   }
1926
1927   if ( $buffer ) { # anything left in $buffer ?
1928     my( $action, $options ) = split( /\s+/, $buffer, 2 );
1929     $options{$action} .= $options . ' '; # merge if more than one line
1930   }
1931
1932   my ($global_opts) =
1933     $self->read_args( $self->split_like_shell( $options{'*'} || '' ) );
1934   my ($action_opts) =
1935     $self->read_args( $self->split_like_shell( $options{$action} || '' ) );
1936
1937   # specific $action options take priority over global options '*'
1938   return $self->_merge_arglist( $action_opts, $global_opts );
1939 }
1940
1941 # merge the relevant options in ~/.modulebuildrc into Module::Build's
1942 # option list where they do not conflict with commandline options.
1943 sub merge_modulebuildrc {
1944   my( $self, $action, %cmdline_opts ) = @_;
1945   my %rc_opts = $self->read_modulebuildrc( $action || $self->{action} || 'build' );
1946   my %new_opts = $self->_merge_arglist( \%cmdline_opts, \%rc_opts );
1947   $self->merge_args( $action, %new_opts );
1948 }
1949
1950 sub merge_args {
1951   my ($self, $action, %args) = @_;
1952   $self->{action} = $action if defined $action;
1953
1954   my %additive = map { $_ => 1 } $self->hash_properties;
1955
1956   # Extract our 'properties' from $cmd_args, the rest are put in 'args'.
1957   while (my ($key, $val) = each %args) {
1958     $self->{phash}{runtime_params}->access( $key => $val )
1959       if $self->valid_property($key);
1960
1961     if ($key eq 'config') {
1962       $self->config($_ => $val->{$_}) foreach keys %$val;
1963     } else {
1964       my $add_to = $additive{$key}             ? $self->{properties}{$key} :
1965                    $self->valid_property($key) ? $self->{properties}       :
1966                    $self->{args}               ;
1967
1968       if ($additive{$key}) {
1969         $add_to->{$_} = $val->{$_} foreach keys %$val;
1970       } else {
1971         $add_to->{$key} = $val;
1972       }
1973     }
1974   }
1975 }
1976
1977 sub cull_args {
1978   my $self = shift;
1979   my ($args, $action) = $self->read_args(@_);
1980   $self->merge_args($action, %$args);
1981   $self->merge_modulebuildrc( $action, %$args );
1982 }
1983
1984 sub super_classes {
1985   my ($self, $class, $seen) = @_;
1986   $class ||= ref($self) || $self;
1987   $seen  ||= {};
1988   
1989   no strict 'refs';
1990   my @super = grep {not $seen->{$_}++} $class, @{ $class . '::ISA' };
1991   return @super, map {$self->super_classes($_,$seen)} @super;
1992 }
1993
1994 sub known_actions {
1995   my ($self) = @_;
1996
1997   my %actions;
1998   no strict 'refs';
1999   
2000   foreach my $class ($self->super_classes) {
2001     foreach ( keys %{ $class . '::' } ) {
2002       $actions{$1}++ if /^ACTION_(\w+)/;
2003     }
2004   }
2005
2006   return wantarray ? sort keys %actions : \%actions;
2007 }
2008
2009 sub get_action_docs {
2010   my ($self, $action) = @_;
2011   my $actions = $self->known_actions;
2012   die "No known action '$action'" unless $actions->{$action};
2013
2014   my ($files_found, @docs) = (0);
2015   foreach my $class ($self->super_classes) {
2016     (my $file = $class) =~ s{::}{/}g;
2017     # NOTE: silently skipping relative paths if any chdir() happened
2018     $file = $INC{$file . '.pm'} or next;
2019     my $fh = IO::File->new("< $file") or next;
2020     $files_found++;
2021
2022     # Code below modified from /usr/bin/perldoc
2023
2024     # Skip to ACTIONS section
2025     local $_;
2026     while (<$fh>) {
2027       last if /^=head1 ACTIONS\s/;
2028     }
2029
2030     # Look for our action and determine the style
2031     my $style;
2032     while (<$fh>) {
2033       last if /^=head1 /;
2034
2035       # only item and head2 are allowed (3&4 are not in 5.005)
2036       if(/^=(item|head2)\s+\Q$action\E\b/) {
2037         $style = $1;
2038         push @docs, $_;
2039         last;
2040       }
2041     }
2042     $style or next; # not here
2043
2044     # and the content
2045     if($style eq 'item') {
2046       my ($found, $inlist) = (0, 0);
2047       while (<$fh>) {
2048         if (/^=(item|back)/) {
2049           last unless $inlist;
2050         }
2051         push @docs, $_;
2052         ++$inlist if /^=over/;
2053         --$inlist if /^=back/;
2054       }
2055     }
2056     else { # head2 style
2057       # stop at anything equal or greater than the found level
2058       while (<$fh>) {
2059         last if(/^=(?:head[12]|cut)/);
2060         push @docs, $_;
2061       }
2062     }
2063     # TODO maybe disallow overriding just pod for an action
2064     # TODO and possibly: @docs and last;
2065   }
2066
2067   unless ($files_found) {
2068     $@ = "Couldn't find any documentation to search";
2069     return;
2070   }
2071   unless (@docs) {
2072     $@ = "Couldn't find any docs for action '$action'";
2073     return;
2074   }
2075   
2076   return join '', @docs;
2077 }
2078
2079 sub ACTION_prereq_report {
2080   my $self = shift;
2081   $self->log_info( $self->prereq_report );
2082 }
2083
2084 sub ACTION_prereq_data {
2085   my $self = shift;
2086   $self->log_info( Module::Build::Dumper->_data_dump( $self->prereq_data ) );
2087 }
2088
2089 sub prereq_data {
2090   my $self = shift;
2091   my @types = ('configure_requires', @{ $self->prereq_action_types } );
2092   my $info = { map { $_ => $self->$_() } grep { %{$self->$_()} } @types };
2093   return $info;
2094 }
2095
2096 sub prereq_report {
2097   my $self = shift;
2098   my $info = $self->prereq_data;
2099
2100   my $output = '';
2101   foreach my $type (keys %$info) {
2102     my $prereqs = $info->{$type};
2103     $output .= "\n$type:\n";
2104     my $mod_len = 2;
2105     my $ver_len = 4;
2106     my %mods;
2107     while ( my ($modname, $spec) = each %$prereqs ) {
2108       my $len  = length $modname;
2109       $mod_len = $len if $len > $mod_len;
2110       $spec    ||= '0';
2111       $len     = length $spec;
2112       $ver_len = $len if $len > $ver_len;
2113
2114       my $mod = $self->check_installed_status($modname, $spec);
2115       $mod->{name} = $modname;
2116       $mod->{ok} ||= 0;
2117       $mod->{ok} = ! $mod->{ok} if $type =~ /^(\w+_)?conflicts$/;
2118
2119       $mods{lc $modname} = $mod;
2120     }
2121
2122     my $space  = q{ } x ($mod_len - 3);
2123     my $vspace = q{ } x ($ver_len - 3);
2124     my $sline  = q{-} x ($mod_len - 3);
2125     my $vline  = q{-} x ($ver_len - 3);
2126     my $disposition = ($type =~ /^(\w+_)?conflicts$/) ?
2127                         'Clash' : 'Need';
2128     $output .=
2129       "    Module $space  $disposition $vspace  Have\n".
2130       "    ------$sline+------$vline-+----------\n";
2131
2132
2133     for my $k (sort keys %mods) {
2134       my $mod = $mods{$k};
2135       my $space  = q{ } x ($mod_len - length $k);
2136       my $vspace = q{ } x ($ver_len - length $mod->{need});
2137       my $f = $mod->{ok} ? ' ' : '!';
2138       $output .=
2139         "  $f $mod->{name} $space     $mod->{need}  $vspace   ".
2140         (defined($mod->{have}) ? $mod->{have} : "")."\n";
2141     }
2142   }
2143   return $output;
2144 }
2145
2146 sub ACTION_help {
2147   my ($self) = @_;
2148   my $actions = $self->known_actions;
2149   
2150   if (@{$self->{args}{ARGV}}) {
2151     my $msg = eval {$self->get_action_docs($self->{args}{ARGV}[0], $actions)};
2152     print $@ ? "$@\n" : $msg;
2153     return;
2154   }
2155
2156   print <<EOF;
2157
2158  Usage: $0 <action> arg1=value arg2=value ...
2159  Example: $0 test verbose=1
2160  
2161  Actions defined:
2162 EOF
2163   
2164   print $self->_action_listing($actions);
2165
2166   print "\nRun `Build help <action>` for details on an individual action.\n";
2167   print "See `perldoc Module::Build` for complete documentation.\n";
2168 }
2169
2170 sub _action_listing {
2171   my ($self, $actions) = @_;
2172
2173   # Flow down columns, not across rows
2174   my @actions = sort keys %$actions;
2175   @actions = map $actions[($_ + ($_ % 2) * @actions) / 2],  0..$#actions;
2176   
2177   my $out = '';
2178   while (my ($one, $two) = splice @actions, 0, 2) {
2179     $out .= sprintf("  %-12s                   %-12s\n", $one, $two||'');
2180   }
2181   return $out;
2182 }
2183
2184 sub ACTION_retest {
2185   my ($self) = @_;
2186   
2187   # Protect others against our @INC changes
2188   local @INC = @INC;
2189
2190   # Filter out nonsensical @INC entries - some versions of
2191   # Test::Harness will really explode the number of entries here
2192   @INC = grep {ref() || -d} @INC if @INC > 100;
2193
2194   $self->do_tests;
2195 }
2196
2197 sub ACTION_testall {
2198   my ($self) = @_;
2199
2200   my @types;
2201   for my $action (grep { $_ ne 'all' } $self->get_test_types) {
2202     # XXX We can't just dispatch because we get multiple summaries but
2203     # we'll need to dispatch to support custom setup/teardown in the
2204     # action.  To support that, we'll need to call something besides
2205     # Harness::runtests() because we'll need to collect the results in
2206     # parts, then run the summary.
2207     push(@types, $action);
2208     #$self->_call_action( "test$action" );
2209   }
2210   $self->generic_test(types => ['default', @types]);
2211 }
2212
2213 sub get_test_types {
2214   my ($self) = @_;
2215
2216   my $t = $self->{properties}->{test_types};
2217   return ( defined $t ? ( keys %$t ) : () );
2218 }
2219
2220
2221 sub ACTION_test {
2222   my ($self) = @_;
2223   $self->generic_test(type => 'default');
2224 }
2225
2226 sub generic_test {
2227   my $self = shift;
2228   (@_ % 2) and croak('Odd number of elements in argument hash');
2229   my %args = @_;
2230
2231   my $p = $self->{properties};
2232
2233   my @types = (
2234     (exists($args{type})  ? $args{type} : ()), 
2235     (exists($args{types}) ? @{$args{types}} : ()),
2236   );
2237   @types or croak "need some types of tests to check";
2238
2239   my %test_types = (
2240     default => $p->{test_file_exts},
2241     (defined($p->{test_types}) ? %{$p->{test_types}} : ()),
2242   );
2243
2244   for my $type (@types) {
2245     croak "$type not defined in test_types!"
2246       unless defined $test_types{ $type };
2247   }
2248
2249   # we use local here because it ends up two method calls deep
2250   local $p->{test_file_exts} = [ map { ref $_ ? @$_ : $_ } @test_types{@types} ];
2251   $self->depends_on('code');
2252
2253   # Protect others against our @INC changes
2254   local @INC = @INC;
2255
2256   # Make sure we test the module in blib/
2257   unshift @INC, (File::Spec->catdir($p->{base_dir}, $self->blib, 'lib'),
2258                  File::Spec->catdir($p->{base_dir}, $self->blib, 'arch'));
2259
2260   # Filter out nonsensical @INC entries - some versions of
2261   # Test::Harness will really explode the number of entries here
2262   @INC = grep {ref() || -d} @INC if @INC > 100;
2263
2264   $self->do_tests;
2265 }
2266
2267 sub do_tests {
2268   my $self = shift;
2269
2270   my $tests = $self->find_test_files;
2271
2272   if(@$tests) {
2273     my $args = $self->tap_harness_args;
2274     if($self->use_tap_harness or ($args and %$args)) {
2275       $self->run_tap_harness($tests);
2276     }
2277     else {
2278       $self->run_test_harness($tests);
2279     }
2280   }
2281   else {
2282     $self->log_info("No tests defined.\n");
2283   }
2284
2285   $self->run_visual_script;
2286 }
2287
2288 sub run_tap_harness {
2289   my ($self, $tests) = @_;
2290
2291   require TAP::Harness;
2292
2293   # TODO allow the test @INC to be set via our API?
2294
2295   TAP::Harness->new({
2296     lib => [@INC],
2297     verbosity => $self->{properties}{verbose},
2298     switches  => [ $self->harness_switches ],
2299     %{ $self->tap_harness_args },
2300   })->runtests(@$tests);
2301 }
2302
2303 sub run_test_harness {
2304     my ($self, $tests) = @_;
2305     require Test::Harness;
2306     my $p = $self->{properties};
2307     my @harness_switches = $self->harness_switches;
2308
2309     # Work around a Test::Harness bug that loses the particular perl
2310     # we're running under.  $self->perl is trustworthy, but $^X isn't.
2311     local $^X = $self->perl;
2312
2313     # Do everything in our power to work with all versions of Test::Harness
2314     local $Test::Harness::switches    = join ' ', grep defined, $Test::Harness::switches, @harness_switches;
2315     local $Test::Harness::Switches    = join ' ', grep defined, $Test::Harness::Switches, @harness_switches;
2316     local $ENV{HARNESS_PERL_SWITCHES} = join ' ', grep defined, $ENV{HARNESS_PERL_SWITCHES}, @harness_switches;
2317
2318     $Test::Harness::switches = undef   unless length $Test::Harness::switches;
2319     $Test::Harness::Switches = undef   unless length $Test::Harness::Switches;
2320     delete $ENV{HARNESS_PERL_SWITCHES} unless length $ENV{HARNESS_PERL_SWITCHES};
2321
2322     local ($Test::Harness::verbose,
2323            $Test::Harness::Verbose,
2324            $ENV{TEST_VERBOSE},
2325            $ENV{HARNESS_VERBOSE}) = ($p->{verbose} || 0) x 4;
2326
2327     Test::Harness::runtests(@$tests);
2328 }
2329
2330 sub run_visual_script {
2331     my $self = shift;
2332     # This will get run and the user will see the output.  It doesn't
2333     # emit Test::Harness-style output.
2334     $self->run_perl_script('visual.pl', '-Mblib='.$self->blib)
2335         if -e 'visual.pl';
2336 }
2337
2338 sub harness_switches {
2339     shift->{properties}{debugger} ? qw(-w -d) : ();
2340 }
2341
2342 sub test_files {
2343   my $self = shift;
2344   my $p = $self->{properties};
2345   if (@_) {
2346     return $p->{test_files} = (@_ == 1 ? shift : [@_]);
2347   }
2348   return $self->find_test_files;
2349 }
2350
2351 sub expand_test_dir {
2352   my ($self, $dir) = @_;
2353   my $exts = $self->{properties}{test_file_exts};
2354
2355   return sort map { @{$self->rscan_dir($dir, qr{^[^.].*\Q$_\E$})} } @$exts
2356     if $self->recursive_test_files;
2357
2358   return sort map { glob File::Spec->catfile($dir, "*$_") } @$exts;
2359 }
2360
2361 sub ACTION_testdb {
2362   my ($self) = @_;
2363   local $self->{properties}{debugger} = 1;
2364   $self->depends_on('test');
2365 }
2366
2367 sub ACTION_testcover {
2368   my ($self) = @_;
2369
2370   unless (Module::Build::ModuleInfo->find_module_by_name('Devel::Cover')) {
2371     warn("Cannot run testcover action unless Devel::Cover is installed.\n");
2372     return;
2373   }
2374
2375   $self->add_to_cleanup('coverage', 'cover_db');
2376   $self->depends_on('code');
2377
2378   # See whether any of the *.pm files have changed since last time
2379   # testcover was run.  If so, start over.
2380   if (-e 'cover_db') {
2381     my $pm_files = $self->rscan_dir
2382         (File::Spec->catdir($self->blib, 'lib'), file_qr('\.pm$') );
2383     my $cover_files = $self->rscan_dir('cover_db', sub {-f $_ and not /\.html$/});
2384     
2385     $self->do_system(qw(cover -delete))
2386       unless $self->up_to_date($pm_files,         $cover_files)
2387           && $self->up_to_date($self->test_files, $cover_files);
2388   }
2389
2390   local $Test::Harness::switches    = 
2391   local $Test::Harness::Switches    = 
2392   local $ENV{HARNESS_PERL_SWITCHES} = "-MDevel::Cover";
2393
2394   $self->depends_on('test');
2395   $self->do_system('cover');
2396 }
2397
2398 sub ACTION_code {
2399   my ($self) = @_;
2400   
2401   # All installable stuff gets created in blib/ .
2402   # Create blib/arch to keep blib.pm happy
2403   my $blib = $self->blib;
2404   $self->add_to_cleanup($blib);
2405   File::Path::mkpath( File::Spec->catdir($blib, 'arch') );
2406   
2407   if (my $split = $self->autosplit) {
2408     $self->autosplit_file($_, $blib) for ref($split) ? @$split : ($split);
2409   }
2410   
2411   foreach my $element (@{$self->build_elements}) {
2412     my $method = "process_${element}_files";
2413     $method = "process_files_by_extension" unless $self->can($method);
2414     $self->$method($element);
2415   }
2416
2417   $self->depends_on('config_data');
2418 }
2419
2420 sub ACTION_build {
2421   my $self = shift;
2422   $self->depends_on('code');
2423   $self->depends_on('docs');
2424 }
2425
2426 sub process_files_by_extension {
2427   my ($self, $ext) = @_;
2428   
2429   my $method = "find_${ext}_files";
2430   my $files = $self->can($method) ? $self->$method() : $self->_find_file_by_type($ext,  'lib');
2431   
2432   while (my ($file, $dest) = each %$files) {
2433     $self->copy_if_modified(from => $file, to => File::Spec->catfile($self->blib, $dest) );
2434   }
2435 }
2436
2437 sub process_support_files {
2438   my $self = shift;
2439   my $p = $self->{properties};
2440   return unless $p->{c_source};
2441   
2442   push @{$p->{include_dirs}}, $p->{c_source};
2443   
2444   my $files = $self->rscan_dir($p->{c_source}, file_qr('\.c(pp)?$'));
2445   foreach my $file (@$files) {
2446     push @{$p->{objects}}, $self->compile_c($file);
2447   }
2448 }
2449
2450 sub process_PL_files {
2451   my ($self) = @_;
2452   my $files = $self->find_PL_files;
2453   
2454   while (my ($file, $to) = each %$files) {
2455     unless ($self->up_to_date( $file, $to )) {
2456       $self->run_perl_script($file, [], [@$to]) or die "$file failed";
2457       $self->add_to_cleanup(@$to);
2458     }
2459   }
2460 }
2461
2462 sub process_xs_files {
2463   my $self = shift;
2464   my $files = $self->find_xs_files;
2465   while (my ($from, $to) = each %$files) {
2466     unless ($from eq $to) {
2467       $self->add_to_cleanup($to);
2468       $self->copy_if_modified( from => $from, to => $to );
2469     }
2470     $self->process_xs($to);
2471   }
2472 }
2473
2474 sub process_pod_files { shift()->process_files_by_extension(shift()) }
2475 sub process_pm_files  { shift()->process_files_by_extension(shift()) }
2476
2477 sub process_script_files {
2478   my $self = shift;
2479   my $files = $self->find_script_files;
2480   return unless keys %$files;
2481
2482   my $script_dir = File::Spec->catdir($self->blib, 'script');
2483   File::Path::mkpath( $script_dir );
2484   
2485   foreach my $file (keys %$files) {
2486     my $result = $self->copy_if_modified($file, $script_dir, 'flatten') or next;
2487     $self->fix_shebang_line($result) unless $self->is_vmsish;
2488     $self->make_executable($result);
2489   }
2490 }
2491
2492 sub find_PL_files {
2493   my $self = shift;
2494   if (my $files = $self->{properties}{PL_files}) {
2495     # 'PL_files' is given as a Unix file spec, so we localize_file_path().
2496     
2497     if (UNIVERSAL::isa($files, 'ARRAY')) {
2498       return { map {$_, [/^(.*)\.PL$/]}
2499                map $self->localize_file_path($_),
2500                @$files };
2501
2502     } elsif (UNIVERSAL::isa($files, 'HASH')) {
2503       my %out;
2504       while (my ($file, $to) = each %$files) {
2505         $out{ $self->localize_file_path($file) } = [ map $self->localize_file_path($_),
2506                                                      ref $to ? @$to : ($to) ];
2507       }
2508       return \%out;
2509
2510     } else {
2511       die "'PL_files' must be a hash reference or array reference";
2512     }
2513   }
2514   
2515   return unless -d 'lib';
2516   return { map {$_, [/^(.*)\.PL$/i ]} @{ $self->rscan_dir('lib',
2517                                                           file_qr('\.PL$')) } };
2518 }
2519
2520 sub find_pm_files  { shift->_find_file_by_type('pm',  'lib') }
2521 sub find_pod_files { shift->_find_file_by_type('pod', 'lib') }
2522 sub find_xs_files  { shift->_find_file_by_type('xs',  'lib') }
2523
2524 sub find_script_files {
2525   my $self = shift;
2526   if (my $files = $self->script_files) {
2527     # Always given as a Unix file spec.  Values in the hash are
2528     # meaningless, but we preserve if present.
2529     return { map {$self->localize_file_path($_), $files->{$_}} keys %$files };
2530   }
2531   
2532   # No default location for script files
2533   return {};
2534 }
2535
2536 sub find_test_files {
2537   my $self = shift;
2538   my $p = $self->{properties};
2539
2540   if (my $files = $p->{test_files}) {
2541     $files = [keys %$files] if UNIVERSAL::isa($files, 'HASH');
2542     $files = [map { -d $_ ? $self->expand_test_dir($_) : $_ }
2543               map glob,
2544               $self->split_like_shell($files)];
2545     
2546     # Always given as a Unix file spec.
2547     return [ map $self->localize_file_path($_), @$files ];
2548     
2549   } else {
2550     # Find all possible tests in t/ or test.pl
2551     my @tests;
2552     push @tests, 'test.pl'                          if -e 'test.pl';
2553     push @tests, $self->expand_test_dir('t')        if -e 't' and -d _;
2554     return \@tests;
2555   }
2556 }
2557
2558 sub _find_file_by_type {
2559   my ($self, $type, $dir) = @_;
2560   
2561   if (my $files = $self->{properties}{"${type}_files"}) {
2562     # Always given as a Unix file spec
2563     return { map $self->localize_file_path($_), %$files };
2564   }
2565   
2566   return {} unless -d $dir;
2567   return { map {$_, $_}
2568            map $self->localize_file_path($_),
2569            grep !/\.\#/,
2570            @{ $self->rscan_dir($dir, file_qr("\\.$type\$")) } };
2571 }
2572
2573 sub localize_file_path {
2574   my ($self, $path) = @_;
2575   return File::Spec->catfile( split m{/}, $path );
2576 }
2577
2578 sub localize_dir_path {
2579   my ($self, $path) = @_;
2580   return File::Spec->catdir( split m{/}, $path );
2581 }
2582
2583 sub fix_shebang_line { # Adapted from fixin() in ExtUtils::MM_Unix 1.35
2584   my ($self, @files) = @_;
2585   my $c = ref($self) ? $self->{config} : 'Module::Build::Config';
2586   
2587   my ($does_shbang) = $c->get('sharpbang') =~ /^\s*\#\!/;
2588   for my $file (@files) {
2589     my $FIXIN = IO::File->new($file) or die "Can't process '$file': $!";
2590     local $/ = "\n";
2591     chomp(my $line = <$FIXIN>);
2592     next unless $line =~ s/^\s*\#!\s*//;     # Not a shbang file.
2593     
2594     my ($cmd, $arg) = (split(' ', $line, 2), '');
2595     next unless $cmd =~ /perl/i;
2596     my $interpreter = $self->{properties}{perl};
2597     
2598     $self->log_verbose("Changing sharpbang in $file to $interpreter");
2599     my $shb = '';
2600     $shb .= $c->get('sharpbang')."$interpreter $arg\n" if $does_shbang;
2601     
2602     # I'm not smart enough to know the ramifications of changing the
2603     # embedded newlines here to \n, so I leave 'em in.
2604     $shb .= qq{
2605 eval 'exec $interpreter $arg -S \$0 \${1+"\$\@"}'
2606     if 0; # not running under some shell
2607 } unless $self->is_windowsish; # this won't work on win32, so don't
2608     
2609     my $FIXOUT = IO::File->new(">$file.new")
2610       or die "Can't create new $file: $!\n";
2611     
2612     # Print out the new #! line (or equivalent).
2613     local $\;
2614     undef $/; # Was localized above
2615     print $FIXOUT $shb, <$FIXIN>;
2616     close $FIXIN;
2617     close $FIXOUT;
2618     
2619     rename($file, "$file.bak")
2620       or die "Can't rename $file to $file.bak: $!";
2621     
2622     rename("$file.new", $file)
2623       or die "Can't rename $file.new to $file: $!";
2624     
2625     $self->delete_filetree("$file.bak")
2626       or $self->log_warn("Couldn't clean up $file.bak, leaving it there");
2627     
2628     $self->do_system($c->get('eunicefix'), $file) if $c->get('eunicefix') ne ':';
2629   }
2630 }
2631
2632
2633 sub ACTION_testpod {
2634   my $self = shift;
2635   $self->depends_on('docs');
2636   
2637   eval q{use Test::Pod 0.95; 1}
2638     or die "The 'testpod' action requires Test::Pod version 0.95";
2639
2640   my @files = sort keys %{$self->_find_pods($self->libdoc_dirs)},
2641                    keys %{$self->_find_pods
2642                              ($self->bindoc_dirs,
2643                               exclude => [ file_qr('\.bat$') ])}
2644     or die "Couldn't find any POD files to test\n";
2645
2646   { package # hide from PAUSE
2647       Module::Build::PodTester;  # Don't want to pollute the main namespace
2648     Test::Pod->import( tests => scalar @files );
2649     pod_file_ok($_) foreach @files;
2650   }
2651 }
2652
2653 sub ACTION_testpodcoverage {
2654   my $self = shift;
2655
2656   $self->depends_on('docs');
2657   
2658   eval q{use Test::Pod::Coverage 1.00; 1}
2659     or die "The 'testpodcoverage' action requires ",
2660            "Test::Pod::Coverage version 1.00";
2661
2662   # TODO this needs test coverage!
2663
2664   # XXX work-around a bug in Test::Pod::Coverage previous to v1.09
2665   # Make sure we test the module in blib/
2666   local @INC = @INC;
2667   my $p = $self->{properties};
2668   unshift(@INC,
2669     # XXX any reason to include arch?
2670     File::Spec->catdir($p->{base_dir}, $self->blib, 'lib'),
2671     #File::Spec->catdir($p->{base_dir}, $self->blib, 'arch')
2672   );
2673
2674   all_pod_coverage_ok();
2675 }
2676
2677 sub ACTION_docs {
2678   my $self = shift;
2679
2680   $self->depends_on('code');
2681   $self->depends_on('manpages', 'html');
2682 }
2683
2684 # Given a file type, will return true if the file type would normally
2685 # be installed when neither install-base nor prefix has been set.
2686 # I.e. it will be true only if the path is set from Config.pm or
2687 # set explicitly by the user via install-path.
2688 sub _is_default_installable {
2689   my $self = shift;
2690   my $type = shift;
2691   return ( $self->install_destination($type) &&
2692            ( $self->install_path($type) ||
2693              $self->install_sets($self->installdirs)->{$type} )
2694          ) ? 1 : 0;
2695 }
2696
2697 sub ACTION_manpages {
2698   my $self = shift;
2699
2700   return unless $self->_mb_feature('manpage_support');
2701
2702   $self->depends_on('code');
2703
2704   foreach my $type ( qw(bin lib) ) {
2705     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2706                                    exclude => [ file_qr('\.bat$') ] );
2707     next unless %$files;
2708
2709     my $sub = $self->can("manify_${type}_pods");
2710     next unless defined( $sub );
2711
2712     if ( $self->invoked_action eq 'manpages' ) {
2713       $self->$sub();
2714     } elsif ( $self->_is_default_installable("${type}doc") ) {
2715       $self->$sub();
2716     }
2717   }
2718
2719 }
2720
2721 sub manify_bin_pods {
2722   my $self    = shift;
2723
2724   my $files   = $self->_find_pods( $self->{properties}{bindoc_dirs},
2725                                    exclude => [ file_qr('\.bat$') ] );
2726   return unless keys %$files;
2727
2728   my $mandir = File::Spec->catdir( $self->blib, 'bindoc' );
2729   File::Path::mkpath( $mandir, 0, oct(777) );
2730
2731   require Pod::Man;
2732   foreach my $file (keys %$files) {
2733     # Pod::Simple based parsers only support one document per instance.
2734     # This is expected to change in a future version (Pod::Simple > 3.03).
2735     my $parser  = Pod::Man->new( section => 1 ); # binaries go in section 1
2736     my $manpage = $self->man1page_name( $file ) . '.' .
2737                   $self->config( 'man1ext' );
2738     my $outfile = File::Spec->catfile($mandir, $manpage);
2739     next if $self->up_to_date( $file, $outfile );
2740     $self->log_info("Manifying $file -> $outfile\n");
2741     $parser->parse_from_file( $file, $outfile );
2742     $files->{$file} = $outfile;
2743   }
2744 }
2745
2746 sub manify_lib_pods {
2747   my $self    = shift;
2748
2749   my $files   = $self->_find_pods($self->{properties}{libdoc_dirs});
2750   return unless keys %$files;
2751
2752   my $mandir = File::Spec->catdir( $self->blib, 'libdoc' );
2753   File::Path::mkpath( $mandir, 0, oct(777) );
2754
2755   require Pod::Man;
2756   while (my ($file, $relfile) = each %$files) {
2757     # Pod::Simple based parsers only support one document per instance.
2758     # This is expected to change in a future version (Pod::Simple > 3.03).
2759     my $parser  = Pod::Man->new( section => 3 ); # libraries go in section 3
2760     my $manpage = $self->man3page_name( $relfile ) . '.' .
2761                   $self->config( 'man3ext' );
2762     my $outfile = File::Spec->catfile( $mandir, $manpage);
2763     next if $self->up_to_date( $file, $outfile );
2764     $self->log_info("Manifying $file -> $outfile\n");
2765     $parser->parse_from_file( $file, $outfile );
2766     $files->{$file} = $outfile;
2767   }
2768 }
2769
2770 sub _find_pods {
2771   my ($self, $dirs, %args) = @_;
2772   my %files;
2773   foreach my $spec (@$dirs) {
2774     my $dir = $self->localize_dir_path($spec);
2775     next unless -e $dir;
2776
2777     FILE: foreach my $file ( @{ $self->rscan_dir( $dir ) } ) {
2778       foreach my $regexp ( @{ $args{exclude} } ) {
2779         next FILE if $file =~ $regexp;
2780       }
2781       $files{$file} = File::Spec->abs2rel($file, $dir) if $self->contains_pod( $file )
2782     }
2783   }
2784   return \%files;
2785 }
2786
2787 sub contains_pod {
2788   my ($self, $file) = @_;
2789   return '' unless -T $file;  # Only look at text files
2790   
2791   my $fh = IO::File->new( $file ) or die "Can't open $file: $!";
2792   while (my $line = <$fh>) {
2793     return 1 if $line =~ /^\=(?:head|pod|item)/;
2794   }
2795   
2796   return '';
2797 }
2798
2799 sub ACTION_html {
2800   my $self = shift;
2801
2802   return unless $self->_mb_feature('HTML_support');
2803
2804   $self->depends_on('code');
2805
2806   foreach my $type ( qw(bin lib) ) {
2807     my $files = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2808                                    exclude => 
2809                                         [ file_qr('\.(?:bat|com|html)$') ] );
2810     next unless %$files;
2811
2812     if ( $self->invoked_action eq 'html' ) {
2813       $self->htmlify_pods( $type );
2814     } elsif ( $self->_is_default_installable("${type}html") ) {
2815       $self->htmlify_pods( $type );
2816     }
2817   }
2818
2819 }
2820
2821
2822 # 1) If it's an ActiveState perl install, we need to run
2823 #    ActivePerl::DocTools->UpdateTOC;
2824 # 2) Links to other modules are not being generated
2825 sub htmlify_pods {
2826   my $self = shift;
2827   my $type = shift;
2828   my $htmldir = shift || File::Spec->catdir($self->blib, "${type}html");
2829
2830   require Module::Build::PodParser;
2831   require Pod::Html;
2832
2833   $self->add_to_cleanup('pod2htm*');
2834
2835   my $pods = $self->_find_pods( $self->{properties}{"${type}doc_dirs"},
2836                                 exclude => [ file_qr('\.(?:bat|com|html)$') ] );
2837   return unless %$pods;  # nothing to do
2838
2839   unless ( -d $htmldir ) {
2840     File::Path::mkpath($htmldir, 0, oct(755))
2841       or die "Couldn't mkdir $htmldir: $!";
2842   }
2843
2844   my @rootdirs = ($type eq 'bin') ? qw(bin) :
2845       $self->installdirs eq 'core' ? qw(lib) : qw(site lib);
2846
2847   my $podpath = join ':',
2848                 map  $_->[1],
2849                 grep -e $_->[0],
2850                 map  [File::Spec->catdir($self->blib, $_), $_],
2851                 qw( script lib );
2852
2853   foreach my $pod ( keys %$pods ) {
2854
2855     my ($name, $path) = File::Basename::fileparse($pods->{$pod},
2856                                                  file_qr('\.(?:pm|plx?|pod)$'));
2857     my @dirs = File::Spec->splitdir( File::Spec->canonpath( $path ) );
2858     pop( @dirs ) if scalar(@dirs) && $dirs[-1] eq File::Spec->curdir;
2859
2860     my $fulldir = File::Spec->catfile($htmldir, @rootdirs, @dirs);
2861     my $outfile = File::Spec->catfile($fulldir, "${name}.html");
2862     my $infile  = File::Spec->abs2rel($pod);
2863
2864     next if $self->up_to_date($infile, $outfile);
2865
2866     unless ( -d $fulldir ){
2867       File::Path::mkpath($fulldir, 0, oct(755))
2868         or die "Couldn't mkdir $fulldir: $!";
2869     }
2870
2871     my $path2root = join( '/', ('..') x (@rootdirs+@dirs) );
2872     my $htmlroot = join( '/',
2873                          ($path2root,
2874                           $self->installdirs eq 'core' ? () : qw(site) ) );
2875
2876     my $fh = IO::File->new($infile) or die "Can't read $infile: $!";
2877     my $abstract = Module::Build::PodParser->new(fh => $fh)->get_abstract();
2878
2879     my $title = join( '::', (@dirs, $name) );
2880     $title .= " - $abstract" if $abstract;
2881
2882     my @opts = (
2883                 '--flush',
2884                 "--title=$title",
2885                 "--podpath=$podpath",
2886                 "--infile=$infile",
2887                 "--outfile=$outfile",
2888                 '--podroot=' . $self->blib,
2889                 "--htmlroot=$htmlroot",
2890                );
2891
2892     if ( eval{Pod::Html->VERSION(1.03)} ) {
2893       push( @opts, ('--header', '--backlink=Back to Top') );
2894       push( @opts, "--css=$path2root/" . $self->html_css) if $self->html_css;
2895     }
2896
2897     $self->log_info("HTMLifying $infile -> $outfile\n");
2898     $self->log_verbose("pod2html @opts\n");
2899     eval { Pod::Html::pod2html(@opts); 1 } 
2900       or $self->log_warn("pod2html @opts failed: $@");
2901   }
2902
2903 }
2904
2905 # Adapted from ExtUtils::MM_Unix
2906 sub man1page_name {
2907   my $self = shift;
2908   return File::Basename::basename( shift );
2909 }
2910
2911 # Adapted from ExtUtils::MM_Unix and Pod::Man
2912 # Depending on M::B's dependency policy, it might make more sense to refactor
2913 # Pod::Man::begin_pod() to extract a name() methods, and use them...
2914 #    -spurkis
2915 sub man3page_name {
2916   my $self = shift;
2917   my ($vol, $dirs, $file) = File::Spec->splitpath( shift );
2918   my @dirs = File::Spec->splitdir( File::Spec->canonpath($dirs) );
2919   
2920   # Remove known exts from the base name
2921   $file =~ s/\.p(?:od|m|l)\z//i;
2922   
2923   return join( $self->manpage_separator, @dirs, $file );
2924 }
2925
2926 sub manpage_separator {
2927   return '::';
2928 }
2929
2930 # For systems that don't have 'diff' executable, should use Algorithm::Diff
2931 sub ACTION_diff {
2932   my $self = shift;
2933   $self->depends_on('build');
2934   my $local_lib = File::Spec->rel2abs('lib');
2935   my @myINC = grep {$_ ne $local_lib} @INC;
2936
2937   # The actual install destination might not be in @INC, so check there too.
2938   push @myINC, map $self->install_destination($_), qw(lib arch);
2939
2940   my @flags = @{$self->{args}{ARGV}};
2941   @flags = $self->split_like_shell($self->{args}{flags} || '') unless @flags;
2942   
2943   my $installmap = $self->install_map;
2944   delete $installmap->{read};
2945   delete $installmap->{write};
2946
2947   my $text_suffix = file_qr('\.(pm|pod)$');
2948
2949   while (my $localdir = each %$installmap) {
2950     my @localparts = File::Spec->splitdir($localdir);
2951     my $files = $self->rscan_dir($localdir, sub {-f});
2952     
2953     foreach my $file (@$files) {
2954       my @parts = File::Spec->splitdir($file);
2955       @parts = @parts[@localparts .. $#parts]; # Get rid of blib/lib or similar
2956       
2957       my $installed = Module::Build::ModuleInfo->find_module_by_name(
2958                         join('::', @parts), \@myINC );
2959       if (not $installed) {
2960         print "Only in lib: $file\n";
2961         next;
2962       }
2963       
2964       my $status = File::Compare::compare($installed, $file);
2965       next if $status == 0;  # Files are the same
2966       die "Can't compare $installed and $file: $!" if $status == -1;
2967       
2968       if ($file =~ $text_suffix) {
2969         $self->do_system('diff', @flags, $installed, $file);
2970       } else {
2971         print "Binary files $file and $installed differ\n";
2972       }
2973     }
2974   }
2975 }
2976
2977 sub ACTION_pure_install {
2978   shift()->depends_on('install');
2979 }
2980
2981 sub ACTION_install {
2982   my ($self) = @_;
2983   require ExtUtils::Install;
2984   $self->depends_on('build');
2985   ExtUtils::Install::install($self->install_map, !$self->quiet, 0, $self->{args}{uninst}||0);
2986 }
2987
2988 sub ACTION_fakeinstall {
2989   my ($self) = @_;
2990   require ExtUtils::Install;
2991   my $eui_version = ExtUtils::Install->VERSION;
2992   if ( $eui_version < 1.32 ) {
2993     $self->log_warn(
2994       "The 'fakeinstall' action requires Extutils::Install 1.32 or later.\n"
2995       . "(You only have version $eui_version)."
2996     );
2997     return;
2998   }
2999   $self->depends_on('build');
3000   ExtUtils::Install::install($self->install_map, !$self->quiet, 1, $self->{args}{uninst}||0);
3001 }
3002
3003 sub ACTION_versioninstall {
3004   my ($self) = @_;
3005   
3006   die "You must have only.pm 0.25 or greater installed for this operation: $@\n"
3007     unless eval { require only; 'only'->VERSION(0.25); 1 };
3008   
3009   $self->depends_on('build');
3010   
3011   my %onlyargs = map {exists($self->{args}{$_}) ? ($_ => $self->{args}{$_}) : ()}
3012     qw(version versionlib);
3013   only::install::install(%onlyargs);
3014 }
3015
3016 sub ACTION_clean {
3017   my ($self) = @_;
3018   foreach my $item (map glob($_), $self->cleanup) {
3019     $self->delete_filetree($item);
3020   }
3021 }
3022
3023 sub ACTION_realclean {
3024   my ($self) = @_;
3025   $self->depends_on('clean');
3026   $self->delete_filetree($self->config_dir, $self->build_script);
3027 }
3028
3029 sub ACTION_ppd {
3030   my ($self) = @_;
3031   require Module::Build::PPMMaker;
3032   my $ppd = Module::Build::PPMMaker->new();
3033   my $file = $ppd->make_ppd(%{$self->{args}}, build => $self);
3034   $self->add_to_cleanup($file);
3035 }
3036
3037 sub ACTION_ppmdist {
3038   my ($self) = @_;
3039
3040   $self->depends_on( 'build' );
3041
3042   my $ppm = $self->ppm_name;
3043   $self->delete_filetree( $ppm );
3044   $self->log_info( "Creating $ppm\n" );
3045   $self->add_to_cleanup( $ppm, "$ppm.tar.gz" );
3046
3047   my %types = ( # translate types/dirs to those expected by ppm
3048     lib     => 'lib',
3049     arch    => 'arch',
3050     bin     => 'bin',
3051     script  => 'script',
3052     bindoc  => 'man1',
3053     libdoc  => 'man3',
3054     binhtml => undef,
3055     libhtml => undef,
3056   );
3057
3058   foreach my $type ($self->install_types) {
3059     next if exists( $types{$type} ) && !defined( $types{$type} );
3060
3061     my $dir = File::Spec->catdir( $self->blib, $type );
3062     next unless -e $dir;
3063
3064     my $files = $self->rscan_dir( $dir );
3065     foreach my $file ( @$files ) {
3066       next unless -f $file;
3067       my $rel_file =
3068         File::Spec->abs2rel( File::Spec->rel2abs( $file ),
3069                              File::Spec->rel2abs( $dir  ) );
3070       my $to_file  =
3071         File::Spec->catfile( $ppm, 'blib',
3072                             exists( $types{$type} ) ? $types{$type} : $type,
3073                             $rel_file );
3074       $self->copy_if_modified( from => $file, to => $to_file );
3075     }
3076   }
3077
3078   foreach my $type ( qw(bin lib) ) {
3079     local $self->{properties}{html_css} = 'Active.css';
3080     $self->htmlify_pods( $type, File::Spec->catdir($ppm, 'blib', 'html') );
3081   }
3082
3083   # create a tarball;
3084   # the directory tar'ed must be blib so we need to do a chdir first
3085   my $target = File::Spec->catfile( File::Spec->updir, $ppm );
3086   $self->_do_in_dir( $ppm, sub { $self->make_tarball( 'blib', $target ) } );
3087
3088   $self->depends_on( 'ppd' );
3089
3090   $self->delete_filetree( $ppm );
3091 }
3092
3093 sub ACTION_pardist {
3094   my ($self) = @_;
3095
3096   # Need PAR::Dist
3097   if ( not eval { require PAR::Dist; PAR::Dist->VERSION(0.17) } ) {
3098     $self->log_warn(
3099       "In order to create .par distributions, you need to\n"
3100       . "install PAR::Dist first."
3101     );
3102     return();
3103   }
3104   
3105   $self->depends_on( 'build' );
3106
3107   return PAR::Dist::blib_to_par(
3108     name => $self->dist_name,
3109     version => $self->dist_version,
3110   );
3111 }
3112
3113 sub ACTION_dist {
3114   my ($self) = @_;
3115   
3116   $self->depends_on('distdir');
3117   
3118   my $dist_dir = $self->dist_dir;
3119   
3120   $self->make_tarball($dist_dir);
3121   $self->delete_filetree($dist_dir);
3122 }
3123
3124 sub ACTION_distcheck {
3125   my ($self) = @_;
3126
3127   require ExtUtils::Manifest;
3128   local $^W; # ExtUtils::Manifest is not warnings clean.
3129   my ($missing, $extra) = ExtUtils::Manifest::fullcheck();
3130
3131   return unless @$missing || @$extra;
3132
3133   my $msg = "MANIFEST appears to be out of sync with the distribution\n";
3134   if ( $self->invoked_action eq 'distcheck' ) {
3135     die $msg;
3136   } else {
3137     warn $msg;
3138   }
3139 }
3140
3141 sub _add_to_manifest {
3142   my ($self, $manifest, $lines) = @_;
3143   $lines = [$lines] unless ref $lines;
3144
3145   my $existing_files = $self->_read_manifest($manifest);
3146   return unless defined( $existing_files );
3147
3148   @$lines = grep {!exists $existing_files->{$_}} @$lines
3149     or return;
3150
3151   my $mode = (stat $manifest)[2];
3152   chmod($mode | oct(222), $manifest) or die "Can't make $manifest writable: $!";
3153   
3154   my $fh = IO::File->new("< $manifest") or die "Can't read $manifest: $!";
3155   my $last_line = (<$fh>)[-1] || "\n";
3156   my $has_newline = $last_line =~ /\n$/;
3157   $fh->close;
3158
3159   $fh = IO::File->new(">> $manifest") or die "Can't write to $manifest: $!";
3160   print $fh "\n" unless $has_newline;
3161   print $fh map "$_\n", @$lines;
3162   close $fh;
3163   chmod($mode, $manifest);
3164
3165   $self->log_info(map "Added to $manifest: $_\n", @$lines);
3166 }
3167
3168 sub _sign_dir {
3169   my ($self, $dir) = @_;
3170
3171   unless (eval { require Module::Signature; 1 }) {
3172     $self->log_warn("Couldn't load Module::Signature for 'distsign' action:\n $@\n");
3173     return;
3174   }
3175   
3176   # Add SIGNATURE to the MANIFEST
3177   {
3178     my $manifest = File::Spec->catfile($dir, 'MANIFEST');
3179     die "Signing a distribution requires a MANIFEST file" unless -e $manifest;
3180     $self->_add_to_manifest($manifest, "SIGNATURE    Added here by Module::Build");
3181   }
3182   
3183   # Would be nice if Module::Signature took a directory argument.
3184   
3185   $self->_do_in_dir($dir, sub {local $Module::Signature::Quiet = 1; Module::Signature::sign()});
3186 }
3187
3188 sub _do_in_dir {
3189   my ($self, $dir, $do) = @_;
3190
3191   my $start_dir = $self->cwd;
3192   chdir $dir or die "Can't chdir() to $dir: $!";
3193   eval {$do->()};
3194   my @err = $@ ? ($@) : ();
3195   chdir $start_dir or push @err, "Can't chdir() back to $start_dir: $!";
3196   die join "\n", @err if @err;
3197 }
3198
3199 sub ACTION_distsign {
3200   my ($self) = @_;
3201   {
3202     local $self->{properties}{sign} = 0;  # We'll sign it ourselves
3203     $self->depends_on('distdir') unless -d $self->dist_dir;
3204   }
3205   $self->_sign_dir($self->dist_dir);
3206 }
3207
3208 sub ACTION_skipcheck {
3209   my ($self) = @_;
3210   
3211   require ExtUtils::Manifest;
3212   local $^W; # ExtUtils::Manifest is not warnings clean.
3213   ExtUtils::Manifest::skipcheck();
3214 }
3215
3216 sub ACTION_distclean {
3217   my ($self) = @_;
3218   
3219   $self->depends_on('realclean');
3220   $self->depends_on('distcheck');
3221 }
3222
3223 sub do_create_makefile_pl {
3224   my $self = shift;
3225   require Module::Build::Compat;
3226   $self->log_info("Creating Makefile.PL\n");
3227   Module::Build::Compat->create_makefile_pl($self->create_makefile_pl, $self, @_);
3228   $self->_add_to_manifest('MANIFEST', 'Makefile.PL');
3229 }
3230
3231 sub do_create_license {
3232   my $self = shift;
3233   $self->log_info("Creating LICENSE file\n");
3234
3235   my $l = $self->license
3236     or die "No license specified";
3237
3238   my $key = $self->valid_licenses->{$l}
3239     or die "'$l' isn't a license key we know about";
3240   my $class = "Software::License::$key";
3241
3242   eval "use $class; 1"
3243     or die "Can't load Software::License to create LICENSE file: $@";
3244
3245   $self->delete_filetree('LICENSE');
3246
3247   my $author = join " & ", @{ $self->dist_author };
3248   my $license = $class->new({holder => $author});
3249   my $fh = IO::File->new('> LICENSE')
3250     or die "Can't write LICENSE file: $!";
3251   print $fh $license->fulltext;
3252   close $fh;
3253
3254   $self->_add_to_manifest('MANIFEST', 'LICENSE');
3255 }
3256
3257 sub do_create_readme {
3258   my $self = shift;
3259   $self->delete_filetree('README');
3260
3261   my $docfile = $self->_main_docfile;
3262   unless ( $docfile ) {
3263     $self->log_warn(<<EOF);
3264 Cannot create README: can't determine which file contains documentation;
3265 Must supply either 'dist_version_from', or 'module_name' parameter.
3266 EOF
3267     return;
3268   }
3269
3270   if ( eval {require Pod::Readme; 1} ) {
3271     $self->log_info("Creating README using Pod::Readme\n");
3272
3273     my $parser = Pod::Readme->new;
3274     $parser->parse_from_file($docfile, 'README', @_);
3275
3276   } elsif ( eval {require Pod::Text; 1} ) {
3277     $self->log_info("Creating README using Pod::Text\n");
3278
3279     my $fh = IO::File->new('> README');
3280     if ( defined($fh) ) {
3281       local $^W = 0;
3282       no strict "refs";
3283
3284       # work around bug in Pod::Text 3.01, which expects
3285       # Pod::Simple::parse_file to take input and output filehandles
3286       # when it actually only takes an input filehandle
3287
3288       my $old_parse_file;
3289       $old_parse_file = \&{"Pod::Simple::parse_file"}
3290         and
3291       local *{"Pod::Simple::parse_file"} = sub {
3292         my $self = shift;
3293         $self->output_fh($_[1]) if $_[1];
3294         $self->$old_parse_file($_[0]);
3295       }
3296         if $Pod::Text::VERSION
3297           == 3.01; # Split line to avoid evil version-finder
3298
3299       Pod::Text::pod2text( $docfile, $fh );
3300
3301       $fh->close;
3302     } else {
3303       $self->log_warn(
3304         "Cannot create 'README' file: Can't open file for writing\n" );
3305       return;
3306     }
3307
3308   } else {
3309     $self->log_warn("Can't load Pod::Readme or Pod::Text to create README\n");
3310     return;
3311   }
3312
3313   $self->_add_to_manifest('MANIFEST', 'README');
3314 }
3315
3316 sub _main_docfile {
3317   my $self = shift;
3318   if ( my $pm_file = $self->dist_version_from ) {
3319     (my $pod_file = $pm_file) =~ s/.pm$/.pod/;
3320     return (-e $pod_file ? $pod_file : $pm_file);
3321   } else {
3322     return undef;
3323   }
3324 }
3325
3326 sub ACTION_distdir {
3327   my ($self) = @_;
3328
3329   $self->depends_on('distmeta');
3330
3331   my $dist_files = $self->_read_manifest('MANIFEST')
3332     or die "Can't create distdir without a MANIFEST file - run 'manifest' action first";
3333   delete $dist_files->{SIGNATURE};  # Don't copy, create a fresh one
3334   die "No files found in MANIFEST - try running 'manifest' action?\n"
3335     unless ($dist_files and keys %$dist_files);
3336   my $metafile = $self->metafile;
3337   $self->log_warn("*** Did you forget to add $metafile to the MANIFEST?\n")
3338     unless exists $dist_files->{$metafile};
3339   
3340   my $dist_dir = $self->dist_dir;
3341   $self->delete_filetree($dist_dir);
3342   $self->log_info("Creating $dist_dir\n");
3343   $self->add_to_cleanup($dist_dir);
3344   
3345   foreach my $file (keys %$dist_files) {
3346     my $new = $self->copy_if_modified(from => $file, to_dir => $dist_dir, verbose => 0);
3347   }
3348   
3349   $self->_sign_dir($dist_dir) if $self->{properties}{sign};
3350 }
3351
3352 sub ACTION_disttest {
3353   my ($self) = @_;
3354
3355   $self->depends_on('distdir');
3356
3357   $self->_do_in_dir
3358     ( $self->dist_dir,
3359       sub {
3360         # XXX could be different names for scripts
3361
3362         $self->run_perl_script('Build.PL') # XXX Should this be run w/ --nouse-rcfile
3363           or die "Error executing 'Build.PL' in dist directory: $!";
3364         $self->run_perl_script('Build')
3365           or die "Error executing 'Build' in dist directory: $!";
3366         $self->run_perl_script('Build', [], ['test'])
3367           or die "Error executing 'Build test' in dist directory";
3368       });
3369 }
3370
3371
3372 =begin private
3373
3374   my $has_include = $build->_eumanifest_has_include;
3375
3376 Returns true if the installed version of ExtUtils::Manifest supports
3377 #include and #include_default directives.  False otherwise.
3378
3379 =end private
3380
3381 =cut
3382
3383 # #!include and #!include_default were added in 1.50
3384 sub _eumanifest_has_include {
3385     my $self = shift;
3386
3387     require ExtUtils::Manifest;
3388     return ExtUtils::Manifest->VERSION >= 1.50 ? 1 : 0;
3389     return 0;
3390 }
3391
3392
3393 =begin private
3394
3395   my $maniskip_file = $build->_default_maniskip;
3396
3397 Returns the location of the installed MANIFEST.SKIP file used by
3398 default.
3399
3400 =end private
3401
3402 =cut
3403
3404 sub _default_maniskip {
3405     my $self = shift;
3406
3407     my $default_maniskip;
3408     for my $dir (@INC) {
3409         $default_maniskip = File::Spec->catfile($dir, "ExtUtils", "MANIFEST.SKIP");
3410         last if -r $default_maniskip;
3411     }
3412
3413     return $default_maniskip;
3414 }
3415
3416
3417 =begin private
3418
3419   my $content = $build->_slurp($file);
3420
3421 Reads $file and returns the $content.
3422
3423 =end private
3424
3425 =cut
3426
3427 sub _slurp {
3428     my $self = shift;
3429     my $file = shift;
3430     open my $fh, "<", $file or croak "Can't open $file: $!";
3431     local $/;
3432     return <$fh>;
3433 }
3434
3435
3436 sub _write_default_maniskip {
3437   my $self = shift;
3438   my $file = shift || 'MANIFEST.SKIP';
3439   my $fh = IO::File->new("> $file")
3440     or die "Can't open $file: $!";
3441
3442   my $content = $self->_eumanifest_has_include ? "#!include_default\n"
3443                                                : $self->_slurp( $self->_default_maniskip );
3444
3445   $content .= <<'EOF';
3446
3447 # Avoid Module::Build generated and utility files.
3448 \bBuild$
3449 \bBuild.bat$
3450 \b_build
3451 \bBuild.COM$
3452 \bBUILD.COM$
3453 \bbuild.com$
3454
3455 # Avoid archives of this distribution
3456 EOF
3457
3458   # Skip, for example, 'Module-Build-0.27.tar.gz'
3459   $content .= '\b'.$self->dist_name.'-[\d\.\_]+'."\n";
3460
3461   print $fh $content;
3462
3463   return;
3464 }
3465
3466 sub ACTION_manifest {
3467   my ($self) = @_;
3468
3469   my $maniskip = 'MANIFEST.SKIP';
3470   unless ( -e 'MANIFEST' || -e $maniskip ) {
3471     $self->log_warn("File '$maniskip' does not exist: Creating a default '$maniskip'\n");
3472     $self->_write_default_maniskip($maniskip);
3473   }
3474
3475   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3476   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3477   ExtUtils::Manifest::mkmanifest();
3478 }
3479
3480 # Case insensitive regex for files
3481 sub file_qr {
3482     return File::Spec->case_tolerant ? qr($_[0])i : qr($_[0]);
3483 }
3484
3485 sub dist_dir {
3486   my ($self) = @_;
3487   return join "-", $self->dist_name, $self->dist_version;
3488 }
3489
3490 sub ppm_name {
3491   my $self = shift;
3492   return 'PPM-' . $self->dist_dir;
3493 }
3494
3495 sub _files_in {
3496   my ($self, $dir) = @_;
3497   return unless -d $dir;
3498
3499   local *DH;
3500   opendir DH, $dir or die "Can't read directory $dir: $!";
3501
3502   my @files;
3503   while (defined (my $file = readdir DH)) {
3504     my $full_path = File::Spec->catfile($dir, $file);
3505     next if -d $full_path;
3506     push @files, $full_path;
3507   }
3508   return @files;
3509 }
3510
3511 sub script_files {
3512   my $self = shift;
3513
3514   for ($self->{properties}{script_files}) {
3515     $_ = shift if @_;
3516     next unless $_;
3517
3518     # Always coerce into a hash
3519     return $_ if UNIVERSAL::isa($_, 'HASH');
3520     return $_ = { map {$_,1} @$_ } if UNIVERSAL::isa($_, 'ARRAY');
3521
3522     die "'script_files' must be a hashref, arrayref, or string" if ref();
3523
3524     return $_ = { map {$_,1} $self->_files_in( $_ ) } if -d $_;
3525     return $_ = {$_ => 1};
3526   }
3527
3528   my %pl_files = map {
3529     File::Spec->canonpath( File::Spec->case_tolerant ? uc $_ : $_ ) => 1 
3530   } keys %{ $self->PL_files || {} };
3531
3532   my @bin_files = $self->_files_in('bin');
3533
3534   my %bin_map = map {
3535     $_ => File::Spec->canonpath( File::Spec->case_tolerant ? uc $_ : $_ ) 
3536   } @bin_files;
3537
3538   return $_ = { map {$_ => 1} grep !$pl_files{$bin_map{$_}}, @bin_files };
3539 }
3540 BEGIN { *scripts = \&script_files; }
3541
3542 {
3543   my %licenses = (
3544     perl         => 'Perl_5',
3545     apache       => 'Apache_2_0',
3546     artistic     => 'Artistic_1_0',
3547     artistic_2   => 'Artistic_2_0',
3548     lgpl         => 'LGPL_2_1',
3549     lgpl2        => 'LGPL_2_1',
3550     lgpl3        => 'LGPL_3_0',
3551     bsd          => 'BSD',
3552     gpl          => 'GPL_1',
3553     gpl2         => 'GPL_2',
3554     gpl3         => 'GPL_3',
3555     mit          => 'MIT',
3556     mozilla      => 'Mozilla_1_1',
3557     open_source  => undef,
3558     unrestricted => undef,
3559     restrictive  => undef,
3560     unknown      => undef,
3561   );
3562
3563   # TODO - would be nice to not have these here, since they're more
3564   # properly stored only in Software::License
3565   my %license_urls = (
3566     perl         => 'http://dev.perl.org/licenses/',
3567     apache       => 'http://apache.org/licenses/LICENSE-2.0',
3568     artistic     => 'http://opensource.org/licenses/artistic-license.php',
3569     artistic_2   => 'http://opensource.org/licenses/artistic-license-2.0.php',
3570     lgpl         => 'http://opensource.org/licenses/lgpl-license.php',
3571     lgpl2        => 'http://opensource.org/licenses/lgpl-2.1.php',
3572     lgpl3        => 'http://opensource.org/licenses/lgpl-3.0.html',
3573     bsd          => 'http://opensource.org/licenses/bsd-license.php',
3574     gpl          => 'http://opensource.org/licenses/gpl-license.php',
3575     gpl2         => 'http://opensource.org/licenses/gpl-2.0.php',
3576     gpl3         => 'http://opensource.org/licenses/gpl-3.0.html',
3577     mit          => 'http://opensource.org/licenses/mit-license.php',
3578     mozilla      => 'http://opensource.org/licenses/mozilla1.1.php',
3579     open_source  => undef,
3580     unrestricted => undef,
3581     restrictive  => undef,
3582     unknown      => undef,
3583   );
3584   sub valid_licenses {
3585     return \%licenses;
3586   }
3587   sub _license_url {
3588     return $license_urls{$_[1]};
3589   }
3590 }
3591
3592 sub _hash_merge {
3593   my ($self, $h, $k, $v) = @_;
3594   if (ref $h->{$k} eq 'ARRAY') {
3595     push @{$h->{$k}}, ref $v ? @$v : $v;
3596   } elsif (ref $h->{$k} eq 'HASH') {
3597     $h->{$k}{$_} = $v->{$_} foreach keys %$v;
3598   } else {
3599     $h->{$k} = $v;
3600   }
3601 }
3602
3603 sub ACTION_distmeta {
3604   my ($self) = @_;
3605
3606   $self->do_create_makefile_pl if $self->create_makefile_pl;
3607   $self->do_create_readme if $self->create_readme;
3608   $self->do_create_license if $self->create_license;
3609   $self->do_create_metafile;
3610 }
3611
3612 sub do_create_metafile {
3613   my $self = shift;
3614   return if $self->{wrote_metadata};
3615   
3616   my $p = $self->{properties};
3617   my $metafile = $self->metafile;
3618   
3619   unless ($p->{license}) {
3620     $self->log_warn("No license specified, setting license = 'unknown'\n");
3621     $p->{license} = 'unknown';
3622   }
3623   unless (exists $self->valid_licenses->{ $p->{license} }) {
3624     die "Unknown license type '$p->{license}'";
3625   }
3626
3627   # If we're in the distdir, the metafile may exist and be non-writable.
3628   $self->delete_filetree($metafile);
3629   $self->log_info("Creating $metafile\n");
3630
3631   # Since we're building ourself, we have to do some special stuff
3632   # here: the ConfigData module is found in blib/lib.
3633   local @INC = @INC;
3634   if (($self->module_name || '') eq 'Module::Build') {
3635     $self->depends_on('config_data');
3636     push @INC, File::Spec->catdir($self->blib, 'lib');
3637   }
3638
3639   if ( $self->write_metafile( $self->metafile, $self->generate_metadata ) ) {
3640     $self->{wrote_metadata} = 1;
3641     $self->_add_to_manifest('MANIFEST', $metafile);
3642   }
3643
3644   return 1;
3645 }
3646
3647 sub generate_metadata {
3648   my $self = shift;
3649   my $node = {};
3650
3651   if ($self->_mb_feature('YAML_support')) {
3652     require YAML;
3653     require YAML::Node;
3654     # We use YAML::Node to get the order nice in the YAML file.
3655     $self->prepare_metadata( $node = YAML::Node->new({}) );
3656   } else {
3657     require Module::Build::YAML;
3658     my @order_keys;
3659     $self->prepare_metadata($node, \@order_keys);
3660     $node->{_order} = \@order_keys;
3661   }
3662   return $node;
3663 }
3664
3665 sub write_metafile {
3666   my $self = shift;
3667   my ($metafile, $node) = @_;
3668
3669   if ($self->_mb_feature('YAML_support')) {
3670     # XXX this is probably redundant, but stick with it
3671     require YAML;
3672     require YAML::Node;
3673     delete $node->{_order}; # XXX also probably redundant, but for safety
3674     # YAML API changed after version 0.30
3675     my $yaml_sub = $YAML::VERSION le '0.30' ? \&YAML::StoreFile : \&YAML::DumpFile;
3676     $yaml_sub->( $metafile, $node );
3677   } else {
3678     # XXX probably redundant
3679     require Module::Build::YAML;
3680     &Module::Build::YAML::DumpFile($metafile, $node);
3681   }
3682   return 1;
3683 }
3684
3685 sub normalize_version {
3686   my ($self, $version) = @_;
3687   if ( $version =~ /[=<>!,]/ ) { # logic, not just version
3688     # take as is without modification
3689   }
3690   elsif ( ref $version eq 'version' || 
3691           ref $version eq 'Module::Build::Version' ) { # version objects
3692     $version = $version->is_qv ? $version->normal : $version->stringify;
3693   }
3694   elsif ( $version =~ /^[^v][^.]*\.[^.]+\./ ) { # no leading v, multiple dots
3695     # normalize string tuples without "v": "1.2.3" -> "v1.2.3"
3696     $version = "v$version";
3697   }
3698   else {
3699     # leave alone
3700   }
3701   return $version;
3702 }
3703
3704 sub prepare_metadata {
3705   my ($self, $node, $keys) = @_;
3706   my $p = $self->{properties};
3707
3708   # A little helper sub
3709   my $add_node = sub {
3710     my ($name, $val) = @_;
3711     $node->{$name} = $val;
3712     push @$keys, $name if $keys;
3713   };
3714
3715   foreach (qw(dist_name dist_version dist_author dist_abstract license)) {
3716     (my $name = $_) =~ s/^dist_//;
3717     $add_node->($name, $self->$_());
3718     die "ERROR: Missing required field '$_' for META.yml\n"
3719       unless defined($node->{$name}) && length($node->{$name});
3720   }
3721   $node->{version} = $self->normalize_version($node->{version}); 
3722
3723   if (defined( my $l = $self->license )) {
3724     die "Unknown license string '$l'"
3725       unless exists $self->valid_licenses->{ $l };
3726
3727     if (my $key = $self->valid_licenses->{ $l }) {
3728       my $class = "Software::License::$key";
3729       if (eval "use $class; 1") {
3730         # S::L requires a 'holder' key
3731         $node->{resources}{license} = $class->new({holder=>"nobody"})->url;
3732       }
3733       else {
3734         $node->{resources}{license} = $self->_license_url($l);
3735       }
3736     }
3737     # XXX we are silently omitting the url for any unknown license
3738   }
3739
3740   # copy prereq data structures so we can modify them before writing to META
3741   my %prereq_types;
3742   for my $type ( 'configure_requires', @{$self->prereq_action_types} ) {
3743     if (exists $p->{$type}) {  
3744       for my $mod ( keys %{ $p->{$type} } ) {
3745         $prereq_types{$type}{$mod} = 
3746           $self->normalize_version($p->{$type}{$mod});
3747       }
3748     }
3749   }
3750
3751   # add current Module::Build to configure_requires if there 
3752   # isn't one already specified (but not ourself, so we're not circular)
3753   if ( $self->dist_name ne 'Module-Build' 
3754     && $self->auto_configure_requires
3755     && ! exists $prereq_types{'configure_requires'}{'Module::Build'}
3756   ) {
3757     $prereq_types{configure_requires}{'Module::Build'} = $VERSION;
3758   }
3759
3760   for my $t ( keys %prereq_types ) {
3761       $add_node->($t, $prereq_types{$t});
3762   }
3763
3764   if (exists $p->{dynamic_config}) {
3765     $add_node->('dynamic_config', $p->{dynamic_config});
3766   }
3767   my $pkgs = eval { $self->find_dist_packages };
3768   if ($@) {
3769     $self->log_warn("$@\nWARNING: Possible missing or corrupt 'MANIFEST' file.\n" .
3770                     "Nothing to enter for 'provides' field in META.yml\n");
3771   } else {
3772     $node->{provides} = $pkgs if %$pkgs;
3773   }
3774 ;
3775   if (exists $p->{no_index}) {
3776     $add_node->('no_index', $p->{no_index});
3777   }
3778
3779   $add_node->('generated_by', "Module::Build version $Module::Build::VERSION");
3780
3781   $add_node->('meta-spec', 
3782               {version => '1.4',
3783                url     => 'http://module-build.sourceforge.net/META-spec-v1.4.html',
3784               });
3785
3786   while (my($k, $v) = each %{$self->meta_add}) {
3787     $add_node->($k, $v);
3788   }
3789
3790   while (my($k, $v) = each %{$self->meta_merge}) {
3791     $self->_hash_merge($node, $k, $v);
3792   }
3793
3794   return $node;
3795 }
3796
3797 sub _read_manifest {
3798   my ($self, $file) = @_;
3799   return undef unless -e $file;
3800
3801   require ExtUtils::Manifest;  # ExtUtils::Manifest is not warnings clean.
3802   local ($^W, $ExtUtils::Manifest::Quiet) = (0,1);
3803   return scalar ExtUtils::Manifest::maniread($file);
3804 }
3805
3806 sub find_dist_packages {
3807   my $self = shift;
3808
3809   # Only packages in .pm files are candidates for inclusion here.
3810   # Only include things in the MANIFEST, not things in developer's
3811   # private stock.
3812
3813   my $manifest = $self->_read_manifest('MANIFEST')
3814     or die "Can't find dist packages without a MANIFEST file - run 'manifest' action first";
3815
3816   # Localize
3817   my %dist_files = map { $self->localize_file_path($_) => $_ }
3818                        keys %$manifest;
3819
3820   my @pm_files = grep {exists $dist_files{$_}} keys %{ $self->find_pm_files };
3821
3822   # First, we enumerate all packages & versions,
3823   # separating into primary & alternative candidates
3824   my( %prime, %alt );
3825   foreach my $file (@pm_files) {
3826     next if $dist_files{$file} =~ m{^t/};  # Skip things in t/
3827
3828     my @path = split( /\//, $dist_files{$file} );
3829     (my $prime_package = join( '::', @path[1..$#path] )) =~ s/\.pm$//;
3830
3831     my $pm_info = Module::Build::ModuleInfo->new_from_file( $file );
3832
3833     foreach my $package ( $pm_info->packages_inside ) {
3834       next if $package eq 'main';  # main can appear numerous times, ignore
3835       next if grep /^_/, split( /::/, $package ); # private package, ignore
3836
3837       my $version = $pm_info->version( $package );
3838
3839       if ( $package eq $prime_package ) {
3840         if ( exists( $prime{$package} ) ) {
3841           # M::B::ModuleInfo will handle this conflict
3842           die "Unexpected conflict in '$package'; multiple versions found.\n";
3843         } else {
3844           $prime{$package}{file} = $dist_files{$file};
3845           $prime{$package}{version} = $version if defined( $version );
3846         }
3847       } else {
3848         push( @{$alt{$package}}, {
3849                                   file    => $dist_files{$file},
3850                                   version => $version,
3851                                  } );
3852       }
3853     }
3854   }
3855
3856   # Then we iterate over all the packages found above, identifying conflicts
3857   # and selecting the "best" candidate for recording the file & version
3858   # for each package.
3859   foreach my $package ( keys( %alt ) ) {
3860     my $result = $self->_resolve_module_versions( $alt{$package} );
3861
3862     if ( exists( $prime{$package} ) ) { # primary package selected
3863
3864       if ( $result->{err} ) {
3865         # Use the selected primary package, but there are conflicting
3866         # errors among multiple alternative packages that need to be
3867         # reported
3868         $self->log_warn(
3869           "Found conflicting versions for package '$package'\n" .
3870           "  $prime{$package}{file} ($prime{$package}{version})\n" .
3871           $result->{err}
3872         );
3873
3874       } elsif ( defined( $result->{version} ) ) {
3875         # There is a primary package selected, and exactly one
3876         # alternative package
3877
3878         if ( exists( $prime{$package}{version} ) &&
3879              defined( $prime{$package}{version} ) ) {
3880           # Unless the version of the primary package agrees with the
3881           # version of the alternative package, report a conflict
3882           if ( $self->compare_versions( $prime{$package}{version}, '!=',
3883                                         $result->{version} ) ) {
3884             $self->log_warn(
3885               "Found conflicting versions for package '$package'\n" .
3886               "  $prime{$package}{file} ($prime{$package}{version})\n" .
3887               "  $result->{file} ($result->{version})\n"
3888             );
3889           }
3890
3891         } else {
3892           # The prime package selected has no version so, we choose to
3893           # use any alternative package that does have a version
3894           $prime{$package}{file}    = $result->{file};
3895           $prime{$package}{version} = $result->{version};
3896         }
3897
3898       } else {
3899         # no alt package found with a version, but we have a prime
3900         # package so we use it whether it has a version or not
3901       }
3902
3903     } else { # No primary package was selected, use the best alternative
3904
3905       if ( $result->{err} ) {
3906         $self->log_warn(
3907           "Found conflicting versions for package '$package'\n" .
3908           $result->{err}
3909         );
3910       }
3911
3912       # Despite possible conflicting versions, we choose to record
3913       # something rather than nothing
3914       $prime{$package}{file}    = $result->{file};
3915       $prime{$package}{version} = $result->{version}
3916           if defined( $result->{version} );
3917     }
3918   }
3919
3920   # Normalize versions.  Can't use exists() here because of bug in YAML::Node.
3921   # XXX "bug in YAML::Node" comment seems irrelvant -- dagolden, 2009-05-18
3922   for (grep defined $_->{version}, values %prime) {
3923     $_->{version} = $self->normalize_version( $_->{version} );
3924   }
3925
3926   return \%prime;
3927 }
3928
3929 # separate out some of the conflict resolution logic from
3930 # $self->find_dist_packages(), above, into a helper function.
3931 #
3932 sub _resolve_module_versions {
3933   my $self = shift;
3934
3935   my $packages = shift;
3936
3937   my( $file, $version );
3938   my $err = '';
3939     foreach my $p ( @$packages ) {
3940       if ( defined( $p->{version} ) ) {
3941         if ( defined( $version ) ) {
3942           if ( $self->compare_versions( $version, '!=', $p->{version} ) ) {
3943             $err .= "  $p->{file} ($p->{version})\n";
3944           } else {
3945             # same version declared multiple times, ignore
3946           }
3947         } else {
3948           $file    = $p->{file};
3949           $version = $p->{version};
3950         }
3951       }
3952       $file ||= $p->{file} if defined( $p->{file} );
3953     }
3954
3955   if ( $err ) {
3956     $err = "  $file ($version)\n" . $err;
3957   }
3958
3959   my %result = (
3960     file    => $file,
3961     version => $version,
3962     err     => $err
3963   );
3964
3965   return \%result;
3966 }
3967
3968 sub make_tarball {
3969   my ($self, $dir, $file) = @_;
3970   $file ||= $dir;
3971   
3972   $self->log_info("Creating $file.tar.gz\n");
3973   
3974   if ($self->{args}{tar}) {
3975     my $tar_flags = $self->verbose ? 'cvf' : 'cf';
3976     $self->do_system($self->split_like_shell($self->{args}{tar}), $tar_flags, "$file.tar", $dir);
3977     $self->do_system($self->split_like_shell($self->{args}{gzip}), "$file.tar") if $self->{args}{gzip};
3978   } else {
3979     require Archive::Tar;
3980
3981     # Archive::Tar versions >= 1.09 use the following to enable a compatibility
3982     # hack so that the resulting archive is compatible with older clients.
3983     $Archive::Tar::DO_NOT_USE_PREFIX = 0;
3984
3985     my $files = $self->rscan_dir($dir);
3986     my $tar   = Archive::Tar->new;
3987     $tar->add_files(@$files);
3988     for my $f ($tar->get_files) {
3989       $f->mode($f->mode & ~022); # chmod go-w
3990     }
3991     $tar->write("$file.tar.gz", 1);
3992   }
3993 }
3994
3995 sub install_path {
3996   my $self = shift;
3997   my( $type, $value ) = ( @_, '<empty>' );
3998
3999   Carp::croak( 'Type argument missing' )
4000     unless defined( $type );
4001
4002   my $map = $self->{properties}{install_path};
4003   return $map unless @_;
4004
4005   # delete existing value if $value is literal undef()
4006   unless ( defined( $value ) ) {
4007     delete( $map->{$type} );
4008     return undef;
4009   }
4010
4011   # return existing value if no new $value is given
4012   if ( $value eq '<empty>' ) {
4013     return undef unless exists $map->{$type};
4014     return $map->{$type};
4015   }
4016
4017   # set value if $value is a valid relative path
4018   return $map->{$type} = $value;
4019 }
4020
4021 sub install_base_relpaths {
4022   # Usage: install_base_relpaths(), install_base_relpaths('lib'),
4023   #   or install_base_relpaths('lib' => $value);
4024   my $self = shift;
4025   my $map = $self->{properties}{install_base_relpaths};
4026   return $map unless @_;
4027   return $self->_relpaths($map, @_);
4028 }
4029
4030
4031 # Translated from ExtUtils::MM_Any::init_INSTALL_from_PREFIX
4032 sub prefix_relative {
4033   my ($self, $type) = @_;
4034   my $installdirs = $self->installdirs;
4035
4036   my $relpath = $self->install_sets($installdirs)->{$type};
4037
4038   return $self->_prefixify($relpath,
4039                            $self->original_prefix($installdirs),
4040                            $type,
4041                           );
4042 }
4043
4044 sub _relpaths {
4045   my $self = shift;
4046   my( $map, $type, $value ) = ( @_, '<empty>' );
4047
4048   Carp::croak( 'Type argument missing' )
4049     unless defined( $type );
4050
4051   my @value = ();
4052
4053   # delete existing value if $value is literal undef()
4054   unless ( defined( $value ) ) {
4055     delete( $map->{$type} );
4056     return undef;
4057   }
4058
4059   # return existing value if no new $value is given
4060   elsif ( $value eq '<empty>' ) {
4061     return undef unless exists $map->{$type};
4062     @value = @{ $map->{$type} };
4063   }
4064
4065   # set value if $value is a valid relative path
4066   else {
4067     Carp::croak( "Value must be a relative path" )
4068       if File::Spec::Unix->file_name_is_absolute($value);
4069
4070     @value = split( /\//, $value );
4071     $map->{$type} = \@value;
4072   }
4073
4074   return File::Spec->catdir( @value );
4075 }
4076
4077 # Defaults to use in case the config install paths cannot be prefixified.
4078 sub prefix_relpaths {
4079   # Usage: prefix_relpaths('site'), prefix_relpaths('site', 'lib'),
4080   #   or prefix_relpaths('site', 'lib' => $value);
4081   my $self = shift;
4082   my $installdirs = shift || $self->installdirs;
4083   my $map = $self->{properties}{prefix_relpaths}{$installdirs};
4084   return $map unless @_;
4085   return $self->_relpaths($map, @_);
4086 }
4087
4088
4089 # Translated from ExtUtils::MM_Unix::prefixify()
4090 sub _prefixify {
4091   my($self, $path, $sprefix, $type) = @_;
4092
4093   my $rprefix = $self->prefix;
4094   $rprefix .= '/' if $sprefix =~ m|/$|;
4095
4096   $self->log_verbose("  prefixify $path from $sprefix to $rprefix\n")
4097     if defined( $path ) && length( $path );
4098
4099   if( !defined( $path ) || ( length( $path ) == 0 ) ) {
4100     $self->log_verbose("  no path to prefixify, falling back to default.\n");
4101     return $self->_prefixify_default( $type, $rprefix );
4102   } elsif( !File::Spec->file_name_is_absolute($path) ) {
4103     $self->log_verbose("    path is relative, not prefixifying.\n");
4104   } elsif( $path !~ s{^\Q$sprefix\E\b}{}s ) {
4105     $self->log_verbose("    cannot prefixify, falling back to default.\n");
4106     return $self->_prefixify_default( $type, $rprefix );
4107   }
4108
4109   $self->log_verbose("    now $path in $rprefix\n");
4110
4111   return $path;
4112 }
4113
4114 sub _prefixify_default {
4115   my $self = shift;
4116   my $type = shift;
4117   my $rprefix = shift;
4118
4119   my $default = $self->prefix_relpaths($self->installdirs, $type);
4120   if( !$default ) {
4121     $self->log_verbose("    no default install location for type '$type', using prefix '$rprefix'.\n");
4122     return $rprefix;
4123   } else {
4124     return $default;
4125   }
4126 }
4127
4128 sub install_destination {
4129   my ($self, $type) = @_;
4130
4131   return $self->install_path($type) if $self->install_path($type);
4132
4133   if ( $self->install_base ) {
4134     my $relpath = $self->install_base_relpaths($type);
4135     return $relpath ? File::Spec->catdir($self->install_base, $relpath) : undef;
4136   }
4137
4138   if ( $self->prefix ) {
4139     my $relpath = $self->prefix_relative($type);
4140     return $relpath ? File::Spec->catdir($self->prefix, $relpath) : undef;
4141   }
4142
4143   return $self->install_sets($self->installdirs)->{$type};
4144 }
4145
4146 sub install_types {
4147   my $self = shift;
4148
4149   my %types;
4150   if ( $self->install_base ) {
4151     %types = %{$self->install_base_relpaths};
4152   } elsif ( $self->prefix ) {
4153     %types = %{$self->prefix_relpaths};
4154   } else {
4155     %types = %{$self->install_sets($self->installdirs)};
4156   }
4157
4158   %types = (%types, %{$self->install_path});
4159
4160   return sort keys %types;
4161 }
4162
4163 sub install_map {
4164   my ($self, $blib) = @_;
4165   $blib ||= $self->blib;
4166
4167   my( %map, @skipping );
4168   foreach my $type ($self->install_types) {
4169     my $localdir = File::Spec->catdir( $blib, $type );
4170     next unless -e $localdir;
4171
4172     if (my $dest = $self->install_destination($type)) {
4173       $map{$localdir} = $dest;
4174     } else {
4175       push( @skipping, $type );
4176     }
4177   }
4178
4179   $self->log_warn(
4180     "WARNING: Can't figure out install path for types: @skipping\n" .
4181     "Files will not be installed.\n"
4182   ) if @skipping;
4183
4184   # Write the packlist into the same place as ExtUtils::MakeMaker.
4185   if ($self->create_packlist and my $module_name = $self->module_name) {
4186     my $archdir = $self->install_destination('arch');
4187     my @ext = split /::/, $module_name;
4188     $map{write} = File::Spec->catfile($archdir, 'auto', @ext, '.packlist');
4189   }
4190
4191   # Handle destdir
4192   if (length(my $destdir = $self->destdir || '')) {
4193     foreach (keys %map) {
4194       # Need to remove volume from $map{$_} using splitpath, or else
4195       # we'll create something crazy like C:\Foo\Bar\E:\Baz\Quux
4196       # VMS will always have the file separate than the path.
4197       my ($volume, $path, $file) = File::Spec->splitpath( $map{$_}, 0 );
4198
4199       # catdir needs a list of directories, or it will create something
4200       # crazy like volume:[Foo.Bar.volume.Baz.Quux]
4201       my @dirs = File::Spec->splitdir($path);
4202
4203       # First merge the directories
4204       $path = File::Spec->catdir($destdir, @dirs);
4205
4206       # Then put the file back on if there is one.
4207       if ($file ne '') {
4208           $map{$_} = File::Spec->catfile($path, $file)
4209       } else {
4210           $map{$_} = $path;
4211       }
4212     }
4213   }
4214   
4215   $map{read} = '';  # To keep ExtUtils::Install quiet
4216
4217   return \%map;
4218 }
4219
4220 sub depends_on {
4221   my $self = shift;
4222   foreach my $action (@_) {
4223     $self->_call_action($action);
4224   }
4225 }
4226
4227 sub rscan_dir {
4228   my ($self, $dir, $pattern) = @_;
4229   my @result;
4230   local $_; # find() can overwrite $_, so protect ourselves
4231   my $subr = !$pattern ? sub {push @result, $File::Find::name} :
4232              !ref($pattern) || (ref $pattern eq 'Regexp') ? sub {push @result, $File::Find::name if /$pattern/} :
4233              ref($pattern) eq 'CODE' ? sub {push @result, $File::Find::name if $pattern->()} :
4234              die "Unknown pattern type";
4235   
4236   File::Find::find({wanted => $subr, no_chdir => 1}, $dir);
4237   return \@result;
4238 }
4239
4240 sub delete_filetree {
4241   my $self = shift;
4242   my $deleted = 0;
4243   foreach (@_) {
4244     next unless -e $_;
4245     $self->log_info("Deleting $_\n");
4246     File::Path::rmtree($_, 0, 0);
4247     die "Couldn't remove '$_': $!\n" if -e $_;
4248     $deleted++;
4249   }
4250   return $deleted;
4251 }
4252
4253 sub autosplit_file {
4254   my ($self, $file, $to) = @_;
4255   require AutoSplit;
4256   my $dir = File::Spec->catdir($to, 'lib', 'auto');
4257   AutoSplit::autosplit($file, $dir);
4258 }
4259
4260 sub cbuilder {
4261   # Returns a CBuilder object
4262
4263   my $self = shift;
4264   my $s = $self->{stash};
4265   return $s->{_cbuilder} if $s->{_cbuilder};
4266   die "Module::Build is not configured with C_support"
4267           unless $self->_mb_feature('C_support');
4268
4269   require ExtUtils::CBuilder;
4270   return $s->{_cbuilder} = ExtUtils::CBuilder->new(
4271     config => $self->config,
4272     ($self->quiet ? (quiet => 1 ) : ()),
4273   );
4274 }
4275
4276 sub have_c_compiler {
4277   my ($self) = @_;
4278   
4279   my $p = $self->{properties};
4280   return $p->{have_compiler} if defined $p->{have_compiler};
4281   
4282   $self->log_verbose("Checking if compiler tools configured... ");
4283   my $b = eval { $self->cbuilder };
4284   my $have = $b && $b->have_compiler;
4285   $self->log_verbose($have ? "ok.\n" : "failed.\n");
4286   return $p->{have_compiler} = $have;
4287 }
4288
4289 sub compile_c {
4290   my ($self, $file, %args) = @_;
4291   my $b = $self->cbuilder;
4292
4293   my $obj_file = $b->object_file($file);
4294   $self->add_to_cleanup($obj_file);
4295   return $obj_file if $self->up_to_date($file, $obj_file);
4296
4297   $b->compile(source => $file,
4298               defines => $args{defines},
4299               object_file => $obj_file,
4300               include_dirs => $self->include_dirs,
4301               extra_compiler_flags => $self->extra_compiler_flags,
4302              );
4303
4304   return $obj_file;
4305 }
4306
4307 sub link_c {
4308   my ($self, $spec) = @_;
4309   my $p = $self->{properties}; # For convenience
4310
4311   $self->add_to_cleanup($spec->{lib_file});
4312
4313   my $objects = $p->{objects} || [];
4314
4315   return $spec->{lib_file}
4316     if $self->up_to_date([$spec->{obj_file}, @$objects],
4317                          $spec->{lib_file});
4318
4319   my $module_name = $spec->{module_name} || $self->module_name;
4320
4321   $self->cbuilder->link(
4322     module_name => $module_name,
4323     objects     => [$spec->{obj_file}, @$objects],
4324     lib_file    => $spec->{lib_file},
4325     extra_linker_flags => $p->{extra_linker_flags} );
4326
4327   return $spec->{lib_file};
4328 }
4329
4330 sub compile_xs {
4331   my ($self, $file, %args) = @_;
4332   
4333   $self->log_info("$file -> $args{outfile}\n");
4334
4335   if (eval {require ExtUtils::ParseXS; 1}) {
4336     
4337     ExtUtils::ParseXS::process_file(
4338                                     filename => $file,
4339                                     prototypes => 0,
4340                                     output => $args{outfile},
4341                                    );
4342   } else {
4343     # Ok, I give up.  Just use backticks.
4344     
4345     my $xsubpp = Module::Build::ModuleInfo->find_module_by_name('ExtUtils::xsubpp')
4346       or die "Can't find ExtUtils::xsubpp in INC (@INC)";
4347     
4348     my @typemaps;
4349     push @typemaps, Module::Build::ModuleInfo->find_module_by_name(
4350         'ExtUtils::typemap', \@INC
4351     );
4352     my $lib_typemap = Module::Build::ModuleInfo->find_module_by_name(
4353         'typemap', [File::Basename::dirname($file)]
4354     );
4355     push @typemaps, $lib_typemap if $lib_typemap;
4356     @typemaps = map {+'-typemap', $_} @typemaps;
4357
4358     my $cf = $self->{config};
4359     my $perl = $self->{properties}{perl};
4360     
4361     my @command = ($perl, "-I".$cf->get('installarchlib'), "-I".$cf->get('installprivlib'), $xsubpp, '-noprototypes',
4362                    @typemaps, $file);
4363     
4364     $self->log_info("@command\n");
4365     my $fh = IO::File->new("> $args{outfile}") or die "Couldn't write $args{outfile}: $!";
4366     print {$fh} $self->_backticks(@command);
4367     close $fh;
4368   }
4369 }
4370
4371 sub split_like_shell {
4372   my ($self, $string) = @_;
4373   
4374   return () unless defined($string);
4375   return @$string if UNIVERSAL::isa($string, 'ARRAY');
4376   $string =~ s/^\s+|\s+$//g;
4377   return () unless length($string);
4378   
4379   return Text::ParseWords::shellwords($string);
4380 }
4381
4382 sub oneliner {
4383   # Returns a string that the shell can evaluate as a perl command.
4384   # This should be avoided whenever possible, since "the shell" really
4385   # means zillions of shells on zillions of platforms and it's really
4386   # hard to get it right all the time.
4387
4388   # Some of this code is stolen with permission from ExtUtils::MakeMaker.
4389
4390   my($self, $cmd, $switches, $args) = @_;
4391   $switches = [] unless defined $switches;
4392   $args = [] unless defined $args;
4393
4394   # Strip leading and trailing newlines
4395   $cmd =~ s{^\n+}{};
4396   $cmd =~ s{\n+$}{};
4397
4398   my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
4399   return $self->_quote_args($perl, @$switches, '-e', $cmd, @$args);
4400 }
4401
4402 sub run_perl_script {
4403   my ($self, $script, $preargs, $postargs) = @_;
4404   foreach ($preargs, $postargs) {
4405     $_ = [ $self->split_like_shell($_) ] unless ref();
4406   }
4407   return $self->run_perl_command([@$preargs, $script, @$postargs]);
4408 }
4409
4410 sub run_perl_command {
4411   # XXX Maybe we should accept @args instead of $args?  Must resolve
4412   # this before documenting.
4413   my ($self, $args) = @_;
4414   $args = [ $self->split_like_shell($args) ] unless ref($args);
4415   my $perl = ref($self) ? $self->perl : $self->find_perl_interpreter;
4416
4417   # Make sure our local additions to @INC are propagated to the subprocess
4418   local $ENV{PERL5LIB} = join $self->config('path_sep'), $self->_added_to_INC;
4419
4420   return $self->do_system($perl, @$args);
4421 }
4422
4423 # Infer various data from the path of the input filename
4424 # that is needed to create output files.
4425 # The input filename is expected to be of the form:
4426 #   lib/Module/Name.ext or Module/Name.ext
4427 sub _infer_xs_spec {
4428   my $self = shift;
4429   my $file = shift;
4430
4431   my $cf = $self->{config};
4432
4433   my %spec;
4434
4435   my( $v, $d, $f ) = File::Spec->splitpath( $file );
4436   my @d = File::Spec->splitdir( $d );
4437   (my $file_base = $f) =~ s/\.[^.]+$//i;
4438
4439   $spec{base_name} = $file_base;
4440
4441   $spec{src_dir} = File::Spec->catpath( $v, $d, '' );
4442
4443   # the module name
4444   shift( @d ) while @d && ($d[0] eq 'lib' || $d[0] eq '');
4445   pop( @d ) while @d && $d[-1] eq '';
4446   $spec{module_name} = join( '::', (@d, $file_base) );
4447
4448   $spec{archdir} = File::Spec->catdir($self->blib, 'arch', 'auto',
4449                                       @d, $file_base);
4450
4451   $spec{bs_file} = File::Spec->catfile($spec{archdir}, "${file_base}.bs");
4452
4453   $spec{lib_file} = File::Spec->catfile($spec{archdir},
4454                                         "${file_base}.".$cf->get('dlext'));
4455
4456   $spec{c_file} = File::Spec->catfile( $spec{src_dir},
4457                                        "${file_base}.c" );
4458
4459   $spec{obj_file} = File::Spec->catfile( $spec{src_dir},
4460                                          "${file_base}".$cf->get('obj_ext') );
4461
4462   return \%spec;
4463 }
4464
4465 sub process_xs {
4466   my ($self, $file) = @_;
4467
4468   my $spec = $self->_infer_xs_spec($file);
4469
4470   # File name, minus the suffix
4471   (my $file_base = $file) =~ s/\.[^.]+$//;
4472
4473   # .xs -> .c
4474   $self->add_to_cleanup($spec->{c_file});
4475
4476   unless ($self->up_to_date($file, $spec->{c_file})) {
4477     $self->compile_xs($file, outfile => $spec->{c_file});
4478   }
4479
4480   # .c -> .o
4481   my $v = $self->dist_version;
4482   $self->compile_c($spec->{c_file},
4483                    defines => {VERSION => qq{"$v"}, XS_VERSION => qq{"$v"}});
4484
4485   # archdir
4486   File::Path::mkpath($spec->{archdir}, 0, oct(777)) unless -d $spec->{archdir};
4487
4488   # .xs -> .bs
4489   $self->add_to_cleanup($spec->{bs_file});
4490   unless ($self->up_to_date($file, $spec->{bs_file})) {
4491     require ExtUtils::Mkbootstrap;
4492     $self->log_info("ExtUtils::Mkbootstrap::Mkbootstrap('$spec->{bs_file}')\n");
4493     ExtUtils::Mkbootstrap::Mkbootstrap($spec->{bs_file});  # Original had $BSLOADLIBS - what's that?
4494     {my $fh = IO::File->new(">> $spec->{bs_file}")}  # create
4495     utime((time)x2, $spec->{bs_file});  # touch
4496   }
4497
4498   # .o -> .(a|bundle)
4499   $self->link_c($spec);
4500 }
4501
4502 sub do_system {
4503   my ($self, @cmd) = @_;
4504   $self->log_info("@cmd\n");
4505
4506   # Some systems proliferate huge PERL5LIBs, try to ameliorate:
4507   my %seen;
4508   my $sep = $self->config('path_sep');
4509   local $ENV{PERL5LIB} = 
4510     ( !exists($ENV{PERL5LIB}) ? '' :
4511       length($ENV{PERL5LIB}) < 500
4512       ? $ENV{PERL5LIB}
4513       : join $sep, grep { ! $seen{$_}++ and -d $_ } split($sep, $ENV{PERL5LIB})
4514     );
4515
4516   my $status = system(@cmd);
4517   if ($status and $! =~ /Argument list too long/i) {
4518     my $env_entries = '';
4519     foreach (sort keys %ENV) { $env_entries .= "$_=>".length($ENV{$_})."; " }
4520     warn "'Argument list' was 'too long', env lengths are $env_entries";
4521   }
4522   return !$status;
4523 }
4524
4525 sub copy_if_modified {
4526   my $self = shift;
4527   my %args = (@_ > 3
4528               ? ( @_ )
4529               : ( from => shift, to_dir => shift, flatten => shift )
4530              );
4531   $args{verbose} = !$self->quiet
4532     unless exists $args{verbose};
4533
4534   my $file = $args{from};
4535   unless (defined $file and length $file) {
4536     die "No 'from' parameter given to copy_if_modified";
4537   }
4538  
4539   # makes no sense to replicate an absolute path, so assume flatten 
4540   $args{flatten} = 1 if File::Spec->file_name_is_absolute( $file );
4541
4542   my $to_path;
4543   if (defined $args{to} and length $args{to}) {
4544     $to_path = $args{to};
4545   } elsif (defined $args{to_dir} and length $args{to_dir}) {
4546     $to_path = File::Spec->catfile( $args{to_dir}, $args{flatten}
4547                                     ? File::Basename::basename($file)
4548                                     : $file );
4549   } else {
4550     die "No 'to' or 'to_dir' parameter given to copy_if_modified";
4551   }
4552   
4553   return if $self->up_to_date($file, $to_path); # Already fresh
4554
4555   {
4556     local $self->{properties}{quiet} = 1;
4557     $self->delete_filetree($to_path); # delete destination if exists
4558   }
4559
4560   # Create parent directories
4561   File::Path::mkpath(File::Basename::dirname($to_path), 0, oct(777));
4562   
4563   $self->log_info("Copying $file -> $to_path\n") if $args{verbose};
4564   
4565   if ($^O eq 'os2') {# copy will not overwrite; 0x1 = overwrite
4566     chmod 0666, $to_path;
4567     File::Copy::syscopy($file, $to_path, 0x1) or die "Can't copy('$file', '$to_path'): $!";
4568   } else {
4569     File::Copy::copy($file, $to_path) or die "Can't copy('$file', '$to_path'): $!";
4570   }
4571
4572   # mode is read-only + (executable if source is executable)
4573   my $mode = oct(444) | ( $self->is_executable($file) ? oct(111) : 0 );
4574   chmod( $mode, $to_path );
4575
4576   return $to_path;
4577 }
4578
4579 sub up_to_date {
4580   my ($self, $source, $derived) = @_;
4581   $source  = [$source]  unless ref $source;
4582   $derived = [$derived] unless ref $derived;
4583
4584   # empty $derived means $source should always run
4585   return 0 if @$source && !@$derived || grep {not -e} @$derived;
4586
4587   my $most_recent_source = time / (24*60*60);
4588   foreach my $file (@$source) {
4589     unless (-e $file) {
4590       $self->log_warn("Can't find source file $file for up-to-date check");
4591       next;
4592     }
4593     $most_recent_source = -M _ if -M _ < $most_recent_source;
4594   }
4595   
4596   foreach my $derived (@$derived) {
4597     return 0 if -M $derived > $most_recent_source;
4598   }
4599   return 1;
4600 }
4601
4602 sub dir_contains {
4603   my ($self, $first, $second) = @_;
4604   # File::Spec doesn't have an easy way to check whether one directory
4605   # is inside another, unfortunately.
4606   
4607   ($first, $second) = map File::Spec->canonpath($_), ($first, $second);
4608   my @first_dirs = File::Spec->splitdir($first);
4609   my @second_dirs = File::Spec->splitdir($second);
4610
4611   return 0 if @second_dirs < @first_dirs;
4612   
4613   my $is_same = ( File::Spec->case_tolerant
4614                   ? sub {lc(shift()) eq lc(shift())}
4615                   : sub {shift() eq shift()} );
4616   
4617   while (@first_dirs) {
4618     return 0 unless $is_same->(shift @first_dirs, shift @second_dirs);
4619   }
4620   
4621   return 1;
4622 }
4623
4624 1;
4625 __END__
4626
4627
4628 =head1 NAME
4629
4630 Module::Build::Base - Default methods for Module::Build
4631
4632 =head1 SYNOPSIS
4633
4634   Please see the Module::Build documentation.
4635
4636 =head1 DESCRIPTION
4637
4638 The C<Module::Build::Base> module defines the core functionality of
4639 C<Module::Build>.  Its methods may be overridden by any of the
4640 platform-dependent modules in the C<Module::Build::Platform::>
4641 namespace, but the intention here is to make this base module as
4642 platform-neutral as possible.  Nicely enough, Perl has several core
4643 tools available in the C<File::> namespace for doing this, so the task
4644 isn't very difficult.
4645
4646 Please see the C<Module::Build> documentation for more details.
4647
4648 =head1 AUTHOR
4649
4650 Ken Williams <kwilliams@cpan.org>
4651
4652 =head1 COPYRIGHT
4653
4654 Copyright (c) 2001-2006 Ken Williams.  All rights reserved.
4655
4656 This library is free software; you can redistribute it and/or
4657 modify it under the same terms as Perl itself.
4658
4659 =head1 SEE ALSO
4660
4661 perl(1), Module::Build(3)
4662
4663 =cut