Move Attribute::Handlers from ext/ to dist/
[perl.git] / Porting / makemeta
1 #!./perl -w
2 # this script must be run by the current perl to get perl's version right
3 #
4 # Create a META.yml file in the current directory. Must be run from the
5 # root directory of a perl source tree.
6
7 use strict;
8 use warnings;
9 use lib "Porting";
10
11 use File::Basename qw( dirname );
12
13 my $file = "META.yml";
14 die "$0: will not override $file, delete it first.\n" if -e $file;
15
16 use Maintainers qw(%Modules get_module_files get_module_pat);
17
18 my @CPAN  = grep { $Modules{$_}{CPAN} } keys %Modules;
19 my @files = map { get_module_files($_) } @CPAN;
20 my @dirs  = grep { -d $_ } map { get_module_pat($_) } @CPAN;
21
22 my %dirs;
23 @dirs{@dirs} = ();
24
25 my $files = join '', map { "    - $_\n" }
26   grep {
27     my $d = $_;
28     while(($d = dirname($d)) ne "."){
29       last if exists $dirs{$d};
30     }
31
32     # if $d is "." it means we tried every parent dir of the file and none
33     # of them were in the private list
34     
35     $d eq "."; 
36   }
37   sort { lc $a cmp lc $b } @files;
38
39 my $dirs  = join '', map { "    - $_\n" } sort { lc $a cmp lc $b } @dirs;
40
41 open my $fh, ">$file" or die "Can't open $file: $!";
42
43 print $fh <<"EOI";
44 name: perl
45 version: $]
46 abstract: Practical Extraction and Report Language
47 author: perl5-porters\@perl.org
48 license: perl
49 resources:
50   homepage: http://www.perl.org/
51   bugtracker: http://rt.perl.org/perlbug/
52   license: http://dev.perl.org/licenses/
53 distribution_type: core
54 generated_by: $0
55 no_index:
56   directory:
57 $dirs
58   file:
59 $files
60 EOI
61
62 close $fh;
63