Revert change 33326
[perl.git] / installperl
1 #!./perl
2
3 BEGIN {
4     require 5.004;
5     chdir '..' if !-d 'lib' and -d '../lib';
6     @INC = 'lib';
7     $ENV{PERL5LIB} = 'lib';
8 }
9
10 BEGIN {
11     use Config;
12     if ($Config{userelocatableinc}) {
13         # This might be a considered a hack. Need to get information about the
14         # configuration from Config.pm *before* Config.pm expands any .../
15         # prefixes.
16         #
17         # So we set $^X to pretend that we're the already installed perl, so
18         # Config.pm doesits ... expansion off that location.
19
20         my $location = $Config{initialinstalllocation};
21         die <<'OS' unless defined $location;
22 $Config{initialinstalllocation} is not defined - can't install a relocatable
23 perl without this.
24 OS
25         $^X = "$location/perl";
26         # And then remove all trace of ever having loaded Config.pm, so that
27         # it will reload with the revised $^X
28         undef %Config::;
29         delete $INC{"Config.pm"};
30         delete $INC{"Config_heavy.pl"};
31         # You never saw us. We weren't here.
32     }
33 }
34
35 use strict;
36 my ($Is_VMS, $Is_W32, $Is_OS2, $Is_Cygwin, $Is_Darwin,
37     $nonono, $dostrip, $versiononly, $silent, $verbose, $force,
38     $otherperls, $archname, $Is_NetWare, $nwinstall, $nopods);
39 use vars qw /$depth/;
40
41 BEGIN {
42     $Is_VMS = $^O eq 'VMS';
43     $Is_W32 = $^O eq 'MSWin32';
44     $Is_OS2 = $^O eq 'os2';
45     $Is_Cygwin = $^O eq 'cygwin';
46     $Is_Darwin = $^O eq 'darwin';
47     if ($Is_VMS) { eval 'use VMS::Filespec;' }
48 }
49
50 my $scr_ext = ($Is_VMS ? '.Com' : $Is_W32 ? '.bat' : '');
51
52 use File::Find;
53 use File::Compare;
54 use File::Copy ();
55 use File::Path ();
56 use ExtUtils::Packlist;
57 use Cwd;
58 use Config;
59 use subs qw(unlink link chmod);
60
61 if ($Config{d_umask}) {
62     umask(022); # umasks like 077 aren't that useful for installations
63 }
64
65 $Is_NetWare = $Config{osname} eq 'NetWare';
66 if ($Is_NetWare) {
67     $Is_W32 = 0;
68     $scr_ext = '.pl';
69 }
70
71 # override the ones in the rest of the script
72 sub mkpath {
73     File::Path::mkpath(@_) unless $nonono;
74 }
75
76 my $mainperldir = "/usr/bin";
77 my $exe_ext = $Config{exe_ext};
78
79 # Allow ``make install PERLNAME=something_besides_perl'':
80 my $perl = defined($ENV{PERLNAME}) ? $ENV{PERLNAME} : 'perl';
81
82 # This is the base used for versioned names, like "perl5.6.0".
83 # It's separate because a common use of $PERLNAME is to install
84 # perl as "perl5", if that's used as base for versioned files you
85 # get "perl55.6.0".
86 my $perl_verbase = defined($ENV{PERLNAME_VERBASE})
87                     ? $ENV{PERLNAME_VERBASE}
88                     : $perl;
89 my $dbg = '';
90 my $ndbg = '';
91 if ( $Is_VMS ) {
92     if ( defined $Config{usevmsdebug} ) {
93         if ( $Config{usevmsdebug} eq 'define' ) {
94             $dbg = 'dbg';
95             $ndbg = 'ndbg';
96         }
97     }
98 }
99
100 $otherperls = 1;
101 my $destdir = '';
102 while (@ARGV) {
103     $nonono = 1 if $ARGV[0] eq '-n';
104     $dostrip = 1 if $ARGV[0] eq '-s';
105     $versiononly = 1 if $ARGV[0] eq '-v';
106     $versiononly = 0 if $ARGV[0] eq '+v';
107     $silent = 1 if $ARGV[0] eq '-S';
108     $otherperls = 0 if $ARGV[0] eq '-o';
109     $force = 1 if $ARGV[0] eq '-f';
110     $verbose = 1 if $ARGV[0] eq '-V' || $ARGV [0] eq '-n';
111     $archname = 1 if $ARGV[0] eq '-A';
112     $nwinstall = 1 if $ARGV[0] eq '-netware';
113     $nopods = 1 if $ARGV[0] eq '-p';
114     $destdir = $1 if $ARGV[0] =~ /^-?-destdir=(.*)$/;
115     if ($ARGV[0] eq '-?' or $ARGV[0] =~ /^-?-h/) {
116         print <<"EOT";
117 Usage $0: [switches]
118   -n        Don't actually run any commands; just print them.
119   -s        Run strip on installed binaries.
120   -v        Only install perl as a binary with the version number in the name.
121             (Override whatever config.sh says)
122   +v        Install perl as "perl" and as a binary with the version number in
123             the name.  (Override whatever config.sh says)
124   -S        Silent mode.
125   -f        Force installation (don't check if same version is there)
126   -o        Skip checking for other copies of perl in your PATH.
127   -V        Verbose mode.
128   -A        Also install perl with the architecture's name in the perl binary's
129             name.
130   -p        Don't install the pod files. [This will break use diagnostics;]
131   -netware  Install correctly on a Netware server.
132   -destdir  Prefix installation directories by this string.
133 EOT
134         exit;
135     }
136     shift;
137 }
138
139 $versiononly = 1 if $Config{versiononly} && !defined $versiononly;
140 my (@scripts, @tolink);
141 open SCRIPTS, "utils.lst" or die "Can't open utils.lst: $!";
142 while (<SCRIPTS>) {
143     next if /^#/;
144     s/\s*#\s*pod\s*=.*//; # install script regardless of pod location
145     next if /a2p/; # a2p is binary, to be installed separately
146     chomp;
147     if (/(\S*)\s*#\s*link\s*=\s*(\S*)/) {
148         push @scripts, $1;
149         push @tolink, [$1, $2];
150     } else {
151         push @scripts, $_;
152     }
153 }
154 close SCRIPTS;
155
156 if ($scr_ext) { @scripts = map { "$_$scr_ext" } @scripts; }
157
158 my @pods = $nopods ? () : (<pod/*.pod>, 'x2p/a2p.pod');
159
160 # Specify here any .pm files that are actually architecture-dependent.
161 # (Those included with XS extensions under ext/ are automatically
162 # added later.)
163 # Now that the default privlib has the full perl version number included,
164 # we no longer have to play the trick of sticking version-specific .pm
165 # files under the archlib directory.
166 my %archpms = (
167     Config => 1,
168     lib => 1,
169     Cwd => 1,
170 );
171
172 if ($^O eq 'dos') {
173     push(@scripts,'djgpp/fixpmain');
174     $archpms{config} = $archpms{filehand} = 1;
175 }
176
177 if ((-e "testcompile") && (defined($ENV{'COMPILE'}))) {
178     push(@scripts, map("$_.exe", @scripts));
179 }
180
181 find(sub {
182     if ("$File::Find::dir/$_" =~ m{^ext\b(.*)/([^/]+)\.pm$}) {
183         my($path, $modname) = ($1,$2);
184
185         # strip to optional "/lib", or remove trailing component
186         $path =~ s{.*/lib\b}{} or $path =~ s{/[^/]*$}{};
187
188         # strip any leading /
189         $path =~ s{^/}{};
190
191         # reconstitute canonical module name
192         $modname = "$path/$modname" if length $path;
193
194         # remember it
195         $archpms{$modname} = 1;
196     }
197 }, 'ext');
198
199 # print "[$_]\n" for sort keys %archpms;
200
201 my $ver = $Config{version};
202 my $release = substr($],0,3);   # Not used currently.
203 my $patchlevel = substr($],3,2);
204 die "Patchlevel of perl ($patchlevel)",
205     "and patchlevel of config.sh ($Config{'PERL_VERSION'}) don't match\n"
206         if $patchlevel != $Config{'PERL_VERSION'};
207
208 # Fetch some frequently-used items from %Config
209 my $installbin = "$destdir$Config{installbin}";
210 my $installscript = "$destdir$Config{installscript}";
211 my $installprivlib = "$destdir$Config{installprivlib}";
212 my $installarchlib = "$destdir$Config{installarchlib}";
213 my $installsitelib = "$destdir$Config{installsitelib}";
214 my $installsitearch = "$destdir$Config{installsitearch}";
215 my $installman1dir = "$destdir$Config{installman1dir}";
216 my $man1ext = $Config{man1ext};
217 my $libperl = $Config{libperl};
218 # Shared library and dynamic loading suffixes.
219 my $so = $Config{so};
220 my $dlext = $Config{dlext};
221 my $dlsrc = $Config{dlsrc};
222 if ($^O eq 'os390') {
223     my $pwd;
224     chomp($pwd=`pwd`);
225     my $archlibexp = $Config{archlibexp};
226     my $usedl = $Config{usedl};
227     if ($usedl eq 'define') {
228         `./$^X -pibak -e 's{$pwd\/libperl.x}{$archlibexp/CORE/libperl.x}' lib/Config.pm`;
229     }
230 }
231
232 if ($nwinstall) {
233     # This is required only if we are installing on a NetWare server
234     $installscript = $Config{installnwscripts};
235     $installprivlib = $Config{installnwlib};
236     $installarchlib = $Config{installnwlib};
237     $installsitelib = $Config{installnwlib};
238 }
239
240 my $d_dosuid = $Config{d_dosuid};
241 my $binexp = $Config{binexp};
242
243 if ($Is_VMS) {  # Hang in there until File::Spec hits the big time
244     foreach ( \$installbin,     \$installscript,  \$installprivlib,
245               \$installarchlib, \$installsitelib, \$installsitearch,
246               \$installman1dir ) {
247         $$_ = unixify($$_);  $$_ =~ s:/$::;
248     }
249 }
250
251 # Do some quick sanity checks.
252
253 if (!$nonono && $d_dosuid && $>) { die "You must run as root to install suidperl\n"; }
254
255    $installbin          || die "No installbin directory in config.sh\n";
256 -d $installbin          || mkpath($installbin, $verbose, 0777);
257 -d $installbin          || $nonono || die "$installbin is not a directory\n";
258 -w $installbin          || $nonono || die "$installbin is not writable by you\n"
259         unless $installbin =~ m#^/afs/# || $nonono;
260
261 if (!$Is_NetWare) {
262 if (!$Is_VMS) {
263 -x 'perl' . $exe_ext    || die "perl isn't executable!\n";
264 }
265 else {
266 -x $ndbg . 'perl' . $exe_ext    || die "${ndbg}perl$exe_ext isn't executable!\n";
267     if ($dbg) {
268         -x $dbg . 'perl' . $exe_ext     || die "${dbg}perl$exe_ext isn't executable!\n";
269     }
270 }
271 -x 'suidperl' . $exe_ext|| die "suidperl isn't executable!\n" if $d_dosuid;
272
273 -f 't/rantests'         || $Is_W32
274                         || warn "WARNING: You've never run 'make test' or",
275                                 " some tests failed! (Installing anyway.)\n";
276 } #if (!$Is_NetWare)
277
278 # This will be used to store the packlist
279 my $packlist = ExtUtils::Packlist->new("$installarchlib/.packlist");
280
281 if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin) {
282     my $perldll;
283
284     if ($Is_Cygwin) {
285         $perldll = $libperl;
286         my $v_e_r_s = $ver; $v_e_r_s =~ tr/./_/;
287         $perldll =~ s/(\..*)?$/$v_e_r_s.$dlext/;
288         $perldll =~ s/^lib/cyg/;
289     } else {
290         $perldll = 'perl511.' . $dlext;
291     }
292
293     if ($dlsrc ne "dl_none.xs") {
294         -f $perldll || die "No perl DLL built\n";
295     }
296
297     # Install the DLL
298     safe_unlink("$installbin/$perldll");
299     copy("$perldll", "$installbin/$perldll");
300     chmod(0755, "$installbin/$perldll");
301     $packlist->{"$installbin/$perldll"} = { type => 'file' };
302 } # if (($Is_W32 and ! $Is_NetWare) or $Is_Cygwin)
303
304 # First we install the version-numbered executables.
305
306 if ($Is_VMS) {
307     safe_unlink("$installbin/perl_setup.com");
308     copy("perl_setup.com", "$installbin/perl_setup.com");
309     chmod(0755, "$installbin/perl_setup.com");
310     safe_unlink("$installbin/$dbg$perl$exe_ext");
311     copy("$dbg$perl$exe_ext", "$installbin/$dbg$perl$exe_ext");
312     chmod(0755, "$installbin/$dbg$perl$exe_ext");
313     safe_unlink("$installbin/$dbg${perl}shr$exe_ext");
314     copy("$dbg${perl}shr$exe_ext", "$installbin/$dbg${perl}shr$exe_ext");
315     chmod(0755, "$installbin/$dbg${perl}shr$exe_ext");
316     if ($ndbg) {
317         safe_unlink("$installbin/$ndbg$perl$exe_ext");
318         copy("$ndbg$perl$exe_ext", "$installbin/$ndbg$perl$exe_ext");
319         chmod(0755, "$installbin/$ndbg$perl$exe_ext");
320         safe_unlink("$installbin/${dbg}a2p$exe_ext");
321         copy("x2p/${dbg}a2p$exe_ext", "$installbin/${dbg}a2p$exe_ext");
322         chmod(0755, "$installbin/${dbg}a2p$exe_ext");
323     }
324 }
325 elsif ($^O eq 'mpeix') {
326     # MPE lacks hard links and requires that executables with special
327     # capabilities reside in the MPE namespace.
328     safe_unlink("$installbin/perl$ver$exe_ext", $Config{perlpath});
329     # Install the primary executable into the MPE namespace as perlpath.
330     copy("perl$exe_ext", $Config{perlpath});
331     chmod(0755, $Config{perlpath});
332     # Create a backup copy with the version number.
333     link($Config{perlpath}, "$installbin/perl$ver$exe_ext");
334 }
335 elsif ($^O ne 'dos') {
336     if (!$Is_NetWare) {
337         safe_unlink("$installbin/$perl_verbase$ver$exe_ext");
338         copy("perl$exe_ext", "$installbin/$perl_verbase$ver$exe_ext");
339         strip("$installbin/$perl_verbase$ver$exe_ext");
340         chmod(0755, "$installbin/$perl_verbase$ver$exe_ext");
341     }
342     else {
343         # If installing onto a NetWare server
344         if ($nwinstall) {
345             # Copy perl.nlm, echo.nlm, type.nlm, a2p.nlm & cgi2perl.nlm
346             mkpath($Config{installnwsystem}, 1, 0777);
347             copy("netware\\".$ENV{'MAKE_TYPE'}."\\perl.nlm", $Config{installnwsystem});
348             copy("netware\\testnlm\\echo\\echo.nlm", $Config{installnwsystem});
349             copy("netware\\testnlm\\type\\type.nlm", $Config{installnwsystem});
350             copy("x2p\\a2p.nlm", $Config{installnwsystem});
351             chmod(0755, "$Config{installnwsystem}\\perl.nlm");
352             mkpath($Config{installnwlcgi}, 1, 0777);
353             copy("lib\\auto\\cgi2perl\\cgi2perl.nlm", $Config{installnwlcgi});
354         }
355     } #if (!$Is_NetWare)
356 }
357 else {
358     safe_unlink("$installbin/$perl.exe");
359     copy("perl.exe", "$installbin/$perl.exe");
360 }
361
362 safe_unlink("$installbin/s$perl_verbase$ver$exe_ext");
363 if ($d_dosuid) {
364     copy("suidperl$exe_ext", "$installbin/s$perl_verbase$ver$exe_ext");
365     chmod(04711, "$installbin/s$perl_verbase$ver$exe_ext");
366 }
367
368 # Install library files.
369
370 my ($do_installarchlib, $do_installprivlib) = (0, 0);
371
372 mkpath($installprivlib, $verbose, 0777);
373 mkpath($installarchlib, $verbose, 0777);
374 mkpath($installsitelib, $verbose, 0777) if ($installsitelib);
375 mkpath($installsitearch, $verbose, 0777) if ($installsitearch);
376
377 if (chdir "lib") {
378     $do_installarchlib = ! samepath($installarchlib, '.');
379     $do_installprivlib = ! samepath($installprivlib, '.');
380     $do_installprivlib = 0 if $versiononly && !($installprivlib =~ m/\Q$ver/);
381
382     if ($do_installarchlib || $do_installprivlib) {
383         find(\&installlib, '.');
384     }
385     chdir ".." || die "Can't cd back to source directory: $!\n";
386 }
387 else {
388     warn "Can't cd to lib to install lib files: $!\n";
389 }
390
391 # Install header files and libraries.
392 mkpath("$installarchlib/CORE", $verbose, 0777);
393 my @corefiles;
394 if ($Is_VMS) {  # We did core file selection during build
395     my $coredir = "lib/$Config{archname}/$ver/CORE";
396     $coredir =~ tr/./_/;
397     map { s|^$coredir/||i; } @corefiles = <$coredir/*.*>;
398 }
399 else {
400     # [als] hard-coded 'libperl' name... not good!
401     @corefiles = <*.h libperl*.* perl*$Config{lib_ext}>;
402
403     # AIX needs perl.exp installed as well.
404     push(@corefiles,'perl.exp') if $^O eq 'aix';
405     if ($^O eq 'mpeix') {
406         # MPE needs mpeixish.h installed as well.
407         mkpath("$installarchlib/CORE/mpeix", $verbose, 0777);
408         push(@corefiles,'mpeix/mpeixish.h');
409     }
410     # If they have built sperl.o...
411     push(@corefiles,'sperl.o') if -f 'sperl.o';
412 }
413 foreach my $file (@corefiles) {
414     # HP-UX (at least) needs to maintain execute permissions
415     # on dynamically-loadable libraries. So we do it for all.
416     if (copy_if_diff($file,"$installarchlib/CORE/$file")) {
417         if ($file =~ /\.(\Q$so\E|\Q$dlext\E)$/) {
418             strip("-S", "$installarchlib/CORE/$file") if $^O =~ /^(rhapsody|darwin)$/;
419             chmod(0555, "$installarchlib/CORE/$file");
420         } else {
421             chmod(0444, "$installarchlib/CORE/$file");
422         }
423     }
424 }
425
426 # Install main perl executables
427 # Make links to ordinary names if installbin directory isn't current directory.
428
429 if (! $versiononly && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS && ! $Is_NetWare) {
430     safe_unlink("$installbin/$perl$exe_ext", "$installbin/suid$perl$exe_ext");
431     if ($^O eq 'mpeix') {
432         # MPE doesn't support hard links, so use a symlink.
433         # We don't want another cloned copy.
434         symlink($Config{perlpath}, "$installbin/perl$exe_ext");
435     } elsif ($^O eq 'vos') {
436         # VOS doesn't support hard links, so use a symlink.
437         symlink("$installbin/$perl_verbase$ver$exe_ext",
438                 "$installbin/$perl$exe_ext");
439     } else {
440         link("$installbin/$perl_verbase$ver$exe_ext",
441                 "$installbin/$perl$exe_ext");
442     }
443     link("$installbin/$perl_verbase$ver$exe_ext",
444             "$installbin/suid$perl$exe_ext")
445       if $d_dosuid;
446 }
447
448 # For development purposes it can be very useful to have multiple perls
449 # build for different "architectures" (eg threading or not) simultaneously.
450 if ($archname && ! samepath($installbin, '.') && ($^O ne 'dos') && ! $Is_VMS) {
451     my $archperl = "$perl_verbase$ver-$Config{archname}$exe_ext";
452     safe_unlink("$installbin/$archperl");
453     if ($^O eq 'mpeix') {
454         # MPE doesn't support hard links, so use a symlink.
455         # We don't want another cloned copy.
456         symlink($Config{perlpath}, "$installbin/$archperl");
457     } elsif ($^O eq 'vos') {
458         # VOS doesn't support hard links, so use a symlink.
459         symlink("$installbin/$perl_verbase$ver$exe_ext",
460                 "$installbin/$archperl");
461     } else {
462         link("$installbin/$perl_verbase$ver$exe_ext", "$installbin/$archperl");
463     }
464 }
465
466 # Offer to install perl in a "standard" location
467
468 my $mainperl_is_instperl = 0;
469
470 if ($Config{installusrbinperl} && $Config{installusrbinperl} eq 'define' &&
471     !$versiononly && !$nonono && !$Is_W32 && !$Is_NetWare && !$Is_VMS && -t STDIN && -t STDERR
472         && -w $mainperldir && ! samepath($mainperldir, $installbin)) {
473     my($usrbinperl)     = "$mainperldir/$perl$exe_ext";
474     my($instperl)       = "$installbin/$perl$exe_ext";
475     my($expinstperl)    = "$binexp/$perl$exe_ext";
476
477     # First make sure $usrbinperl is not already the same as the perl we
478     # just installed.
479     if (-x $usrbinperl) {
480         # Try to be clever about mainperl being a symbolic link
481         # to binexp/perl if binexp and installbin are different.
482         $mainperl_is_instperl =
483             samepath($usrbinperl, $instperl) ||
484             samepath($usrbinperl, $expinstperl) ||
485              (($binexp ne $installbin) &&
486               (-l $usrbinperl) &&
487               ((readlink $usrbinperl) eq $expinstperl));
488     }
489     if (! $mainperl_is_instperl) {
490         unlink($usrbinperl);
491         ( $Config{'d_link'} eq 'define' &&
492           eval { CORE::link $instperl, $usrbinperl } )  ||
493         eval { symlink $expinstperl, $usrbinperl }      ||
494         copy($instperl, $usrbinperl);
495
496         $mainperl_is_instperl = 1;
497     }
498 }
499
500 # Make links to ordinary names if installbin directory isn't current directory.
501 if (!$Is_NetWare && $dbg eq '') {
502     if (! samepath($installbin, 'x2p')) {
503         my $base = 'a2p';
504         $base .= $ver if $versiononly;
505         safe_unlink("$installbin/$base$exe_ext");
506         copy("x2p/a2p$exe_ext", "$installbin/$base$exe_ext");
507         strip("$installbin/$base$exe_ext");
508         chmod(0755, "$installbin/$base$exe_ext");
509     }
510 }
511
512 # cppstdin is just a script, but it is architecture-dependent, so
513 # it can't safely be shared.  Place it in $installbin.
514 # Note that Configure doesn't build cppstin if it isn't needed, so
515 # we skip this if cppstdin doesn't exist.
516 if (! $versiononly && (-f 'cppstdin') && (! samepath($installbin, '.'))) {
517     safe_unlink("$installbin/cppstdin");
518     copy("cppstdin", "$installbin/cppstdin");
519     chmod(0755, "$installbin/cppstdin");
520 }
521
522 sub script_alias {
523     my ($installscript, $orig, $alias, $scr_ext) = @_;
524
525     safe_unlink("$installscript/$alias$scr_ext");
526     if ($^O eq 'dos' or $Is_VMS or $^O eq 'transit') {
527         copy("$installscript/$orig$scr_ext",
528              "$installscript/$alias$scr_ext");
529     } elsif ($^O eq 'vos') {
530         symlink("$installscript/$orig$scr_ext",
531                 "$installscript/$alias$scr_ext");
532     } else {
533         link("$installscript/$orig$scr_ext",
534              "$installscript/$alias$scr_ext");
535     }
536 }
537
538 # Install scripts.
539 mkpath($installscript, $verbose, 0777);
540 if ($versiononly) {
541     for (@scripts) {
542         (my $base = $_) =~ s#.*/##;
543         $base .= $ver;
544         copy($_,    "$installscript/$base");
545         chmod(0755, "$installscript/$base");
546     }
547
548     for (@tolink) {
549         my ($from, $to) = map { "$_$ver" } @$_;
550         (my $frbase = $from) =~ s#.*/##;
551         (my $tobase = $to) =~ s#.*/##;
552         script_alias($installscript, $frbase, $tobase, $scr_ext);
553     }
554 } else {
555     for (@scripts) {
556         (my $base = $_) =~ s#.*/##;
557         copy($_, "$installscript/$base");
558         chmod(0755, "$installscript/$base");
559     }
560
561     for (@tolink) {
562         my ($from, $to) = @$_;
563         (my $frbase = $from) =~ s#.*/##;
564         (my $tobase = $to) =~ s#.*/##;
565         script_alias($installscript, $frbase, $tobase, $scr_ext);
566     }
567 }
568
569 # Install pod pages.  Where? I guess in $installprivlib/pod
570 # ($installprivlib/pods for cygwin).
571
572 my $pod = ($Is_Cygwin || $Is_Darwin || $Is_VMS || $Is_W32) ? 'pods' : 'pod';
573 if ( !$versiononly || ($installprivlib =~ m/\Q$ver/)) {
574     mkpath("${installprivlib}/$pod", $verbose, 0777);
575
576     # If Perl 5.003's perldiag.pod is there, rename it.
577     if (open POD, "${installprivlib}/$pod/perldiag.pod") {
578         read POD, $_, 4000;
579         close POD;
580         # Some of Perl 5.003's diagnostic messages ended with periods.
581         if (/^=.*\.$/m) {
582             my ($from, $to) = ("${installprivlib}/$pod/perldiag.pod",
583                                "${installprivlib}/$pod/perldiag-5.003.pod");
584             print "  rename $from $to";
585             rename($from, $to)
586                 or warn "Couldn't rename $from to $to: $!\n"
587                 unless $nonono;
588         }
589     }
590
591     for (@pods) {
592         # $_ is a name like  pod/perl.pod
593         (my $base = $_) =~ s#.*/##;
594         copy_if_diff($_, "${installprivlib}/$pod/${base}");
595     }
596
597 }
598
599 # Check to make sure there aren't other perls around in installer's
600 # path.  This is probably UNIX-specific.  Check all absolute directories
601 # in the path except for where public executables are supposed to live.
602 # Also skip $mainperl if the user opted to have it be a link to the
603 # installed perl.
604
605 if (!$versiononly && $otherperls) {
606     my ($path, @path);
607     my $dirsep = ($Is_OS2 || $Is_W32 || $Is_NetWare) ? ';' : ':' ;
608     ($path = $ENV{"PATH"}) =~ s:\\:/:g ;
609     @path = split(/$dirsep/, $path);
610     if ($Is_VMS) {
611         my $i = 0;
612         while (exists $ENV{'DCL$PATH' . $i}) {
613             my $dir = unixpath($ENV{'DCL$PATH' . $i});  $dir =~ s-/$--;
614             push(@path,$dir);
615         }
616     }
617     my @otherperls;
618     my %otherperls;
619     for (@path) {
620         next unless m,^/,;
621         # Use &samepath here because some systems have other dirs linked
622         # to $mainperldir (like SunOS)
623         next if samepath($_, $binexp);
624         next if samepath($_, cwd());
625         next if ($mainperl_is_instperl && samepath($_, $mainperldir));
626         my $otherperl = "$_/$perl$exe_ext";
627         next if $otherperls{$otherperl}++;
628         push(@otherperls, $otherperl)
629             if (-x $otherperl && ! -d $otherperl);
630     }
631     if (@otherperls) {
632         warn "\nWarning: $perl appears in your path in the following " .
633             "locations beyond where\nwe just installed it:\n";
634         for (@otherperls) {
635             warn "    ", $_, "\n";
636         }
637         warn "\n";
638     }
639
640 }
641
642 $packlist->write() unless $nonono;
643 print "  Installation complete\n" if $verbose;
644
645 exit 0;
646
647 ###############################################################################
648
649 sub yn {
650     my($prompt) = @_;
651     my($answer);
652     my($default) = $prompt =~ m/\[([yn])\]\s*$/i;
653     print STDERR $prompt;
654     chop($answer = <STDIN>);
655     $answer = $default if $answer =~ m/^\s*$/;
656     ($answer =~ m/^[yY]/);
657 }
658
659 sub unlink {
660     my(@names) = @_;
661     my($cnt) = 0;
662
663     return scalar(@names) if $Is_VMS;
664
665     foreach my $name (@names) {
666         next unless -e $name;
667         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_Cygwin || $Is_NetWare);
668         print "  unlink $name\n" if $verbose;
669         ( CORE::unlink($name) and ++$cnt
670           or warn "Couldn't unlink $name: $!\n" ) unless $nonono;
671     }
672     return $cnt;
673 }
674
675 sub safe_unlink {
676     return if $nonono or $Is_VMS;
677     my @names = @_;
678     foreach my $name (@names) {
679         next unless -e $name;
680         chmod 0777, $name if ($Is_OS2 || $Is_W32 || $Is_NetWare);
681         print "  unlink $name\n" if $verbose;
682         next if CORE::unlink($name);
683         warn "Couldn't unlink $name: $!\n";
684         if ($! =~ /busy/i) {
685             print "  mv $name $name.old\n" if $verbose;
686             safe_rename($name, "$name.old")
687                 or warn "Couldn't rename $name: $!\n";
688         }
689     }
690 }
691
692 sub safe_rename {
693     my($from,$to) = @_;
694     if (-f $to and not unlink($to)) {
695         my($i);
696         for ($i = 1; $i < 50; $i++) {
697             last if rename($to, "$to.$i");
698         }
699         warn("Cannot rename to `$to.$i': $!"), return 0
700            if $i >= 50; # Give up!
701     }
702     link($from,$to) || return 0;
703     unlink($from);
704 }
705
706 sub link {
707     my($from,$to) = @_;
708     my($success) = 0;
709
710     my $xfrom = $from;
711     $xfrom =~ s/^\Q$destdir\E// if $destdir;
712     my $xto = $to;
713     $xto =~ s/^\Q$destdir\E// if $destdir;
714     print $verbose ? "  ln $xfrom $xto\n" : "  $xto\n" unless $silent;
715     eval {
716         CORE::link($from, $to)
717             ? $success++
718             : ($from =~ m#^/afs/# || $to =~ m#^/afs/#)
719               ? die "AFS"  # okay inside eval {}
720               : die "Couldn't link $from to $to: $!\n"
721           unless $nonono;
722         $packlist->{$xto} = { from => $xfrom, type => 'link' };
723     };
724     if ($@) {
725         warn "Replacing link() with File::Copy::copy(): $@";
726         print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
727         print "  creating new version of $xto\n"
728                  if $Is_VMS and -e $to and !$silent;
729         unless ($nonono or File::Copy::copy($from, $to) and ++$success) {
730             # Might have been that F::C::c can't overwrite the target
731             warn "Couldn't copy $from to $to: $!\n"
732                 unless -f $to and (chmod(0666, $to), unlink $to)
733                         and File::Copy::copy($from, $to) and ++$success;
734         }
735         $packlist->{$xto} = { type => 'file' };
736     }
737     $success;
738 }
739
740 sub chmod {
741     my($mode,$name) = @_;
742
743     return if ($^O eq 'dos');
744     printf "  chmod %o %s\n", $mode, $name if $verbose;
745     CORE::chmod($mode,$name)
746         || warn sprintf("Couldn't chmod %o %s: $!\n", $mode, $name)
747       unless $nonono;
748 }
749
750 sub copy {
751     my($from,$to) = @_;
752
753     my $xto = $to;
754     $xto =~ s/^\Q$destdir\E// if $destdir;
755     print $verbose ? "  cp $from $xto\n" : "  $xto\n" unless $silent;
756     print "  creating new version of $xto\n" if $Is_VMS and -e $to and !$silent;
757     unless ($nonono or File::Copy::copy($from, $to)) {
758         # Might have been that F::C::c can't overwrite the target
759         warn "Couldn't copy $from to $to: $!\n"
760             unless -f $to and (chmod(0666, $to), unlink $to)
761                    and File::Copy::copy($from, $to);
762     }
763     $packlist->{$xto} = { type => 'file' };
764 }
765
766 sub samepath {
767     my($p1, $p2) = @_;
768
769     return (lc($p1) eq lc($p2)) if ($Is_W32 || $Is_NetWare);
770
771     if ($p1 ne $p2) {
772         my($dev1, $ino1, $dev2, $ino2);
773         ($dev1, $ino1) = stat($p1);
774         ($dev2, $ino2) = stat($p2);
775         ($dev1 == $dev2 && $ino1 == $ino2);
776     }
777     else {
778         1;
779     }
780 }
781
782 sub installlib {
783     my $dir = $File::Find::dir;
784     $dir =~ s#^\.(?![^/])/?##;
785     local($depth) = $dir ? "lib/$dir" : "lib";
786
787     my $name = $_;
788
789     # Ignore version control directories.
790     if ($name =~ /^(?:CVS|RCS|SCCS|\.svn)\z/ and -d $name) {
791         $File::Find::prune = 1;
792         return;
793     }
794
795     # ignore patch backups, RCS files, emacs backup & temp files and the
796     # .exists files, .PL files, and test files.
797     return if $name =~ m{\.orig$|\.rej$|~$|^#.+#$|,v$|^\.exists|\.PL$|\.plc$|\.t$|^test\.pl$|^dbm_filter_util.pl$} ||
798               $dir  =~ m{/t(?:/|$)};
799     # ignore the cpan script in lib/CPAN/bin, the instmodsh and xsubpp
800     # scripts in lib/ExtUtils, the prove script in lib/Test/Harness,
801     # the corelist script from lib/Module/CoreList/bin and ptar* in
802     # lib/Archive/Tar/bin, the config_data script in lib/Module/Build/scripts
803     # (they're installed later with other utils)
804     return if $name =~ /^(?:cpan|instmodsh|prove|corelist|ptar|cpan2dist|cpanp|cpanp-run-perl|ptardiff|config_data)\z/;
805     # ignore the Makefiles
806     return if $name =~ /^makefile$/i;
807     # ignore the test extensions
808     return if $dir =~ m{\bXS/(?:APItest|Typemap)\b};
809     return if $name =~ m{\b(?:APItest|Typemap)\.pm$};
810     # ignore the demo files
811     return if $dir =~ /\b(?:demos?|eg)\b/;
812
813     # ignore READMEs, MANIFESTs, INSTALL docs, META.ymls and change logs.
814     # Changes.e2x and README.e2x are needed by enc2xs.
815     return if $name =~ m{^(?:README(?:\.\w+)?)$} && $name ne 'README.e2x';
816     return if $name =~ m{^(?:MANIFEST|META\.yml)$};
817     return if $name =~ m{^(?:INSTALL|TODO|BUGS|CREDITS)$}i;
818     return if $name =~ m{^change(?:s|log)(?:\.libnet)?$}i;
819     return if $name =~ m{^(?:SIGNATURE|PAUSE200\d\.pub)$}; # CPAN files
820     return if $name =~ m{^(?:NOTES|PATCHING)$}; # ExtUtils files
821
822     # if using a shared perl library then ignore:
823     # - static library files [of statically linked extensions];
824     # - import library files and export library files (only present on Win32
825     #   anyway?) and empty bootstrap files [of dynamically linked extensions].
826     return if $Config{useshrplib} eq 'true' and
827              ($name =~ /$Config{_a}$/ or $name =~ /\.exp$/ or ($name =~ /\.bs$/ and -z $name));
828
829     $name = "$dir/$name" if $dir ne '';
830
831     my $installlib = $installprivlib;
832     if ($dir =~ /^auto/ ||
833           ($name =~ /^(.*)\.(?:pm|pod)$/ && $archpms{$1}) ||
834           ($name =~ /^(.*)\.(?:h|lib)$/i && ($Is_W32 || $Is_NetWare)) ||
835           $name eq 'Config_heavy.pl'
836        ) {
837         $installlib = $installarchlib;
838         return unless $do_installarchlib;
839     } else {
840         return unless $do_installprivlib;
841     }
842
843     if (-f $_) {
844         if (/\.(?:al|ix)$/ && !($dir =~ m[^auto/(.*)$])) {
845             $installlib = $installprivlib;
846             #We're installing *.al and *.ix files into $installprivlib,
847             #but we have to delete old *.al and *.ix files from the 5.000
848             #distribution:
849             #This might not work because $archname might have changed.
850             unlink("$installarchlib/$name");
851         }
852         my $xname = "$installlib/$name";
853         $xname =~ s/^\Q$destdir\E// if $destdir;
854         $packlist->{$xname} = { type => 'file' };
855         if ($force || compare($_, "$installlib/$name") || $nonono) {
856             unlink("$installlib/$name");
857             mkpath("$installlib/$dir", $verbose, 0777);
858             # HP-UX (at least) needs to maintain execute permissions
859             # on dynamically-loaded libraries.
860             if ($Is_NetWare && !$nwinstall) {
861                 # Don't copy .nlp,.nlm files, doesn't make sense on Windows and also
862                 # if copied will give problems when building new extensions.
863                 # Has to be copied if we are installing on a NetWare server and hence
864                 # the check !$nwinstall
865                 if (!(/\.(?:nlp|nlm|bs)$/)) {
866                     copy_if_diff($_, "$installlib/$name")
867                         and chmod($name =~ /\.(so|$dlext)$/o ? 0555 : 0444,
868                                   "$installlib/$name");
869                 }
870            } else {
871                 if (copy_if_diff($_, "$installlib/$name")) {
872                     if ($name =~ /\.(so|$dlext)$/o) {
873                         strip("-S", "$installlib/$name") if $^O =~ /^(rhapsody|darwin)$/;
874                         chmod(0555, "$installlib/$name");
875                     } else {
876                         strip("-S", "$installlib/$name")
877                             if ($name =~ /\.a$/o and $^O =~ /^(rhapsody|darwin)$/);
878                         chmod(0444, "$installlib/$name");
879                     }
880                 }
881             } #if ($Is_NetWare)
882         }
883     }
884 }
885
886 # Copy $from to $to, only if $from is different than $to.
887 # Also preserve modification times for .a libraries.
888 # On some systems, if you do
889 #   ranlib libperl.a
890 #   cp libperl.a /usr/local/lib/perl5/archlib/CORE/libperl.a
891 # and then try to link against the installed libperl.a, you might
892 # get an error message to the effect that the symbol table is older
893 # than the library.
894 # Return true if copying occurred.
895
896 sub copy_if_diff {
897     my($from,$to)=@_;
898     return 1 if (($^O eq 'VMS') && (-d $from));
899     my $xto = $to;
900     $xto =~ s/^\Q$destdir\E// if $destdir;
901     my $perlpodbadsymlink;
902     if ($from =~ m!^pod/perl[\w-]+\.pod$! &&
903         -l $from &&
904         ! -e $from) {
905         # Some Linux implementations have problems traversing over
906         # multiple symlinks (when going over NFS?) and fail to read
907         # the symlink target.  Combine this with the fact that some
908         # of the pod files (the perl$OS.pod) are symlinks (to ../README.$OS),
909         # and you end up with those pods not getting installed.
910         $perlpodbadsymlink = 1;
911     }
912     -f $from || $perlpodbadsymlink || warn "$0: $from not found";
913     $packlist->{$xto} = { type => 'file' };
914     if ($force || compare($from, $to) || $nonono) {
915         safe_unlink($to);   # In case we don't have write permissions.
916         if ($nonono) {
917             $from = $depth . "/" . $from if $depth;
918         }
919         if ($perlpodbadsymlink && $from =~ m!^pod/perl(.+)\.pod$!) {
920             $from = "README.$1";
921         }
922         copy($from, $to);
923         # Restore timestamps if it's a .a library or for OS/2.
924         if (!$nonono && ($Is_OS2 || $to =~ /\.a$/)) {
925             my ($atime, $mtime) = (stat $from)[8,9];
926             utime $atime, $mtime, $to;
927         }
928         1;
929     }
930 }
931
932 sub strip
933 {
934     my(@args) = @_;
935
936     return unless $dostrip;
937
938     my @opts;
939     while (@args && $args[0] =~ /^(-\w+)$/) {
940         push @opts, shift @args;
941     }
942
943     foreach my $file (@args) {
944         if (-f $file) {
945             if ($verbose) {
946                 print "  strip " . join(' ', @opts);
947                 print " " if (@opts);
948                 print "$file\n";
949             }
950             system("strip", @opts, $file);
951         } else {
952             print "# file '$file' skipped\n" if $verbose;
953         }
954     }
955 }