use strict by default if "use 5.011" is in effect!
[perl.git] / t / comp / use.t
1 #!./perl
2
3 BEGIN {
4     chdir 't' if -d 't';
5     @INC = '../lib';
6     $INC{"feature.pm"} = 1; # so we don't attempt to load feature.pm
7 }
8
9 print "1..65\n";
10
11 # Can't require test.pl, as we're testing the use/require mechanism here.
12
13 my $test = 1;
14
15 sub _ok {
16     my ($type, $got, $expected, $name) = @_;
17
18     my $result;
19     if ($type eq 'is') {
20         $result = $got eq $expected;
21     } elsif ($type eq 'isnt') {
22         $result = $got ne $expected;
23     } elsif ($type eq 'like') {
24         $result = $got =~ $expected;
25     } else {
26         die "Unexpected type '$type'$name";
27     }
28     if ($result) {
29         if ($name) {
30             print "ok $test - $name\n";
31         } else {
32             print "ok $test\n";
33         }
34     } else {
35         if ($name) {
36             print "not ok $test - $name\n";
37         } else {
38             print "not ok $test\n";
39         }
40         my @caller = caller(2);
41         print "# Failed test at $caller[1] line $caller[2]\n";
42         print "# Got      '$got'\n";
43         if ($type eq 'is') {
44             print "# Expected '$expected'\n";
45         } elsif ($type eq 'isnt') {
46             print "# Expected not '$expected'\n";
47         } elsif ($type eq 'like') {
48             print "# Expected $expected\n";
49         }
50     }
51     $test = $test + 1;
52     $result;
53 }
54
55 sub like ($$;$) {
56     _ok ('like', @_);
57 }
58 sub is ($$;$) {
59     _ok ('is', @_);
60 }
61 sub isnt ($$;$) {
62     _ok ('isnt', @_);
63 }
64
65 eval "use 5.000";       # implicit semicolon
66 is ($@, '');
67
68 eval "use 5.000;";
69 is ($@, '');
70
71 eval "use 6.000;";
72 like ($@, qr/Perl v6\.0\.0 required--this is only \Q$^V\E, stopped/);
73
74 eval "no 6.000;";
75 is ($@, '');
76
77 eval "no 5.000;";
78 like ($@, qr/Perls since v5\.0\.0 too modern--this is \Q$^V\E, stopped/);
79
80 eval "use 5.6;";
81 like ($@, qr/Perl v5\.600\.0 required \(did you mean v5\.6\.0\?\)--this is only \Q$^V\E, stopped/);
82
83 eval "use 5.8;";
84 like ($@, qr/Perl v5\.800\.0 required \(did you mean v5\.8\.0\?\)--this is only \Q$^V\E, stopped/);
85
86 eval "use 5.9;";
87 like ($@, qr/Perl v5\.900\.0 required \(did you mean v5\.9\.0\?\)--this is only \Q$^V\E, stopped/);
88
89 eval "use 5.10;";
90 like ($@, qr/Perl v5\.100\.0 required \(did you mean v5\.10\.0\?\)--this is only \Q$^V\E, stopped/);
91
92 eval "use 5.11;";
93 like ($@, qr/Perl v5\.110\.0 required \(did you mean v5\.11\.0\?\)--this is only \Q$^V\E, stopped/);
94
95 eval sprintf "use %.6f;", $];
96 is ($@, '');
97
98
99 eval sprintf "use %.6f;", $] - 0.000001;
100 is ($@, '');
101
102 eval sprintf("use %.6f;", $] + 1);
103 like ($@, qr/Perl v6.\d+.\d+ required--this is only \Q$^V\E, stopped/);
104
105 eval sprintf "use %.6f;", $] + 0.00001;
106 like ($@, qr/Perl v5.\d+.\d+ required--this is only \Q$^V\E, stopped/);
107
108 # check that "use 5.11.0" (and higher) loads strictures
109 eval 'use 5.11.0; ${"foo"} = "bar";';
110 like ($@, qr/Can't use string \("foo"\) as a SCALAR ref while "strict refs" in use/);
111
112 { use lib }     # check that subparse saves pending tokens
113
114 local $lib::VERSION = 1.0;
115
116 eval "use lib 0.9";
117 is ($@, '');
118
119 eval "use lib 1.0";
120 is ($@, '');
121
122 eval "use lib 1.01";
123 isnt ($@, '');
124
125
126 eval "use lib 0.9 qw(fred)";
127 is ($@, '');
128
129 if ($^O eq 'MacOS') {
130     is($INC[0], ":fred:");
131 } else {
132     is($INC[0], "fred");
133 }
134
135 eval "use lib 1.0 qw(joe)";
136 is ($@, '');
137
138
139 if ($^O eq 'MacOS') {
140     is($INC[0], ":joe:");
141 } else {
142     is($INC[0], "joe");
143 }
144
145
146 eval "use lib 1.01 qw(freda)";
147 isnt($@, '');
148
149 if ($^O eq 'MacOS') {
150     isnt($INC[0], ":freda:");
151 } else {
152     isnt($INC[0], "freda");
153 }
154
155 {
156     local $lib::VERSION = 35.36;
157     eval "use lib v33.55";
158     is ($@, '');
159
160     eval "use lib v100.105";
161     like ($@, qr/lib version v100.105.0 required--this is only version v35\.360\.0/);
162
163     eval "use lib 33.55";
164     is ($@, '');
165
166     eval "use lib 100.105";
167     like ($@, qr/lib version 100.105 required--this is only version 35.36/);
168
169     local $lib::VERSION = '35.36';
170     eval "use lib v33.55";
171     like ($@, '');
172
173     eval "use lib v100.105";
174     like ($@, qr/lib version v100.105.0 required--this is only version v35\.360\.0/);
175
176     eval "use lib 33.55";
177     is ($@, '');
178
179     eval "use lib 100.105";
180     like ($@, qr/lib version 100.105 required--this is only version 35.36/);
181
182     local $lib::VERSION = v35.36;
183     eval "use lib v33.55";
184     is ($@, '');
185
186     eval "use lib v100.105";
187     like ($@, qr/lib version v100.105.0 required--this is only version v35\.36\.0/);
188
189     eval "use lib 33.55";
190     is ($@, '');
191
192     eval "use lib 100.105";
193     like ($@, qr/lib version 100.105 required--this is only version v35.36/);
194 }
195
196
197 {
198     # Regression test for patch 14937: 
199     #   Check that a .pm file with no package or VERSION doesn't core.
200     open F, ">xxx$$.pm" or die "Cannot open xxx$$.pm: $!\n";
201     print F "1;\n";
202     close F;
203     eval "use lib '.'; use xxx$$ 3;";
204     like ($@, qr/^xxx$$ defines neither package nor VERSION--version check failed at/);
205     unlink "xxx$$.pm";
206 }
207
208 my @ver = split /\./, sprintf "%vd", $^V;
209
210 foreach my $index (-3..+3) {
211     foreach my $v (0, 1) {
212         my @parts = @ver;
213         if ($index) {
214             if ($index < 0) {
215                 # Jiggle one of the parts down
216                 --$parts[-$index - 1];
217                 if ($parts[-$index - 1] < 0) {
218                     # perl's version number ends with '.0'
219                     $parts[-$index - 1] = 0;
220                     $parts[-$index - 2] -= 2;
221                 }
222             } else {
223                 # Jiggle one of the parts up
224                 ++$parts[$index - 1];
225             }
226         }
227         my $v_version = sprintf "v%d.%d.%d", @parts;
228         my $version;
229         if ($v) {
230             $version = $v_version;
231         } else {
232             $version = $parts[0] + $parts[1] / 1000 + $parts[2] / 1000000;
233         }
234
235         eval "use $version";
236         if ($index > 0) {
237             # The future
238             like ($@,
239                   qr/Perl $v_version required--this is only \Q$^V\E, stopped/,
240                   "use $version");
241         } else {
242             # The present or past
243             is ($@, '', "use $version");
244         }
245
246         eval "no $version";
247         if ($index <= 0) {
248             # The present or past
249             like ($@,
250                   qr/Perls since $v_version too modern--this is \Q$^V\E, stopped/,
251                   "no $version");
252         } else {
253             # future
254             is ($@, '', "no $version");
255         }
256     }
257 }
258