5c71aaf79ab4c77c79fae86795297ea034ec1487
[perl.git] / ext / DynaLoader / DynaLoader_pm.PL
1 use Config;
2
3 sub to_string {
4     my ($value) = @_;
5     $value =~ s/\\/\\\\/g;
6     $value =~ s/'/\\'/g;
7     return "'$value'";
8 }
9
10 #
11 # subroutine expand_os_specific expands $^O-specific preprocessing information
12 # so that it will not be re-calculated at runtime in Dynaloader.pm
13 #
14 # Syntax of preprocessor should be kept extremely simple:
15 #  - directives are in double angle brackets <<...>>
16 #  - <<=string>> will be just evaluated
17 #  - for $^O-specific there are two forms:
18 #   <<$^O-eq-osname>>
19 #   <<$^O-ne-osname>>
20 #  this directive should be closed with respectively
21 #   <</$^O-eq-osname>>
22 #   <</$^O-ne-osname>>
23 #  construct <<|$^O-ne-osname>> means #else
24 #  nested <<$^O...>>-constructs are allowed but nested values must be for 
25 #   different OS-names!
26 #   
27 #  -- added by VKON, 03-10-2004 to separate $^O-specific between OSes
28 #     (so that Win32 never checks for $^O eq 'VMS' for example)
29 #
30 # The $^O tests test both for $^O and for $Config{osname}.
31 # The latter is better for some for cross-compilation setups.
32 #
33 sub expand_os_specific {
34     my $s = shift;
35     for ($s) {
36         s/<<=(.*?)>>/$1/gee;
37         s/<<\$\^O-(eq|ne)-(\w+)>>(.*?)<<\/\$\^O-\1-\2>>/
38           my ($op, $os, $expr) = ($1,$2,$3);
39           if ($op ne 'eq' and $op ne 'ne') {die "wrong eq-ne arg in $&"};
40           if ($expr =~ m[^(.*?)<<\|\$\^O-$op-$os>>(.*?)$]s) {
41               # #if;#else;#endif
42               my ($if,$el) = ($1,$2);
43               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
44                   $if
45               }
46               else {
47                   $el
48               }
49           }
50           else {
51               # #if;#endif
52               if (($op eq 'eq' and ($^O eq $os || $Config{osname} eq $os)) || ($op eq 'ne' and ($^O ne $os || $Config{osname} ne $os))) {
53                   $expr
54               }
55               else {
56                   ""
57               }
58           }
59         /ges;
60         if (/<<(=|\$\^O-)/) {die "bad <<\$^O-eq/ne-osname>> expression.".
61             " Unclosed brackets?";
62         }
63     }
64     $s;
65 }
66
67 unlink "DynaLoader.pm" if -f "DynaLoader.pm";
68 open OUT, ">DynaLoader.pm" or die $!;
69 print OUT <<'EOT';
70
71 # Generated from DynaLoader_pm.PL
72
73 package DynaLoader;
74
75 #   And Gandalf said: 'Many folk like to know beforehand what is to
76 #   be set on the table; but those who have laboured to prepare the
77 #   feast like to keep their secret; for wonder makes the words of
78 #   praise louder.'
79
80 #   (Quote from Tolkien suggested by Anno Siegel.)
81 #
82 # See pod text at end of file for documentation.
83 # See also ext/DynaLoader/README in source tree for other information.
84 #
85 # Tim.Bunce@ig.co.uk, August 1994
86
87 BEGIN {
88     $VERSION = '1.24';
89 }
90
91 use Config;
92
93 # enable debug/trace messages from DynaLoader perl code
94 $dl_debug = $ENV{PERL_DL_DEBUG} || 0 unless defined $dl_debug;
95
96 #
97 # Flags to alter dl_load_file behaviour.  Assigned bits:
98 #   0x01  make symbols available for linking later dl_load_file's.
99 #         (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
100 #         (ignored under VMS; effect is built-in to image linking)
101 #
102 # This is called as a class method $module->dl_load_flags.  The
103 # definition here will be inherited and result on "default" loading
104 # behaviour unless a sub-class of DynaLoader defines its own version.
105 #
106
107 sub dl_load_flags { 0x00 }
108
109 EOT
110
111 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
112     print OUT "(\$dl_dlext, \$dl_so, \$dlsrc) = (",
113               to_string($Config{'dlext'}), ",",
114               to_string($Config{'so'}), ",",
115               to_string($Config{'dlsrc'}), ")\n;" ;
116 }
117 else {
118     print OUT <<'EOT';
119 ($dl_dlext, $dl_so, $dlsrc) = @Config::Config{qw(dlext so dlsrc)};
120 EOT
121 }
122
123 print OUT expand_os_specific(<<'EOT');
124
125 <<$^O-eq-VMS>>
126 # Some systems need special handling to expand file specifications
127 # (VMS support by Charles Bailey <bailey@HMIVAX.HUMGEN.UPENN.EDU>)
128 # See dl_expandspec() for more details. Should be harmless but
129 # inefficient to define on systems that don't need it.
130 $Is_VMS    = $^O eq 'VMS';
131 <</$^O-eq-VMS>>
132 $do_expand = <<$^O-eq-VMS>>1<<|$^O-eq-VMS>>0<</$^O-eq-VMS>>;
133
134 @dl_require_symbols = ();       # names of symbols we need
135 @dl_resolve_using   = ();       # names of files to link with
136 @dl_library_path    = ();       # path to look for files
137
138 #XSLoader.pm may have added elements before we were required
139 #@dl_shared_objects  = ();       # shared objects for symbols we have 
140 #@dl_librefs         = ();       # things we have loaded
141 #@dl_modules         = ();       # Modules we have loaded
142
143 # This is a fix to support DLD's unfortunate desire to relink -lc
144 @dl_resolve_using = dl_findfile('-lc') if $dlsrc eq "dl_dld.xs";
145
146 EOT
147
148 my $cfg_dl_library_path = <<'EOT';
149 push(@dl_library_path, split(' ', $Config::Config{libpth}));
150 EOT
151
152 sub dquoted_comma_list {
153     join(", ", map {'"'.quotemeta($_).'"'} @_);
154 }
155
156 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
157     eval $cfg_dl_library_path;
158     if (!$ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
159         my $dl_library_path = dquoted_comma_list(@dl_library_path);
160         print OUT <<EOT;
161 # The below \@dl_library_path has been expanded (%Config) in Perl build time.
162
163 \@dl_library_path = ($dl_library_path);
164
165 EOT
166     }
167 }
168 else {
169     print OUT <<EOT;
170 # Initialise \@dl_library_path with the 'standard' library path
171 # for this platform as determined by Configure.
172
173 $cfg_dl_library_path
174
175 EOT
176 }
177
178 my $ldlibpthname;
179 my $ldlibpthname_defined;
180 my $pthsep;
181
182 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS}) {
183     $ldlibpthname         = to_string($Config::Config{ldlibpthname});
184     $ldlibpthname_defined = to_string(defined $Config::Config{ldlibpthname} ? 1 : 0);
185     $pthsep               = to_string($Config::Config{path_sep});
186 }
187 else {
188     $ldlibpthname         = q($Config::Config{ldlibpthname});
189     $ldlibpthname_defined = q(defined $Config::Config{ldlibpthname});
190     $pthsep               = q($Config::Config{path_sep});
191 }
192 print OUT <<EOT;
193 my \$ldlibpthname         = $ldlibpthname;
194 my \$ldlibpthname_defined = $ldlibpthname_defined;
195 my \$pthsep               = $pthsep;
196
197 EOT
198
199 my $env_dl_library_path = <<'EOT';
200 if ($ldlibpthname_defined &&
201     exists $ENV{$ldlibpthname}) {
202     push(@dl_library_path, split(/$pthsep/, $ENV{$ldlibpthname}));
203 }
204
205 # E.g. HP-UX supports both its native SHLIB_PATH *and* LD_LIBRARY_PATH.
206
207 if ($ldlibpthname_defined &&
208     $ldlibpthname ne 'LD_LIBRARY_PATH' &&
209     exists $ENV{LD_LIBRARY_PATH}) {
210     push(@dl_library_path, split(/$pthsep/, $ENV{LD_LIBRARY_PATH}));
211 }
212 EOT
213
214 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
215     eval $env_dl_library_path;
216 }
217 else {
218     print OUT <<EOT;
219 # Add to \@dl_library_path any extra directories we can gather from environment
220 # during runtime.
221
222 $env_dl_library_path
223
224 EOT
225 }
226
227 if ($ENV{PERL_BUILD_EXPAND_CONFIG_VARS} && $ENV{PERL_BUILD_EXPAND_ENV_VARS}) {
228     my $dl_library_path = dquoted_comma_list(@dl_library_path);
229     print OUT <<EOT;
230 # The below \@dl_library_path has been expanded (%Config, %ENV)
231 # in Perl build time.
232
233 \@dl_library_path = ($dl_library_path);
234
235 EOT
236 }
237
238 if ( $Config::Config{d_libname_unique} ) {
239     printf OUT <<'EOT', length($Config::Config{dlext}) + 1;
240 sub mod2fname {
241     my $parts = shift;
242     my $so_len = %d;
243     my $name_max = 255; # No easy way to get this here
244     
245     my $libname = "PL_" .  join("__", @$parts);
246     
247     return $libname if (length($libname)+$so_len) <= $name_max;
248     
249     # It's too darned big, so we need to go strip. We use the same
250     # algorithm as xsubpp does. First, strip out doubled __
251     $libname =~ s/__/_/g;
252     return $libname if (length($libname)+$so_len) <= $name_max;
253     
254     # Strip duplicate letters
255     1 while $libname =~ s/(.)\1/\U$1/i;
256     return $libname if (length($libname)+$so_len) <= $name_max;
257     
258     # Still too long. Truncate.
259     $libname = substr($libname, 0, $name_max - $so_len);
260     return $libname;
261 }
262 EOT
263 }
264
265 # following long string contains $^O-specific stuff, which is factored out
266 print OUT expand_os_specific(<<'EOT');
267 # No prizes for guessing why we don't say 'bootstrap DynaLoader;' here.
268 # NOTE: All dl_*.xs (including dl_none.xs) define a dl_error() XSUB
269 boot_DynaLoader('DynaLoader') if defined(&boot_DynaLoader) &&
270                                 !defined(&dl_error);
271
272 if ($dl_debug) {
273     print STDERR "DynaLoader.pm loaded (@INC, @dl_library_path)\n";
274     print STDERR "DynaLoader not linked into this perl\n"
275             unless defined(&boot_DynaLoader);
276 }
277
278 1; # End of main code
279
280
281 sub croak   { require Carp; Carp::croak(@_)   }
282
283 sub bootstrap_inherit {
284     my $module = $_[0];
285     local *isa = *{"$module\::ISA"};
286     local @isa = (@isa, 'DynaLoader');
287     # Cannot goto due to delocalization.  Will report errors on a wrong line?
288     bootstrap(@_);
289 }
290
291 sub bootstrap {
292     # use local vars to enable $module.bs script to edit values
293     local(@args) = @_;
294     local($module) = $args[0];
295     local(@dirs, $file);
296
297     unless ($module) {
298         require Carp;
299         Carp::confess("Usage: DynaLoader::bootstrap(module)");
300     }
301
302     # A common error on platforms which don't support dynamic loading.
303     # Since it's fatal and potentially confusing we give a detailed message.
304     croak("Can't load module $module, dynamic loading not available in this perl.\n".
305         "  (You may need to build a new perl executable which either supports\n".
306         "  dynamic loading or has the $module module statically linked into it.)\n")
307         unless defined(&dl_load_file);
308
309
310     <<$^O-eq-os2>>
311     # Can dynaload, but cannot dynaload Perl modules...
312     die 'Dynaloaded Perl modules are not available in this build of Perl' if $OS2::is_static;
313
314     <</$^O-eq-os2>>
315     my @modparts = split(/::/,$module);
316     my $modfname = $modparts[-1];
317
318     # Some systems have restrictions on files names for DLL's etc.
319     # mod2fname returns appropriate file base name (typically truncated)
320     # It may also edit @modparts if required.
321     $modfname = &mod2fname(\@modparts) if defined &mod2fname;
322
323     <<$^O-eq-NetWare>>
324     # Truncate the module name to 8.3 format for NetWare
325         if ((length($modfname) > 8)) {
326                 $modfname = substr($modfname, 0, 8);
327         }
328     <</$^O-eq-NetWare>>
329
330     my $modpname = join('/',@modparts);
331
332     print STDERR "DynaLoader::bootstrap for $module ",
333                        "(auto/$modpname/$modfname.$dl_dlext)\n"
334         if $dl_debug;
335
336     foreach (@INC) {
337         <<$^O-eq-VMS>>chop($_ = VMS::Filespec::unixpath($_));<</$^O-eq-VMS>>
338             my $dir = "$_/auto/$modpname";
339         
340         next unless -d $dir; # skip over uninteresting directories
341         
342         # check for common cases to avoid autoload of dl_findfile
343         my $try = "$dir/$modfname.$dl_dlext";
344         last if $file = ($do_expand) ? dl_expandspec($try) : ((-f $try) && $try);
345         
346         # no luck here, save dir for possible later dl_findfile search
347         push @dirs, $dir;
348     }
349     # last resort, let dl_findfile have a go in all known locations
350     $file = dl_findfile(map("-L$_",@dirs,@INC), $modfname) unless $file;
351
352     croak("Can't locate loadable object for module $module in \@INC (\@INC contains: @INC)")
353         unless $file;   # wording similar to error from 'require'
354
355     <<$^O-eq-VMS>>$file = uc($file) if $Config::Config{d_vms_case_sensitive_symbols};<</$^O-eq-VMS>>
356     my $bootname = "boot_$module";
357     $bootname =~ s/\W/_/g;
358     @dl_require_symbols = ($bootname);
359
360     # Execute optional '.bootstrap' perl script for this module.
361     # The .bs file can be used to configure @dl_resolve_using etc to
362     # match the needs of the individual module on this architecture.
363     my $bs = $file;
364     $bs =~ s/(\.\w+)?(;\d*)?$/\.bs/; # look for .bs 'beside' the library
365     if (-s $bs) { # only read file if it's not empty
366         print STDERR "BS: $bs ($^O, $dlsrc)\n" if $dl_debug;
367         eval { do $bs; };
368         warn "$bs: $@\n" if $@;
369     }
370
371     my $boot_symbol_ref;
372
373     <<$^O-eq-darwin>>
374     if ($boot_symbol_ref = dl_find_symbol(0, $bootname)) {
375         goto boot; #extension library has already been loaded, e.g. darwin
376     }
377     <</$^O-eq-darwin>>
378
379     # Many dynamic extension loading problems will appear to come from
380     # this section of code: XYZ failed at line 123 of DynaLoader.pm.
381     # Often these errors are actually occurring in the initialisation
382     # C code of the extension XS file. Perl reports the error as being
383     # in this perl code simply because this was the last perl code
384     # it executed.
385
386     my $libref = dl_load_file($file, $module->dl_load_flags) or
387         croak("Can't load '$file' for module $module: ".dl_error());
388
389     push(@dl_librefs,$libref);  # record loaded object
390
391     my @unresolved = dl_undef_symbols();
392     if (@unresolved) {
393         require Carp;
394         Carp::carp("Undefined symbols present after loading $file: @unresolved\n");
395     }
396
397     $boot_symbol_ref = dl_find_symbol($libref, $bootname) or
398          croak("Can't find '$bootname' symbol in $file\n");
399
400     push(@dl_modules, $module); # record loaded module
401
402   boot:
403     my $xs = dl_install_xsub("${module}::bootstrap", $boot_symbol_ref, $file);
404
405     # See comment block above
406
407         push(@dl_shared_objects, $file); # record files loaded
408
409     &$xs(@args);
410 }
411
412 sub dl_findfile {
413     # Read ext/DynaLoader/DynaLoader.doc for detailed information.
414     # This function does not automatically consider the architecture
415     # or the perl library auto directories.
416     my (@args) = @_;
417     my (@dirs,  $dir);   # which directories to search
418     my (@found);         # full paths to real files we have found
419     #my $dl_ext= <<=to_string($Config::Config{'dlext'})>>; # $Config::Config{'dlext'} suffix for perl extensions
420     #my $dl_so = <<=to_string($Config::Config{'so'})>>; # $Config::Config{'so'} suffix for shared libraries
421
422     print STDERR "dl_findfile(@args)\n" if $dl_debug;
423
424     # accumulate directories but process files as they appear
425     arg: foreach(@args) {
426         #  Special fast case: full filepath requires no search
427         <<$^O-eq-VMS>>
428         if (m%[:>/\]]% && -f $_) {
429             push(@found,dl_expandspec(VMS::Filespec::vmsify($_)));
430             last arg unless wantarray;
431             next;
432         }
433         <</$^O-eq-VMS>>
434         <<$^O-ne-VMS>>
435         if (m:/: && -f $_) {
436             push(@found,$_);
437             last arg unless wantarray;
438             next;
439         }
440         <</$^O-ne-VMS>>
441
442         # Deal with directories first:
443         #  Using a -L prefix is the preferred option (faster and more robust)
444         if (m:^-L:) { s/^-L//; push(@dirs, $_); next; }
445
446         #  Otherwise we try to try to spot directories by a heuristic
447         #  (this is a more complicated issue than it first appears)
448         if (m:/: && -d $_) {   push(@dirs, $_); next; }
449
450         <<$^O-eq-VMS>>
451         # VMS: we may be using native VMS directory syntax instead of
452         # Unix emulation, so check this as well
453         if (/[:>\]]/ && -d $_) {   push(@dirs, $_); next; }
454         <</$^O-eq-VMS>>
455
456         #  Only files should get this far...
457         my(@names, $name);    # what filenames to look for
458         if (m:-l: ) {          # convert -lname to appropriate library name
459             s/-l//;
460             push(@names,"lib$_.$dl_so");
461             push(@names,"lib$_.a");
462         } else {                # Umm, a bare name. Try various alternatives:
463             # these should be ordered with the most likely first
464             push(@names,"$_.$dl_dlext")    unless m/\.$dl_dlext$/o;
465             push(@names,"$_.$dl_so")     unless m/\.$dl_so$/o;
466             <<$^O-eq-cygwin>>
467             push(@names,"cyg$_.$dl_so")  unless m:/:;
468             <</$^O-eq-cygwin>>
469             push(@names,"lib$_.$dl_so")  unless m:/:;
470             push(@names,"$_.a")          if !m/\.a$/ and $dlsrc eq "dl_dld.xs";
471             push(@names, $_);
472         }
473         my $dirsep = '/';
474         <<$^O-eq-symbian>>
475         $dirsep = '\\';
476         if ($0 =~ /^([a-z]):/i) {
477             my $drive = $1;
478             @dirs = map { "$drive:$_" } @dirs;
479             @dl_library_path = map { "$drive:$_" } @dl_library_path;
480         }
481         <</$^O-eq-symbian>>
482         foreach $dir (@dirs, @dl_library_path) {
483             next unless -d $dir;
484             <<$^O-eq-VMS>>
485             chop($dir = VMS::Filespec::unixpath($dir));
486             <</$^O-eq-VMS>>
487             foreach $name (@names) {
488                 my($file) = "$dir$dirsep$name";
489                 print STDERR " checking in $dir for $name\n" if $dl_debug;
490                 $file = ($do_expand) ? dl_expandspec($file) : (-f $file && $file);
491                 #$file = _check_file($file);
492                 if ($file) {
493                     push(@found, $file);
494                     next arg; # no need to look any further
495                 }
496             }
497         }
498     }
499     if ($dl_debug) {
500         foreach(@dirs) {
501             print STDERR " dl_findfile ignored non-existent directory: $_\n" unless -d $_;
502         }
503         print STDERR "dl_findfile found: @found\n";
504     }
505     return $found[0] unless wantarray;
506     @found;
507 }
508
509
510 <<$^O-eq-VMS>>
511 # dl_expandspec should be defined in dl_vms.xs
512 <<|$^O-eq-VMS>>
513 sub dl_expandspec {
514     my($spec) = @_;
515     # Optional function invoked if DynaLoader.pm sets $do_expand.
516     # Most systems do not require or use this function.
517     # Some systems may implement it in the dl_*.xs file in which case
518     # this Perl version should be excluded at build time.
519
520     # This function is designed to deal with systems which treat some
521     # 'filenames' in a special way. For example VMS 'Logical Names'
522     # (something like unix environment variables - but different).
523     # This function should recognise such names and expand them into
524     # full file paths.
525     # Must return undef if $spec is invalid or file does not exist.
526
527     my $file = $spec; # default output to input
528
529         return undef unless -f $file;
530     print STDERR "dl_expandspec($spec) => $file\n" if $dl_debug;
531     $file;
532 }
533 <</$^O-eq-VMS>>
534
535 sub dl_find_symbol_anywhere
536 {
537     my $sym = shift;
538     my $libref;
539     foreach $libref (@dl_librefs) {
540         my $symref = dl_find_symbol($libref,$sym);
541         return $symref if $symref;
542     }
543     return undef;
544 }
545
546 __END__
547
548 =head1 NAME
549
550 DynaLoader - Dynamically load C libraries into Perl code
551
552 =head1 SYNOPSIS
553
554     package YourPackage;
555     require DynaLoader;
556     @ISA = qw(... DynaLoader ...);
557     bootstrap YourPackage;
558
559     # optional method for 'global' loading
560     sub dl_load_flags { 0x01 }     
561
562
563 =head1 DESCRIPTION
564
565 This document defines a standard generic interface to the dynamic
566 linking mechanisms available on many platforms.  Its primary purpose is
567 to implement automatic dynamic loading of Perl modules.
568
569 This document serves as both a specification for anyone wishing to
570 implement the DynaLoader for a new platform and as a guide for
571 anyone wishing to use the DynaLoader directly in an application.
572
573 The DynaLoader is designed to be a very simple high-level
574 interface that is sufficiently general to cover the requirements
575 of SunOS, HP-UX, NeXT, Linux, VMS and other platforms.
576
577 It is also hoped that the interface will cover the needs of OS/2, NT
578 etc and also allow pseudo-dynamic linking (using C<ld -A> at runtime).
579
580 It must be stressed that the DynaLoader, by itself, is practically
581 useless for accessing non-Perl libraries because it provides almost no
582 Perl-to-C 'glue'.  There is, for example, no mechanism for calling a C
583 library function or supplying arguments.  A C::DynaLib module
584 is available from CPAN sites which performs that function for some
585 common system types.  And since the year 2000, there's also Inline::C,
586 a module that allows you to write Perl subroutines in C.  Also available
587 from your local CPAN site.
588
589 DynaLoader Interface Summary
590
591   @dl_library_path
592   @dl_resolve_using
593   @dl_require_symbols
594   $dl_debug
595   $dl_dlext
596   @dl_librefs
597   @dl_modules
598   @dl_shared_objects
599                                                   Implemented in:
600   bootstrap($modulename)                               Perl
601   @filepaths = dl_findfile(@names)                     Perl
602   $flags = $modulename->dl_load_flags                  Perl
603   $symref  = dl_find_symbol_anywhere($symbol)          Perl
604
605   $libref  = dl_load_file($filename, $flags)           C
606   $status  = dl_unload_file($libref)                   C
607   $symref  = dl_find_symbol($libref, $symbol)          C
608   @symbols = dl_undef_symbols()                        C
609   dl_install_xsub($name, $symref [, $filename])        C
610   $message = dl_error                                  C
611
612 =over 4
613
614 =item @dl_library_path
615
616 The standard/default list of directories in which dl_findfile() will
617 search for libraries etc.  Directories are searched in order:
618 $dl_library_path[0], [1], ... etc
619
620 @dl_library_path is initialised to hold the list of 'normal' directories
621 (F</usr/lib>, etc) determined by B<Configure> (C<$Config{'libpth'}>).  This should
622 ensure portability across a wide range of platforms.
623
624 @dl_library_path should also be initialised with any other directories
625 that can be determined from the environment at runtime (such as
626 LD_LIBRARY_PATH for SunOS).
627
628 After initialisation @dl_library_path can be manipulated by an
629 application using push and unshift before calling dl_findfile().
630 Unshift can be used to add directories to the front of the search order
631 either to save search time or to override libraries with the same name
632 in the 'normal' directories.
633
634 The load function that dl_load_file() calls may require an absolute
635 pathname.  The dl_findfile() function and @dl_library_path can be
636 used to search for and return the absolute pathname for the
637 library/object that you wish to load.
638
639 =item @dl_resolve_using
640
641 A list of additional libraries or other shared objects which can be
642 used to resolve any undefined symbols that might be generated by a
643 later call to load_file().
644
645 This is only required on some platforms which do not handle dependent
646 libraries automatically.  For example the Socket Perl extension
647 library (F<auto/Socket/Socket.so>) contains references to many socket
648 functions which need to be resolved when it's loaded.  Most platforms
649 will automatically know where to find the 'dependent' library (e.g.,
650 F</usr/lib/libsocket.so>).  A few platforms need to be told the
651 location of the dependent library explicitly.  Use @dl_resolve_using
652 for this.
653
654 Example usage:
655
656     @dl_resolve_using = dl_findfile('-lsocket');
657
658 =item @dl_require_symbols
659
660 A list of one or more symbol names that are in the library/object file
661 to be dynamically loaded.  This is only required on some platforms.
662
663 =item @dl_librefs
664
665 An array of the handles returned by successful calls to dl_load_file(),
666 made by bootstrap, in the order in which they were loaded.
667 Can be used with dl_find_symbol() to look for a symbol in any of
668 the loaded files.
669
670 =item @dl_modules
671
672 An array of module (package) names that have been bootstrap'ed.
673
674 =item @dl_shared_objects
675
676 An array of file names for the shared objects that were loaded.
677
678 =item dl_error()
679
680 Syntax:
681
682     $message = dl_error();
683
684 Error message text from the last failed DynaLoader function.  Note
685 that, similar to errno in unix, a successful function call does not
686 reset this message.
687
688 Implementations should detect the error as soon as it occurs in any of
689 the other functions and save the corresponding message for later
690 retrieval.  This will avoid problems on some platforms (such as SunOS)
691 where the error message is very temporary (e.g., dlerror()).
692
693 =item $dl_debug
694
695 Internal debugging messages are enabled when $dl_debug is set true.
696 Currently setting $dl_debug only affects the Perl side of the
697 DynaLoader.  These messages should help an application developer to
698 resolve any DynaLoader usage problems.
699
700 $dl_debug is set to C<$ENV{'PERL_DL_DEBUG'}> if defined.
701
702 For the DynaLoader developer/porter there is a similar debugging
703 variable added to the C code (see dlutils.c) and enabled if Perl was
704 built with the B<-DDEBUGGING> flag.  This can also be set via the
705 PERL_DL_DEBUG environment variable.  Set to 1 for minimal information or
706 higher for more.
707
708 =item $dl_dlext
709
710 When specified (localised) in a module's F<.pm> file, indicates the extension
711 which the module's loadable object will have. For example:
712
713     local $DynaLoader::dl_dlext = 'unusual_ext';
714
715 would indicate that the module's loadable object has an extension of
716 C<unusual_ext> instead of the more usual C<$Config{dlext}>.  NOTE: This also
717 requires that the module's F<Makefile.PL> specify (in C<WriteMakefile()>):
718
719     DLEXT => 'unusual_ext',
720
721 =item dl_findfile()
722
723 Syntax:
724
725     @filepaths = dl_findfile(@names)
726
727 Determine the full paths (including file suffix) of one or more
728 loadable files given their generic names and optionally one or more
729 directories.  Searches directories in @dl_library_path by default and
730 returns an empty list if no files were found.
731
732 Names can be specified in a variety of platform independent forms.  Any
733 names in the form B<-lname> are converted into F<libname.*>, where F<.*> is
734 an appropriate suffix for the platform.
735
736 If a name does not already have a suitable prefix and/or suffix then
737 the corresponding file will be searched for by trying combinations of
738 prefix and suffix appropriate to the platform: "$name.o", "lib$name.*"
739 and "$name".
740
741 If any directories are included in @names they are searched before
742 @dl_library_path.  Directories may be specified as B<-Ldir>.  Any other
743 names are treated as filenames to be searched for.
744
745 Using arguments of the form C<-Ldir> and C<-lname> is recommended.
746
747 Example: 
748
749     @dl_resolve_using = dl_findfile(qw(-L/usr/5lib -lposix));
750
751
752 =item dl_expandspec()
753
754 Syntax:
755
756     $filepath = dl_expandspec($spec)
757
758 Some unusual systems, such as VMS, require special filename handling in
759 order to deal with symbolic names for files (i.e., VMS's Logical Names).
760
761 To support these systems a dl_expandspec() function can be implemented
762 either in the F<dl_*.xs> file or code can be added to the dl_expandspec()
763 function in F<DynaLoader.pm>.  See F<DynaLoader_pm.PL> for more information.
764
765 =item dl_load_file()
766
767 Syntax:
768
769     $libref = dl_load_file($filename, $flags)
770
771 Dynamically load $filename, which must be the path to a shared object
772 or library.  An opaque 'library reference' is returned as a handle for
773 the loaded object.  Returns undef on error.
774
775 The $flags argument to alters dl_load_file behaviour.  
776 Assigned bits:
777
778  0x01  make symbols available for linking later dl_load_file's.
779        (only known to work on Solaris 2 using dlopen(RTLD_GLOBAL))
780        (ignored under VMS; this is a normal part of image linking)
781
782 (On systems that provide a handle for the loaded object such as SunOS
783 and HPUX, $libref will be that handle.  On other systems $libref will
784 typically be $filename or a pointer to a buffer containing $filename.
785 The application should not examine or alter $libref in any way.)
786
787 This is the function that does the real work.  It should use the
788 current values of @dl_require_symbols and @dl_resolve_using if required.
789
790     SunOS: dlopen($filename)
791     HP-UX: shl_load($filename)
792     Linux: dld_create_reference(@dl_require_symbols); dld_link($filename)
793     NeXT:  rld_load($filename, @dl_resolve_using)
794     VMS:   lib$find_image_symbol($filename,$dl_require_symbols[0])
795
796 (The dlopen() function is also used by Solaris and some versions of
797 Linux, and is a common choice when providing a "wrapper" on other
798 mechanisms as is done in the OS/2 port.)
799
800 =item dl_unload_file()
801
802 Syntax:
803
804     $status = dl_unload_file($libref)
805
806 Dynamically unload $libref, which must be an opaque 'library reference' as
807 returned from dl_load_file.  Returns one on success and zero on failure.
808 This function is optional and may not necessarily be provided on all platforms.
809
810 If it is defined and perl is compiled with the C macro C<DL_UNLOAD_ALL_AT_EXIT>
811 defined, then it is called automatically when the interpreter exits for
812 every shared object or library loaded by DynaLoader::bootstrap.  All such
813 library references are stored in @dl_librefs by DynaLoader::Bootstrap as it
814 loads the libraries.  The files are unloaded in last-in, first-out order.
815
816 This unloading is usually necessary when embedding a shared-object perl (e.g.
817 one configured with -Duseshrplib) within a larger application, and the perl
818 interpreter is created and destroyed several times within the lifetime of the
819 application.  In this case it is possible that the system dynamic linker will
820 unload and then subsequently reload the shared libperl without relocating any
821 references to it from any files DynaLoaded by the previous incarnation of the
822 interpreter.  As a result, any shared objects opened by DynaLoader may point to
823 a now invalid 'ghost' of the libperl shared object, causing apparently random
824 memory corruption and crashes.  This behaviour is most commonly seen when using
825 Apache and mod_perl built with the APXS mechanism.
826
827     SunOS: dlclose($libref)
828     HP-UX: ???
829     Linux: ???
830     NeXT:  ???
831     VMS:   ???
832
833 (The dlclose() function is also used by Solaris and some versions of
834 Linux, and is a common choice when providing a "wrapper" on other
835 mechanisms as is done in the OS/2 port.)
836
837 =item dl_load_flags()
838
839 Syntax:
840
841     $flags = dl_load_flags $modulename;
842
843 Designed to be a method call, and to be overridden by a derived class
844 (i.e. a class which has DynaLoader in its @ISA).  The definition in
845 DynaLoader itself returns 0, which produces standard behavior from
846 dl_load_file().
847
848 =item dl_find_symbol()
849
850 Syntax:
851
852     $symref = dl_find_symbol($libref, $symbol)
853
854 Return the address of the symbol $symbol or C<undef> if not found.  If the
855 target system has separate functions to search for symbols of different
856 types then dl_find_symbol() should search for function symbols first and
857 then other types.
858
859 The exact manner in which the address is returned in $symref is not
860 currently defined.  The only initial requirement is that $symref can
861 be passed to, and understood by, dl_install_xsub().
862
863     SunOS: dlsym($libref, $symbol)
864     HP-UX: shl_findsym($libref, $symbol)
865     Linux: dld_get_func($symbol) and/or dld_get_symbol($symbol)
866     NeXT:  rld_lookup("_$symbol")
867     VMS:   lib$find_image_symbol($libref,$symbol)
868
869
870 =item dl_find_symbol_anywhere()
871
872 Syntax:
873
874     $symref = dl_find_symbol_anywhere($symbol)
875
876 Applies dl_find_symbol() to the members of @dl_librefs and returns
877 the first match found.
878
879 =item dl_undef_symbols()
880
881 Example
882
883     @symbols = dl_undef_symbols()
884
885 Return a list of symbol names which remain undefined after load_file().
886 Returns C<()> if not known.  Don't worry if your platform does not provide
887 a mechanism for this.  Most do not need it and hence do not provide it,
888 they just return an empty list.
889
890
891 =item dl_install_xsub()
892
893 Syntax:
894
895     dl_install_xsub($perl_name, $symref [, $filename])
896
897 Create a new Perl external subroutine named $perl_name using $symref as
898 a pointer to the function which implements the routine.  This is simply
899 a direct call to newXSUB().  Returns a reference to the installed
900 function.
901
902 The $filename parameter is used by Perl to identify the source file for
903 the function if required by die(), caller() or the debugger.  If
904 $filename is not defined then "DynaLoader" will be used.
905
906
907 =item bootstrap()
908
909 Syntax:
910
911 bootstrap($module [...])
912
913 This is the normal entry point for automatic dynamic loading in Perl.
914
915 It performs the following actions:
916
917 =over 8
918
919 =item *
920
921 locates an auto/$module directory by searching @INC
922
923 =item *
924
925 uses dl_findfile() to determine the filename to load
926
927 =item *
928
929 sets @dl_require_symbols to C<("boot_$module")>
930
931 =item *
932
933 executes an F<auto/$module/$module.bs> file if it exists
934 (typically used to add to @dl_resolve_using any files which
935 are required to load the module on the current platform)
936
937 =item *
938
939 calls dl_load_flags() to determine how to load the file.
940
941 =item *
942
943 calls dl_load_file() to load the file
944
945 =item *
946
947 calls dl_undef_symbols() and warns if any symbols are undefined
948
949 =item *
950
951 calls dl_find_symbol() for "boot_$module"
952
953 =item *
954
955 calls dl_install_xsub() to install it as "${module}::bootstrap"
956
957 =item *
958
959 calls &{"${module}::bootstrap"} to bootstrap the module (actually
960 it uses the function reference returned by dl_install_xsub for speed)
961
962 =back
963
964 All arguments to bootstrap() are passed to the module's bootstrap function.
965 The default code generated by F<xsubpp> expects $module [, $version]
966 If the optional $version argument is not given, it defaults to
967 C<$XS_VERSION // $VERSION> in the module's symbol table. The default code
968 compares the Perl-space version with the version of the compiled XS code,
969 and croaks with an error if they do not match.
970
971 =back
972
973
974 =head1 AUTHOR
975
976 Tim Bunce, 11 August 1994.
977
978 This interface is based on the work and comments of (in no particular
979 order): Larry Wall, Robert Sanders, Dean Roehrich, Jeff Okamoto, Anno
980 Siegel, Thomas Neumann, Paul Marquess, Charles Bailey, myself and others.
981
982 Larry Wall designed the elegant inherited bootstrap mechanism and
983 implemented the first Perl 5 dynamic loader using it.
984
985 Solaris global loading added by Nick Ing-Simmons with design/coding
986 assistance from Tim Bunce, January 1996.
987
988 =cut
989 EOT
990
991 close OUT or die $!;
992