Provide defined value for $TODO only where test is still failing.
[perl.git] / pod / perlop.pod
1 =head1 NAME
2 X<operator>
3
4 perlop - Perl operators and precedence
5
6 =head1 DESCRIPTION
7
8 In Perl, the operator determines what operation is performed,
9 independent of the type of the operands.  For example S<C<$x + $y>>
10 is always a numeric addition, and if C<$x> or C<$y> do not contain
11 numbers, an attempt is made to convert them to numbers first.
12
13 This is in contrast to many other dynamic languages, where the
14 operation is determined by the type of the first argument.  It also
15 means that Perl has two versions of some operators, one for numeric
16 and one for string comparison.  For example S<C<$x == $y>> compares
17 two numbers for equality, and S<C<$x eq $y>> compares two strings.
18
19 There are a few exceptions though: C<x> can be either string
20 repetition or list repetition, depending on the type of the left
21 operand, and C<&>, C<|>, C<^> and C<~> can be either string or numeric bit
22 operations.
23
24 =head2 Operator Precedence and Associativity
25 X<operator, precedence> X<precedence> X<associativity>
26
27 Operator precedence and associativity work in Perl more or less like
28 they do in mathematics.
29
30 I<Operator precedence> means some operators group more tightly than others.
31 For example, in C<2 + 4 * 5>, the multiplication has higher precedence, so C<4
32 * 5> is grouped together as the right-hand operand of the addition, rather
33 than C<2 + 4> being grouped together as the left-hand operand of the
34 multiplication. It is as if the expression were written C<2 + (4 * 5)>, not
35 C<(2 + 4) * 5>. So the expression yields C<2 + 20 == 22>, rather than
36 C<6 * 5 == 30>.
37
38 I<Operator associativity> defines what happens if a sequence of the same
39 operators is used one after another: whether they will be grouped at the left
40 or the right. For example, in C<9 - 3 - 2>, subtraction is left associative,
41 so C<9 - 3> is grouped together as the left-hand operand of the second
42 subtraction, rather than C<3 - 2> being grouped together as the right-hand
43 operand of the first subtraction. It is as if the expression were written
44 C<(9 - 3) - 2>, not C<9 - (3 - 2)>. So the expression yields C<6 - 2 == 4>,
45 rather than C<9 - 1 == 8>.
46
47 For simple operators that evaluate all their operands and then combine the
48 values in some way, precedence and associativity (and parentheses) imply some
49 ordering requirements on those combining operations. For example, in C<2 + 4 *
50 5>, the grouping implied by precedence means that the multiplication of 4 and
51 5 must be performed before the addition of 2 and 20, simply because the result
52 of that multiplication is required as one of the operands of the addition. But
53 the order of operations is not fully determined by this: in C<2 * 2 + 4 * 5>
54 both multiplications must be performed before the addition, but the grouping
55 does not say anything about the order in which the two multiplications are
56 performed. In fact Perl has a general rule that the operands of an operator
57 are evaluated in left-to-right order. A few operators such as C<&&=> have
58 special evaluation rules that can result in an operand not being evaluated at
59 all; in general, the top-level operator in an expression has control of
60 operand evaluation.
61
62 Perl operators have the following associativity and precedence,
63 listed from highest precedence to lowest.  Operators borrowed from
64 C keep the same precedence relationship with each other, even where
65 C's precedence is slightly screwy.  (This makes learning Perl easier
66 for C folks.)  With very few exceptions, these all operate on scalar
67 values only, not array values.
68
69     left        terms and list operators (leftward)
70     left        ->
71     nonassoc    ++ --
72     right       **
73     right       ! ~ \ and unary + and -
74     left        =~ !~
75     left        * / % x
76     left        + - .
77     left        << >>
78     nonassoc    named unary operators
79     nonassoc    < > <= >= lt gt le ge
80     nonassoc    == != <=> eq ne cmp ~~
81     left        &
82     left        | ^
83     left        &&
84     left        || //
85     nonassoc    ..  ...
86     right       ?:
87     right       = += -= *= etc. goto last next redo dump
88     left        , =>
89     nonassoc    list operators (rightward)
90     right       not
91     left        and
92     left        or xor
93
94 In the following sections, these operators are covered in detail, in the
95 same order in which they appear in the table above.
96
97 Many operators can be overloaded for objects.  See L<overload>.
98
99 =head2 Terms and List Operators (Leftward)
100 X<list operator> X<operator, list> X<term>
101
102 A TERM has the highest precedence in Perl.  They include variables,
103 quote and quote-like operators, any expression in parentheses,
104 and any function whose arguments are parenthesized.  Actually, there
105 aren't really functions in this sense, just list operators and unary
106 operators behaving as functions because you put parentheses around
107 the arguments.  These are all documented in L<perlfunc>.
108
109 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
110 is followed by a left parenthesis as the next token, the operator and
111 arguments within parentheses are taken to be of highest precedence,
112 just like a normal function call.
113
114 In the absence of parentheses, the precedence of list operators such as
115 C<print>, C<sort>, or C<chmod> is either very high or very low depending on
116 whether you are looking at the left side or the right side of the operator.
117 For example, in
118
119     @ary = (1, 3, sort 4, 2);
120     print @ary;         # prints 1324
121
122 the commas on the right of the C<sort> are evaluated before the C<sort>,
123 but the commas on the left are evaluated after.  In other words,
124 list operators tend to gobble up all arguments that follow, and
125 then act like a simple TERM with regard to the preceding expression.
126 Be careful with parentheses:
127
128     # These evaluate exit before doing the print:
129     print($foo, exit);  # Obviously not what you want.
130     print $foo, exit;   # Nor is this.
131
132     # These do the print before evaluating exit:
133     (print $foo), exit; # This is what you want.
134     print($foo), exit;  # Or this.
135     print ($foo), exit; # Or even this.
136
137 Also note that
138
139     print ($foo & 255) + 1, "\n";
140
141 probably doesn't do what you expect at first glance.  The parentheses
142 enclose the argument list for C<print> which is evaluated (printing
143 the result of S<C<$foo & 255>>).  Then one is added to the return value
144 of C<print> (usually 1).  The result is something like this:
145
146     1 + 1, "\n";    # Obviously not what you meant.
147
148 To do what you meant properly, you must write:
149
150     print(($foo & 255) + 1, "\n");
151
152 See L</Named Unary Operators> for more discussion of this.
153
154 Also parsed as terms are the S<C<do {}>> and S<C<eval {}>> constructs, as
155 well as subroutine and method calls, and the anonymous
156 constructors C<[]> and C<{}>.
157
158 See also L</Quote and Quote-like Operators> toward the end of this section,
159 as well as L</"I/O Operators">.
160
161 =head2 The Arrow Operator
162 X<arrow> X<dereference> X<< -> >>
163
164 "C<< -> >>" is an infix dereference operator, just as it is in C
165 and C++.  If the right side is either a C<[...]>, C<{...}>, or a
166 C<(...)> subscript, then the left side must be either a hard or
167 symbolic reference to an array, a hash, or a subroutine respectively.
168 (Or technically speaking, a location capable of holding a hard
169 reference, if it's an array or hash reference being used for
170 assignment.)  See L<perlreftut> and L<perlref>.
171
172 Otherwise, the right side is a method name or a simple scalar
173 variable containing either the method name or a subroutine reference,
174 and the left side must be either an object (a blessed reference)
175 or a class name (that is, a package name).  See L<perlobj>.
176
177 The dereferencing cases (as opposed to method-calling cases) are
178 somewhat extended by the C<postderef> feature.  For the
179 details of that feature, consult L<perlref/Postfix Dereference Syntax>.
180
181 =head2 Auto-increment and Auto-decrement
182 X<increment> X<auto-increment> X<++> X<decrement> X<auto-decrement> X<-->
183
184 C<"++"> and C<"--"> work as in C.  That is, if placed before a variable,
185 they increment or decrement the variable by one before returning the
186 value, and if placed after, increment or decrement after returning the
187 value.
188
189     $i = 0;  $j = 0;
190     print $i++;  # prints 0
191     print ++$j;  # prints 1
192
193 Note that just as in C, Perl doesn't define B<when> the variable is
194 incremented or decremented.  You just know it will be done sometime
195 before or after the value is returned.  This also means that modifying
196 a variable twice in the same statement will lead to undefined behavior.
197 Avoid statements like:
198
199     $i = $i ++;
200     print ++ $i + $i ++;
201
202 Perl will not guarantee what the result of the above statements is.
203
204 The auto-increment operator has a little extra builtin magic to it.  If
205 you increment a variable that is numeric, or that has ever been used in
206 a numeric context, you get a normal increment.  If, however, the
207 variable has been used in only string contexts since it was set, and
208 has a value that is not the empty string and matches the pattern
209 C</^[a-zA-Z]*[0-9]*\z/>, the increment is done as a string, preserving each
210 character within its range, with carry:
211
212     print ++($foo = "99");      # prints "100"
213     print ++($foo = "a0");      # prints "a1"
214     print ++($foo = "Az");      # prints "Ba"
215     print ++($foo = "zz");      # prints "aaa"
216
217 C<undef> is always treated as numeric, and in particular is changed
218 to C<0> before incrementing (so that a post-increment of an undef value
219 will return C<0> rather than C<undef>).
220
221 The auto-decrement operator is not magical.
222
223 =head2 Exponentiation
224 X<**> X<exponentiation> X<power>
225
226 Binary C<"**"> is the exponentiation operator.  It binds even more
227 tightly than unary minus, so C<-2**4> is C<-(2**4)>, not C<(-2)**4>.
228 (This is
229 implemented using C's C<pow(3)> function, which actually works on doubles
230 internally.)
231
232 Note that certain exponentiation expressions are ill-defined:
233 these include C<0**0>, C<1**Inf>, and C<Inf**0>.  Do not expect
234 any particular results from these special cases, the results
235 are platform-dependent.
236
237 =head2 Symbolic Unary Operators
238 X<unary operator> X<operator, unary>
239
240 Unary C<"!"> performs logical negation, that is, "not".  See also
241 L<C<not>|/Logical Not> for a lower precedence version of this.
242 X<!>
243
244 Unary C<"-"> performs arithmetic negation if the operand is numeric,
245 including any string that looks like a number.  If the operand is
246 an identifier, a string consisting of a minus sign concatenated
247 with the identifier is returned.  Otherwise, if the string starts
248 with a plus or minus, a string starting with the opposite sign is
249 returned.  One effect of these rules is that C<-bareword> is equivalent
250 to the string C<"-bareword">.  If, however, the string begins with a
251 non-alphabetic character (excluding C<"+"> or C<"-">), Perl will attempt
252 to convert
253 the string to a numeric, and the arithmetic negation is performed.  If the
254 string cannot be cleanly converted to a numeric, Perl will give the warning
255 B<Argument "the string" isn't numeric in negation (-) at ...>.
256 X<-> X<negation, arithmetic>
257
258 Unary C<"~"> performs bitwise negation, that is, 1's complement.  For
259 example, S<C<0666 & ~027>> is 0640.  (See also L</Integer Arithmetic> and
260 L</Bitwise String Operators>.)  Note that the width of the result is
261 platform-dependent: C<~0> is 32 bits wide on a 32-bit platform, but 64
262 bits wide on a 64-bit platform, so if you are expecting a certain bit
263 width, remember to use the C<"&"> operator to mask off the excess bits.
264 X<~> X<negation, binary>
265
266 Starting in Perl 5.28, it is a fatal error to try to complement a string
267 containing a character with an ordinal value above 255.
268
269 If the "bitwise" feature is enabled via S<C<use
270 feature 'bitwise'>> or C<use v5.28>, then unary
271 C<"~"> always treats its argument as a number, and an
272 alternate form of the operator, C<"~.">, always treats its argument as a
273 string.  So C<~0> and C<~"0"> will both give 2**32-1 on 32-bit platforms,
274 whereas C<~.0> and C<~."0"> will both yield C<"\xff">.  Until Perl 5.28,
275 this feature produced a warning in the C<"experimental::bitwise"> category.
276
277 Unary C<"+"> has no effect whatsoever, even on strings.  It is useful
278 syntactically for separating a function name from a parenthesized expression
279 that would otherwise be interpreted as the complete list of function
280 arguments.  (See examples above under L</Terms and List Operators (Leftward)>.)
281 X<+>
282
283 Unary C<"\"> creates references.  If its operand is a single sigilled
284 thing, it creates a reference to that object.  If its operand is a
285 parenthesised list, then it creates references to the things mentioned
286 in the list.  Otherwise it puts its operand in list context, and creates
287 a list of references to the scalars in the list provided by the operand.
288 See L<perlreftut>
289 and L<perlref>.  Do not confuse this behavior with the behavior of
290 backslash within a string, although both forms do convey the notion
291 of protecting the next thing from interpolation.
292 X<\> X<reference> X<backslash>
293
294 =head2 Binding Operators
295 X<binding> X<operator, binding> X<=~> X<!~>
296
297 Binary C<"=~"> binds a scalar expression to a pattern match.  Certain operations
298 search or modify the string C<$_> by default.  This operator makes that kind
299 of operation work on some other string.  The right argument is a search
300 pattern, substitution, or transliteration.  The left argument is what is
301 supposed to be searched, substituted, or transliterated instead of the default
302 C<$_>.  When used in scalar context, the return value generally indicates the
303 success of the operation.  The exceptions are substitution (C<s///>)
304 and transliteration (C<y///>) with the C</r> (non-destructive) option,
305 which cause the B<r>eturn value to be the result of the substitution.
306 Behavior in list context depends on the particular operator.
307 See L</"Regexp Quote-Like Operators"> for details and L<perlretut> for
308 examples using these operators.
309
310 If the right argument is an expression rather than a search pattern,
311 substitution, or transliteration, it is interpreted as a search pattern at run
312 time.  Note that this means that its
313 contents will be interpolated twice, so
314
315     '\\' =~ q'\\';
316
317 is not ok, as the regex engine will end up trying to compile the
318 pattern C<\>, which it will consider a syntax error.
319
320 Binary C<"!~"> is just like C<"=~"> except the return value is negated in
321 the logical sense.
322
323 Binary C<"!~"> with a non-destructive substitution (C<s///r>) or transliteration
324 (C<y///r>) is a syntax error.
325
326 =head2 Multiplicative Operators
327 X<operator, multiplicative>
328
329 Binary C<"*"> multiplies two numbers.
330 X<*>
331
332 Binary C<"/"> divides two numbers.
333 X</> X<slash>
334
335 Binary C<"%"> is the modulo operator, which computes the division
336 remainder of its first argument with respect to its second argument.
337 Given integer
338 operands C<$m> and C<$n>: If C<$n> is positive, then S<C<$m % $n>> is
339 C<$m> minus the largest multiple of C<$n> less than or equal to
340 C<$m>.  If C<$n> is negative, then S<C<$m % $n>> is C<$m> minus the
341 smallest multiple of C<$n> that is not less than C<$m> (that is, the
342 result will be less than or equal to zero).  If the operands
343 C<$m> and C<$n> are floating point values and the absolute value of
344 C<$n> (that is C<abs($n)>) is less than S<C<(UV_MAX + 1)>>, only
345 the integer portion of C<$m> and C<$n> will be used in the operation
346 (Note: here C<UV_MAX> means the maximum of the unsigned integer type).
347 If the absolute value of the right operand (C<abs($n)>) is greater than
348 or equal to S<C<(UV_MAX + 1)>>, C<"%"> computes the floating-point remainder
349 C<$r> in the equation S<C<($r = $m - $i*$n)>> where C<$i> is a certain
350 integer that makes C<$r> have the same sign as the right operand
351 C<$n> (B<not> as the left operand C<$m> like C function C<fmod()>)
352 and the absolute value less than that of C<$n>.
353 Note that when S<C<use integer>> is in scope, C<"%"> gives you direct access
354 to the modulo operator as implemented by your C compiler.  This
355 operator is not as well defined for negative operands, but it will
356 execute faster.
357 X<%> X<remainder> X<modulo> X<mod>
358
359 Binary C<x> is the repetition operator.  In scalar context, or if the
360 left operand is neither enclosed in parentheses nor a C<qw//> list,
361 it performs a string repetition.  In that case it supplies scalar
362 context to the left operand, and returns a string consisting of the
363 left operand string repeated the number of times specified by the right
364 operand.  If the C<x> is in list context, and the left operand is either
365 enclosed in parentheses or a C<qw//> list, it performs a list repetition.
366 In that case it supplies list context to the left operand, and returns
367 a list consisting of the left operand list repeated the number of times
368 specified by the right operand.
369 If the right operand is zero or negative (raising a warning on
370 negative), it returns an empty string
371 or an empty list, depending on the context.
372 X<x>
373
374     print '-' x 80;             # print row of dashes
375
376     print "\t" x ($tab/8), ' ' x ($tab%8);      # tab over
377
378     @ones = (1) x 80;           # a list of 80 1's
379     @ones = (5) x @ones;        # set all elements to 5
380
381
382 =head2 Additive Operators
383 X<operator, additive>
384
385 Binary C<"+"> returns the sum of two numbers.
386 X<+>
387
388 Binary C<"-"> returns the difference of two numbers.
389 X<->
390
391 Binary C<"."> concatenates two strings.
392 X<string, concatenation> X<concatenation>
393 X<cat> X<concat> X<concatenate> X<.>
394
395 =head2 Shift Operators
396 X<shift operator> X<operator, shift> X<<< << >>>
397 X<<< >> >>> X<right shift> X<left shift> X<bitwise shift>
398 X<shl> X<shr> X<shift, right> X<shift, left>
399
400 Binary C<<< "<<" >>> returns the value of its left argument shifted left by the
401 number of bits specified by the right argument.  Arguments should be
402 integers.  (See also L</Integer Arithmetic>.)
403
404 Binary C<<< ">>" >>> returns the value of its left argument shifted right by
405 the number of bits specified by the right argument.  Arguments should
406 be integers.  (See also L</Integer Arithmetic>.)
407
408 If S<C<use integer>> (see L</Integer Arithmetic>) is in force then
409 signed C integers are used (I<arithmetic shift>), otherwise unsigned C
410 integers are used (I<logical shift>), even for negative shiftees.
411 In arithmetic right shift the sign bit is replicated on the left,
412 in logical shift zero bits come in from the left.
413
414 Either way, the implementation isn't going to generate results larger
415 than the size of the integer type Perl was built with (32 bits or 64 bits).
416
417 Shifting by negative number of bits means the reverse shift: left
418 shift becomes right shift, right shift becomes left shift.  This is
419 unlike in C, where negative shift is undefined.
420
421 Shifting by more bits than the size of the integers means most of the
422 time zero (all bits fall off), except that under S<C<use integer>>
423 right overshifting a negative shiftee results in -1.  This is unlike
424 in C, where shifting by too many bits is undefined.  A common C
425 behavior is "shift by modulo wordbits", so that for example
426
427     1 >> 64 == 1 >> (64 % 64) == 1 >> 0 == 1  # Common C behavior.
428
429 but that is completely accidental.
430
431 If you get tired of being subject to your platform's native integers,
432 the S<C<use bigint>> pragma neatly sidesteps the issue altogether:
433
434     print 20 << 20;  # 20971520
435     print 20 << 40;  # 5120 on 32-bit machines,
436                      # 21990232555520 on 64-bit machines
437     use bigint;
438     print 20 << 100; # 25353012004564588029934064107520
439
440 =head2 Named Unary Operators
441 X<operator, named unary>
442
443 The various named unary operators are treated as functions with one
444 argument, with optional parentheses.
445
446 If any list operator (C<print()>, etc.) or any unary operator (C<chdir()>, etc.)
447 is followed by a left parenthesis as the next token, the operator and
448 arguments within parentheses are taken to be of highest precedence,
449 just like a normal function call.  For example,
450 because named unary operators are higher precedence than C<||>:
451
452     chdir $foo    || die;       # (chdir $foo) || die
453     chdir($foo)   || die;       # (chdir $foo) || die
454     chdir ($foo)  || die;       # (chdir $foo) || die
455     chdir +($foo) || die;       # (chdir $foo) || die
456
457 but, because C<"*"> is higher precedence than named operators:
458
459     chdir $foo * 20;    # chdir ($foo * 20)
460     chdir($foo) * 20;   # (chdir $foo) * 20
461     chdir ($foo) * 20;  # (chdir $foo) * 20
462     chdir +($foo) * 20; # chdir ($foo * 20)
463
464     rand 10 * 20;       # rand (10 * 20)
465     rand(10) * 20;      # (rand 10) * 20
466     rand (10) * 20;     # (rand 10) * 20
467     rand +(10) * 20;    # rand (10 * 20)
468
469 Regarding precedence, the filetest operators, like C<-f>, C<-M>, etc. are
470 treated like named unary operators, but they don't follow this functional
471 parenthesis rule.  That means, for example, that C<-f($file).".bak"> is
472 equivalent to S<C<-f "$file.bak">>.
473 X<-X> X<filetest> X<operator, filetest>
474
475 See also L</"Terms and List Operators (Leftward)">.
476
477 =head2 Relational Operators
478 X<relational operator> X<operator, relational>
479
480 Perl operators that return true or false generally return values
481 that can be safely used as numbers.  For example, the relational
482 operators in this section and the equality operators in the next
483 one return C<1> for true and a special version of the defined empty
484 string, C<"">, which counts as a zero but is exempt from warnings
485 about improper numeric conversions, just as S<C<"0 but true">> is.
486
487 Binary C<< "<" >> returns true if the left argument is numerically less than
488 the right argument.
489 X<< < >>
490
491 Binary C<< ">" >> returns true if the left argument is numerically greater
492 than the right argument.
493 X<< > >>
494
495 Binary C<< "<=" >> returns true if the left argument is numerically less than
496 or equal to the right argument.
497 X<< <= >>
498
499 Binary C<< ">=" >> returns true if the left argument is numerically greater
500 than or equal to the right argument.
501 X<< >= >>
502
503 Binary C<"lt"> returns true if the left argument is stringwise less than
504 the right argument.
505 X<< lt >>
506
507 Binary C<"gt"> returns true if the left argument is stringwise greater
508 than the right argument.
509 X<< gt >>
510
511 Binary C<"le"> returns true if the left argument is stringwise less than
512 or equal to the right argument.
513 X<< le >>
514
515 Binary C<"ge"> returns true if the left argument is stringwise greater
516 than or equal to the right argument.
517 X<< ge >>
518
519 =head2 Equality Operators
520 X<equality> X<equal> X<equals> X<operator, equality>
521
522 Binary C<< "==" >> returns true if the left argument is numerically equal to
523 the right argument.
524 X<==>
525
526 Binary C<< "!=" >> returns true if the left argument is numerically not equal
527 to the right argument.
528 X<!=>
529
530 Binary C<< "<=>" >> returns -1, 0, or 1 depending on whether the left
531 argument is numerically less than, equal to, or greater than the right
532 argument.  If your platform supports C<NaN>'s (not-a-numbers) as numeric
533 values, using them with C<< "<=>" >> returns undef.  C<NaN> is not
534 C<< "<" >>, C<< "==" >>, C<< ">" >>, C<< "<=" >> or C<< ">=" >> anything
535 (even C<NaN>), so those 5 return false.  S<C<< NaN != NaN >>> returns
536 true, as does S<C<NaN !=> I<anything else>>.  If your platform doesn't
537 support C<NaN>'s then C<NaN> is just a string with numeric value 0.
538 X<< <=> >>
539 X<spaceship>
540
541     $ perl -le '$x = "NaN"; print "No NaN support here" if $x == $x'
542     $ perl -le '$x = "NaN"; print "NaN support here" if $x != $x'
543
544 (Note that the L<bigint>, L<bigrat>, and L<bignum> pragmas all
545 support C<"NaN">.)
546
547 Binary C<"eq"> returns true if the left argument is stringwise equal to
548 the right argument.
549 X<eq>
550
551 Binary C<"ne"> returns true if the left argument is stringwise not equal
552 to the right argument.
553 X<ne>
554
555 Binary C<"cmp"> returns -1, 0, or 1 depending on whether the left
556 argument is stringwise less than, equal to, or greater than the right
557 argument.
558 X<cmp>
559
560 Binary C<"~~"> does a smartmatch between its arguments.  Smart matching
561 is described in the next section.
562 X<~~>
563
564 C<"lt">, C<"le">, C<"ge">, C<"gt"> and C<"cmp"> use the collation (sort)
565 order specified by the current C<LC_COLLATE> locale if a S<C<use
566 locale>> form that includes collation is in effect.  See L<perllocale>.
567 Do not mix these with Unicode,
568 only use them with legacy 8-bit locale encodings.
569 The standard C<L<Unicode::Collate>> and
570 C<L<Unicode::Collate::Locale>> modules offer much more powerful
571 solutions to collation issues.
572
573 For case-insensitive comparisons, look at the L<perlfunc/fc> case-folding
574 function, available in Perl v5.16 or later:
575
576     if ( fc($x) eq fc($y) ) { ... }
577
578 =head2 Smartmatch Operator
579
580 First available in Perl 5.10.1 (the 5.10.0 version behaved differently),
581 binary C<~~> does a "smartmatch" between its arguments.  This is mostly
582 used implicitly in the C<when> construct described in L<perlsyn>, although
583 not all C<when> clauses call the smartmatch operator.  Unique among all of
584 Perl's operators, the smartmatch operator can recurse.  The smartmatch
585 operator is L<experimental|perlpolicy/experimental> and its behavior is
586 subject to change.
587
588 It is also unique in that all other Perl operators impose a context
589 (usually string or numeric context) on their operands, autoconverting
590 those operands to those imposed contexts.  In contrast, smartmatch
591 I<infers> contexts from the actual types of its operands and uses that
592 type information to select a suitable comparison mechanism.
593
594 The C<~~> operator compares its operands "polymorphically", determining how
595 to compare them according to their actual types (numeric, string, array,
596 hash, etc.)  Like the equality operators with which it shares the same
597 precedence, C<~~> returns 1 for true and C<""> for false.  It is often best
598 read aloud as "in", "inside of", or "is contained in", because the left
599 operand is often looked for I<inside> the right operand.  That makes the
600 order of the operands to the smartmatch operand often opposite that of
601 the regular match operator.  In other words, the "smaller" thing is usually
602 placed in the left operand and the larger one in the right.
603
604 The behavior of a smartmatch depends on what type of things its arguments
605 are, as determined by the following table.  The first row of the table
606 whose types apply determines the smartmatch behavior.  Because what
607 actually happens is mostly determined by the type of the second operand,
608 the table is sorted on the right operand instead of on the left.
609
610  Left      Right      Description and pseudocode
611  ===============================================================
612  Any       undef      check whether Any is undefined
613                 like: !defined Any
614
615  Any       Object     invoke ~~ overloading on Object, or die
616
617  Right operand is an ARRAY:
618
619  Left      Right      Description and pseudocode
620  ===============================================================
621  ARRAY1    ARRAY2     recurse on paired elements of ARRAY1 and ARRAY2[2]
622                 like: (ARRAY1[0] ~~ ARRAY2[0])
623                         && (ARRAY1[1] ~~ ARRAY2[1]) && ...
624  HASH      ARRAY      any ARRAY elements exist as HASH keys
625                 like: grep { exists HASH->{$_} } ARRAY
626  Regexp    ARRAY      any ARRAY elements pattern match Regexp
627                 like: grep { /Regexp/ } ARRAY
628  undef     ARRAY      undef in ARRAY
629                 like: grep { !defined } ARRAY
630  Any       ARRAY      smartmatch each ARRAY element[3]
631                 like: grep { Any ~~ $_ } ARRAY
632
633  Right operand is a HASH:
634
635  Left      Right      Description and pseudocode
636  ===============================================================
637  HASH1     HASH2      all same keys in both HASHes
638                 like: keys HASH1 ==
639                          grep { exists HASH2->{$_} } keys HASH1
640  ARRAY     HASH       any ARRAY elements exist as HASH keys
641                 like: grep { exists HASH->{$_} } ARRAY
642  Regexp    HASH       any HASH keys pattern match Regexp
643                 like: grep { /Regexp/ } keys HASH
644  undef     HASH       always false (undef can't be a key)
645                 like: 0 == 1
646  Any       HASH       HASH key existence
647                 like: exists HASH->{Any}
648
649  Right operand is CODE:
650
651  Left      Right      Description and pseudocode
652  ===============================================================
653  ARRAY     CODE       sub returns true on all ARRAY elements[1]
654                 like: !grep { !CODE->($_) } ARRAY
655  HASH      CODE       sub returns true on all HASH keys[1]
656                 like: !grep { !CODE->($_) } keys HASH
657  Any       CODE       sub passed Any returns true
658                 like: CODE->(Any)
659
660 Right operand is a Regexp:
661
662  Left      Right      Description and pseudocode
663  ===============================================================
664  ARRAY     Regexp     any ARRAY elements match Regexp
665                 like: grep { /Regexp/ } ARRAY
666  HASH      Regexp     any HASH keys match Regexp
667                 like: grep { /Regexp/ } keys HASH
668  Any       Regexp     pattern match
669                 like: Any =~ /Regexp/
670
671  Other:
672
673  Left      Right      Description and pseudocode
674  ===============================================================
675  Object    Any        invoke ~~ overloading on Object,
676                       or fall back to...
677
678  Any       Num        numeric equality
679                  like: Any == Num
680  Num       nummy[4]    numeric equality
681                  like: Num == nummy
682  undef     Any        check whether undefined
683                  like: !defined(Any)
684  Any       Any        string equality
685                  like: Any eq Any
686
687
688 Notes:
689
690 =over
691
692 =item 1.
693 Empty hashes or arrays match.
694
695 =item 2.
696 That is, each element smartmatches the element of the same index in the other array.[3]
697
698 =item 3.
699 If a circular reference is found, fall back to referential equality.
700
701 =item 4.
702 Either an actual number, or a string that looks like one.
703
704 =back
705
706 The smartmatch implicitly dereferences any non-blessed hash or array
707 reference, so the C<I<HASH>> and C<I<ARRAY>> entries apply in those cases.
708 For blessed references, the C<I<Object>> entries apply.  Smartmatches
709 involving hashes only consider hash keys, never hash values.
710
711 The "like" code entry is not always an exact rendition.  For example, the
712 smartmatch operator short-circuits whenever possible, but C<grep> does
713 not.  Also, C<grep> in scalar context returns the number of matches, but
714 C<~~> returns only true or false.
715
716 Unlike most operators, the smartmatch operator knows to treat C<undef>
717 specially:
718
719     use v5.10.1;
720     @array = (1, 2, 3, undef, 4, 5);
721     say "some elements undefined" if undef ~~ @array;
722
723 Each operand is considered in a modified scalar context, the modification
724 being that array and hash variables are passed by reference to the
725 operator, which implicitly dereferences them.  Both elements
726 of each pair are the same:
727
728     use v5.10.1;
729
730     my %hash = (red    => 1, blue   => 2, green  => 3,
731                 orange => 4, yellow => 5, purple => 6,
732                 black  => 7, grey   => 8, white  => 9);
733
734     my @array = qw(red blue green);
735
736     say "some array elements in hash keys" if  @array ~~  %hash;
737     say "some array elements in hash keys" if \@array ~~ \%hash;
738
739     say "red in array" if "red" ~~  @array;
740     say "red in array" if "red" ~~ \@array;
741
742     say "some keys end in e" if /e$/ ~~  %hash;
743     say "some keys end in e" if /e$/ ~~ \%hash;
744
745 Two arrays smartmatch if each element in the first array smartmatches
746 (that is, is "in") the corresponding element in the second array,
747 recursively.
748
749     use v5.10.1;
750     my @little = qw(red blue green);
751     my @bigger = ("red", "blue", [ "orange", "green" ] );
752     if (@little ~~ @bigger) {  # true!
753         say "little is contained in bigger";
754     }
755
756 Because the smartmatch operator recurses on nested arrays, this
757 will still report that "red" is in the array.
758
759     use v5.10.1;
760     my @array = qw(red blue green);
761     my $nested_array = [[[[[[[ @array ]]]]]]];
762     say "red in array" if "red" ~~ $nested_array;
763
764 If two arrays smartmatch each other, then they are deep
765 copies of each others' values, as this example reports:
766
767     use v5.12.0;
768     my @a = (0, 1, 2, [3, [4, 5], 6], 7);
769     my @b = (0, 1, 2, [3, [4, 5], 6], 7);
770
771     if (@a ~~ @b && @b ~~ @a) {
772         say "a and b are deep copies of each other";
773     }
774     elsif (@a ~~ @b) {
775         say "a smartmatches in b";
776     }
777     elsif (@b ~~ @a) {
778         say "b smartmatches in a";
779     }
780     else {
781         say "a and b don't smartmatch each other at all";
782     }
783
784
785 If you were to set S<C<$b[3] = 4>>, then instead of reporting that "a and b
786 are deep copies of each other", it now reports that C<"b smartmatches in a">.
787 That's because the corresponding position in C<@a> contains an array that
788 (eventually) has a 4 in it.
789
790 Smartmatching one hash against another reports whether both contain the
791 same keys, no more and no less.  This could be used to see whether two
792 records have the same field names, without caring what values those fields
793 might have.  For example:
794
795     use v5.10.1;
796     sub make_dogtag {
797         state $REQUIRED_FIELDS = { name=>1, rank=>1, serial_num=>1 };
798
799         my ($class, $init_fields) = @_;
800
801         die "Must supply (only) name, rank, and serial number"
802             unless $init_fields ~~ $REQUIRED_FIELDS;
803
804         ...
805     }
806
807 However, this only does what you mean if C<$init_fields> is indeed a hash
808 reference. The condition C<$init_fields ~~ $REQUIRED_FIELDS> also allows the
809 strings C<"name">, C<"rank">, C<"serial_num"> as well as any array reference
810 that contains C<"name"> or C<"rank"> or C<"serial_num"> anywhere to pass
811 through.
812
813 The smartmatch operator is most often used as the implicit operator of a
814 C<when> clause.  See the section on "Switch Statements" in L<perlsyn>.
815
816 =head3 Smartmatching of Objects
817
818 To avoid relying on an object's underlying representation, if the
819 smartmatch's right operand is an object that doesn't overload C<~~>,
820 it raises the exception "C<Smartmatching a non-overloaded object
821 breaks encapsulation>".  That's because one has no business digging
822 around to see whether something is "in" an object.  These are all
823 illegal on objects without a C<~~> overload:
824
825     %hash ~~ $object
826        42 ~~ $object
827    "fred" ~~ $object
828
829 However, you can change the way an object is smartmatched by overloading
830 the C<~~> operator.  This is allowed to
831 extend the usual smartmatch semantics.
832 For objects that do have an C<~~> overload, see L<overload>.
833
834 Using an object as the left operand is allowed, although not very useful.
835 Smartmatching rules take precedence over overloading, so even if the
836 object in the left operand has smartmatch overloading, this will be
837 ignored.  A left operand that is a non-overloaded object falls back on a
838 string or numeric comparison of whatever the C<ref> operator returns.  That
839 means that
840
841     $object ~~ X
842
843 does I<not> invoke the overload method with C<I<X>> as an argument.
844 Instead the above table is consulted as normal, and based on the type of
845 C<I<X>>, overloading may or may not be invoked.  For simple strings or
846 numbers, "in" becomes equivalent to this:
847
848     $object ~~ $number          ref($object) == $number
849     $object ~~ $string          ref($object) eq $string
850
851 For example, this reports that the handle smells IOish
852 (but please don't really do this!):
853
854     use IO::Handle;
855     my $fh = IO::Handle->new();
856     if ($fh ~~ /\bIO\b/) {
857         say "handle smells IOish";
858     }
859
860 That's because it treats C<$fh> as a string like
861 C<"IO::Handle=GLOB(0x8039e0)">, then pattern matches against that.
862
863 =head2 Bitwise And
864 X<operator, bitwise, and> X<bitwise and> X<&>
865
866 Binary C<"&"> returns its operands ANDed together bit by bit.  Although no
867 warning is currently raised, the result is not well defined when this operation
868 is performed on operands that aren't either numbers (see
869 L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String Operators>).
870
871 Note that C<"&"> has lower priority than relational operators, so for example
872 the parentheses are essential in a test like
873
874     print "Even\n" if ($x & 1) == 0;
875
876 If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or
877 C<use v5.28>, then this operator always treats its operands as numbers.
878 Before Perl 5.28 this feature produced a warning in the
879 C<"experimental::bitwise"> category.
880
881 =head2 Bitwise Or and Exclusive Or
882 X<operator, bitwise, or> X<bitwise or> X<|> X<operator, bitwise, xor>
883 X<bitwise xor> X<^>
884
885 Binary C<"|"> returns its operands ORed together bit by bit.
886
887 Binary C<"^"> returns its operands XORed together bit by bit.
888
889 Although no warning is currently raised, the results are not well
890 defined when these operations are performed on operands that aren't either
891 numbers (see L</Integer Arithmetic>) nor bitstrings (see L</Bitwise String
892 Operators>).
893
894 Note that C<"|"> and C<"^"> have lower priority than relational operators, so
895 for example the parentheses are essential in a test like
896
897     print "false\n" if (8 | 2) != 10;
898
899 If the "bitwise" feature is enabled via S<C<use feature 'bitwise'>> or
900 C<use v5.28>, then this operator always treats its operands as numbers.
901 Before Perl 5.28. this feature produced a warning in the
902 C<"experimental::bitwise"> category.
903
904 =head2 C-style Logical And
905 X<&&> X<logical and> X<operator, logical, and>
906
907 Binary C<"&&"> performs a short-circuit logical AND operation.  That is,
908 if the left operand is false, the right operand is not even evaluated.
909 Scalar or list context propagates down to the right operand if it
910 is evaluated.
911
912 =head2 C-style Logical Or
913 X<||> X<operator, logical, or>
914
915 Binary C<"||"> performs a short-circuit logical OR operation.  That is,
916 if the left operand is true, the right operand is not even evaluated.
917 Scalar or list context propagates down to the right operand if it
918 is evaluated.
919
920 =head2 Logical Defined-Or
921 X<//> X<operator, logical, defined-or>
922
923 Although it has no direct equivalent in C, Perl's C<//> operator is related
924 to its C-style "or".  In fact, it's exactly the same as C<||>, except that it
925 tests the left hand side's definedness instead of its truth.  Thus,
926 S<C<< EXPR1 // EXPR2 >>> returns the value of C<< EXPR1 >> if it's defined,
927 otherwise, the value of C<< EXPR2 >> is returned.
928 (C<< EXPR1 >> is evaluated in scalar context, C<< EXPR2 >>
929 in the context of C<< // >> itself).  Usually,
930 this is the same result as S<C<< defined(EXPR1) ? EXPR1 : EXPR2 >>> (except that
931 the ternary-operator form can be used as a lvalue, while S<C<< EXPR1 // EXPR2 >>>
932 cannot).  This is very useful for
933 providing default values for variables.  If you actually want to test if
934 at least one of C<$x> and C<$y> is defined, use S<C<defined($x // $y)>>.
935
936 The C<||>, C<//> and C<&&> operators return the last value evaluated
937 (unlike C's C<||> and C<&&>, which return 0 or 1).  Thus, a reasonably
938 portable way to find out the home directory might be:
939
940     $home =  $ENV{HOME}
941           // $ENV{LOGDIR}
942           // (getpwuid($<))[7]
943           // die "You're homeless!\n";
944
945 In particular, this means that you shouldn't use this
946 for selecting between two aggregates for assignment:
947
948     @a = @b || @c;            # This doesn't do the right thing
949     @a = scalar(@b) || @c;    # because it really means this.
950     @a = @b ? @b : @c;        # This works fine, though.
951
952 As alternatives to C<&&> and C<||> when used for
953 control flow, Perl provides the C<and> and C<or> operators (see below).
954 The short-circuit behavior is identical.  The precedence of C<"and">
955 and C<"or"> is much lower, however, so that you can safely use them after a
956 list operator without the need for parentheses:
957
958     unlink "alpha", "beta", "gamma"
959             or gripe(), next LINE;
960
961 With the C-style operators that would have been written like this:
962
963     unlink("alpha", "beta", "gamma")
964             || (gripe(), next LINE);
965
966 It would be even more readable to write that this way:
967
968     unless(unlink("alpha", "beta", "gamma")) {
969         gripe();
970         next LINE;
971     }
972
973 Using C<"or"> for assignment is unlikely to do what you want; see below.
974
975 =head2 Range Operators
976 X<operator, range> X<range> X<..> X<...>
977
978 Binary C<".."> is the range operator, which is really two different
979 operators depending on the context.  In list context, it returns a
980 list of values counting (up by ones) from the left value to the right
981 value.  If the left value is greater than the right value then it
982 returns the empty list.  The range operator is useful for writing
983 S<C<foreach (1..10)>> loops and for doing slice operations on arrays.  In
984 the current implementation, no temporary array is created when the
985 range operator is used as the expression in C<foreach> loops, but older
986 versions of Perl might burn a lot of memory when you write something
987 like this:
988
989     for (1 .. 1_000_000) {
990         # code
991     }
992
993 The range operator also works on strings, using the magical
994 auto-increment, see below.
995
996 In scalar context, C<".."> returns a boolean value.  The operator is
997 bistable, like a flip-flop, and emulates the line-range (comma)
998 operator of B<sed>, B<awk>, and various editors.  Each C<".."> operator
999 maintains its own boolean state, even across calls to a subroutine
1000 that contains it.  It is false as long as its left operand is false.
1001 Once the left operand is true, the range operator stays true until the
1002 right operand is true, I<AFTER> which the range operator becomes false
1003 again.  It doesn't become false till the next time the range operator
1004 is evaluated.  It can test the right operand and become false on the
1005 same evaluation it became true (as in B<awk>), but it still returns
1006 true once.  If you don't want it to test the right operand until the
1007 next evaluation, as in B<sed>, just use three dots (C<"...">) instead of
1008 two.  In all other regards, C<"..."> behaves just like C<".."> does.
1009
1010 The right operand is not evaluated while the operator is in the
1011 "false" state, and the left operand is not evaluated while the
1012 operator is in the "true" state.  The precedence is a little lower
1013 than || and &&.  The value returned is either the empty string for
1014 false, or a sequence number (beginning with 1) for true.  The sequence
1015 number is reset for each range encountered.  The final sequence number
1016 in a range has the string C<"E0"> appended to it, which doesn't affect
1017 its numeric value, but gives you something to search for if you want
1018 to exclude the endpoint.  You can exclude the beginning point by
1019 waiting for the sequence number to be greater than 1.
1020
1021 If either operand of scalar C<".."> is a constant expression,
1022 that operand is considered true if it is equal (C<==>) to the current
1023 input line number (the C<$.> variable).
1024
1025 To be pedantic, the comparison is actually S<C<int(EXPR) == int(EXPR)>>,
1026 but that is only an issue if you use a floating point expression; when
1027 implicitly using C<$.> as described in the previous paragraph, the
1028 comparison is S<C<int(EXPR) == int($.)>> which is only an issue when C<$.>
1029 is set to a floating point value and you are not reading from a file.
1030 Furthermore, S<C<"span" .. "spat">> or S<C<2.18 .. 3.14>> will not do what
1031 you want in scalar context because each of the operands are evaluated
1032 using their integer representation.
1033
1034 Examples:
1035
1036 As a scalar operator:
1037
1038     if (101 .. 200) { print; } # print 2nd hundred lines, short for
1039                                #  if ($. == 101 .. $. == 200) { print; }
1040
1041     next LINE if (1 .. /^$/);  # skip header lines, short for
1042                                #   next LINE if ($. == 1 .. /^$/);
1043                                # (typically in a loop labeled LINE)
1044
1045     s/^/> / if (/^$/ .. eof());  # quote body
1046
1047     # parse mail messages
1048     while (<>) {
1049         $in_header =   1  .. /^$/;
1050         $in_body   = /^$/ .. eof;
1051         if ($in_header) {
1052             # do something
1053         } else { # in body
1054             # do something else
1055         }
1056     } continue {
1057         close ARGV if eof;             # reset $. each file
1058     }
1059
1060 Here's a simple example to illustrate the difference between
1061 the two range operators:
1062
1063     @lines = ("   - Foo",
1064               "01 - Bar",
1065               "1  - Baz",
1066               "   - Quux");
1067
1068     foreach (@lines) {
1069         if (/0/ .. /1/) {
1070             print "$_\n";
1071         }
1072     }
1073
1074 This program will print only the line containing "Bar".  If
1075 the range operator is changed to C<...>, it will also print the
1076 "Baz" line.
1077
1078 And now some examples as a list operator:
1079
1080     for (101 .. 200) { print }      # print $_ 100 times
1081     @foo = @foo[0 .. $#foo];        # an expensive no-op
1082     @foo = @foo[$#foo-4 .. $#foo];  # slice last 5 items
1083
1084 The range operator (in list context) makes use of the magical
1085 auto-increment algorithm if the operands are strings.  You
1086 can say
1087
1088     @alphabet = ("A" .. "Z");
1089
1090 to get all normal letters of the English alphabet, or
1091
1092     $hexdigit = (0 .. 9, "a" .. "f")[$num & 15];
1093
1094 to get a hexadecimal digit, or
1095
1096     @z2 = ("01" .. "31");
1097     print $z2[$mday];
1098
1099 to get dates with leading zeros.
1100
1101 If the final value specified is not in the sequence that the magical
1102 increment would produce, the sequence goes until the next value would
1103 be longer than the final value specified.
1104
1105 As of Perl 5.26, the list-context range operator on strings works as expected
1106 in the scope of L<< S<C<"use feature 'unicode_strings">>|feature/The
1107 'unicode_strings' feature >>. In previous versions, and outside the scope of
1108 that feature, it exhibits L<perlunicode/The "Unicode Bug">: its behavior
1109 depends on the internal encoding of the range endpoint.
1110
1111 If the initial value specified isn't part of a magical increment
1112 sequence (that is, a non-empty string matching C</^[a-zA-Z]*[0-9]*\z/>),
1113 only the initial value will be returned.  So the following will only
1114 return an alpha:
1115
1116     use charnames "greek";
1117     my @greek_small =  ("\N{alpha}" .. "\N{omega}");
1118
1119 To get the 25 traditional lowercase Greek letters, including both sigmas,
1120 you could use this instead:
1121
1122     use charnames "greek";
1123     my @greek_small =  map { chr } ( ord("\N{alpha}")
1124                                         ..
1125                                      ord("\N{omega}")
1126                                    );
1127
1128 However, because there are I<many> other lowercase Greek characters than
1129 just those, to match lowercase Greek characters in a regular expression,
1130 you could use the pattern C</(?:(?=\p{Greek})\p{Lower})+/> (or the
1131 L<experimental feature|perlrecharclass/Extended Bracketed Character
1132 Classes> C<S</(?[ \p{Greek} & \p{Lower} ])+/>>).
1133
1134 Because each operand is evaluated in integer form, S<C<2.18 .. 3.14>> will
1135 return two elements in list context.
1136
1137     @list = (2.18 .. 3.14); # same as @list = (2 .. 3);
1138
1139 =head2 Conditional Operator
1140 X<operator, conditional> X<operator, ternary> X<ternary> X<?:>
1141
1142 Ternary C<"?:"> is the conditional operator, just as in C.  It works much
1143 like an if-then-else.  If the argument before the C<?> is true, the
1144 argument before the C<:> is returned, otherwise the argument after the
1145 C<:> is returned.  For example:
1146
1147     printf "I have %d dog%s.\n", $n,
1148             ($n == 1) ? "" : "s";
1149
1150 Scalar or list context propagates downward into the 2nd
1151 or 3rd argument, whichever is selected.
1152
1153     $x = $ok ? $y : $z;  # get a scalar
1154     @x = $ok ? @y : @z;  # get an array
1155     $x = $ok ? @y : @z;  # oops, that's just a count!
1156
1157 The operator may be assigned to if both the 2nd and 3rd arguments are
1158 legal lvalues (meaning that you can assign to them):
1159
1160     ($x_or_y ? $x : $y) = $z;
1161
1162 Because this operator produces an assignable result, using assignments
1163 without parentheses will get you in trouble.  For example, this:
1164
1165     $x % 2 ? $x += 10 : $x += 2
1166
1167 Really means this:
1168
1169     (($x % 2) ? ($x += 10) : $x) += 2
1170
1171 Rather than this:
1172
1173     ($x % 2) ? ($x += 10) : ($x += 2)
1174
1175 That should probably be written more simply as:
1176
1177     $x += ($x % 2) ? 10 : 2;
1178
1179 =head2 Assignment Operators
1180 X<assignment> X<operator, assignment> X<=> X<**=> X<+=> X<*=> X<&=>
1181 X<<< <<= >>> X<&&=> X<-=> X</=> X<|=> X<<< >>= >>> X<||=> X<//=> X<.=>
1182 X<%=> X<^=> X<x=> X<&.=> X<|.=> X<^.=>
1183
1184 C<"="> is the ordinary assignment operator.
1185
1186 Assignment operators work as in C.  That is,
1187
1188     $x += 2;
1189
1190 is equivalent to
1191
1192     $x = $x + 2;
1193
1194 although without duplicating any side effects that dereferencing the lvalue
1195 might trigger, such as from C<tie()>.  Other assignment operators work similarly.
1196 The following are recognized:
1197
1198     **=    +=    *=    &=    &.=    <<=    &&=
1199            -=    /=    |=    |.=    >>=    ||=
1200            .=    %=    ^=    ^.=           //=
1201                  x=
1202
1203 Although these are grouped by family, they all have the precedence
1204 of assignment.  These combined assignment operators can only operate on
1205 scalars, whereas the ordinary assignment operator can assign to arrays,
1206 hashes, lists and even references.  (See L<"Context"|perldata/Context>
1207 and L<perldata/List value constructors>, and L<perlref/Assigning to
1208 References>.)
1209
1210 Unlike in C, the scalar assignment operator produces a valid lvalue.
1211 Modifying an assignment is equivalent to doing the assignment and
1212 then modifying the variable that was assigned to.  This is useful
1213 for modifying a copy of something, like this:
1214
1215     ($tmp = $global) =~ tr/13579/24680/;
1216
1217 Although as of 5.14, that can be also be accomplished this way:
1218
1219     use v5.14;
1220     $tmp = ($global =~  tr/13579/24680/r);
1221
1222 Likewise,
1223
1224     ($x += 2) *= 3;
1225
1226 is equivalent to
1227
1228     $x += 2;
1229     $x *= 3;
1230
1231 Similarly, a list assignment in list context produces the list of
1232 lvalues assigned to, and a list assignment in scalar context returns
1233 the number of elements produced by the expression on the right hand
1234 side of the assignment.
1235
1236 The three dotted bitwise assignment operators (C<&.=> C<|.=> C<^.=>) are new in
1237 Perl 5.22.  See L</Bitwise String Operators>.
1238
1239 =head2 Comma Operator
1240 X<comma> X<operator, comma> X<,>
1241
1242 Binary C<","> is the comma operator.  In scalar context it evaluates
1243 its left argument, throws that value away, then evaluates its right
1244 argument and returns that value.  This is just like C's comma operator.
1245
1246 In list context, it's just the list argument separator, and inserts
1247 both its arguments into the list.  These arguments are also evaluated
1248 from left to right.
1249
1250 The C<< => >> operator (sometimes pronounced "fat comma") is a synonym
1251 for the comma except that it causes a
1252 word on its left to be interpreted as a string if it begins with a letter
1253 or underscore and is composed only of letters, digits and underscores.
1254 This includes operands that might otherwise be interpreted as operators,
1255 constants, single number v-strings or function calls.  If in doubt about
1256 this behavior, the left operand can be quoted explicitly.
1257
1258 Otherwise, the C<< => >> operator behaves exactly as the comma operator
1259 or list argument separator, according to context.
1260
1261 For example:
1262
1263     use constant FOO => "something";
1264
1265     my %h = ( FOO => 23 );
1266
1267 is equivalent to:
1268
1269     my %h = ("FOO", 23);
1270
1271 It is I<NOT>:
1272
1273     my %h = ("something", 23);
1274
1275 The C<< => >> operator is helpful in documenting the correspondence
1276 between keys and values in hashes, and other paired elements in lists.
1277
1278     %hash = ( $key => $value );
1279     login( $username => $password );
1280
1281 The special quoting behavior ignores precedence, and hence may apply to
1282 I<part> of the left operand:
1283
1284     print time.shift => "bbb";
1285
1286 That example prints something like C<"1314363215shiftbbb">, because the
1287 C<< => >> implicitly quotes the C<shift> immediately on its left, ignoring
1288 the fact that C<time.shift> is the entire left operand.
1289
1290 =head2 List Operators (Rightward)
1291 X<operator, list, rightward> X<list operator>
1292
1293 On the right side of a list operator, the comma has very low precedence,
1294 such that it controls all comma-separated expressions found there.
1295 The only operators with lower precedence are the logical operators
1296 C<"and">, C<"or">, and C<"not">, which may be used to evaluate calls to list
1297 operators without the need for parentheses:
1298
1299     open HANDLE, "< :encoding(UTF-8)", "filename"
1300         or die "Can't open: $!\n";
1301
1302 However, some people find that code harder to read than writing
1303 it with parentheses:
1304
1305     open(HANDLE, "< :encoding(UTF-8)", "filename")
1306         or die "Can't open: $!\n";
1307
1308 in which case you might as well just use the more customary C<"||"> operator:
1309
1310     open(HANDLE, "< :encoding(UTF-8)", "filename")
1311         || die "Can't open: $!\n";
1312
1313 See also discussion of list operators in L</Terms and List Operators (Leftward)>.
1314
1315 =head2 Logical Not
1316 X<operator, logical, not> X<not>
1317
1318 Unary C<"not"> returns the logical negation of the expression to its right.
1319 It's the equivalent of C<"!"> except for the very low precedence.
1320
1321 =head2 Logical And
1322 X<operator, logical, and> X<and>
1323
1324 Binary C<"and"> returns the logical conjunction of the two surrounding
1325 expressions.  It's equivalent to C<&&> except for the very low
1326 precedence.  This means that it short-circuits: the right
1327 expression is evaluated only if the left expression is true.
1328
1329 =head2 Logical or and Exclusive Or
1330 X<operator, logical, or> X<operator, logical, xor>
1331 X<operator, logical, exclusive or>
1332 X<or> X<xor>
1333
1334 Binary C<"or"> returns the logical disjunction of the two surrounding
1335 expressions.  It's equivalent to C<||> except for the very low precedence.
1336 This makes it useful for control flow:
1337
1338     print FH $data              or die "Can't write to FH: $!";
1339
1340 This means that it short-circuits: the right expression is evaluated
1341 only if the left expression is false.  Due to its precedence, you must
1342 be careful to avoid using it as replacement for the C<||> operator.
1343 It usually works out better for flow control than in assignments:
1344
1345     $x = $y or $z;              # bug: this is wrong
1346     ($x = $y) or $z;            # really means this
1347     $x = $y || $z;              # better written this way
1348
1349 However, when it's a list-context assignment and you're trying to use
1350 C<||> for control flow, you probably need C<"or"> so that the assignment
1351 takes higher precedence.
1352
1353     @info = stat($file) || die;     # oops, scalar sense of stat!
1354     @info = stat($file) or die;     # better, now @info gets its due
1355
1356 Then again, you could always use parentheses.
1357
1358 Binary C<"xor"> returns the exclusive-OR of the two surrounding expressions.
1359 It cannot short-circuit (of course).
1360
1361 There is no low precedence operator for defined-OR.
1362
1363 =head2 C Operators Missing From Perl
1364 X<operator, missing from perl> X<&> X<*>
1365 X<typecasting> X<(TYPE)>
1366
1367 Here is what C has that Perl doesn't:
1368
1369 =over 8
1370
1371 =item unary &
1372
1373 Address-of operator.  (But see the C<"\"> operator for taking a reference.)
1374
1375 =item unary *
1376
1377 Dereference-address operator.  (Perl's prefix dereferencing
1378 operators are typed: C<$>, C<@>, C<%>, and C<&>.)
1379
1380 =item (TYPE)
1381
1382 Type-casting operator.
1383
1384 =back
1385
1386 =head2 Quote and Quote-like Operators
1387 X<operator, quote> X<operator, quote-like> X<q> X<qq> X<qx> X<qw> X<m>
1388 X<qr> X<s> X<tr> X<'> X<''> X<"> X<""> X<//> X<`> X<``> X<<< << >>>
1389 X<escape sequence> X<escape>
1390
1391 While we usually think of quotes as literal values, in Perl they
1392 function as operators, providing various kinds of interpolating and
1393 pattern matching capabilities.  Perl provides customary quote characters
1394 for these behaviors, but also provides a way for you to choose your
1395 quote character for any of them.  In the following table, a C<{}> represents
1396 any pair of delimiters you choose.
1397
1398     Customary  Generic        Meaning        Interpolates
1399         ''       q{}          Literal             no
1400         ""      qq{}          Literal             yes
1401         ``      qx{}          Command             yes*
1402                 qw{}         Word list            no
1403         //       m{}       Pattern match          yes*
1404                 qr{}          Pattern             yes*
1405                  s{}{}      Substitution          yes*
1406                 tr{}{}    Transliteration         no (but see below)
1407                  y{}{}    Transliteration         no (but see below)
1408         <<EOF                 here-doc            yes*
1409
1410         * unless the delimiter is ''.
1411
1412 Non-bracketing delimiters use the same character fore and aft, but the four
1413 sorts of ASCII brackets (round, angle, square, curly) all nest, which means
1414 that
1415
1416     q{foo{bar}baz}
1417
1418 is the same as
1419
1420     'foo{bar}baz'
1421
1422 Note, however, that this does not always work for quoting Perl code:
1423
1424     $s = q{ if($x eq "}") ... }; # WRONG
1425
1426 is a syntax error.  The C<L<Text::Balanced>> module (standard as of v5.8,
1427 and from CPAN before then) is able to do this properly.
1428
1429 There can (and in some cases, must) be whitespace between the operator
1430 and the quoting
1431 characters, except when C<#> is being used as the quoting character.
1432 C<q#foo#> is parsed as the string C<foo>, while S<C<q #foo#>> is the
1433 operator C<q> followed by a comment.  Its argument will be taken
1434 from the next line.  This allows you to write:
1435
1436     s {foo}  # Replace foo
1437       {bar}  # with bar.
1438
1439 The cases where whitespace must be used are when the quoting character
1440 is a word character (meaning it matches C</\w/>):
1441
1442     q XfooX # Works: means the string 'foo'
1443     qXfooX  # WRONG!
1444
1445 The following escape sequences are available in constructs that interpolate,
1446 and in transliterations whose delimiters aren't single quotes (C<"'">).
1447 X<\t> X<\n> X<\r> X<\f> X<\b> X<\a> X<\e> X<\x> X<\0> X<\c> X<\N> X<\N{}>
1448 X<\o{}>
1449
1450     Sequence     Note  Description
1451     \t                  tab               (HT, TAB)
1452     \n                  newline           (NL)
1453     \r                  return            (CR)
1454     \f                  form feed         (FF)
1455     \b                  backspace         (BS)
1456     \a                  alarm (bell)      (BEL)
1457     \e                  escape            (ESC)
1458     \x{263A}     [1,8]  hex char          (example: SMILEY)
1459     \x1b         [2,8]  restricted range hex char (example: ESC)
1460     \N{name}     [3]    named Unicode character or character sequence
1461     \N{U+263D}   [4,8]  Unicode character (example: FIRST QUARTER MOON)
1462     \c[          [5]    control char      (example: chr(27))
1463     \o{23072}    [6,8]  octal char        (example: SMILEY)
1464     \033         [7,8]  restricted range octal char  (example: ESC)
1465
1466 =over 4
1467
1468 =item [1]
1469
1470 The result is the character specified by the hexadecimal number between
1471 the braces.  See L</[8]> below for details on which character.
1472
1473 Only hexadecimal digits are valid between the braces.  If an invalid
1474 character is encountered, a warning will be issued and the invalid
1475 character and all subsequent characters (valid or invalid) within the
1476 braces will be discarded.
1477
1478 If there are no valid digits between the braces, the generated character is
1479 the NULL character (C<\x{00}>).  However, an explicit empty brace (C<\x{}>)
1480 will not cause a warning (currently).
1481
1482 =item [2]
1483
1484 The result is the character specified by the hexadecimal number in the range
1485 0x00 to 0xFF.  See L</[8]> below for details on which character.
1486
1487 Only hexadecimal digits are valid following C<\x>.  When C<\x> is followed
1488 by fewer than two valid digits, any valid digits will be zero-padded.  This
1489 means that C<\x7> will be interpreted as C<\x07>, and a lone C<"\x"> will be
1490 interpreted as C<\x00>.  Except at the end of a string, having fewer than
1491 two valid digits will result in a warning.  Note that although the warning
1492 says the illegal character is ignored, it is only ignored as part of the
1493 escape and will still be used as the subsequent character in the string.
1494 For example:
1495
1496   Original    Result    Warns?
1497   "\x7"       "\x07"    no
1498   "\x"        "\x00"    no
1499   "\x7q"      "\x07q"   yes
1500   "\xq"       "\x00q"   yes
1501
1502 =item [3]
1503
1504 The result is the Unicode character or character sequence given by I<name>.
1505 See L<charnames>.
1506
1507 =item [4]
1508
1509 S<C<\N{U+I<hexadecimal number>}>> means the Unicode character whose Unicode code
1510 point is I<hexadecimal number>.
1511
1512 =item [5]
1513
1514 The character following C<\c> is mapped to some other character as shown in the
1515 table:
1516
1517  Sequence   Value
1518    \c@      chr(0)
1519    \cA      chr(1)
1520    \ca      chr(1)
1521    \cB      chr(2)
1522    \cb      chr(2)
1523    ...
1524    \cZ      chr(26)
1525    \cz      chr(26)
1526    \c[      chr(27)
1527                      # See below for chr(28)
1528    \c]      chr(29)
1529    \c^      chr(30)
1530    \c_      chr(31)
1531    \c?      chr(127) # (on ASCII platforms; see below for link to
1532                      #  EBCDIC discussion)
1533
1534 In other words, it's the character whose code point has had 64 xor'd with
1535 its uppercase.  C<\c?> is DELETE on ASCII platforms because
1536 S<C<ord("?") ^ 64>> is 127, and
1537 C<\c@> is NULL because the ord of C<"@"> is 64, so xor'ing 64 itself produces 0.
1538
1539 Also, C<\c\I<X>> yields S<C< chr(28) . "I<X>">> for any I<X>, but cannot come at the
1540 end of a string, because the backslash would be parsed as escaping the end
1541 quote.
1542
1543 On ASCII platforms, the resulting characters from the list above are the
1544 complete set of ASCII controls.  This isn't the case on EBCDIC platforms; see
1545 L<perlebcdic/OPERATOR DIFFERENCES> for a full discussion of the
1546 differences between these for ASCII versus EBCDIC platforms.
1547
1548 Use of any other character following the C<"c"> besides those listed above is
1549 discouraged, and as of Perl v5.20, the only characters actually allowed
1550 are the printable ASCII ones, minus the left brace C<"{">.  What happens
1551 for any of the allowed other characters is that the value is derived by
1552 xor'ing with the seventh bit, which is 64, and a warning raised if
1553 enabled.  Using the non-allowed characters generates a fatal error.
1554
1555 To get platform independent controls, you can use C<\N{...}>.
1556
1557 =item [6]
1558
1559 The result is the character specified by the octal number between the braces.
1560 See L</[8]> below for details on which character.
1561
1562 If a character that isn't an octal digit is encountered, a warning is raised,
1563 and the value is based on the octal digits before it, discarding it and all
1564 following characters up to the closing brace.  It is a fatal error if there are
1565 no octal digits at all.
1566
1567 =item [7]
1568
1569 The result is the character specified by the three-digit octal number in the
1570 range 000 to 777 (but best to not use above 077, see next paragraph).  See
1571 L</[8]> below for details on which character.
1572
1573 Some contexts allow 2 or even 1 digit, but any usage without exactly
1574 three digits, the first being a zero, may give unintended results.  (For
1575 example, in a regular expression it may be confused with a backreference;
1576 see L<perlrebackslash/Octal escapes>.)  Starting in Perl 5.14, you may
1577 use C<\o{}> instead, which avoids all these problems.  Otherwise, it is best to
1578 use this construct only for ordinals C<\077> and below, remembering to pad to
1579 the left with zeros to make three digits.  For larger ordinals, either use
1580 C<\o{}>, or convert to something else, such as to hex and use C<\N{U+}>
1581 (which is portable between platforms with different character sets) or
1582 C<\x{}> instead.
1583
1584 =item [8]
1585
1586 Several constructs above specify a character by a number.  That number
1587 gives the character's position in the character set encoding (indexed from 0).
1588 This is called synonymously its ordinal, code position, or code point.  Perl
1589 works on platforms that have a native encoding currently of either ASCII/Latin1
1590 or EBCDIC, each of which allow specification of 256 characters.  In general, if
1591 the number is 255 (0xFF, 0377) or below, Perl interprets this in the platform's
1592 native encoding.  If the number is 256 (0x100, 0400) or above, Perl interprets
1593 it as a Unicode code point and the result is the corresponding Unicode
1594 character.  For example C<\x{50}> and C<\o{120}> both are the number 80 in
1595 decimal, which is less than 256, so the number is interpreted in the native
1596 character set encoding.  In ASCII the character in the 80th position (indexed
1597 from 0) is the letter C<"P">, and in EBCDIC it is the ampersand symbol C<"&">.
1598 C<\x{100}> and C<\o{400}> are both 256 in decimal, so the number is interpreted
1599 as a Unicode code point no matter what the native encoding is.  The name of the
1600 character in the 256th position (indexed by 0) in Unicode is
1601 C<LATIN CAPITAL LETTER A WITH MACRON>.
1602
1603 An exception to the above rule is that S<C<\N{U+I<hex number>}>> is
1604 always interpreted as a Unicode code point, so that C<\N{U+0050}> is C<"P"> even
1605 on EBCDIC platforms.
1606
1607 =back
1608
1609 B<NOTE>: Unlike C and other languages, Perl has no C<\v> escape sequence for
1610 the vertical tab (VT, which is 11 in both ASCII and EBCDIC), but you may
1611 use C<\N{VT}>, C<\ck>, C<\N{U+0b}>, or C<\x0b>.  (C<\v>
1612 does have meaning in regular expression patterns in Perl, see L<perlre>.)
1613
1614 The following escape sequences are available in constructs that interpolate,
1615 but not in transliterations.
1616 X<\l> X<\u> X<\L> X<\U> X<\E> X<\Q> X<\F>
1617
1618     \l          lowercase next character only
1619     \u          titlecase (not uppercase!) next character only
1620     \L          lowercase all characters till \E or end of string
1621     \U          uppercase all characters till \E or end of string
1622     \F          foldcase all characters till \E or end of string
1623     \Q          quote (disable) pattern metacharacters till \E or
1624                 end of string
1625     \E          end either case modification or quoted section
1626                 (whichever was last seen)
1627
1628 See L<perlfunc/quotemeta> for the exact definition of characters that
1629 are quoted by C<\Q>.
1630
1631 C<\L>, C<\U>, C<\F>, and C<\Q> can stack, in which case you need one
1632 C<\E> for each.  For example:
1633
1634  say"This \Qquoting \ubusiness \Uhere isn't quite\E done yet,\E is it?";
1635  This quoting\ Business\ HERE\ ISN\'T\ QUITE\ done\ yet\, is it?
1636
1637 If a S<C<use locale>> form that includes C<LC_CTYPE> is in effect (see
1638 L<perllocale>), the case map used by C<\l>, C<\L>, C<\u>, and C<\U> is
1639 taken from the current locale.  If Unicode (for example, C<\N{}> or code
1640 points of 0x100 or beyond) is being used, the case map used by C<\l>,
1641 C<\L>, C<\u>, and C<\U> is as defined by Unicode.  That means that
1642 case-mapping a single character can sometimes produce a sequence of
1643 several characters.
1644 Under S<C<use locale>>, C<\F> produces the same results as C<\L>
1645 for all locales but a UTF-8 one, where it instead uses the Unicode
1646 definition.
1647
1648 All systems use the virtual C<"\n"> to represent a line terminator,
1649 called a "newline".  There is no such thing as an unvarying, physical
1650 newline character.  It is only an illusion that the operating system,
1651 device drivers, C libraries, and Perl all conspire to preserve.  Not all
1652 systems read C<"\r"> as ASCII CR and C<"\n"> as ASCII LF.  For example,
1653 on the ancient Macs (pre-MacOS X) of yesteryear, these used to be reversed,
1654 and on systems without a line terminator,
1655 printing C<"\n"> might emit no actual data.  In general, use C<"\n"> when
1656 you mean a "newline" for your system, but use the literal ASCII when you
1657 need an exact character.  For example, most networking protocols expect
1658 and prefer a CR+LF (C<"\015\012"> or C<"\cM\cJ">) for line terminators,
1659 and although they often accept just C<"\012">, they seldom tolerate just
1660 C<"\015">.  If you get in the habit of using C<"\n"> for networking,
1661 you may be burned some day.
1662 X<newline> X<line terminator> X<eol> X<end of line>
1663 X<\n> X<\r> X<\r\n>
1664
1665 For constructs that do interpolate, variables beginning with "C<$>"
1666 or "C<@>" are interpolated.  Subscripted variables such as C<$a[3]> or
1667 C<< $href->{key}[0] >> are also interpolated, as are array and hash slices.
1668 But method calls such as C<< $obj->meth >> are not.
1669
1670 Interpolating an array or slice interpolates the elements in order,
1671 separated by the value of C<$">, so is equivalent to interpolating
1672 S<C<join $", @array>>.  "Punctuation" arrays such as C<@*> are usually
1673 interpolated only if the name is enclosed in braces C<@{*}>, but the
1674 arrays C<@_>, C<@+>, and C<@-> are interpolated even without braces.
1675
1676 For double-quoted strings, the quoting from C<\Q> is applied after
1677 interpolation and escapes are processed.
1678
1679     "abc\Qfoo\tbar$s\Exyz"
1680
1681 is equivalent to
1682
1683     "abc" . quotemeta("foo\tbar$s") . "xyz"
1684
1685 For the pattern of regex operators (C<qr//>, C<m//> and C<s///>),
1686 the quoting from C<\Q> is applied after interpolation is processed,
1687 but before escapes are processed.  This allows the pattern to match
1688 literally (except for C<$> and C<@>).  For example, the following matches:
1689
1690     '\s\t' =~ /\Q\s\t/
1691
1692 Because C<$> or C<@> trigger interpolation, you'll need to use something
1693 like C</\Quser\E\@\Qhost/> to match them literally.
1694
1695 Patterns are subject to an additional level of interpretation as a
1696 regular expression.  This is done as a second pass, after variables are
1697 interpolated, so that regular expressions may be incorporated into the
1698 pattern from the variables.  If this is not what you want, use C<\Q> to
1699 interpolate a variable literally.
1700
1701 Apart from the behavior described above, Perl does not expand
1702 multiple levels of interpolation.  In particular, contrary to the
1703 expectations of shell programmers, back-quotes do I<NOT> interpolate
1704 within double quotes, nor do single quotes impede evaluation of
1705 variables when used within double quotes.
1706
1707 =head2 Regexp Quote-Like Operators
1708 X<operator, regexp>
1709
1710 Here are the quote-like operators that apply to pattern
1711 matching and related activities.
1712
1713 =over 8
1714
1715 =item C<qr/I<STRING>/msixpodualn>
1716 X<qr> X</i> X</m> X</o> X</s> X</x> X</p>
1717
1718 This operator quotes (and possibly compiles) its I<STRING> as a regular
1719 expression.  I<STRING> is interpolated the same way as I<PATTERN>
1720 in C<m/I<PATTERN>/>.  If C<"'"> is used as the delimiter, no variable
1721 interpolation is done.  Returns a Perl value which may be used instead of the
1722 corresponding C</I<STRING>/msixpodualn> expression.  The returned value is a
1723 normalized version of the original pattern.  It magically differs from
1724 a string containing the same characters: C<ref(qr/x/)> returns "Regexp";
1725 however, dereferencing it is not well defined (you currently get the
1726 normalized version of the original pattern, but this may change).
1727
1728
1729 For example,
1730
1731     $rex = qr/my.STRING/is;
1732     print $rex;                 # prints (?si-xm:my.STRING)
1733     s/$rex/foo/;
1734
1735 is equivalent to
1736
1737     s/my.STRING/foo/is;
1738
1739 The result may be used as a subpattern in a match:
1740
1741     $re = qr/$pattern/;
1742     $string =~ /foo${re}bar/;   # can be interpolated in other
1743                                 # patterns
1744     $string =~ $re;             # or used standalone
1745     $string =~ /$re/;           # or this way
1746
1747 Since Perl may compile the pattern at the moment of execution of the C<qr()>
1748 operator, using C<qr()> may have speed advantages in some situations,
1749 notably if the result of C<qr()> is used standalone:
1750
1751     sub match {
1752         my $patterns = shift;
1753         my @compiled = map qr/$_/i, @$patterns;
1754         grep {
1755             my $success = 0;
1756             foreach my $pat (@compiled) {
1757                 $success = 1, last if /$pat/;
1758             }
1759             $success;
1760         } @_;
1761     }
1762
1763 Precompilation of the pattern into an internal representation at
1764 the moment of C<qr()> avoids the need to recompile the pattern every
1765 time a match C</$pat/> is attempted.  (Perl has many other internal
1766 optimizations, but none would be triggered in the above example if
1767 we did not use C<qr()> operator.)
1768
1769 Options (specified by the following modifiers) are:
1770
1771     m   Treat string as multiple lines.
1772     s   Treat string as single line. (Make . match a newline)
1773     i   Do case-insensitive pattern matching.
1774     x   Use extended regular expressions; specifying two
1775         x's means \t and the SPACE character are ignored within
1776         square-bracketed character classes
1777     p   When matching preserve a copy of the matched string so
1778         that ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be
1779         defined (ignored starting in v5.20) as these are always
1780         defined starting in that release
1781     o   Compile pattern only once.
1782     a   ASCII-restrict: Use ASCII for \d, \s, \w and [[:posix:]]
1783         character classes; specifying two a's adds the further
1784         restriction that no ASCII character will match a
1785         non-ASCII one under /i.
1786     l   Use the current run-time locale's rules.
1787     u   Use Unicode rules.
1788     d   Use Unicode or native charset, as in 5.12 and earlier.
1789     n   Non-capture mode. Don't let () fill in $1, $2, etc...
1790
1791 If a precompiled pattern is embedded in a larger pattern then the effect
1792 of C<"msixpluadn"> will be propagated appropriately.  The effect that the
1793 C</o> modifier has is not propagated, being restricted to those patterns
1794 explicitly using it.
1795
1796 The C</a>, C</d>, C</l>, and C</u> modifiers (added in Perl 5.14)
1797 control the character set rules, but C</a> is the only one you are likely
1798 to want to specify explicitly; the other three are selected
1799 automatically by various pragmas.
1800
1801 See L<perlre> for additional information on valid syntax for I<STRING>, and
1802 for a detailed look at the semantics of regular expressions.  In
1803 particular, all modifiers except the largely obsolete C</o> are further
1804 explained in L<perlre/Modifiers>.  C</o> is described in the next section.
1805
1806 =item C<m/I<PATTERN>/msixpodualngc>
1807 X<m> X<operator, match>
1808 X<regexp, options> X<regexp> X<regex, options> X<regex>
1809 X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c>
1810
1811 =item C</I<PATTERN>/msixpodualngc>
1812
1813 Searches a string for a pattern match, and in scalar context returns
1814 true if it succeeds, false if it fails.  If no string is specified
1815 via the C<=~> or C<!~> operator, the C<$_> string is searched.  (The
1816 string specified with C<=~> need not be an lvalue--it may be the
1817 result of an expression evaluation, but remember the C<=~> binds
1818 rather tightly.)  See also L<perlre>.
1819
1820 Options are as described in C<qr//> above; in addition, the following match
1821 process modifiers are available:
1822
1823  g  Match globally, i.e., find all occurrences.
1824  c  Do not reset search position on a failed match when /g is
1825     in effect.
1826
1827 If C<"/"> is the delimiter then the initial C<m> is optional.  With the C<m>
1828 you can use any pair of non-whitespace (ASCII) characters
1829 as delimiters.  This is particularly useful for matching path names
1830 that contain C<"/">, to avoid LTS (leaning toothpick syndrome).  If C<"?"> is
1831 the delimiter, then a match-only-once rule applies,
1832 described in C<m?I<PATTERN>?> below.  If C<"'"> (single quote) is the delimiter,
1833 no variable interpolation is performed on the I<PATTERN>.
1834 When using a delimiter character valid in an identifier, whitespace is required
1835 after the C<m>.
1836
1837 I<PATTERN> may contain variables, which will be interpolated
1838 every time the pattern search is evaluated, except
1839 for when the delimiter is a single quote.  (Note that C<$(>, C<$)>, and
1840 C<$|> are not interpolated because they look like end-of-string tests.)
1841 Perl will not recompile the pattern unless an interpolated
1842 variable that it contains changes.  You can force Perl to skip the
1843 test and never recompile by adding a C</o> (which stands for "once")
1844 after the trailing delimiter.
1845 Once upon a time, Perl would recompile regular expressions
1846 unnecessarily, and this modifier was useful to tell it not to do so, in the
1847 interests of speed.  But now, the only reasons to use C</o> are one of:
1848
1849 =over
1850
1851 =item 1
1852
1853 The variables are thousands of characters long and you know that they
1854 don't change, and you need to wring out the last little bit of speed by
1855 having Perl skip testing for that.  (There is a maintenance penalty for
1856 doing this, as mentioning C</o> constitutes a promise that you won't
1857 change the variables in the pattern.  If you do change them, Perl won't
1858 even notice.)
1859
1860 =item 2
1861
1862 you want the pattern to use the initial values of the variables
1863 regardless of whether they change or not.  (But there are saner ways
1864 of accomplishing this than using C</o>.)
1865
1866 =item 3
1867
1868 If the pattern contains embedded code, such as
1869
1870     use re 'eval';
1871     $code = 'foo(?{ $x })';
1872     /$code/
1873
1874 then perl will recompile each time, even though the pattern string hasn't
1875 changed, to ensure that the current value of C<$x> is seen each time.
1876 Use C</o> if you want to avoid this.
1877
1878 =back
1879
1880 The bottom line is that using C</o> is almost never a good idea.
1881
1882 =item The empty pattern C<//>
1883
1884 If the I<PATTERN> evaluates to the empty string, the last
1885 I<successfully> matched regular expression is used instead.  In this
1886 case, only the C<g> and C<c> flags on the empty pattern are honored;
1887 the other flags are taken from the original pattern.  If no match has
1888 previously succeeded, this will (silently) act instead as a genuine
1889 empty pattern (which will always match).
1890
1891 Note that it's possible to confuse Perl into thinking C<//> (the empty
1892 regex) is really C<//> (the defined-or operator).  Perl is usually pretty
1893 good about this, but some pathological cases might trigger this, such as
1894 C<$x///> (is that S<C<($x) / (//)>> or S<C<$x // />>?) and S<C<print $fh //>>
1895 (S<C<print $fh(//>> or S<C<print($fh //>>?).  In all of these examples, Perl
1896 will assume you meant defined-or.  If you meant the empty regex, just
1897 use parentheses or spaces to disambiguate, or even prefix the empty
1898 regex with an C<m> (so C<//> becomes C<m//>).
1899
1900 =item Matching in list context
1901
1902 If the C</g> option is not used, C<m//> in list context returns a
1903 list consisting of the subexpressions matched by the parentheses in the
1904 pattern, that is, (C<$1>, C<$2>, C<$3>...)  (Note that here C<$1> etc. are
1905 also set).  When there are no parentheses in the pattern, the return
1906 value is the list C<(1)> for success.
1907 With or without parentheses, an empty list is returned upon failure.
1908
1909 Examples:
1910
1911  open(TTY, "+</dev/tty")
1912     || die "can't access /dev/tty: $!";
1913
1914  <TTY> =~ /^y/i && foo();       # do foo if desired
1915
1916  if (/Version: *([0-9.]*)/) { $version = $1; }
1917
1918  next if m#^/usr/spool/uucp#;
1919
1920  # poor man's grep
1921  $arg = shift;
1922  while (<>) {
1923     print if /$arg/o; # compile only once (no longer needed!)
1924  }
1925
1926  if (($F1, $F2, $Etc) = ($foo =~ /^(\S+)\s+(\S+)\s*(.*)/))
1927
1928 This last example splits C<$foo> into the first two words and the
1929 remainder of the line, and assigns those three fields to C<$F1>, C<$F2>, and
1930 C<$Etc>.  The conditional is true if any variables were assigned; that is,
1931 if the pattern matched.
1932
1933 The C</g> modifier specifies global pattern matching--that is,
1934 matching as many times as possible within the string.  How it behaves
1935 depends on the context.  In list context, it returns a list of the
1936 substrings matched by any capturing parentheses in the regular
1937 expression.  If there are no parentheses, it returns a list of all
1938 the matched strings, as if there were parentheses around the whole
1939 pattern.
1940
1941 In scalar context, each execution of C<m//g> finds the next match,
1942 returning true if it matches, and false if there is no further match.
1943 The position after the last match can be read or set using the C<pos()>
1944 function; see L<perlfunc/pos>.  A failed match normally resets the
1945 search position to the beginning of the string, but you can avoid that
1946 by adding the C</c> modifier (for example, C<m//gc>).  Modifying the target
1947 string also resets the search position.
1948
1949 =item C<\G I<assertion>>
1950
1951 You can intermix C<m//g> matches with C<m/\G.../g>, where C<\G> is a
1952 zero-width assertion that matches the exact position where the
1953 previous C<m//g>, if any, left off.  Without the C</g> modifier, the
1954 C<\G> assertion still anchors at C<pos()> as it was at the start of
1955 the operation (see L<perlfunc/pos>), but the match is of course only
1956 attempted once.  Using C<\G> without C</g> on a target string that has
1957 not previously had a C</g> match applied to it is the same as using
1958 the C<\A> assertion to match the beginning of the string.  Note also
1959 that, currently, C<\G> is only properly supported when anchored at the
1960 very beginning of the pattern.
1961
1962 Examples:
1963
1964     # list context
1965     ($one,$five,$fifteen) = (`uptime` =~ /(\d+\.\d+)/g);
1966
1967     # scalar context
1968     local $/ = "";
1969     while ($paragraph = <>) {
1970         while ($paragraph =~ /\p{Ll}['")]*[.!?]+['")]*\s/g) {
1971             $sentences++;
1972         }
1973     }
1974     say $sentences;
1975
1976 Here's another way to check for sentences in a paragraph:
1977
1978  my $sentence_rx = qr{
1979     (?: (?<= ^ ) | (?<= \s ) )  # after start-of-string or
1980                                 # whitespace
1981     \p{Lu}                      # capital letter
1982     .*?                         # a bunch of anything
1983     (?<= \S )                   # that ends in non-
1984                                 # whitespace
1985     (?<! \b [DMS]r  )           # but isn't a common abbr.
1986     (?<! \b Mrs )
1987     (?<! \b Sra )
1988     (?<! \b St  )
1989     [.?!]                       # followed by a sentence
1990                                 # ender
1991     (?= $ | \s )                # in front of end-of-string
1992                                 # or whitespace
1993  }sx;
1994  local $/ = "";
1995  while (my $paragraph = <>) {
1996     say "NEW PARAGRAPH";
1997     my $count = 0;
1998     while ($paragraph =~ /($sentence_rx)/g) {
1999         printf "\tgot sentence %d: <%s>\n", ++$count, $1;
2000     }
2001  }
2002
2003 Here's how to use C<m//gc> with C<\G>:
2004
2005     $_ = "ppooqppqq";
2006     while ($i++ < 2) {
2007         print "1: '";
2008         print $1 while /(o)/gc; print "', pos=", pos, "\n";
2009         print "2: '";
2010         print $1 if /\G(q)/gc;  print "', pos=", pos, "\n";
2011         print "3: '";
2012         print $1 while /(p)/gc; print "', pos=", pos, "\n";
2013     }
2014     print "Final: '$1', pos=",pos,"\n" if /\G(.)/;
2015
2016 The last example should print:
2017
2018     1: 'oo', pos=4
2019     2: 'q', pos=5
2020     3: 'pp', pos=7
2021     1: '', pos=7
2022     2: 'q', pos=8
2023     3: '', pos=8
2024     Final: 'q', pos=8
2025
2026 Notice that the final match matched C<q> instead of C<p>, which a match
2027 without the C<\G> anchor would have done.  Also note that the final match
2028 did not update C<pos>.  C<pos> is only updated on a C</g> match.  If the
2029 final match did indeed match C<p>, it's a good bet that you're running an
2030 ancient (pre-5.6.0) version of Perl.
2031
2032 A useful idiom for C<lex>-like scanners is C</\G.../gc>.  You can
2033 combine several regexps like this to process a string part-by-part,
2034 doing different actions depending on which regexp matched.  Each
2035 regexp tries to match where the previous one leaves off.
2036
2037  $_ = <<'EOL';
2038     $url = URI::URL->new( "http://example.com/" );
2039     die if $url eq "xXx";
2040  EOL
2041
2042  LOOP: {
2043      print(" digits"),       redo LOOP if /\G\d+\b[,.;]?\s*/gc;
2044      print(" lowercase"),    redo LOOP
2045                                     if /\G\p{Ll}+\b[,.;]?\s*/gc;
2046      print(" UPPERCASE"),    redo LOOP
2047                                     if /\G\p{Lu}+\b[,.;]?\s*/gc;
2048      print(" Capitalized"),  redo LOOP
2049                               if /\G\p{Lu}\p{Ll}+\b[,.;]?\s*/gc;
2050      print(" MiXeD"),        redo LOOP if /\G\pL+\b[,.;]?\s*/gc;
2051      print(" alphanumeric"), redo LOOP
2052                             if /\G[\p{Alpha}\pN]+\b[,.;]?\s*/gc;
2053      print(" line-noise"),   redo LOOP if /\G\W+/gc;
2054      print ". That's all!\n";
2055  }
2056
2057 Here is the output (split into several lines):
2058
2059  line-noise lowercase line-noise UPPERCASE line-noise UPPERCASE
2060  line-noise lowercase line-noise lowercase line-noise lowercase
2061  lowercase line-noise lowercase lowercase line-noise lowercase
2062  lowercase line-noise MiXeD line-noise. That's all!
2063
2064 =item C<m?I<PATTERN>?msixpodualngc>
2065 X<?> X<operator, match-once>
2066
2067 This is just like the C<m/I<PATTERN>/> search, except that it matches
2068 only once between calls to the C<reset()> operator.  This is a useful
2069 optimization when you want to see only the first occurrence of
2070 something in each file of a set of files, for instance.  Only C<m??>
2071 patterns local to the current package are reset.
2072
2073     while (<>) {
2074         if (m?^$?) {
2075                             # blank line between header and body
2076         }
2077     } continue {
2078         reset if eof;       # clear m?? status for next file
2079     }
2080
2081 Another example switched the first "latin1" encoding it finds
2082 to "utf8" in a pod file:
2083
2084     s//utf8/ if m? ^ =encoding \h+ \K latin1 ?x;
2085
2086 The match-once behavior is controlled by the match delimiter being
2087 C<?>; with any other delimiter this is the normal C<m//> operator.
2088
2089 In the past, the leading C<m> in C<m?I<PATTERN>?> was optional, but omitting it
2090 would produce a deprecation warning.  As of v5.22.0, omitting it produces a
2091 syntax error.  If you encounter this construct in older code, you can just add
2092 C<m>.
2093
2094 =item C<s/I<PATTERN>/I<REPLACEMENT>/msixpodualngcer>
2095 X<s> X<substitute> X<substitution> X<replace> X<regexp, replace>
2096 X<regexp, substitute> X</m> X</s> X</i> X</x> X</p> X</o> X</g> X</c> X</e> X</r>
2097
2098 Searches a string for a pattern, and if found, replaces that pattern
2099 with the replacement text and returns the number of substitutions
2100 made.  Otherwise it returns false (a value that is both an empty string (C<"">)
2101 and numeric zero (C<0>) as described in L</Relational Operators>).
2102
2103 If the C</r> (non-destructive) option is used then it runs the
2104 substitution on a copy of the string and instead of returning the
2105 number of substitutions, it returns the copy whether or not a
2106 substitution occurred.  The original string is never changed when
2107 C</r> is used.  The copy will always be a plain string, even if the
2108 input is an object or a tied variable.
2109
2110 If no string is specified via the C<=~> or C<!~> operator, the C<$_>
2111 variable is searched and modified.  Unless the C</r> option is used,
2112 the string specified must be a scalar variable, an array element, a
2113 hash element, or an assignment to one of those; that is, some sort of
2114 scalar lvalue.
2115
2116 If the delimiter chosen is a single quote, no variable interpolation is
2117 done on either the I<PATTERN> or the I<REPLACEMENT>.  Otherwise, if the
2118 I<PATTERN> contains a C<$> that looks like a variable rather than an
2119 end-of-string test, the variable will be interpolated into the pattern
2120 at run-time.  If you want the pattern compiled only once the first time
2121 the variable is interpolated, use the C</o> option.  If the pattern
2122 evaluates to the empty string, the last successfully executed regular
2123 expression is used instead.  See L<perlre> for further explanation on these.
2124
2125 Options are as with C<m//> with the addition of the following replacement
2126 specific options:
2127
2128     e   Evaluate the right side as an expression.
2129     ee  Evaluate the right side as a string then eval the
2130         result.
2131     r   Return substitution and leave the original string
2132         untouched.
2133
2134 Any non-whitespace delimiter may replace the slashes.  Add space after
2135 the C<s> when using a character allowed in identifiers.  If single quotes
2136 are used, no interpretation is done on the replacement string (the C</e>
2137 modifier overrides this, however).  Note that Perl treats backticks
2138 as normal delimiters; the replacement text is not evaluated as a command.
2139 If the I<PATTERN> is delimited by bracketing quotes, the I<REPLACEMENT> has
2140 its own pair of quotes, which may or may not be bracketing quotes, for example,
2141 C<s(foo)(bar)> or C<< s<foo>/bar/ >>.  A C</e> will cause the
2142 replacement portion to be treated as a full-fledged Perl expression
2143 and evaluated right then and there.  It is, however, syntax checked at
2144 compile-time.  A second C<e> modifier will cause the replacement portion
2145 to be C<eval>ed before being run as a Perl expression.
2146
2147 Examples:
2148
2149     s/\bgreen\b/mauve/g;              # don't change wintergreen
2150
2151     $path =~ s|/usr/bin|/usr/local/bin|;
2152
2153     s/Login: $foo/Login: $bar/; # run-time pattern
2154
2155     ($foo = $bar) =~ s/this/that/;      # copy first, then
2156                                         # change
2157     ($foo = "$bar") =~ s/this/that/;    # convert to string,
2158                                         # copy, then change
2159     $foo = $bar =~ s/this/that/r;       # Same as above using /r
2160     $foo = $bar =~ s/this/that/r
2161                 =~ s/that/the other/r;  # Chained substitutes
2162                                         # using /r
2163     @foo = map { s/this/that/r } @bar   # /r is very useful in
2164                                         # maps
2165
2166     $count = ($paragraph =~ s/Mister\b/Mr./g);  # get change-cnt
2167
2168     $_ = 'abc123xyz';
2169     s/\d+/$&*2/e;               # yields 'abc246xyz'
2170     s/\d+/sprintf("%5d",$&)/e;  # yields 'abc  246xyz'
2171     s/\w/$& x 2/eg;             # yields 'aabbcc  224466xxyyzz'
2172
2173     s/%(.)/$percent{$1}/g;      # change percent escapes; no /e
2174     s/%(.)/$percent{$1} || $&/ge;       # expr now, so /e
2175     s/^=(\w+)/pod($1)/ge;       # use function call
2176
2177     $_ = 'abc123xyz';
2178     $x = s/abc/def/r;           # $x is 'def123xyz' and
2179                                 # $_ remains 'abc123xyz'.
2180
2181     # expand variables in $_, but dynamics only, using
2182     # symbolic dereferencing
2183     s/\$(\w+)/${$1}/g;
2184
2185     # Add one to the value of any numbers in the string
2186     s/(\d+)/1 + $1/eg;
2187
2188     # Titlecase words in the last 30 characters only
2189     substr($str, -30) =~ s/\b(\p{Alpha}+)\b/\u\L$1/g;
2190
2191     # This will expand any embedded scalar variable
2192     # (including lexicals) in $_ : First $1 is interpolated
2193     # to the variable name, and then evaluated
2194     s/(\$\w+)/$1/eeg;
2195
2196     # Delete (most) C comments.
2197     $program =~ s {
2198         /\*     # Match the opening delimiter.
2199         .*?     # Match a minimal number of characters.
2200         \*/     # Match the closing delimiter.
2201     } []gsx;
2202
2203     s/^\s*(.*?)\s*$/$1/;        # trim whitespace in $_,
2204                                 # expensively
2205
2206     for ($variable) {           # trim whitespace in $variable,
2207                                 # cheap
2208         s/^\s+//;
2209         s/\s+$//;
2210     }
2211
2212     s/([^ ]*) *([^ ]*)/$2 $1/;  # reverse 1st two fields
2213
2214 Note the use of C<$> instead of C<\> in the last example.  Unlike
2215 B<sed>, we use the \<I<digit>> form only in the left hand side.
2216 Anywhere else it's $<I<digit>>.
2217
2218 Occasionally, you can't use just a C</g> to get all the changes
2219 to occur that you might want.  Here are two common cases:
2220
2221     # put commas in the right places in an integer
2222     1 while s/(\d)(\d\d\d)(?!\d)/$1,$2/g;
2223
2224     # expand tabs to 8-column spacing
2225     1 while s/\t+/' ' x (length($&)*8 - length($`)%8)/e;
2226
2227 =back
2228
2229 =head2 Quote-Like Operators
2230 X<operator, quote-like>
2231
2232 =over 4
2233
2234 =item C<q/I<STRING>/>
2235 X<q> X<quote, single> X<'> X<''>
2236
2237 =item C<'I<STRING>'>
2238
2239 A single-quoted, literal string.  A backslash represents a backslash
2240 unless followed by the delimiter or another backslash, in which case
2241 the delimiter or backslash is interpolated.
2242
2243     $foo = q!I said, "You said, 'She said it.'"!;
2244     $bar = q('This is it.');
2245     $baz = '\n';                # a two-character string
2246
2247 =item C<qq/I<STRING>/>
2248 X<qq> X<quote, double> X<"> X<"">
2249
2250 =item "I<STRING>"
2251
2252 A double-quoted, interpolated string.
2253
2254     $_ .= qq
2255      (*** The previous line contains the naughty word "$1".\n)
2256                 if /\b(tcl|java|python)\b/i;      # :-)
2257     $baz = "\n";                # a one-character string
2258
2259 =item C<qx/I<STRING>/>
2260 X<qx> X<`> X<``> X<backtick>
2261
2262 =item C<`I<STRING>`>
2263
2264 A string which is (possibly) interpolated and then executed as a
2265 system command with F</bin/sh> or its equivalent.  Shell wildcards,
2266 pipes, and redirections will be honored.  The collected standard
2267 output of the command is returned; standard error is unaffected.  In
2268 scalar context, it comes back as a single (potentially multi-line)
2269 string, or C<undef> if the command failed.  In list context, returns a
2270 list of lines (however you've defined lines with C<$/> or
2271 C<$INPUT_RECORD_SEPARATOR>), or an empty list if the command failed.
2272
2273 Because backticks do not affect standard error, use shell file descriptor
2274 syntax (assuming the shell supports this) if you care to address this.
2275 To capture a command's STDERR and STDOUT together:
2276
2277     $output = `cmd 2>&1`;
2278
2279 To capture a command's STDOUT but discard its STDERR:
2280
2281     $output = `cmd 2>/dev/null`;
2282
2283 To capture a command's STDERR but discard its STDOUT (ordering is
2284 important here):
2285
2286     $output = `cmd 2>&1 1>/dev/null`;
2287
2288 To exchange a command's STDOUT and STDERR in order to capture the STDERR
2289 but leave its STDOUT to come out the old STDERR:
2290
2291     $output = `cmd 3>&1 1>&2 2>&3 3>&-`;
2292
2293 To read both a command's STDOUT and its STDERR separately, it's easiest
2294 to redirect them separately to files, and then read from those files
2295 when the program is done:
2296
2297     system("program args 1>program.stdout 2>program.stderr");
2298
2299 The STDIN filehandle used by the command is inherited from Perl's STDIN.
2300 For example:
2301
2302     open(SPLAT, "stuff")   || die "can't open stuff: $!";
2303     open(STDIN, "<&SPLAT") || die "can't dupe SPLAT: $!";
2304     print STDOUT `sort`;
2305
2306 will print the sorted contents of the file named F<"stuff">.
2307
2308 Using single-quote as a delimiter protects the command from Perl's
2309 double-quote interpolation, passing it on to the shell instead:
2310
2311     $perl_info  = qx(ps $$);            # that's Perl's $$
2312     $shell_info = qx'ps $$';            # that's the new shell's $$
2313
2314 How that string gets evaluated is entirely subject to the command
2315 interpreter on your system.  On most platforms, you will have to protect
2316 shell metacharacters if you want them treated literally.  This is in
2317 practice difficult to do, as it's unclear how to escape which characters.
2318 See L<perlsec> for a clean and safe example of a manual C<fork()> and C<exec()>
2319 to emulate backticks safely.
2320
2321 On some platforms (notably DOS-like ones), the shell may not be
2322 capable of dealing with multiline commands, so putting newlines in
2323 the string may not get you what you want.  You may be able to evaluate
2324 multiple commands in a single line by separating them with the command
2325 separator character, if your shell supports that (for example, C<;> on
2326 many Unix shells and C<&> on the Windows NT C<cmd> shell).
2327
2328 Perl will attempt to flush all files opened for
2329 output before starting the child process, but this may not be supported
2330 on some platforms (see L<perlport>).  To be safe, you may need to set
2331 C<$|> (C<$AUTOFLUSH> in C<L<English>>) or call the C<autoflush()> method of
2332 C<L<IO::Handle>> on any open handles.
2333
2334 Beware that some command shells may place restrictions on the length
2335 of the command line.  You must ensure your strings don't exceed this
2336 limit after any necessary interpolations.  See the platform-specific
2337 release notes for more details about your particular environment.
2338
2339 Using this operator can lead to programs that are difficult to port,
2340 because the shell commands called vary between systems, and may in
2341 fact not be present at all.  As one example, the C<type> command under
2342 the POSIX shell is very different from the C<type> command under DOS.
2343 That doesn't mean you should go out of your way to avoid backticks
2344 when they're the right way to get something done.  Perl was made to be
2345 a glue language, and one of the things it glues together is commands.
2346 Just understand what you're getting yourself into.
2347
2348 Like C<system>, backticks put the child process exit code in C<$?>.
2349 If you'd like to manually inspect failure, you can check all possible
2350 failure modes by inspecting C<$?> like this:
2351
2352     if ($? == -1) {
2353         print "failed to execute: $!\n";
2354     }
2355     elsif ($? & 127) {
2356         printf "child died with signal %d, %s coredump\n",
2357             ($? & 127),  ($? & 128) ? 'with' : 'without';
2358     }
2359     else {
2360         printf "child exited with value %d\n", $? >> 8;
2361     }
2362
2363 Use the L<open> pragma to control the I/O layers used when reading the
2364 output of the command, for example:
2365
2366   use open IN => ":encoding(UTF-8)";
2367   my $x = `cmd-producing-utf-8`;
2368
2369 C<qx//> can also be called like a function with L<perlfunc/readpipe>.
2370
2371 See L</"I/O Operators"> for more discussion.
2372
2373 =item C<qw/I<STRING>/>
2374 X<qw> X<quote, list> X<quote, words>
2375
2376 Evaluates to a list of the words extracted out of I<STRING>, using embedded
2377 whitespace as the word delimiters.  It can be understood as being roughly
2378 equivalent to:
2379
2380     split(" ", q/STRING/);
2381
2382 the differences being that it only splits on ASCII whitespace,
2383 generates a real list at compile time, and
2384 in scalar context it returns the last element in the list.  So
2385 this expression:
2386
2387     qw(foo bar baz)
2388
2389 is semantically equivalent to the list:
2390
2391     "foo", "bar", "baz"
2392
2393 Some frequently seen examples:
2394
2395     use POSIX qw( setlocale localeconv )
2396     @EXPORT = qw( foo bar baz );
2397
2398 A common mistake is to try to separate the words with commas or to
2399 put comments into a multi-line C<qw>-string.  For this reason, the
2400 S<C<use warnings>> pragma and the B<-w> switch (that is, the C<$^W> variable)
2401 produces warnings if the I<STRING> contains the C<","> or the C<"#"> character.
2402
2403 =item C<tr/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2404 X<tr> X<y> X<transliterate> X</c> X</d> X</s>
2405
2406 =item C<y/I<SEARCHLIST>/I<REPLACEMENTLIST>/cdsr>
2407
2408 Transliterates all occurrences of the characters found in the search list
2409 with the corresponding character in the replacement list.  It returns
2410 the number of characters replaced or deleted.  If no string is
2411 specified via the C<=~> or C<!~> operator, the C<$_> string is transliterated.
2412
2413 If the C</r> (non-destructive) option is present, a new copy of the string
2414 is made and its characters transliterated, and this copy is returned no
2415 matter whether it was modified or not: the original string is always
2416 left unchanged.  The new copy is always a plain string, even if the input
2417 string is an object or a tied variable.
2418
2419 Unless the C</r> option is used, the string specified with C<=~> must be a
2420 scalar variable, an array element, a hash element, or an assignment to one
2421 of those; in other words, an lvalue.
2422
2423 If the characters delimiting I<SEARCHLIST> and I<REPLACEMENTLIST>
2424 are single quotes (C<tr'I<SEARCHLIST>'I<REPLACEMENTLIST>'>), the only
2425 interpolation is removal of C<\> from pairs of C<\\>.
2426
2427 Otherwise, a character range may be specified with a hyphen, so
2428 C<tr/A-J/0-9/> does the same replacement as
2429 C<tr/ACEGIBDFHJ/0246813579/>.
2430
2431 For B<sed> devotees, C<y> is provided as a synonym for C<tr>.
2432
2433 If the I<SEARCHLIST> is delimited by bracketing quotes, the
2434 I<REPLACEMENTLIST> must have its own pair of quotes, which may or may
2435 not be bracketing quotes; for example, C<tr[aeiouy][yuoiea]> or
2436 C<tr(+\-*/)/ABCD/>.
2437
2438 Characters may be literals or (if the delimiters aren't single quotes)
2439 any of the escape sequences accepted in double-quoted strings.  But
2440 there is never any variable interpolation, so C<"$"> and C<"@"> are
2441 treated as literals.  A hyphen at the beginning or end, or preceded by a
2442 backslash is considered a literal.  Escape sequence details are in L<the
2443 table near the beginning of this section|/Quote and Quote-like
2444 Operators>.
2445
2446 Note that C<tr> does B<not> do regular expression character classes such as
2447 C<\d> or C<\pL>.  The C<tr> operator is not equivalent to the C<L<tr(1)>>
2448 utility.  C<tr[a-z][A-Z]> will uppercase the 26 letters "a" through "z",
2449 but for case changing not confined to ASCII, use
2450 L<C<lc>|perlfunc/lc>, L<C<uc>|perlfunc/uc>,
2451 L<C<lcfirst>|perlfunc/lcfirst>, L<C<ucfirst>|perlfunc/ucfirst>
2452 (all documented in L<perlfunc>), or the
2453 L<substitution operator C<sE<sol>I<PATTERN>E<sol>I<REPLACEMENT>E<sol>>|/sE<sol>PATTERNE<sol>REPLACEMENTE<sol>msixpodualngcer>
2454 (with C<\U>, C<\u>, C<\L>, and C<\l> string-interpolation escapes in the
2455 I<REPLACEMENT> portion).
2456
2457 Most ranges are unportable between character sets, but certain ones
2458 signal Perl to do special handling to make them portable.  There are two
2459 classes of portable ranges.  The first are any subsets of the ranges
2460 C<A-Z>, C<a-z>, and C<0-9>, when expressed as literal characters.
2461
2462   tr/h-k/H-K/
2463
2464 capitalizes the letters C<"h">, C<"i">, C<"j">, and C<"k"> and nothing
2465 else, no matter what the platform's character set is.  In contrast, all
2466 of
2467
2468   tr/\x68-\x6B/\x48-\x4B/
2469   tr/h-\x6B/H-\x4B/
2470   tr/\x68-k/\x48-K/
2471
2472 do the same capitalizations as the previous example when run on ASCII
2473 platforms, but something completely different on EBCDIC ones.
2474
2475 The second class of portable ranges is invoked when one or both of the
2476 range's end points are expressed as C<\N{...}>
2477
2478  $string =~ tr/\N{U+20}-\N{U+7E}//d;
2479
2480 removes from C<$string> all the platform's characters which are
2481 equivalent to any of Unicode U+0020, U+0021, ... U+007D, U+007E.  This
2482 is a portable range, and has the same effect on every platform it is
2483 run on.  It turns out that in this example, these are the ASCII
2484 printable characters.  So after this is run, C<$string> has only
2485 controls and characters which have no ASCII equivalents.
2486
2487 But, even for portable ranges, it is not generally obvious what is
2488 included without having to look things up.  A sound principle is to use
2489 only ranges that both begin from and end at either ASCII alphabetics of
2490 equal case (C<b-e>, C<B-E>), or digits (C<1-4>).  Anything else is
2491 unclear (and unportable unless C<\N{...}> is used).  If in doubt, spell
2492 out the character sets in full.
2493
2494 Options:
2495
2496     c   Complement the SEARCHLIST.
2497     d   Delete found but unreplaced characters.
2498     s   Squash duplicate replaced characters.
2499     r   Return the modified string and leave the original string
2500         untouched.
2501
2502 If the C</c> modifier is specified, the I<SEARCHLIST> character set
2503 is complemented. So for example these two are equivalent (the exact
2504 maximum number will depend on your platform):
2505
2506     tr/\x00-\xfd/ABCD/c
2507     tr/\xfe-\x{7fffffff}/ABCD/
2508
2509 If the C</d> modifier is specified, any characters
2510 specified by I<SEARCHLIST> not found in I<REPLACEMENTLIST> are deleted.
2511 (Note that this is slightly more flexible than the behavior of some
2512 B<tr> programs, which delete anything they find in the I<SEARCHLIST>,
2513 period.)
2514
2515 If the C</s> modifier is specified, runs of the same character in the
2516 result, where each those characters were substituted by the
2517 transliteration, are squashed down to a single instance of the character.
2518
2519 If the C</d> modifier is used, the I<REPLACEMENTLIST> is always interpreted
2520 exactly as specified.  Otherwise, if the I<REPLACEMENTLIST> is shorter
2521 than the I<SEARCHLIST>, the final character is replicated till it is long
2522 enough.  If the I<REPLACEMENTLIST> is empty, the I<SEARCHLIST> is replicated.
2523 This latter is useful for counting characters in a class or for
2524 squashing character sequences in a class. For example, each of these pairs
2525 are equivalent:
2526
2527     tr/abcd//            tr/abcd/abcd/
2528     tr/abcd/AB/          tr/abcd/ABBB/
2529     tr/abcd//d           s/[abcd]//g
2530     tr/abcd/AB/d         (tr/ab/AB/ + s/[cd]//g)  - but run together
2531
2532 Some examples:
2533
2534     $ARGV[1] =~ tr/A-Z/a-z/;    # canonicalize to lower case ASCII
2535
2536     $cnt = tr/*/*/;             # count the stars in $_
2537
2538     $cnt = $sky =~ tr/*/*/;     # count the stars in $sky
2539
2540     $cnt = tr/0-9//;            # count the digits in $_
2541
2542     tr/a-zA-Z//s;               # bookkeeper -> bokeper
2543
2544     ($HOST = $host) =~ tr/a-z/A-Z/;
2545      $HOST = $host  =~ tr/a-z/A-Z/r;   # same thing
2546
2547     $HOST = $host =~ tr/a-z/A-Z/r    # chained with s///r
2548                   =~ s/:/ -p/r;
2549
2550     tr/a-zA-Z/ /cs;             # change non-alphas to single space
2551
2552     @stripped = map tr/a-zA-Z/ /csr, @original;
2553                                 # /r with map
2554
2555     tr [\200-\377]
2556        [\000-\177];             # wickedly delete 8th bit
2557
2558 If multiple transliterations are given for a character, only the
2559 first one is used:
2560
2561     tr/AAA/XYZ/
2562
2563 will transliterate any A to X.
2564
2565 Because the transliteration table is built at compile time, neither
2566 the I<SEARCHLIST> nor the I<REPLACEMENTLIST> are subjected to double quote
2567 interpolation.  That means that if you want to use variables, you
2568 must use an C<eval()>:
2569
2570     eval "tr/$oldlist/$newlist/";
2571     die $@ if $@;
2572
2573     eval "tr/$oldlist/$newlist/, 1" or die $@;
2574
2575 =item C<< <<I<EOF> >>
2576 X<here-doc> X<heredoc> X<here-document> X<<< << >>>
2577
2578 A line-oriented form of quoting is based on the shell "here-document"
2579 syntax.  Following a C<< << >> you specify a string to terminate
2580 the quoted material, and all lines following the current line down to
2581 the terminating string are the value of the item.
2582
2583 Prefixing the terminating string with a C<~> specifies that you
2584 want to use L</Indented Here-docs> (see below).
2585
2586 The terminating string may be either an identifier (a word), or some
2587 quoted text.  An unquoted identifier works like double quotes.
2588 There may not be a space between the C<< << >> and the identifier,
2589 unless the identifier is explicitly quoted.  The terminating string
2590 must appear by itself (unquoted and with no surrounding whitespace)
2591 on the terminating line.
2592
2593 If the terminating string is quoted, the type of quotes used determine
2594 the treatment of the text.
2595
2596 =over 4
2597
2598 =item Double Quotes
2599
2600 Double quotes indicate that the text will be interpolated using exactly
2601 the same rules as normal double quoted strings.
2602
2603        print <<EOF;
2604     The price is $Price.
2605     EOF
2606
2607        print << "EOF"; # same as above
2608     The price is $Price.
2609     EOF
2610
2611
2612 =item Single Quotes
2613
2614 Single quotes indicate the text is to be treated literally with no
2615 interpolation of its content.  This is similar to single quoted
2616 strings except that backslashes have no special meaning, with C<\\>
2617 being treated as two backslashes and not one as they would in every
2618 other quoting construct.
2619
2620 Just as in the shell, a backslashed bareword following the C<<< << >>>
2621 means the same thing as a single-quoted string does:
2622
2623         $cost = <<'VISTA';  # hasta la ...
2624     That'll be $10 please, ma'am.
2625     VISTA
2626
2627         $cost = <<\VISTA;   # Same thing!
2628     That'll be $10 please, ma'am.
2629     VISTA
2630
2631 This is the only form of quoting in perl where there is no need
2632 to worry about escaping content, something that code generators
2633 can and do make good use of.
2634
2635 =item Backticks
2636
2637 The content of the here doc is treated just as it would be if the
2638 string were embedded in backticks.  Thus the content is interpolated
2639 as though it were double quoted and then executed via the shell, with
2640 the results of the execution returned.
2641
2642        print << `EOC`; # execute command and get results
2643     echo hi there
2644     EOC
2645
2646 =back
2647
2648 =over 4
2649
2650 =item Indented Here-docs
2651
2652 The here-doc modifier C<~> allows you to indent your here-docs to make
2653 the code more readable:
2654
2655     if ($some_var) {
2656       print <<~EOF;
2657         This is a here-doc
2658         EOF
2659     }
2660
2661 This will print...
2662
2663     This is a here-doc
2664
2665 ...with no leading whitespace.
2666
2667 The delimiter is used to determine the B<exact> whitespace to
2668 remove from the beginning of each line.  All lines B<must> have
2669 at least the same starting whitespace (except lines only
2670 containing a newline) or perl will croak.  Tabs and spaces can
2671 be mixed, but are matched exactly.  One tab will not be equal to
2672 8 spaces!
2673
2674 Additional beginning whitespace (beyond what preceded the
2675 delimiter) will be preserved:
2676
2677     print <<~EOF;
2678       This text is not indented
2679         This text is indented with two spaces
2680                 This text is indented with two tabs
2681       EOF
2682
2683 Finally, the modifier may be used with all of the forms
2684 mentioned above:
2685
2686     <<~\EOF;
2687     <<~'EOF'
2688     <<~"EOF"
2689     <<~`EOF`
2690
2691 And whitespace may be used between the C<~> and quoted delimiters:
2692
2693     <<~ 'EOF'; # ... "EOF", `EOF`
2694
2695 =back
2696
2697 It is possible to stack multiple here-docs in a row:
2698
2699        print <<"foo", <<"bar"; # you can stack them
2700     I said foo.
2701     foo
2702     I said bar.
2703     bar
2704
2705        myfunc(<< "THIS", 23, <<'THAT');
2706     Here's a line
2707     or two.
2708     THIS
2709     and here's another.
2710     THAT
2711
2712 Just don't forget that you have to put a semicolon on the end
2713 to finish the statement, as Perl doesn't know you're not going to
2714 try to do this:
2715
2716        print <<ABC
2717     179231
2718     ABC
2719        + 20;
2720
2721 If you want to remove the line terminator from your here-docs,
2722 use C<chomp()>.
2723
2724     chomp($string = <<'END');
2725     This is a string.
2726     END
2727
2728 If you want your here-docs to be indented with the rest of the code,
2729 use the C<<< <<~FOO >>> construct described under L</Indented Here-docs>:
2730
2731     $quote = <<~'FINIS';
2732        The Road goes ever on and on,
2733        down from the door where it began.
2734        FINIS
2735
2736 If you use a here-doc within a delimited construct, such as in C<s///eg>,
2737 the quoted material must still come on the line following the
2738 C<<< <<FOO >>> marker, which means it may be inside the delimited
2739 construct:
2740
2741     s/this/<<E . 'that'
2742     the other
2743     E
2744      . 'more '/eg;
2745
2746 It works this way as of Perl 5.18.  Historically, it was inconsistent, and
2747 you would have to write
2748
2749     s/this/<<E . 'that'
2750      . 'more '/eg;
2751     the other
2752     E
2753
2754 outside of string evals.
2755
2756 Additionally, quoting rules for the end-of-string identifier are
2757 unrelated to Perl's quoting rules.  C<q()>, C<qq()>, and the like are not
2758 supported in place of C<''> and C<"">, and the only interpolation is for
2759 backslashing the quoting character:
2760
2761     print << "abc\"def";
2762     testing...
2763     abc"def
2764
2765 Finally, quoted strings cannot span multiple lines.  The general rule is
2766 that the identifier must be a string literal.  Stick with that, and you
2767 should be safe.
2768
2769 =back
2770
2771 =head2 Gory details of parsing quoted constructs
2772 X<quote, gory details>
2773
2774 When presented with something that might have several different
2775 interpretations, Perl uses the B<DWIM> (that's "Do What I Mean")
2776 principle to pick the most probable interpretation.  This strategy
2777 is so successful that Perl programmers often do not suspect the
2778 ambivalence of what they write.  But from time to time, Perl's
2779 notions differ substantially from what the author honestly meant.
2780
2781 This section hopes to clarify how Perl handles quoted constructs.
2782 Although the most common reason to learn this is to unravel labyrinthine
2783 regular expressions, because the initial steps of parsing are the
2784 same for all quoting operators, they are all discussed together.
2785
2786 The most important Perl parsing rule is the first one discussed
2787 below: when processing a quoted construct, Perl first finds the end
2788 of that construct, then interprets its contents.  If you understand
2789 this rule, you may skip the rest of this section on the first
2790 reading.  The other rules are likely to contradict the user's
2791 expectations much less frequently than this first one.
2792
2793 Some passes discussed below are performed concurrently, but because
2794 their results are the same, we consider them individually.  For different
2795 quoting constructs, Perl performs different numbers of passes, from
2796 one to four, but these passes are always performed in the same order.
2797
2798 =over 4
2799
2800 =item Finding the end
2801
2802 The first pass is finding the end of the quoted construct.  This results
2803 in saving to a safe location a copy of the text (between the starting
2804 and ending delimiters), normalized as necessary to avoid needing to know
2805 what the original delimiters were.
2806
2807 If the construct is a here-doc, the ending delimiter is a line
2808 that has a terminating string as the content.  Therefore C<<<EOF> is
2809 terminated by C<EOF> immediately followed by C<"\n"> and starting
2810 from the first column of the terminating line.
2811 When searching for the terminating line of a here-doc, nothing
2812 is skipped.  In other words, lines after the here-doc syntax
2813 are compared with the terminating string line by line.
2814
2815 For the constructs except here-docs, single characters are used as starting
2816 and ending delimiters.  If the starting delimiter is an opening punctuation
2817 (that is C<(>, C<[>, C<{>, or C<< < >>), the ending delimiter is the
2818 corresponding closing punctuation (that is C<)>, C<]>, C<}>, or C<< > >>).
2819 If the starting delimiter is an unpaired character like C</> or a closing
2820 punctuation, the ending delimiter is the same as the starting delimiter.
2821 Therefore a C</> terminates a C<qq//> construct, while a C<]> terminates
2822 both C<qq[]> and C<qq]]> constructs.
2823
2824 When searching for single-character delimiters, escaped delimiters
2825 and C<\\> are skipped.  For example, while searching for terminating C</>,
2826 combinations of C<\\> and C<\/> are skipped.  If the delimiters are
2827 bracketing, nested pairs are also skipped.  For example, while searching
2828 for a closing C<]> paired with the opening C<[>, combinations of C<\\>, C<\]>,
2829 and C<\[> are all skipped, and nested C<[> and C<]> are skipped as well.
2830 However, when backslashes are used as the delimiters (like C<qq\\> and
2831 C<tr\\\>), nothing is skipped.
2832 During the search for the end, backslashes that escape delimiters or
2833 other backslashes are removed (exactly speaking, they are not copied to the
2834 safe location).
2835
2836 For constructs with three-part delimiters (C<s///>, C<y///>, and
2837 C<tr///>), the search is repeated once more.
2838 If the first delimiter is not an opening punctuation, the three delimiters must
2839 be the same, such as C<s!!!> and C<tr)))>,
2840 in which case the second delimiter
2841 terminates the left part and starts the right part at once.
2842 If the left part is delimited by bracketing punctuation (that is C<()>,
2843 C<[]>, C<{}>, or C<< <> >>), the right part needs another pair of
2844 delimiters such as C<s(){}> and C<tr[]//>.  In these cases, whitespace
2845 and comments are allowed between the two parts, although the comment must follow
2846 at least one whitespace character; otherwise a character expected as the
2847 start of the comment may be regarded as the starting delimiter of the right part.
2848
2849 During this search no attention is paid to the semantics of the construct.
2850 Thus:
2851
2852     "$hash{"$foo/$bar"}"
2853
2854 or:
2855
2856     m/
2857       bar       # NOT a comment, this slash / terminated m//!
2858      /x
2859
2860 do not form legal quoted expressions.   The quoted part ends on the
2861 first C<"> and C</>, and the rest happens to be a syntax error.
2862 Because the slash that terminated C<m//> was followed by a C<SPACE>,
2863 the example above is not C<m//x>, but rather C<m//> with no C</x>
2864 modifier.  So the embedded C<#> is interpreted as a literal C<#>.
2865
2866 Also no attention is paid to C<\c\> (multichar control char syntax) during
2867 this search.  Thus the second C<\> in C<qq/\c\/> is interpreted as a part
2868 of C<\/>, and the following C</> is not recognized as a delimiter.
2869 Instead, use C<\034> or C<\x1c> at the end of quoted constructs.
2870
2871 =item Interpolation
2872 X<interpolation>
2873
2874 The next step is interpolation in the text obtained, which is now
2875 delimiter-independent.  There are multiple cases.
2876
2877 =over 4
2878
2879 =item C<<<'EOF'>
2880
2881 No interpolation is performed.
2882 Note that the combination C<\\> is left intact, since escaped delimiters
2883 are not available for here-docs.
2884
2885 =item  C<m''>, the pattern of C<s'''>
2886
2887 No interpolation is performed at this stage.
2888 Any backslashed sequences including C<\\> are treated at the stage
2889 to L</"parsing regular expressions">.
2890
2891 =item C<''>, C<q//>, C<tr'''>, C<y'''>, the replacement of C<s'''>
2892
2893 The only interpolation is removal of C<\> from pairs of C<\\>.
2894 Therefore C<"-"> in C<tr'''> and C<y'''> is treated literally
2895 as a hyphen and no character range is available.
2896 C<\1> in the replacement of C<s'''> does not work as C<$1>.
2897
2898 =item C<tr///>, C<y///>
2899
2900 No variable interpolation occurs.  String modifying combinations for
2901 case and quoting such as C<\Q>, C<\U>, and C<\E> are not recognized.
2902 The other escape sequences such as C<\200> and C<\t> and backslashed
2903 characters such as C<\\> and C<\-> are converted to appropriate literals.
2904 The character C<"-"> is treated specially and therefore C<\-> is treated
2905 as a literal C<"-">.
2906
2907 =item C<"">, C<``>, C<qq//>, C<qx//>, C<< <file*glob> >>, C<<<"EOF">
2908
2909 C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> (possibly paired with C<\E>) are
2910 converted to corresponding Perl constructs.  Thus, C<"$foo\Qbaz$bar">
2911 is converted to S<C<$foo . (quotemeta("baz" . $bar))>> internally.
2912 The other escape sequences such as C<\200> and C<\t> and backslashed
2913 characters such as C<\\> and C<\-> are replaced with appropriate
2914 expansions.
2915
2916 Let it be stressed that I<whatever falls between C<\Q> and C<\E>>
2917 is interpolated in the usual way.  Something like C<"\Q\\E"> has
2918 no C<\E> inside.  Instead, it has C<\Q>, C<\\>, and C<E>, so the
2919 result is the same as for C<"\\\\E">.  As a general rule, backslashes
2920 between C<\Q> and C<\E> may lead to counterintuitive results.  So,
2921 C<"\Q\t\E"> is converted to C<quotemeta("\t")>, which is the same
2922 as C<"\\\t"> (since TAB is not alphanumeric).  Note also that:
2923
2924   $str = '\t';
2925   return "\Q$str";
2926
2927 may be closer to the conjectural I<intention> of the writer of C<"\Q\t\E">.
2928
2929 Interpolated scalars and arrays are converted internally to the C<join> and
2930 C<"."> catenation operations.  Thus, S<C<"$foo XXX '@arr'">> becomes:
2931
2932   $foo . " XXX '" . (join $", @arr) . "'";
2933
2934 All operations above are performed simultaneously, left to right.
2935
2936 Because the result of S<C<"\Q I<STRING> \E">> has all metacharacters
2937 quoted, there is no way to insert a literal C<$> or C<@> inside a
2938 C<\Q\E> pair.  If protected by C<\>, C<$> will be quoted to become
2939 C<"\\\$">; if not, it is interpreted as the start of an interpolated
2940 scalar.
2941
2942 Note also that the interpolation code needs to make a decision on
2943 where the interpolated scalar ends.  For instance, whether
2944 S<C<< "a $x -> {c}" >>> really means:
2945
2946   "a " . $x . " -> {c}";
2947
2948 or:
2949
2950   "a " . $x -> {c};
2951
2952 Most of the time, the longest possible text that does not include
2953 spaces between components and which contains matching braces or
2954 brackets.  because the outcome may be determined by voting based
2955 on heuristic estimators, the result is not strictly predictable.
2956 Fortunately, it's usually correct for ambiguous cases.
2957
2958 =item the replacement of C<s///>
2959
2960 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F> and interpolation
2961 happens as with C<qq//> constructs.
2962
2963 It is at this step that C<\1> is begrudgingly converted to C<$1> in
2964 the replacement text of C<s///>, in order to correct the incorrigible
2965 I<sed> hackers who haven't picked up the saner idiom yet.  A warning
2966 is emitted if the S<C<use warnings>> pragma or the B<-w> command-line flag
2967 (that is, the C<$^W> variable) was set.
2968
2969 =item C<RE> in C<m?RE?>, C</RE/>, C<m/RE/>, C<s/RE/foo/>,
2970
2971 Processing of C<\Q>, C<\U>, C<\u>, C<\L>, C<\l>, C<\F>, C<\E>,
2972 and interpolation happens (almost) as with C<qq//> constructs.
2973
2974 Processing of C<\N{...}> is also done here, and compiled into an intermediate
2975 form for the regex compiler.  (This is because, as mentioned below, the regex
2976 compilation may be done at execution time, and C<\N{...}> is a compile-time
2977 construct.)
2978
2979 However any other combinations of C<\> followed by a character
2980 are not substituted but only skipped, in order to parse them
2981 as regular expressions at the following step.
2982 As C<\c> is skipped at this step, C<@> of C<\c@> in RE is possibly
2983 treated as an array symbol (for example C<@foo>),
2984 even though the same text in C<qq//> gives interpolation of C<\c@>.
2985
2986 Code blocks such as C<(?{BLOCK})> are handled by temporarily passing control
2987 back to the perl parser, in a similar way that an interpolated array
2988 subscript expression such as C<"foo$array[1+f("[xyz")]bar"> would be.
2989
2990 Moreover, inside C<(?{BLOCK})>, S<C<(?# comment )>>, and
2991 a C<#>-comment in a C</x>-regular expression, no processing is
2992 performed whatsoever.  This is the first step at which the presence
2993 of the C</x> modifier is relevant.
2994
2995 Interpolation in patterns has several quirks: C<$|>, C<$(>, C<$)>, C<@+>
2996 and C<@-> are not interpolated, and constructs C<$var[SOMETHING]> are
2997 voted (by several different estimators) to be either an array element
2998 or C<$var> followed by an RE alternative.  This is where the notation
2999 C<${arr[$bar]}> comes handy: C</${arr[0-9]}/> is interpreted as
3000 array element C<-9>, not as a regular expression from the variable
3001 C<$arr> followed by a digit, which would be the interpretation of
3002 C</$arr[0-9]/>.  Since voting among different estimators may occur,
3003 the result is not predictable.
3004
3005 The lack of processing of C<\\> creates specific restrictions on
3006 the post-processed text.  If the delimiter is C</>, one cannot get
3007 the combination C<\/> into the result of this step.  C</> will
3008 finish the regular expression, C<\/> will be stripped to C</> on
3009 the previous step, and C<\\/> will be left as is.  Because C</> is
3010 equivalent to C<\/> inside a regular expression, this does not
3011 matter unless the delimiter happens to be character special to the
3012 RE engine, such as in C<s*foo*bar*>, C<m[foo]>, or C<m?foo?>; or an
3013 alphanumeric char, as in:
3014
3015   m m ^ a \s* b mmx;
3016
3017 In the RE above, which is intentionally obfuscated for illustration, the
3018 delimiter is C<m>, the modifier is C<mx>, and after delimiter-removal the
3019 RE is the same as for S<C<m/ ^ a \s* b /mx>>.  There's more than one
3020 reason you're encouraged to restrict your delimiters to non-alphanumeric,
3021 non-whitespace choices.
3022
3023 =back
3024
3025 This step is the last one for all constructs except regular expressions,
3026 which are processed further.
3027
3028 =item parsing regular expressions
3029 X<regexp, parse>
3030
3031 Previous steps were performed during the compilation of Perl code,
3032 but this one happens at run time, although it may be optimized to
3033 be calculated at compile time if appropriate.  After preprocessing
3034 described above, and possibly after evaluation if concatenation,
3035 joining, casing translation, or metaquoting are involved, the
3036 resulting I<string> is passed to the RE engine for compilation.
3037
3038 Whatever happens in the RE engine might be better discussed in L<perlre>,
3039 but for the sake of continuity, we shall do so here.
3040
3041 This is another step where the presence of the C</x> modifier is
3042 relevant.  The RE engine scans the string from left to right and
3043 converts it into a finite automaton.
3044
3045 Backslashed characters are either replaced with corresponding
3046 literal strings (as with C<\{>), or else they generate special nodes
3047 in the finite automaton (as with C<\b>).  Characters special to the
3048 RE engine (such as C<|>) generate corresponding nodes or groups of
3049 nodes.  C<(?#...)> comments are ignored.  All the rest is either
3050 converted to literal strings to match, or else is ignored (as is
3051 whitespace and C<#>-style comments if C</x> is present).
3052
3053 Parsing of the bracketed character class construct, C<[...]>, is
3054 rather different than the rule used for the rest of the pattern.
3055 The terminator of this construct is found using the same rules as
3056 for finding the terminator of a C<{}>-delimited construct, the only
3057 exception being that C<]> immediately following C<[> is treated as
3058 though preceded by a backslash.
3059
3060 The terminator of runtime C<(?{...})> is found by temporarily switching
3061 control to the perl parser, which should stop at the point where the
3062 logically balancing terminating C<}> is found.
3063
3064 It is possible to inspect both the string given to RE engine and the
3065 resulting finite automaton.  See the arguments C<debug>/C<debugcolor>
3066 in the S<C<use L<re>>> pragma, as well as Perl's B<-Dr> command-line
3067 switch documented in L<perlrun/"Command Switches">.
3068
3069 =item Optimization of regular expressions
3070 X<regexp, optimization>
3071
3072 This step is listed for completeness only.  Since it does not change
3073 semantics, details of this step are not documented and are subject
3074 to change without notice.  This step is performed over the finite
3075 automaton that was generated during the previous pass.
3076
3077 It is at this stage that C<split()> silently optimizes C</^/> to
3078 mean C</^/m>.
3079
3080 =back
3081
3082 =head2 I/O Operators
3083 X<operator, i/o> X<operator, io> X<io> X<while> X<filehandle>
3084 X<< <> >> X<< <<>> >> X<@ARGV>
3085
3086 There are several I/O operators you should know about.
3087
3088 A string enclosed by backticks (grave accents) first undergoes
3089 double-quote interpolation.  It is then interpreted as an external
3090 command, and the output of that command is the value of the
3091 backtick string, like in a shell.  In scalar context, a single string
3092 consisting of all output is returned.  In list context, a list of
3093 values is returned, one per line of output.  (You can set C<$/> to use
3094 a different line terminator.)  The command is executed each time the
3095 pseudo-literal is evaluated.  The status value of the command is
3096 returned in C<$?> (see L<perlvar> for the interpretation of C<$?>).
3097 Unlike in B<csh>, no translation is done on the return data--newlines
3098 remain newlines.  Unlike in any of the shells, single quotes do not
3099 hide variable names in the command from interpretation.  To pass a
3100 literal dollar-sign through to the shell you need to hide it with a
3101 backslash.  The generalized form of backticks is C<qx//>, or you can
3102 call the L<perlfunc/readpipe> function.  (Because
3103 backticks always undergo shell expansion as well, see L<perlsec> for
3104 security concerns.)
3105 X<qx> X<`> X<``> X<backtick> X<glob>
3106
3107 In scalar context, evaluating a filehandle in angle brackets yields
3108 the next line from that file (the newline, if any, included), or
3109 C<undef> at end-of-file or on error.  When C<$/> is set to C<undef>
3110 (sometimes known as file-slurp mode) and the file is empty, it
3111 returns C<''> the first time, followed by C<undef> subsequently.
3112
3113 Ordinarily you must assign the returned value to a variable, but
3114 there is one situation where an automatic assignment happens.  If
3115 and only if the input symbol is the only thing inside the conditional
3116 of a C<while> statement (even if disguised as a C<for(;;)> loop),
3117 the value is automatically assigned to the global variable C<$_>,
3118 destroying whatever was there previously.  (This may seem like an
3119 odd thing to you, but you'll use the construct in almost every Perl
3120 script you write.)  The C<$_> variable is not implicitly localized.
3121 You'll have to put a S<C<local $_;>> before the loop if you want that
3122 to happen.  Furthermore, if the input symbol or an explicit assignment
3123 of the input symbol to a scalar is used as a C<while>/C<for> condition,
3124 then the condition actually tests for definedness of the expression's
3125 value, not for its regular truth value.
3126
3127 Thus the following lines are equivalent:
3128
3129     while (defined($_ = <STDIN>)) { print; }
3130     while ($_ = <STDIN>) { print; }
3131     while (<STDIN>) { print; }
3132     for (;<STDIN>;) { print; }
3133     print while defined($_ = <STDIN>);
3134     print while ($_ = <STDIN>);
3135     print while <STDIN>;
3136
3137 This also behaves similarly, but assigns to a lexical variable
3138 instead of to C<$_>:
3139
3140     while (my $line = <STDIN>) { print $line }
3141
3142 In these loop constructs, the assigned value (whether assignment
3143 is automatic or explicit) is then tested to see whether it is
3144 defined.  The defined test avoids problems where the line has a string
3145 value that would be treated as false by Perl; for example a "" or
3146 a C<"0"> with no trailing newline.  If you really mean for such values
3147 to terminate the loop, they should be tested for explicitly:
3148
3149     while (($_ = <STDIN>) ne '0') { ... }
3150     while (<STDIN>) { last unless $_; ... }
3151
3152 In other boolean contexts, C<< <I<FILEHANDLE>> >> without an
3153 explicit C<defined> test or comparison elicits a warning if the
3154 S<C<use warnings>> pragma or the B<-w>
3155 command-line switch (the C<$^W> variable) is in effect.
3156
3157 The filehandles STDIN, STDOUT, and STDERR are predefined.  (The
3158 filehandles C<stdin>, C<stdout>, and C<stderr> will also work except
3159 in packages, where they would be interpreted as local identifiers
3160 rather than global.)  Additional filehandles may be created with
3161 the C<open()> function, amongst others.  See L<perlopentut> and
3162 L<perlfunc/open> for details on this.
3163 X<stdin> X<stdout> X<sterr>
3164
3165 If a C<< <I<FILEHANDLE>> >> is used in a context that is looking for
3166 a list, a list comprising all input lines is returned, one line per
3167 list element.  It's easy to grow to a rather large data space this
3168 way, so use with care.
3169
3170 C<< <I<FILEHANDLE>> >>  may also be spelled C<readline(*I<FILEHANDLE>)>.
3171 See L<perlfunc/readline>.
3172
3173 The null filehandle C<< <> >> is special: it can be used to emulate the
3174 behavior of B<sed> and B<awk>, and any other Unix filter program
3175 that takes a list of filenames, doing the same to each line
3176 of input from all of them.  Input from C<< <> >> comes either from
3177 standard input, or from each file listed on the command line.  Here's
3178 how it works: the first time C<< <> >> is evaluated, the C<@ARGV> array is
3179 checked, and if it is empty, C<$ARGV[0]> is set to C<"-">, which when opened
3180 gives you standard input.  The C<@ARGV> array is then processed as a list
3181 of filenames.  The loop
3182
3183     while (<>) {
3184         ...                     # code for each line
3185     }
3186
3187 is equivalent to the following Perl-like pseudo code:
3188
3189     unshift(@ARGV, '-') unless @ARGV;
3190     while ($ARGV = shift) {
3191         open(ARGV, $ARGV);
3192         while (<ARGV>) {
3193             ...         # code for each line
3194         }
3195     }
3196
3197 except that it isn't so cumbersome to say, and will actually work.
3198 It really does shift the C<@ARGV> array and put the current filename
3199 into the C<$ARGV> variable.  It also uses filehandle I<ARGV>
3200 internally.  C<< <> >> is just a synonym for C<< <ARGV> >>, which
3201 is magical.  (The pseudo code above doesn't work because it treats
3202 C<< <ARGV> >> as non-magical.)
3203
3204 Since the null filehandle uses the two argument form of L<perlfunc/open>
3205 it interprets special characters, so if you have a script like this:
3206
3207     while (<>) {
3208         print;
3209     }
3210
3211 and call it with S<C<perl dangerous.pl 'rm -rfv *|'>>, it actually opens a
3212 pipe, executes the C<rm> command and reads C<rm>'s output from that pipe.
3213 If you want all items in C<@ARGV> to be interpreted as file names, you
3214 can use the module C<ARGV::readonly> from CPAN, or use the double bracket:
3215
3216     while (<<>>) {
3217         print;
3218     }
3219
3220 Using double angle brackets inside of a while causes the open to use the
3221 three argument form (with the second argument being C<< < >>), so all
3222 arguments in C<ARGV> are treated as literal filenames (including C<"-">).
3223 (Note that for convenience, if you use C<< <<>> >> and if C<@ARGV> is
3224 empty, it will still read from the standard input.)
3225
3226 You can modify C<@ARGV> before the first C<< <> >> as long as the array ends up
3227 containing the list of filenames you really want.  Line numbers (C<$.>)
3228 continue as though the input were one big happy file.  See the example
3229 in L<perlfunc/eof> for how to reset line numbers on each file.
3230
3231 If you want to set C<@ARGV> to your own list of files, go right ahead.
3232 This sets C<@ARGV> to all plain text files if no C<@ARGV> was given:
3233
3234     @ARGV = grep { -f && -T } glob('*') unless @ARGV;
3235
3236 You can even set them to pipe commands.  For example, this automatically
3237 filters compressed arguments through B<gzip>:
3238
3239     @ARGV = map { /\.(gz|Z)$/ ? "gzip -dc < $_ |" : $_ } @ARGV;
3240
3241 If you want to pass switches into your script, you can use one of the
3242 C<Getopts> modules or put a loop on the front like this:
3243
3244     while ($_ = $ARGV[0], /^-/) {
3245         shift;
3246         last if /^--$/;
3247         if (/^-D(.*)/) { $debug = $1 }
3248         if (/^-v/)     { $verbose++  }
3249         # ...           # other switches
3250     }
3251
3252     while (<>) {
3253         # ...           # code for each line
3254     }
3255
3256 The C<< <> >> symbol will return C<undef> for end-of-file only once.
3257 If you call it again after this, it will assume you are processing another
3258 C<@ARGV> list, and if you haven't set C<@ARGV>, will read input from STDIN.
3259
3260 If what the angle brackets contain is a simple scalar variable (for example,
3261 C<$foo>), then that variable contains the name of the
3262 filehandle to input from, or its typeglob, or a reference to the
3263 same.  For example:
3264
3265     $fh = \*STDIN;
3266     $line = <$fh>;
3267
3268 If what's within the angle brackets is neither a filehandle nor a simple
3269 scalar variable containing a filehandle name, typeglob, or typeglob
3270 reference, it is interpreted as a filename pattern to be globbed, and
3271 either a list of filenames or the next filename in the list is returned,
3272 depending on context.  This distinction is determined on syntactic
3273 grounds alone.  That means C<< <$x> >> is always a C<readline()> from
3274 an indirect handle, but C<< <$hash{key}> >> is always a C<glob()>.
3275 That's because C<$x> is a simple scalar variable, but C<$hash{key}> is
3276 not--it's a hash element.  Even C<< <$x > >> (note the extra space)
3277 is treated as C<glob("$x ")>, not C<readline($x)>.
3278
3279 One level of double-quote interpretation is done first, but you can't
3280 say C<< <$foo> >> because that's an indirect filehandle as explained
3281 in the previous paragraph.  (In older versions of Perl, programmers
3282 would insert curly brackets to force interpretation as a filename glob:
3283 C<< <${foo}> >>.  These days, it's considered cleaner to call the
3284 internal function directly as C<glob($foo)>, which is probably the right
3285 way to have done it in the first place.)  For example:
3286
3287     while (<*.c>) {
3288         chmod 0644, $_;
3289     }
3290
3291 is roughly equivalent to:
3292
3293     open(FOO, "echo *.c | tr -s ' \t\r\f' '\\012\\012\\012\\012'|");
3294     while (<FOO>) {
3295         chomp;
3296         chmod 0644, $_;
3297     }
3298
3299 except that the globbing is actually done internally using the standard
3300 C<L<File::Glob>> extension.  Of course, the shortest way to do the above is:
3301
3302     chmod 0644, <*.c>;
3303
3304 A (file)glob evaluates its (embedded) argument only when it is
3305 starting a new list.  All values must be read before it will start
3306 over.  In list context, this isn't important because you automatically
3307 get them all anyway.  However, in scalar context the operator returns
3308 the next value each time it's called, or C<undef> when the list has
3309 run out.  As with filehandle reads, an automatic C<defined> is
3310 generated when the glob occurs in the test part of a C<while>,
3311 because legal glob returns (for example,
3312 a file called F<0>) would otherwise
3313 terminate the loop.  Again, C<undef> is returned only once.  So if
3314 you're expecting a single value from a glob, it is much better to
3315 say
3316
3317     ($file) = <blurch*>;
3318
3319 than
3320
3321     $file = <blurch*>;
3322
3323 because the latter will alternate between returning a filename and
3324 returning false.
3325
3326 If you're trying to do variable interpolation, it's definitely better
3327 to use the C<glob()> function, because the older notation can cause people
3328 to become confused with the indirect filehandle notation.
3329
3330     @files = glob("$dir/*.[ch]");
3331     @files = glob($files[$i]);
3332
3333 If an angle-bracket-based globbing expression is used as the condition of
3334 a C<while> or C<for> loop, then it will be implicitly assigned to C<$_>.
3335 If either a globbing expression or an explicit assignment of a globbing
3336 expression to a scalar is used as a C<while>/C<for> condition, then
3337 the condition actually tests for definedness of the expression's value,
3338 not for its regular truth value.
3339
3340 =head2 Constant Folding
3341 X<constant folding> X<folding>
3342
3343 Like C, Perl does a certain amount of expression evaluation at
3344 compile time whenever it determines that all arguments to an
3345 operator are static and have no side effects.  In particular, string
3346 concatenation happens at compile time between literals that don't do
3347 variable substitution.  Backslash interpolation also happens at
3348 compile time.  You can say
3349
3350       'Now is the time for all'
3351     . "\n"
3352     .  'good men to come to.'
3353
3354 and this all reduces to one string internally.  Likewise, if
3355 you say
3356
3357     foreach $file (@filenames) {
3358         if (-s $file > 5 + 100 * 2**16) {  }
3359     }
3360
3361 the compiler precomputes the number which that expression
3362 represents so that the interpreter won't have to.
3363
3364 =head2 No-ops
3365 X<no-op> X<nop>
3366
3367 Perl doesn't officially have a no-op operator, but the bare constants
3368 C<0> and C<1> are special-cased not to produce a warning in void
3369 context, so you can for example safely do
3370
3371     1 while foo();
3372
3373 =head2 Bitwise String Operators
3374 X<operator, bitwise, string> X<&.> X<|.> X<^.> X<~.>
3375
3376 Bitstrings of any size may be manipulated by the bitwise operators
3377 (C<~ | & ^>).
3378
3379 If the operands to a binary bitwise op are strings of different
3380 sizes, B<|> and B<^> ops act as though the shorter operand had
3381 additional zero bits on the right, while the B<&> op acts as though
3382 the longer operand were truncated to the length of the shorter.
3383 The granularity for such extension or truncation is one or more
3384 bytes.
3385
3386     # ASCII-based examples
3387     print "j p \n" ^ " a h";            # prints "JAPH\n"
3388     print "JA" | "  ph\n";              # prints "japh\n"
3389     print "japh\nJunk" & '_____';       # prints "JAPH\n";
3390     print 'p N$' ^ " E<H\n";            # prints "Perl\n";
3391
3392 If you are intending to manipulate bitstrings, be certain that
3393 you're supplying bitstrings: If an operand is a number, that will imply
3394 a B<numeric> bitwise operation.  You may explicitly show which type of
3395 operation you intend by using C<""> or C<0+>, as in the examples below.
3396
3397     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3398     $foo = '150' |  105;        # yields 255
3399     $foo =  150  | '105';       # yields 255
3400     $foo = '150' | '105';       # yields string '155' (under ASCII)
3401
3402     $baz = 0+$foo & 0+$bar;     # both ops explicitly numeric
3403     $biz = "$foo" ^ "$bar";     # both ops explicitly stringy
3404
3405 This somewhat unpredictable behavior can be avoided with the "bitwise"
3406 feature, new in Perl 5.22.  You can enable it via S<C<use feature
3407 'bitwise'>> or C<use v5.28>.  Before Perl 5.28, it used to emit a warning
3408 in the C<"experimental::bitwise"> category.  Under this feature, the four
3409 standard bitwise operators (C<~ | & ^>) are always numeric.  Adding a dot
3410 after each operator (C<~. |. &. ^.>) forces it to treat its operands as
3411 strings:
3412
3413     use feature "bitwise";
3414     $foo =  150  |  105;        # yields 255  (0x96 | 0x69 is 0xFF)
3415     $foo = '150' |  105;        # yields 255
3416     $foo =  150  | '105';       # yields 255
3417     $foo = '150' | '105';       # yields 255
3418     $foo =  150  |. 105;        # yields string '155'
3419     $foo = '150' |. 105;        # yields string '155'
3420     $foo =  150  |.'105';       # yields string '155'
3421     $foo = '150' |.'105';       # yields string '155'
3422
3423     $baz = $foo &  $bar;        # both operands numeric
3424     $biz = $foo ^. $bar;        # both operands stringy
3425
3426 The assignment variants of these operators (C<&= |= ^= &.= |.= ^.=>)
3427 behave likewise under the feature.
3428
3429 It is a fatal error if an operand contains a character whose ordinal
3430 value is above 0xFF, and hence not expressible except in UTF-8.  The
3431 operation is performed on a non-UTF-8 copy for other operands encoded in
3432 UTF-8.  See L<perlunicode/Byte and Character Semantics>.
3433
3434 See L<perlfunc/vec> for information on how to manipulate individual bits
3435 in a bit vector.
3436
3437 =head2 Integer Arithmetic
3438 X<integer>
3439
3440 By default, Perl assumes that it must do most of its arithmetic in
3441 floating point.  But by saying
3442
3443     use integer;
3444
3445 you may tell the compiler to use integer operations
3446 (see L<integer> for a detailed explanation) from here to the end of
3447 the enclosing BLOCK.  An inner BLOCK may countermand this by saying
3448
3449     no integer;
3450
3451 which lasts until the end of that BLOCK.  Note that this doesn't
3452 mean everything is an integer, merely that Perl will use integer
3453 operations for arithmetic, comparison, and bitwise operators.  For
3454 example, even under S<C<use integer>>, if you take the C<sqrt(2)>, you'll
3455 still get C<1.4142135623731> or so.
3456
3457 Used on numbers, the bitwise operators (C<&> C<|> C<^> C<~> C<< << >>
3458 C<< >> >>) always produce integral results.  (But see also
3459 L</Bitwise String Operators>.)  However, S<C<use integer>> still has meaning for
3460 them.  By default, their results are interpreted as unsigned integers, but
3461 if S<C<use integer>> is in effect, their results are interpreted
3462 as signed integers.  For example, C<~0> usually evaluates to a large
3463 integral value.  However, S<C<use integer; ~0>> is C<-1> on two's-complement
3464 machines.
3465
3466 =head2 Floating-point Arithmetic
3467
3468 X<floating-point> X<floating point> X<float> X<real>
3469
3470 While S<C<use integer>> provides integer-only arithmetic, there is no
3471 analogous mechanism to provide automatic rounding or truncation to a
3472 certain number of decimal places.  For rounding to a certain number
3473 of digits, C<sprintf()> or C<printf()> is usually the easiest route.
3474 See L<perlfaq4>.
3475
3476 Floating-point numbers are only approximations to what a mathematician
3477 would call real numbers.  There are infinitely more reals than floats,
3478 so some corners must be cut.  For example:
3479
3480     printf "%.20g\n", 123456789123456789;
3481     #        produces 123456789123456784
3482
3483 Testing for exact floating-point equality or inequality is not a
3484 good idea.  Here's a (relatively expensive) work-around to compare
3485 whether two floating-point numbers are equal to a particular number of
3486 decimal places.  See Knuth, volume II, for a more robust treatment of
3487 this topic.
3488
3489     sub fp_equal {
3490         my ($X, $Y, $POINTS) = @_;
3491         my ($tX, $tY);
3492         $tX = sprintf("%.${POINTS}g", $X);
3493         $tY = sprintf("%.${POINTS}g", $Y);
3494         return $tX eq $tY;
3495     }
3496
3497 The POSIX module (part of the standard perl distribution) implements
3498 C<ceil()>, C<floor()>, and other mathematical and trigonometric functions.
3499 The C<L<Math::Complex>> module (part of the standard perl distribution)
3500 defines mathematical functions that work on both the reals and the
3501 imaginary numbers.  C<Math::Complex> is not as efficient as POSIX, but
3502 POSIX can't work with complex numbers.
3503
3504 Rounding in financial applications can have serious implications, and
3505 the rounding method used should be specified precisely.  In these
3506 cases, it probably pays not to trust whichever system rounding is
3507 being used by Perl, but to instead implement the rounding function you
3508 need yourself.
3509
3510 =head2 Bigger Numbers
3511 X<number, arbitrary precision>
3512
3513 The standard C<L<Math::BigInt>>, C<L<Math::BigRat>>, and
3514 C<L<Math::BigFloat>> modules,
3515 along with the C<bignum>, C<bigint>, and C<bigrat> pragmas, provide
3516 variable-precision arithmetic and overloaded operators, although
3517 they're currently pretty slow.  At the cost of some space and
3518 considerable speed, they avoid the normal pitfalls associated with
3519 limited-precision representations.
3520
3521         use 5.010;
3522         use bigint;  # easy interface to Math::BigInt
3523         $x = 123456789123456789;
3524         say $x * $x;
3525     +15241578780673678515622620750190521
3526
3527 Or with rationals:
3528
3529         use 5.010;
3530         use bigrat;
3531         $x = 3/22;
3532         $y = 4/6;
3533         say "x/y is ", $x/$y;
3534         say "x*y is ", $x*$y;
3535         x/y is 9/44
3536         x*y is 1/11
3537
3538 Several modules let you calculate with unlimited or fixed precision
3539 (bound only by memory and CPU time).  There
3540 are also some non-standard modules that
3541 provide faster implementations via external C libraries.
3542
3543 Here is a short, but incomplete summary:
3544
3545   Math::String           treat string sequences like numbers
3546   Math::FixedPrecision   calculate with a fixed precision
3547   Math::Currency         for currency calculations
3548   Bit::Vector            manipulate bit vectors fast (uses C)
3549   Math::BigIntFast       Bit::Vector wrapper for big numbers
3550   Math::Pari             provides access to the Pari C library
3551   Math::Cephes           uses the external Cephes C library (no
3552                          big numbers)
3553   Math::Cephes::Fraction fractions via the Cephes library
3554   Math::GMP              another one using an external C library
3555   Math::GMPz             an alternative interface to libgmp's big ints
3556   Math::GMPq             an interface to libgmp's fraction numbers
3557   Math::GMPf             an interface to libgmp's floating point numbers
3558
3559 Choose wisely.
3560
3561 =cut