Provide defined value for $TODO only where test is still failing.
[perl.git] / pod / perlref.pod
1 =head1 NAME
2 X<reference> X<pointer> X<data structure> X<structure> X<struct>
3
4 perlref - Perl references and nested data structures
5
6 =head1 NOTE
7
8 This is complete documentation about all aspects of references.
9 For a shorter, tutorial introduction to just the essential features,
10 see L<perlreftut>.
11
12 =head1 DESCRIPTION
13
14 Before release 5 of Perl it was difficult to represent complex data
15 structures, because all references had to be symbolic--and even then
16 it was difficult to refer to a variable instead of a symbol table entry.
17 Perl now not only makes it easier to use symbolic references to variables,
18 but also lets you have "hard" references to any piece of data or code.
19 Any scalar may hold a hard reference.  Because arrays and hashes contain
20 scalars, you can now easily build arrays of arrays, arrays of hashes,
21 hashes of arrays, arrays of hashes of functions, and so on.
22
23 Hard references are smart--they keep track of reference counts for you,
24 automatically freeing the thing referred to when its reference count goes
25 to zero.  (Reference counts for values in self-referential or
26 cyclic data structures may not go to zero without a little help; see
27 L</"Circular References"> for a detailed explanation.)
28 If that thing happens to be an object, the object is destructed.  See
29 L<perlobj> for more about objects.  (In a sense, everything in Perl is an
30 object, but we usually reserve the word for references to objects that
31 have been officially "blessed" into a class package.)
32
33 Symbolic references are names of variables or other objects, just as a
34 symbolic link in a Unix filesystem contains merely the name of a file.
35 The C<*glob> notation is something of a symbolic reference.  (Symbolic
36 references are sometimes called "soft references", but please don't call
37 them that; references are confusing enough without useless synonyms.)
38 X<reference, symbolic> X<reference, soft>
39 X<symbolic reference> X<soft reference>
40
41 In contrast, hard references are more like hard links in a Unix file
42 system: They are used to access an underlying object without concern for
43 what its (other) name is.  When the word "reference" is used without an
44 adjective, as in the following paragraph, it is usually talking about a
45 hard reference.
46 X<reference, hard> X<hard reference>
47
48 References are easy to use in Perl.  There is just one overriding
49 principle: in general, Perl does no implicit referencing or dereferencing.
50 When a scalar is holding a reference, it always behaves as a simple scalar.
51 It doesn't magically start being an array or hash or subroutine; you have to
52 tell it explicitly to do so, by dereferencing it.
53
54 =head2 Making References
55 X<reference, creation> X<referencing>
56
57 References can be created in several ways.
58
59 =over 4
60
61 =item 1.
62 X<\> X<backslash>
63
64 By using the backslash operator on a variable, subroutine, or value.
65 (This works much like the & (address-of) operator in C.)
66 This typically creates I<another> reference to a variable, because
67 there's already a reference to the variable in the symbol table.  But
68 the symbol table reference might go away, and you'll still have the
69 reference that the backslash returned.  Here are some examples:
70
71     $scalarref = \$foo;
72     $arrayref  = \@ARGV;
73     $hashref   = \%ENV;
74     $coderef   = \&handler;
75     $globref   = \*foo;
76
77 It isn't possible to create a true reference to an IO handle (filehandle
78 or dirhandle) using the backslash operator.  The most you can get is a
79 reference to a typeglob, which is actually a complete symbol table entry.
80 But see the explanation of the C<*foo{THING}> syntax below.  However,
81 you can still use type globs and globrefs as though they were IO handles.
82
83 =item 2.
84 X<array, anonymous> X<[> X<[]> X<square bracket>
85 X<bracket, square> X<arrayref> X<array reference> X<reference, array>
86
87 A reference to an anonymous array can be created using square
88 brackets:
89
90     $arrayref = [1, 2, ['a', 'b', 'c']];
91
92 Here we've created a reference to an anonymous array of three elements
93 whose final element is itself a reference to another anonymous array of three
94 elements.  (The multidimensional syntax described later can be used to
95 access this.  For example, after the above, C<< $arrayref->[2][1] >> would have
96 the value "b".)
97
98 Taking a reference to an enumerated list is not the same
99 as using square brackets--instead it's the same as creating
100 a list of references!
101
102     @list = (\$a, \@b, \%c);
103     @list = \($a, @b, %c);      # same thing!
104
105 As a special case, C<\(@foo)> returns a list of references to the contents
106 of C<@foo>, not a reference to C<@foo> itself.  Likewise for C<%foo>,
107 except that the key references are to copies (since the keys are just
108 strings rather than full-fledged scalars).
109
110 =item 3.
111 X<hash, anonymous> X<{> X<{}> X<curly bracket>
112 X<bracket, curly> X<brace> X<hashref> X<hash reference> X<reference, hash>
113
114 A reference to an anonymous hash can be created using curly
115 brackets:
116
117     $hashref = {
118         'Adam'  => 'Eve',
119         'Clyde' => 'Bonnie',
120     };
121
122 Anonymous hash and array composers like these can be intermixed freely to
123 produce as complicated a structure as you want.  The multidimensional
124 syntax described below works for these too.  The values above are
125 literals, but variables and expressions would work just as well, because
126 assignment operators in Perl (even within local() or my()) are executable
127 statements, not compile-time declarations.
128
129 Because curly brackets (braces) are used for several other things
130 including BLOCKs, you may occasionally have to disambiguate braces at the
131 beginning of a statement by putting a C<+> or a C<return> in front so
132 that Perl realizes the opening brace isn't starting a BLOCK.  The economy and
133 mnemonic value of using curlies is deemed worth this occasional extra
134 hassle.
135
136 For example, if you wanted a function to make a new hash and return a
137 reference to it, you have these options:
138
139     sub hashem {        { @_ } }   # silently wrong
140     sub hashem {       +{ @_ } }   # ok
141     sub hashem { return { @_ } }   # ok
142
143 On the other hand, if you want the other meaning, you can do this:
144
145     sub showem {        { @_ } }   # ambiguous (currently ok,
146                                    # but may change)
147     sub showem {       {; @_ } }   # ok
148     sub showem { { return @_ } }   # ok
149
150 The leading C<+{> and C<{;> always serve to disambiguate
151 the expression to mean either the HASH reference, or the BLOCK.
152
153 =item 4.
154 X<subroutine, anonymous> X<subroutine, reference> X<reference, subroutine>
155 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
156
157 A reference to an anonymous subroutine can be created by using
158 C<sub> without a subname:
159
160     $coderef = sub { print "Boink!\n" };
161
162 Note the semicolon.  Except for the code
163 inside not being immediately executed, a C<sub {}> is not so much a
164 declaration as it is an operator, like C<do{}> or C<eval{}>.  (However, no
165 matter how many times you execute that particular line (unless you're in an
166 C<eval("...")>), $coderef will still have a reference to the I<same>
167 anonymous subroutine.)
168
169 Anonymous subroutines act as closures with respect to my() variables,
170 that is, variables lexically visible within the current scope.  Closure
171 is a notion out of the Lisp world that says if you define an anonymous
172 function in a particular lexical context, it pretends to run in that
173 context even when it's called outside the context.
174
175 In human terms, it's a funny way of passing arguments to a subroutine when
176 you define it as well as when you call it.  It's useful for setting up
177 little bits of code to run later, such as callbacks.  You can even
178 do object-oriented stuff with it, though Perl already provides a different
179 mechanism to do that--see L<perlobj>.
180
181 You might also think of closure as a way to write a subroutine
182 template without using eval().  Here's a small example of how
183 closures work:
184
185     sub newprint {
186         my $x = shift;
187         return sub { my $y = shift; print "$x, $y!\n"; };
188     }
189     $h = newprint("Howdy");
190     $g = newprint("Greetings");
191
192     # Time passes...
193
194     &$h("world");
195     &$g("earthlings");
196
197 This prints
198
199     Howdy, world!
200     Greetings, earthlings!
201
202 Note particularly that $x continues to refer to the value passed
203 into newprint() I<despite> "my $x" having gone out of scope by the
204 time the anonymous subroutine runs.  That's what a closure is all
205 about.
206
207 This applies only to lexical variables, by the way.  Dynamic variables
208 continue to work as they have always worked.  Closure is not something
209 that most Perl programmers need trouble themselves about to begin with.
210
211 =item 5.
212 X<constructor> X<new>
213
214 References are often returned by special subroutines called constructors.  Perl
215 objects are just references to a special type of object that happens to know
216 which package it's associated with.  Constructors are just special subroutines
217 that know how to create that association.  They do so by starting with an
218 ordinary reference, and it remains an ordinary reference even while it's also
219 being an object.  Constructors are often named C<new()>.  You I<can> call them
220 indirectly:
221
222     $objref = new Doggie( Tail => 'short', Ears => 'long' );
223
224 But that can produce ambiguous syntax in certain cases, so it's often
225 better to use the direct method invocation approach:
226
227     $objref   = Doggie->new(Tail => 'short', Ears => 'long');
228
229     use Term::Cap;
230     $terminal = Term::Cap->Tgetent( { OSPEED => 9600 });
231
232     use Tk;
233     $main    = MainWindow->new();
234     $menubar = $main->Frame(-relief              => "raised",
235                             -borderwidth         => 2)
236
237 =item 6.
238 X<autovivification>
239
240 References of the appropriate type can spring into existence if you
241 dereference them in a context that assumes they exist.  Because we haven't
242 talked about dereferencing yet, we can't show you any examples yet.
243
244 =item 7.
245 X<*foo{THING}> X<*>
246
247 A reference can be created by using a special syntax, lovingly known as
248 the *foo{THING} syntax.  *foo{THING} returns a reference to the THING
249 slot in *foo (which is the symbol table entry which holds everything
250 known as foo).
251
252     $scalarref = *foo{SCALAR};
253     $arrayref  = *ARGV{ARRAY};
254     $hashref   = *ENV{HASH};
255     $coderef   = *handler{CODE};
256     $ioref     = *STDIN{IO};
257     $globref   = *foo{GLOB};
258     $formatref = *foo{FORMAT};
259     $globname  = *foo{NAME};    # "foo"
260     $pkgname   = *foo{PACKAGE}; # "main"
261
262 Most of these are self-explanatory, but C<*foo{IO}>
263 deserves special attention.  It returns
264 the IO handle, used for file handles (L<perlfunc/open>), sockets
265 (L<perlfunc/socket> and L<perlfunc/socketpair>), and directory
266 handles (L<perlfunc/opendir>).  For compatibility with previous
267 versions of Perl, C<*foo{FILEHANDLE}> is a synonym for C<*foo{IO}>, though it
268 is discouraged, to encourage a consistent use of one name: IO.  On perls
269 between v5.8 and v5.22, it will issue a deprecation warning, but this
270 deprecation has since been rescinded.
271
272 C<*foo{THING}> returns undef if that particular THING hasn't been used yet,
273 except in the case of scalars.  C<*foo{SCALAR}> returns a reference to an
274 anonymous scalar if $foo hasn't been used yet.  This might change in a
275 future release.
276
277 C<*foo{NAME}> and C<*foo{PACKAGE}> are the exception, in that they return
278 strings, rather than references.  These return the package and name of the
279 typeglob itself, rather than one that has been assigned to it.  So, after
280 C<*foo=*Foo::bar>, C<*foo> will become "*Foo::bar" when used as a string,
281 but C<*foo{PACKAGE}> and C<*foo{NAME}> will continue to produce "main" and
282 "foo", respectively.
283
284 C<*foo{IO}> is an alternative to the C<*HANDLE> mechanism given in
285 L<perldata/"Typeglobs and Filehandles"> for passing filehandles
286 into or out of subroutines, or storing into larger data structures.
287 Its disadvantage is that it won't create a new filehandle for you.
288 Its advantage is that you have less risk of clobbering more than
289 you want to with a typeglob assignment.  (It still conflates file
290 and directory handles, though.)  However, if you assign the incoming
291 value to a scalar instead of a typeglob as we do in the examples
292 below, there's no risk of that happening.
293
294     splutter(*STDOUT);          # pass the whole glob
295     splutter(*STDOUT{IO});      # pass both file and dir handles
296
297     sub splutter {
298         my $fh = shift;
299         print $fh "her um well a hmmm\n";
300     }
301
302     $rec = get_rec(*STDIN);     # pass the whole glob
303     $rec = get_rec(*STDIN{IO}); # pass both file and dir handles
304
305     sub get_rec {
306         my $fh = shift;
307         return scalar <$fh>;
308     }
309
310 =back
311
312 =head2 Using References
313 X<reference, use> X<dereferencing> X<dereference>
314
315 That's it for creating references.  By now you're probably dying to
316 know how to use references to get back to your long-lost data.  There
317 are several basic methods.
318
319 =over 4
320
321 =item 1.
322
323 Anywhere you'd put an identifier (or chain of identifiers) as part
324 of a variable or subroutine name, you can replace the identifier with
325 a simple scalar variable containing a reference of the correct type:
326
327     $bar = $$scalarref;
328     push(@$arrayref, $filename);
329     $$arrayref[0] = "January";
330     $$hashref{"KEY"} = "VALUE";
331     &$coderef(1,2,3);
332     print $globref "output\n";
333
334 It's important to understand that we are specifically I<not> dereferencing
335 C<$arrayref[0]> or C<$hashref{"KEY"}> there.  The dereference of the
336 scalar variable happens I<before> it does any key lookups.  Anything more
337 complicated than a simple scalar variable must use methods 2 or 3 below.
338 However, a "simple scalar" includes an identifier that itself uses method
339 1 recursively.  Therefore, the following prints "howdy".
340
341     $refrefref = \\\"howdy";
342     print $$$$refrefref;
343
344 =item 2.
345
346 Anywhere you'd put an identifier (or chain of identifiers) as part of a
347 variable or subroutine name, you can replace the identifier with a
348 BLOCK returning a reference of the correct type.  In other words, the
349 previous examples could be written like this:
350
351     $bar = ${$scalarref};
352     push(@{$arrayref}, $filename);
353     ${$arrayref}[0] = "January";
354     ${$hashref}{"KEY"} = "VALUE";
355     &{$coderef}(1,2,3);
356     $globref->print("output\n");  # iff IO::Handle is loaded
357
358 Admittedly, it's a little silly to use the curlies in this case, but
359 the BLOCK can contain any arbitrary expression, in particular,
360 subscripted expressions:
361
362     &{ $dispatch{$index} }(1,2,3);      # call correct routine
363
364 Because of being able to omit the curlies for the simple case of C<$$x>,
365 people often make the mistake of viewing the dereferencing symbols as
366 proper operators, and wonder about their precedence.  If they were,
367 though, you could use parentheses instead of braces.  That's not the case.
368 Consider the difference below; case 0 is a short-hand version of case 1,
369 I<not> case 2:
370
371     $$hashref{"KEY"}   = "VALUE";       # CASE 0
372     ${$hashref}{"KEY"} = "VALUE";       # CASE 1
373     ${$hashref{"KEY"}} = "VALUE";       # CASE 2
374     ${$hashref->{"KEY"}} = "VALUE";     # CASE 3
375
376 Case 2 is also deceptive in that you're accessing a variable
377 called %hashref, not dereferencing through $hashref to the hash
378 it's presumably referencing.  That would be case 3.
379
380 =item 3.
381
382 Subroutine calls and lookups of individual array elements arise often
383 enough that it gets cumbersome to use method 2.  As a form of
384 syntactic sugar, the examples for method 2 may be written:
385
386     $arrayref->[0] = "January";   # Array element
387     $hashref->{"KEY"} = "VALUE";  # Hash element
388     $coderef->(1,2,3);            # Subroutine call
389
390 The left side of the arrow can be any expression returning a reference,
391 including a previous dereference.  Note that C<$array[$x]> is I<not> the
392 same thing as C<< $array->[$x] >> here:
393
394     $array[$x]->{"foo"}->[0] = "January";
395
396 This is one of the cases we mentioned earlier in which references could
397 spring into existence when in an lvalue context.  Before this
398 statement, C<$array[$x]> may have been undefined.  If so, it's
399 automatically defined with a hash reference so that we can look up
400 C<{"foo"}> in it.  Likewise C<< $array[$x]->{"foo"} >> will automatically get
401 defined with an array reference so that we can look up C<[0]> in it.
402 This process is called I<autovivification>.
403
404 One more thing here.  The arrow is optional I<between> brackets
405 subscripts, so you can shrink the above down to
406
407     $array[$x]{"foo"}[0] = "January";
408
409 Which, in the degenerate case of using only ordinary arrays, gives you
410 multidimensional arrays just like C's:
411
412     $score[$x][$y][$z] += 42;
413
414 Well, okay, not entirely like C's arrays, actually.  C doesn't know how
415 to grow its arrays on demand.  Perl does.
416
417 =item 4.
418
419 If a reference happens to be a reference to an object, then there are
420 probably methods to access the things referred to, and you should probably
421 stick to those methods unless you're in the class package that defines the
422 object's methods.  In other words, be nice, and don't violate the object's
423 encapsulation without a very good reason.  Perl does not enforce
424 encapsulation.  We are not totalitarians here.  We do expect some basic
425 civility though.
426
427 =back
428
429 Using a string or number as a reference produces a symbolic reference,
430 as explained above.  Using a reference as a number produces an
431 integer representing its storage location in memory.  The only
432 useful thing to be done with this is to compare two references
433 numerically to see whether they refer to the same location.
434 X<reference, numeric context>
435
436     if ($ref1 == $ref2) {  # cheap numeric compare of references
437         print "refs 1 and 2 refer to the same thing\n";
438     }
439
440 Using a reference as a string produces both its referent's type,
441 including any package blessing as described in L<perlobj>, as well
442 as the numeric address expressed in hex.  The ref() operator returns
443 just the type of thing the reference is pointing to, without the
444 address.  See L<perlfunc/ref> for details and examples of its use.
445 X<reference, string context>
446
447 The bless() operator may be used to associate the object a reference
448 points to with a package functioning as an object class.  See L<perlobj>.
449
450 A typeglob may be dereferenced the same way a reference can, because
451 the dereference syntax always indicates the type of reference desired.
452 So C<${*foo}> and C<${\$foo}> both indicate the same scalar variable.
453
454 Here's a trick for interpolating a subroutine call into a string:
455
456     print "My sub returned @{[mysub(1,2,3)]} that time.\n";
457
458 The way it works is that when the C<@{...}> is seen in the double-quoted
459 string, it's evaluated as a block.  The block creates a reference to an
460 anonymous array containing the results of the call to C<mysub(1,2,3)>.  So
461 the whole block returns a reference to an array, which is then
462 dereferenced by C<@{...}> and stuck into the double-quoted string. This
463 chicanery is also useful for arbitrary expressions:
464
465     print "That yields @{[$n + 5]} widgets\n";
466
467 Similarly, an expression that returns a reference to a scalar can be
468 dereferenced via C<${...}>. Thus, the above expression may be written
469 as:
470
471     print "That yields ${\($n + 5)} widgets\n";
472
473 =head2 Circular References
474 X<circular reference> X<reference, circular>
475
476 It is possible to create a "circular reference" in Perl, which can lead
477 to memory leaks. A circular reference occurs when two references
478 contain a reference to each other, like this:
479
480     my $foo = {};
481     my $bar = { foo => $foo };
482     $foo->{bar} = $bar;
483
484 You can also create a circular reference with a single variable:
485
486     my $foo;
487     $foo = \$foo;
488
489 In this case, the reference count for the variables will never reach 0,
490 and the references will never be garbage-collected. This can lead to
491 memory leaks.
492
493 Because objects in Perl are implemented as references, it's possible to
494 have circular references with objects as well. Imagine a TreeNode class
495 where each node references its parent and child nodes. Any node with a
496 parent will be part of a circular reference.
497
498 You can break circular references by creating a "weak reference". A
499 weak reference does not increment the reference count for a variable,
500 which means that the object can go out of scope and be destroyed. You
501 can weaken a reference with the C<weaken> function exported by the
502 L<Scalar::Util> module.
503
504 Here's how we can make the first example safer:
505
506     use Scalar::Util 'weaken';
507
508     my $foo = {};
509     my $bar = { foo => $foo };
510     $foo->{bar} = $bar;
511
512     weaken $foo->{bar};
513
514 The reference from C<$foo> to C<$bar> has been weakened. When the
515 C<$bar> variable goes out of scope, it will be garbage-collected. The
516 next time you look at the value of the C<< $foo->{bar} >> key, it will
517 be C<undef>.
518
519 This action at a distance can be confusing, so you should be careful
520 with your use of weaken. You should weaken the reference in the
521 variable that will go out of scope I<first>. That way, the longer-lived
522 variable will contain the expected reference until it goes out of
523 scope.
524
525 =head2 Symbolic references
526 X<reference, symbolic> X<reference, soft>
527 X<symbolic reference> X<soft reference>
528
529 We said that references spring into existence as necessary if they are
530 undefined, but we didn't say what happens if a value used as a
531 reference is already defined, but I<isn't> a hard reference.  If you
532 use it as a reference, it'll be treated as a symbolic
533 reference.  That is, the value of the scalar is taken to be the I<name>
534 of a variable, rather than a direct link to a (possibly) anonymous
535 value.
536
537 People frequently expect it to work like this.  So it does.
538
539     $name = "foo";
540     $$name = 1;                 # Sets $foo
541     ${$name} = 2;               # Sets $foo
542     ${$name x 2} = 3;           # Sets $foofoo
543     $name->[0] = 4;             # Sets $foo[0]
544     @$name = ();                # Clears @foo
545     &$name();                   # Calls &foo()
546     $pack = "THAT";
547     ${"${pack}::$name"} = 5;    # Sets $THAT::foo without eval
548
549 This is powerful, and slightly dangerous, in that it's possible
550 to intend (with the utmost sincerity) to use a hard reference, and
551 accidentally use a symbolic reference instead.  To protect against
552 that, you can say
553
554     use strict 'refs';
555
556 and then only hard references will be allowed for the rest of the enclosing
557 block.  An inner block may countermand that with
558
559     no strict 'refs';
560
561 Only package variables (globals, even if localized) are visible to
562 symbolic references.  Lexical variables (declared with my()) aren't in
563 a symbol table, and thus are invisible to this mechanism.  For example:
564
565     local $value = 10;
566     $ref = "value";
567     {
568         my $value = 20;
569         print $$ref;
570     }
571
572 This will still print 10, not 20.  Remember that local() affects package
573 variables, which are all "global" to the package.
574
575 =head2 Not-so-symbolic references
576
577 Brackets around a symbolic reference can simply
578 serve to isolate an identifier or variable name from the rest of an
579 expression, just as they always have within a string.  For example,
580
581     $push = "pop on ";
582     print "${push}over";
583
584 has always meant to print "pop on over", even though push is
585 a reserved word.  This is generalized to work the same
586 without the enclosing double quotes, so that
587
588     print ${push} . "over";
589
590 and even
591
592     print ${ push } . "over";
593
594 will have the same effect.  This
595 construct is I<not> considered to be a symbolic reference when you're
596 using strict refs:
597
598     use strict 'refs';
599     ${ bareword };      # Okay, means $bareword.
600     ${ "bareword" };    # Error, symbolic reference.
601
602 Similarly, because of all the subscripting that is done using single words,
603 the same rule applies to any bareword that is used for subscripting a hash.
604 So now, instead of writing
605
606     $hash{ "aaa" }{ "bbb" }{ "ccc" }
607
608 you can write just
609
610     $hash{ aaa }{ bbb }{ ccc }
611
612 and not worry about whether the subscripts are reserved words.  In the
613 rare event that you do wish to do something like
614
615     $hash{ shift }
616
617 you can force interpretation as a reserved word by adding anything that
618 makes it more than a bareword:
619
620     $hash{ shift() }
621     $hash{ +shift }
622     $hash{ shift @_ }
623
624 The C<use warnings> pragma or the B<-w> switch will warn you if it
625 interprets a reserved word as a string.
626 But it will no longer warn you about using lowercase words, because the
627 string is effectively quoted.
628
629 =head2 Pseudo-hashes: Using an array as a hash
630 X<pseudo-hash> X<pseudo hash> X<pseudohash>
631
632 Pseudo-hashes have been removed from Perl.  The 'fields' pragma
633 remains available.
634
635 =head2 Function Templates
636 X<scope, lexical> X<closure> X<lexical> X<lexical scope>
637 X<subroutine, nested> X<sub, nested> X<subroutine, local> X<sub, local>
638
639 As explained above, an anonymous function with access to the lexical
640 variables visible when that function was compiled, creates a closure.  It
641 retains access to those variables even though it doesn't get run until
642 later, such as in a signal handler or a Tk callback.
643
644 Using a closure as a function template allows us to generate many functions
645 that act similarly.  Suppose you wanted functions named after the colors
646 that generated HTML font changes for the various colors:
647
648     print "Be ", red("careful"), "with that ", green("light");
649
650 The red() and green() functions would be similar.  To create these,
651 we'll assign a closure to a typeglob of the name of the function we're
652 trying to build.
653
654     @colors = qw(red blue green yellow orange purple violet);
655     for my $name (@colors) {
656         no strict 'refs';       # allow symbol table manipulation
657         *$name = *{uc $name} = sub { "<FONT COLOR='$name'>@_</FONT>" };
658     }
659
660 Now all those different functions appear to exist independently.  You can
661 call red(), RED(), blue(), BLUE(), green(), etc.  This technique saves on
662 both compile time and memory use, and is less error-prone as well, since
663 syntax checks happen at compile time.  It's critical that any variables in
664 the anonymous subroutine be lexicals in order to create a proper closure.
665 That's the reasons for the C<my> on the loop iteration variable.
666
667 This is one of the only places where giving a prototype to a closure makes
668 much sense.  If you wanted to impose scalar context on the arguments of
669 these functions (probably not a wise idea for this particular example),
670 you could have written it this way instead:
671
672     *$name = sub ($) { "<FONT COLOR='$name'>$_[0]</FONT>" };
673
674 However, since prototype checking happens at compile time, the assignment
675 above happens too late to be of much use.  You could address this by
676 putting the whole loop of assignments within a BEGIN block, forcing it
677 to occur during compilation.
678
679 Access to lexicals that change over time--like those in the C<for> loop
680 above, basically aliases to elements from the surrounding lexical scopes--
681 only works with anonymous subs, not with named subroutines. Generally
682 said, named subroutines do not nest properly and should only be declared
683 in the main package scope.
684
685 This is because named subroutines are created at compile time so their
686 lexical variables get assigned to the parent lexicals from the first
687 execution of the parent block. If a parent scope is entered a second
688 time, its lexicals are created again, while the nested subs still
689 reference the old ones.
690
691 Anonymous subroutines get to capture each time you execute the C<sub>
692 operator, as they are created on the fly. If you are accustomed to using
693 nested subroutines in other programming languages with their own private
694 variables, you'll have to work at it a bit in Perl.  The intuitive coding
695 of this type of thing incurs mysterious warnings about "will not stay
696 shared" due to the reasons explained above.
697 For example, this won't work:
698
699     sub outer {
700         my $x = $_[0] + 35;
701         sub inner { return $x * 19 }   # WRONG
702         return $x + inner();
703     }
704
705 A work-around is the following:
706
707     sub outer {
708         my $x = $_[0] + 35;
709         local *inner = sub { return $x * 19 };
710         return $x + inner();
711     }
712
713 Now inner() can only be called from within outer(), because of the
714 temporary assignments of the anonymous subroutine. But when it does,
715 it has normal access to the lexical variable $x from the scope of
716 outer() at the time outer is invoked.
717
718 This has the interesting effect of creating a function local to another
719 function, something not normally supported in Perl.
720
721 =head1 WARNING: Don't use references as hash keys
722 X<reference, string context> X<reference, use as hash key>
723
724 You may not (usefully) use a reference as the key to a hash.  It will be
725 converted into a string:
726
727     $x{ \$a } = $a;
728
729 If you try to dereference the key, it won't do a hard dereference, and
730 you won't accomplish what you're attempting.  You might want to do something
731 more like
732
733     $r = \@a;
734     $x{ $r } = $r;
735
736 And then at least you can use the values(), which will be
737 real refs, instead of the keys(), which won't.
738
739 The standard Tie::RefHash module provides a convenient workaround to this.
740
741 =head2 Postfix Dereference Syntax
742
743 Beginning in v5.20.0, a postfix syntax for using references is
744 available.  It behaves as described in L</Using References>, but instead
745 of a prefixed sigil, a postfixed sigil-and-star is used.
746
747 For example:
748
749     $r = \@a;
750     @b = $r->@*; # equivalent to @$r or @{ $r }
751
752     $r = [ 1, [ 2, 3 ], 4 ];
753     $r->[1]->@*;  # equivalent to @{ $r->[1] }
754
755 In Perl 5.20 and 5.22, this syntax must be enabled with C<use feature
756 'postderef'>. As of Perl 5.24, no feature declarations are required to make
757 it available.
758
759 Postfix dereference should work in all circumstances where block
760 (circumfix) dereference worked, and should be entirely equivalent.  This
761 syntax allows dereferencing to be written and read entirely
762 left-to-right.  The following equivalencies are defined:
763
764   $sref->$*;  # same as  ${ $sref }
765   $aref->@*;  # same as  @{ $aref }
766   $aref->$#*; # same as $#{ $aref }
767   $href->%*;  # same as  %{ $href }
768   $cref->&*;  # same as  &{ $cref }
769   $gref->**;  # same as  *{ $gref }
770
771 Note especially that C<< $cref->&* >> is I<not> equivalent to C<<
772 $cref->() >>, and can serve different purposes.
773
774 Glob elements can be extracted through the postfix dereferencing feature:
775
776   $gref->*{SCALAR}; # same as *{ $gref }{SCALAR}
777
778 Postfix array and scalar dereferencing I<can> be used in interpolating
779 strings (double quotes or the C<qq> operator), but only if the
780 C<postderef_qq> feature is enabled.
781
782 =head2 Postfix Reference Slicing
783
784 Value slices of arrays and hashes may also be taken with postfix
785 dereferencing notation, with the following equivalencies:
786
787   $aref->@[ ... ];  # same as @$aref[ ... ]
788   $href->@{ ... };  # same as @$href{ ... }
789
790 Postfix key/value pair slicing, added in 5.20.0 and documented in
791 L<the KeyE<sol>Value Hash Slices section of perldata|perldata/"Key/Value Hash
792 Slices">, also behaves as expected:
793
794   $aref->%[ ... ];  # same as %$aref[ ... ]
795   $href->%{ ... };  # same as %$href{ ... }
796
797 As with postfix array, postfix value slice dereferencing I<can> be used
798 in interpolating strings (double quotes or the C<qq> operator), but only
799 if the C<postderef_qq> L<feature> is enabled.
800
801 =head2 Assigning to References
802
803 Beginning in v5.22.0, the referencing operator can be assigned to.  It
804 performs an aliasing operation, so that the variable name referenced on the
805 left-hand side becomes an alias for the thing referenced on the right-hand
806 side:
807
808     \$a = \$b; # $a and $b now point to the same scalar
809     \&foo = \&bar; # foo() now means bar()
810
811 This syntax must be enabled with C<use feature 'refaliasing'>.  It is
812 experimental, and will warn by default unless C<no warnings
813 'experimental::refaliasing'> is in effect.
814
815 These forms may be assigned to, and cause the right-hand side to be
816 evaluated in scalar context:
817
818     \$scalar
819     \@array
820     \%hash
821     \&sub
822     \my $scalar
823     \my @array
824     \my %hash
825     \state $scalar # or @array, etc.
826     \our $scalar   # etc.
827     \local $scalar # etc.
828     \local our $scalar # etc.
829     \$some_array[$index]
830     \$some_hash{$key}
831     \local $some_array[$index]
832     \local $some_hash{$key}
833     condition ? \$this : \$that[0] # etc.
834
835 Slicing operations and parentheses cause
836 the right-hand side to be evaluated in
837 list context:
838
839     \@array[5..7]
840     (\@array[5..7])
841     \(@array[5..7])
842     \@hash{'foo','bar'}
843     (\@hash{'foo','bar'})
844     \(@hash{'foo','bar'})
845     (\$scalar)
846     \($scalar)
847     \(my $scalar)
848     \my($scalar)
849     (\@array)
850     (\%hash)
851     (\&sub)
852     \(&sub)
853     \($foo, @bar, %baz)
854     (\$foo, \@bar, \%baz)
855
856 Each element on the right-hand side must be a reference to a datum of the
857 right type.  Parentheses immediately surrounding an array (and possibly
858 also C<my>/C<state>/C<our>/C<local>) will make each element of the array an
859 alias to the corresponding scalar referenced on the right-hand side:
860
861     \(@a) = \(@b); # @a and @b now have the same elements
862     \my(@a) = \(@b); # likewise
863     \(my @a) = \(@b); # likewise
864     push @a, 3; # but now @a has an extra element that @b lacks
865     \(@a) = (\$a, \$b, \$c); # @a now contains $a, $b, and $c
866
867 Combining that form with C<local> and putting parentheses immediately
868 around a hash are forbidden (because it is not clear what they should do):
869
870     \local(@array) = foo(); # WRONG
871     \(%hash)       = bar(); # WRONG
872
873 Assignment to references and non-references may be combined in lists and
874 conditional ternary expressions, as long as the values on the right-hand
875 side are the right type for each element on the left, though this may make
876 for obfuscated code:
877
878     (my $tom, \my $dick, \my @harry) = (\1, \2, [1..3]);
879     # $tom is now \1
880     # $dick is now 2 (read-only)
881     # @harry is (1,2,3)
882
883     my $type = ref $thingy;
884     ($type ? $type eq 'ARRAY' ? \@foo : \$bar : $baz) = $thingy;
885
886 The C<foreach> loop can also take a reference constructor for its loop
887 variable, though the syntax is limited to one of the following, with an
888 optional C<my>, C<state>, or C<our> after the backslash:
889
890     \$s
891     \@a
892     \%h
893     \&c
894
895 No parentheses are permitted.  This feature is particularly useful for
896 arrays-of-arrays, or arrays-of-hashes:
897
898     foreach \my @a (@array_of_arrays) {
899         frobnicate($a[0], $a[-1]);
900     }
901
902     foreach \my %h (@array_of_hashes) {
903         $h{gelastic}++ if $h{type} eq 'funny';
904     }
905
906 B<CAVEAT:> Aliasing does not work correctly with closures.  If you try to
907 alias lexical variables from an inner subroutine or C<eval>, the aliasing
908 will only be visible within that inner sub, and will not affect the outer
909 subroutine where the variables are declared.  This bizarre behavior is
910 subject to change.
911
912 =head1 Declaring a Reference to a Variable
913
914 Beginning in v5.26.0, the referencing operator can come after C<my>,
915 C<state>, C<our>, or C<local>.  This syntax must be enabled with C<use
916 feature 'declared_refs'>.  It is experimental, and will warn by default
917 unless C<no warnings 'experimental::refaliasing'> is in effect.
918
919 This feature makes these:
920
921     my \$x;
922     our \$y;
923
924 equivalent to:
925
926     \my $x;
927     \our $x;
928
929 It is intended mainly for use in assignments to references (see
930 L</Assigning to References>, above).  It also allows the backslash to be
931 used on just some items in a list of declared variables:
932
933     my ($foo, \@bar, \%baz); # equivalent to:  my $foo, \my(@bar, %baz);
934
935 =head1 SEE ALSO
936
937 Besides the obvious documents, source code can be instructive.
938 Some pathological examples of the use of references can be found
939 in the F<t/op/ref.t> regression test in the Perl source directory.
940
941 See also L<perldsc> and L<perllol> for how to use references to create
942 complex data structures, and L<perlootut> and L<perlobj>
943 for how to use them to create objects.