Cwd::fastcwd in File::Find
[perl.git] / pod / perldata.pod
1 =head1 NAME
2
3 perldata - Perl data types
4
5 =head1 DESCRIPTION
6
7 =head2 Variable names
8
9 Perl has three data structures: scalars, arrays of scalars, and
10 associative arrays of scalars, known as "hashes".  Normal arrays are
11 indexed by number, starting with 0.  (Negative subscripts count from
12 the end.)  Hash arrays are indexed by string.
13
14 Values are usually referred to by name (or through a named reference).
15 The first character of the name tells you to what sort of data
16 structure it refers.  The rest of the name tells you the particular
17 value to which it refers.  Most often, it consists of a single
18 I<identifier>, that is, a string beginning with a letter or underscore,
19 and containing letters, underscores, and digits.  In some cases, it
20 may be a chain of identifiers, separated by C<::> (or by C<'>, but
21 that's deprecated); all but the last are interpreted as names of
22 packages, in order to locate the namespace in which to look
23 up the final identifier (see L<perlmod/Packages> for details).
24 It's possible to substutite for a simple identifier an expression
25 which produces a reference to the value at runtime; this is
26 described in more detail below, and in L<perlref>.
27
28 There are also special variables whose names don't follow these
29 rules, so that they don't accidentally collide with one of your
30 normal variables.  Strings which match parenthesized parts of a
31 regular expression are saved under names containing only digits after
32 the C<$> (see L<perlop> and L<perlre>).  In addition, several special
33 variables which provide windows into the inner working of Perl have names
34 containing punctuation characters (see L<perlvar>).
35
36 Scalar values are always named with '$', even when referring to a scalar
37 that is part of an array.  It works like the English word "the".  Thus
38 we have:
39
40     $days               # the simple scalar value "days"
41     $days[28]           # the 29th element of array @days
42     $days{'Feb'}        # the 'Feb' value from hash %days
43     $#days              # the last index of array @days
44
45 but entire arrays or array slices are denoted by '@', which works much like
46 the word "these" or "those":
47
48     @days               # ($days[0], $days[1],... $days[n])
49     @days[3,4,5]        # same as @days[3..5]
50     @days{'a','c'}      # same as ($days{'a'},$days{'c'})
51
52 and entire hashes are denoted by '%':
53
54     %days               # (key1, val1, key2, val2 ...)
55
56 In addition, subroutines are named with an initial '&', though this is
57 optional when it's otherwise unambiguous (just as "do" is often
58 redundant in English).  Symbol table entries can be named with an
59 initial '*', but you don't really care about that yet.
60
61 Every variable type has its own namespace.  You can, without fear of
62 conflict, use the same name for a scalar variable, an array, or a hash
63 (or, for that matter, a filehandle, a subroutine name, or a label).
64 This means that $foo and @foo are two different variables.  It also
65 means that C<$foo[1]> is a part of @foo, not a part of $foo.  This may
66 seem a bit weird, but that's okay, because it is weird.
67
68 Since variable and array references always start with '$', '@', or '%',
69 the "reserved" words aren't in fact reserved with respect to variable
70 names.  (They ARE reserved with respect to labels and filehandles,
71 however, which don't have an initial special character.  You can't have
72 a filehandle named "log", for instance.  Hint: you could say
73 C<open(LOG,'logfile')> rather than C<open(log,'logfile')>.  Using uppercase
74 filehandles also improves readability and protects you from conflict
75 with future reserved words.)  Case I<IS> significant--"FOO", "Foo" and
76 "foo" are all different names.  Names that start with a letter or
77 underscore may also contain digits and underscores.
78
79 It is possible to replace such an alphanumeric name with an expression
80 that returns a reference to an object of that type.  For a description
81 of this, see L<perlref>.
82
83 Names that start with a digit may only contain more digits.  Names
84 which do not start with a letter, underscore,  or digit are limited to
85 one character, e.g.  C<$%> or C<$$>.  (Most of these one character names
86 have a predefined significance to Perl.  For instance, C<$$> is the
87 current process id.)
88
89 =head2 Context
90
91 The interpretation of operations and values in Perl sometimes depends
92 on the requirements of the context around the operation or value.
93 There are two major contexts: scalar and list.  Certain operations
94 return list values in contexts wanting a list, and scalar values
95 otherwise.  (If this is true of an operation it will be mentioned in
96 the documentation for that operation.)  In other words, Perl overloads
97 certain operations based on whether the expected return value is
98 singular or plural.  (Some words in English work this way, like "fish"
99 and "sheep".)
100
101 In a reciprocal fashion, an operation provides either a scalar or a
102 list context to each of its arguments.  For example, if you say
103
104     int( <STDIN> )
105
106 the integer operation provides a scalar context for the <STDIN>
107 operator, which responds by reading one line from STDIN and passing it
108 back to the integer operation, which will then find the integer value
109 of that line and return that.  If, on the other hand, you say
110
111     sort( <STDIN> )
112
113 then the sort operation provides a list context for <STDIN>, which
114 will proceed to read every line available up to the end of file, and
115 pass that list of lines back to the sort routine, which will then
116 sort those lines and return them as a list to whatever the context
117 of the sort was.
118
119 Assignment is a little bit special in that it uses its left argument to
120 determine the context for the right argument.  Assignment to a scalar
121 evaluates the righthand side in a scalar context, while assignment to
122 an array or array slice evaluates the righthand side in a list
123 context.  Assignment to a list also evaluates the righthand side in a
124 list context.
125
126 User defined subroutines may choose to care whether they are being
127 called in a scalar or list context, but most subroutines do not
128 need to care, because scalars are automatically interpolated into
129 lists.  See L<perlfunc/wantarray>.
130
131 =head2 Scalar values
132
133 All data in Perl is a scalar or an array of scalars or a hash of scalars.
134 Scalar variables may contain various kinds of singular data, such as
135 numbers, strings, and references.  In general, conversion from one form to
136 another is transparent.  (A scalar may not contain multiple values, but
137 may contain a reference to an array or hash containing multiple values.)
138 Because of the automatic conversion of scalars, operations and functions
139 that return scalars don't need to care (and, in fact, can't care) whether
140 the context is looking for a string or a number.
141
142 Scalars aren't necessarily one thing or another.  There's no place to
143 declare a scalar variable to be of type "string", or of type "number", or
144 type "filehandle", or anything else.  Perl is a contextually polymorphic
145 language whose scalars can be strings, numbers, or references (which
146 includes objects).  While strings and numbers are considered pretty
147 much the same thing for nearly all purposes, references are strongly-typed
148 uncastable pointers with built-in reference-counting and destructor
149 invocation.
150
151 A scalar value is interpreted as TRUE in the Boolean sense if it is not
152 the null string or the number 0 (or its string equivalent, "0").  The
153 Boolean context is just a special kind of scalar context.  
154
155 There are actually two varieties of null scalars: defined and
156 undefined.  Undefined null scalars are returned when there is no real
157 value for something, such as when there was an error, or at end of
158 file, or when you refer to an uninitialized variable or element of an
159 array.  An undefined null scalar may become defined the first time you
160 use it as if it were defined, but prior to that you can use the
161 defined() operator to determine whether the value is defined or not.
162
163 To find out whether a given string is a valid non-zero number, it's usually
164 enough to test it against both numeric 0 and also lexical "0" (although
165 this will cause B<-w> noises).  That's because strings that aren't
166 numbers count as 0, just as they do in I<awk>:
167
168     if ($str == 0 && $str ne "0")  {
169         warn "That doesn't look like a number";
170     } 
171
172 That's usually preferable because otherwise you won't treat IEEE notations
173 like C<NaN> or C<Infinity> properly.  At other times you might prefer to
174 use a regular expression to check whether data is numeric.  See L<perlre>
175 for details on regular expressions.
176
177     warn "has nondigits"        if     /\D/;
178     warn "not a whole number"   unless /^\d+$/;
179     warn "not an integer"       unless /^[+-]?\d+$/     
180     warn "not a decimal number" unless /^[+-]?\d+\.?\d*$/ 
181     warn "not a C float" 
182         unless /^([+-]?)(?=\d|\.\d)\d*(\.\d*)?([Ee]([+-]?\d+))?$/;
183
184 The length of an array is a scalar value.  You may find the length of
185 array @days by evaluating C<$#days>, as in B<csh>.  (Actually, it's not
186 the length of the array, it's the subscript of the last element, since
187 there is (ordinarily) a 0th element.)  Assigning to C<$#days> changes the
188 length of the array.  Shortening an array by this method destroys
189 intervening values.  Lengthening an array that was previously shortened
190 I<NO LONGER> recovers the values that were in those elements.  (It used to
191 in Perl 4, but we had to break this to make sure destructors were
192 called when expected.)  You can also gain some measure of efficiency by
193 preextending an array that is going to get big.  (You can also extend
194 an array by assigning to an element that is off the end of the array.)
195 You can truncate an array down to nothing by assigning the null list ()
196 to it.  The following are equivalent:
197
198     @whatever = ();
199     $#whatever = $[ - 1;
200
201 If you evaluate a named array in a scalar context, it returns the length of
202 the array.  (Note that this is not true of lists, which return the
203 last value, like the C comma operator.)  The following is always true:
204
205     scalar(@whatever) == $#whatever - $[ + 1;
206
207 Version 5 of Perl changed the semantics of $[: files that don't set
208 the value of $[ no longer need to worry about whether another
209 file changed its value.  (In other words, use of $[ is deprecated.)
210 So in general you can just assume that
211
212     scalar(@whatever) == $#whatever + 1;
213
214 Some programmers choose to use an explicit conversion so nothing's
215 left to doubt:
216
217     $element_count = scalar(@whatever);
218
219 If you evaluate a hash in a scalar context, it returns a value which is
220 true if and only if the hash contains any key/value pairs.  (If there
221 are any key/value pairs, the value returned is a string consisting of
222 the number of used buckets and the number of allocated buckets, separated
223 by a slash.  This is pretty much only useful to find out whether Perl's
224 (compiled in) hashing algorithm is performing poorly on your data set.
225 For example, you stick 10,000 things in a hash, but evaluating %HASH in
226 scalar context reveals "1/16", which means only one out of sixteen buckets
227 has been touched, and presumably contains all 10,000 of your items.  This
228 isn't supposed to happen.)
229
230 =head2 Scalar value constructors
231
232 Numeric literals are specified in any of the customary floating point or
233 integer formats:
234
235     12345
236     12345.67
237     .23E-10
238     0xffff              # hex
239     0377                # octal
240     4_294_967_296       # underline for legibility
241
242 String literals are usually delimited by either single or double quotes.  They
243 work much like shell quotes:  double-quoted string literals are subject
244 to backslash and variable substitution; single-quoted strings are not
245 (except for "C<\'>" and "C<\\>").  The usual Unix backslash rules apply for making
246 characters such as newline, tab, etc., as well as some more exotic
247 forms.  See L<perlop/qq> for a list.
248
249 You can also embed newlines directly in your strings, i.e. they can end
250 on a different line than they begin.  This is nice, but if you forget
251 your trailing quote, the error will not be reported until Perl finds
252 another line containing the quote character, which may be much further
253 on in the script.  Variable substitution inside strings is limited to
254 scalar variables, arrays, and array slices.  (In other words,
255 names beginning with $ or @, followed by an optional bracketed
256 expression as a subscript.)  The following code segment prints out "The
257 price is $100."
258
259     $Price = '$100';    # not interpreted
260     print "The price is $Price.\n";     # interpreted
261
262 As in some shells, you can put curly brackets around the name to
263 delimit it from following alphanumerics.  In fact, an identifier
264 within such curlies is forced to be a string, as is any single
265 identifier within a hash subscript.  Our earlier example,
266
267     $days{'Feb'}
268
269 can be written as
270
271     $days{Feb}
272
273 and the quotes will be assumed automatically.  But anything more complicated
274 in the subscript will be interpreted as an expression.
275
276 Note that a
277 single-quoted string must be separated from a preceding word by a
278 space, since single quote is a valid (though deprecated) character in
279 a variable name (see L<perlmod/Packages>).
280
281 Two special literals are __LINE__ and __FILE__, which represent the
282 current line number and filename at that point in your program.  They
283 may only be used as separate tokens; they will not be interpolated into
284 strings.  In addition, the token __END__ may be used to indicate the
285 logical end of the script before the actual end of file.  Any following
286 text is ignored, but may be read via the DATA filehandle.  (The DATA
287 filehandle may read data only from the main script, but not from any
288 required file or evaluated string.)  The two control characters ^D and
289 ^Z are synonyms for __END__ (or __DATA__ in a module; see L<SelfLoader> for 
290 details on __DATA__).
291
292 A word that has no other interpretation in the grammar will
293 be treated as if it were a quoted string.  These are known as
294 "barewords".  As with filehandles and labels, a bareword that consists
295 entirely of lowercase letters risks conflict with future reserved
296 words, and if you use the B<-w> switch, Perl will warn you about any
297 such words.  Some people may wish to outlaw barewords entirely.  If you
298 say
299
300     use strict 'subs';
301
302 then any bareword that would NOT be interpreted as a subroutine call
303 produces a compile-time error instead.  The restriction lasts to the
304 end of the enclosing block.  An inner block may countermand this 
305 by saying C<no strict 'subs'>.
306
307 Array variables are interpolated into double-quoted strings by joining all
308 the elements of the array with the delimiter specified in the C<$">
309 variable ($LIST_SEPARATOR in English), space by default.  The following
310 are equivalent:
311
312     $temp = join($",@ARGV);
313     system "echo $temp";
314
315     system "echo @ARGV";
316
317 Within search patterns (which also undergo double-quotish substitution)
318 there is a bad ambiguity:  Is C</$foo[bar]/> to be interpreted as
319 C</${foo}[bar]/> (where C<[bar]> is a character class for the regular
320 expression) or as C</${foo[bar]}/> (where C<[bar]> is the subscript to array
321 @foo)?  If @foo doesn't otherwise exist, then it's obviously a
322 character class.  If @foo exists, Perl takes a good guess about C<[bar]>,
323 and is almost always right.  If it does guess wrong, or if you're just
324 plain paranoid, you can force the correct interpretation with curly
325 brackets as above.
326
327 A line-oriented form of quoting is based on the shell "here-doc" syntax.
328 Following a C<E<lt>E<lt>> you specify a string to terminate the quoted material,
329 and all lines following the current line down to the terminating string
330 are the value of the item.  The terminating string may be either an
331 identifier (a word), or some quoted text.  If quoted, the type of
332 quotes you use determines the treatment of the text, just as in regular
333 quoting.  An unquoted identifier works like double quotes.  There must
334 be no space between the C<E<lt>E<lt>> and the identifier.  (If you put a space it
335 will be treated as a null identifier, which is valid, and matches the
336 first blank line.)  The terminating string must appear by itself 
337 (unquoted and with no surrounding whitespace) on the terminating line.
338
339         print <<EOF;    
340     The price is $Price.
341     EOF
342
343         print <<"EOF";  # same as above
344     The price is $Price.
345     EOF
346
347         print <<`EOC`;  # execute commands
348     echo hi there
349     echo lo there
350     EOC
351
352         print <<"foo", <<"bar"; # you can stack them
353     I said foo.
354     foo
355     I said bar.
356     bar
357
358         myfunc(<<"THIS", 23, <<'THAT');
359     Here's a line
360     or two.
361     THIS
362     and here another.
363     THAT
364
365 Just don't forget that you have to put a semicolon on the end 
366 to finish the statement, as Perl doesn't know you're not going to 
367 try to do this:
368
369         print <<ABC
370     179231
371     ABC
372         + 20;
373
374
375 =head2 List value constructors
376
377 List values are denoted by separating individual values by commas
378 (and enclosing the list in parentheses where precedence requires it):
379
380     (LIST)
381
382 In a context not requiring a list value, the value of the list
383 literal is the value of the final element, as with the C comma operator.
384 For example,
385
386     @foo = ('cc', '-E', $bar);
387
388 assigns the entire list value to array foo, but
389
390     $foo = ('cc', '-E', $bar);
391
392 assigns the value of variable bar to variable foo.  Note that the value
393 of an actual array in a scalar context is the length of the array; the
394 following assigns to $foo the value 3:
395
396     @foo = ('cc', '-E', $bar);
397     $foo = @foo;                # $foo gets 3
398
399 You may have an optional comma before the closing parenthesis of an
400 list literal, so that you can say:
401
402     @foo = (
403         1,
404         2,
405         3,
406     );
407
408 LISTs do automatic interpolation of sublists.  That is, when a LIST is
409 evaluated, each element of the list is evaluated in a list context, and
410 the resulting list value is interpolated into LIST just as if each
411 individual element were a member of LIST.  Thus arrays lose their
412 identity in a LIST--the list
413
414     (@foo,@bar,&SomeSub)
415
416 contains all the elements of @foo followed by all the elements of @bar,
417 followed by all the elements returned by the subroutine named SomeSub when
418 it's called in a list context.
419 To make a list reference that does I<NOT> interpolate, see L<perlref>.
420
421 The null list is represented by ().  Interpolating it in a list
422 has no effect.  Thus ((),(),()) is equivalent to ().  Similarly,
423 interpolating an array with no elements is the same as if no
424 array had been interpolated at that point.
425
426 A list value may also be subscripted like a normal array.  You must
427 put the list in parentheses to avoid ambiguity.  Examples:
428
429     # Stat returns list value.
430     $time = (stat($file))[8];
431
432     # SYNTAX ERROR HERE.
433     $time = stat($file)[8];  # OOPS, FORGOT PARENS
434
435     # Find a hex digit.
436     $hexdigit = ('a','b','c','d','e','f')[$digit-10];
437
438     # A "reverse comma operator".
439     return (pop(@foo),pop(@foo))[0];
440
441 Lists may be assigned to if and only if each element of the list
442 is legal to assign to:
443
444     ($a, $b, $c) = (1, 2, 3);
445
446     ($map{'red'}, $map{'blue'}, $map{'green'}) = (0x00f, 0x0f0, 0xf00);
447
448 Array assignment in a scalar context returns the number of elements
449 produced by the expression on the right side of the assignment:
450
451     $x = (($foo,$bar) = (3,2,1));       # set $x to 3, not 2
452     $x = (($foo,$bar) = f());           # set $x to f()'s return count
453
454 This is very handy when you want to do a list assignment in a Boolean
455 context, since most list functions return a null list when finished,
456 which when assigned produces a 0, which is interpreted as FALSE.
457
458 The final element may be an array or a hash:
459
460     ($a, $b, @rest) = split;
461     local($a, $b, %rest) = @_;
462
463 You can actually put an array or hash anywhere in the list, but the first one
464 in the list will soak up all the values, and anything after it will get
465 a null value.  This may be useful in a local() or my().
466
467 A hash literal contains pairs of values to be interpreted
468 as a key and a value:
469
470     # same as map assignment above
471     %map = ('red',0x00f,'blue',0x0f0,'green',0xf00);
472
473 While literal lists and named arrays are usually interchangeable, that's
474 not the case for hashes.  Just because you can subscript a list value like
475 a normal array does not mean that you can subscript a list value as a
476 hash.  Likewise, hashes included as parts of other lists (including
477 parameters lists and return lists from functions) always flatten out into
478 key/value pairs.  That's why it's good to use references sometimes.
479
480 It is often more readable to use the C<=E<gt>> operator between key/value
481 pairs.  The C<=E<gt>> operator is mostly just a more visually distinctive
482 synonym for a comma, but it also arranges for its left-hand operand to be
483 interpreted as a string, if it's a bareword which would be a legal identifier.
484 This makes it nice for initializing hashes:
485
486     %map = (
487                  red   => 0x00f,
488                  blue  => 0x0f0,
489                  green => 0xf00,
490    );
491
492 or for initializing hash references to be used as records:
493
494     $rec = {
495                 witch => 'Mable the Merciless',
496                 cat   => 'Fluffy the Ferocious',
497                 date  => '10/31/1776',
498     };
499
500 or for using call-by-named-parameter to complicated functions:
501
502    $field = $query->radio_group( 
503                name      => 'group_name',
504                values    => ['eenie','meenie','minie'],
505                default   => 'meenie',
506                linebreak => 'true',
507                labels    => \%labels
508    );
509
510 Note that just because a hash is initialized in that order doesn't
511 mean that it comes out in that order.  See L<perlfunc/sort> for examples
512 of how to arrange for an output ordering.
513
514 =head2 Typeglobs and FileHandles
515
516 Perl uses an internal type called a I<typeglob> to hold an entire
517 symbol table entry.  The type prefix of a typeglob is a C<*>, because
518 it represents all types.  This used to be the preferred way to 
519 pass arrays and hashes by reference into a function, but now that
520 we have real references, this is seldom needed.
521
522 One place where you still use typeglobs (or references thereto)
523 is for passing or storing filehandles.  If you want to save away
524 a filehandle, do it this way:
525
526     $fh = *STDOUT;
527
528 or perhaps as a real reference, like this:
529
530     $fh = \*STDOUT;
531
532 This is also the way to create a local filehandle.  For example:
533
534     sub newopen {
535         my $path = shift;
536         local *FH;  # not my!
537         open (FH, $path) || return undef;
538         return \*FH;
539     }
540     $fh = newopen('/etc/passwd');
541
542 See L<perlref>, L<perlsub>, and L<perlmod/"Symbols Tables"> for more
543 discussion on typeglobs.  See L<perlfunc/open> for other ways of
544 generating filehandles.